Use primop wrappers instead of tagToEnum#
[packages/base.git] / GHC / Ptr.lhs
1 \begin{code}
2 {-# LANGUAGE Unsafe #-}
3 {-# LANGUAGE CPP, NoImplicitPrelude, MagicHash, RoleAnnotations #-}
4 {-# OPTIONS_HADDOCK hide #-}
5
6 -----------------------------------------------------------------------------
7 -- |
8 -- Module      :  GHC.Ptr
9 -- Copyright   :  (c) The FFI Task Force, 2000-2002
10 -- License     :  see libraries/base/LICENSE
11 -- 
12 -- Maintainer  :  ffi@haskell.org
13 -- Stability   :  internal
14 -- Portability :  non-portable (GHC Extensions)
15 --
16 -- The 'Ptr' and 'FunPtr' types and operations.
17 --
18 -----------------------------------------------------------------------------
19
20 -- #hide
21 module GHC.Ptr (
22         Ptr(..), FunPtr(..),
23         nullPtr, castPtr, plusPtr, alignPtr, minusPtr,
24         nullFunPtr, castFunPtr,
25
26         -- * Unsafe functions
27         castFunPtrToPtr, castPtrToFunPtr
28     ) where
29
30 import GHC.Base
31 import GHC.Show
32 import GHC.Num
33 import GHC.List ( length, replicate )
34 import Numeric          ( showHex )
35
36 #include "MachDeps.h"
37
38 ------------------------------------------------------------------------
39 -- Data pointers.
40
41 data Ptr a@R = Ptr Addr# deriving (Eq, Ord)
42 -- ^ A value of type @'Ptr' a@ represents a pointer to an object, or an
43 -- array of objects, which may be marshalled to or from Haskell values
44 -- of type @a@.
45 --
46 -- The type @a@ will often be an instance of class
47 -- 'Foreign.Storable.Storable' which provides the marshalling operations.
48 -- However this is not essential, and you can provide your own operations
49 -- to access the pointer.  For example you might write small foreign
50 -- functions to get or set the fields of a C @struct@.
51
52 -- |The constant 'nullPtr' contains a distinguished value of 'Ptr'
53 -- that is not associated with a valid memory location.
54 nullPtr :: Ptr a
55 nullPtr = Ptr nullAddr#
56
57 -- |The 'castPtr' function casts a pointer from one type to another.
58 castPtr :: Ptr a -> Ptr b
59 castPtr (Ptr addr) = Ptr addr
60
61 -- |Advances the given address by the given offset in bytes.
62 plusPtr :: Ptr a -> Int -> Ptr b
63 plusPtr (Ptr addr) (I# d) = Ptr (plusAddr# addr d)
64
65 -- |Given an arbitrary address and an alignment constraint,
66 -- 'alignPtr' yields the next higher address that fulfills the
67 -- alignment constraint.  An alignment constraint @x@ is fulfilled by
68 -- any address divisible by @x@.  This operation is idempotent.
69 alignPtr :: Ptr a -> Int -> Ptr a
70 alignPtr addr@(Ptr a) (I# i)
71   = case remAddr# a i of {
72       0# -> addr;
73       n -> Ptr (plusAddr# a (i -# n)) }
74
75 -- |Computes the offset required to get from the second to the first
76 -- argument.  We have 
77 --
78 -- > p2 == p1 `plusPtr` (p2 `minusPtr` p1)
79 minusPtr :: Ptr a -> Ptr b -> Int
80 minusPtr (Ptr a1) (Ptr a2) = I# (minusAddr# a1 a2)
81
82 ------------------------------------------------------------------------
83 -- Function pointers for the default calling convention.
84
85 data FunPtr a@R = FunPtr Addr# deriving (Eq, Ord)
86 -- ^ A value of type @'FunPtr' a@ is a pointer to a function callable
87 -- from foreign code.  The type @a@ will normally be a /foreign type/,
88 -- a function type with zero or more arguments where
89 --
90 -- * the argument types are /marshallable foreign types/,
91 --   i.e. 'Char', 'Int', 'Double', 'Float',
92 --   'Bool', 'Data.Int.Int8', 'Data.Int.Int16', 'Data.Int.Int32',
93 --   'Data.Int.Int64', 'Data.Word.Word8', 'Data.Word.Word16',
94 --   'Data.Word.Word32', 'Data.Word.Word64', @'Ptr' a@, @'FunPtr' a@,
95 --   @'Foreign.StablePtr.StablePtr' a@ or a renaming of any of these
96 --   using @newtype@.
97 -- 
98 -- * the return type is either a marshallable foreign type or has the form
99 --   @'IO' t@ where @t@ is a marshallable foreign type or @()@.
100 --
101 -- A value of type @'FunPtr' a@ may be a pointer to a foreign function,
102 -- either returned by another foreign function or imported with a
103 -- a static address import like
104 --
105 -- > foreign import ccall "stdlib.h &free"
106 -- >   p_free :: FunPtr (Ptr a -> IO ())
107 --
108 -- or a pointer to a Haskell function created using a /wrapper/ stub
109 -- declared to produce a 'FunPtr' of the correct type.  For example:
110 --
111 -- > type Compare = Int -> Int -> Bool
112 -- > foreign import ccall "wrapper"
113 -- >   mkCompare :: Compare -> IO (FunPtr Compare)
114 --
115 -- Calls to wrapper stubs like @mkCompare@ allocate storage, which
116 -- should be released with 'Foreign.Ptr.freeHaskellFunPtr' when no
117 -- longer required.
118 --
119 -- To convert 'FunPtr' values to corresponding Haskell functions, one
120 -- can define a /dynamic/ stub for the specific foreign type, e.g.
121 --
122 -- > type IntFunction = CInt -> IO ()
123 -- > foreign import ccall "dynamic" 
124 -- >   mkFun :: FunPtr IntFunction -> IntFunction
125
126 -- |The constant 'nullFunPtr' contains a
127 -- distinguished value of 'FunPtr' that is not
128 -- associated with a valid memory location.
129 nullFunPtr :: FunPtr a
130 nullFunPtr = FunPtr nullAddr#
131
132 -- |Casts a 'FunPtr' to a 'FunPtr' of a different type.
133 castFunPtr :: FunPtr a -> FunPtr b
134 castFunPtr (FunPtr addr) = FunPtr addr
135
136 -- |Casts a 'FunPtr' to a 'Ptr'.
137 --
138 -- /Note:/ this is valid only on architectures where data and function
139 -- pointers range over the same set of addresses, and should only be used
140 -- for bindings to external libraries whose interface already relies on
141 -- this assumption.
142 castFunPtrToPtr :: FunPtr a -> Ptr b
143 castFunPtrToPtr (FunPtr addr) = Ptr addr
144
145 -- |Casts a 'Ptr' to a 'FunPtr'.
146 --
147 -- /Note:/ this is valid only on architectures where data and function
148 -- pointers range over the same set of addresses, and should only be used
149 -- for bindings to external libraries whose interface already relies on
150 -- this assumption.
151 castPtrToFunPtr :: Ptr a -> FunPtr b
152 castPtrToFunPtr (Ptr addr) = FunPtr addr
153
154
155 ------------------------------------------------------------------------
156 -- Show instances for Ptr and FunPtr
157
158 instance Show (Ptr a) where
159    showsPrec _ (Ptr a) rs = pad_out (showHex (wordToInteger(int2Word#(addr2Int# a))) "")
160      where
161         -- want 0s prefixed to pad it out to a fixed length.
162        pad_out ls = 
163           '0':'x':(replicate (2*SIZEOF_HSPTR - length ls) '0') ++ ls ++ rs
164
165 instance Show (FunPtr a) where
166    showsPrec p = showsPrec p . castFunPtrToPtr
167
168 \end{code}