Add missing aarch64 configury bits
[libffi.git] / configure.ac
1 dnl Process this with autoconf to create configure
2
3 AC_PREREQ(2.68)
4
5 AC_INIT([libffi], [3.0.11], [http://github.com/atgreen/libffi/issues])
6 AC_CONFIG_HEADERS([fficonfig.h])
7
8 AC_CANONICAL_SYSTEM
9 target_alias=${target_alias-$host_alias}
10
11 . ${srcdir}/configure.host
12
13 AX_ENABLE_BUILDDIR
14
15 AM_INIT_AUTOMAKE
16
17 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
18 # We must force CC to /not/ be precious variables; otherwise
19 # the wrong, non-multilib-adjusted value will be used in multilibs.
20 # As a side effect, we have to subst CFLAGS ourselves.
21 # Also save and restore CFLAGS, since AC_PROG_CC will come up with
22 # defaults of its own if none are provided.
23
24 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
25 m4_define([_AC_ARG_VAR_PRECIOUS],[])
26 save_CFLAGS=$CFLAGS
27 AC_PROG_CC
28 CFLAGS=$save_CFLAGS
29 m4_undefine([_AC_ARG_VAR_PRECIOUS])
30 m4_rename([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
31
32 AC_SUBST(CFLAGS)
33
34 AM_PROG_AS
35 AM_PROG_CC_C_O
36 AC_PROG_LIBTOOL
37 AC_CONFIG_MACRO_DIR([m4])
38
39 AX_CC_MAXOPT
40 AX_CFLAGS_WARN_ALL
41 if test "x$GCC" = "xyes"; then
42   CFLAGS="$CFLAGS -fexceptions"
43 fi
44
45 AM_MAINTAINER_MODE
46
47 AC_CHECK_HEADERS(sys/mman.h)
48 AC_CHECK_FUNCS(mmap)
49 AC_FUNC_MMAP_BLACKLIST
50
51 dnl The -no-testsuite modules omit the test subdir.
52 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
53
54 TARGETDIR="unknown"
55 case "$host" in
56   aarch64*-*-*)
57         TARGET=AARCH64; TARGETDIR=aarch64
58         ;;
59
60   alpha*-*-*)
61         TARGET=ALPHA; TARGETDIR=alpha;
62         # Support 128-bit long double, changeable via command-line switch.
63         HAVE_LONG_DOUBLE='defined(__LONG_DOUBLE_128__)'
64         ;;
65
66   arm*-*-*)
67         TARGET=ARM; TARGETDIR=arm
68         ;;
69
70   amd64-*-freebsd* | amd64-*-openbsd*)
71         TARGET=X86_64; TARGETDIR=x86
72         ;;
73
74   amd64-*-freebsd*)
75         TARGET=X86_64; TARGETDIR=x86
76         ;;
77
78   avr32*-*-*)
79         TARGET=AVR32; TARGETDIR=avr32
80         ;;
81
82   bfin*)
83         TARGET=BFIN; TARGETDIR=bfin
84         ;;
85
86   cris-*-*)
87         TARGET=LIBFFI_CRIS; TARGETDIR=cris
88         ;;
89
90   frv-*-*)
91         TARGET=FRV; TARGETDIR=frv
92         ;;
93
94   hppa*-*-linux* | parisc*-*-linux* | hppa*-*-openbsd*)
95         TARGET=PA_LINUX; TARGETDIR=pa
96         ;;
97   hppa*64-*-hpux*)
98         TARGET=PA64_HPUX; TARGETDIR=pa
99         ;;
100   hppa*-*-hpux*)
101         TARGET=PA_HPUX; TARGETDIR=pa
102         ;;
103
104   i?86-*-freebsd* | i?86-*-openbsd*)
105         TARGET=X86_FREEBSD; TARGETDIR=x86
106         ;;
107   i?86-win32* | i?86-*-cygwin* | i?86-*-mingw* | i?86-*-os2* | i?86-*-interix*)
108         TARGET=X86_WIN32; TARGETDIR=x86
109         # All mingw/cygwin/win32 builds require -no-undefined for sharedlib.
110         # We must also check with_cross_host to decide if this is a native
111         # or cross-build and select where to install dlls appropriately.
112         if test -n "$with_cross_host" &&
113            test x"$with_cross_host" != x"no"; then
114           AM_LTLDFLAGS='-no-undefined -bindir "$(toolexeclibdir)"';
115         else
116           AM_LTLDFLAGS='-no-undefined -bindir "$(bindir)"';
117         fi
118         ;;
119   i?86-*-darwin*)
120         TARGET=X86_DARWIN; TARGETDIR=x86
121         ;;
122   i?86-*-solaris2.1[[0-9]]*)
123         TARGET=X86_64; TARGETDIR=x86
124         ;;
125   i?86-*-*)
126         TARGET=X86_64; TARGETDIR=x86
127         ;;
128
129   ia64*-*-*)
130         TARGET=IA64; TARGETDIR=ia64
131         ;;
132
133   m32r*-*-*)
134         TARGET=M32R; TARGETDIR=m32r
135         ;;
136
137   m68k-*-*)
138         TARGET=M68K; TARGETDIR=m68k
139         ;;
140
141   mips-sgi-irix5.* | mips-sgi-irix6.* | mips*-*-rtems*)
142         TARGET=MIPS; TARGETDIR=mips
143         ;;
144   mips*-*-linux* | mips*-*-openbsd*)
145         # Support 128-bit long double for NewABI.
146         HAVE_LONG_DOUBLE='defined(__mips64)'
147         TARGET=MIPS; TARGETDIR=mips
148         ;;
149
150   moxie-*-*)
151         TARGET=MOXIE; TARGETDIR=moxie
152         ;;
153
154   powerpc*-*-linux* | powerpc-*-sysv*)
155         TARGET=POWERPC; TARGETDIR=powerpc
156         ;;
157   powerpc-*-amigaos*)
158         TARGET=POWERPC; TARGETDIR=powerpc
159         ;;
160   powerpc-*-beos*)
161         TARGET=POWERPC; TARGETDIR=powerpc
162         ;;
163   powerpc-*-darwin* | powerpc64-*-darwin*)
164         TARGET=POWERPC_DARWIN; TARGETDIR=powerpc
165         ;;
166   powerpc-*-aix* | rs6000-*-aix*)
167         TARGET=POWERPC_AIX; TARGETDIR=powerpc
168         ;;
169   powerpc-*-freebsd* | powerpc-*-openbsd*)
170         TARGET=POWERPC_FREEBSD; TARGETDIR=powerpc
171         ;;
172   powerpc64-*-freebsd*)
173         TARGET=POWERPC; TARGETDIR=powerpc
174         ;;
175   powerpc*-*-rtems*)
176         TARGET=POWERPC; TARGETDIR=powerpc
177         ;;
178
179   s390-*-* | s390x-*-*)
180         TARGET=S390; TARGETDIR=s390
181         ;;
182
183   sh-*-* | sh[[34]]*-*-*)
184         TARGET=SH; TARGETDIR=sh
185         ;;
186   sh64-*-* | sh5*-*-*)
187         TARGET=SH64; TARGETDIR=sh64
188         ;;
189
190   sparc*-*-*)
191         TARGET=SPARC; TARGETDIR=sparc
192         ;;
193
194   tile*-*)
195         TARGET=TILE; TARGETDIR=tile
196         ;;
197
198   x86_64-*-darwin*)
199         TARGET=X86_DARWIN; TARGETDIR=x86
200         ;;
201
202   x86_64-*-cygwin* | x86_64-*-mingw*)
203         TARGET=X86_WIN64; TARGETDIR=x86
204         # All mingw/cygwin/win32 builds require -no-undefined for sharedlib.
205         # We must also check with_cross_host to decide if this is a native
206         # or cross-build and select where to install dlls appropriately.
207         if test -n "$with_cross_host" &&
208            test x"$with_cross_host" != x"no"; then
209           AM_LTLDFLAGS='-no-undefined -bindir "$(toolexeclibdir)"';
210         else
211           AM_LTLDFLAGS='-no-undefined -bindir "$(bindir)"';
212         fi
213         ;;
214
215   x86_64-*-*)
216         TARGET=X86_64; TARGETDIR=x86
217         ;;
218 esac
219
220 AC_SUBST(AM_RUNTESTFLAGS)
221 AC_SUBST(AM_LTLDFLAGS)
222
223 if test $TARGETDIR = unknown; then
224   AC_MSG_ERROR(["libffi has not been ported to $host."])
225 fi
226
227 AM_CONDITIONAL(MIPS, test x$TARGET = xMIPS)
228 AM_CONDITIONAL(BFIN, test x$TARGET = xBFIN)
229 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
230 AM_CONDITIONAL(X86, test x$TARGET = xX86)
231 AM_CONDITIONAL(X86_FREEBSD, test x$TARGET = xX86_FREEBSD)
232 AM_CONDITIONAL(X86_WIN32, test x$TARGET = xX86_WIN32)
233 AM_CONDITIONAL(X86_WIN64, test x$TARGET = xX86_WIN64)
234 AM_CONDITIONAL(X86_DARWIN, test x$TARGET = xX86_DARWIN)
235 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
236 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
237 AM_CONDITIONAL(M32R, test x$TARGET = xM32R)
238 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
239 AM_CONDITIONAL(MOXIE, test x$TARGET = xMOXIE)
240 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
241 AM_CONDITIONAL(POWERPC_AIX, test x$TARGET = xPOWERPC_AIX)
242 AM_CONDITIONAL(POWERPC_DARWIN, test x$TARGET = xPOWERPC_DARWIN)
243 AM_CONDITIONAL(POWERPC_FREEBSD, test x$TARGET = xPOWERPC_FREEBSD)
244 AM_CONDITIONAL(AARCH64, test x$TARGET = xAARCH64)
245 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
246 AM_CONDITIONAL(AVR32, test x$TARGET = xAVR32)
247 AM_CONDITIONAL(LIBFFI_CRIS, test x$TARGET = xLIBFFI_CRIS)
248 AM_CONDITIONAL(FRV, test x$TARGET = xFRV)
249 AM_CONDITIONAL(S390, test x$TARGET = xS390)
250 AM_CONDITIONAL(X86_64, test x$TARGET = xX86_64)
251 AM_CONDITIONAL(SH, test x$TARGET = xSH)
252 AM_CONDITIONAL(SH64, test x$TARGET = xSH64)
253 AM_CONDITIONAL(PA_LINUX, test x$TARGET = xPA_LINUX)
254 AM_CONDITIONAL(PA_HPUX, test x$TARGET = xPA_HPUX)
255 AM_CONDITIONAL(PA64_HPUX, test x$TARGET = xPA64_HPUX)
256 AM_CONDITIONAL(TILE, test x$TARGET = xTILE)
257
258 AC_HEADER_STDC
259 AC_CHECK_FUNCS(memcpy)
260 AC_FUNC_ALLOCA
261
262 AC_CHECK_SIZEOF(double)
263 AC_CHECK_SIZEOF(long double)
264
265 # Also AC_SUBST this variable for ffi.h.
266 if test -z "$HAVE_LONG_DOUBLE"; then
267   HAVE_LONG_DOUBLE=0
268   if test $ac_cv_sizeof_double != $ac_cv_sizeof_long_double; then
269     if test $ac_cv_sizeof_long_double != 0; then
270       HAVE_LONG_DOUBLE=1
271       AC_DEFINE(HAVE_LONG_DOUBLE, 1, [Define if you have the long double type and it is bigger than a double])
272     fi
273   fi
274 fi
275 AC_SUBST(HAVE_LONG_DOUBLE)
276
277 AC_C_BIGENDIAN
278
279 GCC_AS_CFI_PSEUDO_OP
280
281 if test x$TARGET = xSPARC; then
282     AC_CACHE_CHECK([assembler and linker support unaligned pc related relocs],
283         libffi_cv_as_sparc_ua_pcrel, [
284         save_CFLAGS="$CFLAGS"
285         save_LDFLAGS="$LDFLAGS"
286         CFLAGS="$CFLAGS -fpic"
287         LDFLAGS="$LDFLAGS -shared"
288         AC_TRY_LINK([asm (".text; foo: nop; .data; .align 4; .byte 0; .uaword %r_disp32(foo); .text");],,
289                     [libffi_cv_as_sparc_ua_pcrel=yes],
290                     [libffi_cv_as_sparc_ua_pcrel=no])
291         CFLAGS="$save_CFLAGS"
292         LDFLAGS="$save_LDFLAGS"])
293     if test "x$libffi_cv_as_sparc_ua_pcrel" = xyes; then
294         AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
295                   [Define if your assembler and linker support unaligned PC relative relocs.])
296     fi
297
298     AC_CACHE_CHECK([assembler .register pseudo-op support],
299        libffi_cv_as_register_pseudo_op, [
300        libffi_cv_as_register_pseudo_op=unknown
301        # Check if we have .register
302        AC_TRY_COMPILE([asm (".register %g2, #scratch");],,
303                        [libffi_cv_as_register_pseudo_op=yes],
304                        [libffi_cv_as_register_pseudo_op=no])
305     ])
306     if test "x$libffi_cv_as_register_pseudo_op" = xyes; then
307        AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
308                [Define if your assembler supports .register.])
309     fi
310 fi
311
312 if test x$TARGET = xX86 || test x$TARGET = xX86_WIN32 || test x$TARGET = xX86_64; then
313     AC_CACHE_CHECK([assembler supports pc related relocs],
314         libffi_cv_as_x86_pcrel, [
315         libffi_cv_as_x86_pcrel=yes
316         echo '.text; foo: nop; .data; .long foo-.; .text' > conftest.s
317         if $CC $CFLAGS -c conftest.s 2>&1 | $EGREP -i 'illegal|warning' > /dev/null; then
318             libffi_cv_as_x86_pcrel=no
319         fi
320         ])
321     if test "x$libffi_cv_as_x86_pcrel" = xyes; then
322         AC_DEFINE(HAVE_AS_X86_PCREL, 1,
323                   [Define if your assembler supports PC relative relocs.])
324     fi
325
326     AC_CACHE_CHECK([assembler .ascii pseudo-op support],
327        libffi_cv_as_ascii_pseudo_op, [
328        libffi_cv_as_ascii_pseudo_op=unknown
329        # Check if we have .ascii
330        AC_TRY_COMPILE([asm (".ascii \\"string\\"");],,
331                        [libffi_cv_as_ascii_pseudo_op=yes],
332                        [libffi_cv_as_ascii_pseudo_op=no])
333     ])
334     if test "x$libffi_cv_as_ascii_pseudo_op" = xyes; then
335        AC_DEFINE(HAVE_AS_ASCII_PSEUDO_OP, 1,
336                [Define if your assembler supports .ascii.])
337     fi
338
339     AC_CACHE_CHECK([assembler .string pseudo-op support],
340        libffi_cv_as_string_pseudo_op, [
341        libffi_cv_as_string_pseudo_op=unknown
342        # Check if we have .string
343        AC_TRY_COMPILE([asm (".string \\"string\\"");],,
344                        [libffi_cv_as_string_pseudo_op=yes],
345                        [libffi_cv_as_string_pseudo_op=no])
346     ])
347     if test "x$libffi_cv_as_string_pseudo_op" = xyes; then
348        AC_DEFINE(HAVE_AS_STRING_PSEUDO_OP, 1,
349                [Define if your assembler supports .string.])
350     fi
351 fi
352
353 if test x$TARGET = xX86_WIN64; then
354     LT_SYS_SYMBOL_USCORE
355     if test "x$sys_symbol_underscore" = xyes; then
356         AC_DEFINE(SYMBOL_UNDERSCORE, 1, [Define if symbols are underscored.])
357     fi
358 fi
359
360 # On PaX enable kernels that have MPROTECT enable we can't use PROT_EXEC.
361 AC_ARG_ENABLE(pax_emutramp,
362   [  --enable-pax_emutramp       enable pax emulated trampolines, for we can't use PROT_EXEC],
363   if test "$enable_pax_emutramp" = "yes"; then
364     AC_DEFINE(FFI_MMAP_EXEC_EMUTRAMP_PAX, 1,
365       [Define this if you want to enable pax emulated trampolines])
366   fi)
367
368 FFI_EXEC_TRAMPOLINE_TABLE=0
369 case "$target" in
370      *arm*-apple-darwin*)
371        FFI_EXEC_TRAMPOLINE_TABLE=1
372        AC_DEFINE(FFI_EXEC_TRAMPOLINE_TABLE, 1,
373                  [Cannot use PROT_EXEC on this target, so, we revert to
374                    alternative means])
375      ;;
376      *-apple-darwin1* | *-*-freebsd* | *-*-kfreebsd* | *-*-openbsd* | *-pc-solaris*)
377        AC_DEFINE(FFI_MMAP_EXEC_WRIT, 1,
378                  [Cannot use malloc on this target, so, we revert to
379                    alternative means])
380      ;;
381 esac
382 AM_CONDITIONAL(FFI_EXEC_TRAMPOLINE_TABLE, test x$FFI_EXEC_TRAMPOLINE_TABLE = x1)
383 AC_SUBST(FFI_EXEC_TRAMPOLINE_TABLE)
384
385 if test x$TARGET = xX86_64; then
386     AC_CACHE_CHECK([assembler supports unwind section type],
387         libffi_cv_as_x86_64_unwind_section_type, [
388         libffi_cv_as_x86_64_unwind_section_type=yes
389         echo '.section .eh_frame,"a",@unwind' > conftest.s
390         if $CC $CFLAGS -c conftest.s 2>&1 | grep -i warning > /dev/null; then
391             libffi_cv_as_x86_64_unwind_section_type=no
392         fi
393         ])
394     if test "x$libffi_cv_as_x86_64_unwind_section_type" = xyes; then
395         AC_DEFINE(HAVE_AS_X86_64_UNWIND_SECTION_TYPE, 1,
396                   [Define if your assembler supports unwind section type.])
397     fi
398 fi
399
400 if test "x$GCC" = "xyes"; then
401   AC_CACHE_CHECK([whether .eh_frame section should be read-only],
402       libffi_cv_ro_eh_frame, [
403         libffi_cv_ro_eh_frame=no
404         echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
405         if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
406             if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
407                 libffi_cv_ro_eh_frame=yes
408             elif grep '.section.*eh_frame.*#alloc' conftest.c \
409                  | grep -v '#write' > /dev/null; then
410                 libffi_cv_ro_eh_frame=yes
411             fi
412         fi
413         rm -f conftest.*
414       ])
415   if test "x$libffi_cv_ro_eh_frame" = xyes; then
416       AC_DEFINE(HAVE_RO_EH_FRAME, 1,
417               [Define if .eh_frame sections should be read-only.])
418       AC_DEFINE(EH_FRAME_FLAGS, "a",
419               [Define to the flags needed for the .section .eh_frame directive.  ])
420   else
421       AC_DEFINE(EH_FRAME_FLAGS, "aw",
422               [Define to the flags needed for the .section .eh_frame directive.  ])
423   fi
424
425   AC_CACHE_CHECK([for __attribute__((visibility("hidden")))],
426       libffi_cv_hidden_visibility_attribute, [
427         echo 'int __attribute__ ((visibility ("hidden"))) foo (void) { return 1  ; }' > conftest.c
428         libffi_cv_hidden_visibility_attribute=no
429         if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
430             if grep '\.hidden.*foo' conftest.s >/dev/null; then
431                 libffi_cv_hidden_visibility_attribute=yes
432             fi
433         fi
434         rm -f conftest.*
435       ])
436   if test $libffi_cv_hidden_visibility_attribute = yes; then
437       AC_DEFINE(HAVE_HIDDEN_VISIBILITY_ATTRIBUTE, 1,
438               [Define if __attribute__((visibility("hidden"))) is supported.])
439   fi
440 fi
441
442 AH_BOTTOM([
443 #ifdef HAVE_HIDDEN_VISIBILITY_ATTRIBUTE
444 #ifdef LIBFFI_ASM
445 #define FFI_HIDDEN(name) .hidden name
446 #else
447 #define FFI_HIDDEN __attribute__ ((visibility ("hidden")))
448 #endif
449 #else
450 #ifdef LIBFFI_ASM
451 #define FFI_HIDDEN(name)
452 #else
453 #define FFI_HIDDEN
454 #endif
455 #endif
456 ])
457
458 AC_SUBST(TARGET)
459 AC_SUBST(TARGETDIR)
460
461 AC_SUBST(SHELL)
462
463 AC_ARG_ENABLE(debug,
464 [  --enable-debug          debugging mode],
465   if test "$enable_debug" = "yes"; then
466     AC_DEFINE(FFI_DEBUG, 1, [Define this if you want extra debugging.])
467   fi)
468 AM_CONDITIONAL(FFI_DEBUG, test "$enable_debug" = "yes")
469
470 AC_ARG_ENABLE(structs,
471 [  --disable-structs       omit code for struct support],
472   if test "$enable_structs" = "no"; then
473     AC_DEFINE(FFI_NO_STRUCTS, 1, [Define this is you do not want support for aggregate types.])
474   fi)
475
476 AC_ARG_ENABLE(raw-api,
477 [  --disable-raw-api       make the raw api unavailable],
478   if test "$enable_raw_api" = "no"; then
479     AC_DEFINE(FFI_NO_RAW_API, 1, [Define this is you do not want support for the raw API.])
480   fi)
481
482 AC_ARG_ENABLE(purify-safety,
483 [  --enable-purify-safety  purify-safe mode],
484   if test "$enable_purify_safety" = "yes"; then
485     AC_DEFINE(USING_PURIFY, 1, [Define this if you are using Purify and want to suppress spurious messages.])
486   fi)
487
488 # These variables are only ever used when we cross-build to X86_WIN32.
489 # And we only support this with GCC, so...
490 if test x"$GCC" != x"no"; then
491   if test -n "$with_cross_host" &&
492      test x"$with_cross_host" != x"no"; then
493     toolexecdir='$(exec_prefix)/$(target_alias)'
494     toolexeclibdir='$(toolexecdir)/lib'
495   else
496     toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
497     toolexeclibdir='$(libdir)'
498   fi
499   multi_os_directory=`$CC -print-multi-os-directory`
500   case $multi_os_directory in
501     .) ;; # Avoid trailing /.
502     *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
503   esac
504   AC_SUBST(toolexecdir)
505   AC_SUBST(toolexeclibdir)
506 fi
507
508 if test "${multilib}" = "yes"; then
509   multilib_arg="--enable-multilib"
510 else
511   multilib_arg=
512 fi
513
514 AC_CONFIG_COMMANDS(include, [test -d include || mkdir include])
515 AC_CONFIG_COMMANDS(src, [
516 test -d src || mkdir src
517 test -d src/$TARGETDIR || mkdir src/$TARGETDIR
518 ], [TARGETDIR="$TARGETDIR"])
519
520 AC_CONFIG_LINKS(include/ffitarget.h:src/$TARGETDIR/ffitarget.h)
521
522 AC_CONFIG_FILES(include/Makefile include/ffi.h Makefile testsuite/Makefile man/Makefile libffi.pc)
523
524 AC_OUTPUT