Merge pull request #51 from vbudovski/for_upstream
[libffi.git] / configure.ac
1 dnl Process this with autoconf to create configure
2
3 AC_PREREQ(2.68)
4
5 AC_INIT([libffi], [3.0.14-rc0], [http://github.com/atgreen/libffi/issues])
6 AC_CONFIG_HEADERS([fficonfig.h])
7
8 AC_CANONICAL_SYSTEM
9 target_alias=${target_alias-$host_alias}
10
11 . ${srcdir}/configure.host
12
13 AX_ENABLE_BUILDDIR
14
15 AM_INIT_AUTOMAKE
16
17 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
18 # We must force CC to /not/ be precious variables; otherwise
19 # the wrong, non-multilib-adjusted value will be used in multilibs.
20 # As a side effect, we have to subst CFLAGS ourselves.
21 # Also save and restore CFLAGS, since AC_PROG_CC will come up with
22 # defaults of its own if none are provided.
23
24 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
25 m4_define([_AC_ARG_VAR_PRECIOUS],[])
26 save_CFLAGS=$CFLAGS
27 AC_PROG_CC
28 CFLAGS=$save_CFLAGS
29 m4_undefine([_AC_ARG_VAR_PRECIOUS])
30 m4_rename_force([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
31
32 AC_SUBST(CFLAGS)
33
34 AM_PROG_AS
35 AM_PROG_CC_C_O
36 AC_PROG_LIBTOOL
37 AC_CONFIG_MACRO_DIR([m4])
38
39 # Test for 64-bit build.
40 AC_CHECK_SIZEOF([size_t])
41
42 AX_COMPILER_VENDOR
43 AX_CC_MAXOPT
44 # The AX_CFLAGS_WARN_ALL macro doesn't currently work for sunpro
45 # compiler.
46 if test "$ax_cv_c_compiler_vendor" != "sun"; then
47   AX_CFLAGS_WARN_ALL
48 fi
49
50 if test "x$GCC" = "xyes"; then
51   CFLAGS="$CFLAGS -fexceptions"
52   touch local.exp
53 else
54   cat > local.exp <<EOF
55 set CC_FOR_TARGET "$CC"
56 EOF
57 fi
58
59 AM_MAINTAINER_MODE
60
61 AC_CHECK_HEADERS(sys/mman.h)
62 AC_CHECK_FUNCS(mmap)
63 AC_FUNC_MMAP_BLACKLIST
64
65 dnl The -no-testsuite modules omit the test subdir.
66 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
67
68 TARGETDIR="unknown"
69 case "$host" in
70   aarch64*-*-*)
71         TARGET=AARCH64; TARGETDIR=aarch64
72         ;;
73
74   alpha*-*-*)
75         TARGET=ALPHA; TARGETDIR=alpha;
76         # Support 128-bit long double, changeable via command-line switch.
77         HAVE_LONG_DOUBLE='defined(__LONG_DOUBLE_128__)'
78         ;;
79
80   arc*-*-*)
81         TARGET=ARC; TARGETDIR=arc
82         ;;
83
84   arm*-*-*)
85         TARGET=ARM; TARGETDIR=arm
86         ;;
87
88   amd64-*-freebsd* | amd64-*-openbsd*)
89         TARGET=X86_64; TARGETDIR=x86
90         ;;
91
92   amd64-*-freebsd*)
93         TARGET=X86_64; TARGETDIR=x86
94         ;;
95
96   amd64-*-freebsd*)
97         TARGET=X86_64; TARGETDIR=x86
98         ;;
99
100   avr32*-*-*)
101         TARGET=AVR32; TARGETDIR=avr32
102         ;;
103
104   bfin*)
105         TARGET=BFIN; TARGETDIR=bfin
106         ;;
107
108   cris-*-*)
109         TARGET=LIBFFI_CRIS; TARGETDIR=cris
110         ;;
111
112   frv-*-*)
113         TARGET=FRV; TARGETDIR=frv
114         ;;
115
116   hppa*-*-linux* | parisc*-*-linux* | hppa*-*-openbsd*)
117         TARGET=PA_LINUX; TARGETDIR=pa
118         ;;
119   hppa*64-*-hpux*)
120         TARGET=PA64_HPUX; TARGETDIR=pa
121         ;;
122   hppa*-*-hpux*)
123         TARGET=PA_HPUX; TARGETDIR=pa
124         ;;
125
126   i?86-*-freebsd* | i?86-*-openbsd*)
127         TARGET=X86_FREEBSD; TARGETDIR=x86
128         ;;
129   i?86-win32* | i?86-*-cygwin* | i?86-*-mingw* | i?86-*-os2* | i?86-*-interix*)
130         TARGET=X86_WIN32; TARGETDIR=x86
131         # All mingw/cygwin/win32 builds require -no-undefined for sharedlib.
132         # We must also check with_cross_host to decide if this is a native
133         # or cross-build and select where to install dlls appropriately.
134         if test -n "$with_cross_host" &&
135            test x"$with_cross_host" != x"no"; then
136           AM_LTLDFLAGS='-no-undefined -bindir "$(toolexeclibdir)"';
137         else
138           AM_LTLDFLAGS='-no-undefined -bindir "$(bindir)"';
139         fi
140         ;;
141   i?86-*-darwin*)
142         TARGET=X86_DARWIN; TARGETDIR=x86
143         ;;
144   i?86-*-solaris2.1[[0-9]]*)
145         TARGETDIR=x86
146         if test $ac_cv_sizeof_size_t = 4; then
147           TARGET=X86; 
148         else
149           TARGET=X86_64; 
150         fi        
151         ;;
152
153   x86_64-*-darwin*)
154         TARGET=X86_DARWIN; TARGETDIR=x86
155         ;;
156
157   x86_64-*-cygwin* | x86_64-*-mingw*)
158         TARGET=X86_WIN64; TARGETDIR=x86
159         # All mingw/cygwin/win32 builds require -no-undefined for sharedlib.
160         # We must also check with_cross_host to decide if this is a native
161         # or cross-build and select where to install dlls appropriately.
162         if test -n "$with_cross_host" &&
163            test x"$with_cross_host" != x"no"; then
164           AM_LTLDFLAGS='-no-undefined -bindir "$(toolexeclibdir)"';
165         else
166           AM_LTLDFLAGS='-no-undefined -bindir "$(bindir)"';
167         fi
168         ;;
169
170   i?86-*-* | x86_64-*-*)
171         TARGETDIR=x86
172         if test $ac_cv_sizeof_size_t = 4; then
173           case "$host" in
174             *-gnux32)
175               TARGET=X86_64
176               ;;
177             *)
178               TARGET=X86
179               ;;
180           esac  
181         else
182           TARGET=X86_64; 
183         fi        
184         ;;
185
186   ia64*-*-*)
187         TARGET=IA64; TARGETDIR=ia64
188         ;;
189
190   m32r*-*-*)
191         TARGET=M32R; TARGETDIR=m32r
192         ;;
193
194   m68k-*-*)
195         TARGET=M68K; TARGETDIR=m68k
196         ;;
197
198   m88k-*-*)
199         TARGET=M88K; TARGETDIR=m88k
200         ;;
201
202   microblaze*-*-*)
203         TARGET=MICROBLAZE; TARGETDIR=microblaze
204         ;;
205
206   moxie-*-*)
207         TARGET=MOXIE; TARGETDIR=moxie
208         ;;
209
210   metag-*-*)
211         TARGET=METAG; TARGETDIR=metag
212         ;;
213
214   mips-sgi-irix5.* | mips-sgi-irix6.* | mips*-*-rtems*)
215         TARGET=MIPS; TARGETDIR=mips
216         ;;
217   mips*-*-linux* | mips*-*-openbsd*)
218         # Support 128-bit long double for NewABI.
219         HAVE_LONG_DOUBLE='defined(__mips64)'
220         TARGET=MIPS; TARGETDIR=mips
221         ;;
222
223   nios2*-linux*)
224         TARGET=NIOS2; TARGETDIR=nios2
225         ;;
226
227   powerpc*-*-linux* | powerpc-*-sysv*)
228         TARGET=POWERPC; TARGETDIR=powerpc
229         ;;
230   powerpc-*-amigaos*)
231         TARGET=POWERPC; TARGETDIR=powerpc
232         ;;
233   powerpc-*-beos*)
234         TARGET=POWERPC; TARGETDIR=powerpc
235         ;;
236   powerpc-*-darwin* | powerpc64-*-darwin*)
237         TARGET=POWERPC_DARWIN; TARGETDIR=powerpc
238         ;;
239   powerpc-*-aix* | rs6000-*-aix*)
240         TARGET=POWERPC_AIX; TARGETDIR=powerpc
241         ;;
242   powerpc-*-freebsd* | powerpc-*-openbsd*)
243         TARGET=POWERPC_FREEBSD; TARGETDIR=powerpc
244         ;;
245   powerpc64-*-freebsd*)
246         TARGET=POWERPC; TARGETDIR=powerpc
247         ;;
248   powerpc*-*-rtems*)
249         TARGET=POWERPC; TARGETDIR=powerpc
250         ;;
251
252   s390-*-* | s390x-*-*)
253         TARGET=S390; TARGETDIR=s390
254         ;;
255
256   sh-*-* | sh[[34]]*-*-*)
257         TARGET=SH; TARGETDIR=sh
258         ;;
259   sh64-*-* | sh5*-*-*)
260         TARGET=SH64; TARGETDIR=sh64
261         ;;
262
263   sparc*-*-*)
264         TARGET=SPARC; TARGETDIR=sparc
265         ;;
266
267   tile*-*)
268         TARGET=TILE; TARGETDIR=tile
269         ;;
270
271   vax-*-*)
272         TARGET=VAX; TARGETDIR=vax
273         ;;
274
275   xtensa*-*)
276         TARGET=XTENSA; TARGETDIR=xtensa
277         ;;
278
279 esac
280
281 AC_SUBST(AM_RUNTESTFLAGS)
282 AC_SUBST(AM_LTLDFLAGS)
283
284 if test $TARGETDIR = unknown; then
285   AC_MSG_ERROR(["libffi has not been ported to $host."])
286 fi
287
288 AM_CONDITIONAL(MIPS, test x$TARGET = xMIPS)
289 AM_CONDITIONAL(BFIN, test x$TARGET = xBFIN)
290 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
291 AM_CONDITIONAL(X86, test x$TARGET = xX86)
292 AM_CONDITIONAL(X86_FREEBSD, test x$TARGET = xX86_FREEBSD)
293 AM_CONDITIONAL(X86_WIN32, test x$TARGET = xX86_WIN32)
294 AM_CONDITIONAL(X86_WIN64, test x$TARGET = xX86_WIN64)
295 AM_CONDITIONAL(X86_DARWIN, test x$TARGET = xX86_DARWIN)
296 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
297 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
298 AM_CONDITIONAL(M32R, test x$TARGET = xM32R)
299 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
300 AM_CONDITIONAL(M88K, test x$TARGET = xM88K)
301 AM_CONDITIONAL(MICROBLAZE, test x$TARGET = xMICROBLAZE)
302 AM_CONDITIONAL(METAG, test x$TARGET = xMETAG)
303 AM_CONDITIONAL(MOXIE, test x$TARGET = xMOXIE)
304 AM_CONDITIONAL(NIOS2, test x$TARGET = xNIOS2)
305 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
306 AM_CONDITIONAL(POWERPC_AIX, test x$TARGET = xPOWERPC_AIX)
307 AM_CONDITIONAL(POWERPC_DARWIN, test x$TARGET = xPOWERPC_DARWIN)
308 AM_CONDITIONAL(POWERPC_FREEBSD, test x$TARGET = xPOWERPC_FREEBSD)
309 AM_CONDITIONAL(AARCH64, test x$TARGET = xAARCH64)
310 AM_CONDITIONAL(ARC, test x$TARGET = xARC)
311 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
312 AM_CONDITIONAL(AVR32, test x$TARGET = xAVR32)
313 AM_CONDITIONAL(LIBFFI_CRIS, test x$TARGET = xLIBFFI_CRIS)
314 AM_CONDITIONAL(FRV, test x$TARGET = xFRV)
315 AM_CONDITIONAL(S390, test x$TARGET = xS390)
316 AM_CONDITIONAL(X86_64, test x$TARGET = xX86_64)
317 AM_CONDITIONAL(SH, test x$TARGET = xSH)
318 AM_CONDITIONAL(SH64, test x$TARGET = xSH64)
319 AM_CONDITIONAL(PA_LINUX, test x$TARGET = xPA_LINUX)
320 AM_CONDITIONAL(PA_HPUX, test x$TARGET = xPA_HPUX)
321 AM_CONDITIONAL(PA64_HPUX, test x$TARGET = xPA64_HPUX)
322 AM_CONDITIONAL(TILE, test x$TARGET = xTILE)
323 AM_CONDITIONAL(VAX, test x$TARGET = xVAX)
324 AM_CONDITIONAL(XTENSA, test x$TARGET = xXTENSA)
325
326 AC_HEADER_STDC
327 AC_CHECK_FUNCS(memcpy)
328 AC_FUNC_ALLOCA
329
330 AC_CHECK_SIZEOF(double)
331 AC_CHECK_SIZEOF(long double)
332
333 # Also AC_SUBST this variable for ffi.h.
334 if test -z "$HAVE_LONG_DOUBLE"; then
335   HAVE_LONG_DOUBLE=0
336   if test $ac_cv_sizeof_double != $ac_cv_sizeof_long_double; then
337     if test $ac_cv_sizeof_long_double != 0; then
338       HAVE_LONG_DOUBLE=1
339       AC_DEFINE(HAVE_LONG_DOUBLE, 1, [Define if you have the long double type and it is bigger than a double])
340     fi
341   fi
342 fi
343 AC_SUBST(HAVE_LONG_DOUBLE)
344
345 AC_C_BIGENDIAN
346
347 GCC_AS_CFI_PSEUDO_OP
348
349 if test x$TARGET = xSPARC; then
350     AC_CACHE_CHECK([assembler and linker support unaligned pc related relocs],
351         libffi_cv_as_sparc_ua_pcrel, [
352         save_CFLAGS="$CFLAGS"
353         save_LDFLAGS="$LDFLAGS"
354         CFLAGS="$CFLAGS -fpic"
355         LDFLAGS="$LDFLAGS -shared"
356         AC_TRY_LINK([asm (".text; foo: nop; .data; .align 4; .byte 0; .uaword %r_disp32(foo); .text");],,
357                     [libffi_cv_as_sparc_ua_pcrel=yes],
358                     [libffi_cv_as_sparc_ua_pcrel=no])
359         CFLAGS="$save_CFLAGS"
360         LDFLAGS="$save_LDFLAGS"])
361     if test "x$libffi_cv_as_sparc_ua_pcrel" = xyes; then
362         AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
363                   [Define if your assembler and linker support unaligned PC relative relocs.])
364     fi
365
366     AC_CACHE_CHECK([assembler .register pseudo-op support],
367        libffi_cv_as_register_pseudo_op, [
368        libffi_cv_as_register_pseudo_op=unknown
369        # Check if we have .register
370        AC_TRY_COMPILE(,[asm (".register %g2, #scratch");],
371                        [libffi_cv_as_register_pseudo_op=yes],
372                        [libffi_cv_as_register_pseudo_op=no])
373     ])
374     if test "x$libffi_cv_as_register_pseudo_op" = xyes; then
375        AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
376                [Define if your assembler supports .register.])
377     fi
378 fi
379
380 if test x$TARGET = xX86 || test x$TARGET = xX86_WIN32 || test x$TARGET = xX86_64; then
381     AC_CACHE_CHECK([assembler supports pc related relocs],
382         libffi_cv_as_x86_pcrel, [
383         libffi_cv_as_x86_pcrel=no
384         echo '.text; foo: nop; .data; .long foo-.; .text' > conftest.s
385         if $CC $CFLAGS -c conftest.s > /dev/null 2>&1; then
386             libffi_cv_as_x86_pcrel=yes
387         fi
388         ])
389     if test "x$libffi_cv_as_x86_pcrel" = xyes; then
390         AC_DEFINE(HAVE_AS_X86_PCREL, 1,
391                   [Define if your assembler supports PC relative relocs.])
392     fi
393
394     AC_CACHE_CHECK([assembler .ascii pseudo-op support],
395        libffi_cv_as_ascii_pseudo_op, [
396        libffi_cv_as_ascii_pseudo_op=unknown
397        # Check if we have .ascii
398        AC_TRY_COMPILE(,[asm (".ascii \\"string\\"");],
399                        [libffi_cv_as_ascii_pseudo_op=yes],
400                        [libffi_cv_as_ascii_pseudo_op=no])
401     ])
402     if test "x$libffi_cv_as_ascii_pseudo_op" = xyes; then
403        AC_DEFINE(HAVE_AS_ASCII_PSEUDO_OP, 1,
404                [Define if your assembler supports .ascii.])
405     fi
406
407     AC_CACHE_CHECK([assembler .string pseudo-op support],
408        libffi_cv_as_string_pseudo_op, [
409        libffi_cv_as_string_pseudo_op=unknown
410        # Check if we have .string
411        AC_TRY_COMPILE(,[asm (".string \\"string\\"");],
412                        [libffi_cv_as_string_pseudo_op=yes],
413                        [libffi_cv_as_string_pseudo_op=no])
414     ])
415     if test "x$libffi_cv_as_string_pseudo_op" = xyes; then
416        AC_DEFINE(HAVE_AS_STRING_PSEUDO_OP, 1,
417                [Define if your assembler supports .string.])
418     fi
419 fi
420
421 # On PaX enable kernels that have MPROTECT enable we can't use PROT_EXEC.
422 AC_ARG_ENABLE(pax_emutramp,
423   [  --enable-pax_emutramp       enable pax emulated trampolines, for we can't use PROT_EXEC],
424   if test "$enable_pax_emutramp" = "yes"; then
425     AC_DEFINE(FFI_MMAP_EXEC_EMUTRAMP_PAX, 1,
426       [Define this if you want to enable pax emulated trampolines])
427   fi)
428
429 if test x$TARGET = xX86_WIN64; then
430     LT_SYS_SYMBOL_USCORE
431     if test "x$sys_symbol_underscore" = xyes; then
432         AC_DEFINE(SYMBOL_UNDERSCORE, 1, [Define if symbols are underscored.])
433     fi
434 fi
435
436 FFI_EXEC_TRAMPOLINE_TABLE=0
437 case "$target" in
438      *arm*-apple-darwin*)
439        FFI_EXEC_TRAMPOLINE_TABLE=1
440        AC_DEFINE(FFI_EXEC_TRAMPOLINE_TABLE, 1,
441                  [Cannot use PROT_EXEC on this target, so, we revert to
442                    alternative means])
443      ;;
444      *-apple-darwin1* | *-*-freebsd* | *-*-kfreebsd* | *-*-openbsd* | *-pc-solaris*)
445        AC_DEFINE(FFI_MMAP_EXEC_WRIT, 1,
446                  [Cannot use malloc on this target, so, we revert to
447                    alternative means])
448      ;;
449 esac
450 AM_CONDITIONAL(FFI_EXEC_TRAMPOLINE_TABLE, test x$FFI_EXEC_TRAMPOLINE_TABLE = x1)
451 AC_SUBST(FFI_EXEC_TRAMPOLINE_TABLE)
452
453 if test x$TARGET = xX86_64; then
454     AC_CACHE_CHECK([assembler supports unwind section type],
455         libffi_cv_as_x86_64_unwind_section_type, [
456         libffi_cv_as_x86_64_unwind_section_type=yes
457         echo '.section .eh_frame,"a",@unwind' > conftest.s
458         if $CC $CFLAGS -c conftest.s 2>&1 | grep -i warning > /dev/null; then
459             libffi_cv_as_x86_64_unwind_section_type=no
460         fi
461         ])
462     if test "x$libffi_cv_as_x86_64_unwind_section_type" = xyes; then
463         AC_DEFINE(HAVE_AS_X86_64_UNWIND_SECTION_TYPE, 1,
464                   [Define if your assembler supports unwind section type.])
465     fi
466 fi
467
468 if test "x$GCC" = "xyes"; then
469   AC_CACHE_CHECK([whether .eh_frame section should be read-only],
470       libffi_cv_ro_eh_frame, [
471         libffi_cv_ro_eh_frame=no
472         echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
473         if $CC $CFLAGS -c -fpic -fexceptions -o conftest.o conftest.c > /dev/null 2>&1; then
474             objdump -h conftest.o > conftest.dump 2>&1
475             libffi_eh_frame_line=`grep -n eh_frame conftest.dump | cut -d: -f 1`
476             libffi_test_line=`expr $libffi_eh_frame_line + 1`p
477             sed -n $libffi_test_line conftest.dump > conftest.line
478             if grep READONLY conftest.line > /dev/null; then
479                 libffi_cv_ro_eh_frame=yes
480             fi
481         fi
482         rm -f conftest.*
483       ])
484   if test "x$libffi_cv_ro_eh_frame" = xyes; then
485       AC_DEFINE(HAVE_RO_EH_FRAME, 1,
486               [Define if .eh_frame sections should be read-only.])
487       AC_DEFINE(EH_FRAME_FLAGS, "a",
488               [Define to the flags needed for the .section .eh_frame directive.  ])
489   else
490       AC_DEFINE(EH_FRAME_FLAGS, "aw",
491               [Define to the flags needed for the .section .eh_frame directive.  ])
492   fi
493
494   AC_CACHE_CHECK([for __attribute__((visibility("hidden")))],
495       libffi_cv_hidden_visibility_attribute, [
496         echo 'int __attribute__ ((visibility ("hidden"))) foo (void) { return 1  ; }' > conftest.c
497         libffi_cv_hidden_visibility_attribute=no
498         if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
499             if grep '\.hidden.*foo' conftest.s >/dev/null; then
500                 libffi_cv_hidden_visibility_attribute=yes
501             fi
502         fi
503         rm -f conftest.*
504       ])
505   if test $libffi_cv_hidden_visibility_attribute = yes; then
506       AC_DEFINE(HAVE_HIDDEN_VISIBILITY_ATTRIBUTE, 1,
507               [Define if __attribute__((visibility("hidden"))) is supported.])
508   fi
509 fi
510
511 AH_BOTTOM([
512 #ifdef HAVE_HIDDEN_VISIBILITY_ATTRIBUTE
513 #ifdef LIBFFI_ASM
514 #define FFI_HIDDEN(name) .hidden name
515 #else
516 #define FFI_HIDDEN __attribute__ ((visibility ("hidden")))
517 #endif
518 #else
519 #ifdef LIBFFI_ASM
520 #define FFI_HIDDEN(name)
521 #else
522 #define FFI_HIDDEN
523 #endif
524 #endif
525 ])
526
527 AC_SUBST(TARGET)
528 AC_SUBST(TARGETDIR)
529
530 AC_SUBST(SHELL)
531
532 AC_ARG_ENABLE(debug,
533 [  --enable-debug          debugging mode],
534   if test "$enable_debug" = "yes"; then
535     AC_DEFINE(FFI_DEBUG, 1, [Define this if you want extra debugging.])
536   fi)
537 AM_CONDITIONAL(FFI_DEBUG, test "$enable_debug" = "yes")
538
539 AC_ARG_ENABLE(structs,
540 [  --disable-structs       omit code for struct support],
541   if test "$enable_structs" = "no"; then
542     AC_DEFINE(FFI_NO_STRUCTS, 1, [Define this is you do not want support for aggregate types.])
543   fi)
544 AM_CONDITIONAL(FFI_DEBUG, test "$enable_debug" = "yes")
545
546 AC_ARG_ENABLE(raw-api,
547 [  --disable-raw-api       make the raw api unavailable],
548   if test "$enable_raw_api" = "no"; then
549     AC_DEFINE(FFI_NO_RAW_API, 1, [Define this is you do not want support for the raw API.])
550   fi)
551
552 AC_ARG_ENABLE(purify-safety,
553 [  --enable-purify-safety  purify-safe mode],
554   if test "$enable_purify_safety" = "yes"; then
555     AC_DEFINE(USING_PURIFY, 1, [Define this if you are using Purify and want to suppress spurious messages.])
556   fi)
557
558 # These variables are only ever used when we cross-build to X86_WIN32.
559 # And we only support this with GCC, so...
560 if test "x$GCC" = "xyes"; then
561   if test -n "$with_cross_host" &&
562      test x"$with_cross_host" != x"no"; then
563     toolexecdir='$(exec_prefix)/$(target_alias)'
564     toolexeclibdir='$(toolexecdir)/lib'
565   else
566     toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
567     toolexeclibdir='$(libdir)'
568   fi
569   multi_os_directory=`$CC -print-multi-os-directory`
570   case $multi_os_directory in
571     .) ;; # Avoid trailing /.
572     ../*) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
573   esac
574   AC_SUBST(toolexecdir)
575 else
576   toolexeclibdir='$(libdir)'
577 fi
578 AC_SUBST(toolexeclibdir)
579
580 AC_CONFIG_COMMANDS(include, [test -d include || mkdir include])
581 AC_CONFIG_COMMANDS(src, [
582 test -d src || mkdir src
583 test -d src/$TARGETDIR || mkdir src/$TARGETDIR
584 ], [TARGETDIR="$TARGETDIR"])
585
586 AC_CONFIG_LINKS(include/ffitarget.h:src/$TARGETDIR/ffitarget.h)
587
588 AC_CONFIG_FILES(include/Makefile include/ffi.h Makefile testsuite/Makefile man/Makefile libffi.pc)
589
590 AC_OUTPUT