Add moxie support. Release 3.0.12.
[libffi.git] / configure.ac
1 dnl Process this with autoconf to create configure
2
3 AC_PREREQ(2.68)
4
5 AC_INIT([libffi], [3.0.12], [http://github.com/atgreen/libffi/issues])
6 AC_CONFIG_HEADERS([fficonfig.h])
7
8 AC_CANONICAL_SYSTEM
9 target_alias=${target_alias-$host_alias}
10
11 . ${srcdir}/configure.host
12
13 AX_ENABLE_BUILDDIR
14
15 AM_INIT_AUTOMAKE
16
17 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
18 # We must force CC to /not/ be precious variables; otherwise
19 # the wrong, non-multilib-adjusted value will be used in multilibs.
20 # As a side effect, we have to subst CFLAGS ourselves.
21 # Also save and restore CFLAGS, since AC_PROG_CC will come up with
22 # defaults of its own if none are provided.
23
24 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
25 m4_define([_AC_ARG_VAR_PRECIOUS],[])
26 save_CFLAGS=$CFLAGS
27 AC_PROG_CC
28 CFLAGS=$save_CFLAGS
29 m4_undefine([_AC_ARG_VAR_PRECIOUS])
30 m4_rename_force([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
31
32 AC_SUBST(CFLAGS)
33
34 AM_PROG_AS
35 AM_PROG_CC_C_O
36 AC_PROG_LIBTOOL
37 AC_CONFIG_MACRO_DIR([m4])
38
39 # Test for 64-bit build.
40 AC_CHECK_SIZEOF([size_t])
41
42 AX_COMPILER_VENDOR
43 AX_CC_MAXOPT
44 # The AX_CFLAGS_WARN_ALL macro doesn't currently work for sunpro
45 # compiler.
46 if test "$ax_cv_c_compiler_vendor" != "sun"; then
47   AX_CFLAGS_WARN_ALL
48 fi
49
50 if test "x$GCC" = "xyes"; then
51   CFLAGS="$CFLAGS -fexceptions"
52   touch local.exp
53 else
54   cat > local.exp <<EOF
55 set CC_FOR_TARGET "$CC"
56 EOF
57 fi
58
59 AM_MAINTAINER_MODE
60
61 AC_CHECK_HEADERS(sys/mman.h)
62 AC_CHECK_FUNCS(mmap)
63 AC_FUNC_MMAP_BLACKLIST
64
65 dnl The -no-testsuite modules omit the test subdir.
66 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
67
68 TARGETDIR="unknown"
69 case "$host" in
70   aarch64*-*-*)
71         TARGET=AARCH64; TARGETDIR=aarch64
72         ;;
73
74   alpha*-*-*)
75         TARGET=ALPHA; TARGETDIR=alpha;
76         # Support 128-bit long double, changeable via command-line switch.
77         HAVE_LONG_DOUBLE='defined(__LONG_DOUBLE_128__)'
78         ;;
79
80   arm*-*-*)
81         TARGET=ARM; TARGETDIR=arm
82         ;;
83
84   amd64-*-freebsd* | amd64-*-openbsd*)
85         TARGET=X86_64; TARGETDIR=x86
86         ;;
87
88   amd64-*-freebsd*)
89         TARGET=X86_64; TARGETDIR=x86
90         ;;
91
92   amd64-*-freebsd*)
93         TARGET=X86_64; TARGETDIR=x86
94         ;;
95
96   avr32*-*-*)
97         TARGET=AVR32; TARGETDIR=avr32
98         ;;
99
100   bfin*)
101         TARGET=BFIN; TARGETDIR=bfin
102         ;;
103
104   cris-*-*)
105         TARGET=LIBFFI_CRIS; TARGETDIR=cris
106         ;;
107
108   frv-*-*)
109         TARGET=FRV; TARGETDIR=frv
110         ;;
111
112   hppa*-*-linux* | parisc*-*-linux* | hppa*-*-openbsd*)
113         TARGET=PA_LINUX; TARGETDIR=pa
114         ;;
115   hppa*64-*-hpux*)
116         TARGET=PA64_HPUX; TARGETDIR=pa
117         ;;
118   hppa*-*-hpux*)
119         TARGET=PA_HPUX; TARGETDIR=pa
120         ;;
121
122   i?86-*-freebsd* | i?86-*-openbsd*)
123         TARGET=X86_FREEBSD; TARGETDIR=x86
124         ;;
125   i?86-win32* | i?86-*-cygwin* | i?86-*-mingw* | i?86-*-os2* | i?86-*-interix*)
126         TARGET=X86_WIN32; TARGETDIR=x86
127         # All mingw/cygwin/win32 builds require -no-undefined for sharedlib.
128         # We must also check with_cross_host to decide if this is a native
129         # or cross-build and select where to install dlls appropriately.
130         if test -n "$with_cross_host" &&
131            test x"$with_cross_host" != x"no"; then
132           AM_LTLDFLAGS='-no-undefined -bindir "$(toolexeclibdir)"';
133         else
134           AM_LTLDFLAGS='-no-undefined -bindir "$(bindir)"';
135         fi
136         ;;
137   i?86-*-darwin*)
138         TARGET=X86_DARWIN; TARGETDIR=x86
139         ;;
140   i?86-*-solaris2.1[[0-9]]*)
141         TARGETDIR=x86
142         if test $ac_cv_sizeof_size_t = 4; then
143           TARGET=X86; 
144         else
145           TARGET=X86_64; 
146         fi        
147         ;;
148
149   x86_64-*-darwin*)
150         TARGET=X86_DARWIN; TARGETDIR=x86
151         ;;
152
153   x86_64-*-cygwin* | x86_64-*-mingw*)
154         TARGET=X86_WIN64; TARGETDIR=x86
155         # All mingw/cygwin/win32 builds require -no-undefined for sharedlib.
156         # We must also check with_cross_host to decide if this is a native
157         # or cross-build and select where to install dlls appropriately.
158         if test -n "$with_cross_host" &&
159            test x"$with_cross_host" != x"no"; then
160           AM_LTLDFLAGS='-no-undefined -bindir "$(toolexeclibdir)"';
161         else
162           AM_LTLDFLAGS='-no-undefined -bindir "$(bindir)"';
163         fi
164         ;;
165
166   i?86-*-* | x86_64-*-*)
167         TARGETDIR=x86
168         if test $ac_cv_sizeof_size_t = 4; then
169           case "$host" in
170             *-gnux32)
171               TARGET=X86_64
172               ;;
173             *)
174               TARGET=X86
175               ;;
176           esac  
177         else
178           TARGET=X86_64; 
179         fi        
180         ;;
181
182   ia64*-*-*)
183         TARGET=IA64; TARGETDIR=ia64
184         ;;
185
186   m32r*-*-*)
187         TARGET=M32R; TARGETDIR=m32r
188         ;;
189
190   m68k-*-*)
191         TARGET=M68K; TARGETDIR=m68k
192         ;;
193
194   microblaze*-*-*)
195         TARGET=MICROBLAZE; TARGETDIR=microblaze
196         ;;
197
198   moxie-*-*)
199         TARGET=MOXIE; TARGETDIR=moxie
200         ;;
201
202   mips-sgi-irix5.* | mips-sgi-irix6.* | mips*-*-rtems*)
203         TARGET=MIPS; TARGETDIR=mips
204         ;;
205   mips*-*-linux* | mips*-*-openbsd*)
206         # Support 128-bit long double for NewABI.
207         HAVE_LONG_DOUBLE='defined(__mips64)'
208         TARGET=MIPS; TARGETDIR=mips
209         ;;
210
211   powerpc*-*-linux* | powerpc-*-sysv*)
212         TARGET=POWERPC; TARGETDIR=powerpc
213         ;;
214   powerpc-*-amigaos*)
215         TARGET=POWERPC; TARGETDIR=powerpc
216         ;;
217   powerpc-*-beos*)
218         TARGET=POWERPC; TARGETDIR=powerpc
219         ;;
220   powerpc-*-darwin* | powerpc64-*-darwin*)
221         TARGET=POWERPC_DARWIN; TARGETDIR=powerpc
222         ;;
223   powerpc-*-aix* | rs6000-*-aix*)
224         TARGET=POWERPC_AIX; TARGETDIR=powerpc
225         ;;
226   powerpc-*-freebsd* | powerpc-*-openbsd*)
227         TARGET=POWERPC_FREEBSD; TARGETDIR=powerpc
228         ;;
229   powerpc64-*-freebsd*)
230         TARGET=POWERPC; TARGETDIR=powerpc
231         ;;
232   powerpc*-*-rtems*)
233         TARGET=POWERPC; TARGETDIR=powerpc
234         ;;
235
236   s390-*-* | s390x-*-*)
237         TARGET=S390; TARGETDIR=s390
238         ;;
239
240   sh-*-* | sh[[34]]*-*-*)
241         TARGET=SH; TARGETDIR=sh
242         ;;
243   sh64-*-* | sh5*-*-*)
244         TARGET=SH64; TARGETDIR=sh64
245         ;;
246
247   sparc*-*-*)
248         TARGET=SPARC; TARGETDIR=sparc
249         ;;
250
251   tile*-*)
252         TARGET=TILE; TARGETDIR=tile
253         ;;
254
255   xtensa*-*)
256         TARGET=XTENSA; TARGETDIR=xtensa
257         ;;
258
259 esac
260
261 AC_SUBST(AM_RUNTESTFLAGS)
262 AC_SUBST(AM_LTLDFLAGS)
263
264 if test $TARGETDIR = unknown; then
265   AC_MSG_ERROR(["libffi has not been ported to $host."])
266 fi
267
268 AM_CONDITIONAL(MIPS, test x$TARGET = xMIPS)
269 AM_CONDITIONAL(BFIN, test x$TARGET = xBFIN)
270 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
271 AM_CONDITIONAL(X86, test x$TARGET = xX86)
272 AM_CONDITIONAL(X86_FREEBSD, test x$TARGET = xX86_FREEBSD)
273 AM_CONDITIONAL(X86_WIN32, test x$TARGET = xX86_WIN32)
274 AM_CONDITIONAL(X86_WIN64, test x$TARGET = xX86_WIN64)
275 AM_CONDITIONAL(X86_DARWIN, test x$TARGET = xX86_DARWIN)
276 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
277 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
278 AM_CONDITIONAL(M32R, test x$TARGET = xM32R)
279 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
280 AM_CONDITIONAL(MICROBLAZE, test x$TARGET = xMICROBLAZE)
281 AM_CONDITIONAL(MOXIE, test x$TARGET = xMOXIE)
282 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
283 AM_CONDITIONAL(POWERPC_AIX, test x$TARGET = xPOWERPC_AIX)
284 AM_CONDITIONAL(POWERPC_DARWIN, test x$TARGET = xPOWERPC_DARWIN)
285 AM_CONDITIONAL(POWERPC_FREEBSD, test x$TARGET = xPOWERPC_FREEBSD)
286 AM_CONDITIONAL(AARCH64, test x$TARGET = xAARCH64)
287 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
288 AM_CONDITIONAL(AVR32, test x$TARGET = xAVR32)
289 AM_CONDITIONAL(LIBFFI_CRIS, test x$TARGET = xLIBFFI_CRIS)
290 AM_CONDITIONAL(FRV, test x$TARGET = xFRV)
291 AM_CONDITIONAL(S390, test x$TARGET = xS390)
292 AM_CONDITIONAL(X86_64, test x$TARGET = xX86_64)
293 AM_CONDITIONAL(SH, test x$TARGET = xSH)
294 AM_CONDITIONAL(SH64, test x$TARGET = xSH64)
295 AM_CONDITIONAL(PA_LINUX, test x$TARGET = xPA_LINUX)
296 AM_CONDITIONAL(PA_HPUX, test x$TARGET = xPA_HPUX)
297 AM_CONDITIONAL(PA64_HPUX, test x$TARGET = xPA64_HPUX)
298 AM_CONDITIONAL(TILE, test x$TARGET = xTILE)
299 AM_CONDITIONAL(XTENSA, test x$TARGET = xXTENSA)
300
301 AC_HEADER_STDC
302 AC_CHECK_FUNCS(memcpy)
303 AC_FUNC_ALLOCA
304
305 AC_CHECK_SIZEOF(double)
306 AC_CHECK_SIZEOF(long double)
307
308 # Also AC_SUBST this variable for ffi.h.
309 if test -z "$HAVE_LONG_DOUBLE"; then
310   HAVE_LONG_DOUBLE=0
311   if test $ac_cv_sizeof_double != $ac_cv_sizeof_long_double; then
312     if test $ac_cv_sizeof_long_double != 0; then
313       HAVE_LONG_DOUBLE=1
314       AC_DEFINE(HAVE_LONG_DOUBLE, 1, [Define if you have the long double type and it is bigger than a double])
315     fi
316   fi
317 fi
318 AC_SUBST(HAVE_LONG_DOUBLE)
319
320 AC_C_BIGENDIAN
321
322 GCC_AS_CFI_PSEUDO_OP
323
324 if test x$TARGET = xSPARC; then
325     AC_CACHE_CHECK([assembler and linker support unaligned pc related relocs],
326         libffi_cv_as_sparc_ua_pcrel, [
327         save_CFLAGS="$CFLAGS"
328         save_LDFLAGS="$LDFLAGS"
329         CFLAGS="$CFLAGS -fpic"
330         LDFLAGS="$LDFLAGS -shared"
331         AC_TRY_LINK([asm (".text; foo: nop; .data; .align 4; .byte 0; .uaword %r_disp32(foo); .text");],,
332                     [libffi_cv_as_sparc_ua_pcrel=yes],
333                     [libffi_cv_as_sparc_ua_pcrel=no])
334         CFLAGS="$save_CFLAGS"
335         LDFLAGS="$save_LDFLAGS"])
336     if test "x$libffi_cv_as_sparc_ua_pcrel" = xyes; then
337         AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
338                   [Define if your assembler and linker support unaligned PC relative relocs.])
339     fi
340
341     AC_CACHE_CHECK([assembler .register pseudo-op support],
342        libffi_cv_as_register_pseudo_op, [
343        libffi_cv_as_register_pseudo_op=unknown
344        # Check if we have .register
345        AC_TRY_COMPILE(,[asm (".register %g2, #scratch");],
346                        [libffi_cv_as_register_pseudo_op=yes],
347                        [libffi_cv_as_register_pseudo_op=no])
348     ])
349     if test "x$libffi_cv_as_register_pseudo_op" = xyes; then
350        AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
351                [Define if your assembler supports .register.])
352     fi
353 fi
354
355 if test x$TARGET = xX86 || test x$TARGET = xX86_WIN32 || test x$TARGET = xX86_64; then
356     AC_CACHE_CHECK([assembler supports pc related relocs],
357         libffi_cv_as_x86_pcrel, [
358         libffi_cv_as_x86_pcrel=no
359         echo '.text; foo: nop; .data; .long foo-.; .text' > conftest.s
360         if $CC $CFLAGS -c conftest.s > /dev/null 2>&1; then
361             libffi_cv_as_x86_pcrel=yes
362         fi
363         ])
364     if test "x$libffi_cv_as_x86_pcrel" = xyes; then
365         AC_DEFINE(HAVE_AS_X86_PCREL, 1,
366                   [Define if your assembler supports PC relative relocs.])
367     fi
368
369     AC_CACHE_CHECK([assembler .ascii pseudo-op support],
370        libffi_cv_as_ascii_pseudo_op, [
371        libffi_cv_as_ascii_pseudo_op=unknown
372        # Check if we have .ascii
373        AC_TRY_COMPILE(,[asm (".ascii \\"string\\"");],
374                        [libffi_cv_as_ascii_pseudo_op=yes],
375                        [libffi_cv_as_ascii_pseudo_op=no])
376     ])
377     if test "x$libffi_cv_as_ascii_pseudo_op" = xyes; then
378        AC_DEFINE(HAVE_AS_ASCII_PSEUDO_OP, 1,
379                [Define if your assembler supports .ascii.])
380     fi
381
382     AC_CACHE_CHECK([assembler .string pseudo-op support],
383        libffi_cv_as_string_pseudo_op, [
384        libffi_cv_as_string_pseudo_op=unknown
385        # Check if we have .string
386        AC_TRY_COMPILE(,[asm (".string \\"string\\"");],
387                        [libffi_cv_as_string_pseudo_op=yes],
388                        [libffi_cv_as_string_pseudo_op=no])
389     ])
390     if test "x$libffi_cv_as_string_pseudo_op" = xyes; then
391        AC_DEFINE(HAVE_AS_STRING_PSEUDO_OP, 1,
392                [Define if your assembler supports .string.])
393     fi
394 fi
395
396 # On PaX enable kernels that have MPROTECT enable we can't use PROT_EXEC.
397 AC_ARG_ENABLE(pax_emutramp,
398   [  --enable-pax_emutramp       enable pax emulated trampolines, for we can't use PROT_EXEC],
399   if test "$enable_pax_emutramp" = "yes"; then
400     AC_DEFINE(FFI_MMAP_EXEC_EMUTRAMP_PAX, 1,
401       [Define this if you want to enable pax emulated trampolines])
402   fi)
403
404 if test x$TARGET = xX86_WIN64; then
405     LT_SYS_SYMBOL_USCORE
406     if test "x$sys_symbol_underscore" = xyes; then
407         AC_DEFINE(SYMBOL_UNDERSCORE, 1, [Define if symbols are underscored.])
408     fi
409 fi
410
411 FFI_EXEC_TRAMPOLINE_TABLE=0
412 case "$target" in
413      *arm*-apple-darwin*)
414        FFI_EXEC_TRAMPOLINE_TABLE=1
415        AC_DEFINE(FFI_EXEC_TRAMPOLINE_TABLE, 1,
416                  [Cannot use PROT_EXEC on this target, so, we revert to
417                    alternative means])
418      ;;
419      *-apple-darwin1* | *-*-freebsd* | *-*-kfreebsd* | *-*-openbsd* | *-pc-solaris*)
420        AC_DEFINE(FFI_MMAP_EXEC_WRIT, 1,
421                  [Cannot use malloc on this target, so, we revert to
422                    alternative means])
423      ;;
424 esac
425 AM_CONDITIONAL(FFI_EXEC_TRAMPOLINE_TABLE, test x$FFI_EXEC_TRAMPOLINE_TABLE = x1)
426 AC_SUBST(FFI_EXEC_TRAMPOLINE_TABLE)
427
428 if test x$TARGET = xX86_64; then
429     AC_CACHE_CHECK([assembler supports unwind section type],
430         libffi_cv_as_x86_64_unwind_section_type, [
431         libffi_cv_as_x86_64_unwind_section_type=yes
432         echo '.section .eh_frame,"a",@unwind' > conftest.s
433         if $CC $CFLAGS -c conftest.s 2>&1 | grep -i warning > /dev/null; then
434             libffi_cv_as_x86_64_unwind_section_type=no
435         fi
436         ])
437     if test "x$libffi_cv_as_x86_64_unwind_section_type" = xyes; then
438         AC_DEFINE(HAVE_AS_X86_64_UNWIND_SECTION_TYPE, 1,
439                   [Define if your assembler supports unwind section type.])
440     fi
441 fi
442
443 if test "x$GCC" = "xyes"; then
444   AC_CACHE_CHECK([whether .eh_frame section should be read-only],
445       libffi_cv_ro_eh_frame, [
446         libffi_cv_ro_eh_frame=no
447         echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
448         if $CC $CFLAGS -c -fpic -fexceptions -o conftest.o conftest.c > /dev/null 2>&1; then
449             objdump -h conftest.o > conftest.dump 2>&1
450             libffi_eh_frame_line=`grep -n eh_frame conftest.dump | cut -d: -f 1`
451             libffi_test_line=`expr $libffi_eh_frame_line + 1`p
452             sed -n $libffi_test_line conftest.dump > conftest.line
453             if grep READONLY conftest.line > /dev/null; then
454                 libffi_cv_ro_eh_frame=yes
455             fi
456         fi
457         rm -f conftest.*
458       ])
459   if test "x$libffi_cv_ro_eh_frame" = xyes; then
460       AC_DEFINE(HAVE_RO_EH_FRAME, 1,
461               [Define if .eh_frame sections should be read-only.])
462       AC_DEFINE(EH_FRAME_FLAGS, "a",
463               [Define to the flags needed for the .section .eh_frame directive.  ])
464   else
465       AC_DEFINE(EH_FRAME_FLAGS, "aw",
466               [Define to the flags needed for the .section .eh_frame directive.  ])
467   fi
468
469   AC_CACHE_CHECK([for __attribute__((visibility("hidden")))],
470       libffi_cv_hidden_visibility_attribute, [
471         echo 'int __attribute__ ((visibility ("hidden"))) foo (void) { return 1  ; }' > conftest.c
472         libffi_cv_hidden_visibility_attribute=no
473         if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
474             if grep '\.hidden.*foo' conftest.s >/dev/null; then
475                 libffi_cv_hidden_visibility_attribute=yes
476             fi
477         fi
478         rm -f conftest.*
479       ])
480   if test $libffi_cv_hidden_visibility_attribute = yes; then
481       AC_DEFINE(HAVE_HIDDEN_VISIBILITY_ATTRIBUTE, 1,
482               [Define if __attribute__((visibility("hidden"))) is supported.])
483   fi
484 fi
485
486 AH_BOTTOM([
487 #ifdef HAVE_HIDDEN_VISIBILITY_ATTRIBUTE
488 #ifdef LIBFFI_ASM
489 #define FFI_HIDDEN(name) .hidden name
490 #else
491 #define FFI_HIDDEN __attribute__ ((visibility ("hidden")))
492 #endif
493 #else
494 #ifdef LIBFFI_ASM
495 #define FFI_HIDDEN(name)
496 #else
497 #define FFI_HIDDEN
498 #endif
499 #endif
500 ])
501
502 AC_SUBST(TARGET)
503 AC_SUBST(TARGETDIR)
504
505 AC_SUBST(SHELL)
506
507 AC_ARG_ENABLE(debug,
508 [  --enable-debug          debugging mode],
509   if test "$enable_debug" = "yes"; then
510     AC_DEFINE(FFI_DEBUG, 1, [Define this if you want extra debugging.])
511   fi)
512 AM_CONDITIONAL(FFI_DEBUG, test "$enable_debug" = "yes")
513
514 AC_ARG_ENABLE(structs,
515 [  --disable-structs       omit code for struct support],
516   if test "$enable_structs" = "no"; then
517     AC_DEFINE(FFI_NO_STRUCTS, 1, [Define this is you do not want support for aggregate types.])
518   fi)
519 AM_CONDITIONAL(FFI_DEBUG, test "$enable_debug" = "yes")
520
521 AC_ARG_ENABLE(raw-api,
522 [  --disable-raw-api       make the raw api unavailable],
523   if test "$enable_raw_api" = "no"; then
524     AC_DEFINE(FFI_NO_RAW_API, 1, [Define this is you do not want support for the raw API.])
525   fi)
526
527 AC_ARG_ENABLE(purify-safety,
528 [  --enable-purify-safety  purify-safe mode],
529   if test "$enable_purify_safety" = "yes"; then
530     AC_DEFINE(USING_PURIFY, 1, [Define this if you are using Purify and want to suppress spurious messages.])
531   fi)
532
533 # These variables are only ever used when we cross-build to X86_WIN32.
534 # And we only support this with GCC, so...
535 if test "x$GCC" = "xyes"; then
536   if test -n "$with_cross_host" &&
537      test x"$with_cross_host" != x"no"; then
538     toolexecdir='$(exec_prefix)/$(target_alias)'
539     toolexeclibdir='$(toolexecdir)/lib'
540   else
541     toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
542     toolexeclibdir='$(libdir)'
543   fi
544   multi_os_directory=`$CC -print-multi-os-directory`
545   case $multi_os_directory in
546     .) ;; # Avoid trailing /.
547     *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
548   esac
549   AC_SUBST(toolexecdir)
550 else
551   toolexeclibdir='$(libdir)'
552 fi
553 AC_SUBST(toolexeclibdir)
554
555 AC_CONFIG_COMMANDS(include, [test -d include || mkdir include])
556 AC_CONFIG_COMMANDS(src, [
557 test -d src || mkdir src
558 test -d src/$TARGETDIR || mkdir src/$TARGETDIR
559 ], [TARGETDIR="$TARGETDIR"])
560
561 AC_CONFIG_LINKS(include/ffitarget.h:src/$TARGETDIR/ffitarget.h)
562
563 AC_CONFIG_FILES(include/Makefile include/ffi.h Makefile testsuite/Makefile man/Makefile libffi.pc)
564
565 AC_OUTPUT