Add PaX work-around
[libffi.git] / configure.ac
1 dnl Process this with autoconf to create configure
2
3 AC_PREREQ(2.68)
4
5 AC_INIT([libffi], [3.0.11], [http://github.com/atgreen/libffi/issues])
6 AC_CONFIG_HEADERS([fficonfig.h])
7
8 AC_CANONICAL_SYSTEM
9 target_alias=${target_alias-$host_alias}
10
11 . ${srcdir}/configure.host
12
13 AX_ENABLE_BUILDDIR
14
15 AM_INIT_AUTOMAKE
16
17 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
18 # We must force CC to /not/ be precious variables; otherwise
19 # the wrong, non-multilib-adjusted value will be used in multilibs.
20 # As a side effect, we have to subst CFLAGS ourselves.
21 # Also save and restore CFLAGS, since AC_PROG_CC will come up with
22 # defaults of its own if none are provided.
23
24 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
25 m4_define([_AC_ARG_VAR_PRECIOUS],[])
26 save_CFLAGS=$CFLAGS
27 AC_PROG_CC
28 CFLAGS=$save_CFLAGS
29 m4_undefine([_AC_ARG_VAR_PRECIOUS])
30 m4_rename([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
31
32 AC_SUBST(CFLAGS)
33
34 AM_PROG_AS
35 AM_PROG_CC_C_O
36 AC_PROG_LIBTOOL
37 AC_CONFIG_MACRO_DIR([m4])
38
39 AX_CC_MAXOPT
40 AX_CFLAGS_WARN_ALL
41 if test "x$GCC" = "xyes"; then
42   CFLAGS="$CFLAGS -fexceptions"
43 fi
44
45 AM_MAINTAINER_MODE
46
47 AC_CHECK_HEADERS(sys/mman.h)
48 AC_CHECK_FUNCS(mmap)
49 AC_FUNC_MMAP_BLACKLIST
50
51 dnl The -no-testsuite modules omit the test subdir.
52 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
53
54 TARGETDIR="unknown"
55 case "$host" in
56   alpha*-*-*)
57         TARGET=ALPHA; TARGETDIR=alpha;
58         # Support 128-bit long double, changeable via command-line switch.
59         HAVE_LONG_DOUBLE='defined(__LONG_DOUBLE_128__)'
60         ;;
61
62   arm*-*-*)
63         TARGET=ARM; TARGETDIR=arm
64         ;;
65
66   amd64-*-freebsd* | amd64-*-openbsd*)
67         TARGET=X86_64; TARGETDIR=x86
68         ;;
69
70   amd64-*-freebsd*)
71         TARGET=X86_64; TARGETDIR=x86
72         ;;
73
74   avr32*-*-*)
75         TARGET=AVR32; TARGETDIR=avr32
76         ;;
77
78   bfin*)
79         TARGET=BFIN; TARGETDIR=bfin
80         ;;
81
82   cris-*-*)
83         TARGET=LIBFFI_CRIS; TARGETDIR=cris
84         ;;
85
86   frv-*-*)
87         TARGET=FRV; TARGETDIR=frv
88         ;;
89
90   hppa*-*-linux* | parisc*-*-linux* | hppa*-*-openbsd*)
91         TARGET=PA_LINUX; TARGETDIR=pa
92         ;;
93   hppa*64-*-hpux*)
94         TARGET=PA64_HPUX; TARGETDIR=pa
95         ;;
96   hppa*-*-hpux*)
97         TARGET=PA_HPUX; TARGETDIR=pa
98         ;;
99
100   i?86-*-freebsd* | i?86-*-openbsd*)
101         TARGET=X86_FREEBSD; TARGETDIR=x86
102         ;;
103   i?86-win32* | i?86-*-cygwin* | i?86-*-mingw* | i?86-*-os2* | i?86-*-interix*)
104         TARGET=X86_WIN32; TARGETDIR=x86
105         # All mingw/cygwin/win32 builds require -no-undefined for sharedlib.
106         # We must also check with_cross_host to decide if this is a native
107         # or cross-build and select where to install dlls appropriately.
108         if test -n "$with_cross_host" &&
109            test x"$with_cross_host" != x"no"; then
110           AM_LTLDFLAGS='-no-undefined -bindir "$(toolexeclibdir)"';
111         else
112           AM_LTLDFLAGS='-no-undefined -bindir "$(bindir)"';
113         fi
114         ;;
115   i?86-*-darwin*)
116         TARGET=X86_DARWIN; TARGETDIR=x86
117         ;;
118   i?86-*-solaris2.1[[0-9]]*)
119         TARGET=X86_64; TARGETDIR=x86
120         ;;
121   i?86-*-*)
122         TARGET=X86_64; TARGETDIR=x86
123         ;;
124
125   ia64*-*-*)
126         TARGET=IA64; TARGETDIR=ia64
127         ;;
128
129   m32r*-*-*)
130         TARGET=M32R; TARGETDIR=m32r
131         ;;
132
133   m68k-*-*)
134         TARGET=M68K; TARGETDIR=m68k
135         ;;
136
137   mips-sgi-irix5.* | mips-sgi-irix6.* | mips*-*-rtems*)
138         TARGET=MIPS; TARGETDIR=mips
139         ;;
140   mips*-*-linux* | mips*-*-openbsd*)
141         # Support 128-bit long double for NewABI.
142         HAVE_LONG_DOUBLE='defined(__mips64)'
143         TARGET=MIPS; TARGETDIR=mips
144         ;;
145
146   moxie-*-*)
147         TARGET=MOXIE; TARGETDIR=moxie
148         ;;
149
150   powerpc*-*-linux* | powerpc-*-sysv*)
151         TARGET=POWERPC; TARGETDIR=powerpc
152         ;;
153   powerpc-*-amigaos*)
154         TARGET=POWERPC; TARGETDIR=powerpc
155         ;;
156   powerpc-*-beos*)
157         TARGET=POWERPC; TARGETDIR=powerpc
158         ;;
159   powerpc-*-darwin* | powerpc64-*-darwin*)
160         TARGET=POWERPC_DARWIN; TARGETDIR=powerpc
161         ;;
162   powerpc-*-aix* | rs6000-*-aix*)
163         TARGET=POWERPC_AIX; TARGETDIR=powerpc
164         ;;
165   powerpc-*-freebsd* | powerpc-*-openbsd*)
166         TARGET=POWERPC_FREEBSD; TARGETDIR=powerpc
167         ;;
168   powerpc64-*-freebsd*)
169         TARGET=POWERPC; TARGETDIR=powerpc
170         ;;
171   powerpc*-*-rtems*)
172         TARGET=POWERPC; TARGETDIR=powerpc
173         ;;
174
175   s390-*-* | s390x-*-*)
176         TARGET=S390; TARGETDIR=s390
177         ;;
178
179   sh-*-* | sh[[34]]*-*-*)
180         TARGET=SH; TARGETDIR=sh
181         ;;
182   sh64-*-* | sh5*-*-*)
183         TARGET=SH64; TARGETDIR=sh64
184         ;;
185
186   sparc*-*-*)
187         TARGET=SPARC; TARGETDIR=sparc
188         ;;
189
190   tile*-*)
191         TARGET=TILE; TARGETDIR=tile
192         ;;
193
194   x86_64-*-darwin*)
195         TARGET=X86_DARWIN; TARGETDIR=x86
196         ;;
197
198   x86_64-*-cygwin* | x86_64-*-mingw*)
199         TARGET=X86_WIN64; TARGETDIR=x86
200         # All mingw/cygwin/win32 builds require -no-undefined for sharedlib.
201         # We must also check with_cross_host to decide if this is a native
202         # or cross-build and select where to install dlls appropriately.
203         if test -n "$with_cross_host" &&
204            test x"$with_cross_host" != x"no"; then
205           AM_LTLDFLAGS='-no-undefined -bindir "$(toolexeclibdir)"';
206         else
207           AM_LTLDFLAGS='-no-undefined -bindir "$(bindir)"';
208         fi
209         ;;
210
211   x86_64-*-*)
212         TARGET=X86_64; TARGETDIR=x86
213         ;;
214 esac
215
216 AC_SUBST(AM_RUNTESTFLAGS)
217 AC_SUBST(AM_LTLDFLAGS)
218
219 if test $TARGETDIR = unknown; then
220   AC_MSG_ERROR(["libffi has not been ported to $host."])
221 fi
222
223 AM_CONDITIONAL(MIPS, test x$TARGET = xMIPS)
224 AM_CONDITIONAL(BFIN, test x$TARGET = xBFIN)
225 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
226 AM_CONDITIONAL(X86, test x$TARGET = xX86)
227 AM_CONDITIONAL(X86_FREEBSD, test x$TARGET = xX86_FREEBSD)
228 AM_CONDITIONAL(X86_WIN32, test x$TARGET = xX86_WIN32)
229 AM_CONDITIONAL(X86_WIN64, test x$TARGET = xX86_WIN64)
230 AM_CONDITIONAL(X86_DARWIN, test x$TARGET = xX86_DARWIN)
231 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
232 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
233 AM_CONDITIONAL(M32R, test x$TARGET = xM32R)
234 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
235 AM_CONDITIONAL(MOXIE, test x$TARGET = xMOXIE)
236 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
237 AM_CONDITIONAL(POWERPC_AIX, test x$TARGET = xPOWERPC_AIX)
238 AM_CONDITIONAL(POWERPC_DARWIN, test x$TARGET = xPOWERPC_DARWIN)
239 AM_CONDITIONAL(POWERPC_FREEBSD, test x$TARGET = xPOWERPC_FREEBSD)
240 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
241 AM_CONDITIONAL(AVR32, test x$TARGET = xAVR32)
242 AM_CONDITIONAL(LIBFFI_CRIS, test x$TARGET = xLIBFFI_CRIS)
243 AM_CONDITIONAL(FRV, test x$TARGET = xFRV)
244 AM_CONDITIONAL(S390, test x$TARGET = xS390)
245 AM_CONDITIONAL(X86_64, test x$TARGET = xX86_64)
246 AM_CONDITIONAL(SH, test x$TARGET = xSH)
247 AM_CONDITIONAL(SH64, test x$TARGET = xSH64)
248 AM_CONDITIONAL(PA_LINUX, test x$TARGET = xPA_LINUX)
249 AM_CONDITIONAL(PA_HPUX, test x$TARGET = xPA_HPUX)
250 AM_CONDITIONAL(PA64_HPUX, test x$TARGET = xPA64_HPUX)
251 AM_CONDITIONAL(TILE, test x$TARGET = xTILE)
252
253 AC_HEADER_STDC
254 AC_CHECK_FUNCS(memcpy)
255 AC_FUNC_ALLOCA
256
257 AC_CHECK_SIZEOF(double)
258 AC_CHECK_SIZEOF(long double)
259
260 # Also AC_SUBST this variable for ffi.h.
261 if test -z "$HAVE_LONG_DOUBLE"; then
262   HAVE_LONG_DOUBLE=0
263   if test $ac_cv_sizeof_double != $ac_cv_sizeof_long_double; then
264     if test $ac_cv_sizeof_long_double != 0; then
265       HAVE_LONG_DOUBLE=1
266       AC_DEFINE(HAVE_LONG_DOUBLE, 1, [Define if you have the long double type and it is bigger than a double])
267     fi
268   fi
269 fi
270 AC_SUBST(HAVE_LONG_DOUBLE)
271
272 AC_C_BIGENDIAN
273
274 GCC_AS_CFI_PSEUDO_OP
275
276 if test x$TARGET = xSPARC; then
277     AC_CACHE_CHECK([assembler and linker support unaligned pc related relocs],
278         libffi_cv_as_sparc_ua_pcrel, [
279         save_CFLAGS="$CFLAGS"
280         save_LDFLAGS="$LDFLAGS"
281         CFLAGS="$CFLAGS -fpic"
282         LDFLAGS="$LDFLAGS -shared"
283         AC_TRY_LINK([asm (".text; foo: nop; .data; .align 4; .byte 0; .uaword %r_disp32(foo); .text");],,
284                     [libffi_cv_as_sparc_ua_pcrel=yes],
285                     [libffi_cv_as_sparc_ua_pcrel=no])
286         CFLAGS="$save_CFLAGS"
287         LDFLAGS="$save_LDFLAGS"])
288     if test "x$libffi_cv_as_sparc_ua_pcrel" = xyes; then
289         AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
290                   [Define if your assembler and linker support unaligned PC relative relocs.])
291     fi
292
293     AC_CACHE_CHECK([assembler .register pseudo-op support],
294        libffi_cv_as_register_pseudo_op, [
295        libffi_cv_as_register_pseudo_op=unknown
296        # Check if we have .register
297        AC_TRY_COMPILE([asm (".register %g2, #scratch");],,
298                        [libffi_cv_as_register_pseudo_op=yes],
299                        [libffi_cv_as_register_pseudo_op=no])
300     ])
301     if test "x$libffi_cv_as_register_pseudo_op" = xyes; then
302        AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
303                [Define if your assembler supports .register.])
304     fi
305 fi
306
307 if test x$TARGET = xX86 || test x$TARGET = xX86_WIN32 || test x$TARGET = xX86_64; then
308     AC_CACHE_CHECK([assembler supports pc related relocs],
309         libffi_cv_as_x86_pcrel, [
310         libffi_cv_as_x86_pcrel=yes
311         echo '.text; foo: nop; .data; .long foo-.; .text' > conftest.s
312         if $CC $CFLAGS -c conftest.s 2>&1 | $EGREP -i 'illegal|warning' > /dev/null; then
313             libffi_cv_as_x86_pcrel=no
314         fi
315         ])
316     if test "x$libffi_cv_as_x86_pcrel" = xyes; then
317         AC_DEFINE(HAVE_AS_X86_PCREL, 1,
318                   [Define if your assembler supports PC relative relocs.])
319     fi
320
321     AC_CACHE_CHECK([assembler .ascii pseudo-op support],
322        libffi_cv_as_ascii_pseudo_op, [
323        libffi_cv_as_ascii_pseudo_op=unknown
324        # Check if we have .ascii
325        AC_TRY_COMPILE([asm (".ascii \\"string\\"");],,
326                        [libffi_cv_as_ascii_pseudo_op=yes],
327                        [libffi_cv_as_ascii_pseudo_op=no])
328     ])
329     if test "x$libffi_cv_as_ascii_pseudo_op" = xyes; then
330        AC_DEFINE(HAVE_AS_ASCII_PSEUDO_OP, 1,
331                [Define if your assembler supports .ascii.])
332     fi
333
334     AC_CACHE_CHECK([assembler .string pseudo-op support],
335        libffi_cv_as_string_pseudo_op, [
336        libffi_cv_as_string_pseudo_op=unknown
337        # Check if we have .string
338        AC_TRY_COMPILE([asm (".string \\"string\\"");],,
339                        [libffi_cv_as_string_pseudo_op=yes],
340                        [libffi_cv_as_string_pseudo_op=no])
341     ])
342     if test "x$libffi_cv_as_string_pseudo_op" = xyes; then
343        AC_DEFINE(HAVE_AS_STRING_PSEUDO_OP, 1,
344                [Define if your assembler supports .string.])
345     fi
346 fi
347
348 if test x$TARGET = xX86_WIN64; then
349     LT_SYS_SYMBOL_USCORE
350     if test "x$sys_symbol_underscore" = xyes; then
351         AC_DEFINE(SYMBOL_UNDERSCORE, 1, [Define if symbols are underscored.])
352     fi
353 fi
354
355 # On PaX enable kernels that have MPROTECT enable we can't use PROT_EXEC.
356 AC_ARG_ENABLE(pax_emutramp,
357   [  --enable-pax_emutramp       enable pax emulated trampolines, for we can't use PROT_EXEC],
358   if test "$enable_pax_emutramp" = "yes"; then
359     AC_DEFINE(FFI_MMAP_EXEC_EMUTRAMP_PAX, 1,
360       [Define this if you want to enable pax emulated trampolines])
361   fi)
362
363 FFI_EXEC_TRAMPOLINE_TABLE=0
364 case "$target" in
365      *arm*-apple-darwin*)
366        FFI_EXEC_TRAMPOLINE_TABLE=1
367        AC_DEFINE(FFI_EXEC_TRAMPOLINE_TABLE, 1,
368                  [Cannot use PROT_EXEC on this target, so, we revert to
369                    alternative means])
370      ;;
371      *-apple-darwin1* | *-*-freebsd* | *-*-kfreebsd* | *-*-openbsd* | *-pc-solaris*)
372        AC_DEFINE(FFI_MMAP_EXEC_WRIT, 1,
373                  [Cannot use malloc on this target, so, we revert to
374                    alternative means])
375      ;;
376 esac
377 AM_CONDITIONAL(FFI_EXEC_TRAMPOLINE_TABLE, test x$FFI_EXEC_TRAMPOLINE_TABLE = x1)
378 AC_SUBST(FFI_EXEC_TRAMPOLINE_TABLE)
379
380 if test x$TARGET = xX86_64; then
381     AC_CACHE_CHECK([assembler supports unwind section type],
382         libffi_cv_as_x86_64_unwind_section_type, [
383         libffi_cv_as_x86_64_unwind_section_type=yes
384         echo '.section .eh_frame,"a",@unwind' > conftest.s
385         if $CC $CFLAGS -c conftest.s 2>&1 | grep -i warning > /dev/null; then
386             libffi_cv_as_x86_64_unwind_section_type=no
387         fi
388         ])
389     if test "x$libffi_cv_as_x86_64_unwind_section_type" = xyes; then
390         AC_DEFINE(HAVE_AS_X86_64_UNWIND_SECTION_TYPE, 1,
391                   [Define if your assembler supports unwind section type.])
392     fi
393 fi
394
395 if test "x$GCC" = "xyes"; then
396   AC_CACHE_CHECK([whether .eh_frame section should be read-only],
397       libffi_cv_ro_eh_frame, [
398         libffi_cv_ro_eh_frame=no
399         echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
400         if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
401             if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
402                 libffi_cv_ro_eh_frame=yes
403             elif grep '.section.*eh_frame.*#alloc' conftest.c \
404                  | grep -v '#write' > /dev/null; then
405                 libffi_cv_ro_eh_frame=yes
406             fi
407         fi
408         rm -f conftest.*
409       ])
410   if test "x$libffi_cv_ro_eh_frame" = xyes; then
411       AC_DEFINE(HAVE_RO_EH_FRAME, 1,
412               [Define if .eh_frame sections should be read-only.])
413       AC_DEFINE(EH_FRAME_FLAGS, "a",
414               [Define to the flags needed for the .section .eh_frame directive.  ])
415   else
416       AC_DEFINE(EH_FRAME_FLAGS, "aw",
417               [Define to the flags needed for the .section .eh_frame directive.  ])
418   fi
419
420   AC_CACHE_CHECK([for __attribute__((visibility("hidden")))],
421       libffi_cv_hidden_visibility_attribute, [
422         echo 'int __attribute__ ((visibility ("hidden"))) foo (void) { return 1  ; }' > conftest.c
423         libffi_cv_hidden_visibility_attribute=no
424         if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
425             if grep '\.hidden.*foo' conftest.s >/dev/null; then
426                 libffi_cv_hidden_visibility_attribute=yes
427             fi
428         fi
429         rm -f conftest.*
430       ])
431   if test $libffi_cv_hidden_visibility_attribute = yes; then
432       AC_DEFINE(HAVE_HIDDEN_VISIBILITY_ATTRIBUTE, 1,
433               [Define if __attribute__((visibility("hidden"))) is supported.])
434   fi
435 fi
436
437 AH_BOTTOM([
438 #ifdef HAVE_HIDDEN_VISIBILITY_ATTRIBUTE
439 #ifdef LIBFFI_ASM
440 #define FFI_HIDDEN(name) .hidden name
441 #else
442 #define FFI_HIDDEN __attribute__ ((visibility ("hidden")))
443 #endif
444 #else
445 #ifdef LIBFFI_ASM
446 #define FFI_HIDDEN(name)
447 #else
448 #define FFI_HIDDEN
449 #endif
450 #endif
451 ])
452
453 AC_SUBST(TARGET)
454 AC_SUBST(TARGETDIR)
455
456 AC_SUBST(SHELL)
457
458 AC_ARG_ENABLE(debug,
459 [  --enable-debug          debugging mode],
460   if test "$enable_debug" = "yes"; then
461     AC_DEFINE(FFI_DEBUG, 1, [Define this if you want extra debugging.])
462   fi)
463 AM_CONDITIONAL(FFI_DEBUG, test "$enable_debug" = "yes")
464
465 AC_ARG_ENABLE(structs,
466 [  --disable-structs       omit code for struct support],
467   if test "$enable_structs" = "no"; then
468     AC_DEFINE(FFI_NO_STRUCTS, 1, [Define this is you do not want support for aggregate types.])
469   fi)
470
471 AC_ARG_ENABLE(raw-api,
472 [  --disable-raw-api       make the raw api unavailable],
473   if test "$enable_raw_api" = "no"; then
474     AC_DEFINE(FFI_NO_RAW_API, 1, [Define this is you do not want support for the raw API.])
475   fi)
476
477 AC_ARG_ENABLE(purify-safety,
478 [  --enable-purify-safety  purify-safe mode],
479   if test "$enable_purify_safety" = "yes"; then
480     AC_DEFINE(USING_PURIFY, 1, [Define this if you are using Purify and want to suppress spurious messages.])
481   fi)
482
483 # These variables are only ever used when we cross-build to X86_WIN32.
484 # And we only support this with GCC, so...
485 if test x"$GCC" != x"no"; then
486   if test -n "$with_cross_host" &&
487      test x"$with_cross_host" != x"no"; then
488     toolexecdir='$(exec_prefix)/$(target_alias)'
489     toolexeclibdir='$(toolexecdir)/lib'
490   else
491     toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
492     toolexeclibdir='$(libdir)'
493   fi
494   multi_os_directory=`$CC -print-multi-os-directory`
495   case $multi_os_directory in
496     .) ;; # Avoid trailing /.
497     *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
498   esac
499   AC_SUBST(toolexecdir)
500   AC_SUBST(toolexeclibdir)
501 fi
502
503 if test "${multilib}" = "yes"; then
504   multilib_arg="--enable-multilib"
505 else
506   multilib_arg=
507 fi
508
509 AC_CONFIG_COMMANDS(include, [test -d include || mkdir include])
510 AC_CONFIG_COMMANDS(src, [
511 test -d src || mkdir src
512 test -d src/$TARGETDIR || mkdir src/$TARGETDIR
513 ], [TARGETDIR="$TARGETDIR"])
514
515 AC_CONFIG_LINKS(include/ffitarget.h:src/$TARGETDIR/ffitarget.h)
516
517 AC_CONFIG_FILES(include/Makefile include/ffi.h Makefile testsuite/Makefile man/Makefile libffi.pc)
518
519 AC_OUTPUT