df20c2f41ec95eac775a4f639d1aee1fec33a829
[libffi.git] / configure.ac
1 dnl Process this with autoconf to create configure
2
3 AC_PREREQ(2.63)
4
5 AC_INIT([libffi], [3.0.11-rc2], [http://github.com/atgreen/libffi/issues])
6 AC_CONFIG_HEADERS([fficonfig.h])
7
8 AC_CANONICAL_SYSTEM
9 target_alias=${target_alias-$host_alias}
10
11 . ${srcdir}/configure.host
12
13 AX_ENABLE_BUILDDIR
14
15 AM_INIT_AUTOMAKE
16
17 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
18 # We must force CC to /not/ be precious variables; otherwise
19 # the wrong, non-multilib-adjusted value will be used in multilibs.
20 # As a side effect, we have to subst CFLAGS ourselves.
21 # Also save and restore CFLAGS, since AC_PROG_CC will come up with
22 # defaults of its own if none are provided.
23
24 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
25 m4_define([_AC_ARG_VAR_PRECIOUS],[])
26 save_CFLAGS=$CFLAGS
27 AC_PROG_CC
28 CFLAGS=$save_CFLAGS
29 m4_undefine([_AC_ARG_VAR_PRECIOUS])
30 m4_rename([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
31
32 AC_SUBST(CFLAGS)
33
34 AM_PROG_AS
35 AM_PROG_CC_C_O
36 AC_PROG_LIBTOOL
37 AC_CONFIG_MACRO_DIR([m4])
38
39 AX_CC_MAXOPT
40 AX_CFLAGS_WARN_ALL
41 if test "x$GCC" = "xyes"; then
42   CFLAGS="$CFLAGS -fexceptions"
43 fi
44
45 AM_MAINTAINER_MODE
46
47 AC_CHECK_HEADERS(sys/mman.h)
48 AC_CHECK_FUNCS(mmap)
49 AC_FUNC_MMAP_BLACKLIST
50
51 dnl The -no-testsuite modules omit the test subdir.
52 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
53
54 TARGETDIR="unknown"
55 case "$host" in
56   alpha*-*-*)
57         TARGET=ALPHA; TARGETDIR=alpha;
58         # Support 128-bit long double, changeable via command-line switch.
59         HAVE_LONG_DOUBLE='defined(__LONG_DOUBLE_128__)'
60         ;;
61
62   arm*-*-*)
63         TARGET=ARM; TARGETDIR=arm
64         ;;
65
66   amd64-*-freebsd* | amd64-*-openbsd*)
67         TARGET=X86_64; TARGETDIR=x86
68         ;;
69
70   amd64-*-freebsd*)
71         TARGET=X86_64; TARGETDIR=x86
72         ;;
73
74   avr32*-*-*)
75         TARGET=AVR32; TARGETDIR=avr32
76         ;;
77
78   cris-*-*)
79         TARGET=LIBFFI_CRIS; TARGETDIR=cris
80         ;;
81
82   frv-*-*)
83         TARGET=FRV; TARGETDIR=frv
84         ;;
85
86   hppa*-*-linux* | parisc*-*-linux* | hppa*-*-openbsd*)
87         TARGET=PA_LINUX; TARGETDIR=pa
88         ;;
89   hppa*64-*-hpux*)
90         TARGET=PA64_HPUX; TARGETDIR=pa
91         ;;
92   hppa*-*-hpux*)
93         TARGET=PA_HPUX; TARGETDIR=pa
94         ;;
95
96   i?86-*-freebsd* | i?86-*-openbsd*)
97         TARGET=X86_FREEBSD; TARGETDIR=x86
98         ;;
99   i?86-win32* | i?86-*-cygwin* | i?86-*-mingw* | i?86-*-os2* | i?86-*-interix*)
100         TARGET=X86_WIN32; TARGETDIR=x86
101         # All mingw/cygwin/win32 builds require -no-undefined for sharedlib.
102         # We must also check with_cross_host to decide if this is a native
103         # or cross-build and select where to install dlls appropriately.
104         if test -n "$with_cross_host" &&
105            test x"$with_cross_host" != x"no"; then
106           AM_LTLDFLAGS='-no-undefined -bindir "$(toolexeclibdir)"';
107         else
108           AM_LTLDFLAGS='-no-undefined -bindir "$(bindir)"';
109         fi
110         ;;
111   i?86-*-darwin*)
112         TARGET=X86_DARWIN; TARGETDIR=x86
113         ;;
114   i?86-*-solaris2.1[[0-9]]*)
115         TARGET=X86_64; TARGETDIR=x86
116         ;;
117   i?86-*-*)
118         TARGET=X86_64; TARGETDIR=x86
119         ;;
120
121   ia64*-*-*)
122         TARGET=IA64; TARGETDIR=ia64
123         ;;
124
125   m32r*-*-*)
126         TARGET=M32R; TARGETDIR=m32r
127         ;;
128
129   m68k-*-*)
130         TARGET=M68K; TARGETDIR=m68k
131         ;;
132
133   mips-sgi-irix5.* | mips-sgi-irix6.* | mips*-*-rtems*)
134         TARGET=MIPS; TARGETDIR=mips
135         ;;
136   mips*-*-linux* | mips*-*-openbsd*)
137         # Support 128-bit long double for NewABI.
138         HAVE_LONG_DOUBLE='defined(__mips64)'
139         TARGET=MIPS; TARGETDIR=mips
140         ;;
141
142   moxie-*-*)
143         TARGET=MOXIE; TARGETDIR=moxie
144         ;;
145
146   powerpc*-*-linux* | powerpc-*-sysv*)
147         TARGET=POWERPC; TARGETDIR=powerpc
148         ;;
149   powerpc-*-amigaos*)
150         TARGET=POWERPC; TARGETDIR=powerpc
151         ;;
152   powerpc-*-beos*)
153         TARGET=POWERPC; TARGETDIR=powerpc
154         ;;
155   powerpc-*-darwin* | powerpc64-*-darwin*)
156         TARGET=POWERPC_DARWIN; TARGETDIR=powerpc
157         ;;
158   powerpc-*-aix* | rs6000-*-aix*)
159         TARGET=POWERPC_AIX; TARGETDIR=powerpc
160         ;;
161   powerpc-*-freebsd* | powerpc-*-openbsd*)
162         TARGET=POWERPC_FREEBSD; TARGETDIR=powerpc
163         ;;
164   powerpc64-*-freebsd*)
165         TARGET=POWERPC; TARGETDIR=powerpc
166         ;;
167   powerpc*-*-rtems*)
168         TARGET=POWERPC; TARGETDIR=powerpc
169         ;;
170
171   s390-*-* | s390x-*-*)
172         TARGET=S390; TARGETDIR=s390
173         ;;
174
175   sh-*-* | sh[[34]]*-*-*)
176         TARGET=SH; TARGETDIR=sh
177         ;;
178   sh64-*-* | sh5*-*-*)
179         TARGET=SH64; TARGETDIR=sh64
180         ;;
181
182   sparc*-*-*)
183         TARGET=SPARC; TARGETDIR=sparc
184         ;;
185
186   x86_64-*-darwin*)
187         TARGET=X86_DARWIN; TARGETDIR=x86
188         ;;
189
190   x86_64-*-cygwin* | x86_64-*-mingw*)
191         TARGET=X86_WIN64; TARGETDIR=x86
192         ;;
193
194   x86_64-*-*)
195         TARGET=X86_64; TARGETDIR=x86
196         ;;
197 esac
198
199 AC_SUBST(AM_RUNTESTFLAGS)
200 AC_SUBST(AM_LTLDFLAGS)
201
202 if test $TARGETDIR = unknown; then
203   AC_MSG_ERROR(["libffi has not been ported to $host."])
204 fi
205
206 AM_CONDITIONAL(MIPS, test x$TARGET = xMIPS)
207 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
208 AM_CONDITIONAL(X86, test x$TARGET = xX86)
209 AM_CONDITIONAL(X86_FREEBSD, test x$TARGET = xX86_FREEBSD)
210 AM_CONDITIONAL(X86_WIN32, test x$TARGET = xX86_WIN32)
211 AM_CONDITIONAL(X86_WIN64, test x$TARGET = xX86_WIN64)
212 AM_CONDITIONAL(X86_DARWIN, test x$TARGET = xX86_DARWIN)
213 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
214 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
215 AM_CONDITIONAL(M32R, test x$TARGET = xM32R)
216 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
217 AM_CONDITIONAL(MOXIE, test x$TARGET = xMOXIE)
218 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
219 AM_CONDITIONAL(POWERPC_AIX, test x$TARGET = xPOWERPC_AIX)
220 AM_CONDITIONAL(POWERPC_DARWIN, test x$TARGET = xPOWERPC_DARWIN)
221 AM_CONDITIONAL(POWERPC_FREEBSD, test x$TARGET = xPOWERPC_FREEBSD)
222 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
223 AM_CONDITIONAL(AVR32, test x$TARGET = xAVR32)
224 AM_CONDITIONAL(LIBFFI_CRIS, test x$TARGET = xLIBFFI_CRIS)
225 AM_CONDITIONAL(FRV, test x$TARGET = xFRV)
226 AM_CONDITIONAL(S390, test x$TARGET = xS390)
227 AM_CONDITIONAL(X86_64, test x$TARGET = xX86_64)
228 AM_CONDITIONAL(SH, test x$TARGET = xSH)
229 AM_CONDITIONAL(SH64, test x$TARGET = xSH64)
230 AM_CONDITIONAL(PA_LINUX, test x$TARGET = xPA_LINUX)
231 AM_CONDITIONAL(PA_HPUX, test x$TARGET = xPA_HPUX)
232 AM_CONDITIONAL(PA64_HPUX, test x$TARGET = xPA64_HPUX)
233
234 AC_HEADER_STDC
235 AC_CHECK_FUNCS(memcpy)
236 AC_FUNC_ALLOCA
237
238 AC_CHECK_SIZEOF(double)
239 AC_CHECK_SIZEOF(long double)
240
241 # Also AC_SUBST this variable for ffi.h.
242 if test -z "$HAVE_LONG_DOUBLE"; then
243   HAVE_LONG_DOUBLE=0
244   if test $ac_cv_sizeof_double != $ac_cv_sizeof_long_double; then
245     if test $ac_cv_sizeof_long_double != 0; then
246       HAVE_LONG_DOUBLE=1
247       AC_DEFINE(HAVE_LONG_DOUBLE, 1, [Define if you have the long double type and it is bigger than a double])
248     fi
249   fi
250 fi
251 AC_SUBST(HAVE_LONG_DOUBLE)
252
253 AC_C_BIGENDIAN
254
255 GCC_AS_CFI_PSEUDO_OP
256
257 if test x$TARGET = xSPARC; then
258     AC_CACHE_CHECK([assembler and linker support unaligned pc related relocs],
259         libffi_cv_as_sparc_ua_pcrel, [
260         save_CFLAGS="$CFLAGS"
261         save_LDFLAGS="$LDFLAGS"
262         CFLAGS="$CFLAGS -fpic"
263         LDFLAGS="$LDFLAGS -shared"
264         AC_TRY_LINK([asm (".text; foo: nop; .data; .align 4; .byte 0; .uaword %r_disp32(foo); .text");],,
265                     [libffi_cv_as_sparc_ua_pcrel=yes],
266                     [libffi_cv_as_sparc_ua_pcrel=no])
267         CFLAGS="$save_CFLAGS"
268         LDFLAGS="$save_LDFLAGS"])
269     if test "x$libffi_cv_as_sparc_ua_pcrel" = xyes; then
270         AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
271                   [Define if your assembler and linker support unaligned PC relative relocs.])
272     fi
273
274     AC_CACHE_CHECK([assembler .register pseudo-op support],
275        libffi_cv_as_register_pseudo_op, [
276        libffi_cv_as_register_pseudo_op=unknown
277        # Check if we have .register
278        AC_TRY_COMPILE([asm (".register %g2, #scratch");],,
279                        [libffi_cv_as_register_pseudo_op=yes],
280                        [libffi_cv_as_register_pseudo_op=no])
281     ])
282     if test "x$libffi_cv_as_register_pseudo_op" = xyes; then
283        AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
284                [Define if your assembler supports .register.])
285     fi
286 fi
287
288 if test x$TARGET = xX86 || test x$TARGET = xX86_WIN32 || test x$TARGET = xX86_64; then
289     AC_CACHE_CHECK([assembler supports pc related relocs],
290         libffi_cv_as_x86_pcrel, [
291         libffi_cv_as_x86_pcrel=no
292         echo '.text; foo: nop; .data; .long foo-.; .text' > conftest.s
293         if $CC $CFLAGS -c conftest.s > /dev/null; then
294            libffi_cv_as_x86_pcrel=yes
295         fi
296         ])
297     if test "x$libffi_cv_as_x86_pcrel" = xyes; then
298         AC_DEFINE(HAVE_AS_X86_PCREL, 1,
299                   [Define if your assembler supports PC relative relocs.])
300     fi
301
302     AC_CACHE_CHECK([assembler .ascii pseudo-op support],
303        libffi_cv_as_ascii_pseudo_op, [
304        libffi_cv_as_ascii_pseudo_op=unknown
305        # Check if we have .ascii
306        AC_TRY_COMPILE([asm (".ascii \\"string\\"");],,
307                        [libffi_cv_as_ascii_pseudo_op=yes],
308                        [libffi_cv_as_ascii_pseudo_op=no])
309     ])
310     if test "x$libffi_cv_as_ascii_pseudo_op" = xyes; then
311        AC_DEFINE(HAVE_AS_ASCII_PSEUDO_OP, 1,
312                [Define if your assembler supports .ascii.])
313     fi
314
315     AC_CACHE_CHECK([assembler .string pseudo-op support],
316        libffi_cv_as_string_pseudo_op, [
317        libffi_cv_as_string_pseudo_op=unknown
318        # Check if we have .string
319        AC_TRY_COMPILE([asm (".string \\"string\\"");],,
320                        [libffi_cv_as_string_pseudo_op=yes],
321                        [libffi_cv_as_string_pseudo_op=no])
322     ])
323     if test "x$libffi_cv_as_string_pseudo_op" = xyes; then
324        AC_DEFINE(HAVE_AS_STRING_PSEUDO_OP, 1,
325                [Define if your assembler supports .string.])
326     fi
327 fi
328
329 if test x$TARGET = xX86_WIN64; then
330     LT_SYS_SYMBOL_USCORE
331     if test "x$sys_symbol_underscore" = xyes; then
332         AC_DEFINE(SYMBOL_UNDERSCORE, 1, [Define if symbols are underscored.])
333     fi
334 fi
335
336
337 FFI_EXEC_TRAMPOLINE_TABLE=0
338 case "$target" in
339      *arm*-apple-darwin*)
340        FFI_EXEC_TRAMPOLINE_TABLE=1
341        AC_DEFINE(FFI_EXEC_TRAMPOLINE_TABLE, 1,
342                  [Cannot use PROT_EXEC on this target, so, we revert to
343                    alternative means])
344      ;;
345      *-apple-darwin1[[10]]* | *-*-freebsd* | *-*-kfreebsd* | *-*-openbsd* | *-pc-solaris*)
346        AC_DEFINE(FFI_MMAP_EXEC_WRIT, 1,
347                  [Cannot use malloc on this target, so, we revert to
348                    alternative means])
349      ;;
350 esac
351 AM_CONDITIONAL(FFI_EXEC_TRAMPOLINE_TABLE, test x$FFI_EXEC_TRAMPOLINE_TABLE = x1)
352 AC_SUBST(FFI_EXEC_TRAMPOLINE_TABLE)
353
354 if test x$TARGET = xX86_64; then
355     AC_CACHE_CHECK([assembler supports unwind section type],
356         libffi_cv_as_x86_64_unwind_section_type, [
357         libffi_cv_as_x86_64_unwind_section_type=yes
358         echo '.section .eh_frame,"a",@unwind' > conftest.s
359         if $CC $CFLAGS -c conftest.s 2>&1 | grep -i warning > /dev/null; then
360             libffi_cv_as_x86_64_unwind_section_type=no
361         fi
362         ])
363     if test "x$libffi_cv_as_x86_64_unwind_section_type" = xyes; then
364         AC_DEFINE(HAVE_AS_X86_64_UNWIND_SECTION_TYPE, 1,
365                   [Define if your assembler supports unwind section type.])
366     fi
367 fi
368
369 if test "x$GCC" = "xyes"; then
370   AC_CACHE_CHECK([whether .eh_frame section should be read-only],
371       libffi_cv_ro_eh_frame, [
372         libffi_cv_ro_eh_frame=no
373         echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
374         if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
375             if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
376                 libffi_cv_ro_eh_frame=yes
377             elif grep '.section.*eh_frame.*#alloc' conftest.c \
378                  | grep -v '#write' > /dev/null; then
379                 libffi_cv_ro_eh_frame=yes
380             fi
381         fi
382         rm -f conftest.*
383       ])
384   if test "x$libffi_cv_ro_eh_frame" = xyes; then
385       AC_DEFINE(HAVE_RO_EH_FRAME, 1,
386               [Define if .eh_frame sections should be read-only.])
387       AC_DEFINE(EH_FRAME_FLAGS, "a",
388               [Define to the flags needed for the .section .eh_frame directive.  ])
389   else
390       AC_DEFINE(EH_FRAME_FLAGS, "aw",
391               [Define to the flags needed for the .section .eh_frame directive.  ])
392   fi
393
394   AC_CACHE_CHECK([for __attribute__((visibility("hidden")))],
395       libffi_cv_hidden_visibility_attribute, [
396         echo 'int __attribute__ ((visibility ("hidden"))) foo (void) { return 1  ; }' > conftest.c
397         libffi_cv_hidden_visibility_attribute=no
398         if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
399             if grep '\.hidden.*foo' conftest.s >/dev/null; then
400                 libffi_cv_hidden_visibility_attribute=yes
401             fi
402         fi
403         rm -f conftest.*
404       ])
405   if test $libffi_cv_hidden_visibility_attribute = yes; then
406       AC_DEFINE(HAVE_HIDDEN_VISIBILITY_ATTRIBUTE, 1,
407               [Define if __attribute__((visibility("hidden"))) is supported.])
408   fi
409 fi
410
411 AH_BOTTOM([
412 #ifdef HAVE_HIDDEN_VISIBILITY_ATTRIBUTE
413 #ifdef LIBFFI_ASM
414 #define FFI_HIDDEN(name) .hidden name
415 #else
416 #define FFI_HIDDEN __attribute__ ((visibility ("hidden")))
417 #endif
418 #else
419 #ifdef LIBFFI_ASM
420 #define FFI_HIDDEN(name)
421 #else
422 #define FFI_HIDDEN
423 #endif
424 #endif
425 ])
426
427 AC_SUBST(TARGET)
428 AC_SUBST(TARGETDIR)
429
430 AC_SUBST(SHELL)
431
432 AC_ARG_ENABLE(debug,
433 [  --enable-debug          debugging mode],
434   if test "$enable_debug" = "yes"; then
435     AC_DEFINE(FFI_DEBUG, 1, [Define this if you want extra debugging.])
436   fi)
437 AM_CONDITIONAL(FFI_DEBUG, test "$enable_debug" = "yes")
438
439 AC_ARG_ENABLE(structs,
440 [  --disable-structs       omit code for struct support],
441   if test "$enable_structs" = "no"; then
442     AC_DEFINE(FFI_NO_STRUCTS, 1, [Define this is you do not want support for aggregate types.])
443   fi)
444
445 AC_ARG_ENABLE(raw-api,
446 [  --disable-raw-api       make the raw api unavailable],
447   if test "$enable_raw_api" = "no"; then
448     AC_DEFINE(FFI_NO_RAW_API, 1, [Define this is you do not want support for the raw API.])
449   fi)
450
451 AC_ARG_ENABLE(purify-safety,
452 [  --enable-purify-safety  purify-safe mode],
453   if test "$enable_purify_safety" = "yes"; then
454     AC_DEFINE(USING_PURIFY, 1, [Define this if you are using Purify and want to suppress spurious messages.])
455   fi)
456
457 # These variables are only ever used when we cross-build to X86_WIN32.
458 # And we only support this with GCC, so...
459 if test x"$GCC" != x"no"; then
460   if test -n "$with_cross_host" &&
461      test x"$with_cross_host" != x"no"; then
462     toolexecdir='$(exec_prefix)/$(target_alias)'
463     toolexeclibdir='$(toolexecdir)/lib'
464   else
465     toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
466     toolexeclibdir='$(libdir)'
467   fi
468   multi_os_directory=`$CC -print-multi-os-directory`
469   case $multi_os_directory in
470     .) ;; # Avoid trailing /.
471     *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
472   esac
473   AC_SUBST(toolexecdir)
474   AC_SUBST(toolexeclibdir)
475 fi
476
477 if test "${multilib}" = "yes"; then
478   multilib_arg="--enable-multilib"
479 else
480   multilib_arg=
481 fi
482
483 AC_CONFIG_COMMANDS(include, [test -d include || mkdir include])
484 AC_CONFIG_COMMANDS(src, [
485 test -d src || mkdir src
486 test -d src/$TARGETDIR || mkdir src/$TARGETDIR
487 ], [TARGETDIR="$TARGETDIR"])
488
489 AC_CONFIG_LINKS(include/ffitarget.h:src/$TARGETDIR/ffitarget.h)
490
491 AC_CONFIG_FILES(include/Makefile include/ffi.h Makefile testsuite/Makefile man/Makefile libffi.pc)
492
493 AC_OUTPUT