Version 3.0.10
[libffi.git] / .pc / ppc64-darwin / configure.ac
1 dnl Process this with autoconf to create configure
2
3 AC_PREREQ(2.63)
4
5 AC_INIT([libffi], [3.0.10], [http://sourceware.org/libffi.html])
6 AC_CONFIG_HEADERS([fficonfig.h])
7
8 AC_CANONICAL_SYSTEM
9 target_alias=${target_alias-$host_alias}
10
11 . ${srcdir}/configure.host
12
13 AM_INIT_AUTOMAKE
14
15 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
16 # We must force CC to /not/ be precious variables; otherwise
17 # the wrong, non-multilib-adjusted value will be used in multilibs.
18 # As a side effect, we have to subst CFLAGS ourselves.
19 # Also save and restore CFLAGS, since AC_PROG_CC will come up with
20 # defaults of its own if none are provided.
21
22 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
23 m4_define([_AC_ARG_VAR_PRECIOUS],[])
24 save_CFLAGS=$CFLAGS
25 AC_PROG_CC
26 CFLAGS=$save_CFLAGS
27 m4_undefine([_AC_ARG_VAR_PRECIOUS])
28 m4_rename([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
29
30 AC_SUBST(CFLAGS)
31
32 AM_PROG_AS
33 AM_PROG_CC_C_O
34 AC_PROG_LIBTOOL
35 AC_CONFIG_MACRO_DIR([m4])
36
37 AM_MAINTAINER_MODE
38
39 AC_CHECK_HEADERS(sys/mman.h)
40 AC_CHECK_FUNCS(mmap)
41 AC_FUNC_MMAP_BLACKLIST
42
43 dnl The -no-testsuite modules omit the test subdir.
44 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
45
46 TARGETDIR="unknown"
47 case "$host" in
48   alpha*-*-*)
49         TARGET=ALPHA; TARGETDIR=alpha;
50         # Support 128-bit long double, changeable via command-line switch.
51         HAVE_LONG_DOUBLE='defined(__LONG_DOUBLE_128__)'
52         ;;
53
54   arm*-*-*)
55         TARGET=ARM; TARGETDIR=arm
56         ;;
57
58   amd64-*-freebsd* | amd64-*-openbsd*)
59         TARGET=X86_64; TARGETDIR=x86
60         ;;
61
62   amd64-*-freebsd*)
63         TARGET=X86_64; TARGETDIR=x86
64         ;;
65
66   avr32*-*-*)
67         TARGET=AVR32; TARGETDIR=avr32
68         ;;
69
70   cris-*-*)
71         TARGET=LIBFFI_CRIS; TARGETDIR=cris
72         ;;
73
74   frv-*-*)
75         TARGET=FRV; TARGETDIR=frv
76         ;;
77
78   hppa*-*-linux* | parisc*-*-linux*)
79         TARGET=PA_LINUX; TARGETDIR=pa
80         ;;
81   hppa*64-*-hpux*)
82         TARGET=PA64_HPUX; TARGETDIR=pa
83         ;;
84   hppa*-*-hpux*)
85         TARGET=PA_HPUX; TARGETDIR=pa
86         ;;
87
88   i?86-*-freebsd* | i?86-*-openbsd*)
89         TARGET=X86_FREEBSD; TARGETDIR=x86
90         ;;
91   i?86-win32* | i?86-*-cygwin* | i?86-*-mingw* | i?86-*-os2* | i?86-*-interix*)
92         TARGET=X86_WIN32; TARGETDIR=x86
93         # All mingw/cygwin/win32 builds require -no-undefined for sharedlib.
94         # We must also check with_cross_host to decide if this is a native
95         # or cross-build and select where to install dlls appropriately.
96         if test -n "$with_cross_host" &&
97            test x"$with_cross_host" != x"no"; then
98           AM_LTLDFLAGS='-no-undefined -bindir "$(toolexeclibdir)"';
99         else
100           AM_LTLDFLAGS='-no-undefined -bindir "$(bindir)"';
101         fi
102         ;;
103   i?86-*-darwin*)
104         TARGET=X86_DARWIN; TARGETDIR=x86
105         ;;
106   i?86-*-solaris2.1[[0-9]]*)
107         TARGET=X86_64; TARGETDIR=x86
108         ;;
109   i?86-*-*)
110         TARGET=X86; TARGETDIR=x86
111         ;;
112
113   ia64*-*-*)
114         TARGET=IA64; TARGETDIR=ia64
115         ;;
116
117   m32r*-*-*)
118         TARGET=M32R; TARGETDIR=m32r
119         ;;
120
121   m68k-*-*)
122         TARGET=M68K; TARGETDIR=m68k
123         ;;
124
125   mips-sgi-irix5.* | mips-sgi-irix6.* | mips*-*-rtems*)
126         TARGET=MIPS; TARGETDIR=mips
127         ;;
128   mips*-*-linux*)
129         # Support 128-bit long double for NewABI.
130         HAVE_LONG_DOUBLE='defined(__mips64)'
131         TARGET=MIPS; TARGETDIR=mips
132         ;;
133
134   powerpc*-*-linux* | powerpc-*-sysv*)
135         TARGET=POWERPC; TARGETDIR=powerpc
136         ;;
137   powerpc-*-beos*)
138         TARGET=POWERPC; TARGETDIR=powerpc
139         ;;
140   powerpc-*-darwin*)
141         TARGET=POWERPC_DARWIN; TARGETDIR=powerpc
142         ;;
143   powerpc-*-aix* | rs6000-*-aix*)
144         TARGET=POWERPC_AIX; TARGETDIR=powerpc
145         ;;
146   powerpc-*-freebsd*)
147         TARGET=POWERPC_FREEBSD; TARGETDIR=powerpc
148         ;;
149  powerpc64-*-freebsd*)
150         TARGET=POWERPC; TARGETDIR=powerpc
151         ;;
152   powerpc*-*-rtems*)
153         TARGET=POWERPC; TARGETDIR=powerpc
154         ;;
155
156   s390-*-* | s390x-*-*)
157         TARGET=S390; TARGETDIR=s390
158         ;;
159
160   sh-*-* | sh[[34]]*-*-*)
161         TARGET=SH; TARGETDIR=sh
162         ;;
163   sh64-*-* | sh5*-*-*)
164         TARGET=SH64; TARGETDIR=sh64
165         ;;
166
167   sparc*-*-*)
168         TARGET=SPARC; TARGETDIR=sparc
169         ;;
170
171   x86_64-*-darwin*)
172         TARGET=X86_DARWIN; TARGETDIR=x86
173         ;;
174
175   x86_64-*-cygwin* | x86_64-*-mingw*)
176         TARGET=X86_WIN64; TARGETDIR=x86
177         ;;
178
179   x86_64-*-*)
180         TARGET=X86_64; TARGETDIR=x86
181         ;;
182 esac
183
184 AC_SUBST(AM_RUNTESTFLAGS)
185 AC_SUBST(AM_LTLDFLAGS)
186
187 if test $TARGETDIR = unknown; then
188   AC_MSG_ERROR(["libffi has not been ported to $host."])
189 fi
190
191 AM_CONDITIONAL(MIPS, test x$TARGET = xMIPS)
192 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
193 AM_CONDITIONAL(X86, test x$TARGET = xX86)
194 AM_CONDITIONAL(X86_FREEBSD, test x$TARGET = xX86_FREEBSD)
195 AM_CONDITIONAL(X86_WIN32, test x$TARGET = xX86_WIN32)
196 AM_CONDITIONAL(X86_WIN64, test x$TARGET = xX86_WIN64)
197 AM_CONDITIONAL(X86_DARWIN, test x$TARGET = xX86_DARWIN)
198 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
199 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
200 AM_CONDITIONAL(M32R, test x$TARGET = xM32R)
201 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
202 AM_CONDITIONAL(MOXIE, test x$TARGET = xMOXIE)
203 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
204 AM_CONDITIONAL(POWERPC_AIX, test x$TARGET = xPOWERPC_AIX)
205 AM_CONDITIONAL(POWERPC_DARWIN, test x$TARGET = xPOWERPC_DARWIN)
206 AM_CONDITIONAL(POWERPC_FREEBSD, test x$TARGET = xPOWERPC_FREEBSD)
207 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
208 AM_CONDITIONAL(AVR32, test x$TARGET = xAVR32)
209 AM_CONDITIONAL(LIBFFI_CRIS, test x$TARGET = xLIBFFI_CRIS)
210 AM_CONDITIONAL(FRV, test x$TARGET = xFRV)
211 AM_CONDITIONAL(S390, test x$TARGET = xS390)
212 AM_CONDITIONAL(X86_64, test x$TARGET = xX86_64)
213 AM_CONDITIONAL(SH, test x$TARGET = xSH)
214 AM_CONDITIONAL(SH64, test x$TARGET = xSH64)
215 AM_CONDITIONAL(PA_LINUX, test x$TARGET = xPA_LINUX)
216 AM_CONDITIONAL(PA_HPUX, test x$TARGET = xPA_HPUX)
217 AM_CONDITIONAL(PA64_HPUX, test x$TARGET = xPA64_HPUX)
218
219 AC_HEADER_STDC
220 AC_CHECK_FUNCS(memcpy)
221 AC_FUNC_ALLOCA
222
223 AC_CHECK_SIZEOF(double)
224 AC_CHECK_SIZEOF(long double)
225
226 # Also AC_SUBST this variable for ffi.h.
227 if test -z "$HAVE_LONG_DOUBLE"; then
228   HAVE_LONG_DOUBLE=0
229   if test $ac_cv_sizeof_double != $ac_cv_sizeof_long_double; then
230     if test $ac_cv_sizeof_long_double != 0; then
231       HAVE_LONG_DOUBLE=1
232       AC_DEFINE(HAVE_LONG_DOUBLE, 1, [Define if you have the long double type and it is bigger than a double])
233     fi
234   fi
235 fi
236 AC_SUBST(HAVE_LONG_DOUBLE)
237
238 AC_C_BIGENDIAN
239
240 AC_CACHE_CHECK([assembler .cfi pseudo-op support],
241     libffi_cv_as_cfi_pseudo_op, [
242     libffi_cv_as_cfi_pseudo_op=unknown
243     AC_TRY_COMPILE([asm (".cfi_startproc\n\t.cfi_endproc");],,
244                    [libffi_cv_as_cfi_pseudo_op=yes],
245                    [libffi_cv_as_cfi_pseudo_op=no])
246 ])
247 if test "x$libffi_cv_as_cfi_pseudo_op" = xyes; then
248     AC_DEFINE(HAVE_AS_CFI_PSEUDO_OP, 1,
249               [Define if your assembler supports .cfi_* directives.])
250 fi
251
252 if test x$TARGET = xSPARC; then
253     AC_CACHE_CHECK([assembler and linker support unaligned pc related relocs],
254         libffi_cv_as_sparc_ua_pcrel, [
255         save_CFLAGS="$CFLAGS"
256         save_LDFLAGS="$LDFLAGS"
257         CFLAGS="$CFLAGS -fpic"
258         LDFLAGS="$LDFLAGS -shared"
259         AC_TRY_LINK([asm (".text; foo: nop; .data; .align 4; .byte 0; .uaword %r_disp32(foo); .text");],,
260                     [libffi_cv_as_sparc_ua_pcrel=yes],
261                     [libffi_cv_as_sparc_ua_pcrel=no])
262         CFLAGS="$save_CFLAGS"
263         LDFLAGS="$save_LDFLAGS"])
264     if test "x$libffi_cv_as_sparc_ua_pcrel" = xyes; then
265         AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
266                   [Define if your assembler and linker support unaligned PC relative relocs.])
267     fi
268
269     AC_CACHE_CHECK([assembler .register pseudo-op support],
270        libffi_cv_as_register_pseudo_op, [
271        libffi_cv_as_register_pseudo_op=unknown
272        # Check if we have .register
273        AC_TRY_COMPILE([asm (".register %g2, #scratch");],,
274                        [libffi_cv_as_register_pseudo_op=yes],
275                        [libffi_cv_as_register_pseudo_op=no])
276     ])
277     if test "x$libffi_cv_as_register_pseudo_op" = xyes; then
278        AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
279                [Define if your assembler supports .register.])
280     fi
281 fi
282
283 if test x$TARGET = xX86 || test x$TARGET = xX86_WIN32 || test x$TARGET = xX86_64; then
284     AC_CACHE_CHECK([assembler supports pc related relocs],
285         libffi_cv_as_x86_pcrel, [
286         libffi_cv_as_x86_pcrel=no
287         echo '.text; foo: nop; .data; .long foo-.; .text' > conftest.s
288         if $CC $CFLAGS -c conftest.s > /dev/null; then
289            libffi_cv_as_x86_pcrel=yes
290         fi
291         ])
292     if test "x$libffi_cv_as_x86_pcrel" = xyes; then
293         AC_DEFINE(HAVE_AS_X86_PCREL, 1,
294                   [Define if your assembler supports PC relative relocs.])
295     fi
296
297     AC_CACHE_CHECK([assembler .ascii pseudo-op support],
298        libffi_cv_as_ascii_pseudo_op, [
299        libffi_cv_as_ascii_pseudo_op=unknown
300        # Check if we have .ascii
301        AC_TRY_COMPILE([asm (".ascii \\"string\\"");],,
302                        [libffi_cv_as_ascii_pseudo_op=yes],
303                        [libffi_cv_as_ascii_pseudo_op=no])
304     ])
305     if test "x$libffi_cv_as_ascii_pseudo_op" = xyes; then
306        AC_DEFINE(HAVE_AS_ASCII_PSEUDO_OP, 1,
307                [Define if your assembler supports .ascii.])
308     fi
309
310     AC_CACHE_CHECK([assembler .string pseudo-op support],
311        libffi_cv_as_string_pseudo_op, [
312        libffi_cv_as_string_pseudo_op=unknown
313        # Check if we have .string
314        AC_TRY_COMPILE([asm (".string \\"string\\"");],,
315                        [libffi_cv_as_string_pseudo_op=yes],
316                        [libffi_cv_as_string_pseudo_op=no])
317     ])
318     if test "x$libffi_cv_as_string_pseudo_op" = xyes; then
319        AC_DEFINE(HAVE_AS_STRING_PSEUDO_OP, 1,
320                [Define if your assembler supports .string.])
321     fi
322 fi
323
324 if test x$TARGET = xX86_WIN64; then
325     LT_SYS_SYMBOL_USCORE
326     if test "x$sys_symbol_underscore" = xyes; then
327         AC_DEFINE(SYMBOL_UNDERSCORE, 1, [Define if symbols are underscored.])
328     fi
329 fi
330
331
332 FFI_EXEC_TRAMPOLINE_TABLE=0
333 case "$target" in
334      *arm*-apple-darwin*)
335        FFI_EXEC_TRAMPOLINE_TABLE=1
336        AC_DEFINE(FFI_EXEC_TRAMPOLINE_TABLE, 1,
337                  [Cannot use PROT_EXEC on this target, so, we revert to
338                    alternative means])
339      ;;
340      *-apple-darwin10* | *-*-freebsd* | *-*-openbsd* | *-pc-solaris*)
341        AC_DEFINE(FFI_MMAP_EXEC_WRIT, 1,
342                  [Cannot use malloc on this target, so, we revert to
343                    alternative means])
344      ;;
345 esac
346 AM_CONDITIONAL(FFI_EXEC_TRAMPOLINE_TABLE, test x$FFI_EXEC_TRAMPOLINE_TABLE = x1)
347 AC_SUBST(FFI_EXEC_TRAMPOLINE_TABLE)
348
349 if test x$TARGET = xX86_64; then
350     AC_CACHE_CHECK([assembler supports unwind section type],
351         libffi_cv_as_x86_64_unwind_section_type, [
352         libffi_cv_as_x86_64_unwind_section_type=yes
353         echo '.section .eh_frame,"a",@unwind' > conftest.s
354         if $CC $CFLAGS -c conftest.s 2>&1 | grep -i warning > /dev/null; then
355             libffi_cv_as_x86_64_unwind_section_type=no
356         fi
357         ])
358     if test "x$libffi_cv_as_x86_64_unwind_section_type" = xyes; then
359         AC_DEFINE(HAVE_AS_X86_64_UNWIND_SECTION_TYPE, 1,
360                   [Define if your assembler supports unwind section type.])
361     fi
362 fi
363
364 if test "x$GCC" = "xyes"; then
365   AC_CACHE_CHECK([whether .eh_frame section should be read-only],
366       libffi_cv_ro_eh_frame, [
367         libffi_cv_ro_eh_frame=no
368         echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
369         if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
370             if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
371                 libffi_cv_ro_eh_frame=yes
372             elif grep '.section.*eh_frame.*#alloc' conftest.c \
373                  | grep -v '#write' > /dev/null; then
374                 libffi_cv_ro_eh_frame=yes
375             fi
376         fi
377         rm -f conftest.*
378       ])
379   if test "x$libffi_cv_ro_eh_frame" = xyes; then
380       AC_DEFINE(HAVE_RO_EH_FRAME, 1,
381               [Define if .eh_frame sections should be read-only.])
382       AC_DEFINE(EH_FRAME_FLAGS, "a",
383               [Define to the flags needed for the .section .eh_frame directive.  ])
384   else
385       AC_DEFINE(EH_FRAME_FLAGS, "aw",
386               [Define to the flags needed for the .section .eh_frame directive.  ])
387   fi
388
389   AC_CACHE_CHECK([for __attribute__((visibility("hidden")))],
390       libffi_cv_hidden_visibility_attribute, [
391         echo 'int __attribute__ ((visibility ("hidden"))) foo (void) { return 1  ; }' > conftest.c
392         libffi_cv_hidden_visibility_attribute=no
393         if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
394             if grep '\.hidden.*foo' conftest.s >/dev/null; then
395                 libffi_cv_hidden_visibility_attribute=yes
396             fi
397         fi
398         rm -f conftest.*
399       ])
400   if test $libffi_cv_hidden_visibility_attribute = yes; then
401       AC_DEFINE(HAVE_HIDDEN_VISIBILITY_ATTRIBUTE, 1,
402               [Define if __attribute__((visibility("hidden"))) is supported.])
403   fi
404 fi
405
406 AH_BOTTOM([
407 #ifdef HAVE_HIDDEN_VISIBILITY_ATTRIBUTE
408 #ifdef LIBFFI_ASM
409 #define FFI_HIDDEN(name) .hidden name
410 #else
411 #define FFI_HIDDEN __attribute__ ((visibility ("hidden")))
412 #endif
413 #else
414 #ifdef LIBFFI_ASM
415 #define FFI_HIDDEN(name)
416 #else
417 #define FFI_HIDDEN
418 #endif
419 #endif
420 ])
421
422 AC_SUBST(TARGET)
423 AC_SUBST(TARGETDIR)
424
425 AC_SUBST(SHELL)
426
427 AC_ARG_ENABLE(debug,
428 [  --enable-debug          debugging mode],
429   if test "$enable_debug" = "yes"; then
430     AC_DEFINE(FFI_DEBUG, 1, [Define this if you want extra debugging.])
431   fi)
432 AM_CONDITIONAL(FFI_DEBUG, test "$enable_debug" = "yes")
433
434 AC_ARG_ENABLE(structs,
435 [  --disable-structs       omit code for struct support],
436   if test "$enable_structs" = "no"; then
437     AC_DEFINE(FFI_NO_STRUCTS, 1, [Define this is you do not want support for aggregate types.])
438   fi)
439
440 AC_ARG_ENABLE(raw-api,
441 [  --disable-raw-api       make the raw api unavailable],
442   if test "$enable_raw_api" = "no"; then
443     AC_DEFINE(FFI_NO_RAW_API, 1, [Define this is you do not want support for the raw API.])
444   fi)
445
446 AC_ARG_ENABLE(purify-safety,
447 [  --enable-purify-safety  purify-safe mode],
448   if test "$enable_purify_safety" = "yes"; then
449     AC_DEFINE(USING_PURIFY, 1, [Define this if you are using Purify and want to suppress spurious messages.])
450   fi)
451
452 # These variables are only ever used when we cross-build to X86_WIN32.
453 # And we only support this with GCC, so...
454 if test x"$GCC" != x"no"; then
455   if test -n "$with_cross_host" &&
456      test x"$with_cross_host" != x"no"; then
457     toolexecdir='$(exec_prefix)/$(target_alias)'
458     toolexeclibdir='$(toolexecdir)/lib'
459   else
460     toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
461     toolexeclibdir='$(libdir)'
462   fi
463   multi_os_directory=`$CC -print-multi-os-directory`
464   case $multi_os_directory in
465     .) ;; # Avoid trailing /.
466     *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
467   esac
468   AC_SUBST(toolexecdir)
469   AC_SUBST(toolexeclibdir)
470 fi
471
472 if test "${multilib}" = "yes"; then
473   multilib_arg="--enable-multilib"
474 else
475   multilib_arg=
476 fi
477
478 AC_CONFIG_COMMANDS(include, [test -d include || mkdir include])
479 AC_CONFIG_COMMANDS(src, [
480 test -d src || mkdir src
481 test -d src/$TARGETDIR || mkdir src/$TARGETDIR
482 ], [TARGETDIR="$TARGETDIR"])
483
484 AC_CONFIG_LINKS(include/ffitarget.h:src/$TARGETDIR/ffitarget.h)
485
486 AC_CONFIG_FILES(include/Makefile include/ffi.h Makefile testsuite/Makefile man/Makefile libffi.pc)
487
488 AC_OUTPUT