c625a0c2e502519063887eafd250ac8345021628
[libffi.git] / .pc / ungccify / configure.ac
1 dnl Process this with autoconf to create configure
2
3 AC_PREREQ(2.63)
4
5 AC_INIT([libffi], [3.0.11-rc2], [http://github.com/atgreen/libffi/issues])
6 AC_CONFIG_HEADERS([fficonfig.h])
7
8 AC_CANONICAL_SYSTEM
9 target_alias=${target_alias-$host_alias}
10
11 . ${srcdir}/configure.host
12
13 AM_INIT_AUTOMAKE
14
15 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
16 # We must force CC to /not/ be precious variables; otherwise
17 # the wrong, non-multilib-adjusted value will be used in multilibs.
18 # As a side effect, we have to subst CFLAGS ourselves.
19 # Also save and restore CFLAGS, since AC_PROG_CC will come up with
20 # defaults of its own if none are provided.
21
22 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
23 m4_define([_AC_ARG_VAR_PRECIOUS],[])
24 save_CFLAGS=$CFLAGS
25 AC_PROG_CC
26 CFLAGS=$save_CFLAGS
27 m4_undefine([_AC_ARG_VAR_PRECIOUS])
28 m4_rename([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
29
30 AC_SUBST(CFLAGS)
31
32 AM_PROG_AS
33 AM_PROG_CC_C_O
34 AC_PROG_LIBTOOL
35 AC_CONFIG_MACRO_DIR([m4])
36
37 AM_MAINTAINER_MODE
38
39 AC_CHECK_HEADERS(sys/mman.h)
40 AC_CHECK_FUNCS(mmap)
41 AC_FUNC_MMAP_BLACKLIST
42
43 dnl The -no-testsuite modules omit the test subdir.
44 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
45
46 TARGETDIR="unknown"
47 case "$host" in
48   alpha*-*-*)
49         TARGET=ALPHA; TARGETDIR=alpha;
50         # Support 128-bit long double, changeable via command-line switch.
51         HAVE_LONG_DOUBLE='defined(__LONG_DOUBLE_128__)'
52         ;;
53
54   arm*-*-*)
55         TARGET=ARM; TARGETDIR=arm
56         ;;
57
58   amd64-*-freebsd* | amd64-*-openbsd*)
59         TARGET=X86_64; TARGETDIR=x86
60         ;;
61
62   amd64-*-freebsd*)
63         TARGET=X86_64; TARGETDIR=x86
64         ;;
65
66   avr32*-*-*)
67         TARGET=AVR32; TARGETDIR=avr32
68         ;;
69
70   cris-*-*)
71         TARGET=LIBFFI_CRIS; TARGETDIR=cris
72         ;;
73
74   frv-*-*)
75         TARGET=FRV; TARGETDIR=frv
76         ;;
77
78   hppa*-*-linux* | parisc*-*-linux*)
79         TARGET=PA_LINUX; TARGETDIR=pa
80         ;;
81   hppa*64-*-hpux*)
82         TARGET=PA64_HPUX; TARGETDIR=pa
83         ;;
84   hppa*-*-hpux*)
85         TARGET=PA_HPUX; TARGETDIR=pa
86         ;;
87
88   i?86-*-freebsd* | i?86-*-openbsd*)
89         TARGET=X86_FREEBSD; TARGETDIR=x86
90         ;;
91   i?86-win32* | i?86-*-cygwin* | i?86-*-mingw* | i?86-*-os2* | i?86-*-interix*)
92         TARGET=X86_WIN32; TARGETDIR=x86
93         # All mingw/cygwin/win32 builds require -no-undefined for sharedlib.
94         # We must also check with_cross_host to decide if this is a native
95         # or cross-build and select where to install dlls appropriately.
96         if test -n "$with_cross_host" &&
97            test x"$with_cross_host" != x"no"; then
98           AM_LTLDFLAGS='-no-undefined -bindir "$(toolexeclibdir)"';
99         else
100           AM_LTLDFLAGS='-no-undefined -bindir "$(bindir)"';
101         fi
102         ;;
103   i?86-*-darwin*)
104         TARGET=X86_DARWIN; TARGETDIR=x86
105         ;;
106   i?86-*-solaris2.1[[0-9]]*)
107         TARGET=X86_64; TARGETDIR=x86
108         ;;
109   i?86-*-*)
110         TARGET=X86_64; TARGETDIR=x86
111         ;;
112
113   ia64*-*-*)
114         TARGET=IA64; TARGETDIR=ia64
115         ;;
116
117   m32r*-*-*)
118         TARGET=M32R; TARGETDIR=m32r
119         ;;
120
121   m68k-*-*)
122         TARGET=M68K; TARGETDIR=m68k
123         ;;
124
125   mips-sgi-irix5.* | mips-sgi-irix6.* | mips*-*-rtems*)
126         TARGET=MIPS; TARGETDIR=mips
127         ;;
128   mips*-*-linux*)
129         # Support 128-bit long double for NewABI.
130         HAVE_LONG_DOUBLE='defined(__mips64)'
131         TARGET=MIPS; TARGETDIR=mips
132         ;;
133
134   moxie-*-*)
135         TARGET=MOXIE; TARGETDIR=moxie
136         ;;
137
138   powerpc*-*-linux* | powerpc-*-sysv*)
139         TARGET=POWERPC; TARGETDIR=powerpc
140         ;;
141   powerpc-*-beos*)
142         TARGET=POWERPC; TARGETDIR=powerpc
143         ;;
144   powerpc-*-darwin* | powerpc64-*-darwin*)
145         TARGET=POWERPC_DARWIN; TARGETDIR=powerpc
146         ;;
147   powerpc-*-aix* | rs6000-*-aix*)
148         TARGET=POWERPC_AIX; TARGETDIR=powerpc
149         ;;
150   powerpc-*-freebsd*)
151         TARGET=POWERPC_FREEBSD; TARGETDIR=powerpc
152         ;;
153   powerpc64-*-freebsd*)
154         TARGET=POWERPC; TARGETDIR=powerpc
155         ;;
156   powerpc*-*-rtems*)
157         TARGET=POWERPC; TARGETDIR=powerpc
158         ;;
159
160   s390-*-* | s390x-*-*)
161         TARGET=S390; TARGETDIR=s390
162         ;;
163
164   sh-*-* | sh[[34]]*-*-*)
165         TARGET=SH; TARGETDIR=sh
166         ;;
167   sh64-*-* | sh5*-*-*)
168         TARGET=SH64; TARGETDIR=sh64
169         ;;
170
171   sparc*-*-*)
172         TARGET=SPARC; TARGETDIR=sparc
173         ;;
174
175   x86_64-*-darwin*)
176         TARGET=X86_DARWIN; TARGETDIR=x86
177         ;;
178
179   x86_64-*-cygwin* | x86_64-*-mingw*)
180         TARGET=X86_WIN64; TARGETDIR=x86
181         ;;
182
183   x86_64-*-*)
184         TARGET=X86_64; TARGETDIR=x86
185         ;;
186 esac
187
188 AC_SUBST(AM_RUNTESTFLAGS)
189 AC_SUBST(AM_LTLDFLAGS)
190
191 if test $TARGETDIR = unknown; then
192   AC_MSG_ERROR(["libffi has not been ported to $host."])
193 fi
194
195 AM_CONDITIONAL(MIPS, test x$TARGET = xMIPS)
196 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
197 AM_CONDITIONAL(X86, test x$TARGET = xX86)
198 AM_CONDITIONAL(X86_FREEBSD, test x$TARGET = xX86_FREEBSD)
199 AM_CONDITIONAL(X86_WIN32, test x$TARGET = xX86_WIN32)
200 AM_CONDITIONAL(X86_WIN64, test x$TARGET = xX86_WIN64)
201 AM_CONDITIONAL(X86_DARWIN, test x$TARGET = xX86_DARWIN)
202 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
203 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
204 AM_CONDITIONAL(M32R, test x$TARGET = xM32R)
205 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
206 AM_CONDITIONAL(MOXIE, test x$TARGET = xMOXIE)
207 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
208 AM_CONDITIONAL(POWERPC_AIX, test x$TARGET = xPOWERPC_AIX)
209 AM_CONDITIONAL(POWERPC_DARWIN, test x$TARGET = xPOWERPC_DARWIN)
210 AM_CONDITIONAL(POWERPC_FREEBSD, test x$TARGET = xPOWERPC_FREEBSD)
211 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
212 AM_CONDITIONAL(AVR32, test x$TARGET = xAVR32)
213 AM_CONDITIONAL(LIBFFI_CRIS, test x$TARGET = xLIBFFI_CRIS)
214 AM_CONDITIONAL(FRV, test x$TARGET = xFRV)
215 AM_CONDITIONAL(S390, test x$TARGET = xS390)
216 AM_CONDITIONAL(X86_64, test x$TARGET = xX86_64)
217 AM_CONDITIONAL(SH, test x$TARGET = xSH)
218 AM_CONDITIONAL(SH64, test x$TARGET = xSH64)
219 AM_CONDITIONAL(PA_LINUX, test x$TARGET = xPA_LINUX)
220 AM_CONDITIONAL(PA_HPUX, test x$TARGET = xPA_HPUX)
221 AM_CONDITIONAL(PA64_HPUX, test x$TARGET = xPA64_HPUX)
222
223 AC_HEADER_STDC
224 AC_CHECK_FUNCS(memcpy)
225 AC_FUNC_ALLOCA
226
227 AC_CHECK_SIZEOF(double)
228 AC_CHECK_SIZEOF(long double)
229
230 # Also AC_SUBST this variable for ffi.h.
231 if test -z "$HAVE_LONG_DOUBLE"; then
232   HAVE_LONG_DOUBLE=0
233   if test $ac_cv_sizeof_double != $ac_cv_sizeof_long_double; then
234     if test $ac_cv_sizeof_long_double != 0; then
235       HAVE_LONG_DOUBLE=1
236       AC_DEFINE(HAVE_LONG_DOUBLE, 1, [Define if you have the long double type and it is bigger than a double])
237     fi
238   fi
239 fi
240 AC_SUBST(HAVE_LONG_DOUBLE)
241
242 AC_C_BIGENDIAN
243
244 GCC_AS_CFI_PSEUDO_OP
245
246 if test x$TARGET = xSPARC; then
247     AC_CACHE_CHECK([assembler and linker support unaligned pc related relocs],
248         libffi_cv_as_sparc_ua_pcrel, [
249         save_CFLAGS="$CFLAGS"
250         save_LDFLAGS="$LDFLAGS"
251         CFLAGS="$CFLAGS -fpic"
252         LDFLAGS="$LDFLAGS -shared"
253         AC_TRY_LINK([asm (".text; foo: nop; .data; .align 4; .byte 0; .uaword %r_disp32(foo); .text");],,
254                     [libffi_cv_as_sparc_ua_pcrel=yes],
255                     [libffi_cv_as_sparc_ua_pcrel=no])
256         CFLAGS="$save_CFLAGS"
257         LDFLAGS="$save_LDFLAGS"])
258     if test "x$libffi_cv_as_sparc_ua_pcrel" = xyes; then
259         AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
260                   [Define if your assembler and linker support unaligned PC relative relocs.])
261     fi
262
263     AC_CACHE_CHECK([assembler .register pseudo-op support],
264        libffi_cv_as_register_pseudo_op, [
265        libffi_cv_as_register_pseudo_op=unknown
266        # Check if we have .register
267        AC_TRY_COMPILE([asm (".register %g2, #scratch");],,
268                        [libffi_cv_as_register_pseudo_op=yes],
269                        [libffi_cv_as_register_pseudo_op=no])
270     ])
271     if test "x$libffi_cv_as_register_pseudo_op" = xyes; then
272        AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
273                [Define if your assembler supports .register.])
274     fi
275 fi
276
277 if test x$TARGET = xX86 || test x$TARGET = xX86_WIN32 || test x$TARGET = xX86_64; then
278     AC_CACHE_CHECK([assembler supports pc related relocs],
279         libffi_cv_as_x86_pcrel, [
280         libffi_cv_as_x86_pcrel=no
281         echo '.text; foo: nop; .data; .long foo-.; .text' > conftest.s
282         if $CC $CFLAGS -c conftest.s > /dev/null; then
283            libffi_cv_as_x86_pcrel=yes
284         fi
285         ])
286     if test "x$libffi_cv_as_x86_pcrel" = xyes; then
287         AC_DEFINE(HAVE_AS_X86_PCREL, 1,
288                   [Define if your assembler supports PC relative relocs.])
289     fi
290
291     AC_CACHE_CHECK([assembler .ascii pseudo-op support],
292        libffi_cv_as_ascii_pseudo_op, [
293        libffi_cv_as_ascii_pseudo_op=unknown
294        # Check if we have .ascii
295        AC_TRY_COMPILE([asm (".ascii \\"string\\"");],,
296                        [libffi_cv_as_ascii_pseudo_op=yes],
297                        [libffi_cv_as_ascii_pseudo_op=no])
298     ])
299     if test "x$libffi_cv_as_ascii_pseudo_op" = xyes; then
300        AC_DEFINE(HAVE_AS_ASCII_PSEUDO_OP, 1,
301                [Define if your assembler supports .ascii.])
302     fi
303
304     AC_CACHE_CHECK([assembler .string pseudo-op support],
305        libffi_cv_as_string_pseudo_op, [
306        libffi_cv_as_string_pseudo_op=unknown
307        # Check if we have .string
308        AC_TRY_COMPILE([asm (".string \\"string\\"");],,
309                        [libffi_cv_as_string_pseudo_op=yes],
310                        [libffi_cv_as_string_pseudo_op=no])
311     ])
312     if test "x$libffi_cv_as_string_pseudo_op" = xyes; then
313        AC_DEFINE(HAVE_AS_STRING_PSEUDO_OP, 1,
314                [Define if your assembler supports .string.])
315     fi
316 fi
317
318 if test x$TARGET = xX86_WIN64; then
319     LT_SYS_SYMBOL_USCORE
320     if test "x$sys_symbol_underscore" = xyes; then
321         AC_DEFINE(SYMBOL_UNDERSCORE, 1, [Define if symbols are underscored.])
322     fi
323 fi
324
325
326 FFI_EXEC_TRAMPOLINE_TABLE=0
327 case "$target" in
328      *arm*-apple-darwin*)
329        FFI_EXEC_TRAMPOLINE_TABLE=1
330        AC_DEFINE(FFI_EXEC_TRAMPOLINE_TABLE, 1,
331                  [Cannot use PROT_EXEC on this target, so, we revert to
332                    alternative means])
333      ;;
334      *-apple-darwin10* | *-*-freebsd* | *-*-openbsd* | *-pc-solaris*)
335        AC_DEFINE(FFI_MMAP_EXEC_WRIT, 1,
336                  [Cannot use malloc on this target, so, we revert to
337                    alternative means])
338      ;;
339 esac
340 AM_CONDITIONAL(FFI_EXEC_TRAMPOLINE_TABLE, test x$FFI_EXEC_TRAMPOLINE_TABLE = x1)
341 AC_SUBST(FFI_EXEC_TRAMPOLINE_TABLE)
342
343 if test x$TARGET = xX86_64; then
344     AC_CACHE_CHECK([assembler supports unwind section type],
345         libffi_cv_as_x86_64_unwind_section_type, [
346         libffi_cv_as_x86_64_unwind_section_type=yes
347         echo '.section .eh_frame,"a",@unwind' > conftest.s
348         if $CC $CFLAGS -c conftest.s 2>&1 | grep -i warning > /dev/null; then
349             libffi_cv_as_x86_64_unwind_section_type=no
350         fi
351         ])
352     if test "x$libffi_cv_as_x86_64_unwind_section_type" = xyes; then
353         AC_DEFINE(HAVE_AS_X86_64_UNWIND_SECTION_TYPE, 1,
354                   [Define if your assembler supports unwind section type.])
355     fi
356 fi
357
358 if test "x$GCC" = "xyes"; then
359   AC_CACHE_CHECK([whether .eh_frame section should be read-only],
360       libffi_cv_ro_eh_frame, [
361         libffi_cv_ro_eh_frame=no
362         echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
363         if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
364             if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
365                 libffi_cv_ro_eh_frame=yes
366             elif grep '.section.*eh_frame.*#alloc' conftest.c \
367                  | grep -v '#write' > /dev/null; then
368                 libffi_cv_ro_eh_frame=yes
369             fi
370         fi
371         rm -f conftest.*
372       ])
373   if test "x$libffi_cv_ro_eh_frame" = xyes; then
374       AC_DEFINE(HAVE_RO_EH_FRAME, 1,
375               [Define if .eh_frame sections should be read-only.])
376       AC_DEFINE(EH_FRAME_FLAGS, "a",
377               [Define to the flags needed for the .section .eh_frame directive.  ])
378   else
379       AC_DEFINE(EH_FRAME_FLAGS, "aw",
380               [Define to the flags needed for the .section .eh_frame directive.  ])
381   fi
382
383   AC_CACHE_CHECK([for __attribute__((visibility("hidden")))],
384       libffi_cv_hidden_visibility_attribute, [
385         echo 'int __attribute__ ((visibility ("hidden"))) foo (void) { return 1  ; }' > conftest.c
386         libffi_cv_hidden_visibility_attribute=no
387         if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
388             if grep '\.hidden.*foo' conftest.s >/dev/null; then
389                 libffi_cv_hidden_visibility_attribute=yes
390             fi
391         fi
392         rm -f conftest.*
393       ])
394   if test $libffi_cv_hidden_visibility_attribute = yes; then
395       AC_DEFINE(HAVE_HIDDEN_VISIBILITY_ATTRIBUTE, 1,
396               [Define if __attribute__((visibility("hidden"))) is supported.])
397   fi
398 fi
399
400 AH_BOTTOM([
401 #ifdef HAVE_HIDDEN_VISIBILITY_ATTRIBUTE
402 #ifdef LIBFFI_ASM
403 #define FFI_HIDDEN(name) .hidden name
404 #else
405 #define FFI_HIDDEN __attribute__ ((visibility ("hidden")))
406 #endif
407 #else
408 #ifdef LIBFFI_ASM
409 #define FFI_HIDDEN(name)
410 #else
411 #define FFI_HIDDEN
412 #endif
413 #endif
414 ])
415
416 AC_SUBST(TARGET)
417 AC_SUBST(TARGETDIR)
418
419 AC_SUBST(SHELL)
420
421 AC_ARG_ENABLE(debug,
422 [  --enable-debug          debugging mode],
423   if test "$enable_debug" = "yes"; then
424     AC_DEFINE(FFI_DEBUG, 1, [Define this if you want extra debugging.])
425   fi)
426 AM_CONDITIONAL(FFI_DEBUG, test "$enable_debug" = "yes")
427
428 AC_ARG_ENABLE(structs,
429 [  --disable-structs       omit code for struct support],
430   if test "$enable_structs" = "no"; then
431     AC_DEFINE(FFI_NO_STRUCTS, 1, [Define this is you do not want support for aggregate types.])
432   fi)
433
434 AC_ARG_ENABLE(raw-api,
435 [  --disable-raw-api       make the raw api unavailable],
436   if test "$enable_raw_api" = "no"; then
437     AC_DEFINE(FFI_NO_RAW_API, 1, [Define this is you do not want support for the raw API.])
438   fi)
439
440 AC_ARG_ENABLE(purify-safety,
441 [  --enable-purify-safety  purify-safe mode],
442   if test "$enable_purify_safety" = "yes"; then
443     AC_DEFINE(USING_PURIFY, 1, [Define this if you are using Purify and want to suppress spurious messages.])
444   fi)
445
446 # These variables are only ever used when we cross-build to X86_WIN32.
447 # And we only support this with GCC, so...
448 if test x"$GCC" != x"no"; then
449   if test -n "$with_cross_host" &&
450      test x"$with_cross_host" != x"no"; then
451     toolexecdir='$(exec_prefix)/$(target_alias)'
452     toolexeclibdir='$(toolexecdir)/lib'
453   else
454     toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
455     toolexeclibdir='$(libdir)'
456   fi
457   multi_os_directory=`$CC -print-multi-os-directory`
458   case $multi_os_directory in
459     .) ;; # Avoid trailing /.
460     *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
461   esac
462   AC_SUBST(toolexecdir)
463   AC_SUBST(toolexeclibdir)
464 fi
465
466 if test "${multilib}" = "yes"; then
467   multilib_arg="--enable-multilib"
468 else
469   multilib_arg=
470 fi
471
472 AC_CONFIG_COMMANDS(include, [test -d include || mkdir include])
473 AC_CONFIG_COMMANDS(src, [
474 test -d src || mkdir src
475 test -d src/$TARGETDIR || mkdir src/$TARGETDIR
476 ], [TARGETDIR="$TARGETDIR"])
477
478 AC_CONFIG_LINKS(include/ffitarget.h:src/$TARGETDIR/ffitarget.h)
479
480 AC_CONFIG_FILES(include/Makefile include/ffi.h Makefile testsuite/Makefile man/Makefile libffi.pc)
481
482 AC_OUTPUT