Merge with GCC. Eliminate quilt bits.
[libffi.git] / configure.ac
1 dnl Process this with autoconf to create configure
2
3 AC_PREREQ(2.64)
4
5 AC_INIT([libffi], [3.0.11], [http://gcc.gnu.org/bugs.html])
6 AC_CONFIG_HEADERS([fficonfig.h])
7
8 AM_ENABLE_MULTILIB(, ..)
9
10 AC_CANONICAL_SYSTEM
11 target_alias=${target_alias-$host_alias}
12
13 . ${srcdir}/configure.host
14
15 AM_INIT_AUTOMAKE
16
17 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
18 # We must force CC to /not/ be precious variables; otherwise
19 # the wrong, non-multilib-adjusted value will be used in multilibs.
20 # As a side effect, we have to subst CFLAGS ourselves.
21
22 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
23 m4_define([_AC_ARG_VAR_PRECIOUS],[])
24 AC_PROG_CC
25 m4_rename_force([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
26
27 AC_SUBST(CFLAGS)
28
29 AM_PROG_AS
30 AM_PROG_CC_C_O
31 AC_PROG_LIBTOOL
32
33 AM_MAINTAINER_MODE
34
35 AC_CHECK_HEADERS(sys/mman.h)
36 AC_CHECK_FUNCS(mmap)
37 AC_FUNC_MMAP_BLACKLIST
38
39 dnl The -no-testsuite modules omit the test subdir.
40 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
41
42 TARGETDIR="unknown"
43 case "$host" in
44   aarch64*-*-*)
45         TARGET=AARCH64; TARGETDIR=aarch64
46         ;;
47
48   alpha*-*-*)
49         TARGET=ALPHA; TARGETDIR=alpha;
50         # Support 128-bit long double, changeable via command-line switch.
51         HAVE_LONG_DOUBLE='defined(__LONG_DOUBLE_128__)'
52         ;;
53
54   arm*-*-*)
55         TARGET=ARM; TARGETDIR=arm
56         ;;
57
58   amd64-*-freebsd* | amd64-*-openbsd*)
59         TARGET=X86_64; TARGETDIR=x86
60         ;;
61
62   amd64-*-freebsd*)
63         TARGET=X86_64; TARGETDIR=x86
64         ;;
65
66   avr32*-*-*)
67         TARGET=AVR32; TARGETDIR=avr32
68         ;;
69
70   bfin*)
71         TARGET=BFIN; TARGETDIR=bfin
72         ;;
73
74   cris-*-*)
75         TARGET=LIBFFI_CRIS; TARGETDIR=cris
76         ;;
77
78   frv-*-*)
79         TARGET=FRV; TARGETDIR=frv
80         ;;
81
82   hppa*-*-linux* | parisc*-*-linux* | hppa*-*-openbsd*)
83         TARGET=PA_LINUX; TARGETDIR=pa
84         ;;
85   hppa*64-*-hpux*)
86         TARGET=PA64_HPUX; TARGETDIR=pa
87         ;;
88   hppa*-*-hpux*)
89         TARGET=PA_HPUX; TARGETDIR=pa
90         ;;
91
92   i?86-*-freebsd* | i?86-*-openbsd*)
93         TARGET=X86_FREEBSD; TARGETDIR=x86
94         ;;
95   i?86-win32* | i?86-*-cygwin* | i?86-*-mingw* | i?86-*-os2* | i?86-*-interix*)
96         TARGET=X86_WIN32; TARGETDIR=x86
97         # All mingw/cygwin/win32 builds require -no-undefined for sharedlib.
98         # We must also check with_cross_host to decide if this is a native
99         # or cross-build and select where to install dlls appropriately.
100         if test -n "$with_cross_host" &&
101            test x"$with_cross_host" != x"no"; then
102           AM_LTLDFLAGS='-no-undefined -bindir "$(toolexeclibdir)"';
103         else
104           AM_LTLDFLAGS='-no-undefined -bindir "$(bindir)"';
105         fi
106         ;;
107   i?86-*-darwin*)
108         TARGET=X86_DARWIN; TARGETDIR=x86
109         ;;
110   i?86-*-solaris2.1[[0-9]]*)
111         TARGET=X86_64; TARGETDIR=x86
112         ;;
113   i?86-*-*)
114         TARGET=X86_64; TARGETDIR=x86
115         ;;
116
117   ia64*-*-*)
118         TARGET=IA64; TARGETDIR=ia64
119         ;;
120
121   m32r*-*-*)
122         TARGET=M32R; TARGETDIR=m32r
123         ;;
124
125   m68k-*-*)
126         TARGET=M68K; TARGETDIR=m68k
127         ;;
128
129   mips-sgi-irix5.* | mips-sgi-irix6.* | mips*-*-rtems*)
130         TARGET=MIPS; TARGETDIR=mips
131         ;;
132   mips*-*-linux* | mips*-*-openbsd*)
133         # Support 128-bit long double for NewABI.
134         HAVE_LONG_DOUBLE='defined(__mips64)'
135         TARGET=MIPS; TARGETDIR=mips
136         ;;
137
138   powerpc*-*-linux* | powerpc-*-sysv*)
139         TARGET=POWERPC; TARGETDIR=powerpc
140         ;;
141   powerpc-*-amigaos*)
142         TARGET=POWERPC; TARGETDIR=powerpc
143         ;;
144   powerpc-*-beos*)
145         TARGET=POWERPC; TARGETDIR=powerpc
146         ;;
147   powerpc-*-darwin* | powerpc64-*-darwin*)
148         TARGET=POWERPC_DARWIN; TARGETDIR=powerpc
149         ;;
150   powerpc-*-aix* | rs6000-*-aix*)
151         TARGET=POWERPC_AIX; TARGETDIR=powerpc
152         ;;
153   powerpc-*-freebsd* | powerpc-*-openbsd*)
154         TARGET=POWERPC_FREEBSD; TARGETDIR=powerpc
155         ;;
156   powerpc64-*-freebsd*)
157         TARGET=POWERPC; TARGETDIR=powerpc
158         ;;
159   powerpc*-*-rtems*)
160         TARGET=POWERPC; TARGETDIR=powerpc
161         ;;
162
163   s390-*-* | s390x-*-*)
164         TARGET=S390; TARGETDIR=s390
165         ;;
166
167   sh-*-* | sh[[34]]*-*-*)
168         TARGET=SH; TARGETDIR=sh
169         ;;
170   sh64-*-* | sh5*-*-*)
171         TARGET=SH64; TARGETDIR=sh64
172         ;;
173
174   sparc*-*-*)
175         TARGET=SPARC; TARGETDIR=sparc
176         ;;
177
178   tile*-*)
179         TARGET=TILE; TARGETDIR=tile
180         ;;
181
182   x86_64-*-darwin*)
183         TARGET=X86_DARWIN; TARGETDIR=x86
184         ;;
185
186   x86_64-*-cygwin* | x86_64-*-mingw*)
187         TARGET=X86_WIN64; TARGETDIR=x86
188         # All mingw/cygwin/win32 builds require -no-undefined for sharedlib.
189         # We must also check with_cross_host to decide if this is a native
190         # or cross-build and select where to install dlls appropriately.
191         if test -n "$with_cross_host" &&
192            test x"$with_cross_host" != x"no"; then
193           AM_LTLDFLAGS='-no-undefined -bindir "$(toolexeclibdir)"';
194         else
195           AM_LTLDFLAGS='-no-undefined -bindir "$(bindir)"';
196         fi
197         ;;
198
199   x86_64-*-*)
200         TARGET=X86_64; TARGETDIR=x86
201         ;;
202 esac
203
204 AC_SUBST(AM_RUNTESTFLAGS)
205 AC_SUBST(AM_LTLDFLAGS)
206
207 if test $TARGETDIR = unknown; then
208   AC_MSG_ERROR(["libffi has not been ported to $host."])
209 fi
210
211 AM_CONDITIONAL(MIPS, test x$TARGET = xMIPS)
212 AM_CONDITIONAL(BFIN, test x$TARGET = xBFIN)
213 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
214 AM_CONDITIONAL(X86, test x$TARGET = xX86)
215 AM_CONDITIONAL(X86_FREEBSD, test x$TARGET = xX86_FREEBSD)
216 AM_CONDITIONAL(X86_WIN32, test x$TARGET = xX86_WIN32)
217 AM_CONDITIONAL(X86_WIN64, test x$TARGET = xX86_WIN64)
218 AM_CONDITIONAL(X86_DARWIN, test x$TARGET = xX86_DARWIN)
219 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
220 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
221 AM_CONDITIONAL(M32R, test x$TARGET = xM32R)
222 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
223 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
224 AM_CONDITIONAL(POWERPC_AIX, test x$TARGET = xPOWERPC_AIX)
225 AM_CONDITIONAL(POWERPC_DARWIN, test x$TARGET = xPOWERPC_DARWIN)
226 AM_CONDITIONAL(POWERPC_FREEBSD, test x$TARGET = xPOWERPC_FREEBSD)
227 AM_CONDITIONAL(AARCH64, test x$TARGET = xAARCH64)
228 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
229 AM_CONDITIONAL(AVR32, test x$TARGET = xAVR32)
230 AM_CONDITIONAL(LIBFFI_CRIS, test x$TARGET = xLIBFFI_CRIS)
231 AM_CONDITIONAL(FRV, test x$TARGET = xFRV)
232 AM_CONDITIONAL(S390, test x$TARGET = xS390)
233 AM_CONDITIONAL(X86_64, test x$TARGET = xX86_64)
234 AM_CONDITIONAL(SH, test x$TARGET = xSH)
235 AM_CONDITIONAL(SH64, test x$TARGET = xSH64)
236 AM_CONDITIONAL(PA_LINUX, test x$TARGET = xPA_LINUX)
237 AM_CONDITIONAL(PA_HPUX, test x$TARGET = xPA_HPUX)
238 AM_CONDITIONAL(PA64_HPUX, test x$TARGET = xPA64_HPUX)
239 AM_CONDITIONAL(TILE, test x$TARGET = xTILE)
240
241 AC_HEADER_STDC
242 AC_CHECK_FUNCS(memcpy)
243 AC_FUNC_ALLOCA
244
245 AC_CHECK_SIZEOF(double)
246 AC_CHECK_SIZEOF(long double)
247
248 # Also AC_SUBST this variable for ffi.h.
249 if test -z "$HAVE_LONG_DOUBLE"; then
250   HAVE_LONG_DOUBLE=0
251   if test $ac_cv_sizeof_double != $ac_cv_sizeof_long_double; then
252     if test $ac_cv_sizeof_long_double != 0; then
253       HAVE_LONG_DOUBLE=1
254       AC_DEFINE(HAVE_LONG_DOUBLE, 1, [Define if you have the long double type and it is bigger than a double])
255     fi
256   fi
257 fi
258 AC_SUBST(HAVE_LONG_DOUBLE)
259
260 AC_C_BIGENDIAN
261
262 GCC_AS_CFI_PSEUDO_OP
263
264 if test x$TARGET = xSPARC; then
265     AC_CACHE_CHECK([assembler and linker support unaligned pc related relocs],
266         libffi_cv_as_sparc_ua_pcrel, [
267         save_CFLAGS="$CFLAGS"
268         save_LDFLAGS="$LDFLAGS"
269         CFLAGS="$CFLAGS -fpic"
270         LDFLAGS="$LDFLAGS -shared"
271         AC_TRY_LINK([asm (".text; foo: nop; .data; .align 4; .byte 0; .uaword %r_disp32(foo); .text");],,
272                     [libffi_cv_as_sparc_ua_pcrel=yes],
273                     [libffi_cv_as_sparc_ua_pcrel=no])
274         CFLAGS="$save_CFLAGS"
275         LDFLAGS="$save_LDFLAGS"])
276     if test "x$libffi_cv_as_sparc_ua_pcrel" = xyes; then
277         AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
278                   [Define if your assembler and linker support unaligned PC relative relocs.])
279     fi
280
281     AC_CACHE_CHECK([assembler .register pseudo-op support],
282        libffi_cv_as_register_pseudo_op, [
283        libffi_cv_as_register_pseudo_op=unknown
284        # Check if we have .register
285        AC_TRY_COMPILE([asm (".register %g2, #scratch");],,
286                        [libffi_cv_as_register_pseudo_op=yes],
287                        [libffi_cv_as_register_pseudo_op=no])
288     ])
289     if test "x$libffi_cv_as_register_pseudo_op" = xyes; then
290        AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
291                [Define if your assembler supports .register.])
292     fi
293 fi
294
295 if test x$TARGET = xX86 || test x$TARGET = xX86_WIN32 || test x$TARGET = xX86_64; then
296     AC_CACHE_CHECK([assembler supports pc related relocs],
297         libffi_cv_as_x86_pcrel, [
298         libffi_cv_as_x86_pcrel=yes
299         echo '.text; foo: nop; .data; .long foo-.; .text' > conftest.s
300         if $CC $CFLAGS -c conftest.s 2>&1 | $EGREP -i 'illegal|warning' > /dev/null; then
301             libffi_cv_as_x86_pcrel=no
302         fi
303         ])
304     if test "x$libffi_cv_as_x86_pcrel" = xyes; then
305         AC_DEFINE(HAVE_AS_X86_PCREL, 1,
306                   [Define if your assembler supports PC relative relocs.])
307     fi
308
309     AC_CACHE_CHECK([assembler .ascii pseudo-op support],
310        libffi_cv_as_ascii_pseudo_op, [
311        libffi_cv_as_ascii_pseudo_op=unknown
312        # Check if we have .ascii
313        AC_TRY_COMPILE([asm (".ascii \\"string\\"");],,
314                        [libffi_cv_as_ascii_pseudo_op=yes],
315                        [libffi_cv_as_ascii_pseudo_op=no])
316     ])
317     if test "x$libffi_cv_as_ascii_pseudo_op" = xyes; then
318        AC_DEFINE(HAVE_AS_ASCII_PSEUDO_OP, 1,
319                [Define if your assembler supports .ascii.])
320     fi
321
322     AC_CACHE_CHECK([assembler .string pseudo-op support],
323        libffi_cv_as_string_pseudo_op, [
324        libffi_cv_as_string_pseudo_op=unknown
325        # Check if we have .string
326        AC_TRY_COMPILE([asm (".string \\"string\\"");],,
327                        [libffi_cv_as_string_pseudo_op=yes],
328                        [libffi_cv_as_string_pseudo_op=no])
329     ])
330     if test "x$libffi_cv_as_string_pseudo_op" = xyes; then
331        AC_DEFINE(HAVE_AS_STRING_PSEUDO_OP, 1,
332                [Define if your assembler supports .string.])
333     fi
334 fi
335
336 # On PaX enable kernels that have MPROTECT enable we can't use PROT_EXEC.
337 AC_ARG_ENABLE(pax_emutramp,
338   [  --enable-pax_emutramp       enable pax emulated trampolines, for we can't use PROT_EXEC],
339   if test "$enable_pax_emutramp" = "yes"; then
340     AC_DEFINE(FFI_MMAP_EXEC_EMUTRAMP_PAX, 1,
341       [Define this if you want to enable pax emulated trampolines])
342   fi)
343
344 FFI_EXEC_TRAMPOLINE_TABLE=0
345 case "$target" in
346      *arm*-apple-darwin*)
347        FFI_EXEC_TRAMPOLINE_TABLE=1
348        AC_DEFINE(FFI_EXEC_TRAMPOLINE_TABLE, 1,
349                  [Cannot use PROT_EXEC on this target, so, we revert to
350                    alternative means])
351      ;;
352      *-apple-darwin1* | *-*-freebsd* | *-*-kfreebsd* | *-*-openbsd* | *-pc-solaris*)
353        AC_DEFINE(FFI_MMAP_EXEC_WRIT, 1,
354                  [Cannot use malloc on this target, so, we revert to
355                    alternative means])
356      ;;
357 esac
358 AM_CONDITIONAL(FFI_EXEC_TRAMPOLINE_TABLE, test x$FFI_EXEC_TRAMPOLINE_TABLE = x1)
359 AC_SUBST(FFI_EXEC_TRAMPOLINE_TABLE)
360
361 if test x$TARGET = xX86_64; then
362     AC_CACHE_CHECK([assembler supports unwind section type],
363         libffi_cv_as_x86_64_unwind_section_type, [
364         libffi_cv_as_x86_64_unwind_section_type=yes
365         echo '.section .eh_frame,"a",@unwind' > conftest.s
366         if $CC $CFLAGS -c conftest.s 2>&1 | grep -i warning > /dev/null; then
367             libffi_cv_as_x86_64_unwind_section_type=no
368         fi
369         ])
370     if test "x$libffi_cv_as_x86_64_unwind_section_type" = xyes; then
371         AC_DEFINE(HAVE_AS_X86_64_UNWIND_SECTION_TYPE, 1,
372                   [Define if your assembler supports unwind section type.])
373     fi
374 fi
375
376 if test "x$GCC" = "xyes"; then
377   AC_CACHE_CHECK([whether .eh_frame section should be read-only],
378       libffi_cv_ro_eh_frame, [
379         libffi_cv_ro_eh_frame=no
380         echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
381         if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
382             if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
383                 libffi_cv_ro_eh_frame=yes
384             elif grep '.section.*eh_frame.*#alloc' conftest.c \
385                  | grep -v '#write' > /dev/null; then
386                 libffi_cv_ro_eh_frame=yes
387             fi
388         fi
389         rm -f conftest.*
390       ])
391   if test "x$libffi_cv_ro_eh_frame" = xyes; then
392       AC_DEFINE(HAVE_RO_EH_FRAME, 1,
393               [Define if .eh_frame sections should be read-only.])
394       AC_DEFINE(EH_FRAME_FLAGS, "a",
395               [Define to the flags needed for the .section .eh_frame directive.  ])
396   else
397       AC_DEFINE(EH_FRAME_FLAGS, "aw",
398               [Define to the flags needed for the .section .eh_frame directive.  ])
399   fi
400
401   AC_CACHE_CHECK([for __attribute__((visibility("hidden")))],
402       libffi_cv_hidden_visibility_attribute, [
403         echo 'int __attribute__ ((visibility ("hidden"))) foo (void) { return 1  ; }' > conftest.c
404         libffi_cv_hidden_visibility_attribute=no
405         if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
406             if grep '\.hidden.*foo' conftest.s >/dev/null; then
407                 libffi_cv_hidden_visibility_attribute=yes
408             fi
409         fi
410         rm -f conftest.*
411       ])
412   if test $libffi_cv_hidden_visibility_attribute = yes; then
413       AC_DEFINE(HAVE_HIDDEN_VISIBILITY_ATTRIBUTE, 1,
414               [Define if __attribute__((visibility("hidden"))) is supported.])
415   fi
416 fi
417
418 AH_BOTTOM([
419 #ifdef HAVE_HIDDEN_VISIBILITY_ATTRIBUTE
420 #ifdef LIBFFI_ASM
421 #define FFI_HIDDEN(name) .hidden name
422 #else
423 #define FFI_HIDDEN __attribute__ ((visibility ("hidden")))
424 #endif
425 #else
426 #ifdef LIBFFI_ASM
427 #define FFI_HIDDEN(name)
428 #else
429 #define FFI_HIDDEN
430 #endif
431 #endif
432 ])
433
434 AC_SUBST(TARGET)
435 AC_SUBST(TARGETDIR)
436
437 AC_SUBST(SHELL)
438
439 AC_ARG_ENABLE(debug,
440 [  --enable-debug          debugging mode],
441   if test "$enable_debug" = "yes"; then
442     AC_DEFINE(FFI_DEBUG, 1, [Define this if you want extra debugging.])
443   fi)
444 AM_CONDITIONAL(FFI_DEBUG, test "$enable_debug" = "yes")
445
446 AC_ARG_ENABLE(structs,
447 [  --disable-structs       omit code for struct support],
448   if test "$enable_structs" = "no"; then
449     AC_DEFINE(FFI_NO_STRUCTS, 1, [Define this is you do not want support for aggregate types.])
450   fi)
451
452 AC_ARG_ENABLE(raw-api,
453 [  --disable-raw-api       make the raw api unavailable],
454   if test "$enable_raw_api" = "no"; then
455     AC_DEFINE(FFI_NO_RAW_API, 1, [Define this is you do not want support for the raw API.])
456   fi)
457
458 AC_ARG_ENABLE(purify-safety,
459 [  --enable-purify-safety  purify-safe mode],
460   if test "$enable_purify_safety" = "yes"; then
461     AC_DEFINE(USING_PURIFY, 1, [Define this if you are using Purify and want to suppress spurious messages.])
462   fi)
463
464 if test -n "$with_cross_host" &&
465    test x"$with_cross_host" != x"no"; then
466   toolexecdir='$(exec_prefix)/$(target_alias)'
467   toolexeclibdir='$(toolexecdir)/lib'
468 else
469   toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
470   toolexeclibdir='$(libdir)'
471 fi
472 multi_os_directory=`$CC -print-multi-os-directory`
473 case $multi_os_directory in
474   .) ;; # Avoid trailing /.
475   *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
476 esac
477 AC_SUBST(toolexecdir)
478 AC_SUBST(toolexeclibdir)
479
480 if test "${multilib}" = "yes"; then
481   multilib_arg="--enable-multilib"
482 else
483   multilib_arg=
484 fi
485
486 AC_CONFIG_COMMANDS(include, [test -d include || mkdir include])
487 AC_CONFIG_COMMANDS(src, [
488 test -d src || mkdir src
489 test -d src/$TARGETDIR || mkdir src/$TARGETDIR
490 ], [TARGETDIR="$TARGETDIR"])
491
492 AC_CONFIG_LINKS(include/ffitarget.h:src/$TARGETDIR/ffitarget.h)
493
494 AC_CONFIG_FILES(include/Makefile include/ffi.h Makefile testsuite/Makefile man/Makefile)
495
496 AC_OUTPUT