Rebase post GCC merge
[libffi.git] / configure.ac
1 dnl Process this with autoconf to create configure
2
3 AC_PREREQ(2.64)
4
5 AC_INIT([libffi], [3.0.11-rc2], [http://github.com/atgreen/libffi/issues])
6 AC_CONFIG_HEADERS([fficonfig.h])
7
8 AC_CANONICAL_SYSTEM
9 target_alias=${target_alias-$host_alias}
10
11 . ${srcdir}/configure.host
12
13 AX_ENABLE_BUILDDIR
14
15 AM_INIT_AUTOMAKE
16
17 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
18 # We must force CC to /not/ be precious variables; otherwise
19 # the wrong, non-multilib-adjusted value will be used in multilibs.
20 # As a side effect, we have to subst CFLAGS ourselves.
21 # Also save and restore CFLAGS, since AC_PROG_CC will come up with
22 # defaults of its own if none are provided.
23
24 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
25 m4_define([_AC_ARG_VAR_PRECIOUS],[])
26 save_CFLAGS=$CFLAGS
27 AC_PROG_CC
28 CFLAGS=$save_CFLAGS
29 m4_undefine([_AC_ARG_VAR_PRECIOUS])
30 m4_rename([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
31
32 AC_SUBST(CFLAGS)
33
34 AM_PROG_AS
35 AM_PROG_CC_C_O
36 AC_PROG_LIBTOOL
37 AC_CONFIG_MACRO_DIR([m4])
38
39 AX_CC_MAXOPT
40 AX_CFLAGS_WARN_ALL
41 if test "x$GCC" = "xyes"; then
42   CFLAGS="$CFLAGS -fexceptions"
43 fi
44
45 AM_MAINTAINER_MODE
46
47 AC_CHECK_HEADERS(sys/mman.h)
48 AC_CHECK_FUNCS(mmap)
49 AC_FUNC_MMAP_BLACKLIST
50
51 dnl The -no-testsuite modules omit the test subdir.
52 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
53
54 TARGETDIR="unknown"
55 case "$host" in
56   alpha*-*-*)
57         TARGET=ALPHA; TARGETDIR=alpha;
58         # Support 128-bit long double, changeable via command-line switch.
59         HAVE_LONG_DOUBLE='defined(__LONG_DOUBLE_128__)'
60         ;;
61
62   arm*-*-*)
63         TARGET=ARM; TARGETDIR=arm
64         ;;
65
66   amd64-*-freebsd* | amd64-*-openbsd*)
67         TARGET=X86_64; TARGETDIR=x86
68         ;;
69
70   amd64-*-freebsd*)
71         TARGET=X86_64; TARGETDIR=x86
72         ;;
73
74   avr32*-*-*)
75         TARGET=AVR32; TARGETDIR=avr32
76         ;;
77
78   cris-*-*)
79         TARGET=LIBFFI_CRIS; TARGETDIR=cris
80         ;;
81
82   frv-*-*)
83         TARGET=FRV; TARGETDIR=frv
84         ;;
85
86   hppa*-*-linux* | parisc*-*-linux* | hppa*-*-openbsd*)
87         TARGET=PA_LINUX; TARGETDIR=pa
88         ;;
89   hppa*64-*-hpux*)
90         TARGET=PA64_HPUX; TARGETDIR=pa
91         ;;
92   hppa*-*-hpux*)
93         TARGET=PA_HPUX; TARGETDIR=pa
94         ;;
95
96   i?86-*-freebsd* | i?86-*-openbsd*)
97         TARGET=X86_FREEBSD; TARGETDIR=x86
98         ;;
99   i?86-win32* | i?86-*-cygwin* | i?86-*-mingw* | i?86-*-os2* | i?86-*-interix*)
100         TARGET=X86_WIN32; TARGETDIR=x86
101         # All mingw/cygwin/win32 builds require -no-undefined for sharedlib.
102         # We must also check with_cross_host to decide if this is a native
103         # or cross-build and select where to install dlls appropriately.
104         if test -n "$with_cross_host" &&
105            test x"$with_cross_host" != x"no"; then
106           AM_LTLDFLAGS='-no-undefined -bindir "$(toolexeclibdir)"';
107         else
108           AM_LTLDFLAGS='-no-undefined -bindir "$(bindir)"';
109         fi
110         ;;
111   i?86-*-darwin*)
112         TARGET=X86_DARWIN; TARGETDIR=x86
113         ;;
114   i?86-*-solaris2.1[[0-9]]*)
115         TARGET=X86_64; TARGETDIR=x86
116         ;;
117   i?86-*-*)
118         TARGET=X86_64; TARGETDIR=x86
119         ;;
120
121   ia64*-*-*)
122         TARGET=IA64; TARGETDIR=ia64
123         ;;
124
125   m32r*-*-*)
126         TARGET=M32R; TARGETDIR=m32r
127         ;;
128
129   m68k-*-*)
130         TARGET=M68K; TARGETDIR=m68k
131         ;;
132
133   mips-sgi-irix5.* | mips-sgi-irix6.* | mips*-*-rtems*)
134         TARGET=MIPS; TARGETDIR=mips
135         ;;
136   mips*-*-linux* | mips*-*-openbsd*)
137         # Support 128-bit long double for NewABI.
138         HAVE_LONG_DOUBLE='defined(__mips64)'
139         TARGET=MIPS; TARGETDIR=mips
140         ;;
141
142   moxie-*-*)
143         TARGET=MOXIE; TARGETDIR=moxie
144         ;;
145
146   powerpc*-*-linux* | powerpc-*-sysv*)
147         TARGET=POWERPC; TARGETDIR=powerpc
148         ;;
149   powerpc-*-amigaos*)
150         TARGET=POWERPC; TARGETDIR=powerpc
151         ;;
152   powerpc-*-beos*)
153         TARGET=POWERPC; TARGETDIR=powerpc
154         ;;
155   powerpc-*-darwin* | powerpc64-*-darwin*)
156         TARGET=POWERPC_DARWIN; TARGETDIR=powerpc
157         ;;
158   powerpc-*-aix* | rs6000-*-aix*)
159         TARGET=POWERPC_AIX; TARGETDIR=powerpc
160         ;;
161   powerpc-*-freebsd* | powerpc-*-openbsd*)
162         TARGET=POWERPC_FREEBSD; TARGETDIR=powerpc
163         ;;
164   powerpc64-*-freebsd*)
165         TARGET=POWERPC; TARGETDIR=powerpc
166         ;;
167   powerpc*-*-rtems*)
168         TARGET=POWERPC; TARGETDIR=powerpc
169         ;;
170
171   s390-*-* | s390x-*-*)
172         TARGET=S390; TARGETDIR=s390
173         ;;
174
175   sh-*-* | sh[[34]]*-*-*)
176         TARGET=SH; TARGETDIR=sh
177         ;;
178   sh64-*-* | sh5*-*-*)
179         TARGET=SH64; TARGETDIR=sh64
180         ;;
181
182   sparc*-*-*)
183         TARGET=SPARC; TARGETDIR=sparc
184         ;;
185
186   x86_64-*-darwin*)
187         TARGET=X86_DARWIN; TARGETDIR=x86
188         ;;
189
190   x86_64-*-cygwin* | x86_64-*-mingw*)
191         TARGET=X86_WIN64; TARGETDIR=x86
192         # All mingw/cygwin/win32 builds require -no-undefined for sharedlib.
193         # We must also check with_cross_host to decide if this is a native
194         # or cross-build and select where to install dlls appropriately.
195         if test -n "$with_cross_host" &&
196            test x"$with_cross_host" != x"no"; then
197           AM_LTLDFLAGS='-no-undefined -bindir "$(toolexeclibdir)"';
198         else
199           AM_LTLDFLAGS='-no-undefined -bindir "$(bindir)"';
200         fi
201         ;;
202
203   x86_64-*-*)
204         TARGET=X86_64; TARGETDIR=x86
205         ;;
206 esac
207
208 AC_SUBST(AM_RUNTESTFLAGS)
209 AC_SUBST(AM_LTLDFLAGS)
210
211 if test $TARGETDIR = unknown; then
212   AC_MSG_ERROR(["libffi has not been ported to $host."])
213 fi
214
215 AM_CONDITIONAL(MIPS, test x$TARGET = xMIPS)
216 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
217 AM_CONDITIONAL(X86, test x$TARGET = xX86)
218 AM_CONDITIONAL(X86_FREEBSD, test x$TARGET = xX86_FREEBSD)
219 AM_CONDITIONAL(X86_WIN32, test x$TARGET = xX86_WIN32)
220 AM_CONDITIONAL(X86_WIN64, test x$TARGET = xX86_WIN64)
221 AM_CONDITIONAL(X86_DARWIN, test x$TARGET = xX86_DARWIN)
222 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
223 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
224 AM_CONDITIONAL(M32R, test x$TARGET = xM32R)
225 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
226 AM_CONDITIONAL(MOXIE, test x$TARGET = xMOXIE)
227 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
228 AM_CONDITIONAL(POWERPC_AIX, test x$TARGET = xPOWERPC_AIX)
229 AM_CONDITIONAL(POWERPC_DARWIN, test x$TARGET = xPOWERPC_DARWIN)
230 AM_CONDITIONAL(POWERPC_FREEBSD, test x$TARGET = xPOWERPC_FREEBSD)
231 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
232 AM_CONDITIONAL(AVR32, test x$TARGET = xAVR32)
233 AM_CONDITIONAL(LIBFFI_CRIS, test x$TARGET = xLIBFFI_CRIS)
234 AM_CONDITIONAL(FRV, test x$TARGET = xFRV)
235 AM_CONDITIONAL(S390, test x$TARGET = xS390)
236 AM_CONDITIONAL(X86_64, test x$TARGET = xX86_64)
237 AM_CONDITIONAL(SH, test x$TARGET = xSH)
238 AM_CONDITIONAL(SH64, test x$TARGET = xSH64)
239 AM_CONDITIONAL(PA_LINUX, test x$TARGET = xPA_LINUX)
240 AM_CONDITIONAL(PA_HPUX, test x$TARGET = xPA_HPUX)
241 AM_CONDITIONAL(PA64_HPUX, test x$TARGET = xPA64_HPUX)
242
243 AC_HEADER_STDC
244 AC_CHECK_FUNCS(memcpy)
245 AC_FUNC_ALLOCA
246
247 AC_CHECK_SIZEOF(double)
248 AC_CHECK_SIZEOF(long double)
249
250 # Also AC_SUBST this variable for ffi.h.
251 if test -z "$HAVE_LONG_DOUBLE"; then
252   HAVE_LONG_DOUBLE=0
253   if test $ac_cv_sizeof_double != $ac_cv_sizeof_long_double; then
254     if test $ac_cv_sizeof_long_double != 0; then
255       HAVE_LONG_DOUBLE=1
256       AC_DEFINE(HAVE_LONG_DOUBLE, 1, [Define if you have the long double type and it is bigger than a double])
257     fi
258   fi
259 fi
260 AC_SUBST(HAVE_LONG_DOUBLE)
261
262 AC_C_BIGENDIAN
263
264 GCC_AS_CFI_PSEUDO_OP
265
266 if test x$TARGET = xSPARC; then
267     AC_CACHE_CHECK([assembler and linker support unaligned pc related relocs],
268         libffi_cv_as_sparc_ua_pcrel, [
269         save_CFLAGS="$CFLAGS"
270         save_LDFLAGS="$LDFLAGS"
271         CFLAGS="$CFLAGS -fpic"
272         LDFLAGS="$LDFLAGS -shared"
273         AC_TRY_LINK([asm (".text; foo: nop; .data; .align 4; .byte 0; .uaword %r_disp32(foo); .text");],,
274                     [libffi_cv_as_sparc_ua_pcrel=yes],
275                     [libffi_cv_as_sparc_ua_pcrel=no])
276         CFLAGS="$save_CFLAGS"
277         LDFLAGS="$save_LDFLAGS"])
278     if test "x$libffi_cv_as_sparc_ua_pcrel" = xyes; then
279         AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
280                   [Define if your assembler and linker support unaligned PC relative relocs.])
281     fi
282
283     AC_CACHE_CHECK([assembler .register pseudo-op support],
284        libffi_cv_as_register_pseudo_op, [
285        libffi_cv_as_register_pseudo_op=unknown
286        # Check if we have .register
287        AC_TRY_COMPILE([asm (".register %g2, #scratch");],,
288                        [libffi_cv_as_register_pseudo_op=yes],
289                        [libffi_cv_as_register_pseudo_op=no])
290     ])
291     if test "x$libffi_cv_as_register_pseudo_op" = xyes; then
292        AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
293                [Define if your assembler supports .register.])
294     fi
295 fi
296
297 if test x$TARGET = xX86 || test x$TARGET = xX86_WIN32 || test x$TARGET = xX86_64; then
298     AC_CACHE_CHECK([assembler supports pc related relocs],
299         libffi_cv_as_x86_pcrel, [
300         libffi_cv_as_x86_pcrel=yes
301         echo '.text; foo: nop; .data; .long foo-.; .text' > conftest.s
302         if $CC $CFLAGS -c conftest.s 2>&1 | $EGREP -i 'illegal|warning' > /dev/null; then
303             libffi_cv_as_x86_pcrel=no
304         fi
305         ])
306     if test "x$libffi_cv_as_x86_pcrel" = xyes; then
307         AC_DEFINE(HAVE_AS_X86_PCREL, 1,
308                   [Define if your assembler supports PC relative relocs.])
309     fi
310
311     AC_CACHE_CHECK([assembler .ascii pseudo-op support],
312        libffi_cv_as_ascii_pseudo_op, [
313        libffi_cv_as_ascii_pseudo_op=unknown
314        # Check if we have .ascii
315        AC_TRY_COMPILE([asm (".ascii \\"string\\"");],,
316                        [libffi_cv_as_ascii_pseudo_op=yes],
317                        [libffi_cv_as_ascii_pseudo_op=no])
318     ])
319     if test "x$libffi_cv_as_ascii_pseudo_op" = xyes; then
320        AC_DEFINE(HAVE_AS_ASCII_PSEUDO_OP, 1,
321                [Define if your assembler supports .ascii.])
322     fi
323
324     AC_CACHE_CHECK([assembler .string pseudo-op support],
325        libffi_cv_as_string_pseudo_op, [
326        libffi_cv_as_string_pseudo_op=unknown
327        # Check if we have .string
328        AC_TRY_COMPILE([asm (".string \\"string\\"");],,
329                        [libffi_cv_as_string_pseudo_op=yes],
330                        [libffi_cv_as_string_pseudo_op=no])
331     ])
332     if test "x$libffi_cv_as_string_pseudo_op" = xyes; then
333        AC_DEFINE(HAVE_AS_STRING_PSEUDO_OP, 1,
334                [Define if your assembler supports .string.])
335     fi
336 fi
337
338 if test x$TARGET = xX86_WIN64; then
339     LT_SYS_SYMBOL_USCORE
340     if test "x$sys_symbol_underscore" = xyes; then
341         AC_DEFINE(SYMBOL_UNDERSCORE, 1, [Define if symbols are underscored.])
342     fi
343 fi
344
345
346 FFI_EXEC_TRAMPOLINE_TABLE=0
347 case "$target" in
348      *arm*-apple-darwin*)
349        FFI_EXEC_TRAMPOLINE_TABLE=1
350        AC_DEFINE(FFI_EXEC_TRAMPOLINE_TABLE, 1,
351                  [Cannot use PROT_EXEC on this target, so, we revert to
352                    alternative means])
353      ;;
354      *-apple-darwin1[[10]]* | *-*-freebsd* | *-*-kfreebsd* | *-*-openbsd* | *-pc-solaris*)
355        AC_DEFINE(FFI_MMAP_EXEC_WRIT, 1,
356                  [Cannot use malloc on this target, so, we revert to
357                    alternative means])
358      ;;
359 esac
360 AM_CONDITIONAL(FFI_EXEC_TRAMPOLINE_TABLE, test x$FFI_EXEC_TRAMPOLINE_TABLE = x1)
361 AC_SUBST(FFI_EXEC_TRAMPOLINE_TABLE)
362
363 if test x$TARGET = xX86_64; then
364     AC_CACHE_CHECK([assembler supports unwind section type],
365         libffi_cv_as_x86_64_unwind_section_type, [
366         libffi_cv_as_x86_64_unwind_section_type=yes
367         echo '.section .eh_frame,"a",@unwind' > conftest.s
368         if $CC $CFLAGS -c conftest.s 2>&1 | grep -i warning > /dev/null; then
369             libffi_cv_as_x86_64_unwind_section_type=no
370         fi
371         ])
372     if test "x$libffi_cv_as_x86_64_unwind_section_type" = xyes; then
373         AC_DEFINE(HAVE_AS_X86_64_UNWIND_SECTION_TYPE, 1,
374                   [Define if your assembler supports unwind section type.])
375     fi
376 fi
377
378 if test "x$GCC" = "xyes"; then
379   AC_CACHE_CHECK([whether .eh_frame section should be read-only],
380       libffi_cv_ro_eh_frame, [
381         libffi_cv_ro_eh_frame=no
382         echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
383         if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
384             if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
385                 libffi_cv_ro_eh_frame=yes
386             elif grep '.section.*eh_frame.*#alloc' conftest.c \
387                  | grep -v '#write' > /dev/null; then
388                 libffi_cv_ro_eh_frame=yes
389             fi
390         fi
391         rm -f conftest.*
392       ])
393   if test "x$libffi_cv_ro_eh_frame" = xyes; then
394       AC_DEFINE(HAVE_RO_EH_FRAME, 1,
395               [Define if .eh_frame sections should be read-only.])
396       AC_DEFINE(EH_FRAME_FLAGS, "a",
397               [Define to the flags needed for the .section .eh_frame directive.  ])
398   else
399       AC_DEFINE(EH_FRAME_FLAGS, "aw",
400               [Define to the flags needed for the .section .eh_frame directive.  ])
401   fi
402
403   AC_CACHE_CHECK([for __attribute__((visibility("hidden")))],
404       libffi_cv_hidden_visibility_attribute, [
405         echo 'int __attribute__ ((visibility ("hidden"))) foo (void) { return 1  ; }' > conftest.c
406         libffi_cv_hidden_visibility_attribute=no
407         if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
408             if grep '\.hidden.*foo' conftest.s >/dev/null; then
409                 libffi_cv_hidden_visibility_attribute=yes
410             fi
411         fi
412         rm -f conftest.*
413       ])
414   if test $libffi_cv_hidden_visibility_attribute = yes; then
415       AC_DEFINE(HAVE_HIDDEN_VISIBILITY_ATTRIBUTE, 1,
416               [Define if __attribute__((visibility("hidden"))) is supported.])
417   fi
418 fi
419
420 AH_BOTTOM([
421 #ifdef HAVE_HIDDEN_VISIBILITY_ATTRIBUTE
422 #ifdef LIBFFI_ASM
423 #define FFI_HIDDEN(name) .hidden name
424 #else
425 #define FFI_HIDDEN __attribute__ ((visibility ("hidden")))
426 #endif
427 #else
428 #ifdef LIBFFI_ASM
429 #define FFI_HIDDEN(name)
430 #else
431 #define FFI_HIDDEN
432 #endif
433 #endif
434 ])
435
436 AC_SUBST(TARGET)
437 AC_SUBST(TARGETDIR)
438
439 AC_SUBST(SHELL)
440
441 AC_ARG_ENABLE(debug,
442 [  --enable-debug          debugging mode],
443   if test "$enable_debug" = "yes"; then
444     AC_DEFINE(FFI_DEBUG, 1, [Define this if you want extra debugging.])
445   fi)
446 AM_CONDITIONAL(FFI_DEBUG, test "$enable_debug" = "yes")
447
448 AC_ARG_ENABLE(structs,
449 [  --disable-structs       omit code for struct support],
450   if test "$enable_structs" = "no"; then
451     AC_DEFINE(FFI_NO_STRUCTS, 1, [Define this is you do not want support for aggregate types.])
452   fi)
453
454 AC_ARG_ENABLE(raw-api,
455 [  --disable-raw-api       make the raw api unavailable],
456   if test "$enable_raw_api" = "no"; then
457     AC_DEFINE(FFI_NO_RAW_API, 1, [Define this is you do not want support for the raw API.])
458   fi)
459
460 AC_ARG_ENABLE(purify-safety,
461 [  --enable-purify-safety  purify-safe mode],
462   if test "$enable_purify_safety" = "yes"; then
463     AC_DEFINE(USING_PURIFY, 1, [Define this if you are using Purify and want to suppress spurious messages.])
464   fi)
465
466 # These variables are only ever used when we cross-build to X86_WIN32.
467 # And we only support this with GCC, so...
468 if test x"$GCC" != x"no"; then
469   if test -n "$with_cross_host" &&
470      test x"$with_cross_host" != x"no"; then
471     toolexecdir='$(exec_prefix)/$(target_alias)'
472     toolexeclibdir='$(toolexecdir)/lib'
473   else
474     toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
475     toolexeclibdir='$(libdir)'
476   fi
477   multi_os_directory=`$CC -print-multi-os-directory`
478   case $multi_os_directory in
479     .) ;; # Avoid trailing /.
480     *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
481   esac
482   AC_SUBST(toolexecdir)
483   AC_SUBST(toolexeclibdir)
484 fi
485
486 if test "${multilib}" = "yes"; then
487   multilib_arg="--enable-multilib"
488 else
489   multilib_arg=
490 fi
491
492 AC_CONFIG_COMMANDS(include, [test -d include || mkdir include])
493 AC_CONFIG_COMMANDS(src, [
494 test -d src || mkdir src
495 test -d src/$TARGETDIR || mkdir src/$TARGETDIR
496 ], [TARGETDIR="$TARGETDIR"])
497
498 AC_CONFIG_LINKS(include/ffitarget.h:src/$TARGETDIR/ffitarget.h)
499
500 AC_CONFIG_FILES(include/Makefile include/ffi.h Makefile testsuite/Makefile man/Makefile libffi.pc)
501
502 AC_OUTPUT