Ensure that users don't include ffitarget.h directly
[libffi.git] / .pc / ungccify / configure.ac
1 dnl Process this with autoconf to create configure
2
3 AC_PREREQ(2.63)
4
5 AC_INIT([libffi], [3.0.11-rc2], [http://github.com/atgreen/libffi/issues])
6 AC_CONFIG_HEADERS([fficonfig.h])
7
8 AC_CANONICAL_SYSTEM
9 target_alias=${target_alias-$host_alias}
10
11 . ${srcdir}/configure.host
12
13 AM_INIT_AUTOMAKE
14
15 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
16 # We must force CC to /not/ be precious variables; otherwise
17 # the wrong, non-multilib-adjusted value will be used in multilibs.
18 # As a side effect, we have to subst CFLAGS ourselves.
19 # Also save and restore CFLAGS, since AC_PROG_CC will come up with
20 # defaults of its own if none are provided.
21
22 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
23 m4_define([_AC_ARG_VAR_PRECIOUS],[])
24 save_CFLAGS=$CFLAGS
25 AC_PROG_CC
26 CFLAGS=$save_CFLAGS
27 m4_undefine([_AC_ARG_VAR_PRECIOUS])
28 m4_rename([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
29
30 AC_SUBST(CFLAGS)
31
32 AM_PROG_AS
33 AM_PROG_CC_C_O
34 AC_PROG_LIBTOOL
35 AC_CONFIG_MACRO_DIR([m4])
36
37 AM_MAINTAINER_MODE
38
39 AC_CHECK_HEADERS(sys/mman.h)
40 AC_CHECK_FUNCS(mmap)
41 AC_FUNC_MMAP_BLACKLIST
42
43 dnl The -no-testsuite modules omit the test subdir.
44 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
45
46 TARGETDIR="unknown"
47 case "$host" in
48   alpha*-*-*)
49         TARGET=ALPHA; TARGETDIR=alpha;
50         # Support 128-bit long double, changeable via command-line switch.
51         HAVE_LONG_DOUBLE='defined(__LONG_DOUBLE_128__)'
52         ;;
53
54   arm*-*-*)
55         TARGET=ARM; TARGETDIR=arm
56         ;;
57
58   amd64-*-freebsd* | amd64-*-openbsd*)
59         TARGET=X86_64; TARGETDIR=x86
60         ;;
61
62   amd64-*-freebsd*)
63         TARGET=X86_64; TARGETDIR=x86
64         ;;
65
66   avr32*-*-*)
67         TARGET=AVR32; TARGETDIR=avr32
68         ;;
69
70   cris-*-*)
71         TARGET=LIBFFI_CRIS; TARGETDIR=cris
72         ;;
73
74   frv-*-*)
75         TARGET=FRV; TARGETDIR=frv
76         ;;
77
78   hppa*-*-linux* | parisc*-*-linux*)
79         TARGET=PA_LINUX; TARGETDIR=pa
80         ;;
81   hppa*64-*-hpux*)
82         TARGET=PA64_HPUX; TARGETDIR=pa
83         ;;
84   hppa*-*-hpux*)
85         TARGET=PA_HPUX; TARGETDIR=pa
86         ;;
87
88   i?86-*-freebsd* | i?86-*-openbsd*)
89         TARGET=X86_FREEBSD; TARGETDIR=x86
90         ;;
91   i?86-win32* | i?86-*-cygwin* | i?86-*-mingw* | i?86-*-os2* | i?86-*-interix*)
92         TARGET=X86_WIN32; TARGETDIR=x86
93         # All mingw/cygwin/win32 builds require -no-undefined for sharedlib.
94         # We must also check with_cross_host to decide if this is a native
95         # or cross-build and select where to install dlls appropriately.
96         if test -n "$with_cross_host" &&
97            test x"$with_cross_host" != x"no"; then
98           AM_LTLDFLAGS='-no-undefined -bindir "$(toolexeclibdir)"';
99         else
100           AM_LTLDFLAGS='-no-undefined -bindir "$(bindir)"';
101         fi
102         ;;
103   i?86-*-darwin*)
104         TARGET=X86_DARWIN; TARGETDIR=x86
105         ;;
106   i?86-*-solaris2.1[[0-9]]*)
107         TARGET=X86_64; TARGETDIR=x86
108         ;;
109   i?86-*-*)
110         TARGET=X86_64; TARGETDIR=x86
111         ;;
112
113   ia64*-*-*)
114         TARGET=IA64; TARGETDIR=ia64
115         ;;
116
117   m32r*-*-*)
118         TARGET=M32R; TARGETDIR=m32r
119         ;;
120
121   m68k-*-*)
122         TARGET=M68K; TARGETDIR=m68k
123         ;;
124
125   mips-sgi-irix5.* | mips-sgi-irix6.* | mips*-*-rtems*)
126         TARGET=MIPS; TARGETDIR=mips
127         ;;
128   mips*-*-linux*)
129         # Support 128-bit long double for NewABI.
130         HAVE_LONG_DOUBLE='defined(__mips64)'
131         TARGET=MIPS; TARGETDIR=mips
132         ;;
133
134   moxie-*-*)
135         TARGET=MOXIE; TARGETDIR=moxie
136         ;;
137
138   powerpc*-*-linux* | powerpc-*-sysv*)
139         TARGET=POWERPC; TARGETDIR=powerpc
140         ;;
141   powerpc-*-beos*)
142         TARGET=POWERPC; TARGETDIR=powerpc
143         ;;
144   powerpc-*-darwin* | powerpc64-*-darwin*)
145         TARGET=POWERPC_DARWIN; TARGETDIR=powerpc
146         ;;
147   powerpc-*-aix* | rs6000-*-aix*)
148         TARGET=POWERPC_AIX; TARGETDIR=powerpc
149         ;;
150   powerpc-*-freebsd*)
151         TARGET=POWERPC_FREEBSD; TARGETDIR=powerpc
152         ;;
153   powerpc64-*-freebsd*)
154         TARGET=POWERPC; TARGETDIR=powerpc
155         ;;
156   powerpc*-*-rtems*)
157         TARGET=POWERPC; TARGETDIR=powerpc
158         ;;
159
160   s390-*-* | s390x-*-*)
161         TARGET=S390; TARGETDIR=s390
162         ;;
163
164   sh-*-* | sh[[34]]*-*-*)
165         TARGET=SH; TARGETDIR=sh
166         ;;
167   sh64-*-* | sh5*-*-*)
168         TARGET=SH64; TARGETDIR=sh64
169         ;;
170
171   sparc*-*-*)
172         TARGET=SPARC; TARGETDIR=sparc
173         ;;
174
175   x86_64-*-darwin*)
176         TARGET=X86_DARWIN; TARGETDIR=x86
177         ;;
178
179   x86_64-*-cygwin* | x86_64-*-mingw*)
180         TARGET=X86_WIN64; TARGETDIR=x86
181         # All mingw/cygwin/win32 builds require -no-undefined for sharedlib.
182         # We must also check with_cross_host to decide if this is a native
183         # or cross-build and select where to install dlls appropriately.
184         if test -n "$with_cross_host" &&
185            test x"$with_cross_host" != x"no"; then
186           AM_LTLDFLAGS='-no-undefined -bindir "$(toolexeclibdir)"';
187         else
188           AM_LTLDFLAGS='-no-undefined -bindir "$(bindir)"';
189         fi
190         ;;
191
192   x86_64-*-*)
193         TARGET=X86_64; TARGETDIR=x86
194         ;;
195 esac
196
197 AC_SUBST(AM_RUNTESTFLAGS)
198 AC_SUBST(AM_LTLDFLAGS)
199
200 if test $TARGETDIR = unknown; then
201   AC_MSG_ERROR(["libffi has not been ported to $host."])
202 fi
203
204 AM_CONDITIONAL(MIPS, test x$TARGET = xMIPS)
205 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
206 AM_CONDITIONAL(X86, test x$TARGET = xX86)
207 AM_CONDITIONAL(X86_FREEBSD, test x$TARGET = xX86_FREEBSD)
208 AM_CONDITIONAL(X86_WIN32, test x$TARGET = xX86_WIN32)
209 AM_CONDITIONAL(X86_WIN64, test x$TARGET = xX86_WIN64)
210 AM_CONDITIONAL(X86_DARWIN, test x$TARGET = xX86_DARWIN)
211 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
212 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
213 AM_CONDITIONAL(M32R, test x$TARGET = xM32R)
214 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
215 AM_CONDITIONAL(MOXIE, test x$TARGET = xMOXIE)
216 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
217 AM_CONDITIONAL(POWERPC_AIX, test x$TARGET = xPOWERPC_AIX)
218 AM_CONDITIONAL(POWERPC_DARWIN, test x$TARGET = xPOWERPC_DARWIN)
219 AM_CONDITIONAL(POWERPC_FREEBSD, test x$TARGET = xPOWERPC_FREEBSD)
220 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
221 AM_CONDITIONAL(AVR32, test x$TARGET = xAVR32)
222 AM_CONDITIONAL(LIBFFI_CRIS, test x$TARGET = xLIBFFI_CRIS)
223 AM_CONDITIONAL(FRV, test x$TARGET = xFRV)
224 AM_CONDITIONAL(S390, test x$TARGET = xS390)
225 AM_CONDITIONAL(X86_64, test x$TARGET = xX86_64)
226 AM_CONDITIONAL(SH, test x$TARGET = xSH)
227 AM_CONDITIONAL(SH64, test x$TARGET = xSH64)
228 AM_CONDITIONAL(PA_LINUX, test x$TARGET = xPA_LINUX)
229 AM_CONDITIONAL(PA_HPUX, test x$TARGET = xPA_HPUX)
230 AM_CONDITIONAL(PA64_HPUX, test x$TARGET = xPA64_HPUX)
231
232 AC_HEADER_STDC
233 AC_CHECK_FUNCS(memcpy)
234 AC_FUNC_ALLOCA
235
236 AC_CHECK_SIZEOF(double)
237 AC_CHECK_SIZEOF(long double)
238
239 # Also AC_SUBST this variable for ffi.h.
240 if test -z "$HAVE_LONG_DOUBLE"; then
241   HAVE_LONG_DOUBLE=0
242   if test $ac_cv_sizeof_double != $ac_cv_sizeof_long_double; then
243     if test $ac_cv_sizeof_long_double != 0; then
244       HAVE_LONG_DOUBLE=1
245       AC_DEFINE(HAVE_LONG_DOUBLE, 1, [Define if you have the long double type and it is bigger than a double])
246     fi
247   fi
248 fi
249 AC_SUBST(HAVE_LONG_DOUBLE)
250
251 AC_C_BIGENDIAN
252
253 GCC_AS_CFI_PSEUDO_OP
254
255 if test x$TARGET = xSPARC; then
256     AC_CACHE_CHECK([assembler and linker support unaligned pc related relocs],
257         libffi_cv_as_sparc_ua_pcrel, [
258         save_CFLAGS="$CFLAGS"
259         save_LDFLAGS="$LDFLAGS"
260         CFLAGS="$CFLAGS -fpic"
261         LDFLAGS="$LDFLAGS -shared"
262         AC_TRY_LINK([asm (".text; foo: nop; .data; .align 4; .byte 0; .uaword %r_disp32(foo); .text");],,
263                     [libffi_cv_as_sparc_ua_pcrel=yes],
264                     [libffi_cv_as_sparc_ua_pcrel=no])
265         CFLAGS="$save_CFLAGS"
266         LDFLAGS="$save_LDFLAGS"])
267     if test "x$libffi_cv_as_sparc_ua_pcrel" = xyes; then
268         AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
269                   [Define if your assembler and linker support unaligned PC relative relocs.])
270     fi
271
272     AC_CACHE_CHECK([assembler .register pseudo-op support],
273        libffi_cv_as_register_pseudo_op, [
274        libffi_cv_as_register_pseudo_op=unknown
275        # Check if we have .register
276        AC_TRY_COMPILE([asm (".register %g2, #scratch");],,
277                        [libffi_cv_as_register_pseudo_op=yes],
278                        [libffi_cv_as_register_pseudo_op=no])
279     ])
280     if test "x$libffi_cv_as_register_pseudo_op" = xyes; then
281        AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
282                [Define if your assembler supports .register.])
283     fi
284 fi
285
286 if test x$TARGET = xX86 || test x$TARGET = xX86_WIN32 || test x$TARGET = xX86_64; then
287     AC_CACHE_CHECK([assembler supports pc related relocs],
288         libffi_cv_as_x86_pcrel, [
289         libffi_cv_as_x86_pcrel=no
290         echo '.text; foo: nop; .data; .long foo-.; .text' > conftest.s
291         if $CC $CFLAGS -c conftest.s > /dev/null; then
292            libffi_cv_as_x86_pcrel=yes
293         fi
294         ])
295     if test "x$libffi_cv_as_x86_pcrel" = xyes; then
296         AC_DEFINE(HAVE_AS_X86_PCREL, 1,
297                   [Define if your assembler supports PC relative relocs.])
298     fi
299
300     AC_CACHE_CHECK([assembler .ascii pseudo-op support],
301        libffi_cv_as_ascii_pseudo_op, [
302        libffi_cv_as_ascii_pseudo_op=unknown
303        # Check if we have .ascii
304        AC_TRY_COMPILE([asm (".ascii \\"string\\"");],,
305                        [libffi_cv_as_ascii_pseudo_op=yes],
306                        [libffi_cv_as_ascii_pseudo_op=no])
307     ])
308     if test "x$libffi_cv_as_ascii_pseudo_op" = xyes; then
309        AC_DEFINE(HAVE_AS_ASCII_PSEUDO_OP, 1,
310                [Define if your assembler supports .ascii.])
311     fi
312
313     AC_CACHE_CHECK([assembler .string pseudo-op support],
314        libffi_cv_as_string_pseudo_op, [
315        libffi_cv_as_string_pseudo_op=unknown
316        # Check if we have .string
317        AC_TRY_COMPILE([asm (".string \\"string\\"");],,
318                        [libffi_cv_as_string_pseudo_op=yes],
319                        [libffi_cv_as_string_pseudo_op=no])
320     ])
321     if test "x$libffi_cv_as_string_pseudo_op" = xyes; then
322        AC_DEFINE(HAVE_AS_STRING_PSEUDO_OP, 1,
323                [Define if your assembler supports .string.])
324     fi
325 fi
326
327 if test x$TARGET = xX86_WIN64; then
328     LT_SYS_SYMBOL_USCORE
329     if test "x$sys_symbol_underscore" = xyes; then
330         AC_DEFINE(SYMBOL_UNDERSCORE, 1, [Define if symbols are underscored.])
331     fi
332 fi
333
334
335 FFI_EXEC_TRAMPOLINE_TABLE=0
336 case "$target" in
337      *arm*-apple-darwin*)
338        FFI_EXEC_TRAMPOLINE_TABLE=1
339        AC_DEFINE(FFI_EXEC_TRAMPOLINE_TABLE, 1,
340                  [Cannot use PROT_EXEC on this target, so, we revert to
341                    alternative means])
342      ;;
343      *-apple-darwin10* | *-*-freebsd* | *-*-openbsd* | *-pc-solaris*)
344        AC_DEFINE(FFI_MMAP_EXEC_WRIT, 1,
345                  [Cannot use malloc on this target, so, we revert to
346                    alternative means])
347      ;;
348 esac
349 AM_CONDITIONAL(FFI_EXEC_TRAMPOLINE_TABLE, test x$FFI_EXEC_TRAMPOLINE_TABLE = x1)
350 AC_SUBST(FFI_EXEC_TRAMPOLINE_TABLE)
351
352 if test x$TARGET = xX86_64; then
353     AC_CACHE_CHECK([assembler supports unwind section type],
354         libffi_cv_as_x86_64_unwind_section_type, [
355         libffi_cv_as_x86_64_unwind_section_type=yes
356         echo '.section .eh_frame,"a",@unwind' > conftest.s
357         if $CC $CFLAGS -c conftest.s 2>&1 | grep -i warning > /dev/null; then
358             libffi_cv_as_x86_64_unwind_section_type=no
359         fi
360         ])
361     if test "x$libffi_cv_as_x86_64_unwind_section_type" = xyes; then
362         AC_DEFINE(HAVE_AS_X86_64_UNWIND_SECTION_TYPE, 1,
363                   [Define if your assembler supports unwind section type.])
364     fi
365 fi
366
367 if test "x$GCC" = "xyes"; then
368   AC_CACHE_CHECK([whether .eh_frame section should be read-only],
369       libffi_cv_ro_eh_frame, [
370         libffi_cv_ro_eh_frame=no
371         echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
372         if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
373             if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
374                 libffi_cv_ro_eh_frame=yes
375             elif grep '.section.*eh_frame.*#alloc' conftest.c \
376                  | grep -v '#write' > /dev/null; then
377                 libffi_cv_ro_eh_frame=yes
378             fi
379         fi
380         rm -f conftest.*
381       ])
382   if test "x$libffi_cv_ro_eh_frame" = xyes; then
383       AC_DEFINE(HAVE_RO_EH_FRAME, 1,
384               [Define if .eh_frame sections should be read-only.])
385       AC_DEFINE(EH_FRAME_FLAGS, "a",
386               [Define to the flags needed for the .section .eh_frame directive.  ])
387   else
388       AC_DEFINE(EH_FRAME_FLAGS, "aw",
389               [Define to the flags needed for the .section .eh_frame directive.  ])
390   fi
391
392   AC_CACHE_CHECK([for __attribute__((visibility("hidden")))],
393       libffi_cv_hidden_visibility_attribute, [
394         echo 'int __attribute__ ((visibility ("hidden"))) foo (void) { return 1  ; }' > conftest.c
395         libffi_cv_hidden_visibility_attribute=no
396         if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
397             if grep '\.hidden.*foo' conftest.s >/dev/null; then
398                 libffi_cv_hidden_visibility_attribute=yes
399             fi
400         fi
401         rm -f conftest.*
402       ])
403   if test $libffi_cv_hidden_visibility_attribute = yes; then
404       AC_DEFINE(HAVE_HIDDEN_VISIBILITY_ATTRIBUTE, 1,
405               [Define if __attribute__((visibility("hidden"))) is supported.])
406   fi
407 fi
408
409 AH_BOTTOM([
410 #ifdef HAVE_HIDDEN_VISIBILITY_ATTRIBUTE
411 #ifdef LIBFFI_ASM
412 #define FFI_HIDDEN(name) .hidden name
413 #else
414 #define FFI_HIDDEN __attribute__ ((visibility ("hidden")))
415 #endif
416 #else
417 #ifdef LIBFFI_ASM
418 #define FFI_HIDDEN(name)
419 #else
420 #define FFI_HIDDEN
421 #endif
422 #endif
423 ])
424
425 AC_SUBST(TARGET)
426 AC_SUBST(TARGETDIR)
427
428 AC_SUBST(SHELL)
429
430 AC_ARG_ENABLE(debug,
431 [  --enable-debug          debugging mode],
432   if test "$enable_debug" = "yes"; then
433     AC_DEFINE(FFI_DEBUG, 1, [Define this if you want extra debugging.])
434   fi)
435 AM_CONDITIONAL(FFI_DEBUG, test "$enable_debug" = "yes")
436
437 AC_ARG_ENABLE(structs,
438 [  --disable-structs       omit code for struct support],
439   if test "$enable_structs" = "no"; then
440     AC_DEFINE(FFI_NO_STRUCTS, 1, [Define this is you do not want support for aggregate types.])
441   fi)
442
443 AC_ARG_ENABLE(raw-api,
444 [  --disable-raw-api       make the raw api unavailable],
445   if test "$enable_raw_api" = "no"; then
446     AC_DEFINE(FFI_NO_RAW_API, 1, [Define this is you do not want support for the raw API.])
447   fi)
448
449 AC_ARG_ENABLE(purify-safety,
450 [  --enable-purify-safety  purify-safe mode],
451   if test "$enable_purify_safety" = "yes"; then
452     AC_DEFINE(USING_PURIFY, 1, [Define this if you are using Purify and want to suppress spurious messages.])
453   fi)
454
455 # These variables are only ever used when we cross-build to X86_WIN32.
456 # And we only support this with GCC, so...
457 if test x"$GCC" != x"no"; then
458   if test -n "$with_cross_host" &&
459      test x"$with_cross_host" != x"no"; then
460     toolexecdir='$(exec_prefix)/$(target_alias)'
461     toolexeclibdir='$(toolexecdir)/lib'
462   else
463     toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
464     toolexeclibdir='$(libdir)'
465   fi
466   multi_os_directory=`$CC -print-multi-os-directory`
467   case $multi_os_directory in
468     .) ;; # Avoid trailing /.
469     *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
470   esac
471   AC_SUBST(toolexecdir)
472   AC_SUBST(toolexeclibdir)
473 fi
474
475 if test "${multilib}" = "yes"; then
476   multilib_arg="--enable-multilib"
477 else
478   multilib_arg=
479 fi
480
481 AC_CONFIG_COMMANDS(include, [test -d include || mkdir include])
482 AC_CONFIG_COMMANDS(src, [
483 test -d src || mkdir src
484 test -d src/$TARGETDIR || mkdir src/$TARGETDIR
485 ], [TARGETDIR="$TARGETDIR"])
486
487 AC_CONFIG_LINKS(include/ffitarget.h:src/$TARGETDIR/ffitarget.h)
488
489 AC_CONFIG_FILES(include/Makefile include/ffi.h Makefile testsuite/Makefile man/Makefile libffi.pc)
490
491 AC_OUTPUT