Add -no-undefined for both 32- and 64-bit x86
[libffi.git] / configure.ac
1 dnl Process this with autoconf to create configure
2
3 AC_PREREQ(2.63)
4
5 AC_INIT([libffi], [3.0.11-rc2], [http://github.com/atgreen/libffi/issues])
6 AC_CONFIG_HEADERS([fficonfig.h])
7
8 AC_CANONICAL_SYSTEM
9 target_alias=${target_alias-$host_alias}
10
11 . ${srcdir}/configure.host
12
13 AX_ENABLE_BUILDDIR
14
15 AM_INIT_AUTOMAKE
16
17 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
18 # We must force CC to /not/ be precious variables; otherwise
19 # the wrong, non-multilib-adjusted value will be used in multilibs.
20 # As a side effect, we have to subst CFLAGS ourselves.
21 # Also save and restore CFLAGS, since AC_PROG_CC will come up with
22 # defaults of its own if none are provided.
23
24 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
25 m4_define([_AC_ARG_VAR_PRECIOUS],[])
26 save_CFLAGS=$CFLAGS
27 AC_PROG_CC
28 CFLAGS=$save_CFLAGS
29 m4_undefine([_AC_ARG_VAR_PRECIOUS])
30 m4_rename([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
31
32 AC_SUBST(CFLAGS)
33
34 AM_PROG_AS
35 AM_PROG_CC_C_O
36 AC_PROG_LIBTOOL
37 AC_CONFIG_MACRO_DIR([m4])
38
39 AX_CC_MAXOPT
40 AX_CFLAGS_WARN_ALL
41 if test "x$GCC" = "xyes"; then
42   CFLAGS="$CFLAGS -fexceptions"
43 fi
44
45 AM_MAINTAINER_MODE
46
47 AC_CHECK_HEADERS(sys/mman.h)
48 AC_CHECK_FUNCS(mmap)
49 AC_FUNC_MMAP_BLACKLIST
50
51 dnl The -no-testsuite modules omit the test subdir.
52 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
53
54 TARGETDIR="unknown"
55 case "$host" in
56   alpha*-*-*)
57         TARGET=ALPHA; TARGETDIR=alpha;
58         # Support 128-bit long double, changeable via command-line switch.
59         HAVE_LONG_DOUBLE='defined(__LONG_DOUBLE_128__)'
60         ;;
61
62   arm*-*-*)
63         TARGET=ARM; TARGETDIR=arm
64         ;;
65
66   amd64-*-freebsd* | amd64-*-openbsd*)
67         TARGET=X86_64; TARGETDIR=x86
68         ;;
69
70   amd64-*-freebsd*)
71         TARGET=X86_64; TARGETDIR=x86
72         ;;
73
74   avr32*-*-*)
75         TARGET=AVR32; TARGETDIR=avr32
76         ;;
77
78   cris-*-*)
79         TARGET=LIBFFI_CRIS; TARGETDIR=cris
80         ;;
81
82   frv-*-*)
83         TARGET=FRV; TARGETDIR=frv
84         ;;
85
86   hppa*-*-linux* | parisc*-*-linux* | hppa*-*-openbsd*)
87         TARGET=PA_LINUX; TARGETDIR=pa
88         ;;
89   hppa*64-*-hpux*)
90         TARGET=PA64_HPUX; TARGETDIR=pa
91         ;;
92   hppa*-*-hpux*)
93         TARGET=PA_HPUX; TARGETDIR=pa
94         ;;
95
96   i?86-*-freebsd* | i?86-*-openbsd*)
97         TARGET=X86_FREEBSD; TARGETDIR=x86
98         ;;
99   i?86-win32* | i?86-*-cygwin* | i?86-*-mingw* | i?86-*-os2* | i?86-*-interix*)
100         TARGET=X86_WIN32; TARGETDIR=x86
101         ;;
102   i?86-*-darwin*)
103         TARGET=X86_DARWIN; TARGETDIR=x86
104         ;;
105   i?86-*-solaris2.1[[0-9]]*)
106         TARGET=X86_64; TARGETDIR=x86
107         ;;
108   i?86-*-*)
109         TARGET=X86_64; TARGETDIR=x86
110         ;;
111
112   ia64*-*-*)
113         TARGET=IA64; TARGETDIR=ia64
114         ;;
115
116   m32r*-*-*)
117         TARGET=M32R; TARGETDIR=m32r
118         ;;
119
120   m68k-*-*)
121         TARGET=M68K; TARGETDIR=m68k
122         ;;
123
124   mips-sgi-irix5.* | mips-sgi-irix6.* | mips*-*-rtems*)
125         TARGET=MIPS; TARGETDIR=mips
126         ;;
127   mips*-*-linux* | mips*-*-openbsd*)
128         # Support 128-bit long double for NewABI.
129         HAVE_LONG_DOUBLE='defined(__mips64)'
130         TARGET=MIPS; TARGETDIR=mips
131         ;;
132
133   moxie-*-*)
134         TARGET=MOXIE; TARGETDIR=moxie
135         ;;
136
137   powerpc*-*-linux* | powerpc-*-sysv*)
138         TARGET=POWERPC; TARGETDIR=powerpc
139         ;;
140   powerpc-*-amigaos*)
141         TARGET=POWERPC; TARGETDIR=powerpc
142         ;;
143   powerpc-*-beos*)
144         TARGET=POWERPC; TARGETDIR=powerpc
145         ;;
146   powerpc-*-darwin* | powerpc64-*-darwin*)
147         TARGET=POWERPC_DARWIN; TARGETDIR=powerpc
148         ;;
149   powerpc-*-aix* | rs6000-*-aix*)
150         TARGET=POWERPC_AIX; TARGETDIR=powerpc
151         ;;
152   powerpc-*-freebsd* | powerpc-*-openbsd*)
153         TARGET=POWERPC_FREEBSD; TARGETDIR=powerpc
154         ;;
155   powerpc64-*-freebsd*)
156         TARGET=POWERPC; TARGETDIR=powerpc
157         ;;
158   powerpc*-*-rtems*)
159         TARGET=POWERPC; TARGETDIR=powerpc
160         ;;
161
162   s390-*-* | s390x-*-*)
163         TARGET=S390; TARGETDIR=s390
164         ;;
165
166   sh-*-* | sh[[34]]*-*-*)
167         TARGET=SH; TARGETDIR=sh
168         ;;
169   sh64-*-* | sh5*-*-*)
170         TARGET=SH64; TARGETDIR=sh64
171         ;;
172
173   sparc*-*-*)
174         TARGET=SPARC; TARGETDIR=sparc
175         ;;
176
177   x86_64-*-darwin*)
178         TARGET=X86_DARWIN; TARGETDIR=x86
179         ;;
180
181   x86_64-*-cygwin* | x86_64-*-mingw*)
182         TARGET=X86_WIN64; TARGETDIR=x86
183         ;;
184
185   x86_64-*-*)
186         TARGET=X86_64; TARGETDIR=x86
187         ;;
188 esac
189
190 case "$host" in
191      *-win32* | *-*-cygwin* | *-*-mingw* | *-*-os2* | *-*-interix*)
192         # All mingw/cygwin/win32 builds require -no-undefined for sharedlib.
193         # We must also check with_cross_host to decide if this is a native
194         # or cross-build and select where to install dlls appropriately.
195         if test -n "$with_cross_host" &&
196            test x"$with_cross_host" != x"no"; then
197           AM_LTLDFLAGS='-no-undefined -bindir "$(toolexeclibdir)"';
198         else
199           AM_LTLDFLAGS='-no-undefined -bindir "$(bindir)"';
200         fi
201         ;;
202 esac
203
204 AC_SUBST(AM_RUNTESTFLAGS)
205 AC_SUBST(AM_LTLDFLAGS)
206
207 if test $TARGETDIR = unknown; then
208   AC_MSG_ERROR(["libffi has not been ported to $host."])
209 fi
210
211 AM_CONDITIONAL(MIPS, test x$TARGET = xMIPS)
212 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
213 AM_CONDITIONAL(X86, test x$TARGET = xX86)
214 AM_CONDITIONAL(X86_FREEBSD, test x$TARGET = xX86_FREEBSD)
215 AM_CONDITIONAL(X86_WIN32, test x$TARGET = xX86_WIN32)
216 AM_CONDITIONAL(X86_WIN64, test x$TARGET = xX86_WIN64)
217 AM_CONDITIONAL(X86_DARWIN, test x$TARGET = xX86_DARWIN)
218 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
219 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
220 AM_CONDITIONAL(M32R, test x$TARGET = xM32R)
221 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
222 AM_CONDITIONAL(MOXIE, test x$TARGET = xMOXIE)
223 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
224 AM_CONDITIONAL(POWERPC_AIX, test x$TARGET = xPOWERPC_AIX)
225 AM_CONDITIONAL(POWERPC_DARWIN, test x$TARGET = xPOWERPC_DARWIN)
226 AM_CONDITIONAL(POWERPC_FREEBSD, test x$TARGET = xPOWERPC_FREEBSD)
227 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
228 AM_CONDITIONAL(AVR32, test x$TARGET = xAVR32)
229 AM_CONDITIONAL(LIBFFI_CRIS, test x$TARGET = xLIBFFI_CRIS)
230 AM_CONDITIONAL(FRV, test x$TARGET = xFRV)
231 AM_CONDITIONAL(S390, test x$TARGET = xS390)
232 AM_CONDITIONAL(X86_64, test x$TARGET = xX86_64)
233 AM_CONDITIONAL(SH, test x$TARGET = xSH)
234 AM_CONDITIONAL(SH64, test x$TARGET = xSH64)
235 AM_CONDITIONAL(PA_LINUX, test x$TARGET = xPA_LINUX)
236 AM_CONDITIONAL(PA_HPUX, test x$TARGET = xPA_HPUX)
237 AM_CONDITIONAL(PA64_HPUX, test x$TARGET = xPA64_HPUX)
238
239 AC_HEADER_STDC
240 AC_CHECK_FUNCS(memcpy)
241 AC_FUNC_ALLOCA
242
243 AC_CHECK_SIZEOF(double)
244 AC_CHECK_SIZEOF(long double)
245
246 # Also AC_SUBST this variable for ffi.h.
247 if test -z "$HAVE_LONG_DOUBLE"; then
248   HAVE_LONG_DOUBLE=0
249   if test $ac_cv_sizeof_double != $ac_cv_sizeof_long_double; then
250     if test $ac_cv_sizeof_long_double != 0; then
251       HAVE_LONG_DOUBLE=1
252       AC_DEFINE(HAVE_LONG_DOUBLE, 1, [Define if you have the long double type and it is bigger than a double])
253     fi
254   fi
255 fi
256 AC_SUBST(HAVE_LONG_DOUBLE)
257
258 AC_C_BIGENDIAN
259
260 GCC_AS_CFI_PSEUDO_OP
261
262 if test x$TARGET = xSPARC; then
263     AC_CACHE_CHECK([assembler and linker support unaligned pc related relocs],
264         libffi_cv_as_sparc_ua_pcrel, [
265         save_CFLAGS="$CFLAGS"
266         save_LDFLAGS="$LDFLAGS"
267         CFLAGS="$CFLAGS -fpic"
268         LDFLAGS="$LDFLAGS -shared"
269         AC_TRY_LINK([asm (".text; foo: nop; .data; .align 4; .byte 0; .uaword %r_disp32(foo); .text");],,
270                     [libffi_cv_as_sparc_ua_pcrel=yes],
271                     [libffi_cv_as_sparc_ua_pcrel=no])
272         CFLAGS="$save_CFLAGS"
273         LDFLAGS="$save_LDFLAGS"])
274     if test "x$libffi_cv_as_sparc_ua_pcrel" = xyes; then
275         AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
276                   [Define if your assembler and linker support unaligned PC relative relocs.])
277     fi
278
279     AC_CACHE_CHECK([assembler .register pseudo-op support],
280        libffi_cv_as_register_pseudo_op, [
281        libffi_cv_as_register_pseudo_op=unknown
282        # Check if we have .register
283        AC_TRY_COMPILE([asm (".register %g2, #scratch");],,
284                        [libffi_cv_as_register_pseudo_op=yes],
285                        [libffi_cv_as_register_pseudo_op=no])
286     ])
287     if test "x$libffi_cv_as_register_pseudo_op" = xyes; then
288        AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
289                [Define if your assembler supports .register.])
290     fi
291 fi
292
293 if test x$TARGET = xX86 || test x$TARGET = xX86_WIN32 || test x$TARGET = xX86_64; then
294     AC_CACHE_CHECK([assembler supports pc related relocs],
295         libffi_cv_as_x86_pcrel, [
296         libffi_cv_as_x86_pcrel=no
297         echo '.text; foo: nop; .data; .long foo-.; .text' > conftest.s
298         if $CC $CFLAGS -c conftest.s > /dev/null; then
299            libffi_cv_as_x86_pcrel=yes
300         fi
301         ])
302     if test "x$libffi_cv_as_x86_pcrel" = xyes; then
303         AC_DEFINE(HAVE_AS_X86_PCREL, 1,
304                   [Define if your assembler supports PC relative relocs.])
305     fi
306
307     AC_CACHE_CHECK([assembler .ascii pseudo-op support],
308        libffi_cv_as_ascii_pseudo_op, [
309        libffi_cv_as_ascii_pseudo_op=unknown
310        # Check if we have .ascii
311        AC_TRY_COMPILE([asm (".ascii \\"string\\"");],,
312                        [libffi_cv_as_ascii_pseudo_op=yes],
313                        [libffi_cv_as_ascii_pseudo_op=no])
314     ])
315     if test "x$libffi_cv_as_ascii_pseudo_op" = xyes; then
316        AC_DEFINE(HAVE_AS_ASCII_PSEUDO_OP, 1,
317                [Define if your assembler supports .ascii.])
318     fi
319
320     AC_CACHE_CHECK([assembler .string pseudo-op support],
321        libffi_cv_as_string_pseudo_op, [
322        libffi_cv_as_string_pseudo_op=unknown
323        # Check if we have .string
324        AC_TRY_COMPILE([asm (".string \\"string\\"");],,
325                        [libffi_cv_as_string_pseudo_op=yes],
326                        [libffi_cv_as_string_pseudo_op=no])
327     ])
328     if test "x$libffi_cv_as_string_pseudo_op" = xyes; then
329        AC_DEFINE(HAVE_AS_STRING_PSEUDO_OP, 1,
330                [Define if your assembler supports .string.])
331     fi
332 fi
333
334 if test x$TARGET = xX86_WIN64; then
335     LT_SYS_SYMBOL_USCORE
336     if test "x$sys_symbol_underscore" = xyes; then
337         AC_DEFINE(SYMBOL_UNDERSCORE, 1, [Define if symbols are underscored.])
338     fi
339 fi
340
341
342 FFI_EXEC_TRAMPOLINE_TABLE=0
343 case "$target" in
344      *arm*-apple-darwin*)
345        FFI_EXEC_TRAMPOLINE_TABLE=1
346        AC_DEFINE(FFI_EXEC_TRAMPOLINE_TABLE, 1,
347                  [Cannot use PROT_EXEC on this target, so, we revert to
348                    alternative means])
349      ;;
350      *-apple-darwin1[[10]]* | *-*-freebsd* | *-*-kfreebsd* | *-*-openbsd* | *-pc-solaris*)
351        AC_DEFINE(FFI_MMAP_EXEC_WRIT, 1,
352                  [Cannot use malloc on this target, so, we revert to
353                    alternative means])
354      ;;
355 esac
356 AM_CONDITIONAL(FFI_EXEC_TRAMPOLINE_TABLE, test x$FFI_EXEC_TRAMPOLINE_TABLE = x1)
357 AC_SUBST(FFI_EXEC_TRAMPOLINE_TABLE)
358
359 if test x$TARGET = xX86_64; then
360     AC_CACHE_CHECK([assembler supports unwind section type],
361         libffi_cv_as_x86_64_unwind_section_type, [
362         libffi_cv_as_x86_64_unwind_section_type=yes
363         echo '.section .eh_frame,"a",@unwind' > conftest.s
364         if $CC $CFLAGS -c conftest.s 2>&1 | grep -i warning > /dev/null; then
365             libffi_cv_as_x86_64_unwind_section_type=no
366         fi
367         ])
368     if test "x$libffi_cv_as_x86_64_unwind_section_type" = xyes; then
369         AC_DEFINE(HAVE_AS_X86_64_UNWIND_SECTION_TYPE, 1,
370                   [Define if your assembler supports unwind section type.])
371     fi
372 fi
373
374 if test "x$GCC" = "xyes"; then
375   AC_CACHE_CHECK([whether .eh_frame section should be read-only],
376       libffi_cv_ro_eh_frame, [
377         libffi_cv_ro_eh_frame=no
378         echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
379         if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
380             if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
381                 libffi_cv_ro_eh_frame=yes
382             elif grep '.section.*eh_frame.*#alloc' conftest.c \
383                  | grep -v '#write' > /dev/null; then
384                 libffi_cv_ro_eh_frame=yes
385             fi
386         fi
387         rm -f conftest.*
388       ])
389   if test "x$libffi_cv_ro_eh_frame" = xyes; then
390       AC_DEFINE(HAVE_RO_EH_FRAME, 1,
391               [Define if .eh_frame sections should be read-only.])
392       AC_DEFINE(EH_FRAME_FLAGS, "a",
393               [Define to the flags needed for the .section .eh_frame directive.  ])
394   else
395       AC_DEFINE(EH_FRAME_FLAGS, "aw",
396               [Define to the flags needed for the .section .eh_frame directive.  ])
397   fi
398
399   AC_CACHE_CHECK([for __attribute__((visibility("hidden")))],
400       libffi_cv_hidden_visibility_attribute, [
401         echo 'int __attribute__ ((visibility ("hidden"))) foo (void) { return 1  ; }' > conftest.c
402         libffi_cv_hidden_visibility_attribute=no
403         if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
404             if grep '\.hidden.*foo' conftest.s >/dev/null; then
405                 libffi_cv_hidden_visibility_attribute=yes
406             fi
407         fi
408         rm -f conftest.*
409       ])
410   if test $libffi_cv_hidden_visibility_attribute = yes; then
411       AC_DEFINE(HAVE_HIDDEN_VISIBILITY_ATTRIBUTE, 1,
412               [Define if __attribute__((visibility("hidden"))) is supported.])
413   fi
414 fi
415
416 AH_BOTTOM([
417 #ifdef HAVE_HIDDEN_VISIBILITY_ATTRIBUTE
418 #ifdef LIBFFI_ASM
419 #define FFI_HIDDEN(name) .hidden name
420 #else
421 #define FFI_HIDDEN __attribute__ ((visibility ("hidden")))
422 #endif
423 #else
424 #ifdef LIBFFI_ASM
425 #define FFI_HIDDEN(name)
426 #else
427 #define FFI_HIDDEN
428 #endif
429 #endif
430 ])
431
432 AC_SUBST(TARGET)
433 AC_SUBST(TARGETDIR)
434
435 AC_SUBST(SHELL)
436
437 AC_ARG_ENABLE(debug,
438 [  --enable-debug          debugging mode],
439   if test "$enable_debug" = "yes"; then
440     AC_DEFINE(FFI_DEBUG, 1, [Define this if you want extra debugging.])
441   fi)
442 AM_CONDITIONAL(FFI_DEBUG, test "$enable_debug" = "yes")
443
444 AC_ARG_ENABLE(structs,
445 [  --disable-structs       omit code for struct support],
446   if test "$enable_structs" = "no"; then
447     AC_DEFINE(FFI_NO_STRUCTS, 1, [Define this is you do not want support for aggregate types.])
448   fi)
449
450 AC_ARG_ENABLE(raw-api,
451 [  --disable-raw-api       make the raw api unavailable],
452   if test "$enable_raw_api" = "no"; then
453     AC_DEFINE(FFI_NO_RAW_API, 1, [Define this is you do not want support for the raw API.])
454   fi)
455
456 AC_ARG_ENABLE(purify-safety,
457 [  --enable-purify-safety  purify-safe mode],
458   if test "$enable_purify_safety" = "yes"; then
459     AC_DEFINE(USING_PURIFY, 1, [Define this if you are using Purify and want to suppress spurious messages.])
460   fi)
461
462 # These variables are only ever used when we cross-build to X86_WIN32.
463 # And we only support this with GCC, so...
464 if test x"$GCC" != x"no"; then
465   if test -n "$with_cross_host" &&
466      test x"$with_cross_host" != x"no"; then
467     toolexecdir='$(exec_prefix)/$(target_alias)'
468     toolexeclibdir='$(toolexecdir)/lib'
469   else
470     toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
471     toolexeclibdir='$(libdir)'
472   fi
473   multi_os_directory=`$CC -print-multi-os-directory`
474   case $multi_os_directory in
475     .) ;; # Avoid trailing /.
476     *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
477   esac
478   AC_SUBST(toolexecdir)
479   AC_SUBST(toolexeclibdir)
480 fi
481
482 if test "${multilib}" = "yes"; then
483   multilib_arg="--enable-multilib"
484 else
485   multilib_arg=
486 fi
487
488 AC_CONFIG_COMMANDS(include, [test -d include || mkdir include])
489 AC_CONFIG_COMMANDS(src, [
490 test -d src || mkdir src
491 test -d src/$TARGETDIR || mkdir src/$TARGETDIR
492 ], [TARGETDIR="$TARGETDIR"])
493
494 AC_CONFIG_LINKS(include/ffitarget.h:src/$TARGETDIR/ffitarget.h)
495
496 AC_CONFIG_FILES(include/Makefile include/ffi.h Makefile testsuite/Makefile man/Makefile libffi.pc)
497
498 AC_OUTPUT