Fix typo
[libffi.git] / testsuite / lib / libffi.exp
1 #   Copyright (C) 2003, 2005, 2008, 2009, 2010, 2011, 2014 Free Software Foundation, Inc.
2
3 # This program is free software; you can redistribute it and/or modify
4 # it under the terms of the GNU General Public License as published by
5 # the Free Software Foundation; either version 3 of the License, or
6 # (at your option) any later version.
7 #
8 # This program is distributed in the hope that it will be useful,
9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
11 # GNU General Public License for more details.
12 #
13 # You should have received a copy of the GNU General Public License
14 # along with this program; see the file COPYING3.  If not see
15 # <http://www.gnu.org/licenses/>.
16
17 proc load_gcc_lib { filename } {
18     global srcdir
19     load_file $srcdir/lib/$filename
20 }
21
22 load_lib dg.exp
23 load_lib libgloss.exp
24 load_gcc_lib target-libpath.exp
25 load_gcc_lib wrapper.exp
26
27
28 # Define libffi callbacks for dg.exp.
29
30 proc libffi-dg-test-1 { target_compile prog do_what extra_tool_flags } {
31
32     # To get all \n in dg-output test strings to match printf output
33     # in a system that outputs it as \015\012 (i.e. not just \012), we
34     # need to change all \n into \r?\n.  As there is no dejagnu flag
35     # or hook to do that, we simply change the text being tested.
36     # Unfortunately, we have to know that the variable is called
37     # dg-output-text and lives in the caller of libffi-dg-test, which
38     # is two calls up.  Overriding proc dg-output would be longer and
39     # would necessarily have the same assumption.
40     upvar 2 dg-output-text output_match
41
42     if { [llength $output_match] > 1 } {
43         regsub -all "\n" [lindex $output_match 1] "\r?\n" x
44         set output_match [lreplace $output_match 1 1 $x]
45     }
46
47     # Set up the compiler flags, based on what we're going to do.
48
49     set options [list]
50     switch $do_what {
51         "compile" {
52             set compile_type "assembly"
53             set output_file "[file rootname [file tail $prog]].s"
54         }
55         "link" {
56             set compile_type "executable"
57             set output_file "[file rootname [file tail $prog]].exe"
58             # The following line is needed for targets like the i960 where
59             # the default output file is b.out.  Sigh.
60         }
61         "run" {
62             set compile_type "executable"
63             # FIXME: "./" is to cope with "." not being in $PATH.
64             # Should this be handled elsewhere?
65             # YES.
66             set output_file "./[file rootname [file tail $prog]].exe"
67             # This is the only place where we care if an executable was
68             # created or not.  If it was, dg.exp will try to run it.
69             remote_file build delete $output_file;
70         }
71         default {
72             perror "$do_what: not a valid dg-do keyword"
73             return ""
74         }
75     }
76
77     if { $extra_tool_flags != "" } {
78         lappend options "additional_flags=$extra_tool_flags"
79     }
80
81     set comp_output [libffi_target_compile "$prog" "$output_file" "$compile_type" $options];
82
83
84     return [list $comp_output $output_file]
85 }
86
87
88 proc libffi-dg-test { prog do_what extra_tool_flags } {
89     return [libffi-dg-test-1 target_compile $prog $do_what $extra_tool_flags]
90 }
91
92 proc libffi-init { args } {
93     global gluefile wrap_flags;
94     global srcdir
95     global blddirffi
96     global objdir
97     global TOOL_OPTIONS
98     global tool
99     global libffi_include
100     global libffi_link_flags
101     global tool_root_dir
102     global ld_library_path
103     global compiler_vendor
104
105     if ![info exists blddirffi] {
106         set blddirffi [pwd]/..
107     }
108
109     verbose "libffi $blddirffi"
110
111     # Which compiler are we building with?
112     set tmp [grep "$blddirffi/config.log" "^ax_cv_c_compiler_vendor.*$"]
113     regexp -- {^[^=]*=(.*)$} $tmp nil compiler_vendor
114
115     if { [string match $compiler_vendor "gnu"] } {
116         set gccdir [lookfor_file $tool_root_dir gcc/libgcc.a]
117         if {$gccdir != ""} {
118             set gccdir [file dirname $gccdir]
119         }
120         verbose "gccdir $gccdir"
121
122         set ld_library_path "."
123         append ld_library_path ":${gccdir}"
124
125         set compiler "${gccdir}/xgcc"
126         if { [is_remote host] == 0 && [which $compiler] != 0 } {
127             foreach i "[exec $compiler --print-multi-lib]" {
128                 set mldir ""
129                 regexp -- "\[a-z0-9=_/\.-\]*;" $i mldir
130                 set mldir [string trimright $mldir "\;@"]
131                 if { "$mldir" == "." } {
132                     continue
133                 }
134                 if { [llength [glob -nocomplain ${gccdir}/${mldir}/libgcc_s*.so.*]] >= 1 } {
135                     append ld_library_path ":${gccdir}/${mldir}"
136                 }
137             }
138         }
139     }
140
141     # add the library path for libffi.
142     append ld_library_path ":${blddirffi}/.libs"
143
144     verbose "ld_library_path: $ld_library_path"
145
146     # Point to the Libffi headers in libffi.
147     set libffi_include "${blddirffi}/include"
148     verbose "libffi_include $libffi_include"
149
150     set libffi_dir  "${blddirffi}/.libs"
151     verbose "libffi_dir $libffi_dir"
152     if { $libffi_dir != "" } {
153         set libffi_dir [file dirname ${libffi_dir}]
154         set libffi_link_flags "-L${libffi_dir}/.libs"
155     }
156
157     set_ld_library_path_env_vars
158     libffi_maybe_build_wrapper "${objdir}/testglue.o"
159 }
160
161 proc libffi_exit { } {
162     global gluefile;
163
164     if [info exists gluefile] {
165         file_on_build delete $gluefile;
166         unset gluefile;
167     }
168 }
169
170 proc libffi_target_compile { source dest type options } {
171     global gluefile wrap_flags;
172     global srcdir
173     global blddirffi
174     global TOOL_OPTIONS
175     global libffi_link_flags
176     global libffi_include
177     global target_triplet
178     global compiler_vendor
179
180     if { [target_info needs_status_wrapper]!="" && [info exists gluefile] } {
181         lappend options "libs=${gluefile}"
182         lappend options "ldflags=$wrap_flags"
183     }
184
185     # TOOL_OPTIONS must come first, so that it doesn't override testcase
186     # specific options.
187     if [info exists TOOL_OPTIONS] {
188         lappend  options "additional_flags=$TOOL_OPTIONS"
189     }
190
191     # search for ffi_mips.h in srcdir, too
192     lappend options "additional_flags=-I${libffi_include} -I${srcdir}/../include  -I${libffi_include}/.."
193     lappend options "additional_flags=${libffi_link_flags}"
194
195     # Darwin needs a stack execution allowed flag.
196
197     if { [istarget "*-*-darwin9*"] || [istarget "*-*-darwin1*"]
198          || [istarget "*-*-darwin2*"] } {
199         lappend options "additional_flags=-Wl,-allow_stack_execute"
200     }
201
202     # If you're building the compiler with --prefix set to a place
203     # where it's not yet installed, then the linker won't be able to
204     # find the libgcc used by libffi.dylib.  We could pass the
205     # -dylib_file option, but that's complicated, and it's much easier
206     # to just make the linker find libgcc using -L options.
207     if { [string match "*-*-darwin*" $target_triplet] } {
208         lappend options "libs= -shared-libgcc"
209     }
210
211     if { [string match "*-*-openbsd*" $target_triplet] } {
212         lappend options "libs= -lpthread"
213     }
214
215     lappend options "libs= -lffi"
216
217     if { [string match "aarch64*-*-linux*" $target_triplet] } {
218         lappend options "libs= -lpthread"
219     }
220
221     # this may be required for g++, but just confused clang.
222     if { [string match "*.cc" $source] } {
223         if { [string match $compiler_vendor "gnu"] } {
224             lappend options "c++"
225         }
226     }
227
228     if { [string match "arc*-*-linux*" $target_triplet] } {
229         lappend options "libs= -lpthread"
230     }
231
232     verbose "options: $options"
233     return [target_compile $source $dest $type $options]
234 }
235
236 # TEST should be a preprocessor condition.  Returns true if it holds.
237 proc libffi_feature_test { test } {
238     set src "ffitest[pid].c"
239
240     set f [open $src "w"]
241     puts $f "#include <ffi.h>"
242     puts $f $test
243     puts $f "/* OK */"
244     puts $f "#else"
245     puts $f "# error Failed $test"
246     puts $f "#endif"
247     close $f
248
249     set lines [libffi_target_compile $src /dev/null assembly ""]
250     file delete $src
251
252     return [string match "" $lines]
253 }
254
255 # Utility routines.
256
257 #
258 # search_for -- looks for a string match in a file
259 #
260 proc search_for { file pattern } {
261     set fd [open $file r]
262     while { [gets $fd cur_line]>=0 } {
263         if [string match "*$pattern*" $cur_line] then {
264             close $fd
265             return 1
266         }
267     }
268     close $fd
269     return 0
270 }
271
272 # Modified dg-runtest that can cycle through a list of optimization options
273 # as c-torture does.
274 proc libffi-dg-runtest { testcases default-extra-flags } {
275     global runtests
276
277     foreach test $testcases {
278         # If we're only testing specific files and this isn't one of
279         # them, skip it.
280         if ![runtest_file_p $runtests $test] {
281             continue
282         }
283
284         # Look for a loop within the source code - if we don't find one,
285         # don't pass -funroll[-all]-loops.
286         global torture_with_loops torture_without_loops
287         if [expr [search_for $test "for*("]+[search_for $test "while*("]] {
288             set option_list $torture_with_loops
289         } else {
290             set option_list $torture_without_loops
291         }
292
293         set nshort [file tail [file dirname $test]]/[file tail $test]
294
295         foreach flags $option_list {
296             verbose "Testing $nshort, $flags" 1
297             dg-test $test $flags ${default-extra-flags}
298         }
299     }
300 }
301
302 proc run-many-tests { testcases extra_flags } {
303     global compiler_vendor
304     switch $compiler_vendor {
305       "clang" {
306         set common "-W -Wall"
307         set optimizations { "-O0" "-O1" "-O2" "-O3" "-Os" }
308       }
309       "gnu" {
310         set common "-W -Wall -Wno-psabi"
311         set optimizations { "-O0" "-O2" "-O3" "-Os" "-O2 -fomit-frame-pointer" }
312       }
313       default {
314         # Assume we are using the vendor compiler.
315         set common ""
316         set optimizations { "" }
317       }
318     }
319
320     set targetabis { "" }
321     if [string match $compiler_vendor "gnu"] {
322         if [istarget "i?86-*-*"] {
323             set targetabis {
324                 ""
325                 "-DABI_NUM=FFI_STDCALL -DABI_ATTR=__STDCALL__"
326                 "-DABI_NUM=FFI_THISCALL -DABI_ATTR=__THISCALL__"
327                 "-DABI_NUM=FFI_FASTCALL -DABI_ATTR=__FASTCALL__"
328             }
329         } elseif [istarget "x86_64-*-*"] {
330             set targetabis {
331                 ""
332                 "-DABI_NUM=FFI_WIN64 -DABI_ATTR=__MSABI__"
333             }
334         }
335     }
336
337     set common [ concat $common $extra_flags ]
338     foreach test $testcases {
339         set testname [file tail $test]
340         if [search_for $test "ABI_NUM"] {
341             set abis $targetabis
342         } else {
343             set abis { "" }
344         }
345         foreach opt $optimizations {
346             foreach abi $abis {
347                 set options [concat $common $opt $abi]
348                 verbose "Testing $testname, $options" 1
349                 dg-test $test $options ""
350             }
351         }
352     }
353 }
354
355 # Like check_conditional_xfail, but callable from a dg test.
356
357 proc dg-xfail-if { args } {
358     set args [lreplace $args 0 0]
359     set selector "target [join [lindex $args 1]]"
360     if { [dg-process-target $selector] == "S" } {
361         global compiler_conditional_xfail_data
362         set compiler_conditional_xfail_data $args
363     }
364 }
365
366 proc check-flags { args } {
367
368     # The args are within another list; pull them out.
369     set args [lindex $args 0]
370
371     # The next two arguments are optional.  If they were not specified,
372     # use the defaults.
373     if { [llength $args] == 2 } {
374         lappend $args [list "*"]
375     }
376     if { [llength $args] == 3 } {
377         lappend $args [list ""]
378     }
379
380     # If the option strings are the defaults, or the same as the
381     # defaults, there is no need to call check_conditional_xfail to
382     # compare them to the actual options.
383     if { [string compare [lindex $args 2] "*"] == 0
384          && [string compare [lindex $args 3] "" ] == 0 } {
385         set result 1    
386     } else {
387         # The target list might be an effective-target keyword, so replace
388         # the original list with "*-*-*", since we already know it matches.
389         set result [check_conditional_xfail [lreplace $args 1 1 "*-*-*"]]
390     }
391
392     return $result
393 }
394
395 proc dg-skip-if { args } {
396     # Verify the number of arguments.  The last two are optional.
397     set args [lreplace $args 0 0]
398     if { [llength $args] < 2 || [llength $args] > 4 } {
399         error "dg-skip-if 2: need 2, 3, or 4 arguments"
400     }
401
402     # Don't bother if we're already skipping the test.
403     upvar dg-do-what dg-do-what
404     if { [lindex ${dg-do-what} 1] == "N" } {
405       return
406     }
407
408     set selector [list target [lindex $args 1]]
409     if { [dg-process-target $selector] == "S" } {
410         if [check-flags $args] {
411             upvar dg-do-what dg-do-what
412             set dg-do-what [list [lindex ${dg-do-what} 0] "N" "P"]
413         }
414     }
415 }
416
417 # We need to make sure that additional_files and additional_sources
418 # are both cleared out after every test.  It is not enough to clear
419 # them out *before* the next test run because gcc-target-compile gets
420 # run directly from some .exp files (outside of any test).  (Those
421 # uses should eventually be eliminated.)
422
423 # Because the DG framework doesn't provide a hook that is run at the
424 # end of a test, we must replace dg-test with a wrapper.
425
426 if { [info procs saved-dg-test] == [list] } {
427     rename dg-test saved-dg-test
428
429     proc dg-test { args } {
430         global additional_files
431         global additional_sources
432         global errorInfo
433
434         if { [ catch { eval saved-dg-test $args } errmsg ] } {
435             set saved_info $errorInfo
436             set additional_files ""
437             set additional_sources ""
438             error $errmsg $saved_info
439         }
440         set additional_files ""
441         set additional_sources ""
442     }
443 }
444
445 # Local Variables:
446 # tcl-indent-level:4
447 # End: