Don't use warning checking macro with sun compiler
[libffi.git] / configure.ac
1 dnl Process this with autoconf to create configure
2
3 AC_PREREQ(2.68)
4
5 AC_INIT([libffi], [3.0.12-rc0], [http://gcc.gnu.org/bugs.html])
6 AC_CONFIG_HEADERS([fficonfig.h])
7
8 AC_CANONICAL_SYSTEM
9 target_alias=${target_alias-$host_alias}
10
11 . ${srcdir}/configure.host
12
13 AX_ENABLE_BUILDDIR
14
15 AM_INIT_AUTOMAKE
16
17 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
18 # We must force CC to /not/ be precious variables; otherwise
19 # the wrong, non-multilib-adjusted value will be used in multilibs.
20 # As a side effect, we have to subst CFLAGS ourselves.
21 # Also save and restore CFLAGS, since AC_PROG_CC will come up with
22 # defaults of its own if none are provided.
23
24 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
25 m4_define([_AC_ARG_VAR_PRECIOUS],[])
26 save_CFLAGS=$CFLAGS
27 AC_PROG_CC
28 CFLAGS=$save_CFLAGS
29 m4_undefine([_AC_ARG_VAR_PRECIOUS])
30 m4_rename_force([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
31
32 AC_SUBST(CFLAGS)
33
34 AM_PROG_AS
35 AM_PROG_CC_C_O
36 AC_PROG_LIBTOOL
37 AC_CONFIG_MACRO_DIR([m4])
38
39 AX_COMPILER_VENDOR
40 AX_CC_MAXOPT
41 # The AX_CFLAGS_WARN_ALL macro doesn't currently work for sunpro
42 # compiler.
43 if test "$ax_cv_c_compiler_vendor" != "sun"; then
44   AX_CFLAGS_WARN_ALL
45 fi
46
47 if test "x$GCC" = "xyes"; then
48   CFLAGS="$CFLAGS -fexceptions"
49   touch local.exp
50 else
51   cat > local.exp <<EOF
52 set CC_FOR_TARGET "$CC"
53 EOF
54 fi
55
56 AM_MAINTAINER_MODE
57
58 AC_CHECK_HEADERS(sys/mman.h)
59 AC_CHECK_FUNCS(mmap)
60 AC_FUNC_MMAP_BLACKLIST
61
62 dnl The -no-testsuite modules omit the test subdir.
63 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
64
65 TARGETDIR="unknown"
66 case "$host" in
67   aarch64*-*-*)
68         TARGET=AARCH64; TARGETDIR=aarch64
69         ;;
70
71   alpha*-*-*)
72         TARGET=ALPHA; TARGETDIR=alpha;
73         # Support 128-bit long double, changeable via command-line switch.
74         HAVE_LONG_DOUBLE='defined(__LONG_DOUBLE_128__)'
75         ;;
76
77   arm*-*-*)
78         TARGET=ARM; TARGETDIR=arm
79         ;;
80
81   amd64-*-freebsd* | amd64-*-openbsd*)
82         TARGET=X86_64; TARGETDIR=x86
83         ;;
84
85   amd64-*-freebsd*)
86         TARGET=X86_64; TARGETDIR=x86
87         ;;
88
89   amd64-*-freebsd*)
90         TARGET=X86_64; TARGETDIR=x86
91         ;;
92
93   avr32*-*-*)
94         TARGET=AVR32; TARGETDIR=avr32
95         ;;
96
97   bfin*)
98         TARGET=BFIN; TARGETDIR=bfin
99         ;;
100
101   cris-*-*)
102         TARGET=LIBFFI_CRIS; TARGETDIR=cris
103         ;;
104
105   frv-*-*)
106         TARGET=FRV; TARGETDIR=frv
107         ;;
108
109   hppa*-*-linux* | parisc*-*-linux* | hppa*-*-openbsd*)
110         TARGET=PA_LINUX; TARGETDIR=pa
111         ;;
112   hppa*64-*-hpux*)
113         TARGET=PA64_HPUX; TARGETDIR=pa
114         ;;
115   hppa*-*-hpux*)
116         TARGET=PA_HPUX; TARGETDIR=pa
117         ;;
118
119   i?86-*-freebsd* | i?86-*-openbsd*)
120         TARGET=X86_FREEBSD; TARGETDIR=x86
121         ;;
122   i?86-win32* | i?86-*-cygwin* | i?86-*-mingw* | i?86-*-os2* | i?86-*-interix*)
123         TARGET=X86_WIN32; TARGETDIR=x86
124         # All mingw/cygwin/win32 builds require -no-undefined for sharedlib.
125         # We must also check with_cross_host to decide if this is a native
126         # or cross-build and select where to install dlls appropriately.
127         if test -n "$with_cross_host" &&
128            test x"$with_cross_host" != x"no"; then
129           AM_LTLDFLAGS='-no-undefined -bindir "$(toolexeclibdir)"';
130         else
131           AM_LTLDFLAGS='-no-undefined -bindir "$(bindir)"';
132         fi
133         ;;
134   i?86-*-darwin*)
135         TARGET=X86_DARWIN; TARGETDIR=x86
136         ;;
137   i?86-*-solaris2.1[[0-9]]*)
138         TARGET=X86; TARGETDIR=x86
139         ;;
140   i?86-*-*)
141         TARGET=X86_64; TARGETDIR=x86
142         ;;
143
144   ia64*-*-*)
145         TARGET=IA64; TARGETDIR=ia64
146         ;;
147
148   m32r*-*-*)
149         TARGET=M32R; TARGETDIR=m32r
150         ;;
151
152   m68k-*-*)
153         TARGET=M68K; TARGETDIR=m68k
154         ;;
155
156   mips-sgi-irix5.* | mips-sgi-irix6.* | mips*-*-rtems*)
157         TARGET=MIPS; TARGETDIR=mips
158         ;;
159   mips*-*-linux* | mips*-*-openbsd*)
160         # Support 128-bit long double for NewABI.
161         HAVE_LONG_DOUBLE='defined(__mips64)'
162         TARGET=MIPS; TARGETDIR=mips
163         ;;
164
165   powerpc*-*-linux* | powerpc-*-sysv*)
166         TARGET=POWERPC; TARGETDIR=powerpc
167         ;;
168   powerpc-*-amigaos*)
169         TARGET=POWERPC; TARGETDIR=powerpc
170         ;;
171   powerpc-*-beos*)
172         TARGET=POWERPC; TARGETDIR=powerpc
173         ;;
174   powerpc-*-darwin* | powerpc64-*-darwin*)
175         TARGET=POWERPC_DARWIN; TARGETDIR=powerpc
176         ;;
177   powerpc-*-aix* | rs6000-*-aix*)
178         TARGET=POWERPC_AIX; TARGETDIR=powerpc
179         ;;
180   powerpc-*-freebsd* | powerpc-*-openbsd*)
181         TARGET=POWERPC_FREEBSD; TARGETDIR=powerpc
182         ;;
183   powerpc64-*-freebsd*)
184         TARGET=POWERPC; TARGETDIR=powerpc
185         ;;
186   powerpc*-*-rtems*)
187         TARGET=POWERPC; TARGETDIR=powerpc
188         ;;
189
190   s390-*-* | s390x-*-*)
191         TARGET=S390; TARGETDIR=s390
192         ;;
193
194   sh-*-* | sh[[34]]*-*-*)
195         TARGET=SH; TARGETDIR=sh
196         ;;
197   sh64-*-* | sh5*-*-*)
198         TARGET=SH64; TARGETDIR=sh64
199         ;;
200
201   sparc*-*-*)
202         TARGET=SPARC; TARGETDIR=sparc
203         ;;
204
205   tile*-*)
206         TARGET=TILE; TARGETDIR=tile
207         ;;
208
209   x86_64-*-darwin*)
210         TARGET=X86_DARWIN; TARGETDIR=x86
211         ;;
212
213   x86_64-*-cygwin* | x86_64-*-mingw*)
214         TARGET=X86_WIN64; TARGETDIR=x86
215         # All mingw/cygwin/win32 builds require -no-undefined for sharedlib.
216         # We must also check with_cross_host to decide if this is a native
217         # or cross-build and select where to install dlls appropriately.
218         if test -n "$with_cross_host" &&
219            test x"$with_cross_host" != x"no"; then
220           AM_LTLDFLAGS='-no-undefined -bindir "$(toolexeclibdir)"';
221         else
222           AM_LTLDFLAGS='-no-undefined -bindir "$(bindir)"';
223         fi
224         ;;
225
226   x86_64-*-*)
227         TARGET=X86_64; TARGETDIR=x86
228         ;;
229 esac
230
231 AC_SUBST(AM_RUNTESTFLAGS)
232 AC_SUBST(AM_LTLDFLAGS)
233
234 if test $TARGETDIR = unknown; then
235   AC_MSG_ERROR(["libffi has not been ported to $host."])
236 fi
237
238 AM_CONDITIONAL(MIPS, test x$TARGET = xMIPS)
239 AM_CONDITIONAL(BFIN, test x$TARGET = xBFIN)
240 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
241 AM_CONDITIONAL(X86, test x$TARGET = xX86)
242 AM_CONDITIONAL(X86_FREEBSD, test x$TARGET = xX86_FREEBSD)
243 AM_CONDITIONAL(X86_WIN32, test x$TARGET = xX86_WIN32)
244 AM_CONDITIONAL(X86_WIN64, test x$TARGET = xX86_WIN64)
245 AM_CONDITIONAL(X86_DARWIN, test x$TARGET = xX86_DARWIN)
246 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
247 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
248 AM_CONDITIONAL(M32R, test x$TARGET = xM32R)
249 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
250 AM_CONDITIONAL(MOXIE, test x$TARGET = xMOXIE)
251 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
252 AM_CONDITIONAL(POWERPC_AIX, test x$TARGET = xPOWERPC_AIX)
253 AM_CONDITIONAL(POWERPC_DARWIN, test x$TARGET = xPOWERPC_DARWIN)
254 AM_CONDITIONAL(POWERPC_FREEBSD, test x$TARGET = xPOWERPC_FREEBSD)
255 AM_CONDITIONAL(AARCH64, test x$TARGET = xAARCH64)
256 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
257 AM_CONDITIONAL(AVR32, test x$TARGET = xAVR32)
258 AM_CONDITIONAL(LIBFFI_CRIS, test x$TARGET = xLIBFFI_CRIS)
259 AM_CONDITIONAL(FRV, test x$TARGET = xFRV)
260 AM_CONDITIONAL(S390, test x$TARGET = xS390)
261 AM_CONDITIONAL(X86_64, test x$TARGET = xX86_64)
262 AM_CONDITIONAL(SH, test x$TARGET = xSH)
263 AM_CONDITIONAL(SH64, test x$TARGET = xSH64)
264 AM_CONDITIONAL(PA_LINUX, test x$TARGET = xPA_LINUX)
265 AM_CONDITIONAL(PA_HPUX, test x$TARGET = xPA_HPUX)
266 AM_CONDITIONAL(PA64_HPUX, test x$TARGET = xPA64_HPUX)
267 AM_CONDITIONAL(TILE, test x$TARGET = xTILE)
268
269 AC_HEADER_STDC
270 AC_CHECK_FUNCS(memcpy)
271 AC_FUNC_ALLOCA
272
273 AC_CHECK_SIZEOF(double)
274 AC_CHECK_SIZEOF(long double)
275
276 # Also AC_SUBST this variable for ffi.h.
277 if test -z "$HAVE_LONG_DOUBLE"; then
278   HAVE_LONG_DOUBLE=0
279   if test $ac_cv_sizeof_double != $ac_cv_sizeof_long_double; then
280     if test $ac_cv_sizeof_long_double != 0; then
281       HAVE_LONG_DOUBLE=1
282       AC_DEFINE(HAVE_LONG_DOUBLE, 1, [Define if you have the long double type and it is bigger than a double])
283     fi
284   fi
285 fi
286 AC_SUBST(HAVE_LONG_DOUBLE)
287
288 AC_C_BIGENDIAN
289
290 GCC_AS_CFI_PSEUDO_OP
291
292 if test x$TARGET = xSPARC; then
293     AC_CACHE_CHECK([assembler and linker support unaligned pc related relocs],
294         libffi_cv_as_sparc_ua_pcrel, [
295         save_CFLAGS="$CFLAGS"
296         save_LDFLAGS="$LDFLAGS"
297         CFLAGS="$CFLAGS -fpic"
298         LDFLAGS="$LDFLAGS -shared"
299         AC_TRY_LINK([asm (".text; foo: nop; .data; .align 4; .byte 0; .uaword %r_disp32(foo); .text");],,
300                     [libffi_cv_as_sparc_ua_pcrel=yes],
301                     [libffi_cv_as_sparc_ua_pcrel=no])
302         CFLAGS="$save_CFLAGS"
303         LDFLAGS="$save_LDFLAGS"])
304     if test "x$libffi_cv_as_sparc_ua_pcrel" = xyes; then
305         AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
306                   [Define if your assembler and linker support unaligned PC relative relocs.])
307     fi
308
309     AC_CACHE_CHECK([assembler .register pseudo-op support],
310        libffi_cv_as_register_pseudo_op, [
311        libffi_cv_as_register_pseudo_op=unknown
312        # Check if we have .register
313        AC_TRY_COMPILE([asm (".register %g2, #scratch");],,
314                        [libffi_cv_as_register_pseudo_op=yes],
315                        [libffi_cv_as_register_pseudo_op=no])
316     ])
317     if test "x$libffi_cv_as_register_pseudo_op" = xyes; then
318        AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
319                [Define if your assembler supports .register.])
320     fi
321 fi
322
323 if test x$TARGET = xX86 || test x$TARGET = xX86_WIN32 || test x$TARGET = xX86_64; then
324     AC_CACHE_CHECK([assembler supports pc related relocs],
325         libffi_cv_as_x86_pcrel, [
326         libffi_cv_as_x86_pcrel=yes
327         echo '.text; foo: nop; .data; .long foo-.; .text' > conftest.s
328         if $CC $CFLAGS -c conftest.s 2>&1 | $EGREP -i 'illegal|warning' > /dev/null; then
329             libffi_cv_as_x86_pcrel=no
330         fi
331         ])
332     if test "x$libffi_cv_as_x86_pcrel" = xyes; then
333         AC_DEFINE(HAVE_AS_X86_PCREL, 1,
334                   [Define if your assembler supports PC relative relocs.])
335     fi
336
337     AC_CACHE_CHECK([assembler .ascii pseudo-op support],
338        libffi_cv_as_ascii_pseudo_op, [
339        libffi_cv_as_ascii_pseudo_op=unknown
340        # Check if we have .ascii
341        AC_TRY_COMPILE([asm (".ascii \\"string\\"");],,
342                        [libffi_cv_as_ascii_pseudo_op=yes],
343                        [libffi_cv_as_ascii_pseudo_op=no])
344     ])
345     if test "x$libffi_cv_as_ascii_pseudo_op" = xyes; then
346        AC_DEFINE(HAVE_AS_ASCII_PSEUDO_OP, 1,
347                [Define if your assembler supports .ascii.])
348     fi
349
350     AC_CACHE_CHECK([assembler .string pseudo-op support],
351        libffi_cv_as_string_pseudo_op, [
352        libffi_cv_as_string_pseudo_op=unknown
353        # Check if we have .string
354        AC_TRY_COMPILE([asm (".string \\"string\\"");],,
355                        [libffi_cv_as_string_pseudo_op=yes],
356                        [libffi_cv_as_string_pseudo_op=no])
357     ])
358     if test "x$libffi_cv_as_string_pseudo_op" = xyes; then
359        AC_DEFINE(HAVE_AS_STRING_PSEUDO_OP, 1,
360                [Define if your assembler supports .string.])
361     fi
362 fi
363
364 # On PaX enable kernels that have MPROTECT enable we can't use PROT_EXEC.
365 AC_ARG_ENABLE(pax_emutramp,
366   [  --enable-pax_emutramp       enable pax emulated trampolines, for we can't use PROT_EXEC],
367   if test "$enable_pax_emutramp" = "yes"; then
368     AC_DEFINE(FFI_MMAP_EXEC_EMUTRAMP_PAX, 1,
369       [Define this if you want to enable pax emulated trampolines])
370   fi)
371
372 if test x$TARGET = xX86_WIN64; then
373     LT_SYS_SYMBOL_USCORE
374     if test "x$sys_symbol_underscore" = xyes; then
375         AC_DEFINE(SYMBOL_UNDERSCORE, 1, [Define if symbols are underscored.])
376     fi
377 fi
378
379 FFI_EXEC_TRAMPOLINE_TABLE=0
380 case "$target" in
381      *arm*-apple-darwin*)
382        FFI_EXEC_TRAMPOLINE_TABLE=1
383        AC_DEFINE(FFI_EXEC_TRAMPOLINE_TABLE, 1,
384                  [Cannot use PROT_EXEC on this target, so, we revert to
385                    alternative means])
386      ;;
387      *-apple-darwin1* | *-*-freebsd* | *-*-kfreebsd* | *-*-openbsd* | *-pc-solaris*)
388        AC_DEFINE(FFI_MMAP_EXEC_WRIT, 1,
389                  [Cannot use malloc on this target, so, we revert to
390                    alternative means])
391      ;;
392 esac
393 AM_CONDITIONAL(FFI_EXEC_TRAMPOLINE_TABLE, test x$FFI_EXEC_TRAMPOLINE_TABLE = x1)
394 AC_SUBST(FFI_EXEC_TRAMPOLINE_TABLE)
395
396 if test x$TARGET = xX86_64; then
397     AC_CACHE_CHECK([assembler supports unwind section type],
398         libffi_cv_as_x86_64_unwind_section_type, [
399         libffi_cv_as_x86_64_unwind_section_type=yes
400         echo '.section .eh_frame,"a",@unwind' > conftest.s
401         if $CC $CFLAGS -c conftest.s 2>&1 | grep -i warning > /dev/null; then
402             libffi_cv_as_x86_64_unwind_section_type=no
403         fi
404         ])
405     if test "x$libffi_cv_as_x86_64_unwind_section_type" = xyes; then
406         AC_DEFINE(HAVE_AS_X86_64_UNWIND_SECTION_TYPE, 1,
407                   [Define if your assembler supports unwind section type.])
408     fi
409 fi
410
411 if test "x$GCC" = "xyes"; then
412   AC_CACHE_CHECK([whether .eh_frame section should be read-only],
413       libffi_cv_ro_eh_frame, [
414         libffi_cv_ro_eh_frame=no
415         echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
416         if $CC $CFLAGS -c -fpic -fexceptions -o conftest.o conftest.c > /dev/null 2>&1; then
417             objdump -h conftest.o > conftest.dump 2>&1
418             libffi_eh_frame_line=`grep -n eh_frame conftest.dump | cut -d: -f 1`
419             libffi_test_line=`expr $libffi_eh_frame_line + 1`p
420             sed -n $libffi_test_line conftest.dump > conftest.line
421             if grep READONLY conftest.line > /dev/null; then
422                 libffi_cv_ro_eh_frame=yes
423             fi
424         fi
425         rm -f conftest.*
426       ])
427   if test "x$libffi_cv_ro_eh_frame" = xyes; then
428       AC_DEFINE(HAVE_RO_EH_FRAME, 1,
429               [Define if .eh_frame sections should be read-only.])
430       AC_DEFINE(EH_FRAME_FLAGS, "a",
431               [Define to the flags needed for the .section .eh_frame directive.  ])
432   else
433       AC_DEFINE(EH_FRAME_FLAGS, "aw",
434               [Define to the flags needed for the .section .eh_frame directive.  ])
435   fi
436
437   AC_CACHE_CHECK([for __attribute__((visibility("hidden")))],
438       libffi_cv_hidden_visibility_attribute, [
439         echo 'int __attribute__ ((visibility ("hidden"))) foo (void) { return 1  ; }' > conftest.c
440         libffi_cv_hidden_visibility_attribute=no
441         if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
442             if grep '\.hidden.*foo' conftest.s >/dev/null; then
443                 libffi_cv_hidden_visibility_attribute=yes
444             fi
445         fi
446         rm -f conftest.*
447       ])
448   if test $libffi_cv_hidden_visibility_attribute = yes; then
449       AC_DEFINE(HAVE_HIDDEN_VISIBILITY_ATTRIBUTE, 1,
450               [Define if __attribute__((visibility("hidden"))) is supported.])
451   fi
452 fi
453
454 AH_BOTTOM([
455 #ifdef HAVE_HIDDEN_VISIBILITY_ATTRIBUTE
456 #ifdef LIBFFI_ASM
457 #define FFI_HIDDEN(name) .hidden name
458 #else
459 #define FFI_HIDDEN __attribute__ ((visibility ("hidden")))
460 #endif
461 #else
462 #ifdef LIBFFI_ASM
463 #define FFI_HIDDEN(name)
464 #else
465 #define FFI_HIDDEN
466 #endif
467 #endif
468 ])
469
470 AC_SUBST(TARGET)
471 AC_SUBST(TARGETDIR)
472
473 AC_SUBST(SHELL)
474
475 AC_ARG_ENABLE(debug,
476 [  --enable-debug          debugging mode],
477   if test "$enable_debug" = "yes"; then
478     AC_DEFINE(FFI_DEBUG, 1, [Define this if you want extra debugging.])
479   fi)
480 AM_CONDITIONAL(FFI_DEBUG, test "$enable_debug" = "yes")
481
482 AC_ARG_ENABLE(structs,
483 [  --disable-structs       omit code for struct support],
484   if test "$enable_structs" = "no"; then
485     AC_DEFINE(FFI_NO_STRUCTS, 1, [Define this is you do not want support for aggregate types.])
486   fi)
487 AM_CONDITIONAL(FFI_DEBUG, test "$enable_debug" = "yes")
488
489 AC_ARG_ENABLE(raw-api,
490 [  --disable-raw-api       make the raw api unavailable],
491   if test "$enable_raw_api" = "no"; then
492     AC_DEFINE(FFI_NO_RAW_API, 1, [Define this is you do not want support for the raw API.])
493   fi)
494
495 AC_ARG_ENABLE(purify-safety,
496 [  --enable-purify-safety  purify-safe mode],
497   if test "$enable_purify_safety" = "yes"; then
498     AC_DEFINE(USING_PURIFY, 1, [Define this if you are using Purify and want to suppress spurious messages.])
499   fi)
500
501 # These variables are only ever used when we cross-build to X86_WIN32.
502 # And we only support this with GCC, so...
503 if test x"$GCC" != x"no"; then
504   if test -n "$with_cross_host" &&
505      test x"$with_cross_host" != x"no"; then
506     toolexecdir='$(exec_prefix)/$(target_alias)'
507     toolexeclibdir='$(toolexecdir)/lib'
508   else
509     toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
510     toolexeclibdir='$(libdir)'
511   fi
512   multi_os_directory=`$CC -print-multi-os-directory`
513   case $multi_os_directory in
514     .) ;; # Avoid trailing /.
515     *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
516   esac
517   AC_SUBST(toolexecdir)
518   AC_SUBST(toolexeclibdir)
519 fi
520
521 AC_CONFIG_COMMANDS(include, [test -d include || mkdir include])
522 AC_CONFIG_COMMANDS(src, [
523 test -d src || mkdir src
524 test -d src/$TARGETDIR || mkdir src/$TARGETDIR
525 ], [TARGETDIR="$TARGETDIR"])
526
527 AC_CONFIG_LINKS(include/ffitarget.h:src/$TARGETDIR/ffitarget.h)
528
529 AC_CONFIG_FILES(include/Makefile include/ffi.h Makefile testsuite/Makefile man/Makefile libffi.pc)
530
531 AC_OUTPUT