Merge pull request #159 from nobu/fix-void-arith
[libffi.git] / configure.ac
1 dnl Process this with autoconf to create configure
2
3 AC_PREREQ(2.68)
4
5 AC_INIT([libffi], [3.99999], [http://github.com/atgreen/libffi/issues])
6 AC_CONFIG_HEADERS([fficonfig.h])
7
8 AC_CANONICAL_SYSTEM
9 target_alias=${target_alias-$host_alias}
10
11 case "${host}" in
12   frv*-elf)
13     LDFLAGS=`echo $LDFLAGS | sed "s/\-B[^ ]*libgloss\/frv\///"`\ -B`pwd`/../libgloss/frv/
14     ;;
15 esac
16
17 AX_ENABLE_BUILDDIR
18
19 AM_INIT_AUTOMAKE
20
21 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
22 # We must force CC to /not/ be precious variables; otherwise
23 # the wrong, non-multilib-adjusted value will be used in multilibs.
24 # As a side effect, we have to subst CFLAGS ourselves.
25 # Also save and restore CFLAGS, since AC_PROG_CC will come up with
26 # defaults of its own if none are provided.
27
28 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
29 m4_define([_AC_ARG_VAR_PRECIOUS],[])
30 save_CFLAGS=$CFLAGS
31 AC_PROG_CC
32 AC_PROG_CXX
33 CFLAGS=$save_CFLAGS
34 m4_undefine([_AC_ARG_VAR_PRECIOUS])
35 m4_rename_force([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
36
37 AC_SUBST(CFLAGS)
38
39 AM_PROG_AS
40 AM_PROG_CC_C_O
41 AC_PROG_LIBTOOL
42 AC_CONFIG_MACRO_DIR([m4])
43
44 # Test for 64-bit build.
45 AC_CHECK_SIZEOF([size_t])
46
47 AX_COMPILER_VENDOR
48 AX_CC_MAXOPT
49 # The AX_CFLAGS_WARN_ALL macro doesn't currently work for sunpro
50 # compiler.
51 if test "$ax_cv_c_compiler_vendor" != "sun"; then
52   AX_CFLAGS_WARN_ALL
53 fi
54
55 if test "x$GCC" = "xyes"; then
56   CFLAGS="$CFLAGS -fexceptions"
57 fi
58
59 cat > local.exp <<EOF
60 set CC_FOR_TARGET "$CC"
61 set CXX_FOR_TARGET "$CXX"
62 EOF
63
64 AM_MAINTAINER_MODE
65
66 AC_CHECK_HEADERS(sys/mman.h)
67 AC_CHECK_FUNCS([mmap mkostemp])
68 AC_FUNC_MMAP_BLACKLIST
69
70 dnl The -no-testsuite modules omit the test subdir.
71 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
72
73 TARGETDIR="unknown"
74 HAVE_LONG_DOUBLE_VARIANT=0
75
76 . ${srcdir}/configure.host
77
78 if test -n "${UNSUPPORTED}"; then
79   AC_MSG_ERROR(["libffi has not been ported to $host."])
80 fi
81
82 AC_SUBST(AM_RUNTESTFLAGS)
83 AC_SUBST(AM_LTLDFLAGS)
84
85 AC_HEADER_STDC
86 AC_CHECK_FUNCS(memcpy)
87 AC_FUNC_ALLOCA
88
89 AC_CHECK_SIZEOF(double)
90 AC_CHECK_SIZEOF(long double)
91
92 # Also AC_SUBST this variable for ffi.h.
93 if test -z "$HAVE_LONG_DOUBLE"; then
94   HAVE_LONG_DOUBLE=0
95   if test $ac_cv_sizeof_long_double != 0; then
96     if test $HAVE_LONG_DOUBLE_VARIANT != 0; then
97       AC_DEFINE(HAVE_LONG_DOUBLE_VARIANT, 1, [Define if you support more than one size of the long double type])
98       HAVE_LONG_DOUBLE=1
99     else
100       if test $ac_cv_sizeof_double != $ac_cv_sizeof_long_double; then
101         HAVE_LONG_DOUBLE=1
102         AC_DEFINE(HAVE_LONG_DOUBLE, 1, [Define if you have the long double type and it is bigger than a double])
103       fi
104     fi
105   fi
106 fi
107 AC_SUBST(HAVE_LONG_DOUBLE)
108 AC_SUBST(HAVE_LONG_DOUBLE_VARIANT)
109
110 AC_C_BIGENDIAN
111
112 GCC_AS_CFI_PSEUDO_OP
113
114 if test x$TARGET = xSPARC; then
115     AC_CACHE_CHECK([assembler and linker support unaligned pc related relocs],
116         libffi_cv_as_sparc_ua_pcrel, [
117         save_CFLAGS="$CFLAGS"
118         save_LDFLAGS="$LDFLAGS"
119         CFLAGS="$CFLAGS -fpic"
120         LDFLAGS="$LDFLAGS -shared"
121         AC_TRY_LINK([asm (".text; foo: nop; .data; .align 4; .byte 0; .uaword %r_disp32(foo); .text");],,
122                     [libffi_cv_as_sparc_ua_pcrel=yes],
123                     [libffi_cv_as_sparc_ua_pcrel=no])
124         CFLAGS="$save_CFLAGS"
125         LDFLAGS="$save_LDFLAGS"])
126     if test "x$libffi_cv_as_sparc_ua_pcrel" = xyes; then
127         AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
128                   [Define if your assembler and linker support unaligned PC relative relocs.])
129     fi
130
131     AC_CACHE_CHECK([assembler .register pseudo-op support],
132        libffi_cv_as_register_pseudo_op, [
133        libffi_cv_as_register_pseudo_op=unknown
134        # Check if we have .register
135        AC_TRY_COMPILE(,[asm (".register %g2, #scratch");],
136                        [libffi_cv_as_register_pseudo_op=yes],
137                        [libffi_cv_as_register_pseudo_op=no])
138     ])
139     if test "x$libffi_cv_as_register_pseudo_op" = xyes; then
140        AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
141                [Define if your assembler supports .register.])
142     fi
143 fi
144
145 if test x$TARGET = xX86 || test x$TARGET = xX86_WIN32 || test x$TARGET = xX86_64; then
146     AC_CACHE_CHECK([assembler supports pc related relocs],
147         libffi_cv_as_x86_pcrel, [
148         libffi_cv_as_x86_pcrel=no
149         echo '.text; foo: nop; .data; .long foo-.; .text' > conftest.s
150         if $CC $CFLAGS -c conftest.s > /dev/null 2>&1; then
151             libffi_cv_as_x86_pcrel=yes
152         fi
153         ])
154     if test "x$libffi_cv_as_x86_pcrel" = xyes; then
155         AC_DEFINE(HAVE_AS_X86_PCREL, 1,
156                   [Define if your assembler supports PC relative relocs.])
157     fi
158
159     AC_CACHE_CHECK([assembler .ascii pseudo-op support],
160        libffi_cv_as_ascii_pseudo_op, [
161        libffi_cv_as_ascii_pseudo_op=unknown
162        # Check if we have .ascii
163        AC_TRY_COMPILE(,[asm (".ascii \\"string\\"");],
164                        [libffi_cv_as_ascii_pseudo_op=yes],
165                        [libffi_cv_as_ascii_pseudo_op=no])
166     ])
167     if test "x$libffi_cv_as_ascii_pseudo_op" = xyes; then
168        AC_DEFINE(HAVE_AS_ASCII_PSEUDO_OP, 1,
169                [Define if your assembler supports .ascii.])
170     fi
171
172     AC_CACHE_CHECK([assembler .string pseudo-op support],
173        libffi_cv_as_string_pseudo_op, [
174        libffi_cv_as_string_pseudo_op=unknown
175        # Check if we have .string
176        AC_TRY_COMPILE(,[asm (".string \\"string\\"");],
177                        [libffi_cv_as_string_pseudo_op=yes],
178                        [libffi_cv_as_string_pseudo_op=no])
179     ])
180     if test "x$libffi_cv_as_string_pseudo_op" = xyes; then
181        AC_DEFINE(HAVE_AS_STRING_PSEUDO_OP, 1,
182                [Define if your assembler supports .string.])
183     fi
184 fi
185
186 if test x$TARGET = xS390; then
187     AC_CACHE_CHECK([compiler uses zarch features],
188         libffi_cv_as_s390_zarch, [
189         libffi_cv_as_s390_zarch=no
190         echo 'void foo(void) { bar(); bar(); }' > conftest.c
191         if $CC $CFLAGS -S conftest.c > /dev/null 2>&1; then
192             if grep -q brasl conftest.s; then
193                 libffi_cv_as_s390_zarch=yes
194             fi
195         fi
196         ])
197     if test "x$libffi_cv_as_s390_zarch" = xyes; then
198         AC_DEFINE(HAVE_AS_S390_ZARCH, 1,
199                   [Define if the compiler uses zarch features.])
200     fi
201 fi
202
203 # On PaX enable kernels that have MPROTECT enable we can't use PROT_EXEC.
204 AC_ARG_ENABLE(pax_emutramp,
205   [  --enable-pax_emutramp       enable pax emulated trampolines, for we can't use PROT_EXEC],
206   if test "$enable_pax_emutramp" = "yes"; then
207     AC_DEFINE(FFI_MMAP_EXEC_EMUTRAMP_PAX, 1,
208       [Define this if you want to enable pax emulated trampolines])
209   fi)
210
211 LT_SYS_SYMBOL_USCORE
212 if test "x$sys_symbol_underscore" = xyes; then
213     AC_DEFINE(SYMBOL_UNDERSCORE, 1, [Define if symbols are underscored.])
214 fi
215
216 FFI_EXEC_TRAMPOLINE_TABLE=0
217 case "$target" in
218      *arm*-apple-darwin*)
219        FFI_EXEC_TRAMPOLINE_TABLE=1
220        AC_DEFINE(FFI_EXEC_TRAMPOLINE_TABLE, 1,
221                  [Cannot use PROT_EXEC on this target, so, we revert to
222                    alternative means])
223      ;;
224      *-apple-darwin1* | *-*-freebsd* | *-*-kfreebsd* | *-*-openbsd* | *-pc-solaris*)
225        AC_DEFINE(FFI_MMAP_EXEC_WRIT, 1,
226                  [Cannot use malloc on this target, so, we revert to
227                    alternative means])
228      ;;
229 esac
230 AM_CONDITIONAL(FFI_EXEC_TRAMPOLINE_TABLE, test x$FFI_EXEC_TRAMPOLINE_TABLE = x1)
231 AC_SUBST(FFI_EXEC_TRAMPOLINE_TABLE)
232
233 if test x$TARGET = xX86_64; then
234     AC_CACHE_CHECK([toolchain supports unwind section type],
235         libffi_cv_as_x86_64_unwind_section_type, [
236         cat  > conftest1.s << EOF
237 .text
238 .globl foo
239 foo:
240 jmp bar
241 .section .eh_frame,"a",@unwind
242 bar:
243 EOF
244
245         cat > conftest2.c  << EOF
246 extern void foo();
247 int main(){foo();}
248 EOF
249
250         libffi_cv_as_x86_64_unwind_section_type=no
251         # we ensure that we can compile _and_ link an assembly file containing an @unwind section
252         # since the compiler can support it and not the linker (ie old binutils)
253         if $CC -Wa,--fatal-warnings $CFLAGS -c conftest1.s > /dev/null 2>&1 && \
254            $CC conftest2.c conftest1.o > /dev/null 2>&1 ; then
255             libffi_cv_as_x86_64_unwind_section_type=yes
256         fi
257         ])
258     if test "x$libffi_cv_as_x86_64_unwind_section_type" = xyes; then
259         AC_DEFINE(HAVE_AS_X86_64_UNWIND_SECTION_TYPE, 1,
260                   [Define if your assembler supports unwind section type.])
261     fi
262 fi
263
264 if test "x$GCC" = "xyes"; then
265   AC_CACHE_CHECK([whether .eh_frame section should be read-only],
266       libffi_cv_ro_eh_frame, [
267         libffi_cv_ro_eh_frame=no
268         echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
269         if $CC $CFLAGS -c -fpic -fexceptions -o conftest.o conftest.c > /dev/null 2>&1; then
270             objdump -h conftest.o > conftest.dump 2>&1
271             libffi_eh_frame_line=`grep -n eh_frame conftest.dump | cut -d: -f 1`
272             libffi_test_line=`expr $libffi_eh_frame_line + 1`p
273             sed -n $libffi_test_line conftest.dump > conftest.line
274             if grep READONLY conftest.line > /dev/null; then
275                 libffi_cv_ro_eh_frame=yes
276             fi
277         fi
278         rm -f conftest.*
279       ])
280   if test "x$libffi_cv_ro_eh_frame" = xyes; then
281       AC_DEFINE(HAVE_RO_EH_FRAME, 1,
282               [Define if .eh_frame sections should be read-only.])
283       AC_DEFINE(EH_FRAME_FLAGS, "a",
284               [Define to the flags needed for the .section .eh_frame directive.  ])
285   else
286       AC_DEFINE(EH_FRAME_FLAGS, "aw",
287               [Define to the flags needed for the .section .eh_frame directive.  ])
288   fi
289
290   AC_CACHE_CHECK([for __attribute__((visibility("hidden")))],
291       libffi_cv_hidden_visibility_attribute, [
292         echo 'int __attribute__ ((visibility ("hidden"))) foo (void) { return 1  ; }' > conftest.c
293         libffi_cv_hidden_visibility_attribute=no
294         if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
295             if grep '\.hidden.*foo' conftest.s >/dev/null; then
296                 libffi_cv_hidden_visibility_attribute=yes
297             fi
298         fi
299         rm -f conftest.*
300       ])
301   if test $libffi_cv_hidden_visibility_attribute = yes; then
302       AC_DEFINE(HAVE_HIDDEN_VISIBILITY_ATTRIBUTE, 1,
303               [Define if __attribute__((visibility("hidden"))) is supported.])
304   fi
305 fi
306
307 AH_BOTTOM([
308 #ifdef HAVE_HIDDEN_VISIBILITY_ATTRIBUTE
309 #ifdef LIBFFI_ASM
310 #define FFI_HIDDEN(name) .hidden name
311 #else
312 #define FFI_HIDDEN __attribute__ ((visibility ("hidden")))
313 #endif
314 #else
315 #ifdef LIBFFI_ASM
316 #define FFI_HIDDEN(name)
317 #else
318 #define FFI_HIDDEN
319 #endif
320 #endif
321 ])
322
323 AC_SUBST(TARGET)
324 AC_SUBST(TARGETDIR)
325
326 changequote(<,>)
327 TARGET_OBJ=
328 for i in $SOURCES; do
329   TARGET_OBJ="${TARGET_OBJ} src/${TARGETDIR}/"`echo $i | sed 's/[cS]$/lo/'`
330 done
331 changequote([,])
332 AC_SUBST(TARGET_OBJ)
333
334 AC_SUBST(SHELL)
335
336 AC_ARG_ENABLE(debug,
337 [  --enable-debug          debugging mode],
338   if test "$enable_debug" = "yes"; then
339     AC_DEFINE(FFI_DEBUG, 1, [Define this if you want extra debugging.])
340   fi)
341 AM_CONDITIONAL(FFI_DEBUG, test "$enable_debug" = "yes")
342
343 AC_ARG_ENABLE(structs,
344 [  --disable-structs       omit code for struct support],
345   if test "$enable_structs" = "no"; then
346     AC_DEFINE(FFI_NO_STRUCTS, 1, [Define this if you do not want support for aggregate types.])
347   fi)
348 AM_CONDITIONAL(FFI_DEBUG, test "$enable_debug" = "yes")
349
350 AC_ARG_ENABLE(raw-api,
351 [  --disable-raw-api       make the raw api unavailable],
352   if test "$enable_raw_api" = "no"; then
353     AC_DEFINE(FFI_NO_RAW_API, 1, [Define this if you do not want support for the raw API.])
354   fi)
355
356 AC_ARG_ENABLE(purify-safety,
357 [  --enable-purify-safety  purify-safe mode],
358   if test "$enable_purify_safety" = "yes"; then
359     AC_DEFINE(USING_PURIFY, 1, [Define this if you are using Purify and want to suppress spurious messages.])
360   fi)
361
362 # These variables are only ever used when we cross-build to X86_WIN32.
363 # And we only support this with GCC, so...
364 if test "x$GCC" = "xyes"; then
365   if test -n "$with_cross_host" &&
366      test x"$with_cross_host" != x"no"; then
367     toolexecdir="${exec_prefix}"/'$(target_alias)'
368     toolexeclibdir="${toolexecdir}"/lib
369   else
370     toolexecdir="${libdir}"/gcc-lib/'$(target_alias)'
371     toolexeclibdir="${libdir}"
372   fi
373   multi_os_directory=`$CC $CFLAGS -print-multi-os-directory`
374   case $multi_os_directory in
375     .) ;; # Avoid trailing /.
376     ../*) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
377   esac
378   AC_SUBST(toolexecdir)
379 else
380   toolexeclibdir="${libdir}"
381 fi
382 AC_SUBST(toolexeclibdir)
383
384 AC_CONFIG_COMMANDS(include, [test -d include || mkdir include])
385 AC_CONFIG_COMMANDS(src, [
386 test -d src || mkdir src
387 test -d src/$TARGETDIR || mkdir src/$TARGETDIR
388 ], [TARGETDIR="$TARGETDIR"])
389
390 AC_CONFIG_LINKS(include/ffitarget.h:src/$TARGETDIR/ffitarget.h)
391
392 AC_CONFIG_FILES(include/Makefile include/ffi.h Makefile testsuite/Makefile man/Makefile libffi.pc)
393
394 AC_OUTPUT