mend
[libffi.git] / configure.ac
1 dnl Process this with autoconf to create configure
2
3 AC_PREREQ(2.63)
4
5 AC_INIT([libffi], [3.0.11-rc2], [http://github.com/atgreen/libffi/issues])
6 AC_CONFIG_HEADERS([fficonfig.h])
7
8 AC_CANONICAL_SYSTEM
9 target_alias=${target_alias-$host_alias}
10
11 . ${srcdir}/configure.host
12
13 AX_ENABLE_BUILDDIR
14
15 AM_INIT_AUTOMAKE
16
17 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
18 # We must force CC to /not/ be precious variables; otherwise
19 # the wrong, non-multilib-adjusted value will be used in multilibs.
20 # As a side effect, we have to subst CFLAGS ourselves.
21 # Also save and restore CFLAGS, since AC_PROG_CC will come up with
22 # defaults of its own if none are provided.
23
24 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
25 m4_define([_AC_ARG_VAR_PRECIOUS],[])
26 save_CFLAGS=$CFLAGS
27 AC_PROG_CC
28 CFLAGS=$save_CFLAGS
29 m4_undefine([_AC_ARG_VAR_PRECIOUS])
30 m4_rename([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
31
32 AC_SUBST(CFLAGS)
33
34 AM_PROG_AS
35 AM_PROG_CC_C_O
36 AC_PROG_LIBTOOL
37 AC_CONFIG_MACRO_DIR([m4])
38
39 AX_CC_MAXOPT
40 AX_CFLAGS_WARN_ALL
41 if test "x$GCC" = "xyes"; then
42   CFLAGS="$CFLAGS -fexceptions"
43 fi
44
45 AM_MAINTAINER_MODE
46
47 AC_CHECK_HEADERS(sys/mman.h)
48 AC_CHECK_FUNCS(mmap)
49 AC_FUNC_MMAP_BLACKLIST
50
51 dnl The -no-testsuite modules omit the test subdir.
52 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
53
54 TARGETDIR="unknown"
55 case "$host" in
56   alpha*-*-*)
57         TARGET=ALPHA; TARGETDIR=alpha;
58         # Support 128-bit long double, changeable via command-line switch.
59         HAVE_LONG_DOUBLE='defined(__LONG_DOUBLE_128__)'
60         ;;
61
62   arm*-*-*)
63         TARGET=ARM; TARGETDIR=arm
64         ;;
65
66   amd64-*-freebsd* | amd64-*-openbsd*)
67         TARGET=X86_64; TARGETDIR=x86
68         ;;
69
70   amd64-*-freebsd*)
71         TARGET=X86_64; TARGETDIR=x86
72         ;;
73
74   avr32*-*-*)
75         TARGET=AVR32; TARGETDIR=avr32
76         ;;
77
78   cris-*-*)
79         TARGET=LIBFFI_CRIS; TARGETDIR=cris
80         ;;
81
82   frv-*-*)
83         TARGET=FRV; TARGETDIR=frv
84         ;;
85
86   hppa*-*-linux* | parisc*-*-linux* | hppa*-*-openbsd*)
87         TARGET=PA_LINUX; TARGETDIR=pa
88         ;;
89   hppa*64-*-hpux*)
90         TARGET=PA64_HPUX; TARGETDIR=pa
91         ;;
92   hppa*-*-hpux*)
93         TARGET=PA_HPUX; TARGETDIR=pa
94         ;;
95
96   i?86-*-freebsd* | i?86-*-openbsd*)
97         TARGET=X86_FREEBSD; TARGETDIR=x86
98         ;;
99   i?86-win32* | i?86-*-cygwin* | i?86-*-mingw* | i?86-*-os2* | i?86-*-interix*)
100         TARGET=X86_WIN32; TARGETDIR=x86
101         # All mingw/cygwin/win32 builds require -no-undefined for sharedlib.
102         # We must also check with_cross_host to decide if this is a native
103         # or cross-build and select where to install dlls appropriately.
104         if test -n "$with_cross_host" &&
105            test x"$with_cross_host" != x"no"; then
106           AM_LTLDFLAGS='-no-undefined -bindir "$(toolexeclibdir)"';
107         else
108           AM_LTLDFLAGS='-no-undefined -bindir "$(bindir)"';
109         fi
110         ;;
111   i?86-*-darwin*)
112         TARGET=X86_DARWIN; TARGETDIR=x86
113         ;;
114   i?86-*-solaris2.1[[0-9]]*)
115         TARGET=X86_64; TARGETDIR=x86
116         ;;
117   i?86-*-*)
118         TARGET=X86_64; TARGETDIR=x86
119         ;;
120
121   ia64*-*-*)
122         TARGET=IA64; TARGETDIR=ia64
123         ;;
124
125   m32r*-*-*)
126         TARGET=M32R; TARGETDIR=m32r
127         ;;
128
129   m68k-*-*)
130         TARGET=M68K; TARGETDIR=m68k
131         ;;
132
133   mips-sgi-irix5.* | mips-sgi-irix6.* | mips*-*-rtems*)
134         TARGET=MIPS; TARGETDIR=mips
135         ;;
136   mips*-*-linux* | mips*-*-openbsd*)
137         # Support 128-bit long double for NewABI.
138         HAVE_LONG_DOUBLE='defined(__mips64)'
139         TARGET=MIPS; TARGETDIR=mips
140         ;;
141
142   moxie-*-*)
143         TARGET=MOXIE; TARGETDIR=moxie
144         ;;
145
146   powerpc*-*-linux* | powerpc-*-sysv*)
147         TARGET=POWERPC; TARGETDIR=powerpc
148         ;;
149   powerpc-*-beos*)
150         TARGET=POWERPC; TARGETDIR=powerpc
151         ;;
152   powerpc-*-darwin* | powerpc64-*-darwin*)
153         TARGET=POWERPC_DARWIN; TARGETDIR=powerpc
154         ;;
155   powerpc-*-aix* | rs6000-*-aix*)
156         TARGET=POWERPC_AIX; TARGETDIR=powerpc
157         ;;
158   powerpc-*-freebsd* | powerpc-*-openbsd*)
159         TARGET=POWERPC_FREEBSD; TARGETDIR=powerpc
160         ;;
161   powerpc64-*-freebsd*)
162         TARGET=POWERPC; TARGETDIR=powerpc
163         ;;
164   powerpc*-*-rtems*)
165         TARGET=POWERPC; TARGETDIR=powerpc
166         ;;
167
168   s390-*-* | s390x-*-*)
169         TARGET=S390; TARGETDIR=s390
170         ;;
171
172   sh-*-* | sh[[34]]*-*-*)
173         TARGET=SH; TARGETDIR=sh
174         ;;
175   sh64-*-* | sh5*-*-*)
176         TARGET=SH64; TARGETDIR=sh64
177         ;;
178
179   sparc*-*-*)
180         TARGET=SPARC; TARGETDIR=sparc
181         ;;
182
183   x86_64-*-darwin*)
184         TARGET=X86_DARWIN; TARGETDIR=x86
185         ;;
186
187   x86_64-*-cygwin* | x86_64-*-mingw*)
188         TARGET=X86_WIN64; TARGETDIR=x86
189         ;;
190
191   x86_64-*-*)
192         TARGET=X86_64; TARGETDIR=x86
193         ;;
194 esac
195
196 AC_SUBST(AM_RUNTESTFLAGS)
197 AC_SUBST(AM_LTLDFLAGS)
198
199 if test $TARGETDIR = unknown; then
200   AC_MSG_ERROR(["libffi has not been ported to $host."])
201 fi
202
203 AM_CONDITIONAL(MIPS, test x$TARGET = xMIPS)
204 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
205 AM_CONDITIONAL(X86, test x$TARGET = xX86)
206 AM_CONDITIONAL(X86_FREEBSD, test x$TARGET = xX86_FREEBSD)
207 AM_CONDITIONAL(X86_WIN32, test x$TARGET = xX86_WIN32)
208 AM_CONDITIONAL(X86_WIN64, test x$TARGET = xX86_WIN64)
209 AM_CONDITIONAL(X86_DARWIN, test x$TARGET = xX86_DARWIN)
210 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
211 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
212 AM_CONDITIONAL(M32R, test x$TARGET = xM32R)
213 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
214 AM_CONDITIONAL(MOXIE, test x$TARGET = xMOXIE)
215 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
216 AM_CONDITIONAL(POWERPC_AIX, test x$TARGET = xPOWERPC_AIX)
217 AM_CONDITIONAL(POWERPC_DARWIN, test x$TARGET = xPOWERPC_DARWIN)
218 AM_CONDITIONAL(POWERPC_FREEBSD, test x$TARGET = xPOWERPC_FREEBSD)
219 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
220 AM_CONDITIONAL(AVR32, test x$TARGET = xAVR32)
221 AM_CONDITIONAL(LIBFFI_CRIS, test x$TARGET = xLIBFFI_CRIS)
222 AM_CONDITIONAL(FRV, test x$TARGET = xFRV)
223 AM_CONDITIONAL(S390, test x$TARGET = xS390)
224 AM_CONDITIONAL(X86_64, test x$TARGET = xX86_64)
225 AM_CONDITIONAL(SH, test x$TARGET = xSH)
226 AM_CONDITIONAL(SH64, test x$TARGET = xSH64)
227 AM_CONDITIONAL(PA_LINUX, test x$TARGET = xPA_LINUX)
228 AM_CONDITIONAL(PA_HPUX, test x$TARGET = xPA_HPUX)
229 AM_CONDITIONAL(PA64_HPUX, test x$TARGET = xPA64_HPUX)
230
231 AC_HEADER_STDC
232 AC_CHECK_FUNCS(memcpy)
233 AC_FUNC_ALLOCA
234
235 AC_CHECK_SIZEOF(double)
236 AC_CHECK_SIZEOF(long double)
237
238 # Also AC_SUBST this variable for ffi.h.
239 if test -z "$HAVE_LONG_DOUBLE"; then
240   HAVE_LONG_DOUBLE=0
241   if test $ac_cv_sizeof_double != $ac_cv_sizeof_long_double; then
242     if test $ac_cv_sizeof_long_double != 0; then
243       HAVE_LONG_DOUBLE=1
244       AC_DEFINE(HAVE_LONG_DOUBLE, 1, [Define if you have the long double type and it is bigger than a double])
245     fi
246   fi
247 fi
248 AC_SUBST(HAVE_LONG_DOUBLE)
249
250 AC_C_BIGENDIAN
251
252 GCC_AS_CFI_PSEUDO_OP
253
254 if test x$TARGET = xSPARC; then
255     AC_CACHE_CHECK([assembler and linker support unaligned pc related relocs],
256         libffi_cv_as_sparc_ua_pcrel, [
257         save_CFLAGS="$CFLAGS"
258         save_LDFLAGS="$LDFLAGS"
259         CFLAGS="$CFLAGS -fpic"
260         LDFLAGS="$LDFLAGS -shared"
261         AC_TRY_LINK([asm (".text; foo: nop; .data; .align 4; .byte 0; .uaword %r_disp32(foo); .text");],,
262                     [libffi_cv_as_sparc_ua_pcrel=yes],
263                     [libffi_cv_as_sparc_ua_pcrel=no])
264         CFLAGS="$save_CFLAGS"
265         LDFLAGS="$save_LDFLAGS"])
266     if test "x$libffi_cv_as_sparc_ua_pcrel" = xyes; then
267         AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
268                   [Define if your assembler and linker support unaligned PC relative relocs.])
269     fi
270
271     AC_CACHE_CHECK([assembler .register pseudo-op support],
272        libffi_cv_as_register_pseudo_op, [
273        libffi_cv_as_register_pseudo_op=unknown
274        # Check if we have .register
275        AC_TRY_COMPILE([asm (".register %g2, #scratch");],,
276                        [libffi_cv_as_register_pseudo_op=yes],
277                        [libffi_cv_as_register_pseudo_op=no])
278     ])
279     if test "x$libffi_cv_as_register_pseudo_op" = xyes; then
280        AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
281                [Define if your assembler supports .register.])
282     fi
283 fi
284
285 if test x$TARGET = xX86 || test x$TARGET = xX86_WIN32 || test x$TARGET = xX86_64; then
286     AC_CACHE_CHECK([assembler supports pc related relocs],
287         libffi_cv_as_x86_pcrel, [
288         libffi_cv_as_x86_pcrel=no
289         echo '.text; foo: nop; .data; .long foo-.; .text' > conftest.s
290         if $CC $CFLAGS -c conftest.s > /dev/null; then
291            libffi_cv_as_x86_pcrel=yes
292         fi
293         ])
294     if test "x$libffi_cv_as_x86_pcrel" = xyes; then
295         AC_DEFINE(HAVE_AS_X86_PCREL, 1,
296                   [Define if your assembler supports PC relative relocs.])
297     fi
298
299     AC_CACHE_CHECK([assembler .ascii pseudo-op support],
300        libffi_cv_as_ascii_pseudo_op, [
301        libffi_cv_as_ascii_pseudo_op=unknown
302        # Check if we have .ascii
303        AC_TRY_COMPILE([asm (".ascii \\"string\\"");],,
304                        [libffi_cv_as_ascii_pseudo_op=yes],
305                        [libffi_cv_as_ascii_pseudo_op=no])
306     ])
307     if test "x$libffi_cv_as_ascii_pseudo_op" = xyes; then
308        AC_DEFINE(HAVE_AS_ASCII_PSEUDO_OP, 1,
309                [Define if your assembler supports .ascii.])
310     fi
311
312     AC_CACHE_CHECK([assembler .string pseudo-op support],
313        libffi_cv_as_string_pseudo_op, [
314        libffi_cv_as_string_pseudo_op=unknown
315        # Check if we have .string
316        AC_TRY_COMPILE([asm (".string \\"string\\"");],,
317                        [libffi_cv_as_string_pseudo_op=yes],
318                        [libffi_cv_as_string_pseudo_op=no])
319     ])
320     if test "x$libffi_cv_as_string_pseudo_op" = xyes; then
321        AC_DEFINE(HAVE_AS_STRING_PSEUDO_OP, 1,
322                [Define if your assembler supports .string.])
323     fi
324 fi
325
326 if test x$TARGET = xX86_WIN64; then
327     LT_SYS_SYMBOL_USCORE
328     if test "x$sys_symbol_underscore" = xyes; then
329         AC_DEFINE(SYMBOL_UNDERSCORE, 1, [Define if symbols are underscored.])
330     fi
331 fi
332
333
334 FFI_EXEC_TRAMPOLINE_TABLE=0
335 case "$target" in
336      *arm*-apple-darwin*)
337        FFI_EXEC_TRAMPOLINE_TABLE=1
338        AC_DEFINE(FFI_EXEC_TRAMPOLINE_TABLE, 1,
339                  [Cannot use PROT_EXEC on this target, so, we revert to
340                    alternative means])
341      ;;
342      *-apple-darwin1* | *-*-freebsd* | *-*-kfreebsd* | *-*-openbsd* | *-pc-solaris*)
343        AC_DEFINE(FFI_MMAP_EXEC_WRIT, 1,
344                  [Cannot use malloc on this target, so, we revert to
345                    alternative means])
346      ;;
347 esac
348 AM_CONDITIONAL(FFI_EXEC_TRAMPOLINE_TABLE, test x$FFI_EXEC_TRAMPOLINE_TABLE = x1)
349 AC_SUBST(FFI_EXEC_TRAMPOLINE_TABLE)
350
351 if test x$TARGET = xX86_64; then
352     AC_CACHE_CHECK([assembler supports unwind section type],
353         libffi_cv_as_x86_64_unwind_section_type, [
354         libffi_cv_as_x86_64_unwind_section_type=yes
355         echo '.section .eh_frame,"a",@unwind' > conftest.s
356         if $CC $CFLAGS -c conftest.s 2>&1 | grep -i warning > /dev/null; then
357             libffi_cv_as_x86_64_unwind_section_type=no
358         fi
359         ])
360     if test "x$libffi_cv_as_x86_64_unwind_section_type" = xyes; then
361         AC_DEFINE(HAVE_AS_X86_64_UNWIND_SECTION_TYPE, 1,
362                   [Define if your assembler supports unwind section type.])
363     fi
364 fi
365
366 if test "x$GCC" = "xyes"; then
367   AC_CACHE_CHECK([whether .eh_frame section should be read-only],
368       libffi_cv_ro_eh_frame, [
369         libffi_cv_ro_eh_frame=no
370         echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
371         if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
372             if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
373                 libffi_cv_ro_eh_frame=yes
374             elif grep '.section.*eh_frame.*#alloc' conftest.c \
375                  | grep -v '#write' > /dev/null; then
376                 libffi_cv_ro_eh_frame=yes
377             fi
378         fi
379         rm -f conftest.*
380       ])
381   if test "x$libffi_cv_ro_eh_frame" = xyes; then
382       AC_DEFINE(HAVE_RO_EH_FRAME, 1,
383               [Define if .eh_frame sections should be read-only.])
384       AC_DEFINE(EH_FRAME_FLAGS, "a",
385               [Define to the flags needed for the .section .eh_frame directive.  ])
386   else
387       AC_DEFINE(EH_FRAME_FLAGS, "aw",
388               [Define to the flags needed for the .section .eh_frame directive.  ])
389   fi
390
391   AC_CACHE_CHECK([for __attribute__((visibility("hidden")))],
392       libffi_cv_hidden_visibility_attribute, [
393         echo 'int __attribute__ ((visibility ("hidden"))) foo (void) { return 1  ; }' > conftest.c
394         libffi_cv_hidden_visibility_attribute=no
395         if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
396             if grep '\.hidden.*foo' conftest.s >/dev/null; then
397                 libffi_cv_hidden_visibility_attribute=yes
398             fi
399         fi
400         rm -f conftest.*
401       ])
402   if test $libffi_cv_hidden_visibility_attribute = yes; then
403       AC_DEFINE(HAVE_HIDDEN_VISIBILITY_ATTRIBUTE, 1,
404               [Define if __attribute__((visibility("hidden"))) is supported.])
405   fi
406 fi
407
408 AH_BOTTOM([
409 #ifdef HAVE_HIDDEN_VISIBILITY_ATTRIBUTE
410 #ifdef LIBFFI_ASM
411 #define FFI_HIDDEN(name) .hidden name
412 #else
413 #define FFI_HIDDEN __attribute__ ((visibility ("hidden")))
414 #endif
415 #else
416 #ifdef LIBFFI_ASM
417 #define FFI_HIDDEN(name)
418 #else
419 #define FFI_HIDDEN
420 #endif
421 #endif
422 ])
423
424 AC_SUBST(TARGET)
425 AC_SUBST(TARGETDIR)
426
427 AC_SUBST(SHELL)
428
429 AC_ARG_ENABLE(debug,
430 [  --enable-debug          debugging mode],
431   if test "$enable_debug" = "yes"; then
432     AC_DEFINE(FFI_DEBUG, 1, [Define this if you want extra debugging.])
433   fi)
434 AM_CONDITIONAL(FFI_DEBUG, test "$enable_debug" = "yes")
435
436 AC_ARG_ENABLE(structs,
437 [  --disable-structs       omit code for struct support],
438   if test "$enable_structs" = "no"; then
439     AC_DEFINE(FFI_NO_STRUCTS, 1, [Define this is you do not want support for aggregate types.])
440   fi)
441
442 AC_ARG_ENABLE(raw-api,
443 [  --disable-raw-api       make the raw api unavailable],
444   if test "$enable_raw_api" = "no"; then
445     AC_DEFINE(FFI_NO_RAW_API, 1, [Define this is you do not want support for the raw API.])
446   fi)
447
448 AC_ARG_ENABLE(purify-safety,
449 [  --enable-purify-safety  purify-safe mode],
450   if test "$enable_purify_safety" = "yes"; then
451     AC_DEFINE(USING_PURIFY, 1, [Define this if you are using Purify and want to suppress spurious messages.])
452   fi)
453
454 # These variables are only ever used when we cross-build to X86_WIN32.
455 # And we only support this with GCC, so...
456 if test x"$GCC" != x"no"; then
457   if test -n "$with_cross_host" &&
458      test x"$with_cross_host" != x"no"; then
459     toolexecdir='$(exec_prefix)/$(target_alias)'
460     toolexeclibdir='$(toolexecdir)/lib'
461   else
462     toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
463     toolexeclibdir='$(libdir)'
464   fi
465   multi_os_directory=`$CC -print-multi-os-directory`
466   case $multi_os_directory in
467     .) ;; # Avoid trailing /.
468     *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
469   esac
470   AC_SUBST(toolexecdir)
471   AC_SUBST(toolexeclibdir)
472 fi
473
474 if test "${multilib}" = "yes"; then
475   multilib_arg="--enable-multilib"
476 else
477   multilib_arg=
478 fi
479
480 AC_CONFIG_COMMANDS(include, [test -d include || mkdir include])
481 AC_CONFIG_COMMANDS(src, [
482 test -d src || mkdir src
483 test -d src/$TARGETDIR || mkdir src/$TARGETDIR
484 ], [TARGETDIR="$TARGETDIR"])
485
486 AC_CONFIG_LINKS(include/ffitarget.h:src/$TARGETDIR/ffitarget.h)
487
488 AC_CONFIG_FILES(include/Makefile include/ffi.h Makefile testsuite/Makefile man/Makefile libffi.pc)
489
490 AC_OUTPUT