14d3a3c3fc665745322977bf13dbbb60ce0b4094
[libffi.git] / libffi / configure.ac
1 dnl Process this with autoconf to create configure
2
3 AC_PREREQ(2.59)
4
5 AC_INIT([libffi], [2.99.3], [http://gcc.gnu.org/bugs.html])
6 AC_CONFIG_HEADERS([fficonfig.h])
7
8 AC_CANONICAL_SYSTEM
9 target_alias=${target_alias-$host_alias}
10
11 . ${srcdir}/configure.host
12
13 AM_INIT_AUTOMAKE
14
15 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
16 # We must force CC to /not/ be precious variables; otherwise
17 # the wrong, non-multilib-adjusted value will be used in multilibs.
18 # As a side effect, we have to subst CFLAGS ourselves.
19
20 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
21 m4_define([_AC_ARG_VAR_PRECIOUS],[])
22 AC_PROG_CC
23 m4_rename([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
24
25 AC_SUBST(CFLAGS)
26
27 AM_PROG_AS
28 AM_PROG_CC_C_O
29 AC_PROG_LIBTOOL
30
31 AM_MAINTAINER_MODE
32
33 AC_CHECK_HEADERS(sys/mman.h)
34 AC_CHECK_FUNCS(mmap)
35 AC_FUNC_MMAP_BLACKLIST
36
37 dnl The -no-testsuite modules omit the test subdir.
38 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
39
40 TARGETDIR="unknown"
41 case "$host" in
42   alpha*-*-*)
43         TARGET=ALPHA; TARGETDIR=alpha;
44         # Support 128-bit long double, changable via command-line switch.
45         HAVE_LONG_DOUBLE='defined(__LONG_DOUBLE_128__)'
46         ;;
47
48   arm*-*-*)
49         TARGET=ARM; TARGETDIR=arm
50         ;;
51
52   cris-*-*)
53         TARGET=LIBFFI_CRIS; TARGETDIR=cris
54         ;;
55
56   frv-*-*)
57         TARGET=FRV; TARGETDIR=frv
58         ;;
59
60   hppa*-*-linux* | parisc*-*-linux*)
61         TARGET=PA_LINUX; TARGETDIR=pa
62         ;;
63   hppa*64-*-hpux*)
64         TARGET=PA64_HPUX; TARGETDIR=pa
65         ;;
66   hppa*-*-hpux*)
67         TARGET=PA_HPUX; TARGETDIR=pa
68         ;;
69
70   i?86-win32* | i?86-*-cygwin* | i?86-*-mingw*)
71         TARGET=X86_WIN32; TARGETDIR=x86
72         ;;
73   i?86-*-darwin*)
74         TARGET=X86_DARWIN; TARGETDIR=x86
75         ;;
76   i?86-*-solaris2.1[[0-9]]*)
77         TARGET=X86_64; TARGETDIR=x86
78         ;;
79   i?86-*-*)
80         TARGET=X86; TARGETDIR=x86
81         ;;
82
83   ia64*-*-*)
84         TARGET=IA64; TARGETDIR=ia64
85         ;;
86
87   m32r*-*-*)
88         TARGET=M32R; TARGETDIR=m32r
89         ;;
90
91   m68k-*-*)
92         TARGET=M68K; TARGETDIR=m68k
93         ;;
94
95   mips-sgi-irix5.* | mips-sgi-irix6.*)
96         TARGET=MIPS; TARGETDIR=mips
97         ;;
98   mips*-*-linux*)
99         TARGET=MIPS; TARGETDIR=mips
100         ;;
101
102   powerpc*-*-linux* | powerpc-*-sysv*)
103         TARGET=POWERPC; TARGETDIR=powerpc
104         ;;
105   powerpc-*-beos*)
106         TARGET=POWERPC; TARGETDIR=powerpc
107         ;;
108   powerpc-*-darwin*)
109         TARGET=POWERPC_DARWIN; TARGETDIR=powerpc
110         ;;
111   powerpc-*-aix* | rs6000-*-aix*)
112         TARGET=POWERPC_AIX; TARGETDIR=powerpc
113         ;;
114   powerpc-*-freebsd*)
115         TARGET=POWERPC_FREEBSD; TARGETDIR=powerpc
116         ;;
117   powerpc*-*-rtems*)
118         TARGET=POWERPC; TARGETDIR=powerpc
119         ;;
120
121   s390-*-* | s390x-*-*)
122         TARGET=S390; TARGETDIR=s390
123         ;;
124
125   sh-*-* | sh[[34]]*-*-*)
126         TARGET=SH; TARGETDIR=sh
127         ;;
128   sh64-*-* | sh5*-*-*)
129         TARGET=SH64; TARGETDIR=sh64
130         ;;
131
132   sparc*-*-*)
133         TARGET=SPARC; TARGETDIR=sparc
134         ;;
135
136   x86_64-*-darwin*)
137         TARGET=X86_DARWIN; TARGETDIR=x86
138         ;;
139   x86_64-*-cygwin* | x86_64-*-mingw*)
140         ;;
141   x86_64-*-*)
142         TARGET=X86_64; TARGETDIR=x86
143         ;;
144 esac
145
146 AC_SUBST(AM_RUNTESTFLAGS)
147
148 if test $TARGETDIR = unknown; then
149   AC_MSG_ERROR(["libffi has not been ported to $host."])
150 fi
151
152 AM_CONDITIONAL(MIPS, test x$TARGET = xMIPS)
153 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
154 AM_CONDITIONAL(X86, test x$TARGET = xX86)
155 AM_CONDITIONAL(X86_WIN32, test x$TARGET = xX86_WIN32)
156 AM_CONDITIONAL(X86_DARWIN, test x$TARGET = xX86_DARWIN)
157 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
158 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
159 AM_CONDITIONAL(M32R, test x$TARGET = xM32R)
160 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
161 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
162 AM_CONDITIONAL(POWERPC_AIX, test x$TARGET = xPOWERPC_AIX)
163 AM_CONDITIONAL(POWERPC_DARWIN, test x$TARGET = xPOWERPC_DARWIN)
164 AM_CONDITIONAL(POWERPC_FREEBSD, test x$TARGET = xPOWERPC_FREEBSD)
165 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
166 AM_CONDITIONAL(LIBFFI_CRIS, test x$TARGET = xLIBFFI_CRIS)
167 AM_CONDITIONAL(FRV, test x$TARGET = xFRV)
168 AM_CONDITIONAL(S390, test x$TARGET = xS390)
169 AM_CONDITIONAL(X86_64, test x$TARGET = xX86_64)
170 AM_CONDITIONAL(SH, test x$TARGET = xSH)
171 AM_CONDITIONAL(SH64, test x$TARGET = xSH64)
172 AM_CONDITIONAL(PA_LINUX, test x$TARGET = xPA_LINUX)
173 AM_CONDITIONAL(PA_HPUX, test x$TARGET = xPA_HPUX)
174 AM_CONDITIONAL(PA64_HPUX, test x$TARGET = xPA64_HPUX)
175
176 AC_HEADER_STDC
177 AC_CHECK_FUNCS(memcpy)
178 AC_FUNC_ALLOCA
179
180 AC_CHECK_SIZEOF(double)
181 AC_CHECK_SIZEOF(long double)
182
183 # Also AC_SUBST this variable for ffi.h.
184 if test -z "$HAVE_LONG_DOUBLE"; then
185   HAVE_LONG_DOUBLE=0
186   if test $ac_cv_sizeof_double != $ac_cv_sizeof_long_double; then
187     if test $ac_cv_sizeof_long_double != 0; then
188       HAVE_LONG_DOUBLE=1
189       AC_DEFINE(HAVE_LONG_DOUBLE, 1, [Define if you have the long double type and it is bigger than a double])
190     fi
191   fi
192 fi
193 AC_SUBST(HAVE_LONG_DOUBLE)
194
195 AC_C_BIGENDIAN
196
197 AC_CACHE_CHECK([assembler .cfi pseudo-op support],
198     libffi_cv_as_cfi_pseudo_op, [
199     libffi_cv_as_cfi_pseudo_op=unknown
200     AC_TRY_COMPILE([asm (".cfi_startproc\n\t.cfi_endproc");],,
201                    [libffi_cv_as_cfi_pseudo_op=yes],
202                    [libffi_cv_as_cfi_pseudo_op=no])
203 ])
204 if test "x$libffi_cv_as_cfi_pseudo_op" = xyes; then
205     AC_DEFINE(HAVE_AS_CFI_PSEUDO_OP, 1,
206               [Define if your assembler supports .cfi_* directives.])
207 fi
208
209 if test x$TARGET = xSPARC; then
210     AC_CACHE_CHECK([assembler and linker support unaligned pc related relocs],
211         libffi_cv_as_sparc_ua_pcrel, [
212         save_CFLAGS="$CFLAGS"
213         save_LDFLAGS="$LDFLAGS"
214         CFLAGS="$CFLAGS -fpic"
215         LDFLAGS="$LDFLAGS -shared"
216         AC_TRY_LINK([asm (".text; foo: nop; .data; .align 4; .byte 0; .uaword %r_disp32(foo); .text");],,
217                     [libffi_cv_as_sparc_ua_pcrel=yes],
218                     [libffi_cv_as_sparc_ua_pcrel=no])
219         CFLAGS="$save_CFLAGS"
220         LDFLAGS="$save_LDFLAGS"])
221     if test "x$libffi_cv_as_sparc_ua_pcrel" = xyes; then
222         AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
223                   [Define if your assembler and linker support unaligned PC relative relocs.])
224     fi
225
226     AC_CACHE_CHECK([assembler .register pseudo-op support],
227        libffi_cv_as_register_pseudo_op, [
228        libffi_cv_as_register_pseudo_op=unknown
229        # Check if we have .register
230        AC_TRY_COMPILE([asm (".register %g2, #scratch");],,
231                        [libffi_cv_as_register_pseudo_op=yes],
232                        [libffi_cv_as_register_pseudo_op=no])
233     ])
234     if test "x$libffi_cv_as_register_pseudo_op" = xyes; then
235        AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
236                [Define if your assembler supports .register.])
237     fi
238 fi
239
240 AC_CACHE_CHECK([whether .eh_frame section should be read-only],
241     libffi_cv_ro_eh_frame, [
242         libffi_cv_ro_eh_frame=no
243         echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
244         if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
245             if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
246                 libffi_cv_ro_eh_frame=yes
247             elif grep '.section.*eh_frame.*#alloc' conftest.c \
248                  | grep -v '#write' > /dev/null; then
249                 libffi_cv_ro_eh_frame=yes
250             fi
251         fi
252         rm -f conftest.*
253     ])
254 if test "x$libffi_cv_ro_eh_frame" = xyes; then
255     AC_DEFINE(HAVE_RO_EH_FRAME, 1,
256               [Define if .eh_frame sections should be read-only.])
257     AC_DEFINE(EH_FRAME_FLAGS, "a",
258               [Define to the flags needed for the .section .eh_frame directive.])
259 else
260     AC_DEFINE(EH_FRAME_FLAGS, "aw",
261               [Define to the flags needed for the .section .eh_frame directive.])
262 fi
263
264 AC_CACHE_CHECK([for __attribute__((visibility("hidden")))],
265     libffi_cv_hidden_visibility_attribute, [
266         echo 'int __attribute__ ((visibility ("hidden"))) foo (void) { return 1; }' > conftest.c
267         libffi_cv_hidden_visibility_attribute=no
268         if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
269             if grep '\.hidden.*foo' conftest.s >/dev/null; then
270                 libffi_cv_hidden_visibility_attribute=yes
271             fi
272         fi
273         rm -f conftest.*
274     ])
275 if test $libffi_cv_hidden_visibility_attribute = yes; then
276     AC_DEFINE(HAVE_HIDDEN_VISIBILITY_ATTRIBUTE, 1,
277               [Define if __attribute__((visibility("hidden"))) is supported.])
278 fi
279
280 AH_BOTTOM([
281 #ifdef HAVE_HIDDEN_VISIBILITY_ATTRIBUTE
282 #ifdef LIBFFI_ASM
283 #define FFI_HIDDEN(name) .hidden name
284 #else
285 #define FFI_HIDDEN __attribute__ ((visibility ("hidden")))
286 #endif
287 #else
288 #ifdef LIBFFI_ASM
289 #define FFI_HIDDEN(name)
290 #else
291 #define FFI_HIDDEN
292 #endif
293 #endif
294 ])
295
296 AC_SUBST(TARGET)
297 AC_SUBST(TARGETDIR)
298
299 AC_SUBST(SHELL)
300
301 AC_ARG_ENABLE(debug,
302 [  --enable-debug          debugging mode],
303   if test "$enable_debug" = "yes"; then
304     AC_DEFINE(FFI_DEBUG, 1, [Define this if you want extra debugging.])
305   fi)
306
307 AC_ARG_ENABLE(structs,
308 [  --disable-structs       omit code for struct support],
309   if test "$enable_structs" = "no"; then
310     AC_DEFINE(FFI_NO_STRUCTS, 1, [Define this is you do not want support for aggregate types.])
311   fi)
312
313 AC_ARG_ENABLE(raw-api,
314 [  --disable-raw-api       make the raw api unavailable],
315   if test "$enable_raw_api" = "no"; then
316     AC_DEFINE(FFI_NO_RAW_API, 1, [Define this is you do not want support for the raw API.])
317   fi)
318
319 AC_ARG_ENABLE(purify-safety,
320 [  --enable-purify-safety  purify-safe mode],
321   if test "$enable_purify_safety" = "yes"; then
322     AC_DEFINE(USING_PURIFY, 1, [Define this if you are using Purify and want to suppress spurious messages.])
323   fi)
324
325 if test -n "$with_cross_host" &&
326    test x"$with_cross_host" != x"no"; then
327   toolexecdir='$(exec_prefix)/$(target_alias)'
328   toolexeclibdir='$(toolexecdir)/lib'
329 else
330   toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
331   toolexeclibdir='$(libdir)'
332 fi
333 multi_os_directory=`$CC -print-multi-os-directory`
334 case $multi_os_directory in
335   .) ;; # Avoid trailing /.
336   *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
337 esac
338 AC_SUBST(toolexecdir)
339 AC_SUBST(toolexeclibdir)
340
341 if test "${multilib}" = "yes"; then
342   multilib_arg="--enable-multilib"
343 else
344   multilib_arg=
345 fi
346
347 AC_CONFIG_COMMANDS(include, [test -d include || mkdir include])
348 AC_CONFIG_COMMANDS(src, [
349 test -d src || mkdir src
350 test -d src/$TARGETDIR || mkdir src/$TARGETDIR
351 ], [TARGETDIR="$TARGETDIR"])
352
353 AC_CONFIG_LINKS(include/ffitarget.h:src/$TARGETDIR/ffitarget.h)
354
355 AC_CONFIG_FILES(include/Makefile include/ffi.h Makefile testsuite/Makefile man/Makefile libffi.pc)
356
357 AC_OUTPUT