052a77bdf5e08775c5baf76058208d325d0f6e9c
[libffi.git] / libffi / configure.ac
1 dnl Process this with autoconf to create configure
2
3 AC_PREREQ(2.59)
4
5 AC_INIT([libffi], [3.0.8], [http://gcc.gnu.org/bugs.html])
6 AC_CONFIG_HEADERS([fficonfig.h])
7
8 AC_CANONICAL_SYSTEM
9 target_alias=${target_alias-$host_alias}
10
11 . ${srcdir}/configure.host
12
13 AM_INIT_AUTOMAKE
14
15 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
16 # We must force CC to /not/ be precious variables; otherwise
17 # the wrong, non-multilib-adjusted value will be used in multilibs.
18 # As a side effect, we have to subst CFLAGS ourselves.
19
20 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
21 m4_define([_AC_ARG_VAR_PRECIOUS],[])
22 AC_PROG_CC
23 m4_rename([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
24
25 AC_SUBST(CFLAGS)
26
27 AM_PROG_AS
28 AM_PROG_CC_C_O
29 AC_PROG_LIBTOOL
30
31 AM_MAINTAINER_MODE
32
33 AC_CHECK_HEADERS(sys/mman.h)
34 AC_CHECK_FUNCS(mmap)
35 AC_FUNC_MMAP_BLACKLIST
36
37 dnl The -no-testsuite modules omit the test subdir.
38 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
39
40 TARGETDIR="unknown"
41 case "$host" in
42   alpha*-*-*)
43         TARGET=ALPHA; TARGETDIR=alpha;
44         # Support 128-bit long double, changable via command-line switch.
45         HAVE_LONG_DOUBLE='defined(__LONG_DOUBLE_128__)'
46         ;;
47
48   arm*-*-*)
49         TARGET=ARM; TARGETDIR=arm
50         ;;
51
52   amd64-*-freebsd*)
53         TARGET=X86_64; TARGETDIR=x86
54         ;;
55
56   cris-*-*)
57         TARGET=LIBFFI_CRIS; TARGETDIR=cris
58         ;;
59
60   frv-*-*)
61         TARGET=FRV; TARGETDIR=frv
62         ;;
63
64   hppa*-*-linux* | parisc*-*-linux*)
65         TARGET=PA_LINUX; TARGETDIR=pa
66         ;;
67   hppa*64-*-hpux*)
68         TARGET=PA64_HPUX; TARGETDIR=pa
69         ;;
70   hppa*-*-hpux*)
71         TARGET=PA_HPUX; TARGETDIR=pa
72         ;;
73
74   i386-*-freebsd* | i386-*-openbsd*)
75         TARGET=X86_FREEBSD; TARGETDIR=x86
76         ;;
77   i?86-win32* | i?86-*-cygwin* | i?86-*-mingw*)
78         TARGET=X86_WIN32; TARGETDIR=x86
79         ;;
80   i?86-*-darwin*)
81         TARGET=X86_DARWIN; TARGETDIR=x86
82         ;;
83   i?86-*-solaris2.1[[0-9]]*)
84         TARGET=X86_64; TARGETDIR=x86
85         ;;
86   i?86-*-*)
87         TARGET=X86; TARGETDIR=x86
88         ;;
89
90   ia64*-*-*)
91         TARGET=IA64; TARGETDIR=ia64
92         ;;
93
94   m32r*-*-*)
95         TARGET=M32R; TARGETDIR=m32r
96         ;;
97
98   m68k-*-*)
99         TARGET=M68K; TARGETDIR=m68k
100         ;;
101
102   mips-sgi-irix5.* | mips-sgi-irix6.*)
103         TARGET=MIPS; TARGETDIR=mips
104         ;;
105   mips*-*-linux*)
106         TARGET=MIPS; TARGETDIR=mips
107         ;;
108
109   powerpc*-*-linux* | powerpc-*-sysv*)
110         TARGET=POWERPC; TARGETDIR=powerpc
111         ;;
112   powerpc-*-beos*)
113         TARGET=POWERPC; TARGETDIR=powerpc
114         ;;
115   powerpc-*-darwin*)
116         TARGET=POWERPC_DARWIN; TARGETDIR=powerpc
117         ;;
118   powerpc-*-aix* | rs6000-*-aix*)
119         TARGET=POWERPC_AIX; TARGETDIR=powerpc
120         ;;
121   powerpc-*-freebsd*)
122         TARGET=POWERPC_FREEBSD; TARGETDIR=powerpc
123         ;;
124   powerpc*-*-rtems*)
125         TARGET=POWERPC; TARGETDIR=powerpc
126         ;;
127
128   s390-*-* | s390x-*-*)
129         TARGET=S390; TARGETDIR=s390
130         ;;
131
132   sh-*-* | sh[[34]]*-*-*)
133         TARGET=SH; TARGETDIR=sh
134         ;;
135   sh64-*-* | sh5*-*-*)
136         TARGET=SH64; TARGETDIR=sh64
137         ;;
138
139   sparc*-*-*)
140         TARGET=SPARC; TARGETDIR=sparc
141         ;;
142
143   x86_64-*-darwin*)
144         TARGET=X86_DARWIN; TARGETDIR=x86
145         ;;
146   x86_64-*-cygwin* | x86_64-*-mingw*)
147         ;;
148   x86_64-*-*)
149         TARGET=X86_64; TARGETDIR=x86
150         ;;
151 esac
152
153 AC_SUBST(AM_RUNTESTFLAGS)
154
155 if test $TARGETDIR = unknown; then
156   AC_MSG_ERROR(["libffi has not been ported to $host."])
157 fi
158
159 AM_CONDITIONAL(MIPS, test x$TARGET = xMIPS)
160 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
161 AM_CONDITIONAL(X86, test x$TARGET = xX86)
162 AM_CONDITIONAL(X86_FREEBSD, test x$TARGET = xX86_FREEBSD)
163 AM_CONDITIONAL(X86_WIN32, test x$TARGET = xX86_WIN32)
164 AM_CONDITIONAL(X86_DARWIN, test x$TARGET = xX86_DARWIN)
165 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
166 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
167 AM_CONDITIONAL(M32R, test x$TARGET = xM32R)
168 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
169 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
170 AM_CONDITIONAL(POWERPC_AIX, test x$TARGET = xPOWERPC_AIX)
171 AM_CONDITIONAL(POWERPC_DARWIN, test x$TARGET = xPOWERPC_DARWIN)
172 AM_CONDITIONAL(POWERPC_FREEBSD, test x$TARGET = xPOWERPC_FREEBSD)
173 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
174 AM_CONDITIONAL(LIBFFI_CRIS, test x$TARGET = xLIBFFI_CRIS)
175 AM_CONDITIONAL(FRV, test x$TARGET = xFRV)
176 AM_CONDITIONAL(S390, test x$TARGET = xS390)
177 AM_CONDITIONAL(X86_64, test x$TARGET = xX86_64)
178 AM_CONDITIONAL(SH, test x$TARGET = xSH)
179 AM_CONDITIONAL(SH64, test x$TARGET = xSH64)
180 AM_CONDITIONAL(PA_LINUX, test x$TARGET = xPA_LINUX)
181 AM_CONDITIONAL(PA_HPUX, test x$TARGET = xPA_HPUX)
182 AM_CONDITIONAL(PA64_HPUX, test x$TARGET = xPA64_HPUX)
183
184 AC_HEADER_STDC
185 AC_CHECK_FUNCS(memcpy)
186 AC_FUNC_ALLOCA
187
188 AC_CHECK_SIZEOF(double)
189 AC_CHECK_SIZEOF(long double)
190
191 # Also AC_SUBST this variable for ffi.h.
192 if test -z "$HAVE_LONG_DOUBLE"; then
193   HAVE_LONG_DOUBLE=0
194   if test $ac_cv_sizeof_double != $ac_cv_sizeof_long_double; then
195     if test $ac_cv_sizeof_long_double != 0; then
196       HAVE_LONG_DOUBLE=1
197       AC_DEFINE(HAVE_LONG_DOUBLE, 1, [Define if you have the long double type and it is bigger than a double])
198     fi
199   fi
200 fi
201 AC_SUBST(HAVE_LONG_DOUBLE)
202
203 AC_C_BIGENDIAN
204
205 AC_CACHE_CHECK([assembler .cfi pseudo-op support],
206     libffi_cv_as_cfi_pseudo_op, [
207     libffi_cv_as_cfi_pseudo_op=unknown
208     AC_TRY_COMPILE([asm (".cfi_startproc\n\t.cfi_endproc");],,
209                    [libffi_cv_as_cfi_pseudo_op=yes],
210                    [libffi_cv_as_cfi_pseudo_op=no])
211 ])
212 if test "x$libffi_cv_as_cfi_pseudo_op" = xyes; then
213     AC_DEFINE(HAVE_AS_CFI_PSEUDO_OP, 1,
214               [Define if your assembler supports .cfi_* directives.])
215 fi
216
217 if test x$TARGET = xSPARC; then
218     AC_CACHE_CHECK([assembler and linker support unaligned pc related relocs],
219         libffi_cv_as_sparc_ua_pcrel, [
220         save_CFLAGS="$CFLAGS"
221         save_LDFLAGS="$LDFLAGS"
222         CFLAGS="$CFLAGS -fpic"
223         LDFLAGS="$LDFLAGS -shared"
224         AC_TRY_LINK([asm (".text; foo: nop; .data; .align 4; .byte 0; .uaword %r_disp32(foo); .text");],,
225                     [libffi_cv_as_sparc_ua_pcrel=yes],
226                     [libffi_cv_as_sparc_ua_pcrel=no])
227         CFLAGS="$save_CFLAGS"
228         LDFLAGS="$save_LDFLAGS"])
229     if test "x$libffi_cv_as_sparc_ua_pcrel" = xyes; then
230         AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
231                   [Define if your assembler and linker support unaligned PC relative relocs.])
232     fi
233
234     AC_CACHE_CHECK([assembler .register pseudo-op support],
235        libffi_cv_as_register_pseudo_op, [
236        libffi_cv_as_register_pseudo_op=unknown
237        # Check if we have .register
238        AC_TRY_COMPILE([asm (".register %g2, #scratch");],,
239                        [libffi_cv_as_register_pseudo_op=yes],
240                        [libffi_cv_as_register_pseudo_op=no])
241     ])
242     if test "x$libffi_cv_as_register_pseudo_op" = xyes; then
243        AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
244                [Define if your assembler supports .register.])
245     fi
246 fi
247
248 if test x$TARGET = xX86 || test x$TARGET = xX86_64; then
249     AC_CACHE_CHECK([assembler supports pc related relocs],
250         libffi_cv_as_x86_pcrel, [
251         libffi_cv_as_x86_pcrel=yes
252         echo '.text; foo: nop; .data; .long foo-.; .text' > conftest.s
253         if $CC $CFLAGS -c conftest.s 2>&1 | grep -i warning > /dev/null; then
254             libffi_cv_as_x86_pcrel=no
255         fi
256         ])
257     if test "x$libffi_cv_as_x86_pcrel" = xyes; then
258         AC_DEFINE(HAVE_AS_X86_PCREL, 1,
259                   [Define if your assembler supports PC relative relocs.])
260     fi
261 fi
262
263 AC_CACHE_CHECK([whether .eh_frame section should be read-only],
264     libffi_cv_ro_eh_frame, [
265         libffi_cv_ro_eh_frame=no
266         echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
267         if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
268             if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
269                 libffi_cv_ro_eh_frame=yes
270             elif grep '.section.*eh_frame.*#alloc' conftest.c \
271                  | grep -v '#write' > /dev/null; then
272                 libffi_cv_ro_eh_frame=yes
273             fi
274         fi
275         rm -f conftest.*
276     ])
277 if test "x$libffi_cv_ro_eh_frame" = xyes; then
278     AC_DEFINE(HAVE_RO_EH_FRAME, 1,
279               [Define if .eh_frame sections should be read-only.])
280     AC_DEFINE(EH_FRAME_FLAGS, "a",
281               [Define to the flags needed for the .section .eh_frame directive.])
282 else
283     AC_DEFINE(EH_FRAME_FLAGS, "aw",
284               [Define to the flags needed for the .section .eh_frame directive.])
285 fi
286
287 AC_CACHE_CHECK([for __attribute__((visibility("hidden")))],
288     libffi_cv_hidden_visibility_attribute, [
289         echo 'int __attribute__ ((visibility ("hidden"))) foo (void) { return 1; }' > conftest.c
290         libffi_cv_hidden_visibility_attribute=no
291         if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
292             if grep '\.hidden.*foo' conftest.s >/dev/null; then
293                 libffi_cv_hidden_visibility_attribute=yes
294             fi
295         fi
296         rm -f conftest.*
297     ])
298 if test $libffi_cv_hidden_visibility_attribute = yes; then
299     AC_DEFINE(HAVE_HIDDEN_VISIBILITY_ATTRIBUTE, 1,
300               [Define if __attribute__((visibility("hidden"))) is supported.])
301 fi
302
303 AH_BOTTOM([
304 #ifdef HAVE_HIDDEN_VISIBILITY_ATTRIBUTE
305 #ifdef LIBFFI_ASM
306 #define FFI_HIDDEN(name) .hidden name
307 #else
308 #define FFI_HIDDEN __attribute__ ((visibility ("hidden")))
309 #endif
310 #else
311 #ifdef LIBFFI_ASM
312 #define FFI_HIDDEN(name)
313 #else
314 #define FFI_HIDDEN
315 #endif
316 #endif
317 ])
318
319 AC_SUBST(TARGET)
320 AC_SUBST(TARGETDIR)
321
322 AC_SUBST(SHELL)
323
324 AC_ARG_ENABLE(debug,
325 [  --enable-debug          debugging mode],
326   if test "$enable_debug" = "yes"; then
327     AC_DEFINE(FFI_DEBUG, 1, [Define this if you want extra debugging.])
328   fi)
329
330 AC_ARG_ENABLE(structs,
331 [  --disable-structs       omit code for struct support],
332   if test "$enable_structs" = "no"; then
333     AC_DEFINE(FFI_NO_STRUCTS, 1, [Define this is you do not want support for aggregate types.])
334   fi)
335
336 AC_ARG_ENABLE(raw-api,
337 [  --disable-raw-api       make the raw api unavailable],
338   if test "$enable_raw_api" = "no"; then
339     AC_DEFINE(FFI_NO_RAW_API, 1, [Define this is you do not want support for the raw API.])
340   fi)
341
342 AC_ARG_ENABLE(purify-safety,
343 [  --enable-purify-safety  purify-safe mode],
344   if test "$enable_purify_safety" = "yes"; then
345     AC_DEFINE(USING_PURIFY, 1, [Define this if you are using Purify and want to suppress spurious messages.])
346   fi)
347
348 if test -n "$with_cross_host" &&
349    test x"$with_cross_host" != x"no"; then
350   toolexecdir='$(exec_prefix)/$(target_alias)'
351   toolexeclibdir='$(toolexecdir)/lib'
352 else
353   toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
354   toolexeclibdir='$(libdir)'
355 fi
356 multi_os_directory=`$CC -print-multi-os-directory`
357 case $multi_os_directory in
358   .) ;; # Avoid trailing /.
359   *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
360 esac
361 AC_SUBST(toolexecdir)
362 AC_SUBST(toolexeclibdir)
363
364 if test "${multilib}" = "yes"; then
365   multilib_arg="--enable-multilib"
366 else
367   multilib_arg=
368 fi
369
370 AC_CONFIG_COMMANDS(include, [test -d include || mkdir include])
371 AC_CONFIG_COMMANDS(src, [
372 test -d src || mkdir src
373 test -d src/$TARGETDIR || mkdir src/$TARGETDIR
374 ], [TARGETDIR="$TARGETDIR"])
375
376 AC_CONFIG_LINKS(include/ffitarget.h:src/$TARGETDIR/ffitarget.h)
377
378 AC_CONFIG_FILES(include/Makefile include/ffi.h Makefile testsuite/Makefile man/Makefile libffi.pc)
379
380 AC_OUTPUT