Many new patches
[libffi.git] / .pc / more-openbsd / configure.ac
1 dnl Process this with autoconf to create configure
2
3 AC_PREREQ(2.63)
4
5 AC_INIT([libffi], [3.0.10rc10], [http://sourceware.org/libffi.html])
6 AC_CONFIG_HEADERS([fficonfig.h])
7
8 AC_CANONICAL_SYSTEM
9 target_alias=${target_alias-$host_alias}
10
11 . ${srcdir}/configure.host
12
13 AX_ENABLE_BUILDDIR
14
15 AM_INIT_AUTOMAKE
16
17 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
18 # We must force CC to /not/ be precious variables; otherwise
19 # the wrong, non-multilib-adjusted value will be used in multilibs.
20 # As a side effect, we have to subst CFLAGS ourselves.
21 # Also save and restore CFLAGS, since AC_PROG_CC will come up with
22 # defaults of its own if none are provided.
23
24 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
25 m4_define([_AC_ARG_VAR_PRECIOUS],[])
26 save_CFLAGS=$CFLAGS
27 AC_PROG_CC
28 CFLAGS=$save_CFLAGS
29 m4_undefine([_AC_ARG_VAR_PRECIOUS])
30 m4_rename([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
31
32 AC_SUBST(CFLAGS)
33
34 AM_PROG_AS
35 AM_PROG_CC_C_O
36 AC_PROG_LIBTOOL
37 AC_CONFIG_MACRO_DIR([m4])
38
39 AX_CC_MAXOPT
40 AX_CFLAGS_WARN_ALL
41 if test "x$GCC" = "xyes"; then
42   CFLAGS="$CFLAGS -fexceptions"
43 fi
44
45 AM_MAINTAINER_MODE
46
47 AC_CHECK_HEADERS(sys/mman.h)
48 AC_CHECK_FUNCS(mmap)
49 AC_FUNC_MMAP_BLACKLIST
50
51 dnl The -no-testsuite modules omit the test subdir.
52 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
53
54 TARGETDIR="unknown"
55 case "$host" in
56   alpha*-*-*)
57         TARGET=ALPHA; TARGETDIR=alpha;
58         # Support 128-bit long double, changeable via command-line switch.
59         HAVE_LONG_DOUBLE='defined(__LONG_DOUBLE_128__)'
60         ;;
61
62   arm*-*-*)
63         TARGET=ARM; TARGETDIR=arm
64         ;;
65
66   amd64-*-freebsd* | amd64-*-openbsd*)
67         TARGET=X86_64; TARGETDIR=x86
68         ;;
69
70   amd64-*-freebsd*)
71         TARGET=X86_64; TARGETDIR=x86
72         ;;
73
74   avr32*-*-*)
75         TARGET=AVR32; TARGETDIR=avr32
76         ;;
77
78   cris-*-*)
79         TARGET=LIBFFI_CRIS; TARGETDIR=cris
80         ;;
81
82   frv-*-*)
83         TARGET=FRV; TARGETDIR=frv
84         ;;
85
86   hppa*-*-linux* | parisc*-*-linux*)
87         TARGET=PA_LINUX; TARGETDIR=pa
88         ;;
89   hppa*64-*-hpux*)
90         TARGET=PA64_HPUX; TARGETDIR=pa
91         ;;
92   hppa*-*-hpux*)
93         TARGET=PA_HPUX; TARGETDIR=pa
94         ;;
95
96   i?86-*-freebsd* | i?86-*-openbsd*)
97         TARGET=X86_FREEBSD; TARGETDIR=x86
98         ;;
99   i?86-win32* | i?86-*-cygwin* | i?86-*-mingw* | i?86-*-os2* | i?86-*-interix*)
100         TARGET=X86_WIN32; TARGETDIR=x86
101         # All mingw/cygwin/win32 builds require -no-undefined for sharedlib.
102         # We must also check with_cross_host to decide if this is a native
103         # or cross-build and select where to install dlls appropriately.
104         if test -n "$with_cross_host" &&
105            test x"$with_cross_host" != x"no"; then
106           AM_LTLDFLAGS='-no-undefined -bindir "$(toolexeclibdir)"';
107         else
108           AM_LTLDFLAGS='-no-undefined -bindir "$(bindir)"';
109         fi
110         ;;
111   i?86-*-darwin*)
112         TARGET=X86_DARWIN; TARGETDIR=x86
113         ;;
114   i?86-*-solaris2.1[[0-9]]*)
115         TARGET=X86_64; TARGETDIR=x86
116         ;;
117   i?86-*-*)
118         TARGET=X86; TARGETDIR=x86
119         ;;
120
121   ia64*-*-*)
122         TARGET=IA64; TARGETDIR=ia64
123         ;;
124
125   m32r*-*-*)
126         TARGET=M32R; TARGETDIR=m32r
127         ;;
128
129   m68k-*-*)
130         TARGET=M68K; TARGETDIR=m68k
131         ;;
132
133   mips-sgi-irix5.* | mips-sgi-irix6.* | mips*-*-rtems*)
134         TARGET=MIPS; TARGETDIR=mips
135         ;;
136   mips*-*-linux*)
137         # Support 128-bit long double for NewABI.
138         HAVE_LONG_DOUBLE='defined(__mips64)'
139         TARGET=MIPS; TARGETDIR=mips
140         ;;
141
142   powerpc*-*-linux* | powerpc-*-sysv*)
143         TARGET=POWERPC; TARGETDIR=powerpc
144         ;;
145   powerpc-*-beos*)
146         TARGET=POWERPC; TARGETDIR=powerpc
147         ;;
148   powerpc-*-darwin* | powerpc64-*-darwin*)
149         TARGET=POWERPC_DARWIN; TARGETDIR=powerpc
150         ;;
151   powerpc-*-aix* | rs6000-*-aix*)
152         TARGET=POWERPC_AIX; TARGETDIR=powerpc
153         ;;
154   powerpc-*-freebsd*)
155         TARGET=POWERPC_FREEBSD; TARGETDIR=powerpc
156         ;;
157   powerpc64-*-freebsd*)
158         TARGET=POWERPC; TARGETDIR=powerpc
159         ;;
160   powerpc*-*-rtems*)
161         TARGET=POWERPC; TARGETDIR=powerpc
162         ;;
163
164   s390-*-* | s390x-*-*)
165         TARGET=S390; TARGETDIR=s390
166         ;;
167
168   sh-*-* | sh[[34]]*-*-*)
169         TARGET=SH; TARGETDIR=sh
170         ;;
171   sh64-*-* | sh5*-*-*)
172         TARGET=SH64; TARGETDIR=sh64
173         ;;
174
175   sparc*-*-*)
176         TARGET=SPARC; TARGETDIR=sparc
177         ;;
178
179   x86_64-*-darwin*)
180         TARGET=X86_DARWIN; TARGETDIR=x86
181         ;;
182
183   x86_64-*-cygwin* | x86_64-*-mingw*)
184         TARGET=X86_WIN64; TARGETDIR=x86
185         ;;
186
187   x86_64-*-*)
188         TARGET=X86_64; TARGETDIR=x86
189         ;;
190 esac
191
192 AC_SUBST(AM_RUNTESTFLAGS)
193 AC_SUBST(AM_LTLDFLAGS)
194
195 if test $TARGETDIR = unknown; then
196   AC_MSG_ERROR(["libffi has not been ported to $host."])
197 fi
198
199 AM_CONDITIONAL(MIPS, test x$TARGET = xMIPS)
200 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
201 AM_CONDITIONAL(X86, test x$TARGET = xX86)
202 AM_CONDITIONAL(X86_FREEBSD, test x$TARGET = xX86_FREEBSD)
203 AM_CONDITIONAL(X86_WIN32, test x$TARGET = xX86_WIN32)
204 AM_CONDITIONAL(X86_WIN64, test x$TARGET = xX86_WIN64)
205 AM_CONDITIONAL(X86_DARWIN, test x$TARGET = xX86_DARWIN)
206 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
207 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
208 AM_CONDITIONAL(M32R, test x$TARGET = xM32R)
209 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
210 AM_CONDITIONAL(MOXIE, test x$TARGET = xMOXIE)
211 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
212 AM_CONDITIONAL(POWERPC_AIX, test x$TARGET = xPOWERPC_AIX)
213 AM_CONDITIONAL(POWERPC_DARWIN, test x$TARGET = xPOWERPC_DARWIN)
214 AM_CONDITIONAL(POWERPC_FREEBSD, test x$TARGET = xPOWERPC_FREEBSD)
215 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
216 AM_CONDITIONAL(AVR32, test x$TARGET = xAVR32)
217 AM_CONDITIONAL(LIBFFI_CRIS, test x$TARGET = xLIBFFI_CRIS)
218 AM_CONDITIONAL(FRV, test x$TARGET = xFRV)
219 AM_CONDITIONAL(S390, test x$TARGET = xS390)
220 AM_CONDITIONAL(X86_64, test x$TARGET = xX86_64)
221 AM_CONDITIONAL(SH, test x$TARGET = xSH)
222 AM_CONDITIONAL(SH64, test x$TARGET = xSH64)
223 AM_CONDITIONAL(PA_LINUX, test x$TARGET = xPA_LINUX)
224 AM_CONDITIONAL(PA_HPUX, test x$TARGET = xPA_HPUX)
225 AM_CONDITIONAL(PA64_HPUX, test x$TARGET = xPA64_HPUX)
226
227 AC_HEADER_STDC
228 AC_CHECK_FUNCS(memcpy)
229 AC_FUNC_ALLOCA
230
231 AC_CHECK_SIZEOF(double)
232 AC_CHECK_SIZEOF(long double)
233
234 # Also AC_SUBST this variable for ffi.h.
235 if test -z "$HAVE_LONG_DOUBLE"; then
236   HAVE_LONG_DOUBLE=0
237   if test $ac_cv_sizeof_double != $ac_cv_sizeof_long_double; then
238     if test $ac_cv_sizeof_long_double != 0; then
239       HAVE_LONG_DOUBLE=1
240       AC_DEFINE(HAVE_LONG_DOUBLE, 1, [Define if you have the long double type and it is bigger than a double])
241     fi
242   fi
243 fi
244 AC_SUBST(HAVE_LONG_DOUBLE)
245
246 AC_C_BIGENDIAN
247
248 AC_CACHE_CHECK([assembler .cfi pseudo-op support],
249     libffi_cv_as_cfi_pseudo_op, [
250     libffi_cv_as_cfi_pseudo_op=unknown
251     AC_TRY_COMPILE([asm (".cfi_startproc\n\t.cfi_endproc");],,
252                    [libffi_cv_as_cfi_pseudo_op=yes],
253                    [libffi_cv_as_cfi_pseudo_op=no])
254 ])
255 if test "x$libffi_cv_as_cfi_pseudo_op" = xyes; then
256     AC_DEFINE(HAVE_AS_CFI_PSEUDO_OP, 1,
257               [Define if your assembler supports .cfi_* directives.])
258 fi
259
260 if test x$TARGET = xSPARC; then
261     AC_CACHE_CHECK([assembler and linker support unaligned pc related relocs],
262         libffi_cv_as_sparc_ua_pcrel, [
263         save_CFLAGS="$CFLAGS"
264         save_LDFLAGS="$LDFLAGS"
265         CFLAGS="$CFLAGS -fpic"
266         LDFLAGS="$LDFLAGS -shared"
267         AC_TRY_LINK([asm (".text; foo: nop; .data; .align 4; .byte 0; .uaword %r_disp32(foo); .text");],,
268                     [libffi_cv_as_sparc_ua_pcrel=yes],
269                     [libffi_cv_as_sparc_ua_pcrel=no])
270         CFLAGS="$save_CFLAGS"
271         LDFLAGS="$save_LDFLAGS"])
272     if test "x$libffi_cv_as_sparc_ua_pcrel" = xyes; then
273         AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
274                   [Define if your assembler and linker support unaligned PC relative relocs.])
275     fi
276
277     AC_CACHE_CHECK([assembler .register pseudo-op support],
278        libffi_cv_as_register_pseudo_op, [
279        libffi_cv_as_register_pseudo_op=unknown
280        # Check if we have .register
281        AC_TRY_COMPILE([asm (".register %g2, #scratch");],,
282                        [libffi_cv_as_register_pseudo_op=yes],
283                        [libffi_cv_as_register_pseudo_op=no])
284     ])
285     if test "x$libffi_cv_as_register_pseudo_op" = xyes; then
286        AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
287                [Define if your assembler supports .register.])
288     fi
289 fi
290
291 if test x$TARGET = xX86 || test x$TARGET = xX86_WIN32 || test x$TARGET = xX86_64; then
292     AC_CACHE_CHECK([assembler supports pc related relocs],
293         libffi_cv_as_x86_pcrel, [
294         libffi_cv_as_x86_pcrel=no
295         echo '.text; foo: nop; .data; .long foo-.; .text' > conftest.s
296         if $CC $CFLAGS -c conftest.s > /dev/null; then
297            libffi_cv_as_x86_pcrel=yes
298         fi
299         ])
300     if test "x$libffi_cv_as_x86_pcrel" = xyes; then
301         AC_DEFINE(HAVE_AS_X86_PCREL, 1,
302                   [Define if your assembler supports PC relative relocs.])
303     fi
304
305     AC_CACHE_CHECK([assembler .ascii pseudo-op support],
306        libffi_cv_as_ascii_pseudo_op, [
307        libffi_cv_as_ascii_pseudo_op=unknown
308        # Check if we have .ascii
309        AC_TRY_COMPILE([asm (".ascii \\"string\\"");],,
310                        [libffi_cv_as_ascii_pseudo_op=yes],
311                        [libffi_cv_as_ascii_pseudo_op=no])
312     ])
313     if test "x$libffi_cv_as_ascii_pseudo_op" = xyes; then
314        AC_DEFINE(HAVE_AS_ASCII_PSEUDO_OP, 1,
315                [Define if your assembler supports .ascii.])
316     fi
317
318     AC_CACHE_CHECK([assembler .string pseudo-op support],
319        libffi_cv_as_string_pseudo_op, [
320        libffi_cv_as_string_pseudo_op=unknown
321        # Check if we have .string
322        AC_TRY_COMPILE([asm (".string \\"string\\"");],,
323                        [libffi_cv_as_string_pseudo_op=yes],
324                        [libffi_cv_as_string_pseudo_op=no])
325     ])
326     if test "x$libffi_cv_as_string_pseudo_op" = xyes; then
327        AC_DEFINE(HAVE_AS_STRING_PSEUDO_OP, 1,
328                [Define if your assembler supports .string.])
329     fi
330 fi
331
332 if test x$TARGET = xX86_WIN64; then
333     LT_SYS_SYMBOL_USCORE
334     if test "x$sys_symbol_underscore" = xyes; then
335         AC_DEFINE(SYMBOL_UNDERSCORE, 1, [Define if symbols are underscored.])
336     fi
337 fi
338
339
340 FFI_EXEC_TRAMPOLINE_TABLE=0
341 case "$target" in
342      *arm*-apple-darwin*)
343        FFI_EXEC_TRAMPOLINE_TABLE=1
344        AC_DEFINE(FFI_EXEC_TRAMPOLINE_TABLE, 1,
345                  [Cannot use PROT_EXEC on this target, so, we revert to
346                    alternative means])
347      ;;
348      *-apple-darwin10* | *-*-freebsd* | *-*-openbsd* | *-pc-solaris*)
349        AC_DEFINE(FFI_MMAP_EXEC_WRIT, 1,
350                  [Cannot use malloc on this target, so, we revert to
351                    alternative means])
352      ;;
353 esac
354 AM_CONDITIONAL(FFI_EXEC_TRAMPOLINE_TABLE, test x$FFI_EXEC_TRAMPOLINE_TABLE = x1)
355 AC_SUBST(FFI_EXEC_TRAMPOLINE_TABLE)
356
357 if test x$TARGET = xX86_64; then
358     AC_CACHE_CHECK([assembler supports unwind section type],
359         libffi_cv_as_x86_64_unwind_section_type, [
360         libffi_cv_as_x86_64_unwind_section_type=yes
361         echo '.section .eh_frame,"a",@unwind' > conftest.s
362         if $CC $CFLAGS -c conftest.s 2>&1 | grep -i warning > /dev/null; then
363             libffi_cv_as_x86_64_unwind_section_type=no
364         fi
365         ])
366     if test "x$libffi_cv_as_x86_64_unwind_section_type" = xyes; then
367         AC_DEFINE(HAVE_AS_X86_64_UNWIND_SECTION_TYPE, 1,
368                   [Define if your assembler supports unwind section type.])
369     fi
370 fi
371
372 if test "x$GCC" = "xyes"; then
373   AC_CACHE_CHECK([whether .eh_frame section should be read-only],
374       libffi_cv_ro_eh_frame, [
375         libffi_cv_ro_eh_frame=no
376         echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
377         if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
378             if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
379                 libffi_cv_ro_eh_frame=yes
380             elif grep '.section.*eh_frame.*#alloc' conftest.c \
381                  | grep -v '#write' > /dev/null; then
382                 libffi_cv_ro_eh_frame=yes
383             fi
384         fi
385         rm -f conftest.*
386       ])
387   if test "x$libffi_cv_ro_eh_frame" = xyes; then
388       AC_DEFINE(HAVE_RO_EH_FRAME, 1,
389               [Define if .eh_frame sections should be read-only.])
390       AC_DEFINE(EH_FRAME_FLAGS, "a",
391               [Define to the flags needed for the .section .eh_frame directive.  ])
392   else
393       AC_DEFINE(EH_FRAME_FLAGS, "aw",
394               [Define to the flags needed for the .section .eh_frame directive.  ])
395   fi
396
397   AC_CACHE_CHECK([for __attribute__((visibility("hidden")))],
398       libffi_cv_hidden_visibility_attribute, [
399         echo 'int __attribute__ ((visibility ("hidden"))) foo (void) { return 1  ; }' > conftest.c
400         libffi_cv_hidden_visibility_attribute=no
401         if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
402             if grep '\.hidden.*foo' conftest.s >/dev/null; then
403                 libffi_cv_hidden_visibility_attribute=yes
404             fi
405         fi
406         rm -f conftest.*
407       ])
408   if test $libffi_cv_hidden_visibility_attribute = yes; then
409       AC_DEFINE(HAVE_HIDDEN_VISIBILITY_ATTRIBUTE, 1,
410               [Define if __attribute__((visibility("hidden"))) is supported.])
411   fi
412 fi
413
414 AH_BOTTOM([
415 #ifdef HAVE_HIDDEN_VISIBILITY_ATTRIBUTE
416 #ifdef LIBFFI_ASM
417 #define FFI_HIDDEN(name) .hidden name
418 #else
419 #define FFI_HIDDEN __attribute__ ((visibility ("hidden")))
420 #endif
421 #else
422 #ifdef LIBFFI_ASM
423 #define FFI_HIDDEN(name)
424 #else
425 #define FFI_HIDDEN
426 #endif
427 #endif
428 ])
429
430 AC_SUBST(TARGET)
431 AC_SUBST(TARGETDIR)
432
433 AC_SUBST(SHELL)
434
435 AC_ARG_ENABLE(debug,
436 [  --enable-debug          debugging mode],
437   if test "$enable_debug" = "yes"; then
438     AC_DEFINE(FFI_DEBUG, 1, [Define this if you want extra debugging.])
439   fi)
440 AM_CONDITIONAL(FFI_DEBUG, test "$enable_debug" = "yes")
441
442 AC_ARG_ENABLE(structs,
443 [  --disable-structs       omit code for struct support],
444   if test "$enable_structs" = "no"; then
445     AC_DEFINE(FFI_NO_STRUCTS, 1, [Define this is you do not want support for aggregate types.])
446   fi)
447
448 AC_ARG_ENABLE(raw-api,
449 [  --disable-raw-api       make the raw api unavailable],
450   if test "$enable_raw_api" = "no"; then
451     AC_DEFINE(FFI_NO_RAW_API, 1, [Define this is you do not want support for the raw API.])
452   fi)
453
454 AC_ARG_ENABLE(purify-safety,
455 [  --enable-purify-safety  purify-safe mode],
456   if test "$enable_purify_safety" = "yes"; then
457     AC_DEFINE(USING_PURIFY, 1, [Define this if you are using Purify and want to suppress spurious messages.])
458   fi)
459
460 # These variables are only ever used when we cross-build to X86_WIN32.
461 # And we only support this with GCC, so...
462 if test x"$GCC" != x"no"; then
463   if test -n "$with_cross_host" &&
464      test x"$with_cross_host" != x"no"; then
465     toolexecdir='$(exec_prefix)/$(target_alias)'
466     toolexeclibdir='$(toolexecdir)/lib'
467   else
468     toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
469     toolexeclibdir='$(libdir)'
470   fi
471   multi_os_directory=`$CC -print-multi-os-directory`
472   case $multi_os_directory in
473     .) ;; # Avoid trailing /.
474     *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
475   esac
476   AC_SUBST(toolexecdir)
477   AC_SUBST(toolexeclibdir)
478 fi
479
480 if test "${multilib}" = "yes"; then
481   multilib_arg="--enable-multilib"
482 else
483   multilib_arg=
484 fi
485
486 AC_CONFIG_COMMANDS(include, [test -d include || mkdir include])
487 AC_CONFIG_COMMANDS(src, [
488 test -d src || mkdir src
489 test -d src/$TARGETDIR || mkdir src/$TARGETDIR
490 ], [TARGETDIR="$TARGETDIR"])
491
492 AC_CONFIG_LINKS(include/ffitarget.h:src/$TARGETDIR/ffitarget.h)
493
494 AC_CONFIG_FILES(include/Makefile include/ffi.h Makefile testsuite/Makefile man/Makefile libffi.pc)
495
496 AC_OUTPUT