Many new patches
[libffi.git] / .pc / debug-build / configure.ac
1 dnl Process this with autoconf to create configure
2
3 AC_PREREQ(2.63)
4
5 AC_INIT([libffi], [3.0.10rc10], [http://sourceware.org/libffi.html])
6 AC_CONFIG_HEADERS([fficonfig.h])
7
8 AC_CANONICAL_SYSTEM
9 target_alias=${target_alias-$host_alias}
10
11 . ${srcdir}/configure.host
12
13 AM_INIT_AUTOMAKE
14
15 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
16 # We must force CC to /not/ be precious variables; otherwise
17 # the wrong, non-multilib-adjusted value will be used in multilibs.
18 # As a side effect, we have to subst CFLAGS ourselves.
19
20 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
21 m4_define([_AC_ARG_VAR_PRECIOUS],[])
22 AC_PROG_CC
23 m4_undefine([_AC_ARG_VAR_PRECIOUS])
24 m4_rename([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
25
26 AC_SUBST(CFLAGS)
27
28 AM_PROG_AS
29 AM_PROG_CC_C_O
30 AC_PROG_LIBTOOL
31 AC_CONFIG_MACRO_DIR([m4])
32
33 AM_MAINTAINER_MODE
34
35 AC_CHECK_HEADERS(sys/mman.h)
36 AC_CHECK_FUNCS(mmap)
37 AC_FUNC_MMAP_BLACKLIST
38
39 dnl The -no-testsuite modules omit the test subdir.
40 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
41
42 TARGETDIR="unknown"
43 case "$host" in
44   alpha*-*-*)
45         TARGET=ALPHA; TARGETDIR=alpha;
46         # Support 128-bit long double, changeable via command-line switch.
47         HAVE_LONG_DOUBLE='defined(__LONG_DOUBLE_128__)'
48         ;;
49
50   arm*-*-*)
51         TARGET=ARM; TARGETDIR=arm
52         ;;
53
54   amd64-*-freebsd* | amd64-*-openbsd*)
55         TARGET=X86_64; TARGETDIR=x86
56         ;;
57
58   amd64-*-freebsd*)
59         TARGET=X86_64; TARGETDIR=x86
60         ;;
61
62   avr32*-*-*)
63         TARGET=AVR32; TARGETDIR=avr32
64         ;;
65
66   cris-*-*)
67         TARGET=LIBFFI_CRIS; TARGETDIR=cris
68         ;;
69
70   frv-*-*)
71         TARGET=FRV; TARGETDIR=frv
72         ;;
73
74   hppa*-*-linux* | parisc*-*-linux*)
75         TARGET=PA_LINUX; TARGETDIR=pa
76         ;;
77   hppa*64-*-hpux*)
78         TARGET=PA64_HPUX; TARGETDIR=pa
79         ;;
80   hppa*-*-hpux*)
81         TARGET=PA_HPUX; TARGETDIR=pa
82         ;;
83
84   i?86-*-freebsd* | i?86-*-openbsd*)
85         TARGET=X86_FREEBSD; TARGETDIR=x86
86         ;;
87   i?86-win32* | i?86-*-cygwin* | i?86-*-mingw* | i?86-*-os2*)
88         TARGET=X86_WIN32; TARGETDIR=x86
89         # All mingw/cygwin/win32 builds require -no-undefined for sharedlib.
90         # We must also check with_cross_host to decide if this is a native
91         # or cross-build and select where to install dlls appropriately.
92         if test -n "$with_cross_host" &&
93            test x"$with_cross_host" != x"no"; then
94           AM_LTLDFLAGS='-no-undefined -bindir "$(toolexeclibdir)"';
95         else
96           AM_LTLDFLAGS='-no-undefined -bindir "$(bindir)"';
97         fi
98         ;;
99   i?86-*-darwin*)
100         TARGET=X86_DARWIN; TARGETDIR=x86
101         ;;
102   i?86-*-solaris2.1[[0-9]]*)
103         TARGET=X86_64; TARGETDIR=x86
104         ;;
105   i?86-*-*)
106         TARGET=X86; TARGETDIR=x86
107         ;;
108
109   ia64*-*-*)
110         TARGET=IA64; TARGETDIR=ia64
111         ;;
112
113   m32r*-*-*)
114         TARGET=M32R; TARGETDIR=m32r
115         ;;
116
117   m68k-*-*)
118         TARGET=M68K; TARGETDIR=m68k
119         ;;
120
121   mips-sgi-irix5.* | mips-sgi-irix6.* | mips*-*-rtems*)
122         TARGET=MIPS; TARGETDIR=mips
123         ;;
124   mips*-*-linux*)
125         # Support 128-bit long double for NewABI.
126         HAVE_LONG_DOUBLE='defined(__mips64)'
127         TARGET=MIPS; TARGETDIR=mips
128         ;;
129
130   powerpc*-*-linux* | powerpc-*-sysv*)
131         TARGET=POWERPC; TARGETDIR=powerpc
132         ;;
133   powerpc-*-beos*)
134         TARGET=POWERPC; TARGETDIR=powerpc
135         ;;
136   powerpc-*-darwin*)
137         TARGET=POWERPC_DARWIN; TARGETDIR=powerpc
138         ;;
139   powerpc-*-aix* | rs6000-*-aix*)
140         TARGET=POWERPC_AIX; TARGETDIR=powerpc
141         ;;
142   powerpc-*-freebsd*)
143         TARGET=POWERPC_FREEBSD; TARGETDIR=powerpc
144         ;;
145  powerpc64-*-freebsd*)
146         TARGET=POWERPC; TARGETDIR=powerpc
147         ;;
148   powerpc*-*-rtems*)
149         TARGET=POWERPC; TARGETDIR=powerpc
150         ;;
151
152   s390-*-* | s390x-*-*)
153         TARGET=S390; TARGETDIR=s390
154         ;;
155
156   sh-*-* | sh[[34]]*-*-*)
157         TARGET=SH; TARGETDIR=sh
158         ;;
159   sh64-*-* | sh5*-*-*)
160         TARGET=SH64; TARGETDIR=sh64
161         ;;
162
163   sparc*-*-*)
164         TARGET=SPARC; TARGETDIR=sparc
165         ;;
166
167   x86_64-*-darwin*)
168         TARGET=X86_DARWIN; TARGETDIR=x86
169         ;;
170
171   x86_64-*-cygwin* | x86_64-*-mingw*)
172         TARGET=X86_WIN64; TARGETDIR=x86
173         ;;
174
175   x86_64-*-*)
176         TARGET=X86_64; TARGETDIR=x86
177         ;;
178 esac
179
180 AC_SUBST(AM_RUNTESTFLAGS)
181 AC_SUBST(AM_LTLDFLAGS)
182
183 if test $TARGETDIR = unknown; then
184   AC_MSG_ERROR(["libffi has not been ported to $host."])
185 fi
186
187 AM_CONDITIONAL(MIPS, test x$TARGET = xMIPS)
188 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
189 AM_CONDITIONAL(X86, test x$TARGET = xX86)
190 AM_CONDITIONAL(X86_FREEBSD, test x$TARGET = xX86_FREEBSD)
191 AM_CONDITIONAL(X86_WIN32, test x$TARGET = xX86_WIN32)
192 AM_CONDITIONAL(X86_WIN64, test x$TARGET = xX86_WIN64)
193 AM_CONDITIONAL(X86_DARWIN, test x$TARGET = xX86_DARWIN)
194 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
195 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
196 AM_CONDITIONAL(M32R, test x$TARGET = xM32R)
197 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
198 AM_CONDITIONAL(MOXIE, test x$TARGET = xMOXIE)
199 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
200 AM_CONDITIONAL(POWERPC_AIX, test x$TARGET = xPOWERPC_AIX)
201 AM_CONDITIONAL(POWERPC_DARWIN, test x$TARGET = xPOWERPC_DARWIN)
202 AM_CONDITIONAL(POWERPC_FREEBSD, test x$TARGET = xPOWERPC_FREEBSD)
203 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
204 AM_CONDITIONAL(AVR32, test x$TARGET = xAVR32)
205 AM_CONDITIONAL(LIBFFI_CRIS, test x$TARGET = xLIBFFI_CRIS)
206 AM_CONDITIONAL(FRV, test x$TARGET = xFRV)
207 AM_CONDITIONAL(S390, test x$TARGET = xS390)
208 AM_CONDITIONAL(X86_64, test x$TARGET = xX86_64)
209 AM_CONDITIONAL(SH, test x$TARGET = xSH)
210 AM_CONDITIONAL(SH64, test x$TARGET = xSH64)
211 AM_CONDITIONAL(PA_LINUX, test x$TARGET = xPA_LINUX)
212 AM_CONDITIONAL(PA_HPUX, test x$TARGET = xPA_HPUX)
213 AM_CONDITIONAL(PA64_HPUX, test x$TARGET = xPA64_HPUX)
214
215 AC_HEADER_STDC
216 AC_CHECK_FUNCS(memcpy)
217 AC_FUNC_ALLOCA
218
219 AC_CHECK_SIZEOF(double)
220 AC_CHECK_SIZEOF(long double)
221
222 # Also AC_SUBST this variable for ffi.h.
223 if test -z "$HAVE_LONG_DOUBLE"; then
224   HAVE_LONG_DOUBLE=0
225   if test $ac_cv_sizeof_double != $ac_cv_sizeof_long_double; then
226     if test $ac_cv_sizeof_long_double != 0; then
227       HAVE_LONG_DOUBLE=1
228       AC_DEFINE(HAVE_LONG_DOUBLE, 1, [Define if you have the long double type and it is bigger than a double])
229     fi
230   fi
231 fi
232 AC_SUBST(HAVE_LONG_DOUBLE)
233
234 AC_C_BIGENDIAN
235
236 AC_CACHE_CHECK([assembler .cfi pseudo-op support],
237     libffi_cv_as_cfi_pseudo_op, [
238     libffi_cv_as_cfi_pseudo_op=unknown
239     AC_TRY_COMPILE([asm (".cfi_startproc\n\t.cfi_endproc");],,
240                    [libffi_cv_as_cfi_pseudo_op=yes],
241                    [libffi_cv_as_cfi_pseudo_op=no])
242 ])
243 if test "x$libffi_cv_as_cfi_pseudo_op" = xyes; then
244     AC_DEFINE(HAVE_AS_CFI_PSEUDO_OP, 1,
245               [Define if your assembler supports .cfi_* directives.])
246 fi
247
248 if test x$TARGET = xSPARC; then
249     AC_CACHE_CHECK([assembler and linker support unaligned pc related relocs],
250         libffi_cv_as_sparc_ua_pcrel, [
251         save_CFLAGS="$CFLAGS"
252         save_LDFLAGS="$LDFLAGS"
253         CFLAGS="$CFLAGS -fpic"
254         LDFLAGS="$LDFLAGS -shared"
255         AC_TRY_LINK([asm (".text; foo: nop; .data; .align 4; .byte 0; .uaword %r_disp32(foo); .text");],,
256                     [libffi_cv_as_sparc_ua_pcrel=yes],
257                     [libffi_cv_as_sparc_ua_pcrel=no])
258         CFLAGS="$save_CFLAGS"
259         LDFLAGS="$save_LDFLAGS"])
260     if test "x$libffi_cv_as_sparc_ua_pcrel" = xyes; then
261         AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
262                   [Define if your assembler and linker support unaligned PC relative relocs.])
263     fi
264
265     AC_CACHE_CHECK([assembler .register pseudo-op support],
266        libffi_cv_as_register_pseudo_op, [
267        libffi_cv_as_register_pseudo_op=unknown
268        # Check if we have .register
269        AC_TRY_COMPILE([asm (".register %g2, #scratch");],,
270                        [libffi_cv_as_register_pseudo_op=yes],
271                        [libffi_cv_as_register_pseudo_op=no])
272     ])
273     if test "x$libffi_cv_as_register_pseudo_op" = xyes; then
274        AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
275                [Define if your assembler supports .register.])
276     fi
277 fi
278
279 if test x$TARGET = xX86 || test x$TARGET = xX86_WIN32 || test x$TARGET = xX86_64; then
280     AC_CACHE_CHECK([assembler supports pc related relocs],
281         libffi_cv_as_x86_pcrel, [
282         libffi_cv_as_x86_pcrel=yes
283         echo '.text; foo: nop; .data; .long foo-.; .text' > conftest.s
284         if $CC $CFLAGS -c conftest.s 2>&1 | $EGREP -i 'illegal|warning' > /dev/null; then
285             libffi_cv_as_x86_pcrel=no
286         fi
287         ])
288     if test "x$libffi_cv_as_x86_pcrel" = xyes; then
289         AC_DEFINE(HAVE_AS_X86_PCREL, 1,
290                   [Define if your assembler supports PC relative relocs.])
291     fi
292
293     AC_CACHE_CHECK([assembler .ascii pseudo-op support],
294        libffi_cv_as_ascii_pseudo_op, [
295        libffi_cv_as_ascii_pseudo_op=unknown
296        # Check if we have .ascii
297        AC_TRY_COMPILE([asm (".ascii \\"string\\"");],,
298                        [libffi_cv_as_ascii_pseudo_op=yes],
299                        [libffi_cv_as_ascii_pseudo_op=no])
300     ])
301     if test "x$libffi_cv_as_ascii_pseudo_op" = xyes; then
302        AC_DEFINE(HAVE_AS_ASCII_PSEUDO_OP, 1,
303                [Define if your assembler supports .ascii.])
304     fi
305
306     AC_CACHE_CHECK([assembler .string pseudo-op support],
307        libffi_cv_as_string_pseudo_op, [
308        libffi_cv_as_string_pseudo_op=unknown
309        # Check if we have .string
310        AC_TRY_COMPILE([asm (".string \\"string\\"");],,
311                        [libffi_cv_as_string_pseudo_op=yes],
312                        [libffi_cv_as_string_pseudo_op=no])
313     ])
314     if test "x$libffi_cv_as_string_pseudo_op" = xyes; then
315        AC_DEFINE(HAVE_AS_STRING_PSEUDO_OP, 1,
316                [Define if your assembler supports .string.])
317     fi
318 fi
319
320 case "$target" in
321      *-apple-darwin10* | *-*-freebsd* | *-*-openbsd* | *-pc-solaris*)
322        AC_DEFINE(FFI_MMAP_EXEC_WRIT, 1,
323                  [Cannot use malloc on this target, so, we revert to
324                    alternative means])
325      ;;
326 esac
327
328 if test x$TARGET = xX86_64; then
329     AC_CACHE_CHECK([assembler supports unwind section type],
330         libffi_cv_as_x86_64_unwind_section_type, [
331         libffi_cv_as_x86_64_unwind_section_type=yes
332         echo '.section .eh_frame,"a",@unwind' > conftest.s
333         if $CC $CFLAGS -c conftest.s 2>&1 | grep -i warning > /dev/null; then
334             libffi_cv_as_x86_64_unwind_section_type=no
335         fi
336         ])
337     if test "x$libffi_cv_as_x86_64_unwind_section_type" = xyes; then
338         AC_DEFINE(HAVE_AS_X86_64_UNWIND_SECTION_TYPE, 1,
339                   [Define if your assembler supports unwind section type.])
340     fi
341 fi
342
343 AC_CACHE_CHECK([whether .eh_frame section should be read-only],
344     libffi_cv_ro_eh_frame, [
345         libffi_cv_ro_eh_frame=no
346         echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
347         if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
348             if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
349                 libffi_cv_ro_eh_frame=yes
350             elif grep '.section.*eh_frame.*#alloc' conftest.c \
351                  | grep -v '#write' > /dev/null; then
352                 libffi_cv_ro_eh_frame=yes
353             fi
354         fi
355         rm -f conftest.*
356     ])
357 if test "x$libffi_cv_ro_eh_frame" = xyes; then
358     AC_DEFINE(HAVE_RO_EH_FRAME, 1,
359               [Define if .eh_frame sections should be read-only.])
360     AC_DEFINE(EH_FRAME_FLAGS, "a",
361               [Define to the flags needed for the .section .eh_frame directive.])
362 else
363     AC_DEFINE(EH_FRAME_FLAGS, "aw",
364               [Define to the flags needed for the .section .eh_frame directive.])
365 fi
366
367 AC_CACHE_CHECK([for __attribute__((visibility("hidden")))],
368     libffi_cv_hidden_visibility_attribute, [
369         echo 'int __attribute__ ((visibility ("hidden"))) foo (void) { return 1; }' > conftest.c
370         libffi_cv_hidden_visibility_attribute=no
371         if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
372             if grep '\.hidden.*foo' conftest.s >/dev/null; then
373                 libffi_cv_hidden_visibility_attribute=yes
374             fi
375         fi
376         rm -f conftest.*
377     ])
378 if test $libffi_cv_hidden_visibility_attribute = yes; then
379     AC_DEFINE(HAVE_HIDDEN_VISIBILITY_ATTRIBUTE, 1,
380               [Define if __attribute__((visibility("hidden"))) is supported.])
381 fi
382
383 AH_BOTTOM([
384 #ifdef HAVE_HIDDEN_VISIBILITY_ATTRIBUTE
385 #ifdef LIBFFI_ASM
386 #define FFI_HIDDEN(name) .hidden name
387 #else
388 #define FFI_HIDDEN __attribute__ ((visibility ("hidden")))
389 #endif
390 #else
391 #ifdef LIBFFI_ASM
392 #define FFI_HIDDEN(name)
393 #else
394 #define FFI_HIDDEN
395 #endif
396 #endif
397 ])
398
399 AC_SUBST(TARGET)
400 AC_SUBST(TARGETDIR)
401
402 AC_SUBST(SHELL)
403
404 AC_ARG_ENABLE(debug,
405 [  --enable-debug          debugging mode],
406   if test "$enable_debug" = "yes"; then
407     AC_DEFINE(FFI_DEBUG, 1, [Define this if you want extra debugging.])
408   fi)
409
410 AC_ARG_ENABLE(structs,
411 [  --disable-structs       omit code for struct support],
412   if test "$enable_structs" = "no"; then
413     AC_DEFINE(FFI_NO_STRUCTS, 1, [Define this is you do not want support for aggregate types.])
414   fi)
415
416 AC_ARG_ENABLE(raw-api,
417 [  --disable-raw-api       make the raw api unavailable],
418   if test "$enable_raw_api" = "no"; then
419     AC_DEFINE(FFI_NO_RAW_API, 1, [Define this is you do not want support for the raw API.])
420   fi)
421
422 AC_ARG_ENABLE(purify-safety,
423 [  --enable-purify-safety  purify-safe mode],
424   if test "$enable_purify_safety" = "yes"; then
425     AC_DEFINE(USING_PURIFY, 1, [Define this if you are using Purify and want to suppress spurious messages.])
426   fi)
427
428 # These variables are only ever used when we cross-build to X86_WIN32.
429 # And we only support this with GCC, so...
430 if test x"$GCC" != x"no"; then
431   if test -n "$with_cross_host" &&
432      test x"$with_cross_host" != x"no"; then
433     toolexecdir='$(exec_prefix)/$(target_alias)'
434     toolexeclibdir='$(toolexecdir)/lib'
435   else
436     toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
437     toolexeclibdir='$(libdir)'
438   fi
439   multi_os_directory=`$CC -print-multi-os-directory`
440   case $multi_os_directory in
441     .) ;; # Avoid trailing /.
442     *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
443   esac
444   AC_SUBST(toolexecdir)
445   AC_SUBST(toolexeclibdir)
446 fi
447
448 if test "${multilib}" = "yes"; then
449   multilib_arg="--enable-multilib"
450 else
451   multilib_arg=
452 fi
453
454 AC_CONFIG_COMMANDS(include, [test -d include || mkdir include])
455 AC_CONFIG_COMMANDS(src, [
456 test -d src || mkdir src
457 test -d src/$TARGETDIR || mkdir src/$TARGETDIR
458 ], [TARGETDIR="$TARGETDIR"])
459
460 AC_CONFIG_LINKS(include/ffitarget.h:src/$TARGETDIR/ffitarget.h)
461
462 AC_CONFIG_FILES(include/Makefile include/ffi.h Makefile testsuite/Makefile man/Makefile libffi.pc)
463
464 AC_OUTPUT