Add comments.
[hadrian.git] / src / Oracles / ModuleFiles.hs
1 {-# LANGUAGE DeriveDataTypeable, GeneralizedNewtypeDeriving #-}
2 module Oracles.ModuleFiles (
3 findGenerator, haskellSources, moduleFilesOracle
4 ) where
5
6 import qualified Data.HashMap.Strict as Map
7
8 import Base
9 import Context
10 import Expression
11 import Oracles.PackageData
12 import Settings.Paths
13
14 newtype ModuleFilesKey = ModuleFilesKey Context
15 deriving (Show, Typeable, Eq, Hashable, Binary, NFData)
16
17 newtype Generator = Generator (Context, FilePath)
18 deriving (Show, Typeable, Eq, Hashable, Binary, NFData)
19
20 -- The following generators and corresponding source extensions are supported:
21 determineBuilder :: FilePath -> Maybe Builder
22 determineBuilder file = case takeExtension file of
23 ".x" -> Just Alex
24 ".y" -> Just Happy
25 ".ly" -> Just Happy
26 ".hsc" -> Just Hsc2Hs
27 _ -> Nothing
28
29 -- | Find the generator for a given 'Context' and a source file. For example:
30 -- findGenerator (Context Stage1 compiler vanilla)
31 -- ".build/stage1/compiler/build/Lexer.hs"
32 -- == Just ("compiler/parser/Lexer.x", Alex)
33 -- findGenerator (Context Stage1 base vanilla)
34 -- ".build/stage1/base/build/Prelude.hs"
35 -- == Nothing
36 findGenerator :: Context -> FilePath -> Action (Maybe (FilePath, Builder))
37 findGenerator context file = do
38 maybeSource <- askOracle $ Generator (context, file)
39 return $ do
40 source <- maybeSource
41 builder <- determineBuilder source
42 return (source, builder)
43
44 -- | Find all Haskell source files for a given 'Context'.
45 haskellSources :: Context -> Action [FilePath]
46 haskellSources context = do
47 let autogen = contextPath context -/- "build/autogen"
48 -- Generated source files live in build/ and have extension "hs", except
49 -- that GHC/Prim.hs lives in build/autogen/. TODO: fix the inconsistency?
50 let modFile ("GHC.Prim", _) = autogen -/- "GHC/Prim.hs"
51 modFile (m, Nothing ) = generatedFile context m
52 modFile (m, Just file )
53 | takeExtension file `elem` [".hs", ".lhs"] = file
54 | otherwise = generatedFile context m
55 map modFile <$> contextFiles context
56
57 generatedFile :: Context -> String -> FilePath
58 generatedFile context moduleName =
59 contextPath context -/- "build" -/- replaceEq '.' '/' moduleName <.> "hs"
60
61 contextFiles :: Context -> Action [(String, Maybe FilePath)]
62 contextFiles context@Context {..} = do
63 let path = contextPath context
64 modules <- fmap sort . pkgDataList $ Modules path
65 zip modules <$> askOracle (ModuleFilesKey context)
66
67 -- | This is an important oracle whose role is to find and cache module source
68 -- files. It takes a 'Context', looks up corresponding source directories @dirs@
69 -- and sorted list of module names @modules@, and for each module, e.g.
70 -- @A.B.C@, returns a 'FilePath' of the form @dir/A/B/C.extension@, such that
71 -- @dir@ belongs to @dirs@, and file @dir/A/B/C.extension@ exists, or 'Nothing'
72 -- if there is no such file. If more than one matching file is found an error is
73 -- raised. For example, for @Context Stage1 compiler vanilla@, @dirs@ will
74 -- contain ["compiler/codeGen", "compiler/parser"], and @modules@ will contain
75 -- ["CodeGen.Platform.ARM", "Config", "Lexer"]; the oracle will produce a list
76 -- containing [Just "compiler/codeGen/CodeGen/Platform/ARM.hs", Nothing,
77 -- Just "compiler/parser/Lexer.x"].
78 moduleFilesOracle :: Rules ()
79 moduleFilesOracle = void $ do
80 void $ addOracle $ \(ModuleFilesKey context) -> do
81 let path = contextPath context
82 autogen = path -/- "build/autogen"
83 srcDirs <- pkgDataList $ SrcDirs path
84 modules <- fmap sort . pkgDataList $ Modules path
85 let dirs = autogen : map (pkgPath (package context) -/-) srcDirs
86 modDirFiles = groupSort $ map decodeModule modules
87 result <- fmap concat . forM dirs $ \dir -> do
88 todo <- filterM (doesDirectoryExist . (dir -/-) . fst) modDirFiles
89 forM todo $ \(mDir, mFiles) -> do
90 let fullDir = dir -/- mDir
91 files <- getDirectoryFiles fullDir ["*"]
92 let noBoot = filter (not . (isSuffixOf "-boot")) files
93 cmp fe f = compare (dropExtension fe) f
94 found = intersectOrd cmp noBoot mFiles
95 return (map (fullDir -/-) found, mDir)
96 let pairs = sort [ (encodeModule d f, f) | (fs, d) <- result, f <- fs ]
97 multi = [ (m, f1, f2) | (m, f1):(n, f2):_ <- tails pairs, m == n ]
98 unless (null multi) $ do
99 let (m, f1, f2) = head multi
100 putError $ "Module " ++ m ++ " has more than one source file: "
101 ++ f1 ++ " and " ++ f2 ++ "."
102 return $ lookupAll modules pairs
103
104 -- Optimisation: we discard .(l)hs files here, because they are never used
105 -- as generators, and hence would be discarded in 'findGenerator' anyway.
106 gens <- newCache $ \context -> do
107 files <- contextFiles context
108 return $ Map.fromList [ (generatedFile context modName, src)
109 | (modName, Just src) <- files
110 , takeExtension src `notElem` [".hs", ".lhs"] ]
111
112 addOracle $ \(Generator (context, file)) -> Map.lookup file <$> gens context