Move decode/encodeModule to Oracles.ModuleFiles.
[hadrian.git] / src / Oracles / ModuleFiles.hs
1 {-# LANGUAGE DeriveDataTypeable, GeneralizedNewtypeDeriving #-}
2 module Oracles.ModuleFiles (
3 decodeModule, encodeModule, findGenerator, haskellSources, moduleFilesOracle
4 ) where
5
6 import qualified Data.HashMap.Strict as Map
7
8 import Base
9 import Context
10 import Expression
11 import Oracles.PackageData
12 import Settings.Paths
13
14 newtype ModuleFilesKey = ModuleFilesKey (Stage, Package)
15 deriving (Show, Typeable, Eq, Hashable, Binary, NFData)
16
17 newtype Generator = Generator (Stage, Package, FilePath)
18 deriving (Show, Typeable, Eq, Hashable, Binary, NFData)
19
20 -- The following generators and corresponding source extensions are supported:
21 determineBuilder :: FilePath -> Maybe Builder
22 determineBuilder file = case takeExtension file of
23 ".x" -> Just Alex
24 ".y" -> Just Happy
25 ".ly" -> Just Happy
26 ".hsc" -> Just Hsc2Hs
27 _ -> Nothing
28
29 -- | Given a module name extract the directory and file name, e.g.:
30 --
31 -- > decodeModule "Data.Functor.Identity" == ("Data/Functor/", "Identity")
32 -- > decodeModule "Prelude" == ("./", "Prelude")
33 decodeModule :: String -> (FilePath, String)
34 decodeModule = splitFileName . replaceEq '.' '/'
35
36 -- | Given the directory and file name find the corresponding module name, e.g.:
37 --
38 -- > encodeModule "Data/Functor/" "Identity.hs" == "Data.Functor.Identity"
39 -- > encodeModule "./" "Prelude" == "Prelude"
40 -- > uncurry encodeModule (decodeModule name) == name
41 encodeModule :: FilePath -> String -> String
42 encodeModule dir file = replaceEq '/' '.' $ dir -/- takeBaseName file
43
44 -- | Find the generator for a given 'Context' and a source file. For example:
45 -- findGenerator (Context Stage1 compiler vanilla)
46 -- ".build/stage1/compiler/build/Lexer.hs"
47 -- == Just ("compiler/parser/Lexer.x", Alex)
48 -- findGenerator (Context Stage1 base vanilla)
49 -- ".build/stage1/base/build/Prelude.hs"
50 -- == Nothing
51 findGenerator :: Context -> FilePath -> Action (Maybe (FilePath, Builder))
52 findGenerator Context {..} file = do
53 maybeSource <- askOracle $ Generator (stage, package, file)
54 return $ do
55 source <- maybeSource
56 builder <- determineBuilder source
57 return (source, builder)
58
59 -- | Find all Haskell source files for a given 'Context'.
60 haskellSources :: Context -> Action [FilePath]
61 haskellSources context = do
62 let autogen = buildPath context -/- "autogen"
63 -- Generated source files live in buildPath and have extension "hs", except
64 -- for GHC/Prim.hs that lives in autogen. TODO: fix the inconsistency?
65 let modFile ("GHC.Prim", _) = autogen -/- "GHC/Prim.hs"
66 modFile (m, Nothing ) = generatedFile context m
67 modFile (m, Just file )
68 | takeExtension file `elem` [".hs", ".lhs"] = file
69 | otherwise = generatedFile context m
70 map modFile <$> contextFiles context
71
72 generatedFile :: Context -> String -> FilePath
73 generatedFile context moduleName =
74 buildPath context -/- replaceEq '.' '/' moduleName <.> "hs"
75
76 contextFiles :: Context -> Action [(String, Maybe FilePath)]
77 contextFiles context@Context {..} = do
78 modules <- fmap sort . pkgDataList . Modules $ buildPath context
79 zip modules <$> askOracle (ModuleFilesKey (stage, package))
80
81 -- | This is an important oracle whose role is to find and cache module source
82 -- files. It takes a 'Stage' and a 'Package', looks up corresponding source
83 -- directories @dirs@ and a sorted list of module names @modules@, and for each
84 -- module, e.g. @A.B.C@, returns a 'FilePath' of the form @dir/A/B/C.extension@,
85 -- such that @dir@ belongs to @dirs@, and file @dir/A/B/C.extension@ exists, or
86 -- 'Nothing' if there is no such file. If more than one matching file is found
87 -- an error is raised. For example, for 'Stage1' and 'compiler', @dirs@ will
88 -- contain ["compiler/codeGen", "compiler/parser"], and @modules@ will contain
89 -- ["CodeGen.Platform.ARM", "Config", "Lexer"]; the oracle will produce a list
90 -- containing [Just "compiler/codeGen/CodeGen/Platform/ARM.hs", Nothing,
91 -- Just "compiler/parser/Lexer.x"]. The oracle ignores @.(l)hs-boot@ files.
92 moduleFilesOracle :: Rules ()
93 moduleFilesOracle = void $ do
94 void $ addOracle $ \(ModuleFilesKey (stage, package)) -> do
95 let path = buildPath $ vanillaContext stage package
96 srcDirs <- pkgDataList $ SrcDirs path
97 modules <- fmap sort . pkgDataList $ Modules path
98 let dirs = (path -/- "autogen") : map (pkgPath package -/-) srcDirs
99 modDirFiles = groupSort $ map decodeModule modules
100 result <- fmap concat . forM dirs $ \dir -> do
101 todo <- filterM (doesDirectoryExist . (dir -/-) . fst) modDirFiles
102 forM todo $ \(mDir, mFiles) -> do
103 let fullDir = dir -/- mDir
104 files <- getDirectoryFiles fullDir ["*"]
105 let noBoot = filter (not . (isSuffixOf "-boot")) files
106 cmp fe f = compare (dropExtension fe) f
107 found = intersectOrd cmp noBoot mFiles
108 return (map (fullDir -/-) found, mDir)
109 let pairs = sort [ (encodeModule d f, f) | (fs, d) <- result, f <- fs ]
110 multi = [ (m, f1, f2) | (m, f1):(n, f2):_ <- tails pairs, m == n ]
111 unless (null multi) $ do
112 let (m, f1, f2) = head multi
113 putError $ "Module " ++ m ++ " has more than one source file: "
114 ++ f1 ++ " and " ++ f2 ++ "."
115 return $ lookupAll modules pairs
116
117 -- Optimisation: we discard .(l)hs files here, because they are never used
118 -- as generators, and hence would be discarded in 'findGenerator' anyway.
119 generators <- newCache $ \(stage, package) -> do
120 let context = vanillaContext stage package
121 files <- contextFiles context
122 return $ Map.fromList [ (generatedFile context modName, src)
123 | (modName, Just src) <- files
124 , takeExtension src `notElem` [".hs", ".lhs"] ]
125
126 addOracle $ \(Generator (stage, package, file)) ->
127 Map.lookup file <$> generators (stage, package)