ff98b748c93ee7097f8626f635c68b7ca061621c
[ghc.git] / compiler / parser / Parser.y.pp
1 --                                                              -*-haskell-*-
2 -- ---------------------------------------------------------------------------
3 -- (c) The University of Glasgow 1997-2003
4 ---
5 -- The GHC grammar.
6 --
7 -- Author(s): Simon Marlow, Sven Panne 1997, 1998, 1999
8 -- ---------------------------------------------------------------------------
9
10 {
11 {-# LANGUAGE BangPatterns #-} -- required for versions of Happy before 1.18.6
12 {-# OPTIONS -Wwarn -w #-}
13 -- The above warning supression flag is a temporary kludge.
14 -- While working on this module you are encouraged to remove it and fix
15 -- any warnings in the module. See
16 --     http://hackage.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#Warnings
17 -- for details
18
19 {-# OPTIONS_GHC -O0 -fno-ignore-interface-pragmas #-}
20 {-
21 Careful optimisation of the parser: we don't want to throw everything
22 at it, because that takes too long and doesn't buy much, but we do want
23 to inline certain key external functions, so we instruct GHC not to
24 throw away inlinings as it would normally do in -O0 mode.
25 -}
26
27 module Parser ( parseModule, parseStmt, parseIdentifier, parseType,
28                 parseHeader ) where
29
30 import HsSyn
31 import RdrHsSyn
32 import HscTypes         ( IsBootInterface, WarningTxt(..) )
33 import Lexer
34 import RdrName
35 import TcEvidence       ( emptyTcEvBinds )
36 import TysPrim          ( liftedTypeKindTyConName, eqPrimTyCon )
37 import TysWiredIn       ( unitTyCon, unitDataCon, tupleTyCon, tupleCon, nilDataCon,
38                           unboxedUnitTyCon, unboxedUnitDataCon,
39                           listTyCon_RDR, parrTyCon_RDR, consDataCon_RDR, eqTyCon_RDR )
40 import Type             ( funTyCon )
41 import ForeignCall
42 import OccName          ( varName, dataName, tcClsName, tvName )
43 import DataCon          ( DataCon, dataConName )
44 import SrcLoc
45 import Module
46 import StaticFlags      ( opt_SccProfilingOn, opt_Hpc )
47 import Kind             ( Kind, liftedTypeKind, unliftedTypeKind, mkArrowKind )
48 import Class            ( FunDep )
49 import BasicTypes
50 import DynFlags
51 import OrdList
52 import HaddockUtils
53
54 import FastString
55 import Maybes           ( orElse )
56 import Outputable
57
58 import Control.Monad    ( unless )
59 import GHC.Exts
60 import Data.Char
61 import Control.Monad    ( mplus )
62 }
63
64 {-
65 -----------------------------------------------------------------------------
66 24 Februar 2006
67
68 Conflicts: 33 shift/reduce
69            1 reduce/reduce
70
71 The reduce/reduce conflict is weird.  It's between tyconsym and consym, and I
72 would think the two should never occur in the same context.
73
74   -=chak
75
76 -----------------------------------------------------------------------------
77 31 December 2006
78
79 Conflicts: 34 shift/reduce
80            1 reduce/reduce
81
82 The reduce/reduce conflict is weird.  It's between tyconsym and consym, and I
83 would think the two should never occur in the same context.
84
85   -=chak
86
87 -----------------------------------------------------------------------------
88 6 December 2006
89
90 Conflicts: 32 shift/reduce
91            1 reduce/reduce
92
93 The reduce/reduce conflict is weird.  It's between tyconsym and consym, and I
94 would think the two should never occur in the same context.
95
96   -=chak
97
98 -----------------------------------------------------------------------------
99 26 July 2006
100
101 Conflicts: 37 shift/reduce
102            1 reduce/reduce
103
104 The reduce/reduce conflict is weird.  It's between tyconsym and consym, and I
105 would think the two should never occur in the same context.
106
107   -=chak
108
109 -----------------------------------------------------------------------------
110 Conflicts: 38 shift/reduce (1.25)
111
112 10 for abiguity in 'if x then y else z + 1'             [State 178]
113         (shift parses as 'if x then y else (z + 1)', as per longest-parse rule)
114         10 because op might be: : - ! * . `x` VARSYM CONSYM QVARSYM QCONSYM
115
116 1 for ambiguity in 'if x then y else z :: T'            [State 178]
117         (shift parses as 'if x then y else (z :: T)', as per longest-parse rule)
118
119 4 for ambiguity in 'if x then y else z -< e'            [State 178]
120         (shift parses as 'if x then y else (z -< T)', as per longest-parse rule)
121         There are four such operators: -<, >-, -<<, >>-
122
123
124 2 for ambiguity in 'case v of { x :: T -> T ... } '     [States 11, 253]
125         Which of these two is intended?
126           case v of
127             (x::T) -> T         -- Rhs is T
128     or
129           case v of
130             (x::T -> T) -> ..   -- Rhs is ...
131
132 10 for ambiguity in 'e :: a `b` c'.  Does this mean     [States 11, 253]
133         (e::a) `b` c, or 
134         (e :: (a `b` c))
135     As well as `b` we can have !, VARSYM, QCONSYM, and CONSYM, hence 5 cases
136     Same duplication between states 11 and 253 as the previous case
137
138 1 for ambiguity in 'let ?x ...'                         [State 329]
139         the parser can't tell whether the ?x is the lhs of a normal binding or
140         an implicit binding.  Fortunately resolving as shift gives it the only
141         sensible meaning, namely the lhs of an implicit binding.
142
143 1 for ambiguity in '{-# RULES "name" [ ... #-}          [State 382]
144         we don't know whether the '[' starts the activation or not: it
145         might be the start of the declaration with the activation being
146         empty.  --SDM 1/4/2002
147
148 1 for ambiguity in '{-# RULES "name" forall = ... #-}'  [State 474]
149         since 'forall' is a valid variable name, we don't know whether
150         to treat a forall on the input as the beginning of a quantifier
151         or the beginning of the rule itself.  Resolving to shift means
152         it's always treated as a quantifier, hence the above is disallowed.
153         This saves explicitly defining a grammar for the rule lhs that
154         doesn't include 'forall'.
155
156 1 for ambiguity when the source file starts with "-- | doc". We need another
157   token of lookahead to determine if a top declaration or the 'module' keyword
158   follows. Shift parses as if the 'module' keyword follows.   
159
160 -- ---------------------------------------------------------------------------
161 -- Adding location info
162
163 This is done in a stylised way using the three macros below, L0, L1
164 and LL.  Each of these macros can be thought of as having type
165
166    L0, L1, LL :: a -> Located a
167
168 They each add a SrcSpan to their argument.
169
170    L0   adds 'noSrcSpan', used for empty productions
171      -- This doesn't seem to work anymore -=chak
172
173    L1   for a production with a single token on the lhs.  Grabs the SrcSpan
174         from that token.
175
176    LL   for a production with >1 token on the lhs.  Makes up a SrcSpan from
177         the first and last tokens.
178
179 These suffice for the majority of cases.  However, we must be
180 especially careful with empty productions: LL won't work if the first
181 or last token on the lhs can represent an empty span.  In these cases,
182 we have to calculate the span using more of the tokens from the lhs, eg.
183
184         | 'newtype' tycl_hdr '=' newconstr deriving
185                 { L (comb3 $1 $4 $5)
186                     (mkTyData NewType (unLoc $2) [$4] (unLoc $5)) }
187
188 We provide comb3 and comb4 functions which are useful in such cases.
189
190 Be careful: there's no checking that you actually got this right, the
191 only symptom will be that the SrcSpans of your syntax will be
192 incorrect.
193
194 /*
195  * We must expand these macros *before* running Happy, which is why this file is
196  * Parser.y.pp rather than just Parser.y - we run the C pre-processor first.
197  */
198 #define L0   L noSrcSpan
199 #define L1   sL (getLoc $1)
200 #define LL   sL (comb2 $1 $>)
201
202 -- -----------------------------------------------------------------------------
203
204 -}
205
206 %token
207  '_'            { L _ ITunderscore }            -- Haskell keywords
208  'as'           { L _ ITas }
209  'case'         { L _ ITcase }          
210  'class'        { L _ ITclass } 
211  'data'         { L _ ITdata } 
212  'default'      { L _ ITdefault }
213  'deriving'     { L _ ITderiving }
214  'do'           { L _ ITdo }
215  'else'         { L _ ITelse }
216  'hiding'       { L _ IThiding }
217  'if'           { L _ ITif }
218  'import'       { L _ ITimport }
219  'in'           { L _ ITin }
220  'infix'        { L _ ITinfix }
221  'infixl'       { L _ ITinfixl }
222  'infixr'       { L _ ITinfixr }
223  'instance'     { L _ ITinstance }
224  'let'          { L _ ITlet }
225  'module'       { L _ ITmodule }
226  'newtype'      { L _ ITnewtype }
227  'of'           { L _ ITof }
228  'qualified'    { L _ ITqualified }
229  'then'         { L _ ITthen }
230  'type'         { L _ ITtype }
231  'where'        { L _ ITwhere }
232  '_scc_'        { L _ ITscc }         -- ToDo: remove
233
234  'forall'       { L _ ITforall }                -- GHC extension keywords
235  'foreign'      { L _ ITforeign }
236  'export'       { L _ ITexport }
237  'label'        { L _ ITlabel } 
238  'dynamic'      { L _ ITdynamic }
239  'safe'         { L _ ITsafe }
240  'interruptible' { L _ ITinterruptible }
241  'unsafe'       { L _ ITunsafe }
242  'mdo'          { L _ ITmdo }
243  'family'       { L _ ITfamily }
244  'stdcall'      { L _ ITstdcallconv }
245  'ccall'        { L _ ITccallconv }
246  'capi'         { L _ ITcapiconv }
247  'prim'         { L _ ITprimcallconv }
248  'proc'         { L _ ITproc }          -- for arrow notation extension
249  'rec'          { L _ ITrec }           -- for arrow notation extension
250  'group'    { L _ ITgroup }     -- for list transform extension
251  'by'       { L _ ITby }        -- for list transform extension
252  'using'    { L _ ITusing }     -- for list transform extension
253
254  '{-# INLINE'             { L _ (ITinline_prag _ _) }
255  '{-# SPECIALISE'         { L _ ITspec_prag }
256  '{-# SPECIALISE_INLINE'  { L _ (ITspec_inline_prag _) }
257  '{-# SOURCE'                                   { L _ ITsource_prag }
258  '{-# RULES'                                    { L _ ITrules_prag }
259  '{-# CORE'                                     { L _ ITcore_prag }              -- hdaume: annotated core
260  '{-# SCC'                { L _ ITscc_prag }
261  '{-# GENERATED'          { L _ ITgenerated_prag }
262  '{-# DEPRECATED'         { L _ ITdeprecated_prag }
263  '{-# WARNING'            { L _ ITwarning_prag }
264  '{-# UNPACK'             { L _ ITunpack_prag }
265  '{-# NOUNPACK'           { L _ ITnounpack_prag }
266  '{-# ANN'                { L _ ITann_prag }
267  '{-# VECTORISE'          { L _ ITvect_prag }
268  '{-# VECTORISE_SCALAR'   { L _ ITvect_scalar_prag }
269  '{-# NOVECTORISE'        { L _ ITnovect_prag }
270  '{-# CTYPE'              { L _ ITctype }
271  '#-}'                                          { L _ ITclose_prag }
272
273  '..'           { L _ ITdotdot }                        -- reserved symbols
274  ':'            { L _ ITcolon }
275  '::'           { L _ ITdcolon }
276  '='            { L _ ITequal }
277  '\\'           { L _ ITlam }
278  '|'            { L _ ITvbar }
279  '<-'           { L _ ITlarrow }
280  '->'           { L _ ITrarrow }
281  '@'            { L _ ITat }
282  '~'            { L _ ITtilde }
283  '~#'           { L _ ITtildehsh }
284  '=>'           { L _ ITdarrow }
285  '-'            { L _ ITminus }
286  '!'            { L _ ITbang }
287  '*'            { L _ ITstar }
288  '-<'           { L _ ITlarrowtail }            -- for arrow notation
289  '>-'           { L _ ITrarrowtail }            -- for arrow notation
290  '-<<'          { L _ ITLarrowtail }            -- for arrow notation
291  '>>-'          { L _ ITRarrowtail }            -- for arrow notation
292  '.'            { L _ ITdot }
293
294  '{'            { L _ ITocurly }                        -- special symbols
295  '}'            { L _ ITccurly }
296  vocurly        { L _ ITvocurly } -- virtual open curly (from layout)
297  vccurly        { L _ ITvccurly } -- virtual close curly (from layout)
298  '['            { L _ ITobrack }
299  ']'            { L _ ITcbrack }
300  '[:'           { L _ ITopabrack }
301  ':]'           { L _ ITcpabrack }
302  '('            { L _ IToparen }
303  ')'            { L _ ITcparen }
304  '(#'           { L _ IToubxparen }
305  '#)'           { L _ ITcubxparen }
306  '(|'           { L _ IToparenbar }
307  '|)'           { L _ ITcparenbar }
308  ';'            { L _ ITsemi }
309  ','            { L _ ITcomma }
310  '`'            { L _ ITbackquote }
311  SIMPLEQUOTE    { L _ ITsimpleQuote      }     -- 'x
312
313  VARID          { L _ (ITvarid    _) }          -- identifiers
314  CONID          { L _ (ITconid    _) }
315  VARSYM         { L _ (ITvarsym   _) }
316  CONSYM         { L _ (ITconsym   _) }
317  QVARID         { L _ (ITqvarid   _) }
318  QCONID         { L _ (ITqconid   _) }
319  QVARSYM        { L _ (ITqvarsym  _) }
320  QCONSYM        { L _ (ITqconsym  _) }
321  PREFIXQVARSYM  { L _ (ITprefixqvarsym  _) }
322  PREFIXQCONSYM  { L _ (ITprefixqconsym  _) }
323
324  IPDUPVARID     { L _ (ITdupipvarid   _) }              -- GHC extension
325
326  CHAR           { L _ (ITchar     _) }
327  STRING         { L _ (ITstring   _) }
328  INTEGER        { L _ (ITinteger  _) }
329  RATIONAL       { L _ (ITrational _) }
330                     
331  PRIMCHAR       { L _ (ITprimchar   _) }
332  PRIMSTRING     { L _ (ITprimstring _) }
333  PRIMINTEGER    { L _ (ITprimint    _) }
334  PRIMWORD       { L _ (ITprimword  _) }
335  PRIMFLOAT      { L _ (ITprimfloat  _) }
336  PRIMDOUBLE     { L _ (ITprimdouble _) }
337
338  DOCNEXT        { L _ (ITdocCommentNext _) }
339  DOCPREV        { L _ (ITdocCommentPrev _) }
340  DOCNAMED       { L _ (ITdocCommentNamed _) }
341  DOCSECTION     { L _ (ITdocSection _ _) }
342
343 -- Template Haskell 
344 '[|'            { L _ ITopenExpQuote  }       
345 '[p|'           { L _ ITopenPatQuote  }      
346 '[t|'           { L _ ITopenTypQuote  }      
347 '[d|'           { L _ ITopenDecQuote  }      
348 '|]'            { L _ ITcloseQuote    }
349 TH_ID_SPLICE    { L _ (ITidEscape _)  }     -- $x
350 '$('            { L _ ITparenEscape   }     -- $( exp )
351 TH_TY_QUOTE     { L _ ITtyQuote       }      -- ''T
352 TH_QUASIQUOTE   { L _ (ITquasiQuote _) }
353
354 %monad { P } { >>= } { return }
355 %lexer { lexer } { L _ ITeof }
356 %name parseModule module
357 %name parseStmt   maybe_stmt
358 %name parseIdentifier  identifier
359 %name parseType ctype
360 %partial parseHeader header
361 %tokentype { (Located Token) }
362 %%
363
364 -----------------------------------------------------------------------------
365 -- Identifiers; one of the entry points
366 identifier :: { Located RdrName }
367         : qvar                          { $1 }
368         | qcon                          { $1 }
369         | qvarop                        { $1 }
370         | qconop                        { $1 }
371     | '(' '->' ')'      { LL $ getRdrName funTyCon }
372
373 -----------------------------------------------------------------------------
374 -- Module Header
375
376 -- The place for module deprecation is really too restrictive, but if it
377 -- was allowed at its natural place just before 'module', we get an ugly
378 -- s/r conflict with the second alternative. Another solution would be the
379 -- introduction of a new pragma DEPRECATED_MODULE, but this is not very nice,
380 -- either, and DEPRECATED is only expected to be used by people who really
381 -- know what they are doing. :-)
382
383 module  :: { Located (HsModule RdrName) }
384         : maybedocheader 'module' modid maybemodwarning maybeexports 'where' body
385                 {% fileSrcSpan >>= \ loc ->
386                    return (L loc (HsModule (Just $3) $5 (fst $7) (snd $7) $4 $1
387                           ) )}
388         | body2
389                 {% fileSrcSpan >>= \ loc ->
390                    return (L loc (HsModule Nothing Nothing
391                           (fst $1) (snd $1) Nothing Nothing
392                           )) }
393
394 maybedocheader :: { Maybe LHsDocString }
395         : moduleheader            { $1 }
396         | {- empty -}             { Nothing }
397
398 missing_module_keyword :: { () }
399         : {- empty -}                           {% pushCurrentContext }
400
401 maybemodwarning :: { Maybe WarningTxt }
402     : '{-# DEPRECATED' strings '#-}' { Just (DeprecatedTxt $ unLoc $2) }
403     | '{-# WARNING' strings '#-}'    { Just (WarningTxt $ unLoc $2) }
404     |  {- empty -}                  { Nothing }
405
406 body    :: { ([LImportDecl RdrName], [LHsDecl RdrName]) }
407         :  '{'            top '}'               { $2 }
408         |      vocurly    top close             { $2 }
409
410 body2   :: { ([LImportDecl RdrName], [LHsDecl RdrName]) }
411         :  '{' top '}'                          { $2 }
412         |  missing_module_keyword top close     { $2 }
413
414 top     :: { ([LImportDecl RdrName], [LHsDecl RdrName]) }
415         : importdecls                           { (reverse $1,[]) }
416         | importdecls ';' cvtopdecls            { (reverse $1,$3) }
417         | cvtopdecls                            { ([],$1) }
418
419 cvtopdecls :: { [LHsDecl RdrName] }
420         : topdecls                              { cvTopDecls $1 }
421
422 -----------------------------------------------------------------------------
423 -- Module declaration & imports only
424
425 header  :: { Located (HsModule RdrName) }
426         : maybedocheader 'module' modid maybemodwarning maybeexports 'where' header_body
427                 {% fileSrcSpan >>= \ loc ->
428                    return (L loc (HsModule (Just $3) $5 $7 [] $4 $1
429                           ))}
430         | header_body2
431                 {% fileSrcSpan >>= \ loc ->
432                    return (L loc (HsModule Nothing Nothing $1 [] Nothing
433                           Nothing)) }
434
435 header_body :: { [LImportDecl RdrName] }
436         :  '{'            importdecls           { $2 }
437         |      vocurly    importdecls           { $2 }
438
439 header_body2 :: { [LImportDecl RdrName] }
440         :  '{' importdecls                      { $2 }
441         |  missing_module_keyword importdecls   { $2 }
442
443 -----------------------------------------------------------------------------
444 -- The Export List
445
446 maybeexports :: { Maybe [LIE RdrName] }
447         :  '(' exportlist ')'                   { Just $2 }
448         |  {- empty -}                          { Nothing }
449
450 exportlist :: { [LIE RdrName] }
451         : expdoclist ',' expdoclist             { $1 ++ $3 }
452         | exportlist1                           { $1 }
453
454 exportlist1 :: { [LIE RdrName] }
455         : expdoclist export expdoclist ',' exportlist  { $1 ++ ($2 : $3) ++ $5 }
456         | expdoclist export expdoclist                 { $1 ++ ($2 : $3) }
457         | expdoclist                                   { $1 }
458
459 expdoclist :: { [LIE RdrName] }
460         : exp_doc expdoclist                           { $1 : $2 }
461         | {- empty -}                                  { [] }
462
463 exp_doc :: { LIE RdrName }                                                   
464         : docsection    { L1 (case (unLoc $1) of (n, doc) -> IEGroup n doc) }
465         | docnamed      { L1 (IEDocNamed ((fst . unLoc) $1)) } 
466         | docnext       { L1 (IEDoc (unLoc $1)) }       
467                        
468    -- No longer allow things like [] and (,,,) to be exported
469    -- They are built in syntax, always available
470 export  :: { LIE RdrName }
471         :  qvar                         { L1 (IEVar (unLoc $1)) }
472         |  oqtycon                      { L1 (IEThingAbs (unLoc $1)) }
473         |  oqtycon '(' '..' ')'         { LL (IEThingAll (unLoc $1)) }
474         |  oqtycon '(' ')'              { LL (IEThingWith (unLoc $1) []) }
475         |  oqtycon '(' qcnames ')'      { LL (IEThingWith (unLoc $1) (reverse $3)) }
476         |  'module' modid               { LL (IEModuleContents (unLoc $2)) }
477
478 qcnames :: { [RdrName] }
479         :  qcnames ',' qcname_ext       { unLoc $3 : $1 }
480         |  qcname_ext                   { [unLoc $1]  }
481
482 qcname_ext :: { Located RdrName }       -- Variable or data constructor
483                                         -- or tagged type constructor
484         :  qcname                       { $1 }
485         |  'type' qcon                  { sL (comb2 $1 $2) 
486                                              (setRdrNameSpace (unLoc $2) 
487                                                               tcClsName)  }
488
489 -- Cannot pull into qcname_ext, as qcname is also used in expression.
490 qcname  :: { Located RdrName }  -- Variable or data constructor
491         :  qvar                         { $1 }
492         |  qcon                         { $1 }
493
494 -----------------------------------------------------------------------------
495 -- Import Declarations
496
497 -- import decls can be *empty*, or even just a string of semicolons
498 -- whereas topdecls must contain at least one topdecl.
499
500 importdecls :: { [LImportDecl RdrName] }
501         : importdecls ';' importdecl            { $3 : $1 }
502         | importdecls ';'                       { $1 }
503         | importdecl                            { [ $1 ] }
504         | {- empty -}                           { [] }
505
506 importdecl :: { LImportDecl RdrName }
507         : 'import' maybe_src maybe_safe optqualified maybe_pkg modid maybeas maybeimpspec 
508                 { L (comb4 $1 $6 $7 $8) $
509                   ImportDecl { ideclName = $6, ideclPkgQual = $5
510                              , ideclSource = $2, ideclSafe = $3
511                              , ideclQualified = $4, ideclImplicit = False
512                              , ideclAs = unLoc $7, ideclHiding = unLoc $8 } }
513
514 maybe_src :: { IsBootInterface }
515         : '{-# SOURCE' '#-}'                    { True }
516         | {- empty -}                           { False }
517
518 maybe_safe :: { Bool }
519         : 'safe'                                { True }
520         | {- empty -}                           { False }
521
522 maybe_pkg :: { Maybe FastString }
523         : STRING                                { Just (getSTRING $1) }
524         | {- empty -}                           { Nothing }
525
526 optqualified :: { Bool }
527         : 'qualified'                           { True  }
528         | {- empty -}                           { False }
529
530 maybeas :: { Located (Maybe ModuleName) }
531         : 'as' modid                            { LL (Just (unLoc $2)) }
532         | {- empty -}                           { noLoc Nothing }
533
534 maybeimpspec :: { Located (Maybe (Bool, [LIE RdrName])) }
535         : impspec                               { L1 (Just (unLoc $1)) }
536         | {- empty -}                           { noLoc Nothing }
537
538 impspec :: { Located (Bool, [LIE RdrName]) }
539         :  '(' exportlist ')'                   { LL (False, $2) }
540         |  'hiding' '(' exportlist ')'          { LL (True,  $3) }
541
542 -----------------------------------------------------------------------------
543 -- Fixity Declarations
544
545 prec    :: { Int }
546         : {- empty -}           { 9 }
547         | INTEGER               {% checkPrecP (L1 (fromInteger (getINTEGER $1))) }
548
549 infix   :: { Located FixityDirection }
550         : 'infix'                               { L1 InfixN  }
551         | 'infixl'                              { L1 InfixL  }
552         | 'infixr'                              { L1 InfixR }
553
554 ops     :: { Located [Located RdrName] }
555         : ops ',' op                            { LL ($3 : unLoc $1) }
556         | op                                    { L1 [$1] }
557
558 -----------------------------------------------------------------------------
559 -- Top-Level Declarations
560
561 topdecls :: { OrdList (LHsDecl RdrName) }
562         : topdecls ';' topdecl                  { $1 `appOL` $3 }
563         | topdecls ';'                          { $1 }
564         | topdecl                               { $1 }
565
566 topdecl :: { OrdList (LHsDecl RdrName) }
567         : cl_decl                               { unitOL (L1 (TyClD (unLoc $1))) }
568         | ty_decl                               { unitOL (L1 (TyClD (unLoc $1))) }
569         | inst_decl                             { unitOL (L1 (InstD (unLoc $1))) }
570         | stand_alone_deriving                  { unitOL (LL (DerivD (unLoc $1))) }
571         | 'default' '(' comma_types0 ')'        { unitOL (LL $ DefD (DefaultDecl $3)) }
572         | 'foreign' fdecl                       { unitOL (LL (unLoc $2)) }
573         | '{-# DEPRECATED' deprecations '#-}'   { $2 }
574         | '{-# WARNING' warnings '#-}'          { $2 }
575         | '{-# RULES' rules '#-}'               { $2 }
576         | '{-# VECTORISE_SCALAR' qvar '#-}'     { unitOL $ LL $ VectD (HsVect       $2 Nothing) }
577         | '{-# VECTORISE' qvar '=' exp '#-}'    { unitOL $ LL $ VectD (HsVect       $2 (Just $4)) }
578         | '{-# NOVECTORISE' qvar '#-}'          { unitOL $ LL $ VectD (HsNoVect     $2) }
579         | '{-# VECTORISE' 'type' gtycon '#-}'     
580                                                 { unitOL $ LL $ 
581                                                     VectD (HsVectTypeIn False $3 Nothing) }
582         | '{-# VECTORISE_SCALAR' 'type' gtycon '#-}'     
583                                                 { unitOL $ LL $ 
584                                                     VectD (HsVectTypeIn True $3 Nothing) }
585         | '{-# VECTORISE' 'type' gtycon '=' gtycon '#-}'     
586                                                 { unitOL $ LL $ 
587                                                     VectD (HsVectTypeIn False $3 (Just $5)) }
588         | '{-# VECTORISE_SCALAR' 'type' gtycon '=' gtycon '#-}'     
589                                                 { unitOL $ LL $ 
590                                                     VectD (HsVectTypeIn True $3 (Just $5)) }
591         | '{-# VECTORISE' 'class' gtycon '#-}'  { unitOL $ LL $ VectD (HsVectClassIn $3) }
592         | '{-# VECTORISE_SCALAR' 'instance' type '#-}'     
593                                                 { unitOL $ LL $ VectD (HsVectInstIn $3) }
594         | annotation { unitOL $1 }
595         | decl                                  { unLoc $1 }
596
597         -- Template Haskell Extension
598         -- The $(..) form is one possible form of infixexp
599         -- but we treat an arbitrary expression just as if 
600         -- it had a $(..) wrapped around it
601         | infixexp                              { unitOL (LL $ mkTopSpliceDecl $1) } 
602
603 -- Type classes
604 --
605 cl_decl :: { LTyClDecl RdrName }
606         : 'class' tycl_hdr fds where_cls        {% mkClassDecl (comb4 $1 $2 $3 $4) $2 $3 $4 }
607
608 -- Type declarations (toplevel)
609 --
610 ty_decl :: { LTyClDecl RdrName }
611            -- ordinary type synonyms
612         : 'type' type '=' ctypedoc
613                 -- Note ctype, not sigtype, on the right of '='
614                 -- We allow an explicit for-all but we don't insert one
615                 -- in   type Foo a = (b,b)
616                 -- Instead we just say b is out of scope
617                 --
618                 -- Note the use of type for the head; this allows
619                 -- infix type constructors to be declared 
620                 {% mkTySynonym (comb2 $1 $4) False $2 $4 }
621
622            -- type family declarations
623         | 'type' 'family' type opt_kind_sig 
624                 -- Note the use of type for the head; this allows
625                 -- infix type constructors to be declared
626                 {% mkTyFamily (comb3 $1 $3 $4) TypeFamily $3 (unLoc $4) }
627
628           -- ordinary data type or newtype declaration
629         | data_or_newtype capi_ctype tycl_hdr constrs deriving
630                 {% mkTyData (comb4 $1 $3 $4 $5) (unLoc $1) False $2 $3 
631                             Nothing (reverse (unLoc $4)) (unLoc $5) }
632                                    -- We need the location on tycl_hdr in case 
633                                    -- constrs and deriving are both empty
634
635           -- ordinary GADT declaration
636         | data_or_newtype capi_ctype tycl_hdr opt_kind_sig 
637                  gadt_constrlist
638                  deriving
639                 {% mkTyData (comb4 $1 $3 $5 $6) (unLoc $1) False $2 $3 
640                             (unLoc $4) (unLoc $5) (unLoc $6) }
641                                    -- We need the location on tycl_hdr in case 
642                                    -- constrs and deriving are both empty
643
644           -- data/newtype family
645         | 'data' 'family' type opt_kind_sig
646                 {% mkTyFamily (comb3 $1 $2 $4) DataFamily $3 (unLoc $4) }
647
648 inst_decl :: { LInstDecl RdrName }
649         : 'instance' inst_type where_inst
650                  { let (binds, sigs, ats, _) = cvBindsAndSigs (unLoc $3)
651                    in L (comb3 $1 $2 $3) (ClsInstDecl $2 binds sigs ats) }
652
653            -- type instance declarations
654         | 'type' 'instance' type '=' ctype
655                 -- Note the use of type for the head; this allows
656                 -- infix type constructors and type patterns
657                 {% do { L loc d <- mkTySynonym (comb2 $1 $5) True $3 $5
658                       ; return (L loc (FamInstDecl d)) } }
659
660           -- data/newtype instance declaration
661         | data_or_newtype 'instance' tycl_hdr constrs deriving
662                 {% do { L loc d <- mkTyData (comb4 $1 $3 $4 $5) (unLoc $1) True Nothing $3
663                                       Nothing (reverse (unLoc $4)) (unLoc $5)
664                       ; return (L loc (FamInstDecl d)) } }
665
666           -- GADT instance declaration
667         | data_or_newtype 'instance' tycl_hdr opt_kind_sig 
668                  gadt_constrlist
669                  deriving
670                 {% do { L loc d <- mkTyData (comb4 $1 $3 $5 $6) (unLoc $1) True Nothing $3
671                                             (unLoc $4) (unLoc $5) (unLoc $6)
672                       ; return (L loc (FamInstDecl d)) } }
673         
674 -- Associated type family declarations
675 --
676 -- * They have a different syntax than on the toplevel (no family special
677 --   identifier).
678 --
679 -- * They also need to be separate from instances; otherwise, data family
680 --   declarations without a kind signature cause parsing conflicts with empty
681 --   data declarations. 
682 --
683 at_decl_cls :: { LTyClDecl RdrName }
684            -- type family declarations
685         : 'type' type opt_kind_sig
686                 -- Note the use of type for the head; this allows
687                 -- infix type constructors to be declared.
688                 {% mkTyFamily (comb3 $1 $2 $3) TypeFamily $2 (unLoc $3) }
689
690            -- default type instance
691         | 'type' type '=' ctype
692                 -- Note the use of type for the head; this allows
693                 -- infix type constructors and type patterns
694                 {% mkTySynonym (comb2 $1 $4) True $2 $4 }
695
696           -- data/newtype family declaration
697         | 'data' type opt_kind_sig
698                 {% mkTyFamily (comb3 $1 $2 $3) DataFamily $2 (unLoc $3) }
699
700 -- Associated type instances
701 --
702 at_decl_inst :: { LTyClDecl RdrName }
703            -- type instance declarations
704         : 'type' type '=' ctype
705                 -- Note the use of type for the head; this allows
706                 -- infix type constructors and type patterns
707                 {% mkTySynonym (comb2 $1 $4) True $2 $4 }
708
709         -- data/newtype instance declaration
710         | data_or_newtype capi_ctype tycl_hdr constrs deriving
711                 {% mkTyData (comb4 $1 $3 $4 $5) (unLoc $1) True $2 $3 
712                             Nothing (reverse (unLoc $4)) (unLoc $5) }
713
714         -- GADT instance declaration
715         | data_or_newtype capi_ctype tycl_hdr opt_kind_sig 
716                  gadt_constrlist
717                  deriving
718                 {% mkTyData (comb4 $1 $3 $5 $6) (unLoc $1) True $2 $3 
719                             (unLoc $4) (unLoc $5) (unLoc $6) }
720
721 data_or_newtype :: { Located NewOrData }
722         : 'data'        { L1 DataType }
723         | 'newtype'     { L1 NewType }
724
725 opt_kind_sig :: { Located (Maybe (LHsKind RdrName)) }
726         :                               { noLoc Nothing }
727         | '::' kind                     { LL (Just $2) }
728
729 -- tycl_hdr parses the header of a class or data type decl,
730 -- which takes the form
731 --      T a b
732 --      Eq a => T a
733 --      (Eq a, Ord b) => T a b
734 --      T Int [a]                       -- for associated types
735 -- Rather a lot of inlining here, else we get reduce/reduce errors
736 tycl_hdr :: { Located (Maybe (LHsContext RdrName), LHsType RdrName) }
737         : context '=>' type             { LL (Just $1, $3) }
738         | type                          { L1 (Nothing, $1) }
739
740 capi_ctype :: { Maybe CType }
741 capi_ctype : '{-# CTYPE' STRING STRING '#-}' { Just (CType (Just (Header (getSTRING $2))) (getSTRING $3)) }
742            | '{-# CTYPE'        STRING '#-}' { Just (CType Nothing                        (getSTRING $2)) }
743            |                                 { Nothing }
744
745 -----------------------------------------------------------------------------
746 -- Stand-alone deriving
747
748 -- Glasgow extension: stand-alone deriving declarations
749 stand_alone_deriving :: { LDerivDecl RdrName }
750         : 'deriving' 'instance' inst_type { LL (DerivDecl $3) }
751
752 -----------------------------------------------------------------------------
753 -- Nested declarations
754
755 -- Declaration in class bodies
756 --
757 decl_cls  :: { Located (OrdList (LHsDecl RdrName)) }
758 decl_cls  : at_decl_cls                 { LL (unitOL (L1 (TyClD (unLoc $1)))) }
759           | decl                        { $1 }
760
761           -- A 'default' signature used with the generic-programming extension
762           | 'default' infixexp '::' sigtypedoc
763                     {% do { (TypeSig l ty) <- checkValSig $2 $4
764                           ; return (LL $ unitOL (LL $ SigD (GenericSig l ty))) } }
765
766 decls_cls :: { Located (OrdList (LHsDecl RdrName)) }    -- Reversed
767           : decls_cls ';' decl_cls      { LL (unLoc $1 `appOL` unLoc $3) }
768           | decls_cls ';'               { LL (unLoc $1) }
769           | decl_cls                    { $1 }
770           | {- empty -}                 { noLoc nilOL }
771
772
773 decllist_cls
774         :: { Located (OrdList (LHsDecl RdrName)) }      -- Reversed
775         : '{'         decls_cls '}'     { LL (unLoc $2) }
776         |     vocurly decls_cls close   { $2 }
777
778 -- Class body
779 --
780 where_cls :: { Located (OrdList (LHsDecl RdrName)) }    -- Reversed
781                                 -- No implicit parameters
782                                 -- May have type declarations
783         : 'where' decllist_cls          { LL (unLoc $2) }
784         | {- empty -}                   { noLoc nilOL }
785
786 -- Declarations in instance bodies
787 --
788 decl_inst  :: { Located (OrdList (LHsDecl RdrName)) }
789 decl_inst  : at_decl_inst               { LL (unitOL (L1 (TyClD (unLoc $1)))) }
790            | decl                       { $1 }
791
792 decls_inst :: { Located (OrdList (LHsDecl RdrName)) }   -- Reversed
793            : decls_inst ';' decl_inst   { LL (unLoc $1 `appOL` unLoc $3) }
794            | decls_inst ';'             { LL (unLoc $1) }
795            | decl_inst                  { $1 }
796            | {- empty -}                { noLoc nilOL }
797
798 decllist_inst 
799         :: { Located (OrdList (LHsDecl RdrName)) }      -- Reversed
800         : '{'         decls_inst '}'    { LL (unLoc $2) }
801         |     vocurly decls_inst close  { $2 }
802
803 -- Instance body
804 --
805 where_inst :: { Located (OrdList (LHsDecl RdrName)) }   -- Reversed
806                                 -- No implicit parameters
807                                 -- May have type declarations
808         : 'where' decllist_inst         { LL (unLoc $2) }
809         | {- empty -}                   { noLoc nilOL }
810
811 -- Declarations in binding groups other than classes and instances
812 --
813 decls   :: { Located (OrdList (LHsDecl RdrName)) }      
814         : decls ';' decl                { let { this = unLoc $3;
815                                     rest = unLoc $1;
816                                     these = rest `appOL` this }
817                               in rest `seq` this `seq` these `seq`
818                                     LL these }
819         | decls ';'                     { LL (unLoc $1) }
820         | decl                          { $1 }
821         | {- empty -}                   { noLoc nilOL }
822
823 decllist :: { Located (OrdList (LHsDecl RdrName)) }
824         : '{'            decls '}'      { LL (unLoc $2) }
825         |     vocurly    decls close    { $2 }
826
827 -- Binding groups other than those of class and instance declarations
828 --
829 binds   ::  { Located (HsLocalBinds RdrName) }          -- May have implicit parameters
830                                                 -- No type declarations
831         : decllist                      { L1 (HsValBinds (cvBindGroup (unLoc $1))) }
832         | '{'            dbinds '}'     { LL (HsIPBinds (IPBinds (unLoc $2) emptyTcEvBinds)) }
833         |     vocurly    dbinds close   { L (getLoc $2) (HsIPBinds (IPBinds (unLoc $2) emptyTcEvBinds)) }
834
835 wherebinds :: { Located (HsLocalBinds RdrName) }        -- May have implicit parameters
836                                                 -- No type declarations
837         : 'where' binds                 { LL (unLoc $2) }
838         | {- empty -}                   { noLoc emptyLocalBinds }
839
840
841 -----------------------------------------------------------------------------
842 -- Transformation Rules
843
844 rules   :: { OrdList (LHsDecl RdrName) }
845         :  rules ';' rule                       { $1 `snocOL` $3 }
846         |  rules ';'                            { $1 }
847         |  rule                                 { unitOL $1 }
848         |  {- empty -}                          { nilOL }
849
850 rule    :: { LHsDecl RdrName }
851         : STRING activation rule_forall infixexp '=' exp
852              { LL $ RuleD (HsRule (getSTRING $1) 
853                                   ($2 `orElse` AlwaysActive) 
854                                   $3 $4 placeHolderNames $6 placeHolderNames) }
855
856 activation :: { Maybe Activation } 
857         : {- empty -}                           { Nothing }
858         | explicit_activation                   { Just $1 }
859
860 explicit_activation :: { Activation }  -- In brackets
861         : '[' INTEGER ']'               { ActiveAfter  (fromInteger (getINTEGER $2)) }
862         | '[' '~' INTEGER ']'           { ActiveBefore (fromInteger (getINTEGER $3)) }
863
864 rule_forall :: { [RuleBndr RdrName] }
865         : 'forall' rule_var_list '.'            { $2 }
866         | {- empty -}                           { [] }
867
868 rule_var_list :: { [RuleBndr RdrName] }
869         : rule_var                              { [$1] }
870         | rule_var rule_var_list                { $1 : $2 }
871
872 rule_var :: { RuleBndr RdrName }
873         : varid                                 { RuleBndr $1 }
874         | '(' varid '::' ctype ')'              { RuleBndrSig $2 $4 }
875
876 -----------------------------------------------------------------------------
877 -- Warnings and deprecations (c.f. rules)
878
879 warnings :: { OrdList (LHsDecl RdrName) }
880         : warnings ';' warning          { $1 `appOL` $3 }
881         | warnings ';'                  { $1 }
882         | warning                               { $1 }
883         | {- empty -}                           { nilOL }
884
885 -- SUP: TEMPORARY HACK, not checking for `module Foo'
886 warning :: { OrdList (LHsDecl RdrName) }
887         : namelist strings
888                 { toOL [ LL $ WarningD (Warning n (WarningTxt $ unLoc $2))
889                        | n <- unLoc $1 ] }
890
891 deprecations :: { OrdList (LHsDecl RdrName) }
892         : deprecations ';' deprecation          { $1 `appOL` $3 }
893         | deprecations ';'                      { $1 }
894         | deprecation                           { $1 }
895         | {- empty -}                           { nilOL }
896
897 -- SUP: TEMPORARY HACK, not checking for `module Foo'
898 deprecation :: { OrdList (LHsDecl RdrName) }
899         : namelist strings
900                 { toOL [ LL $ WarningD (Warning n (DeprecatedTxt $ unLoc $2))
901                        | n <- unLoc $1 ] }
902
903 strings :: { Located [FastString] }
904     : STRING { L1 [getSTRING $1] }
905     | '[' stringlist ']' { LL $ fromOL (unLoc $2) }
906
907 stringlist :: { Located (OrdList FastString) }
908     : stringlist ',' STRING { LL (unLoc $1 `snocOL` getSTRING $3) }
909     | STRING                { LL (unitOL (getSTRING $1)) }
910
911 -----------------------------------------------------------------------------
912 -- Annotations
913 annotation :: { LHsDecl RdrName }
914     : '{-# ANN' name_var aexp '#-}'      { LL (AnnD $ HsAnnotation (ValueAnnProvenance (unLoc $2)) $3) }
915     | '{-# ANN' 'type' tycon aexp '#-}'  { LL (AnnD $ HsAnnotation (TypeAnnProvenance (unLoc $3)) $4) }
916     | '{-# ANN' 'module' aexp '#-}'      { LL (AnnD $ HsAnnotation ModuleAnnProvenance $3) }
917
918
919 -----------------------------------------------------------------------------
920 -- Foreign import and export declarations
921
922 fdecl :: { LHsDecl RdrName }
923 fdecl : 'import' callconv safety fspec
924                 {% mkImport $2 $3 (unLoc $4) >>= return.LL }
925       | 'import' callconv        fspec          
926                 {% do { d <- mkImport $2 PlaySafe (unLoc $3);
927                         return (LL d) } }
928       | 'export' callconv fspec
929                 {% mkExport $2 (unLoc $3) >>= return.LL }
930
931 callconv :: { CCallConv }
932           : 'stdcall'                   { StdCallConv }
933           | 'ccall'                     { CCallConv   }
934           | 'capi'                      { CApiConv    }
935           | 'prim'                      { PrimCallConv}
936
937 safety :: { Safety }
938         : 'unsafe'                      { PlayRisky }
939         | 'safe'                        { PlaySafe }
940         | 'interruptible'               { PlayInterruptible }
941
942 fspec :: { Located (Located FastString, Located RdrName, LHsType RdrName) }
943        : STRING var '::' sigtypedoc     { LL (L (getLoc $1) (getSTRING $1), $2, $4) }
944        |        var '::' sigtypedoc     { LL (noLoc nilFS, $1, $3) }
945          -- if the entity string is missing, it defaults to the empty string;
946          -- the meaning of an empty entity string depends on the calling
947          -- convention
948
949 -----------------------------------------------------------------------------
950 -- Type signatures
951
952 opt_sig :: { Maybe (LHsType RdrName) }
953         : {- empty -}                   { Nothing }
954         | '::' sigtype                  { Just $2 }
955
956 opt_asig :: { Maybe (LHsType RdrName) }
957         : {- empty -}                   { Nothing }
958         | '::' atype                    { Just $2 }
959
960 sigtype :: { LHsType RdrName }          -- Always a HsForAllTy,
961                                         -- to tell the renamer where to generalise
962         : ctype                         { L1 (mkImplicitHsForAllTy (noLoc []) $1) }
963         -- Wrap an Implicit forall if there isn't one there already
964
965 sigtypedoc :: { LHsType RdrName }       -- Always a HsForAllTy
966         : ctypedoc                      { L1 (mkImplicitHsForAllTy (noLoc []) $1) }
967         -- Wrap an Implicit forall if there isn't one there already
968
969 sig_vars :: { Located [Located RdrName] }
970          : sig_vars ',' var             { LL ($3 : unLoc $1) }
971          | var                          { L1 [$1] }
972
973 sigtypes1 :: { [LHsType RdrName] }      -- Always HsForAllTys
974         : sigtype                       { [ $1 ] }
975         | sigtype ',' sigtypes1         { $1 : $3 }
976
977 -----------------------------------------------------------------------------
978 -- Types
979
980 infixtype :: { LHsType RdrName }
981         : btype qtyconop type         { LL $ mkHsOpTy $1 $2 $3 }
982         | btype tyvarop  type    { LL $ mkHsOpTy $1 $2 $3 }
983
984 strict_mark :: { Located HsBang }
985         : '!'                           { L1 HsStrict }
986         | '{-# UNPACK' '#-}' '!'        { LL HsUnpack }
987         | '{-# NOUNPACK' '#-}' '!'      { LL HsNoUnpack }
988
989 -- A ctype is a for-all type
990 ctype   :: { LHsType RdrName }
991         : 'forall' tv_bndrs '.' ctype   { LL $ mkExplicitHsForAllTy $2 (noLoc []) $4 }
992         | context '=>' ctype            { LL $ mkImplicitHsForAllTy   $1 $3 }
993         -- A type of form (context => type) is an *implicit* HsForAllTy
994         | ipvar '::' type               { LL (HsIParamTy (unLoc $1) $3) }
995         | type                          { $1 }
996
997 ----------------------
998 -- Notes for 'ctypedoc'
999 -- It would have been nice to simplify the grammar by unifying `ctype` and 
1000 -- ctypedoc` into one production, allowing comments on types everywhere (and
1001 -- rejecting them after parsing, where necessary).  This is however not possible
1002 -- since it leads to ambiguity. The reason is the support for comments on record
1003 -- fields: 
1004 --         data R = R { field :: Int -- ^ comment on the field }
1005 -- If we allow comments on types here, it's not clear if the comment applies
1006 -- to 'field' or to 'Int'. So we must use `ctype` to describe the type.
1007
1008 ctypedoc :: { LHsType RdrName }
1009         : 'forall' tv_bndrs '.' ctypedoc        { LL $ mkExplicitHsForAllTy $2 (noLoc []) $4 }
1010         | context '=>' ctypedoc         { LL $ mkImplicitHsForAllTy   $1 $3 }
1011         -- A type of form (context => type) is an *implicit* HsForAllTy
1012         | ipvar '::' type               { LL (HsIParamTy (unLoc $1) $3) }
1013         | typedoc                       { $1 }
1014
1015 ----------------------
1016 -- Notes for 'context'
1017 -- We parse a context as a btype so that we don't get reduce/reduce
1018 -- errors in ctype.  The basic problem is that
1019 --      (Eq a, Ord a)
1020 -- looks so much like a tuple type.  We can't tell until we find the =>
1021
1022 -- We have the t1 ~ t2 form both in 'context' and in type, 
1023 -- to permit an individual equational constraint without parenthesis.
1024 -- Thus for some reason we allow    f :: a~b => blah
1025 -- but not                          f :: ?x::Int => blah
1026 context :: { LHsContext RdrName }
1027         : btype '~'      btype          {% checkContext
1028                                              (LL $ HsEqTy $1 $3) }
1029         | btype                         {% checkContext $1 }
1030
1031 type :: { LHsType RdrName }
1032         : btype                         { $1 }
1033         | btype qtyconop type           { LL $ mkHsOpTy $1 $2 $3 }
1034         | btype tyvarop  type           { LL $ mkHsOpTy $1 $2 $3 }
1035         | btype '->'     ctype          { LL $ HsFunTy $1 $3 }
1036         | btype '~'      btype          { LL $ HsEqTy $1 $3 }
1037                                         -- see Note [Promotion]
1038         | btype SIMPLEQUOTE qconop type     { LL $ mkHsOpTy $1 $3 $4 }
1039         | btype SIMPLEQUOTE varop  type     { LL $ mkHsOpTy $1 $3 $4 }
1040
1041 typedoc :: { LHsType RdrName }
1042         : btype                          { $1 }
1043         | btype docprev                  { LL $ HsDocTy $1 $2 }
1044         | btype qtyconop type            { LL $ mkHsOpTy $1 $2 $3 }
1045         | btype qtyconop type docprev    { LL $ HsDocTy (L (comb3 $1 $2 $3) (mkHsOpTy $1 $2 $3)) $4 }
1046         | btype tyvarop  type            { LL $ mkHsOpTy $1 $2 $3 }
1047         | btype tyvarop  type docprev    { LL $ HsDocTy (L (comb3 $1 $2 $3) (mkHsOpTy $1 $2 $3)) $4 }
1048         | btype '->'     ctypedoc        { LL $ HsFunTy $1 $3 }
1049         | btype docprev '->' ctypedoc    { LL $ HsFunTy (L (comb2 $1 $2) (HsDocTy $1 $2)) $4 }
1050         | btype '~'      btype           { LL $ HsEqTy $1 $3 }
1051
1052 btype :: { LHsType RdrName }
1053         : btype atype                   { LL $ HsAppTy $1 $2 }
1054         | atype                         { $1 }
1055
1056 atype :: { LHsType RdrName }
1057         : ntgtycon                       { L1 (HsTyVar (unLoc $1)) }      -- Not including unit tuples
1058         | tyvar                          { L1 (HsTyVar (unLoc $1)) }      -- (See Note [Unit tuples])
1059         | strict_mark atype              { LL (HsBangTy (unLoc $1) $2) }  -- Constructor sigs only
1060         | '{' fielddecls '}'             {% checkRecordSyntax (LL $ HsRecTy $2) } -- Constructor sigs only
1061         | '(' ')'                        { LL $ HsTupleTy HsBoxedOrConstraintTuple []      }
1062         | '(' ctype ',' comma_types1 ')' { LL $ HsTupleTy HsBoxedOrConstraintTuple ($2:$4) }
1063         | '(#' '#)'                      { LL $ HsTupleTy HsUnboxedTuple           []      }       
1064         | '(#' comma_types1 '#)'         { LL $ HsTupleTy HsUnboxedTuple           $2      }
1065         | '[' ctype ']'                  { LL $ HsListTy  $2 }
1066         | '[:' ctype ':]'                { LL $ HsPArrTy  $2 }
1067         | '(' ctype ')'                  { LL $ HsParTy   $2 }
1068         | '(' ctype '::' kind ')'        { LL $ HsKindSig $2 $4 }
1069         | quasiquote                     { L1 (HsQuasiQuoteTy (unLoc $1)) }
1070         | '$(' exp ')'                   { LL $ mkHsSpliceTy $2 }
1071         | TH_ID_SPLICE                   { LL $ mkHsSpliceTy $ L1 $ HsVar $
1072                                            mkUnqual varName (getTH_ID_SPLICE $1) }
1073                                                       -- see Note [Promotion] for the followings
1074         | SIMPLEQUOTE qconid                          { LL $ HsTyVar $ unLoc $2 }
1075         | SIMPLEQUOTE  '(' ')'                        { LL $ HsTyVar $ getRdrName unitDataCon }
1076         | SIMPLEQUOTE  '(' ctype ',' comma_types1 ')' { LL $ HsExplicitTupleTy [] ($3 : $5) }
1077         | SIMPLEQUOTE  '[' comma_types0 ']'           { LL $ HsExplicitListTy placeHolderKind $3 }
1078         | '[' ctype ',' comma_types1 ']'              { LL $ HsExplicitListTy placeHolderKind ($2 : $4) }
1079
1080 -- An inst_type is what occurs in the head of an instance decl
1081 --      e.g.  (Foo a, Gaz b) => Wibble a b
1082 -- It's kept as a single type, with a MonoDictTy at the right
1083 -- hand corner, for convenience.
1084 inst_type :: { LHsType RdrName }
1085         : sigtype                       { $1 }
1086
1087 inst_types1 :: { [LHsType RdrName] }
1088         : inst_type                     { [$1] }
1089         | inst_type ',' inst_types1     { $1 : $3 }
1090
1091 comma_types0  :: { [LHsType RdrName] }
1092         : comma_types1                  { $1 }
1093         | {- empty -}                   { [] }
1094
1095 comma_types1    :: { [LHsType RdrName] }
1096         : ctype                         { [$1] }
1097         | ctype  ',' comma_types1       { $1 : $3 }
1098
1099 tv_bndrs :: { [LHsTyVarBndr RdrName] }
1100          : tv_bndr tv_bndrs             { $1 : $2 }
1101          | {- empty -}                  { [] }
1102
1103 tv_bndr :: { LHsTyVarBndr RdrName }
1104         : tyvar                         { L1 (UserTyVar (unLoc $1) placeHolderKind) }
1105         | '(' tyvar '::' kind ')'       { LL (KindedTyVar (unLoc $2) $4 placeHolderKind) }
1106
1107 fds :: { Located [Located (FunDep RdrName)] }
1108         : {- empty -}                   { noLoc [] }
1109         | '|' fds1                      { LL (reverse (unLoc $2)) }
1110
1111 fds1 :: { Located [Located (FunDep RdrName)] }
1112         : fds1 ',' fd                   { LL ($3 : unLoc $1) }
1113         | fd                            { L1 [$1] }
1114
1115 fd :: { Located (FunDep RdrName) }
1116         : varids0 '->' varids0          { L (comb3 $1 $2 $3)
1117                                            (reverse (unLoc $1), reverse (unLoc $3)) }
1118
1119 varids0 :: { Located [RdrName] }
1120         : {- empty -}                   { noLoc [] }
1121         | varids0 tyvar                 { LL (unLoc $2 : unLoc $1) }
1122
1123 -----------------------------------------------------------------------------
1124 -- Kinds
1125
1126 kind :: { LHsKind RdrName }
1127         : bkind                  { $1 }
1128         | bkind '->' kind        { LL $ HsFunTy $1 $3 }
1129
1130 bkind :: { LHsKind RdrName }
1131         : akind                  { $1 }
1132         | bkind akind            { LL $ HsAppTy $1 $2 }
1133
1134 akind :: { LHsKind RdrName }
1135         : '*'                    { L1 $ HsTyVar (nameRdrName liftedTypeKindTyConName) }
1136         | '(' kind ')'           { LL $ HsParTy $2 }
1137         | pkind                  { $1 }
1138
1139 pkind :: { LHsKind RdrName }  -- promoted type, see Note [Promotion]
1140         : qtycon                          { L1 $ HsTyVar $ unLoc $1 }
1141         | '(' ')'                         { LL $ HsTyVar $ getRdrName unitTyCon }
1142         | '(' kind ',' comma_kinds1 ')'   { LL $ HsTupleTy HsBoxedTuple ($2 : $4) }
1143         | '[' kind ']'                    { LL $ HsListTy $2 }
1144
1145 comma_kinds1 :: { [LHsKind RdrName] }
1146         : kind                          { [$1] }
1147         | kind  ',' comma_kinds1        { $1 : $3 }
1148
1149 {- Note [Promotion]
1150    ~~~~~~~~~~~~~~~~
1151
1152 - Syntax of promoted qualified names
1153 We write 'Nat.Zero instead of Nat.'Zero when dealing with qualified
1154 names. Moreover ticks are only allowed in types, not in kinds, for a
1155 few reasons:
1156   1. we don't need quotes since we cannot define names in kinds
1157   2. if one day we merge types and kinds, tick would mean look in DataName
1158   3. we don't have a kind namespace anyway
1159
1160 - Syntax of explicit kind polymorphism  (IA0_TODO: not yet implemented)
1161 Kind abstraction is implicit. We write
1162 > data SList (s :: k -> *) (as :: [k]) where ...
1163 because it looks like what we do in terms
1164 > id (x :: a) = x
1165
1166 - Name resolution
1167 When the user write Zero instead of 'Zero in types, we parse it a
1168 HsTyVar ("Zero", TcClsName) instead of HsTyVar ("Zero", DataName). We
1169 deal with this in the renamer. If a HsTyVar ("Zero", TcClsName) is not
1170 bounded in the type level, then we look for it in the term level (we
1171 change its namespace to DataName, see Note [Demotion] in OccName). And
1172 both become a HsTyVar ("Zero", DataName) after the renamer.
1173
1174 -}
1175
1176
1177 -----------------------------------------------------------------------------
1178 -- Datatype declarations
1179
1180 gadt_constrlist :: { Located [LConDecl RdrName] }       -- Returned in order
1181         : 'where' '{'        gadt_constrs '}'      { L (comb2 $1 $3) (unLoc $3) }
1182         | 'where' vocurly    gadt_constrs close    { L (comb2 $1 $3) (unLoc $3) }
1183         | {- empty -}                              { noLoc [] }
1184
1185 gadt_constrs :: { Located [LConDecl RdrName] }
1186         : gadt_constr ';' gadt_constrs  { L (comb2 (head $1) $3) ($1 ++ unLoc $3) }
1187         | gadt_constr                   { L (getLoc (head $1)) $1 }
1188         | {- empty -}                   { noLoc [] }
1189
1190 -- We allow the following forms:
1191 --      C :: Eq a => a -> T a
1192 --      C :: forall a. Eq a => !a -> T a
1193 --      D { x,y :: a } :: T a
1194 --      forall a. Eq a => D { x,y :: a } :: T a
1195
1196 gadt_constr :: { [LConDecl RdrName] }   -- Returns a list because of:   C,D :: ty
1197         : con_list '::' sigtype
1198                 { map (sL (comb2 $1 $3)) (mkGadtDecl (unLoc $1) $3) } 
1199
1200                 -- Deprecated syntax for GADT record declarations
1201         | oqtycon '{' fielddecls '}' '::' sigtype
1202                 {% do { cd <- mkDeprecatedGadtRecordDecl (comb2 $1 $6) $1 $3 $6
1203                       ; cd' <- checkRecordSyntax cd
1204                       ; return [cd'] } }
1205
1206 constrs :: { Located [LConDecl RdrName] }
1207         : maybe_docnext '=' constrs1    { L (comb2 $2 $3) (addConDocs (unLoc $3) $1) }
1208
1209 constrs1 :: { Located [LConDecl RdrName] }
1210         : constrs1 maybe_docnext '|' maybe_docprev constr { LL (addConDoc $5 $2 : addConDocFirst (unLoc $1) $4) }
1211         | constr                                          { L1 [$1] }
1212
1213 constr :: { LConDecl RdrName }
1214         : maybe_docnext forall context '=>' constr_stuff maybe_docprev  
1215                 { let (con,details) = unLoc $5 in 
1216                   addConDoc (L (comb4 $2 $3 $4 $5) (mkSimpleConDecl con (unLoc $2) $3 details))
1217                             ($1 `mplus` $6) }
1218         | maybe_docnext forall constr_stuff maybe_docprev
1219                 { let (con,details) = unLoc $3 in 
1220                   addConDoc (L (comb2 $2 $3) (mkSimpleConDecl con (unLoc $2) (noLoc []) details))
1221                             ($1 `mplus` $4) }
1222
1223 forall :: { Located [LHsTyVarBndr RdrName] }
1224         : 'forall' tv_bndrs '.'         { LL $2 }
1225         | {- empty -}                   { noLoc [] }
1226
1227 constr_stuff :: { Located (Located RdrName, HsConDeclDetails RdrName) }
1228 -- We parse the constructor declaration 
1229 --      C t1 t2
1230 -- as a btype (treating C as a type constructor) and then convert C to be
1231 -- a data constructor.  Reason: it might continue like this:
1232 --      C t1 t2 %: D Int
1233 -- in which case C really would be a type constructor.  We can't resolve this
1234 -- ambiguity till we come across the constructor oprerator :% (or not, more usually)
1235         : btype                         {% splitCon $1 >>= return.LL }
1236         | btype conop btype             {  LL ($2, InfixCon $1 $3) }
1237
1238 fielddecls :: { [ConDeclField RdrName] }
1239         : {- empty -}     { [] }
1240         | fielddecls1     { $1 }
1241
1242 fielddecls1 :: { [ConDeclField RdrName] }
1243         : fielddecl maybe_docnext ',' maybe_docprev fielddecls1
1244                       { [ addFieldDoc f $4 | f <- $1 ] ++ addFieldDocs $5 $2 }
1245                              -- This adds the doc $4 to each field separately
1246         | fielddecl   { $1 }
1247
1248 fielddecl :: { [ConDeclField RdrName] }    -- A list because of   f,g :: Int
1249         : maybe_docnext sig_vars '::' ctype maybe_docprev      { [ ConDeclField fld $4 ($1 `mplus` $5) 
1250                                                                  | fld <- reverse (unLoc $2) ] }
1251
1252 -- We allow the odd-looking 'inst_type' in a deriving clause, so that
1253 -- we can do deriving( forall a. C [a] ) in a newtype (GHC extension).
1254 -- The 'C [a]' part is converted to an HsPredTy by checkInstType
1255 -- We don't allow a context, but that's sorted out by the type checker.
1256 deriving :: { Located (Maybe [LHsType RdrName]) }
1257         : {- empty -}                           { noLoc Nothing }
1258         | 'deriving' qtycon                     { let { L loc tv = $2 }
1259                                                   in LL (Just [L loc (HsTyVar tv)]) } 
1260         | 'deriving' '(' ')'                    { LL (Just []) }
1261         | 'deriving' '(' inst_types1 ')'        { LL (Just $3) }
1262              -- Glasgow extension: allow partial 
1263              -- applications in derivings
1264
1265 -----------------------------------------------------------------------------
1266 -- Value definitions
1267
1268 {- Note [Declaration/signature overlap]
1269 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1270 There's an awkward overlap with a type signature.  Consider
1271         f :: Int -> Int = ...rhs...
1272    Then we can't tell whether it's a type signature or a value
1273    definition with a result signature until we see the '='.
1274    So we have to inline enough to postpone reductions until we know.
1275 -}
1276
1277 {-
1278   ATTENTION: Dirty Hackery Ahead! If the second alternative of vars is var
1279   instead of qvar, we get another shift/reduce-conflict. Consider the
1280   following programs:
1281   
1282      { (^^) :: Int->Int ; }          Type signature; only var allowed
1283
1284      { (^^) :: Int->Int = ... ; }    Value defn with result signature;
1285                                      qvar allowed (because of instance decls)
1286   
1287   We can't tell whether to reduce var to qvar until after we've read the signatures.
1288 -}
1289
1290 docdecl :: { LHsDecl RdrName }
1291         : docdecld { L1 (DocD (unLoc $1)) }
1292
1293 docdecld :: { LDocDecl }
1294         : docnext                               { L1 (DocCommentNext (unLoc $1)) }
1295         | docprev                               { L1 (DocCommentPrev (unLoc $1)) }
1296         | docnamed                              { L1 (case (unLoc $1) of (n, doc) -> DocCommentNamed n doc) }
1297         | docsection                            { L1 (case (unLoc $1) of (n, doc) -> DocGroup n doc) }
1298
1299 decl    :: { Located (OrdList (LHsDecl RdrName)) }
1300         : sigdecl               { $1 }
1301
1302         | '!' aexp rhs          {% do { let { e = LL (SectionR (LL (HsVar bang_RDR)) $2) };
1303                                         pat <- checkPattern e;
1304                                         return $ LL $ unitOL $ LL $ ValD $
1305                                                PatBind pat (unLoc $3)
1306                                                        placeHolderType placeHolderNames (Nothing,[]) } }
1307                                 -- Turn it all into an expression so that
1308                                 -- checkPattern can check that bangs are enabled
1309
1310         | infixexp opt_sig rhs  {% do { r <- checkValDef $1 $2 $3;
1311                                         let { l = comb2 $1 $> };
1312                                         return $! (sL l (unitOL $! (sL l $ ValD r))) } }
1313         | docdecl               { LL $ unitOL $1 }
1314
1315 rhs     :: { Located (GRHSs RdrName) }
1316         : '=' exp wherebinds    { sL (comb3 $1 $2 $3) $ GRHSs (unguardedRHS $2) (unLoc $3) }
1317         | gdrhs wherebinds      { LL $ GRHSs (reverse (unLoc $1)) (unLoc $2) }
1318
1319 gdrhs :: { Located [LGRHS RdrName] }
1320         : gdrhs gdrh            { LL ($2 : unLoc $1) }
1321         | gdrh                  { L1 [$1] }
1322
1323 gdrh :: { LGRHS RdrName }
1324         : '|' guardquals '=' exp        { sL (comb2 $1 $>) $ GRHS (unLoc $2) $4 }
1325
1326 sigdecl :: { Located (OrdList (LHsDecl RdrName)) }
1327         : 
1328         -- See Note [Declaration/signature overlap] for why we need infixexp here
1329           infixexp '::' sigtypedoc
1330                         {% do s <- checkValSig $1 $3 
1331                         ; return (LL $ unitOL (LL $ SigD s)) }
1332         | var ',' sig_vars '::' sigtypedoc
1333                                 { LL $ toOL [ LL $ SigD (TypeSig ($1 : unLoc $3) $5) ] }
1334         | infix prec ops        { LL $ toOL [ LL $ SigD (FixSig (FixitySig n (Fixity $2 (unLoc $1))))
1335                                              | n <- unLoc $3 ] }
1336         | '{-# INLINE' activation qvar '#-}'        
1337                 { LL $ unitOL (LL $ SigD (InlineSig $3 (mkInlinePragma (getINLINE $1) $2))) }
1338         | '{-# SPECIALISE' activation qvar '::' sigtypes1 '#-}'
1339                 { let inl_prag = mkInlinePragma (EmptyInlineSpec, FunLike) $2
1340                   in LL $ toOL [ LL $ SigD (SpecSig $3 t inl_prag) 
1341                                | t <- $5] }
1342         | '{-# SPECIALISE_INLINE' activation qvar '::' sigtypes1 '#-}'
1343                 { LL $ toOL [ LL $ SigD (SpecSig $3 t (mkInlinePragma (getSPEC_INLINE $1) $2))
1344                             | t <- $5] }
1345         | '{-# SPECIALISE' 'instance' inst_type '#-}'
1346                 { LL $ unitOL (LL $ SigD (SpecInstSig $3)) }
1347
1348 -----------------------------------------------------------------------------
1349 -- Expressions
1350
1351 quasiquote :: { Located (HsQuasiQuote RdrName) }
1352         : TH_QUASIQUOTE   { let { loc = getLoc $1
1353                                 ; ITquasiQuote (quoter, quote, quoteSpan) = unLoc $1
1354                                 ; quoterId = mkUnqual varName quoter }
1355                             in L1 (mkHsQuasiQuote quoterId (RealSrcSpan quoteSpan) quote) }
1356
1357 exp   :: { LHsExpr RdrName }
1358         : infixexp '::' sigtype         { LL $ ExprWithTySig $1 $3 }
1359         | infixexp '-<' exp             { LL $ HsArrApp $1 $3 placeHolderType HsFirstOrderApp True }
1360         | infixexp '>-' exp             { LL $ HsArrApp $3 $1 placeHolderType HsFirstOrderApp False }
1361         | infixexp '-<<' exp            { LL $ HsArrApp $1 $3 placeHolderType HsHigherOrderApp True }
1362         | infixexp '>>-' exp            { LL $ HsArrApp $3 $1 placeHolderType HsHigherOrderApp False}
1363         | infixexp                      { $1 }
1364
1365 infixexp :: { LHsExpr RdrName }
1366         : exp10                         { $1 }
1367         | infixexp qop exp10            { LL (OpApp $1 $2 (panic "fixity") $3) }
1368
1369 exp10 :: { LHsExpr RdrName }
1370         : '\\' apat apats opt_asig '->' exp     
1371                         { LL $ HsLam (mkMatchGroup [LL $ Match ($2:$3) $4
1372                                                                 (unguardedGRHSs $6)
1373                                                             ]) }
1374         | 'let' binds 'in' exp                  { LL $ HsLet (unLoc $2) $4 }
1375         | 'if' exp optSemi 'then' exp optSemi 'else' exp
1376                                         {% checkDoAndIfThenElse $2 $3 $5 $6 $8 >>
1377                                            return (LL $ mkHsIf $2 $5 $8) }
1378         | 'case' exp 'of' altslist              { LL $ HsCase $2 (mkMatchGroup (unLoc $4)) }
1379         | '-' fexp                              { LL $ NegApp $2 noSyntaxExpr }
1380
1381         | 'do' stmtlist                 { L (comb2 $1 $2) (mkHsDo DoExpr  (unLoc $2)) }
1382         | 'mdo' stmtlist                { L (comb2 $1 $2) (mkHsDo MDoExpr (unLoc $2)) }
1383
1384         | scc_annot exp                         { LL $ if opt_SccProfilingOn
1385                                                         then HsSCC (unLoc $1) $2
1386                                                         else HsPar $2 }
1387         | hpc_annot exp                         { LL $ if opt_Hpc
1388                                                         then HsTickPragma (unLoc $1) $2
1389                                                         else HsPar $2 }
1390
1391         | 'proc' aexp '->' exp  
1392                         {% checkPattern $2 >>= \ p -> 
1393                            return (LL $ HsProc p (LL $ HsCmdTop $4 [] 
1394                                                    placeHolderType undefined)) }
1395                                                 -- TODO: is LL right here?
1396
1397         | '{-# CORE' STRING '#-}' exp           { LL $ HsCoreAnn (getSTRING $2) $4 }
1398                                                     -- hdaume: core annotation
1399         | fexp                                  { $1 }
1400
1401 optSemi :: { Bool }
1402         : ';'         { True }
1403         | {- empty -} { False }
1404
1405 scc_annot :: { Located FastString }
1406         : '_scc_' STRING                        {% (addWarning Opt_WarnWarningsDeprecations (getLoc $1) (text "_scc_ is deprecated; use an SCC pragma instead")) >>= \_ ->
1407                                    ( do scc <- getSCC $2; return $ LL scc ) }
1408         | '{-# SCC' STRING '#-}'                {% do scc <- getSCC $2; return $ LL scc }
1409         | '{-# SCC' VARID  '#-}'                { LL (getVARID $2) }
1410
1411 hpc_annot :: { Located (FastString,(Int,Int),(Int,Int)) }
1412         : '{-# GENERATED' STRING INTEGER ':' INTEGER '-' INTEGER ':' INTEGER '#-}'
1413                                                 { LL $ (getSTRING $2
1414                                                        ,( fromInteger $ getINTEGER $3
1415                                                         , fromInteger $ getINTEGER $5
1416                                                         )
1417                                                        ,( fromInteger $ getINTEGER $7
1418                                                         , fromInteger $ getINTEGER $9
1419                                                         )
1420                                                        )
1421                                                  }
1422
1423 fexp    :: { LHsExpr RdrName }
1424         : fexp aexp                             { LL $ HsApp $1 $2 }
1425         | aexp                                  { $1 }
1426
1427 aexp    :: { LHsExpr RdrName }
1428         : qvar '@' aexp                 { LL $ EAsPat $1 $3 }
1429         | '~' aexp                      { LL $ ELazyPat $2 }
1430         | aexp1                 { $1 }
1431
1432 aexp1   :: { LHsExpr RdrName }
1433         : aexp1 '{' fbinds '}'  {% do { r <- mkRecConstrOrUpdate $1 (comb2 $2 $4) $3
1434                                       ; checkRecordSyntax (LL r) }}
1435         | aexp2                 { $1 }
1436
1437 aexp2   :: { LHsExpr RdrName }
1438         : ipvar                         { L1 (HsIPVar $! unLoc $1) }
1439         | qcname                        { L1 (HsVar   $! unLoc $1) }
1440         | literal                       { L1 (HsLit   $! unLoc $1) }
1441 -- This will enable overloaded strings permanently.  Normally the renamer turns HsString
1442 -- into HsOverLit when -foverloaded-strings is on.
1443 --      | STRING                        { sL (getLoc $1) (HsOverLit $! mkHsIsString (getSTRING $1) placeHolderType) }
1444         | INTEGER                       { sL (getLoc $1) (HsOverLit $! mkHsIntegral (getINTEGER $1) placeHolderType) }
1445         | RATIONAL                      { sL (getLoc $1) (HsOverLit $! mkHsFractional (getRATIONAL $1) placeHolderType) }
1446
1447         -- N.B.: sections get parsed by these next two productions.
1448         -- This allows you to write, e.g., '(+ 3, 4 -)', which isn't
1449         -- correct Haskell (you'd have to write '((+ 3), (4 -))')
1450         -- but the less cluttered version fell out of having texps.
1451         | '(' texp ')'                  { LL (HsPar $2) }
1452         | '(' tup_exprs ')'             { LL (ExplicitTuple $2 Boxed) }
1453
1454         | '(#' texp '#)'                { LL (ExplicitTuple [Present $2] Unboxed) }
1455         | '(#' tup_exprs '#)'           { LL (ExplicitTuple $2 Unboxed) }
1456
1457         | '[' list ']'                  { LL (unLoc $2) }
1458         | '[:' parr ':]'                { LL (unLoc $2) }
1459         | '_'                           { L1 EWildPat }
1460         
1461         -- Template Haskell Extension
1462         | TH_ID_SPLICE          { L1 $ HsSpliceE (mkHsSplice 
1463                                         (L1 $ HsVar (mkUnqual varName 
1464                                                         (getTH_ID_SPLICE $1)))) } 
1465         | '$(' exp ')'          { LL $ HsSpliceE (mkHsSplice $2) }               
1466
1467
1468         | SIMPLEQUOTE  qvar     { LL $ HsBracket (VarBr True  (unLoc $2)) }
1469         | SIMPLEQUOTE  qcon     { LL $ HsBracket (VarBr True  (unLoc $2)) }
1470         | TH_TY_QUOTE tyvar     { LL $ HsBracket (VarBr False (unLoc $2)) }
1471         | TH_TY_QUOTE gtycon    { LL $ HsBracket (VarBr False (unLoc $2)) }
1472         | '[|' exp '|]'         { LL $ HsBracket (ExpBr $2) }                       
1473         | '[t|' ctype '|]'      { LL $ HsBracket (TypBr $2) }                       
1474         | '[p|' infixexp '|]'   {% checkPattern $2 >>= \p ->
1475                                         return (LL $ HsBracket (PatBr p)) }
1476         | '[d|' cvtopbody '|]'  { LL $ HsBracket (DecBrL $2) }
1477         | quasiquote            { L1 (HsQuasiQuoteE (unLoc $1)) }
1478
1479         -- arrow notation extension
1480         | '(|' aexp2 cmdargs '|)'       { LL $ HsArrForm $2 Nothing (reverse $3) }
1481
1482 cmdargs :: { [LHsCmdTop RdrName] }
1483         : cmdargs acmd                  { $2 : $1 }
1484         | {- empty -}                   { [] }
1485
1486 acmd    :: { LHsCmdTop RdrName }
1487         : aexp2                 { L1 $ HsCmdTop $1 [] placeHolderType undefined }
1488
1489 cvtopbody :: { [LHsDecl RdrName] }
1490         :  '{'            cvtopdecls0 '}'               { $2 }
1491         |      vocurly    cvtopdecls0 close             { $2 }
1492
1493 cvtopdecls0 :: { [LHsDecl RdrName] }
1494         : {- empty -}           { [] }
1495         | cvtopdecls            { $1 }
1496
1497 -----------------------------------------------------------------------------
1498 -- Tuple expressions
1499
1500 -- "texp" is short for tuple expressions: 
1501 -- things that can appear unparenthesized as long as they're
1502 -- inside parens or delimitted by commas
1503 texp :: { LHsExpr RdrName }
1504         : exp                           { $1 }
1505
1506         -- Note [Parsing sections]
1507         -- ~~~~~~~~~~~~~~~~~~~~~~~
1508         -- We include left and right sections here, which isn't
1509         -- technically right according to the Haskell standard.
1510         -- For example (3 +, True) isn't legal.
1511         -- However, we want to parse bang patterns like
1512         --      (!x, !y)
1513         -- and it's convenient to do so here as a section
1514         -- Then when converting expr to pattern we unravel it again
1515         -- Meanwhile, the renamer checks that real sections appear
1516         -- inside parens.
1517         | infixexp qop        { LL $ SectionL $1 $2 }
1518         | qopm infixexp       { LL $ SectionR $1 $2 }
1519
1520        -- View patterns get parenthesized above
1521         | exp '->' texp   { LL $ EViewPat $1 $3 }
1522
1523 -- Always at least one comma
1524 tup_exprs :: { [HsTupArg RdrName] }
1525            : texp commas_tup_tail  { Present $1 : $2 }
1526            | commas tup_tail       { replicate $1 missingTupArg ++ $2 }
1527
1528 -- Always starts with commas; always follows an expr
1529 commas_tup_tail :: { [HsTupArg RdrName] }
1530 commas_tup_tail : commas tup_tail  { replicate ($1-1) missingTupArg ++ $2 }
1531
1532 -- Always follows a comma
1533 tup_tail :: { [HsTupArg RdrName] }
1534           : texp commas_tup_tail        { Present $1 : $2 }
1535           | texp                        { [Present $1] }
1536           | {- empty -}                 { [missingTupArg] }
1537
1538 -----------------------------------------------------------------------------
1539 -- List expressions
1540
1541 -- The rules below are little bit contorted to keep lexps left-recursive while
1542 -- avoiding another shift/reduce-conflict.
1543
1544 list :: { LHsExpr RdrName }
1545         : texp                  { L1 $ ExplicitList placeHolderType [$1] }
1546         | lexps                 { L1 $ ExplicitList placeHolderType (reverse (unLoc $1)) }
1547         | texp '..'             { LL $ ArithSeq noPostTcExpr (From $1) }
1548         | texp ',' exp '..'     { LL $ ArithSeq noPostTcExpr (FromThen $1 $3) }
1549         | texp '..' exp         { LL $ ArithSeq noPostTcExpr (FromTo $1 $3) }
1550         | texp ',' exp '..' exp { LL $ ArithSeq noPostTcExpr (FromThenTo $1 $3 $5) }
1551         | texp '|' flattenedpquals      
1552              {% checkMonadComp >>= \ ctxt ->
1553                 return (sL (comb2 $1 $>) $ 
1554                         mkHsComp ctxt (unLoc $3) $1) }
1555
1556 lexps :: { Located [LHsExpr RdrName] }
1557         : lexps ',' texp                { LL (((:) $! $3) $! unLoc $1) }
1558         | texp ',' texp                 { LL [$3,$1] }
1559
1560 -----------------------------------------------------------------------------
1561 -- List Comprehensions
1562
1563 flattenedpquals :: { Located [LStmt RdrName] }
1564     : pquals   { case (unLoc $1) of
1565                     [qs] -> L1 qs
1566                     -- We just had one thing in our "parallel" list so 
1567                     -- we simply return that thing directly
1568                     
1569                     qss -> L1 [L1 $ ParStmt [(qs, undefined) | qs <- qss] noSyntaxExpr noSyntaxExpr noSyntaxExpr]
1570                     -- We actually found some actual parallel lists so
1571                     -- we wrap them into as a ParStmt
1572                 }
1573
1574 pquals :: { Located [[LStmt RdrName]] }
1575     : squals '|' pquals     { L (getLoc $2) (reverse (unLoc $1) : unLoc $3) }
1576     | squals                { L (getLoc $1) [reverse (unLoc $1)] }
1577
1578 squals :: { Located [LStmt RdrName] }   -- In reverse order, because the last 
1579                                         -- one can "grab" the earlier ones
1580     : squals ',' transformqual               { LL [L (getLoc $3) ((unLoc $3) (reverse (unLoc $1)))] }
1581     | squals ',' qual                        { LL ($3 : unLoc $1) }
1582     | transformqual                          { LL [L (getLoc $1) ((unLoc $1) [])] }
1583     | qual                                   { L1 [$1] }
1584 --  | transformquals1 ',' '{|' pquals '|}'   { LL ($4 : unLoc $1) }
1585 --  | '{|' pquals '|}'                       { L1 [$2] }
1586
1587
1588 -- It is possible to enable bracketing (associating) qualifier lists
1589 -- by uncommenting the lines with {| |} above. Due to a lack of
1590 -- consensus on the syntax, this feature is not being used until we
1591 -- get user demand.
1592
1593 transformqual :: { Located ([LStmt RdrName] -> Stmt RdrName) }
1594                         -- Function is applied to a list of stmts *in order*
1595     : 'then' exp                           { LL $ \ss -> (mkTransformStmt    ss $2)    }
1596     | 'then' exp 'by' exp                  { LL $ \ss -> (mkTransformByStmt  ss $2 $4) }
1597     | 'then' 'group' 'using' exp           { LL $ \ss -> (mkGroupUsingStmt   ss $4)    }
1598     | 'then' 'group' 'by' exp 'using' exp  { LL $ \ss -> (mkGroupByUsingStmt ss $4 $6) }
1599
1600 -- Note that 'group' is a special_id, which means that you can enable
1601 -- TransformListComp while still using Data.List.group. However, this
1602 -- introduces a shift/reduce conflict. Happy chooses to resolve the conflict
1603 -- in by choosing the "group by" variant, which is what we want.
1604
1605 -----------------------------------------------------------------------------
1606 -- Parallel array expressions
1607
1608 -- The rules below are little bit contorted; see the list case for details.
1609 -- Note that, in contrast to lists, we only have finite arithmetic sequences.
1610 -- Moreover, we allow explicit arrays with no element (represented by the nil
1611 -- constructor in the list case).
1612
1613 parr :: { LHsExpr RdrName }
1614         :                               { noLoc (ExplicitPArr placeHolderType []) }
1615         | texp                          { L1 $ ExplicitPArr placeHolderType [$1] }
1616         | lexps                         { L1 $ ExplicitPArr placeHolderType 
1617                                                        (reverse (unLoc $1)) }
1618         | texp '..' exp                 { LL $ PArrSeq noPostTcExpr (FromTo $1 $3) }
1619         | texp ',' exp '..' exp         { LL $ PArrSeq noPostTcExpr (FromThenTo $1 $3 $5) }
1620         | texp '|' flattenedpquals      { LL $ mkHsComp PArrComp (unLoc $3) $1 }
1621
1622 -- We are reusing `lexps' and `flattenedpquals' from the list case.
1623
1624 -----------------------------------------------------------------------------
1625 -- Guards
1626
1627 guardquals :: { Located [LStmt RdrName] }
1628     : guardquals1           { L (getLoc $1) (reverse (unLoc $1)) }
1629
1630 guardquals1 :: { Located [LStmt RdrName] }
1631     : guardquals1 ',' qual  { LL ($3 : unLoc $1) }
1632     | qual                  { L1 [$1] }
1633
1634 -----------------------------------------------------------------------------
1635 -- Case alternatives
1636
1637 altslist :: { Located [LMatch RdrName] }
1638         : '{'            alts '}'       { LL (reverse (unLoc $2)) }
1639         |     vocurly    alts  close    { L (getLoc $2) (reverse (unLoc $2)) }
1640
1641 alts    :: { Located [LMatch RdrName] }
1642         : alts1                         { L1 (unLoc $1) }
1643         | ';' alts                      { LL (unLoc $2) }
1644
1645 alts1   :: { Located [LMatch RdrName] }
1646         : alts1 ';' alt                 { LL ($3 : unLoc $1) }
1647         | alts1 ';'                     { LL (unLoc $1) }
1648         | alt                           { L1 [$1] }
1649
1650 alt     :: { LMatch RdrName }
1651         : pat opt_sig alt_rhs           { LL (Match [$1] $2 (unLoc $3)) }
1652
1653 alt_rhs :: { Located (GRHSs RdrName) }
1654         : ralt wherebinds               { LL (GRHSs (unLoc $1) (unLoc $2)) }
1655
1656 ralt :: { Located [LGRHS RdrName] }
1657         : '->' exp                      { LL (unguardedRHS $2) }
1658         | gdpats                        { L1 (reverse (unLoc $1)) }
1659
1660 gdpats :: { Located [LGRHS RdrName] }
1661         : gdpats gdpat                  { LL ($2 : unLoc $1) }
1662         | gdpat                         { L1 [$1] }
1663
1664 gdpat   :: { LGRHS RdrName }
1665         : '|' guardquals '->' exp               { sL (comb2 $1 $>) $ GRHS (unLoc $2) $4 }
1666
1667 -- 'pat' recognises a pattern, including one with a bang at the top
1668 --      e.g.  "!x" or "!(x,y)" or "C a b" etc
1669 -- Bangs inside are parsed as infix operator applications, so that
1670 -- we parse them right when bang-patterns are off
1671 pat     :: { LPat RdrName }
1672 pat     :  exp                  {% checkPattern $1 }
1673         | '!' aexp              {% checkPattern (LL (SectionR (L1 (HsVar bang_RDR)) $2)) }
1674
1675 apat   :: { LPat RdrName }      
1676 apat    : aexp                  {% checkPattern $1 }
1677         | '!' aexp              {% checkPattern (LL (SectionR (L1 (HsVar bang_RDR)) $2)) }
1678
1679 apats  :: { [LPat RdrName] }
1680         : apat apats            { $1 : $2 }
1681         | {- empty -}           { [] }
1682
1683 -----------------------------------------------------------------------------
1684 -- Statement sequences
1685
1686 stmtlist :: { Located [LStmt RdrName] }
1687         : '{'           stmts '}'       { LL (unLoc $2) }
1688         |     vocurly   stmts close     { $2 }
1689
1690 --      do { ;; s ; s ; ; s ;; }
1691 -- The last Stmt should be an expression, but that's hard to enforce
1692 -- here, because we need too much lookahead if we see do { e ; }
1693 -- So we use ExprStmts throughout, and switch the last one over
1694 -- in ParseUtils.checkDo instead
1695 stmts :: { Located [LStmt RdrName] }
1696         : stmt stmts_help               { LL ($1 : unLoc $2) }
1697         | ';' stmts                     { LL (unLoc $2) }
1698         | {- empty -}                   { noLoc [] }
1699
1700 stmts_help :: { Located [LStmt RdrName] } -- might be empty
1701         : ';' stmts                     { LL (unLoc $2) }
1702         | {- empty -}                   { noLoc [] }
1703
1704 -- For typing stmts at the GHCi prompt, where 
1705 -- the input may consist of just comments.
1706 maybe_stmt :: { Maybe (LStmt RdrName) }
1707         : stmt                          { Just $1 }
1708         | {- nothing -}                 { Nothing }
1709
1710 stmt  :: { LStmt RdrName }
1711         : qual                              { $1 }
1712         | 'rec' stmtlist                { LL $ mkRecStmt (unLoc $2) }
1713
1714 qual  :: { LStmt RdrName }
1715     : pat '<-' exp                      { LL $ mkBindStmt $1 $3 }
1716     | exp                                   { L1 $ mkExprStmt $1 }
1717     | 'let' binds                       { LL $ LetStmt (unLoc $2) }
1718
1719 -----------------------------------------------------------------------------
1720 -- Record Field Update/Construction
1721
1722 fbinds  :: { ([HsRecField RdrName (LHsExpr RdrName)], Bool) }
1723         : fbinds1                       { $1 }
1724         | {- empty -}                   { ([], False) }
1725
1726 fbinds1 :: { ([HsRecField RdrName (LHsExpr RdrName)], Bool) }
1727         : fbind ',' fbinds1             { case $3 of (flds, dd) -> ($1 : flds, dd) } 
1728         | fbind                         { ([$1], False) }
1729         | '..'                          { ([],   True) }
1730   
1731 fbind   :: { HsRecField RdrName (LHsExpr RdrName) }
1732         : qvar '=' exp  { HsRecField $1 $3                False }
1733         | qvar          { HsRecField $1 placeHolderPunRhs True }
1734                         -- In the punning case, use a place-holder
1735                         -- The renamer fills in the final value
1736
1737 -----------------------------------------------------------------------------
1738 -- Implicit Parameter Bindings
1739
1740 dbinds  :: { Located [LIPBind RdrName] }
1741         : dbinds ';' dbind              { let { this = $3; rest = unLoc $1 }
1742                               in rest `seq` this `seq` LL (this : rest) }
1743         | dbinds ';'                    { LL (unLoc $1) }
1744         | dbind                         { let this = $1 in this `seq` L1 [this] }
1745 --      | {- empty -}                   { [] }
1746
1747 dbind   :: { LIPBind RdrName }
1748 dbind   : ipvar '=' exp                 { LL (IPBind (unLoc $1) $3) }
1749
1750 ipvar   :: { Located (IPName RdrName) }
1751         : IPDUPVARID            { L1 (IPName (mkUnqual varName (getIPDUPVARID $1))) }
1752
1753 -----------------------------------------------------------------------------
1754 -- Warnings and deprecations
1755
1756 namelist :: { Located [RdrName] }
1757 namelist : name_var              { L1 [unLoc $1] }
1758          | name_var ',' namelist { LL (unLoc $1 : unLoc $3) }
1759
1760 name_var :: { Located RdrName }
1761 name_var : var { $1 }
1762          | con { $1 }
1763
1764 -----------------------------------------
1765 -- Data constructors
1766 qcon    :: { Located RdrName }
1767         : qconid                { $1 }
1768         | '(' qconsym ')'       { LL (unLoc $2) }
1769         | sysdcon               { L1 $ nameRdrName (dataConName (unLoc $1)) }
1770 -- The case of '[:' ':]' is part of the production `parr'
1771
1772 con     :: { Located RdrName }
1773         : conid                 { $1 }
1774         | '(' consym ')'        { LL (unLoc $2) }
1775         | sysdcon               { L1 $ nameRdrName (dataConName (unLoc $1)) }
1776
1777 con_list :: { Located [Located RdrName] }
1778 con_list : con                  { L1 [$1] }
1779          | con ',' con_list     { LL ($1 : unLoc $3) }
1780
1781 sysdcon :: { Located DataCon }  -- Wired in data constructors
1782         : '(' ')'               { LL unitDataCon }
1783         | '(' commas ')'        { LL $ tupleCon BoxedTuple ($2 + 1) }
1784         | '(#' '#)'             { LL $ unboxedUnitDataCon }
1785         | '(#' commas '#)'      { LL $ tupleCon UnboxedTuple ($2 + 1) }
1786         | '[' ']'               { LL nilDataCon }
1787
1788 conop :: { Located RdrName }
1789         : consym                { $1 }  
1790         | '`' conid '`'         { LL (unLoc $2) }
1791
1792 qconop :: { Located RdrName }
1793         : qconsym               { $1 }
1794         | '`' qconid '`'        { LL (unLoc $2) }
1795
1796 ----------------------------------------------------------------------------
1797 -- Type constructors
1798
1799
1800 -- See Note [Unit tuples] in HsTypes for the distinction 
1801 -- between gtycon and ntgtycon
1802 gtycon :: { Located RdrName }  -- A "general" qualified tycon, including unit tuples
1803         : ntgtycon                      { $1 }
1804         | '(' ')'                       { LL $ getRdrName unitTyCon }
1805         | '(#' '#)'                     { LL $ getRdrName unboxedUnitTyCon }
1806
1807 ntgtycon :: { Located RdrName }  -- A "general" qualified tycon, excluding unit tuples
1808         : oqtycon                       { $1 }
1809         | '(' commas ')'                { LL $ getRdrName (tupleTyCon BoxedTuple ($2 + 1)) }
1810         | '(#' commas '#)'              { LL $ getRdrName (tupleTyCon UnboxedTuple ($2 + 1)) }
1811         | '(' '->' ')'                  { LL $ getRdrName funTyCon }
1812         | '[' ']'                       { LL $ listTyCon_RDR }
1813         | '[:' ':]'                     { LL $ parrTyCon_RDR }
1814         | '(' '~#' ')'                  { LL $ getRdrName eqPrimTyCon }
1815
1816 oqtycon :: { Located RdrName }  -- An "ordinary" qualified tycon;
1817                                 -- These can appear in export lists
1818         : qtycon                        { $1 }
1819         | '(' qtyconsym ')'             { LL (unLoc $2) }
1820         | '(' '~' ')'                   { LL $ eqTyCon_RDR }
1821
1822 qtyconop :: { Located RdrName } -- Qualified or unqualified
1823         : qtyconsym                     { $1 }
1824         | '`' qtycon '`'                { LL (unLoc $2) }
1825
1826 qtycon :: { Located RdrName }   -- Qualified or unqualified
1827         : QCONID                        { L1 $! mkQual tcClsName (getQCONID $1) }
1828         | PREFIXQCONSYM                 { L1 $! mkQual tcClsName (getPREFIXQCONSYM $1) }
1829         | tycon                         { $1 }
1830
1831 tycon   :: { Located RdrName }  -- Unqualified
1832         : CONID                         { L1 $! mkUnqual tcClsName (getCONID $1) }
1833
1834 qtyconsym :: { Located RdrName }
1835         : QCONSYM                       { L1 $! mkQual tcClsName (getQCONSYM $1) }
1836         | tyconsym                      { $1 }
1837
1838 tyconsym :: { Located RdrName }
1839         : CONSYM                        { L1 $! mkUnqual tcClsName (getCONSYM $1) }
1840
1841 -----------------------------------------------------------------------------
1842 -- Operators
1843
1844 op      :: { Located RdrName }   -- used in infix decls
1845         : varop                 { $1 }
1846         | conop                 { $1 }
1847
1848 varop   :: { Located RdrName }
1849         : varsym                { $1 }
1850         | '`' varid '`'         { LL (unLoc $2) }
1851
1852 qop     :: { LHsExpr RdrName }   -- used in sections
1853         : qvarop                { L1 $ HsVar (unLoc $1) }
1854         | qconop                { L1 $ HsVar (unLoc $1) }
1855
1856 qopm    :: { LHsExpr RdrName }   -- used in sections
1857         : qvaropm               { L1 $ HsVar (unLoc $1) }
1858         | qconop                { L1 $ HsVar (unLoc $1) }
1859
1860 qvarop :: { Located RdrName }
1861         : qvarsym               { $1 }
1862         | '`' qvarid '`'        { LL (unLoc $2) }
1863
1864 qvaropm :: { Located RdrName }
1865         : qvarsym_no_minus      { $1 }
1866         | '`' qvarid '`'        { LL (unLoc $2) }
1867
1868 -----------------------------------------------------------------------------
1869 -- Type variables
1870
1871 tyvar   :: { Located RdrName }
1872 tyvar   : tyvarid               { $1 }
1873         | '(' tyvarsym ')'      { LL (unLoc $2) }
1874
1875 tyvarop :: { Located RdrName }
1876 tyvarop : '`' tyvarid '`'       { LL (unLoc $2) }
1877         | tyvarsym              { $1 }
1878         | '.'                   {% parseErrorSDoc (getLoc $1) 
1879                                       (vcat [ptext (sLit "Illegal symbol '.' in type"), 
1880                                              ptext (sLit "Perhaps you intended -XRankNTypes or similar flag"),
1881                                              ptext (sLit "to enable explicit-forall syntax: forall <tvs>. <type>")])
1882                                 }
1883
1884 tyvarid :: { Located RdrName }
1885         : VARID                 { L1 $! mkUnqual tvName (getVARID $1) }
1886         | special_id            { L1 $! mkUnqual tvName (unLoc $1) }
1887         | 'unsafe'              { L1 $! mkUnqual tvName (fsLit "unsafe") }
1888         | 'safe'                { L1 $! mkUnqual tvName (fsLit "safe") }
1889         | 'interruptible'       { L1 $! mkUnqual tvName (fsLit "interruptible") }
1890
1891 tyvarsym :: { Located RdrName }
1892 -- Does not include "!", because that is used for strictness marks
1893 --               or ".", because that separates the quantified type vars from the rest
1894 --               or "*", because that's used for kinds
1895 tyvarsym : VARSYM               { L1 $! mkUnqual tvName (getVARSYM $1) }
1896
1897 -----------------------------------------------------------------------------
1898 -- Variables 
1899
1900 var     :: { Located RdrName }
1901         : varid                 { $1 }
1902         | '(' varsym ')'        { LL (unLoc $2) }
1903
1904 qvar    :: { Located RdrName }
1905         : qvarid                { $1 }
1906         | '(' varsym ')'        { LL (unLoc $2) }
1907         | '(' qvarsym1 ')'      { LL (unLoc $2) }
1908 -- We've inlined qvarsym here so that the decision about
1909 -- whether it's a qvar or a var can be postponed until
1910 -- *after* we see the close paren.
1911
1912 qvarid :: { Located RdrName }
1913         : varid                 { $1 }
1914         | QVARID                { L1 $! mkQual varName (getQVARID $1) }
1915         | PREFIXQVARSYM         { L1 $! mkQual varName (getPREFIXQVARSYM $1) }
1916
1917 varid :: { Located RdrName }
1918         : VARID                 { L1 $! mkUnqual varName (getVARID $1) }
1919         | special_id            { L1 $! mkUnqual varName (unLoc $1) }
1920         | 'unsafe'              { L1 $! mkUnqual varName (fsLit "unsafe") }
1921         | 'safe'                { L1 $! mkUnqual varName (fsLit "safe") }
1922         | 'interruptible'       { L1 $! mkUnqual varName (fsLit "interruptible") }
1923         | 'forall'              { L1 $! mkUnqual varName (fsLit "forall") }
1924         | 'family'              { L1 $! mkUnqual varName (fsLit "family") }
1925
1926 qvarsym :: { Located RdrName }
1927         : varsym                { $1 }
1928         | qvarsym1              { $1 }
1929
1930 qvarsym_no_minus :: { Located RdrName }
1931         : varsym_no_minus       { $1 }
1932         | qvarsym1              { $1 }
1933
1934 qvarsym1 :: { Located RdrName }
1935 qvarsym1 : QVARSYM              { L1 $ mkQual varName (getQVARSYM $1) }
1936
1937 varsym :: { Located RdrName }
1938         : varsym_no_minus       { $1 }
1939         | '-'                   { L1 $ mkUnqual varName (fsLit "-") }
1940
1941 varsym_no_minus :: { Located RdrName } -- varsym not including '-'
1942         : VARSYM                { L1 $ mkUnqual varName (getVARSYM $1) }
1943         | special_sym           { L1 $ mkUnqual varName (unLoc $1) }
1944
1945
1946 -- These special_ids are treated as keywords in various places, 
1947 -- but as ordinary ids elsewhere.   'special_id' collects all these
1948 -- except 'unsafe', 'interruptible', 'forall', and 'family' whose treatment differs
1949 -- depending on context 
1950 special_id :: { Located FastString }
1951 special_id
1952         : 'as'                  { L1 (fsLit "as") }
1953         | 'qualified'           { L1 (fsLit "qualified") }
1954         | 'hiding'              { L1 (fsLit "hiding") }
1955         | 'export'              { L1 (fsLit "export") }
1956         | 'label'               { L1 (fsLit "label")  }
1957         | 'dynamic'             { L1 (fsLit "dynamic") }
1958         | 'stdcall'             { L1 (fsLit "stdcall") }
1959         | 'ccall'               { L1 (fsLit "ccall") }
1960         | 'capi'                { L1 (fsLit "capi") }
1961         | 'prim'                { L1 (fsLit "prim") }
1962         | 'group'               { L1 (fsLit "group") }
1963
1964 special_sym :: { Located FastString }
1965 special_sym : '!'       { L1 (fsLit "!") }
1966             | '.'       { L1 (fsLit ".") }
1967             | '*'       { L1 (fsLit "*") }
1968
1969 -----------------------------------------------------------------------------
1970 -- Data constructors
1971
1972 qconid :: { Located RdrName }   -- Qualified or unqualified
1973         : conid                 { $1 }
1974         | QCONID                { L1 $! mkQual dataName (getQCONID $1) }
1975         | PREFIXQCONSYM         { L1 $! mkQual dataName (getPREFIXQCONSYM $1) }
1976
1977 conid   :: { Located RdrName }
1978         : CONID                 { L1 $ mkUnqual dataName (getCONID $1) }
1979
1980 qconsym :: { Located RdrName }  -- Qualified or unqualified
1981         : consym                { $1 }
1982         | QCONSYM               { L1 $ mkQual dataName (getQCONSYM $1) }
1983
1984 consym :: { Located RdrName }
1985         : CONSYM                { L1 $ mkUnqual dataName (getCONSYM $1) }
1986
1987         -- ':' means only list cons
1988         | ':'                   { L1 $ consDataCon_RDR }
1989
1990
1991 -----------------------------------------------------------------------------
1992 -- Literals
1993
1994 literal :: { Located HsLit }
1995         : CHAR                  { L1 $ HsChar       $ getCHAR $1 }
1996         | STRING                { L1 $ HsString     $ getSTRING $1 }
1997         | PRIMINTEGER           { L1 $ HsIntPrim    $ getPRIMINTEGER $1 }
1998         | PRIMWORD              { L1 $ HsWordPrim    $ getPRIMWORD $1 }
1999         | PRIMCHAR              { L1 $ HsCharPrim   $ getPRIMCHAR $1 }
2000         | PRIMSTRING            { L1 $ HsStringPrim $ getPRIMSTRING $1 }
2001         | PRIMFLOAT             { L1 $ HsFloatPrim  $ getPRIMFLOAT $1 }
2002         | PRIMDOUBLE            { L1 $ HsDoublePrim $ getPRIMDOUBLE $1 }
2003
2004 -----------------------------------------------------------------------------
2005 -- Layout
2006
2007 close :: { () }
2008         : vccurly               { () } -- context popped in lexer.
2009         | error                 {% popContext }
2010
2011 -----------------------------------------------------------------------------
2012 -- Miscellaneous (mostly renamings)
2013
2014 modid   :: { Located ModuleName }
2015         : CONID                 { L1 $ mkModuleNameFS (getCONID $1) }
2016         | QCONID                { L1 $ let (mod,c) = getQCONID $1 in
2017                                   mkModuleNameFS
2018                                    (mkFastString
2019                                      (unpackFS mod ++ '.':unpackFS c))
2020                                 }
2021
2022 commas :: { Int }
2023         : commas ','                    { $1 + 1 }
2024         | ','                           { 1 }
2025
2026 -----------------------------------------------------------------------------
2027 -- Documentation comments
2028
2029 docnext :: { LHsDocString }
2030   : DOCNEXT {% return (L1 (HsDocString (mkFastString (getDOCNEXT $1)))) }
2031
2032 docprev :: { LHsDocString }
2033   : DOCPREV {% return (L1 (HsDocString (mkFastString (getDOCPREV $1)))) }
2034
2035 docnamed :: { Located (String, HsDocString) }
2036   : DOCNAMED {%
2037       let string = getDOCNAMED $1 
2038           (name, rest) = break isSpace string
2039       in return (L1 (name, HsDocString (mkFastString rest))) }
2040
2041 docsection :: { Located (Int, HsDocString) }
2042   : DOCSECTION {% let (n, doc) = getDOCSECTION $1 in
2043         return (L1 (n, HsDocString (mkFastString doc))) }
2044
2045 moduleheader :: { Maybe LHsDocString }
2046         : DOCNEXT {% let string = getDOCNEXT $1 in
2047                      return (Just (L1 (HsDocString (mkFastString string)))) }
2048
2049 maybe_docprev :: { Maybe LHsDocString }
2050         : docprev                       { Just $1 }
2051         | {- empty -}                   { Nothing }
2052
2053 maybe_docnext :: { Maybe LHsDocString }
2054         : docnext                       { Just $1 }
2055         | {- empty -}                   { Nothing }
2056
2057 {
2058 happyError :: P a
2059 happyError = srcParseFail
2060
2061 getVARID        (L _ (ITvarid    x)) = x
2062 getCONID        (L _ (ITconid    x)) = x
2063 getVARSYM       (L _ (ITvarsym   x)) = x
2064 getCONSYM       (L _ (ITconsym   x)) = x
2065 getQVARID       (L _ (ITqvarid   x)) = x
2066 getQCONID       (L _ (ITqconid   x)) = x
2067 getQVARSYM      (L _ (ITqvarsym  x)) = x
2068 getQCONSYM      (L _ (ITqconsym  x)) = x
2069 getPREFIXQVARSYM (L _ (ITprefixqvarsym  x)) = x
2070 getPREFIXQCONSYM (L _ (ITprefixqconsym  x)) = x
2071 getIPDUPVARID   (L _ (ITdupipvarid   x)) = x
2072 getCHAR         (L _ (ITchar     x)) = x
2073 getSTRING       (L _ (ITstring   x)) = x
2074 getINTEGER      (L _ (ITinteger  x)) = x
2075 getRATIONAL     (L _ (ITrational x)) = x
2076 getPRIMCHAR     (L _ (ITprimchar   x)) = x
2077 getPRIMSTRING   (L _ (ITprimstring x)) = x
2078 getPRIMINTEGER  (L _ (ITprimint    x)) = x
2079 getPRIMWORD     (L _ (ITprimword x)) = x
2080 getPRIMFLOAT    (L _ (ITprimfloat  x)) = x
2081 getPRIMDOUBLE   (L _ (ITprimdouble x)) = x
2082 getTH_ID_SPLICE (L _ (ITidEscape x)) = x
2083 getINLINE       (L _ (ITinline_prag inl conl)) = (inl,conl)
2084 getSPEC_INLINE  (L _ (ITspec_inline_prag True))  = (Inline,  FunLike)
2085 getSPEC_INLINE  (L _ (ITspec_inline_prag False)) = (NoInline,FunLike)
2086
2087 getDOCNEXT (L _ (ITdocCommentNext x)) = x
2088 getDOCPREV (L _ (ITdocCommentPrev x)) = x
2089 getDOCNAMED (L _ (ITdocCommentNamed x)) = x
2090 getDOCSECTION (L _ (ITdocSection n x)) = (n, x)
2091
2092 getSCC :: Located Token -> P FastString
2093 getSCC lt = do let s = getSTRING lt
2094                    err = "Spaces are not allowed in SCCs"
2095                -- We probably actually want to be more restrictive than this
2096                if ' ' `elem` unpackFS s
2097                    then failSpanMsgP (getLoc lt) (text err)
2098                    else return s
2099
2100 -- Utilities for combining source spans
2101 comb2 :: Located a -> Located b -> SrcSpan
2102 comb2 a b = a `seq` b `seq` combineLocs a b
2103
2104 comb3 :: Located a -> Located b -> Located c -> SrcSpan
2105 comb3 a b c = a `seq` b `seq` c `seq`
2106     combineSrcSpans (getLoc a) (combineSrcSpans (getLoc b) (getLoc c))
2107
2108 comb4 :: Located a -> Located b -> Located c -> Located d -> SrcSpan
2109 comb4 a b c d = a `seq` b `seq` c `seq` d `seq`
2110     (combineSrcSpans (getLoc a) $ combineSrcSpans (getLoc b) $
2111                 combineSrcSpans (getLoc c) (getLoc d))
2112
2113 -- strict constructor version:
2114 {-# INLINE sL #-}
2115 sL :: SrcSpan -> a -> Located a
2116 sL span a = span `seq` a `seq` L span a
2117
2118 -- Make a source location for the file.  We're a bit lazy here and just
2119 -- make a point SrcSpan at line 1, column 0.  Strictly speaking we should
2120 -- try to find the span of the whole file (ToDo).
2121 fileSrcSpan :: P SrcSpan
2122 fileSrcSpan = do 
2123   l <- getSrcLoc; 
2124   let loc = mkSrcLoc (srcLocFile l) 1 1;
2125   return (mkSrcSpan loc loc)
2126 }