users-guide: Update link to Safe Coercions paper
[ghc.git] / docs / users_guide / glasgow_exts.rst
1 .. index::
2    single: language, GHC extensions
3
4 As with all known Haskell systems, GHC implements some extensions to the
5 standard Haskell language. They can all be enabled or disabled by command line
6 flags or language pragmas. By default GHC understands the most recent Haskell
7 version it supports, plus a handful of extensions.
8
9 Some of the Glasgow extensions serve to give you access to the
10 underlying facilities with which we implement Haskell. Thus, you can get
11 at the Raw Iron, if you are willing to write some non-portable code at a
12 more primitive level. You need not be “stuck” on performance because of
13 the implementation costs of Haskell's "high-level" features—you can
14 always code "under" them. In an extreme case, you can write all your
15 time-critical code in C, and then just glue it together with Haskell!
16
17 Before you get too carried away working at the lowest level (e.g.,
18 sloshing ``MutableByteArray#``\ s around your program), you may wish to
19 check if there are libraries that provide a "Haskellised veneer" over
20 the features you want. The separate
21 `libraries documentation <../libraries/index.html>`__ describes all the
22 libraries that come with GHC.
23
24 .. _options-language:
25
26 Language options
27 ================
28
29 .. index::
30    single: language; option
31    single: options; language
32    single: extensions; options controlling
33
34 The language extensions control what variation of the language are
35 permitted.
36
37 Language options can be controlled in two ways:
38
39 -  Every language option can switched on by a command-line flag
40    "``-X...``" (e.g. ``-XTemplateHaskell``), and switched off by the
41    flag "``-XNo...``"; (e.g. ``-XNoTemplateHaskell``).
42
43 -  Language options recognised by Cabal can also be enabled using the
44    ``LANGUAGE`` pragma, thus ``{-# LANGUAGE TemplateHaskell #-}`` (see
45    :ref:`language-pragma`).
46
47 GHC supports these language options:
48
49 .. extension-print::
50     :type: table
51
52 Although not recommended, the deprecated :ghc-flag:`-fglasgow-exts` flag enables
53 a large swath of the extensions supported by GHC at once.
54
55 .. ghc-flag:: -fglasgow-exts
56     :shortdesc: Deprecated. Enable most language extensions;
57         see :ref:`options-language` for exactly which ones.
58     :type: dynamic
59     :reverse: -fno-glasgow-exts
60     :category: misc
61
62     The flag ``-fglasgow-exts`` is equivalent to enabling the following extensions:
63
64     .. include:: what_glasgow_exts_does.rst
65
66     Enabling these options is the *only* effect of ``-fglasgow-exts``. We are trying
67     to move away from this portmanteau flag, and towards enabling features
68     individually.
69
70 .. _primitives:
71
72 Unboxed types and primitive operations
73 ======================================
74
75 GHC is built on a raft of primitive data types and operations;
76 "primitive" in the sense that they cannot be defined in Haskell itself.
77 While you really can use this stuff to write fast code, we generally
78 find it a lot less painful, and more satisfying in the long run, to use
79 higher-level language features and libraries. With any luck, the code
80 you write will be optimised to the efficient unboxed version in any
81 case. And if it isn't, we'd like to know about it.
82
83 All these primitive data types and operations are exported by the
84 library ``GHC.Prim``, for which there is
85 :ghc-prim-ref:`detailed online documentation <GHC.Prim.>`. (This
86 documentation is generated from the file ``compiler/prelude/primops.txt.pp``.)
87
88 If you want to mention any of the primitive data types or operations in
89 your program, you must first import ``GHC.Prim`` to bring them into
90 scope. Many of them have names ending in ``#``, and to mention such names
91 you need the :extension:`MagicHash` extension.
92
93 The primops make extensive use of `unboxed types <#glasgow-unboxed>`__
94 and `unboxed tuples <#unboxed-tuples>`__, which we briefly summarise
95 here.
96
97 .. _glasgow-unboxed:
98
99 Unboxed types
100 -------------
101
102 Most types in GHC are boxed, which means that values of that type are
103 represented by a pointer to a heap object. The representation of a
104 Haskell ``Int``, for example, is a two-word heap object. An unboxed
105 type, however, is represented by the value itself, no pointers or heap
106 allocation are involved.
107
108 Unboxed types correspond to the “raw machine” types you would use in C:
109 ``Int#`` (long int), ``Double#`` (double), ``Addr#`` (void \*), etc. The
110 *primitive operations* (PrimOps) on these types are what you might
111 expect; e.g., ``(+#)`` is addition on ``Int#``\ s, and is the
112 machine-addition that we all know and love—usually one instruction.
113
114 Primitive (unboxed) types cannot be defined in Haskell, and are
115 therefore built into the language and compiler. Primitive types are
116 always unlifted; that is, a value of a primitive type cannot be bottom.
117 (Note: a "boxed" type means that a value is represented by a pointer to a heap
118 object; a "lifted" type means that terms of that type may be bottom. See
119 the next paragraph for an example.)
120 We use the convention (but it is only a convention) that primitive
121 types, values, and operations have a ``#`` suffix (see
122 :ref:`magic-hash`). For some primitive types we have special syntax for
123 literals, also described in the `same section <#magic-hash>`__.
124
125 Primitive values are often represented by a simple bit-pattern, such as
126 ``Int#``, ``Float#``, ``Double#``. But this is not necessarily the case:
127 a primitive value might be represented by a pointer to a heap-allocated
128 object. Examples include ``Array#``, the type of primitive arrays. Thus,
129 ``Array#`` is an unlifted, boxed type. A
130 primitive array is heap-allocated because it is too big a value to fit
131 in a register, and would be too expensive to copy around; in a sense, it
132 is accidental that it is represented by a pointer. If a pointer
133 represents a primitive value, then it really does point to that value:
134 no unevaluated thunks, no indirections. Nothing can be at the other end
135 of the pointer than the primitive value. A numerically-intensive program
136 using unboxed types can go a *lot* faster than its “standard”
137 counterpart—we saw a threefold speedup on one example.
138
139 Unboxed type kinds
140 ------------------
141
142 Because unboxed types are represented without the use of pointers, we
143 cannot store them in use a polymorphic datatype at an unboxed type.
144 For example, the ``Just`` node
145 of ``Just 42#`` would have to be different from the ``Just`` node of
146 ``Just 42``; the former stores an integer directly, while the latter
147 stores a pointer. GHC currently does not support this variety of ``Just``
148 nodes (nor for any other datatype). Accordingly, the *kind* of an unboxed
149 type is different from the kind of a boxed type.
150
151 The Haskell Report describes that ``*`` (spelled ``Type`` and imported from
152 ``Data.Kind`` in the GHC dialect of Haskell) is the kind of ordinary datatypes,
153 such as ``Int``. Furthermore, type constructors can have kinds with arrows; for
154 example, ``Maybe`` has kind ``Type -> Type``. Unboxed types have a kind that
155 specifies their runtime representation. For example, the type ``Int#`` has kind
156 ``TYPE 'IntRep`` and ``Double#`` has kind ``TYPE 'DoubleRep``. These kinds say
157 that the runtime representation of an ``Int#`` is a machine integer, and the
158 runtime representation of a ``Double#`` is a machine double-precision floating
159 point. In contrast, the kind ``Type`` is actually just a synonym for ``TYPE
160 'LiftedRep``. More details of the ``TYPE`` mechanisms appear in the `section
161 on runtime representation polymorphism <#runtime-rep>`__.
162
163 Given that ``Int#``'s kind is not ``Type``, it then it follows that ``Maybe
164 Int#`` is disallowed. Similarly, because type variables tend to be of kind
165 ``Type`` (for example, in ``(.) :: (b -> c) -> (a -> b) -> a -> c``, all the
166 type variables have kind ``Type``), polymorphism tends not to work over
167 primitive types. Stepping back, this makes some sense, because a polymorphic
168 function needs to manipulate the pointers to its data, and most primitive types
169 are unboxed.
170
171 There are some restrictions on the use of primitive types:
172
173 -  You cannot define a newtype whose representation type (the argument
174    type of the data constructor) is an unboxed type. Thus, this is
175    illegal:
176
177    ::
178
179          newtype A = MkA Int#
180
181 -  You cannot bind a variable with an unboxed type in a *top-level*
182    binding.
183
184 -  You cannot bind a variable with an unboxed type in a *recursive*
185    binding.
186
187 -  You may bind unboxed variables in a (non-recursive, non-top-level)
188    pattern binding, but you must make any such pattern-match strict.
189    (Failing to do so emits a warning :ghc-flag:`-Wunbanged-strict-patterns`.)
190    For example, rather than:
191
192    ::
193
194          data Foo = Foo Int Int#
195
196          f x = let (Foo a b, w) = ..rhs.. in ..body..
197
198    you must write:
199
200    ::
201
202          data Foo = Foo Int Int#
203
204          f x = let !(Foo a b, w) = ..rhs.. in ..body..
205
206    since ``b`` has type ``Int#``.
207
208 .. _unboxed-tuples:
209
210 Unboxed tuples
211 --------------
212
213 .. extension:: UnboxedTuples
214     :shortdesc: Enable the use of unboxed tuple syntax.
215
216     :since: 6.8.1
217
218
219 Unboxed tuples aren't really exported by ``GHC.Exts``; they are a
220 syntactic extension (:extension:`UnboxedTuples`). An
221 unboxed tuple looks like this: ::
222
223     (# e_1, ..., e_n #)
224
225 where ``e_1..e_n`` are expressions of any type (primitive or
226 non-primitive). The type of an unboxed tuple looks the same.
227
228 Note that when unboxed tuples are enabled, ``(#`` is a single lexeme, so
229 for example when using operators like ``#`` and ``#-`` you need to write
230 ``( # )`` and ``( #- )`` rather than ``(#)`` and ``(#-)``.
231
232 Unboxed tuples are used for functions that need to return multiple
233 values, but they avoid the heap allocation normally associated with
234 using fully-fledged tuples. When an unboxed tuple is returned, the
235 components are put directly into registers or on the stack; the unboxed
236 tuple itself does not have a composite representation. Many of the
237 primitive operations listed in ``primops.txt.pp`` return unboxed tuples.
238 In particular, the ``IO`` and ``ST`` monads use unboxed tuples to avoid
239 unnecessary allocation during sequences of operations.
240
241 There are some restrictions on the use of unboxed tuples:
242
243 -  The typical use of unboxed tuples is simply to return multiple
244    values, binding those multiple results with a ``case`` expression,
245    thus:
246
247    ::
248
249          f x y = (# x+1, y-1 #)
250          g x = case f x x of { (# a, b #) -> a + b }
251
252    You can have an unboxed tuple in a pattern binding, thus
253
254    ::
255
256          f x = let (# p,q #) = h x in ..body..
257
258    If the types of ``p`` and ``q`` are not unboxed, the resulting
259    binding is lazy like any other Haskell pattern binding. The above
260    example desugars like this:
261
262    ::
263
264          f x = let t = case h x of { (# p,q #) -> (p,q) }
265                    p = fst t
266                    q = snd t
267                in ..body..
268
269    Indeed, the bindings can even be recursive.
270
271 .. _unboxed-sums:
272
273 Unboxed sums
274 ------------
275
276 .. extension:: UnboxedSums
277     :shortdesc: Enable unboxed sums.
278
279     :since: 8.2.1
280
281     Enable the use of unboxed sum syntax.
282
283 `-XUnboxedSums` enables new syntax for anonymous, unboxed sum types. The syntax
284 for an unboxed sum type with N alternatives is ::
285
286     (# t_1 | t_2 | ... | t_N #)
287
288 where ``t_1`` ... ``t_N`` are types (which can be unlifted, including unboxed
289 tuples and sums).
290
291 Unboxed tuples can be used for multi-arity alternatives. For example: ::
292
293     (# (# Int, String #) | Bool #)
294
295 The term level syntax is similar. Leading and preceding bars (`|`) indicate which
296 alternative it is. Here are two terms of the type shown above: ::
297
298     (# (# 1, "foo" #) | #) -- first alternative
299
300     (# | True #) -- second alternative
301
302 The pattern syntax reflects the term syntax: ::
303
304     case x of
305       (# (# i, str #) | #) -> ...
306       (# | bool #) -> ...
307
308 Unboxed sums are "unboxed" in the sense that, instead of allocating sums in the
309 heap and representing values as pointers, unboxed sums are represented as their
310 components, just like unboxed tuples. These "components" depend on alternatives
311 of a sum type. Like unboxed tuples, unboxed sums are lazy in their lifted
312 components.
313
314 The code generator tries to generate as compact layout as possible for each
315 unboxed sum. In the best case, size of an unboxed sum is size of its biggest
316 alternative plus one word (for a tag). The algorithm for generating the memory
317 layout for a sum type works like this:
318
319 - All types are classified as one of these classes: 32bit word, 64bit word,
320   32bit float, 64bit float, pointer.
321
322 - For each alternative of the sum type, a layout that consists of these fields
323   is generated. For example, if an alternative has ``Int``, ``Float#`` and
324   ``String`` fields, the layout will have an 32bit word, 32bit float and
325   pointer fields.
326
327 - Layout fields are then overlapped so that the final layout will be as compact
328   as possible. For example, suppose we have the unboxed sum: ::
329
330     (# (# Word32#, String, Float# #)
331     |  (# Float#, Float#, Maybe Int #) #)
332
333   The final layout will be something like ::
334
335     Int32, Float32, Float32, Word32, Pointer
336
337   The first ``Int32`` is for the tag. There are two ``Float32`` fields because
338   floating point types can't overlap with other types, because of limitations of
339   the code generator that we're hoping to overcome in the future. The second
340   alternative needs two ``Float32`` fields: The ``Word32`` field is for the
341   ``Word32#`` in the first alternative. The ``Pointer`` field is shared between
342   ``String`` and ``Maybe Int`` values of the alternatives.
343
344   As another example, this is the layout for the unboxed version of ``Maybe a``
345   type, ``(# (# #) | a #)``: ::
346
347     Int32, Pointer
348
349   The ``Pointer`` field is not used when tag says that it's ``Nothing``.
350   Otherwise ``Pointer`` points to the value in ``Just``. As mentioned
351   above, this type is lazy in its lifted field. Therefore, the type ::
352
353     data Maybe' a = Maybe' (# (# #) | a #)
354
355   is *precisely* isomorphic to the type ``Maybe a``, although its memory
356   representation is different.
357
358   In the degenerate case where all the alternatives have zero width, such
359   as the ``Bool``-like ``(# (# #) | (# #) #)``, the unboxed sum layout only
360   has an ``Int32`` tag field (i.e., the whole thing is represented by an integer).
361
362 .. _syntax-extns:
363
364 Syntactic extensions
365 ====================
366
367 .. _unicode-syntax:
368
369 Unicode syntax
370 --------------
371
372 .. extension:: UnicodeSyntax
373     :shortdesc: Enable unicode syntax.
374
375     :since: 6.8.1
376
377     Enable the use of Unicode characters in place of their equivalent ASCII
378     sequences.
379
380 The language extension :extension:`UnicodeSyntax` enables
381 Unicode characters to be used to stand for certain ASCII character
382 sequences. The following alternatives are provided:
383
384 +--------------+---------------+-------------+-----------------------------------------+
385 | ASCII        | Unicode       | Code point  | Name                                    |
386 |              | alternative   |             |                                         |
387 +==============+===============+=============+=========================================+
388 | ``::``       | ∷             | 0x2237      | PROPORTION                              |
389 +--------------+---------------+-------------+-----------------------------------------+
390 | ``=>``       | ⇒             | 0x21D2      | RIGHTWARDS DOUBLE ARROW                 |
391 +--------------+---------------+-------------+-----------------------------------------+
392 | ``->``       | →             | 0x2192      | RIGHTWARDS ARROW                        |
393 +--------------+---------------+-------------+-----------------------------------------+
394 | ``<-``       | ←             | 0x2190      | LEFTWARDS ARROW                         |
395 +--------------+---------------+-------------+-----------------------------------------+
396 | ``>-``       | ⤚             | 0x291a      | RIGHTWARDS ARROW-TAIL                   |
397 +--------------+---------------+-------------+-----------------------------------------+
398 | ``-<``       | ⤙             | 0x2919      | LEFTWARDS ARROW-TAIL                    |
399 +--------------+---------------+-------------+-----------------------------------------+
400 | ``>>-``      | ⤜             | 0x291C      | RIGHTWARDS DOUBLE ARROW-TAIL            |
401 +--------------+---------------+-------------+-----------------------------------------+
402 | ``-<<``      | ⤛             | 0x291B      | LEFTWARDS DOUBLE ARROW-TAIL             |
403 +--------------+---------------+-------------+-----------------------------------------+
404 | ``*``        | ★             | 0x2605      | BLACK STAR                              |
405 +--------------+---------------+-------------+-----------------------------------------+
406 | ``forall``   | ∀             | 0x2200      | FOR ALL                                 |
407 +--------------+---------------+-------------+-----------------------------------------+
408 | ``(|``       | ⦇             | 0x2987      | Z NOTATION LEFT IMAGE BRACKET           |
409 +--------------+---------------+-------------+-----------------------------------------+
410 | ``|)``       | ⦈             | 0x2988      | Z NOTATION RIGHT IMAGE BRACKET          |
411 +--------------+---------------+-------------+-----------------------------------------+
412 | ``[|``       | ⟦             | 0x27E6      | MATHEMATICAL LEFT WHITE SQUARE BRACKET  |
413 +--------------+---------------+-------------+-----------------------------------------+
414 | ``|]``       | ⟧             | 0x27E7      | MATHEMATICAL RIGHT WHITE SQUARE BRACKET |
415 +--------------+---------------+-------------+-----------------------------------------+
416
417 .. _magic-hash:
418
419 The magic hash
420 --------------
421
422 .. extension:: MagicHash
423     :shortdesc: Allow ``#`` as a postfix modifier on identifiers.
424
425     :since: 6.8.1
426
427     Enables the use of the hash character (``#``) as an identifier suffix.
428
429 The language extension :extension:`MagicHash` allows ``#`` as a postfix modifier
430 to identifiers. Thus, ``x#`` is a valid variable, and ``T#`` is a valid type
431 constructor or data constructor.
432
433 The hash sign does not change semantics at all. We tend to use variable
434 names ending in "#" for unboxed values or types (e.g. ``Int#``), but
435 there is no requirement to do so; they are just plain ordinary
436 variables. Nor does the :extension:`MagicHash` extension bring anything into
437 scope. For example, to bring ``Int#`` into scope you must import
438 ``GHC.Prim`` (see :ref:`primitives`); the :extension:`MagicHash` extension then
439 allows you to *refer* to the ``Int#`` that is now in scope. Note that
440 with this option, the meaning of ``x#y = 0`` is changed: it defines a
441 function ``x#`` taking a single argument ``y``; to define the operator
442 ``#``, put a space: ``x # y = 0``.
443
444 The :extension:`MagicHash` also enables some new forms of literals (see
445 :ref:`glasgow-unboxed`):
446
447 -  ``'x'#`` has type ``Char#``
448
449 -  ``"foo"#`` has type ``Addr#``
450
451 -  ``3#`` has type ``Int#``. In general, any Haskell integer lexeme
452    followed by a ``#`` is an ``Int#`` literal, e.g. ``-0x3A#`` as well as
453    ``32#``.
454
455 -  ``3##`` has type ``Word#``. In general, any non-negative Haskell
456    integer lexeme followed by ``##`` is a ``Word#``.
457
458 -  ``3.2#`` has type ``Float#``.
459
460 -  ``3.2##`` has type ``Double#``
461
462 .. _negative-literals:
463
464 Negative literals
465 -----------------
466
467 .. extension:: NegativeLiterals
468     :shortdesc: Enable support for negative literals.
469
470     :since: 7.8.1
471
472     Enable the use of un-parenthesized negative numeric literals.
473
474 The literal ``-123`` is, according to Haskell98 and Haskell 2010,
475 desugared as ``negate (fromInteger 123)``. The language extension
476 :extension:`NegativeLiterals` means that it is instead desugared as
477 ``fromInteger (-123)``.
478
479 This can make a difference when the positive and negative range of a
480 numeric data type don't match up. For example, in 8-bit arithmetic -128
481 is representable, but +128 is not. So ``negate (fromInteger 128)`` will
482 elicit an unexpected integer-literal-overflow message.
483
484 .. _num-decimals:
485
486 Fractional looking integer literals
487 -----------------------------------
488
489 .. extension:: NumDecimals
490     :shortdesc: Enable support for 'fractional' integer literals.
491
492     :since: 7.8.1
493
494     Allow the use of floating-point literal syntax for integral types.
495
496 Haskell 2010 and Haskell 98 define floating literals with the syntax
497 ``1.2e6``. These literals have the type ``Fractional a => a``.
498
499 The language extension :extension:`NumDecimals` allows you to also use the
500 floating literal syntax for instances of ``Integral``, and have values
501 like ``(1.2e6 :: Num a => a)``
502
503 .. _binary-literals:
504
505 Binary integer literals
506 -----------------------
507
508 .. extension:: BinaryLiterals
509     :shortdesc: Enable support for binary literals.
510
511     :since: 7.10.1
512
513     Allow the use of binary notation in integer literals.
514
515 Haskell 2010 and Haskell 98 allows for integer literals to be given in
516 decimal, octal (prefixed by ``0o`` or ``0O``), or hexadecimal notation
517 (prefixed by ``0x`` or ``0X``).
518
519 The language extension :extension:`BinaryLiterals` adds support for expressing
520 integer literals in binary notation with the prefix ``0b`` or ``0B``. For
521 instance, the binary integer literal ``0b11001001`` will be desugared into
522 ``fromInteger 201`` when :extension:`BinaryLiterals` is enabled.
523
524 .. _hex-float-literals:
525
526 Hexadecimal floating point literals
527 -----------------------------------
528
529 .. extension:: HexFloatLiterals
530     :shortdesc: Enable support for :ref:`hexadecimal floating point literals <hex-float-literals>`.
531
532     :since: 8.4.1
533
534     Allow writing floating point literals using hexadecimal notation.
535
536 The hexadecimal notation for floating point literals is useful when you
537 need to specify floating point constants precisely, as the literal notation
538 corresponds closely to the underlying bit-encoding of the number.
539
540 In this notation floating point numbers are written using hexadecimal digits,
541 and so the digits are interpreted using base 16, rather then the usual 10.
542 This means that digits left of the decimal point correspond to positive
543 powers of 16, while the ones to the right correspond to negative ones.
544
545 You may also write an explicit exponent, which is similar to the exponent
546 in decimal notation with the following differences:
547 - the exponent begins with ``p`` instead of ``e``
548 - the exponent is written in base ``10`` (**not** 16)
549 - the base of the exponent is ``2`` (**not** 16).
550
551 In terms of the underlying bit encoding, each hexadecimal digit corresponds
552 to 4 bits, and you may think of the exponent as "moving" the floating point
553 by one bit left (negative) or right (positive).  Here are some examples:
554
555 -  ``0x0.1``     is the same as ``1/16``
556 -  ``0x0.01``    is the same as ``1/256``
557 -  ``0xF.FF``    is the same as ``15 + 15/16 + 15/256``
558 -  ``0x0.1p4``   is the same as ``1``
559 -  ``0x0.1p-4``  is the same as ``1/256``
560 -  ``0x0.1p12``  is the same as ``256``
561
562
563
564
565 .. _numeric-underscores:
566
567 Numeric underscores
568 -------------------
569
570 .. extension:: NumericUnderscores
571     :shortdesc: Enable support for :ref:`numeric underscores <numeric-underscores>`.
572
573     :since: 8.6.1
574
575     Allow the use of underscores in numeric literals.
576
577 GHC allows for numeric literals to be given in decimal, octal, hexadecimal,
578 binary, or float notation.
579
580 The language extension :extension:`NumericUnderscores` adds support for expressing
581 underscores in numeric literals.
582 For instance, the numeric literal ``1_000_000`` will be parsed into
583 ``1000000`` when :extension:`NumericUnderscores` is enabled.
584 That is, underscores in numeric literals are ignored when
585 :extension:`NumericUnderscores` is enabled.
586 See also :ghc-ticket:`14473`.
587
588 For example:
589
590 .. code-block:: none
591
592     -- decimal
593     million    = 1_000_000
594     billion    = 1_000_000_000
595     lightspeed = 299_792_458
596     version    = 8_04_1
597     date       = 2017_12_31
598
599     -- hexadecimal
600     red_mask = 0xff_00_00
601     size1G   = 0x3fff_ffff
602
603     -- binary
604     bit8th   = 0b01_0000_0000
605     packbits = 0b1_11_01_0000_0_111
606     bigbits  = 0b1100_1011__1110_1111__0101_0011
607
608     -- float
609     pi       = 3.141_592_653_589_793
610     faraday  = 96_485.332_89
611     avogadro = 6.022_140_857e+23
612
613     -- function
614     isUnderMillion = (< 1_000_000)
615
616     clip64M x
617         | x > 0x3ff_ffff = 0x3ff_ffff
618         | otherwise = x
619
620     test8bit x = (0b01_0000_0000 .&. x) /= 0
621
622 About validity:
623
624 .. code-block:: none
625
626     x0 = 1_000_000   -- valid
627     x1 = 1__000000   -- valid
628     x2 = 1000000_    -- invalid
629     x3 = _1000000    -- invalid
630
631     e0 = 0.0001      -- valid
632     e1 = 0.000_1     -- valid
633     e2 = 0_.0001     -- invalid
634     e3 = _0.0001     -- invalid
635     e4 = 0._0001     -- invalid
636     e5 = 0.0001_     -- invalid
637
638     f0 = 1e+23       -- valid
639     f1 = 1_e+23      -- valid
640     f2 = 1__e+23     -- valid
641     f3 = 1e_+23      -- invalid
642
643     g0 = 1e+23       -- valid
644     g1 = 1e+_23      -- invalid
645     g2 = 1e+23_      -- invalid
646
647     h0 = 0xffff      -- valid
648     h1 = 0xff_ff     -- valid
649     h2 = 0x_ffff     -- valid
650     h3 = 0x__ffff    -- valid
651     h4 = _0xffff     -- invalid
652
653 .. _pattern-guards:
654
655 Pattern guards
656 --------------
657
658 .. extension:: NoPatternGuards
659     :shortdesc: Disable pattern guards.
660         Implied by :extension:`Haskell98`.
661
662     :implied by: :extension:`Haskell98`
663     :since: 6.8.1
664
665 Disable `pattern guards
666 <http://www.haskell.org/onlinereport/haskell2010/haskellch3.html#x8-460003.13>`__.
667
668 .. _view-patterns:
669
670 View patterns
671 -------------
672
673 .. extension:: ViewPatterns
674     :shortdesc: Enable view patterns.
675
676     :since: 6.10.1
677
678     Allow use of view pattern syntax.
679
680 View patterns are enabled by the language extension :extension:`ViewPatterns`. More
681 information and examples of view patterns can be found on the
682 :ghc-wiki:`Wiki page <ViewPatterns>`.
683
684 View patterns are somewhat like pattern guards that can be nested inside
685 of other patterns. They are a convenient way of pattern-matching against
686 values of abstract types. For example, in a programming language
687 implementation, we might represent the syntax of the types of the
688 language as follows: ::
689
690     type Typ
691
692     data TypView = Unit
693                  | Arrow Typ Typ
694
695     view :: Typ -> TypView
696
697     -- additional operations for constructing Typ's ...
698
699 The representation of Typ is held abstract, permitting implementations
700 to use a fancy representation (e.g., hash-consing to manage sharing).
701 Without view patterns, using this signature is a little inconvenient: ::
702
703     size :: Typ -> Integer
704     size t = case view t of
705       Unit -> 1
706       Arrow t1 t2 -> size t1 + size t2
707
708 It is necessary to iterate the case, rather than using an equational
709 function definition. And the situation is even worse when the matching
710 against ``t`` is buried deep inside another pattern.
711
712 View patterns permit calling the view function inside the pattern and
713 matching against the result: ::
714
715     size (view -> Unit) = 1
716     size (view -> Arrow t1 t2) = size t1 + size t2
717
718 That is, we add a new form of pattern, written ⟨expression⟩ ``->``
719 ⟨pattern⟩ that means "apply the expression to whatever we're trying to
720 match against, and then match the result of that application against the
721 pattern". The expression can be any Haskell expression of function type,
722 and view patterns can be used wherever patterns are used.
723
724 The semantics of a pattern ``(`` ⟨exp⟩ ``->`` ⟨pat⟩ ``)`` are as
725 follows:
726
727 -  Scoping:
728    The variables bound by the view pattern are the variables bound by
729    ⟨pat⟩.
730
731    Any variables in ⟨exp⟩ are bound occurrences, but variables bound "to
732    the left" in a pattern are in scope. This feature permits, for
733    example, one argument to a function to be used in the view of another
734    argument. For example, the function ``clunky`` from
735    :ref:`pattern-guards` can be written using view patterns as follows: ::
736
737        clunky env (lookup env -> Just val1) (lookup env -> Just val2) = val1 + val2
738        ...other equations for clunky...
739
740    More precisely, the scoping rules are:
741
742    -  In a single pattern, variables bound by patterns to the left of a
743       view pattern expression are in scope. For example: ::
744
745           example :: Maybe ((String -> Integer,Integer), String) -> Bool
746           example Just ((f,_), f -> 4) = True
747
748       Additionally, in function definitions, variables bound by matching
749       earlier curried arguments may be used in view pattern expressions
750       in later arguments: ::
751
752           example :: (String -> Integer) -> String -> Bool
753           example f (f -> 4) = True
754
755       That is, the scoping is the same as it would be if the curried
756       arguments were collected into a tuple.
757
758    -  In mutually recursive bindings, such as ``let``, ``where``, or the
759       top level, view patterns in one declaration may not mention
760       variables bound by other declarations. That is, each declaration
761       must be self-contained. For example, the following program is not
762       allowed: ::
763
764           let {(x -> y) = e1 ;
765                (y -> x) = e2 } in x
766
767    (For some amplification on this design choice see :ghc-ticket:`4061`.
768
769 -  Typing: If ⟨exp⟩ has type ⟨T1⟩ ``->`` ⟨T2⟩ and ⟨pat⟩ matches a ⟨T2⟩,
770    then the whole view pattern matches a ⟨T1⟩.
771
772 -  Matching: To the equations in Section 3.17.3 of the `Haskell 98
773    Report <http://www.haskell.org/onlinereport/>`__, add the following: ::
774
775        case v of { (e -> p) -> e1 ; _ -> e2 }
776         =
777        case (e v) of { p -> e1 ; _ -> e2 }
778
779    That is, to match a variable ⟨v⟩ against a pattern ``(`` ⟨exp⟩ ``->``
780    ⟨pat⟩ ``)``, evaluate ``(`` ⟨exp⟩ ⟨v⟩ ``)`` and match the result
781    against ⟨pat⟩.
782
783 -  Efficiency: When the same view function is applied in multiple
784    branches of a function definition or a case expression (e.g., in
785    ``size`` above), GHC makes an attempt to collect these applications
786    into a single nested case expression, so that the view function is
787    only applied once. Pattern compilation in GHC follows the matrix
788    algorithm described in Chapter 4 of `The Implementation of Functional
789    Programming
790    Languages <http://research.microsoft.com/~simonpj/Papers/slpj-book-1987/>`__.
791    When the top rows of the first column of a matrix are all view
792    patterns with the "same" expression, these patterns are transformed
793    into a single nested case. This includes, for example, adjacent view
794    patterns that line up in a tuple, as in
795
796    ::
797
798        f ((view -> A, p1), p2) = e1
799        f ((view -> B, p3), p4) = e2
800
801    The current notion of when two view pattern expressions are "the
802    same" is very restricted: it is not even full syntactic equality.
803    However, it does include variables, literals, applications, and
804    tuples; e.g., two instances of ``view ("hi", "there")`` will be
805    collected. However, the current implementation does not compare up to
806    alpha-equivalence, so two instances of ``(x, view x -> y)`` will not
807    be coalesced.
808
809 .. _n-k-patterns:
810
811 n+k patterns
812 ------------
813
814 .. extension:: NPlusKPatterns
815     :shortdesc: Enable support for ``n+k`` patterns.
816         Implied by :extension:`Haskell98`.
817
818     :implied by: :extension:`Haskell98`
819     :since: 6.12.1
820
821     Enable use of ``n+k`` patterns.
822
823 .. _recursive-do-notation:
824
825 The recursive do-notation
826 -------------------------
827
828 .. extension:: RecursiveDo
829     :shortdesc: Enable recursive do (mdo) notation.
830
831     :since: 6.8.1
832
833     Allow the use of recursive ``do`` notation.
834
835 The do-notation of Haskell 98 does not allow *recursive bindings*, that
836 is, the variables bound in a do-expression are visible only in the
837 textually following code block. Compare this to a let-expression, where
838 bound variables are visible in the entire binding group.
839
840 It turns out that such recursive bindings do indeed make sense for a
841 variety of monads, but not all. In particular, recursion in this sense
842 requires a fixed-point operator for the underlying monad, captured by
843 the ``mfix`` method of the ``MonadFix`` class, defined in
844 ``Control.Monad.Fix`` as follows: ::
845
846     class Monad m => MonadFix m where
847        mfix :: (a -> m a) -> m a
848
849 Haskell's ``Maybe``, ``[]`` (list), ``ST`` (both strict and lazy
850 versions), ``IO``, and many other monads have ``MonadFix`` instances. On
851 the negative side, the continuation monad, with the signature
852 ``(a -> r) -> r``, does not.
853
854 For monads that do belong to the ``MonadFix`` class, GHC provides an
855 extended version of the do-notation that allows recursive bindings. The
856 :extension:`RecursiveDo` (language pragma: ``RecursiveDo``) provides the
857 necessary syntactic support, introducing the keywords ``mdo`` and
858 ``rec`` for higher and lower levels of the notation respectively. Unlike
859 bindings in a ``do`` expression, those introduced by ``mdo`` and ``rec``
860 are recursively defined, much like in an ordinary let-expression. Due to
861 the new keyword ``mdo``, we also call this notation the *mdo-notation*.
862
863 Here is a simple (albeit contrived) example:
864
865 ::
866
867     {-# LANGUAGE RecursiveDo #-}
868     justOnes = mdo { xs <- Just (1:xs)
869                    ; return (map negate xs) }
870
871 or equivalently
872
873 ::
874
875     {-# LANGUAGE RecursiveDo #-}
876     justOnes = do { rec { xs <- Just (1:xs) }
877                   ; return (map negate xs) }
878
879 As you can guess ``justOnes`` will evaluate to ``Just [-1,-1,-1,...``.
880
881 GHC's implementation the mdo-notation closely follows the original
882 translation as described in the paper `A recursive do for
883 Haskell <http://leventerkok.github.io/papers/recdo.pdf>`__, which
884 in turn is based on the work `Value Recursion in Monadic
885 Computations <http://leventerkok.github.io/papers/erkok-thesis.pdf>`__.
886 Furthermore, GHC extends the syntax described in the former paper with a
887 lower level syntax flagged by the ``rec`` keyword, as we describe next.
888
889 Recursive binding groups
890 ~~~~~~~~~~~~~~~~~~~~~~~~
891
892 The extension :extension:`RecursiveDo` also introduces a new keyword ``rec``, which
893 wraps a mutually-recursive group of monadic statements inside a ``do``
894 expression, producing a single statement. Similar to a ``let`` statement
895 inside a ``do``, variables bound in the ``rec`` are visible throughout
896 the ``rec`` group, and below it. For example, compare
897
898 ::
899
900         do { a <- getChar            do { a <- getChar
901            ; let { r1 = f a r2          ; rec { r1 <- f a r2
902            ;     ; r2 = g r1 }          ;     ; r2 <- g r1 }
903            ; return (r1 ++ r2) }        ; return (r1 ++ r2) }
904
905 In both cases, ``r1`` and ``r2`` are available both throughout the
906 ``let`` or ``rec`` block, and in the statements that follow it. The
907 difference is that ``let`` is non-monadic, while ``rec`` is monadic. (In
908 Haskell ``let`` is really ``letrec``, of course.)
909
910 The semantics of ``rec`` is fairly straightforward. Whenever GHC finds a
911 ``rec`` group, it will compute its set of bound variables, and will
912 introduce an appropriate call to the underlying monadic value-recursion
913 operator ``mfix``, belonging to the ``MonadFix`` class. Here is an
914 example:
915
916 ::
917
918     rec { b <- f a c     ===>    (b,c) <- mfix (\ ~(b,c) -> do { b <- f a c
919         ; c <- f b a }                                         ; c <- f b a
920                                                                ; return (b,c) })
921
922 As usual, the meta-variables ``b``, ``c`` etc., can be arbitrary
923 patterns. In general, the statement ``rec ss`` is desugared to the
924 statement
925
926 ::
927
928     vs <- mfix (\ ~vs -> do { ss; return vs })
929
930 where ``vs`` is a tuple of the variables bound by ``ss``.
931
932 Note in particular that the translation for a ``rec`` block only
933 involves wrapping a call to ``mfix``: it performs no other analysis on
934 the bindings. The latter is the task for the ``mdo`` notation, which is
935 described next.
936
937 The ``mdo`` notation
938 ~~~~~~~~~~~~~~~~~~~~
939
940 A ``rec``-block tells the compiler where precisely the recursive knot
941 should be tied. It turns out that the placement of the recursive knots
942 can be rather delicate: in particular, we would like the knots to be
943 wrapped around as minimal groups as possible. This process is known as
944 *segmentation*, and is described in detail in Section 3.2 of `A
945 recursive do for
946 Haskell <http://leventerkok.github.io/papers/recdo.pdf>`__.
947 Segmentation improves polymorphism and reduces the size of the recursive
948 knot. Most importantly, it avoids unnecessary interference caused by a
949 fundamental issue with the so-called *right-shrinking* axiom for monadic
950 recursion. In brief, most monads of interest (IO, strict state, etc.) do
951 *not* have recursion operators that satisfy this axiom, and thus not
952 performing segmentation can cause unnecessary interference, changing the
953 termination behavior of the resulting translation. (Details can be found
954 in Sections 3.1 and 7.2.2 of `Value Recursion in Monadic
955 Computations <http://leventerkok.github.io/papers/erkok-thesis.pdf>`__.)
956
957 The ``mdo`` notation removes the burden of placing explicit ``rec``
958 blocks in the code. Unlike an ordinary ``do`` expression, in which
959 variables bound by statements are only in scope for later statements,
960 variables bound in an ``mdo`` expression are in scope for all statements
961 of the expression. The compiler then automatically identifies minimal
962 mutually recursively dependent segments of statements, treating them as
963 if the user had wrapped a ``rec`` qualifier around them.
964
965 The definition is syntactic:
966
967 -  A generator ⟨g⟩ *depends* on a textually following generator ⟨g'⟩, if
968
969    -  ⟨g'⟩ defines a variable that is used by ⟨g⟩, or
970
971    -  ⟨g'⟩ textually appears between ⟨g⟩ and ⟨g''⟩, where ⟨g⟩ depends on
972       ⟨g''⟩.
973
974 -  A *segment* of a given ``mdo``-expression is a minimal sequence of
975    generators such that no generator of the sequence depends on an
976    outside generator. As a special case, although it is not a generator,
977    the final expression in an ``mdo``-expression is considered to form a
978    segment by itself.
979
980 Segments in this sense are related to *strongly-connected components*
981 analysis, with the exception that bindings in a segment cannot be
982 reordered and must be contiguous.
983
984 Here is an example ``mdo``-expression, and its translation to ``rec``
985 blocks:
986
987 ::
988
989     mdo { a <- getChar      ===> do { a <- getChar
990         ; b <- f a c                ; rec { b <- f a c
991         ; c <- f b a                ;     ; c <- f b a }
992         ; z <- h a b                ; z <- h a b
993         ; d <- g d e                ; rec { d <- g d e
994         ; e <- g a z                ;     ; e <- g a z }
995         ; putChar c }               ; putChar c }
996
997 Note that a given ``mdo`` expression can cause the creation of multiple
998 ``rec`` blocks. If there are no recursive dependencies, ``mdo`` will
999 introduce no ``rec`` blocks. In this latter case an ``mdo`` expression
1000 is precisely the same as a ``do`` expression, as one would expect.
1001
1002 In summary, given an ``mdo`` expression, GHC first performs
1003 segmentation, introducing ``rec`` blocks to wrap over minimal recursive
1004 groups. Then, each resulting ``rec`` is desugared, using a call to
1005 ``Control.Monad.Fix.mfix`` as described in the previous section. The
1006 original ``mdo``-expression typechecks exactly when the desugared
1007 version would do so.
1008
1009 Here are some other important points in using the recursive-do notation:
1010
1011 -  It is enabled with the extension :extension:`RecursiveDo`, or the
1012    ``LANGUAGE RecursiveDo`` pragma. (The same extension enables both
1013    ``mdo``-notation, and the use of ``rec`` blocks inside ``do``
1014    expressions.)
1015
1016 -  ``rec`` blocks can also be used inside ``mdo``-expressions, which
1017    will be treated as a single statement. However, it is good style to
1018    either use ``mdo`` or ``rec`` blocks in a single expression.
1019
1020 -  If recursive bindings are required for a monad, then that monad must
1021    be declared an instance of the ``MonadFix`` class.
1022
1023 -  The following instances of ``MonadFix`` are automatically provided:
1024    List, Maybe, IO. Furthermore, the ``Control.Monad.ST`` and
1025    ``Control.Monad.ST.Lazy`` modules provide the instances of the
1026    ``MonadFix`` class for Haskell's internal state monad (strict and
1027    lazy, respectively).
1028
1029 -  Like ``let`` and ``where`` bindings, name shadowing is not allowed
1030    within an ``mdo``-expression or a ``rec``-block; that is, all the
1031    names bound in a single ``rec`` must be distinct. (GHC will complain
1032    if this is not the case.)
1033
1034 .. _applicative-do:
1035
1036 Applicative do-notation
1037 -----------------------
1038
1039 .. index::
1040    single: Applicative do-notation
1041    single: do-notation; Applicative
1042
1043 .. extension:: ApplicativeDo
1044     :shortdesc: Enable Applicative do-notation desugaring
1045
1046     :since: 8.0.1
1047
1048     Allow use of ``Applicative`` ``do`` notation.
1049
1050 The language option :extension:`ApplicativeDo` enables an alternative translation for
1051 the do-notation, which uses the operators ``<$>``, ``<*>``, along with ``join``
1052 as far as possible. There are two main reasons for wanting to do this:
1053
1054 -  We can use do-notation with types that are an instance of ``Applicative`` and
1055    ``Functor``, but not ``Monad``
1056 -  In some monads, using the applicative operators is more efficient than monadic
1057    bind. For example, it may enable more parallelism.
1058
1059 Applicative do-notation desugaring preserves the original semantics, provided
1060 that the ``Applicative`` instance satisfies ``<*> = ap`` and ``pure = return``
1061 (these are true of all the common monadic types). Thus, you can normally turn on
1062 :extension:`ApplicativeDo` without fear of breaking your program. There is one pitfall
1063 to watch out for; see :ref:`applicative-do-pitfall`.
1064
1065 There are no syntactic changes with :extension:`ApplicativeDo`. The only way it shows
1066 up at the source level is that you can have a ``do`` expression that doesn't
1067 require a ``Monad`` constraint. For example, in GHCi: ::
1068
1069     Prelude> :set -XApplicativeDo
1070     Prelude> :t \m -> do { x <- m; return (not x) }
1071     \m -> do { x <- m; return (not x) }
1072       :: Functor f => f Bool -> f Bool
1073
1074 This example only requires ``Functor``, because it is translated into ``(\x ->
1075 not x) <$> m``. A more complex example requires ``Applicative``, ::
1076
1077     Prelude> :t \m -> do { x <- m 'a'; y <- m 'b'; return (x || y) }
1078     \m -> do { x <- m 'a'; y <- m 'b'; return (x || y) }
1079       :: Applicative f => (Char -> f Bool) -> f Bool
1080
1081 Here GHC has translated the expression into ::
1082
1083     (\x y -> x || y) <$> m 'a' <*> m 'b'
1084
1085 It is possible to see the actual translation by using :ghc-flag:`-ddump-ds`, but be
1086 warned, the output is quite verbose.
1087
1088 Note that if the expression can't be translated into uses of ``<$>``, ``<*>``
1089 only, then it will incur a ``Monad`` constraint as usual. This happens when
1090 there is a dependency on a value produced by an earlier statement in the
1091 ``do``-block: ::
1092
1093     Prelude> :t \m -> do { x <- m True; y <- m x; return (x || y) }
1094     \m -> do { x <- m True; y <- m x; return (x || y) }
1095       :: Monad m => (Bool -> m Bool) -> m Bool
1096
1097 Here, ``m x`` depends on the value of ``x`` produced by the first statement, so
1098 the expression cannot be translated using ``<*>``.
1099
1100 In general, the rule for when a ``do`` statement incurs a ``Monad`` constraint
1101 is as follows. If the do-expression has the following form: ::
1102
1103     do p1 <- E1; ...; pn <- En; return E
1104
1105 where none of the variables defined by ``p1...pn`` are mentioned in ``E1...En``,
1106 and ``p1...pn`` are all variables or lazy patterns,
1107 then the expression will only require ``Applicative``. Otherwise, the expression
1108 will require ``Monad``. The block may return a pure expression ``E`` depending
1109 upon the results ``p1...pn`` with either ``return`` or ``pure``.
1110
1111 Note: the final statement must match one of these patterns exactly:
1112
1113 - ``return E``
1114 - ``return $ E``
1115 - ``pure E``
1116 - ``pure $ E``
1117
1118 otherwise GHC cannot recognise it as a ``return`` statement, and the
1119 transformation to use ``<$>`` that we saw above does not apply.  In
1120 particular, slight variations such as ``return . Just $ x`` or ``let x
1121 = e in return x`` would not be recognised.
1122
1123 If the final statement is not of one of these forms, GHC falls back to
1124 standard ``do`` desugaring, and the expression will require a
1125 ``Monad`` constraint.
1126
1127 When the statements of a ``do`` expression have dependencies between
1128 them, and ``ApplicativeDo`` cannot infer an ``Applicative`` type, it
1129 uses a heuristic algorithm to try to use ``<*>`` as much as possible.
1130 This algorithm usually finds the best solution, but in rare complex
1131 cases it might miss an opportunity.  There is an algorithm that finds
1132 the optimal solution, provided as an option:
1133
1134 .. ghc-flag:: -foptimal-applicative-do
1135     :shortdesc: Use a slower but better algorithm for ApplicativeDo
1136     :type: dynamic
1137     :reverse: -fno-optimal-applicative-do
1138     :category: optimization
1139
1140     :since: 8.0.1
1141
1142     Enables an alternative algorithm for choosing where to use ``<*>``
1143     in conjunction with the ``ApplicativeDo`` language extension.
1144     This algorithm always finds the optimal solution, but it is
1145     expensive: ``O(n^3)``, so this option can lead to long compile
1146     times when there are very large ``do`` expressions (over 100
1147     statements).  The default ``ApplicativeDo`` algorithm is ``O(n^2)``.
1148
1149
1150 .. _applicative-do-strict:
1151
1152 Strict patterns
1153 ~~~~~~~~~~~~~~~
1154
1155
1156 A strict pattern match in a bind statement prevents
1157 ``ApplicativeDo`` from transforming that statement to use
1158 ``Applicative``.  This is because the transformation would change the
1159 semantics by making the expression lazier.
1160
1161 For example, this code will require a ``Monad`` constraint::
1162
1163     > :t \m -> do { (x:xs) <- m; return x }
1164     \m -> do { (x:xs) <- m; return x } :: Monad m => m [b] -> m b
1165
1166 but making the pattern match lazy allows it to have a ``Functor`` constraint::
1167
1168     > :t \m -> do { ~(x:xs) <- m; return x }
1169     \m -> do { ~(x:xs) <- m; return x } :: Functor f => f [b] -> f b
1170
1171 A "strict pattern match" is any pattern match that can fail.  For
1172 example, ``()``, ``(x:xs)``, ``!z``, and ``C x`` are strict patterns,
1173 but ``x`` and ``~(1,2)`` are not.  For the purposes of
1174 ``ApplicativeDo``, a pattern match against a ``newtype`` constructor
1175 is considered strict.
1176
1177 When there's a strict pattern match in a sequence of statements,
1178 ``ApplicativeDo`` places a ``>>=`` between that statement and the one
1179 that follows it.  The sequence may be transformed to use ``<*>``
1180 elsewhere, but the strict pattern match and the following statement
1181 will always be connected with ``>>=``, to retain the same strictness
1182 semantics as the standard do-notation.  If you don't want this, simply
1183 put a ``~`` on the pattern match to make it lazy.
1184
1185 .. _applicative-do-pitfall:
1186
1187 Things to watch out for
1188 ~~~~~~~~~~~~~~~~~~~~~~~
1189
1190 Your code should just work as before when :extension:`ApplicativeDo` is enabled,
1191 provided you use conventional ``Applicative`` instances. However, if you define
1192 a ``Functor`` or ``Applicative`` instance using do-notation, then it will likely
1193 get turned into an infinite loop by GHC. For example, if you do this: ::
1194
1195     instance Functor MyType where
1196         fmap f m = do x <- m; return (f x)
1197
1198 Then applicative desugaring will turn it into ::
1199
1200     instance Functor MyType where
1201         fmap f m = fmap (\x -> f x) m
1202
1203 And the program will loop at runtime. Similarly, an ``Applicative`` instance
1204 like this ::
1205
1206     instance Applicative MyType where
1207         pure = return
1208         x <*> y = do f <- x; a <- y; return (f a)
1209
1210 will result in an infinte loop when ``<*>`` is called.
1211
1212 Just as you wouldn't define a ``Monad`` instance using the do-notation, you
1213 shouldn't define ``Functor`` or ``Applicative`` instance using do-notation (when
1214 using ``ApplicativeDo``) either. The correct way to define these instances in
1215 terms of ``Monad`` is to use the ``Monad`` operations directly, e.g. ::
1216
1217     instance Functor MyType where
1218         fmap f m = m >>= return . f
1219
1220     instance Applicative MyType where
1221         pure = return
1222         (<*>) = ap
1223
1224
1225 .. _parallel-list-comprehensions:
1226
1227 Parallel List Comprehensions
1228 ----------------------------
1229
1230 .. index::
1231    single: list comprehensions; parallel
1232    single: parallel list comprehensions
1233
1234 .. extension:: ParallelListComp
1235     :shortdesc: Enable parallel list comprehensions.
1236
1237     :since: 6.8.1
1238
1239     Allow parallel list comprehension syntax.
1240
1241 Parallel list comprehensions are a natural extension to list
1242 comprehensions. List comprehensions can be thought of as a nice syntax
1243 for writing maps and filters. Parallel comprehensions extend this to
1244 include the ``zipWith`` family.
1245
1246 A parallel list comprehension has multiple independent branches of
1247 qualifier lists, each separated by a ``|`` symbol. For example, the
1248 following zips together two lists: ::
1249
1250        [ (x, y) | x <- xs | y <- ys ]
1251
1252 The behaviour of parallel list comprehensions follows that of zip, in
1253 that the resulting list will have the same length as the shortest
1254 branch.
1255
1256 We can define parallel list comprehensions by translation to regular
1257 comprehensions. Here's the basic idea:
1258
1259 Given a parallel comprehension of the form: ::
1260
1261        [ e | p1 <- e11, p2 <- e12, ...
1262            | q1 <- e21, q2 <- e22, ...
1263            ...
1264        ]
1265
1266 This will be translated to: ::
1267
1268        [ e | ((p1,p2), (q1,q2), ...) <- zipN [(p1,p2) | p1 <- e11, p2 <- e12, ...]
1269                                              [(q1,q2) | q1 <- e21, q2 <- e22, ...]
1270                                              ...
1271        ]
1272
1273 where ``zipN`` is the appropriate zip for the given number of branches.
1274
1275 .. _generalised-list-comprehensions:
1276
1277 Generalised (SQL-like) List Comprehensions
1278 ------------------------------------------
1279
1280 .. index::
1281    single: list comprehensions; generalised
1282    single: extended list comprehensions
1283    single: group
1284    single: SQL
1285
1286 .. extension:: TransformListComp
1287     :shortdesc: Enable generalised list comprehensions.
1288
1289     :since: 6.10.1
1290
1291     Allow use of generalised list (SQL-like) comprehension syntax. This
1292     introduces the ``group``, ``by``, and ``using`` keywords.
1293
1294 Generalised list comprehensions are a further enhancement to the list
1295 comprehension syntactic sugar to allow operations such as sorting and
1296 grouping which are familiar from SQL. They are fully described in the
1297 paper `Comprehensive comprehensions: comprehensions with "order by" and
1298 "group by" <https://www.microsoft.com/en-us/research/wp-content/uploads/2007/09/list-comp.pdf>`__,
1299 except that the syntax we use differs slightly from the paper.
1300
1301 The extension is enabled with the extension :extension:`TransformListComp`.
1302
1303 Here is an example:
1304
1305 ::
1306
1307     employees = [ ("Simon", "MS", 80)
1308                 , ("Erik", "MS", 100)
1309                 , ("Phil", "Ed", 40)
1310                 , ("Gordon", "Ed", 45)
1311                 , ("Paul", "Yale", 60) ]
1312
1313     output = [ (the dept, sum salary)
1314              | (name, dept, salary) <- employees
1315              , then group by dept using groupWith
1316              , then sortWith by (sum salary)
1317              , then take 5 ]
1318
1319 In this example, the list ``output`` would take on the value:
1320
1321 ::
1322
1323     [("Yale", 60), ("Ed", 85), ("MS", 180)]
1324
1325 There are three new keywords: ``group``, ``by``, and ``using``. (The
1326 functions ``sortWith`` and ``groupWith`` are not keywords; they are
1327 ordinary functions that are exported by ``GHC.Exts``.)
1328
1329 There are five new forms of comprehension qualifier, all introduced by
1330 the (existing) keyword ``then``:
1331
1332 -  ::
1333
1334        then f
1335
1336    This statement requires that
1337    f
1338    have the type
1339    forall a. [a] -> [a]
1340    . You can see an example of its use in the motivating example, as
1341    this form is used to apply
1342    take 5
1343    .
1344 -  ::
1345
1346        then f by e
1347
1348    This form is similar to the previous one, but allows you to create a
1349    function which will be passed as the first argument to f. As a
1350    consequence f must have the type
1351    ``forall a. (a -> t) -> [a] -> [a]``. As you can see from the type,
1352    this function lets f "project out" some information from the elements
1353    of the list it is transforming.
1354
1355    An example is shown in the opening example, where ``sortWith`` is
1356    supplied with a function that lets it find out the ``sum salary`` for
1357    any item in the list comprehension it transforms.
1358
1359 -  ::
1360
1361        then group by e using f
1362
1363    This is the most general of the grouping-type statements. In this
1364    form, f is required to have type
1365    ``forall a. (a -> t) -> [a] -> [[a]]``. As with the ``then f by e``
1366    case above, the first argument is a function supplied to f by the
1367    compiler which lets it compute e on every element of the list being
1368    transformed. However, unlike the non-grouping case, f additionally
1369    partitions the list into a number of sublists: this means that at
1370    every point after this statement, binders occurring before it in the
1371    comprehension refer to *lists* of possible values, not single values.
1372    To help understand this, let's look at an example:
1373
1374    ::
1375
1376        -- This works similarly to groupWith in GHC.Exts, but doesn't sort its input first
1377        groupRuns :: Eq b => (a -> b) -> [a] -> [[a]]
1378        groupRuns f = groupBy (\x y -> f x == f y)
1379
1380        output = [ (the x, y)
1381        | x <- ([1..3] ++ [1..2])
1382        , y <- [4..6]
1383        , then group by x using groupRuns ]
1384
1385    This results in the variable ``output`` taking on the value below:
1386
1387    ::
1388
1389        [(1, [4, 5, 6]), (2, [4, 5, 6]), (3, [4, 5, 6]), (1, [4, 5, 6]), (2, [4, 5, 6])]
1390
1391    Note that we have used the ``the`` function to change the type of x
1392    from a list to its original numeric type. The variable y, in
1393    contrast, is left unchanged from the list form introduced by the
1394    grouping.
1395
1396 -  ::
1397
1398        then group using f
1399
1400    With this form of the group statement, f is required to simply have
1401    the type ``forall a. [a] -> [[a]]``, which will be used to group up
1402    the comprehension so far directly. An example of this form is as
1403    follows:
1404
1405    ::
1406
1407        output = [ x
1408        | y <- [1..5]
1409        , x <- "hello"
1410        , then group using inits]
1411
1412    This will yield a list containing every prefix of the word "hello"
1413    written out 5 times:
1414
1415    ::
1416
1417        ["","h","he","hel","hell","hello","helloh","hellohe","hellohel","hellohell","hellohello","hellohelloh",...]
1418
1419 .. _monad-comprehensions:
1420
1421 Monad comprehensions
1422 --------------------
1423
1424 .. index::
1425    single: monad comprehensions
1426
1427 .. extension:: MonadComprehensions
1428     :shortdesc: Enable monad comprehensions.
1429
1430     :since: 7.2.1
1431
1432     Enable list comprehension syntax for arbitrary monads.
1433
1434 Monad comprehensions generalise the list comprehension notation,
1435 including parallel comprehensions (:ref:`parallel-list-comprehensions`)
1436 and transform comprehensions (:ref:`generalised-list-comprehensions`) to
1437 work for any monad.
1438
1439 Monad comprehensions support:
1440
1441 -  Bindings: ::
1442
1443        [ x + y | x <- Just 1, y <- Just 2 ]
1444
1445    Bindings are translated with the ``(>>=)`` and ``return`` functions
1446    to the usual do-notation: ::
1447
1448        do x <- Just 1
1449           y <- Just 2
1450           return (x+y)
1451
1452 -  Guards: ::
1453
1454        [ x | x <- [1..10], x <= 5 ]
1455
1456    Guards are translated with the ``guard`` function, which requires a
1457    ``MonadPlus`` instance: ::
1458
1459        do x <- [1..10]
1460           guard (x <= 5)
1461           return x
1462
1463 -  Transform statements (as with :extension:`TransformListComp`): ::
1464
1465        [ x+y | x <- [1..10], y <- [1..x], then take 2 ]
1466
1467    This translates to: ::
1468
1469        do (x,y) <- take 2 (do x <- [1..10]
1470                               y <- [1..x]
1471                               return (x,y))
1472           return (x+y)
1473
1474 -  Group statements (as with :extension:`TransformListComp`):
1475
1476    ::
1477
1478        [ x | x <- [1,1,2,2,3], then group by x using GHC.Exts.groupWith ]
1479        [ x | x <- [1,1,2,2,3], then group using myGroup ]
1480
1481 -  Parallel statements (as with :extension:`ParallelListComp`):
1482
1483    ::
1484
1485        [ (x+y) | x <- [1..10]
1486                | y <- [11..20]
1487                ]
1488
1489    Parallel statements are translated using the ``mzip`` function, which
1490    requires a ``MonadZip`` instance defined in
1491    :base-ref:`Control.Monad.Zip.`:
1492
1493    ::
1494
1495        do (x,y) <- mzip (do x <- [1..10]
1496                             return x)
1497                         (do y <- [11..20]
1498                             return y)
1499           return (x+y)
1500
1501 All these features are enabled by default if the :extension:`MonadComprehensions`
1502 extension is enabled. The types and more detailed examples on how to use
1503 comprehensions are explained in the previous chapters
1504 :ref:`generalised-list-comprehensions` and
1505 :ref:`parallel-list-comprehensions`. In general you just have to replace
1506 the type ``[a]`` with the type ``Monad m => m a`` for monad
1507 comprehensions.
1508
1509 .. note::
1510     Even though most of these examples are using the list monad, monad
1511     comprehensions work for any monad. The ``base`` package offers all
1512     necessary instances for lists, which make :extension:`MonadComprehensions`
1513     backward compatible to built-in, transform and parallel list
1514     comprehensions.
1515
1516 More formally, the desugaring is as follows. We write ``D[ e | Q]`` to
1517 mean the desugaring of the monad comprehension ``[ e | Q]``:
1518
1519 .. code-block:: none
1520
1521     Expressions: e
1522     Declarations: d
1523     Lists of qualifiers: Q,R,S
1524
1525     -- Basic forms
1526     D[ e | ]               = return e
1527     D[ e | p <- e, Q ]  = e >>= \p -> D[ e | Q ]
1528     D[ e | e, Q ]          = guard e >> \p -> D[ e | Q ]
1529     D[ e | let d, Q ]      = let d in D[ e | Q ]
1530
1531     -- Parallel comprehensions (iterate for multiple parallel branches)
1532     D[ e | (Q | R), S ]    = mzip D[ Qv | Q ] D[ Rv | R ] >>= \(Qv,Rv) -> D[ e | S ]
1533
1534     -- Transform comprehensions
1535     D[ e | Q then f, R ]                  = f D[ Qv | Q ] >>= \Qv -> D[ e | R ]
1536
1537     D[ e | Q then f by b, R ]             = f (\Qv -> b) D[ Qv | Q ] >>= \Qv -> D[ e | R ]
1538
1539     D[ e | Q then group using f, R ]      = f D[ Qv | Q ] >>= \ys ->
1540                                             case (fmap selQv1 ys, ..., fmap selQvn ys) of
1541                                              Qv -> D[ e | R ]
1542
1543     D[ e | Q then group by b using f, R ] = f (\Qv -> b) D[ Qv | Q ] >>= \ys ->
1544                                             case (fmap selQv1 ys, ..., fmap selQvn ys) of
1545                                                Qv -> D[ e | R ]
1546
1547     where  Qv is the tuple of variables bound by Q (and used subsequently)
1548            selQvi is a selector mapping Qv to the ith component of Qv
1549
1550     Operator     Standard binding       Expected type
1551     --------------------------------------------------------------------
1552     return       GHC.Base               t1 -> m t2
1553     (>>=)        GHC.Base               m1 t1 -> (t2 -> m2 t3) -> m3 t3
1554     (>>)         GHC.Base               m1 t1 -> m2 t2         -> m3 t3
1555     guard        Control.Monad          t1 -> m t2
1556     fmap         GHC.Base               forall a b. (a->b) -> n a -> n b
1557     mzip         Control.Monad.Zip      forall a b. m a -> m b -> m (a,b)
1558
1559 The comprehension should typecheck when its desugaring would typecheck,
1560 except that (as discussed in :ref:`generalised-list-comprehensions`) in the
1561 "then ``f``" and "then group using ``f``" clauses, when the "by ``b``" qualifier
1562 is omitted, argument ``f`` should have a polymorphic type. In particular, "then
1563 ``Data.List.sort``" and "then group using ``Data.List.group``" are
1564 insufficiently polymorphic.
1565
1566 Monad comprehensions support rebindable syntax
1567 (:ref:`rebindable-syntax`). Without rebindable syntax, the operators
1568 from the "standard binding" module are used; with rebindable syntax, the
1569 operators are looked up in the current lexical scope. For example,
1570 parallel comprehensions will be typechecked and desugared using whatever
1571 "``mzip``" is in scope.
1572
1573 The rebindable operators must have the "Expected type" given in the
1574 table above. These types are surprisingly general. For example, you can
1575 use a bind operator with the type
1576
1577 ::
1578
1579     (>>=) :: T x y a -> (a -> T y z b) -> T x z b
1580
1581 In the case of transform comprehensions, notice that the groups are
1582 parameterised over some arbitrary type ``n`` (provided it has an
1583 ``fmap``, as well as the comprehension being over an arbitrary monad.
1584
1585 .. _monadfail-desugaring:
1586
1587 New monadic failure desugaring mechanism
1588 ----------------------------------------
1589
1590 .. extension:: MonadFailDesugaring
1591     :shortdesc: Enable monadfail desugaring.
1592
1593     :since: 8.0.1
1594
1595     Use the ``MonadFail.fail`` instead of the legacy ``Monad.fail`` function
1596     when desugaring refutable patterns in ``do`` blocks.
1597
1598 The ``-XMonadFailDesugaring`` extension switches the desugaring of
1599 ``do``-blocks to use ``MonadFail.fail`` instead of ``Monad.fail``.
1600
1601 This extension is enabled by default since GHC 8.6.1, under the
1602 `MonadFail Proposal (MFP)
1603 <https://prime.haskell.org/wiki/Libraries/Proposals/MonadFail>`__.
1604
1605 This extension is temporary, and will be deprecated in a future release.
1606
1607 .. _rebindable-syntax:
1608
1609 Rebindable syntax and the implicit Prelude import
1610 -------------------------------------------------
1611
1612 .. extension:: NoImplicitPrelude
1613     :shortdesc: Don't implicitly ``import Prelude``.
1614         Implied by :extension:`RebindableSyntax`.
1615
1616     :since: 6.8.1
1617
1618     Don't import ``Prelude`` by default.
1619
1620 GHC normally imports ``Prelude.hi`` files for
1621 you. If you'd rather it didn't, then give it a ``-XNoImplicitPrelude``
1622 option. The idea is that you can then import a Prelude of your own. (But
1623 don't call it ``Prelude``; the Haskell module namespace is flat, and you
1624 must not conflict with any Prelude module.)
1625
1626 .. extension:: RebindableSyntax
1627     :shortdesc: Employ rebindable syntax.
1628         Implies :extension:`NoImplicitPrelude`.
1629
1630     :implies: :extension:`NoImplicitPrelude`
1631     :since: 7.0.1
1632
1633     Enable rebinding of a variety of usually-built-in operations.
1634
1635 Suppose you are importing a Prelude of your own in order to define your
1636 own numeric class hierarchy. It completely defeats that purpose if the
1637 literal "1" means "``Prelude.fromInteger 1``", which is what the Haskell
1638 Report specifies. So the :extension:`RebindableSyntax` extension causes the
1639 following pieces of built-in syntax to refer to *whatever is in scope*,
1640 not the Prelude versions:
1641
1642 -  An integer literal ``368`` means "``fromInteger (368::Integer)``",
1643    rather than "``Prelude.fromInteger (368::Integer)``".
1644
1645 -  Fractional literals are handed in just the same way, except that the
1646    translation is ``fromRational (3.68::Rational)``.
1647
1648 -  The equality test in an overloaded numeric pattern uses whatever
1649    ``(==)`` is in scope.
1650
1651 -  The subtraction operation, and the greater-than-or-equal test, in
1652    ``n+k`` patterns use whatever ``(-)`` and ``(>=)`` are in scope.
1653
1654 -  Negation (e.g. "``- (f x)``") means "``negate (f x)``", both in
1655    numeric patterns, and expressions.
1656
1657 -  Conditionals (e.g. "``if`` e1 ``then`` e2 ``else`` e3") means
1658    "``ifThenElse`` e1 e2 e3". However ``case`` expressions are
1659    unaffected.
1660
1661 -  "Do" notation is translated using whatever functions ``(>>=)``,
1662    ``(>>)``, and ``fail``, are in scope (not the Prelude versions). List
1663    comprehensions, ``mdo`` (:ref:`recursive-do-notation`), and parallel
1664    array comprehensions, are unaffected.
1665
1666 -  Arrow notation (see :ref:`arrow-notation`) uses whatever ``arr``,
1667    ``(>>>)``, ``first``, ``app``, ``(|||)`` and ``loop`` functions are
1668    in scope. But unlike the other constructs, the types of these
1669    functions must match the Prelude types very closely. Details are in
1670    flux; if you want to use this, ask!
1671
1672 -  List notation, such as ``[x,y]`` or ``[m..n]`` can also be treated
1673    via rebindable syntax if you use `-XOverloadedLists`;
1674    see :ref:`overloaded-lists`.
1675
1676 -  An overloaded label "``#foo``" means "``fromLabel @"foo"``", rather than
1677    "``GHC.OverloadedLabels.fromLabel @"foo"``" (see :ref:`overloaded-labels`).
1678
1679 :extension:`RebindableSyntax` implies :extension:`NoImplicitPrelude`.
1680
1681 In all cases (apart from arrow notation), the static semantics should be
1682 that of the desugared form, even if that is a little unexpected. For
1683 example, the static semantics of the literal ``368`` is exactly that of
1684 ``fromInteger (368::Integer)``; it's fine for ``fromInteger`` to have
1685 any of the types: ::
1686
1687     fromInteger :: Integer -> Integer
1688     fromInteger :: forall a. Foo a => Integer -> a
1689     fromInteger :: Num a => a -> Integer
1690     fromInteger :: Integer -> Bool -> Bool
1691
1692 Be warned: this is an experimental facility, with fewer checks than
1693 usual. Use ``-dcore-lint`` to typecheck the desugared program. If Core
1694 Lint is happy you should be all right.
1695
1696 Things unaffected by :extension:`RebindableSyntax`
1697 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1698
1699 :extension:`RebindableSyntax` does not apply to any code generated from a
1700 ``deriving`` clause or declaration. To see why, consider the following code: ::
1701
1702     {-# LANGUAGE RebindableSyntax, OverloadedStrings #-}
1703     newtype Text = Text String
1704
1705     fromString :: String -> Text
1706     fromString = Text
1707
1708     data Foo = Foo deriving Show
1709
1710 This will generate code to the effect of: ::
1711
1712     instance Show Foo where
1713       showsPrec _ Foo = showString "Foo"
1714
1715 But because :extension:`RebindableSyntax` and :extension:`OverloadedStrings`
1716 are enabled, the ``"Foo"`` string literal would now be of type ``Text``, not
1717 ``String``, which ``showString`` doesn't accept! This causes the generated
1718 ``Show`` instance to fail to typecheck. It's hard to imagine any scenario where
1719 it would be desirable have :extension:`RebindableSyntax` behavior within
1720 derived code, so GHC simply ignores :extension:`RebindableSyntax` entirely
1721 when checking derived code.
1722
1723 .. _postfix-operators:
1724
1725 Postfix operators
1726 -----------------
1727
1728 .. extension:: PostfixOperators
1729     :shortdesc: Enable postfix operators.
1730
1731     :since: 7.10.1
1732
1733     Allow the use of post-fix operators
1734
1735 The :extension:`PostfixOperators` extension enables a small extension to the syntax
1736 of left operator sections, which allows you to define postfix operators.
1737 The extension is this: the left section ::
1738
1739       (e !)
1740
1741 is equivalent (from the point of view of both type checking and
1742 execution) to the expression ::
1743
1744       ((!) e)
1745
1746 (for any expression ``e`` and operator ``(!)``. The strict Haskell 98
1747 interpretation is that the section is equivalent to ::
1748
1749       (\y -> (!) e y)
1750
1751 That is, the operator must be a function of two arguments. GHC allows it
1752 to take only one argument, and that in turn allows you to write the
1753 function postfix.
1754
1755 The extension does not extend to the left-hand side of function
1756 definitions; you must define such a function in prefix form.
1757
1758 .. _tuple-sections:
1759
1760 Tuple sections
1761 --------------
1762
1763 .. extension:: TupleSections
1764     :shortdesc: Enable tuple sections.
1765
1766     :since: 6.12
1767
1768     Allow the use of tuple section syntax
1769
1770 The :extension:`TupleSections` extension enables partially applied
1771 tuple constructors. For example, the following program ::
1772
1773       (, True)
1774
1775 is considered to be an alternative notation for the more unwieldy
1776 alternative ::
1777
1778       \x -> (x, True)
1779
1780 You can omit any combination of arguments to the tuple, as in the
1781 following ::
1782
1783       (, "I", , , "Love", , 1337)
1784
1785 which translates to ::
1786
1787       \a b c d -> (a, "I", b, c, "Love", d, 1337)
1788
1789 If you have `unboxed tuples <#unboxed-tuples>`__ enabled, tuple sections
1790 will also be available for them, like so ::
1791
1792       (# , True #)
1793
1794 Because there is no unboxed unit tuple, the following expression ::
1795
1796       (# #)
1797
1798 continues to stand for the unboxed singleton tuple data constructor.
1799
1800 .. _lambda-case:
1801
1802 Lambda-case
1803 -----------
1804
1805 .. extension:: LambdaCase
1806     :shortdesc: Enable lambda-case expressions.
1807
1808     :since: 7.6.1
1809
1810     Allow the use of lambda-case syntax.
1811
1812 The :extension:`LambdaCase` extension enables expressions of the form ::
1813
1814       \case { p1 -> e1; ...; pN -> eN }
1815
1816 which is equivalent to ::
1817
1818       \freshName -> case freshName of { p1 -> e1; ...; pN -> eN }
1819
1820 Note that ``\case`` starts a layout, so you can write ::
1821
1822       \case
1823         p1 -> e1
1824         ...
1825         pN -> eN
1826
1827 .. _empty-case:
1828
1829 Empty case alternatives
1830 -----------------------
1831
1832 .. extension:: EmptyCase
1833     :shortdesc: Allow empty case alternatives.
1834
1835     :since: 7.8.1
1836
1837     Allow empty case expressions.
1838
1839 The :extension:`EmptyCase` extension enables case expressions, or lambda-case
1840 expressions, that have no alternatives, thus: ::
1841
1842     case e of { }   -- No alternatives
1843
1844 or ::
1845
1846     \case { }       -- -XLambdaCase is also required
1847
1848 This can be useful when you know that the expression being scrutinised
1849 has no non-bottom values. For example:
1850
1851 ::
1852
1853       data Void
1854       f :: Void -> Int
1855       f x = case x of { }
1856
1857 With dependently-typed features it is more useful (see :ghc-ticket:`2431`). For
1858 example, consider these two candidate definitions of ``absurd``:
1859
1860 ::
1861
1862     data a :~: b where
1863       Refl :: a :~: a
1864
1865     absurd :: True :~: False -> a
1866     absurd x = error "absurd"    -- (A)
1867     absurd x = case x of {}      -- (B)
1868
1869 We much prefer (B). Why? Because GHC can figure out that
1870 ``(True :~: False)`` is an empty type. So (B) has no partiality and GHC
1871 is able to compile with :ghc-flag:`-Wincomplete-patterns` and
1872 :ghc-flag:`-Werror`. On the other hand (A) looks dangerous, and GHC doesn't
1873 check to make sure that, in fact, the function can never get called.
1874
1875 .. _multi-way-if:
1876
1877 Multi-way if-expressions
1878 ------------------------
1879
1880 .. extension:: MultiWayIf
1881     :shortdesc: Enable multi-way if-expressions.
1882
1883     :since: 7.6.1
1884
1885     Allow the use of multi-way-``if`` syntax.
1886
1887 With :extension:`MultiWayIf` extension GHC accepts conditional expressions with
1888 multiple branches: ::
1889
1890       if | guard1 -> expr1
1891          | ...
1892          | guardN -> exprN
1893
1894 which is roughly equivalent to ::
1895
1896       case () of
1897         _ | guard1 -> expr1
1898         ...
1899         _ | guardN -> exprN
1900
1901 Multi-way if expressions introduce a new layout context. So the example
1902 above is equivalent to: ::
1903
1904       if { | guard1 -> expr1
1905          ; | ...
1906          ; | guardN -> exprN
1907          }
1908
1909 The following behaves as expected: ::
1910
1911       if | guard1 -> if | guard2 -> expr2
1912                         | guard3 -> expr3
1913          | guard4 -> expr4
1914
1915 because layout translates it as ::
1916
1917       if { | guard1 -> if { | guard2 -> expr2
1918                           ; | guard3 -> expr3
1919                           }
1920          ; | guard4 -> expr4
1921          }
1922
1923 Layout with multi-way if works in the same way as other layout contexts,
1924 except that the semi-colons between guards in a multi-way if are
1925 optional. So it is not necessary to line up all the guards at the same
1926 column; this is consistent with the way guards work in function
1927 definitions and case expressions.
1928
1929 .. _local-fixity-declarations:
1930
1931 Local Fixity Declarations
1932 -------------------------
1933
1934 A careful reading of the Haskell 98 Report reveals that fixity
1935 declarations (``infix``, ``infixl``, and ``infixr``) are permitted to
1936 appear inside local bindings such those introduced by ``let`` and
1937 ``where``. However, the Haskell Report does not specify the semantics of
1938 such bindings very precisely.
1939
1940 In GHC, a fixity declaration may accompany a local binding: ::
1941
1942     let f = ...
1943         infixr 3 `f`
1944     in
1945         ...
1946
1947 and the fixity declaration applies wherever the binding is in scope. For
1948 example, in a ``let``, it applies in the right-hand sides of other
1949 ``let``-bindings and the body of the ``let``\ C. Or, in recursive ``do``
1950 expressions (:ref:`recursive-do-notation`), the local fixity
1951 declarations of a ``let`` statement scope over other statements in the
1952 group, just as the bound name does.
1953
1954 Moreover, a local fixity declaration *must* accompany a local binding
1955 of that name: it is not possible to revise the fixity of name bound
1956 elsewhere, as in ::
1957
1958     let infixr 9 $ in ...
1959
1960 Because local fixity declarations are technically Haskell 98, no extension is
1961 necessary to enable them.
1962
1963 .. _package-imports:
1964
1965 Import and export extensions
1966 ----------------------------
1967
1968 Hiding things the imported module doesn't export
1969 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1970
1971 Technically in Haskell 2010 this is illegal: ::
1972
1973     module A( f ) where
1974       f = True
1975
1976     module B where
1977       import A hiding( g )  -- A does not export g
1978       g = f
1979
1980 The ``import A hiding( g )`` in module ``B`` is technically an error
1981 (`Haskell Report,
1982 5.3.1 <http://www.haskell.org/onlinereport/haskell2010/haskellch5.html#x11-1020005.3.1>`__)
1983 because ``A`` does not export ``g``. However GHC allows it, in the
1984 interests of supporting backward compatibility; for example, a newer
1985 version of ``A`` might export ``g``, and you want ``B`` to work in
1986 either case.
1987
1988 The warning :ghc-flag:`-Wdodgy-imports`, which is off by default but included
1989 with :ghc-flag:`-W`, warns if you hide something that the imported module does
1990 not export.
1991
1992 .. _package-qualified-imports:
1993
1994 Package-qualified imports
1995 ~~~~~~~~~~~~~~~~~~~~~~~~~
1996
1997 .. extension:: PackageImports
1998     :shortdesc: Enable package-qualified imports.
1999
2000     :since: 6.10.1
2001
2002     Allow the use of package-qualified ``import`` syntax.
2003
2004 With the :extension:`PackageImports` extension, GHC allows import declarations to be
2005 qualified by the package name that the module is intended to be imported
2006 from. For example: ::
2007
2008     import "network" Network.Socket
2009
2010 would import the module ``Network.Socket`` from the package ``network``
2011 (any version). This may be used to disambiguate an import when the same
2012 module is available from multiple packages, or is present in both the
2013 current package being built and an external package.
2014
2015 The special package name ``this`` can be used to refer to the current
2016 package being built.
2017
2018 .. note::
2019    You probably don't need to use this feature, it was added mainly so that we
2020    can build backwards-compatible versions of packages when APIs change. It can
2021    lead to fragile dependencies in the common case: modules occasionally move
2022    from one package to another, rendering any package-qualified imports broken.
2023    See also :ref:`package-thinning-and-renaming` for an alternative way of
2024    disambiguating between module names.
2025
2026 .. _safe-imports-ext:
2027
2028 Safe imports
2029 ~~~~~~~~~~~~
2030
2031 .. extension:: Safe
2032     :shortdesc: Enable the :ref:`Safe Haskell <safe-haskell>` Safe mode.
2033     :noindex:
2034
2035     :since: 7.2.1
2036
2037     Declare the Safe Haskell state of the current module.
2038
2039 .. extension:: Trustworthy
2040     :shortdesc: Enable the :ref:`Safe Haskell <safe-haskell>` Trustworthy mode.
2041     :noindex:
2042
2043     :since: 7.2.1
2044
2045     Declare the Safe Haskell state of the current module.
2046
2047 .. extension:: Unsafe
2048     :shortdesc: Enable Safe Haskell Unsafe mode.
2049     :noindex:
2050
2051     :since: 7.4.1
2052
2053     Declare the Safe Haskell state of the current module.
2054
2055 With the :extension:`Safe`, :extension:`Trustworthy` and :extension:`Unsafe`
2056 language flags, GHC extends the import declaration syntax to take an optional
2057 ``safe`` keyword after the ``import`` keyword. This feature is part of the Safe
2058 Haskell GHC extension. For example: ::
2059
2060     import safe qualified Network.Socket as NS
2061
2062 would import the module ``Network.Socket`` with compilation only
2063 succeeding if ``Network.Socket`` can be safely imported. For a description of
2064 when a import is considered safe see :ref:`safe-haskell`.
2065
2066 .. _explicit-namespaces:
2067
2068 Explicit namespaces in import/export
2069 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2070
2071 .. extension:: ExplicitNamespaces
2072     :shortdesc: Enable using the keyword ``type`` to specify the namespace of
2073         entries in imports and exports (:ref:`explicit-namespaces`).
2074         Implied by :extension:`TypeOperators` and :extension:`TypeFamilies`.
2075
2076     :since: 7.6.1
2077
2078     Enable use of explicit namespaces in module export lists.
2079
2080 In an import or export list, such as ::
2081
2082       module M( f, (++) ) where ...
2083         import N( f, (++) )
2084         ...
2085
2086 the entities ``f`` and ``(++)`` are *values*. However, with type
2087 operators (:ref:`type-operators`) it becomes possible to declare
2088 ``(++)`` as a *type constructor*. In that case, how would you export or
2089 import it?
2090
2091 The :extension:`ExplicitNamespaces` extension allows you to prefix the name of
2092 a type constructor in an import or export list with "``type``" to
2093 disambiguate this case, thus: ::
2094
2095       module M( f, type (++) ) where ...
2096         import N( f, type (++) )
2097         ...
2098       module N( f, type (++) ) where
2099         data family a ++ b = L a | R b
2100
2101 The extension :extension:`ExplicitNamespaces` is implied by
2102 :extension:`TypeOperators` and (for some reason) by :extension:`TypeFamilies`.
2103
2104 In addition, with :extension:`PatternSynonyms` you can prefix the name of a
2105 data constructor in an import or export list with the keyword
2106 ``pattern``, to allow the import or export of a data constructor without
2107 its parent type constructor (see :ref:`patsyn-impexp`).
2108
2109 .. _block-arguments:
2110
2111 More liberal syntax for function arguments
2112 ------------------------------------------
2113
2114 .. extension:: BlockArguments
2115     :shortdesc: Allow ``do`` blocks and other constructs as function arguments.
2116
2117     :since: 8.6.1
2118
2119     Allow ``do`` expressions, lambda expressions, etc. to be directly used as
2120     a function argument.
2121
2122 In Haskell 2010, certain kinds of expressions can be used without parentheses
2123 as an argument to an operator, but not as an argument to a function.
2124 They include ``do``, lambda, ``if``, ``case``, and ``let``
2125 expressions. Some GHC extensions also define language constructs of this type:
2126 ``mdo`` (:ref:`recursive-do-notation`), ``\case`` (:ref:`lambda-case`), and
2127 ``proc`` (:ref:`arrow-notation`).
2128
2129 The :extension:`BlockArguments` extension allows these constructs to be directly
2130 used as a function argument. For example::
2131
2132     when (x > 0) do
2133       print x
2134       exitFailure
2135
2136 will be parsed as::
2137
2138     when (x > 0) (do
2139       print x
2140       exitFailure)
2141
2142 and
2143
2144 ::
2145
2146     withForeignPtr fptr \ptr -> c_memcpy buf ptr size
2147
2148 will be parsed as::
2149
2150     withForeignPtr fptr (\ptr -> c_memcpy buf ptr size)
2151
2152 Changes to the grammar
2153 ~~~~~~~~~~~~~~~~~~~~~~
2154
2155 The Haskell report `defines
2156 <https://www.haskell.org/onlinereport/haskell2010/haskellch3.html#x8-220003>`_
2157 the ``lexp`` nonterminal thus (``*`` indicates a rule of interest)::
2158
2159     lexp  →  \ apat1 … apatn -> exp            (lambda abstraction, n ≥ 1)  *
2160           |  let decls in exp                  (let expression)             *
2161           |  if exp [;] then exp [;] else exp  (conditional)                *
2162           |  case exp of { alts }              (case expression)            *
2163           |  do { stmts }                      (do expression)              *
2164           |  fexp
2165
2166     fexp  →  [fexp] aexp                       (function application)
2167
2168     aexp  →  qvar                              (variable)
2169           |  gcon                              (general constructor)
2170           |  literal
2171           |  ( exp )                           (parenthesized expression)
2172           |  qcon { fbind1 … fbindn }          (labeled construction)
2173           |  aexp { fbind1 … fbindn }          (labelled update)
2174           |  …
2175
2176 The :extension:`BlockArguments` extension moves these production rules under
2177 ``aexp``::
2178
2179     lexp  →  fexp
2180
2181     fexp  →  [fexp] aexp                       (function application)
2182
2183     aexp  →  qvar                              (variable)
2184           |  gcon                              (general constructor)
2185           |  literal
2186           |  ( exp )                           (parenthesized expression)
2187           |  qcon { fbind1 … fbindn }          (labeled construction)
2188           |  aexp { fbind1 … fbindn }          (labelled update)
2189           |  \ apat1 … apatn -> exp            (lambda abstraction, n ≥ 1)  *
2190           |  let decls in exp                  (let expression)             *
2191           |  if exp [;] then exp [;] else exp  (conditional)                *
2192           |  case exp of { alts }              (case expression)            *
2193           |  do { stmts }                      (do expression)              *
2194           |  …
2195
2196 Now the ``lexp`` nonterminal is redundant and can be dropped from the grammar.
2197
2198 Note that this change relies on an existing meta-rule to resolve ambiguities:
2199
2200     The grammar is ambiguous regarding the extent of lambda abstractions, let
2201     expressions, and conditionals. The ambiguity is resolved by the meta-rule
2202     that each of these constructs extends as far to the right as possible.
2203
2204 For example, ``f \a -> a b`` will be parsed as ``f (\a -> a b)``, not as ``f
2205 (\a -> a) b``.
2206
2207 .. _syntax-stolen:
2208
2209 Summary of stolen syntax
2210 ------------------------
2211
2212 Turning on an option that enables special syntax *might* cause working
2213 Haskell 98 code to fail to compile, perhaps because it uses a variable
2214 name which has become a reserved word. This section lists the syntax
2215 that is "stolen" by language extensions. We use notation and nonterminal
2216 names from the Haskell 98 lexical syntax (see the Haskell 98 Report). We
2217 only list syntax changes here that might affect existing working
2218 programs (i.e. "stolen" syntax). Many of these extensions will also
2219 enable new context-free syntax, but in all cases programs written to use
2220 the new syntax would not be compilable without the option enabled.
2221
2222 There are two classes of special syntax:
2223
2224 -  New reserved words and symbols: character sequences which are no
2225    longer available for use as identifiers in the program.
2226
2227 -  Other special syntax: sequences of characters that have a different
2228    meaning when this particular option is turned on.
2229
2230 The following syntax is stolen:
2231
2232 ``forall``
2233     .. index::
2234        single: forall
2235
2236     Stolen (in types) by: :extension:`ExplicitForAll`, and hence by
2237     :extension:`ScopedTypeVariables`, :extension:`LiberalTypeSynonyms`,
2238     :extension:`RankNTypes`, :extension:`ExistentialQuantification`
2239
2240 ``mdo``
2241     .. index::
2242        single: mdo
2243
2244     Stolen by: :extension:`RecursiveDo`
2245
2246 ``foreign``
2247     .. index::
2248        single: foreign
2249
2250     Stolen by: :extension:`ForeignFunctionInterface`
2251
2252 ``rec``, ``proc``, ``-<``, ``>-``, ``-<<``, ``>>-``, ``(|``, ``|)``
2253     .. index::
2254        single: proc
2255
2256     Stolen by: :extension:`Arrows`
2257
2258 ``?varid``
2259     .. index::
2260        single: implicit parameters
2261
2262     Stolen by: :extension:`ImplicitParams`
2263
2264 ``[|``, ``[e|``, ``[p|``, ``[d|``, ``[t|``, ``[||``, ``[e||``
2265     .. index::
2266        single: Quasi-quotes
2267
2268     Stolen by: :extension:`QuasiQuotes`. Moreover, this introduces an ambiguity
2269     with list comprehension syntax. See the
2270     :ref:`discussion on quasi-quoting <quasi-quotes-list-comprehension-ambiguity>`
2271     for details.
2272
2273 ``$(``, ``$$(``, ``$varid``, ``$$varid``
2274     .. index::
2275        single: Template Haskell
2276
2277     Stolen by: :extension:`TemplateHaskell`
2278
2279 ``[varid|``
2280     .. index::
2281        single: quasi-quotation
2282
2283     Stolen by: :extension:`QuasiQuotes`
2284
2285 ⟨varid⟩, ``#``\ ⟨char⟩, ``#``, ⟨string⟩, ``#``, ⟨integer⟩, ``#``, ⟨float⟩, ``#``, ⟨float⟩, ``##``
2286     Stolen by: :extension:`MagicHash`
2287
2288 ``(#``, ``#)``
2289     Stolen by: :extension:`UnboxedTuples`
2290
2291 ⟨varid⟩, ``!``, ⟨varid⟩
2292     Stolen by: :extension:`BangPatterns`
2293
2294 ``pattern``
2295     Stolen by: :extension:`PatternSynonyms`
2296
2297 ``static``
2298     Stolen by: :extension:`StaticPointers`
2299
2300 .. _data-type-extensions:
2301
2302 Extensions to data types and type synonyms
2303 ==========================================
2304
2305 .. _nullary-types:
2306
2307 Data types with no constructors
2308 -------------------------------
2309
2310 .. extension:: EmptyDataDecls
2311     :shortdesc: Allow definition of empty ``data`` types.
2312
2313     :since: 6.8.1
2314
2315     Allow definition of empty ``data`` types.
2316
2317 With the :extension:`EmptyDataDecls` extension, GHC lets you declare a
2318 data type with no constructors.
2319
2320 You only need to enable this extension if the language you're using
2321 is Haskell 98, in which a data type must have at least one constructor.
2322 Haskell 2010 relaxed this rule to allow data types with no constructors,
2323 and thus :extension:`EmptyDataDecls` is enabled by default when the
2324 language is Haskell 2010.
2325
2326 For example: ::
2327
2328       data S      -- S :: Type
2329       data T a    -- T :: Type -> Type
2330
2331 Syntactically, the declaration lacks the "= constrs" part. The type can be
2332 parameterised over types of any kind, but if the kind is not ``Type`` then an
2333 explicit kind annotation must be used (see :ref:`kinding`).
2334
2335 Such data types have only one value, namely bottom. Nevertheless, they
2336 can be useful when defining "phantom types".
2337
2338 In conjunction with the :ghc-flag:`-XEmptyDataDeriving` extension, empty data
2339 declarations can also derive instances of standard type classes
2340 (see :ref:`empty-data-deriving`).
2341
2342 .. _datatype-contexts:
2343
2344 Data type contexts
2345 ------------------
2346
2347 .. extension:: DatatypeContexts
2348     :shortdesc: Allow contexts on ``data`` types.
2349
2350     :since: 7.0.1
2351
2352     Allow contexts on ``data`` types.
2353
2354 Haskell allows datatypes to be given contexts, e.g. ::
2355
2356     data Eq a => Set a = NilSet | ConsSet a (Set a)
2357
2358 give constructors with types: ::
2359
2360     NilSet :: Set a
2361     ConsSet :: Eq a => a -> Set a -> Set a
2362
2363 This is widely considered a misfeature, and is going to be removed from
2364 the language. In GHC, it is controlled by the deprecated extension
2365 ``DatatypeContexts``.
2366
2367 .. _infix-tycons:
2368
2369 Infix type constructors, classes, and type variables
2370 ----------------------------------------------------
2371
2372 GHC allows type constructors, classes, and type variables to be
2373 operators, and to be written infix, very much like expressions. More
2374 specifically:
2375
2376 -  A type constructor or class can be any non-reserved operator.
2377    Symbols used in types are always like capitalized identifiers; they
2378    are never variables. Note that this is different from the lexical
2379    syntax of data constructors, which are required to begin with a
2380    ``:``.
2381
2382 -  Data type and type-synonym declarations can be written infix,
2383    parenthesised if you want further arguments. E.g. ::
2384
2385          data a :*: b = Foo a b
2386          type a :+: b = Either a b
2387          class a :=: b where ...
2388
2389          data (a :**: b) x = Baz a b x
2390          type (a :++: b) y = Either (a,b) y
2391
2392 -  Types, and class constraints, can be written infix. For example ::
2393
2394          x :: Int :*: Bool
2395          f :: (a :=: b) => a -> b
2396
2397 -  Back-quotes work as for expressions, both for type constructors and
2398    type variables; e.g. ``Int `Either` Bool``, or ``Int `a` Bool``.
2399    Similarly, parentheses work the same; e.g. ``(:*:) Int Bool``.
2400
2401 -  Fixities may be declared for type constructors, or classes, just as
2402    for data constructors. However, one cannot distinguish between the
2403    two in a fixity declaration; a fixity declaration sets the fixity for
2404    a data constructor and the corresponding type constructor. For
2405    example: ::
2406
2407          infixl 7 T, :*:
2408
2409    sets the fixity for both type constructor ``T`` and data constructor
2410    ``T``, and similarly for ``:*:``. ``Int `a` Bool``.
2411
2412 -  The function arrow ``->`` is ``infixr`` with fixity -1.
2413
2414 .. _type-operators:
2415
2416 Type operators
2417 --------------
2418
2419 .. extension:: TypeOperators
2420     :shortdesc: Enable type operators.
2421         Implies :extension:`ExplicitNamespaces`.
2422
2423     :implies: :extension:`ExplicitNamespaces`
2424     :since: 6.8.1
2425
2426     Allow the use and definition of types with operator names.
2427
2428 In types, an operator symbol like ``(+)`` is normally treated as a type
2429 *variable*, just like ``a``. Thus in Haskell 98 you can say
2430
2431 ::
2432
2433     type T (+) = ((+), (+))
2434     -- Just like: type T a = (a,a)
2435
2436     f :: T Int -> Int
2437     f (x,y)= x
2438
2439 As you can see, using operators in this way is not very useful, and
2440 Haskell 98 does not even allow you to write them infix.
2441
2442 The language :extension:`TypeOperators` changes this behaviour:
2443
2444 -  Operator symbols become type *constructors* rather than type
2445    *variables*.
2446
2447 -  Operator symbols in types can be written infix, both in definitions
2448    and uses. For example: ::
2449
2450        data a + b = Plus a b
2451        type Foo = Int + Bool
2452
2453 -  There is now some potential ambiguity in import and export lists; for
2454    example if you write ``import M( (+) )`` do you mean the *function*
2455    ``(+)`` or the *type constructor* ``(+)``? The default is the former,
2456    but with :extension:`ExplicitNamespaces` (which is implied by
2457    :extension:`TypeOperators`) GHC allows you to specify the latter by
2458    preceding it with the keyword ``type``, thus: ::
2459
2460        import M( type (+) )
2461
2462    See :ref:`explicit-namespaces`.
2463
2464 -  The fixity of a type operator may be set using the usual fixity
2465    declarations but, as in :ref:`infix-tycons`, the function and type
2466    constructor share a single fixity.
2467
2468 .. _type-synonyms:
2469
2470 Liberalised type synonyms
2471 -------------------------
2472
2473 .. extension:: LiberalTypeSynonyms
2474     :shortdesc: Enable liberalised type synonyms.
2475
2476     :implies: :extension:`ExplicitForAll`
2477     :since: 6.8.1
2478
2479     Relax many of the Haskell 98 rules on type synonym definitions.
2480
2481 Type synonyms are like macros at the type level, but Haskell 98 imposes
2482 many rules on individual synonym declarations. With the
2483 :extension:`LiberalTypeSynonyms` extension, GHC does validity checking on types
2484 *only after expanding type synonyms*. That means that GHC can be very
2485 much more liberal about type synonyms than Haskell 98.
2486
2487 -  You can write a ``forall`` (including overloading) in a type synonym,
2488    thus: ::
2489
2490          type Discard a = forall b. Show b => a -> b -> (a, String)
2491
2492          f :: Discard a
2493          f x y = (x, show y)
2494
2495          g :: Discard Int -> (Int,String)    -- A rank-2 type
2496          g f = f 3 True
2497
2498 -  If you also use :extension:`UnboxedTuples`, you can write an unboxed tuple
2499    in a type synonym: ::
2500
2501          type Pr = (# Int, Int #)
2502
2503          h :: Int -> Pr
2504          h x = (# x, x #)
2505
2506 -  You can apply a type synonym to a forall type: ::
2507
2508          type Foo a = a -> a -> Bool
2509
2510          f :: Foo (forall b. b->b)
2511
2512    After expanding the synonym, ``f`` has the legal (in GHC) type: ::
2513
2514          f :: (forall b. b->b) -> (forall b. b->b) -> Bool
2515
2516 -  You can apply a type synonym to a partially applied type synonym: ::
2517
2518          type Generic i o = forall x. i x -> o x
2519          type Id x = x
2520
2521          foo :: Generic Id []
2522
2523    After expanding the synonym, ``foo`` has the legal (in GHC) type: ::
2524
2525          foo :: forall x. x -> [x]
2526
2527 GHC currently does kind checking before expanding synonyms (though even
2528 that could be changed).
2529
2530 After expanding type synonyms, GHC does validity checking on types,
2531 looking for the following malformedness which isn't detected simply by
2532 kind checking:
2533
2534 -  Type constructor applied to a type involving for-alls (if
2535    :extension:`ImpredicativeTypes` is off)
2536
2537 -  Partially-applied type synonym.
2538
2539 So, for example, this will be rejected: ::
2540
2541       type Pr = forall a. a
2542
2543       h :: [Pr]
2544       h = ...
2545
2546 because GHC does not allow type constructors applied to for-all types.
2547
2548 .. _existential-quantification:
2549
2550 Existentially quantified data constructors
2551 ------------------------------------------
2552
2553 .. extension:: ExistentialQuantification
2554     :shortdesc: Enable liberalised type synonyms.
2555
2556     :implies: :extension:`ExplicitForAll`
2557     :since: 6.8.1
2558
2559     Allow existentially quantified type variables in types.
2560
2561 The idea of using existential quantification in data type declarations
2562 was suggested by Perry, and implemented in Hope+ (Nigel Perry, *The
2563 Implementation of Practical Functional Programming Languages*, PhD
2564 Thesis, University of London, 1991). It was later formalised by Laufer
2565 and Odersky (*Polymorphic type inference and abstract data types*,
2566 TOPLAS, 16(5), pp. 1411-1430, 1994). It's been in Lennart Augustsson's
2567 ``hbc`` Haskell compiler for several years, and proved very useful.
2568 Here's the idea. Consider the declaration: ::
2569
2570       data Foo = forall a. MkFoo a (a -> Bool)
2571                | Nil
2572
2573 The data type ``Foo`` has two constructors with types: ::
2574
2575       MkFoo :: forall a. a -> (a -> Bool) -> Foo
2576       Nil   :: Foo
2577
2578 Notice that the type variable ``a`` in the type of ``MkFoo`` does not
2579 appear in the data type itself, which is plain ``Foo``. For example, the
2580 following expression is fine: ::
2581
2582       [MkFoo 3 even, MkFoo 'c' isUpper] :: [Foo]
2583
2584 Here, ``(MkFoo 3 even)`` packages an integer with a function ``even``
2585 that maps an integer to ``Bool``; and ``MkFoo 'c'
2586 isUpper`` packages a character with a compatible function. These two
2587 things are each of type ``Foo`` and can be put in a list.
2588
2589 What can we do with a value of type ``Foo``? In particular, what
2590 happens when we pattern-match on ``MkFoo``? ::
2591
2592       f (MkFoo val fn) = ???
2593
2594 Since all we know about ``val`` and ``fn`` is that they are compatible,
2595 the only (useful) thing we can do with them is to apply ``fn`` to
2596 ``val`` to get a boolean. For example: ::
2597
2598       f :: Foo -> Bool
2599       f (MkFoo val fn) = fn val
2600
2601 What this allows us to do is to package heterogeneous values together
2602 with a bunch of functions that manipulate them, and then treat that
2603 collection of packages in a uniform manner. You can express quite a bit
2604 of object-oriented-like programming this way.
2605
2606 .. _existential:
2607
2608 Why existential?
2609 ~~~~~~~~~~~~~~~~
2610
2611 What has this to do with *existential* quantification? Simply that
2612 ``MkFoo`` has the (nearly) isomorphic type ::
2613
2614       MkFoo :: (exists a . (a, a -> Bool)) -> Foo
2615
2616 But Haskell programmers can safely think of the ordinary *universally*
2617 quantified type given above, thereby avoiding adding a new existential
2618 quantification construct.
2619
2620 .. _existential-with-context:
2621
2622 Existentials and type classes
2623 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2624
2625 An easy extension is to allow arbitrary contexts before the constructor.
2626 For example: ::
2627
2628     data Baz = forall a. Eq a => Baz1 a a
2629              | forall b. Show b => Baz2 b (b -> b)
2630
2631 The two constructors have the types you'd expect: ::
2632
2633     Baz1 :: forall a. Eq a => a -> a -> Baz
2634     Baz2 :: forall b. Show b => b -> (b -> b) -> Baz
2635
2636 But when pattern matching on ``Baz1`` the matched values can be compared
2637 for equality, and when pattern matching on ``Baz2`` the first matched
2638 value can be converted to a string (as well as applying the function to
2639 it). So this program is legal: ::
2640
2641       f :: Baz -> String
2642       f (Baz1 p q) | p == q    = "Yes"
2643                    | otherwise = "No"
2644       f (Baz2 v fn)            = show (fn v)
2645
2646 Operationally, in a dictionary-passing implementation, the constructors
2647 ``Baz1`` and ``Baz2`` must store the dictionaries for ``Eq`` and
2648 ``Show`` respectively, and extract it on pattern matching.
2649
2650 .. _existential-records:
2651
2652 Record Constructors
2653 ~~~~~~~~~~~~~~~~~~~
2654
2655 GHC allows existentials to be used with records syntax as well. For
2656 example: ::
2657
2658     data Counter a = forall self. NewCounter
2659         { _this    :: self
2660         , _inc     :: self -> self
2661         , _display :: self -> IO ()
2662         , tag      :: a
2663         }
2664
2665 Here ``tag`` is a public field, with a well-typed selector function
2666 ``tag :: Counter a -> a``. The ``self`` type is hidden from the outside;
2667 any attempt to apply ``_this``, ``_inc`` or ``_display`` as functions
2668 will raise a compile-time error. In other words, *GHC defines a record
2669 selector function only for fields whose type does not mention the
2670 existentially-quantified variables*. (This example used an underscore in
2671 the fields for which record selectors will not be defined, but that is
2672 only programming style; GHC ignores them.)
2673
2674 To make use of these hidden fields, we need to create some helper
2675 functions: ::
2676
2677     inc :: Counter a -> Counter a
2678     inc (NewCounter x i d t) = NewCounter
2679         { _this = i x, _inc = i, _display = d, tag = t }
2680
2681     display :: Counter a -> IO ()
2682     display NewCounter{ _this = x, _display = d } = d x
2683
2684 Now we can define counters with different underlying implementations: ::
2685
2686     counterA :: Counter String
2687     counterA = NewCounter
2688         { _this = 0, _inc = (1+), _display = print, tag = "A" }
2689
2690     counterB :: Counter String
2691     counterB = NewCounter
2692         { _this = "", _inc = ('#':), _display = putStrLn, tag = "B" }
2693
2694     main = do
2695         display (inc counterA)         -- prints "1"
2696         display (inc (inc counterB))   -- prints "##"
2697
2698 Record update syntax is supported for existentials (and GADTs): ::
2699
2700     setTag :: Counter a -> a -> Counter a
2701     setTag obj t = obj{ tag = t }
2702
2703 The rule for record update is this:
2704
2705     the types of the updated fields may mention only the universally-quantified
2706     type variables of the data constructor. For GADTs, the field may mention
2707     only types that appear as a simple type-variable argument in the
2708     constructor's result type.
2709
2710 For example: ::
2711
2712     data T a b where { T1 { f1::a, f2::b, f3::(b,c) } :: T a b } -- c is existential
2713     upd1 t x = t { f1=x }   -- OK:   upd1 :: T a b -> a' -> T a' b
2714     upd2 t x = t { f3=x }   -- BAD   (f3's type mentions c, which is
2715                             --        existentially quantified)
2716
2717     data G a b where { G1 { g1::a, g2::c } :: G a [c] }
2718     upd3 g x = g { g1=x }   -- OK:   upd3 :: G a b -> c -> G c b
2719     upd4 g x = g { g2=x }   -- BAD (f2's type mentions c, which is not a simple
2720                             --      type-variable argument in G1's result type)
2721
2722 Restrictions
2723 ~~~~~~~~~~~~
2724
2725 There are several restrictions on the ways in which existentially-quantified
2726 constructors can be used.
2727
2728 -  When pattern matching, each pattern match introduces a new, distinct,
2729    type for each existential type variable. These types cannot be
2730    unified with any other type, nor can they escape from the scope of
2731    the pattern match. For example, these fragments are incorrect: ::
2732
2733        f1 (MkFoo a f) = a
2734
2735    Here, the type bound by ``MkFoo`` "escapes", because ``a`` is the
2736    result of ``f1``. One way to see why this is wrong is to ask what
2737    type ``f1`` has: ::
2738
2739          f1 :: Foo -> a             -- Weird!
2740
2741    What is this "``a``" in the result type? Clearly we don't mean this: ::
2742
2743          f1 :: forall a. Foo -> a   -- Wrong!
2744
2745    The original program is just plain wrong. Here's another sort of
2746    error ::
2747
2748          f2 (Baz1 a b) (Baz1 p q) = a==q
2749
2750    It's ok to say ``a==b`` or ``p==q``, but ``a==q`` is wrong because it
2751    equates the two distinct types arising from the two ``Baz1``
2752    constructors.
2753
2754 -  You can't pattern-match on an existentially quantified constructor in
2755    a ``let`` or ``where`` group of bindings. So this is illegal: ::
2756
2757          f3 x = a==b where { Baz1 a b = x }
2758
2759    Instead, use a ``case`` expression: ::
2760
2761          f3 x = case x of Baz1 a b -> a==b
2762
2763    In general, you can only pattern-match on an existentially-quantified
2764    constructor in a ``case`` expression or in the patterns of a function
2765    definition. The reason for this restriction is really an
2766    implementation one. Type-checking binding groups is already a
2767    nightmare without existentials complicating the picture. Also an
2768    existential pattern binding at the top level of a module doesn't make
2769    sense, because it's not clear how to prevent the
2770    existentially-quantified type "escaping". So for now, there's a
2771    simple-to-state restriction. We'll see how annoying it is.
2772
2773 -  You can't use existential quantification for ``newtype``
2774    declarations. So this is illegal: ::
2775
2776          newtype T = forall a. Ord a => MkT a
2777
2778    Reason: a value of type ``T`` must be represented as a pair of a
2779    dictionary for ``Ord t`` and a value of type ``t``. That contradicts
2780    the idea that ``newtype`` should have no concrete representation. You
2781    can get just the same efficiency and effect by using ``data`` instead
2782    of ``newtype``. If there is no overloading involved, then there is
2783    more of a case for allowing an existentially-quantified ``newtype``,
2784    because the ``data`` version does carry an implementation cost, but
2785    single-field existentially quantified constructors aren't much use.
2786    So the simple restriction (no existential stuff on ``newtype``)
2787    stands, unless there are convincing reasons to change it.
2788
2789 -  You can't use ``deriving`` to define instances of a data type with
2790    existentially quantified data constructors. Reason: in most cases it
2791    would not make sense. For example:; ::
2792
2793        data T = forall a. MkT [a] deriving( Eq )
2794
2795    To derive ``Eq`` in the standard way we would need to have equality
2796    between the single component of two ``MkT`` constructors: ::
2797
2798        instance Eq T where
2799          (MkT a) == (MkT b) = ???
2800
2801    But ``a`` and ``b`` have distinct types, and so can't be compared.
2802    It's just about possible to imagine examples in which the derived
2803    instance would make sense, but it seems altogether simpler simply to
2804    prohibit such declarations. Define your own instances!
2805
2806 .. _gadt-style:
2807
2808 Declaring data types with explicit constructor signatures
2809 ---------------------------------------------------------
2810
2811 .. extension:: GADTSyntax
2812     :shortdesc: Enable generalised algebraic data type syntax.
2813
2814     :since: 7.2.1
2815
2816     Allow the use of GADT syntax in data type definitions (but not GADTs
2817     themselves; for this see :extension:`GADTs`)
2818
2819 When the ``GADTSyntax`` extension is enabled, GHC allows you to declare
2820 an algebraic data type by giving the type signatures of constructors
2821 explicitly. For example: ::
2822
2823       data Maybe a where
2824           Nothing :: Maybe a
2825           Just    :: a -> Maybe a
2826
2827 The form is called a "GADT-style declaration" because Generalised
2828 Algebraic Data Types, described in :ref:`gadt`, can only be declared
2829 using this form.
2830
2831 Notice that GADT-style syntax generalises existential types
2832 (:ref:`existential-quantification`). For example, these two declarations
2833 are equivalent: ::
2834
2835       data Foo = forall a. MkFoo a (a -> Bool)
2836       data Foo' where { MKFoo :: a -> (a->Bool) -> Foo' }
2837
2838 Any data type that can be declared in standard Haskell 98 syntax can
2839 also be declared using GADT-style syntax. The choice is largely
2840 stylistic, but GADT-style declarations differ in one important respect:
2841 they treat class constraints on the data constructors differently.
2842 Specifically, if the constructor is given a type-class context, that
2843 context is made available by pattern matching. For example: ::
2844
2845       data Set a where
2846         MkSet :: Eq a => [a] -> Set a
2847
2848       makeSet :: Eq a => [a] -> Set a
2849       makeSet xs = MkSet (nub xs)
2850
2851       insert :: a -> Set a -> Set a
2852       insert a (MkSet as) | a `elem` as = MkSet as
2853                           | otherwise   = MkSet (a:as)
2854
2855 A use of ``MkSet`` as a constructor (e.g. in the definition of
2856 ``makeSet``) gives rise to a ``(Eq a)`` constraint, as you would expect.
2857 The new feature is that pattern-matching on ``MkSet`` (as in the
2858 definition of ``insert``) makes *available* an ``(Eq a)`` context. In
2859 implementation terms, the ``MkSet`` constructor has a hidden field that
2860 stores the ``(Eq a)`` dictionary that is passed to ``MkSet``; so when
2861 pattern-matching that dictionary becomes available for the right-hand
2862 side of the match. In the example, the equality dictionary is used to
2863 satisfy the equality constraint generated by the call to ``elem``, so
2864 that the type of ``insert`` itself has no ``Eq`` constraint.
2865
2866 For example, one possible application is to reify dictionaries: ::
2867
2868        data NumInst a where
2869          MkNumInst :: Num a => NumInst a
2870
2871        intInst :: NumInst Int
2872        intInst = MkNumInst
2873
2874        plus :: NumInst a -> a -> a -> a
2875        plus MkNumInst p q = p + q
2876
2877 Here, a value of type ``NumInst a`` is equivalent to an explicit
2878 ``(Num a)`` dictionary.
2879
2880 All this applies to constructors declared using the syntax of
2881 :ref:`existential-with-context`. For example, the ``NumInst`` data type
2882 above could equivalently be declared like this: ::
2883
2884        data NumInst a
2885           = Num a => MkNumInst (NumInst a)
2886
2887 Notice that, unlike the situation when declaring an existential, there
2888 is no ``forall``, because the ``Num`` constrains the data type's
2889 universally quantified type variable ``a``. A constructor may have both
2890 universal and existential type variables: for example, the following two
2891 declarations are equivalent: ::
2892
2893        data T1 a
2894         = forall b. (Num a, Eq b) => MkT1 a b
2895        data T2 a where
2896         MkT2 :: (Num a, Eq b) => a -> b -> T2 a
2897
2898 All this behaviour contrasts with Haskell 98's peculiar treatment of
2899 contexts on a data type declaration (Section 4.2.1 of the Haskell 98
2900 Report). In Haskell 98 the definition ::
2901
2902       data Eq a => Set' a = MkSet' [a]
2903
2904 gives ``MkSet'`` the same type as ``MkSet`` above. But instead of
2905 *making available* an ``(Eq a)`` constraint, pattern-matching on
2906 ``MkSet'`` *requires* an ``(Eq a)`` constraint! GHC faithfully
2907 implements this behaviour, odd though it is. But for GADT-style
2908 declarations, GHC's behaviour is much more useful, as well as much more
2909 intuitive.
2910
2911 The rest of this section gives further details about GADT-style data
2912 type declarations.
2913
2914 -  The result type of each data constructor must begin with the type
2915    constructor being defined. If the result type of all constructors has
2916    the form ``T a1 ... an``, where ``a1 ... an`` are distinct type
2917    variables, then the data type is *ordinary*; otherwise is a
2918    *generalised* data type (:ref:`gadt`).
2919
2920 -  As with other type signatures, you can give a single signature for
2921    several data constructors. In this example we give a single signature
2922    for ``T1`` and ``T2``: ::
2923
2924          data T a where
2925            T1,T2 :: a -> T a
2926            T3 :: T a
2927
2928 -  The type signature of each constructor is independent, and is
2929    implicitly universally quantified as usual. In particular, the type
2930    variable(s) in the "``data T a where``" header have no scope, and
2931    different constructors may have different universally-quantified type
2932    variables: ::
2933
2934          data T a where        -- The 'a' has no scope
2935            T1,T2 :: b -> T b   -- Means forall b. b -> T b
2936            T3 :: T a           -- Means forall a. T a
2937
2938 -  A constructor signature may mention type class constraints, which can
2939    differ for different constructors. For example, this is fine: ::
2940
2941          data T a where
2942            T1 :: Eq b => b -> b -> T b
2943            T2 :: (Show c, Ix c) => c -> [c] -> T c
2944
2945    When pattern matching, these constraints are made available to
2946    discharge constraints in the body of the match. For example: ::
2947
2948          f :: T a -> String
2949          f (T1 x y) | x==y      = "yes"
2950                     | otherwise = "no"
2951          f (T2 a b)             = show a
2952
2953    Note that ``f`` is not overloaded; the ``Eq`` constraint arising from
2954    the use of ``==`` is discharged by the pattern match on ``T1`` and
2955    similarly the ``Show`` constraint arising from the use of ``show``.
2956
2957 -  Unlike a Haskell-98-style data type declaration, the type variable(s)
2958    in the "``data Set a where``" header have no scope. Indeed, one can
2959    write a kind signature instead: ::
2960
2961          data Set :: Type -> Type where ...
2962
2963    or even a mixture of the two: ::
2964
2965          data Bar a :: (Type -> Type) -> Type where ...
2966
2967    The type variables (if given) may be explicitly kinded, so we could
2968    also write the header for ``Foo`` like this: ::
2969
2970          data Bar a (b :: Type -> Type) where ...
2971
2972 -  You can use strictness annotations, in the obvious places in the
2973    constructor type: ::
2974
2975          data Term a where
2976              Lit    :: !Int -> Term Int
2977              If     :: Term Bool -> !(Term a) -> !(Term a) -> Term a
2978              Pair   :: Term a -> Term b -> Term (a,b)
2979
2980 -  You can use a ``deriving`` clause on a GADT-style data type
2981    declaration. For example, these two declarations are equivalent ::
2982
2983          data Maybe1 a where {
2984              Nothing1 :: Maybe1 a ;
2985              Just1    :: a -> Maybe1 a
2986            } deriving( Eq, Ord )
2987
2988          data Maybe2 a = Nothing2 | Just2 a
2989               deriving( Eq, Ord )
2990
2991 -  The type signature may have quantified type variables that do not
2992    appear in the result type: ::
2993
2994          data Foo where
2995             MkFoo :: a -> (a->Bool) -> Foo
2996             Nil   :: Foo
2997
2998    Here the type variable ``a`` does not appear in the result type of
2999    either constructor. Although it is universally quantified in the type
3000    of the constructor, such a type variable is often called
3001    "existential". Indeed, the above declaration declares precisely the
3002    same type as the ``data Foo`` in :ref:`existential-quantification`.
3003
3004    The type may contain a class context too, of course: ::
3005
3006          data Showable where
3007            MkShowable :: Show a => a -> Showable
3008
3009 -  You can use record syntax on a GADT-style data type declaration: ::
3010
3011          data Person where
3012              Adult :: { name :: String, children :: [Person] } -> Person
3013              Child :: Show a => { name :: !String, funny :: a } -> Person
3014
3015    As usual, for every constructor that has a field ``f``, the type of
3016    field ``f`` must be the same (modulo alpha conversion). The ``Child``
3017    constructor above shows that the signature may have a context,
3018    existentially-quantified variables, and strictness annotations, just
3019    as in the non-record case. (NB: the "type" that follows the
3020    double-colon is not really a type, because of the record syntax and
3021    strictness annotations. A "type" of this form can appear only in a
3022    constructor signature.)
3023
3024 -  Record updates are allowed with GADT-style declarations, only fields
3025    that have the following property: the type of the field mentions no
3026    existential type variables.
3027
3028 -  As in the case of existentials declared using the Haskell-98-like
3029    record syntax (:ref:`existential-records`), record-selector functions
3030    are generated only for those fields that have well-typed selectors.
3031    Here is the example of that section, in GADT-style syntax: ::
3032
3033        data Counter a where
3034            NewCounter :: { _this    :: self
3035                          , _inc     :: self -> self
3036                          , _display :: self -> IO ()
3037                          , tag      :: a
3038                          } -> Counter a
3039
3040    As before, only one selector function is generated here, that for
3041    ``tag``. Nevertheless, you can still use all the field names in
3042    pattern matching and record construction.
3043
3044 -  In a GADT-style data type declaration there is no obvious way to
3045    specify that a data constructor should be infix, which makes a
3046    difference if you derive ``Show`` for the type. (Data constructors
3047    declared infix are displayed infix by the derived ``show``.) So GHC
3048    implements the following design: a data constructor declared in a
3049    GADT-style data type declaration is displayed infix by ``Show`` iff
3050    (a) it is an operator symbol, (b) it has two arguments, (c) it has a
3051    programmer-supplied fixity declaration. For example
3052
3053    ::
3054
3055           infix 6 (:--:)
3056           data T a where
3057             (:--:) :: Int -> Bool -> T Int
3058
3059 .. _gadt:
3060
3061 Generalised Algebraic Data Types (GADTs)
3062 ----------------------------------------
3063
3064 .. extension:: GADTs
3065     :shortdesc: Enable generalised algebraic data types.
3066         Implies :extension:`GADTSyntax` and :extension:`MonoLocalBinds`.
3067
3068     :implies: :extension:`MonoLocalBinds`, :extension:`GADTSyntax`
3069     :since: 6.8.1
3070
3071     Allow use of Generalised Algebraic Data Types (GADTs).
3072
3073 Generalised Algebraic Data Types generalise ordinary algebraic data
3074 types by allowing constructors to have richer return types. Here is an
3075 example: ::
3076
3077       data Term a where
3078           Lit    :: Int -> Term Int
3079           Succ   :: Term Int -> Term Int
3080           IsZero :: Term Int -> Term Bool
3081           If     :: Term Bool -> Term a -> Term a -> Term a
3082           Pair   :: Term a -> Term b -> Term (a,b)
3083
3084 Notice that the return type of the constructors is not always
3085 ``Term a``, as is the case with ordinary data types. This generality
3086 allows us to write a well-typed ``eval`` function for these ``Terms``: ::
3087
3088       eval :: Term a -> a
3089       eval (Lit i)      = i
3090       eval (Succ t)     = 1 + eval t
3091       eval (IsZero t)   = eval t == 0
3092       eval (If b e1 e2) = if eval b then eval e1 else eval e2
3093       eval (Pair e1 e2) = (eval e1, eval e2)
3094
3095 The key point about GADTs is that *pattern matching causes type
3096 refinement*. For example, in the right hand side of the equation ::
3097
3098       eval :: Term a -> a
3099       eval (Lit i) =  ...
3100
3101 the type ``a`` is refined to ``Int``. That's the whole point! A precise
3102 specification of the type rules is beyond what this user manual aspires
3103 to, but the design closely follows that described in the paper `Simple
3104 unification-based type inference for
3105 GADTs <http://research.microsoft.com/%7Esimonpj/papers/gadt/>`__, (ICFP
3106 2006). The general principle is this: *type refinement is only carried
3107 out based on user-supplied type annotations*. So if no type signature is
3108 supplied for ``eval``, no type refinement happens, and lots of obscure
3109 error messages will occur. However, the refinement is quite general. For
3110 example, if we had: ::
3111
3112       eval :: Term a -> a -> a
3113       eval (Lit i) j =  i+j
3114
3115 the pattern match causes the type ``a`` to be refined to ``Int``
3116 (because of the type of the constructor ``Lit``), and that refinement
3117 also applies to the type of ``j``, and the result type of the ``case``
3118 expression. Hence the addition ``i+j`` is legal.
3119
3120 These and many other examples are given in papers by Hongwei Xi, and Tim
3121 Sheard. There is a longer introduction `on the
3122 wiki <http://www.haskell.org/haskellwiki/GADT>`__, and Ralf Hinze's `Fun
3123 with phantom
3124 types <http://www.cs.ox.ac.uk/ralf.hinze/publications/With.pdf>`__ also
3125 has a number of examples. Note that papers may use different notation to
3126 that implemented in GHC.
3127
3128 The rest of this section outlines the extensions to GHC that support
3129 GADTs. The extension is enabled with :extension:`GADTs`. The :extension:`GADTs` extension
3130 also sets :extension:`GADTSyntax` and :extension:`MonoLocalBinds`.
3131
3132 -  A GADT can only be declared using GADT-style syntax
3133    (:ref:`gadt-style`); the old Haskell 98 syntax for data declarations
3134    always declares an ordinary data type. The result type of each
3135    constructor must begin with the type constructor being defined, but
3136    for a GADT the arguments to the type constructor can be arbitrary
3137    monotypes. For example, in the ``Term`` data type above, the type of
3138    each constructor must end with ``Term ty``, but the ``ty`` need not
3139    be a type variable (e.g. the ``Lit`` constructor).
3140
3141 -  It is permitted to declare an ordinary algebraic data type using
3142    GADT-style syntax. What makes a GADT into a GADT is not the syntax,
3143    but rather the presence of data constructors whose result type is not
3144    just ``T a b``.
3145
3146 -  You cannot use a ``deriving`` clause for a GADT; only for an ordinary
3147    data type.
3148
3149 -  As mentioned in :ref:`gadt-style`, record syntax is supported. For
3150    example:
3151
3152    ::
3153
3154          data Term a where
3155              Lit    :: { val  :: Int }      -> Term Int
3156              Succ   :: { num  :: Term Int } -> Term Int
3157              Pred   :: { num  :: Term Int } -> Term Int
3158              IsZero :: { arg  :: Term Int } -> Term Bool
3159              Pair   :: { arg1 :: Term a
3160                        , arg2 :: Term b
3161                        }                    -> Term (a,b)
3162              If     :: { cnd  :: Term Bool
3163                        , tru  :: Term a
3164                        , fls  :: Term a
3165                        }                    -> Term a
3166
3167    However, for GADTs there is the following additional constraint:
3168    every constructor that has a field ``f`` must have the same result
3169    type (modulo alpha conversion) Hence, in the above example, we cannot
3170    merge the ``num`` and ``arg`` fields above into a single name.
3171    Although their field types are both ``Term Int``, their selector
3172    functions actually have different types:
3173
3174    ::
3175
3176          num :: Term Int -> Term Int
3177          arg :: Term Bool -> Term Int
3178
3179 -  When pattern-matching against data constructors drawn from a GADT,
3180    for example in a ``case`` expression, the following rules apply:
3181
3182    -  The type of the scrutinee must be rigid.
3183
3184    -  The type of the entire ``case`` expression must be rigid.
3185
3186    -  The type of any free variable mentioned in any of the ``case``
3187       alternatives must be rigid.
3188
3189    A type is "rigid" if it is completely known to the compiler at its
3190    binding site. The easiest way to ensure that a variable a rigid type
3191    is to give it a type signature. For more precise details see `Simple
3192    unification-based type inference for
3193    GADTs <http://research.microsoft.com/%7Esimonpj/papers/gadt/>`__. The
3194    criteria implemented by GHC are given in the Appendix.
3195
3196 .. _record-system-extensions:
3197
3198 Extensions to the record system
3199 ===============================
3200
3201 .. _traditional-record-syntax:
3202
3203 Traditional record syntax
3204 -------------------------
3205
3206 .. extension:: NoTraditionalRecordSyntax
3207     :shortdesc: Disable support for traditional record syntax
3208         (as supported by Haskell 98) ``C {f = x}``
3209
3210     :since: 7.4.1
3211
3212     Disallow use of record syntax.
3213
3214 Traditional record syntax, such as ``C {f = x}``, is enabled by default.
3215 To disable it, you can use the :extension:`NoTraditionalRecordSyntax` extension.
3216
3217 .. _disambiguate-fields:
3218
3219 Record field disambiguation
3220 ---------------------------
3221
3222 .. extension:: DisambiguateRecordFields
3223     :shortdesc: Enable record field disambiguation.
3224         Implied by :extension:`RecordWildCards`.
3225
3226     :since: 6.8.1
3227
3228     Allow the compiler to automatically choose between identically-named
3229     record selectors based on type (if the choice is unambiguous).
3230
3231 In record construction and record pattern matching it is entirely
3232 unambiguous which field is referred to, even if there are two different
3233 data types in scope with a common field name. For example:
3234
3235 ::
3236
3237     module M where
3238       data S = MkS { x :: Int, y :: Bool }
3239
3240     module Foo where
3241       import M
3242
3243       data T = MkT { x :: Int }
3244
3245       ok1 (MkS { x = n }) = n+1   -- Unambiguous
3246       ok2 n = MkT { x = n+1 }     -- Unambiguous
3247
3248       bad1 k = k { x = 3 }        -- Ambiguous
3249       bad2 k = x k                -- Ambiguous
3250
3251 Even though there are two ``x``'s in scope, it is clear that the ``x``
3252 in the pattern in the definition of ``ok1`` can only mean the field
3253 ``x`` from type ``S``. Similarly for the function ``ok2``. However, in
3254 the record update in ``bad1`` and the record selection in ``bad2`` it is
3255 not clear which of the two types is intended.
3256
3257 Haskell 98 regards all four as ambiguous, but with the
3258 :extension:`DisambiguateRecordFields` extension, GHC will accept the former two. The
3259 rules are precisely the same as those for instance declarations in
3260 Haskell 98, where the method names on the left-hand side of the method
3261 bindings in an instance declaration refer unambiguously to the method of
3262 that class (provided they are in scope at all), even if there are other
3263 variables in scope with the same name. This reduces the clutter of
3264 qualified names when you import two records from different modules that
3265 use the same field name.
3266
3267 Some details:
3268
3269 -  Field disambiguation can be combined with punning (see
3270    :ref:`record-puns`). For example: ::
3271
3272        module Foo where
3273          import M
3274          x=True
3275          ok3 (MkS { x }) = x+1   -- Uses both disambiguation and punning
3276
3277 -  With :extension:`DisambiguateRecordFields` you can use *unqualified* field
3278    names even if the corresponding selector is only in scope *qualified*
3279    For example, assuming the same module ``M`` as in our earlier
3280    example, this is legal: ::
3281
3282        module Foo where
3283          import qualified M    -- Note qualified
3284
3285          ok4 (M.MkS { x = n }) = n+1   -- Unambiguous
3286
3287    Since the constructor ``MkS`` is only in scope qualified, you must
3288    name it ``M.MkS``, but the field ``x`` does not need to be qualified
3289    even though ``M.x`` is in scope but ``x`` is not (In effect, it is
3290    qualified by the constructor).
3291
3292 .. _duplicate-record-fields:
3293
3294 Duplicate record fields
3295 -----------------------
3296
3297 .. extension:: DuplicateRecordFields
3298     :shortdesc: Allow definition of record types with identically-named fields.
3299
3300     :implies: :extension:`DisambiguateRecordFields`
3301     :since: 8.0.1
3302
3303     Allow definition of record types with identically-named fields.
3304
3305 Going beyond :extension:`DisambiguateRecordFields` (see :ref:`disambiguate-fields`),
3306 the :extension:`DuplicateRecordFields` extension allows multiple datatypes to be
3307 declared using the same field names in a single module. For example, it allows
3308 this: ::
3309
3310     module M where
3311       data S = MkS { x :: Int }
3312       data T = MkT { x :: Bool }
3313
3314 Uses of fields that are always unambiguous because they mention the constructor,
3315 including construction and pattern-matching, may freely use duplicated field
3316 names. For example, the following are permitted (just as with
3317 :extension:`DisambiguateRecordFields`): ::
3318
3319     s = MkS { x = 3 }
3320
3321     f (MkT { x = b }) = b
3322
3323 Field names used as selector functions or in record updates must be unambiguous,
3324 either because there is only one such field in scope, or because a type
3325 signature is supplied, as described in the following sections.
3326
3327 Selector functions
3328 ~~~~~~~~~~~~~~~~~~
3329
3330 Fields may be used as selector functions only if they are unambiguous, so this
3331 is still not allowed if both ``S(x)`` and ``T(x)`` are in scope: ::
3332
3333     bad r = x r
3334
3335 An ambiguous selector may be disambiguated by the type being "pushed down" to
3336 the occurrence of the selector (see :ref:`higher-rank-type-inference` for more
3337 details on what "pushed down" means). For example, the following are permitted: ::
3338
3339     ok1 = x :: S -> Int
3340
3341     ok2 :: S -> Int
3342     ok2 = x
3343
3344     ok3 = k x -- assuming we already have k :: (S -> Int) -> _
3345
3346 In addition, the datatype that is meant may be given as a type signature on the
3347 argument to the selector: ::
3348
3349     ok4 s = x (s :: S)
3350
3351 However, we do not infer the type of the argument to determine the datatype, or
3352 have any way of deferring the choice to the constraint solver. Thus the
3353 following is ambiguous: ::
3354
3355     bad :: S -> Int
3356     bad s = x s
3357
3358 Even though a field label is duplicated in its defining module, it may be
3359 possible to use the selector unambiguously elsewhere. For example, another
3360 module could import ``S(x)`` but not ``T(x)``, and then use ``x`` unambiguously.
3361
3362 Record updates
3363 ~~~~~~~~~~~~~~
3364
3365 In a record update such as ``e { x = 1 }``, if there are multiple ``x`` fields
3366 in scope, then the type of the context must fix which record datatype is
3367 intended, or a type annotation must be supplied. Consider the following
3368 definitions: ::
3369
3370     data S = MkS { foo :: Int }
3371     data T = MkT { foo :: Int, bar :: Int }
3372     data U = MkU { bar :: Int, baz :: Int }
3373
3374 Without :extension:`DuplicateRecordFields`, an update mentioning ``foo`` will always be
3375 ambiguous if all these definitions were in scope. When the extension is enabled,
3376 there are several options for disambiguating updates:
3377
3378 - Check for types that have all the fields being updated. For example: ::
3379
3380       f x = x { foo = 3, bar = 2 }
3381
3382   Here ``f`` must be updating ``T`` because neither ``S`` nor ``U`` have both
3383   fields.
3384
3385 - Use the type being pushed in to the record update, as in the following: ::
3386
3387       g1 :: T -> T
3388       g1 x = x { foo = 3 }
3389
3390       g2 x = x { foo = 3 } :: T
3391
3392       g3 = k (x { foo = 3 }) -- assuming we already have k :: T -> _
3393
3394 - Use an explicit type signature on the record expression, as in: ::
3395
3396       h x = (x :: T) { foo = 3 }
3397
3398 The type of the expression being updated will not be inferred, and no
3399 constraint-solving will be performed, so the following will be rejected as
3400 ambiguous: ::
3401
3402     let x :: T
3403         x = blah
3404     in x { foo = 3 }
3405
3406     \x -> [x { foo = 3 },  blah :: T ]
3407
3408     \ (x :: T) -> x { foo = 3 }
3409
3410 Import and export of record fields
3411 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
3412
3413 When :extension:`DuplicateRecordFields` is enabled, an ambiguous field must be exported
3414 as part of its datatype, rather than at the top level. For example, the
3415 following is legal: ::
3416
3417     module M (S(x), T(..)) where
3418       data S = MkS { x :: Int }
3419       data T = MkT { x :: Bool }
3420
3421 However, this would not be permitted, because ``x`` is ambiguous: ::
3422
3423     module M (x) where ...
3424
3425 Similar restrictions apply on import.
3426
3427 .. _record-puns:
3428
3429 Record puns
3430 -----------
3431
3432 .. extension:: NamedFieldPuns
3433     :shortdesc: Enable record puns.
3434
3435     :since: 6.10.1
3436
3437     Allow use of record puns.
3438
3439 Record puns are enabled by the language extension :extension:`NamedFieldPuns`.
3440
3441 When using records, it is common to write a pattern that binds a
3442 variable with the same name as a record field, such as: ::
3443
3444     data C = C {a :: Int}
3445     f (C {a = a}) = a
3446
3447 Record punning permits the variable name to be elided, so one can simply
3448 write ::
3449
3450     f (C {a}) = a
3451
3452 to mean the same pattern as above. That is, in a record pattern, the
3453 pattern ``a`` expands into the pattern ``a = a`` for the same name
3454 ``a``.
3455
3456 Note that:
3457
3458 -  Record punning can also be used in an expression, writing, for
3459    example, ::
3460
3461        let a = 1 in C {a}
3462
3463    instead of ::
3464
3465        let a = 1 in C {a = a}
3466
3467    The expansion is purely syntactic, so the expanded right-hand side
3468    expression refers to the nearest enclosing variable that is spelled
3469    the same as the field name.
3470
3471 -  Puns and other patterns can be mixed in the same record: ::
3472
3473        data C = C {a :: Int, b :: Int}
3474        f (C {a, b = 4}) = a
3475
3476 -  Puns can be used wherever record patterns occur (e.g. in ``let``
3477    bindings or at the top-level).
3478
3479 -  A pun on a qualified field name is expanded by stripping off the
3480    module qualifier. For example: ::
3481
3482        f (C {M.a}) = a
3483
3484    means ::
3485
3486        f (M.C {M.a = a}) = a
3487
3488    (This is useful if the field selector ``a`` for constructor ``M.C``
3489    is only in scope in qualified form.)
3490
3491 .. _record-wildcards:
3492
3493 Record wildcards
3494 ----------------
3495
3496 .. extension:: RecordWildCards
3497     :shortdesc: Enable record wildcards.
3498         Implies :extension:`DisambiguateRecordFields`.
3499
3500     :implies: :extension:`DisambiguateRecordFields`.
3501     :since: 6.8.1
3502
3503     Allow the use of wildcards in record construction and pattern matching.
3504
3505 Record wildcards are enabled by the language extension :extension:`RecordWildCards`. This
3506 exension implies :extension:`DisambiguateRecordFields`.
3507
3508 For records with many fields, it can be tiresome to write out each field
3509 individually in a record pattern, as in ::
3510
3511     data C = C {a :: Int, b :: Int, c :: Int, d :: Int}
3512     f (C {a = 1, b = b, c = c, d = d}) = b + c + d
3513
3514 Record wildcard syntax permits a "``..``" in a record pattern, where
3515 each elided field ``f`` is replaced by the pattern ``f = f``. For
3516 example, the above pattern can be written as ::
3517
3518     f (C {a = 1, ..}) = b + c + d
3519
3520 More details:
3521
3522 -  Record wildcards in patterns can be mixed with other patterns,
3523    including puns (:ref:`record-puns`); for example, in a pattern
3524    ``(C {a = 1, b, ..})``. Additionally, record wildcards can be used
3525    wherever record patterns occur, including in ``let`` bindings and at
3526    the top-level. For example, the top-level binding ::
3527
3528        C {a = 1, ..} = e
3529
3530    defines ``b``, ``c``, and ``d``.
3531
3532 -  Record wildcards can also be used in an expression, when constructing
3533    a record. For example, ::
3534
3535        let {a = 1; b = 2; c = 3; d = 4} in C {..}
3536
3537    in place of ::
3538
3539        let {a = 1; b = 2; c = 3; d = 4} in C {a=a, b=b, c=c, d=d}
3540
3541    The expansion is purely syntactic, so the record wildcard expression
3542    refers to the nearest enclosing variables that are spelled the same
3543    as the omitted field names.
3544
3545 -  For both pattern and expression wildcards, the "``..``" expands to
3546    the missing *in-scope* record fields. Specifically the expansion of
3547    "``C {..}``" includes ``f`` if and only if:
3548
3549    -  ``f`` is a record field of constructor ``C``.
3550
3551    -  The record field ``f`` is in scope somehow (either qualified or
3552       unqualified).
3553
3554    These rules restrict record wildcards to the situations in which the
3555    user could have written the expanded version. For example ::
3556
3557        module M where
3558          data R = R { a,b,c :: Int }
3559        module X where
3560          import M( R(R,a,c) )
3561          f a b = R { .. }
3562
3563    The ``R{..}`` expands to ``R{a=a}``, omitting ``b`` since the
3564    record field is not in scope, and omitting ``c`` since the variable
3565    ``c`` is not in scope (apart from the binding of the record selector
3566    ``c``, of course).
3567
3568 -  When record wildcards are use in record construction, a field ``f``
3569    is initialised only if ``f`` is in scope,
3570    and is not imported or bound at top level.
3571    For example, ``f`` can be bound by an enclosing pattern match or
3572    let/where-binding. For example ::
3573
3574         module M where
3575           import A( a )
3576
3577           data R = R { a,b,c,d :: Int }
3578
3579           c = 3 :: Int
3580
3581           f b = R { .. }  -- Expands to R { b = b, d = d }
3582             where
3583               d = b+1
3584
3585    Here, ``a`` is imported, and ``c`` is bound at top level, so neither
3586    contribute to the expansion of the "``..``".
3587    The motivation here is that it should be
3588    easy for the reader to figure out what the "``..``" expands to.
3589
3590 -  Record wildcards cannot be used (a) in a record update construct, and
3591    (b) for data constructors that are not declared with record fields.
3592    For example: ::
3593
3594        f x = x { v=True, .. }   -- Illegal (a)
3595
3596        data T = MkT Int Bool
3597        g = MkT { .. }           -- Illegal (b)
3598        h (MkT { .. }) = True    -- Illegal (b)
3599
3600
3601 .. _record-field-selector-polymorphism:
3602
3603 Record field selector polymorphism
3604 ----------------------------------
3605
3606 The module :base-ref:`GHC.Records.` defines the following: ::
3607
3608   class HasField (x :: k) r a | x r -> a where
3609     getField :: r -> a
3610
3611 A ``HasField x r a`` constraint represents the fact that ``x`` is a
3612 field of type ``a`` belonging to a record type ``r``.  The
3613 ``getField`` method gives the record selector function.
3614
3615 This allows definitions that are polymorphic over record types with a specified
3616 field.  For example, the following works with any record type that has a field
3617 ``name :: String``: ::
3618
3619   foo :: HasField "name" r String => r -> String
3620   foo r = reverse (getField @"name" r)
3621
3622 ``HasField`` is a magic built-in typeclass (similar to ``Coercible``, for
3623 example).  It is given special treatment by the constraint solver (see
3624 :ref:`solving-hasfield-constraints`).  Users may define their own instances of
3625 ``HasField`` also (see :ref:`virtual-record-fields`).
3626
3627 .. _solving-hasfield-constraints:
3628
3629 Solving HasField constraints
3630 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
3631
3632 If the constraint solver encounters a constraint ``HasField x r a``
3633 where ``r`` is a concrete datatype with a field ``x`` in scope, it
3634 will automatically solve the constraint using the field selector as
3635 the dictionary, unifying ``a`` with the type of the field if
3636 necessary.  This happens irrespective of which extensions are enabled.
3637
3638 For example, if the following datatype is in scope ::
3639
3640   data Person = Person { name :: String }
3641
3642 the end result is rather like having an instance ::
3643
3644   instance HasField "name" Person String where
3645     getField = name
3646
3647 except that this instance is not actually generated anywhere, rather
3648 the constraint is solved directly by the constraint solver.
3649
3650 A field must be in scope for the corresponding ``HasField`` constraint
3651 to be solved.  This retains the existing representation hiding
3652 mechanism, whereby a module may choose not to export a field,
3653 preventing client modules from accessing or updating it directly.
3654
3655 Solving ``HasField`` constraints depends on the field selector functions that
3656 are generated for each datatype definition:
3657
3658 -  If a record field does not have a selector function because its type would allow
3659    an existential variable to escape, the corresponding ``HasField`` constraint
3660    will not be solved.  For example, ::
3661
3662      {-# LANGUAGE ExistentialQuantification #-}
3663      data Exists t = forall x . MkExists { unExists :: t x }
3664
3665    does not give rise to a selector ``unExists :: Exists t -> t x`` and we will not
3666    solve ``HasField "unExists" (Exists t) a`` automatically.
3667
3668 -  If a record field has a polymorphic type (and hence the selector function is
3669    higher-rank), the corresponding ``HasField`` constraint will not be solved,
3670    because doing so would violate the functional dependency on ``HasField`` and/or
3671    require impredicativity.  For example, ::
3672
3673      {-# LANGUAGE RankNTypes #-}
3674      data Higher = MkHigher { unHigher :: forall t . t -> t }
3675
3676    gives rise to a selector ``unHigher :: Higher -> (forall t . t -> t)`` but does
3677    not lead to solution of the constraint ``HasField "unHigher" Higher a``.
3678
3679 -  A record GADT may have a restricted type for a selector function, which may lead
3680    to additional unification when solving ``HasField`` constraints.  For example, ::
3681
3682      {-# LANGUAGE GADTs #-}
3683      data Gadt t where
3684        MkGadt :: { unGadt :: Maybe v } -> Gadt [v]
3685
3686    gives rise to a selector ``unGadt :: Gadt [v] -> Maybe v``, so the solver will reduce
3687    the constraint ``HasField "unGadt" (Gadt t) b`` by unifying ``t ~ [v]`` and
3688    ``b ~ Maybe v`` for some fresh metavariable ``v``, rather as if we had an instance ::
3689
3690      instance (t ~ [v], b ~ Maybe v) => HasField "unGadt" (Gadt t) b
3691
3692 -  If a record type has an old-fashioned datatype context, the ``HasField``
3693    constraint will be reduced to solving the constraints from the context.
3694    For example, ::
3695
3696      {-# LANGUAGE DatatypeContexts #-}
3697      data Eq a => Silly a = MkSilly { unSilly :: a }
3698
3699    gives rise to a selector ``unSilly :: Eq a => Silly a -> a``, so
3700    the solver will reduce the constraint ``HasField "unSilly" (Silly a) b`` to
3701    ``Eq a`` (and unify ``a`` with ``b``), rather as if we had an instance ::
3702
3703      instance (Eq a, a ~ b) => HasField "unSilly" (Silly a) b
3704
3705 .. _virtual-record-fields:
3706
3707 Virtual record fields
3708 ~~~~~~~~~~~~~~~~~~~~~
3709
3710 Users may define their own instances of ``HasField``, provided they do
3711 not conflict with the built-in constraint solving behaviour.  This
3712 allows "virtual" record fields to be defined for datatypes that do not
3713 otherwise have them.
3714
3715 For example, this instance would make the ``name`` field of ``Person``
3716 accessible using ``#fullname`` as well: ::
3717
3718   instance HasField "fullname" Person String where
3719     getField = name
3720
3721 More substantially, an anonymous records library could provide
3722 ``HasField`` instances for its anonymous records, and thus be
3723 compatible with the polymorphic record selectors introduced by this
3724 proposal.  For example, something like this makes it possible to use
3725 ``getField`` to access ``Record`` values with the appropriate
3726 string in the type-level list of fields: ::
3727
3728   data Record (xs :: [(k, Type)]) where
3729     Nil  :: Record '[]
3730     Cons :: Proxy x -> a -> Record xs -> Record ('(x, a) ': xs)
3731
3732   instance HasField x (Record ('(x, a) ': xs)) a where
3733     getField (Cons _ v _) = v
3734   instance HasField x (Record xs) a => HasField x (Record ('(y, b) ': xs)) a where
3735     getField (Cons _ _ r) = getField @x r
3736
3737   r :: Record '[ '("name", String) ]
3738   r = Cons Proxy "R" Nil)
3739
3740   x = getField @"name" r
3741
3742 Since representations such as this can support field labels with kinds other
3743 than ``Symbol``, the ``HasField`` class is poly-kinded (even though the built-in
3744 constraint solving works only at kind ``Symbol``).  In particular, this allows
3745 users to declare scoped field labels such as in the following example: ::
3746
3747   data PersonFields = Name
3748
3749   s :: Record '[ '(Name, String) ]
3750   s = Cons Proxy "S" Nil
3751
3752   y = getField @Name s
3753
3754 In order to avoid conflicting with the built-in constraint solving,
3755 the following user-defined ``HasField`` instances are prohibited (in
3756 addition to the usual rules, such as the prohibition on type
3757 families appearing in instance heads):
3758
3759 -  ``HasField _ r _`` where ``r`` is a variable;
3760
3761 -  ``HasField _ (T ...) _`` if ``T`` is a data family (because it
3762    might have fields introduced later, using data instance declarations);
3763
3764 -  ``HasField x (T ...) _`` if ``x`` is a variable and ``T`` has any
3765    fields at all (but this instance is permitted if ``T`` has no fields);
3766
3767 -  ``HasField "foo" (T ...) _`` if ``T`` has a field ``foo`` (but this
3768    instance is permitted if it does not).
3769
3770 If a field has a higher-rank or existential type, the corresponding ``HasField``
3771 constraint will not be solved automatically (as described above), but in the
3772 interests of simplicity we do not permit users to define their own instances
3773 either.  If a field is not in scope, the corresponding instance is still
3774 prohibited, to avoid conflicts in downstream modules.
3775
3776
3777 .. _deriving:
3778
3779 Extensions to the "deriving" mechanism
3780 ======================================
3781
3782 Haskell 98 allows the programmer to add a deriving clause to a data type
3783 declaration, to generate a standard instance declaration for specified class.
3784 GHC extends this mechanism along several axes:
3785
3786 * The derivation mechanism can be used separtely from the data type
3787   declaration, using the `standalone deriving mechanism
3788   <#stand-alone-deriving>`__.
3789
3790 * In Haskell 98, the only derivable classes are ``Eq``,
3791   ``Ord``, ``Enum``, ``Ix``, ``Bounded``, ``Read``, and ``Show``. `Various
3792   language extensions <#deriving-extra>`__ extend this list.
3793
3794 * Besides the stock approach to deriving instances by generating all method
3795   definitions, GHC supports two additional deriving strategies, which can
3796   derive arbitrary classes:
3797
3798   * `Generalised newtype deriving <#newtype-deriving>`__ for newtypes and
3799   * `deriving any class <#derive-any-class>`__ using an empty instance
3800     declaration.
3801
3802   The user can optionally declare the desired `deriving strategy
3803   <#deriving-stragies>`__, especially if the compiler chooses the wrong
3804   one `by default <#default-deriving-strategy>`__.
3805
3806 .. _empty-data-deriving:
3807
3808 Deriving instances for empty data types
3809 ---------------------------------------
3810
3811 .. ghc-flag:: -XEmptyDataDeriving
3812     :shortdesc: Allow deriving instances of standard type classes for
3813                 empty data types.
3814     :type: dynamic
3815     :reverse: -XNoEmptyDataDeriving
3816     :category:
3817
3818     :since: 8.4.1
3819
3820     Allow deriving instances of standard type classes for empty data types.
3821
3822 One can write data types with no constructors using the
3823 :ghc-flag:`-XEmptyDataDecls` flag (see :ref:`nullary-types`), which is on by
3824 default in Haskell 2010. What is not on by default is the ability to derive
3825 type class instances for these types. This ability is enabled through use of
3826 the :ghc-flag:`-XEmptyDataDeriving` flag. For instance, this lets one write: ::
3827
3828     data Empty deriving (Eq, Ord, Read, Show)
3829
3830 This would generate the following instances: ::
3831
3832     instance Eq Empty where
3833       _ == _ = True
3834
3835     instance Ord Empty where
3836       compare _ _ = EQ
3837
3838     instance Read Empty where
3839       readPrec = pfail
3840
3841     instance Show Empty where
3842       showsPrec _ x = case x of {}
3843
3844 The :ghc-flag:`-XEmptyDataDeriving` flag is only required to enable deriving
3845 of these four "standard" type classes (which are mentioned in the Haskell
3846 Report). Other extensions to the ``deriving`` mechanism, which are explained
3847 below in greater detail, do not require :ghc-flag:`-XEmptyDataDeriving` to be
3848 used in conjunction with empty data types. These include:
3849
3850 * :ghc-flag:`-XStandaloneDeriving` (see :ref:`stand-alone-deriving`)
3851 * Type classes which require their own extensions to be enabled to be derived,
3852   such as :ghc-flag:`-XDeriveFunctor` (see :ref:`deriving-extra`)
3853 * :ghc-flag:`-XDeriveAnyClass` (see :ref:`derive-any-class`)
3854
3855 .. _deriving-inferred:
3856
3857 Inferred context for deriving clauses
3858 -------------------------------------
3859
3860 The Haskell Report is vague about exactly when a ``deriving`` clause is
3861 legal. For example: ::
3862
3863       data T0 f a = MkT0 a         deriving( Eq )
3864       data T1 f a = MkT1 (f a)     deriving( Eq )
3865       data T2 f a = MkT2 (f (f a)) deriving( Eq )
3866
3867 The natural generated ``Eq`` code would result in these instance
3868 declarations: ::
3869
3870       instance Eq a         => Eq (T0 f a) where ...
3871       instance Eq (f a)     => Eq (T1 f a) where ...
3872       instance Eq (f (f a)) => Eq (T2 f a) where ...
3873
3874 The first of these is obviously fine. The second is still fine, although
3875 less obviously. The third is not Haskell 98, and risks losing
3876 termination of instances.
3877
3878 GHC takes a conservative position: it accepts the first two, but not the
3879 third. The rule is this: each constraint in the inferred instance
3880 context must consist only of type variables, with no repetitions.
3881
3882 This rule is applied regardless of flags. If you want a more exotic
3883 context, you can write it yourself, using the `standalone deriving
3884 mechanism <#stand-alone-deriving>`__.
3885
3886 .. _stand-alone-deriving:
3887
3888 Stand-alone deriving declarations
3889 ---------------------------------
3890
3891 .. extension:: StandaloneDeriving
3892     :shortdesc: Enable standalone deriving.
3893
3894     :since: 6.8.1
3895
3896     Allow the use of stand-alone ``deriving`` declarations.
3897
3898 GHC allows stand-alone ``deriving`` declarations, enabled by
3899 :extension:`StandaloneDeriving`: ::
3900
3901       data Foo a = Bar a | Baz String
3902
3903       deriving instance Eq a => Eq (Foo a)
3904
3905 The syntax is identical to that of an ordinary instance declaration
3906 apart from (a) the keyword ``deriving``, and (b) the absence of the
3907 ``where`` part.
3908
3909 However, standalone deriving differs from a ``deriving`` clause in a
3910 number of important ways:
3911
3912 -  The standalone deriving declaration does not need to be in the same
3913    module as the data type declaration. (But be aware of the dangers of
3914    orphan instances (:ref:`orphan-modules`).
3915
3916 -  In most cases, you must supply an explicit context (in the example the
3917    context is ``(Eq a)``), exactly as you would in an ordinary instance
3918    declaration. (In contrast, in a ``deriving`` clause attached to a
3919    data type declaration, the context is inferred.)
3920
3921    The exception to this rule is that the context of a standalone deriving
3922    declaration can infer its context when a single, extra-wildcards constraint
3923    is used as the context, such as in: ::
3924
3925          deriving instance _ => Eq (Foo a)
3926
3927    This is essentially the same as if you had written ``deriving Foo`` after
3928    the declaration for ``data Foo a``. Using this feature requires the use of
3929    :extension:`PartialTypeSignatures` (:ref:`partial-type-signatures`).
3930
3931 -  Unlike a ``deriving`` declaration attached to a ``data`` declaration,
3932    the instance can be more specific than the data type (assuming you
3933    also use :extension:`FlexibleInstances`, :ref:`instance-rules`). Consider
3934    for example ::
3935
3936          data Foo a = Bar a | Baz String
3937
3938          deriving instance Eq a => Eq (Foo [a])
3939          deriving instance Eq a => Eq (Foo (Maybe a))
3940
3941    This will generate a derived instance for ``(Foo [a])`` and
3942    ``(Foo (Maybe a))``, but other types such as ``(Foo (Int,Bool))``
3943    will not be an instance of ``Eq``.
3944
3945 -  Unlike a ``deriving`` declaration attached to a ``data`` declaration,
3946    GHC does not restrict the form of the data type. Instead, GHC simply
3947    generates the appropriate boilerplate code for the specified class,
3948    and typechecks it. If there is a type error, it is your problem. (GHC
3949    will show you the offending code if it has a type error.)
3950
3951    The merit of this is that you can derive instances for GADTs and
3952    other exotic data types, providing only that the boilerplate code
3953    does indeed typecheck. For example: ::
3954
3955          data T a where
3956             T1 :: T Int
3957             T2 :: T Bool
3958
3959          deriving instance Show (T a)
3960
3961    In this example, you cannot say ``... deriving( Show )`` on the data
3962    type declaration for ``T``, because ``T`` is a GADT, but you *can*
3963    generate the instance declaration using stand-alone deriving.
3964
3965    The down-side is that, if the boilerplate code fails to typecheck,
3966    you will get an error message about that code, which you did not
3967    write. Whereas, with a ``deriving`` clause the side-conditions are
3968    necessarily more conservative, but any error message may be more
3969    comprehensible.
3970
3971 -  Under most circumstances, you cannot use standalone deriving to create an
3972    instance for a data type whose constructors are not all in scope. This is
3973    because the derived instance would generate code that uses the constructors
3974    behind the scenes, which would break abstraction.
3975
3976    The one exception to this rule is :extension:`DeriveAnyClass`, since
3977    deriving an instance via :extension:`DeriveAnyClass` simply generates
3978    an empty instance declaration, which does not require the use of any
3979    constructors. See the `deriving any class <#derive-any-class>`__ section
3980    for more details.
3981
3982 In other ways, however, a standalone deriving obeys the same rules as
3983 ordinary deriving:
3984
3985 -  A ``deriving instance`` declaration must obey the same rules
3986    concerning form and termination as ordinary instance declarations,
3987    controlled by the same flags; see :ref:`instance-decls`.
3988
3989 -  The stand-alone syntax is generalised for newtypes in exactly the
3990    same way that ordinary ``deriving`` clauses are generalised
3991    (:ref:`newtype-deriving`). For example: ::
3992
3993          newtype Foo a = MkFoo (State Int a)
3994
3995          deriving instance MonadState Int Foo
3996
3997    GHC always treats the *last* parameter of the instance (``Foo`` in
3998    this example) as the type whose instance is being derived.
3999
4000 .. _deriving-extra:
4001
4002 Deriving instances of extra classes (``Data``, etc.)
4003 ----------------------------------------------------
4004
4005 Haskell 98 allows the programmer to add "``deriving( Eq, Ord )``" to a
4006 data type declaration, to generate a standard instance declaration for
4007 classes specified in the ``deriving`` clause. In Haskell 98, the only
4008 classes that may appear in the ``deriving`` clause are the standard
4009 classes ``Eq``, ``Ord``, ``Enum``, ``Ix``, ``Bounded``, ``Read``, and
4010 ``Show``.
4011
4012 GHC extends this list with several more classes that may be
4013 automatically derived:
4014
4015 -  With :extension:`DeriveGeneric`, you can derive instances of the classes
4016    ``Generic`` and ``Generic1``, defined in ``GHC.Generics``. You can
4017    use these to define generic functions, as described in
4018    :ref:`generic-programming`.
4019
4020 -  With :extension:`DeriveFunctor`, you can derive instances of the class
4021    ``Functor``, defined in ``GHC.Base``.
4022
4023 -  With :extension:`DeriveDataTypeable`, you can derive instances of the class
4024    ``Data``, defined in ``Data.Data``.
4025
4026 -  With :extension:`DeriveFoldable`, you can derive instances of the class
4027    ``Foldable``, defined in ``Data.Foldable``.
4028
4029 -  With :extension:`DeriveTraversable`, you can derive instances of the class
4030    ``Traversable``, defined in ``Data.Traversable``. Since the
4031    ``Traversable`` instance dictates the instances of ``Functor`` and
4032    ``Foldable``, you'll probably want to derive them too, so
4033    :extension:`DeriveTraversable` implies :extension:`DeriveFunctor` and
4034    :extension:`DeriveFoldable`.
4035
4036 -  With :extension:`DeriveLift`, you can derive instances of the class ``Lift``,
4037    defined in the ``Language.Haskell.TH.Syntax`` module of the
4038    ``template-haskell`` package.
4039
4040 You can also use a standalone deriving declaration instead (see
4041 :ref:`stand-alone-deriving`).
4042
4043 In each case the appropriate class must be in scope before it can be
4044 mentioned in the ``deriving`` clause.
4045
4046 .. _deriving-functor:
4047
4048 Deriving ``Functor`` instances
4049 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
4050
4051 .. extension:: DeriveFunctor
4052     :shortdesc: Enable deriving for the Functor class.
4053         Implied by :extension:`DeriveTraversable`.
4054
4055     :since: 7.10.1
4056
4057     Allow automatic deriving of instances for the ``Functor`` typeclass.
4058
4059
4060 With :extension:`DeriveFunctor`, one can derive ``Functor`` instances for data types
4061 of kind ``Type -> Type``. For example, this declaration::
4062
4063     data Example a = Ex a Char (Example a) (Example Char)
4064       deriving Functor
4065
4066 would generate the following instance: ::
4067
4068     instance Functor Example where
4069       fmap f (Ex a1 a2 a3 a4) = Ex (f a1) a2 (fmap f a3) a4
4070
4071 The basic algorithm for :extension:`DeriveFunctor` walks the arguments of each
4072 constructor of a data type, applying a mapping function depending on the type
4073 of each argument. If a plain type variable is found that is syntactically
4074 equivalent to the last type parameter of the data type (``a`` in the above
4075 example), then we apply the function ``f`` directly to it. If a type is
4076 encountered that is not syntactically equivalent to the last type parameter
4077 *but does mention* the last type parameter somewhere in it, then a recursive
4078 call to ``fmap`` is made. If a type is found which doesn't mention the last
4079 type parameter at all, then it is left alone.
4080
4081 The second of those cases, in which a type is unequal to the type parameter but
4082 does contain the type parameter, can be surprisingly tricky. For example, the
4083 following example compiles::
4084
4085     newtype Right a = Right (Either Int a) deriving Functor
4086
4087 Modifying the code slightly, however, produces code which will not compile::
4088
4089     newtype Wrong a = Wrong (Either a Int) deriving Functor
4090
4091 The difference involves the placement of the last type parameter, ``a``. In the
4092 ``Right`` case, ``a`` occurs within the type ``Either Int a``, and moreover, it
4093 appears as the last type argument of ``Either``. In the ``Wrong`` case,
4094 however, ``a`` is not the last type argument to ``Either``; rather, ``Int`` is.
4095
4096 This distinction is important because of the way :extension:`DeriveFunctor` works. The
4097 derived ``Functor Right`` instance would be::
4098
4099     instance Functor Right where
4100       fmap f (Right a) = Right (fmap f a)
4101
4102 Given a value of type ``Right a``, GHC must produce a value of type
4103 ``Right b``. Since the argument to the ``Right`` constructor has type
4104 ``Either Int a``, the code recursively calls ``fmap`` on it to produce a value
4105 of type ``Either Int b``, which is used in turn to construct a final value of
4106 type ``Right b``.
4107
4108 The generated code for the ``Functor Wrong`` instance would look exactly the
4109 same, except with ``Wrong`` replacing every occurrence of ``Right``. The
4110 problem is now that ``fmap`` is being applied recursively to a value of type
4111 ``Either a Int``. This cannot possibly produce a value of type
4112 ``Either b Int``, as ``fmap`` can only change the last type parameter! This
4113 causes the generated code to be ill-typed.
4114
4115 As a general rule, if a data type has a derived ``Functor`` instance and its
4116 last type parameter occurs on the right-hand side of the data declaration, then
4117 either it must (1) occur bare (e.g., ``newtype Id a = Id a``), or (2) occur as the
4118 last argument of a type constructor (as in ``Right`` above).
4119
4120 There are two exceptions to this rule:
4121
4122 #. Tuple types. When a non-unit tuple is used on the right-hand side of a data
4123    declaration, :extension:`DeriveFunctor` treats it as a product of distinct types.
4124    In other words, the following code::
4125
4126        newtype Triple a = Triple (a, Int, [a]) deriving Functor
4127
4128    Would result in a generated ``Functor`` instance like so::
4129 <