Fix #11407.
[ghc.git] / compiler / cmm / CmmLex.x
1 -----------------------------------------------------------------------------
2 --
3 -- (c) The University of Glasgow, 2004-2006
4 --
5 -- Lexer for concrete Cmm.  We try to stay close to the C-- spec, but there
6 -- are a few minor differences:
7 --
8 --   * extra keywords for our macros, and float32/float64 types
9 --   * global registers (Sp,Hp, etc.)
10 --
11 -----------------------------------------------------------------------------
12
13 {
14 -- See Note [Warnings in code generated by Alex] in compiler/parser/Lexer.x
15 {-# OPTIONS_GHC -fno-warn-unused-matches #-}
16 {-# OPTIONS_GHC -fno-warn-unused-binds #-}
17 {-# OPTIONS_GHC -fno-warn-unused-imports #-}
18 {-# OPTIONS_GHC -fno-warn-tabs #-}
19 {-# OPTIONS_GHC -fno-warn-missing-signatures #-}
20
21 module CmmLex (
22    CmmToken(..), cmmlex,
23   ) where
24
25 import CmmExpr
26
27 import Lexer
28 import SrcLoc
29 import UniqFM
30 import StringBuffer
31 import FastString
32 import Ctype
33 import Util
34 --import TRACE
35
36 import Data.Word
37 import Data.Char
38 }
39
40 $whitechar   = [\ \t\n\r\f\v\xa0] -- \xa0 is Unicode no-break space
41 $white_no_nl = $whitechar # \n
42
43 $ascdigit  = 0-9
44 $unidigit  = \x01 -- Trick Alex into handling Unicode. See alexGetChar.
45 $digit     = [$ascdigit $unidigit]
46 $octit     = 0-7
47 $hexit     = [$digit A-F a-f]
48
49 $unilarge  = \x03 -- Trick Alex into handling Unicode. See alexGetChar.
50 $asclarge  = [A-Z \xc0-\xd6 \xd8-\xde]
51 $large     = [$asclarge $unilarge]
52
53 $unismall  = \x04 -- Trick Alex into handling Unicode. See alexGetChar.
54 $ascsmall  = [a-z \xdf-\xf6 \xf8-\xff]
55 $small     = [$ascsmall $unismall \_]
56
57 $namebegin = [$large $small \. \$ \@]
58 $namechar  = [$namebegin $digit]
59
60 @decimal     = $digit+
61 @octal       = $octit+
62 @hexadecimal = $hexit+
63 @exponent    = [eE] [\-\+]? @decimal
64
65 @floating_point = @decimal \. @decimal @exponent? | @decimal @exponent
66
67 @escape      = \\ ([abfnrt\\\'\"\?] | x $hexit{1,2} | $octit{1,3})
68 @strchar     = ($printable # [\"\\]) | @escape
69
70 cmm :-
71
72 $white_no_nl+           ;
73 ^\# pragma .* \n        ; -- Apple GCC 3.3 CPP generates pragmas in its output
74
75 ^\# (line)?             { begin line_prag }
76
77 -- single-line line pragmas, of the form
78 --    # <line> "<file>" <extra-stuff> \n
79 <line_prag> $digit+                     { setLine line_prag1 }
80 <line_prag1> \" [^\"]* \"       { setFile line_prag2 }
81 <line_prag2> .*                         { pop }
82
83 <0> {
84   \n                    ;
85
86   [\:\;\{\}\[\]\(\)\=\`\~\/\*\%\-\+\&\^\|\>\<\,\!]      { special_char }
87
88   ".."                  { kw CmmT_DotDot }
89   "::"                  { kw CmmT_DoubleColon }
90   ">>"                  { kw CmmT_Shr }
91   "<<"                  { kw CmmT_Shl }
92   ">="                  { kw CmmT_Ge }
93   "<="                  { kw CmmT_Le }
94   "=="                  { kw CmmT_Eq }
95   "!="                  { kw CmmT_Ne }
96   "&&"                  { kw CmmT_BoolAnd }
97   "||"                  { kw CmmT_BoolOr }
98
99   P@decimal             { global_regN (\n -> VanillaReg n VGcPtr) }
100   R@decimal             { global_regN (\n -> VanillaReg n VNonGcPtr) }
101   F@decimal             { global_regN FloatReg }
102   D@decimal             { global_regN DoubleReg }
103   L@decimal             { global_regN LongReg }
104   Sp                    { global_reg Sp }
105   SpLim                 { global_reg SpLim }
106   Hp                    { global_reg Hp }
107   HpLim                 { global_reg HpLim }
108   CCCS                  { global_reg CCCS }
109   CurrentTSO            { global_reg CurrentTSO }
110   CurrentNursery        { global_reg CurrentNursery }
111   HpAlloc               { global_reg HpAlloc }
112   BaseReg               { global_reg BaseReg }
113   MachSp                { global_reg MachSp }
114   UnwindReturnReg       { global_reg UnwindReturnReg }
115
116   $namebegin $namechar* { name }
117
118   0 @octal              { tok_octal }
119   @decimal              { tok_decimal }
120   0[xX] @hexadecimal    { tok_hexadecimal }
121   @floating_point       { strtoken tok_float }
122
123   \" @strchar* \"       { strtoken tok_string }
124 }
125
126 {
127 data CmmToken
128   = CmmT_SpecChar  Char
129   | CmmT_DotDot
130   | CmmT_DoubleColon
131   | CmmT_Shr
132   | CmmT_Shl
133   | CmmT_Ge
134   | CmmT_Le
135   | CmmT_Eq
136   | CmmT_Ne
137   | CmmT_BoolAnd
138   | CmmT_BoolOr
139   | CmmT_CLOSURE
140   | CmmT_INFO_TABLE
141   | CmmT_INFO_TABLE_RET
142   | CmmT_INFO_TABLE_FUN
143   | CmmT_INFO_TABLE_CONSTR
144   | CmmT_INFO_TABLE_SELECTOR
145   | CmmT_else
146   | CmmT_export
147   | CmmT_section
148   | CmmT_goto
149   | CmmT_if
150   | CmmT_call
151   | CmmT_jump
152   | CmmT_foreign
153   | CmmT_never
154   | CmmT_prim
155   | CmmT_reserve
156   | CmmT_return
157   | CmmT_returns
158   | CmmT_import
159   | CmmT_switch
160   | CmmT_case
161   | CmmT_default
162   | CmmT_push
163   | CmmT_unwind
164   | CmmT_bits8
165   | CmmT_bits16
166   | CmmT_bits32
167   | CmmT_bits64
168   | CmmT_bits128
169   | CmmT_bits256
170   | CmmT_bits512
171   | CmmT_float32
172   | CmmT_float64
173   | CmmT_gcptr
174   | CmmT_GlobalReg GlobalReg
175   | CmmT_Name      FastString
176   | CmmT_String    String
177   | CmmT_Int       Integer
178   | CmmT_Float     Rational
179   | CmmT_EOF
180   deriving (Show)
181
182 -- -----------------------------------------------------------------------------
183 -- Lexer actions
184
185 type Action = RealSrcSpan -> StringBuffer -> Int -> P (RealLocated CmmToken)
186
187 begin :: Int -> Action
188 begin code _span _str _len = do pushLexState code; lexToken
189
190 pop :: Action
191 pop _span _buf _len = popLexState >> lexToken
192
193 special_char :: Action
194 special_char span buf _len = return (L span (CmmT_SpecChar (currentChar buf)))
195
196 kw :: CmmToken -> Action
197 kw tok span _buf _len = return (L span tok)
198
199 global_regN :: (Int -> GlobalReg) -> Action
200 global_regN con span buf len
201   = return (L span (CmmT_GlobalReg (con (fromIntegral n))))
202   where buf' = stepOn buf
203         n = parseUnsignedInteger buf' (len-1) 10 octDecDigit
204
205 global_reg :: GlobalReg -> Action
206 global_reg r span _buf _len = return (L span (CmmT_GlobalReg r))
207
208 strtoken :: (String -> CmmToken) -> Action
209 strtoken f span buf len =
210   return (L span $! (f $! lexemeToString buf len))
211
212 name :: Action
213 name span buf len =
214   case lookupUFM reservedWordsFM fs of
215         Just tok -> return (L span tok)
216         Nothing  -> return (L span (CmmT_Name fs))
217   where
218         fs = lexemeToFastString buf len
219
220 reservedWordsFM = listToUFM $
221         map (\(x, y) -> (mkFastString x, y)) [
222         ( "CLOSURE",            CmmT_CLOSURE ),
223         ( "INFO_TABLE",         CmmT_INFO_TABLE ),
224         ( "INFO_TABLE_RET",     CmmT_INFO_TABLE_RET ),
225         ( "INFO_TABLE_FUN",     CmmT_INFO_TABLE_FUN ),
226         ( "INFO_TABLE_CONSTR",  CmmT_INFO_TABLE_CONSTR ),
227         ( "INFO_TABLE_SELECTOR",CmmT_INFO_TABLE_SELECTOR ),
228         ( "else",               CmmT_else ),
229         ( "export",             CmmT_export ),
230         ( "section",            CmmT_section ),
231         ( "goto",               CmmT_goto ),
232         ( "if",                 CmmT_if ),
233         ( "call",               CmmT_call ),
234         ( "jump",               CmmT_jump ),
235         ( "foreign",            CmmT_foreign ),
236         ( "never",              CmmT_never ),
237         ( "prim",               CmmT_prim ),
238         ( "reserve",            CmmT_reserve ),
239         ( "return",             CmmT_return ),
240         ( "returns",            CmmT_returns ),
241         ( "import",             CmmT_import ),
242         ( "switch",             CmmT_switch ),
243         ( "case",               CmmT_case ),
244         ( "default",            CmmT_default ),
245         ( "push",               CmmT_push ),
246         ( "unwind",             CmmT_unwind ),
247         ( "bits8",              CmmT_bits8 ),
248         ( "bits16",             CmmT_bits16 ),
249         ( "bits32",             CmmT_bits32 ),
250         ( "bits64",             CmmT_bits64 ),
251         ( "bits128",            CmmT_bits128 ),
252         ( "bits256",            CmmT_bits256 ),
253         ( "bits512",            CmmT_bits512 ),
254         ( "float32",            CmmT_float32 ),
255         ( "float64",            CmmT_float64 ),
256 -- New forms
257         ( "b8",                 CmmT_bits8 ),
258         ( "b16",                CmmT_bits16 ),
259         ( "b32",                CmmT_bits32 ),
260         ( "b64",                CmmT_bits64 ),
261         ( "b128",               CmmT_bits128 ),
262         ( "b256",               CmmT_bits256 ),
263         ( "b512",               CmmT_bits512 ),
264         ( "f32",                CmmT_float32 ),
265         ( "f64",                CmmT_float64 ),
266         ( "gcptr",              CmmT_gcptr )
267         ]
268
269 tok_decimal span buf len
270   = return (L span (CmmT_Int  $! parseUnsignedInteger buf len 10 octDecDigit))
271
272 tok_octal span buf len
273   = return (L span (CmmT_Int  $! parseUnsignedInteger (offsetBytes 1 buf) (len-1) 8 octDecDigit))
274
275 tok_hexadecimal span buf len
276   = return (L span (CmmT_Int  $! parseUnsignedInteger (offsetBytes 2 buf) (len-2) 16 hexDigit))
277
278 tok_float str = CmmT_Float $! readRational str
279
280 tok_string str = CmmT_String (read str)
281                  -- urk, not quite right, but it'll do for now
282
283 -- -----------------------------------------------------------------------------
284 -- Line pragmas
285
286 setLine :: Int -> Action
287 setLine code span buf len = do
288   let line = parseUnsignedInteger buf len 10 octDecDigit
289   setSrcLoc (mkRealSrcLoc (srcSpanFile span) (fromIntegral line - 1) 1)
290         -- subtract one: the line number refers to the *following* line
291   -- trace ("setLine "  ++ show line) $ do
292   popLexState >> pushLexState code
293   lexToken
294
295 setFile :: Int -> Action
296 setFile code span buf len = do
297   let file = lexemeToFastString (stepOn buf) (len-2)
298   setSrcLoc (mkRealSrcLoc file (srcSpanEndLine span) (srcSpanEndCol span))
299   popLexState >> pushLexState code
300   lexToken
301
302 -- -----------------------------------------------------------------------------
303 -- This is the top-level function: called from the parser each time a
304 -- new token is to be read from the input.
305
306 cmmlex :: (Located CmmToken -> P a) -> P a
307 cmmlex cont = do
308   (L span tok) <- lexToken
309   --trace ("token: " ++ show tok) $ do
310   cont (L (RealSrcSpan span) tok)
311
312 lexToken :: P (RealLocated CmmToken)
313 lexToken = do
314   inp@(loc1,buf) <- getInput
315   sc <- getLexState
316   case alexScan inp sc of
317     AlexEOF -> do let span = mkRealSrcSpan loc1 loc1
318                   setLastToken span 0
319                   return (L span CmmT_EOF)
320     AlexError (loc2,_) -> do failLocMsgP loc1 loc2 "lexical error"
321     AlexSkip inp2 _ -> do
322         setInput inp2
323         lexToken
324     AlexToken inp2@(end,_buf2) len t -> do
325         setInput inp2
326         let span = mkRealSrcSpan loc1 end
327         span `seq` setLastToken span len
328         t span buf len
329
330 -- -----------------------------------------------------------------------------
331 -- Monad stuff
332
333 -- Stuff that Alex needs to know about our input type:
334 type AlexInput = (RealSrcLoc,StringBuffer)
335
336 alexInputPrevChar :: AlexInput -> Char
337 alexInputPrevChar (_,s) = prevChar s '\n'
338
339 -- backwards compatibility for Alex 2.x
340 alexGetChar :: AlexInput -> Maybe (Char,AlexInput)
341 alexGetChar inp = case alexGetByte inp of
342                     Nothing    -> Nothing
343                     Just (b,i) -> c `seq` Just (c,i)
344                        where c = chr $ fromIntegral b
345
346 alexGetByte :: AlexInput -> Maybe (Word8,AlexInput)
347 alexGetByte (loc,s)
348   | atEnd s   = Nothing
349   | otherwise = b `seq` loc' `seq` s' `seq` Just (b, (loc', s'))
350   where c    = currentChar s
351         b    = fromIntegral $ ord $ c
352         loc' = advanceSrcLoc loc c
353         s'   = stepOn s
354
355 getInput :: P AlexInput
356 getInput = P $ \s@PState{ loc=l, buffer=b } -> POk s (l,b)
357
358 setInput :: AlexInput -> P ()
359 setInput (l,b) = P $ \s -> POk s{ loc=l, buffer=b } ()
360 }