Make rejigConRes do kind substitutions
[ghc.git] / configure.ac
1 dnl == autoconf source for the Glasgow FP tools ==
2 dnl (run "grep '^dnl \*' configure.ac | sed -e 's/dnl / /g; s/\*\*/   +/g;'"
3 dnl  (or some such) to see the outline of this file)
4 dnl
5 #
6 # (c) The University of Glasgow 1994-2012
7 #
8 # Configure script template for GHC
9 #
10 # Process with 'autoreconf' to get a working configure script.
11 #
12 # For the generated configure script, do "./configure --help" to
13 # see what flags are available. (Better yet, read the documentation!)
14 #
15
16 AC_INIT([The Glorious Glasgow Haskell Compilation System], [8.3], [glasgow-haskell-bugs@haskell.org], [ghc-AC_PACKAGE_VERSION])
17
18 # Set this to YES for a released version, otherwise NO
19 : ${RELEASE=NO}
20
21 # The primary version (e.g. 7.5, 7.4.1) is set in the AC_INIT line
22 # above.  If this is not a released version, then we will append the
23 # date to the version number (e.g. 7.4.20111220).  The date is
24 # constructed by finding the date of the most recent patch in the
25 # git repository.  If this is a source distribution (not a git
26 # checkout), then we ship a file 'VERSION' containing the full version
27 # when the source distribution was created.
28
29 if test ! -f mk/config.h.in; then
30    echo "mk/config.h.in doesn't exist: perhaps you haven't run 'perl boot'?"
31    exit 1
32 fi
33
34 AC_SUBST([CONFIGURE_ARGS], [$ac_configure_args])
35
36 dnl this makes sure `./configure --target=<cross-compile-target>`
37 dnl works as expected, since we're slightly modifying how Autoconf
38 dnl interprets build/host/target and how this interacts with $CC tests
39 test -n "$target_alias" && ac_tool_prefix=$target_alias-
40
41 dnl ----------------------------------------------------------
42 dnl ** Find unixy sort and find commands,
43 dnl ** which are needed by FP_SETUP_PROJECT_VERSION
44
45 dnl ** Find find command (for Win32's benefit)
46 FP_PROG_FIND
47 FP_PROG_SORT
48
49 dnl ----------------------------------------------------------
50 FP_SETUP_PROJECT_VERSION
51
52 # Hmmm, we fix the RPM release number to 1 here... Is this convenient?
53 AC_SUBST([release], [1])
54
55 # First off, a distrib sanity check..
56 AC_CONFIG_SRCDIR([mk/config.mk.in])
57
58 dnl * We require autoconf version 2.60
59 dnl We need 2.50 due to the use of AC_SYS_LARGEFILE and AC_MSG_NOTICE.
60 dnl We need 2.52 due to the use of AS_TR_CPP and AS_TR_SH.
61 dnl Using autoconf 2.59 started to give nonsense like this
62 dnl  #define SIZEOF_CHAR 0
63 dnl recently.
64 AC_PREREQ([2.60])
65
66 # -------------------------------------------------------------------------
67 # Prepare to generate the following header files
68 #
69 #
70 AC_CONFIG_HEADER(mk/config.h)
71
72 # No, semi-sadly, we don't do `--srcdir'...
73 if test x"$srcdir" != 'x.' ; then
74     echo "This configuration does not support the \`--srcdir' option.."
75     exit 1
76 fi
77
78 dnl --------------------------------------------------------------
79 dnl * Project specific configuration options
80 dnl --------------------------------------------------------------
81 dnl What follows is a bunch of options that can either be configured
82 dnl through command line options to the configure script or by
83 dnl supplying defns in the build tree's mk/build.mk. Having the option to
84 dnl use either is considered a Feature.
85
86 dnl ** What command to use to compile compiler sources ?
87 dnl --------------------------------------------------------------
88
89 AC_ARG_WITH([ghc],
90 [AC_HELP_STRING([--with-ghc=ARG],
91   [Use ARG as the path to GHC  [default=autodetect]])],
92   [WithGhc="$withval"],
93   [if test "$GHC" = ""; then
94     AC_PATH_PROG([GHC], [ghc])
95   fi
96   WithGhc="$GHC"])
97
98 dnl ** Tell the make system which OS we are using
99 dnl $OSTYPE is set by the operating system to "msys" or "cygwin" or something
100 AC_SUBST(OSTYPE)
101
102 AC_ARG_ENABLE(bootstrap-with-devel-snapshot,
103 [AC_HELP_STRING([--enable-bootstrap-with-devel-snapshot],
104                 [Allow bootstrapping using a development snapshot of GHC.  This is not guaranteed to work.])],
105         EnableBootstrapWithDevelSnaphost=YES,
106         EnableBootstrapWithDevelSnaphost=NO
107 )
108
109 AC_ARG_ENABLE(tarballs-autodownload,
110 [AC_HELP_STRING([--enable-tarballs-autodownload],
111                 [Automatically download Windows distribution binaries if needed.])],
112         TarballsAutodownload=YES,
113         TarballsAutodownload=NO
114 )
115
116 AC_ARG_ENABLE(distro-toolchain,
117 [AC_HELP_STRING([--enable-distro-toolchain],
118                 [Do not use bundled Windows toolchain binaries.])],
119         EnableDistroToolchain=YES,
120         EnableDistroToolchain=NO
121 )
122
123 if test "$EnableDistroToolchain" = "YES"; then
124   TarballsAutodownload=NO
125 fi
126
127 dnl CC_STAGE0 is like the "previous" variable CC (inherited by CC_STAGE[123])
128 dnl but instead used by stage0 for bootstrapping stage1
129 AC_ARG_VAR(CC_STAGE0, [C compiler command (bootstrap)])
130
131 if test "$WithGhc" != ""; then
132   FPTOOLS_GHC_VERSION([GhcVersion], [GhcMajVersion], [GhcMinVersion], [GhcPatchLevel])dnl
133
134   if test "$GhcMajVersion" = "unknown" || test "$GhcMinVersion" = "unknown"; then
135      AC_MSG_ERROR([Cannot determine the version of $WithGhc.  Is it really GHC?])
136   fi
137
138   AC_SUBST(GhcVersion)dnl
139   AC_SUBST(GhcMajVersion)dnl
140   AC_SUBST(GhcMinVersion)dnl
141   AC_SUBST(GhcPatchLevel)dnl
142   GhcMinVersion2=`echo "$GhcMinVersion" | sed 's/^\\(.\\)$/0\\1/'`
143   GhcCanonVersion="$GhcMajVersion$GhcMinVersion2"
144
145   dnl infer CC_STAGE0 from `ghc --info` unless explicitly set by user
146   if test -z "$CC_STAGE0"; then
147     BOOTSTRAPPING_GHC_INFO_FIELD([CC_STAGE0],[C compiler command])
148   fi
149
150   BOOTSTRAPPING_GHC_INFO_FIELD([LD_STAGE0],[ld command])
151   BOOTSTRAPPING_GHC_INFO_FIELD([AR_STAGE0],[ar command])
152   BOOTSTRAPPING_GHC_INFO_FIELD([AR_OPTS_STAGE0],[ar flags])
153   BOOTSTRAPPING_GHC_INFO_FIELD([ArSupportsAtFile_STAGE0],[ar supports at file])
154 fi
155
156 dnl ** Must have GHC to build GHC
157 if test "$WithGhc" = ""
158 then
159     AC_MSG_ERROR([GHC is required.])
160 fi
161 FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[8.0],
162     [AC_MSG_ERROR([GHC version 8.0 or later is required to compile GHC.])])
163
164 if test `expr $GhcMinVersion % 2` = "1"
165 then
166     if test "$EnableBootstrapWithDevelSnaphost" = "NO"
167     then
168         AC_MSG_ERROR([
169      $WithGhc is a development snapshot of GHC, version $GhcVersion.
170      Bootstrapping using this version of GHC is not supported, and may not
171      work.  Use --enable-bootstrap-with-devel-snapshot to try it anyway,
172      or --with-ghc to specify a different GHC to use.])
173     fi
174 fi
175
176 GHC_PACKAGE_DB_FLAG=package-db
177 AC_SUBST(GHC_PACKAGE_DB_FLAG)
178
179 # GHC is passed to Cabal, so we need a native path
180 if test "${WithGhc}" != ""
181 then
182     ghc_host_os=`"${WithGhc}" +RTS --info | grep 'Host OS' | sed -e 's/.*, "//' -e 's/")//'`
183
184     if test "$ghc_host_os" = "mingw32"
185     then
186         if test "${OSTYPE}" = "msys"
187         then
188             WithGhc=`echo "${WithGhc}" | sed "s#^/\([a-zA-Z]\)/#\1:/#"`
189         else
190             # Canonicalise to <drive>:/path/to/ghc
191             WithGhc=`cygpath -m "${WithGhc}"`
192         fi
193         echo "GHC path canonicalised to: ${WithGhc}"
194     fi
195 fi
196 AC_SUBST([WithGhc])
197
198 dnl ** Without optimization some INLINE trickery fails for GHCi
199 SRC_CC_OPTS="-O"
200
201 dnl--------------------------------------------------------------------
202 dnl * Choose host(/target/build) platform
203 dnl--------------------------------------------------------------------
204 dnl If we aren't explicitly told what values to use with configure flags,
205 dnl we ask the bootstrapping compiler what platform it is for
206
207 if test "${WithGhc}" != ""
208 then
209         bootstrap_host=`"${WithGhc}" +RTS --info | grep '^ ,("Host platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
210         bootstrap_target=`"${WithGhc}" +RTS --info | grep '^ ,("Target platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
211         if test "$bootstrap_host" != "$bootstrap_target"
212         then
213                 echo "Bootstrapping GHC is a cross compiler. This probably isn't going to work"
214         fi
215 fi
216
217 # We have to run these unconditionally, but we may discard their
218 # results in the following code
219 AC_CANONICAL_BUILD
220 AC_CANONICAL_HOST
221 AC_CANONICAL_TARGET
222
223 FPTOOLS_SET_PLATFORM_VARS
224
225 # Verify that the installed (bootstrap) GHC is capable of generating
226 # code for the requested build platform.
227 if test "$BuildPlatform" != "$bootstrap_target"
228 then
229     echo "This GHC (${WithGhc}) does not generate code for the build platform"
230     echo "   GHC target platform    : $bootstrap_target"
231     echo "   Desired build platform : $BuildPlatform"
232     exit 1
233 fi
234
235 # Testing if we shall enable shared libs support on Solaris.
236 # Anything older than SunOS 5.11 aka Solaris 11 (Express) is broken.
237
238 SOLARIS_BROKEN_SHLD=NO
239
240 case $host in
241      i386-*-solaris2)
242      # here we go with the test
243      MINOR=`uname -r|cut -d '.' -f 2-`
244      if test "$MINOR" -lt "11"; then
245          SOLARIS_BROKEN_SHLD=YES
246      fi
247      ;;
248 esac
249
250 AC_SUBST(SOLARIS_BROKEN_SHLD)
251
252 dnl ** Do an unregisterised build?
253 dnl --------------------------------------------------------------
254 case "$TargetArch" in
255     i386|x86_64|powerpc|powerpc64|powerpc64le|arm|aarch64)
256         UnregisterisedDefault=NO
257         ;;
258     *)
259         UnregisterisedDefault=YES
260         ;;
261 esac
262 AC_ARG_ENABLE(unregisterised,
263 [AC_HELP_STRING([--enable-unregisterised],
264 [Build an unregisterised compiler (enabled by default on platforms without registerised support) [default="$UnregisterisedDefault"]])],
265 [ if test x"$enableval" = x"yes"; then
266         Unregisterised=YES
267   else
268         Unregisterised=NO
269   fi
270 ],
271 [Unregisterised="$UnregisterisedDefault"]
272 )
273 AC_SUBST(Unregisterised)
274
275 dnl ** Does target have runtime linker support?
276 dnl --------------------------------------------------------------
277 case "$target" in
278     powerpc64-*|powerpc64le-*|powerpc-ibm-aix*)
279         HaskellHaveRTSLinker=NO
280         ;;
281     *)
282         HaskellHaveRTSLinker=YES
283         ;;
284 esac
285 AC_SUBST(HaskellHaveRTSLinker)
286
287 # Requires FPTOOLS_SET_PLATFORM_VARS to be run first.
288 FP_FIND_ROOT
289
290 fail() {
291     echo >&2
292     echo "$1" >&2
293     exit 1
294 }
295
296
297 if test "$HostOS" = "mingw32"
298 then
299     # Find the mingw-w64 7z file to extract.
300     # NB. If you update the tarballs to a new version of gcc, don't
301     # forget to tweak the paths in driver/gcc/gcc.c.
302     if test "$HostArch" = "i386"
303     then
304         mingw_arch="i686"
305         tarball_dest_dir="mingw-w64/x86"
306         tarball_mingw_dir="mingw32"
307     else
308         mingw_arch="x86_64"
309         tarball_dest_dir="mingw-w64/x86_64"
310         tarball_mingw_dir="mingw64"
311     fi
312 fi
313
314 set_up_tarballs() {
315     AC_MSG_NOTICE([Checking for Windows toolchain tarballs...])
316     local action
317     if test "$TarballsAutodownload" = "NO"
318     then
319         action="verify"
320     else
321         action="download"
322     fi
323     mk/get-win32-tarballs.sh $action $HostArch > missing-win32-tarballs
324     case $? in
325         0)
326            rm missing-win32-tarballs
327            ;;
328         2)
329            echo
330            echo "Error:"
331            echo "Needed msys2 tarballs are missing. You have a few options to get them,"
332            echo
333            echo "  * run configure with the --enable-tarballs-autodownload option"
334            echo
335            echo "  * run mk/get-win32-tarballs.sh download ${HostArch}"
336            echo
337            echo "  * manually download the files listed in ./missing-win32-tarballs and place"
338            echo "    them in the ghc-tarballs directory."
339            echo
340            exit 1
341            ;;
342         *)
343            echo
344            echo "Error fetching msys2 tarballs; see errors above."
345            exit 1
346            ;;
347     esac
348
349     # Extract all the tarballs in one go
350     if ! test -d inplace/mingw
351     then
352         AC_MSG_NOTICE([Extracting Windows toolchain from archives (may take a while)...])
353         rm -rf inplace/mingw
354         local base_dir="../ghc-tarballs/${tarball_dest_dir}"
355         ( cd inplace &&
356         find "${base_dir}" -name "*.tar.xz" -exec tar xfJ {} \; &&
357         rm ".MTREE" &&
358         rm ".PKGINFO" &&
359         cd .. ) || fail "Error: Could not extract Windows toolchains."
360
361         mv "inplace/${tarball_mingw_dir}" inplace/mingw &&
362         touch inplace/mingw
363
364         # NB. Now since the GCC is hardcoded to use /mingw32 we need to
365         # make a wrapper around it to give it the proper paths
366         mv inplace/mingw/bin/gcc.exe inplace/mingw/bin/realgcc.exe
367         PATH=`pwd`/inplace/mingw/bin:$PATH
368         inplace/mingw/bin/realgcc.exe driver/gcc/gcc.c driver/utils/cwrapper.c driver/utils/getLocation.c -Idriver/utils -o inplace/mingw/bin/gcc.exe
369
370         AC_MSG_NOTICE([In-tree MingW-w64 tree created])
371     fi
372 }
373
374 if test "$HostOS" = "mingw32" -a "$EnableDistroToolchain" = "NO"
375 then
376     test -d inplace || mkdir inplace
377
378     # NB. Download and extract the MingW-w64 distribution if required
379     set_up_tarballs
380
381     mingwbin="$hardtop/inplace/mingw/bin/"
382     CC="${mingwbin}gcc.exe"
383     LD="${mingwbin}ld.exe"
384     NM="${mingwbin}nm.exe"
385     RANLIB="${mingwbin}ranlib.exe"
386     OBJDUMP="${mingwbin}objdump.exe"
387     fp_prog_ar="${mingwbin}ar.exe"
388
389     AC_PATH_PROG([Genlib],[genlib])
390
391     # NB. Download the perl binaries if required
392     if ! test -d inplace/perl ||
393          test inplace/perl -ot ghc-tarballs/perl/ghc-perl*.tar.gz
394     then
395         AC_MSG_NOTICE([Making in-tree perl tree])
396         rm -rf inplace/perl
397         mkdir inplace/perl
398         (
399             cd inplace/perl &&
400             tar -zxf ../../ghc-tarballs/perl/ghc-perl*.tar.gz
401         )
402         AC_MSG_NOTICE([In-tree perl tree created])
403     fi
404 fi
405
406 # We don't want to bundle a MinGW-w64 toolchain
407 # So we have to find these individual tools.
408 if test "$EnableDistroToolchain" = "YES"
409 then
410     # Ideally should use AC_CHECK_TARGET_TOOL but our triples
411     # are screwed up. Configure doesn't think they're ever equal and
412     # so never tried without the prefix.
413     AC_PATH_PROG([CC],[gcc], [clang])
414     AC_PATH_PROG([NM],[nm])
415     AC_PATH_PROG([AR],[ar])
416     AC_PATH_PROG([RANLIB],[ranlib])
417     AC_PATH_PROG([OBJDUMP],[objdump])
418     AC_PATH_PROG([DllWrap],[dllwrap])
419     AC_PATH_PROG([Windres],[windres])
420     AC_PATH_PROG([Genlib],[genlib])
421 fi
422
423 DllWrapCmd="$DllWrap"
424 WindresCmd="$Windres"
425
426 HAVE_GENLIB=False
427 if test "$HostOS" = "mingw32"
428 then
429     if test "$Genlib" != ""; then
430         GenlibCmd="$(cygpath -m $Genlib)"
431         HAVE_GENLIB=True
432     fi
433 fi
434
435 AC_SUBST([DllWrapCmd])
436 AC_SUBST([WindresCmd])
437 AC_SUBST([GenlibCmd])
438 AC_SUBST([HAVE_GENLIB])
439
440 FP_ICONV
441 FP_GMP
442 FP_CURSES
443
444 XCODE_VERSION()
445
446
447 dnl ** Building a cross compiler?
448 dnl --------------------------------------------------------------
449 CrossCompiling=NO
450 # If 'host' and 'target' differ, then this means we are building a cross-compiler.
451 if test "$TargetPlatform" != "$HostPlatform" ; then
452     CrossCompiling=YES
453     cross_compiling=yes   # This tells configure that it can accept just 'target',
454                           # otherwise you get
455                           #   configure: error: cannot run C compiled programs.
456                           #   If you meant to cross compile, use `--host'.
457 fi
458 if test "$BuildPlatform" != "$HostPlatform" ; then
459    AC_MSG_ERROR([
460 You've selected:
461
462   BUILD:  $BuildPlatform   (the architecture we're building on)
463   HOST:   $HostPlatform    (the architecture the compiler we're building will execute on)
464   TARGET: $TargetPlatform  (the architecture the compiler we're building will produce code for)
465
466 BUILD must equal HOST; that is, we do not support building GHC itself
467 with a cross-compiler.  To cross-compile GHC itself, set TARGET: stage
468 1 will be a cross-compiler, and stage 2 will be the cross-compiled
469 GHC.
470 ])
471 fi
472 # Despite its similarity in name to TargetPlatform, TargetPlatformFull is used
473 # in calls to subproject configure scripts and thus must be set to the autoconf
474 # triple, not the normalized GHC triple that TargetPlatform is set to.
475 #
476 # We use the non-canonicalized triple, target_alias, here since the subproject
477 # configure scripts will use this triple to construct the names of the toolchain
478 # executables. If we instead passed down the triple produced by
479 # AC_CANONICAL_TARGET then it may look for the target toolchain under the wrong
480 # name (this is a known problem in the case of the Android NDK, which has
481 # slightly odd triples).
482 #
483 # It may be better to just do away with the GHC triples altogether. This would
484 # all be taken care of for us if we configured the subprojects using
485 # AC_CONFIG_DIR, but unfortunately Cabal needs to be the one to do the
486 # configuration.
487 #
488 # We also use non-canonicalized triple when install stage1 crosscompiler
489 if test -z "${target_alias}"
490 then
491   # --target wasn't given; use result from AC_CANONICAL_TARGET
492   TargetPlatformFull="${target}"
493 else
494   TargetPlatformFull="${target_alias}"
495 fi
496 if test "$CrossCompiling" = "YES"
497 then
498   # Use value passed by user from --target=
499   CrossCompilePrefix="${TargetPlatformFull}-"
500 else
501   CrossCompilePrefix=""
502 fi
503 AC_SUBST(CrossCompiling)
504 AC_SUBST(CrossCompilePrefix)
505 AC_SUBST(TargetPlatformFull)
506 AC_SUBST(EnableDistroToolchain)
507
508 dnl ** Which gcc to use?
509 dnl --------------------------------------------------------------
510
511 AC_ARG_WITH([gcc],
512         AS_HELP_STRING([--with-gcc=ARG], [Use ARG as the path to gcc (obsolete, use CC=ARG instead) [default=autodetect]]),
513         AC_MSG_ERROR([--with-gcc=$withval is obsolete (use './configure CC=$withval' or 'CC=$withval ./configure' instead)]))
514
515 AC_ARG_WITH([clang],
516         AS_HELP_STRING([--with-clang=ARG], [Use ARG as the path to gcc (obsolete, use CC=ARG instead) [default=autodetect]]),
517         AC_MSG_ERROR([--with-clang=$withval is obsolete (use './configure CC=$withval' or 'CC=$withval ./configure' instead)]))
518
519 dnl detect compiler (prefer gcc over clang) and set $CC (unless CC already set),
520 dnl later CC is copied to CC_STAGE{1,2,3}
521 AC_PROG_CC([gcc clang])
522
523 MAYBE_OVERRIDE_STAGE0([ar],[AR_STAGE0])
524
525 dnl make extensions visible to allow feature-tests to detect them lateron
526 AC_USE_SYSTEM_EXTENSIONS
527
528 dnl ** figure out how to invoke the C preprocessor (i.e. `gcc -E`)
529 AC_PROG_CPP
530
531 # --with-hs-cpp/--with-hs-cpp-flags
532 FP_CPP_CMD_WITH_ARGS(HaskellCPPCmd, HaskellCPPArgs)
533 AC_SUBST([HaskellCPPCmd])
534 AC_SUBST([HaskellCPPArgs])
535
536 FP_SET_CFLAGS_C99([CC],[CFLAGS],[CPPFLAGS])
537 FP_SET_CFLAGS_C99([CC_STAGE0],[CONF_CC_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
538 FP_SET_CFLAGS_C99([CC],[CONF_CC_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
539 FP_SET_CFLAGS_C99([CC],[CONF_CC_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])
540
541 dnl ** Choose a linker
542 dnl --------------------------------------------------------------
543 FIND_LD([$target],[GccUseLdOpt])
544 CONF_GCC_LINKER_OPTS_STAGE1="$CONF_GCC_LINKER_OPTS_STAGE1 $GccUseLdOpt"
545 CONF_GCC_LINKER_OPTS_STAGE2="$CONF_GCC_LINKER_OPTS_STAGE2 $GccUseLdOpt"
546 LdCmd="$LD"
547 CFLAGS="$CFLAGS $GccUseLdOpt"
548 AC_SUBST([LdCmd])
549
550 dnl ** Which nm to use?
551 dnl --------------------------------------------------------------
552 if test "$HostOS" != "mingw32"; then
553     AC_CHECK_TARGET_TOOL([NM], [nm])
554     if test "$NM" = ":"; then
555         AC_MSG_ERROR([cannot find nm in your PATH])
556     fi
557 fi
558 NmCmd="$NM"
559 AC_SUBST([NmCmd])
560
561 if test "$TargetOS_CPP" = "darwin"
562 then
563     AC_MSG_CHECKING(whether nm program is broken)
564     # Some versions of XCode ship a broken version of `nm`. Detect and work
565     # around this issue. See : https://ghc.haskell.org/trac/ghc/ticket/11744
566     nmver=$(${NM} --version | grep version | sed 's/ //g')
567     case "$nmver" in
568         LLVMversion7.3.0|LLVMversion7.3.1)
569             AC_MSG_RESULT(yes)
570             echo "The detected nm program is broken."
571             echo
572             echo "See: https://ghc.haskell.org/trac/ghc/ticket/11744"
573             echo
574             echo "Try re-running configure with:"
575             echo
576             echo '   NM=$(xcrun --find nm-classic) ./configure'
577             echo
578             exit 1
579             ;;
580         *)
581             AC_MSG_RESULT(no)
582             ;;
583         esac
584 fi
585
586 dnl ** Which objdump to use?
587 dnl --------------------------------------------------------------
588 dnl Note: we may not have objdump on OS X, and we only need it on
589 dnl Windows (for DLL checks), OpenBSD, and AIX
590 case $HostOS_CPP in
591   cygwin32|mingw32|openbsd|aix)
592     AC_CHECK_TARGET_TOOL([OBJDUMP], [objdump])
593     ;;
594 esac
595
596 ObjdumpCmd="$OBJDUMP"
597 AC_SUBST([ObjdumpCmd])
598
599 dnl ** Which ranlib to use?
600 dnl --------------------------------------------------------------
601 AC_PROG_RANLIB
602 if test "$RANLIB" = ":"; then
603     AC_MSG_ERROR([cannot find ranlib in your PATH])
604 fi
605 RanlibCmd="$RANLIB"
606 RANLIB="$RanlibCmd"
607
608 dnl ** which libtool to use?
609 dnl --------------------------------------------------------------
610 # The host normalization on Windows breaks autoconf, it no longer
611 # thinks that target == host so it never checks the unqualified
612 # tools for Windows. I don't know why we do this whole normalization thing
613 # as it just breaks everything.. but for now, just check the unqualified one
614 # if on Windows.
615 if test "$HostOS" = "mingw32"
616 then
617     AC_PATH_PROG([LIBTOOL],[libtool])
618     LibtoolCmd="$(cygpath -m $LIBTOOL)"
619 else
620     AC_CHECK_TARGET_TOOL([LIBTOOL], [libtool])
621     LibtoolCmd="$LIBTOOL"
622     LIBTOOL="$LibtoolCmd"
623 fi
624 AC_SUBST([LibtoolCmd])
625
626 # Here is where we re-target which specific version of the LLVM
627 # tools we are looking for. In the past, GHC supported a number of
628 # versions of LLVM simultaneously, but that stopped working around
629 # 3.5/3.6 release of LLVM.
630 LlvmVersion=4.0
631 AC_SUBST([LlvmVersion])
632 sUPPORTED_LLVM_VERSION=$(echo \($LlvmVersion\) | sed 's/\./,/')
633 AC_DEFINE_UNQUOTED([sUPPORTED_LLVM_VERSION], ${sUPPORTED_LLVM_VERSION}, [The supported LLVM version number])
634
635 dnl ** Which LLVM clang to use?
636 dnl --------------------------------------------------------------
637 AC_CHECK_TARGET_TOOL([CLANG], [clang])
638 ClangCmd="$CLANG"
639 AC_SUBST([ClangCmd])
640
641 dnl ** Which LLVM llc to use?
642 dnl --------------------------------------------------------------
643 FIND_LLVM_PROG([LLC], [llc], [$LlvmVersion])
644 LlcCmd="$LLC"
645 AC_SUBST([LlcCmd])
646
647 dnl ** Which LLVM opt to use?
648 dnl --------------------------------------------------------------
649 FIND_LLVM_PROG([OPT], [opt], [$LlvmVersion])
650 OptCmd="$OPT"
651 AC_SUBST([OptCmd])
652
653 dnl --------------------------------------------------------------
654 dnl End of configure script option section
655 dnl --------------------------------------------------------------
656
657
658 dnl --------------------------------------------------------------
659 dnl ** Can the unix package be built?
660 dnl --------------------------------------------------------------
661
662 if test "$TargetOS" = "mingw32"
663 then
664     GhcLibsWithUnix=NO
665 else
666     GhcLibsWithUnix=YES
667 fi
668 AC_SUBST([GhcLibsWithUnix])
669
670 dnl ** does #! work?
671 AC_SYS_INTERPRETER()
672
673 # Check for split-objs
674 SplitObjsBroken=NO
675 dnl ** look for `perl'
676 case $HostOS_CPP in
677 cygwin32|mingw32)
678   if test "$EnableDistroToolchain" = "NO"; then
679     PerlCmd=$hardtop/inplace/perl/perl
680   else
681     AC_PATH_PROG([PerlCmd],[perl])
682   fi
683   ;;
684 *)
685     AC_PATH_PROG([PerlCmd],[perl])
686     if test -z "$PerlCmd"
687     then
688         AC_MSG_WARN([No Perl on PATH, disabling split object support])
689         SplitObjsBroken=YES
690     else
691         FPTOOLS_CHECK_PERL_VERSION
692     fi
693     ;;
694 esac
695 AC_SUBST([SplitObjsBroken])
696
697 dnl ** look for GCC and find out which version
698 dnl     Figure out which C compiler to use.  Gcc is preferred.
699 dnl     If gcc, make sure it's at least 3.0
700 dnl
701 FP_GCC_VERSION
702
703 dnl ** See whether gcc supports -no-pie
704 FP_GCC_SUPPORTS_NO_PIE
705
706 dnl ** look to see if we have a C compiler using an llvm back end.
707 dnl
708 FP_CC_LLVM_BACKEND
709
710 FP_PROG_LD_IS_GNU
711 FP_PROG_LD_BUILD_ID
712 FP_PROG_LD_NO_COMPACT_UNWIND
713 FP_PROG_LD_FILELIST
714
715 FPTOOLS_SET_C_LD_FLAGS([target],[CFLAGS],[LDFLAGS],[IGNORE_LINKER_LD_FLAGS],[CPPFLAGS])
716 FPTOOLS_SET_C_LD_FLAGS([build],[CONF_CC_OPTS_STAGE0],[CONF_GCC_LINKER_OPTS_STAGE0],[CONF_LD_LINKER_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
717 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE1],[CONF_GCC_LINKER_OPTS_STAGE1],[CONF_LD_LINKER_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
718 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE2],[CONF_GCC_LINKER_OPTS_STAGE2],[CONF_LD_LINKER_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])
719 # Stage 3 won't be supported by cross-compilation
720
721 FP_GCC_EXTRA_FLAGS
722
723 # See rules/distdir-way-opts.mk for details.
724 # Flags passed to the C compiler
725 AC_SUBST(CONF_CC_OPTS_STAGE0)
726 AC_SUBST(CONF_CC_OPTS_STAGE1)
727 AC_SUBST(CONF_CC_OPTS_STAGE2)
728 # Flags passed to the C compiler when we ask it to link
729 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE0)
730 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE1)
731 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE2)
732 # Flags passed to the linker when we ask it to link
733 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE0)
734 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE1)
735 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE2)
736 # Flags passed to the C preprocessor
737 AC_SUBST(CONF_CPP_OPTS_STAGE0)
738 AC_SUBST(CONF_CPP_OPTS_STAGE1)
739 AC_SUBST(CONF_CPP_OPTS_STAGE2)
740 # Flags passed to the Haskell compiler
741 AC_SUBST(CONF_HC_OPTS_STAGE0)
742 AC_SUBST(CONF_HC_OPTS_STAGE1)
743 AC_SUBST(CONF_HC_OPTS_STAGE2)
744
745 dnl ** Set up the variables for the platform in the settings file.
746 dnl May need to use gcc to find platform details.
747 dnl --------------------------------------------------------------
748 FPTOOLS_SET_HASKELL_PLATFORM_VARS
749
750 dnl ** figure out how to do context diffs
751 FP_PROG_CONTEXT_DIFF
752
753 dnl Let's make sure install-sh is executable here.  If we got it from
754 dnl a darcs repo, it might not be (see bug #978).
755 chmod +x install-sh
756 dnl ** figure out how to do a BSD-ish install
757 AC_PROG_INSTALL
758
759 dnl ** how to invoke `ar' and `ranlib'
760 FP_PROG_AR_SUPPORTS_ATFILE
761 FP_PROG_AR_NEEDS_RANLIB
762
763 dnl ** Check to see whether ln -s works
764 AC_PROG_LN_S
765
766 FP_SETTINGS
767
768 dnl ** Find the path to sed
769 AC_PATH_PROGS(SedCmd,gsed sed,sed)
770
771
772 dnl ** check for time command
773 AC_PATH_PROG(TimeCmd,time)
774
775 dnl ** check for tar
776 dnl   if GNU tar is named gtar, look for it first.
777 AC_PATH_PROGS(TarCmd,gnutar gtar tar,tar)
778
779 dnl ** check for compressors
780 AC_PATH_PROGS(Bzip2Cmd,bzip2, bzip2)
781 AC_PATH_PROGS(GzipCmd,gzip, gzip)
782 AC_PATH_PROGS(XzCmd,pxz xz, xz)
783
784 dnl ** check for patch
785 dnl if GNU patch is named gpatch, look for it first
786 AC_PATH_PROGS(PatchCmd,gpatch patch, patch)
787
788 dnl ** check for dtrace (currently only implemented for Mac OS X)
789 HaveDtrace=NO
790 AC_PATH_PROG(DtraceCmd,dtrace)
791 if test -n "$DtraceCmd"; then
792   if test "x$TargetOS_CPP-$TargetVendor_CPP" = "xdarwin-apple" -o "x$TargetOS_CPP-$TargetVendor_CPP" = "xsolaris2-unknown"; then
793     HaveDtrace=YES
794   fi
795 fi
796 AC_SUBST(HaveDtrace)
797
798 AC_PATH_PROG(HSCOLOUR,HsColour)
799 # HsColour is passed to Cabal, so we need a native path
800 if test "$HostOS"      = "mingw32" && \
801    test "${OSTYPE}"   != "msys"    && \
802    test "${HSCOLOUR}" != ""
803 then
804     # Canonicalise to <drive>:/path/to/gcc
805     HSCOLOUR=`cygpath -m ${HSCOLOUR}`
806 fi
807
808 dnl ** check for Sphinx toolchain
809 AC_PATH_PROG(SPHINXBUILD,sphinx-build)
810 AC_CACHE_CHECK([for version of sphinx-build], fp_cv_sphinx_version,
811 changequote(, )dnl
812 [if test -n "$SPHINXBUILD"; then
813   fp_cv_sphinx_version=`"$SPHINXBUILD" --version 2>&1 | sed 's/Sphinx\( (sphinx-build)\)\? v\?\([0-9]\.[0-9]\.[0-9]\)/\2/' | head -n1`;
814 fi;
815 changequote([, ])dnl
816 ])
817 FP_COMPARE_VERSIONS([$fp_cv_sphinx_version],-lt,1.0.0,
818     [AC_MSG_WARN([Sphinx version 1.0.0 or later is required to build documentation]); SPHINXBUILD=;])
819
820 dnl ** check for xelatex
821 AC_PATH_PROG(XELATEX,xelatex)
822
823 dnl ** check for ghc-pkg command
824 FP_PROG_GHC_PKG
825
826 dnl ** check for installed happy binary + version
827 FPTOOLS_HAPPY
828
829 dnl ** check for installed alex binary + version
830 FPTOOLS_ALEX
831
832 dnl --------------------------------------------------
833 dnl ### program checking section ends here ###
834 dnl --------------------------------------------------
835
836 dnl --------------------------------------------------
837 dnl * Platform header file and syscall feature tests
838 dnl ### checking the state of the local header files and syscalls ###
839
840 dnl ** check for full ANSI header (.h) files
841 AC_HEADER_STDC
842
843 dnl ** Enable large file support.  NB. do this before testing the type of
844 dnl    off_t, because it will affect the result of that test.
845 AC_SYS_LARGEFILE
846
847 dnl ** check for specific header (.h) files that we are interested in
848 AC_CHECK_HEADERS([ctype.h dirent.h dlfcn.h errno.h fcntl.h grp.h limits.h locale.h nlist.h pthread.h pwd.h signal.h sys/param.h sys/mman.h sys/resource.h sys/select.h sys/time.h sys/timeb.h sys/timerfd.h sys/timers.h sys/times.h sys/utsname.h sys/wait.h termios.h time.h utime.h windows.h winsock.h sched.h])
849
850 dnl sys/cpuset.h needs sys/param.h to be included first on FreeBSD 9.1; #7708
851 AC_CHECK_HEADERS([sys/cpuset.h], [], [],
852 [[#if HAVE_SYS_PARAM_H
853 # include <sys/param.h>
854 #endif
855 ]])
856
857 dnl ** check if it is safe to include both <time.h> and <sys/time.h>
858 AC_HEADER_TIME
859
860 dnl ** do we have long longs?
861 AC_CHECK_TYPES([long long])
862
863 dnl ** what are the sizes of various types
864 FP_CHECK_SIZEOF_AND_ALIGNMENT(char)
865 FP_CHECK_SIZEOF_AND_ALIGNMENT(double)
866 FP_CHECK_SIZEOF_AND_ALIGNMENT(float)
867 FP_CHECK_SIZEOF_AND_ALIGNMENT(int)
868 FP_CHECK_SIZEOF_AND_ALIGNMENT(long)
869 if test "$ac_cv_type_long_long" = yes; then
870 FP_CHECK_SIZEOF_AND_ALIGNMENT(long long)
871 fi
872 FP_CHECK_SIZEOF_AND_ALIGNMENT(short)
873 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned char)
874 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned int)
875 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned long)
876 if test "$ac_cv_type_long_long" = yes; then
877 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned long long)
878 fi
879 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned short)
880 FP_CHECK_SIZEOF_AND_ALIGNMENT(void *)
881
882 FP_CHECK_SIZEOF_AND_ALIGNMENT(int8_t)
883 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint8_t)
884 FP_CHECK_SIZEOF_AND_ALIGNMENT(int16_t)
885 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint16_t)
886 FP_CHECK_SIZEOF_AND_ALIGNMENT(int32_t)
887 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint32_t)
888 FP_CHECK_SIZEOF_AND_ALIGNMENT(int64_t)
889 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint64_t)
890
891
892 dnl for use in settings.in
893 TargetWordSize=$ac_cv_sizeof_void_p
894 AC_SUBST(TargetWordSize)
895 FP_CHECK_FUNC([WinExec],
896   [@%:@include <windows.h>], [WinExec("",0)])
897
898 FP_CHECK_FUNC([GetModuleFileName],
899   [@%:@include <windows.h>], [GetModuleFileName((HMODULE)0,(LPTSTR)0,0)])
900
901 dnl ** check for more functions
902 dnl ** The following have been verified to be used in ghc/, but might be used somewhere else, too.
903 AC_CHECK_FUNCS([getclock getrusage gettimeofday setitimer siginterrupt sysconf times ctime_r sched_setaffinity setlocale])
904
905 dnl ** On OS X 10.4 (at least), time.h doesn't declare ctime_r if
906 dnl ** _POSIX_C_SOURCE is defined
907 AC_CHECK_DECLS([ctime_r], , ,
908 [#define _POSIX_SOURCE 1
909 #define _POSIX_C_SOURCE 199506L
910 #include <time.h>])
911
912 dnl ** check for mingwex library
913 AC_CHECK_LIB(mingwex, closedir, HaveLibMingwEx=YES, HaveLibMingwEx=NO)
914 AC_SUBST(HaveLibMingwEx)
915
916 if test $HaveLibMingwEx = YES ; then
917   AC_DEFINE([HAVE_MINGWEX], [1], [Define to 1 if you have the mingwex library.])
918 fi
919
920 dnl ** check for math library
921 dnl    Keep that check as early as possible.
922 dnl    as we need to know whether we need libm
923 dnl    for math functions or not
924 dnl    (see http://ghc.haskell.org/trac/ghc/ticket/3730)
925 AC_CHECK_LIB(m, atan, HaveLibM=YES, HaveLibM=NO)
926 if test $HaveLibM = YES
927 then
928   AC_DEFINE([HAVE_LIBM], [1], [Define to 1 if you need to link with libm])
929 fi
930
931 FP_BFD_SUPPORT
932
933 dnl ################################################################
934 dnl Check for libraries
935 dnl ################################################################
936
937 # system libffi
938
939 AC_ARG_WITH([system-libffi],
940 [AC_HELP_STRING([--with-system-libffi],
941   [Use system provided libffi for RTS [default=no]])
942 ])
943
944 AS_IF([test "x$with_system_libffi" = "xyes"],
945   [UseSystemLibFFI="YES"], [UseSystemLibFFI="NO"]
946 )
947
948
949 AC_SUBST(UseSystemLibFFI)
950
951 AC_ARG_WITH([ffi-includes],
952 [AC_HELP_STRING([--with-ffi-includes=ARG],
953   [Find includes for libffi in ARG [default=system default]])
954 ],
955 [
956  if test "x$UseSystemLibFFI" != "xYES"; then
957     AC_MSG_WARN([--with-ffi-includes will be ignored, --with-system-libffi not set])
958  else
959     FFIIncludeDir="$withval"
960     LIBFFI_CFLAGS="-I$withval"
961  fi
962 ])
963
964 AC_SUBST(FFIIncludeDir)
965
966 AC_ARG_WITH([ffi-libraries],
967 [AC_HELP_STRING([--with-ffi-libraries=ARG],
968   [Find libffi in ARG [default=system default]])
969 ],
970 [
971  if test "x$UseSystemLibFFI" != "xYES"; then
972     AC_MSG_WARN([--with-ffi-libraries will be ignored, --with-system-libffi not set])
973  else
974     FFILibDir="$withval" LIBFFI_LDFLAGS="-L$withval"
975  fi
976 ])
977
978 AC_SUBST(FFILibDir)
979
980 AS_IF([test "$UseSystemLibFFI" = "YES"], [
981  CFLAGS2="$CFLAGS"
982  CFLAGS="$LIBFFI_CFLAGS $CFLAGS"
983  LDFLAGS2="$LDFLAGS"
984  LDFLAGS="$LIBFFI_LDFLAGS $LDFLAGS"
985  if test "$HostOS" = "openbsd";
986  then
987    # OpenBSD's libffi is not directly linked to the libpthread but
988    # still requires pthread functionality. This means that any client
989    # binary which links with libffi also needs to link with
990    # libpthread. If it does not, then linking fails with unresolved
991    # symbols.
992    LDFLAGS="$LDFLAGS -lpthread"
993  fi
994  AC_CHECK_LIB(ffi, ffi_call,
995   [AC_CHECK_HEADERS([ffi.h], [break], [])
996    AC_DEFINE([HAVE_LIBFFI], [1], [Define to 1 if you have libffi.])],
997   [AC_MSG_ERROR([Cannot find system libffi])])
998  CFLAGS="$CFLAGS2"
999  LDFLAGS="$LDFLAGS2"
1000 ])
1001
1002 dnl ** check whether we need -ldl to get dlopen()
1003 AC_CHECK_LIB(dl, dlopen)
1004
1005 dnl --------------------------------------------------
1006 dnl * Miscellaneous feature tests
1007 dnl --------------------------------------------------
1008
1009 dnl ** can we get alloca?
1010 AC_FUNC_ALLOCA
1011
1012 dnl ** working vfork?
1013 AC_FUNC_FORK
1014
1015 dnl ** determine whether or not const works
1016 AC_C_CONST
1017
1018 dnl ** are we big endian?
1019 AC_C_BIGENDIAN
1020 FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN
1021
1022 dnl ** check for leading underscores in symbol names
1023 FP_LEADING_UNDERSCORE
1024
1025 FP_VISIBILITY_HIDDEN
1026
1027 dnl ** check for librt
1028 AC_CHECK_LIB(rt, clock_gettime)
1029 AC_CHECK_FUNCS(clock_gettime timer_settime)
1030 FP_CHECK_TIMER_CREATE
1031
1032 dnl ** check for Apple's "interesting" long double compatibility scheme
1033 AC_MSG_CHECKING(for printf\$LDBLStub)
1034 AC_TRY_LINK_FUNC(printf\$LDBLStub,
1035     [
1036         AC_MSG_RESULT(yes)
1037         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[1],
1038             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
1039     ],
1040     [
1041         AC_MSG_RESULT(no)
1042         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[0],
1043             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
1044     ])
1045
1046 dnl Some platforms (e.g. Android's Bionic) have pthreads support available
1047 dnl without linking against libpthread. Check whether -lpthread is necessary
1048 dnl to use pthreads.
1049 dnl
1050 dnl Note that it is important that this happens before we AC_CHECK_LIB(thread)
1051 AC_MSG_CHECKING(whether -lpthread is needed for pthreads)
1052 AC_CHECK_FUNC(pthread_create,
1053     [
1054         AC_MSG_RESULT(no)
1055         need_lpthread=0
1056     ],
1057     [
1058         AC_CHECK_LIB(pthread, pthread_create,
1059             [
1060                 AC_MSG_RESULT(yes)
1061                 need_lpthread=1
1062             ],
1063             [
1064                 AC_MSG_RESULT([no pthreads support found.])
1065                 need_lpthread=0
1066             ])
1067     ])
1068 AC_DEFINE_UNQUOTED([NEED_PTHREAD_LIB], [$need_lpthread],
1069     [Define 1 if we need to link code using pthreads with -lpthread])
1070
1071 dnl ** pthread_setname_np is a recent addition to glibc, and OS X has
1072 dnl    a different single-argument version.
1073 AC_CHECK_LIB(pthread, pthread_setname_np)
1074 AC_MSG_CHECKING(for pthread_setname_np)
1075 AC_TRY_LINK(
1076 [
1077 #define _GNU_SOURCE
1078 #include <pthread.h>
1079 ],
1080 [pthread_setname_np(pthread_self(), "name");],
1081     AC_MSG_RESULT(yes)
1082     AC_DEFINE([HAVE_PTHREAD_SETNAME_NP], [1],
1083       [Define to 1 if you have the glibc version of pthread_setname_np]),
1084     AC_MSG_RESULT(no)
1085 )
1086
1087 dnl ** check for eventfd which is needed by the I/O manager
1088 AC_CHECK_HEADERS([sys/eventfd.h])
1089 AC_CHECK_FUNCS([eventfd])
1090
1091 dnl ** Check for __thread support in the compiler
1092 AC_MSG_CHECKING(for __thread support)
1093 AC_COMPILE_IFELSE(
1094   [ AC_LANG_SOURCE([[__thread int tester = 0;]]) ],
1095   [
1096    AC_MSG_RESULT(yes)
1097    AC_DEFINE([CC_SUPPORTS_TLS],[1],[Define to 1 if __thread is supported])
1098   ],
1099   [
1100    AC_MSG_RESULT(no)
1101    AC_DEFINE([CC_SUPPORTS_TLS],[0],[Define to 1 if __thread is supported])
1102   ])
1103
1104 dnl large address space support (see includes/rts/storage/MBlock.h)
1105 dnl
1106 dnl Darwin has vm_allocate/vm_protect
1107 dnl Linux has mmap(MAP_NORESERVE)/madv(MADV_DONTNEED)
1108 dnl FreeBSD, Solaris and maybe other have MAP_NORESERVE/MADV_FREE
1109 dnl (They also have MADV_DONTNEED, but it means something else!)
1110 dnl
1111 dnl Windows has VirtualAlloc MEM_RESERVE/MEM_COMMIT, however
1112 dnl it counts page-table space as committed memory, and so quickly
1113 dnl runs out of paging file when we have multiple processes reserving
1114 dnl 1TB of address space, we get the following error:
1115 dnl    VirtualAlloc MEM_RESERVE 1099512676352 bytes failed: The paging file is too small for this operation to complete.
1116 dnl
1117
1118 AC_ARG_ENABLE(large-address-space,
1119     [AC_HELP_STRING([--enable-large-address-space],
1120         [Use a single large address space on 64 bit systems (enabled by default on 64 bit platforms)])],
1121     EnableLargeAddressSpace=$enableval,
1122     EnableLargeAddressSpace=yes
1123 )
1124
1125 use_large_address_space=no
1126 if test "$ac_cv_sizeof_void_p" -eq 8 ; then
1127     if test "x$EnableLargeAddressSpace" = "xyes" ; then
1128         if test "$ghc_host_os" = "darwin" ; then
1129             use_large_address_space=yes
1130         elif test "$ghc_host_os" = "openbsd" ; then
1131             # as of OpenBSD 5.8 (2015), OpenBSD does not support mmap with MAP_NORESERVE.
1132             # The flag MAP_NORESERVE is supported for source compatibility reasons,
1133             # but is completely ignored by OS mmap
1134             use_large_address_space=no
1135         else
1136             AC_CHECK_DECLS([MAP_NORESERVE, MADV_FREE, MADV_DONTNEED],[],[],
1137                 [
1138                 #include <unistd.h>
1139                 #include <sys/types.h>
1140                 #include <sys/mman.h>
1141                 #include <fcntl.h>
1142             ])
1143             if test "$ac_cv_have_decl_MAP_NORESERVE" = "yes" &&
1144                 test "$ac_cv_have_decl_MADV_FREE" = "yes" ||
1145                 test "$ac_cv_have_decl_MADV_DONTNEED" = "yes" ; then
1146                     use_large_address_space=yes
1147             fi
1148         fi
1149     fi
1150 fi
1151 if test "$use_large_address_space" = "yes" ; then
1152    AC_DEFINE([USE_LARGE_ADDRESS_SPACE], [1], [Enable single heap address space support])
1153 fi
1154
1155 dnl ** Use MMAP in the runtime linker?
1156 dnl --------------------------------------------------------------
1157
1158 case ${TargetOS} in
1159     linux|linux-android|freebsd|dragonfly|netbsd|openbsd|kfreebsdgnu|gnu|solaris2)
1160         RtsLinkerUseMmap=1
1161         ;;
1162     darwin|ios)
1163         # Don't use mmap on powerpc/darwin as the mmap there doesn't support
1164         # reallocating. Reallocating is needed to allocate jump islands just
1165         # after each object image. Jumps to these jump islands use relative
1166         # branches which are limited to offsets that can be represented in
1167         # 24-bits.
1168         if test "$TargetArch" != "powerpc" ; then
1169             RtsLinkerUseMmap=1
1170         else
1171             RtsLinkerUseMmap=0
1172         fi
1173         ;;
1174     *)
1175         # Windows (which doesn't have mmap) and everything else.
1176         RtsLinkerUseMmap=0
1177         ;;
1178     esac
1179
1180 AC_DEFINE_UNQUOTED([RTS_LINKER_USE_MMAP], [$RtsLinkerUseMmap],
1181                    [Use mmap in the runtime linker])
1182
1183 dnl ** Have libdw?
1184 dnl --------------------------------------------------------------
1185 UseLibdw=NO
1186 USE_LIBDW=0
1187 AC_ARG_ENABLE(dwarf-unwind,
1188     [AC_HELP_STRING([--enable-dwarf-unwind],
1189         [Enable DWARF unwinding support in the runtime system via elfutils' libdw [default=no]])],
1190     [AC_CHECK_LIB(dw, dwfl_attach_state, [UseLibdw=YES], [UseLibdw=NO])],
1191     [UseLibdw=NO]
1192 )
1193 AC_SUBST(UseLibdw)
1194 if test $UseLibdw = "YES" ; then
1195         USE_LIBDW=1
1196 fi
1197 AC_DEFINE_UNQUOTED([USE_LIBDW], [$USE_LIBDW], [Set to 1 to use libdw])
1198
1199 dnl ** Have libnuma?
1200 dnl --------------------------------------------------------------
1201 HaveLibNuma=0
1202 AC_CHECK_HEADERS([numa.h numaif.h])
1203
1204 if test "$ac_cv_header_numa_h$ac_cv_header_numaif_h" = "yesyes" ; then
1205     AC_CHECK_LIB(numa, numa_available,HaveLibNuma=1)
1206 fi
1207 AC_DEFINE_UNQUOTED([HAVE_LIBNUMA], [$HaveLibNuma], [Define to 1 if you have libnuma])
1208
1209 dnl ** Documentation
1210 dnl --------------------------------------------------------------
1211 if test -n "$SPHINXBUILD"; then
1212     BUILD_MAN=YES
1213     BUILD_SPHINX_HTML=YES
1214     if test -n "$XELATEX"; then
1215         BUILD_SPHINX_PDF=YES
1216     else
1217         BUILD_SPHINX_PDF=NO
1218     fi
1219 else
1220     BUILD_MAN=NO
1221     BUILD_SPHINX_HTML=NO
1222     BUILD_SPHINX_PDF=NO
1223 fi
1224 AC_SUBST(BUILD_MAN)
1225 AC_SUBST(BUILD_SPHINX_HTML)
1226 AC_SUBST(BUILD_SPHINX_PDF)
1227
1228 LIBRARY_VERSION(base)
1229 LIBRARY_VERSION(Cabal, Cabal/Cabal)
1230 LIBRARY_VERSION(ghc-prim)
1231 LIBRARY_VERSION(ghc-compact)
1232 LIBRARY_ghc_VERSION="$ProjectVersion"
1233 AC_SUBST(LIBRARY_ghc_VERSION)
1234
1235 if grep '       ' compiler/ghc.cabal.in 2>&1 >/dev/null; then
1236    AC_MSG_ERROR([compiler/ghc.cabal.in contains tab characters; please remove them])
1237 fi
1238
1239 # Create the configuration for the Hadrian build system if it is present
1240 if test -e hadrian/cfg/system.config.in; then
1241     AC_CONFIG_FILES([hadrian/cfg/system.config])
1242 fi
1243
1244 # We got caught by
1245 #     http://savannah.gnu.org/bugs/index.php?1516
1246 #     $(eval ...) inside conditionals causes errors
1247 # with make 3.80, so warn the user if it looks like they're about to
1248 # try to use it.
1249 # We would use "grep -q" here, but Solaris's grep doesn't support it.
1250 print_make_warning=""
1251 checkMake380() {
1252     make_ver=`$1 --version 2>&1 | head -1`
1253     if echo "$make_ver" | grep 'GNU Make 3\.80' > /dev/null
1254     then
1255         print_make_warning="true"
1256     fi
1257     if echo "$make_ver" | grep 'GNU Make' > /dev/null
1258     then
1259         MakeCmd=$1
1260         AC_SUBST(MakeCmd)
1261     fi
1262 }
1263
1264 checkMake380 make
1265 checkMake380 gmake
1266
1267 AC_CONFIG_FILES([mk/config.mk mk/install.mk mk/project.mk compiler/ghc.cabal ghc/ghc-bin.cabal utils/runghc/runghc.cabal utils/gen-dll/gen-dll.cabal libraries/ghc-boot/ghc-boot.cabal libraries/ghc-boot-th/ghc-boot-th.cabal libraries/ghci/ghci.cabal settings docs/users_guide/ghc_config.py docs/index.html libraries/prologue.txt distrib/configure.ac])
1268 AC_OUTPUT
1269 [
1270 if test "$print_make_warning" = "true"; then
1271    echo
1272    echo "WARNING: It looks like \"$MakeCmd\" is GNU make 3.80."
1273    echo "This version cannot be used to build GHC."
1274    echo "Please use GNU make >= 3.81."
1275 fi
1276
1277 echo "
1278 ----------------------------------------------------------------------
1279 Configure completed successfully.
1280
1281    Building GHC version  : $ProjectVersion
1282           Git commit id  : $ProjectGitCommitId
1283
1284    Build platform        : $BuildPlatform
1285    Host platform         : $HostPlatform
1286    Target platform       : $TargetPlatform
1287 "
1288
1289 echo "\
1290    Bootstrapping using   : $WithGhc
1291       which is version   : $GhcVersion
1292 "
1293
1294 if test "x$CC_LLVM_BACKEND" = "x1"; then
1295     if test "x$CC_CLANG_BACKEND" = "x1"; then
1296         CompilerName="clang        "
1297     else
1298         CompilerName="llvm-gcc     "
1299     fi
1300 else
1301     CompilerName="gcc          "
1302 fi
1303
1304 echo "\
1305    Using (for bootstrapping) : $CC_STAGE0
1306    Using $CompilerName       : $CC
1307       which is version       : $GccVersion
1308    Building a cross compiler : $CrossCompiling
1309    Unregisterised            : $Unregisterised
1310    hs-cpp       : $HaskellCPPCmd
1311    hs-cpp-flags : $HaskellCPPArgs
1312    ar           : $ArCmd
1313    ld           : $LdCmd
1314    nm           : $NmCmd
1315    libtool      : $LibtoolCmd
1316    objdump      : $ObjdumpCmd
1317    ranlib       : $RanlibCmd
1318    windres      : $WindresCmd
1319    dllwrap      : $DllWrapCmd
1320    genlib       : $GenlibCmd
1321    Happy        : $HappyCmd ($HappyVersion)
1322    Alex         : $AlexCmd ($AlexVersion)
1323    Perl         : $PerlCmd
1324    sphinx-build : $SPHINXBUILD
1325    xelatex      : $XELATEX
1326
1327    Using LLVM tools
1328       clang : $ClangCmd
1329       llc   : $LlcCmd
1330       opt   : $OptCmd"
1331
1332 if test "$HSCOLOUR" = ""; then
1333 echo "
1334    HsColour was not found; documentation will not contain source links
1335 "
1336 else
1337 echo "\
1338    HsColour : $HSCOLOUR
1339 "
1340 fi
1341
1342 echo "\
1343    Tools to build Sphinx HTML documentation available: $BUILD_SPHINX_HTML
1344    Tools to build Sphinx PDF documentation available: $BUILD_SPHINX_PDF"
1345
1346 echo "----------------------------------------------------------------------
1347 "
1348
1349 echo "\
1350 For a standard build of GHC (fully optimised with profiling), type (g)make.
1351
1352 To make changes to the default build configuration, copy the file
1353 mk/build.mk.sample to mk/build.mk, and edit the settings in there.
1354
1355 For more information on how to configure your GHC build, see
1356    http://ghc.haskell.org/trac/ghc/wiki/Building
1357 "]