[project @ 2003-08-20 15:44:18 by panne]
[ghc.git] / aclocal.m4
1 # Extra autoconf macros for the Glasgow fptools
2 #
3 # To be a good autoconf citizen, names of local macros have prefixed with FP_ to
4 # ensure we don't clash with any pre-supplied autoconf ones.
5
6
7 # FP_EVAL_STDERR(COMMAND)
8 # ------------------------
9 # Eval COMMAND, save its stderr (without lines resulting from shell tracing)
10 # into the file conftest.err and the exit status in the variable fp_status.
11 AC_DEFUN([FP_EVAL_STDERR],
12 [{ (eval $1) 2>conftest.er1
13   fp_status=$?
14   grep -v '^ *+' conftest.er1 >conftest.err
15   rm -f conftest.er1
16   (exit $fp_status); }[]dnl
17 ])# FP_EVAL_STDERR
18
19
20 # FP_CHECK_FLAG(FLAG, [ACTION-IF-SUPPORTED], [ACTION-IF-NOT-SUPPORTED])
21 # -----------------------------------------------------------------------
22 # Check to see whether the compiler for the current language supports a
23 # particular option.
24 #
25 # Implementation note: When given an unkown option, GCC issues an warning on
26 # stderr only, but returns an exit value of 0 nevertheless. Consequently we have
27 # to check stderr *and* the exit value.
28 #
29 # Used by ghc.
30 AC_DEFUN(FP_CHECK_FLAG,
31 [AC_LANG_COMPILER_REQUIRE()dnl
32 AC_LANG_CASE([C],          [fp_compiler="$CC"  m4_pushdef([fp_Flags], [CFLAGS])],
33              [C++],        [fp_compiler="$CXX" m4_pushdef([fp_Flags], [CXXFLAGS])],
34              [Fortran 77], [fp_compiler="$F77" m4_pushdef([fp_Flags], [FFLAGS])])
35 m4_pushdef([fp_Cache], [fp_cv_[]fp_Flags[]AS_TR_SH([$1])])[]dnl
36 AC_CACHE_CHECK([whether $fp_compiler accepts $1], [fp_Cache],
37 [AC_LANG_CONFTEST([AC_LANG_PROGRAM()])
38 fp_save_flags="$fp_Flags"
39 fp_Flags="$fp_Flags $1"
40 fp_Cache=no
41 if FP_EVAL_STDERR([$ac_compile conftest.$ac_ext]) >/dev/null; then
42   test -s conftest.err || fp_Cache=yes
43 fi
44 fp_Flags="$fp_save_flags"
45 rm -f conftest.err conftest.$ac_ext])
46 AS_IF([test $fp_Cache = yes], [$2], [$3])[]dnl
47 m4_popdef([fp_Cache])[]dnl
48 m4_popdef([fp_Flags])[]dnl
49 ])# FP_CHECK_FLAG
50
51
52 # FP_PROG_CONTEXT_DIFF
53 # --------------------
54 # Figure out how to do context diffs. Sets the output variable ContextDiffCmd.
55 #
56 # Note: NeXTStep thinks diff'ing a file against itself is "trouble".
57 #
58 # Used by ghc, glafp-utils/ltx, and glafp-utils/runstdtest.
59 AC_DEFUN([FP_PROG_CONTEXT_DIFF],
60 [AC_CACHE_CHECK([for a working context diff], [fp_cv_context_diff],
61 [echo foo > conftest1
62 echo foo > conftest2
63 fp_cv_context_diff=no
64 for fp_var in '-C 1' '-c1'
65 do
66   if diff $fp_var conftest1 conftest2 > /dev/null 2>&1; then
67     fp_cv_context_diff="diff $fp_var"
68     break
69   fi
70 done])
71 if test x"$fp_cv_context_diff" = xno; then
72    AC_MSG_ERROR([cannot figure out how to do context diffs])
73 fi
74 AC_SUBST(ContextDiffCmd, [$fp_cv_context_diff])
75 ])# FP_PROG_CONTEXT_DIFF
76
77
78 # FP_DECL_ALTZONE
79 # -------------------
80 # Defines HAVE_DECL_ALTZONE to 1 if declared, 0 otherwise.
81 #
82 # Used by base package.
83 AC_DEFUN([FP_DECL_ALTZONE],
84 [AC_REQUIRE([AC_HEADER_TIME])dnl
85 AC_CHECK_HEADERS([sys/time.h])
86 AC_CHECK_DECLS([altzone], [], [],[#if TIME_WITH_SYS_TIME
87 # include <sys/time.h>
88 # include <time.h>
89 #else
90 # if HAVE_SYS_TIME_H
91 #  include <sys/time.h>
92 # else
93 #  include <time.h>
94 # endif
95 #endif])
96 ])# FP_DECL_ALTZONE
97
98
99 # FP_COMPUTE_INT(EXPRESSION, VARIABLE, INCLUDES, IF-FAILS)
100 # ---------------------------------------------------------
101 # Assign VARIABLE the value of the compile-time EXPRESSION using INCLUDES for
102 # compilation. Execute IF-FAILS when unable to determine the value. Works for
103 # cross-compilation, too.
104 #
105 # Implementation note: We are lazy and use an internal autoconf macro, but it
106 # is supported in autoconf versions 2.50 up to the actual 2.57, so there is
107 # little risk.
108 AC_DEFUN([FP_COMPUTE_INT],
109 [_AC_COMPUTE_INT([$1], [$2], [$3], [$4])[]dnl
110 ])# FP_COMPUTE_INT
111
112
113 # FP_CHECK_ALIGNMENT(TYPE, [IGNORED], [INCLUDES = DEFAULT-INCLUDES])
114 # ------------------------------------------------------------------
115 # A variation of AC_CHECK_SIZEOF for computing the alignment restrictions of a
116 # given type. Defines ALIGNMENT_TYPE.
117 AC_DEFUN([FP_CHECK_ALIGNMENT],
118 [AS_LITERAL_IF([$1], [],
119                [AC_FATAL([$0: requires literal arguments])])[]dnl
120 AC_CHECK_TYPE([$1], [], [], [$3])[]dnl
121 m4_pushdef([fp_Cache], [AS_TR_SH([fp_cv_alignment_$1])])[]dnl
122 AC_CACHE_CHECK([alignment of $1], [fp_Cache],
123 [if test "$AS_TR_SH([ac_cv_type_$1])" = yes; then
124   FP_COMPUTE_INT([(long) (&((struct { char c; $1 ty; } *)0)->ty)],
125                  [fp_Cache],
126                  [AC_INCLUDES_DEFAULT([$3])],
127                  [AC_MSG_ERROR([cannot compute alignment ($1)
128 See `config.log' for more details.], [77])])
129 else
130   fp_Cache=0
131 fi])[]dnl
132 AC_DEFINE_UNQUOTED(AS_TR_CPP(alignment_$1), $fp_Cache, [The alignment of a `$1'.])[]dnl
133 m4_popdef([fp_Cache])[]dnl
134 ])# FP_CHECK_ALIGNMENT
135
136
137 # FP_CHECK_CONST(EXPRESSION, [INCLUDES = DEFAULT-INCLUDES], [VALUE-IF-FAIL = (-1)])
138 # ---------------------------------------------------------------------------------
139 # Defines CONST_EXPRESSION to the value of the compile-time EXPRESSION, using
140 # INCLUDES. If the value cannot be determined, use VALUE-IF-FAIL.
141 AC_DEFUN([FP_CHECK_CONST],
142 [AS_VAR_PUSHDEF([fp_Cache], [fp_cv_const_$1])[]dnl
143 AC_CACHE_CHECK([value of $1], fp_Cache,
144 [FP_COMPUTE_INT([$1], fp_check_const_result, [AC_INCLUDES_DEFAULT([$2])],
145                 [fp_check_const_result=m4_default([$3], ['(-1)'])])
146 AS_VAR_SET(fp_Cache, [$fp_check_const_result])])[]dnl
147 AC_DEFINE_UNQUOTED(AS_TR_CPP([CONST_$1]), AS_VAR_GET(fp_Cache), [The value of $1.])[]dnl
148 AS_VAR_POPDEF([fp_Cache])[]dnl
149 ])# FP_CHECK_CONST
150
151
152 # FP_CHECK_CONSTS_TEMPLATE(EXPRESSION...)
153 # ----------------------------------
154 # autoheader helper for FP_CHECK_CONSTS
155 m4_define([FP_CHECK_CONSTS_TEMPLATE],
156 [AC_FOREACH([fp_Const], [$1],
157   [AH_TEMPLATE(AS_TR_CPP(CONST_[]fp_Const),
158                [The value of ]fp_Const[.])])[]dnl
159 ])# FP_CHECK_CONSTS_TEMPLATE
160
161
162 # FP_CHECK_CONSTS(EXPRESSION..., [INCLUDES = DEFAULT-INCLUDES], [VALUE-IF-FAIL = (-1)])
163 # -------------------------------------------------------------------------------------
164 # List version of FP_CHECK_CONST
165 AC_DEFUN(FP_CHECK_CONSTS,
166 [FP_CHECK_CONSTS_TEMPLATE([$1])dnl
167 for fp_const_name in $1
168 do
169 FP_CHECK_CONST([$fp_const_name], [$2], [$3])
170 done
171 ])# FP_CHECK_CONSTS
172
173
174 dnl ** check for leading underscores in symbol names
175 dnl 
176 dnl Test for determining whether symbol names have a leading
177 dnl underscore.
178 dnl 
179 dnl We assume that they _haven't_ if anything goes wrong.
180 dnl
181 dnl Some nlist implementations seem to try to be compatible by ignoring
182 dnl a leading underscore sometimes (eg. FreeBSD).  We therefore have
183 dnl to work around this by checking for *no* leading underscore first.
184 dnl Sigh.  --SDM
185 dnl
186 dnl Similarly on OpenBSD, but this test doesn't help. -- dons
187 dnl
188 AC_DEFUN(FPTOOLS_UNDERSCORE,
189 [AC_CHECK_LIB(elf, nlist, LIBS="-lelf $LIBS")dnl
190 AC_CACHE_CHECK([leading underscore in symbol names], fptools_cv_lead_uscore,
191
192 dnl
193 dnl Hack!: nlist() under Digital UNIX insist on there being an _,
194 dnl but symbol table listings shows none. What is going on here?!?
195 dnl
196 dnl Another hack: cygwin doesn't come with nlist.h , so we hardwire
197 dnl the underscoredness of that "platform"
198 changequote(<<, >>)dnl
199 <<
200 case $HostPlatform in
201 *openbsd*) # x86 openbsd is ELF from 3.4 >, meaning no leading uscore
202     case $build in
203         i386-*2\.[[0-9]] | i386-*3\.[[0-3]] ) fptools_cv_lead_uscore='yes' ;;
204         *)      fptools_cv_lead_uscore='no' ;;
205     esac ;;
206 alpha-dec-osf*) fptools_cv_lead_uscore='no';;
207 *cygwin32) fptools_cv_lead_uscore='yes';;
208 *mingw32) fptools_cv_lead_uscore='yes';;
209 *) >>
210 changequote([, ])dnl
211 AC_TRY_RUN([#ifdef HAVE_NLIST_H
212 #include <nlist.h>
213 changequote(<<, >>)dnl
214 <<
215 struct nlist xYzzY1[] = {{"xYzzY1", 0},{0}};
216 struct nlist xYzzY2[] = {{"_xYzzY2", 0},{0}};
217 #endif
218
219 main(argc, argv)
220 int argc;
221 char **argv;
222 {
223 #ifdef HAVE_NLIST_H
224     if(nlist(argv[0], xYzzY1) == 0 && xYzzY1[0].n_value != 0)
225         exit(1);
226     if(nlist(argv[0], xYzzY2) == 0 && xYzzY2[0].n_value != 0)
227         exit(0);>>
228 changequote([, ])dnl
229 #endif
230     exit(1);
231 }], fptools_cv_lead_uscore=yes, fptools_cv_lead_uscore=no, fptools_cv_lead_uscore=NO)
232 ;;
233 esac);
234 LeadingUnderscore=`echo $fptools_cv_lead_uscore | sed 'y/yesno/YESNO/'`
235 AC_SUBST(LeadingUnderscore)
236 case $LeadingUnderscore in
237 YES) AC_DEFINE([LEADING_UNDERSCORE], [1], [Define to 1 if C symbols have a leading underscore added by the compiler.]);;
238 esac
239 ])
240
241 dnl
242 dnl FPTOOLS_PROG_CHECK_VERSION(VERSIONSTR1, TEST, VERSIONSTR2,
243 dnl                            ACTION-IF-TRUE [, ACTION-IF-FALSE])
244 dnl
245 dnl compare versions field-wise (separator is '.')
246 dnl TEST is one of {-lt,-le,-eq,-ge,-gt}
247 dnl
248 dnl quite shell-independant and SUSv2 compliant code
249 dnl
250 dnl NOTE: the loop could be unrolled within autoconf, but the
251 dnl       macro code would be a) longer and b) harder to debug... ;)
252 dnl
253 AC_DEFUN(FPTOOLS_PROG_CHECK_VERSION,
254 [if ( IFS=".";
255       a="[$1]";  b="[$3]";
256       while test -n "$a$b"
257       do
258               set -- [$]a;  h1="[$]1";  shift 2>/dev/null;  a="[$]*"
259               set -- [$]b;  h2="[$]1";  shift 2>/dev/null;  b="[$]*"
260               test -n "[$]h1" || h1=0;  test -n "[$]h2" || h2=0
261               test [$]{h1} -eq [$]{h2} || break
262       done
263       test [$]{h1} [$2] [$]{h2}
264     )
265 then ifelse([$4],,[:],[
266   $4])
267 ifelse([$5],,,
268 [else
269   $5])
270 fi
271 ])])dnl
272
273
274 dnl
275 dnl Check for Greencard and version.
276 dnl
277 AC_DEFUN(FPTOOLS_GREENCARD,
278 [
279 AC_PATH_PROG(GreencardCmd,greencard)
280 AC_CACHE_CHECK([for version of greencard], fptools_cv_greencard_version,
281 changequote(, )dnl
282 [if test x"$GreencardCmd" != x; then
283    fptools_cv_greencard_version="`$GreencardCmd --version |
284                           grep 'version' | sed -e 's/greencard. version \([^ ]*\).*/\1/g'`"
285 else
286    fptools_cv_greencard_version=""
287 fi
288 changequote([, ])dnl
289 ])
290 FPTOOLS_PROG_CHECK_VERSION([$fptools_cv_greencard_version],-lt,$1,
291   [AC_MSG_ERROR([greencard version $1 or later is required (found '$fptools_cv_greencard_version')])])dnl
292 GreencardVersion=$fptools_cv_greencard_version
293 AC_SUBST(GreencardVersion)
294 ])
295
296 dnl
297 dnl Check for Happy and version.  If we're building GHC, then we need
298 dnl at least Happy version 1.13.  If there's no installed Happy, we look
299 dnl for a happy source tree and point the build system at that instead.
300 dnl
301 AC_DEFUN(FPTOOLS_HAPPY,
302 [
303 if test -d $srcdir/happy; then
304    SrcTreeHappyCmd=$hardtop/happy/src/happy-inplace
305 fi
306 if test x"$UseSrcTreeHappy" = xYES; then
307   HappyCmd=$SrcTreeHappyCmd
308 else
309   AC_PATH_PROG(HappyCmd,happy,$SrcTreeHappyCmd)
310 fi
311 AC_CACHE_CHECK([for version of happy], fptools_cv_happy_version,
312 changequote(, )dnl
313 [if test x"$HappyCmd" = x"$SrcTreeHappyCmd"; then
314    fptools_cv_happy_version=`grep '^ProjectVersion[     ]*=' $srcdir/happy/mk/version.mk | sed 's/.*\([0-9][0-9]*\.[0-9][0-9]*\).*/\1/g'`;
315 elif test x"$HappyCmd" != x; then
316    fptools_cv_happy_version="`$HappyCmd -v |
317                           grep 'Happy Version' | sed -e 's/Happy Version \([^ ]*\).*/\1/g'`" ;
318 else
319    fptools_cv_happy_version="";
320 fi;
321 changequote([, ])dnl
322 ])
323 if test -d $srcdir/ghc -a ! -f $srcdir/ghc/compiler/parser/Parser.hs; then
324   FPTOOLS_PROG_CHECK_VERSION([$fptools_cv_happy_version],-lt,[1.13],
325   [AC_MSG_ERROR([Happy version 1.13 or later is required to compile GHC.])])dnl
326 fi
327 HappyVersion=$fptools_cv_happy_version;
328 AC_SUBST(HappyVersion)
329 ])
330
331 dnl
332 dnl Check for Haddock and version.  If there's no installed Haddock, we look
333 dnl for a haddock source tree and point the build system at that instead.
334 dnl
335 AC_DEFUN(FPTOOLS_HADDOCK,
336 [
337 if test -d $srcdir/haddock; then
338    SrcTreeHaddockCmd=$hardtop/haddock/src/haddock-inplace
339 fi
340 if test x"$UseSrcTreeHaddock" = xYES; then
341   HaddockCmd=$SrcTreeHaddockCmd
342 else
343   AC_PATH_PROG(HaddockCmd,haddock,$SrcTreeHaddockCmd)
344 fi
345 dnl Darn, I forgot to make Haddock print out its version number when
346 dnl invoked with -v.  We could try generating some HTML and grepping
347 dnl through that to find the version number, but I think we'll make
348 dnl do without it for now.
349 ])
350
351 dnl
352 dnl Check for Alex and version.  If we're building GHC, then we need
353 dnl at least Alex version 2.0.  If there's no installed Alex, we look
354 dnl for a alex source tree and point the build system at that instead.
355 dnl
356 AC_DEFUN(FPTOOLS_ALEX,
357 [
358 if test -d $srcdir/alex; then
359    SrcTreeAlexCmd=$hardtop/alex/src/alex-inplace
360 fi
361 if test x"$UseSrcTreeAlex" = xYES; then
362   AlexCmd=$SrcTreeAlexCmd
363 else
364   AC_PATH_PROG(AlexCmd,alex,$SrcTreeAlexCmd)
365 fi
366 AC_CACHE_CHECK([for version of alex], fptools_cv_alex_version,
367 changequote(, )dnl
368 [if test x"$AlexCmd" = x"$SrcTreeAlexCmd"; then
369    fptools_cv_alex_version=`grep '^ProjectVersion[      ]*=' $srcdir/alex/mk/version.mk | sed 's/.*\([0-9][0-9]*\.[0-9][0-9]*\).*/\1/g'`;
370 elif test x"$AlexCmd" != x; then
371    fptools_cv_alex_version="`$AlexCmd -v |
372                           grep 'Alex [Vv]ersion' | sed -e 's/Alex [Vv]ersion \([0-9\.]*\).*/\1/g'`" ;
373 else
374    fptools_cv_alex_version="";
375 fi;
376 changequote([, ])dnl
377 ])
378 dnl if test -d $srcdir/ghc -a ! -f $srcdir/ghc/compiler/parser/Lexer.hs; then
379 dnl   FPTOOLS_PROG_CHECK_VERSION([$fptools_cv_alex_version],-lt,[2.0],
380 dnl   [AC_MSG_ERROR([Alex version 2.0 or later is required to compile GHC.])])dnl
381 dnl fi
382 AlexVersion=$fptools_cv_alex_version;
383 AC_SUBST(AlexVersion)
384 ])
385
386
387 dnl
388 dnl Check whether ld supports -x
389 dnl
390 AC_DEFUN(FPTOOLS_LD_X,
391 [AC_CACHE_CHECK([whether ld understands -x], fptools_cv_ld_x,
392 [
393 echo 'foo() {}' > conftest.c
394 ${CC-cc} -c conftest.c
395 if ${LdCmd} -r -x -o foo.o conftest.o; then
396    fptools_cv_ld_x=yes
397 else
398    fptools_cv_ld_x=no
399 fi
400 rm -rf conftest.c conftest.o foo.o
401 ])
402 if test "$fptools_cv_ld_x" = yes; then
403         LdXFlag=-x
404 else
405         LdXFlag=
406 fi
407 AC_SUBST(LdXFlag)
408 ])
409
410
411 dnl *** Checking for ar and its arguments + whether we need ranlib.
412 dnl
413 dnl ArCmd, ArSupportsInput and RANLIB are AC_SUBST'ed
414 dnl On Digital UNIX, we test for the -Z (compress) and
415 dnl -input (take list of files from external file) flags.
416 dnl 
417 AC_DEFUN(FPTOOLS_PROG_AR_AND_RANLIB,
418 [AC_PATH_PROG(ArCmdRaw,ar)
419 if test -z "$ArCmdRaw"; then
420     echo "You don't seem to have ar in your PATH...I have no idea how to make a library"
421     exit 1;
422 fi
423 dnl GNU ar needs special treatment: it appears to have problems with
424 dnl object files with the same name if you use the 's' modifier, but
425 dnl simple 'ar q' works fine, and doesn't need a separate ranlib.
426 if $ArCmdRaw --version | grep 'GNU' >/dev/null 2>/dev/null; then
427     ArCmdArgs='q'
428     NeedRanLib=''
429 elif $ArCmdRaw clqsZ conftest.a >/dev/null 2>/dev/null; then
430     ArCmdArgs="clqsZ"
431     NeedRanLib=''
432 elif $ArCmdRaw clqs conftest.a >/dev/null 2>/dev/null; then
433     ArCmdArgs="clqs"
434     NeedRanLib=''
435 elif $ArCmdRaw cqs conftest.a >/dev/null 2>/dev/null; then
436     ArCmdArgs="cqs"
437     NeedRanLib=''
438 elif $ArCmdRaw clq conftest.a >/dev/null 2>/dev/null; then
439     ArCmdArgs="clq"
440     NeedRanLib='YES'
441 elif $ArCmdRaw cq conftest.a >/dev/null 2>/dev/null; then
442     ArCmdArgs="cq"
443     NeedRanLib='YES'
444 elif $ArCmdRaw cq conftest.a 2>&1 | grep 'no archive members specified' >/dev/null 2>/dev/null; then
445     ArCmdArgs="cq"
446     NeedRanLib='YES'
447 else
448     echo "I can't figure out how to use your $ArCmd"
449     exit 1
450 fi
451 rm -rf conftest*
452 case $HostPlatform in
453  *mingw32) 
454           ArCmd="`cygpath -w ${ArCmdRaw} | sed -e 's@\\\\@/@g' ` ${ArCmdArgs}"
455           ;;
456  *) ArCmd="${ArCmdRaw} ${ArCmdArgs}"
457     ;;
458 esac
459 test -n "$ArCmd" && test -n "$verbose" && echo "        setting ArCmd to $ArCmd"
460 AC_SUBST(ArCmd)
461 if $ArCmd conftest.a -input /dev/null >/dev/null 2>/dev/null; then
462     ArSupportsInput='-input'
463 else
464     ArSupportsInput=''
465 fi
466 rm -rf conftest*
467 test -n "$ArSupportsInput" && test -n "$verbose" && echo "        setting ArSupportsInput to $ArSupportsInput"
468 AC_SUBST(ArSupportsInput)
469 if test -z "$NeedRanLib"; then
470     RANLIB=':'
471     test -n "$verbose" && echo "        setting RANLIB to $RANLIB"
472     AC_SUBST(RANLIB)
473 else
474     AC_PROG_RANLIB
475 fi
476 ])
477
478 dnl
479 dnl AC_SHEBANG_PERL - can we she-bang perl?
480 dnl
481 AC_DEFUN(FPTOOLS_SHEBANG_PERL,
482 [AC_CACHE_CHECK([if your perl works in shell scripts], fptools_cv_shebang_perl,
483 [echo "#!$PerlCmd"'
484 exit $1;
485 ' > conftest
486 chmod u+x conftest
487 (SHELL=/bin/sh; export SHELL; ./conftest 69 > /dev/null)
488 if test $? -ne 69; then
489    fptools_cv_shebang_perl=yes
490 else
491    fptools_cv_shebang_perl=no
492 fi
493 rm -f conftest
494 ])])
495
496 dnl
497 dnl Extra testing of the result AC_PROG_CC, testing the gcc version no.
498 dnl *Must* be called after AC_PROG_CC
499 dnl
500 AC_DEFUN(FPTOOLS_HAVE_GCC,
501 [AC_CACHE_CHECK([whether you have an ok gcc], fptools_cv_have_gcc,
502 [if test -z "$GCC"; then
503     echo ''
504     echo "You would be better off with gcc"
505     echo "Perhaps it is already installed, but not in your PATH?"
506     fptools_cv_have_gcc='no'
507 else
508 changequote(, )dnl
509     gcc_version_str="`$CC -v 2>&1 | grep 'version ' | sed -e 's/.*version [^0-9]*\([0-9][0-9]*\)\.\([0-9][0-9]*\).*/\1\.\2/g' `"
510 changequote([, ])dnl
511     fptools_cv_have_gcc='yes'
512     FPTOOLS_PROG_CHECK_VERSION($gcc_version_str, -lt, "2.0",
513         fptools_cv_have_gcc='no'
514         echo ""
515         echo "your gcc version appears to be ..."
516         $CC --version
517         echo "gcc prior to 2.0 and have never worked with ghc."
518         echo "we recommend 2.95.3, although versions back to 2.7.2 should be ok."
519         AC_MSG_ERROR([gcc 1.X has never been supported])
520     )
521 fi
522 ])
523 HaveGcc=`echo $fptools_cv_have_gcc | sed 'y/yesno/YESNO/'`
524 AC_SUBST(HaveGcc)
525 ])
526
527 dnl
528 dnl Some OSs (Mandrake Linux, in particular) configure GCC with
529 dnl -momit-leaf-frame-pointer on by default.  If this is the case, we
530 dnl need to turn it off for mangling to work.  The test is currently a bit
531 dnl crude, using only the version number of gcc.
532 dnl
533 AC_DEFUN(FPTOOLS_GCC_NEEDS_NO_OMIT_LFPTR,
534 [AC_CACHE_CHECK([whether gcc needs -mno-omit-leaf-frame-pointer], fptools_cv_gcc_needs_no_omit_lfptr,
535 [
536  fptools_cv_gcc_needs_no_omit_lfptr='no'
537  FPTOOLS_PROG_CHECK_VERSION($gcc_version_str, -ge, "3.2",
538      fptools_cv_gcc_needs_no_omit_lfptr='yes')
539 ])
540 if test "$fptools_cv_gcc_needs_no_omit_lfptr" = "yes"; then
541    AC_DEFINE([HAVE_GCC_MNO_OMIT_LFPTR], [1], [Define to 1 if gcc supports -mno-omit-leaf-frame-pointer.])
542 fi
543 ])
544
545 dnl Small feature test for perl version. Assumes PerlCmd
546 dnl contains path to perl binary
547 dnl
548 AC_DEFUN(FPTOOLS_CHECK_PERL_VERSION,
549 [$PerlCmd -v >conftest.out 2>&1
550 if grep "version 5" conftest.out >/dev/null 2>&1; then
551    :
552 else
553    if grep "v5.6" conftest.out >/dev/null 2>&1; then
554       :
555    else
556       if grep "v5.8" conftest.out >/dev/null 2>&1; then
557          :
558       else
559          if grep "version 6" conftest.out >/dev/null 2>&1; then
560             :
561          else
562             echo "Your version of perl probably won't work."
563          fi  
564       fi
565    fi
566 fi
567 rm -fr conftest*
568 ])
569
570 dnl
571 dnl Getting at the right version of 'find'
572 dnl (i.e., not the MS util on a Win32 box).
573 dnl
574 AC_DEFUN(FPTOOLS_FIND_FIND,
575 [
576 AC_PATH_PROG(Find2Cmd, find)
577 $Find2Cmd --version > conftest.out 2>&1 
578 if grep "FIND: Parameter format" conftest.out >/dev/null 2>&1 ; then
579    # Encountered MS' find utility, which is not what we're after.
580    #
581    # HACK - AC_CHECK_PROG is useful here in that does let you reject
582    # an (absolute) entry in the path (Find2Cmd). It is not so useful
583    # in that it doesn't let you (AFAIU) set VARIABLE equal to the 
584    # absolute path eventually found. So, hack around this by inspecting
585    # what variables hold the abs. path & use them directly.
586    AC_CHECK_PROG(FindCmd,find,`echo $ac_dir/$ac_word`,find,,$Find2Cmd)
587 else
588 FindCmd=$Find2Cmd
589 AC_SUBST(FindCmd)
590 fi
591 ])
592
593 dnl
594 dnl FPTOOLS_NOCACHE_CHECK prints a message, then sets the
595 dnl values of the second argument to the result of running
596 dnl the commands given by the third. It does not cache its
597 dnl result, so it is suitable for checks which should be
598 dnl run every time.
599 dnl
600 AC_DEFUN(FPTOOLS_NOCACHE_CHECK,
601 [AC_MSG_CHECKING([$1])
602  $3
603  AC_MSG_RESULT([$][$2])
604 ])
605
606 dnl
607 dnl FPTOOLS_GHC_VERSION(version)
608 dnl FPTOOLS_GHC_VERSION(major, minor [, patchlevel])
609 dnl FPTOOLS_GHC_VERSION(version, major, minor, patchlevel)
610 dnl
611 dnl Test for version of installed ghc.  Uses $GHC.
612 dnl [original version pinched from c2hs]
613 dnl
614 AC_DEFUN(FPTOOLS_GHC_VERSION,
615 [FPTOOLS_NOCACHE_CHECK([version of ghc], [fptools_version_of_ghc],
616 ["${WithGhc-ghc}" --version > conftestghc 2>&1
617   cat conftestghc >&AC_FD_CC
618 #Useless Use Of cat award...
619   fptools_version_of_ghc=`cat conftestghc | sed -n -e 's/, patchlevel *\([[0-9]]\)/.\1/;s/.* version \([[0-9]][[0-9.]]*\).*/\1/p'`
620   rm -fr conftest*
621   if test "[$]fptools_version_of_ghc" = ""
622   then
623     fptools_version_of_ghc='unknown'
624   fi
625 fptools_version_of_ghc[_major]=`echo [$]fptools_version_of_ghc | sed -e 's/^\([[0-9]]\).*/\1/'`
626 fptools_version_of_ghc[_minor]=`echo [$]fptools_version_of_ghc | sed -e 's/^[[0-9]]\.\([[0-9]]*\).*/\1/'`
627 fptools_version_of_ghc[_pl]=`echo [$]fptools_version_of_ghc | sed -n -e 's/^[[0-9]]\.[[0-9]]*\.\([[0-9]]*\)/\1/p'`
628 #
629 if test "[$]fptools_version_of_ghc[_pl]" = ""
630 then
631   fptools_version_of_ghc[_all]="[$]fptools_version_of_ghc[_major].[$]fptools_version_of_ghc[_minor]"
632   fptools_version_of_ghc[_pl]="0"
633 else
634   fptools_version_of_ghc[_all]="[$]fptools_version_of_ghc[_major].[$]fptools_version_of_ghc[_minor].[$]fptools_version_of_ghc[_pl]"
635 fi
636 #
637 ifelse($#, [1], [dnl
638 [$1]="[$]fptools_version_of_ghc[_all]"
639 ], $#, [2], [dnl
640 [$1]="[$]fptools_version_of_ghc[_major]"
641 [$2]="[$]fptools_version_of_ghc[_minor]"
642 ], $#, [3], [dnl
643 [$1]="[$]fptools_version_of_ghc[_major]"
644 [$2]="[$]fptools_version_of_ghc[_minor]"
645 [$3]="[$]fptools_version_of_ghc[_pl]"
646 ], $#, [4], [dnl
647 [$1]="[$]fptools_version_of_ghc[_all]"
648 [$2]="[$]fptools_version_of_ghc[_major]"
649 [$3]="[$]fptools_version_of_ghc[_minor]"
650 [$4]="[$]fptools_version_of_ghc[_pl]"
651 ])
652 ])
653 ])dnl
654
655
656 dnl ** Map an arithmetic C type to a Haskell type.
657 dnl    Based on autconf's AC_CHECK_SIZEOF.
658
659 dnl FPTOOLS_CHECK_HTYPE(TYPE [, DEFAULT_VALUE, [, VALUE-FOR-CROSS-COMPILATION])
660 AC_DEFUN(FPTOOLS_CHECK_HTYPE,
661 [changequote(<<, >>)dnl
662 dnl The name to #define.
663 define(<<AC_TYPE_NAME>>, translit(htype_$1, [a-z *], [A-Z_P]))dnl
664 dnl The cache variable name.
665 define(<<AC_CV_NAME>>, translit(fptools_cv_htype_$1, [ *], [_p]))dnl
666 changequote([, ])dnl
667 AC_MSG_CHECKING(Haskell type for $1)
668 AC_CACHE_VAL(AC_CV_NAME,
669 [AC_TRY_RUN([#include <stdio.h>
670 #include <stddef.h>
671
672 #ifdef HAVE_SYS_TYPES_H
673 # include <sys/types.h>
674 #endif
675
676 #ifdef HAVE_UNISTD_H
677 # include <unistd.h>
678 #endif
679
680 #ifdef HAVE_SYS_STAT_H
681 # include <sys/stat.h>
682 #endif
683
684 #ifdef HAVE_FCNTL_H
685 # include <fcntl.h>
686 #endif
687
688 #ifdef HAVE_SIGNAL_H
689 # include <signal.h>
690 #endif
691
692 #ifdef HAVE_TIME_H
693 # include <time.h>
694 #endif
695
696 #ifdef HAVE_TERMIOS_H
697 # include <termios.h>
698 #endif
699
700 #ifdef HAVE_STRING_H
701 # include <string.h>
702 #endif
703
704 #ifdef HAVE_CTYPE_H
705 # include <ctype.h>
706 #endif
707
708 #ifdef HAVE_GL_GL_H
709 # include <GL/gl.h>
710 #endif
711
712 #ifdef HAVE_OPENGL_GL_H
713 # include <OpenGL/gl.h>
714 #endif
715
716 #ifdef HAVE_SYS_RESOURCE_H
717 # include <sys/resource.h>
718 #endif
719
720 typedef $1 testing;
721
722 main() {
723   FILE *f=fopen("conftestval", "w");
724   if (!f) exit(1);
725   if (((testing)((int)((testing)1.4))) == ((testing)1.4)) {
726     fprintf(f, "%s%d\n",
727            ((testing)(-1) < (testing)0) ? "Int" : "Word",
728            sizeof(testing)*8);
729   } else {
730     fprintf(f,"%s\n",
731            (sizeof(testing) >  sizeof(double)) ? "LDouble" :
732            (sizeof(testing) == sizeof(double)) ? "Double"  : "Float");
733   }
734   fclose(f);
735   exit(0);
736 }], AC_CV_NAME=`cat conftestval`,
737 ifelse([$2], , AC_CV_NAME=NotReallyAType,      AC_CV_NAME=$2),
738 ifelse([$3], , AC_CV_NAME=NotReallyATypeCross, AC_CV_NAME=$3))]) dnl
739 AC_MSG_RESULT($AC_CV_NAME)
740 AC_DEFINE_UNQUOTED(AC_TYPE_NAME, $AC_CV_NAME, [Define to Haskell type for $1])
741 undefine([AC_TYPE_NAME])dnl
742 undefine([AC_CV_NAME])dnl
743 ])
744
745
746 dnl *** Can we open files in binary mode? ***
747 dnl 
748 AC_DEFUN(FPTOOLS_O_BINARY,
749 [
750 AC_REQUIRE([AC_PROG_CC])
751 AC_MSG_CHECKING(whether we can open files in binary mode)
752 AC_CACHE_VAL(fptools_cv_have_o_binary,
753 [
754 AC_LANG_SAVE
755 AC_LANG_C
756 AC_TRY_COMPILE(
757 [#ifdef HAVE_FCNTL_H
758 #include <fcntl.h>
759 #endif],
760 [int x = O_BINARY;],
761 fptools_cv_have_o_binary=yes,
762 fptools_cv_have_o_binary=no)
763 AC_LANG_RESTORE
764 ])
765 AC_MSG_RESULT($fptools_cv_have_o_binary)
766 if test "$fptools_cv_have_o_binary" = yes; then
767   AC_DEFINE([HAVE_O_BINARY], [1], [Define to 1 if fcntl.h defines O_BINARY.])
768 fi
769 ])
770
771
772 dnl Based on AC_TRY_LINK - run iftrue if links cleanly with no warning
773
774 dnl FPTOOLS_TRY_LINK_NOWARN(flags,main?,iftrue,iffalse)
775
776 AC_DEFUN(FPTOOLS_TRY_LINK_NOWARN,
777 [
778 ac_save_LIBS="$LIBS"
779 LIBS=[$1];
780 cat > conftest.$ac_ext <<EOF
781 dnl This sometimes fails to find confdefs.h, for some reason.
782 dnl [#]line __oline__ "[$]0"
783 [#]line __oline__ "configure"
784 #include "confdefs.h"
785 [$2]
786 int t() { return 0; }
787 EOF
788 if AC_TRY_EVAL(ac_link); then
789   ifelse([$3], , :, [
790     LIBS="$ac_save_LIBS"
791     rm -rf conftest*
792     $3])
793   ifelse([$4], , , [else
794     LIBS="$ac_save_LIBS"
795     rm -rf conftest*
796     $4
797 ])dnl
798 fi
799 rm -f conftest*
800 ]
801 )
802
803 dnl Loosely based on AC_CHECK_LIB in acgeneral.m4 in autoconf distribution
804
805 dnl FPTOOLS_CHECK_FLAG_NOWARN(NAME, FLAG, CODE, iftrue, iffalse)
806
807 AC_DEFUN(FPTOOLS_CHECK_FLAG_NOWARN,
808 [AC_MSG_CHECKING([for $1])
809  AC_CACHE_VAL(ac_cv_flag_$1,
810    [FPTOOLS_TRY_LINK_NOWARN("$2", [main() { $3; exit(0); } ],
811      eval "ac_cv_flag_$1=yes",
812      eval "ac_cv_flag_$1=no"
813    )]
814  )
815 if eval "test \"`echo '$ac_cv_flag_'$1`\" = yes"; then
816   AC_MSG_RESULT(yes)
817   LIBS="$2 $LIBS"
818   $4
819 else
820   AC_MSG_RESULT(no)
821   $5
822 fi
823 ])
824
825 dnl FPTOOLS_CHECK_LIB_NOWARN(LIBRARY, FUNCTION)
826
827 AC_DEFUN(FPTOOLS_CHECK_LIB_NOWARN,
828 [FPTOOLS_CHECK_FLAG_NOWARN([function_$2],[],[extern char $2(); $2();],
829 [changequote(, )dnl
830   ac_tr_lib=HAVE_LIB`echo $1 | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
831  changequote([, ])dnl
832  AC_DEFINE_UNQUOTED($ac_tr_lib)
833 ],
834 [FPTOOLS_CHECK_FLAG_NOWARN([library_$1],[-l$1],[extern char $2(); $2();],
835 [changequote(, )dnl
836   ac_tr_lib=HAVE_LIB`echo $1 | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
837  changequote([, ])dnl
838  AC_DEFINE_UNQUOTED($ac_tr_lib)
839 ],
840 []
841 )])]
842 )
843
844
845 dnl ** Check which CATALOG file we have to use with DocBook SGML.
846 dnl
847 dnl FPTOOLS_DOCBOOK_CATALOG(VARIABLE, JADE, STYLESHEET, CATALOGS-TO-CHECK-FOR)
848 dnl
849 dnl If any of the catalogs given in CATALOGS-TO-CHECK-FOR works on this
850 dnl platform, let VARIABLE refer to this catalog; otherwise, VARIABLE
851 dnl is set to "no".  JADE is the jade executable and STYLESHEET
852 dnl a DocBook style sheet.
853 dnl
854 AC_DEFUN(FPTOOLS_DOCBOOK_CATALOG,
855 [AC_CACHE_CHECK([for DocBook CATALOG], fptools_cv_sgml_catalog,
856 [
857 cat > conftest.sgml << EOF
858 <!DOCTYPE Article PUBLIC "-//OASIS//DTD DocBook V3.1//EN">
859 <Article>
860 <ArtHeader>
861 <Title>Test</Title>
862 <Author><OtherName>Test</OtherName></Author>
863 <Address>Test</Address>
864 <PubDate>Test</PubDate>
865 </ArtHeader>
866 <Sect1><Title>Test</Title>
867 <Para>
868 Test.
869 </Para>
870 </Sect1>
871 </Article>
872 EOF
873 fptools_cv_sgml_catalog=no
874 if test -z "$SGML_CATALOG_FILES" ; then
875  for fptools_catalog in $4; do
876    ac_try="$2 -t rtf -d $3#print -c $fptools_catalog conftest.sgml"
877    if AC_TRY_EVAL(ac_try); then
878      fptools_cv_sgml_catalog=[$]fptools_catalog
879      break
880    fi
881  done
882 else
883 # If the env var SGML_CATALOG_FILES is defined, assume things are cool.
884   fptools_cv_sgml_catalog="yes"
885 fi
886 ])
887 rm -rf conftest*
888 if test $fptools_cv_sgml_catalog != "no"; then
889   $1=$fptools_cv_sgml_catalog
890 fi
891 ])
892
893 dnl ######################################################################
894 dnl FPTOOLS_SEARCH_LIBS(INCLUDES, FUNCTION, SEARCH-LIBS [, ACTION-IF-FOUND
895 dnl                     [, ACTION-IF-NOT-FOUND [, OTHER-LIBRARIES]]])
896 dnl Search for a library defining FUNC, if it's not already available.
897 dnl This is almost the same as AC_SEARCH_LIBS, but the INCLUDES can be
898 dnl specified.
899 dnl ######################################################################
900
901 AC_DEFUN(FPTOOLS_SEARCH_LIBS,
902 [AC_PREREQ([2.13])
903 AC_CACHE_CHECK([for library containing $2], [ac_cv_search_$2],
904 [ac_func_search_save_LIBS="$LIBS"
905 ac_cv_search_$2="no"
906 AC_TRY_LINK([$1], [$2()], [ac_cv_search_$2="none required"])
907 test "$ac_cv_search_$2" = "no" && for i in $3; do
908 LIBS="-l$i $6 $ac_func_search_save_LIBS"
909 AC_TRY_LINK([$1], [$2()],
910 [ac_cv_search_$2="-l$i"
911 break])
912 done
913 LIBS="$ac_func_search_save_LIBS"])
914 if test "$ac_cv_search_$2" != "no"; then
915   test "$ac_cv_search_$2" = "none required" || LIBS="$ac_cv_search_$2 $LIBS"
916   $4
917 else :
918   $5
919 fi])
920
921 dnl ####################### -*- Mode: M4 -*- ###########################
922 dnl Copyright (C) 98, 1999 Matthew D. Langston <langston@SLAC.Stanford.EDU>
923 dnl
924 dnl This file is free software; you can redistribute it and/or modify it
925 dnl under the terms of the GNU General Public License as published by
926 dnl the Free Software Foundation; either version 2 of the License, or
927 dnl (at your option) any later version.
928 dnl
929 dnl This file is distributed in the hope that it will be useful, but
930 dnl WITHOUT ANY WARRANTY; without even the implied warranty of
931 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
932 dnl General Public License for more details.
933 dnl
934 dnl You should have received a copy of the GNU General Public License
935 dnl along with this file; if not, write to:
936 dnl
937 dnl   Free Software Foundation, Inc.
938 dnl   Suite 330
939 dnl   59 Temple Place
940 dnl   Boston, MA 02111-1307, USA.
941 dnl ####################################################################
942
943
944 dnl @synopsis FPTOOLS_CHECK_LIBM
945 dnl 
946 dnl Search for math library (typically -lm).
947 dnl
948 dnl The variable LIBM (which is not an output variable by default) is
949 dnl set to a value which is suitable for use in a Makefile (for example,
950 dnl in make's LOADLIBES macro) provided you AC_SUBST it first.
951 dnl
952 dnl @author Matthew D. Langston <langston@SLAC.Stanford.EDU>
953
954 # FPTOOLS_CHECK_LIBM - check for math library
955 AC_DEFUN(FPTOOLS_CHECK_LIBM,
956 [AC_REQUIRE([AC_CANONICAL_HOST])dnl
957 LIBM=
958 case "$host" in
959 *-*-beos*)
960   # These system don't have libm
961   ;;
962 *-ncr-sysv4.3*)
963   AC_CHECK_LIB(mw, _mwvalidcheckl, LIBM="-lmw")
964   AC_CHECK_LIB(m, main, LIBM="$LIBM -lm")
965   ;;
966 *)
967   AC_CHECK_LIB(m, main, LIBM="-lm")
968   ;;
969 esac
970 ])
971
972 dnl ######################################################################
973 dnl Note: Caching has been completely rewritten, but is still no perfect yet.
974 dnl ######################################################################
975
976 dnl ########################### -*- Mode: M4 -*- #######################
977 dnl Copyright (C) 98, 1999 Matthew D. Langston <langston@SLAC.Stanford.EDU>
978 dnl
979 dnl This file is free software; you can redistribute it and/or modify it
980 dnl under the terms of the GNU General Public License as published by
981 dnl the Free Software Foundation; either version 2 of the License, or
982 dnl (at your option) any later version.
983 dnl
984 dnl This file is distributed in the hope that it will be useful, but
985 dnl WITHOUT ANY WARRANTY; without even the implied warranty of
986 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
987 dnl General Public License for more details.
988 dnl
989 dnl You should have received a copy of the GNU General Public License
990 dnl along with this file; if not, write to:
991 dnl
992 dnl   Free Software Foundation, Inc.
993 dnl   Suite 330
994 dnl   59 Temple Place
995 dnl   Boston, MA 02111-1307, USA.
996 dnl ####################################################################
997
998 dnl @synopsis FPTOOLS_HAVE_OPENGL
999 dnl 
1000 dnl Search for OpenGL.  We search first for Mesa (a GPL'ed version of
1001 dnl OpenGL) before a vendor's version of OpenGL if we were specifically
1002 dnl asked to with `--with-Mesa=yes' or `--with-Mesa'.
1003 dnl
1004 dnl The four "standard" OpenGL libraries are searched for: "-lGL",
1005 dnl "-lGLU", "-lGLX" (or "-lMesaGL", "-lMesaGLU" as the case may be) and
1006 dnl "-lglut".
1007 dnl
1008 dnl All of the libraries that are found (since "-lglut" or "-lGLX" might
1009 dnl be missing) are added to the shell output variable "GL_LIBS", along
1010 dnl with any other libraries that are necessary to successfully link an
1011 dnl OpenGL application (e.g. the X11 libraries).  Care has been taken to
1012 dnl make sure that all of the libraries in "GL_LIBS" are listed in the
1013 dnl proper order.
1014 dnl
1015 dnl Additionally, the shell output variable "GL_CFLAGS" is set to any
1016 dnl flags (e.g. "-I" flags) that are necessary to successfully compile
1017 dnl an OpenGL application.
1018 dnl
1019 dnl The following shell variable (which are not output variables) are
1020 dnl also set to either "yes" or "no" (depending on which libraries were
1021 dnl found) to help you determine exactly what was found.
1022 dnl
1023 dnl   have_GL
1024 dnl   have_GLU
1025 dnl   have_GLX
1026 dnl   have_glut
1027 dnl
1028 dnl A complete little toy "Automake `make distcheck'" package of how to
1029 dnl use this macro is available at:
1030 dnl
1031 dnl   ftp://ftp.slac.stanford.edu/users/langston/autoconf/ac_opengl-0.01.tar.gz
1032 dnl
1033 dnl Please note that as the ac_opengl macro and the toy example evolves,
1034 dnl the version number increases, so you may have to adjust the above
1035 dnl URL accordingly.
1036 dnl
1037 dnl @author Matthew D. Langston <langston@SLAC.Stanford.EDU>
1038
1039 AC_DEFUN(FPTOOLS_HAVE_OPENGL,
1040 [
1041   AC_REQUIRE([AC_PROG_CC])
1042   AC_REQUIRE([AC_PATH_X])
1043   AC_REQUIRE([AC_PATH_XTRA])
1044   AC_REQUIRE([FPTOOLS_CHECK_LIBM])
1045
1046 dnl Check for Mesa first if we were asked to.
1047   AC_ARG_ENABLE(Mesa,
1048 [  --enable-mesa
1049         Prefer Mesa over a vendor's native OpenGL library (default=no)
1050 ],
1051                 use_Mesa=$enableval,
1052                 use_Mesa=no)
1053
1054   if test x"$use_Mesa" = xyes; then
1055      GL_search_list="MesaGL  GL  opengl32"
1056     GLU_search_list="MesaGLU GLU glu32"
1057     GLX_search_list="MesaGLX GLX"
1058   else
1059      GL_search_list="GL  opengl32 MesaGL"
1060     GLU_search_list="GLU glu32    MesaGLU"
1061     GLX_search_list="GLX          MesaGLX"
1062   fi      
1063
1064   AC_LANG_SAVE
1065   AC_LANG_C
1066
1067 dnl If we are running under X11 then add in the appropriate libraries.
1068   if test x"$no_x" != xyes; then
1069 dnl Add everything we need to compile and link X programs to GL_CFLAGS
1070 dnl and GL_X_LIBS/GLUT_X_LIBS.
1071     GL_CFLAGS="$CPPFLAGS $X_CFLAGS"
1072     GL_X_LIBS="$X_LIBS $X_PRE_LIBS -lXext -lX11 $X_EXTRA_LIBS $LIBM"
1073     GLUT_X_LIBS="$X_LIBS $X_PRE_LIBS -lXmu -lXt -lXi -lXext -lX11 $X_EXTRA_LIBS $LIBM"
1074   fi
1075   GL_save_CPPFLAGS="$CPPFLAGS"
1076   CPPFLAGS="$GL_CFLAGS"
1077
1078   GL_save_LIBS="$LIBS"
1079   LIBS="$GL_X_LIBS"
1080
1081   FPTOOLS_SEARCH_LIBS([#include <GL/gl.h>],   glEnd,         $GL_search_list,  have_GL=yes,   have_GL=no)
1082   FPTOOLS_SEARCH_LIBS([#include <GL/glu.h>],  gluNewQuadric, $GLU_search_list, have_GLU=yes,  have_GLU=no)
1083   FPTOOLS_SEARCH_LIBS([#include <GL/glx.h>],  glXWaitX,      $GLX_search_list, have_GLX=yes,  have_GLX=no)
1084
1085   if test -n "$LIBS"; then
1086     GL_LIBS="$LDFLAGS $LIBS"
1087   else
1088     GL_LIBS="$LDFLAGS"
1089     GL_CFLAGS=
1090   fi
1091
1092   LIBS="$GLUT_X_LIBS"
1093
1094   FPTOOLS_SEARCH_LIBS([#include <GL/glut.h>], glutMainLoop,  glut32 glut,      have_glut=yes, have_glut=no)
1095
1096   if test -n "$LIBS"; then
1097     GLUT_LIBS="$LDFLAGS $LIBS"
1098   fi
1099
1100   AC_CACHE_CHECK([OpenGL flags], mdl_cv_gl_cflags, [mdl_cv_gl_cflags="$GL_CFLAGS"])
1101   GL_CFLAGS="$mdl_cv_gl_cflags"
1102   AC_SUBST(GL_CFLAGS)
1103   AC_CACHE_CHECK([OpenGL libs],  mdl_cv_gl_libs,   [mdl_cv_gl_libs="$GL_LIBS"])
1104   GL_LIBS="$mdl_cv_gl_libs"
1105   AC_SUBST(GL_LIBS)
1106   AC_CACHE_CHECK([GLUT libs],  mdl_cv_glut_libs,   [mdl_cv_glut_libs="$GLUT_LIBS"])
1107   GLUT_LIBS="$mdl_cv_glut_libs"
1108   AC_SUBST(GLUT_LIBS)
1109
1110 dnl Reset GL_X_LIBS/GLUT_X_LIBS regardless, since they were just temporary variables
1111 dnl and we don't want to be global namespace polluters.
1112   GL_X_LIBS=
1113   GLUT_X_LIBS=
1114
1115   LIBS="$GL_save_LIBS"
1116   CPPFLAGS="$GL_save_CPPFLAGS"
1117
1118   AC_LANG_RESTORE
1119 ])
1120
1121 # LocalWords:  fi