Remove duplicate "since" field in glasgow_exts.rst
[ghc.git] / docs / users_guide / glasgow_exts.rst
1 .. index::
2    single: language, GHC extensions
3
4 As with all known Haskell systems, GHC implements some extensions to the
5 standard Haskell language. They can all be enabled or disabled by command line
6 flags or language pragmas. By default GHC understands the most recent Haskell
7 version it supports, plus a handful of extensions.
8
9 Some of the Glasgow extensions serve to give you access to the
10 underlying facilities with which we implement Haskell. Thus, you can get
11 at the Raw Iron, if you are willing to write some non-portable code at a
12 more primitive level. You need not be “stuck” on performance because of
13 the implementation costs of Haskell's "high-level" features—you can
14 always code "under" them. In an extreme case, you can write all your
15 time-critical code in C, and then just glue it together with Haskell!
16
17 Before you get too carried away working at the lowest level (e.g.,
18 sloshing ``MutableByteArray#``\ s around your program), you may wish to
19 check if there are libraries that provide a "Haskellised veneer" over
20 the features you want. The separate
21 `libraries documentation <../libraries/index.html>`__ describes all the
22 libraries that come with GHC.
23
24 .. _options-language:
25
26 Language options
27 ================
28
29 .. index::
30    single: language; option
31    single: options; language
32    single: extensions; options controlling
33
34 The language extensions control what variation of the language are
35 permitted.
36
37 Language options can be controlled in two ways:
38
39 -  Every language option can switched on by a command-line flag
40    "``-X...``" (e.g. ``-XTemplateHaskell``), and switched off by the
41    flag "``-XNo...``"; (e.g. ``-XNoTemplateHaskell``).
42
43 -  Language options recognised by Cabal can also be enabled using the
44    ``LANGUAGE`` pragma, thus ``{-# LANGUAGE TemplateHaskell #-}`` (see
45    :ref:`language-pragma`).
46
47 GHC supports these language options:
48
49 .. extension-print::
50     :type: table
51
52 Although not recommended, the deprecated :ghc-flag:`-fglasgow-exts` flag enables
53 a large swath of the extensions supported by GHC at once.
54
55 .. ghc-flag:: -fglasgow-exts
56     :shortdesc: Deprecated. Enable most language extensions;
57         see :ref:`options-language` for exactly which ones.
58     :type: dynamic
59     :reverse: -fno-glasgow-exts
60     :category: misc
61
62     The flag ``-fglasgow-exts`` is equivalent to enabling the following extensions:
63
64     .. include:: what_glasgow_exts_does.rst
65
66     Enabling these options is the *only* effect of ``-fglasgow-exts``. We are trying
67     to move away from this portmanteau flag, and towards enabling features
68     individually.
69
70 .. _primitives:
71
72 Unboxed types and primitive operations
73 ======================================
74
75 GHC is built on a raft of primitive data types and operations;
76 "primitive" in the sense that they cannot be defined in Haskell itself.
77 While you really can use this stuff to write fast code, we generally
78 find it a lot less painful, and more satisfying in the long run, to use
79 higher-level language features and libraries. With any luck, the code
80 you write will be optimised to the efficient unboxed version in any
81 case. And if it isn't, we'd like to know about it.
82
83 All these primitive data types and operations are exported by the
84 library ``GHC.Prim``, for which there is
85 :ghc-prim-ref:`detailed online documentation <GHC.Prim.>`. (This
86 documentation is generated from the file ``compiler/prelude/primops.txt.pp``.)
87
88 If you want to mention any of the primitive data types or operations in
89 your program, you must first import ``GHC.Prim`` to bring them into
90 scope. Many of them have names ending in ``#``, and to mention such names
91 you need the :extension:`MagicHash` extension.
92
93 The primops make extensive use of `unboxed types <#glasgow-unboxed>`__
94 and `unboxed tuples <#unboxed-tuples>`__, which we briefly summarise
95 here.
96
97 .. _glasgow-unboxed:
98
99 Unboxed types
100 -------------
101
102 Most types in GHC are boxed, which means that values of that type are
103 represented by a pointer to a heap object. The representation of a
104 Haskell ``Int``, for example, is a two-word heap object. An unboxed
105 type, however, is represented by the value itself, no pointers or heap
106 allocation are involved.
107
108 Unboxed types correspond to the “raw machine” types you would use in C:
109 ``Int#`` (long int), ``Double#`` (double), ``Addr#`` (void \*), etc. The
110 *primitive operations* (PrimOps) on these types are what you might
111 expect; e.g., ``(+#)`` is addition on ``Int#``\ s, and is the
112 machine-addition that we all know and love—usually one instruction.
113
114 Primitive (unboxed) types cannot be defined in Haskell, and are
115 therefore built into the language and compiler. Primitive types are
116 always unlifted; that is, a value of a primitive type cannot be bottom.
117 (Note: a "boxed" type means that a value is represented by a pointer to a heap
118 object; a "lifted" type means that terms of that type may be bottom. See
119 the next paragraph for an example.)
120 We use the convention (but it is only a convention) that primitive
121 types, values, and operations have a ``#`` suffix (see
122 :ref:`magic-hash`). For some primitive types we have special syntax for
123 literals, also described in the `same section <#magic-hash>`__.
124
125 Primitive values are often represented by a simple bit-pattern, such as
126 ``Int#``, ``Float#``, ``Double#``. But this is not necessarily the case:
127 a primitive value might be represented by a pointer to a heap-allocated
128 object. Examples include ``Array#``, the type of primitive arrays. Thus,
129 ``Array#`` is an unlifted, boxed type. A
130 primitive array is heap-allocated because it is too big a value to fit
131 in a register, and would be too expensive to copy around; in a sense, it
132 is accidental that it is represented by a pointer. If a pointer
133 represents a primitive value, then it really does point to that value:
134 no unevaluated thunks, no indirections. Nothing can be at the other end
135 of the pointer than the primitive value. A numerically-intensive program
136 using unboxed types can go a *lot* faster than its “standard”
137 counterpart—we saw a threefold speedup on one example.
138
139 Unboxed type kinds
140 ------------------
141
142 Because unboxed types are represented without the use of pointers, we
143 cannot store them in use a polymorphic datatype at an unboxed type.
144 For example, the ``Just`` node
145 of ``Just 42#`` would have to be different from the ``Just`` node of
146 ``Just 42``; the former stores an integer directly, while the latter
147 stores a pointer. GHC currently does not support this variety of ``Just``
148 nodes (nor for any other datatype). Accordingly, the *kind* of an unboxed
149 type is different from the kind of a boxed type.
150
151 The Haskell Report describes that ``*`` (spelled ``Type`` and imported from
152 ``Data.Kind`` in the GHC dialect of Haskell) is the kind of ordinary datatypes,
153 such as ``Int``. Furthermore, type constructors can have kinds with arrows; for
154 example, ``Maybe`` has kind ``Type -> Type``. Unboxed types have a kind that
155 specifies their runtime representation. For example, the type ``Int#`` has kind
156 ``TYPE 'IntRep`` and ``Double#`` has kind ``TYPE 'DoubleRep``. These kinds say
157 that the runtime representation of an ``Int#`` is a machine integer, and the
158 runtime representation of a ``Double#`` is a machine double-precision floating
159 point. In contrast, the kind ``Type`` is actually just a synonym for ``TYPE
160 'LiftedRep``. More details of the ``TYPE`` mechanisms appear in the `section
161 on runtime representation polymorphism <#runtime-rep>`__.
162
163 Given that ``Int#``'s kind is not ``Type``, it then it follows that ``Maybe
164 Int#`` is disallowed. Similarly, because type variables tend to be of kind
165 ``Type`` (for example, in ``(.) :: (b -> c) -> (a -> b) -> a -> c``, all the
166 type variables have kind ``Type``), polymorphism tends not to work over
167 primitive types. Stepping back, this makes some sense, because a polymorphic
168 function needs to manipulate the pointers to its data, and most primitive types
169 are unboxed.
170
171 There are some restrictions on the use of primitive types:
172
173 -  You cannot define a newtype whose representation type (the argument
174    type of the data constructor) is an unboxed type. Thus, this is
175    illegal:
176
177    ::
178
179          newtype A = MkA Int#
180
181 -  You cannot bind a variable with an unboxed type in a *top-level*
182    binding.
183
184 -  You cannot bind a variable with an unboxed type in a *recursive*
185    binding.
186
187 -  You may bind unboxed variables in a (non-recursive, non-top-level)
188    pattern binding, but you must make any such pattern-match strict.
189    (Failing to do so emits a warning :ghc-flag:`-Wunbanged-strict-patterns`.)
190    For example, rather than:
191
192    ::
193
194          data Foo = Foo Int Int#
195
196          f x = let (Foo a b, w) = ..rhs.. in ..body..
197
198    you must write:
199
200    ::
201
202          data Foo = Foo Int Int#
203
204          f x = let !(Foo a b, w) = ..rhs.. in ..body..
205
206    since ``b`` has type ``Int#``.
207
208 .. _unboxed-tuples:
209
210 Unboxed tuples
211 --------------
212
213 .. extension:: UnboxedTuples
214     :shortdesc: Enable the use of unboxed tuple syntax.
215
216     :since: 6.8.1
217
218
219 Unboxed tuples aren't really exported by ``GHC.Exts``; they are a
220 syntactic extension (:extension:`UnboxedTuples`). An
221 unboxed tuple looks like this: ::
222
223     (# e_1, ..., e_n #)
224
225 where ``e_1..e_n`` are expressions of any type (primitive or
226 non-primitive). The type of an unboxed tuple looks the same.
227
228 Note that when unboxed tuples are enabled, ``(#`` is a single lexeme, so
229 for example when using operators like ``#`` and ``#-`` you need to write
230 ``( # )`` and ``( #- )`` rather than ``(#)`` and ``(#-)``.
231
232 Unboxed tuples are used for functions that need to return multiple
233 values, but they avoid the heap allocation normally associated with
234 using fully-fledged tuples. When an unboxed tuple is returned, the
235 components are put directly into registers or on the stack; the unboxed
236 tuple itself does not have a composite representation. Many of the
237 primitive operations listed in ``primops.txt.pp`` return unboxed tuples.
238 In particular, the ``IO`` and ``ST`` monads use unboxed tuples to avoid
239 unnecessary allocation during sequences of operations.
240
241 There are some restrictions on the use of unboxed tuples:
242
243 -  The typical use of unboxed tuples is simply to return multiple
244    values, binding those multiple results with a ``case`` expression,
245    thus:
246
247    ::
248
249          f x y = (# x+1, y-1 #)
250          g x = case f x x of { (# a, b #) -> a + b }
251
252    You can have an unboxed tuple in a pattern binding, thus
253
254    ::
255
256          f x = let (# p,q #) = h x in ..body..
257
258    If the types of ``p`` and ``q`` are not unboxed, the resulting
259    binding is lazy like any other Haskell pattern binding. The above
260    example desugars like this:
261
262    ::
263
264          f x = let t = case h x of { (# p,q #) -> (p,q) }
265                    p = fst t
266                    q = snd t
267                in ..body..
268
269    Indeed, the bindings can even be recursive.
270
271 .. _unboxed-sums:
272
273 Unboxed sums
274 ------------
275
276 .. extension:: UnboxedSums
277     :shortdesc: Enable unboxed sums.
278
279     :since: 8.2.1
280
281     Enable the use of unboxed sum syntax.
282
283 `-XUnboxedSums` enables new syntax for anonymous, unboxed sum types. The syntax
284 for an unboxed sum type with N alternatives is ::
285
286     (# t_1 | t_2 | ... | t_N #)
287
288 where ``t_1`` ... ``t_N`` are types (which can be unlifted, including unboxed
289 tuples and sums).
290
291 Unboxed tuples can be used for multi-arity alternatives. For example: ::
292
293     (# (# Int, String #) | Bool #)
294
295 The term level syntax is similar. Leading and preceding bars (`|`) indicate which
296 alternative it is. Here are two terms of the type shown above: ::
297
298     (# (# 1, "foo" #) | #) -- first alternative
299
300     (# | True #) -- second alternative
301
302 The pattern syntax reflects the term syntax: ::
303
304     case x of
305       (# (# i, str #) | #) -> ...
306       (# | bool #) -> ...
307
308 Unboxed sums are "unboxed" in the sense that, instead of allocating sums in the
309 heap and representing values as pointers, unboxed sums are represented as their
310 components, just like unboxed tuples. These "components" depend on alternatives
311 of a sum type. Like unboxed tuples, unboxed sums are lazy in their lifted
312 components.
313
314 The code generator tries to generate as compact layout as possible for each
315 unboxed sum. In the best case, size of an unboxed sum is size of its biggest
316 alternative plus one word (for a tag). The algorithm for generating the memory
317 layout for a sum type works like this:
318
319 - All types are classified as one of these classes: 32bit word, 64bit word,
320   32bit float, 64bit float, pointer.
321
322 - For each alternative of the sum type, a layout that consists of these fields
323   is generated. For example, if an alternative has ``Int``, ``Float#`` and
324   ``String`` fields, the layout will have an 32bit word, 32bit float and
325   pointer fields.
326
327 - Layout fields are then overlapped so that the final layout will be as compact
328   as possible. For example, suppose we have the unboxed sum: ::
329
330     (# (# Word32#, String, Float# #)
331     |  (# Float#, Float#, Maybe Int #) #)
332
333   The final layout will be something like ::
334
335     Int32, Float32, Float32, Word32, Pointer
336
337   The first ``Int32`` is for the tag. There are two ``Float32`` fields because
338   floating point types can't overlap with other types, because of limitations of
339   the code generator that we're hoping to overcome in the future. The second
340   alternative needs two ``Float32`` fields: The ``Word32`` field is for the
341   ``Word32#`` in the first alternative. The ``Pointer`` field is shared between
342   ``String`` and ``Maybe Int`` values of the alternatives.
343
344   As another example, this is the layout for the unboxed version of ``Maybe a``
345   type, ``(# (# #) | a #)``: ::
346
347     Int32, Pointer
348
349   The ``Pointer`` field is not used when tag says that it's ``Nothing``.
350   Otherwise ``Pointer`` points to the value in ``Just``. As mentioned
351   above, this type is lazy in its lifted field. Therefore, the type ::
352
353     data Maybe' a = Maybe' (# (# #) | a #)
354
355   is *precisely* isomorphic to the type ``Maybe a``, although its memory
356   representation is different.
357
358   In the degenerate case where all the alternatives have zero width, such
359   as the ``Bool``-like ``(# (# #) | (# #) #)``, the unboxed sum layout only
360   has an ``Int32`` tag field (i.e., the whole thing is represented by an integer).
361
362 .. _syntax-extns:
363
364 Syntactic extensions
365 ====================
366
367 .. _unicode-syntax:
368
369 Unicode syntax
370 --------------
371
372 .. extension:: UnicodeSyntax
373     :shortdesc: Enable unicode syntax.
374
375     :since: 6.8.1
376
377     Enable the use of Unicode characters in place of their equivalent ASCII
378     sequences.
379
380 The language extension :extension:`UnicodeSyntax` enables
381 Unicode characters to be used to stand for certain ASCII character
382 sequences. The following alternatives are provided:
383
384 +--------------+---------------+-------------+-----------------------------------------+
385 | ASCII        | Unicode       | Code point  | Name                                    |
386 |              | alternative   |             |                                         |
387 +==============+===============+=============+=========================================+
388 | ``::``       | ∷             | 0x2237      | PROPORTION                              |
389 +--------------+---------------+-------------+-----------------------------------------+
390 | ``=>``       | ⇒             | 0x21D2      | RIGHTWARDS DOUBLE ARROW                 |
391 +--------------+---------------+-------------+-----------------------------------------+
392 | ``->``       | →             | 0x2192      | RIGHTWARDS ARROW                        |
393 +--------------+---------------+-------------+-----------------------------------------+
394 | ``<-``       | ←             | 0x2190      | LEFTWARDS ARROW                         |
395 +--------------+---------------+-------------+-----------------------------------------+
396 | ``>-``       | ⤚             | 0x291a      | RIGHTWARDS ARROW-TAIL                   |
397 +--------------+---------------+-------------+-----------------------------------------+
398 | ``-<``       | ⤙             | 0x2919      | LEFTWARDS ARROW-TAIL                    |
399 +--------------+---------------+-------------+-----------------------------------------+
400 | ``>>-``      | ⤜             | 0x291C      | RIGHTWARDS DOUBLE ARROW-TAIL            |
401 +--------------+---------------+-------------+-----------------------------------------+
402 | ``-<<``      | ⤛             | 0x291B      | LEFTWARDS DOUBLE ARROW-TAIL             |
403 +--------------+---------------+-------------+-----------------------------------------+
404 | ``*``        | ★             | 0x2605      | BLACK STAR                              |
405 +--------------+---------------+-------------+-----------------------------------------+
406 | ``forall``   | ∀             | 0x2200      | FOR ALL                                 |
407 +--------------+---------------+-------------+-----------------------------------------+
408 | ``(|``       | ⦇             | 0x2987      | Z NOTATION LEFT IMAGE BRACKET           |
409 +--------------+---------------+-------------+-----------------------------------------+
410 | ``|)``       | ⦈             | 0x2988      | Z NOTATION RIGHT IMAGE BRACKET          |
411 +--------------+---------------+-------------+-----------------------------------------+
412 | ``[|``       | ⟦             | 0x27E6      | MATHEMATICAL LEFT WHITE SQUARE BRACKET  |
413 +--------------+---------------+-------------+-----------------------------------------+
414 | ``|]``       | ⟧             | 0x27E7      | MATHEMATICAL RIGHT WHITE SQUARE BRACKET |
415 +--------------+---------------+-------------+-----------------------------------------+
416
417 .. _magic-hash:
418
419 The magic hash
420 --------------
421
422 .. extension:: MagicHash
423     :shortdesc: Allow ``#`` as a postfix modifier on identifiers.
424
425     :since: 6.8.1
426
427     Enables the use of the hash character (``#``) as an identifier suffix.
428
429 The language extension :extension:`MagicHash` allows ``#`` as a postfix modifier
430 to identifiers. Thus, ``x#`` is a valid variable, and ``T#`` is a valid type
431 constructor or data constructor.
432
433 The hash sign does not change semantics at all. We tend to use variable
434 names ending in "#" for unboxed values or types (e.g. ``Int#``), but
435 there is no requirement to do so; they are just plain ordinary
436 variables. Nor does the :extension:`MagicHash` extension bring anything into
437 scope. For example, to bring ``Int#`` into scope you must import
438 ``GHC.Prim`` (see :ref:`primitives`); the :extension:`MagicHash` extension then
439 allows you to *refer* to the ``Int#`` that is now in scope. Note that
440 with this option, the meaning of ``x#y = 0`` is changed: it defines a
441 function ``x#`` taking a single argument ``y``; to define the operator
442 ``#``, put a space: ``x # y = 0``.
443
444 The :extension:`MagicHash` also enables some new forms of literals (see
445 :ref:`glasgow-unboxed`):
446
447 -  ``'x'#`` has type ``Char#``
448
449 -  ``"foo"#`` has type ``Addr#``
450
451 -  ``3#`` has type ``Int#``. In general, any Haskell integer lexeme
452    followed by a ``#`` is an ``Int#`` literal, e.g. ``-0x3A#`` as well as
453    ``32#``.
454
455 -  ``3##`` has type ``Word#``. In general, any non-negative Haskell
456    integer lexeme followed by ``##`` is a ``Word#``.
457
458 -  ``3.2#`` has type ``Float#``.
459
460 -  ``3.2##`` has type ``Double#``
461
462 .. _negative-literals:
463
464 Negative literals
465 -----------------
466
467 .. extension:: NegativeLiterals
468     :shortdesc: Enable support for negative literals.
469
470     :since: 7.8.1
471
472     Enable the use of un-parenthesized negative numeric literals.
473
474 The literal ``-123`` is, according to Haskell98 and Haskell 2010,
475 desugared as ``negate (fromInteger 123)``. The language extension
476 :extension:`NegativeLiterals` means that it is instead desugared as
477 ``fromInteger (-123)``.
478
479 This can make a difference when the positive and negative range of a
480 numeric data type don't match up. For example, in 8-bit arithmetic -128
481 is representable, but +128 is not. So ``negate (fromInteger 128)`` will
482 elicit an unexpected integer-literal-overflow message.
483
484 .. _num-decimals:
485
486 Fractional looking integer literals
487 -----------------------------------
488
489 .. extension:: NumDecimals
490     :shortdesc: Enable support for 'fractional' integer literals.
491
492     :since: 7.8.1
493
494     Allow the use of floating-point literal syntax for integral types.
495
496 Haskell 2010 and Haskell 98 define floating literals with the syntax
497 ``1.2e6``. These literals have the type ``Fractional a => a``.
498
499 The language extension :extension:`NumDecimals` allows you to also use the
500 floating literal syntax for instances of ``Integral``, and have values
501 like ``(1.2e6 :: Num a => a)``
502
503 .. _binary-literals:
504
505 Binary integer literals
506 -----------------------
507
508 .. extension:: BinaryLiterals
509     :shortdesc: Enable support for binary literals.
510
511     :since: 7.10.1
512
513     Allow the use of binary notation in integer literals.
514
515 Haskell 2010 and Haskell 98 allows for integer literals to be given in
516 decimal, octal (prefixed by ``0o`` or ``0O``), or hexadecimal notation
517 (prefixed by ``0x`` or ``0X``).
518
519 The language extension :extension:`BinaryLiterals` adds support for expressing
520 integer literals in binary notation with the prefix ``0b`` or ``0B``. For
521 instance, the binary integer literal ``0b11001001`` will be desugared into
522 ``fromInteger 201`` when :extension:`BinaryLiterals` is enabled.
523
524 .. _hex-float-literals:
525
526 Hexadecimal floating point literals
527 -----------------------------------
528
529 .. extension:: HexFloatLiterals
530     :shortdesc: Enable support for :ref:`hexadecimal floating point literals <hex-float-literals>`.
531
532     :since: 8.4.1
533
534     Allow writing floating point literals using hexadecimal notation.
535
536 The hexadecimal notation for floating point literals is useful when you
537 need to specify floating point constants precisely, as the literal notation
538 corresponds closely to the underlying bit-encoding of the number.
539
540 In this notation floating point numbers are written using hexadecimal digits,
541 and so the digits are interpreted using base 16, rather then the usual 10.
542 This means that digits left of the decimal point correspond to positive
543 powers of 16, while the ones to the right correspond to negative ones.
544
545 You may also write an explicit exponent, which is similar to the exponent
546 in decimal notation with the following differences:
547 - the exponent begins with ``p`` instead of ``e``
548 - the exponent is written in base ``10`` (**not** 16)
549 - the base of the exponent is ``2`` (**not** 16).
550
551 In terms of the underlying bit encoding, each hexadecimal digit corresponds
552 to 4 bits, and you may think of the exponent as "moving" the floating point
553 by one bit left (negative) or right (positive).  Here are some examples:
554
555 -  ``0x0.1``     is the same as ``1/16``
556 -  ``0x0.01``    is the same as ``1/256``
557 -  ``0xF.FF``    is the same as ``15 + 15/16 + 15/256``
558 -  ``0x0.1p4``   is the same as ``1``
559 -  ``0x0.1p-4``  is the same as ``1/256``
560 -  ``0x0.1p12``  is the same as ``256``
561
562
563
564
565 .. _numeric-underscores:
566
567 Numeric underscores
568 -------------------
569
570 .. extension:: NumericUnderscores
571     :shortdesc: Enable support for :ref:`numeric underscores <numeric-underscores>`.
572
573     :since: 8.6.1
574
575     Allow the use of underscores in numeric literals.
576
577 GHC allows for numeric literals to be given in decimal, octal, hexadecimal,
578 binary, or float notation.
579
580 The language extension :extension:`NumericUnderscores` adds support for expressing
581 underscores in numeric literals.
582 For instance, the numeric literal ``1_000_000`` will be parsed into
583 ``1000000`` when :extension:`NumericUnderscores` is enabled.
584 That is, underscores in numeric literals are ignored when
585 :extension:`NumericUnderscores` is enabled.
586 See also :ghc-ticket:`14473`.
587
588 For example: ::
589
590     -- decimal
591     million    = 1_000_000
592     billion    = 1_000_000_000
593     lightspeed = 299_792_458
594     version    = 8_04_1
595     date       = 2017_12_31
596
597     -- hexadecimal
598     red_mask = 0xff_00_00
599     size1G   = 0x3fff_ffff
600
601     -- binary
602     bit8th   = 0b01_0000_0000
603     packbits = 0b1_11_01_0000_0_111
604     bigbits  = 0b1100_1011__1110_1111__0101_0011
605
606     -- float
607     pi       = 3.141_592_653_589_793
608     faraday  = 96_485.332_89
609     avogadro = 6.022_140_857e+23
610
611     -- function
612     isUnderMillion = (< 1_000_000)
613
614     clip64M x
615         | x > 0x3ff_ffff = 0x3ff_ffff
616         | otherwise = x
617
618     test8bit x = (0b01_0000_0000 .&. x) /= 0
619
620 About validity: ::
621
622     x0 = 1_000_000   -- valid
623     x1 = 1__000000   -- valid
624     x2 = 1000000_    -- invalid
625     x3 = _1000000    -- invalid
626
627     e0 = 0.0001      -- valid
628     e1 = 0.000_1     -- valid
629     e2 = 0_.0001     -- invalid
630     e3 = _0.0001     -- invalid
631     e4 = 0._0001     -- invalid
632     e5 = 0.0001_     -- invalid
633
634     f0 = 1e+23       -- valid
635     f1 = 1_e+23      -- valid
636     f2 = 1__e+23     -- valid
637     f3 = 1e_+23      -- invalid
638
639     g0 = 1e+23       -- valid
640     g1 = 1e+_23      -- invalid
641     g2 = 1e+23_      -- invalid
642
643     h0 = 0xffff      -- valid
644     h1 = 0xff_ff     -- valid
645     h2 = 0x_ffff     -- valid
646     h3 = 0x__ffff    -- valid
647     h4 = _0xffff     -- invalid
648
649 .. _pattern-guards:
650
651 Pattern guards
652 --------------
653
654 .. extension:: NoPatternGuards
655     :shortdesc: Disable pattern guards.
656         Implied by :extension:`Haskell98`.
657
658     :implied by: :extension:`Haskell98`
659     :since: 6.8.1
660
661 Disable `pattern guards
662 <http://www.haskell.org/onlinereport/haskell2010/haskellch3.html#x8-460003.13>`__.
663
664 .. _view-patterns:
665
666 View patterns
667 -------------
668
669 .. extension:: ViewPatterns
670     :shortdesc: Enable view patterns.
671
672     :since: 6.10.1
673
674     Allow use of view pattern syntax.
675
676 View patterns are enabled by the language extension :extension:`ViewPatterns`. More
677 information and examples of view patterns can be found on the
678 :ghc-wiki:`Wiki page <ViewPatterns>`.
679
680 View patterns are somewhat like pattern guards that can be nested inside
681 of other patterns. They are a convenient way of pattern-matching against
682 values of abstract types. For example, in a programming language
683 implementation, we might represent the syntax of the types of the
684 language as follows: ::
685
686     type Typ
687
688     data TypView = Unit
689                  | Arrow Typ Typ
690
691     view :: Typ -> TypView
692
693     -- additional operations for constructing Typ's ...
694
695 The representation of Typ is held abstract, permitting implementations
696 to use a fancy representation (e.g., hash-consing to manage sharing).
697 Without view patterns, using this signature is a little inconvenient: ::
698
699     size :: Typ -> Integer
700     size t = case view t of
701       Unit -> 1
702       Arrow t1 t2 -> size t1 + size t2
703
704 It is necessary to iterate the case, rather than using an equational
705 function definition. And the situation is even worse when the matching
706 against ``t`` is buried deep inside another pattern.
707
708 View patterns permit calling the view function inside the pattern and
709 matching against the result: ::
710
711     size (view -> Unit) = 1
712     size (view -> Arrow t1 t2) = size t1 + size t2
713
714 That is, we add a new form of pattern, written ⟨expression⟩ ``->``
715 ⟨pattern⟩ that means "apply the expression to whatever we're trying to
716 match against, and then match the result of that application against the
717 pattern". The expression can be any Haskell expression of function type,
718 and view patterns can be used wherever patterns are used.
719
720 The semantics of a pattern ``(`` ⟨exp⟩ ``->`` ⟨pat⟩ ``)`` are as
721 follows:
722
723 -  Scoping:
724    The variables bound by the view pattern are the variables bound by
725    ⟨pat⟩.
726
727    Any variables in ⟨exp⟩ are bound occurrences, but variables bound "to
728    the left" in a pattern are in scope. This feature permits, for
729    example, one argument to a function to be used in the view of another
730    argument. For example, the function ``clunky`` from
731    :ref:`pattern-guards` can be written using view patterns as follows: ::
732
733        clunky env (lookup env -> Just val1) (lookup env -> Just val2) = val1 + val2
734        ...other equations for clunky...
735
736    More precisely, the scoping rules are:
737
738    -  In a single pattern, variables bound by patterns to the left of a
739       view pattern expression are in scope. For example: ::
740
741           example :: Maybe ((String -> Integer,Integer), String) -> Bool
742           example Just ((f,_), f -> 4) = True
743
744       Additionally, in function definitions, variables bound by matching
745       earlier curried arguments may be used in view pattern expressions
746       in later arguments: ::
747
748           example :: (String -> Integer) -> String -> Bool
749           example f (f -> 4) = True
750
751       That is, the scoping is the same as it would be if the curried
752       arguments were collected into a tuple.
753
754    -  In mutually recursive bindings, such as ``let``, ``where``, or the
755       top level, view patterns in one declaration may not mention
756       variables bound by other declarations. That is, each declaration
757       must be self-contained. For example, the following program is not
758       allowed: ::
759
760           let {(x -> y) = e1 ;
761                (y -> x) = e2 } in x
762
763    (For some amplification on this design choice see :ghc-ticket:`4061`.
764
765 -  Typing: If ⟨exp⟩ has type ⟨T1⟩ ``->`` ⟨T2⟩ and ⟨pat⟩ matches a ⟨T2⟩,
766    then the whole view pattern matches a ⟨T1⟩.
767
768 -  Matching: To the equations in Section 3.17.3 of the `Haskell 98
769    Report <http://www.haskell.org/onlinereport/>`__, add the following: ::
770
771        case v of { (e -> p) -> e1 ; _ -> e2 }
772         =
773        case (e v) of { p -> e1 ; _ -> e2 }
774
775    That is, to match a variable ⟨v⟩ against a pattern ``(`` ⟨exp⟩ ``->``
776    ⟨pat⟩ ``)``, evaluate ``(`` ⟨exp⟩ ⟨v⟩ ``)`` and match the result
777    against ⟨pat⟩.
778
779 -  Efficiency: When the same view function is applied in multiple
780    branches of a function definition or a case expression (e.g., in
781    ``size`` above), GHC makes an attempt to collect these applications
782    into a single nested case expression, so that the view function is
783    only applied once. Pattern compilation in GHC follows the matrix
784    algorithm described in Chapter 4 of `The Implementation of Functional
785    Programming
786    Languages <http://research.microsoft.com/~simonpj/Papers/slpj-book-1987/>`__.
787    When the top rows of the first column of a matrix are all view
788    patterns with the "same" expression, these patterns are transformed
789    into a single nested case. This includes, for example, adjacent view
790    patterns that line up in a tuple, as in
791
792    ::
793
794        f ((view -> A, p1), p2) = e1
795        f ((view -> B, p3), p4) = e2
796
797    The current notion of when two view pattern expressions are "the
798    same" is very restricted: it is not even full syntactic equality.
799    However, it does include variables, literals, applications, and
800    tuples; e.g., two instances of ``view ("hi", "there")`` will be
801    collected. However, the current implementation does not compare up to
802    alpha-equivalence, so two instances of ``(x, view x -> y)`` will not
803    be coalesced.
804
805 .. _n-k-patterns:
806
807 n+k patterns
808 ------------
809
810 .. extension:: NPlusKPatterns
811     :shortdesc: Enable support for ``n+k`` patterns.
812         Implied by :extension:`Haskell98`.
813
814     :implied by: :extension:`Haskell98`
815     :since: 6.12.1
816
817     Enable use of ``n+k`` patterns.
818
819 .. _recursive-do-notation:
820
821 The recursive do-notation
822 -------------------------
823
824 .. extension:: RecursiveDo
825     :shortdesc: Enable recursive do (mdo) notation.
826
827     :since: 6.8.1
828
829     Allow the use of recursive ``do`` notation.
830
831 The do-notation of Haskell 98 does not allow *recursive bindings*, that
832 is, the variables bound in a do-expression are visible only in the
833 textually following code block. Compare this to a let-expression, where
834 bound variables are visible in the entire binding group.
835
836 It turns out that such recursive bindings do indeed make sense for a
837 variety of monads, but not all. In particular, recursion in this sense
838 requires a fixed-point operator for the underlying monad, captured by
839 the ``mfix`` method of the ``MonadFix`` class, defined in
840 ``Control.Monad.Fix`` as follows: ::
841
842     class Monad m => MonadFix m where
843        mfix :: (a -> m a) -> m a
844
845 Haskell's ``Maybe``, ``[]`` (list), ``ST`` (both strict and lazy
846 versions), ``IO``, and many other monads have ``MonadFix`` instances. On
847 the negative side, the continuation monad, with the signature
848 ``(a -> r) -> r``, does not.
849
850 For monads that do belong to the ``MonadFix`` class, GHC provides an
851 extended version of the do-notation that allows recursive bindings. The
852 :extension:`RecursiveDo` (language pragma: ``RecursiveDo``) provides the
853 necessary syntactic support, introducing the keywords ``mdo`` and
854 ``rec`` for higher and lower levels of the notation respectively. Unlike
855 bindings in a ``do`` expression, those introduced by ``mdo`` and ``rec``
856 are recursively defined, much like in an ordinary let-expression. Due to
857 the new keyword ``mdo``, we also call this notation the *mdo-notation*.
858
859 Here is a simple (albeit contrived) example:
860
861 ::
862
863     {-# LANGUAGE RecursiveDo #-}
864     justOnes = mdo { xs <- Just (1:xs)
865                    ; return (map negate xs) }
866
867 or equivalently
868
869 ::
870
871     {-# LANGUAGE RecursiveDo #-}
872     justOnes = do { rec { xs <- Just (1:xs) }
873                   ; return (map negate xs) }
874
875 As you can guess ``justOnes`` will evaluate to ``Just [-1,-1,-1,...``.
876
877 GHC's implementation the mdo-notation closely follows the original
878 translation as described in the paper `A recursive do for
879 Haskell <http://leventerkok.github.io/papers/recdo.pdf>`__, which
880 in turn is based on the work `Value Recursion in Monadic
881 Computations <http://leventerkok.github.io/papers/erkok-thesis.pdf>`__.
882 Furthermore, GHC extends the syntax described in the former paper with a
883 lower level syntax flagged by the ``rec`` keyword, as we describe next.
884
885 Recursive binding groups
886 ~~~~~~~~~~~~~~~~~~~~~~~~
887
888 The extension :extension:`RecursiveDo` also introduces a new keyword ``rec``, which
889 wraps a mutually-recursive group of monadic statements inside a ``do``
890 expression, producing a single statement. Similar to a ``let`` statement
891 inside a ``do``, variables bound in the ``rec`` are visible throughout
892 the ``rec`` group, and below it. For example, compare
893
894 ::
895
896         do { a <- getChar            do { a <- getChar
897            ; let { r1 = f a r2          ; rec { r1 <- f a r2
898            ;     ; r2 = g r1 }          ;     ; r2 <- g r1 }
899            ; return (r1 ++ r2) }        ; return (r1 ++ r2) }
900
901 In both cases, ``r1`` and ``r2`` are available both throughout the
902 ``let`` or ``rec`` block, and in the statements that follow it. The
903 difference is that ``let`` is non-monadic, while ``rec`` is monadic. (In
904 Haskell ``let`` is really ``letrec``, of course.)
905
906 The semantics of ``rec`` is fairly straightforward. Whenever GHC finds a
907 ``rec`` group, it will compute its set of bound variables, and will
908 introduce an appropriate call to the underlying monadic value-recursion
909 operator ``mfix``, belonging to the ``MonadFix`` class. Here is an
910 example:
911
912 ::
913
914     rec { b <- f a c     ===>    (b,c) <- mfix (\ ~(b,c) -> do { b <- f a c
915         ; c <- f b a }                                         ; c <- f b a
916                                                                ; return (b,c) })
917
918 As usual, the meta-variables ``b``, ``c`` etc., can be arbitrary
919 patterns. In general, the statement ``rec ss`` is desugared to the
920 statement
921
922 ::
923
924     vs <- mfix (\ ~vs -> do { ss; return vs })
925
926 where ``vs`` is a tuple of the variables bound by ``ss``.
927
928 Note in particular that the translation for a ``rec`` block only
929 involves wrapping a call to ``mfix``: it performs no other analysis on
930 the bindings. The latter is the task for the ``mdo`` notation, which is
931 described next.
932
933 The ``mdo`` notation
934 ~~~~~~~~~~~~~~~~~~~~
935
936 A ``rec``-block tells the compiler where precisely the recursive knot
937 should be tied. It turns out that the placement of the recursive knots
938 can be rather delicate: in particular, we would like the knots to be
939 wrapped around as minimal groups as possible. This process is known as
940 *segmentation*, and is described in detail in Section 3.2 of `A
941 recursive do for
942 Haskell <http://leventerkok.github.io/papers/recdo.pdf>`__.
943 Segmentation improves polymorphism and reduces the size of the recursive
944 knot. Most importantly, it avoids unnecessary interference caused by a
945 fundamental issue with the so-called *right-shrinking* axiom for monadic
946 recursion. In brief, most monads of interest (IO, strict state, etc.) do
947 *not* have recursion operators that satisfy this axiom, and thus not
948 performing segmentation can cause unnecessary interference, changing the
949 termination behavior of the resulting translation. (Details can be found
950 in Sections 3.1 and 7.2.2 of `Value Recursion in Monadic
951 Computations <http://leventerkok.github.io/papers/erkok-thesis.pdf>`__.)
952
953 The ``mdo`` notation removes the burden of placing explicit ``rec``
954 blocks in the code. Unlike an ordinary ``do`` expression, in which
955 variables bound by statements are only in scope for later statements,
956 variables bound in an ``mdo`` expression are in scope for all statements
957 of the expression. The compiler then automatically identifies minimal
958 mutually recursively dependent segments of statements, treating them as
959 if the user had wrapped a ``rec`` qualifier around them.
960
961 The definition is syntactic:
962
963 -  A generator ⟨g⟩ *depends* on a textually following generator ⟨g'⟩, if
964
965    -  ⟨g'⟩ defines a variable that is used by ⟨g⟩, or
966
967    -  ⟨g'⟩ textually appears between ⟨g⟩ and ⟨g''⟩, where ⟨g⟩ depends on
968       ⟨g''⟩.
969
970 -  A *segment* of a given ``mdo``-expression is a minimal sequence of
971    generators such that no generator of the sequence depends on an
972    outside generator. As a special case, although it is not a generator,
973    the final expression in an ``mdo``-expression is considered to form a
974    segment by itself.
975
976 Segments in this sense are related to *strongly-connected components*
977 analysis, with the exception that bindings in a segment cannot be
978 reordered and must be contiguous.
979
980 Here is an example ``mdo``-expression, and its translation to ``rec``
981 blocks:
982
983 ::
984
985     mdo { a <- getChar      ===> do { a <- getChar
986         ; b <- f a c                ; rec { b <- f a c
987         ; c <- f b a                ;     ; c <- f b a }
988         ; z <- h a b                ; z <- h a b
989         ; d <- g d e                ; rec { d <- g d e
990         ; e <- g a z                ;     ; e <- g a z }
991         ; putChar c }               ; putChar c }
992
993 Note that a given ``mdo`` expression can cause the creation of multiple
994 ``rec`` blocks. If there are no recursive dependencies, ``mdo`` will
995 introduce no ``rec`` blocks. In this latter case an ``mdo`` expression
996 is precisely the same as a ``do`` expression, as one would expect.
997
998 In summary, given an ``mdo`` expression, GHC first performs
999 segmentation, introducing ``rec`` blocks to wrap over minimal recursive
1000 groups. Then, each resulting ``rec`` is desugared, using a call to
1001 ``Control.Monad.Fix.mfix`` as described in the previous section. The
1002 original ``mdo``-expression typechecks exactly when the desugared
1003 version would do so.
1004
1005 Here are some other important points in using the recursive-do notation:
1006
1007 -  It is enabled with the extension :extension:`RecursiveDo`, or the
1008    ``LANGUAGE RecursiveDo`` pragma. (The same extension enables both
1009    ``mdo``-notation, and the use of ``rec`` blocks inside ``do``
1010    expressions.)
1011
1012 -  ``rec`` blocks can also be used inside ``mdo``-expressions, which
1013    will be treated as a single statement. However, it is good style to
1014    either use ``mdo`` or ``rec`` blocks in a single expression.
1015
1016 -  If recursive bindings are required for a monad, then that monad must
1017    be declared an instance of the ``MonadFix`` class.
1018
1019 -  The following instances of ``MonadFix`` are automatically provided:
1020    List, Maybe, IO. Furthermore, the ``Control.Monad.ST`` and
1021    ``Control.Monad.ST.Lazy`` modules provide the instances of the
1022    ``MonadFix`` class for Haskell's internal state monad (strict and
1023    lazy, respectively).
1024
1025 -  Like ``let`` and ``where`` bindings, name shadowing is not allowed
1026    within an ``mdo``-expression or a ``rec``-block; that is, all the
1027    names bound in a single ``rec`` must be distinct. (GHC will complain
1028    if this is not the case.)
1029
1030 .. _applicative-do:
1031
1032 Applicative do-notation
1033 -----------------------
1034
1035 .. index::
1036    single: Applicative do-notation
1037    single: do-notation; Applicative
1038
1039 .. extension:: ApplicativeDo
1040     :shortdesc: Enable Applicative do-notation desugaring
1041
1042     :since: 8.0.1
1043
1044     Allow use of ``Applicative`` ``do`` notation.
1045
1046 The language option :extension:`ApplicativeDo` enables an alternative translation for
1047 the do-notation, which uses the operators ``<$>``, ``<*>``, along with ``join``
1048 as far as possible. There are two main reasons for wanting to do this:
1049
1050 -  We can use do-notation with types that are an instance of ``Applicative`` and
1051    ``Functor``, but not ``Monad``
1052 -  In some monads, using the applicative operators is more efficient than monadic
1053    bind. For example, it may enable more parallelism.
1054
1055 Applicative do-notation desugaring preserves the original semantics, provided
1056 that the ``Applicative`` instance satisfies ``<*> = ap`` and ``pure = return``
1057 (these are true of all the common monadic types). Thus, you can normally turn on
1058 :extension:`ApplicativeDo` without fear of breaking your program. There is one pitfall
1059 to watch out for; see :ref:`applicative-do-pitfall`.
1060
1061 There are no syntactic changes with :extension:`ApplicativeDo`. The only way it shows
1062 up at the source level is that you can have a ``do`` expression that doesn't
1063 require a ``Monad`` constraint. For example, in GHCi: ::
1064
1065     Prelude> :set -XApplicativeDo
1066     Prelude> :t \m -> do { x <- m; return (not x) }
1067     \m -> do { x <- m; return (not x) }
1068       :: Functor f => f Bool -> f Bool
1069
1070 This example only requires ``Functor``, because it is translated into ``(\x ->
1071 not x) <$> m``. A more complex example requires ``Applicative``, ::
1072
1073     Prelude> :t \m -> do { x <- m 'a'; y <- m 'b'; return (x || y) }
1074     \m -> do { x <- m 'a'; y <- m 'b'; return (x || y) }
1075       :: Applicative f => (Char -> f Bool) -> f Bool
1076
1077 Here GHC has translated the expression into ::
1078
1079     (\x y -> x || y) <$> m 'a' <*> m 'b'
1080
1081 It is possible to see the actual translation by using :ghc-flag:`-ddump-ds`, but be
1082 warned, the output is quite verbose.
1083
1084 Note that if the expression can't be translated into uses of ``<$>``, ``<*>``
1085 only, then it will incur a ``Monad`` constraint as usual. This happens when
1086 there is a dependency on a value produced by an earlier statement in the
1087 ``do``-block: ::
1088
1089     Prelude> :t \m -> do { x <- m True; y <- m x; return (x || y) }
1090     \m -> do { x <- m True; y <- m x; return (x || y) }
1091       :: Monad m => (Bool -> m Bool) -> m Bool
1092
1093 Here, ``m x`` depends on the value of ``x`` produced by the first statement, so
1094 the expression cannot be translated using ``<*>``.
1095
1096 In general, the rule for when a ``do`` statement incurs a ``Monad`` constraint
1097 is as follows. If the do-expression has the following form: ::
1098
1099     do p1 <- E1; ...; pn <- En; return E
1100
1101 where none of the variables defined by ``p1...pn`` are mentioned in ``E1...En``,
1102 and ``p1...pn`` are all variables or lazy patterns,
1103 then the expression will only require ``Applicative``. Otherwise, the expression
1104 will require ``Monad``. The block may return a pure expression ``E`` depending
1105 upon the results ``p1...pn`` with either ``return`` or ``pure``.
1106
1107 Note: the final statement must match one of these patterns exactly:
1108
1109 - ``return E``
1110 - ``return $ E``
1111 - ``pure E``
1112 - ``pure $ E``
1113
1114 otherwise GHC cannot recognise it as a ``return`` statement, and the
1115 transformation to use ``<$>`` that we saw above does not apply.  In
1116 particular, slight variations such as ``return . Just $ x`` or ``let x
1117 = e in return x`` would not be recognised.
1118
1119 If the final statement is not of one of these forms, GHC falls back to
1120 standard ``do`` desugaring, and the expression will require a
1121 ``Monad`` constraint.
1122
1123 When the statements of a ``do`` expression have dependencies between
1124 them, and ``ApplicativeDo`` cannot infer an ``Applicative`` type, it
1125 uses a heuristic algorithm to try to use ``<*>`` as much as possible.
1126 This algorithm usually finds the best solution, but in rare complex
1127 cases it might miss an opportunity.  There is an algorithm that finds
1128 the optimal solution, provided as an option:
1129
1130 .. ghc-flag:: -foptimal-applicative-do
1131     :shortdesc: Use a slower but better algorithm for ApplicativeDo
1132     :type: dynamic
1133     :reverse: -fno-optimal-applicative-do
1134     :category: optimization
1135
1136     :since: 8.0.1
1137
1138     Enables an alternative algorithm for choosing where to use ``<*>``
1139     in conjunction with the ``ApplicativeDo`` language extension.
1140     This algorithm always finds the optimal solution, but it is
1141     expensive: ``O(n^3)``, so this option can lead to long compile
1142     times when there are very large ``do`` expressions (over 100
1143     statements).  The default ``ApplicativeDo`` algorithm is ``O(n^2)``.
1144
1145
1146 .. _applicative-do-strict:
1147
1148 Strict patterns
1149 ~~~~~~~~~~~~~~~
1150
1151
1152 A strict pattern match in a bind statement prevents
1153 ``ApplicativeDo`` from transforming that statement to use
1154 ``Applicative``.  This is because the transformation would change the
1155 semantics by making the expression lazier.
1156
1157 For example, this code will require a ``Monad`` constraint::
1158
1159     > :t \m -> do { (x:xs) <- m; return x }
1160     \m -> do { (x:xs) <- m; return x } :: Monad m => m [b] -> m b
1161
1162 but making the pattern match lazy allows it to have a ``Functor`` constraint::
1163
1164     > :t \m -> do { ~(x:xs) <- m; return x }
1165     \m -> do { ~(x:xs) <- m; return x } :: Functor f => f [b] -> f b
1166
1167 A "strict pattern match" is any pattern match that can fail.  For
1168 example, ``()``, ``(x:xs)``, ``!z``, and ``C x`` are strict patterns,
1169 but ``x`` and ``~(1,2)`` are not.  For the purposes of
1170 ``ApplicativeDo``, a pattern match against a ``newtype`` constructor
1171 is considered strict.
1172
1173 When there's a strict pattern match in a sequence of statements,
1174 ``ApplicativeDo`` places a ``>>=`` between that statement and the one
1175 that follows it.  The sequence may be transformed to use ``<*>``
1176 elsewhere, but the strict pattern match and the following statement
1177 will always be connected with ``>>=``, to retain the same strictness
1178 semantics as the standard do-notation.  If you don't want this, simply
1179 put a ``~`` on the pattern match to make it lazy.
1180
1181 .. _applicative-do-pitfall:
1182
1183 Things to watch out for
1184 ~~~~~~~~~~~~~~~~~~~~~~~
1185
1186 Your code should just work as before when :extension:`ApplicativeDo` is enabled,
1187 provided you use conventional ``Applicative`` instances. However, if you define
1188 a ``Functor`` or ``Applicative`` instance using do-notation, then it will likely
1189 get turned into an infinite loop by GHC. For example, if you do this: ::
1190
1191     instance Functor MyType where
1192         fmap f m = do x <- m; return (f x)
1193
1194 Then applicative desugaring will turn it into ::
1195
1196     instance Functor MyType where
1197         fmap f m = fmap (\x -> f x) m
1198
1199 And the program will loop at runtime. Similarly, an ``Applicative`` instance
1200 like this ::
1201
1202     instance Applicative MyType where
1203         pure = return
1204         x <*> y = do f <- x; a <- y; return (f a)
1205
1206 will result in an infinte loop when ``<*>`` is called.
1207
1208 Just as you wouldn't define a ``Monad`` instance using the do-notation, you
1209 shouldn't define ``Functor`` or ``Applicative`` instance using do-notation (when
1210 using ``ApplicativeDo``) either. The correct way to define these instances in
1211 terms of ``Monad`` is to use the ``Monad`` operations directly, e.g. ::
1212
1213     instance Functor MyType where
1214         fmap f m = m >>= return . f
1215
1216     instance Applicative MyType where
1217         pure = return
1218         (<*>) = ap
1219
1220
1221 .. _parallel-list-comprehensions:
1222
1223 Parallel List Comprehensions
1224 ----------------------------
1225
1226 .. index::
1227    single: list comprehensions; parallel
1228    single: parallel list comprehensions
1229
1230 .. extension:: ParallelListComp
1231     :shortdesc: Enable parallel list comprehensions.
1232
1233     :since: 6.8.1
1234
1235     Allow parallel list comprehension syntax.
1236
1237 Parallel list comprehensions are a natural extension to list
1238 comprehensions. List comprehensions can be thought of as a nice syntax
1239 for writing maps and filters. Parallel comprehensions extend this to
1240 include the ``zipWith`` family.
1241
1242 A parallel list comprehension has multiple independent branches of
1243 qualifier lists, each separated by a ``|`` symbol. For example, the
1244 following zips together two lists: ::
1245
1246        [ (x, y) | x <- xs | y <- ys ]
1247
1248 The behaviour of parallel list comprehensions follows that of zip, in
1249 that the resulting list will have the same length as the shortest
1250 branch.
1251
1252 We can define parallel list comprehensions by translation to regular
1253 comprehensions. Here's the basic idea:
1254
1255 Given a parallel comprehension of the form: ::
1256
1257        [ e | p1 <- e11, p2 <- e12, ...
1258            | q1 <- e21, q2 <- e22, ...
1259            ...
1260        ]
1261
1262 This will be translated to: ::
1263
1264        [ e | ((p1,p2), (q1,q2), ...) <- zipN [(p1,p2) | p1 <- e11, p2 <- e12, ...]
1265                                              [(q1,q2) | q1 <- e21, q2 <- e22, ...]
1266                                              ...
1267        ]
1268
1269 where ``zipN`` is the appropriate zip for the given number of branches.
1270
1271 .. _generalised-list-comprehensions:
1272
1273 Generalised (SQL-like) List Comprehensions
1274 ------------------------------------------
1275
1276 .. index::
1277    single: list comprehensions; generalised
1278    single: extended list comprehensions
1279    single: group
1280    single: SQL
1281
1282 .. extension:: TransformListComp
1283     :shortdesc: Enable generalised list comprehensions.
1284
1285     :since: 6.10.1
1286
1287     Allow use of generalised list (SQL-like) comprehension syntax. This
1288     introduces the ``group``, ``by``, and ``using`` keywords.
1289
1290 Generalised list comprehensions are a further enhancement to the list
1291 comprehension syntactic sugar to allow operations such as sorting and
1292 grouping which are familiar from SQL. They are fully described in the
1293 paper `Comprehensive comprehensions: comprehensions with "order by" and
1294 "group by" <https://www.microsoft.com/en-us/research/wp-content/uploads/2007/09/list-comp.pdf>`__,
1295 except that the syntax we use differs slightly from the paper.
1296
1297 The extension is enabled with the extension :extension:`TransformListComp`.
1298
1299 Here is an example:
1300
1301 ::
1302
1303     employees = [ ("Simon", "MS", 80)
1304                 , ("Erik", "MS", 100)
1305                 , ("Phil", "Ed", 40)
1306                 , ("Gordon", "Ed", 45)
1307                 , ("Paul", "Yale", 60) ]
1308
1309     output = [ (the dept, sum salary)
1310              | (name, dept, salary) <- employees
1311              , then group by dept using groupWith
1312              , then sortWith by (sum salary)
1313              , then take 5 ]
1314
1315 In this example, the list ``output`` would take on the value:
1316
1317 ::
1318
1319     [("Yale", 60), ("Ed", 85), ("MS", 180)]
1320
1321 There are three new keywords: ``group``, ``by``, and ``using``. (The
1322 functions ``sortWith`` and ``groupWith`` are not keywords; they are
1323 ordinary functions that are exported by ``GHC.Exts``.)
1324
1325 There are five new forms of comprehension qualifier, all introduced by
1326 the (existing) keyword ``then``:
1327
1328 -  ::
1329
1330        then f
1331
1332    This statement requires that
1333    f
1334    have the type
1335    forall a. [a] -> [a]
1336    . You can see an example of its use in the motivating example, as
1337    this form is used to apply
1338    take 5
1339    .
1340 -  ::
1341
1342        then f by e
1343
1344    This form is similar to the previous one, but allows you to create a
1345    function which will be passed as the first argument to f. As a
1346    consequence f must have the type
1347    ``forall a. (a -> t) -> [a] -> [a]``. As you can see from the type,
1348    this function lets f "project out" some information from the elements
1349    of the list it is transforming.
1350
1351    An example is shown in the opening example, where ``sortWith`` is
1352    supplied with a function that lets it find out the ``sum salary`` for
1353    any item in the list comprehension it transforms.
1354
1355 -  ::
1356
1357        then group by e using f
1358
1359    This is the most general of the grouping-type statements. In this
1360    form, f is required to have type
1361    ``forall a. (a -> t) -> [a] -> [[a]]``. As with the ``then f by e``
1362    case above, the first argument is a function supplied to f by the
1363    compiler which lets it compute e on every element of the list being
1364    transformed. However, unlike the non-grouping case, f additionally
1365    partitions the list into a number of sublists: this means that at
1366    every point after this statement, binders occurring before it in the
1367    comprehension refer to *lists* of possible values, not single values.
1368    To help understand this, let's look at an example:
1369
1370    ::
1371
1372        -- This works similarly to groupWith in GHC.Exts, but doesn't sort its input first
1373        groupRuns :: Eq b => (a -> b) -> [a] -> [[a]]
1374        groupRuns f = groupBy (\x y -> f x == f y)
1375
1376        output = [ (the x, y)
1377        | x <- ([1..3] ++ [1..2])
1378        , y <- [4..6]
1379        , then group by x using groupRuns ]
1380
1381    This results in the variable ``output`` taking on the value below:
1382
1383    ::
1384
1385        [(1, [4, 5, 6]), (2, [4, 5, 6]), (3, [4, 5, 6]), (1, [4, 5, 6]), (2, [4, 5, 6])]
1386
1387    Note that we have used the ``the`` function to change the type of x
1388    from a list to its original numeric type. The variable y, in
1389    contrast, is left unchanged from the list form introduced by the
1390    grouping.
1391
1392 -  ::
1393
1394        then group using f
1395
1396    With this form of the group statement, f is required to simply have
1397    the type ``forall a. [a] -> [[a]]``, which will be used to group up
1398    the comprehension so far directly. An example of this form is as
1399    follows:
1400
1401    ::
1402
1403        output = [ x
1404        | y <- [1..5]
1405        , x <- "hello"
1406        , then group using inits]
1407
1408    This will yield a list containing every prefix of the word "hello"
1409    written out 5 times:
1410
1411    ::
1412
1413        ["","h","he","hel","hell","hello","helloh","hellohe","hellohel","hellohell","hellohello","hellohelloh",...]
1414
1415 .. _monad-comprehensions:
1416
1417 Monad comprehensions
1418 --------------------
1419
1420 .. index::
1421    single: monad comprehensions
1422
1423 .. extension:: MonadComprehensions
1424     :shortdesc: Enable monad comprehensions.
1425
1426     :since: 7.2.1
1427
1428     Enable list comprehension syntax for arbitrary monads.
1429
1430 Monad comprehensions generalise the list comprehension notation,
1431 including parallel comprehensions (:ref:`parallel-list-comprehensions`)
1432 and transform comprehensions (:ref:`generalised-list-comprehensions`) to
1433 work for any monad.
1434
1435 Monad comprehensions support:
1436
1437 -  Bindings: ::
1438
1439        [ x + y | x <- Just 1, y <- Just 2 ]
1440
1441    Bindings are translated with the ``(>>=)`` and ``return`` functions
1442    to the usual do-notation: ::
1443
1444        do x <- Just 1
1445           y <- Just 2
1446           return (x+y)
1447
1448 -  Guards: ::
1449
1450        [ x | x <- [1..10], x <= 5 ]
1451
1452    Guards are translated with the ``guard`` function, which requires a
1453    ``MonadPlus`` instance: ::
1454
1455        do x <- [1..10]
1456           guard (x <= 5)
1457           return x
1458
1459 -  Transform statements (as with :extension:`TransformListComp`): ::
1460
1461        [ x+y | x <- [1..10], y <- [1..x], then take 2 ]
1462
1463    This translates to: ::
1464
1465        do (x,y) <- take 2 (do x <- [1..10]
1466                               y <- [1..x]
1467                               return (x,y))
1468           return (x+y)
1469
1470 -  Group statements (as with :extension:`TransformListComp`):
1471
1472    ::
1473
1474        [ x | x <- [1,1,2,2,3], then group by x using GHC.Exts.groupWith ]
1475        [ x | x <- [1,1,2,2,3], then group using myGroup ]
1476
1477 -  Parallel statements (as with :extension:`ParallelListComp`):
1478
1479    ::
1480
1481        [ (x+y) | x <- [1..10]
1482                | y <- [11..20]
1483                ]
1484
1485    Parallel statements are translated using the ``mzip`` function, which
1486    requires a ``MonadZip`` instance defined in
1487    :base-ref:`Control.Monad.Zip.`:
1488
1489    ::
1490
1491        do (x,y) <- mzip (do x <- [1..10]
1492                             return x)
1493                         (do y <- [11..20]
1494                             return y)
1495           return (x+y)
1496
1497 All these features are enabled by default if the :extension:`MonadComprehensions`
1498 extension is enabled. The types and more detailed examples on how to use
1499 comprehensions are explained in the previous chapters
1500 :ref:`generalised-list-comprehensions` and
1501 :ref:`parallel-list-comprehensions`. In general you just have to replace
1502 the type ``[a]`` with the type ``Monad m => m a`` for monad
1503 comprehensions.
1504
1505 .. note::
1506     Even though most of these examples are using the list monad, monad
1507     comprehensions work for any monad. The ``base`` package offers all
1508     necessary instances for lists, which make :extension:`MonadComprehensions`
1509     backward compatible to built-in, transform and parallel list
1510     comprehensions.
1511
1512 More formally, the desugaring is as follows. We write ``D[ e | Q]`` to
1513 mean the desugaring of the monad comprehension ``[ e | Q]``:
1514
1515 .. code-block:: none
1516
1517     Expressions: e
1518     Declarations: d
1519     Lists of qualifiers: Q,R,S
1520
1521     -- Basic forms
1522     D[ e | ]               = return e
1523     D[ e | p <- e, Q ]  = e >>= \p -> D[ e | Q ]
1524     D[ e | e, Q ]          = guard e >> \p -> D[ e | Q ]
1525     D[ e | let d, Q ]      = let d in D[ e | Q ]
1526
1527     -- Parallel comprehensions (iterate for multiple parallel branches)
1528     D[ e | (Q | R), S ]    = mzip D[ Qv | Q ] D[ Rv | R ] >>= \(Qv,Rv) -> D[ e | S ]
1529
1530     -- Transform comprehensions
1531     D[ e | Q then f, R ]                  = f D[ Qv | Q ] >>= \Qv -> D[ e | R ]
1532
1533     D[ e | Q then f by b, R ]             = f (\Qv -> b) D[ Qv | Q ] >>= \Qv -> D[ e | R ]
1534
1535     D[ e | Q then group using f, R ]      = f D[ Qv | Q ] >>= \ys ->
1536                                             case (fmap selQv1 ys, ..., fmap selQvn ys) of
1537                                              Qv -> D[ e | R ]
1538
1539     D[ e | Q then group by b using f, R ] = f (\Qv -> b) D[ Qv | Q ] >>= \ys ->
1540                                             case (fmap selQv1 ys, ..., fmap selQvn ys) of
1541                                                Qv -> D[ e | R ]
1542
1543     where  Qv is the tuple of variables bound by Q (and used subsequently)
1544            selQvi is a selector mapping Qv to the ith component of Qv
1545
1546     Operator     Standard binding       Expected type
1547     --------------------------------------------------------------------
1548     return       GHC.Base               t1 -> m t2
1549     (>>=)        GHC.Base               m1 t1 -> (t2 -> m2 t3) -> m3 t3
1550     (>>)         GHC.Base               m1 t1 -> m2 t2         -> m3 t3
1551     guard        Control.Monad          t1 -> m t2
1552     fmap         GHC.Base               forall a b. (a->b) -> n a -> n b
1553     mzip         Control.Monad.Zip      forall a b. m a -> m b -> m (a,b)
1554
1555 The comprehension should typecheck when its desugaring would typecheck,
1556 except that (as discussed in :ref:`generalised-list-comprehensions`) in the
1557 "then ``f``" and "then group using ``f``" clauses, when the "by ``b``" qualifier
1558 is omitted, argument ``f`` should have a polymorphic type. In particular, "then
1559 ``Data.List.sort``" and "then group using ``Data.List.group``" are
1560 insufficiently polymorphic.
1561
1562 Monad comprehensions support rebindable syntax
1563 (:ref:`rebindable-syntax`). Without rebindable syntax, the operators
1564 from the "standard binding" module are used; with rebindable syntax, the
1565 operators are looked up in the current lexical scope. For example,
1566 parallel comprehensions will be typechecked and desugared using whatever
1567 "``mzip``" is in scope.
1568
1569 The rebindable operators must have the "Expected type" given in the
1570 table above. These types are surprisingly general. For example, you can
1571 use a bind operator with the type
1572
1573 ::
1574
1575     (>>=) :: T x y a -> (a -> T y z b) -> T x z b
1576
1577 In the case of transform comprehensions, notice that the groups are
1578 parameterised over some arbitrary type ``n`` (provided it has an
1579 ``fmap``, as well as the comprehension being over an arbitrary monad.
1580
1581 .. _monadfail-desugaring:
1582
1583 New monadic failure desugaring mechanism
1584 ----------------------------------------
1585
1586 .. extension:: MonadFailDesugaring
1587     :shortdesc: Enable monadfail desugaring.
1588
1589     :since: 8.0.1
1590
1591     Use the ``MonadFail.fail`` instead of the legacy ``Monad.fail`` function
1592     when desugaring refutable patterns in ``do`` blocks.
1593
1594 The ``-XMonadFailDesugaring`` extension switches the desugaring of
1595 ``do``-blocks to use ``MonadFail.fail`` instead of ``Monad.fail``.
1596
1597 This extension is enabled by default since GHC 8.6.1, under the
1598 `MonadFail Proposal (MFP)
1599 <https://prime.haskell.org/wiki/Libraries/Proposals/MonadFail>`__.
1600
1601 This extension is temporary, and will be deprecated in a future release.
1602
1603 .. _rebindable-syntax:
1604
1605 Rebindable syntax and the implicit Prelude import
1606 -------------------------------------------------
1607
1608 .. extension:: NoImplicitPrelude
1609     :shortdesc: Don't implicitly ``import Prelude``.
1610         Implied by :extension:`RebindableSyntax`.
1611
1612     :since: 6.8.1
1613
1614     Don't import ``Prelude`` by default.
1615
1616 GHC normally imports ``Prelude.hi`` files for
1617 you. If you'd rather it didn't, then give it a ``-XNoImplicitPrelude``
1618 option. The idea is that you can then import a Prelude of your own. (But
1619 don't call it ``Prelude``; the Haskell module namespace is flat, and you
1620 must not conflict with any Prelude module.)
1621
1622 .. extension:: RebindableSyntax
1623     :shortdesc: Employ rebindable syntax.
1624         Implies :extension:`NoImplicitPrelude`.
1625
1626     :implies: :extension:`NoImplicitPrelude`
1627     :since: 7.0.1
1628
1629     Enable rebinding of a variety of usually-built-in operations.
1630
1631 Suppose you are importing a Prelude of your own in order to define your
1632 own numeric class hierarchy. It completely defeats that purpose if the
1633 literal "1" means "``Prelude.fromInteger 1``", which is what the Haskell
1634 Report specifies. So the :extension:`RebindableSyntax` extension causes the
1635 following pieces of built-in syntax to refer to *whatever is in scope*,
1636 not the Prelude versions:
1637
1638 -  An integer literal ``368`` means "``fromInteger (368::Integer)``",
1639    rather than "``Prelude.fromInteger (368::Integer)``".
1640
1641 -  Fractional literals are handed in just the same way, except that the
1642    translation is ``fromRational (3.68::Rational)``.
1643
1644 -  The equality test in an overloaded numeric pattern uses whatever
1645    ``(==)`` is in scope.
1646
1647 -  The subtraction operation, and the greater-than-or-equal test, in
1648    ``n+k`` patterns use whatever ``(-)`` and ``(>=)`` are in scope.
1649
1650 -  Negation (e.g. "``- (f x)``") means "``negate (f x)``", both in
1651    numeric patterns, and expressions.
1652
1653 -  Conditionals (e.g. "``if`` e1 ``then`` e2 ``else`` e3") means
1654    "``ifThenElse`` e1 e2 e3". However ``case`` expressions are
1655    unaffected.
1656
1657 -  "Do" notation is translated using whatever functions ``(>>=)``,
1658    ``(>>)``, and ``fail``, are in scope (not the Prelude versions). List
1659    comprehensions, ``mdo`` (:ref:`recursive-do-notation`), and parallel
1660    array comprehensions, are unaffected.
1661
1662 -  Arrow notation (see :ref:`arrow-notation`) uses whatever ``arr``,
1663    ``(>>>)``, ``first``, ``app``, ``(|||)`` and ``loop`` functions are
1664    in scope. But unlike the other constructs, the types of these
1665    functions must match the Prelude types very closely. Details are in
1666    flux; if you want to use this, ask!
1667
1668 -  List notation, such as ``[x,y]`` or ``[m..n]`` can also be treated
1669    via rebindable syntax if you use `-XOverloadedLists`;
1670    see :ref:`overloaded-lists`.
1671
1672 -  An overloaded label "``#foo``" means "``fromLabel @"foo"``", rather than
1673    "``GHC.OverloadedLabels.fromLabel @"foo"``" (see :ref:`overloaded-labels`).
1674
1675 :extension:`RebindableSyntax` implies :extension:`NoImplicitPrelude`.
1676
1677 In all cases (apart from arrow notation), the static semantics should be
1678 that of the desugared form, even if that is a little unexpected. For
1679 example, the static semantics of the literal ``368`` is exactly that of
1680 ``fromInteger (368::Integer)``; it's fine for ``fromInteger`` to have
1681 any of the types: ::
1682
1683     fromInteger :: Integer -> Integer
1684     fromInteger :: forall a. Foo a => Integer -> a
1685     fromInteger :: Num a => a -> Integer
1686     fromInteger :: Integer -> Bool -> Bool
1687
1688 Be warned: this is an experimental facility, with fewer checks than
1689 usual. Use ``-dcore-lint`` to typecheck the desugared program. If Core
1690 Lint is happy you should be all right.
1691
1692 Things unaffected by :extension:`RebindableSyntax`
1693 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1694
1695 :extension:`RebindableSyntax` does not apply to any code generated from a
1696 ``deriving`` clause or declaration. To see why, consider the following code: ::
1697
1698     {-# LANGUAGE RebindableSyntax, OverloadedStrings #-}
1699     newtype Text = Text String
1700
1701     fromString :: String -> Text
1702     fromString = Text
1703
1704     data Foo = Foo deriving Show
1705
1706 This will generate code to the effect of: ::
1707
1708     instance Show Foo where
1709       showsPrec _ Foo = showString "Foo"
1710
1711 But because :extension:`RebindableSyntax` and :extension:`OverloadedStrings`
1712 are enabled, the ``"Foo"`` string literal would now be of type ``Text``, not
1713 ``String``, which ``showString`` doesn't accept! This causes the generated
1714 ``Show`` instance to fail to typecheck. It's hard to imagine any scenario where
1715 it would be desirable have :extension:`RebindableSyntax` behavior within
1716 derived code, so GHC simply ignores :extension:`RebindableSyntax` entirely
1717 when checking derived code.
1718
1719 .. _postfix-operators:
1720
1721 Postfix operators
1722 -----------------
1723
1724 .. extension:: PostfixOperators
1725     :shortdesc: Enable postfix operators.
1726
1727     :since: 7.10.1
1728
1729     Allow the use of post-fix operators
1730
1731 The :extension:`PostfixOperators` extension enables a small extension to the syntax
1732 of left operator sections, which allows you to define postfix operators.
1733 The extension is this: the left section ::
1734
1735       (e !)
1736
1737 is equivalent (from the point of view of both type checking and
1738 execution) to the expression ::
1739
1740       ((!) e)
1741
1742 (for any expression ``e`` and operator ``(!)``. The strict Haskell 98
1743 interpretation is that the section is equivalent to ::
1744
1745       (\y -> (!) e y)
1746
1747 That is, the operator must be a function of two arguments. GHC allows it
1748 to take only one argument, and that in turn allows you to write the
1749 function postfix.
1750
1751 The extension does not extend to the left-hand side of function
1752 definitions; you must define such a function in prefix form.
1753
1754 .. _tuple-sections:
1755
1756 Tuple sections
1757 --------------
1758
1759 .. extension:: TupleSections
1760     :shortdesc: Enable tuple sections.
1761
1762     :since: 6.12
1763
1764     Allow the use of tuple section syntax
1765
1766 The :extension:`TupleSections` extension enables partially applied
1767 tuple constructors. For example, the following program ::
1768
1769       (, True)
1770
1771 is considered to be an alternative notation for the more unwieldy
1772 alternative ::
1773
1774       \x -> (x, True)
1775
1776 You can omit any combination of arguments to the tuple, as in the
1777 following ::
1778
1779       (, "I", , , "Love", , 1337)
1780
1781 which translates to ::
1782
1783       \a b c d -> (a, "I", b, c, "Love", d, 1337)
1784
1785 If you have `unboxed tuples <#unboxed-tuples>`__ enabled, tuple sections
1786 will also be available for them, like so ::
1787
1788       (# , True #)
1789
1790 Because there is no unboxed unit tuple, the following expression ::
1791
1792       (# #)
1793
1794 continues to stand for the unboxed singleton tuple data constructor.
1795
1796 .. _lambda-case:
1797
1798 Lambda-case
1799 -----------
1800
1801 .. extension:: LambdaCase
1802     :shortdesc: Enable lambda-case expressions.
1803
1804     :since: 7.6.1
1805
1806     Allow the use of lambda-case syntax.
1807
1808 The :extension:`LambdaCase` extension enables expressions of the form ::
1809
1810       \case { p1 -> e1; ...; pN -> eN }
1811
1812 which is equivalent to ::
1813
1814       \freshName -> case freshName of { p1 -> e1; ...; pN -> eN }
1815
1816 Note that ``\case`` starts a layout, so you can write ::
1817
1818       \case
1819         p1 -> e1
1820         ...
1821         pN -> eN
1822
1823 .. _empty-case:
1824
1825 Empty case alternatives
1826 -----------------------
1827
1828 .. extension:: EmptyCase
1829     :shortdesc: Allow empty case alternatives.
1830
1831     :since: 7.8.1
1832
1833     Allow empty case expressions.
1834
1835 The :extension:`EmptyCase` extension enables case expressions, or lambda-case
1836 expressions, that have no alternatives, thus: ::
1837
1838     case e of { }   -- No alternatives
1839
1840 or ::
1841
1842     \case { }       -- -XLambdaCase is also required
1843
1844 This can be useful when you know that the expression being scrutinised
1845 has no non-bottom values. For example:
1846
1847 ::
1848
1849       data Void
1850       f :: Void -> Int
1851       f x = case x of { }
1852
1853 With dependently-typed features it is more useful (see :ghc-ticket:`2431`). For
1854 example, consider these two candidate definitions of ``absurd``:
1855
1856 ::
1857
1858     data a :~: b where
1859       Refl :: a :~: a
1860
1861     absurd :: True :~: False -> a
1862     absurd x = error "absurd"    -- (A)
1863     absurd x = case x of {}      -- (B)
1864
1865 We much prefer (B). Why? Because GHC can figure out that
1866 ``(True :~: False)`` is an empty type. So (B) has no partiality and GHC
1867 is able to compile with :ghc-flag:`-Wincomplete-patterns` and
1868 :ghc-flag:`-Werror`. On the other hand (A) looks dangerous, and GHC doesn't
1869 check to make sure that, in fact, the function can never get called.
1870
1871 .. _multi-way-if:
1872
1873 Multi-way if-expressions
1874 ------------------------
1875
1876 .. extension:: MultiWayIf
1877     :shortdesc: Enable multi-way if-expressions.
1878
1879     :since: 7.6.1
1880
1881     Allow the use of multi-way-``if`` syntax.
1882
1883 With :extension:`MultiWayIf` extension GHC accepts conditional expressions with
1884 multiple branches: ::
1885
1886       if | guard1 -> expr1
1887          | ...
1888          | guardN -> exprN
1889
1890 which is roughly equivalent to ::
1891
1892       case () of
1893         _ | guard1 -> expr1
1894         ...
1895         _ | guardN -> exprN
1896
1897 Multi-way if expressions introduce a new layout context. So the example
1898 above is equivalent to: ::
1899
1900       if { | guard1 -> expr1
1901          ; | ...
1902          ; | guardN -> exprN
1903          }
1904
1905 The following behaves as expected: ::
1906
1907       if | guard1 -> if | guard2 -> expr2
1908                         | guard3 -> expr3
1909          | guard4 -> expr4
1910
1911 because layout translates it as ::
1912
1913       if { | guard1 -> if { | guard2 -> expr2
1914                           ; | guard3 -> expr3
1915                           }
1916          ; | guard4 -> expr4
1917          }
1918
1919 Layout with multi-way if works in the same way as other layout contexts,
1920 except that the semi-colons between guards in a multi-way if are
1921 optional. So it is not necessary to line up all the guards at the same
1922 column; this is consistent with the way guards work in function
1923 definitions and case expressions.
1924
1925 .. _local-fixity-declarations:
1926
1927 Local Fixity Declarations
1928 -------------------------
1929
1930 A careful reading of the Haskell 98 Report reveals that fixity
1931 declarations (``infix``, ``infixl``, and ``infixr``) are permitted to
1932 appear inside local bindings such those introduced by ``let`` and
1933 ``where``. However, the Haskell Report does not specify the semantics of
1934 such bindings very precisely.
1935
1936 In GHC, a fixity declaration may accompany a local binding: ::
1937
1938     let f = ...
1939         infixr 3 `f`
1940     in
1941         ...
1942
1943 and the fixity declaration applies wherever the binding is in scope. For
1944 example, in a ``let``, it applies in the right-hand sides of other
1945 ``let``-bindings and the body of the ``let``\ C. Or, in recursive ``do``
1946 expressions (:ref:`recursive-do-notation`), the local fixity
1947 declarations of a ``let`` statement scope over other statements in the
1948 group, just as the bound name does.
1949
1950 Moreover, a local fixity declaration *must* accompany a local binding
1951 of that name: it is not possible to revise the fixity of name bound
1952 elsewhere, as in ::
1953
1954     let infixr 9 $ in ...
1955
1956 Because local fixity declarations are technically Haskell 98, no extension is
1957 necessary to enable them.
1958
1959 .. _package-imports:
1960
1961 Import and export extensions
1962 ----------------------------
1963
1964 Hiding things the imported module doesn't export
1965 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1966
1967 Technically in Haskell 2010 this is illegal: ::
1968
1969     module A( f ) where
1970       f = True
1971
1972     module B where
1973       import A hiding( g )  -- A does not export g
1974       g = f
1975
1976 The ``import A hiding( g )`` in module ``B`` is technically an error
1977 (`Haskell Report,
1978 5.3.1 <http://www.haskell.org/onlinereport/haskell2010/haskellch5.html#x11-1020005.3.1>`__)
1979 because ``A`` does not export ``g``. However GHC allows it, in the
1980 interests of supporting backward compatibility; for example, a newer
1981 version of ``A`` might export ``g``, and you want ``B`` to work in
1982 either case.
1983
1984 The warning :ghc-flag:`-Wdodgy-imports`, which is off by default but included
1985 with :ghc-flag:`-W`, warns if you hide something that the imported module does
1986 not export.
1987
1988 .. _package-qualified-imports:
1989
1990 Package-qualified imports
1991 ~~~~~~~~~~~~~~~~~~~~~~~~~
1992
1993 .. extension:: PackageImports
1994     :shortdesc: Enable package-qualified imports.
1995
1996     :since: 6.10.1
1997
1998     Allow the use of package-qualified ``import`` syntax.
1999
2000 With the :extension:`PackageImports` extension, GHC allows import declarations to be
2001 qualified by the package name that the module is intended to be imported
2002 from. For example: ::
2003
2004     import "network" Network.Socket
2005
2006 would import the module ``Network.Socket`` from the package ``network``
2007 (any version). This may be used to disambiguate an import when the same
2008 module is available from multiple packages, or is present in both the
2009 current package being built and an external package.
2010
2011 The special package name ``this`` can be used to refer to the current
2012 package being built.
2013
2014 .. note::
2015    You probably don't need to use this feature, it was added mainly so that we
2016    can build backwards-compatible versions of packages when APIs change. It can
2017    lead to fragile dependencies in the common case: modules occasionally move
2018    from one package to another, rendering any package-qualified imports broken.
2019    See also :ref:`package-thinning-and-renaming` for an alternative way of
2020    disambiguating between module names.
2021
2022 .. _safe-imports-ext:
2023
2024 Safe imports
2025 ~~~~~~~~~~~~
2026
2027 .. extension:: Safe
2028     :shortdesc: Enable the :ref:`Safe Haskell <safe-haskell>` Safe mode.
2029     :noindex:
2030
2031     :since: 7.2.1
2032
2033     Declare the Safe Haskell state of the current module.
2034
2035 .. extension:: Trustworthy
2036     :shortdesc: Enable the :ref:`Safe Haskell <safe-haskell>` Trustworthy mode.
2037     :noindex:
2038
2039     :since: 7.2.1
2040
2041     Declare the Safe Haskell state of the current module.
2042
2043 .. extension:: Unsafe
2044     :shortdesc: Enable Safe Haskell Unsafe mode.
2045     :noindex:
2046
2047     :since: 7.4.1
2048
2049     Declare the Safe Haskell state of the current module.
2050
2051 With the :extension:`Safe`, :extension:`Trustworthy` and :extension:`Unsafe`
2052 language flags, GHC extends the import declaration syntax to take an optional
2053 ``safe`` keyword after the ``import`` keyword. This feature is part of the Safe
2054 Haskell GHC extension. For example: ::
2055
2056     import safe qualified Network.Socket as NS
2057
2058 would import the module ``Network.Socket`` with compilation only
2059 succeeding if ``Network.Socket`` can be safely imported. For a description of
2060 when a import is considered safe see :ref:`safe-haskell`.
2061
2062 .. _explicit-namespaces:
2063
2064 Explicit namespaces in import/export
2065 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2066
2067 .. extension:: ExplicitNamespaces
2068     :shortdesc: Enable using the keyword ``type`` to specify the namespace of
2069         entries in imports and exports (:ref:`explicit-namespaces`).
2070         Implied by :extension:`TypeOperators` and :extension:`TypeFamilies`.
2071
2072     :since: 7.6.1
2073
2074     Enable use of explicit namespaces in module export lists.
2075
2076 In an import or export list, such as ::
2077
2078       module M( f, (++) ) where ...
2079         import N( f, (++) )
2080         ...
2081
2082 the entities ``f`` and ``(++)`` are *values*. However, with type
2083 operators (:ref:`type-operators`) it becomes possible to declare
2084 ``(++)`` as a *type constructor*. In that case, how would you export or
2085 import it?
2086
2087 The :extension:`ExplicitNamespaces` extension allows you to prefix the name of
2088 a type constructor in an import or export list with "``type``" to
2089 disambiguate this case, thus: ::
2090
2091       module M( f, type (++) ) where ...
2092         import N( f, type (++) )
2093         ...
2094       module N( f, type (++) ) where
2095         data family a ++ b = L a | R b
2096
2097 The extension :extension:`ExplicitNamespaces` is implied by
2098 :extension:`TypeOperators` and (for some reason) by :extension:`TypeFamilies`.
2099
2100 In addition, with :extension:`PatternSynonyms` you can prefix the name of a
2101 data constructor in an import or export list with the keyword
2102 ``pattern``, to allow the import or export of a data constructor without
2103 its parent type constructor (see :ref:`patsyn-impexp`).
2104
2105 .. _block-arguments:
2106
2107 More liberal syntax for function arguments
2108 ------------------------------------------
2109
2110 .. extension:: BlockArguments
2111     :shortdesc: Allow ``do`` blocks and other constructs as function arguments.
2112
2113     :since: 8.6.1
2114
2115     Allow ``do`` expressions, lambda expressions, etc. to be directly used as
2116     a function argument.
2117
2118 In Haskell 2010, certain kinds of expressions can be used without parentheses
2119 as an argument to an operator, but not as an argument to a function.
2120 They include ``do``, lambda, ``if``, ``case``, and ``let``
2121 expressions. Some GHC extensions also define language constructs of this type:
2122 ``mdo`` (:ref:`recursive-do-notation`), ``\case`` (:ref:`lambda-case`), and
2123 ``proc`` (:ref:`arrow-notation`).
2124
2125 The :extension:`BlockArguments` extension allows these constructs to be directly
2126 used as a function argument. For example::
2127
2128     when (x > 0) do
2129       print x
2130       exitFailure
2131
2132 will be parsed as::
2133
2134     when (x > 0) (do
2135       print x
2136       exitFailure)
2137
2138 and
2139
2140 ::
2141
2142     withForeignPtr fptr \ptr -> c_memcpy buf ptr size
2143
2144 will be parsed as::
2145
2146     withForeignPtr fptr (\ptr -> c_memcpy buf ptr size)
2147
2148 Changes to the grammar
2149 ~~~~~~~~~~~~~~~~~~~~~~
2150
2151 The Haskell report `defines
2152 <https://www.haskell.org/onlinereport/haskell2010/haskellch3.html#x8-220003>`_
2153 the ``lexp`` nonterminal thus (``*`` indicates a rule of interest)::
2154
2155     lexp  →  \ apat1 … apatn -> exp            (lambda abstraction, n ≥ 1)  *
2156           |  let decls in exp                  (let expression)             *
2157           |  if exp [;] then exp [;] else exp  (conditional)                *
2158           |  case exp of { alts }              (case expression)            *
2159           |  do { stmts }                      (do expression)              *
2160           |  fexp
2161
2162     fexp  →  [fexp] aexp                       (function application)
2163
2164     aexp  →  qvar                              (variable)
2165           |  gcon                              (general constructor)
2166           |  literal
2167           |  ( exp )                           (parenthesized expression)
2168           |  qcon { fbind1 … fbindn }          (labeled construction)
2169           |  aexp { fbind1 … fbindn }          (labelled update)
2170           |  …
2171
2172 The :extension:`BlockArguments` extension moves these production rules under
2173 ``aexp``::
2174
2175     lexp  →  fexp
2176
2177     fexp  →  [fexp] aexp                       (function application)
2178
2179     aexp  →  qvar                              (variable)
2180           |  gcon                              (general constructor)
2181           |  literal
2182           |  ( exp )                           (parenthesized expression)
2183           |  qcon { fbind1 … fbindn }          (labeled construction)
2184           |  aexp { fbind1 … fbindn }          (labelled update)
2185           |  \ apat1 … apatn -> exp            (lambda abstraction, n ≥ 1)  *
2186           |  let decls in exp                  (let expression)             *
2187           |  if exp [;] then exp [;] else exp  (conditional)                *
2188           |  case exp of { alts }              (case expression)            *
2189           |  do { stmts }                      (do expression)              *
2190           |  …
2191
2192 Now the ``lexp`` nonterminal is redundant and can be dropped from the grammar.
2193
2194 Note that this change relies on an existing meta-rule to resolve ambiguities:
2195
2196     The grammar is ambiguous regarding the extent of lambda abstractions, let
2197     expressions, and conditionals. The ambiguity is resolved by the meta-rule
2198     that each of these constructs extends as far to the right as possible.
2199
2200 For example, ``f \a -> a b`` will be parsed as ``f (\a -> a b)``, not as ``f
2201 (\a -> a) b``.
2202
2203 .. _syntax-stolen:
2204
2205 Summary of stolen syntax
2206 ------------------------
2207
2208 Turning on an option that enables special syntax *might* cause working
2209 Haskell 98 code to fail to compile, perhaps because it uses a variable
2210 name which has become a reserved word. This section lists the syntax
2211 that is "stolen" by language extensions. We use notation and nonterminal
2212 names from the Haskell 98 lexical syntax (see the Haskell 98 Report). We
2213 only list syntax changes here that might affect existing working
2214 programs (i.e. "stolen" syntax). Many of these extensions will also
2215 enable new context-free syntax, but in all cases programs written to use
2216 the new syntax would not be compilable without the option enabled.
2217
2218 There are two classes of special syntax:
2219
2220 -  New reserved words and symbols: character sequences which are no
2221    longer available for use as identifiers in the program.
2222
2223 -  Other special syntax: sequences of characters that have a different
2224    meaning when this particular option is turned on.
2225
2226 The following syntax is stolen:
2227
2228 ``forall``
2229     .. index::
2230        single: forall
2231
2232     Stolen (in types) by: :extension:`ExplicitForAll`, and hence by
2233     :extension:`ScopedTypeVariables`, :extension:`LiberalTypeSynonyms`,
2234     :extension:`RankNTypes`, :extension:`ExistentialQuantification`
2235
2236 ``mdo``
2237     .. index::
2238        single: mdo
2239
2240     Stolen by: :extension:`RecursiveDo`
2241
2242 ``foreign``
2243     .. index::
2244        single: foreign
2245
2246     Stolen by: :extension:`ForeignFunctionInterface`
2247
2248 ``rec``, ``proc``, ``-<``, ``>-``, ``-<<``, ``>>-``, ``(|``, ``|)``
2249     .. index::
2250        single: proc
2251
2252     Stolen by: :extension:`Arrows`
2253
2254 ``?varid``
2255     .. index::
2256        single: implicit parameters
2257
2258     Stolen by: :extension:`ImplicitParams`
2259
2260 ``[|``, ``[e|``, ``[p|``, ``[d|``, ``[t|``, ``[||``, ``[e||``
2261     .. index::
2262        single: Quasi-quotes
2263
2264     Stolen by: :extension:`QuasiQuotes`. Moreover, this introduces an ambiguity
2265     with list comprehension syntax. See the
2266     :ref:`discussion on quasi-quoting <quasi-quotes-list-comprehension-ambiguity>`
2267     for details.
2268
2269 ``$(``, ``$$(``, ``$varid``, ``$$varid``
2270     .. index::
2271        single: Template Haskell
2272
2273     Stolen by: :extension:`TemplateHaskell`
2274
2275 ``[varid|``
2276     .. index::
2277        single: quasi-quotation
2278
2279     Stolen by: :extension:`QuasiQuotes`
2280
2281 ⟨varid⟩, ``#``\ ⟨char⟩, ``#``, ⟨string⟩, ``#``, ⟨integer⟩, ``#``, ⟨float⟩, ``#``, ⟨float⟩, ``##``
2282     Stolen by: :extension:`MagicHash`
2283
2284 ``(#``, ``#)``
2285     Stolen by: :extension:`UnboxedTuples`
2286
2287 ⟨varid⟩, ``!``, ⟨varid⟩
2288     Stolen by: :extension:`BangPatterns`
2289
2290 ``pattern``
2291     Stolen by: :extension:`PatternSynonyms`
2292
2293 .. _data-type-extensions:
2294
2295 Extensions to data types and type synonyms
2296 ==========================================
2297
2298 .. _nullary-types:
2299
2300 Data types with no constructors
2301 -------------------------------
2302
2303 .. extension:: EmptyDataDecls
2304     :shortdesc: Allow definition of empty ``data`` types.
2305
2306     :since: 6.8.1
2307
2308     Allow definition of empty ``data`` types.
2309
2310 With the :extension:`EmptyDataDecls` extension, GHC
2311 lets you declare a data type with no constructors. For example: ::
2312
2313       data S      -- S :: Type
2314       data T a    -- T :: Type -> Type
2315
2316 Syntactically, the declaration lacks the "= constrs" part. The type can be
2317 parameterised over types of any kind, but if the kind is not ``Type`` then an
2318 explicit kind annotation must be used (see :ref:`kinding`).
2319
2320 Such data types have only one value, namely bottom. Nevertheless, they
2321 can be useful when defining "phantom types".
2322
2323 In conjunction with the :ghc-flag:`-XEmptyDataDeriving` extension, empty data
2324 declarations can also derive instances of standard type classes
2325 (see :ref:`empty-data-deriving`).
2326
2327 .. _datatype-contexts:
2328
2329 Data type contexts
2330 ------------------
2331
2332 .. extension:: DatatypeContexts
2333     :shortdesc: Allow contexts on ``data`` types.
2334
2335     :since: 7.0.1
2336
2337     Allow contexts on ``data`` types.
2338
2339 Haskell allows datatypes to be given contexts, e.g. ::
2340
2341     data Eq a => Set a = NilSet | ConsSet a (Set a)
2342
2343 give constructors with types: ::
2344
2345     NilSet :: Set a
2346     ConsSet :: Eq a => a -> Set a -> Set a
2347
2348 This is widely considered a misfeature, and is going to be removed from
2349 the language. In GHC, it is controlled by the deprecated extension
2350 ``DatatypeContexts``.
2351
2352 .. _infix-tycons:
2353
2354 Infix type constructors, classes, and type variables
2355 ----------------------------------------------------
2356
2357 GHC allows type constructors, classes, and type variables to be
2358 operators, and to be written infix, very much like expressions. More
2359 specifically:
2360
2361 -  A type constructor or class can be any non-reserved operator.
2362    Symbols used in types are always like capitalized identifiers; they
2363    are never variables. Note that this is different from the lexical
2364    syntax of data constructors, which are required to begin with a
2365    ``:``.
2366
2367 -  Data type and type-synonym declarations can be written infix,
2368    parenthesised if you want further arguments. E.g. ::
2369
2370          data a :*: b = Foo a b
2371          type a :+: b = Either a b
2372          class a :=: b where ...
2373
2374          data (a :**: b) x = Baz a b x
2375          type (a :++: b) y = Either (a,b) y
2376
2377 -  Types, and class constraints, can be written infix. For example ::
2378
2379          x :: Int :*: Bool
2380          f :: (a :=: b) => a -> b
2381
2382 -  Back-quotes work as for expressions, both for type constructors and
2383    type variables; e.g. ``Int `Either` Bool``, or ``Int `a` Bool``.
2384    Similarly, parentheses work the same; e.g. ``(:*:) Int Bool``.
2385
2386 -  Fixities may be declared for type constructors, or classes, just as
2387    for data constructors. However, one cannot distinguish between the
2388    two in a fixity declaration; a fixity declaration sets the fixity for
2389    a data constructor and the corresponding type constructor. For
2390    example: ::
2391
2392          infixl 7 T, :*:
2393
2394    sets the fixity for both type constructor ``T`` and data constructor
2395    ``T``, and similarly for ``:*:``. ``Int `a` Bool``.
2396
2397 -  Function arrow is ``infixr`` with fixity 0 (this might change; it's
2398    not clear what it should be).
2399
2400 .. _type-operators:
2401
2402 Type operators
2403 --------------
2404
2405 .. extension:: TypeOperators
2406     :shortdesc: Enable type operators.
2407         Implies :extension:`ExplicitNamespaces`.
2408
2409     :implies: :extension:`ExplicitNamespaces`
2410     :since: 6.8.1
2411
2412     Allow the use and definition of types with operator names.
2413
2414 In types, an operator symbol like ``(+)`` is normally treated as a type
2415 *variable*, just like ``a``. Thus in Haskell 98 you can say
2416
2417 ::
2418
2419     type T (+) = ((+), (+))
2420     -- Just like: type T a = (a,a)
2421
2422     f :: T Int -> Int
2423     f (x,y)= x
2424
2425 As you can see, using operators in this way is not very useful, and
2426 Haskell 98 does not even allow you to write them infix.
2427
2428 The language :extension:`TypeOperators` changes this behaviour:
2429
2430 -  Operator symbols become type *constructors* rather than type
2431    *variables*.
2432
2433 -  Operator symbols in types can be written infix, both in definitions
2434    and uses. For example: ::
2435
2436        data a + b = Plus a b
2437        type Foo = Int + Bool
2438
2439 -  There is now some potential ambiguity in import and export lists; for
2440    example if you write ``import M( (+) )`` do you mean the *function*
2441    ``(+)`` or the *type constructor* ``(+)``? The default is the former,
2442    but with :extension:`ExplicitNamespaces` (which is implied by
2443    :extension:`TypeOperators`) GHC allows you to specify the latter by
2444    preceding it with the keyword ``type``, thus: ::
2445
2446        import M( type (+) )
2447
2448    See :ref:`explicit-namespaces`.
2449
2450 -  The fixity of a type operator may be set using the usual fixity
2451    declarations but, as in :ref:`infix-tycons`, the function and type
2452    constructor share a single fixity.
2453
2454 .. _type-synonyms:
2455
2456 Liberalised type synonyms
2457 -------------------------
2458
2459 .. extension:: LiberalTypeSynonyms
2460     :shortdesc: Enable liberalised type synonyms.
2461
2462     :implies: :extension:`ExplicitForAll`
2463     :since: 6.8.1
2464
2465     Relax many of the Haskell 98 rules on type synonym definitions.
2466
2467 Type synonyms are like macros at the type level, but Haskell 98 imposes
2468 many rules on individual synonym declarations. With the
2469 :extension:`LiberalTypeSynonyms` extension, GHC does validity checking on types
2470 *only after expanding type synonyms*. That means that GHC can be very
2471 much more liberal about type synonyms than Haskell 98.
2472
2473 -  You can write a ``forall`` (including overloading) in a type synonym,
2474    thus: ::
2475
2476          type Discard a = forall b. Show b => a -> b -> (a, String)
2477
2478          f :: Discard a
2479          f x y = (x, show y)
2480
2481          g :: Discard Int -> (Int,String)    -- A rank-2 type
2482          g f = f 3 True
2483
2484 -  If you also use :extension:`UnboxedTuples`, you can write an unboxed tuple
2485    in a type synonym: ::
2486
2487          type Pr = (# Int, Int #)
2488
2489          h :: Int -> Pr
2490          h x = (# x, x #)
2491
2492 -  You can apply a type synonym to a forall type: ::
2493
2494          type Foo a = a -> a -> Bool
2495
2496          f :: Foo (forall b. b->b)
2497
2498    After expanding the synonym, ``f`` has the legal (in GHC) type: ::
2499
2500          f :: (forall b. b->b) -> (forall b. b->b) -> Bool
2501
2502 -  You can apply a type synonym to a partially applied type synonym: ::
2503
2504          type Generic i o = forall x. i x -> o x
2505          type Id x = x
2506
2507          foo :: Generic Id []
2508
2509    After expanding the synonym, ``foo`` has the legal (in GHC) type: ::
2510
2511          foo :: forall x. x -> [x]
2512
2513 GHC currently does kind checking before expanding synonyms (though even
2514 that could be changed).
2515
2516 After expanding type synonyms, GHC does validity checking on types,
2517 looking for the following malformedness which isn't detected simply by
2518 kind checking:
2519
2520 -  Type constructor applied to a type involving for-alls (if
2521    :extension:`ImpredicativeTypes` is off)
2522
2523 -  Partially-applied type synonym.
2524
2525 So, for example, this will be rejected: ::
2526
2527       type Pr = forall a. a
2528
2529       h :: [Pr]
2530       h = ...
2531
2532 because GHC does not allow type constructors applied to for-all types.
2533
2534 .. _existential-quantification:
2535
2536 Existentially quantified data constructors
2537 ------------------------------------------
2538
2539 .. extension:: ExistentialQuantification
2540     :shortdesc: Enable liberalised type synonyms.
2541
2542     :implies: :extension:`ExplicitForAll`
2543     :since: 6.8.1
2544
2545     Allow existentially quantified type variables in types.
2546
2547 The idea of using existential quantification in data type declarations
2548 was suggested by Perry, and implemented in Hope+ (Nigel Perry, *The
2549 Implementation of Practical Functional Programming Languages*, PhD
2550 Thesis, University of London, 1991). It was later formalised by Laufer
2551 and Odersky (*Polymorphic type inference and abstract data types*,
2552 TOPLAS, 16(5), pp. 1411-1430, 1994). It's been in Lennart Augustsson's
2553 ``hbc`` Haskell compiler for several years, and proved very useful.
2554 Here's the idea. Consider the declaration: ::
2555
2556       data Foo = forall a. MkFoo a (a -> Bool)
2557                | Nil
2558
2559 The data type ``Foo`` has two constructors with types: ::
2560
2561       MkFoo :: forall a. a -> (a -> Bool) -> Foo
2562       Nil   :: Foo
2563
2564 Notice that the type variable ``a`` in the type of ``MkFoo`` does not
2565 appear in the data type itself, which is plain ``Foo``. For example, the
2566 following expression is fine: ::
2567
2568       [MkFoo 3 even, MkFoo 'c' isUpper] :: [Foo]
2569
2570 Here, ``(MkFoo 3 even)`` packages an integer with a function ``even``
2571 that maps an integer to ``Bool``; and ``MkFoo 'c'
2572 isUpper`` packages a character with a compatible function. These two
2573 things are each of type ``Foo`` and can be put in a list.
2574
2575 What can we do with a value of type ``Foo``? In particular, what
2576 happens when we pattern-match on ``MkFoo``? ::
2577
2578       f (MkFoo val fn) = ???
2579
2580 Since all we know about ``val`` and ``fn`` is that they are compatible,
2581 the only (useful) thing we can do with them is to apply ``fn`` to
2582 ``val`` to get a boolean. For example: ::
2583
2584       f :: Foo -> Bool
2585       f (MkFoo val fn) = fn val
2586
2587 What this allows us to do is to package heterogeneous values together
2588 with a bunch of functions that manipulate them, and then treat that
2589 collection of packages in a uniform manner. You can express quite a bit
2590 of object-oriented-like programming this way.
2591
2592 .. _existential:
2593
2594 Why existential?
2595 ~~~~~~~~~~~~~~~~
2596
2597 What has this to do with *existential* quantification? Simply that
2598 ``MkFoo`` has the (nearly) isomorphic type ::
2599
2600       MkFoo :: (exists a . (a, a -> Bool)) -> Foo
2601
2602 But Haskell programmers can safely think of the ordinary *universally*
2603 quantified type given above, thereby avoiding adding a new existential
2604 quantification construct.
2605
2606 .. _existential-with-context:
2607
2608 Existentials and type classes
2609 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2610
2611 An easy extension is to allow arbitrary contexts before the constructor.
2612 For example: ::
2613
2614     data Baz = forall a. Eq a => Baz1 a a
2615              | forall b. Show b => Baz2 b (b -> b)
2616
2617 The two constructors have the types you'd expect: ::
2618
2619     Baz1 :: forall a. Eq a => a -> a -> Baz
2620     Baz2 :: forall b. Show b => b -> (b -> b) -> Baz
2621
2622 But when pattern matching on ``Baz1`` the matched values can be compared
2623 for equality, and when pattern matching on ``Baz2`` the first matched
2624 value can be converted to a string (as well as applying the function to
2625 it). So this program is legal: ::
2626
2627       f :: Baz -> String
2628       f (Baz1 p q) | p == q    = "Yes"
2629                    | otherwise = "No"
2630       f (Baz2 v fn)            = show (fn v)
2631
2632 Operationally, in a dictionary-passing implementation, the constructors
2633 ``Baz1`` and ``Baz2`` must store the dictionaries for ``Eq`` and
2634 ``Show`` respectively, and extract it on pattern matching.
2635
2636 .. _existential-records:
2637
2638 Record Constructors
2639 ~~~~~~~~~~~~~~~~~~~
2640
2641 GHC allows existentials to be used with records syntax as well. For
2642 example: ::
2643
2644     data Counter a = forall self. NewCounter
2645         { _this    :: self
2646         , _inc     :: self -> self
2647         , _display :: self -> IO ()
2648         , tag      :: a
2649         }
2650
2651 Here ``tag`` is a public field, with a well-typed selector function
2652 ``tag :: Counter a -> a``. The ``self`` type is hidden from the outside;
2653 any attempt to apply ``_this``, ``_inc`` or ``_display`` as functions
2654 will raise a compile-time error. In other words, *GHC defines a record
2655 selector function only for fields whose type does not mention the
2656 existentially-quantified variables*. (This example used an underscore in
2657 the fields for which record selectors will not be defined, but that is
2658 only programming style; GHC ignores them.)
2659
2660 To make use of these hidden fields, we need to create some helper
2661 functions: ::
2662
2663     inc :: Counter a -> Counter a
2664     inc (NewCounter x i d t) = NewCounter
2665         { _this = i x, _inc = i, _display = d, tag = t }
2666
2667     display :: Counter a -> IO ()
2668     display NewCounter{ _this = x, _display = d } = d x
2669
2670 Now we can define counters with different underlying implementations: ::
2671
2672     counterA :: Counter String
2673     counterA = NewCounter
2674         { _this = 0, _inc = (1+), _display = print, tag = "A" }
2675
2676     counterB :: Counter String
2677     counterB = NewCounter
2678         { _this = "", _inc = ('#':), _display = putStrLn, tag = "B" }
2679
2680     main = do
2681         display (inc counterA)         -- prints "1"
2682         display (inc (inc counterB))   -- prints "##"
2683
2684 Record update syntax is supported for existentials (and GADTs): ::
2685
2686     setTag :: Counter a -> a -> Counter a
2687     setTag obj t = obj{ tag = t }
2688
2689 The rule for record update is this:
2690
2691     the types of the updated fields may mention only the universally-quantified
2692     type variables of the data constructor. For GADTs, the field may mention
2693     only types that appear as a simple type-variable argument in the
2694     constructor's result type.
2695
2696 For example: ::
2697
2698     data T a b where { T1 { f1::a, f2::b, f3::(b,c) } :: T a b } -- c is existential
2699     upd1 t x = t { f1=x }   -- OK:   upd1 :: T a b -> a' -> T a' b
2700     upd2 t x = t { f3=x }   -- BAD   (f3's type mentions c, which is
2701                             --        existentially quantified)
2702
2703     data G a b where { G1 { g1::a, g2::c } :: G a [c] }
2704     upd3 g x = g { g1=x }   -- OK:   upd3 :: G a b -> c -> G c b
2705     upd4 g x = g { g2=x }   -- BAD (f2's type mentions c, which is not a simple
2706                             --      type-variable argument in G1's result type)
2707
2708 Restrictions
2709 ~~~~~~~~~~~~
2710
2711 There are several restrictions on the ways in which existentially-quantified
2712 constructors can be used.
2713
2714 -  When pattern matching, each pattern match introduces a new, distinct,
2715    type for each existential type variable. These types cannot be
2716    unified with any other type, nor can they escape from the scope of
2717    the pattern match. For example, these fragments are incorrect: ::
2718
2719        f1 (MkFoo a f) = a
2720
2721    Here, the type bound by ``MkFoo`` "escapes", because ``a`` is the
2722    result of ``f1``. One way to see why this is wrong is to ask what
2723    type ``f1`` has: ::
2724
2725          f1 :: Foo -> a             -- Weird!
2726
2727    What is this "``a``" in the result type? Clearly we don't mean this: ::
2728
2729          f1 :: forall a. Foo -> a   -- Wrong!
2730
2731    The original program is just plain wrong. Here's another sort of
2732    error ::
2733
2734          f2 (Baz1 a b) (Baz1 p q) = a==q
2735
2736    It's ok to say ``a==b`` or ``p==q``, but ``a==q`` is wrong because it
2737    equates the two distinct types arising from the two ``Baz1``
2738    constructors.
2739
2740 -  You can't pattern-match on an existentially quantified constructor in
2741    a ``let`` or ``where`` group of bindings. So this is illegal: ::
2742
2743          f3 x = a==b where { Baz1 a b = x }
2744
2745    Instead, use a ``case`` expression: ::
2746
2747          f3 x = case x of Baz1 a b -> a==b
2748
2749    In general, you can only pattern-match on an existentially-quantified
2750    constructor in a ``case`` expression or in the patterns of a function
2751    definition. The reason for this restriction is really an
2752    implementation one. Type-checking binding groups is already a
2753    nightmare without existentials complicating the picture. Also an
2754    existential pattern binding at the top level of a module doesn't make
2755    sense, because it's not clear how to prevent the
2756    existentially-quantified type "escaping". So for now, there's a
2757    simple-to-state restriction. We'll see how annoying it is.
2758
2759 -  You can't use existential quantification for ``newtype``
2760    declarations. So this is illegal: ::
2761
2762          newtype T = forall a. Ord a => MkT a
2763
2764    Reason: a value of type ``T`` must be represented as a pair of a
2765    dictionary for ``Ord t`` and a value of type ``t``. That contradicts
2766    the idea that ``newtype`` should have no concrete representation. You
2767    can get just the same efficiency and effect by using ``data`` instead
2768    of ``newtype``. If there is no overloading involved, then there is
2769    more of a case for allowing an existentially-quantified ``newtype``,
2770    because the ``data`` version does carry an implementation cost, but
2771    single-field existentially quantified constructors aren't much use.
2772    So the simple restriction (no existential stuff on ``newtype``)
2773    stands, unless there are convincing reasons to change it.
2774
2775 -  You can't use ``deriving`` to define instances of a data type with
2776    existentially quantified data constructors. Reason: in most cases it
2777    would not make sense. For example:; ::
2778
2779        data T = forall a. MkT [a] deriving( Eq )
2780
2781    To derive ``Eq`` in the standard way we would need to have equality
2782    between the single component of two ``MkT`` constructors: ::
2783
2784        instance Eq T where
2785          (MkT a) == (MkT b) = ???
2786
2787    But ``a`` and ``b`` have distinct types, and so can't be compared.
2788    It's just about possible to imagine examples in which the derived
2789    instance would make sense, but it seems altogether simpler simply to
2790    prohibit such declarations. Define your own instances!
2791
2792 .. _gadt-style:
2793
2794 Declaring data types with explicit constructor signatures
2795 ---------------------------------------------------------
2796
2797 .. extension:: GADTSyntax
2798     :shortdesc: Enable generalised algebraic data type syntax.
2799
2800     :since: 7.2.1
2801
2802     Allow the use of GADT syntax in data type definitions (but not GADTs
2803     themselves; for this see :extension:`GADTs`)
2804
2805 When the ``GADTSyntax`` extension is enabled, GHC allows you to declare
2806 an algebraic data type by giving the type signatures of constructors
2807 explicitly. For example: ::
2808
2809       data Maybe a where
2810           Nothing :: Maybe a
2811           Just    :: a -> Maybe a
2812
2813 The form is called a "GADT-style declaration" because Generalised
2814 Algebraic Data Types, described in :ref:`gadt`, can only be declared
2815 using this form.
2816
2817 Notice that GADT-style syntax generalises existential types
2818 (:ref:`existential-quantification`). For example, these two declarations
2819 are equivalent: ::
2820
2821       data Foo = forall a. MkFoo a (a -> Bool)
2822       data Foo' where { MKFoo :: a -> (a->Bool) -> Foo' }
2823
2824 Any data type that can be declared in standard Haskell 98 syntax can
2825 also be declared using GADT-style syntax. The choice is largely
2826 stylistic, but GADT-style declarations differ in one important respect:
2827 they treat class constraints on the data constructors differently.
2828 Specifically, if the constructor is given a type-class context, that
2829 context is made available by pattern matching. For example: ::
2830
2831       data Set a where
2832         MkSet :: Eq a => [a] -> Set a
2833
2834       makeSet :: Eq a => [a] -> Set a
2835       makeSet xs = MkSet (nub xs)
2836
2837       insert :: a -> Set a -> Set a
2838       insert a (MkSet as) | a `elem` as = MkSet as
2839                           | otherwise   = MkSet (a:as)
2840
2841 A use of ``MkSet`` as a constructor (e.g. in the definition of
2842 ``makeSet``) gives rise to a ``(Eq a)`` constraint, as you would expect.
2843 The new feature is that pattern-matching on ``MkSet`` (as in the
2844 definition of ``insert``) makes *available* an ``(Eq a)`` context. In
2845 implementation terms, the ``MkSet`` constructor has a hidden field that
2846 stores the ``(Eq a)`` dictionary that is passed to ``MkSet``; so when
2847 pattern-matching that dictionary becomes available for the right-hand
2848 side of the match. In the example, the equality dictionary is used to
2849 satisfy the equality constraint generated by the call to ``elem``, so
2850 that the type of ``insert`` itself has no ``Eq`` constraint.
2851
2852 For example, one possible application is to reify dictionaries: ::
2853
2854        data NumInst a where
2855          MkNumInst :: Num a => NumInst a
2856
2857        intInst :: NumInst Int
2858        intInst = MkNumInst
2859
2860        plus :: NumInst a -> a -> a -> a
2861        plus MkNumInst p q = p + q
2862
2863 Here, a value of type ``NumInst a`` is equivalent to an explicit
2864 ``(Num a)`` dictionary.
2865
2866 All this applies to constructors declared using the syntax of
2867 :ref:`existential-with-context`. For example, the ``NumInst`` data type
2868 above could equivalently be declared like this: ::
2869
2870        data NumInst a
2871           = Num a => MkNumInst (NumInst a)
2872
2873 Notice that, unlike the situation when declaring an existential, there
2874 is no ``forall``, because the ``Num`` constrains the data type's
2875 universally quantified type variable ``a``. A constructor may have both
2876 universal and existential type variables: for example, the following two
2877 declarations are equivalent: ::
2878
2879        data T1 a
2880         = forall b. (Num a, Eq b) => MkT1 a b
2881        data T2 a where
2882         MkT2 :: (Num a, Eq b) => a -> b -> T2 a
2883
2884 All this behaviour contrasts with Haskell 98's peculiar treatment of
2885 contexts on a data type declaration (Section 4.2.1 of the Haskell 98
2886 Report). In Haskell 98 the definition ::
2887
2888       data Eq a => Set' a = MkSet' [a]
2889
2890 gives ``MkSet'`` the same type as ``MkSet`` above. But instead of
2891 *making available* an ``(Eq a)`` constraint, pattern-matching on
2892 ``MkSet'`` *requires* an ``(Eq a)`` constraint! GHC faithfully
2893 implements this behaviour, odd though it is. But for GADT-style
2894 declarations, GHC's behaviour is much more useful, as well as much more
2895 intuitive.
2896
2897 The rest of this section gives further details about GADT-style data
2898 type declarations.
2899
2900 -  The result type of each data constructor must begin with the type
2901    constructor being defined. If the result type of all constructors has
2902    the form ``T a1 ... an``, where ``a1 ... an`` are distinct type
2903    variables, then the data type is *ordinary*; otherwise is a
2904    *generalised* data type (:ref:`gadt`).
2905
2906 -  As with other type signatures, you can give a single signature for
2907    several data constructors. In this example we give a single signature
2908    for ``T1`` and ``T2``: ::
2909
2910          data T a where
2911            T1,T2 :: a -> T a
2912            T3 :: T a
2913
2914 -  The type signature of each constructor is independent, and is
2915    implicitly universally quantified as usual. In particular, the type
2916    variable(s) in the "``data T a where``" header have no scope, and
2917    different constructors may have different universally-quantified type
2918    variables: ::
2919
2920          data T a where        -- The 'a' has no scope
2921            T1,T2 :: b -> T b   -- Means forall b. b -> T b
2922            T3 :: T a           -- Means forall a. T a
2923
2924 -  A constructor signature may mention type class constraints, which can
2925    differ for different constructors. For example, this is fine: ::
2926
2927          data T a where
2928            T1 :: Eq b => b -> b -> T b
2929            T2 :: (Show c, Ix c) => c -> [c] -> T c
2930
2931    When pattern matching, these constraints are made available to
2932    discharge constraints in the body of the match. For example: ::
2933
2934          f :: T a -> String
2935          f (T1 x y) | x==y      = "yes"
2936                     | otherwise = "no"
2937          f (T2 a b)             = show a
2938
2939    Note that ``f`` is not overloaded; the ``Eq`` constraint arising from
2940    the use of ``==`` is discharged by the pattern match on ``T1`` and
2941    similarly the ``Show`` constraint arising from the use of ``show``.
2942
2943 -  Unlike a Haskell-98-style data type declaration, the type variable(s)
2944    in the "``data Set a where``" header have no scope. Indeed, one can
2945    write a kind signature instead: ::
2946
2947          data Set :: Type -> Type where ...
2948
2949    or even a mixture of the two: ::
2950
2951          data Bar a :: (Type -> Type) -> Type where ...
2952
2953    The type variables (if given) may be explicitly kinded, so we could
2954    also write the header for ``Foo`` like this: ::
2955
2956          data Bar a (b :: Type -> Type) where ...
2957
2958 -  You can use strictness annotations, in the obvious places in the
2959    constructor type: ::
2960
2961          data Term a where
2962              Lit    :: !Int -> Term Int
2963              If     :: Term Bool -> !(Term a) -> !(Term a) -> Term a
2964              Pair   :: Term a -> Term b -> Term (a,b)
2965
2966 -  You can use a ``deriving`` clause on a GADT-style data type
2967    declaration. For example, these two declarations are equivalent ::
2968
2969          data Maybe1 a where {
2970              Nothing1 :: Maybe1 a ;
2971              Just1    :: a -> Maybe1 a
2972            } deriving( Eq, Ord )
2973
2974          data Maybe2 a = Nothing2 | Just2 a
2975               deriving( Eq, Ord )
2976
2977 -  The type signature may have quantified type variables that do not
2978    appear in the result type: ::
2979
2980          data Foo where
2981             MkFoo :: a -> (a->Bool) -> Foo
2982             Nil   :: Foo
2983
2984    Here the type variable ``a`` does not appear in the result type of
2985    either constructor. Although it is universally quantified in the type
2986    of the constructor, such a type variable is often called
2987    "existential". Indeed, the above declaration declares precisely the
2988    same type as the ``data Foo`` in :ref:`existential-quantification`.
2989
2990    The type may contain a class context too, of course: ::
2991
2992          data Showable where
2993            MkShowable :: Show a => a -> Showable
2994
2995 -  You can use record syntax on a GADT-style data type declaration: ::
2996
2997          data Person where
2998              Adult :: { name :: String, children :: [Person] } -> Person
2999              Child :: Show a => { name :: !String, funny :: a } -> Person
3000
3001    As usual, for every constructor that has a field ``f``, the type of
3002    field ``f`` must be the same (modulo alpha conversion). The ``Child``
3003    constructor above shows that the signature may have a context,
3004    existentially-quantified variables, and strictness annotations, just
3005    as in the non-record case. (NB: the "type" that follows the
3006    double-colon is not really a type, because of the record syntax and
3007    strictness annotations. A "type" of this form can appear only in a
3008    constructor signature.)
3009
3010 -  Record updates are allowed with GADT-style declarations, only fields
3011    that have the following property: the type of the field mentions no
3012    existential type variables.
3013
3014 -  As in the case of existentials declared using the Haskell-98-like
3015    record syntax (:ref:`existential-records`), record-selector functions
3016    are generated only for those fields that have well-typed selectors.
3017    Here is the example of that section, in GADT-style syntax: ::
3018
3019        data Counter a where
3020            NewCounter :: { _this    :: self
3021                          , _inc     :: self -> self
3022                          , _display :: self -> IO ()
3023                          , tag      :: a
3024                          } -> Counter a
3025
3026    As before, only one selector function is generated here, that for
3027    ``tag``. Nevertheless, you can still use all the field names in
3028    pattern matching and record construction.
3029
3030 -  In a GADT-style data type declaration there is no obvious way to
3031    specify that a data constructor should be infix, which makes a
3032    difference if you derive ``Show`` for the type. (Data constructors
3033    declared infix are displayed infix by the derived ``show``.) So GHC
3034    implements the following design: a data constructor declared in a
3035    GADT-style data type declaration is displayed infix by ``Show`` iff
3036    (a) it is an operator symbol, (b) it has two arguments, (c) it has a
3037    programmer-supplied fixity declaration. For example
3038
3039    ::
3040
3041           infix 6 (:--:)
3042           data T a where
3043             (:--:) :: Int -> Bool -> T Int
3044
3045 .. _gadt:
3046
3047 Generalised Algebraic Data Types (GADTs)
3048 ----------------------------------------
3049
3050 .. extension:: GADTs
3051     :shortdesc: Enable generalised algebraic data types.
3052         Implies :extension:`GADTSyntax` and :extension:`MonoLocalBinds`.
3053
3054     :implies: :extension:`MonoLocalBinds`, :extension:`GADTSyntax`
3055     :since: 6.8.1
3056
3057     Allow use of Generalised Algebraic Data Types (GADTs).
3058
3059 Generalised Algebraic Data Types generalise ordinary algebraic data
3060 types by allowing constructors to have richer return types. Here is an
3061 example: ::
3062
3063       data Term a where
3064           Lit    :: Int -> Term Int
3065           Succ   :: Term Int -> Term Int
3066           IsZero :: Term Int -> Term Bool
3067           If     :: Term Bool -> Term a -> Term a -> Term a
3068           Pair   :: Term a -> Term b -> Term (a,b)
3069
3070 Notice that the return type of the constructors is not always
3071 ``Term a``, as is the case with ordinary data types. This generality
3072 allows us to write a well-typed ``eval`` function for these ``Terms``: ::
3073
3074       eval :: Term a -> a
3075       eval (Lit i)      = i
3076       eval (Succ t)     = 1 + eval t
3077       eval (IsZero t)   = eval t == 0
3078       eval (If b e1 e2) = if eval b then eval e1 else eval e2
3079       eval (Pair e1 e2) = (eval e1, eval e2)
3080
3081 The key point about GADTs is that *pattern matching causes type
3082 refinement*. For example, in the right hand side of the equation ::
3083
3084       eval :: Term a -> a
3085       eval (Lit i) =  ...
3086
3087 the type ``a`` is refined to ``Int``. That's the whole point! A precise
3088 specification of the type rules is beyond what this user manual aspires
3089 to, but the design closely follows that described in the paper `Simple
3090 unification-based type inference for
3091 GADTs <http://research.microsoft.com/%7Esimonpj/papers/gadt/>`__, (ICFP
3092 2006). The general principle is this: *type refinement is only carried
3093 out based on user-supplied type annotations*. So if no type signature is
3094 supplied for ``eval``, no type refinement happens, and lots of obscure
3095 error messages will occur. However, the refinement is quite general. For
3096 example, if we had: ::
3097
3098       eval :: Term a -> a -> a
3099       eval (Lit i) j =  i+j
3100
3101 the pattern match causes the type ``a`` to be refined to ``Int``
3102 (because of the type of the constructor ``Lit``), and that refinement
3103 also applies to the type of ``j``, and the result type of the ``case``
3104 expression. Hence the addition ``i+j`` is legal.
3105
3106 These and many other examples are given in papers by Hongwei Xi, and Tim
3107 Sheard. There is a longer introduction `on the
3108 wiki <http://www.haskell.org/haskellwiki/GADT>`__, and Ralf Hinze's `Fun
3109 with phantom
3110 types <http://www.cs.ox.ac.uk/ralf.hinze/publications/With.pdf>`__ also
3111 has a number of examples. Note that papers may use different notation to
3112 that implemented in GHC.
3113
3114 The rest of this section outlines the extensions to GHC that support
3115 GADTs. The extension is enabled with :extension:`GADTs`. The :extension:`GADTs` extension
3116 also sets :extension:`GADTSyntax` and :extension:`MonoLocalBinds`.
3117
3118 -  A GADT can only be declared using GADT-style syntax
3119    (:ref:`gadt-style`); the old Haskell 98 syntax for data declarations
3120    always declares an ordinary data type. The result type of each
3121    constructor must begin with the type constructor being defined, but
3122    for a GADT the arguments to the type constructor can be arbitrary
3123    monotypes. For example, in the ``Term`` data type above, the type of
3124    each constructor must end with ``Term ty``, but the ``ty`` need not
3125    be a type variable (e.g. the ``Lit`` constructor).
3126
3127 -  It is permitted to declare an ordinary algebraic data type using
3128    GADT-style syntax. What makes a GADT into a GADT is not the syntax,
3129    but rather the presence of data constructors whose result type is not
3130    just ``T a b``.
3131
3132 -  You cannot use a ``deriving`` clause for a GADT; only for an ordinary
3133    data type.
3134
3135 -  As mentioned in :ref:`gadt-style`, record syntax is supported. For
3136    example:
3137
3138    ::
3139
3140          data Term a where
3141              Lit    :: { val  :: Int }      -> Term Int
3142              Succ   :: { num  :: Term Int } -> Term Int
3143              Pred   :: { num  :: Term Int } -> Term Int
3144              IsZero :: { arg  :: Term Int } -> Term Bool
3145              Pair   :: { arg1 :: Term a
3146                        , arg2 :: Term b
3147                        }                    -> Term (a,b)
3148              If     :: { cnd  :: Term Bool
3149                        , tru  :: Term a
3150                        , fls  :: Term a
3151                        }                    -> Term a
3152
3153    However, for GADTs there is the following additional constraint:
3154    every constructor that has a field ``f`` must have the same result
3155    type (modulo alpha conversion) Hence, in the above example, we cannot
3156    merge the ``num`` and ``arg`` fields above into a single name.
3157    Although their field types are both ``Term Int``, their selector
3158    functions actually have different types:
3159
3160    ::
3161
3162          num :: Term Int -> Term Int
3163          arg :: Term Bool -> Term Int
3164
3165 -  When pattern-matching against data constructors drawn from a GADT,
3166    for example in a ``case`` expression, the following rules apply:
3167
3168    -  The type of the scrutinee must be rigid.
3169
3170    -  The type of the entire ``case`` expression must be rigid.
3171
3172    -  The type of any free variable mentioned in any of the ``case``
3173       alternatives must be rigid.
3174
3175    A type is "rigid" if it is completely known to the compiler at its
3176    binding site. The easiest way to ensure that a variable a rigid type
3177    is to give it a type signature. For more precise details see `Simple
3178    unification-based type inference for
3179    GADTs <http://research.microsoft.com/%7Esimonpj/papers/gadt/>`__. The
3180    criteria implemented by GHC are given in the Appendix.
3181
3182 .. _record-system-extensions:
3183
3184 Extensions to the record system
3185 ===============================
3186
3187 .. _traditional-record-syntax:
3188
3189 Traditional record syntax
3190 -------------------------
3191
3192 .. extension:: NoTraditionalRecordSyntax
3193     :shortdesc: Disable support for traditional record syntax
3194         (as supported by Haskell 98) ``C {f = x}``
3195
3196     :since: 7.4.1
3197
3198     Disallow use of record syntax.
3199
3200 Traditional record syntax, such as ``C {f = x}``, is enabled by default.
3201 To disable it, you can use the :extension:`NoTraditionalRecordSyntax` extension.
3202
3203 .. _disambiguate-fields:
3204
3205 Record field disambiguation
3206 ---------------------------
3207
3208 .. extension:: DisambiguateRecordFields
3209     :shortdesc: Enable record field disambiguation.
3210         Implied by :extension:`RecordWildCards`.
3211
3212     :since: 6.8.1
3213
3214     Allow the compiler to automatically choose between identically-named
3215     record selectors based on type (if the choice is unambiguous).
3216
3217 In record construction and record pattern matching it is entirely
3218 unambiguous which field is referred to, even if there are two different
3219 data types in scope with a common field name. For example:
3220
3221 ::
3222
3223     module M where
3224       data S = MkS { x :: Int, y :: Bool }
3225
3226     module Foo where
3227       import M
3228
3229       data T = MkT { x :: Int }
3230
3231       ok1 (MkS { x = n }) = n+1   -- Unambiguous
3232       ok2 n = MkT { x = n+1 }     -- Unambiguous
3233
3234       bad1 k = k { x = 3 }        -- Ambiguous
3235       bad2 k = x k                -- Ambiguous
3236
3237 Even though there are two ``x``'s in scope, it is clear that the ``x``
3238 in the pattern in the definition of ``ok1`` can only mean the field
3239 ``x`` from type ``S``. Similarly for the function ``ok2``. However, in
3240 the record update in ``bad1`` and the record selection in ``bad2`` it is
3241 not clear which of the two types is intended.
3242
3243 Haskell 98 regards all four as ambiguous, but with the
3244 :extension:`DisambiguateRecordFields` extension, GHC will accept the former two. The
3245 rules are precisely the same as those for instance declarations in
3246 Haskell 98, where the method names on the left-hand side of the method
3247 bindings in an instance declaration refer unambiguously to the method of
3248 that class (provided they are in scope at all), even if there are other
3249 variables in scope with the same name. This reduces the clutter of
3250 qualified names when you import two records from different modules that
3251 use the same field name.
3252
3253 Some details:
3254
3255 -  Field disambiguation can be combined with punning (see
3256    :ref:`record-puns`). For example: ::
3257
3258        module Foo where
3259          import M
3260          x=True
3261          ok3 (MkS { x }) = x+1   -- Uses both disambiguation and punning
3262
3263 -  With :extension:`DisambiguateRecordFields` you can use *unqualified* field
3264    names even if the corresponding selector is only in scope *qualified*
3265    For example, assuming the same module ``M`` as in our earlier
3266    example, this is legal: ::
3267
3268        module Foo where
3269          import qualified M    -- Note qualified
3270
3271          ok4 (M.MkS { x = n }) = n+1   -- Unambiguous
3272
3273    Since the constructor ``MkS`` is only in scope qualified, you must
3274    name it ``M.MkS``, but the field ``x`` does not need to be qualified
3275    even though ``M.x`` is in scope but ``x`` is not (In effect, it is
3276    qualified by the constructor).
3277
3278 .. _duplicate-record-fields:
3279
3280 Duplicate record fields
3281 -----------------------
3282
3283 .. extension:: DuplicateRecordFields
3284     :shortdesc: Allow definition of record types with identically-named fields.
3285
3286     :implies: :extension:`DisambiguateRecordFields`
3287     :since: 8.0.1
3288
3289     Allow definition of record types with identically-named fields.
3290
3291 Going beyond :extension:`DisambiguateRecordFields` (see :ref:`disambiguate-fields`),
3292 the :extension:`DuplicateRecordFields` extension allows multiple datatypes to be
3293 declared using the same field names in a single module. For example, it allows
3294 this: ::
3295
3296     module M where
3297       data S = MkS { x :: Int }
3298       data T = MkT { x :: Bool }
3299
3300 Uses of fields that are always unambiguous because they mention the constructor,
3301 including construction and pattern-matching, may freely use duplicated field
3302 names. For example, the following are permitted (just as with
3303 :extension:`DisambiguateRecordFields`): ::
3304
3305     s = MkS { x = 3 }
3306
3307     f (MkT { x = b }) = b
3308
3309 Field names used as selector functions or in record updates must be unambiguous,
3310 either because there is only one such field in scope, or because a type
3311 signature is supplied, as described in the following sections.
3312
3313 Selector functions
3314 ~~~~~~~~~~~~~~~~~~
3315
3316 Fields may be used as selector functions only if they are unambiguous, so this
3317 is still not allowed if both ``S(x)`` and ``T(x)`` are in scope: ::
3318
3319     bad r = x r
3320
3321 An ambiguous selector may be disambiguated by the type being "pushed down" to
3322 the occurrence of the selector (see :ref:`higher-rank-type-inference` for more
3323 details on what "pushed down" means). For example, the following are permitted: ::
3324
3325     ok1 = x :: S -> Int
3326
3327     ok2 :: S -> Int
3328     ok2 = x
3329
3330     ok3 = k x -- assuming we already have k :: (S -> Int) -> _
3331
3332 In addition, the datatype that is meant may be given as a type signature on the
3333 argument to the selector: ::
3334
3335     ok4 s = x (s :: S)
3336
3337 However, we do not infer the type of the argument to determine the datatype, or
3338 have any way of deferring the choice to the constraint solver. Thus the
3339 following is ambiguous: ::
3340
3341     bad :: S -> Int
3342     bad s = x s
3343
3344 Even though a field label is duplicated in its defining module, it may be
3345 possible to use the selector unambiguously elsewhere. For example, another
3346 module could import ``S(x)`` but not ``T(x)``, and then use ``x`` unambiguously.
3347
3348 Record updates
3349 ~~~~~~~~~~~~~~
3350
3351 In a record update such as ``e { x = 1 }``, if there are multiple ``x`` fields
3352 in scope, then the type of the context must fix which record datatype is
3353 intended, or a type annotation must be supplied. Consider the following
3354 definitions: ::
3355
3356     data S = MkS { foo :: Int }
3357     data T = MkT { foo :: Int, bar :: Int }
3358     data U = MkU { bar :: Int, baz :: Int }
3359
3360 Without :extension:`DuplicateRecordFields`, an update mentioning ``foo`` will always be
3361 ambiguous if all these definitions were in scope. When the extension is enabled,
3362 there are several options for disambiguating updates:
3363
3364 - Check for types that have all the fields being updated. For example: ::
3365
3366       f x = x { foo = 3, bar = 2 }
3367
3368   Here ``f`` must be updating ``T`` because neither ``S`` nor ``U`` have both
3369   fields.
3370
3371 - Use the type being pushed in to the record update, as in the following: ::
3372
3373       g1 :: T -> T
3374       g1 x = x { foo = 3 }
3375
3376       g2 x = x { foo = 3 } :: T
3377
3378       g3 = k (x { foo = 3 }) -- assuming we already have k :: T -> _
3379
3380 - Use an explicit type signature on the record expression, as in: ::
3381
3382       h x = (x :: T) { foo = 3 }
3383
3384 The type of the expression being updated will not be inferred, and no
3385 constraint-solving will be performed, so the following will be rejected as
3386 ambiguous: ::
3387
3388     let x :: T
3389         x = blah
3390     in x { foo = 3 }
3391
3392     \x -> [x { foo = 3 },  blah :: T ]
3393
3394     \ (x :: T) -> x { foo = 3 }
3395
3396 Import and export of record fields
3397 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
3398
3399 When :extension:`DuplicateRecordFields` is enabled, an ambiguous field must be exported
3400 as part of its datatype, rather than at the top level. For example, the
3401 following is legal: ::
3402
3403     module M (S(x), T(..)) where
3404       data S = MkS { x :: Int }
3405       data T = MkT { x :: Bool }
3406
3407 However, this would not be permitted, because ``x`` is ambiguous: ::
3408
3409     module M (x) where ...
3410
3411 Similar restrictions apply on import.
3412
3413 .. _record-puns:
3414
3415 Record puns
3416 -----------
3417
3418 .. extension:: NamedFieldPuns
3419     :shortdesc: Enable record puns.
3420
3421     :since: 6.10.1
3422
3423     Allow use of record puns.
3424
3425 Record puns are enabled by the language extension :extension:`NamedFieldPuns`.
3426
3427 When using records, it is common to write a pattern that binds a
3428 variable with the same name as a record field, such as: ::
3429
3430     data C = C {a :: Int}
3431     f (C {a = a}) = a
3432
3433 Record punning permits the variable name to be elided, so one can simply
3434 write ::
3435
3436     f (C {a}) = a
3437
3438 to mean the same pattern as above. That is, in a record pattern, the
3439 pattern ``a`` expands into the pattern ``a = a`` for the same name
3440 ``a``.
3441
3442 Note that:
3443
3444 -  Record punning can also be used in an expression, writing, for
3445    example, ::
3446
3447        let a = 1 in C {a}
3448
3449    instead of ::
3450
3451        let a = 1 in C {a = a}
3452
3453    The expansion is purely syntactic, so the expanded right-hand side
3454    expression refers to the nearest enclosing variable that is spelled
3455    the same as the field name.
3456
3457 -  Puns and other patterns can be mixed in the same record: ::
3458
3459        data C = C {a :: Int, b :: Int}
3460        f (C {a, b = 4}) = a
3461
3462 -  Puns can be used wherever record patterns occur (e.g. in ``let``
3463    bindings or at the top-level).
3464
3465 -  A pun on a qualified field name is expanded by stripping off the
3466    module qualifier. For example: ::
3467
3468        f (C {M.a}) = a
3469
3470    means ::
3471
3472        f (M.C {M.a = a}) = a
3473
3474    (This is useful if the field selector ``a`` for constructor ``M.C``
3475    is only in scope in qualified form.)
3476
3477 .. _record-wildcards:
3478
3479 Record wildcards
3480 ----------------
3481
3482 .. extension:: RecordWildCards
3483     :shortdesc: Enable record wildcards.
3484         Implies :extension:`DisambiguateRecordFields`.
3485
3486     :implies: :extension:`DisambiguateRecordFields`.
3487     :since: 6.8.1
3488
3489     Allow the use of wildcards in record construction and pattern matching.
3490
3491 Record wildcards are enabled by the language extension :extension:`RecordWildCards`. This
3492 exension implies :extension:`DisambiguateRecordFields`.
3493
3494 For records with many fields, it can be tiresome to write out each field
3495 individually in a record pattern, as in ::
3496
3497     data C = C {a :: Int, b :: Int, c :: Int, d :: Int}
3498     f (C {a = 1, b = b, c = c, d = d}) = b + c + d
3499
3500 Record wildcard syntax permits a "``..``" in a record pattern, where
3501 each elided field ``f`` is replaced by the pattern ``f = f``. For
3502 example, the above pattern can be written as ::
3503
3504     f (C {a = 1, ..}) = b + c + d
3505
3506 More details:
3507
3508 -  Record wildcards in patterns can be mixed with other patterns,
3509    including puns (:ref:`record-puns`); for example, in a pattern
3510    ``(C {a = 1, b, ..})``. Additionally, record wildcards can be used
3511    wherever record patterns occur, including in ``let`` bindings and at
3512    the top-level. For example, the top-level binding ::
3513
3514        C {a = 1, ..} = e
3515
3516    defines ``b``, ``c``, and ``d``.
3517
3518 -  Record wildcards can also be used in an expression, when constructing
3519    a record. For example, ::
3520
3521        let {a = 1; b = 2; c = 3; d = 4} in C {..}
3522
3523    in place of ::
3524
3525        let {a = 1; b = 2; c = 3; d = 4} in C {a=a, b=b, c=c, d=d}
3526
3527    The expansion is purely syntactic, so the record wildcard expression
3528    refers to the nearest enclosing variables that are spelled the same
3529    as the omitted field names.
3530
3531 -  For both pattern and expression wildcards, the "``..``" expands to
3532    the missing *in-scope* record fields. Specifically the expansion of
3533    "``C {..}``" includes ``f`` if and only if:
3534
3535    -  ``f`` is a record field of constructor ``C``.
3536
3537    -  The record field ``f`` is in scope somehow (either qualified or
3538       unqualified).
3539
3540    These rules restrict record wildcards to the situations in which the
3541    user could have written the expanded version. For example ::
3542
3543        module M where
3544          data R = R { a,b,c :: Int }
3545        module X where
3546          import M( R(a,c) )
3547          f b = R { .. }
3548
3549    The ``R{..}`` expands to ``R{M.a=a}``, omitting ``b`` since the
3550    record field is not in scope, and omitting ``c`` since the variable
3551    ``c`` is not in scope (apart from the binding of the record selector
3552    ``c``, of course).
3553
3554 -  When record wildcards are use in record construction, a field ``f``
3555    is initialised only if ``f`` is in scope,
3556    and is not imported or bound at top level.
3557    For example, ``f`` can be bound by an enclosing pattern match or
3558    let/where-binding. For example ::
3559
3560         module M where
3561           import A( a )
3562
3563           data R = R { a,b,c,d :: Int }
3564
3565           c = 3 :: Int
3566
3567           f b = R { .. }  -- Expands to R { b = b, d = d }
3568             where
3569               d = b+1
3570
3571    Here, ``a`` is imported, and ``c`` is bound at top level, so neither
3572    contribute to the expansion of the "``..``".
3573    The motivation here is that it should be
3574    easy for the reader to figure out what the "``..``" expands to.
3575
3576 -  Record wildcards cannot be used (a) in a record update construct, and
3577    (b) for data constructors that are not declared with record fields.
3578    For example: ::
3579
3580        f x = x { v=True, .. }   -- Illegal (a)
3581
3582        data T = MkT Int Bool
3583        g = MkT { .. }           -- Illegal (b)
3584        h (MkT { .. }) = True    -- Illegal (b)
3585
3586
3587 .. _record-field-selector-polymorphism:
3588
3589 Record field selector polymorphism
3590 ----------------------------------
3591
3592 The module :base-ref:`GHC.Records.` defines the following: ::
3593
3594   class HasField (x :: k) r a | x r -> a where
3595     getField :: r -> a
3596
3597 A ``HasField x r a`` constraint represents the fact that ``x`` is a
3598 field of type ``a`` belonging to a record type ``r``.  The
3599 ``getField`` method gives the record selector function.
3600
3601 This allows definitions that are polymorphic over record types with a specified
3602 field.  For example, the following works with any record type that has a field
3603 ``name :: String``: ::
3604
3605   foo :: HasField "name" r String => r -> String
3606   foo r = reverse (getField @"name" r)
3607
3608 ``HasField`` is a magic built-in typeclass (similar to ``Coercible``, for
3609 example).  It is given special treatment by the constraint solver (see
3610 :ref:`solving-hasfield-constraints`).  Users may define their own instances of
3611 ``HasField`` also (see :ref:`virtual-record-fields`).
3612
3613 .. _solving-hasfield-constraints:
3614
3615 Solving HasField constraints
3616 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
3617
3618 If the constraint solver encounters a constraint ``HasField x r a``
3619 where ``r`` is a concrete datatype with a field ``x`` in scope, it
3620 will automatically solve the constraint using the field selector as
3621 the dictionary, unifying ``a`` with the type of the field if
3622 necessary.  This happens irrespective of which extensions are enabled.
3623
3624 For example, if the following datatype is in scope ::
3625
3626   data Person = Person { name :: String }
3627
3628 the end result is rather like having an instance ::
3629
3630   instance HasField "name" Person String where
3631     getField = name
3632
3633 except that this instance is not actually generated anywhere, rather
3634 the constraint is solved directly by the constraint solver.
3635
3636 A field must be in scope for the corresponding ``HasField`` constraint
3637 to be solved.  This retains the existing representation hiding
3638 mechanism, whereby a module may choose not to export a field,
3639 preventing client modules from accessing or updating it directly.
3640
3641 Solving ``HasField`` constraints depends on the field selector functions that
3642 are generated for each datatype definition:
3643
3644 -  If a record field does not have a selector function because its type would allow
3645    an existential variable to escape, the corresponding ``HasField`` constraint
3646    will not be solved.  For example, ::
3647
3648      {-# LANGUAGE ExistentialQuantification #-}
3649      data Exists t = forall x . MkExists { unExists :: t x }
3650
3651    does not give rise to a selector ``unExists :: Exists t -> t x`` and we will not
3652    solve ``HasField "unExists" (Exists t) a`` automatically.
3653
3654 -  If a record field has a polymorphic type (and hence the selector function is
3655    higher-rank), the corresponding ``HasField`` constraint will not be solved,
3656    because doing so would violate the functional dependency on ``HasField`` and/or
3657    require impredicativity.  For example, ::
3658
3659      {-# LANGUAGE RankNTypes #-}
3660      data Higher = MkHigher { unHigher :: forall t . t -> t }
3661
3662    gives rise to a selector ``unHigher :: Higher -> (forall t . t -> t)`` but does
3663    not lead to solution of the constraint ``HasField "unHigher" Higher a``.
3664
3665 -  A record GADT may have a restricted type for a selector function, which may lead
3666    to additional unification when solving ``HasField`` constraints.  For example, ::
3667
3668      {-# LANGUAGE GADTs #-}
3669      data Gadt t where
3670        MkGadt :: { unGadt :: Maybe v } -> Gadt [v]
3671
3672    gives rise to a selector ``unGadt :: Gadt [v] -> Maybe v``, so the solver will reduce
3673    the constraint ``HasField "unGadt" (Gadt t) b`` by unifying ``t ~ [v]`` and
3674    ``b ~ Maybe v`` for some fresh metavariable ``v``, rather as if we had an instance ::
3675
3676      instance (t ~ [v], b ~ Maybe v) => HasField "unGadt" (Gadt t) b
3677
3678 -  If a record type has an old-fashioned datatype context, the ``HasField``
3679    constraint will be reduced to solving the constraints from the context.
3680    For example, ::
3681
3682      {-# LANGUAGE DatatypeContexts #-}
3683      data Eq a => Silly a = MkSilly { unSilly :: a }
3684
3685    gives rise to a selector ``unSilly :: Eq a => Silly a -> a``, so
3686    the solver will reduce the constraint ``HasField "unSilly" (Silly a) b`` to
3687    ``Eq a`` (and unify ``a`` with ``b``), rather as if we had an instance ::
3688
3689      instance (Eq a, a ~ b) => HasField "unSilly" (Silly a) b
3690
3691 .. _virtual-record-fields:
3692
3693 Virtual record fields
3694 ~~~~~~~~~~~~~~~~~~~~~
3695
3696 Users may define their own instances of ``HasField``, provided they do
3697 not conflict with the built-in constraint solving behaviour.  This
3698 allows "virtual" record fields to be defined for datatypes that do not
3699 otherwise have them.
3700
3701 For example, this instance would make the ``name`` field of ``Person``
3702 accessible using ``#fullname`` as well: ::
3703
3704   instance HasField "fullname" Person String where
3705     getField = name
3706
3707 More substantially, an anonymous records library could provide
3708 ``HasField`` instances for its anonymous records, and thus be
3709 compatible with the polymorphic record selectors introduced by this
3710 proposal.  For example, something like this makes it possible to use
3711 ``getField`` to access ``Record`` values with the appropriate
3712 string in the type-level list of fields: ::
3713
3714   data Record (xs :: [(k, Type)]) where
3715     Nil  :: Record '[]
3716     Cons :: Proxy x -> a -> Record xs -> Record ('(x, a) ': xs)
3717
3718   instance HasField x (Record ('(x, a) ': xs)) a where
3719     getField (Cons _ v _) = v
3720   instance HasField x (Record xs) a => HasField x (Record ('(y, b) ': xs)) a where
3721     getField (Cons _ _ r) = getField @x r
3722
3723   r :: Record '[ '("name", String) ]
3724   r = Cons Proxy "R" Nil)
3725
3726   x = getField @"name" r
3727
3728 Since representations such as this can support field labels with kinds other
3729 than ``Symbol``, the ``HasField`` class is poly-kinded (even though the built-in
3730 constraint solving works only at kind ``Symbol``).  In particular, this allows
3731 users to declare scoped field labels such as in the following example: ::
3732
3733   data PersonFields = Name
3734
3735   s :: Record '[ '(Name, String) ]
3736   s = Cons Proxy "S" Nil
3737
3738   y = getField @Name s
3739
3740 In order to avoid conflicting with the built-in constraint solving,
3741 the following user-defined ``HasField`` instances are prohibited (in
3742 addition to the usual rules, such as the prohibition on type
3743 families appearing in instance heads):
3744
3745 -  ``HasField _ r _`` where ``r`` is a variable;
3746
3747 -  ``HasField _ (T ...) _`` if ``T`` is a data family (because it
3748    might have fields introduced later, using data instance declarations);
3749
3750 -  ``HasField x (T ...) _`` if ``x`` is a variable and ``T`` has any
3751    fields at all (but this instance is permitted if ``T`` has no fields);
3752
3753 -  ``HasField "foo" (T ...) _`` if ``T`` has a field ``foo`` (but this
3754    instance is permitted if it does not).
3755
3756 If a field has a higher-rank or existential type, the corresponding ``HasField``
3757 constraint will not be solved automatically (as described above), but in the
3758 interests of simplicity we do not permit users to define their own instances
3759 either.  If a field is not in scope, the corresponding instance is still
3760 prohibited, to avoid conflicts in downstream modules.
3761
3762
3763 .. _deriving:
3764
3765 Extensions to the "deriving" mechanism
3766 ======================================
3767
3768 Haskell 98 allows the programmer to add a deriving clause to a data type
3769 declaration, to generate a standard instance declaration for specified class.
3770 GHC extends this mechanism along several axes:
3771
3772 * The derivation mechanism can be used separtely from the data type
3773   declaration, using the `standalone deriving mechanism
3774   <#stand-alone-deriving>`__.
3775
3776 * In Haskell 98, the only derivable classes are ``Eq``,
3777   ``Ord``, ``Enum``, ``Ix``, ``Bounded``, ``Read``, and ``Show``. `Various
3778   language extensions <#deriving-extra>`__ extend this list.
3779
3780 * Besides the stock approach to deriving instances by generating all method
3781   definitions, GHC supports two additional deriving strategies, which can
3782   derive arbitrary classes:
3783
3784   * `Generalised newtype deriving <#newtype-deriving>`__ for newtypes and
3785   * `deriving any class <#derive-any-class>`__ using an empty instance
3786     declaration.
3787
3788   The user can optionally declare the desired `deriving strategy
3789   <#deriving-stragies>`__, especially if the compiler chooses the wrong
3790   one `by default <#default-deriving-strategy>`__.
3791
3792 .. _empty-data-deriving:
3793
3794 Deriving instances for empty data types
3795 ---------------------------------------
3796
3797 .. ghc-flag:: -XEmptyDataDeriving
3798     :shortdesc: Allow deriving instances of standard type classes for
3799                 empty data types.
3800     :type: dynamic
3801     :reverse: -XNoEmptyDataDeriving
3802     :category:
3803
3804     :since: 8.4.1
3805
3806     Allow deriving instances of standard type classes for empty data types.
3807
3808 One can write data types with no constructors using the
3809 :ghc-flag:`-XEmptyDataDecls` flag (see :ref:`nullary-types`), which is on by
3810 default in Haskell 2010. What is not on by default is the ability to derive
3811 type class instances for these types. This ability is enabled through use of
3812 the :ghc-flag:`-XEmptyDataDeriving` flag. For instance, this lets one write: ::
3813
3814     data Empty deriving (Eq, Ord, Read, Show)
3815
3816 This would generate the following instances: ::
3817
3818     instance Eq Empty where
3819       _ == _ = True
3820
3821     instance Ord Empty where
3822       compare _ _ = EQ
3823
3824     instance Read Empty where
3825       readPrec = pfail
3826
3827     instance Show Empty where
3828       showsPrec _ x = case x of {}
3829
3830 The :ghc-flag:`-XEmptyDataDeriving` flag is only required to enable deriving
3831 of these four "standard" type classes (which are mentioned in the Haskell
3832 Report). Other extensions to the ``deriving`` mechanism, which are explained
3833 below in greater detail, do not require :ghc-flag:`-XEmptyDataDeriving` to be
3834 used in conjunction with empty data types. These include:
3835
3836 * :ghc-flag:`-XStandaloneDeriving` (see :ref:`stand-alone-deriving`)
3837 * Type classes which require their own extensions to be enabled to be derived,
3838   such as :ghc-flag:`-XDeriveFunctor` (see :ref:`deriving-extra`)
3839 * :ghc-flag:`-XDeriveAnyClass` (see :ref:`derive-any-class`)
3840
3841 .. _deriving-inferred:
3842
3843 Inferred context for deriving clauses
3844 -------------------------------------
3845
3846 The Haskell Report is vague about exactly when a ``deriving`` clause is
3847 legal. For example: ::
3848
3849       data T0 f a = MkT0 a         deriving( Eq )
3850       data T1 f a = MkT1 (f a)     deriving( Eq )
3851       data T2 f a = MkT2 (f (f a)) deriving( Eq )
3852
3853 The natural generated ``Eq`` code would result in these instance
3854 declarations: ::
3855
3856       instance Eq a         => Eq (T0 f a) where ...
3857       instance Eq (f a)     => Eq (T1 f a) where ...
3858       instance Eq (f (f a)) => Eq (T2 f a) where ...
3859
3860 The first of these is obviously fine. The second is still fine, although
3861 less obviously. The third is not Haskell 98, and risks losing
3862 termination of instances.
3863
3864 GHC takes a conservative position: it accepts the first two, but not the
3865 third. The rule is this: each constraint in the inferred instance
3866 context must consist only of type variables, with no repetitions.
3867
3868 This rule is applied regardless of flags. If you want a more exotic
3869 context, you can write it yourself, using the `standalone deriving
3870 mechanism <#stand-alone-deriving>`__.
3871
3872 .. _stand-alone-deriving:
3873
3874 Stand-alone deriving declarations
3875 ---------------------------------
3876
3877 .. extension:: StandaloneDeriving
3878     :shortdesc: Enable standalone deriving.
3879
3880     :since: 6.8.1
3881
3882     Allow the use of stand-alone ``deriving`` declarations.
3883
3884 GHC allows stand-alone ``deriving`` declarations, enabled by
3885 :extension:`StandaloneDeriving`: ::
3886
3887       data Foo a = Bar a | Baz String
3888
3889       deriving instance Eq a => Eq (Foo a)
3890
3891 The syntax is identical to that of an ordinary instance declaration
3892 apart from (a) the keyword ``deriving``, and (b) the absence of the
3893 ``where`` part.
3894
3895 However, standalone deriving differs from a ``deriving`` clause in a
3896 number of important ways:
3897
3898 -  The standalone deriving declaration does not need to be in the same
3899    module as the data type declaration. (But be aware of the dangers of
3900    orphan instances (:ref:`orphan-modules`).
3901
3902 -  In most cases, you must supply an explicit context (in the example the
3903    context is ``(Eq a)``), exactly as you would in an ordinary instance
3904    declaration. (In contrast, in a ``deriving`` clause attached to a
3905    data type declaration, the context is inferred.)
3906
3907    The exception to this rule is that the context of a standalone deriving
3908    declaration can infer its context when a single, extra-wildcards constraint
3909    is used as the context, such as in: ::
3910
3911          deriving instance _ => Eq (Foo a)
3912
3913    This is essentially the same as if you had written ``deriving Foo`` after
3914    the declaration for ``data Foo a``. Using this feature requires the use of
3915    :extension:`PartialTypeSignatures` (:ref:`partial-type-signatures`).
3916
3917 -  Unlike a ``deriving`` declaration attached to a ``data`` declaration,
3918    the instance can be more specific than the data type (assuming you
3919    also use :extension:`FlexibleInstances`, :ref:`instance-rules`). Consider
3920    for example ::
3921
3922          data Foo a = Bar a | Baz String
3923
3924          deriving instance Eq a => Eq (Foo [a])
3925          deriving instance Eq a => Eq (Foo (Maybe a))
3926
3927    This will generate a derived instance for ``(Foo [a])`` and
3928    ``(Foo (Maybe a))``, but other types such as ``(Foo (Int,Bool))``
3929    will not be an instance of ``Eq``.
3930
3931 -  Unlike a ``deriving`` declaration attached to a ``data`` declaration,
3932    GHC does not restrict the form of the data type. Instead, GHC simply
3933    generates the appropriate boilerplate code for the specified class,
3934    and typechecks it. If there is a type error, it is your problem. (GHC
3935    will show you the offending code if it has a type error.)
3936
3937    The merit of this is that you can derive instances for GADTs and
3938    other exotic data types, providing only that the boilerplate code
3939    does indeed typecheck. For example: ::
3940
3941          data T a where
3942             T1 :: T Int
3943             T2 :: T Bool
3944
3945          deriving instance Show (T a)
3946
3947    In this example, you cannot say ``... deriving( Show )`` on the data
3948    type declaration for ``T``, because ``T`` is a GADT, but you *can*
3949    generate the instance declaration using stand-alone deriving.
3950
3951    The down-side is that, if the boilerplate code fails to typecheck,
3952    you will get an error message about that code, which you did not
3953    write. Whereas, with a ``deriving`` clause the side-conditions are
3954    necessarily more conservative, but any error message may be more
3955    comprehensible.
3956
3957 -  Under most circumstances, you cannot use standalone deriving to create an
3958    instance for a data type whose constructors are not all in scope. This is
3959    because the derived instance would generate code that uses the constructors
3960    behind the scenes, which would break abstraction.
3961
3962    The one exception to this rule is :extension:`DeriveAnyClass`, since
3963    deriving an instance via :extension:`DeriveAnyClass` simply generates
3964    an empty instance declaration, which does not require the use of any
3965    constructors. See the `deriving any class <#derive-any-class>`__ section
3966    for more details.
3967
3968 In other ways, however, a standalone deriving obeys the same rules as
3969 ordinary deriving:
3970
3971 -  A ``deriving instance`` declaration must obey the same rules
3972    concerning form and termination as ordinary instance declarations,
3973    controlled by the same flags; see :ref:`instance-decls`.
3974
3975 -  The stand-alone syntax is generalised for newtypes in exactly the
3976    same way that ordinary ``deriving`` clauses are generalised
3977    (:ref:`newtype-deriving`). For example: ::
3978
3979          newtype Foo a = MkFoo (State Int a)
3980
3981          deriving instance MonadState Int Foo
3982
3983    GHC always treats the *last* parameter of the instance (``Foo`` in
3984    this example) as the type whose instance is being derived.
3985
3986 .. _deriving-extra:
3987
3988 Deriving instances of extra classes (``Data``, etc.)
3989 ----------------------------------------------------
3990
3991 Haskell 98 allows the programmer to add "``deriving( Eq, Ord )``" to a
3992 data type declaration, to generate a standard instance declaration for
3993 classes specified in the ``deriving`` clause. In Haskell 98, the only
3994 classes that may appear in the ``deriving`` clause are the standard
3995 classes ``Eq``, ``Ord``, ``Enum``, ``Ix``, ``Bounded``, ``Read``, and
3996 ``Show``.
3997
3998 GHC extends this list with several more classes that may be
3999 automatically derived:
4000
4001 -  With :extension:`DeriveGeneric`, you can derive instances of the classes
4002    ``Generic`` and ``Generic1``, defined in ``GHC.Generics``. You can
4003    use these to define generic functions, as described in
4004    :ref:`generic-programming`.
4005
4006 -  With :extension:`DeriveFunctor`, you can derive instances of the class
4007    ``Functor``, defined in ``GHC.Base``.
4008
4009 -  With :extension:`DeriveDataTypeable`, you can derive instances of the class
4010    ``Data``, defined in ``Data.Data``.
4011
4012 -  With :extension:`DeriveFoldable`, you can derive instances of the class
4013    ``Foldable``, defined in ``Data.Foldable``.
4014
4015 -  With :extension:`DeriveTraversable`, you can derive instances of the class
4016    ``Traversable``, defined in ``Data.Traversable``. Since the
4017    ``Traversable`` instance dictates the instances of ``Functor`` and
4018    ``Foldable``, you'll probably want to derive them too, so
4019    :extension:`DeriveTraversable` implies :extension:`DeriveFunctor` and
4020    :extension:`DeriveFoldable`.
4021
4022 -  With :extension:`DeriveLift`, you can derive instances of the class ``Lift``,
4023    defined in the ``Language.Haskell.TH.Syntax`` module of the
4024    ``template-haskell`` package.
4025
4026 You can also use a standalone deriving declaration instead (see
4027 :ref:`stand-alone-deriving`).
4028
4029 In each case the appropriate class must be in scope before it can be
4030 mentioned in the ``deriving`` clause.
4031
4032 .. _deriving-functor:
4033
4034 Deriving ``Functor`` instances
4035 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
4036
4037 .. extension:: DeriveFunctor
4038     :shortdesc: Enable deriving for the Functor class.
4039         Implied by :extension:`DeriveTraversable`.
4040
4041     :since: 7.10.1
4042
4043     Allow automatic deriving of instances for the ``Functor`` typeclass.
4044
4045
4046 With :extension:`DeriveFunctor`, one can derive ``Functor`` instances for data types
4047 of kind ``Type -> Type``. For example, this declaration::
4048
4049     data Example a = Ex a Char (Example a) (Example Char)
4050       deriving Functor
4051
4052 would generate the following instance: ::
4053
4054     instance Functor Example where
4055       fmap f (Ex a1 a2 a3 a4) = Ex (f a1) a2 (fmap f a3) a4
4056
4057 The basic algorithm for :extension:`DeriveFunctor` walks the arguments of each
4058 constructor of a data type, applying a mapping function depending on the type
4059 of each argument. If a plain type variable is found that is syntactically
4060 equivalent to the last type parameter of the data type (``a`` in the above
4061 example), then we apply the function ``f`` directly to it. If a type is
4062 encountered that is not syntactically equivalent to the last type parameter
4063 *but does mention* the last type parameter somewhere in it, then a recursive
4064 call to ``fmap`` is made. If a type is found which doesn't mention the last
4065 type parameter at all, then it is left alone.
4066
4067 The second of those cases, in which a type is unequal to the type parameter but
4068 does contain the type parameter, can be surprisingly tricky. For example, the
4069 following example compiles::
4070
4071     newtype Right a = Right (Either Int a) deriving Functor
4072
4073 Modifying the code slightly, however, produces code which will not compile::
4074
4075     newtype Wrong a = Wrong (Either a Int) deriving Functor
4076
4077 The difference involves the placement of the last type parameter, ``a``. In the
4078 ``Right`` case, ``a`` occurs within the type ``Either Int a``, and moreover, it
4079 appears as the last type argument of ``Either``. In the ``Wrong`` case,
4080 however, ``a`` is not the last type argument to ``Either``; rather, ``Int`` is.
4081
4082 This distinction is important because of the way :extension:`DeriveFunctor` works. The
4083 derived ``Functor Right`` instance would be::
4084
4085     instance Functor Right where
4086       fmap f (Right a) = Right (fmap f a)
4087
4088 Given a value of type ``Right a``, GHC must produce a value of type
4089 ``Right b``. Since the argument to the ``Right`` constructor has type
4090 ``Either Int a``, the code recursively calls ``fmap`` on it to produce a value
4091 of type ``Either Int b``, which is used in turn to construct a final value of
4092 type ``Right b``.
4093
4094 The generated code for the ``Functor Wrong`` instance would look exactly the
4095 same, except with ``Wrong`` replacing every occurrence of ``Right``. The
4096 problem is now that ``fmap`` is being applied recursively to a value of type
4097 ``Either a Int``. This cannot possibly produce a value of type
4098 ``Either b Int``, as ``fmap`` can only change the last type parameter! This
4099 causes the generated code to be ill-typed.
4100
4101 As a general rule, if a data type has a derived ``Functor`` instance and its
4102 last type parameter occurs on the right-hand side of the data declaration, then
4103 either it must (1) occur bare (e.g., ``newtype Id a = Id a``), or (2) occur as the
4104 last argument of a type constructor (as in ``Right`` above).
4105
4106 There are two exceptions to this rule:
4107
4108 #. Tuple types. When a non-unit tuple is used on the right-hand side of a data
4109    declaration, :extension:`DeriveFunctor` treats it as a product of distinct types.
4110    In other words, the following code::
4111
4112        newtype Triple a = Triple (a, Int, [a]) deriving Functor
4113
4114    Would result in a generated ``Functor`` instance like so::
4115
4116        instance Functor Triple where
4117          fmap f (Triple a) =
4118            Triple (case a of
4119                         (a1, a2, a3) -> (f a1, a2, fmap f a3))
4120
4121    That is, :extension:`DeriveFunctor` pattern-matches its way into tuples and maps
4122    over each type that constitutes the tuple. The generated code is
4123    reminiscent of what would be generated from
4124    ``data Triple a = Triple a Int [a]``, except with extra machinery to handle
4125    the tuple.
4126