Fix Trac #3965: tighten conditions when deriving Data
[ghc.git] / compiler / typecheck / TcDeriv.lhs
1 %
2 % (c) The University of Glasgow 2006
3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
4 %
5
6 Handles @deriving@ clauses on @data@ declarations.
7
8 \begin{code}
9 module TcDeriv ( tcDeriving ) where
10
11 #include "HsVersions.h"
12
13 import HsSyn
14 import DynFlags
15
16 import Generics
17 import TcRnMonad
18 import TcEnv
19 import TcClassDcl( tcAddDeclCtxt )      -- Small helper
20 import TcGenDeriv                       -- Deriv stuff
21 import InstEnv
22 import Inst
23 import TcHsType
24 import TcMType
25 import TcSimplify
26
27 import RnBinds
28 import RnEnv
29 import HscTypes
30
31 import Class
32 import Type
33 import Coercion
34 import ErrUtils
35 import MkId
36 import DataCon
37 import Maybes
38 import RdrName
39 import Name
40 import NameSet
41 import TyCon
42 import TcType
43 import Var
44 import VarSet
45 import PrelNames
46 import SrcLoc
47 import Util
48 import ListSetOps
49 import Outputable
50 import FastString
51 import Bag
52
53 import Control.Monad
54 \end{code}
55
56 %************************************************************************
57 %*                                                                      *
58                 Overview
59 %*                                                                      *
60 %************************************************************************
61
62 Overall plan
63 ~~~~~~~~~~~~
64 1.  Convert the decls (i.e. data/newtype deriving clauses, 
65     plus standalone deriving) to [EarlyDerivSpec]
66
67 2.  Infer the missing contexts for the Left DerivSpecs
68
69 3.  Add the derived bindings, generating InstInfos
70
71 \begin{code}
72 -- DerivSpec is purely  local to this module
73 data DerivSpec  = DS { ds_loc     :: SrcSpan 
74                      , ds_orig    :: InstOrigin 
75                      , ds_name    :: Name
76                      , ds_tvs     :: [TyVar] 
77                      , ds_theta   :: ThetaType
78                      , ds_cls     :: Class
79                      , ds_tys     :: [Type]
80                      , ds_tc      :: TyCon
81                      , ds_tc_args :: [Type]
82                      , ds_newtype :: Bool }
83         -- This spec implies a dfun declaration of the form
84         --       df :: forall tvs. theta => C tys
85         -- The Name is the name for the DFun we'll build
86         -- The tyvars bind all the variables in the theta
87         -- For family indexes, the tycon in 
88         --       in ds_tys is the *family* tycon
89         --       in ds_tc, ds_tc_args is the *representation* tycon
90         -- For non-family tycons, both are the same
91
92         -- ds_newtype = True  <=> Newtype deriving
93         --              False <=> Vanilla deriving
94
95 type DerivContext = Maybe ThetaType
96    -- Nothing    <=> Vanilla deriving; infer the context of the instance decl
97    -- Just theta <=> Standalone deriving: context supplied by programmer
98
99 type EarlyDerivSpec = Either DerivSpec DerivSpec
100         -- Left  ds => the context for the instance should be inferred
101         --             In this case ds_theta is the list of all the 
102         --                constraints needed, such as (Eq [a], Eq a)
103         --                The inference process is to reduce this to a 
104         --                simpler form (e.g. Eq a)
105         -- 
106         -- Right ds => the exact context for the instance is supplied 
107         --             by the programmer; it is ds_theta
108
109 pprDerivSpec :: DerivSpec -> SDoc
110 pprDerivSpec (DS { ds_loc = l, ds_name = n, ds_tvs = tvs, 
111                    ds_cls = c, ds_tys = tys, ds_theta = rhs })
112   = parens (hsep [ppr l, ppr n, ppr tvs, ppr c, ppr tys]
113             <+> equals <+> ppr rhs)
114 \end{code}
115
116
117 Inferring missing contexts 
118 ~~~~~~~~~~~~~~~~~~~~~~~~~~
119 Consider
120
121         data T a b = C1 (Foo a) (Bar b)
122                    | C2 Int (T b a)
123                    | C3 (T a a)
124                    deriving (Eq)
125
126 [NOTE: See end of these comments for what to do with 
127         data (C a, D b) => T a b = ...
128 ]
129
130 We want to come up with an instance declaration of the form
131
132         instance (Ping a, Pong b, ...) => Eq (T a b) where
133                 x == y = ...
134
135 It is pretty easy, albeit tedious, to fill in the code "...".  The
136 trick is to figure out what the context for the instance decl is,
137 namely @Ping@, @Pong@ and friends.
138
139 Let's call the context reqd for the T instance of class C at types
140 (a,b, ...)  C (T a b).  Thus:
141
142         Eq (T a b) = (Ping a, Pong b, ...)
143
144 Now we can get a (recursive) equation from the @data@ decl:
145
146         Eq (T a b) = Eq (Foo a) u Eq (Bar b)    -- From C1
147                    u Eq (T b a) u Eq Int        -- From C2
148                    u Eq (T a a)                 -- From C3
149
150 Foo and Bar may have explicit instances for @Eq@, in which case we can
151 just substitute for them.  Alternatively, either or both may have
152 their @Eq@ instances given by @deriving@ clauses, in which case they
153 form part of the system of equations.
154
155 Now all we need do is simplify and solve the equations, iterating to
156 find the least fixpoint.  Notice that the order of the arguments can
157 switch around, as here in the recursive calls to T.
158
159 Let's suppose Eq (Foo a) = Eq a, and Eq (Bar b) = Ping b.
160
161 We start with:
162
163         Eq (T a b) = {}         -- The empty set
164
165 Next iteration:
166         Eq (T a b) = Eq (Foo a) u Eq (Bar b)    -- From C1
167                    u Eq (T b a) u Eq Int        -- From C2
168                    u Eq (T a a)                 -- From C3
169
170         After simplification:
171                    = Eq a u Ping b u {} u {} u {}
172                    = Eq a u Ping b
173
174 Next iteration:
175
176         Eq (T a b) = Eq (Foo a) u Eq (Bar b)    -- From C1
177                    u Eq (T b a) u Eq Int        -- From C2
178                    u Eq (T a a)                 -- From C3
179
180         After simplification:
181                    = Eq a u Ping b
182                    u (Eq b u Ping a)
183                    u (Eq a u Ping a)
184
185                    = Eq a u Ping b u Eq b u Ping a
186
187 The next iteration gives the same result, so this is the fixpoint.  We
188 need to make a canonical form of the RHS to ensure convergence.  We do
189 this by simplifying the RHS to a form in which
190
191         - the classes constrain only tyvars
192         - the list is sorted by tyvar (major key) and then class (minor key)
193         - no duplicates, of course
194
195 So, here are the synonyms for the ``equation'' structures:
196
197
198 Note [Data decl contexts]
199 ~~~~~~~~~~~~~~~~~~~~~~~~~
200 Consider
201
202         data (RealFloat a) => Complex a = !a :+ !a deriving( Read )
203
204 We will need an instance decl like:
205
206         instance (Read a, RealFloat a) => Read (Complex a) where
207           ...
208
209 The RealFloat in the context is because the read method for Complex is bound
210 to construct a Complex, and doing that requires that the argument type is
211 in RealFloat. 
212
213 But this ain't true for Show, Eq, Ord, etc, since they don't construct
214 a Complex; they only take them apart.
215
216 Our approach: identify the offending classes, and add the data type
217 context to the instance decl.  The "offending classes" are
218
219         Read, Enum?
220
221 FURTHER NOTE ADDED March 2002.  In fact, Haskell98 now requires that
222 pattern matching against a constructor from a data type with a context
223 gives rise to the constraints for that context -- or at least the thinned
224 version.  So now all classes are "offending".
225
226 Note [Newtype deriving]
227 ~~~~~~~~~~~~~~~~~~~~~~~
228 Consider this:
229     class C a b
230     instance C [a] Char
231     newtype T = T Char deriving( C [a] )
232
233 Notice the free 'a' in the deriving.  We have to fill this out to 
234     newtype T = T Char deriving( forall a. C [a] )
235
236 And then translate it to:
237     instance C [a] Char => C [a] T where ...
238     
239         
240 Note [Newtype deriving superclasses]
241 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
242 (See also Trac #1220 for an interesting exchange on newtype
243 deriving and superclasses.)
244
245 The 'tys' here come from the partial application in the deriving
246 clause. The last arg is the new instance type.
247
248 We must pass the superclasses; the newtype might be an instance
249 of them in a different way than the representation type
250 E.g.            newtype Foo a = Foo a deriving( Show, Num, Eq )
251 Then the Show instance is not done via isomorphism; it shows
252         Foo 3 as "Foo 3"
253 The Num instance is derived via isomorphism, but the Show superclass
254 dictionary must the Show instance for Foo, *not* the Show dictionary
255 gotten from the Num dictionary. So we must build a whole new dictionary
256 not just use the Num one.  The instance we want is something like:
257      instance (Num a, Show (Foo a), Eq (Foo a)) => Num (Foo a) where
258         (+) = ((+)@a)
259         ...etc...
260 There may be a coercion needed which we get from the tycon for the newtype
261 when the dict is constructed in TcInstDcls.tcInstDecl2
262
263
264 Note [Unused constructors and deriving clauses]
265 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
266 See Trac #3221.  Consider
267    data T = T1 | T2 deriving( Show )
268 Are T1 and T2 unused?  Well, no: the deriving clause expands to mention
269 both of them.  So we gather defs/uses from deriving just like anything else.
270
271 %************************************************************************
272 %*                                                                      *
273 \subsection[TcDeriv-driver]{Top-level function for \tr{derivings}}
274 %*                                                                      *
275 %************************************************************************
276
277 \begin{code}
278 tcDeriving  :: [LTyClDecl Name]  -- All type constructors
279             -> [LInstDecl Name]  -- All instance declarations
280             -> [LDerivDecl Name] -- All stand-alone deriving declarations
281             -> TcM ([InstInfo Name],    -- The generated "instance decls"
282                     HsValBinds Name,    -- Extra generated top-level bindings
283                     DefUses)
284
285 tcDeriving tycl_decls inst_decls deriv_decls
286   = recoverM (return ([], emptyValBindsOut, emptyDUs)) $
287     do  {       -- Fish the "deriving"-related information out of the TcEnv
288                 -- And make the necessary "equations".
289           is_boot <- tcIsHsBoot
290         ; traceTc (text "tcDeriving" <+> ppr is_boot)
291         ; early_specs <- makeDerivSpecs is_boot tycl_decls inst_decls deriv_decls
292
293         ; overlap_flag <- getOverlapFlag
294         ; let (infer_specs, given_specs) = splitEithers early_specs
295         ; insts1 <- mapM (genInst True overlap_flag) given_specs
296
297         ; final_specs <- extendLocalInstEnv (map (iSpec . fst) insts1) $
298                          inferInstanceContexts overlap_flag infer_specs
299
300         ; insts2 <- mapM (genInst False overlap_flag) final_specs
301
302                  -- Generate the generic to/from functions from each type declaration
303         ; gen_binds <- mkGenericBinds is_boot tycl_decls
304         ; (inst_info, rn_binds, rn_dus) <- renameDeriv is_boot gen_binds (insts1 ++ insts2)
305
306         ; dflags <- getDOpts
307         ; liftIO (dumpIfSet_dyn dflags Opt_D_dump_deriv "Derived instances"
308                  (ddump_deriving inst_info rn_binds))
309
310         ; return (inst_info, rn_binds, rn_dus) }
311   where
312     ddump_deriving :: [InstInfo Name] -> HsValBinds Name -> SDoc
313     ddump_deriving inst_infos extra_binds
314       = vcat (map pprInstInfoDetails inst_infos) $$ ppr extra_binds
315
316 renameDeriv :: Bool -> LHsBinds RdrName
317             -> [(InstInfo RdrName, DerivAuxBinds)]
318             -> TcM ([InstInfo Name], HsValBinds Name, DefUses)
319 renameDeriv is_boot gen_binds insts
320   | is_boot     -- If we are compiling a hs-boot file, don't generate any derived bindings
321                 -- The inst-info bindings will all be empty, but it's easier to
322                 -- just use rn_inst_info to change the type appropriately
323   = do  { (rn_inst_infos, fvs) <- mapAndUnzipM rn_inst_info inst_infos  
324         ; return (rn_inst_infos, emptyValBindsOut, usesOnly (plusFVs fvs)) }
325
326   | otherwise
327   = discardWarnings $    -- Discard warnings about unused bindings etc
328     do  { (rn_gen, dus_gen) <- setOptM Opt_ScopedTypeVariables $  -- Type signatures in patterns 
329                                                                   -- are used in the generic binds
330                                rnTopBinds (ValBindsIn gen_binds [])
331         ; keepAliveSetTc (duDefs dus_gen)       -- Mark these guys to be kept alive
332
333                 -- Generate and rename any extra not-one-inst-decl-specific binds, 
334                 -- notably "con2tag" and/or "tag2con" functions.  
335                 -- Bring those names into scope before renaming the instances themselves
336         ; loc <- getSrcSpanM    -- Generic loc for shared bindings
337         ; let aux_binds = listToBag $ map (genAuxBind loc) $ 
338                           rm_dups [] $ concat deriv_aux_binds
339         ; rn_aux_lhs <- rnTopBindsLHS emptyFsEnv (ValBindsIn aux_binds [])
340         ; let aux_names = collectHsValBinders rn_aux_lhs
341
342         ; bindLocalNames aux_names $ 
343     do  { (rn_aux, dus_aux) <- rnTopBindsRHS (mkNameSet aux_names) rn_aux_lhs
344         ; (rn_inst_infos, fvs_insts) <- mapAndUnzipM rn_inst_info inst_infos
345         ; return (rn_inst_infos, rn_aux `plusHsValBinds` rn_gen,
346                   dus_gen `plusDU` dus_aux `plusDU` usesOnly (plusFVs fvs_insts)) } }
347
348   where
349     (inst_infos, deriv_aux_binds) = unzip insts
350     
351         -- Remove duplicate requests for auxilliary bindings
352     rm_dups acc [] = acc
353     rm_dups acc (b:bs) | any (isDupAux b) acc = rm_dups acc bs
354                        | otherwise            = rm_dups (b:acc) bs
355
356
357     rn_inst_info :: InstInfo RdrName -> TcM (InstInfo Name, FreeVars)
358     rn_inst_info info@(InstInfo { iBinds = NewTypeDerived coi tc })
359         = return ( info { iBinds = NewTypeDerived coi tc }
360                  , mkFVs (map dataConName (tyConDataCons tc)))
361           -- See Note [Newtype deriving and unused constructors]
362
363     rn_inst_info (InstInfo { iSpec = inst, iBinds = VanillaInst binds sigs standalone_deriv })
364         =       -- Bring the right type variables into 
365                 -- scope (yuk), and rename the method binds
366            ASSERT( null sigs )
367            bindLocalNames (map Var.varName tyvars) $
368            do { (rn_binds, fvs) <- rnMethodBinds clas_nm (\_ -> []) [] binds
369               ; let binds' = VanillaInst rn_binds [] standalone_deriv
370               ; return (InstInfo { iSpec = inst, iBinds = binds' }, fvs) }
371         where
372           (tyvars,_, clas,_) = instanceHead inst
373           clas_nm            = className clas
374
375 -----------------------------------------
376 mkGenericBinds :: Bool -> [LTyClDecl Name] -> TcM (LHsBinds RdrName)
377 mkGenericBinds is_boot tycl_decls
378   | is_boot 
379   = return emptyBag
380   | otherwise
381   = do  { tcs <- mapM tcLookupTyCon [ tcdName d 
382                                     | L _ d <- tycl_decls, isDataDecl d ]
383         ; return (unionManyBags [ mkTyConGenericBinds tc
384                                 | tc <- tcs, tyConHasGenerics tc ]) }
385                 -- We are only interested in the data type declarations,
386                 -- and then only in the ones whose 'has-generics' flag is on
387                 -- The predicate tyConHasGenerics finds both of these
388 \end{code}
389
390 Note [Newtype deriving and unused constructors]
391 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
392 Consider this (see Trac #1954):
393
394   module Bug(P) where
395   newtype P a = MkP (IO a) deriving Monad
396
397 If you compile with -fwarn-unused-binds you do not expect the warning
398 "Defined but not used: data consructor MkP". Yet the newtype deriving
399 code does not explicitly mention MkP, but it should behave as if you
400 had written
401   instance Monad P where
402      return x = MkP (return x)
403      ...etc...
404
405 So we want to signal a user of the data constructor 'MkP'.  That's
406 what we do in rn_inst_info, and it's the only reason we have the TyCon
407 stored in NewTypeDerived.
408
409
410 %************************************************************************
411 %*                                                                      *
412                 From HsSyn to DerivSpec
413 %*                                                                      *
414 %************************************************************************
415
416 @makeDerivSpecs@ fishes around to find the info about needed derived instances.
417
418 \begin{code}
419 makeDerivSpecs :: Bool 
420                -> [LTyClDecl Name] 
421                -> [LInstDecl Name]
422                -> [LDerivDecl Name] 
423                -> TcM [EarlyDerivSpec]
424
425 makeDerivSpecs is_boot tycl_decls inst_decls deriv_decls
426   | is_boot     -- No 'deriving' at all in hs-boot files
427   = do  { mapM_ add_deriv_err deriv_locs 
428         ; return [] }
429   | otherwise
430   = do  { eqns1 <- mapAndRecoverM deriveTyData all_tydata
431         ; eqns2 <- mapAndRecoverM deriveStandalone deriv_decls
432         ; return (eqns1 ++ eqns2) }
433   where
434     extractTyDataPreds decls
435       = [(p, d) | d@(L _ (TyData {tcdDerivs = Just preds})) <- decls, p <- preds]
436
437     all_tydata :: [(LHsType Name, LTyClDecl Name)]
438         -- Derived predicate paired with its data type declaration
439     all_tydata = extractTyDataPreds tycl_decls ++
440                  [ pd                -- Traverse assoc data families
441                  | L _ (InstDecl _ _ _ ats) <- inst_decls
442                  , pd <- extractTyDataPreds ats ]
443
444     deriv_locs = map (getLoc . snd) all_tydata
445                  ++ map getLoc deriv_decls
446
447     add_deriv_err loc = setSrcSpan loc $
448                         addErr (hang (ptext (sLit "Deriving not permitted in hs-boot file"))
449                                    2 (ptext (sLit "Use an instance declaration instead")))
450
451 ------------------------------------------------------------------
452 deriveStandalone :: LDerivDecl Name -> TcM EarlyDerivSpec
453 -- Standalone deriving declarations
454 --  e.g.   deriving instance Show a => Show (T a)
455 -- Rather like tcLocalInstDecl
456 deriveStandalone (L loc (DerivDecl deriv_ty))
457   = setSrcSpan loc                   $
458     addErrCtxt (standaloneCtxt deriv_ty)  $
459     do { traceTc (text "standalone deriving decl for" <+> ppr deriv_ty)
460        ; (tvs, theta, tau) <- tcHsInstHead deriv_ty
461        ; traceTc (text "standalone deriving;"
462               <+> text "tvs:" <+> ppr tvs
463               <+> text "theta:" <+> ppr theta
464               <+> text "tau:" <+> ppr tau)
465        ; (cls, inst_tys) <- checkValidInstance deriv_ty tvs theta tau
466                 -- C.f. TcInstDcls.tcLocalInstDecl1
467
468        ; let cls_tys = take (length inst_tys - 1) inst_tys
469              inst_ty = last inst_tys
470        ; traceTc (text "standalone deriving;"
471               <+> text "class:" <+> ppr cls
472               <+> text "class types:" <+> ppr cls_tys
473               <+> text "type:" <+> ppr inst_ty)
474        ; mkEqnHelp StandAloneDerivOrigin tvs cls cls_tys inst_ty
475                    (Just theta) }
476
477 ------------------------------------------------------------------
478 deriveTyData :: (LHsType Name, LTyClDecl Name) -> TcM EarlyDerivSpec
479 deriveTyData (L loc deriv_pred, L _ decl@(TyData { tcdLName = L _ tycon_name, 
480                                                    tcdTyVars = tv_names, 
481                                                    tcdTyPats = ty_pats }))
482   = setSrcSpan loc     $        -- Use the location of the 'deriving' item
483     tcAddDeclCtxt decl $
484     do  { (tvs, tc, tc_args) <- get_lhs ty_pats
485         ; tcExtendTyVarEnv tvs $        -- Deriving preds may (now) mention
486                                         -- the type variables for the type constructor
487
488     do  { (deriv_tvs, cls, cls_tys) <- tcHsDeriv deriv_pred
489                 -- The "deriv_pred" is a LHsType to take account of the fact that for
490                 -- newtype deriving we allow deriving (forall a. C [a]).
491
492         -- Given data T a b c = ... deriving( C d ),
493         -- we want to drop type variables from T so that (C d (T a)) is well-kinded
494         ; let cls_tyvars = classTyVars cls
495               kind = tyVarKind (last cls_tyvars)
496               (arg_kinds, _) = splitKindFunTys kind
497               n_args_to_drop = length arg_kinds 
498               n_args_to_keep = tyConArity tc - n_args_to_drop
499               args_to_drop   = drop n_args_to_keep tc_args
500               inst_ty        = mkTyConApp tc (take n_args_to_keep tc_args)
501               inst_ty_kind   = typeKind inst_ty
502               dropped_tvs    = mkVarSet (mapCatMaybes getTyVar_maybe args_to_drop)
503               univ_tvs       = (mkVarSet tvs `extendVarSetList` deriv_tvs)
504                                         `minusVarSet` dropped_tvs
505  
506         -- Check that the result really is well-kinded
507         ; checkTc (n_args_to_keep >= 0 && (inst_ty_kind `eqKind` kind))
508                   (derivingKindErr tc cls cls_tys kind)
509
510         ; checkTc (sizeVarSet dropped_tvs == n_args_to_drop &&           -- (a)
511                    tyVarsOfTypes (inst_ty:cls_tys) `subVarSet` univ_tvs) -- (b)
512                   (derivingEtaErr cls cls_tys inst_ty)
513                 -- Check that 
514                 --  (a) The data type can be eta-reduced; eg reject:
515                 --              data instance T a a = ... deriving( Monad )
516                 --  (b) The type class args do not mention any of the dropped type
517                 --      variables 
518                 --              newtype T a s = ... deriving( ST s )
519
520         -- Type families can't be partially applied
521         -- e.g.   newtype instance T Int a = MkT [a] deriving( Monad )
522         -- Note [Deriving, type families, and partial applications]
523         ; checkTc (not (isOpenTyCon tc) || n_args_to_drop == 0)
524                   (typeFamilyPapErr tc cls cls_tys inst_ty)
525
526         ; mkEqnHelp DerivOrigin (varSetElems univ_tvs) cls cls_tys inst_ty Nothing } }
527   where
528         -- Tiresomely we must figure out the "lhs", which is awkward for type families
529         -- E.g.   data T a b = .. deriving( Eq )
530         --          Here, the lhs is (T a b)
531         --        data instance TF Int b = ... deriving( Eq )
532         --          Here, the lhs is (TF Int b)
533         -- But if we just look up the tycon_name, we get is the *family*
534         -- tycon, but not pattern types -- they are in the *rep* tycon.
535     get_lhs Nothing     = do { tc <- tcLookupTyCon tycon_name
536                              ; let tvs = tyConTyVars tc
537                              ; return (tvs, tc, mkTyVarTys tvs) }
538     get_lhs (Just pats) = do { let hs_app = nlHsTyConApp tycon_name pats
539                              ; (tvs, tc_app) <- tcHsQuantifiedType tv_names hs_app
540                              ; let (tc, tc_args) = tcSplitTyConApp tc_app
541                              ; return (tvs, tc, tc_args) }
542
543 deriveTyData _other
544   = panic "derivTyData" -- Caller ensures that only TyData can happen
545 \end{code}
546
547 Note [Deriving, type families, and partial applications]
548 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
549 When there are no type families, it's quite easy:
550
551     newtype S a = MkS [a]
552     -- :CoS :: S  ~ []  -- Eta-reduced
553
554     instance Eq [a] => Eq (S a)         -- by coercion sym (Eq (coMkS a)) : Eq [a] ~ Eq (S a)
555     instance Monad [] => Monad S        -- by coercion sym (Monad coMkS)  : Monad [] ~ Monad S 
556
557 When type familes are involved it's trickier:
558
559     data family T a b
560     newtype instance T Int a = MkT [a] deriving( Eq, Monad )
561     -- :RT is the representation type for (T Int a)
562     --  :CoF:R1T a :: T Int a ~ :RT a   -- Not eta reduced
563     --  :Co:R1T    :: :RT ~ []          -- Eta-reduced
564
565     instance Eq [a] => Eq (T Int a)     -- easy by coercion
566     instance Monad [] => Monad (T Int)  -- only if we can eta reduce???
567
568 The "???" bit is that we don't build the :CoF thing in eta-reduced form
569 Henc the current typeFamilyPapErr, even though the instance makes sense.
570 After all, we can write it out
571     instance Monad [] => Monad (T Int)  -- only if we can eta reduce???
572       return x = MkT [x]
573       ... etc ...       
574
575 \begin{code}
576 mkEqnHelp :: InstOrigin -> [TyVar] -> Class -> [Type] -> Type
577           -> DerivContext       -- Just    => context supplied (standalone deriving)
578                                 -- Nothing => context inferred (deriving on data decl)
579           -> TcRn EarlyDerivSpec
580 -- Make the EarlyDerivSpec for an instance
581 --      forall tvs. theta => cls (tys ++ [ty])
582 -- where the 'theta' is optional (that's the Maybe part)
583 -- Assumes that this declaration is well-kinded
584
585 mkEqnHelp orig tvs cls cls_tys tc_app mtheta
586   | Just (tycon, tc_args) <- tcSplitTyConApp_maybe tc_app
587   , isAlgTyCon tycon    -- Check for functions, primitive types etc
588   = do  { (rep_tc, rep_tc_args) <- tcLookupFamInstExact tycon tc_args
589                   -- Be careful to test rep_tc here: in the case of families, 
590                   -- we want to check the instance tycon, not the family tycon
591
592         -- For standalone deriving (mtheta /= Nothing), 
593         -- check that all the data constructors are in scope.
594         -- No need for this when deriving Typeable, becuase we don't need
595         -- the constructors for that.
596         ; rdr_env <- getGlobalRdrEnv
597         ; let hidden_data_cons = isAbstractTyCon rep_tc || any not_in_scope (tyConDataCons rep_tc)
598               not_in_scope dc  = null (lookupGRE_Name rdr_env (dataConName dc))
599         ; checkTc (isNothing mtheta || 
600                    not hidden_data_cons ||
601                    className cls `elem` typeableClassNames) 
602                   (derivingHiddenErr tycon)
603
604         ; dflags <- getDOpts
605         ; if isDataTyCon rep_tc then
606                 mkDataTypeEqn orig dflags tvs cls cls_tys
607                               tycon tc_args rep_tc rep_tc_args mtheta
608           else
609                 mkNewTypeEqn orig dflags tvs cls cls_tys 
610                              tycon tc_args rep_tc rep_tc_args mtheta }
611   | otherwise
612   = failWithTc (derivingThingErr False cls cls_tys tc_app
613                (ptext (sLit "The last argument of the instance must be a data or newtype application")))
614 \end{code}
615
616 Note [Looking up family instances for deriving]
617 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
618 tcLookupFamInstExact is an auxiliary lookup wrapper which requires
619 that looked-up family instances exist.  If called with a vanilla
620 tycon, the old type application is simply returned.
621
622 If we have
623   data instance F () = ... deriving Eq
624   data instance F () = ... deriving Eq
625 then tcLookupFamInstExact will be confused by the two matches;
626 but that can't happen because tcInstDecls1 doesn't call tcDeriving
627 if there are any overlaps.
628
629 There are two other things that might go wrong with the lookup.
630 First, we might see a standalone deriving clause
631         deriving Eq (F ())
632 when there is no data instance F () in scope. 
633
634 Note that it's OK to have
635   data instance F [a] = ...
636   deriving Eq (F [(a,b)])
637 where the match is not exact; the same holds for ordinary data types
638 with standalone deriving declrations.
639
640 \begin{code}
641 tcLookupFamInstExact :: TyCon -> [Type] -> TcM (TyCon, [Type])
642 tcLookupFamInstExact tycon tys
643   | not (isOpenTyCon tycon)
644   = return (tycon, tys)
645   | otherwise
646   = do { maybeFamInst <- tcLookupFamInst tycon tys
647        ; case maybeFamInst of
648            Nothing      -> famInstNotFound tycon tys
649            Just famInst -> return famInst
650        }
651
652 famInstNotFound :: TyCon -> [Type] -> TcM a
653 famInstNotFound tycon tys 
654   = failWithTc (ptext (sLit "No family instance for")
655                         <+> quotes (pprTypeApp tycon tys))
656 \end{code}
657
658
659 %************************************************************************
660 %*                                                                      *
661                 Deriving data types
662 %*                                                                      *
663 %************************************************************************
664
665 \begin{code}
666 mkDataTypeEqn :: InstOrigin
667               -> DynFlags
668               -> [Var]                  -- Universally quantified type variables in the instance
669               -> Class                  -- Class for which we need to derive an instance
670               -> [Type]                 -- Other parameters to the class except the last
671               -> TyCon                  -- Type constructor for which the instance is requested 
672                                         --    (last parameter to the type class)
673               -> [Type]                 -- Parameters to the type constructor
674               -> TyCon                  -- rep of the above (for type families)
675               -> [Type]                 -- rep of the above
676               -> DerivContext        -- Context of the instance, for standalone deriving
677               -> TcRn EarlyDerivSpec    -- Return 'Nothing' if error
678
679 mkDataTypeEqn orig dflags tvs cls cls_tys
680               tycon tc_args rep_tc rep_tc_args mtheta
681   = case checkSideConditions dflags mtheta cls cls_tys rep_tc of
682         -- NB: pass the *representation* tycon to checkSideConditions
683         CanDerive               -> go_for_it
684         NonDerivableClass       -> bale_out (nonStdErr cls)
685         DerivableClassError msg -> bale_out msg
686   where
687     go_for_it    = mk_data_eqn orig tvs cls tycon tc_args rep_tc rep_tc_args mtheta
688     bale_out msg = failWithTc (derivingThingErr False cls cls_tys (mkTyConApp tycon tc_args) msg)
689
690 mk_data_eqn, mk_typeable_eqn
691    :: InstOrigin -> [TyVar] -> Class 
692    -> TyCon -> [TcType] -> TyCon -> [TcType] -> DerivContext
693    -> TcM EarlyDerivSpec
694 mk_data_eqn orig tvs cls tycon tc_args rep_tc rep_tc_args mtheta
695   | getName cls `elem` typeableClassNames
696   = mk_typeable_eqn orig tvs cls tycon tc_args rep_tc rep_tc_args mtheta
697
698   | otherwise
699   = do  { dfun_name <- new_dfun_name cls tycon
700         ; loc <- getSrcSpanM
701         ; let inst_tys = [mkTyConApp tycon tc_args]
702               inferred_constraints = inferConstraints tvs cls inst_tys rep_tc rep_tc_args
703               spec = DS { ds_loc = loc, ds_orig = orig
704                         , ds_name = dfun_name, ds_tvs = tvs 
705                         , ds_cls = cls, ds_tys = inst_tys
706                         , ds_tc = rep_tc, ds_tc_args = rep_tc_args
707                         , ds_theta =  mtheta `orElse` inferred_constraints
708                         , ds_newtype = False }
709
710         ; return (if isJust mtheta then Right spec      -- Specified context
711                                    else Left spec) }    -- Infer context
712
713 mk_typeable_eqn orig tvs cls tycon tc_args rep_tc rep_tc_args mtheta
714         -- The Typeable class is special in several ways
715         --        data T a b = ... deriving( Typeable )
716         -- gives
717         --        instance Typeable2 T where ...
718         -- Notice that:
719         -- 1. There are no constraints in the instance
720         -- 2. There are no type variables either
721         -- 3. The actual class we want to generate isn't necessarily
722         --      Typeable; it depends on the arity of the type
723   | isNothing mtheta    -- deriving on a data type decl
724   = do  { checkTc (cls `hasKey` typeableClassKey)
725                   (ptext (sLit "Use deriving( Typeable ) on a data type declaration"))
726         ; real_cls <- tcLookupClass (typeableClassNames !! tyConArity tycon)
727         ; mk_typeable_eqn orig tvs real_cls tycon [] rep_tc [] (Just []) }
728
729   | otherwise           -- standaone deriving
730   = do  { checkTc (null tc_args)
731                   (ptext (sLit "Derived typeable instance must be of form (Typeable") 
732                         <> int (tyConArity tycon) <+> ppr tycon <> rparen)
733         ; dfun_name <- new_dfun_name cls tycon
734         ; loc <- getSrcSpanM
735         ; return (Right $
736                   DS { ds_loc = loc, ds_orig = orig, ds_name = dfun_name, ds_tvs = []
737                      , ds_cls = cls, ds_tys = [mkTyConApp tycon []]
738                      , ds_tc = rep_tc, ds_tc_args = rep_tc_args
739                      , ds_theta = mtheta `orElse` [], ds_newtype = False })  }
740
741
742 inferConstraints :: [TyVar] -> Class -> [TcType] -> TyCon -> [TcType] -> ThetaType
743 -- Generate a sufficiently large set of constraints that typechecking the
744 -- generated method definitions should succeed.   This set will be simplified
745 -- before being used in the instance declaration
746 inferConstraints _ cls inst_tys rep_tc rep_tc_args
747   = ASSERT2( equalLength rep_tc_tvs all_rep_tc_args, ppr cls <+> ppr rep_tc )
748     stupid_constraints ++ extra_constraints
749     ++ sc_constraints ++ con_arg_constraints
750   where
751        -- Constraints arising from the arguments of each constructor
752     con_arg_constraints
753       = [ mkClassPred cls [arg_ty] 
754         | data_con <- tyConDataCons rep_tc,
755           arg_ty   <- ASSERT( isVanillaDataCon data_con )
756                         get_constrained_tys $
757                         dataConInstOrigArgTys data_con all_rep_tc_args,
758           not (isUnLiftedType arg_ty) ]
759                 -- No constraints for unlifted types
760                 -- Where they are legal we generate specilised function calls
761
762                 -- For functor-like classes, two things are different
763                 -- (a) We recurse over argument types to generate constraints
764                 --     See Functor examples in TcGenDeriv
765                 -- (b) The rep_tc_args will be one short
766     is_functor_like = getUnique cls `elem` functorLikeClassKeys
767
768     get_constrained_tys :: [Type] -> [Type]
769     get_constrained_tys tys 
770         | is_functor_like = concatMap (deepSubtypesContaining last_tv) tys
771         | otherwise       = tys
772
773     rep_tc_tvs = tyConTyVars rep_tc
774     last_tv = last rep_tc_tvs
775     all_rep_tc_args | is_functor_like = rep_tc_args ++ [mkTyVarTy last_tv]
776                     | otherwise       = rep_tc_args
777
778         -- Constraints arising from superclasses
779         -- See Note [Superclasses of derived instance]
780     sc_constraints = substTheta (zipOpenTvSubst (classTyVars cls) inst_tys)
781                                 (classSCTheta cls)
782
783         -- Stupid constraints
784     stupid_constraints = substTheta subst (tyConStupidTheta rep_tc)
785     subst = zipTopTvSubst rep_tc_tvs all_rep_tc_args
786               
787         -- Extra Data constraints
788         -- The Data class (only) requires that for 
789         --    instance (...) => Data (T t1 t2) 
790         -- IF   t1:*, t2:*
791         -- THEN (Data t1, Data t2) are among the (...) constraints
792         -- Reason: when the IF holds, we generate a method
793         --             dataCast2 f = gcast2 f
794         --         and we need the Data constraints to typecheck the method
795     extra_constraints 
796       | cls `hasKey` dataClassKey
797       , all (isLiftedTypeKind . typeKind) rep_tc_args 
798       = [mkClassPred cls [ty] | ty <- rep_tc_args]
799       | otherwise 
800       = []
801
802 ------------------------------------------------------------------
803 -- Check side conditions that dis-allow derivability for particular classes
804 -- This is *apart* from the newtype-deriving mechanism
805 --
806 -- Here we get the representation tycon in case of family instances as it has
807 -- the data constructors - but we need to be careful to fall back to the
808 -- family tycon (with indexes) in error messages.
809
810 data DerivStatus = CanDerive
811                  | DerivableClassError SDoc     -- Standard class, but can't do it
812                  | NonDerivableClass            -- Non-standard class
813
814 checkSideConditions :: DynFlags -> DerivContext -> Class -> [TcType] -> TyCon -> DerivStatus
815 checkSideConditions dflags mtheta cls cls_tys rep_tc
816   | Just cond <- sideConditions mtheta cls
817   = case (cond (dflags, rep_tc)) of
818         Just err -> DerivableClassError err     -- Class-specific error
819         Nothing  | null cls_tys -> CanDerive    -- All derivable classes are unary, so
820                                                 -- cls_tys (the type args other than last) 
821                                                 -- should be null
822                  | otherwise    -> DerivableClassError ty_args_why      -- e.g. deriving( Eq s )
823   | otherwise = NonDerivableClass       -- Not a standard class
824   where
825     ty_args_why = quotes (ppr (mkClassPred cls cls_tys)) <+> ptext (sLit "is not a class")
826
827 nonStdErr :: Class -> SDoc
828 nonStdErr cls = quotes (ppr cls) <+> ptext (sLit "is not a derivable class")
829
830 sideConditions :: DerivContext -> Class -> Maybe Condition
831 sideConditions mtheta cls
832   | cls_key == eqClassKey          = Just cond_std
833   | cls_key == ordClassKey         = Just cond_std
834   | cls_key == showClassKey        = Just cond_std
835   | cls_key == readClassKey        = Just (cond_std `andCond` cond_noUnliftedArgs)
836   | cls_key == enumClassKey        = Just (cond_std `andCond` cond_isEnumeration)
837   | cls_key == ixClassKey          = Just (cond_std `andCond` cond_enumOrProduct)
838   | cls_key == boundedClassKey     = Just (cond_std `andCond` cond_enumOrProduct)
839   | cls_key == dataClassKey        = Just (checkFlag Opt_DeriveDataTypeable `andCond` 
840                                            cond_std `andCond` cond_noUnliftedArgs)
841   | cls_key == functorClassKey     = Just (checkFlag Opt_DeriveFunctor `andCond`
842                                            cond_functorOK True)  -- NB: no cond_std!
843   | cls_key == foldableClassKey    = Just (checkFlag Opt_DeriveFoldable `andCond`
844                                            cond_functorOK False) -- Functor/Fold/Trav works ok for rank-n types
845   | cls_key == traversableClassKey = Just (checkFlag Opt_DeriveTraversable `andCond`
846                                            cond_functorOK False)
847   | getName cls `elem` typeableClassNames = Just (checkFlag Opt_DeriveDataTypeable `andCond` cond_typeableOK)
848   | otherwise = Nothing
849   where
850     cls_key = getUnique cls
851     cond_std = cond_stdOK mtheta
852
853 type Condition = (DynFlags, TyCon) -> Maybe SDoc
854         -- first Bool is whether or not we are allowed to derive Data and Typeable
855         -- second Bool is whether or not we are allowed to derive Functor
856         -- TyCon is the *representation* tycon if the 
857         --      data type is an indexed one
858         -- Nothing => OK
859
860 orCond :: Condition -> Condition -> Condition
861 orCond c1 c2 tc 
862   = case c1 tc of
863         Nothing -> Nothing              -- c1 succeeds
864         Just x  -> case c2 tc of        -- c1 fails
865                      Nothing -> Nothing
866                      Just y  -> Just (x $$ ptext (sLit "  and") $$ y)
867                                         -- Both fail
868
869 andCond :: Condition -> Condition -> Condition
870 andCond c1 c2 tc = case c1 tc of
871                      Nothing -> c2 tc   -- c1 succeeds
872                      Just x  -> Just x  -- c1 fails
873
874 cond_stdOK :: DerivContext -> Condition
875 cond_stdOK (Just _) _
876   = Nothing     -- Don't check these conservative conditions for
877                 -- standalone deriving; just generate the code
878 cond_stdOK Nothing (_, rep_tc)
879   | null data_cons      = Just (no_cons_why $$ suggestion)
880   | not (null con_whys) = Just (vcat con_whys $$ suggestion)
881   | otherwise           = Nothing
882   where
883     suggestion  = ptext (sLit "Possible fix: use a standalone deriving declaration instead")
884     data_cons   = tyConDataCons rep_tc
885     no_cons_why = quotes (pprSourceTyCon rep_tc) <+> 
886                   ptext (sLit "has no data constructors")
887
888     con_whys = mapCatMaybes check_con data_cons
889
890     check_con :: DataCon -> Maybe SDoc
891     check_con con 
892       | isVanillaDataCon con
893       , all isTauTy (dataConOrigArgTys con) = Nothing
894       | otherwise = Just (badCon con (ptext (sLit "does not have a Haskell-98 type")))
895   
896 cond_enumOrProduct :: Condition
897 cond_enumOrProduct = cond_isEnumeration `orCond` 
898                        (cond_isProduct `andCond` cond_noUnliftedArgs)
899
900 cond_noUnliftedArgs :: Condition
901 -- For some classes (eg Eq, Ord) we allow unlifted arg types
902 -- by generating specilaised code.  For others (eg Data) we don't.
903 cond_noUnliftedArgs (_, tc)
904   | null bad_cons = Nothing
905   | otherwise     = Just why
906   where
907     bad_cons = [ con | con <- tyConDataCons tc
908                      , any isUnLiftedType (dataConOrigArgTys con) ]
909     why = badCon (head bad_cons) (ptext (sLit "has arguments of unlifted type"))
910
911 cond_isEnumeration :: Condition
912 cond_isEnumeration (_, rep_tc)
913   | isEnumerationTyCon rep_tc = Nothing
914   | otherwise                 = Just why
915   where
916     why = quotes (pprSourceTyCon rep_tc) <+> 
917           ptext (sLit "has non-nullary constructors")
918
919 cond_isProduct :: Condition
920 cond_isProduct (_, rep_tc)
921   | isProductTyCon rep_tc = Nothing
922   | otherwise             = Just why
923   where
924     why = quotes (pprSourceTyCon rep_tc) <+> 
925           ptext (sLit "has more than one constructor")
926
927 cond_typeableOK :: Condition
928 -- OK for Typeable class
929 -- Currently: (a) args all of kind *
930 --            (b) 7 or fewer args
931 cond_typeableOK (_, rep_tc)
932   | tyConArity rep_tc > 7       = Just too_many
933   | not (all (isSubArgTypeKind . tyVarKind) (tyConTyVars rep_tc)) 
934                                 = Just bad_kind
935   | isFamInstTyCon rep_tc       = Just fam_inst  -- no Typable for family insts
936   | otherwise                   = Nothing
937   where
938     too_many = quotes (pprSourceTyCon rep_tc) <+> 
939                ptext (sLit "has too many arguments")
940     bad_kind = quotes (pprSourceTyCon rep_tc) <+> 
941                ptext (sLit "has arguments of kind other than `*'")
942     fam_inst = quotes (pprSourceTyCon rep_tc) <+> 
943                ptext (sLit "is a type family")
944
945
946 functorLikeClassKeys :: [Unique]
947 functorLikeClassKeys = [functorClassKey, foldableClassKey, traversableClassKey]
948
949 cond_functorOK :: Bool -> Condition
950 -- OK for Functor class
951 -- Currently: (a) at least one argument
952 --            (b) don't use argument contravariantly
953 --            (c) don't use argument in the wrong place, e.g. data T a = T (X a a)
954 --            (d) optionally: don't use function types
955 cond_functorOK allowFunctions (dflags, rep_tc) 
956   | not (dopt Opt_DeriveFunctor dflags)
957   = Just (ptext (sLit "You need -XDeriveFunctor to derive an instance for this class"))
958   | otherwise
959   = msum (map check_con data_cons)      -- msum picks the first 'Just', if any
960   where
961     data_cons = tyConDataCons rep_tc
962     check_con con = msum (check_vanilla con : foldDataConArgs (ft_check con) con)
963
964     check_vanilla :: DataCon -> Maybe SDoc
965     check_vanilla con | isVanillaDataCon con = Nothing
966                       | otherwise            = Just (badCon con existential)
967
968     ft_check :: DataCon -> FFoldType (Maybe SDoc)
969     ft_check con = FT { ft_triv = Nothing, ft_var = Nothing
970                       , ft_co_var = Just (badCon con covariant)
971                       , ft_fun = \x y -> if allowFunctions then x `mplus` y 
972                                                            else Just (badCon con functions)
973                       , ft_tup = \_ xs  -> msum xs
974                       , ft_ty_app = \_ x   -> x
975                       , ft_bad_app = Just (badCon con wrong_arg)
976                       , ft_forall = \_ x   -> x }
977                     
978     existential = ptext (sLit "has existential arguments")
979     covariant   = ptext (sLit "uses the type variable in a function argument")
980     functions   = ptext (sLit "contains function types")
981     wrong_arg   = ptext (sLit "uses the type variable in an argument other than the last")
982
983 checkFlag :: DynFlag -> Condition
984 checkFlag flag (dflags, _)
985   | dopt flag dflags = Nothing
986   | otherwise        = Just why
987   where
988     why = ptext (sLit "You need -X") <> text flag_str 
989           <+> ptext (sLit "to derive an instance for this class")
990     flag_str = case [ s | (s, f, _) <- xFlags, f==flag ] of
991                  [s]   -> s
992                  other -> pprPanic "checkFlag" (ppr other)
993
994 std_class_via_iso :: Class -> Bool
995 -- These standard classes can be derived for a newtype
996 -- using the isomorphism trick *even if no -XGeneralizedNewtypeDeriving
997 -- because giving so gives the same results as generating the boilerplate
998 std_class_via_iso clas  
999   = classKey clas `elem` [eqClassKey, ordClassKey, ixClassKey, boundedClassKey]
1000         -- Not Read/Show because they respect the type
1001         -- Not Enum, because newtypes are never in Enum
1002
1003
1004 non_iso_class :: Class -> Bool
1005 -- *Never* derive Read,Show,Typeable,Data by isomorphism,
1006 -- even with -XGeneralizedNewtypeDeriving
1007 non_iso_class cls 
1008   = classKey cls `elem` ([readClassKey, showClassKey, dataClassKey] ++
1009                          typeableClassKeys)
1010
1011 typeableClassKeys :: [Unique]
1012 typeableClassKeys = map getUnique typeableClassNames
1013
1014 new_dfun_name :: Class -> TyCon -> TcM Name
1015 new_dfun_name clas tycon        -- Just a simple wrapper
1016   = do { loc <- getSrcSpanM     -- The location of the instance decl, not of the tycon
1017         ; newDFunName clas [mkTyConApp tycon []] loc }
1018         -- The type passed to newDFunName is only used to generate
1019         -- a suitable string; hence the empty type arg list
1020
1021 badCon :: DataCon -> SDoc -> SDoc
1022 badCon con msg = ptext (sLit "Constructor") <+> quotes (ppr con) <+> msg
1023 \end{code}
1024
1025 Note [Superclasses of derived instance] 
1026 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1027 In general, a derived instance decl needs the superclasses of the derived
1028 class too.  So if we have
1029         data T a = ...deriving( Ord )
1030 then the initial context for Ord (T a) should include Eq (T a).  Often this is 
1031 redundant; we'll also generate an Ord constraint for each constructor argument,
1032 and that will probably generate enough constraints to make the Eq (T a) constraint 
1033 be satisfied too.  But not always; consider:
1034
1035  data S a = S
1036  instance Eq (S a)
1037  instance Ord (S a)
1038
1039  data T a = MkT (S a) deriving( Ord )
1040  instance Num a => Eq (T a)
1041
1042 The derived instance for (Ord (T a)) must have a (Num a) constraint!
1043 Similarly consider:
1044         data T a = MkT deriving( Data, Typeable )
1045 Here there *is* no argument field, but we must nevertheless generate
1046 a context for the Data instances:
1047         instance Typable a => Data (T a) where ...
1048
1049
1050 %************************************************************************
1051 %*                                                                      *
1052                 Deriving newtypes
1053 %*                                                                      *
1054 %************************************************************************
1055
1056 \begin{code}
1057 mkNewTypeEqn :: InstOrigin -> DynFlags -> [Var] -> Class
1058              -> [Type] -> TyCon -> [Type] -> TyCon -> [Type]
1059              -> DerivContext
1060              -> TcRn EarlyDerivSpec
1061 mkNewTypeEqn orig dflags tvs
1062              cls cls_tys tycon tc_args rep_tycon rep_tc_args mtheta
1063 -- Want: instance (...) => cls (cls_tys ++ [tycon tc_args]) where ...
1064   | can_derive_via_isomorphism && (newtype_deriving || std_class_via_iso cls)
1065   = do  { traceTc (text "newtype deriving:" <+> ppr tycon <+> ppr rep_tys)
1066         ; dfun_name <- new_dfun_name cls tycon
1067         ; loc <- getSrcSpanM
1068         ; let spec = DS { ds_loc = loc, ds_orig = orig
1069                         , ds_name = dfun_name, ds_tvs = varSetElems dfun_tvs 
1070                         , ds_cls = cls, ds_tys = inst_tys
1071                         , ds_tc = rep_tycon, ds_tc_args = rep_tc_args
1072                         , ds_theta =  mtheta `orElse` all_preds
1073                         , ds_newtype = True }
1074         ; return (if isJust mtheta then Right spec
1075                                    else Left spec) }
1076
1077   | otherwise
1078   = case checkSideConditions dflags mtheta cls cls_tys rep_tycon of
1079       CanDerive -> go_for_it    -- Use the standard H98 method
1080       DerivableClassError msg   -- Error with standard class
1081         | can_derive_via_isomorphism -> bale_out (msg $$ suggest_nd)
1082         | otherwise                  -> bale_out msg
1083       NonDerivableClass         -- Must use newtype deriving
1084         | newtype_deriving           -> bale_out cant_derive_err  -- Too hard, even with newtype deriving
1085         | can_derive_via_isomorphism -> bale_out (non_std $$ suggest_nd) -- Try newtype deriving!
1086         | otherwise                  -> bale_out non_std
1087   where
1088         newtype_deriving = dopt Opt_GeneralizedNewtypeDeriving dflags
1089         go_for_it        = mk_data_eqn orig tvs cls tycon tc_args rep_tycon rep_tc_args mtheta
1090         bale_out msg     = failWithTc (derivingThingErr newtype_deriving cls cls_tys inst_ty msg)
1091
1092         non_std    = nonStdErr cls
1093         suggest_nd = ptext (sLit "Try -XGeneralizedNewtypeDeriving for GHC's newtype-deriving extension")
1094
1095         -- Here is the plan for newtype derivings.  We see
1096         --        newtype T a1...an = MkT (t ak+1...an) deriving (.., C s1 .. sm, ...)
1097         -- where t is a type,
1098         --       ak+1...an is a suffix of a1..an, and are all tyars
1099         --       ak+1...an do not occur free in t, nor in the s1..sm
1100         --       (C s1 ... sm) is a  *partial applications* of class C 
1101         --                      with the last parameter missing
1102         --       (T a1 .. ak) matches the kind of C's last argument
1103         --              (and hence so does t)
1104         -- The latter kind-check has been done by deriveTyData already,
1105         -- and tc_args are already trimmed
1106         --
1107         -- We generate the instance
1108         --       instance forall ({a1..ak} u fvs(s1..sm)).
1109         --                C s1 .. sm t => C s1 .. sm (T a1...ak)
1110         -- where T a1...ap is the partial application of 
1111         --       the LHS of the correct kind and p >= k
1112         --
1113         --      NB: the variables below are:
1114         --              tc_tvs = [a1, ..., an]
1115         --              tyvars_to_keep = [a1, ..., ak]
1116         --              rep_ty = t ak .. an
1117         --              deriv_tvs = fvs(s1..sm) \ tc_tvs
1118         --              tys = [s1, ..., sm]
1119         --              rep_fn' = t
1120         --
1121         -- Running example: newtype T s a = MkT (ST s a) deriving( Monad )
1122         -- We generate the instance
1123         --      instance Monad (ST s) => Monad (T s) where 
1124
1125         nt_eta_arity = length (fst (newTyConEtadRhs rep_tycon))
1126                 -- For newtype T a b = MkT (S a a b), the TyCon machinery already
1127                 -- eta-reduces the representation type, so we know that
1128                 --      T a ~ S a a
1129                 -- That's convenient here, because we may have to apply
1130                 -- it to fewer than its original complement of arguments
1131
1132         -- Note [Newtype representation]
1133         -- ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1134         -- Need newTyConRhs (*not* a recursive representation finder) 
1135         -- to get the representation type. For example
1136         --      newtype B = MkB Int
1137         --      newtype A = MkA B deriving( Num )
1138         -- We want the Num instance of B, *not* the Num instance of Int,
1139         -- when making the Num instance of A!
1140         rep_inst_ty = newTyConInstRhs rep_tycon rep_tc_args
1141         rep_tys     = cls_tys ++ [rep_inst_ty]
1142         rep_pred    = mkClassPred cls rep_tys
1143                 -- rep_pred is the representation dictionary, from where
1144                 -- we are gong to get all the methods for the newtype
1145                 -- dictionary 
1146
1147
1148     -- Next we figure out what superclass dictionaries to use
1149     -- See Note [Newtype deriving superclasses] above
1150
1151         cls_tyvars = classTyVars cls
1152         dfun_tvs = tyVarsOfTypes inst_tys
1153         inst_ty = mkTyConApp tycon tc_args
1154         inst_tys = cls_tys ++ [inst_ty]
1155         sc_theta = substTheta (zipOpenTvSubst cls_tyvars inst_tys)
1156                               (classSCTheta cls)
1157
1158                 -- If there are no tyvars, there's no need
1159                 -- to abstract over the dictionaries we need
1160                 -- Example:     newtype T = MkT Int deriving( C )
1161                 -- We get the derived instance
1162                 --              instance C T
1163                 -- rather than
1164                 --              instance C Int => C T
1165         all_preds = rep_pred : sc_theta         -- NB: rep_pred comes first
1166
1167         -------------------------------------------------------------------
1168         --  Figuring out whether we can only do this newtype-deriving thing
1169
1170         can_derive_via_isomorphism
1171            =  not (non_iso_class cls)
1172            && arity_ok
1173            && eta_ok
1174            && ats_ok
1175 --         && not (isRecursiveTyCon tycon)      -- Note [Recursive newtypes]
1176
1177         arity_ok = length cls_tys + 1 == classArity cls
1178                 -- Well kinded; eg not: newtype T ... deriving( ST )
1179                 --                      because ST needs *2* type params
1180
1181         -- Check that eta reduction is OK
1182         eta_ok = nt_eta_arity <= length rep_tc_args
1183                 -- The newtype can be eta-reduced to match the number
1184                 --     of type argument actually supplied
1185                 --        newtype T a b = MkT (S [a] b) deriving( Monad )
1186                 --     Here the 'b' must be the same in the rep type (S [a] b)
1187                 --     And the [a] must not mention 'b'.  That's all handled
1188                 --     by nt_eta_rity.
1189
1190         ats_ok = null (classATs cls)    
1191                -- No associated types for the class, because we don't 
1192                -- currently generate type 'instance' decls; and cannot do
1193                -- so for 'data' instance decls
1194                                          
1195         cant_derive_err
1196            = vcat [ ppUnless arity_ok arity_msg
1197                   , ppUnless eta_ok eta_msg
1198                   , ppUnless ats_ok ats_msg ]
1199         arity_msg = quotes (ppr (mkClassPred cls cls_tys)) <+> ptext (sLit "does not have arity 1")
1200         eta_msg   = ptext (sLit "cannot eta-reduce the representation type enough")
1201         ats_msg   = ptext (sLit "the class has associated types")
1202 \end{code}
1203
1204 Note [Recursive newtypes]
1205 ~~~~~~~~~~~~~~~~~~~~~~~~~
1206 Newtype deriving works fine, even if the newtype is recursive.
1207 e.g.    newtype S1 = S1 [T1 ()]
1208         newtype T1 a = T1 (StateT S1 IO a ) deriving( Monad )
1209 Remember, too, that type families are curretly (conservatively) given
1210 a recursive flag, so this also allows newtype deriving to work
1211 for type famillies.
1212
1213 We used to exclude recursive types, because we had a rather simple
1214 minded way of generating the instance decl:
1215    newtype A = MkA [A]
1216    instance Eq [A] => Eq A      -- Makes typechecker loop!
1217 But now we require a simple context, so it's ok.
1218
1219
1220 %************************************************************************
1221 %*                                                                      *
1222 \subsection[TcDeriv-fixpoint]{Finding the fixed point of \tr{deriving} equations}
1223 %*                                                                      *
1224 %************************************************************************
1225
1226 A ``solution'' (to one of the equations) is a list of (k,TyVarTy tv)
1227 terms, which is the final correct RHS for the corresponding original
1228 equation.
1229 \begin{itemize}
1230 \item
1231 Each (k,TyVarTy tv) in a solution constrains only a type
1232 variable, tv.
1233
1234 \item
1235 The (k,TyVarTy tv) pairs in a solution are canonically
1236 ordered by sorting on type varible, tv, (major key) and then class, k,
1237 (minor key)
1238 \end{itemize}
1239
1240 \begin{code}
1241 inferInstanceContexts :: OverlapFlag -> [DerivSpec] -> TcM [DerivSpec]
1242
1243 inferInstanceContexts _ [] = return []
1244
1245 inferInstanceContexts oflag infer_specs
1246   = do  { traceTc (text "inferInstanceContexts" <+> vcat (map pprDerivSpec infer_specs))
1247         ; iterate_deriv 1 initial_solutions }
1248   where
1249     ------------------------------------------------------------------
1250         -- The initial solutions for the equations claim that each
1251         -- instance has an empty context; this solution is certainly
1252         -- in canonical form.
1253     initial_solutions :: [ThetaType]
1254     initial_solutions = [ [] | _ <- infer_specs ]
1255
1256     ------------------------------------------------------------------
1257         -- iterate_deriv calculates the next batch of solutions,
1258         -- compares it with the current one; finishes if they are the
1259         -- same, otherwise recurses with the new solutions.
1260         -- It fails if any iteration fails
1261     iterate_deriv :: Int -> [ThetaType] -> TcM [DerivSpec]
1262     iterate_deriv n current_solns
1263       | n > 20  -- Looks as if we are in an infinite loop
1264                 -- This can happen if we have -XUndecidableInstances
1265                 -- (See TcSimplify.tcSimplifyDeriv.)
1266       = pprPanic "solveDerivEqns: probable loop" 
1267                  (vcat (map pprDerivSpec infer_specs) $$ ppr current_solns)
1268       | otherwise
1269       = do {      -- Extend the inst info from the explicit instance decls
1270                   -- with the current set of solutions, and simplify each RHS
1271              let inst_specs = zipWithEqual "add_solns" (mkInstance oflag)
1272                                            current_solns infer_specs
1273            ; new_solns <- checkNoErrs $
1274                           extendLocalInstEnv inst_specs $
1275                           mapM gen_soln infer_specs
1276
1277            ; if (current_solns == new_solns) then
1278                 return [ spec { ds_theta = soln } 
1279                        | (spec, soln) <- zip infer_specs current_solns ]
1280              else
1281                 iterate_deriv (n+1) new_solns }
1282
1283     ------------------------------------------------------------------
1284     gen_soln :: DerivSpec  -> TcM [PredType]
1285     gen_soln (DS { ds_loc = loc, ds_orig = orig, ds_tvs = tyvars 
1286                  , ds_cls = clas, ds_tys = inst_tys, ds_theta = deriv_rhs })
1287       = setSrcSpan loc  $
1288         addErrCtxt (derivInstCtxt clas inst_tys) $ 
1289         do { theta <- tcSimplifyDeriv orig tyvars deriv_rhs
1290                 -- checkValidInstance tyvars theta clas inst_tys
1291                 -- Not necessary; see Note [Exotic derived instance contexts]
1292                 --                in TcSimplify
1293
1294                   -- Check for a bizarre corner case, when the derived instance decl should
1295                   -- have form  instance C a b => D (T a) where ...
1296                   -- Note that 'b' isn't a parameter of T.  This gives rise to all sorts
1297                   -- of problems; in particular, it's hard to compare solutions for
1298                   -- equality when finding the fixpoint.  So I just rule it out for now.
1299            ; let tv_set = mkVarSet tyvars
1300                  weird_preds = [pred | pred <- theta, not (tyVarsOfPred pred `subVarSet` tv_set)]  
1301            ; mapM_ (addErrTc . badDerivedPred) weird_preds      
1302
1303            ; traceTc (text "TcDeriv" <+> (ppr deriv_rhs $$ ppr theta))
1304                 -- Claim: the result instance declaration is guaranteed valid
1305                 -- Hence no need to call:
1306                 --   checkValidInstance tyvars theta clas inst_tys
1307            ; return (sortLe (<=) theta) }       -- Canonicalise before returning the solution
1308
1309 ------------------------------------------------------------------
1310 mkInstance :: OverlapFlag -> ThetaType -> DerivSpec -> Instance
1311 mkInstance overlap_flag theta
1312             (DS { ds_name = dfun_name
1313                 , ds_tvs = tyvars, ds_cls = clas, ds_tys = tys })
1314   = mkLocalInstance dfun overlap_flag
1315   where
1316     dfun = mkDictFunId dfun_name tyvars theta clas tys
1317
1318
1319 extendLocalInstEnv :: [Instance] -> TcM a -> TcM a
1320 -- Add new locally-defined instances; don't bother to check
1321 -- for functional dependency errors -- that'll happen in TcInstDcls
1322 extendLocalInstEnv dfuns thing_inside
1323  = do { env <- getGblEnv
1324       ; let  inst_env' = extendInstEnvList (tcg_inst_env env) dfuns 
1325              env'      = env { tcg_inst_env = inst_env' }
1326       ; setGblEnv env' thing_inside }
1327 \end{code}
1328
1329
1330 %************************************************************************
1331 %*                                                                      *
1332 \subsection[TcDeriv-normal-binds]{Bindings for the various classes}
1333 %*                                                                      *
1334 %************************************************************************
1335
1336 After all the trouble to figure out the required context for the
1337 derived instance declarations, all that's left is to chug along to
1338 produce them.  They will then be shoved into @tcInstDecls2@, which
1339 will do all its usual business.
1340
1341 There are lots of possibilities for code to generate.  Here are
1342 various general remarks.
1343
1344 PRINCIPLES:
1345 \begin{itemize}
1346 \item
1347 We want derived instances of @Eq@ and @Ord@ (both v common) to be
1348 ``you-couldn't-do-better-by-hand'' efficient.
1349
1350 \item
1351 Deriving @Show@---also pretty common--- should also be reasonable good code.
1352
1353 \item
1354 Deriving for the other classes isn't that common or that big a deal.
1355 \end{itemize}
1356
1357 PRAGMATICS:
1358
1359 \begin{itemize}
1360 \item
1361 Deriving @Ord@ is done mostly with the 1.3 @compare@ method.
1362
1363 \item
1364 Deriving @Eq@ also uses @compare@, if we're deriving @Ord@, too.
1365
1366 \item
1367 We {\em normally} generate code only for the non-defaulted methods;
1368 there are some exceptions for @Eq@ and (especially) @Ord@...
1369
1370 \item
1371 Sometimes we use a @_con2tag_<tycon>@ function, which returns a data
1372 constructor's numeric (@Int#@) tag.  These are generated by
1373 @gen_tag_n_con_binds@, and the heuristic for deciding if one of
1374 these is around is given by @hasCon2TagFun@.
1375
1376 The examples under the different sections below will make this
1377 clearer.
1378
1379 \item
1380 Much less often (really just for deriving @Ix@), we use a
1381 @_tag2con_<tycon>@ function.  See the examples.
1382
1383 \item
1384 We use the renamer!!!  Reason: we're supposed to be
1385 producing @LHsBinds Name@ for the methods, but that means
1386 producing correctly-uniquified code on the fly.  This is entirely
1387 possible (the @TcM@ monad has a @UniqueSupply@), but it is painful.
1388 So, instead, we produce @MonoBinds RdrName@ then heave 'em through
1389 the renamer.  What a great hack!
1390 \end{itemize}
1391
1392 \begin{code}
1393 -- Generate the InstInfo for the required instance paired with the
1394 --   *representation* tycon for that instance,
1395 -- plus any auxiliary bindings required
1396 --
1397 -- Representation tycons differ from the tycon in the instance signature in
1398 -- case of instances for indexed families.
1399 --
1400 genInst :: Bool         -- True <=> standalone deriving
1401         -> OverlapFlag
1402         -> DerivSpec -> TcM (InstInfo RdrName, DerivAuxBinds)
1403 genInst standalone_deriv oflag spec
1404   | ds_newtype spec
1405   = return (InstInfo { iSpec  = mkInstance oflag (ds_theta spec) spec
1406                      , iBinds = NewTypeDerived co rep_tycon }, [])
1407
1408   | otherwise
1409   = do  { let loc  = getSrcSpan (ds_name spec)
1410               inst = mkInstance oflag (ds_theta spec) spec
1411               clas = ds_cls spec
1412
1413           -- In case of a family instance, we need to use the representation
1414           -- tycon (after all, it has the data constructors)
1415         ; fix_env <- getFixityEnv
1416         ; let (meth_binds, aux_binds) = genDerivBinds loc fix_env clas rep_tycon
1417               binds = VanillaInst meth_binds [] standalone_deriv
1418         ; return (InstInfo { iSpec = inst, iBinds = binds }, aux_binds)
1419         }
1420   where
1421     rep_tycon   = ds_tc spec
1422     rep_tc_args = ds_tc_args spec
1423     co1 = case tyConFamilyCoercion_maybe rep_tycon of
1424               Nothing     -> IdCo
1425               Just co_con -> ACo (mkTyConApp co_con rep_tc_args)
1426     co2 = case newTyConCo_maybe rep_tycon of
1427               Nothing     -> IdCo       -- The newtype is transparent; no need for a cast
1428               Just co_con -> ACo (mkTyConApp co_con rep_tc_args)
1429     co = co1 `mkTransCoI` co2
1430
1431 -- Example: newtype instance N [a] = N1 (Tree a) 
1432 --          deriving instance Eq b => Eq (N [(b,b)])
1433 -- From the instance, we get an implicit newtype R1:N a = N1 (Tree a)
1434 -- When dealing with the deriving clause
1435 --    co1 : N [(b,b)] ~ R1:N (b,b)
1436 --    co2 : R1:N (b,b) ~ Tree (b,b)
1437 --    co  : N [(b,b)] ~ Tree (b,b)
1438
1439 genDerivBinds :: SrcSpan -> FixityEnv -> Class -> TyCon -> (LHsBinds RdrName, DerivAuxBinds)
1440 genDerivBinds loc fix_env clas tycon
1441   | className clas `elem` typeableClassNames
1442   = (gen_Typeable_binds loc tycon, [])
1443
1444   | otherwise
1445   = case assocMaybe gen_list (getUnique clas) of
1446         Just gen_fn -> gen_fn loc tycon
1447         Nothing     -> pprPanic "genDerivBinds: bad derived class" (ppr clas)
1448   where
1449     gen_list :: [(Unique, SrcSpan -> TyCon -> (LHsBinds RdrName, DerivAuxBinds))]
1450     gen_list = [(eqClassKey,       gen_Eq_binds)
1451                ,(ordClassKey,      gen_Ord_binds)
1452                ,(enumClassKey,     gen_Enum_binds)
1453                ,(boundedClassKey,  gen_Bounded_binds)
1454                ,(ixClassKey,       gen_Ix_binds)
1455                ,(showClassKey,     gen_Show_binds fix_env)
1456                ,(readClassKey,     gen_Read_binds fix_env)
1457                ,(dataClassKey,     gen_Data_binds)
1458                ,(functorClassKey,  gen_Functor_binds)
1459                ,(foldableClassKey, gen_Foldable_binds)
1460                ,(traversableClassKey, gen_Traversable_binds)
1461                ]
1462 \end{code}
1463
1464
1465 %************************************************************************
1466 %*                                                                      *
1467 \subsection[TcDeriv-taggery-Names]{What con2tag/tag2con functions are available?}
1468 %*                                                                      *
1469 %************************************************************************
1470
1471 \begin{code}
1472 derivingKindErr :: TyCon -> Class -> [Type] -> Kind -> Message
1473 derivingKindErr tc cls cls_tys cls_kind
1474   = hang (ptext (sLit "Cannot derive well-kinded instance of form")
1475                 <+> quotes (pprClassPred cls cls_tys <+> parens (ppr tc <+> ptext (sLit "..."))))
1476        2 (ptext (sLit "Class") <+> quotes (ppr cls)
1477             <+> ptext (sLit "expects an argument of kind") <+> quotes (pprKind cls_kind))
1478
1479 derivingEtaErr :: Class -> [Type] -> Type -> Message
1480 derivingEtaErr cls cls_tys inst_ty
1481   = sep [ptext (sLit "Cannot eta-reduce to an instance of form"),
1482          nest 2 (ptext (sLit "instance (...) =>")
1483                 <+> pprClassPred cls (cls_tys ++ [inst_ty]))]
1484
1485 typeFamilyPapErr :: TyCon -> Class -> [Type] -> Type -> Message
1486 typeFamilyPapErr tc cls cls_tys inst_ty
1487   = hang (ptext (sLit "Derived instance") <+> quotes (pprClassPred cls (cls_tys ++ [inst_ty])))
1488        2 (ptext (sLit "requires illegal partial application of data type family") <+> ppr tc) 
1489
1490 derivingThingErr :: Bool -> Class -> [Type] -> Type -> Message -> Message
1491 derivingThingErr newtype_deriving clas tys ty why
1492   = sep [(hang (ptext (sLit "Can't make a derived instance of"))
1493              2 (quotes (ppr pred)) 
1494           $$ nest 2 extra) <> colon,
1495          nest 2 why]
1496   where
1497     extra | newtype_deriving = ptext (sLit "(even with cunning newtype deriving)")
1498           | otherwise        = empty
1499     pred = mkClassPred clas (tys ++ [ty])
1500
1501 derivingHiddenErr :: TyCon -> SDoc
1502 derivingHiddenErr tc
1503   = hang (ptext (sLit "The data constructors of") <+> quotes (ppr tc) <+> ptext (sLit "are not all in scope"))
1504        2 (ptext (sLit "so you cannot derive an instance for it"))
1505
1506 standaloneCtxt :: LHsType Name -> SDoc
1507 standaloneCtxt ty = hang (ptext (sLit "In the stand-alone deriving instance for")) 
1508                        2 (quotes (ppr ty))
1509
1510 derivInstCtxt :: Class -> [Type] -> Message
1511 derivInstCtxt clas inst_tys
1512   = ptext (sLit "When deriving the instance for") <+> parens (pprClassPred clas inst_tys)
1513
1514 badDerivedPred :: PredType -> Message
1515 badDerivedPred pred
1516   = vcat [ptext (sLit "Can't derive instances where the instance context mentions"),
1517           ptext (sLit "type variables that are not data type parameters"),
1518           nest 2 (ptext (sLit "Offending constraint:") <+> ppr pred)]
1519 \end{code}