cf95f03673eb37c1a3f7a4754b1a0ec582017480
[ghc.git] / compiler / typecheck / TcPat.lhs
1 %
2 % (c) The University of Glasgow 2006
3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
4 %
5
6 TcPat: Typechecking patterns
7
8 \begin{code}
9 {-# LANGUAGE CPP, RankNTypes #-}
10 {-# OPTIONS_GHC -fno-warn-tabs #-}
11 -- The above warning supression flag is a temporary kludge.
12 -- While working on this module you are encouraged to remove it and
13 -- detab the module (please do the detabbing in a separate patch). See
14 --     http://ghc.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#TabsvsSpaces
15 -- for details
16
17 module TcPat ( tcLetPat, TcSigFun, TcPragFun
18              , TcSigInfo(..), findScopedTyVars
19              , LetBndrSpec(..), addInlinePrags, warnPrags
20              , tcPat, tcPats, newNoSigLetBndr
21              , addDataConStupidTheta, badFieldCon, polyPatSig ) where
22
23 #include "HsVersions.h"
24
25 import {-# SOURCE #-}   TcExpr( tcSyntaxOp, tcInferRho)
26
27 import HsSyn
28 import TcHsSyn
29 import TcRnMonad
30 import Inst
31 import Id
32 import Var
33 import Name
34 import NameSet
35 import TcEnv
36 --import TcExpr
37 import TcMType
38 import TcValidity( arityErr )
39 import TcType
40 import TcUnify
41 import TcHsType
42 import TysWiredIn
43 import TcEvidence
44 import TyCon
45 import DataCon
46 import PatSyn
47 import ConLike
48 import PrelNames
49 import BasicTypes hiding (SuccessFlag(..))
50 import DynFlags
51 import SrcLoc
52 import Util
53 import Outputable
54 import FastString
55 import Control.Monad
56 \end{code}
57
58
59 %************************************************************************
60 %*                                                                      *
61                 External interface
62 %*                                                                      *
63 %************************************************************************
64
65 \begin{code}
66 tcLetPat :: TcSigFun -> LetBndrSpec
67          -> LPat Name -> TcSigmaType 
68          -> TcM a
69          -> TcM (LPat TcId, a)
70 tcLetPat sig_fn no_gen pat pat_ty thing_inside
71   = tc_lpat pat pat_ty penv thing_inside 
72   where
73     penv = PE { pe_lazy = True
74               , pe_ctxt = LetPat sig_fn no_gen }
75
76 -----------------
77 tcPats :: HsMatchContext Name
78        -> [LPat Name]            -- Patterns,
79        -> [TcSigmaType]          --   and their types
80        -> TcM a                  --   and the checker for the body
81        -> TcM ([LPat TcId], a)
82
83 -- This is the externally-callable wrapper function
84 -- Typecheck the patterns, extend the environment to bind the variables,
85 -- do the thing inside, use any existentially-bound dictionaries to 
86 -- discharge parts of the returning LIE, and deal with pattern type
87 -- signatures
88
89 --   1. Initialise the PatState
90 --   2. Check the patterns
91 --   3. Check the body
92 --   4. Check that no existentials escape
93
94 tcPats ctxt pats pat_tys thing_inside
95   = tc_lpats penv pats pat_tys thing_inside
96   where
97     penv = PE { pe_lazy = False, pe_ctxt = LamPat ctxt }
98
99 tcPat :: HsMatchContext Name
100       -> LPat Name -> TcSigmaType 
101       -> TcM a                 -- Checker for body, given
102                                -- its result type
103       -> TcM (LPat TcId, a)
104 tcPat ctxt pat pat_ty thing_inside
105   = tc_lpat pat pat_ty penv thing_inside
106   where
107     penv = PE { pe_lazy = False, pe_ctxt = LamPat ctxt }
108    
109
110 -----------------
111 data PatEnv
112   = PE { pe_lazy :: Bool        -- True <=> lazy context, so no existentials allowed
113        , pe_ctxt :: PatCtxt     -- Context in which the whole pattern appears
114        }
115
116 data PatCtxt
117   = LamPat   -- Used for lambdas, case etc
118        (HsMatchContext Name) 
119
120   | LetPat   -- Used only for let(rec) pattern bindings
121              -- See Note [Typing patterns in pattern bindings]
122        TcSigFun        -- Tells type sig if any
123        LetBndrSpec     -- True <=> no generalisation of this let
124
125 data LetBndrSpec 
126   = LetLclBndr            -- The binder is just a local one;
127                           -- an AbsBinds will provide the global version
128
129   | LetGblBndr TcPragFun  -- Genrealisation plan is NoGen, so there isn't going 
130                           -- to be an AbsBinds; So we must bind the global version
131                           -- of the binder right away.  
132                           -- Oh, and dhhere is the inline-pragma information
133
134 makeLazy :: PatEnv -> PatEnv
135 makeLazy penv = penv { pe_lazy = True }
136
137 patSigCtxt :: PatEnv -> UserTypeCtxt
138 patSigCtxt (PE { pe_ctxt = LetPat {} }) = BindPatSigCtxt
139 patSigCtxt (PE { pe_ctxt = LamPat {} }) = LamPatSigCtxt
140
141 ---------------
142 type TcPragFun = Name -> [LSig Name]
143 type TcSigFun  = Name -> Maybe TcSigInfo
144
145 data TcSigInfo
146   = TcSigInfo {
147         sig_id     :: TcId,         --  *Polymorphic* binder for this value...
148
149         sig_tvs    :: [(Maybe Name, TcTyVar)],    
150                            -- Instantiated type and kind variables
151                            -- Just n <=> this skolem is lexically in scope with name n
152                            -- See Note [Binding scoped type variables]
153
154         sig_theta  :: TcThetaType,  -- Instantiated theta
155
156         sig_tau    :: TcSigmaType,  -- Instantiated tau
157                                     -- See Note [sig_tau may be polymorphic]
158
159         sig_loc    :: SrcSpan       -- The location of the signature
160     }
161
162 findScopedTyVars  -- See Note [Binding scoped type variables]
163   :: LHsType Name             -- The HsType
164   -> TcType                   -- The corresponding Type:
165                               --   uses same Names as the HsType
166   -> [TcTyVar]                -- The instantiated forall variables of the Type
167   -> [(Maybe Name, TcTyVar)]  -- In 1-1 correspondence with the instantiated vars
168 findScopedTyVars hs_ty sig_ty inst_tvs
169   = zipWith find sig_tvs inst_tvs
170   where
171     find sig_tv inst_tv
172       | tv_name `elemNameSet` scoped_names = (Just tv_name, inst_tv)
173       | otherwise                          = (Nothing,      inst_tv)
174       where
175         tv_name = tyVarName sig_tv
176
177     scoped_names = mkNameSet (hsExplicitTvs hs_ty)
178     (sig_tvs,_)  = tcSplitForAllTys sig_ty
179
180 instance Outputable TcSigInfo where
181     ppr (TcSigInfo { sig_id = id, sig_tvs = tyvars, sig_theta = theta, sig_tau = tau})
182         = ppr id <+> dcolon <+> vcat [ pprSigmaType (mkSigmaTy (map snd tyvars) theta tau)
183                                      , ppr (map fst tyvars) ]
184 \end{code}
185
186 Note [Binding scoped type variables]
187 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
188 The type variables *brought into lexical scope* by a type signature may
189 be a subset of the *quantified type variables* of the signatures, for two reasons:
190
191 * With kind polymorphism a signature like
192     f :: forall f a. f a -> f a
193   may actuallly give rise to
194     f :: forall k. forall (f::k -> *) (a:k). f a -> f a
195   So the sig_tvs will be [k,f,a], but only f,a are scoped.
196   NB: the scoped ones are not necessarily the *inital* ones!
197
198 * Even aside from kind polymorphism, tere may be more instantiated
199   type variables than lexically-scoped ones.  For example:
200         type T a = forall b. b -> (a,b)
201         f :: forall c. T c
202   Here, the signature for f will have one scoped type variable, c,
203   but two instantiated type variables, c' and b'.
204
205 The function findScopedTyVars takes
206   * hs_ty:    the original HsForAllTy
207   * sig_ty:   the corresponding Type (which is guaranteed to use the same Names
208               as the HsForAllTy)
209   * inst_tvs: the skolems instantiated from the forall's in sig_ty
210 It returns a [(Maybe Name, TcTyVar)], in 1-1 correspondence with inst_tvs
211 but with a (Just n) for the lexically scoped name of each in-scope tyvar.
212
213 Note [sig_tau may be polymorphic]
214 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
215 Note that "sig_tau" might actually be a polymorphic type,
216 if the original function had a signature like
217    forall a. Eq a => forall b. Ord b => ....
218 But that's ok: tcMatchesFun (called by tcRhs) can deal with that
219 It happens, too!  See Note [Polymorphic methods] in TcClassDcl.
220
221 Note [Existential check]
222 ~~~~~~~~~~~~~~~~~~~~~~~~
223 Lazy patterns can't bind existentials.  They arise in two ways:
224   * Let bindings      let { C a b = e } in b
225   * Twiddle patterns  f ~(C a b) = e
226 The pe_lazy field of PatEnv says whether we are inside a lazy
227 pattern (perhaps deeply)
228
229 If we aren't inside a lazy pattern then we can bind existentials,
230 but we need to be careful about "extra" tyvars. Consider
231     (\C x -> d) : pat_ty -> res_ty
232 When looking for existential escape we must check that the existential
233 bound by C don't unify with the free variables of pat_ty, OR res_ty
234 (or of course the environment).   Hence we need to keep track of the 
235 res_ty free vars.
236
237
238 %************************************************************************
239 %*                                                                      *
240                 Binders
241 %*                                                                      *
242 %************************************************************************
243
244 \begin{code}
245 tcPatBndr :: PatEnv -> Name -> TcSigmaType -> TcM (TcCoercion, TcId)
246 -- (coi, xp) = tcPatBndr penv x pat_ty
247 -- Then coi : pat_ty ~ typeof(xp)
248 --
249 tcPatBndr (PE { pe_ctxt = LetPat lookup_sig no_gen}) bndr_name pat_ty
250           -- See Note [Typing patterns in pattern bindings]
251   | LetGblBndr prags <- no_gen
252   , Just sig <- lookup_sig bndr_name
253   = do { bndr_id <- addInlinePrags (sig_id sig) (prags bndr_name)
254        ; traceTc "tcPatBndr(gbl,sig)" (ppr bndr_id $$ ppr (idType bndr_id)) 
255        ; co <- unifyPatType (idType bndr_id) pat_ty
256        ; return (co, bndr_id) }
257       
258   | otherwise 
259   = do { bndr_id <- newNoSigLetBndr no_gen bndr_name pat_ty
260        ; traceTc "tcPatBndr(no-sig)" (ppr bndr_id $$ ppr (idType bndr_id))
261        ; return (mkTcNomReflCo pat_ty, bndr_id) }
262
263 tcPatBndr (PE { pe_ctxt = _lam_or_proc }) bndr_name pat_ty
264   = do { bndr <- mkLocalBinder bndr_name pat_ty
265        ; return (mkTcNomReflCo pat_ty, bndr) }
266
267 ------------
268 newNoSigLetBndr :: LetBndrSpec -> Name -> TcType -> TcM TcId
269 -- In the polymorphic case (no_gen = LetLclBndr), generate a "monomorphic version" 
270 --    of the Id; the original name will be bound to the polymorphic version
271 --    by the AbsBinds
272 -- In the monomorphic case (no_gen = LetBglBndr) there is no AbsBinds, and we 
273 --    use the original name directly
274 newNoSigLetBndr LetLclBndr name ty 
275   =do  { mono_name <- newLocalName name
276        ; mkLocalBinder mono_name ty }
277 newNoSigLetBndr (LetGblBndr prags) name ty 
278   = do { id <- mkLocalBinder name ty
279        ; addInlinePrags id (prags name) }
280
281 ----------
282 addInlinePrags :: TcId -> [LSig Name] -> TcM TcId
283 addInlinePrags poly_id prags
284   = do { traceTc "addInlinePrags" (ppr poly_id $$ ppr prags) 
285        ; tc_inl inl_sigs }
286   where
287     inl_sigs = filter isInlineLSig prags
288     tc_inl [] = return poly_id
289     tc_inl (L loc (InlineSig _ prag) : other_inls)
290        = do { unless (null other_inls) (setSrcSpan loc warn_dup_inline)
291             ; traceTc "addInlinePrag" (ppr poly_id $$ ppr prag) 
292             ; return (poly_id `setInlinePragma` prag) }
293     tc_inl _ = panic "tc_inl"
294
295     warn_dup_inline = warnPrags poly_id inl_sigs $
296                       ptext (sLit "Duplicate INLINE pragmas for")
297
298 warnPrags :: Id -> [LSig Name] -> SDoc -> TcM ()
299 warnPrags id bad_sigs herald
300   = addWarnTc (hang (herald <+> quotes (ppr id))
301                   2 (ppr_sigs bad_sigs))
302   where
303     ppr_sigs sigs = vcat (map (ppr . getLoc) sigs)
304
305 -----------------
306 mkLocalBinder :: Name -> TcType -> TcM TcId
307 mkLocalBinder name ty
308   = return (Id.mkLocalId name ty)
309 \end{code}
310
311 Note [Typing patterns in pattern bindings]
312 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
313 Suppose we are typing a pattern binding
314     pat = rhs
315 Then the PatCtxt will be (LetPat sig_fn let_bndr_spec).
316
317 There can still be signatures for the binders:
318      data T = MkT (forall a. a->a) Int
319      x :: forall a. a->a
320      y :: Int
321      MkT x y = <rhs>
322
323 Two cases, dealt with by the LetPat case of tcPatBndr
324
325  * If we are generalising (generalisation plan is InferGen or
326    CheckGen), then the let_bndr_spec will be LetLclBndr.  In that case
327    we want to bind a cloned, local version of the variable, with the
328    type given by the pattern context, *not* by the signature (even if
329    there is one; see Trac #7268). The mkExport part of the
330    generalisation step will do the checking and impedence matching
331    against the signature.
332
333  * If for some some reason we are not generalising (plan = NoGen), the
334    LetBndrSpec will be LetGblBndr.  In that case we must bind the
335    global version of the Id, and do so with precisely the type given
336    in the signature.  (Then we unify with the type from the pattern
337    context type.
338
339
340 %************************************************************************
341 %*                                                                      *
342                 The main worker functions
343 %*                                                                      *
344 %************************************************************************
345
346 Note [Nesting]
347 ~~~~~~~~~~~~~~
348 tcPat takes a "thing inside" over which the pattern scopes.  This is partly
349 so that tcPat can extend the environment for the thing_inside, but also 
350 so that constraints arising in the thing_inside can be discharged by the
351 pattern.
352
353 This does not work so well for the ErrCtxt carried by the monad: we don't
354 want the error-context for the pattern to scope over the RHS. 
355 Hence the getErrCtxt/setErrCtxt stuff in tcMultiple
356
357 \begin{code}
358 --------------------
359 type Checker inp out =  forall r.
360                           inp
361                        -> PatEnv
362                        -> TcM r
363                        -> TcM (out, r)
364
365 tcMultiple :: Checker inp out -> Checker [inp] [out]
366 tcMultiple tc_pat args penv thing_inside
367   = do  { err_ctxt <- getErrCtxt
368         ; let loop _ []
369                 = do { res <- thing_inside
370                      ; return ([], res) }
371
372               loop penv (arg:args)
373                 = do { (p', (ps', res)) 
374                                 <- tc_pat arg penv $ 
375                                    setErrCtxt err_ctxt $
376                                    loop penv args
377                 -- setErrCtxt: restore context before doing the next pattern
378                 -- See note [Nesting] above
379                                 
380                      ; return (p':ps', res) }
381
382         ; loop penv args }
383
384 --------------------
385 tc_lpat :: LPat Name 
386         -> TcSigmaType
387         -> PatEnv
388         -> TcM a
389         -> TcM (LPat TcId, a)
390 tc_lpat (L span pat) pat_ty penv thing_inside
391   = setSrcSpan span $
392     do  { (pat', res) <- maybeWrapPatCtxt pat (tc_pat penv pat pat_ty)
393                                           thing_inside
394         ; return (L span pat', res) }
395
396 tc_lpats :: PatEnv
397          -> [LPat Name] -> [TcSigmaType]
398          -> TcM a       
399          -> TcM ([LPat TcId], a)
400 tc_lpats penv pats tys thing_inside 
401   = ASSERT2( equalLength pats tys, ppr pats $$ ppr tys )
402     tcMultiple (\(p,t) -> tc_lpat p t) 
403                 (zipEqual "tc_lpats" pats tys)
404                 penv thing_inside 
405
406 --------------------
407 tc_pat  :: PatEnv
408         -> Pat Name 
409         -> TcSigmaType  -- Fully refined result type
410         -> TcM a                -- Thing inside
411         -> TcM (Pat TcId,       -- Translated pattern
412                 a)              -- Result of thing inside
413
414 tc_pat penv (VarPat name) pat_ty thing_inside
415   = do  { (co, id) <- tcPatBndr penv name pat_ty
416         ; res <- tcExtendIdEnv1 name id thing_inside
417         ; return (mkHsWrapPatCo co (VarPat id) pat_ty, res) }
418
419 tc_pat penv (ParPat pat) pat_ty thing_inside
420   = do  { (pat', res) <- tc_lpat pat pat_ty penv thing_inside
421         ; return (ParPat pat', res) }
422
423 tc_pat penv (BangPat pat) pat_ty thing_inside
424   = do  { (pat', res) <- tc_lpat pat pat_ty penv thing_inside
425         ; return (BangPat pat', res) }
426
427 tc_pat penv lpat@(LazyPat pat) pat_ty thing_inside
428   = do  { (pat', (res, pat_ct)) 
429                 <- tc_lpat pat pat_ty (makeLazy penv) $ 
430                    captureConstraints thing_inside
431                 -- Ignore refined penv', revert to penv
432
433         ; emitConstraints pat_ct
434         -- captureConstraints/extendConstraints: 
435         --   see Note [Hopping the LIE in lazy patterns]
436
437         -- Check there are no unlifted types under the lazy pattern
438         ; when (any (isUnLiftedType . idType) $ collectPatBinders pat') $
439                lazyUnliftedPatErr lpat
440
441         -- Check that the expected pattern type is itself lifted
442         ; pat_ty' <- newFlexiTyVarTy liftedTypeKind
443         ; _ <- unifyType pat_ty pat_ty'
444
445         ; return (LazyPat pat', res) }
446
447 tc_pat _ p@(QuasiQuotePat _) _ _
448   = pprPanic "Should never see QuasiQuotePat in type checker" (ppr p)
449
450 tc_pat _ (WildPat _) pat_ty thing_inside
451   = do  { res <- thing_inside 
452         ; return (WildPat pat_ty, res) }
453
454 tc_pat penv (AsPat (L nm_loc name) pat) pat_ty thing_inside
455   = do  { (co, bndr_id) <- setSrcSpan nm_loc (tcPatBndr penv name pat_ty)
456         ; (pat', res) <- tcExtendIdEnv1 name bndr_id $
457                          tc_lpat pat (idType bndr_id) penv thing_inside
458             -- NB: if we do inference on:
459             --          \ (y@(x::forall a. a->a)) = e
460             -- we'll fail.  The as-pattern infers a monotype for 'y', which then
461             -- fails to unify with the polymorphic type for 'x'.  This could 
462             -- perhaps be fixed, but only with a bit more work.
463             --
464             -- If you fix it, don't forget the bindInstsOfPatIds!
465         ; return (mkHsWrapPatCo co (AsPat (L nm_loc bndr_id) pat') pat_ty, res) }
466
467 tc_pat penv (ViewPat expr pat _) overall_pat_ty thing_inside 
468   = do  {
469          -- Morally, expr must have type `forall a1...aN. OPT' -> B` 
470          -- where overall_pat_ty is an instance of OPT'.
471          -- Here, we infer a rho type for it,
472          -- which replaces the leading foralls and constraints
473          -- with fresh unification variables.
474         ; (expr',expr'_inferred) <- tcInferRho expr
475
476          -- next, we check that expr is coercible to `overall_pat_ty -> pat_ty`
477          -- NOTE: this forces pat_ty to be a monotype (because we use a unification 
478          -- variable to find it).  this means that in an example like
479          -- (view -> f)    where view :: _ -> forall b. b
480          -- we will only be able to use view at one instantation in the
481          -- rest of the view
482         ; (expr_co, pat_ty) <- tcInfer $ \ pat_ty -> 
483                 unifyType expr'_inferred (mkFunTy overall_pat_ty pat_ty)
484         
485          -- pattern must have pat_ty
486         ; (pat', res) <- tc_lpat pat pat_ty penv thing_inside
487
488         ; return (ViewPat (mkLHsWrapCo expr_co expr') pat' overall_pat_ty, res) }
489
490 -- Type signatures in patterns
491 -- See Note [Pattern coercions] below
492 tc_pat penv (SigPatIn pat sig_ty) pat_ty thing_inside
493   = do  { (inner_ty, tv_binds, wrap) <- tcPatSig (patSigCtxt penv) sig_ty pat_ty
494         ; (pat', res) <- tcExtendTyVarEnv2 tv_binds $
495                          tc_lpat pat inner_ty penv thing_inside
496
497         ; return (mkHsWrapPat wrap (SigPatOut pat' inner_ty) pat_ty, res) }
498
499 ------------------------
500 -- Lists, tuples, arrays
501 tc_pat penv (ListPat pats _ Nothing) pat_ty thing_inside
502   = do  { (coi, elt_ty) <- matchExpectedPatTy matchExpectedListTy pat_ty      
503         ; (pats', res) <- tcMultiple (\p -> tc_lpat p elt_ty)
504                                      pats penv thing_inside
505         ; return (mkHsWrapPat coi (ListPat pats' elt_ty Nothing) pat_ty, res) 
506         }
507
508 tc_pat penv (ListPat pats _ (Just (_,e))) pat_ty thing_inside
509   = do  { list_pat_ty <- newFlexiTyVarTy liftedTypeKind
510         ; e' <- tcSyntaxOp ListOrigin e (mkFunTy pat_ty list_pat_ty)
511         ; (coi, elt_ty) <- matchExpectedPatTy matchExpectedListTy list_pat_ty
512         ; (pats', res) <- tcMultiple (\p -> tc_lpat p elt_ty)
513                                      pats penv thing_inside
514         ; return (mkHsWrapPat coi (ListPat pats' elt_ty (Just (pat_ty,e'))) list_pat_ty, res) 
515         }
516
517 tc_pat penv (PArrPat pats _) pat_ty thing_inside
518   = do  { (coi, elt_ty) <- matchExpectedPatTy matchExpectedPArrTy pat_ty
519         ; (pats', res) <- tcMultiple (\p -> tc_lpat p elt_ty)
520                                      pats penv thing_inside 
521         ; return (mkHsWrapPat coi (PArrPat pats' elt_ty) pat_ty, res)
522         }
523
524 tc_pat penv (TuplePat pats boxity _) pat_ty thing_inside
525   = do  { let tc = tupleTyCon (boxityNormalTupleSort boxity) (length pats)
526         ; (coi, arg_tys) <- matchExpectedPatTy (matchExpectedTyConApp tc) pat_ty
527         ; (pats', res) <- tc_lpats penv pats arg_tys thing_inside
528
529         ; dflags <- getDynFlags
530
531         -- Under flag control turn a pattern (x,y,z) into ~(x,y,z)
532         -- so that we can experiment with lazy tuple-matching.
533         -- This is a pretty odd place to make the switch, but
534         -- it was easy to do.
535         ; let 
536               unmangled_result = TuplePat pats' boxity arg_tys
537                                  -- pat_ty /= pat_ty iff coi /= IdCo
538               possibly_mangled_result
539                 | gopt Opt_IrrefutableTuples dflags &&
540                   isBoxed boxity            = LazyPat (noLoc unmangled_result)
541                 | otherwise                 = unmangled_result
542
543         ; ASSERT( length arg_tys == length pats )      -- Syntactically enforced
544           return (mkHsWrapPat coi possibly_mangled_result pat_ty, res)
545         }
546
547 ------------------------
548 -- Data constructors
549 tc_pat penv (ConPatIn con arg_pats) pat_ty thing_inside
550   = tcConPat penv con pat_ty arg_pats thing_inside
551
552 ------------------------
553 -- Literal patterns
554 tc_pat _ (LitPat simple_lit) pat_ty thing_inside
555   = do  { let lit_ty = hsLitType simple_lit
556         ; co <- unifyPatType lit_ty pat_ty
557                 -- coi is of kind: pat_ty ~ lit_ty
558         ; res <- thing_inside 
559         ; return ( mkHsWrapPatCo co (LitPat simple_lit) pat_ty 
560                  , res) }
561
562 ------------------------
563 -- Overloaded patterns: n, and n+k
564 tc_pat _ (NPat over_lit mb_neg eq) pat_ty thing_inside
565   = do  { let orig = LiteralOrigin over_lit
566         ; lit'    <- newOverloadedLit orig over_lit pat_ty
567         ; eq'     <- tcSyntaxOp orig eq (mkFunTys [pat_ty, pat_ty] boolTy)
568         ; mb_neg' <- case mb_neg of
569                         Nothing  -> return Nothing      -- Positive literal
570                         Just neg ->     -- Negative literal
571                                         -- The 'negate' is re-mappable syntax
572                             do { neg' <- tcSyntaxOp orig neg (mkFunTy pat_ty pat_ty)
573                                ; return (Just neg') }
574         ; res <- thing_inside 
575         ; return (NPat lit' mb_neg' eq', res) }
576
577 tc_pat penv (NPlusKPat (L nm_loc name) lit ge minus) pat_ty thing_inside
578   = do  { (co, bndr_id) <- setSrcSpan nm_loc (tcPatBndr penv name pat_ty)
579         ; let pat_ty' = idType bndr_id
580               orig    = LiteralOrigin lit
581         ; lit' <- newOverloadedLit orig lit pat_ty'
582
583         -- The '>=' and '-' parts are re-mappable syntax
584         ; ge'    <- tcSyntaxOp orig ge    (mkFunTys [pat_ty', pat_ty'] boolTy)
585         ; minus' <- tcSyntaxOp orig minus (mkFunTys [pat_ty', pat_ty'] pat_ty')
586         ; let pat' = NPlusKPat (L nm_loc bndr_id) lit' ge' minus'
587
588         -- The Report says that n+k patterns must be in Integral
589         -- We may not want this when using re-mappable syntax, though (ToDo?)
590         ; icls <- tcLookupClass integralClassName
591         ; instStupidTheta orig [mkClassPred icls [pat_ty']]     
592     
593         ; res <- tcExtendIdEnv1 name bndr_id thing_inside
594         ; return (mkHsWrapPatCo co pat' pat_ty, res) }
595
596 tc_pat _ _other_pat _ _ = panic "tc_pat"        -- ConPatOut, SigPatOut
597
598 ----------------
599 unifyPatType :: TcType -> TcType -> TcM TcCoercion
600 -- In patterns we want a coercion from the
601 -- context type (expected) to the actual pattern type
602 -- But we don't want to reverse the args to unifyType because
603 -- that controls the actual/expected stuff in error messages
604 unifyPatType actual_ty expected_ty
605   = do { coi <- unifyType actual_ty expected_ty
606        ; return (mkTcSymCo coi) }
607 \end{code}
608
609 Note [Hopping the LIE in lazy patterns]
610 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
611 In a lazy pattern, we must *not* discharge constraints from the RHS
612 from dictionaries bound in the pattern.  E.g.
613         f ~(C x) = 3
614 We can't discharge the Num constraint from dictionaries bound by
615 the pattern C!  
616
617 So we have to make the constraints from thing_inside "hop around" 
618 the pattern.  Hence the captureConstraints and emitConstraints.
619
620 The same thing ensures that equality constraints in a lazy match
621 are not made available in the RHS of the match. For example
622         data T a where { T1 :: Int -> T Int; ... }
623         f :: T a -> Int -> a
624         f ~(T1 i) y = y
625 It's obviously not sound to refine a to Int in the right
626 hand side, because the arugment might not match T1 at all!
627
628 Finally, a lazy pattern should not bind any existential type variables
629 because they won't be in scope when we do the desugaring
630
631
632 %************************************************************************
633 %*                                                                      *
634         Most of the work for constructors is here
635         (the rest is in the ConPatIn case of tc_pat)
636 %*                                                                      *
637 %************************************************************************
638
639 [Pattern matching indexed data types]
640 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
641 Consider the following declarations:
642
643   data family Map k :: * -> *
644   data instance Map (a, b) v = MapPair (Map a (Pair b v))
645
646 and a case expression
647
648   case x :: Map (Int, c) w of MapPair m -> ...
649
650 As explained by [Wrappers for data instance tycons] in MkIds.lhs, the
651 worker/wrapper types for MapPair are
652
653   $WMapPair :: forall a b v. Map a (Map a b v) -> Map (a, b) v
654   $wMapPair :: forall a b v. Map a (Map a b v) -> :R123Map a b v
655
656 So, the type of the scrutinee is Map (Int, c) w, but the tycon of MapPair is
657 :R123Map, which means the straight use of boxySplitTyConApp would give a type
658 error.  Hence, the smart wrapper function boxySplitTyConAppWithFamily calls
659 boxySplitTyConApp with the family tycon Map instead, which gives us the family
660 type list {(Int, c), w}.  To get the correct split for :R123Map, we need to
661 unify the family type list {(Int, c), w} with the instance types {(a, b), v}
662 (provided by tyConFamInst_maybe together with the family tycon).  This
663 unification yields the substitution [a -> Int, b -> c, v -> w], which gives us
664 the split arguments for the representation tycon :R123Map as {Int, c, w}
665
666 In other words, boxySplitTyConAppWithFamily implicitly takes the coercion 
667
668   Co123Map a b v :: {Map (a, b) v ~ :R123Map a b v}
669
670 moving between representation and family type into account.  To produce type
671 correct Core, this coercion needs to be used to case the type of the scrutinee
672 from the family to the representation type.  This is achieved by
673 unwrapFamInstScrutinee using a CoPat around the result pattern.
674
675 Now it might appear seem as if we could have used the previous GADT type
676 refinement infrastructure of refineAlt and friends instead of the explicit
677 unification and CoPat generation.  However, that would be wrong.  Why?  The
678 whole point of GADT refinement is that the refinement is local to the case
679 alternative.  In contrast, the substitution generated by the unification of
680 the family type list and instance types needs to be propagated to the outside.
681 Imagine that in the above example, the type of the scrutinee would have been
682 (Map x w), then we would have unified {x, w} with {(a, b), v}, yielding the
683 substitution [x -> (a, b), v -> w].  In contrast to GADT matching, the
684 instantiation of x with (a, b) must be global; ie, it must be valid in *all*
685 alternatives of the case expression, whereas in the GADT case it might vary
686 between alternatives.
687
688 RIP GADT refinement: refinements have been replaced by the use of explicit
689 equality constraints that are used in conjunction with implication constraints
690 to express the local scope of GADT refinements.
691
692 \begin{code}
693 --      Running example:
694 -- MkT :: forall a b c. (a~[b]) => b -> c -> T a
695 --       with scrutinee of type (T ty)
696
697 tcConPat :: PatEnv -> Located Name 
698          -> TcRhoType           -- Type of the pattern
699          -> HsConPatDetails Name -> TcM a
700          -> TcM (Pat TcId, a)
701 tcConPat penv con_lname@(L _ con_name) pat_ty arg_pats thing_inside
702   = do  { con_like <- tcLookupConLike con_name
703         ; case con_like of
704             RealDataCon data_con -> tcDataConPat penv con_lname data_con
705                                                  pat_ty arg_pats thing_inside
706             PatSynCon pat_syn -> tcPatSynPat penv con_lname pat_syn
707                                              pat_ty arg_pats thing_inside
708         }
709
710 tcDataConPat :: PatEnv -> Located Name -> DataCon
711              -> TcRhoType               -- Type of the pattern
712              -> HsConPatDetails Name -> TcM a
713              -> TcM (Pat TcId, a)
714 tcDataConPat penv (L con_span con_name) data_con pat_ty arg_pats thing_inside
715   = do  { let tycon = dataConTyCon data_con
716                   -- For data families this is the representation tycon
717               (univ_tvs, ex_tvs, eq_spec, theta, arg_tys, _)
718                 = dataConFullSig data_con
719               header = L con_span (RealDataCon data_con)
720
721           -- Instantiate the constructor type variables [a->ty]
722           -- This may involve doing a family-instance coercion, 
723           -- and building a wrapper 
724         ; (wrap, ctxt_res_tys) <- matchExpectedPatTy (matchExpectedConTy tycon) pat_ty
725
726           -- Add the stupid theta
727         ; setSrcSpan con_span $ addDataConStupidTheta data_con ctxt_res_tys
728
729         ; checkExistentials ex_tvs penv 
730         ; (tenv, ex_tvs') <- tcInstSuperSkolTyVarsX
731                                (zipTopTvSubst univ_tvs ctxt_res_tys) ex_tvs
732                      -- Get location from monad, not from ex_tvs
733
734         ; let -- pat_ty' = mkTyConApp tycon ctxt_res_tys
735               -- pat_ty' is type of the actual constructor application
736               -- pat_ty' /= pat_ty iff coi /= IdCo
737
738               arg_tys' = substTys tenv arg_tys
739
740         ; traceTc "tcConPat" (vcat [ ppr con_name, ppr univ_tvs, ppr ex_tvs, ppr eq_spec
741                                    , ppr ex_tvs', ppr ctxt_res_tys, ppr arg_tys' ])
742         ; if null ex_tvs && null eq_spec && null theta
743           then do { -- The common case; no class bindings etc 
744                     -- (see Note [Arrows and patterns])
745                     (arg_pats', res) <- tcConArgs (RealDataCon data_con) arg_tys'
746                                                   arg_pats penv thing_inside
747                   ; let res_pat = ConPatOut { pat_con = header,
748                                               pat_tvs = [], pat_dicts = [], 
749                                               pat_binds = emptyTcEvBinds,
750                                               pat_args = arg_pats', 
751                                               pat_arg_tys = ctxt_res_tys,
752                                               pat_wrap = idHsWrapper }
753
754                   ; return (mkHsWrapPat wrap res_pat pat_ty, res) }
755
756           else do   -- The general case, with existential, 
757                     -- and local equality constraints
758         { let theta'   = substTheta tenv (eqSpecPreds eq_spec ++ theta)
759                            -- order is *important* as we generate the list of
760                            -- dictionary binders from theta'
761               no_equalities = not (any isEqPred theta')
762               skol_info = case pe_ctxt penv of
763                             LamPat mc -> PatSkol (RealDataCon data_con) mc
764                             LetPat {} -> UnkSkol -- Doesn't matter
765  
766         ; gadts_on    <- xoptM Opt_GADTs
767         ; families_on <- xoptM Opt_TypeFamilies
768         ; checkTc (no_equalities || gadts_on || families_on)
769                   (ptext (sLit "A pattern match on a GADT requires GADTs or TypeFamilies"))
770                   -- Trac #2905 decided that a *pattern-match* of a GADT
771                   -- should require the GADT language flag.  
772                   -- Re TypeFamilies see also #7156 
773
774         ; given <- newEvVars theta'
775         ; (ev_binds, (arg_pats', res))
776              <- checkConstraints skol_info ex_tvs' given $
777                 tcConArgs (RealDataCon data_con) arg_tys' arg_pats penv thing_inside
778
779         ; let res_pat = ConPatOut { pat_con   = header,
780                                     pat_tvs   = ex_tvs',
781                                     pat_dicts = given,
782                                     pat_binds = ev_binds,
783                                     pat_args  = arg_pats', 
784                                     pat_arg_tys = ctxt_res_tys,
785                                     pat_wrap  = idHsWrapper }
786         ; return (mkHsWrapPat wrap res_pat pat_ty, res)
787         } }
788
789 tcPatSynPat :: PatEnv -> Located Name -> PatSyn
790             -> TcRhoType                -- Type of the pattern
791             -> HsConPatDetails Name -> TcM a
792             -> TcM (Pat TcId, a)
793 tcPatSynPat penv (L con_span _) pat_syn pat_ty arg_pats thing_inside
794   = do  { let (univ_tvs, ex_tvs, prov_theta, req_theta) = patSynSig pat_syn
795               arg_tys = patSynArgs pat_syn
796               ty = patSynType pat_syn
797
798         ; (univ_tvs', inst_tys, subst) <- tcInstTyVars univ_tvs
799
800         ; checkExistentials ex_tvs penv
801         ; (tenv, ex_tvs') <- tcInstSuperSkolTyVarsX subst ex_tvs
802         ; let ty' = substTy tenv ty
803               arg_tys' = substTys tenv arg_tys
804               prov_theta' = substTheta tenv prov_theta
805               req_theta' = substTheta tenv req_theta
806
807         ; wrap <- coToHsWrapper <$> unifyType ty' pat_ty
808         ; traceTc "tcPatSynPat" (ppr pat_syn $$
809                                  ppr pat_ty $$
810                                  ppr ty' $$
811                                  ppr ex_tvs' $$
812                                  ppr prov_theta' $$
813                                  ppr req_theta' $$
814                                  ppr arg_tys')
815
816         ; prov_dicts' <- newEvVars prov_theta'
817
818         -- Using a pattern synonym requires the PatternSynonyms
819         -- language flag to keep consistent with #2905
820         ; patsyns_on <- xoptM Opt_PatternSynonyms
821         ; checkTc patsyns_on
822                   (ptext (sLit "A pattern match on a pattern synonym requires PatternSynonyms"))
823
824         ; let skol_info = case pe_ctxt penv of
825                             LamPat mc -> PatSkol (PatSynCon pat_syn) mc
826                             LetPat {} -> UnkSkol -- Doesn't matter
827
828         ; req_wrap <- instCall PatOrigin inst_tys req_theta'
829         ; traceTc "instCall" (ppr req_wrap)
830
831         ; traceTc "checkConstraints {" empty
832         ; (ev_binds, (arg_pats', res))
833              <- checkConstraints skol_info ex_tvs' prov_dicts' $
834                 tcConArgs (PatSynCon pat_syn) arg_tys' arg_pats penv thing_inside
835
836         ; traceTc "checkConstraints }" (ppr ev_binds)
837         ; let res_pat = ConPatOut { pat_con   = L con_span $ PatSynCon pat_syn,
838                                     pat_tvs   = ex_tvs',
839                                     pat_dicts = prov_dicts',
840                                     pat_binds = ev_binds,
841                                     pat_args  = arg_pats',
842                                     pat_arg_tys = mkTyVarTys univ_tvs',
843                                     pat_wrap  = req_wrap }
844         ; return (mkHsWrapPat wrap res_pat pat_ty, res) }
845
846 ----------------------------
847 matchExpectedPatTy :: (TcRhoType -> TcM (TcCoercion, a))
848                     -> TcRhoType -> TcM (HsWrapper, a) 
849 -- See Note [Matching polytyped patterns]
850 -- Returns a wrapper : pat_ty ~ inner_ty
851 matchExpectedPatTy inner_match pat_ty
852   | null tvs && null theta
853   = do { (co, res) <- inner_match pat_ty
854        ; return (coToHsWrapper (mkTcSymCo co), res) }
855          -- The Sym is because the inner_match returns a coercion
856          -- that is the other way round to matchExpectedPatTy
857
858   | otherwise
859   = do { (_, tys, subst) <- tcInstTyVars tvs
860        ; wrap1 <- instCall PatOrigin tys (substTheta subst theta)
861        ; (wrap2, arg_tys) <- matchExpectedPatTy inner_match (TcType.substTy subst tau)
862        ; return (wrap2 <.> wrap1 , arg_tys) }
863   where
864     (tvs, theta, tau) = tcSplitSigmaTy pat_ty
865
866 ----------------------------
867 matchExpectedConTy :: TyCon      -- The TyCon that this data 
868                                  -- constructor actually returns
869                    -> TcRhoType  -- The type of the pattern
870                    -> TcM (TcCoercion, [TcSigmaType])
871 -- See Note [Matching constructor patterns]
872 -- Returns a coercion : T ty1 ... tyn ~ pat_ty
873 -- This is the same way round as matchExpectedListTy etc
874 -- but the other way round to matchExpectedPatTy
875 matchExpectedConTy data_tc pat_ty
876   | Just (fam_tc, fam_args, co_tc) <- tyConFamInstSig_maybe data_tc
877          -- Comments refer to Note [Matching constructor patterns]
878          -- co_tc :: forall a. T [a] ~ T7 a
879   = do { (_, tys, subst) <- tcInstTyVars (tyConTyVars data_tc)
880              -- tys = [ty1,ty2]
881
882        ; traceTc "matchExpectedConTy" (vcat [ppr data_tc, 
883                                              ppr (tyConTyVars data_tc),
884                                              ppr fam_tc, ppr fam_args])
885        ; co1 <- unifyType (mkTyConApp fam_tc (substTys subst fam_args)) pat_ty
886              -- co1 : T (ty1,ty2) ~ pat_ty
887
888        ; let co2 = mkTcUnbranchedAxInstCo Nominal co_tc tys
889              -- co2 : T (ty1,ty2) ~ T7 ty1 ty2
890
891        ; return (mkTcSymCo co2 `mkTcTransCo` co1, tys) }
892
893   | otherwise
894   = matchExpectedTyConApp data_tc pat_ty
895              -- coi : T tys ~ pat_ty
896 \end{code}
897
898 Note [Matching constructor patterns]
899 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
900 Suppose (coi, tys) = matchExpectedConType data_tc pat_ty
901
902  * In the simple case, pat_ty = tc tys
903
904  * If pat_ty is a polytype, we want to instantiate it
905    This is like part of a subsumption check.  Eg
906       f :: (forall a. [a]) -> blah
907       f [] = blah
908
909  * In a type family case, suppose we have
910           data family T a
911           data instance T (p,q) = A p | B q
912        Then we'll have internally generated
913               data T7 p q = A p | B q
914               axiom coT7 p q :: T (p,q) ~ T7 p q
915  
916        So if pat_ty = T (ty1,ty2), we return (coi, [ty1,ty2]) such that
917            coi = coi2 . coi1 : T7 t ~ pat_ty
918            coi1 : T (ty1,ty2) ~ pat_ty
919            coi2 : T7 ty1 ty2 ~ T (ty1,ty2)
920
921    For families we do all this matching here, not in the unifier,
922    because we never want a whisper of the data_tycon to appear in
923    error messages; it's a purely internal thing
924
925 \begin{code}
926 tcConArgs :: ConLike -> [TcSigmaType]
927           -> Checker (HsConPatDetails Name) (HsConPatDetails Id)
928
929 tcConArgs con_like arg_tys (PrefixCon arg_pats) penv thing_inside
930   = do  { checkTc (con_arity == no_of_args)     -- Check correct arity
931                   (arityErr "Constructor" con_like con_arity no_of_args)
932         ; let pats_w_tys = zipEqual "tcConArgs" arg_pats arg_tys
933         ; (arg_pats', res) <- tcMultiple tcConArg pats_w_tys
934                                               penv thing_inside 
935         ; return (PrefixCon arg_pats', res) }
936   where
937     con_arity  = conLikeArity con_like
938     no_of_args = length arg_pats
939
940 tcConArgs con_like arg_tys (InfixCon p1 p2) penv thing_inside
941   = do  { checkTc (con_arity == 2)      -- Check correct arity
942                   (arityErr "Constructor" con_like con_arity 2)
943         ; let [arg_ty1,arg_ty2] = arg_tys       -- This can't fail after the arity check
944         ; ([p1',p2'], res) <- tcMultiple tcConArg [(p1,arg_ty1),(p2,arg_ty2)]
945                                               penv thing_inside
946         ; return (InfixCon p1' p2', res) }
947   where
948     con_arity  = conLikeArity con_like
949
950 tcConArgs con_like arg_tys (RecCon (HsRecFields rpats dd)) penv thing_inside
951   = do  { (rpats', res) <- tcMultiple tc_field rpats penv thing_inside
952         ; return (RecCon (HsRecFields rpats' dd), res) }
953   where
954     tc_field :: Checker (HsRecField FieldLabel (LPat Name)) (HsRecField TcId (LPat TcId))
955     tc_field (HsRecField field_lbl pat pun) penv thing_inside
956       = do { (sel_id, pat_ty) <- wrapLocFstM find_field_ty field_lbl
957            ; (pat', res) <- tcConArg (pat, pat_ty) penv thing_inside
958            ; return (HsRecField sel_id pat' pun, res) }
959
960     find_field_ty :: FieldLabel -> TcM (Id, TcType)
961     find_field_ty field_lbl
962         = case [ty | (f,ty) <- field_tys, f == field_lbl] of
963
964                 -- No matching field; chances are this field label comes from some
965                 -- other record type (or maybe none).  If this happens, just fail,
966                 -- otherwise we get crashes later (Trac #8570), and similar:
967                 --      f (R { foo = (a,b) }) = a+b
968                 -- If foo isn't one of R's fields, we don't want to crash when
969                 -- typechecking the "a+b".
970            [] -> failWith (badFieldCon con_like field_lbl)
971
972                 -- The normal case, when the field comes from the right constructor
973            (pat_ty : extras) ->
974                 ASSERT( null extras )
975                 do { sel_id <- tcLookupField field_lbl
976                    ; return (sel_id, pat_ty) }
977
978     field_tys :: [(FieldLabel, TcType)]
979     field_tys = case con_like of
980         RealDataCon data_con -> zip (dataConFieldLabels data_con) arg_tys
981           -- Don't use zipEqual! If the constructor isn't really a record, then
982           -- dataConFieldLabels will be empty (and each field in the pattern
983           -- will generate an error below).
984         PatSynCon{} -> []
985
986 conLikeArity :: ConLike -> Arity
987 conLikeArity (RealDataCon data_con) = dataConSourceArity data_con
988 conLikeArity (PatSynCon   pat_syn)  = patSynArity pat_syn
989
990 tcConArg :: Checker (LPat Name, TcSigmaType) (LPat Id)
991 tcConArg (arg_pat, arg_ty) penv thing_inside
992   = tc_lpat arg_pat arg_ty penv thing_inside
993 \end{code}
994
995 \begin{code}
996 addDataConStupidTheta :: DataCon -> [TcType] -> TcM ()
997 -- Instantiate the "stupid theta" of the data con, and throw 
998 -- the constraints into the constraint set
999 addDataConStupidTheta data_con inst_tys
1000   | null stupid_theta = return ()
1001   | otherwise         = instStupidTheta origin inst_theta
1002   where
1003     origin = OccurrenceOf (dataConName data_con)
1004         -- The origin should always report "occurrence of C"
1005         -- even when C occurs in a pattern
1006     stupid_theta = dataConStupidTheta data_con
1007     tenv = mkTopTvSubst (dataConUnivTyVars data_con `zip` inst_tys)
1008          -- NB: inst_tys can be longer than the univ tyvars
1009          --     because the constructor might have existentials
1010     inst_theta = substTheta tenv stupid_theta
1011 \end{code}
1012
1013 Note [Arrows and patterns]
1014 ~~~~~~~~~~~~~~~~~~~~~~~~~~
1015 (Oct 07) Arrow noation has the odd property that it involves 
1016 "holes in the scope". For example:
1017   expr :: Arrow a => a () Int
1018   expr = proc (y,z) -> do
1019           x <- term -< y
1020           expr' -< x
1021
1022 Here the 'proc (y,z)' binding scopes over the arrow tails but not the
1023 arrow body (e.g 'term').  As things stand (bogusly) all the
1024 constraints from the proc body are gathered together, so constraints
1025 from 'term' will be seen by the tcPat for (y,z).  But we must *not*
1026 bind constraints from 'term' here, because the desugarer will not make
1027 these bindings scope over 'term'.
1028
1029 The Right Thing is not to confuse these constraints together. But for
1030 now the Easy Thing is to ensure that we do not have existential or
1031 GADT constraints in a 'proc', and to short-cut the constraint
1032 simplification for such vanilla patterns so that it binds no
1033 constraints. Hence the 'fast path' in tcConPat; but it's also a good
1034 plan for ordinary vanilla patterns to bypass the constraint
1035 simplification step.
1036
1037 %************************************************************************
1038 %*                                                                      *
1039                 Note [Pattern coercions]
1040 %*                                                                      *
1041 %************************************************************************
1042
1043 In principle, these program would be reasonable:
1044         
1045         f :: (forall a. a->a) -> Int
1046         f (x :: Int->Int) = x 3
1047
1048         g :: (forall a. [a]) -> Bool
1049         g [] = True
1050
1051 In both cases, the function type signature restricts what arguments can be passed
1052 in a call (to polymorphic ones).  The pattern type signature then instantiates this
1053 type.  For example, in the first case,  (forall a. a->a) <= Int -> Int, and we
1054 generate the translated term
1055         f = \x' :: (forall a. a->a).  let x = x' Int in x 3
1056
1057 From a type-system point of view, this is perfectly fine, but it's *very* seldom useful.
1058 And it requires a significant amount of code to implement, because we need to decorate
1059 the translated pattern with coercion functions (generated from the subsumption check 
1060 by tcSub).  
1061
1062 So for now I'm just insisting on type *equality* in patterns.  No subsumption. 
1063
1064 Old notes about desugaring, at a time when pattern coercions were handled:
1065
1066 A SigPat is a type coercion and must be handled one at at time.  We can't
1067 combine them unless the type of the pattern inside is identical, and we don't
1068 bother to check for that.  For example:
1069
1070         data T = T1 Int | T2 Bool
1071         f :: (forall a. a -> a) -> T -> t
1072         f (g::Int->Int)   (T1 i) = T1 (g i)
1073         f (g::Bool->Bool) (T2 b) = T2 (g b)
1074
1075 We desugar this as follows:
1076
1077         f = \ g::(forall a. a->a) t::T ->
1078             let gi = g Int
1079             in case t of { T1 i -> T1 (gi i)
1080                            other ->
1081             let gb = g Bool
1082             in case t of { T2 b -> T2 (gb b)
1083                            other -> fail }}
1084
1085 Note that we do not treat the first column of patterns as a
1086 column of variables, because the coerced variables (gi, gb)
1087 would be of different types.  So we get rather grotty code.
1088 But I don't think this is a common case, and if it was we could
1089 doubtless improve it.
1090
1091 Meanwhile, the strategy is:
1092         * treat each SigPat coercion (always non-identity coercions)
1093                 as a separate block
1094         * deal with the stuff inside, and then wrap a binding round
1095                 the result to bind the new variable (gi, gb, etc)
1096
1097
1098 %************************************************************************
1099 %*                                                                      *
1100 \subsection{Errors and contexts}
1101 %*                                                                      *
1102 %************************************************************************
1103
1104 \begin{code}
1105 maybeWrapPatCtxt :: Pat Name -> (TcM a -> TcM b) -> TcM a -> TcM b
1106 -- Not all patterns are worth pushing a context
1107 maybeWrapPatCtxt pat tcm thing_inside 
1108   | not (worth_wrapping pat) = tcm thing_inside
1109   | otherwise                = addErrCtxt msg $ tcm $ popErrCtxt thing_inside
1110                                -- Remember to pop before doing thing_inside
1111   where
1112    worth_wrapping (VarPat {}) = False
1113    worth_wrapping (ParPat {}) = False
1114    worth_wrapping (AsPat {})  = False
1115    worth_wrapping _           = True
1116    msg = hang (ptext (sLit "In the pattern:")) 2 (ppr pat)
1117
1118 -----------------------------------------------
1119 checkExistentials :: [TyVar] -> PatEnv -> TcM ()
1120           -- See Note [Arrows and patterns]
1121 checkExistentials [] _                                 = return ()
1122 checkExistentials _ (PE { pe_ctxt = LetPat {}})        = failWithTc existentialLetPat
1123 checkExistentials _ (PE { pe_ctxt = LamPat ProcExpr }) = failWithTc existentialProcPat
1124 checkExistentials _ (PE { pe_lazy = True })            = failWithTc existentialLazyPat
1125 checkExistentials _ _                                  = return ()
1126
1127 existentialLazyPat :: SDoc
1128 existentialLazyPat
1129   = hang (ptext (sLit "An existential or GADT data constructor cannot be used"))
1130        2 (ptext (sLit "inside a lazy (~) pattern"))
1131
1132 existentialProcPat :: SDoc
1133 existentialProcPat 
1134   = ptext (sLit "Proc patterns cannot use existential or GADT data constructors")
1135
1136 existentialLetPat :: SDoc
1137 existentialLetPat
1138   = vcat [text "My brain just exploded",
1139           text "I can't handle pattern bindings for existential or GADT data constructors.",
1140           text "Instead, use a case-expression, or do-notation, to unpack the constructor."]
1141
1142 badFieldCon :: ConLike -> Name -> SDoc
1143 badFieldCon con field
1144   = hsep [ptext (sLit "Constructor") <+> quotes (ppr con),
1145           ptext (sLit "does not have field"), quotes (ppr field)]
1146
1147 polyPatSig :: TcType -> SDoc
1148 polyPatSig sig_ty
1149   = hang (ptext (sLit "Illegal polymorphic type signature in pattern:"))
1150        2 (ppr sig_ty)
1151
1152 lazyUnliftedPatErr :: OutputableBndr name => Pat name -> TcM ()
1153 lazyUnliftedPatErr pat
1154   = failWithTc $
1155     hang (ptext (sLit "A lazy (~) pattern cannot contain unlifted types:"))
1156        2 (ppr pat)
1157 \end{code}