Correct name of Note in comment
[ghc.git] / configure.ac
1 dnl == autoconf source for the Glasgow FP tools ==
2 dnl (run "grep '^dnl \*' configure.ac | sed -e 's/dnl / /g; s/\*\*/   +/g;'"
3 dnl  (or some such) to see the outline of this file)
4 dnl
5 #
6 # (c) The University of Glasgow 1994-2012
7 #
8 # Configure script template for GHC
9 #
10 # Process with 'autoreconf' to get a working configure script.
11 #
12 # For the generated configure script, do "./configure --help" to
13 # see what flags are available. (Better yet, read the documentation!)
14 #
15
16 AC_INIT([The Glorious Glasgow Haskell Compilation System], [8.1], [glasgow-haskell-bugs@haskell.org], [ghc-AC_PACKAGE_VERSION])
17
18 # Set this to YES for a released version, otherwise NO
19 : ${RELEASE=NO}
20
21 # The primary version (e.g. 7.5, 7.4.1) is set in the AC_INIT line
22 # above.  If this is not a released version, then we will append the
23 # date to the version number (e.g. 7.4.20111220).  The date is
24 # constructed by finding the date of the most recent patch in the
25 # git repository.  If this is a source distribution (not a git
26 # checkout), then we ship a file 'VERSION' containing the full version
27 # when the source distribution was created.
28
29 if test ! -f mk/config.h.in; then
30    echo "mk/config.h.in doesn't exist: perhaps you haven't run 'perl boot'?"
31    exit 1
32 fi
33
34 AC_SUBST([CONFIGURE_ARGS], [$ac_configure_args])
35
36 dnl this makes sure `./configure --target=<cross-compile-target>`
37 dnl works as expected, since we're slightly modifying how Autoconf
38 dnl interprets build/host/target and how this interacts with $CC tests
39 test -n "$target_alias" && ac_tool_prefix=$target_alias-
40
41 dnl ----------------------------------------------------------
42 dnl ** Find unixy sort and find commands,
43 dnl ** which are needed by FP_SETUP_PROJECT_VERSION
44
45 dnl ** Find find command (for Win32's benefit)
46 FP_PROG_FIND
47 FP_PROG_SORT
48
49 dnl ----------------------------------------------------------
50 FP_SETUP_PROJECT_VERSION
51
52 # Hmmm, we fix the RPM release number to 1 here... Is this convenient?
53 AC_SUBST([release], [1])
54
55 # First off, a distrib sanity check..
56 AC_CONFIG_SRCDIR([mk/config.mk.in])
57
58 dnl * We require autoconf version 2.60
59 dnl We need 2.50 due to the use of AC_SYS_LARGEFILE and AC_MSG_NOTICE.
60 dnl We need 2.52 due to the use of AS_TR_CPP and AS_TR_SH.
61 dnl Using autoconf 2.59 started to give nonsense like this
62 dnl  #define SIZEOF_CHAR 0
63 dnl recently.
64 AC_PREREQ([2.60])
65
66 # -------------------------------------------------------------------------
67 # Prepare to generate the following header files
68 #
69 #
70 AC_CONFIG_HEADER(mk/config.h)
71
72 # No, semi-sadly, we don't do `--srcdir'...
73 if test x"$srcdir" != 'x.' ; then
74     echo "This configuration does not support the \`--srcdir' option.."
75     exit 1
76 fi
77
78 dnl --------------------------------------------------------------
79 dnl * Project specific configuration options
80 dnl --------------------------------------------------------------
81 dnl What follows is a bunch of options that can either be configured
82 dnl through command line options to the configure script or by
83 dnl supplying defns in the build tree's mk/build.mk. Having the option to
84 dnl use either is considered a Feature.
85
86 dnl ** What command to use to compile compiler sources ?
87 dnl --------------------------------------------------------------
88
89 AC_ARG_WITH([ghc],
90 [AC_HELP_STRING([--with-ghc=ARG],
91   [Use ARG as the path to GHC  [default=autodetect]])],
92   [WithGhc="$withval"],
93   [if test "$GHC" = ""; then
94     AC_PATH_PROG([GHC], [ghc])
95   fi
96   WithGhc="$GHC"])
97
98 dnl ** Tell the make system which OS we are using
99 dnl $OSTYPE is set by the operating system to "msys" or "cygwin" or something
100 AC_SUBST(OSTYPE)
101
102 AC_ARG_ENABLE(bootstrap-with-devel-snapshot,
103 [AC_HELP_STRING([--enable-bootstrap-with-devel-snapshot],
104                 [Allow bootstrapping using a development snapshot of GHC.  This is not guaranteed to work.])],
105         EnableBootstrapWithDevelSnaphost=YES,
106         EnableBootstrapWithDevelSnaphost=NO
107 )
108
109 AC_ARG_ENABLE(tarballs-autodownload,
110 [AC_HELP_STRING([--enable-tarballs-autodownload],
111                 [Automatically download Windows distribution binaries if needed.])],
112         TarballsAutodownload=YES,
113         TarballsAutodownload=NO
114 )
115
116 dnl CC_STAGE0 is like the "previous" variable CC (inherited by CC_STAGE[123])
117 dnl but instead used by stage0 for bootstrapping stage1
118 AC_ARG_VAR(CC_STAGE0, [C compiler command (bootstrap)])
119
120 if test "$WithGhc" != ""; then
121   FPTOOLS_GHC_VERSION([GhcVersion], [GhcMajVersion], [GhcMinVersion], [GhcPatchLevel])dnl
122
123   if test "$GhcMajVersion" = "unknown" -o "$GhcMinVersion" = "unknown"; then
124      AC_MSG_ERROR([Cannot determine the version of $WithGhc.  Is it really GHC?])
125   fi
126
127   AC_SUBST(GhcVersion)dnl
128   AC_SUBST(GhcMajVersion)dnl
129   AC_SUBST(GhcMinVersion)dnl
130   AC_SUBST(GhcPatchLevel)dnl
131   GhcMinVersion2=`echo "$GhcMinVersion" | sed 's/^\\(.\\)$/0\\1/'`
132   GhcCanonVersion="$GhcMajVersion$GhcMinVersion2"
133
134   dnl infer CC_STAGE0 from `ghc --info` unless explicitly set by user
135   if test -z "$CC_STAGE0"; then
136     BOOTSTRAPPING_GHC_INFO_FIELD([CC_STAGE0],[C compiler command])
137   fi
138
139   BOOTSTRAPPING_GHC_INFO_FIELD([LD_STAGE0],[ld command])
140   BOOTSTRAPPING_GHC_INFO_FIELD([AR_STAGE0],[ar command])
141   BOOTSTRAPPING_GHC_INFO_FIELD([AR_OPTS_STAGE0],[ar flags])
142   BOOTSTRAPPING_GHC_INFO_FIELD([ArSupportsAtFile_STAGE0],[ar supports at file])
143 fi
144
145 dnl ** Must have GHC to build GHC
146 if test "$WithGhc" = ""
147 then
148     AC_MSG_ERROR([GHC is required.])
149 fi
150 FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[7.10],
151     [AC_MSG_ERROR([GHC version 7.10 or later is required to compile GHC.])])
152
153 if test `expr $GhcMinVersion % 2` = "1"
154 then
155     if test "$EnableBootstrapWithDevelSnaphost" = "NO"
156     then
157         AC_MSG_ERROR([
158      $WithGhc is a development snapshot of GHC, version $GhcVersion.
159      Bootstrapping using this version of GHC is not supported, and may not
160      work.  Use --enable-bootstrap-with-devel-snapshot to try it anyway,
161      or --with-ghc to specify a different GHC to use.])
162     fi
163 fi
164
165 GHC_PACKAGE_DB_FLAG=package-db
166 AC_SUBST(GHC_PACKAGE_DB_FLAG)
167
168 FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[7.11],
169                     SUPPORTS_THIS_UNIT_ID=NO,
170                     SUPPORTS_THIS_UNIT_ID=YES)
171 AC_SUBST(SUPPORTS_THIS_UNIT_ID)
172
173 # GHC is passed to Cabal, so we need a native path
174 if test "${WithGhc}" != ""
175 then
176     ghc_host_os=`"${WithGhc}" +RTS --info | grep 'Host OS' | sed -e 's/.*, "//' -e 's/")//'`
177
178     if test "$ghc_host_os" = "mingw32"
179     then
180         # Canonicalise to <drive>:/path/to/ghc
181         WithGhc=`cygpath -m "${WithGhc}"`
182
183         echo "GHC path canonicalised to: ${WithGhc}"
184     fi
185 fi
186 AC_SUBST([WithGhc])
187
188 dnl ** Without optimization some INLINE trickery fails for GHCi
189 SRC_CC_OPTS="-O"
190
191 dnl--------------------------------------------------------------------
192 dnl * Choose host(/target/build) platform
193 dnl--------------------------------------------------------------------
194 dnl If we aren't explicitly told what values to use with configure flags,
195 dnl we ask the bootstrapping compiler what platform it is for
196
197 if test "${WithGhc}" != ""
198 then
199         bootstrap_host=`"${WithGhc}" +RTS --info | grep '^ ,("Host platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
200         bootstrap_target=`"${WithGhc}" +RTS --info | grep '^ ,("Target platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
201         if test "$bootstrap_host" != "$bootstrap_target"
202         then
203                 echo "Bootstrapping GHC is a cross compiler. This probably isn't going to work"
204         fi
205 fi
206
207 # We have to run these unconditionally, but we may discard their
208 # results in the following code
209 AC_CANONICAL_BUILD
210 AC_CANONICAL_HOST
211 AC_CANONICAL_TARGET
212
213 FPTOOLS_SET_PLATFORM_VARS
214
215 # Verify that the installed (bootstrap) GHC is capable of generating
216 # code for the requested build platform.
217 if test "$BuildPlatform" != "$bootstrap_target"
218 then
219     echo "This GHC (${WithGhc}) does not generate code for the build platform"
220     echo "   GHC target platform    : $bootstrap_target"
221     echo "   Desired build platform : $BuildPlatform"
222     exit 1
223 fi
224
225 # Testing if we shall enable shared libs support on Solaris.
226 # Anything older than SunOS 5.11 aka Solaris 11 (Express) is broken.
227
228 SOLARIS_BROKEN_SHLD=NO
229
230 case $host in
231      i386-*-solaris2)
232      # here we go with the test
233      MINOR=`uname -r|cut -d '.' -f 2-`
234      if test "$MINOR" -lt "11"; then
235          SOLARIS_BROKEN_SHLD=YES
236      fi
237      ;;
238 esac
239
240 AC_SUBST(SOLARIS_BROKEN_SHLD)
241
242 dnl ** Do an unregisterised build?
243 dnl --------------------------------------------------------------
244 case "$HostArch" in
245     i386|x86_64|powerpc|powerpc64|powerpc64le|arm)
246         UnregisterisedDefault=NO
247         ;;
248     *)
249         UnregisterisedDefault=YES
250         ;;
251 esac
252 AC_ARG_ENABLE(unregisterised,
253 [AC_HELP_STRING([--enable-unregisterised],
254 [Build an unregisterised compiler (enabled by default on platforms without registerised support) [default="$UnregisterisedDefault"]])],
255 [ if test x"$enableval" = x"yes"; then
256         Unregisterised=YES
257   else
258         Unregisterised=NO
259   fi
260 ],
261 [Unregisterised="$UnregisterisedDefault"]
262 )
263 AC_SUBST(Unregisterised)
264
265 # Requires FPTOOLS_SET_PLATFORM_VARS to be run first.
266 FP_FIND_ROOT
267
268 fail() {
269     echo >&2
270     echo "$1" >&2
271     exit 1
272 }
273
274
275 if test "$HostOS" = "mingw32"
276 then
277     # Find the mingw-w64 7z file to extract.
278     # NB. If you update the tarballs to a new version of gcc, don't
279     # forget to tweak the paths in driver/gcc/gcc.c.
280     if test "$HostArch" = "i386"
281     then
282         mingw_arch="i686"
283         tarball_dest_dir="mingw-w64/x86"
284         tarball_mingw_dir="mingw32"
285     else
286         mingw_arch="x86_64"
287         tarball_dest_dir="mingw-w64/x86_64"
288         tarball_mingw_dir="mingw64"
289     fi
290 fi
291
292 set_up_tarballs() {
293     AC_MSG_NOTICE([Checking for Windows toolchain tarballs...])
294     local action
295     if test "$TarballsAutodownload" = "NO"
296     then
297         action="verify"
298     else
299         action="download"
300     fi
301     mk/get-win32-tarballs.sh $action $HostArch > missing-win32-tarballs
302     case $? in
303         0)
304            rm missing-win32-tarballs
305            ;;
306         2)
307            echo
308            echo "Error:"
309            echo "Needed msys2 tarballs are missing. You have a few options to get them,"
310            echo
311            echo "  * run configure with the --enable-tarballs-autodownload option"
312            echo
313            echo "  * run mk/get-win32-tarballs.sh download ${HostArch}"
314            echo
315            echo "  * manually download the files listed in ./missing-win32-tarballs and place"
316            echo "    them in the ghc-tarballs directory."
317            echo
318            exit 1
319            ;;
320         *)
321            echo
322            echo "Error fetching msys2 tarballs; see errors above."
323            exit 1
324            ;;
325     esac
326
327     # Extract all the tarballs in one go
328     if ! test -d inplace/mingw
329     then
330         AC_MSG_NOTICE([Extracting Windows toolchain from archives (may take a while)...])
331         rm -rf inplace/mingw
332         local base_dir="../ghc-tarballs/${tarball_dest_dir}"
333         ( cd inplace &&
334         find "${base_dir}" -name "*.tar.xz" -exec tar xfJ {} \; &&
335         rm ".MTREE" &&
336         rm ".PKGINFO" &&
337         cd .. ) || fail "Error: Could not extract Windows toolchains."
338
339         mv "inplace/${tarball_mingw_dir}" inplace/mingw &&
340         touch inplace/mingw
341
342         # NB. Now since the GCC is hardcoded to use /mingw32 we need to
343         # make a wrapper around it to give it the proper paths
344         mv inplace/mingw/bin/gcc.exe inplace/mingw/bin/realgcc.exe
345         PATH=`pwd`/inplace/mingw/bin:$PATH
346         inplace/mingw/bin/realgcc.exe driver/gcc/gcc.c driver/utils/cwrapper.c driver/utils/getLocation.c -Idriver/utils -o inplace/mingw/bin/gcc.exe
347
348         AC_MSG_NOTICE([In-tree MingW-w64 tree created])
349     fi
350 }
351
352 if test "$HostOS" = "mingw32"
353 then
354     test -d inplace || mkdir inplace
355
356     # NB. Download and extract the MingW-w64 distribution if required
357     set_up_tarballs
358
359     mingwbin="$hardtop/inplace/mingw/bin/"
360     CC="${mingwbin}gcc.exe"
361     LD="${mingwbin}ld.exe"
362     NM="${mingwbin}nm.exe"
363     RANLIB="${mingwbin}ranlib.exe"
364     OBJDUMP="${mingwbin}objdump.exe"
365     Windres="${mingwbin}windres.exe"
366     DllWrap="${mingwbin}dllwrap.exe"
367     fp_prog_ar="${mingwbin}ar.exe"
368
369     # NB. Download the perl binaries if required
370     if ! test -d inplace/perl ||
371          test inplace/perl -ot ghc-tarballs/perl/ghc-perl*.tar.gz
372     then
373         AC_MSG_NOTICE([Making in-tree perl tree])
374         rm -rf inplace/perl
375         mkdir inplace/perl
376         (
377             cd inplace/perl &&
378             tar -zxf ../../ghc-tarballs/perl/ghc-perl*.tar.gz
379         )
380         AC_MSG_NOTICE([In-tree perl tree created])
381     fi
382 fi
383
384 FP_ICONV
385 FP_GMP
386 FP_CURSES
387
388 XCODE_VERSION()
389
390 SplitObjsBroken=NO
391 if test "$TargetOS_CPP" = "darwin"
392 then
393     # Split objects is broken (#4013) with XCode < 3.2
394     if test "$XCodeVersion1" -lt 3
395     then
396         SplitObjsBroken=YES
397     else
398         if test "$XCodeVersion1" -eq 3
399         then
400             if test "$XCodeVersion2" -lt 2
401             then
402                 SplitObjsBroken=YES
403             fi
404         fi
405     fi
406 fi
407 AC_SUBST([SplitObjsBroken])
408
409 dnl ** Building a cross compiler?
410 dnl --------------------------------------------------------------
411 CrossCompiling=NO
412 # If 'host' and 'target' differ, then this means we are building a cross-compiler.
413 if test "$TargetPlatform" != "$HostPlatform" ; then
414     CrossCompiling=YES
415     cross_compiling=yes   # This tells configure that it can accept just 'target',
416                           # otherwise you get
417                           #   configure: error: cannot run C compiled programs.
418                           #   If you meant to cross compile, use `--host'.
419 fi
420 if test "$BuildPlatform" != "$HostPlatform" ; then
421    AC_MSG_ERROR([
422 You've selected:
423
424   BUILD:  $BuildPlatform   (the architecture we're building on)
425   HOST:   $HostPlatform    (the architecture the compiler we're building will execute on)
426   TARGET: $TargetPlatform  (the architecture the compiler we're building will produce code for)
427
428 BUILD must equal HOST; that is, we do not support building GHC itself
429 with a cross-compiler.  To cross-compile GHC itself, set TARGET: stage
430 1 will be a cross-compiler, and stage 2 will be the cross-compiled
431 GHC.
432 ])
433 fi
434 if test "$CrossCompiling" = "YES"
435 then
436   CrossCompilePrefix="${target}-"
437 else
438   CrossCompilePrefix=""
439 fi
440 TargetPlatformFull="${TargetPlatform}"
441 AC_SUBST(CrossCompiling)
442 AC_SUBST(CrossCompilePrefix)
443 AC_SUBST(TargetPlatformFull)
444
445 dnl ** Which gcc to use?
446 dnl --------------------------------------------------------------
447
448 AC_ARG_WITH([gcc],
449         AS_HELP_STRING([--with-gcc=ARG], [Use ARG as the path to gcc (obsolete, use CC=ARG instead) [default=autodetect]]),
450         AC_MSG_ERROR([--with-gcc=$withval is obsolete (use './configure CC=$withval' or 'CC=$withval ./configure' instead)]))
451
452 AC_ARG_WITH([clang],
453         AS_HELP_STRING([--with-clang=ARG], [Use ARG as the path to gcc (obsolete, use CC=ARG instead) [default=autodetect]]),
454         AC_MSG_ERROR([--with-clang=$withval is obsolete (use './configure CC=$withval' or 'CC=$withval ./configure' instead)]))
455
456 dnl detect compiler (prefer gcc over clang) and set $CC (unless CC already set),
457 dnl later CC is copied to CC_STAGE{1,2,3}
458 AC_PROG_CC([gcc clang])
459
460 MAYBE_OVERRIDE_STAGE0([ar],[AR_STAGE0])
461
462 dnl make extensions visible to allow feature-tests to detect them lateron
463 AC_USE_SYSTEM_EXTENSIONS
464
465 dnl ** figure out how to invoke the C preprocessor (i.e. `gcc -E`)
466 AC_PROG_CPP
467
468 # --with-hs-cpp/--with-hs-cpp-flags
469 FP_CPP_CMD_WITH_ARGS(HaskellCPPCmd, HaskellCPPArgs)
470 AC_SUBST([HaskellCPPCmd])
471 AC_SUBST([HaskellCPPArgs])
472
473 FP_SET_CFLAGS_C99([CC],[CFLAGS],[CPPFLAGS])
474 FP_SET_CFLAGS_C99([CC_STAGE0],[CONF_CC_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
475 FP_SET_CFLAGS_C99([CC],[CONF_CC_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
476 FP_SET_CFLAGS_C99([CC],[CONF_CC_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])
477
478 dnl ** Which ld to use?
479 dnl --------------------------------------------------------------
480 FIND_LD([LdCmd])
481 AC_SUBST([LdCmd])
482
483 dnl ** Which nm to use?
484 dnl --------------------------------------------------------------
485 FP_ARG_WITH_PATH_GNU_PROG([NM], [nm], [nm])
486
487 if test "$TargetOS_CPP" = "darwin"
488 then
489     AC_MSG_CHECKING(whether nm program is broken)
490     # Some versions of XCode ship a broken version of `nm`. Detect and work
491     # around this issue. See : https://ghc.haskell.org/trac/ghc/ticket/11744
492     nmver=$(${NM} --version | grep version | sed 's/ //g')
493     case "$nmver" in
494         LLVMversion7.3.0|LLVMversion7.3.1)
495             AC_MSG_RESULT(yes)
496             echo "The detected nm program is broken."
497             echo
498             echo "See: https://ghc.haskell.org/trac/ghc/ticket/11744"
499             echo
500             echo "Try re-running configure with:"
501             echo
502             echo '   ./configure --with-nm=$(xcrun --find nm-classic)'
503             echo
504             exit 1
505             ;;
506         *)
507             AC_MSG_RESULT(no)
508             ;;
509         esac
510 fi
511
512 NmCmd="$NM"
513 AC_SUBST([NmCmd])
514
515 dnl ** Which objdump to use?
516 dnl --------------------------------------------------------------
517 FP_ARG_WITH_PATH_GNU_PROG_OPTIONAL([OBJDUMP], [objdump], [objdump])
518 ObjdumpCmd="$OBJDUMP"
519 AC_SUBST([ObjdumpCmd])
520
521 dnl ** Which ar to use?
522 dnl --------------------------------------------------------------
523 FP_ARG_WITH_PATH_GNU_PROG([AR], [ar], [ar])
524 ArCmd="$AR"
525 fp_prog_ar="$AR"
526 AC_SUBST([ArCmd])
527
528 dnl ** Which ranlib to use?
529 dnl --------------------------------------------------------------
530 FP_ARG_WITH_PATH_GNU_PROG([RANLIB], [ranlib], [ranlib])
531 RanlibCmd="$RANLIB"
532 RANLIB="$RanlibCmd"
533
534
535 # Note: we may not have objdump on OS X, and we only need it on Windows (for DLL checks)
536 case $HostOS_CPP in
537 cygwin32|mingw32)
538     dnl ** Which objdump to use?
539     dnl --------------------------------------------------------------
540     FP_ARG_WITH_PATH_GNU_PROG([OBJDUMP], [objdump], [objdump])
541     ObjdumpCmd="$OBJDUMP"
542     AC_SUBST([ObjdumpCmd])
543     ;;
544 esac
545
546 # Here is where we re-target which specific version of the LLVM
547 # tools we are looking for. In the past, GHC supported a number of
548 # versions of LLVM simultaneously, but that stopped working around
549 # 3.5/3.6 release of LLVM.
550 LlvmVersion=3.8
551 AC_SUBST([LlvmVersion])
552 sUPPORTED_LLVM_VERSION=$(echo \($LlvmVersion\) | sed 's/\./,/')
553 AC_DEFINE_UNQUOTED([sUPPORTED_LLVM_VERSION], ${sUPPORTED_LLVM_VERSION}, [The supported LLVM version number])
554
555 dnl ** Which LLVM llc to use?
556 dnl --------------------------------------------------------------
557 FIND_LLVM_PROG([LLC], [llc], [llc], [$LlvmVersion])
558 LlcCmd="$LLC"
559 AC_SUBST([LlcCmd])
560
561 dnl ** Which LLVM opt to use?
562 dnl --------------------------------------------------------------
563 FIND_LLVM_PROG([OPT], [opt], [opt], [$LlvmVersion])
564 OptCmd="$OPT"
565 AC_SUBST([OptCmd])
566
567 dnl --------------------------------------------------------------
568 dnl End of configure script option section
569 dnl --------------------------------------------------------------
570
571
572 dnl --------------------------------------------------------------
573 dnl ** Can the unix package be built?
574 dnl --------------------------------------------------------------
575
576 if test "$TargetOS" = "mingw32"
577 then
578     GhcLibsWithUnix=NO
579 else
580     GhcLibsWithUnix=YES
581 fi
582 AC_SUBST([GhcLibsWithUnix])
583
584 dnl ** does #! work?
585 AC_SYS_INTERPRETER()
586
587 dnl ** look for `perl'
588 case $HostOS_CPP in
589 cygwin32|mingw32)
590     PerlCmd=$hardtop/inplace/perl/perl
591     ;;
592 *)
593     AC_PATH_PROG(PerlCmd,perl)
594     if test -z "$PerlCmd"
595     then
596         echo "You must install perl before you can continue"
597         echo "Perhaps it is already installed, but not in your PATH?"
598         exit 1
599     else
600         FPTOOLS_CHECK_PERL_VERSION
601     fi
602     ;;
603 esac
604
605 dnl ** look for GCC and find out which version
606 dnl     Figure out which C compiler to use.  Gcc is preferred.
607 dnl     If gcc, make sure it's at least 3.0
608 dnl
609 FP_GCC_VERSION
610
611 dnl ** See whether gcc supports -no-pie
612 FP_GCC_SUPPORTS_NO_PIE
613
614 dnl ** look to see if we have a C compiler using an llvm back end.
615 dnl
616 FP_CC_LLVM_BACKEND
617
618 FP_PROG_LD_IS_GNU
619 FP_PROG_LD_BUILD_ID
620 FP_PROG_LD_NO_COMPACT_UNWIND
621 FP_PROG_LD_FILELIST
622
623
624 FPTOOLS_SET_C_LD_FLAGS([target],[CFLAGS],[LDFLAGS],[IGNORE_LINKER_LD_FLAGS],[CPPFLAGS])
625 FPTOOLS_SET_C_LD_FLAGS([build],[CONF_CC_OPTS_STAGE0],[CONF_GCC_LINKER_OPTS_STAGE0],[CONF_LD_LINKER_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
626 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE1],[CONF_GCC_LINKER_OPTS_STAGE1],[CONF_LD_LINKER_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
627 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE2],[CONF_GCC_LINKER_OPTS_STAGE2],[CONF_LD_LINKER_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])
628 # Stage 3 won't be supported by cross-compilation
629
630 FP_GCC_EXTRA_FLAGS
631
632 # See rules/distdir-way-opts.mk for details.
633 # Flags passed to the C compiler
634 AC_SUBST(CONF_CC_OPTS_STAGE0)
635 AC_SUBST(CONF_CC_OPTS_STAGE1)
636 AC_SUBST(CONF_CC_OPTS_STAGE2)
637 # Flags passed to the C compiler when we ask it to link
638 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE0)
639 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE1)
640 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE2)
641 # Flags passed to the linker when we ask it to link
642 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE0)
643 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE1)
644 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE2)
645 # Flags passed to the C preprocessor
646 AC_SUBST(CONF_CPP_OPTS_STAGE0)
647 AC_SUBST(CONF_CPP_OPTS_STAGE1)
648 AC_SUBST(CONF_CPP_OPTS_STAGE2)
649 # Flags passed to the Haskell compiler
650 AC_SUBST(CONF_HC_OPTS_STAGE0)
651 AC_SUBST(CONF_HC_OPTS_STAGE1)
652 AC_SUBST(CONF_HC_OPTS_STAGE2)
653
654 dnl ** Set up the variables for the platform in the settings file.
655 dnl May need to use gcc to find platform details.
656 dnl --------------------------------------------------------------
657 FPTOOLS_SET_HASKELL_PLATFORM_VARS
658
659 dnl ** figure out how to do context diffs
660 FP_PROG_CONTEXT_DIFF
661
662 dnl Let's make sure install-sh is executable here.  If we got it from
663 dnl a darcs repo, it might not be (see bug #978).
664 chmod +x install-sh
665 dnl ** figure out how to do a BSD-ish install
666 AC_PROG_INSTALL
667
668 dnl ** how to invoke `ar' and `ranlib'
669 FP_PROG_AR_SUPPORTS_ATFILE
670 FP_PROG_AR_NEEDS_RANLIB
671
672 dnl ** Check to see whether ln -s works
673 AC_PROG_LN_S
674
675 FP_SETTINGS
676
677 dnl ** Find the path to sed
678 AC_PATH_PROGS(SedCmd,gsed sed,sed)
679
680
681 dnl ** check for time command
682 AC_PATH_PROG(TimeCmd,time)
683
684 dnl ** check for tar
685 dnl   if GNU tar is named gtar, look for it first.
686 AC_PATH_PROGS(TarCmd,gnutar gtar tar,tar)
687
688 dnl ** check for patch
689 dnl if GNU patch is named gpatch, look for it first
690 AC_PATH_PROGS(PatchCmd,gpatch patch, patch)
691
692 dnl ** check for dtrace (currently only implemented for Mac OS X)
693 HaveDtrace=NO
694 AC_PATH_PROG(DtraceCmd,dtrace)
695 if test -n "$DtraceCmd"; then
696   if test "x$TargetOS_CPP-$TargetVendor_CPP" = "xdarwin-apple" -o "x$TargetOS_CPP-$TargetVendor_CPP" = "xsolaris2-unknown"; then
697     HaveDtrace=YES
698   fi
699 fi
700 AC_SUBST(HaveDtrace)
701
702 AC_PATH_PROG(HSCOLOUR,HsColour)
703 # HsColour is passed to Cabal, so we need a native path
704 if test "$HostOS"      = "mingw32" && \
705    test "${HSCOLOUR}" != ""
706 then
707     # Canonicalise to <drive>:/path/to/gcc
708     HSCOLOUR=`cygpath -m ${HSCOLOUR}`
709 fi
710
711 dnl ** check for Sphinx toolchain
712 AC_PATH_PROG(SPHINXBUILD,sphinx-build)
713 AC_CACHE_CHECK([for version of sphinx-build], fp_cv_sphinx_version,
714 changequote(, )dnl
715 [if test -n "$SPHINXBUILD"; then
716   fp_cv_sphinx_version=`"$SPHINXBUILD" --version 2>&1 | sed 's/Sphinx\( (sphinx-build)\)\? v\?\([0-9]\.[0-9]\.[0-9]\)/\2/' | head -n1`;
717 fi;
718 changequote([, ])dnl
719 ])
720 FP_COMPARE_VERSIONS([$fp_cv_sphinx_version],-lt,1.0.0,
721     [AC_MSG_WARN([Sphinx version 1.0.0 or later is required to build documentation]); SPHINXBUILD=;])
722
723 dnl ** check for xelatex
724 AC_PATH_PROG(XELATEX,xelatex)
725
726 dnl ** check for ghc-pkg command
727 FP_PROG_GHC_PKG
728
729 dnl ** check for installed happy binary + version
730 FPTOOLS_HAPPY
731
732 dnl ** check for installed alex binary + version
733 FPTOOLS_ALEX
734
735 dnl --------------------------------------------------
736 dnl ### program checking section ends here ###
737 dnl --------------------------------------------------
738
739 dnl --------------------------------------------------
740 dnl * Platform header file and syscall feature tests
741 dnl ### checking the state of the local header files and syscalls ###
742
743 dnl ** check for full ANSI header (.h) files
744 AC_HEADER_STDC
745
746 dnl ** Enable large file support.  NB. do this before testing the type of
747 dnl    off_t, because it will affect the result of that test.
748 AC_SYS_LARGEFILE
749
750 dnl ** check for specific header (.h) files that we are interested in
751 AC_CHECK_HEADERS([ctype.h dirent.h dlfcn.h errno.h fcntl.h grp.h limits.h locale.h nlist.h pthread.h pwd.h signal.h sys/param.h sys/mman.h sys/resource.h sys/select.h sys/time.h sys/timeb.h sys/timerfd.h sys/timers.h sys/times.h sys/utsname.h sys/wait.h termios.h time.h utime.h windows.h winsock.h sched.h])
752
753 dnl sys/cpuset.h needs sys/param.h to be included first on FreeBSD 9.1; #7708
754 AC_CHECK_HEADERS([sys/cpuset.h], [], [],
755 [[#if HAVE_SYS_PARAM_H
756 # include <sys/param.h>
757 #endif
758 ]])
759
760 dnl ** check if it is safe to include both <time.h> and <sys/time.h>
761 AC_HEADER_TIME
762
763 dnl ** do we have long longs?
764 AC_CHECK_TYPES([long long])
765
766 dnl ** what are the sizes of various types
767 FP_CHECK_SIZEOF_AND_ALIGNMENT(char)
768 FP_CHECK_SIZEOF_AND_ALIGNMENT(double)
769 FP_CHECK_SIZEOF_AND_ALIGNMENT(float)
770 FP_CHECK_SIZEOF_AND_ALIGNMENT(int)
771 FP_CHECK_SIZEOF_AND_ALIGNMENT(long)
772 if test "$ac_cv_type_long_long" = yes; then
773 FP_CHECK_SIZEOF_AND_ALIGNMENT(long long)
774 fi
775 FP_CHECK_SIZEOF_AND_ALIGNMENT(short)
776 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned char)
777 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned int)
778 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned long)
779 if test "$ac_cv_type_long_long" = yes; then
780 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned long long)
781 fi
782 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned short)
783 FP_CHECK_SIZEOF_AND_ALIGNMENT(void *)
784
785 FP_CHECK_SIZEOF_AND_ALIGNMENT(int8_t)
786 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint8_t)
787 FP_CHECK_SIZEOF_AND_ALIGNMENT(int16_t)
788 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint16_t)
789 FP_CHECK_SIZEOF_AND_ALIGNMENT(int32_t)
790 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint32_t)
791 FP_CHECK_SIZEOF_AND_ALIGNMENT(int64_t)
792 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint64_t)
793
794
795 dnl for use in settings.in
796 WordSize=$ac_cv_sizeof_void_p
797 AC_SUBST(WordSize)
798 FP_CHECK_FUNC([WinExec],
799   [@%:@include <windows.h>], [WinExec("",0)])
800
801 FP_CHECK_FUNC([GetModuleFileName],
802   [@%:@include <windows.h>], [GetModuleFileName((HMODULE)0,(LPTSTR)0,0)])
803
804 dnl ** check for more functions
805 dnl ** The following have been verified to be used in ghc/, but might be used somewhere else, too.
806 AC_CHECK_FUNCS([getclock getrusage gettimeofday setitimer siginterrupt sysconf times ctime_r sched_setaffinity setlocale])
807
808 dnl ** On OS X 10.4 (at least), time.h doesn't declare ctime_r if
809 dnl ** _POSIX_C_SOURCE is defined
810 AC_CHECK_DECLS([ctime_r], , ,
811 [#define _POSIX_SOURCE 1
812 #define _POSIX_C_SOURCE 199506L
813 #include <time.h>])
814
815 dnl ** check for mingwex library
816 AC_CHECK_LIB(mingwex, closedir, HaveLibMingwEx=YES, HaveLibMingwEx=NO)
817 AC_SUBST(HaveLibMingwEx)
818
819 if test $HaveLibMingwEx = YES ; then
820   AC_DEFINE([HAVE_MINGWEX], [1], [Define to 1 if you have the mingwex library.])
821 fi
822
823 dnl ** check for math library
824 dnl    Keep that check as early as possible.
825 dnl    as we need to know whether we need libm
826 dnl    for math functions or not
827 dnl    (see http://ghc.haskell.org/trac/ghc/ticket/3730)
828 AC_CHECK_LIB(m, atan, HaveLibM=YES, HaveLibM=NO)
829 if test $HaveLibM = YES
830 then
831   AC_DEFINE([HAVE_LIBM], [1], [Define to 1 if you need to link with libm])
832 fi
833
834 FP_BFD_SUPPORT
835
836 dnl ################################################################
837 dnl Check for libraries
838 dnl ################################################################
839
840 # system libffi
841
842 AC_ARG_WITH([system-libffi],
843 [AC_HELP_STRING([--with-system-libffi],
844   [Use system provided libffi for RTS [default=no]])
845 ])
846
847 AS_IF([test "x$with_system_libffi" = "xyes"],
848   [UseSystemLibFFI="YES"], [UseSystemLibFFI="NO"]
849 )
850
851
852 AC_SUBST(UseSystemLibFFI)
853
854 AC_ARG_WITH([ffi-includes],
855 [AC_HELP_STRING([--with-ffi-includes=ARG],
856   [Find includes for libffi in ARG [default=system default]])
857 ],
858 [
859  if test "x$UseSystemLibFFI" != "xYES"; then
860     AC_MSG_WARN([--with-ffi-includes will be ignored, --with-system-libffi not set])
861  else
862     FFIIncludeDir="$withval"
863     LIBFFI_CFLAGS="-I$withval"
864  fi
865 ])
866
867 AC_SUBST(FFIIncludeDir)
868
869 AC_ARG_WITH([ffi-libraries],
870 [AC_HELP_STRING([--with-ffi-libraries=ARG],
871   [Find libffi in ARG [default=system default]])
872 ],
873 [
874  if test "x$UseSystemLibFFI" != "xYES"; then
875     AC_MSG_WARN([--with-ffi-libraries will be ignored, --with-system-libffi not set])
876  else
877     FFILibDir="$withval" LIBFFI_LDFLAGS="-L$withval"
878  fi
879 ])
880
881 AC_SUBST(FFILibDir)
882
883 AS_IF([test "$UseSystemLibFFI" = "YES"], [
884  CFLAGS2="$CFLAGS"
885  CFLAGS="$LIBFFI_CFLAGS $CFLAGS"
886  LDFLAGS2="$LDFLAGS"
887  LDFLAGS="$LIBFFI_LDFLAGS $LDFLAGS"
888  if test "$HostOS" = "openbsd";
889  then
890    # OpenBSD's libffi is not directly linked to the libpthread but
891    # still requires pthread functionality. This means that any client
892    # binary which links with libffi also needs to link with
893    # libpthread. If it does not, then linking fails with unresolved
894    # symbols.
895    LDFLAGS="$LDFLAGS -lpthread"
896  fi
897  AC_CHECK_LIB(ffi, ffi_call,
898   [AC_CHECK_HEADERS([ffi.h], [break], [])
899    AC_DEFINE([HAVE_LIBFFI], [1], [Define to 1 if you have libffi.])],
900   [AC_MSG_ERROR([Cannot find system libffi])])
901  CFLAGS="$CFLAGS2"
902  LDFLAGS="$LDFLAGS2"
903 ])
904
905 dnl ** check whether we need -ldl to get dlopen()
906 AC_CHECK_LIB(dl, dlopen)
907
908 dnl --------------------------------------------------
909 dnl * Miscellaneous feature tests
910 dnl --------------------------------------------------
911
912 dnl ** can we get alloca?
913 AC_FUNC_ALLOCA
914
915 dnl ** working vfork?
916 AC_FUNC_FORK
917
918 dnl ** determine whether or not const works
919 AC_C_CONST
920
921 dnl ** are we big endian?
922 AC_C_BIGENDIAN
923 FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN
924
925 dnl ** check for leading underscores in symbol names
926 FP_LEADING_UNDERSCORE
927
928 FP_VISIBILITY_HIDDEN
929
930 dnl ** check for librt
931 AC_CHECK_LIB(rt, clock_gettime)
932 AC_CHECK_FUNCS(clock_gettime timer_settime)
933 FP_CHECK_TIMER_CREATE
934
935 dnl ** check for Apple's "interesting" long double compatibility scheme
936 AC_MSG_CHECKING(for printf\$LDBLStub)
937 AC_TRY_LINK_FUNC(printf\$LDBLStub,
938     [
939         AC_MSG_RESULT(yes)
940         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[1],
941             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
942     ],
943     [
944         AC_MSG_RESULT(no)
945         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[0],
946             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
947     ])
948
949 dnl ** pthread_setname_np is a recent addition to glibc, and OS X has
950 dnl    a different single-argument version.
951 AC_CHECK_LIB(pthread, pthread_setname_np)
952 AC_MSG_CHECKING(for pthread_setname_np)
953 AC_TRY_LINK(
954 [
955 #define _GNU_SOURCE
956 #include <pthread.h>
957 ],
958 [pthread_setname_np(pthread_self(), "name");],
959     AC_MSG_RESULT(yes)
960     AC_DEFINE([HAVE_PTHREAD_SETNAME_NP], [1],
961       [Define to 1 if you have the glibc version of pthread_setname_np]),
962     AC_MSG_RESULT(no)
963 )
964
965 dnl ** check for eventfd which is needed by the I/O manager
966 AC_CHECK_HEADERS([sys/eventfd.h])
967 AC_CHECK_FUNCS([eventfd])
968
969 dnl ** Check for __thread support in the compiler
970 AC_MSG_CHECKING(for __thread support)
971 AC_COMPILE_IFELSE(
972   [ AC_LANG_SOURCE([[__thread int tester = 0;]]) ],
973   [
974    AC_MSG_RESULT(yes)
975    AC_DEFINE([CC_SUPPORTS_TLS],[1],[Define to 1 if __thread is supported])
976   ],
977   [
978    AC_MSG_RESULT(no)
979    AC_DEFINE([CC_SUPPORTS_TLS],[0],[Define to 1 if __thread is supported])
980   ])
981
982 dnl large address space support (see includes/rts/storage/MBlock.h)
983 dnl
984 dnl Darwin has vm_allocate/vm_protect
985 dnl Linux has mmap(MAP_NORESERVE)/madv(MADV_DONTNEED)
986 dnl FreeBSD, Solaris and maybe other have MAP_NORESERVE/MADV_FREE
987 dnl (They also have MADV_DONTNEED, but it means something else!)
988 dnl
989 dnl Windows has VirtualAlloc MEM_RESERVE/MEM_COMMIT, however
990 dnl it counts page-table space as committed memory, and so quickly
991 dnl runs out of paging file when we have multiple processes reserving
992 dnl 1TB of address space, we get the following error:
993 dnl    VirtualAlloc MEM_RESERVE 1099512676352 bytes failed: The paging file is too small for this operation to complete.
994 dnl
995
996 AC_ARG_ENABLE(large-address-space,
997     [AC_HELP_STRING([--enable-large-address-space],
998         [Use a single large address space on 64 bit systems (enabled by default on 64 bit platforms)])],
999     EnableLargeAddressSpace=$enableval,
1000     EnableLargeAddressSpace=yes
1001 )
1002
1003 use_large_address_space=no
1004 if test "$ac_cv_sizeof_void_p" -eq 8 ; then
1005     if test "x$EnableLargeAddressSpace" = "xyes" ; then
1006         if test "$ghc_host_os" = "darwin" ; then
1007             use_large_address_space=yes
1008         elif test "$ghc_host_os" = "openbsd" ; then
1009             # as of OpenBSD 5.8 (2015), OpenBSD does not support mmap with MAP_NORESERVE.
1010             # The flag MAP_NORESERVE is supported for source compatibility reasons,
1011             # but is completely ignored by OS mmap
1012             use_large_address_space=no
1013         else
1014             AC_CHECK_DECLS([MAP_NORESERVE, MADV_FREE, MADV_DONTNEED],[],[],
1015                 [
1016                 #include <unistd.h>
1017                 #include <sys/types.h>
1018                 #include <sys/mman.h>
1019                 #include <fcntl.h>
1020             ])
1021             if test "$ac_cv_have_decl_MAP_NORESERVE" = "yes" &&
1022                 test "$ac_cv_have_decl_MADV_FREE" = "yes" ||
1023                 test "$ac_cv_have_decl_MADV_DONTNEED" = "yes" ; then
1024                     use_large_address_space=yes
1025             fi
1026         fi
1027     fi
1028 fi
1029 if test "$use_large_address_space" = "yes" ; then
1030    AC_DEFINE([USE_LARGE_ADDRESS_SPACE], [1], [Enable single heap address space support])
1031 fi
1032
1033 dnl ** Use MMAP in the runtime linker?
1034 dnl --------------------------------------------------------------
1035
1036 case ${TargetOS} in
1037     linux|freebsd|dragonfly|netbsd|openbsd|kfreebsdgnu|gnu|solaris2)
1038         RtsLinkerUseMmap=1
1039         ;;
1040     darwin)
1041         # Don't use mmap on powerpc/darwin as the mmap there doesn't support
1042         # reallocating. Reallocating is needed to allocate jump islands just
1043         # after each object image. Jumps to these jump islands use relative
1044         # branches which are limited to offsets that can be represented in
1045         # 24-bits.
1046         if test "$TargetArch" != "powerpc" ; then
1047             RtsLinkerUseMmap=1
1048         else
1049             RtsLinkerUseMmap=0
1050         fi
1051         ;;
1052     *)
1053         # Windows (which doesn't have mmap) and everything else.
1054         RtsLinkerUseMmap=0
1055         ;;
1056     esac
1057
1058 AC_DEFINE_UNQUOTED([RTS_LINKER_USE_MMAP], [$RtsLinkerUseMmap],
1059                    [Use mmap in the runtime linker])
1060
1061 dnl ** Have libdw?
1062 dnl --------------------------------------------------------------
1063 UseLibdw=NO
1064 USE_LIBDW=0
1065 AC_ARG_ENABLE(dwarf-unwind,
1066     [AC_HELP_STRING([--enable-dwarf-unwind],
1067         [Enable DWARF unwinding support in the runtime system via elfutils' libdw [default=no]])],
1068     [AC_CHECK_LIB(dw, dwfl_attach_state, [UseLibdw=YES], [UseLibdw=NO])],
1069     [UseLibdw=NO]
1070 )
1071 AC_SUBST(UseLibdw)
1072 if test $UseLibdw = "YES" ; then
1073         USE_LIBDW=1
1074 fi
1075 AC_DEFINE_UNQUOTED([USE_LIBDW], [$USE_LIBDW], [Set to 1 to use libdw])
1076
1077 dnl ** Have libnuma?
1078 dnl --------------------------------------------------------------
1079 HaveLibNuma=0
1080 AC_CHECK_HEADERS([numa.h numaif.h])
1081
1082 if test "$ac_cv_header_numa_h$ac_cv_header_numaif_h" = "yesyes" ; then
1083     AC_CHECK_LIB(numa, numa_available,HaveLibNuma=1)
1084 fi
1085 AC_DEFINE_UNQUOTED([HAVE_LIBNUMA], [$HaveLibNuma], [Define to 1 if you have libnuma])
1086
1087 dnl ** Documentation
1088 dnl --------------------------------------------------------------
1089 if test -n "$SPHINXBUILD"; then
1090     BUILD_MAN=YES
1091     BUILD_SPHINX_HTML=YES
1092     if test -n "$XELATEX"; then
1093         BUILD_SPHINX_PDF=YES
1094     else
1095         BUILD_SPHINX_PDF=NO
1096     fi
1097 else
1098     BUILD_MAN=NO
1099     BUILD_SPHINX_HTML=NO
1100     BUILD_SPHINX_PDF=NO
1101 fi
1102 AC_SUBST(BUILD_MAN)
1103 AC_SUBST(BUILD_SPHINX_HTML)
1104 AC_SUBST(BUILD_SPHINX_PDF)
1105
1106 LIBRARY_VERSION(base)
1107 LIBRARY_VERSION(Cabal, Cabal/Cabal)
1108 LIBRARY_VERSION(ghc-prim)
1109 LIBRARY_ghc_VERSION="$ProjectVersion"
1110 AC_SUBST(LIBRARY_ghc_VERSION)
1111
1112 if grep '       ' compiler/ghc.cabal.in 2>&1 >/dev/null; then
1113    AC_MSG_ERROR([compiler/ghc.cabal.in contains tab characters; please remove them])
1114 fi
1115
1116 # Create the configuration for the Hadrian build system if it is present
1117 if test -e hadrian/cfg/system.config.in; then
1118     AC_CONFIG_FILES([hadrian/cfg/system.config])
1119 fi
1120
1121 # We got caught by
1122 #     http://savannah.gnu.org/bugs/index.php?1516
1123 #     $(eval ...) inside conditionals causes errors
1124 # with make 3.80, so warn the user if it looks like they're about to
1125 # try to use it.
1126 # We would use "grep -q" here, but Solaris's grep doesn't support it.
1127 print_make_warning=""
1128 checkMake380() {
1129     make_ver=`$1 --version 2>&1 | head -1`
1130     if echo "$make_ver" | grep 'GNU Make 3\.80' > /dev/null
1131     then
1132         print_make_warning="true"
1133     fi
1134     if echo "$make_ver" | grep 'GNU Make' > /dev/null
1135     then
1136         MakeCmd=$1
1137         AC_SUBST(MakeCmd)
1138     fi
1139 }
1140
1141 checkMake380 make
1142 checkMake380 gmake
1143
1144 AC_CONFIG_FILES([mk/config.mk mk/install.mk mk/project.mk compiler/ghc.cabal ghc/ghc-bin.cabal utils/runghc/runghc.cabal libraries/ghc-boot/ghc-boot.cabal libraries/ghc-boot-th/ghc-boot-th.cabal libraries/ghci/ghci.cabal settings docs/users_guide/ghc_config.py docs/index.html libraries/prologue.txt distrib/configure.ac])
1145 AC_OUTPUT
1146
1147 if test "$print_make_warning" = "true"; then
1148    echo
1149    echo "WARNING: It looks like \"$MakeCmd\" is GNU make 3.80."
1150    echo "This version cannot be used to build GHC."
1151    echo "Please use GNU make >= 3.81."
1152 fi
1153
1154 echo ["
1155 ----------------------------------------------------------------------
1156 Configure completed successfully.
1157
1158    Building GHC version  : $ProjectVersion
1159           Git commit id  : $ProjectGitCommitId
1160
1161    Build platform        : $BuildPlatform
1162    Host platform         : $HostPlatform
1163    Target platform       : $TargetPlatform
1164 "]
1165
1166 echo ["\
1167    Bootstrapping using   : $WithGhc
1168       which is version   : $GhcVersion
1169 "]
1170
1171 if test "x$CC_LLVM_BACKEND" = "x1"; then
1172     if test "x$CC_CLANG_BACKEND" = "x1"; then
1173         CompilerName="clang        "
1174     else
1175         CompilerName="llvm-gcc     "
1176     fi
1177 else
1178     CompilerName="gcc          "
1179 fi
1180
1181 echo ["\
1182    Using (for bootstrapping) : $CC_STAGE0
1183    Using $CompilerName       : $CC
1184       which is version       : $GccVersion
1185    Building a cross compiler : $CrossCompiling
1186    Unregisterised            : $Unregisterised
1187    hs-cpp       : $HaskellCPPCmd
1188    hs-cpp-flags : $HaskellCPPArgs
1189    ld           : $LdCmd
1190    nm           : $NmCmd
1191    objdump      : $ObjdumpCmd
1192    Happy        : $HappyCmd ($HappyVersion)
1193    Alex         : $AlexCmd ($AlexVersion)
1194    Perl         : $PerlCmd
1195    sphinx-build : $SPHINXBUILD
1196    xelatex      : $XELATEX
1197
1198    Using LLVM tools
1199       llc   : $LlcCmd
1200       opt   : $OptCmd"]
1201
1202 if test "$HSCOLOUR" = ""; then
1203 echo ["
1204    HsColour was not found; documentation will not contain source links
1205 "]
1206 else
1207 echo ["\
1208    HsColour : $HSCOLOUR
1209 "]
1210 fi
1211
1212 echo ["\
1213    Tools to build Sphinx HTML documentation available: $BUILD_SPHINX_HTML
1214    Tools to build Sphinx PDF documentation available: $BUILD_SPHINX_PDF"]
1215
1216 echo ["----------------------------------------------------------------------
1217 "]
1218
1219 echo "\
1220 For a standard build of GHC (fully optimised with profiling), type (g)make.
1221
1222 To make changes to the default build configuration, copy the file
1223 mk/build.mk.sample to mk/build.mk, and edit the settings in there.
1224
1225 For more information on how to configure your GHC build, see
1226    http://ghc.haskell.org/trac/ghc/wiki/Building
1227 "