Change the ranlib detection
[ghc.git] / configure.ac
1 dnl == autoconf source for the Glasgow FP tools ==
2 dnl (run "grep '^dnl \*' configure.ac | sed -e 's/dnl / /g; s/\*\*/   +/g;'"
3 dnl  (or some such) to see the outline of this file)
4 dnl
5 #
6 # (c) The University of Glasgow 1994-2012
7 #
8 # Configure script template for GHC
9 #
10 # Process with 'autoreconf' to get a working configure script.
11 #
12 # For the generated configure script, do "./configure --help" to
13 # see what flags are available. (Better yet, read the documentation!)
14 #
15
16 AC_INIT([The Glorious Glasgow Haskell Compilation System], [7.7], [glasgow-haskell-bugs@haskell.org], [ghc])
17
18 # Set this to YES for a released version, otherwise NO
19 : ${RELEASE=NO}
20
21 # The primary version (e.g. 7.5, 7.4.1) is set in the AC_INIT line
22 # above.  If this is not a released version, then we will append the
23 # date to the version number (e.g. 7.4.20111220).  The date is
24 # constructed by finding the date of the most recent patch in the
25 # git repository.  If this is a source distribution (not a git
26 # checkout), then we ship a file 'VERSION' containing the full version
27 # when the source distribution was created.
28
29 if test ! -f mk/config.h.in; then
30    echo "mk/config.h.in doesn't exist: perhaps you haven't run 'perl boot'?"
31    exit 1
32 fi
33
34 AC_SUBST([CONFIGURE_ARGS], [$ac_configure_args])
35
36 dnl ----------------------------------------------------------
37 dnl ** Find unixy sort and find commands, 
38 dnl ** which are needed by FP_SETUP_PROJECT_VERSION
39
40 dnl ** Find find command (for Win32's benefit)
41 FP_PROG_FIND
42 FP_PROG_SORT
43
44 dnl ----------------------------------------------------------
45 FP_SETUP_PROJECT_VERSION
46
47 # Hmmm, we fix the RPM release number to 1 here... Is this convenient?
48 AC_SUBST([release], [1])
49
50 # First off, a distrib sanity check..
51 AC_CONFIG_SRCDIR([mk/config.mk.in])
52
53 dnl * We require autoconf version 2.60
54 dnl We need 2.50 due to the use of AC_SYS_LARGEFILE and AC_MSG_NOTICE.
55 dnl We need 2.52 due to the use of AS_TR_CPP and AS_TR_SH.
56 dnl Using autoconf 2.59 started to give nonsense like this
57 dnl  #define SIZEOF_CHAR 0
58 dnl recently.
59 AC_PREREQ([2.60])
60
61 # -------------------------------------------------------------------------
62 # Prepare to generate the following header files
63 #
64 #
65 AC_CONFIG_HEADER(mk/config.h)
66
67 # No, semi-sadly, we don't do `--srcdir'...
68 if test x"$srcdir" != 'x.' ; then
69     echo "This configuration does not support the \`--srcdir' option.."
70     exit 1
71 fi
72
73 dnl --------------------------------------------------------------
74 dnl * Project specific configuration options
75 dnl --------------------------------------------------------------
76 dnl What follows is a bunch of options that can either be configured
77 dnl through command line options to the configure script or by
78 dnl supplying defns in the build tree's mk/build.mk. Having the option to
79 dnl use either is considered a Feature.
80
81 dnl ** What command to use to compile compiler sources ?
82 dnl --------------------------------------------------------------
83
84 AC_ARG_WITH([ghc],
85 [AC_HELP_STRING([--with-ghc=ARG],
86   [Use ARG as the path to GHC  [default=autodetect]])],
87   [WithGhc="$withval"],
88   [if test "$GHC" = ""; then
89     AC_PATH_PROG([GHC], [ghc])
90   fi
91   WithGhc="$GHC"])
92
93 dnl ** Tell the make system which OS we are using
94 dnl $OSTYPE is set by the operating system to "msys" or "cygwin" or something 
95 AC_SUBST(OSTYPE)
96
97 AC_ARG_ENABLE(bootstrap-with-devel-snapshot,
98 [AC_HELP_STRING([--enable-bootstrap-with-devel-snapshot],
99                 [Allow bootstrapping using a development snapshot of GHC.  This is not guaranteed to work.])],
100         EnableBootstrapWithDevelSnaphost=YES,
101         EnableBootstrapWithDevelSnaphost=NO
102 )
103
104 if test "$WithGhc" != ""; then
105   FPTOOLS_GHC_VERSION([GhcVersion], [GhcMajVersion], [GhcMinVersion], [GhcPatchLevel])dnl
106
107   if test "$GhcMajVersion" = "unknown" -o "$GhcMinVersion" = "unknown"; then
108      AC_MSG_ERROR([Cannot determine the version of $WithGhc.  Is it really GHC?])
109   fi
110
111   AC_SUBST(GhcVersion)dnl
112   AC_SUBST(GhcMajVersion)dnl
113   AC_SUBST(GhcMinVersion)dnl
114   AC_SUBST(GhcPatchLevel)dnl
115   GhcMinVersion2=`echo "$GhcMinVersion" | sed 's/^\\(.\\)$/0\\1/'`
116   GhcCanonVersion="$GhcMajVersion$GhcMinVersion2"
117
118   BOOTSTRAPPING_GHC_INFO_FIELD([OS_STAGE0],[target os])
119   BOOTSTRAPPING_GHC_INFO_FIELD([CC_STAGE0],[C compiler command])
120   dnl ToDo, once "ld command" is reliably available.
121   dnl Then, we can remove the LD_STAGE0 hack in mk/build-package-date.mk
122   dnl BOOTSTRAPPING_GHC_INFO_FIELD([LD_STAGE0],[ld command])
123   if test "x$OS_STAGE0" != "xOSDarwin"; then
124     BOOTSTRAPPING_GHC_INFO_FIELD([AR_STAGE0],[ar command])
125     BOOTSTRAPPING_GHC_INFO_FIELD([AR_OPTS_STAGE0],[ar flags])
126     BOOTSTRAPPING_GHC_INFO_FIELD([ArSupportsAtFile_STAGE0],[ar supports at file])
127   else
128     AR_STAGE0='$(AR)'
129     AR_OPTS_STAGE0='$(AR_OPTS)'
130     ArSupportsAtFile_STAGE0='$(ArSupportsAtFile)'
131   fi
132 fi
133
134 dnl ** Must have GHC to build GHC
135 if test "$WithGhc" = ""
136 then
137     AC_MSG_ERROR([GHC is required.])
138 fi
139 FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[7.4],
140     [AC_MSG_ERROR([GHC version 7.4 or later is required to compile GHC.])])dnl
141
142 if test `expr $GhcMinVersion % 2` = "1"
143 then
144     if test "$EnableBootstrapWithDevelSnaphost" = "NO"
145     then
146         AC_MSG_ERROR([
147      $WithGhc is a development snapshot of GHC, version $GhcVersion.
148      Bootstrapping using this version of GHC is not supported, and may not
149      work.  Use --enable-bootstrap-with-devel-snapshot to try it anyway,
150      or --with-ghc to specify a different GHC to use.])
151     fi
152 fi
153
154 FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[7.5],
155                     GHC_PACKAGE_DB_FLAG=package-conf,
156                     GHC_PACKAGE_DB_FLAG=package-db)
157 AC_SUBST(GHC_PACKAGE_DB_FLAG)
158
159 # GHC is passed to Cabal, so we need a native path
160 if test "${WithGhc}" != ""
161 then
162     ghc_host_os=`"${WithGhc}" +RTS --info | grep 'Host OS' | sed -e 's/.*, "//' -e 's/")//'`
163
164     if test "$ghc_host_os" = "mingw32"
165     then
166         if test "${OSTYPE}" = "msys"
167         then
168             WithGhc=`echo "${WithGhc}" | sed "s#^/\([a-zA-Z]\)/#\1:/#"`
169         else
170             # Canonicalise to <drive>:/path/to/ghc
171             WithGhc=`cygpath -m "${WithGhc}"`
172         fi
173         echo "GHC path canonicalised to: ${WithGhc}"
174     fi
175 fi
176 AC_SUBST([WithGhc])
177
178 dnl ** Without optimization some INLINE trickery fails for GHCi
179 SRC_CC_OPTS="-O"
180
181 dnl--------------------------------------------------------------------
182 dnl * Choose host(/target/build) platform
183 dnl--------------------------------------------------------------------
184 dnl If we aren't explicitly told what values to use with configure flags,
185 dnl we ask the bootstrapping compiler what platform it is for
186
187 if test "${WithGhc}" != ""
188 then
189         bootstrap_host=`"${WithGhc}" +RTS --info | grep '^ ,("Host platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
190         bootstrap_target=`"${WithGhc}" +RTS --info | grep '^ ,("Target platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
191         if test "$bootstrap_host" != "$bootstrap_target"
192         then
193                 echo "Bootstrapping GHC is a cross compiler. This probably isn't going to work"
194         fi
195 fi
196
197 # We have to run these unconditionally, but we may discard their
198 # results in the following code
199 AC_CANONICAL_BUILD
200 AC_CANONICAL_HOST
201 AC_CANONICAL_TARGET
202
203 FPTOOLS_SET_PLATFORM_VARS
204
205 # Verify that the installed (bootstrap) GHC is capable of generating
206 # code for the requested build platform.
207 if test "$BuildPlatform" != "$bootstrap_target"
208 then
209     echo "This GHC (${WithGhc}) does not generate code for the build platform"
210     echo "   GHC target platform    : $bootstrap_target"
211     echo "   Desired build platform : $BuildPlatform"
212     exit 1
213 fi
214
215 # Testing if we shall enable shared libs support on Solaris.
216 # Anything older than SunOS 5.11 aka Solaris 11 (Express) is broken.
217
218 SOLARIS_BROKEN_SHLD=NO
219
220 case $host in
221      i386-*-solaris2)
222      # here we go with the test
223      MINOR=`uname -r|cut -d '.' -f 2-`
224      if test "$MINOR" -lt "11"; then
225         SOLARIS_BROKEN_SHLD=YES
226      fi
227      ;;
228 esac
229
230 AC_SUBST(SOLARIS_BROKEN_SHLD)
231
232 dnl ** Do an unregisterised build?
233 dnl --------------------------------------------------------------
234 case "$HostArch" in
235     i386|x86_64|powerpc|arm)
236         UnregisterisedDefault=NO
237         ;;
238     *)
239         UnregisterisedDefault=YES
240         ;;
241 esac
242 AC_ARG_ENABLE(unregisterised,
243 [AC_HELP_STRING([--enable-unregisterised],
244 [Build an unregisterised compiler (enabled by default on platforms without registerised support) [default="$UnregisterisedDefault"]])],
245 [ if test x"$enableval" = x"yes"; then
246         Unregisterised=YES
247   else
248         Unregisterised=NO
249   fi
250 ],
251 [Unregisterised="$UnregisterisedDefault"]
252 )
253 AC_SUBST(Unregisterised)
254
255 AC_ARG_WITH(hc,
256 [AC_HELP_STRING([--with-hc=ARG],
257         [Use ARG as the path to the compiler for compiling ordinary
258          Haskell code  (default= value of --with-ghc)])],
259 [WithHc="$withval"],
260 [WithHc=$WithGhc]
261 )
262 AC_SUBST(WithHc)
263
264 # This uses GHC, so put it after the "GHC is required" check above:
265 FP_INTREE_GHC_PWD
266 FP_FIND_ROOT
267
268 if test "$HostOS" = "mingw32"
269 then
270     test -d inplace || mkdir inplace
271
272     if test "$HostArch" = "i386"
273     then
274         # NB. If you update the tarballs to a new version of gcc, don't
275         # forget to tweak the paths in driver/gcc/gcc.c.
276         if ! test -d inplace/mingw ||
277              test inplace/mingw -ot ghc-tarballs/mingw/binutils*.tar.lzma  ||
278              test inplace/mingw -ot ghc-tarballs/mingw/gcc-core*.tar.lzma  ||
279              test inplace/mingw -ot ghc-tarballs/mingw/gcc-c++*.tar.lzma   ||
280              test inplace/mingw -ot ghc-tarballs/mingw/libgcc*.tar.gz      ||
281              test inplace/mingw -ot ghc-tarballs/mingw/libgmp*.tar.gz      ||
282              test inplace/mingw -ot ghc-tarballs/mingw/libmpc*.tar.gz      ||
283              test inplace/mingw -ot ghc-tarballs/mingw/libmpfr*.tar.gz     ||
284              test inplace/mingw -ot ghc-tarballs/mingw/libstdc*.tar.lzma   ||
285              test inplace/mingw -ot ghc-tarballs/mingw/mingwrt*-dev.tar.gz ||
286              test inplace/mingw -ot ghc-tarballs/mingw/mingwrt*-dll.tar.gz ||
287              test inplace/mingw -ot ghc-tarballs/mingw/w32api*.tar.lzma
288         then
289             AC_MSG_NOTICE([Making in-tree mingw tree])
290             rm -rf inplace/mingw
291             mkdir inplace/mingw
292             (
293                 cd inplace/mingw &&
294                 tar --lzma -xf ../../ghc-tarballs/mingw/binutils*.tar.lzma  &&
295                 tar --lzma -xf ../../ghc-tarballs/mingw/gcc-core*.tar.lzma  &&
296                 tar --lzma -xf ../../ghc-tarballs/mingw/gcc-c++*.tar.lzma   &&
297                 tar --lzma -xf ../../ghc-tarballs/mingw/libgcc*.tar.lzma    &&
298                 tar --lzma -xf ../../ghc-tarballs/mingw/libgmp*.tar.lzma    &&
299                 tar --lzma -xf ../../ghc-tarballs/mingw/libmpc*.tar.lzma    &&
300                 tar --lzma -xf ../../ghc-tarballs/mingw/libmpfr*.tar.lzma   &&
301                 tar --lzma -xf ../../ghc-tarballs/mingw/libstdc*.tar.lzma   &&
302                 tar -z     -xf ../../ghc-tarballs/mingw/mingwrt*-dev.tar.gz &&
303                 tar -z     -xf ../../ghc-tarballs/mingw/mingwrt*-dll.tar.gz &&
304                 tar --lzma -xf ../../ghc-tarballs/mingw/w32api*.tar.lzma    &&
305                 mv bin/gcc.exe bin/realgcc.exe
306             )
307             PATH=`pwd`/inplace/mingw/bin:$PATH inplace/mingw/bin/realgcc.exe driver/gcc/gcc.c driver/utils/cwrapper.c driver/utils/getLocation.c -Idriver/utils -o inplace/mingw/bin/gcc.exe
308             AC_MSG_NOTICE([In-tree mingw tree created])
309         fi
310     else
311         # NB. If you update the tarballs to a new version of gcc, don't
312         # forget to tweak the paths in driver/gcc/gcc.c.
313         if ! test -d inplace/mingw ||
314              test inplace/mingw -ot ghc-tarballs/mingw64/*.tar.bz2
315         then
316             AC_MSG_NOTICE([Making in-tree mingw tree])
317             rm -rf inplace/mingw
318             mkdir inplace/mingw
319             (
320                 cd inplace/mingw &&
321                 tar -jxf ../../ghc-tarballs/mingw64/*.tar.bz2
322             )
323             AC_MSG_NOTICE([In-tree mingw tree created])
324         fi
325     fi
326
327     mingwbin="$hardtop/inplace/mingw/bin/"
328     CC="${mingwbin}gcc.exe"
329     LD="${mingwbin}ld.exe"
330     NM="${mingwbin}nm.exe"
331     RANLIB="${mingwbin}ranlib.exe"
332     OBJDUMP="${mingwbin}objdump.exe"
333     fp_prog_ar="${mingwbin}ar.exe"
334
335     if ! test -d inplace/perl ||
336          test inplace/perl -ot ghc-tarballs/perl/ghc-perl*.tar.gz
337     then
338         AC_MSG_NOTICE([Making in-tree perl tree])
339         rm -rf inplace/perl
340         mkdir inplace/perl
341         (
342             cd inplace/perl &&
343             tar -zxf ../../ghc-tarballs/perl/ghc-perl*.tar.gz
344         )
345         AC_MSG_NOTICE([In-tree perl tree created])
346     fi
347 fi
348
349 # system libffi
350
351 AC_ARG_WITH([system-libffi],
352 [AC_HELP_STRING([--with-system-libffi],
353   [Use system provided libffi for RTS [default=no]])
354 ])
355
356 AS_IF([test "x$with_system_libffi" = "xyes"],
357   [UseSystemLibFFI="YES"], [UseSystemLibFFI="NO"]
358 )
359
360
361 AC_SUBST(UseSystemLibFFI)
362
363 AC_ARG_WITH([ffi-includes],
364 [AC_HELP_STRING([--with-ffi-includes=ARG]
365   [Find includes for libffi in ARG [default=system default]])
366 ],
367 [
368  if test "x$UseSystemLibFFI" != "xYES"; then
369     AC_MSG_WARN([--with-ffi-includes will be ignored, --with-system-libffi not set])
370  else
371     FFIIncludeDir="$withval"
372     LIBFFI_CFLAGS="-I $withval" 
373  fi
374 ])
375
376 AC_SUBST(FFIIncludeDir)
377
378 AC_ARG_WITH([ffi-libraries],
379 [AC_HELP_STRING([--with-ffi-libraries=ARG]
380   [Find libffi in ARG [default=system default]])
381 ],
382 [
383  if test "x$UseSystemLibFFI" != "xYES"; then
384     AC_MSG_WARN([--with-ffi-libraries will be ignored, --with-system-libffi not set])
385  else
386     FFILibDir="$withval" LIBFFI_LDFLAGS="-L$withval"
387  fi
388 ])
389
390 AC_SUBST(FFILibDir)
391
392 AS_IF([test "$UseSystemLibFFI" = "YES"], [
393  CFLAGS2="$CFLAGS"
394  CFLAGS="$LIBFFI_CFLAGS $CFLAGS"
395  LDFLAGS2="$LDFLAGS"
396  LDFLAGS="$LIBFFI_LDFLAGS $LDFLAGS"
397  AC_CHECK_LIB(ffi, ffi_call,
398   [AC_CHECK_HEADERS([ffi.h], [break], [])
399    AC_DEFINE([HAVE_LIBFFI], [1], [Define to 1 if you have libffi.])],
400   [AC_MSG_ERROR([Cannot find system libffi])])
401  CFLAGS="$CFLAGS2"
402  LDFLAGS="$LDFLAGS2"
403 ])
404
405 FP_ICONV
406 FP_GMP
407
408 XCODE_VERSION()
409
410 SplitObjsBroken=NO
411 if test "$TargetOS_CPP" = "darwin"
412 then
413     # Split objects is broken (#4013) with XCode < 3.2
414     if test "$XCodeVersion1" -lt 3
415     then
416         SplitObjsBroken=YES
417     else
418         if test "$XCodeVersion1" -eq 3
419         then
420             if test "$XCodeVersion2" -lt 2
421             then
422                 SplitObjsBroken=YES
423             fi
424         fi
425     fi
426 fi
427 AC_SUBST([SplitObjsBroken])
428
429 dnl ** Building a cross compiler?
430 dnl --------------------------------------------------------------
431 CrossCompiling=NO
432 # If 'host' and 'target' differ, then this means we are building a cross-compiler.
433 if test "$target" != "$host" ; then
434     CrossCompiling=YES
435     cross_compiling=yes   # This tells configure that it can accept just 'target',
436                           # otherwise you get
437                           #   configure: error: cannot run C compiled programs.
438                           #   If you meant to cross compile, use `--host'.
439 fi
440 if test "$build" != "$host" ; then
441    AC_MSG_ERROR([
442 You've selected:
443
444   BUILD:  $build   (the architecture we're building on)
445   HOST:   $host    (the architecture the compiler we're building will execute on)
446   TARGET: $target  (the architecture the compiler we're building will produce code for)
447
448 BUILD must equal HOST; that is, we do not support building GHC itself
449 with a cross-compiler.  To cross-compile GHC itself, set TARGET: stage
450 1 will be a cross-compiler, and stage 2 will be the cross-compiled
451 GHC.
452 ])
453 fi
454 if test "$CrossCompiling" = "YES"
455 then
456   CrossCompilePrefix="${target}-"
457 else
458   CrossCompilePrefix=""
459 fi
460 TargetPlatformFull="${target}"
461 AC_SUBST(CrossCompiling)
462 AC_SUBST(CrossCompilePrefix)
463 AC_SUBST(TargetPlatformFull)
464
465 dnl ** Which gcc to use?
466 dnl --------------------------------------------------------------
467 FIND_GCC([WhatGccIsCalled], [gcc], [gcc])
468 CC="$WhatGccIsCalled"
469 export CC
470
471 dnl ** Which ld to use?
472 dnl --------------------------------------------------------------
473 FP_ARG_WITH_PATH_GNU_PROG([LD], [ld], [ld])
474 LdCmd="$LD"
475 AC_SUBST([LdCmd])
476
477 dnl ** Which nm to use?
478 dnl --------------------------------------------------------------
479 FP_ARG_WITH_PATH_GNU_PROG([NM], [nm], [nm])
480 NmCmd="$NM"
481 AC_SUBST([NmCmd])
482
483 # Note: we may not have objdump on OS X, and we only need it on Windows (for DLL checks)
484 case $HostOS_CPP in
485 cygwin32|mingw32)
486     dnl ** Which objdump to use?
487     dnl --------------------------------------------------------------
488     FP_ARG_WITH_PATH_GNU_PROG([OBJDUMP], [objdump], [objdump])
489     ObjdumpCmd="$OBJDUMP"
490     AC_SUBST([ObjdumpCmd])
491     ;;
492 esac
493
494 dnl ** Which LLVM llc to use?
495 dnl --------------------------------------------------------------
496 FIND_LLVM_PROG([LLC], [llc], [llc])
497 LlcCmd="$LLC"
498 AC_SUBST([LlcCmd])
499
500 dnl ** Which LLVM opt to use?
501 dnl --------------------------------------------------------------
502 FIND_LLVM_PROG([OPT], [opt], [opt])
503 OptCmd="$OPT"
504 AC_SUBST([OptCmd])
505
506 dnl --------------------------------------------------------------
507 dnl End of configure script option section
508 dnl --------------------------------------------------------------
509
510
511 dnl --------------------------------------------------------------
512 dnl * General configuration checks
513 dnl --------------------------------------------------------------
514
515 dnl ** Can the unix package be built?
516 dnl --------------------------------------------------------------
517
518 if test "$TargetOS" = "mingw32"
519 then
520     GhcLibsWithUnix=NO
521 else
522     GhcLibsWithUnix=YES
523 fi
524 AC_SUBST([GhcLibsWithUnix])
525
526 dnl ** does #! work?
527 AC_SYS_INTERPRETER()
528
529 dnl ** look for `perl'
530 case $HostOS_CPP in
531 cygwin32|mingw32)
532     PerlCmd=$hardtop/inplace/perl/perl
533     ;;
534 *)
535     AC_PATH_PROG(PerlCmd,perl)
536     if test -z "$PerlCmd"
537     then
538         echo "You must install perl before you can continue"
539         echo "Perhaps it is already installed, but not in your PATH?"
540         exit 1
541     else
542         FPTOOLS_CHECK_PERL_VERSION
543     fi
544     ;;
545 esac
546
547 dnl ** look for GCC and find out which version
548 dnl     Figure out which C compiler to use.  Gcc is preferred.
549 dnl     If gcc, make sure it's at least 3.0
550 dnl
551 FP_GCC_VERSION
552
553 dnl ** look to see if we have a C compiler using an llvm back end.
554 dnl
555 FP_CC_LLVM_BACKEND
556
557 FP_PROG_LD_IS_GNU
558 FP_PROG_LD_BUILD_ID
559 FP_PROG_LD_NO_COMPACT_UNWIND
560 FP_PROG_LD_FILELIST
561
562
563 FPTOOLS_SET_C_LD_FLAGS([target],[CFLAGS],[LDFLAGS],[IGNORE_LINKER_LD_FLAGS],[CPPFLAGS])
564 FPTOOLS_SET_C_LD_FLAGS([build],[CONF_CC_OPTS_STAGE0],[CONF_GCC_LINKER_OPTS_STAGE0],[CONF_LD_LINKER_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
565 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE1],[CONF_GCC_LINKER_OPTS_STAGE1],[CONF_LD_LINKER_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
566 # Stage 3 won't be supported by cross-compilation
567 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE2],[CONF_GCC_LINKER_OPTS_STAGE2],[CONF_LD_LINKER_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])
568
569 FP_GCC_EXTRA_FLAGS
570
571 dnl ** figure out how to invoke cpp directly (gcc -E is no good)
572 AC_PROG_CPP
573
574 AC_SUBST(CONF_CC_OPTS_STAGE0)
575 AC_SUBST(CONF_CC_OPTS_STAGE1)
576 AC_SUBST(CONF_CC_OPTS_STAGE2)
577 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE0)
578 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE1)
579 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE2)
580 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE0)
581 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE1)
582 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE2)
583 AC_SUBST(CONF_CPP_OPTS_STAGE0)
584 AC_SUBST(CONF_CPP_OPTS_STAGE1)
585 AC_SUBST(CONF_CPP_OPTS_STAGE2)
586
587 dnl ** Set up the variables for the platform in the settings file.
588 dnl May need to use gcc to find platform details.
589 dnl --------------------------------------------------------------
590 FPTOOLS_SET_HASKELL_PLATFORM_VARS
591
592 dnl ** figure out how to do context diffs
593 FP_PROG_CONTEXT_DIFF
594
595 dnl Let's make sure install-sh is executable here.  If we got it from
596 dnl a darcs repo, it might not be (see bug #978).
597 chmod +x install-sh
598 dnl ** figure out how to do a BSD-ish install
599 AC_PROG_INSTALL
600
601 dnl If you can run configure, you certainly have /bin/sh
602 AC_DEFINE([HAVE_BIN_SH], [1], [Define to 1 if you have /bin/sh.])
603
604 dnl ** how to invoke `ar' and `ranlib'
605 FP_PROG_AR_SUPPORTS_ATFILE
606 FP_PROG_AR_NEEDS_RANLIB
607
608 dnl ** Check to see whether ln -s works
609 AC_PROG_LN_S
610
611 FP_SETTINGS
612
613 dnl ** Find the path to sed
614 AC_PATH_PROGS(SedCmd,gsed sed,sed)
615
616
617 dnl ** check for time command
618 AC_PATH_PROG(TimeCmd,time)
619
620 dnl ** check for tar
621 dnl   if GNU tar is named gtar, look for it first.
622 AC_PATH_PROGS(TarCmd,gnutar gtar tar,tar)
623
624 dnl ** check for patch
625 dnl if GNU patch is named gpatch, look for it first
626 AC_PATH_PROGS(PatchCmd,gpatch patch, patch)
627
628 dnl ** check for dtrace (currently only implemented for Mac OS X)
629 HaveDtrace=NO
630 AC_PATH_PROG(DtraceCmd,dtrace)
631 if test -n "$DtraceCmd"; then
632   if test "x$TargetOS_CPP-$TargetVendor_CPP" = "xdarwin-apple" -o "x$TargetOS_CPP-$TargetVendor_CPP" = "xsolaris2-unknown"; then
633     HaveDtrace=YES
634   fi
635 fi
636 AC_SUBST(HaveDtrace)
637
638 AC_PATH_PROG(HSCOLOUR,HsColour)
639 # HsColour is passed to Cabal, so we need a native path
640 if test "$HostOS"      = "mingw32" && \
641    test "${OSTYPE}"   != "msys"    && \
642    test "${HSCOLOUR}" != ""
643 then
644     # Canonicalise to <drive>:/path/to/gcc
645     HSCOLOUR=`cygpath -m ${HSCOLOUR}`
646 fi
647
648 dnl ** check for DocBook toolchain
649 FP_CHECK_DOCBOOK_DTD
650 FP_DOCBOOK_XSL
651 FP_PROG_DBLATEX
652
653 dnl ** check for ghc-pkg command
654 FP_PROG_GHC_PKG
655
656 dnl ** check for installed happy binary + version
657 FPTOOLS_HAPPY
658
659 dnl ** check for installed alex binary + version
660 FPTOOLS_ALEX
661
662 dnl --------------------------------------------------
663 dnl ### program checking section ends here ###
664 dnl --------------------------------------------------
665
666 dnl --------------------------------------------------
667 dnl * Platform header file and syscall feature tests
668 dnl ### checking the state of the local header files and syscalls ###
669
670 dnl ** check for full ANSI header (.h) files
671 AC_HEADER_STDC
672
673 dnl ** Enable large file support.  NB. do this before testing the type of
674 dnl    off_t, because it will affect the result of that test.
675 AC_SYS_LARGEFILE
676
677 dnl ** check for specific header (.h) files that we are interested in
678 AC_CHECK_HEADERS([bfd.h ctype.h dirent.h dlfcn.h errno.h fcntl.h grp.h limits.h locale.h nlist.h pthread.h pwd.h signal.h sys/param.h sys/mman.h sys/resource.h sys/select.h sys/time.h sys/timeb.h sys/timers.h sys/times.h sys/utsname.h sys/wait.h termios.h time.h utime.h windows.h winsock.h sched.h])
679
680 dnl sys/cpuset.h needs sys/param.h to be included first on FreeBSD 9.1; #7708
681 AC_CHECK_HEADERS([sys/cpuset.h], [], [],
682 [[#if HAVE_SYS_PARAM_H
683 # include <sys/param.h>
684 #endif
685 ]])
686
687 dnl ** check if it is safe to include both <time.h> and <sys/time.h>
688 AC_HEADER_TIME
689
690 dnl ** do we have long longs?
691 AC_CHECK_TYPES([long long])
692
693 dnl ** what are the sizes of various types
694 AC_CHECK_SIZEOF(char,               1)
695 AC_CHECK_SIZEOF(double,             8)
696 AC_CHECK_SIZEOF(float,              4)
697 AC_CHECK_SIZEOF(int,                4)
698 AC_CHECK_SIZEOF(long,               4)
699 if test "$ac_cv_type_long_long" = yes; then
700 AC_CHECK_SIZEOF(long long,          8)
701 fi
702 AC_CHECK_SIZEOF(short,              2)
703 AC_CHECK_SIZEOF(unsigned char,      1)
704 AC_CHECK_SIZEOF(unsigned int,       4)
705 AC_CHECK_SIZEOF(unsigned long,      4)
706 if test "$ac_cv_type_long_long" = yes; then
707 AC_CHECK_SIZEOF(unsigned long long, 8)
708 fi
709 AC_CHECK_SIZEOF(unsigned short,     2)
710 AC_CHECK_SIZEOF(void *,             4)
711
712 dnl for use in settings.in
713 WordSize=$ac_cv_sizeof_void_p
714 AC_SUBST(WordSize)
715
716 dnl ** what are alignment constraints on various types
717 FP_CHECK_ALIGNMENT(char)
718 FP_CHECK_ALIGNMENT(double)
719 FP_CHECK_ALIGNMENT(float)
720 FP_CHECK_ALIGNMENT(int)
721 FP_CHECK_ALIGNMENT(long)
722 if test "$ac_cv_type_long_long" = yes; then
723 FP_CHECK_ALIGNMENT(long long)
724 fi
725 FP_CHECK_ALIGNMENT(short)
726 FP_CHECK_ALIGNMENT(unsigned char)
727 FP_CHECK_ALIGNMENT(unsigned int)
728 FP_CHECK_ALIGNMENT(unsigned long)
729 if test "$ac_cv_type_long_long" = yes; then
730 FP_CHECK_ALIGNMENT(unsigned long long)
731 fi
732 FP_CHECK_ALIGNMENT(unsigned short)
733 FP_CHECK_ALIGNMENT(void *)
734
735 FP_CHECK_FUNC([WinExec],
736   [@%:@include <windows.h>], [WinExec("",0)])
737
738 FP_CHECK_FUNC([GetModuleFileName],
739   [@%:@include <windows.h>], [GetModuleFileName((HMODULE)0,(LPTSTR)0,0)])
740
741 dnl ** check return type of signal handlers
742 dnl Foo: assumes we can use prototypes.
743 dnl On BCC, signal handlers have type "int(void)", elsewhere its "void(int)".
744 dnl AC_CACHE_CHECK([type of signal handlers], ac_cv_type_signal_handler,
745 dnl [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
746 dnl #include <signal.h>
747 dnl #ifdef signal
748 dnl #undef signal
749 dnl #endif
750 dnl void (*signal (int, void (*)(int)))(int);
751 dnl ]],
752 dnl [[int i;]])],
753 dnl [ac_cv_type_signal_handler=void_int],
754 dnl [ac_cv_type_signal_handler=int_void])])
755 dnl if test "$ac_cv_type_signal_handler" = void_int; then
756 dnl AC_DEFINE(VOID_INT_SIGNALS)
757 dnl fi
758
759 dnl On BCC, signal handlers have type "int(void)", elsewhere its "void(int)".
760 AC_TYPE_SIGNAL
761 if test "$ac_cv_type_signal" = void; then
762   AC_DEFINE([VOID_INT_SIGNALS], [1], [Define to 1 if signal handlers have type void (*)(int). Otherwise, they're assumed to have type int (*)(void).])
763 fi
764
765 dnl ** check for more functions
766 dnl ** The following have been verified to be used in ghc/, but might be used somewhere else, too.
767 AC_CHECK_FUNCS([getclock getrusage gettimeofday setitimer siginterrupt sysconf times ctime_r sched_setaffinity setlocale])
768
769 dnl ** On OS X 10.4 (at least), time.h doesn't declare ctime_r if
770 dnl ** _POSIX_C_SOURCE is defined
771 AC_CHECK_DECLS([ctime_r], , ,
772 [#define _POSIX_SOURCE 1
773 #define _POSIX_C_SOURCE 199506L
774 #include <time.h>])
775
776 dnl ** check for mingwex library
777 AC_CHECK_LIB(mingwex, closedir, HaveLibMingwEx=YES, HaveLibMingwEx=NO)
778 AC_SUBST(HaveLibMingwEx)
779
780 if test $HaveLibMingwEx = YES ; then
781   AC_DEFINE([HAVE_MINGWEX], [1], [Define to 1 if you have the mingwex library.])
782 fi
783
784 dnl ** check for math library
785 dnl    Keep that check as early as possible.
786 dnl    as we need to know whether we need libm
787 dnl    for math functions or not
788 dnl    (see http://hackage.haskell.org/trac/ghc/ticket/3730)
789 AC_CHECK_LIB(m, atan, HaveLibM=YES, HaveLibM=NO)
790 if test $HaveLibM = YES
791 then
792   AC_DEFINE([HAVE_LIBM], [1], [Define to 1 if you need to link with libm])
793 fi
794
795 dnl ** check whether this machine has BFD and libiberty installed (used for debugging)
796 dnl    the order of these tests matters: bfd needs libiberty
797 AC_CHECK_LIB(iberty, xmalloc)
798 AC_CHECK_LIB(bfd,    bfd_uncompress_section_contents)
799
800 dnl ################################################################
801 dnl Check for libraries
802 dnl ################################################################
803
804 dnl ** check whether we need -ldl to get dlopen()
805
806 AC_CHECK_LIB(dl, dlopen,
807     [HaveLibDL=YES
808      AC_DEFINE([HAVE_LIBDL], [1], [Define to 1 if you need -ldl to get dlopen().])
809      LIBS="$LIBS -ldl"],
810     [HaveLibDL=NO])
811 AC_SUBST(HaveLibDL)
812
813 dnl --------------------------------------------------
814 dnl * Miscellaneous feature tests
815 dnl --------------------------------------------------
816
817 dnl ** can we get alloca?
818 AC_FUNC_ALLOCA
819
820 dnl ** working vfork?
821 AC_FUNC_FORK
822
823 dnl ** determine whether or not const works
824 AC_C_CONST
825
826 dnl ** are we big endian?
827 AC_C_BIGENDIAN
828 FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN
829
830 dnl ** check for leading underscores in symbol names
831 FP_LEADING_UNDERSCORE
832
833 FP_VISIBILITY_HIDDEN
834
835 dnl ** check for librt
836 AC_CHECK_LIB(rt, clock_gettime)
837 AC_CHECK_FUNCS(clock_gettime timer_settime)
838 FP_CHECK_TIMER_CREATE
839
840 dnl ** check for Apple's "interesting" long double compatibility scheme
841 AC_MSG_CHECKING(for printf\$LDBLStub)
842 AC_TRY_LINK_FUNC(printf\$LDBLStub,
843     [
844         AC_MSG_RESULT(yes)
845         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[1],
846             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
847     ],
848     [
849         AC_MSG_RESULT(no)
850         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[0],
851             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
852     ])
853
854 dnl ** check for eventfd which is needed by the I/O manager
855 AC_CHECK_HEADERS([sys/eventfd.h])
856 AC_CHECK_FUNCS([eventfd])
857
858 # checking for PAPI
859 AC_CHECK_LIB(papi, PAPI_library_init, HavePapiLib=YES, HavePapiLib=NO)
860 AC_CHECK_HEADER([papi.h], [HavePapiHeader=YES], [HavePapiHeader=NO])
861 AC_SUBST(HavePapiLib)
862 AC_SUBST(HavePapiHeader)
863
864 AC_CHECK_FUNCS(__mingw_vfprintf)
865
866 if test "$HavePapiLib" = "YES" -a "$HavePapiHeader" = "YES"; then
867    HavePapi=YES
868 else
869    HavePapi=NO
870 fi
871 AC_SUBST(HavePapi)
872
873 if test "$HAVE_DOCBOOK_XSL" = "NO" ||
874    test "$XsltprocCmd" = ""
875 then
876     BUILD_DOCBOOK_HTML=NO
877 else
878     BUILD_DOCBOOK_HTML=YES
879 fi
880 AC_SUBST(BUILD_DOCBOOK_HTML)
881
882 if test "$DblatexCmd" = ""
883 then
884     BUILD_DOCBOOK_PS=NO
885     BUILD_DOCBOOK_PDF=NO
886 else
887     BUILD_DOCBOOK_PS=YES
888     BUILD_DOCBOOK_PDF=YES
889 fi
890 AC_SUBST(BUILD_DOCBOOK_PS)
891 AC_SUBST(BUILD_DOCBOOK_PDF)
892
893 LIBRARY_VERSION(base)
894 LIBRARY_VERSION(Cabal, Cabal/Cabal)
895 LIBRARY_VERSION(ghc-prim)
896 LIBRARY_ghc_VERSION="$ProjectVersion"
897 AC_SUBST(LIBRARY_ghc_VERSION)
898
899 if grep '       ' compiler/ghc.cabal.in 2>&1 >/dev/null; then
900    AC_MSG_ERROR([compiler/ghc.cabal.in contains tab characters; please remove them])
901 fi
902
903 AC_CONFIG_FILES([mk/config.mk mk/install.mk mk/project.mk compiler/ghc.cabal ghc/ghc-bin.cabal utils/runghc/runghc.cabal settings docs/users_guide/ug-book.xml docs/users_guide/ug-ent.xml docs/index.html libraries/prologue.txt distrib/configure.ac])
904 AC_OUTPUT
905
906 # We got caught by
907 #     http://savannah.gnu.org/bugs/index.php?1516
908 #     $(eval ...) inside conditionals causes errors
909 # with make 3.80, so warn the user if it looks like they're about to
910 # try to use it.
911 # We would use "grep -q" here, but Solaris's grep doesn't support it.
912 checkMake380() {
913     if $1 --version 2>&1 | head -1 | grep 'GNU Make 3\.80' > /dev/null
914     then
915         echo
916         echo "WARNING: It looks like \"$1\" is GNU make 3.80."
917         echo "This version cannot be used to build GHC."
918         echo "Please use GNU make >= 3.81."
919     fi
920 }
921
922 checkMake380 make
923 checkMake380 gmake
924
925 echo ["
926 ----------------------------------------------------------------------
927 Configure completed successfully.
928
929    Building GHC version  : $ProjectVersion
930
931    Build platform        : $BuildPlatform
932    Host platform         : $HostPlatform
933    Target platform       : $TargetPlatform
934 "]
935
936 echo ["\
937    Bootstrapping using   : $WithGhc
938       which is version   : $GhcVersion
939 "]
940
941 if test "x$CC_LLVM_BACKEND" = "x1"; then
942     if test "x$CC_CLANG_BACKEND" = "x1"; then
943         CompilerName="clang        "
944     else
945         CompilerName="llvm-gcc     "
946     fi
947 else
948     CompilerName="gcc          "
949 fi
950
951 echo ["\
952    Using $CompilerName       : $WhatGccIsCalled
953       which is version       : $GccVersion
954    Building a cross compiler : $CrossCompiling
955
956    ld       : $LdCmd
957    Happy    : $HappyCmd ($HappyVersion)
958    Alex     : $AlexCmd ($AlexVersion)
959    Perl     : $PerlCmd
960    dblatex  : $DblatexCmd
961    xsltproc : $XsltprocCmd
962
963    Using LLVM tools
964       llc   : $LlcCmd
965       opt   : $OptCmd"]
966
967 if test "$HSCOLOUR" = ""; then
968 echo ["
969    HsColour was not found; documentation will not contain source links
970 "]
971 else
972 echo ["\
973    HsColour : $HSCOLOUR
974 "]
975 fi
976
977 echo ["\
978    Building DocBook HTML documentation : $BUILD_DOCBOOK_HTML
979    Building DocBook PS documentation   : $BUILD_DOCBOOK_PS
980    Building DocBook PDF documentation  : $BUILD_DOCBOOK_PDF"]
981
982 echo ["----------------------------------------------------------------------
983 "]
984
985 echo "\
986 For a standard build of GHC (fully optimised with profiling), type (g)make.
987
988 To make changes to the default build configuration, copy the file
989 mk/build.mk.sample to mk/build.mk, and edit the settings in there.
990
991 For more information on how to configure your GHC build, see
992    http://hackage.haskell.org/trac/ghc/wiki/Building
993 "