Merge branch 'master' of darcs.haskell.org:/srv/darcs//ghc
[ghc.git] / compiler / simplCore / Simplify.lhs
1 %
2 % (c) The AQUA Project, Glasgow University, 1993-1998
3 %
4 \section[Simplify]{The main module of the simplifier}
5
6 \begin{code}
7 {-# OPTIONS -fno-warn-tabs #-}
8 -- The above warning supression flag is a temporary kludge.
9 -- While working on this module you are encouraged to remove it and
10 -- detab the module (please do the detabbing in a separate patch). See
11 --     http://hackage.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#TabsvsSpaces
12 -- for details
13
14 module Simplify ( simplTopBinds, simplExpr ) where
15
16 #include "HsVersions.h"
17
18 import DynFlags
19 import SimplMonad
20 import Type hiding      ( substTy, extendTvSubst, substTyVar )
21 import SimplEnv
22 import SimplUtils
23 import FamInstEnv       ( FamInstEnv )
24 import Literal          ( litIsLifted )
25 import Id
26 import MkId             ( seqId, realWorldPrimId )
27 import MkCore           ( mkImpossibleExpr, castBottomExpr )
28 import IdInfo
29 import Name             ( mkSystemVarName, isExternalName )
30 import Coercion hiding  ( substCo, substTy, substCoVar, extendTvSubst )
31 import OptCoercion      ( optCoercion )
32 import FamInstEnv       ( topNormaliseType )
33 import DataCon          ( DataCon, dataConWorkId, dataConRepStrictness )
34 import CoreMonad        ( Tick(..), SimplifierMode(..) )
35 import CoreSyn
36 import Demand           ( isStrictDmd, StrictSig(..), dmdTypeDepth )
37 import PprCore          ( pprParendExpr, pprCoreExpr )
38 import CoreUnfold 
39 import CoreUtils
40 import qualified CoreSubst
41 import CoreArity
42 import Rules            ( lookupRule, getRules )
43 import BasicTypes       ( isMarkedStrict, Arity )
44 import TysPrim          ( realWorldStatePrimTy )
45 import BasicTypes       ( TopLevelFlag(..), isTopLevel, RecFlag(..) )
46 import MonadUtils       ( foldlM, mapAccumLM )
47 import Maybes           ( orElse, isNothing )
48 import Data.List        ( mapAccumL )
49 import Outputable
50 import FastString
51 import Pair
52 import Util
53 \end{code}
54
55
56 The guts of the simplifier is in this module, but the driver loop for
57 the simplifier is in SimplCore.lhs.
58
59
60 -----------------------------------------
61         *** IMPORTANT NOTE ***
62 -----------------------------------------
63 The simplifier used to guarantee that the output had no shadowing, but
64 it does not do so any more.   (Actually, it never did!)  The reason is
65 documented with simplifyArgs.
66
67
68 -----------------------------------------
69         *** IMPORTANT NOTE ***
70 -----------------------------------------
71 Many parts of the simplifier return a bunch of "floats" as well as an
72 expression. This is wrapped as a datatype SimplUtils.FloatsWith.
73
74 All "floats" are let-binds, not case-binds, but some non-rec lets may
75 be unlifted (with RHS ok-for-speculation).
76
77
78
79 -----------------------------------------
80         ORGANISATION OF FUNCTIONS
81 -----------------------------------------
82 simplTopBinds
83   - simplify all top-level binders
84   - for NonRec, call simplRecOrTopPair
85   - for Rec,    call simplRecBind
86
87
88         ------------------------------
89 simplExpr (applied lambda)      ==> simplNonRecBind
90 simplExpr (Let (NonRec ...) ..) ==> simplNonRecBind
91 simplExpr (Let (Rec ...)    ..) ==> simplify binders; simplRecBind
92
93         ------------------------------
94 simplRecBind    [binders already simplfied]
95   - use simplRecOrTopPair on each pair in turn
96
97 simplRecOrTopPair [binder already simplified]
98   Used for: recursive bindings (top level and nested)
99             top-level non-recursive bindings
100   Returns:
101   - check for PreInlineUnconditionally
102   - simplLazyBind
103
104 simplNonRecBind
105   Used for: non-top-level non-recursive bindings
106             beta reductions (which amount to the same thing)
107   Because it can deal with strict arts, it takes a
108         "thing-inside" and returns an expression
109
110   - check for PreInlineUnconditionally
111   - simplify binder, including its IdInfo
112   - if strict binding
113         simplStrictArg
114         mkAtomicArgs
115         completeNonRecX
116     else
117         simplLazyBind
118         addFloats
119
120 simplNonRecX:   [given a *simplified* RHS, but an *unsimplified* binder]
121   Used for: binding case-binder and constr args in a known-constructor case
122   - check for PreInLineUnconditionally
123   - simplify binder
124   - completeNonRecX
125
126         ------------------------------
127 simplLazyBind:  [binder already simplified, RHS not]
128   Used for: recursive bindings (top level and nested)
129             top-level non-recursive bindings
130             non-top-level, but *lazy* non-recursive bindings
131         [must not be strict or unboxed]
132   Returns floats + an augmented environment, not an expression
133   - substituteIdInfo and add result to in-scope
134         [so that rules are available in rec rhs]
135   - simplify rhs
136   - mkAtomicArgs
137   - float if exposes constructor or PAP
138   - completeBind
139
140
141 completeNonRecX:        [binder and rhs both simplified]
142   - if the the thing needs case binding (unlifted and not ok-for-spec)
143         build a Case
144    else
145         completeBind
146         addFloats
147
148 completeBind:   [given a simplified RHS]
149         [used for both rec and non-rec bindings, top level and not]
150   - try PostInlineUnconditionally
151   - add unfolding [this is the only place we add an unfolding]
152   - add arity
153
154
155
156 Right hand sides and arguments
157 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
158 In many ways we want to treat
159         (a) the right hand side of a let(rec), and
160         (b) a function argument
161 in the same way.  But not always!  In particular, we would
162 like to leave these arguments exactly as they are, so they
163 will match a RULE more easily.
164
165         f (g x, h x)
166         g (+ x)
167
168 It's harder to make the rule match if we ANF-ise the constructor,
169 or eta-expand the PAP:
170
171         f (let { a = g x; b = h x } in (a,b))
172         g (\y. + x y)
173
174 On the other hand if we see the let-defns
175
176         p = (g x, h x)
177         q = + x
178
179 then we *do* want to ANF-ise and eta-expand, so that p and q
180 can be safely inlined.
181
182 Even floating lets out is a bit dubious.  For let RHS's we float lets
183 out if that exposes a value, so that the value can be inlined more vigorously.
184 For example
185
186         r = let x = e in (x,x)
187
188 Here, if we float the let out we'll expose a nice constructor. We did experiments
189 that showed this to be a generally good thing.  But it was a bad thing to float
190 lets out unconditionally, because that meant they got allocated more often.
191
192 For function arguments, there's less reason to expose a constructor (it won't
193 get inlined).  Just possibly it might make a rule match, but I'm pretty skeptical.
194 So for the moment we don't float lets out of function arguments either.
195
196
197 Eta expansion
198 ~~~~~~~~~~~~~~
199 For eta expansion, we want to catch things like
200
201         case e of (a,b) -> \x -> case a of (p,q) -> \y -> r
202
203 If the \x was on the RHS of a let, we'd eta expand to bring the two
204 lambdas together.  And in general that's a good thing to do.  Perhaps
205 we should eta expand wherever we find a (value) lambda?  Then the eta
206 expansion at a let RHS can concentrate solely on the PAP case.
207
208
209 %************************************************************************
210 %*                                                                      *
211 \subsection{Bindings}
212 %*                                                                      *
213 %************************************************************************
214
215 \begin{code}
216 simplTopBinds :: SimplEnv -> [InBind] -> SimplM SimplEnv
217
218 simplTopBinds env0 binds0
219   = do  {       -- Put all the top-level binders into scope at the start
220                 -- so that if a transformation rule has unexpectedly brought
221                 -- anything into scope, then we don't get a complaint about that.
222                 -- It's rather as if the top-level binders were imported.
223                 -- See note [Glomming] in OccurAnal.
224         ; env1 <- simplRecBndrs env0 (bindersOfBinds binds0)
225         ; dflags <- getDynFlags
226         ; let dump_flag = dopt Opt_D_verbose_core2core dflags
227         ; env2 <- simpl_binds dump_flag env1 binds0
228         ; freeTick SimplifierDone
229         ; return env2 }
230   where
231         -- We need to track the zapped top-level binders, because
232         -- they should have their fragile IdInfo zapped (notably occurrence info)
233         -- That's why we run down binds and bndrs' simultaneously.
234         --
235         -- The dump-flag emits a trace for each top-level binding, which
236         -- helps to locate the tracing for inlining and rule firing
237     simpl_binds :: Bool -> SimplEnv -> [InBind] -> SimplM SimplEnv
238     simpl_binds _    env []           = return env
239     simpl_binds dump env (bind:binds) = do { env' <- trace_bind dump bind $
240                                                      simpl_bind env bind
241                                            ; simpl_binds dump env' binds }
242
243     trace_bind True  bind = pprTrace "SimplBind" (ppr (bindersOf bind))
244     trace_bind False _    = \x -> x
245
246     simpl_bind env (Rec pairs)  = simplRecBind      env  TopLevel pairs
247     simpl_bind env (NonRec b r) = simplRecOrTopPair env' TopLevel NonRecursive b b' r
248         where
249           (env', b') = addBndrRules env b (lookupRecBndr env b)
250 \end{code}
251
252
253 %************************************************************************
254 %*                                                                      *
255 \subsection{Lazy bindings}
256 %*                                                                      *
257 %************************************************************************
258
259 simplRecBind is used for
260         * recursive bindings only
261
262 \begin{code}
263 simplRecBind :: SimplEnv -> TopLevelFlag
264              -> [(InId, InExpr)]
265              -> SimplM SimplEnv
266 simplRecBind env0 top_lvl pairs0
267   = do  { let (env_with_info, triples) = mapAccumL add_rules env0 pairs0
268         ; env1 <- go (zapFloats env_with_info) triples
269         ; return (env0 `addRecFloats` env1) }
270         -- addFloats adds the floats from env1,
271         -- _and_ updates env0 with the in-scope set from env1
272   where
273     add_rules :: SimplEnv -> (InBndr,InExpr) -> (SimplEnv, (InBndr, OutBndr, InExpr))
274         -- Add the (substituted) rules to the binder
275     add_rules env (bndr, rhs) = (env', (bndr, bndr', rhs))
276         where
277           (env', bndr') = addBndrRules env bndr (lookupRecBndr env bndr)
278
279     go env [] = return env
280
281     go env ((old_bndr, new_bndr, rhs) : pairs)
282         = do { env' <- simplRecOrTopPair env top_lvl Recursive old_bndr new_bndr rhs
283              ; go env' pairs }
284 \end{code}
285
286 simplOrTopPair is used for
287         * recursive bindings (whether top level or not)
288         * top-level non-recursive bindings
289
290 It assumes the binder has already been simplified, but not its IdInfo.
291
292 \begin{code}
293 simplRecOrTopPair :: SimplEnv
294                   -> TopLevelFlag -> RecFlag
295                   -> InId -> OutBndr -> InExpr  -- Binder and rhs
296                   -> SimplM SimplEnv    -- Returns an env that includes the binding
297
298 simplRecOrTopPair env top_lvl is_rec old_bndr new_bndr rhs
299   | preInlineUnconditionally env top_lvl old_bndr rhs   -- Check for unconditional inline
300   = do  { tick (PreInlineUnconditionally old_bndr)
301         ; return (extendIdSubst env old_bndr (mkContEx env rhs)) }
302
303   | otherwise
304   = simplLazyBind env top_lvl is_rec old_bndr new_bndr rhs env
305 \end{code}
306
307
308 simplLazyBind is used for
309   * [simplRecOrTopPair] recursive bindings (whether top level or not)
310   * [simplRecOrTopPair] top-level non-recursive bindings
311   * [simplNonRecE]      non-top-level *lazy* non-recursive bindings
312
313 Nota bene:
314     1. It assumes that the binder is *already* simplified,
315        and is in scope, and its IdInfo too, except unfolding
316
317     2. It assumes that the binder type is lifted.
318
319     3. It does not check for pre-inline-unconditionallly;
320        that should have been done already.
321
322 \begin{code}
323 simplLazyBind :: SimplEnv
324               -> TopLevelFlag -> RecFlag
325               -> InId -> OutId          -- Binder, both pre-and post simpl
326                                         -- The OutId has IdInfo, except arity, unfolding
327               -> InExpr -> SimplEnv     -- The RHS and its environment
328               -> SimplM SimplEnv
329
330 simplLazyBind env top_lvl is_rec bndr bndr1 rhs rhs_se
331   = -- pprTrace "simplLazyBind" ((ppr bndr <+> ppr bndr1) $$ ppr rhs $$ ppr (seIdSubst rhs_se)) $
332     do  { let   rhs_env     = rhs_se `setInScope` env
333                 (tvs, body) = case collectTyBinders rhs of
334                                 (tvs, body) | not_lam body -> (tvs,body)
335                                             | otherwise    -> ([], rhs)
336                 not_lam (Lam _ _) = False
337                 not_lam _         = True
338                         -- Do not do the "abstract tyyvar" thing if there's
339                         -- a lambda inside, becuase it defeats eta-reduction
340                         --    f = /\a. \x. g a x  
341                         -- should eta-reduce
342
343
344         ; (body_env, tvs') <- simplBinders rhs_env tvs
345                 -- See Note [Floating and type abstraction] in SimplUtils
346
347         -- Simplify the RHS
348         ; let   body_out_ty :: OutType
349                 body_out_ty = substTy body_env (exprType body)
350         ; (body_env1, body1) <- simplExprF body_env body (mkRhsStop body_out_ty)
351         -- ANF-ise a constructor or PAP rhs
352         ; (body_env2, body2) <- prepareRhs top_lvl body_env1 bndr1 body1
353
354         ; (env', rhs')
355             <-  if not (doFloatFromRhs top_lvl is_rec False body2 body_env2)
356                 then                            -- No floating, revert to body1
357                      do { rhs' <- mkLam env tvs' (wrapFloats body_env1 body1)
358                         ; return (env, rhs') }
359
360                 else if null tvs then           -- Simple floating
361                      do { tick LetFloatFromLet
362                         ; return (addFloats env body_env2, body2) }
363
364                 else                            -- Do type-abstraction first
365                      do { tick LetFloatFromLet
366                         ; (poly_binds, body3) <- abstractFloats tvs' body_env2 body2
367                         ; rhs' <- mkLam env tvs' body3
368                         ; env' <- foldlM (addPolyBind top_lvl) env poly_binds
369                         ; return (env', rhs') }
370
371         ; completeBind env' top_lvl bndr bndr1 rhs' }
372 \end{code}
373
374 A specialised variant of simplNonRec used when the RHS is already simplified,
375 notably in knownCon.  It uses case-binding where necessary.
376
377 \begin{code}
378 simplNonRecX :: SimplEnv
379              -> InId            -- Old binder
380              -> OutExpr         -- Simplified RHS
381              -> SimplM SimplEnv
382
383 simplNonRecX env bndr new_rhs
384   | isDeadBinder bndr   -- Not uncommon; e.g. case (a,b) of c { (p,q) -> p }
385   = return env          --               Here c is dead, and we avoid creating
386                         --               the binding c = (a,b)
387   | Coercion co <- new_rhs    
388   = return (extendCvSubst env bndr co)
389   | otherwise           --               the binding b = (a,b)
390   = do  { (env', bndr') <- simplBinder env bndr
391         ; completeNonRecX NotTopLevel env' (isStrictId bndr) bndr bndr' new_rhs }
392                 -- simplNonRecX is only used for NotTopLevel things
393
394 completeNonRecX :: TopLevelFlag -> SimplEnv
395                 -> Bool
396                 -> InId                 -- Old binder
397                 -> OutId                -- New binder
398                 -> OutExpr              -- Simplified RHS
399                 -> SimplM SimplEnv
400
401 completeNonRecX top_lvl env is_strict old_bndr new_bndr new_rhs
402   = do  { (env1, rhs1) <- prepareRhs top_lvl (zapFloats env) new_bndr new_rhs
403         ; (env2, rhs2) <- 
404                 if doFloatFromRhs NotTopLevel NonRecursive is_strict rhs1 env1
405                 then do { tick LetFloatFromLet
406                         ; return (addFloats env env1, rhs1) }   -- Add the floats to the main env
407                 else return (env, wrapFloats env1 rhs1)         -- Wrap the floats around the RHS
408         ; completeBind env2 NotTopLevel old_bndr new_bndr rhs2 }
409 \end{code}
410
411 {- No, no, no!  Do not try preInlineUnconditionally in completeNonRecX
412    Doing so risks exponential behaviour, because new_rhs has been simplified once already
413    In the cases described by the folowing commment, postInlineUnconditionally will
414    catch many of the relevant cases.
415         -- This happens; for example, the case_bndr during case of
416         -- known constructor:  case (a,b) of x { (p,q) -> ... }
417         -- Here x isn't mentioned in the RHS, so we don't want to
418         -- create the (dead) let-binding  let x = (a,b) in ...
419         --
420         -- Similarly, single occurrences can be inlined vigourously
421         -- e.g.  case (f x, g y) of (a,b) -> ....
422         -- If a,b occur once we can avoid constructing the let binding for them.
423
424    Furthermore in the case-binding case preInlineUnconditionally risks extra thunks
425         -- Consider     case I# (quotInt# x y) of
426         --                I# v -> let w = J# v in ...
427         -- If we gaily inline (quotInt# x y) for v, we end up building an
428         -- extra thunk:
429         --                let w = J# (quotInt# x y) in ...
430         -- because quotInt# can fail.
431
432   | preInlineUnconditionally env NotTopLevel bndr new_rhs
433   = thing_inside (extendIdSubst env bndr (DoneEx new_rhs))
434 -}
435
436 ----------------------------------
437 prepareRhs takes a putative RHS, checks whether it's a PAP or
438 constructor application and, if so, converts it to ANF, so that the
439 resulting thing can be inlined more easily.  Thus
440         x = (f a, g b)
441 becomes
442         t1 = f a
443         t2 = g b
444         x = (t1,t2)
445
446 We also want to deal well cases like this
447         v = (f e1 `cast` co) e2
448 Here we want to make e1,e2 trivial and get
449         x1 = e1; x2 = e2; v = (f x1 `cast` co) v2
450 That's what the 'go' loop in prepareRhs does
451
452 \begin{code}
453 prepareRhs :: TopLevelFlag -> SimplEnv -> OutId -> OutExpr -> SimplM (SimplEnv, OutExpr)
454 -- Adds new floats to the env iff that allows us to return a good RHS
455 prepareRhs top_lvl env id (Cast rhs co)    -- Note [Float coercions]
456   | Pair ty1 _ty2 <- coercionKind co       -- Do *not* do this if rhs has an unlifted type
457   , not (isUnLiftedType ty1)            -- see Note [Float coercions (unlifted)]
458   = do  { (env', rhs') <- makeTrivialWithInfo top_lvl env sanitised_info rhs
459         ; return (env', Cast rhs' co) }
460   where
461     sanitised_info = vanillaIdInfo `setStrictnessInfo` strictnessInfo info
462                                    `setDemandInfo`     demandInfo info
463     info = idInfo id
464
465 prepareRhs top_lvl env0 _ rhs0
466   = do  { (_is_exp, env1, rhs1) <- go 0 env0 rhs0
467         ; return (env1, rhs1) }
468   where
469     go n_val_args env (Cast rhs co)
470         = do { (is_exp, env', rhs') <- go n_val_args env rhs
471              ; return (is_exp, env', Cast rhs' co) }
472     go n_val_args env (App fun (Type ty))
473         = do { (is_exp, env', rhs') <- go n_val_args env fun
474              ; return (is_exp, env', App rhs' (Type ty)) }
475     go n_val_args env (App fun arg)
476         = do { (is_exp, env', fun') <- go (n_val_args+1) env fun
477              ; case is_exp of
478                 True -> do { (env'', arg') <- makeTrivial top_lvl env' arg
479                            ; return (True, env'', App fun' arg') }
480                 False -> return (False, env, App fun arg) }
481     go n_val_args env (Var fun)
482         = return (is_exp, env, Var fun)
483         where
484           is_exp = isExpandableApp fun n_val_args   -- The fun a constructor or PAP
485                         -- See Note [CONLIKE pragma] in BasicTypes
486                         -- The definition of is_exp should match that in
487                         -- OccurAnal.occAnalApp
488
489     go _ env other
490         = return (False, env, other)
491 \end{code}
492
493
494 Note [Float coercions]
495 ~~~~~~~~~~~~~~~~~~~~~~
496 When we find the binding
497         x = e `cast` co
498 we'd like to transform it to
499         x' = e
500         x = x `cast` co         -- A trivial binding
501 There's a chance that e will be a constructor application or function, or something
502 like that, so moving the coerion to the usage site may well cancel the coersions
503 and lead to further optimisation.  Example:
504
505      data family T a :: *
506      data instance T Int = T Int
507
508      foo :: Int -> Int -> Int
509      foo m n = ...
510         where
511           x = T m
512           go 0 = 0
513           go n = case x of { T m -> go (n-m) }
514                 -- This case should optimise
515
516 Note [Preserve strictness when floating coercions]
517 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
518 In the Note [Float coercions] transformation, keep the strictness info.
519 Eg
520         f = e `cast` co    -- f has strictness SSL
521 When we transform to
522         f' = e             -- f' also has strictness SSL
523         f = f' `cast` co   -- f still has strictness SSL
524
525 Its not wrong to drop it on the floor, but better to keep it.
526
527 Note [Float coercions (unlifted)]
528 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
529 BUT don't do [Float coercions] if 'e' has an unlifted type.
530 This *can* happen:
531
532      foo :: Int = (error (# Int,Int #) "urk")
533                   `cast` CoUnsafe (# Int,Int #) Int
534
535 If do the makeTrivial thing to the error call, we'll get
536     foo = case error (# Int,Int #) "urk" of v -> v `cast` ...
537 But 'v' isn't in scope!
538
539 These strange casts can happen as a result of case-of-case
540         bar = case (case x of { T -> (# 2,3 #); F -> error "urk" }) of
541                 (# p,q #) -> p+q
542
543
544 \begin{code}
545 makeTrivial :: TopLevelFlag -> SimplEnv -> OutExpr -> SimplM (SimplEnv, OutExpr)
546 -- Binds the expression to a variable, if it's not trivial, returning the variable
547 makeTrivial top_lvl env expr = makeTrivialWithInfo top_lvl env vanillaIdInfo expr
548
549 makeTrivialWithInfo :: TopLevelFlag -> SimplEnv -> IdInfo 
550                     -> OutExpr -> SimplM (SimplEnv, OutExpr)
551 -- Propagate strictness and demand info to the new binder
552 -- Note [Preserve strictness when floating coercions]
553 -- Returned SimplEnv has same substitution as incoming one
554 makeTrivialWithInfo top_lvl env info expr
555   | exprIsTrivial expr                          -- Already trivial
556   || not (bindingOk top_lvl expr expr_ty)       -- Cannot trivialise
557                                                 --   See Note [Cannot trivialise]
558   = return (env, expr)
559   | otherwise           -- See Note [Take care] below
560   = do  { uniq <- getUniqueM
561         ; let name = mkSystemVarName uniq (fsLit "a")
562               var = mkLocalIdWithInfo name expr_ty info
563         ; env'  <- completeNonRecX top_lvl env False var var expr
564         ; expr' <- simplVar env' var
565         ; return (env', expr') }
566         -- The simplVar is needed becase we're constructing a new binding
567         --     a = rhs
568         -- And if rhs is of form (rhs1 |> co), then we might get
569         --     a1 = rhs1
570         --     a = a1 |> co
571         -- and now a's RHS is trivial and can be substituted out, and that
572         -- is what completeNonRecX will do
573         -- To put it another way, it's as if we'd simplified
574         --    let var = e in var
575   where
576     expr_ty = exprType expr
577
578 bindingOk :: TopLevelFlag -> CoreExpr -> Type -> Bool
579 -- True iff we can have a binding of this expression at this level
580 -- Precondition: the type is the type of the expression
581 bindingOk top_lvl _ expr_ty
582   | isTopLevel top_lvl = not (isUnLiftedType expr_ty) 
583   | otherwise          = True
584 \end{code}
585
586 Note [Cannot trivialise]
587 ~~~~~~~~~~~~~~~~~~~~~~~~
588 Consider tih
589    f :: Int -> Addr#
590    
591    foo :: Bar
592    foo = Bar (f 3)
593
594 Then we can't ANF-ise foo, even though we'd like to, because
595 we can't make a top-level binding for the Addr# (f 3). And if
596 so we don't want to turn it into
597    foo = let x = f 3 in Bar x
598 because we'll just end up inlining x back, and that makes the
599 simplifier loop.  Better not to ANF-ise it at all.
600
601 A case in point is literal strings (a MachStr is not regarded as
602 trivial):
603
604    foo = Ptr "blob"#
605
606 We don't want to ANF-ise this.
607
608 %************************************************************************
609 %*                                                                      *
610 \subsection{Completing a lazy binding}
611 %*                                                                      *
612 %************************************************************************
613
614 completeBind
615   * deals only with Ids, not TyVars
616   * takes an already-simplified binder and RHS
617   * is used for both recursive and non-recursive bindings
618   * is used for both top-level and non-top-level bindings
619
620 It does the following:
621   - tries discarding a dead binding
622   - tries PostInlineUnconditionally
623   - add unfolding [this is the only place we add an unfolding]
624   - add arity
625
626 It does *not* attempt to do let-to-case.  Why?  Because it is used for
627   - top-level bindings (when let-to-case is impossible)
628   - many situations where the "rhs" is known to be a WHNF
629                 (so let-to-case is inappropriate).
630
631 Nor does it do the atomic-argument thing
632
633 \begin{code}
634 completeBind :: SimplEnv
635              -> TopLevelFlag            -- Flag stuck into unfolding
636              -> InId                    -- Old binder
637              -> OutId -> OutExpr        -- New binder and RHS
638              -> SimplM SimplEnv
639 -- completeBind may choose to do its work
640 --      * by extending the substitution (e.g. let x = y in ...)
641 --      * or by adding to the floats in the envt
642
643 completeBind env top_lvl old_bndr new_bndr new_rhs
644  | isCoVar old_bndr
645  = case new_rhs of
646      Coercion co -> return (extendCvSubst env old_bndr co)
647      _           -> return (addNonRec env new_bndr new_rhs)
648
649  | otherwise
650  = ASSERT( isId new_bndr )
651    do { let old_info = idInfo old_bndr
652             old_unf  = unfoldingInfo old_info
653             occ_info = occInfo old_info
654
655         -- Do eta-expansion on the RHS of the binding
656         -- See Note [Eta-expanding at let bindings] in SimplUtils
657       ; (new_arity, final_rhs) <- tryEtaExpand env new_bndr new_rhs
658
659         -- Simplify the unfolding
660       ; new_unfolding <- simplUnfolding env top_lvl old_bndr final_rhs old_unf
661
662       ; if postInlineUnconditionally env top_lvl new_bndr occ_info
663                                      final_rhs new_unfolding
664
665                         -- Inline and discard the binding
666         then do  { tick (PostInlineUnconditionally old_bndr)
667                  ; return (extendIdSubst env old_bndr (DoneEx final_rhs)) }
668                 -- Use the substitution to make quite, quite sure that the
669                 -- substitution will happen, since we are going to discard the binding
670         else
671    do { let info1 = idInfo new_bndr `setArityInfo` new_arity
672         
673               -- Unfolding info: Note [Setting the new unfolding]
674             info2 = info1 `setUnfoldingInfo` new_unfolding
675
676               -- Demand info: Note [Setting the demand info]
677               --
678               -- We also have to nuke demand info if for some reason
679               -- eta-expansion *reduces* the arity of the binding to less
680               -- than that of the strictness sig. This can happen: see Note [Arity decrease].
681             info3 | isEvaldUnfolding new_unfolding
682                     || (case strictnessInfo info2 of
683                           Just (StrictSig dmd_ty) -> new_arity < dmdTypeDepth dmd_ty
684                           Nothing                 -> False)
685                   = zapDemandInfo info2 `orElse` info2
686                   | otherwise
687                   = info2
688
689             final_id = new_bndr `setIdInfo` info3
690
691       ; -- pprTrace "Binding" (ppr final_id <+> ppr new_unfolding) $
692         return (addNonRec env final_id final_rhs) } }
693                 -- The addNonRec adds it to the in-scope set too
694
695 ------------------------------
696 addPolyBind :: TopLevelFlag -> SimplEnv -> OutBind -> SimplM SimplEnv
697 -- Add a new binding to the environment, complete with its unfolding
698 -- but *do not* do postInlineUnconditionally, because we have already
699 -- processed some of the scope of the binding
700 -- We still want the unfolding though.  Consider
701 --      let 
702 --            x = /\a. let y = ... in Just y
703 --      in body
704 -- Then we float the y-binding out (via abstractFloats and addPolyBind)
705 -- but 'x' may well then be inlined in 'body' in which case we'd like the 
706 -- opportunity to inline 'y' too.
707 --
708 -- INVARIANT: the arity is correct on the incoming binders
709
710 addPolyBind top_lvl env (NonRec poly_id rhs)
711   = do  { unfolding <- simplUnfolding env top_lvl poly_id rhs noUnfolding
712                         -- Assumes that poly_id did not have an INLINE prag
713                         -- which is perhaps wrong.  ToDo: think about this
714         ; let final_id = setIdInfo poly_id $
715                          idInfo poly_id `setUnfoldingInfo` unfolding
716
717         ; return (addNonRec env final_id rhs) }
718
719 addPolyBind _ env bind@(Rec _) 
720   = return (extendFloats env bind)
721         -- Hack: letrecs are more awkward, so we extend "by steam"
722         -- without adding unfoldings etc.  At worst this leads to
723         -- more simplifier iterations
724
725 ------------------------------
726 simplUnfolding :: SimplEnv-> TopLevelFlag
727                -> InId
728                -> OutExpr
729                -> Unfolding -> SimplM Unfolding
730 -- Note [Setting the new unfolding]
731 simplUnfolding env _ _ _ (DFunUnfolding ar con ops)
732   = return (DFunUnfolding ar con ops')
733   where
734     ops' = map (substExpr (text "simplUnfolding") env) ops
735
736 simplUnfolding env top_lvl id _
737     (CoreUnfolding { uf_tmpl = expr, uf_arity = arity
738                    , uf_src = src, uf_guidance = guide })
739   | isStableSource src
740   = do { expr' <- simplExpr rule_env expr
741        ; let src' = CoreSubst.substUnfoldingSource (mkCoreSubst (text "inline-unf") env) src
742              is_top_lvl = isTopLevel top_lvl
743        ; case guide of
744            UnfWhen sat_ok _    -- Happens for INLINE things
745               -> let guide' = UnfWhen sat_ok (inlineBoringOk expr')
746                      -- Refresh the boring-ok flag, in case expr'
747                      -- has got small. This happens, notably in the inlinings
748                      -- for dfuns for single-method classes; see
749                      -- Note [Single-method classes] in TcInstDcls.
750                      -- A test case is Trac #4138
751                  in return (mkCoreUnfolding src' is_top_lvl expr' arity guide')
752                  -- See Note [Top-level flag on inline rules] in CoreUnfold
753
754            _other              -- Happens for INLINABLE things
755               -> let bottoming = isBottomingId id
756                  in bottoming `seq` -- See Note [Force bottoming field]
757                     return (mkUnfolding src' is_top_lvl bottoming expr')
758                 -- If the guidance is UnfIfGoodArgs, this is an INLINABLE
759                 -- unfolding, and we need to make sure the guidance is kept up
760                 -- to date with respect to any changes in the unfolding.
761        }
762   where
763     act      = idInlineActivation id
764     rule_env = updMode (updModeForInlineRules act) env
765                -- See Note [Simplifying inside InlineRules] in SimplUtils
766
767 simplUnfolding _ top_lvl id new_rhs _
768   = let bottoming = isBottomingId id
769     in bottoming `seq`  -- See Note [Force bottoming field]
770        return (mkUnfolding InlineRhs (isTopLevel top_lvl) bottoming new_rhs)
771           -- We make an  unfolding *even for loop-breakers*.
772           -- Reason: (a) It might be useful to know that they are WHNF
773           --         (b) In TidyPgm we currently assume that, if we want to
774           --             expose the unfolding then indeed we *have* an unfolding
775           --             to expose.  (We could instead use the RHS, but currently
776           --             we don't.)  The simple thing is always to have one.
777 \end{code}
778
779 Note [Force bottoming field]
780 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
781 We need to force bottoming, or the new unfolding holds
782 on to the old unfolding (which is part of the id).
783
784 Note [Arity decrease]
785 ~~~~~~~~~~~~~~~~~~~~~
786 Generally speaking the arity of a binding should not decrease.  But it *can* 
787 legitimately happen becuase of RULES.  Eg
788         f = g Int
789 where g has arity 2, will have arity 2.  But if there's a rewrite rule
790         g Int --> h
791 where h has arity 1, then f's arity will decrease.  Here's a real-life example,
792 which is in the output of Specialise:
793
794      Rec {
795         $dm {Arity 2} = \d.\x. op d
796         {-# RULES forall d. $dm Int d = $s$dm #-}
797         
798         dInt = MkD .... opInt ...
799         opInt {Arity 1} = $dm dInt
800
801         $s$dm {Arity 0} = \x. op dInt }
802
803 Here opInt has arity 1; but when we apply the rule its arity drops to 0.
804 That's why Specialise goes to a little trouble to pin the right arity
805 on specialised functions too.
806
807 Note [Setting the new unfolding]
808 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
809 * If there's an INLINE pragma, we simplify the RHS gently.  Maybe we
810   should do nothing at all, but simplifying gently might get rid of 
811   more crap.
812
813 * If not, we make an unfolding from the new RHS.  But *only* for
814   non-loop-breakers. Making loop breakers not have an unfolding at all
815   means that we can avoid tests in exprIsConApp, for example.  This is
816   important: if exprIsConApp says 'yes' for a recursive thing, then we
817   can get into an infinite loop
818
819 If there's an InlineRule on a loop breaker, we hang on to the inlining.
820 It's pretty dodgy, but the user did say 'INLINE'.  May need to revisit
821 this choice.
822
823 Note [Setting the demand info]
824 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
825 If the unfolding is a value, the demand info may
826 go pear-shaped, so we nuke it.  Example:
827      let x = (a,b) in
828      case x of (p,q) -> h p q x
829 Here x is certainly demanded. But after we've nuked
830 the case, we'll get just
831      let x = (a,b) in h a b x
832 and now x is not demanded (I'm assuming h is lazy)
833 This really happens.  Similarly
834      let f = \x -> e in ...f..f...
835 After inlining f at some of its call sites the original binding may
836 (for example) be no longer strictly demanded.
837 The solution here is a bit ad hoc...
838
839
840 %************************************************************************
841 %*                                                                      *
842 \subsection[Simplify-simplExpr]{The main function: simplExpr}
843 %*                                                                      *
844 %************************************************************************
845
846 The reason for this OutExprStuff stuff is that we want to float *after*
847 simplifying a RHS, not before.  If we do so naively we get quadratic
848 behaviour as things float out.
849
850 To see why it's important to do it after, consider this (real) example:
851
852         let t = f x
853         in fst t
854 ==>
855         let t = let a = e1
856                     b = e2
857                 in (a,b)
858         in fst t
859 ==>
860         let a = e1
861             b = e2
862             t = (a,b)
863         in
864         a       -- Can't inline a this round, cos it appears twice
865 ==>
866         e1
867
868 Each of the ==> steps is a round of simplification.  We'd save a
869 whole round if we float first.  This can cascade.  Consider
870
871         let f = g d
872         in \x -> ...f...
873 ==>
874         let f = let d1 = ..d.. in \y -> e
875         in \x -> ...f...
876 ==>
877         let d1 = ..d..
878         in \x -> ...(\y ->e)...
879
880 Only in this second round can the \y be applied, and it
881 might do the same again.
882
883
884 \begin{code}
885 simplExpr :: SimplEnv -> CoreExpr -> SimplM CoreExpr
886 simplExpr env expr = simplExprC env expr (mkBoringStop expr_out_ty)
887   where
888     expr_out_ty :: OutType
889     expr_out_ty = substTy env (exprType expr)
890
891 simplExprC :: SimplEnv -> CoreExpr -> SimplCont -> SimplM CoreExpr
892         -- Simplify an expression, given a continuation
893 simplExprC env expr cont
894   = -- pprTrace "simplExprC" (ppr expr $$ ppr cont {- $$ ppr (seIdSubst env) -} $$ ppr (seFloats env) ) $
895     do  { (env', expr') <- simplExprF (zapFloats env) expr cont
896         ; -- pprTrace "simplExprC ret" (ppr expr $$ ppr expr') $
897           -- pprTrace "simplExprC ret3" (ppr (seInScope env')) $
898           -- pprTrace "simplExprC ret4" (ppr (seFloats env')) $
899           return (wrapFloats env' expr') }
900
901 --------------------------------------------------
902 simplExprF :: SimplEnv -> InExpr -> SimplCont
903            -> SimplM (SimplEnv, OutExpr)
904
905 simplExprF env e cont
906   = {- pprTrace "simplExprF" (vcat 
907       [ ppr e
908       , text "cont =" <+> ppr cont
909       , text "inscope =" <+> ppr (seInScope env)
910       , text "tvsubst =" <+> ppr (seTvSubst env)
911       , text "idsubst =" <+> ppr (seIdSubst env)
912       , text "cvsubst =" <+> ppr (seCvSubst env)
913       {- , ppr (seFloats env) -} 
914       ]) $ -}
915     simplExprF1 env e cont
916
917 simplExprF1 :: SimplEnv -> InExpr -> SimplCont
918             -> SimplM (SimplEnv, OutExpr)
919 simplExprF1 env (Var v)        cont = simplIdF env v cont
920 simplExprF1 env (Lit lit)      cont = rebuild env (Lit lit) cont
921 simplExprF1 env (Tick t expr)  cont = simplTick env t expr cont
922 simplExprF1 env (Cast body co) cont = simplCast env body co cont
923 simplExprF1 env (Coercion co)  cont = simplCoercionF env co cont
924 simplExprF1 env (Type ty)      cont = ASSERT( contIsRhsOrArg cont )
925                                       rebuild env (Type (substTy env ty)) cont
926 simplExprF1 env (App fun arg)  cont = simplExprF env fun $
927                                       ApplyTo NoDup arg env cont
928
929 simplExprF1 env expr@(Lam {}) cont
930   = simplLam env zapped_bndrs body cont
931         -- The main issue here is under-saturated lambdas
932         --   (\x1. \x2. e) arg1
933         -- Here x1 might have "occurs-once" occ-info, because occ-info
934         -- is computed assuming that a group of lambdas is applied
935         -- all at once.  If there are too few args, we must zap the
936         -- occ-info, UNLESS the remaining binders are one-shot
937   where
938     (bndrs, body) = collectBinders expr
939     zapped_bndrs | need_to_zap = map zap bndrs
940                  | otherwise   = bndrs
941
942     need_to_zap = any zappable_bndr (drop n_args bndrs)
943     n_args = countArgs cont
944         -- NB: countArgs counts all the args (incl type args)
945         -- and likewise drop counts all binders (incl type lambdas)
946
947     zappable_bndr b = isId b && not (isOneShotBndr b)
948     zap b | isTyVar b = b
949           | otherwise = zapLamIdInfo b
950
951 simplExprF1 env (Case scrut bndr alts_ty alts) cont
952   | sm_case_case (getMode env)
953   =     -- Simplify the scrutinee with a Select continuation
954     simplExprF env scrut (Select NoDup bndr alts env cont)
955
956   | otherwise
957   =     -- If case-of-case is off, simply simplify the case expression
958         -- in a vanilla Stop context, and rebuild the result around it
959     do  { case_expr' <- simplExprC env scrut 
960                              (Select NoDup bndr alts env (mkBoringStop alts_out_ty))
961         ; rebuild env case_expr' cont }
962   where
963     alts_out_ty = substTy env alts_ty
964
965 simplExprF1 env (Let (Rec pairs) body) cont
966   = do  { env' <- simplRecBndrs env (map fst pairs)
967                 -- NB: bndrs' don't have unfoldings or rules
968                 -- We add them as we go down
969
970         ; env'' <- simplRecBind env' NotTopLevel pairs
971         ; simplExprF env'' body cont }
972
973 simplExprF1 env (Let (NonRec bndr rhs) body) cont
974   = simplNonRecE env bndr (rhs, env) ([], body) cont
975
976 ---------------------------------
977 simplType :: SimplEnv -> InType -> SimplM OutType
978         -- Kept monadic just so we can do the seqType
979 simplType env ty
980   = -- pprTrace "simplType" (ppr ty $$ ppr (seTvSubst env)) $
981     seqType new_ty `seq` return new_ty
982   where
983     new_ty = substTy env ty
984
985 ---------------------------------
986 simplCoercionF :: SimplEnv -> InCoercion -> SimplCont
987                -> SimplM (SimplEnv, OutExpr)
988 simplCoercionF env co cont 
989   = do { co' <- simplCoercion env co
990        ; rebuild env (Coercion co') cont }
991
992 simplCoercion :: SimplEnv -> InCoercion -> SimplM OutCoercion
993 simplCoercion env co
994   = let opt_co = optCoercion (getCvSubst env) co
995     in seqCo opt_co `seq` return opt_co
996
997 -----------------------------------
998 -- | Push a TickIt context outwards past applications and cases, as
999 -- long as this is a non-scoping tick, to let case and application
1000 -- optimisations apply.
1001
1002 simplTick :: SimplEnv -> Tickish Id -> InExpr -> SimplCont
1003           -> SimplM (SimplEnv, OutExpr)
1004 simplTick env tickish expr cont
1005   -- A scoped tick turns into a continuation, so that we can spot
1006   -- (scc t (\x . e)) in simplLam and eliminate the scc.  If we didn't do
1007   -- it this way, then it would take two passes of the simplifier to
1008   -- reduce ((scc t (\x . e)) e').
1009   -- NB, don't do this with counting ticks, because if the expr is
1010   -- bottom, then rebuildCall will discard the continuation.
1011
1012 -- XXX: we cannot do this, because the simplifier assumes that
1013 -- the context can be pushed into a case with a single branch. e.g.
1014 --    scc<f>  case expensive of p -> e
1015 -- becomes
1016 --    case expensive of p -> scc<f> e
1017 --
1018 -- So I'm disabling this for now.  It just means we will do more
1019 -- simplifier iterations that necessary in some cases.
1020
1021 --  | tickishScoped tickish && not (tickishCounts tickish)
1022 --  = simplExprF env expr (TickIt tickish cont)
1023
1024   -- For non-scoped ticks, we push the continuation inside the
1025   -- tick.  This has the effect of moving the tick to the outside of a
1026   -- case or application context, allowing the normal case and
1027   -- application optimisations to fire.
1028   | not (tickishScoped tickish)
1029   = do { (env', expr') <- simplExprF env expr cont
1030        ; return (env', mkTick tickish expr')
1031        }
1032
1033   -- For breakpoints, we cannot do any floating of bindings around the
1034   -- tick, because breakpoints cannot be split into tick/scope pairs.
1035   | not (tickishCanSplit tickish)
1036   = no_floating_past_tick
1037
1038   | interesting_cont, Just expr' <- push_tick_inside tickish expr
1039     -- see Note [case-of-scc-of-case]
1040   = simplExprF env expr' cont
1041
1042   | otherwise
1043   = no_floating_past_tick -- was: wrap_floats, see below
1044
1045  where
1046   interesting_cont = case cont of
1047                         Select {} -> True
1048                         _ -> False
1049
1050   push_tick_inside t expr0
1051      | not (tickishCanSplit t) = Nothing
1052      | otherwise
1053        = case expr0 of
1054            Tick t' expr
1055               -- scc t (tick t' E)
1056               --   Pull the tick to the outside
1057               -- This one is important for #5363
1058               | not (tickishScoped t')
1059                  -> Just (Tick t' (Tick t expr))
1060
1061               -- scc t (scc t' E)
1062               --   Try to push t' into E first, and if that works,
1063               --   try to push t in again
1064               | Just expr' <- push_tick_inside t' expr
1065                  -> push_tick_inside t expr'
1066
1067               | otherwise -> Nothing
1068
1069            Case scrut bndr ty alts
1070               -> Just (Case (mkTick t scrut) bndr ty alts')
1071              where t_scope = mkNoTick t -- drop the tick on the dup'd ones
1072                    alts'   = [ (c,bs, mkTick t_scope e) | (c,bs,e) <- alts]
1073            _other -> Nothing
1074     where
1075
1076   no_floating_past_tick =
1077     do { let (inc,outc) = splitCont cont
1078        ; (env', expr') <- simplExprF (zapFloats env) expr inc
1079        ; let tickish' = simplTickish env tickish
1080        ; (env'', expr'') <- rebuild (zapFloats env')
1081                                     (wrapFloats env' expr')
1082                                     (TickIt tickish' outc)
1083        ; return (addFloats env env'', expr'')
1084        }
1085
1086 -- Alternative version that wraps outgoing floats with the tick.  This
1087 -- results in ticks being duplicated, as we don't make any attempt to
1088 -- eliminate the tick if we re-inline the binding (because the tick
1089 -- semantics allows unrestricted inlining of HNFs), so I'm not doing
1090 -- this any more.  FloatOut will catch any real opportunities for
1091 -- floating.
1092 --
1093 --  wrap_floats =
1094 --    do { let (inc,outc) = splitCont cont
1095 --       ; (env', expr') <- simplExprF (zapFloats env) expr inc
1096 --       ; let tickish' = simplTickish env tickish
1097 --       ; let wrap_float (b,rhs) = (zapIdStrictness (setIdArity b 0),
1098 --                                   mkTick (mkNoTick tickish') rhs)
1099 --              -- when wrapping a float with mkTick, we better zap the Id's
1100 --              -- strictness info and arity, because it might be wrong now.
1101 --       ; let env'' = addFloats env (mapFloats env' wrap_float)
1102 --       ; rebuild env'' expr' (TickIt tickish' outc)
1103 --       }
1104
1105
1106   simplTickish env tickish
1107     | Breakpoint n ids <- tickish
1108           = Breakpoint n (map (getDoneId . substId env) ids)
1109     | otherwise = tickish
1110
1111   -- push type application and coercion inside a tick
1112   splitCont :: SimplCont -> (SimplCont, SimplCont)
1113   splitCont (ApplyTo f (Type t) env c) = (ApplyTo f (Type t) env inc, outc)
1114     where (inc,outc) = splitCont c
1115   splitCont (CoerceIt co c) = (CoerceIt co inc, outc)
1116     where (inc,outc) = splitCont c
1117   splitCont other = (mkBoringStop (contInputType other), other)
1118
1119   getDoneId (DoneId id) = id
1120   getDoneId (DoneEx e)  = getIdFromTrivialExpr e -- Note [substTickish] in CoreSubst
1121   getDoneId other = pprPanic "getDoneId" (ppr other)
1122
1123 -- Note [case-of-scc-of-case]
1124 -- It's pretty important to be able to transform case-of-case when
1125 -- there's an SCC in the way.  For example, the following comes up
1126 -- in nofib/real/compress/Encode.hs:
1127 --
1128 --        case scctick<code_string.r1>
1129 --             case $wcode_string_r13s wild_XC w1_s137 w2_s138 l_aje
1130 --             of _ { (# ww1_s13f, ww2_s13g, ww3_s13h #) ->
1131 --             (ww1_s13f, ww2_s13g, ww3_s13h)
1132 --             }
1133 --        of _ { (ww_s12Y, ww1_s12Z, ww2_s130) ->
1134 --        tick<code_string.f1>
1135 --        (ww_s12Y,
1136 --         ww1_s12Z,
1137 --         PTTrees.PT
1138 --           @ GHC.Types.Char @ GHC.Types.Int wild2_Xj ww2_s130 r_ajf)
1139 --        }
1140 --  
1141 -- We really want this case-of-case to fire, because then the 3-tuple
1142 -- will go away (indeed, the CPR optimisation is relying on this
1143 -- happening).  But the scctick is in the way - we need to push it
1144 -- inside to expose the case-of-case.  So we perform this
1145 -- transformation on the inner case:
1146 --
1147 --   scctick c (case e of { p1 -> e1; ...; pn -> en })
1148 --    ==>
1149 --   case (scctick c e) of { p1 -> scc c e1; ...; pn -> scc c en }
1150 --
1151 -- So we've moved a constant amount of work out of the scc to expose
1152 -- the case.  We only do this when the continuation is interesting: in
1153 -- for now, it has to be another Case (maybe generalise this later).
1154 \end{code}
1155
1156
1157 %************************************************************************
1158 %*                                                                      *
1159 \subsection{The main rebuilder}
1160 %*                                                                      *
1161 %************************************************************************
1162
1163 \begin{code}
1164 rebuild :: SimplEnv -> OutExpr -> SimplCont -> SimplM (SimplEnv, OutExpr)
1165 -- At this point the substitution in the SimplEnv should be irrelevant
1166 -- only the in-scope set and floats should matter
1167 rebuild env expr cont
1168   = case cont of
1169       Stop {}                       -> return (env, expr)
1170       CoerceIt co cont              -> rebuild env (mkCast expr co) cont 
1171                                     -- NB: mkCast implements the (Coercion co |> g) optimisation
1172       Select _ bndr alts se cont    -> rebuildCase (se `setFloats` env) expr bndr alts cont
1173       StrictArg info _ cont         -> rebuildCall env (info `addArgTo` expr) cont
1174       StrictBind b bs body se cont  -> do { env' <- simplNonRecX (se `setFloats` env) b expr
1175                                           ; simplLam env' bs body cont }
1176       ApplyTo dup_flag arg se cont  -- See Note [Avoid redundant simplification]
1177         | isSimplified dup_flag     -> rebuild env (App expr arg) cont
1178         | otherwise                 -> do { arg' <- simplExpr (se `setInScope` env) arg
1179                                           ; rebuild env (App expr arg') cont }
1180       TickIt t cont                 -> rebuild env (mkTick t expr) cont
1181 \end{code}
1182
1183
1184 %************************************************************************
1185 %*                                                                      *
1186 \subsection{Lambdas}
1187 %*                                                                      *
1188 %************************************************************************
1189
1190 \begin{code}
1191 simplCast :: SimplEnv -> InExpr -> Coercion -> SimplCont
1192           -> SimplM (SimplEnv, OutExpr)
1193 simplCast env body co0 cont0
1194   = do  { co1 <- simplCoercion env co0
1195         ; -- pprTrace "simplCast" (ppr co1) $
1196           simplExprF env body (addCoerce co1 cont0) }
1197   where
1198        addCoerce co cont = add_coerce co (coercionKind co) cont
1199
1200        add_coerce _co (Pair s1 k1) cont     -- co :: ty~ty
1201          | s1 `eqType` k1 = cont    -- is a no-op
1202
1203        add_coerce co1 (Pair s1 _k2) (CoerceIt co2 cont)
1204          | (Pair _l1 t1) <- coercionKind co2
1205                 --      e |> (g1 :: S1~L) |> (g2 :: L~T1)
1206                 -- ==>
1207                 --      e,                       if S1=T1
1208                 --      e |> (g1 . g2 :: S1~T1)  otherwise
1209                 --
1210                 -- For example, in the initial form of a worker
1211                 -- we may find  (coerce T (coerce S (\x.e))) y
1212                 -- and we'd like it to simplify to e[y/x] in one round
1213                 -- of simplification
1214          , s1 `eqType` t1  = cont            -- The coerces cancel out
1215          | otherwise       = CoerceIt (mkTransCo co1 co2) cont
1216
1217        add_coerce co (Pair s1s2 _t1t2) (ApplyTo dup (Type arg_ty) arg_se cont)
1218                 -- (f |> g) ty  --->   (f ty) |> (g @ ty)
1219                 -- This implements the PushT rule from the paper
1220          | Just (tyvar,_) <- splitForAllTy_maybe s1s2
1221          = ASSERT( isTyVar tyvar )
1222            ApplyTo Simplified (Type arg_ty') (zapSubstEnv arg_se) (addCoerce new_cast cont)
1223          where
1224            new_cast = mkInstCo co arg_ty'
1225            arg_ty' | isSimplified dup = arg_ty
1226                    | otherwise        = substTy (arg_se `setInScope` env) arg_ty
1227
1228        add_coerce co (Pair s1s2 t1t2) (ApplyTo dup arg arg_se cont)
1229          | isFunTy s1s2   -- This implements the Push rule from the paper
1230          , isFunTy t1t2   -- Check t1t2 to ensure 'arg' is a value arg
1231                 --      (e |> (g :: s1s2 ~ t1->t2)) f
1232                 -- ===>
1233                 --      (e (f |> (arg g :: t1~s1))
1234                 --      |> (res g :: s2->t2)
1235                 --
1236                 -- t1t2 must be a function type, t1->t2, because it's applied
1237                 -- to something but s1s2 might conceivably not be
1238                 --
1239                 -- When we build the ApplyTo we can't mix the out-types
1240                 -- with the InExpr in the argument, so we simply substitute
1241                 -- to make it all consistent.  It's a bit messy.
1242                 -- But it isn't a common case.
1243                 --
1244                 -- Example of use: Trac #995
1245          = ApplyTo dup new_arg (zapSubstEnv arg_se) (addCoerce co2 cont)
1246          where
1247            -- we split coercion t1->t2 ~ s1->s2 into t1 ~ s1 and
1248            -- t2 ~ s2 with left and right on the curried form:
1249            --    (->) t1 t2 ~ (->) s1 s2
1250            [co1, co2] = decomposeCo 2 co
1251            new_arg    = mkCast arg' (mkSymCo co1)
1252            arg'       = substExpr (text "move-cast") arg_se' arg
1253            arg_se'    = arg_se `setInScope` env
1254
1255        add_coerce co _ cont = CoerceIt co cont
1256 \end{code}
1257
1258
1259 %************************************************************************
1260 %*                                                                      *
1261 \subsection{Lambdas}
1262 %*                                                                      *
1263 %************************************************************************
1264
1265 Note [Zap unfolding when beta-reducing]
1266 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1267 Lambda-bound variables can have stable unfoldings, such as
1268    $j = \x. \b{Unf=Just x}. e
1269 See Note [Case binders and join points] below; the unfolding for lets
1270 us optimise e better.  However when we beta-reduce it we want to
1271 revert to using the actual value, otherwise we can end up in the
1272 stupid situation of
1273           let x = blah in
1274           let b{Unf=Just x} = y
1275           in ...b...
1276 Here it'd be far better to drop the unfolding and use the actual RHS.
1277
1278 \begin{code}
1279 simplLam :: SimplEnv -> [InId] -> InExpr -> SimplCont
1280          -> SimplM (SimplEnv, OutExpr)
1281
1282 simplLam env [] body cont = simplExprF env body cont
1283
1284         -- Beta reduction
1285 simplLam env (bndr:bndrs) body (ApplyTo _ arg arg_se cont)
1286   = do  { tick (BetaReduction bndr)
1287         ; simplNonRecE env (zap_unfolding bndr) (arg, arg_se) (bndrs, body) cont }
1288   where
1289     zap_unfolding bndr  -- See Note [Zap unfolding when beta-reducing]
1290       | isId bndr, isStableUnfolding (realIdUnfolding bndr)
1291       = setIdUnfolding bndr NoUnfolding
1292       | otherwise = bndr
1293
1294       -- discard a non-counting tick on a lambda.  This may change the
1295       -- cost attribution slightly (moving the allocation of the
1296       -- lambda elsewhere), but we don't care: optimisation changes
1297       -- cost attribution all the time.
1298 simplLam env bndrs body (TickIt tickish cont)
1299   | not (tickishCounts tickish)
1300   = simplLam env bndrs body cont
1301
1302         -- Not enough args, so there are real lambdas left to put in the result
1303 simplLam env bndrs body cont
1304   = do  { (env', bndrs') <- simplLamBndrs env bndrs
1305         ; body' <- simplExpr env' body
1306         ; new_lam <- mkLam env' bndrs' body'
1307         ; rebuild env' new_lam cont }
1308
1309 ------------------
1310 simplNonRecE :: SimplEnv
1311              -> InBndr                  -- The binder
1312              -> (InExpr, SimplEnv)      -- Rhs of binding (or arg of lambda)
1313              -> ([InBndr], InExpr)      -- Body of the let/lambda
1314                                         --      \xs.e
1315              -> SimplCont
1316              -> SimplM (SimplEnv, OutExpr)
1317
1318 -- simplNonRecE is used for
1319 --  * non-top-level non-recursive lets in expressions
1320 --  * beta reduction
1321 --
1322 -- It deals with strict bindings, via the StrictBind continuation,
1323 -- which may abort the whole process
1324 --
1325 -- The "body" of the binding comes as a pair of ([InId],InExpr)
1326 -- representing a lambda; so we recurse back to simplLam
1327 -- Why?  Because of the binder-occ-info-zapping done before
1328 --       the call to simplLam in simplExprF (Lam ...)
1329
1330         -- First deal with type applications and type lets
1331         --   (/\a. e) (Type ty)   and   (let a = Type ty in e)
1332 simplNonRecE env bndr (Type ty_arg, rhs_se) (bndrs, body) cont
1333   = ASSERT( isTyVar bndr )
1334     do  { ty_arg' <- simplType (rhs_se `setInScope` env) ty_arg
1335         ; simplLam (extendTvSubst env bndr ty_arg') bndrs body cont }
1336
1337 simplNonRecE env bndr (rhs, rhs_se) (bndrs, body) cont
1338   | preInlineUnconditionally env NotTopLevel bndr rhs
1339   = do  { tick (PreInlineUnconditionally bndr)
1340         ; -- pprTrace "preInlineUncond" (ppr bndr <+> ppr rhs) $
1341           simplLam (extendIdSubst env bndr (mkContEx rhs_se rhs)) bndrs body cont }
1342
1343   | isStrictId bndr              -- Includes coercions
1344   = do  { simplExprF (rhs_se `setFloats` env) rhs
1345                      (StrictBind bndr bndrs body env cont) }
1346
1347   | otherwise
1348   = ASSERT( not (isTyVar bndr) )
1349     do  { (env1, bndr1) <- simplNonRecBndr env bndr
1350         ; let (env2, bndr2) = addBndrRules env1 bndr bndr1
1351         ; env3 <- simplLazyBind env2 NotTopLevel NonRecursive bndr bndr2 rhs rhs_se
1352         ; simplLam env3 bndrs body cont }
1353 \end{code}
1354
1355 %************************************************************************
1356 %*                                                                      *
1357                      Variables
1358 %*                                                                      *
1359 %************************************************************************
1360
1361 \begin{code}
1362 simplVar :: SimplEnv -> InVar -> SimplM OutExpr
1363 -- Look up an InVar in the environment
1364 simplVar env var
1365   | isTyVar var = return (Type (substTyVar env var))
1366   | isCoVar var = return (Coercion (substCoVar env var))
1367   | otherwise
1368   = case substId env var of
1369         DoneId var1          -> return (Var var1)
1370         DoneEx e             -> return e
1371         ContEx tvs cvs ids e -> simplExpr (setSubstEnv env tvs cvs ids) e
1372
1373 simplIdF :: SimplEnv -> InId -> SimplCont -> SimplM (SimplEnv, OutExpr)
1374 simplIdF env var cont
1375   = case substId env var of
1376         DoneEx e             -> simplExprF (zapSubstEnv env) e cont
1377         ContEx tvs cvs ids e -> simplExprF (setSubstEnv env tvs cvs ids) e cont
1378         DoneId var1          -> completeCall env var1 cont
1379                 -- Note [zapSubstEnv]
1380                 -- The template is already simplified, so don't re-substitute.
1381                 -- This is VITAL.  Consider
1382                 --      let x = e in
1383                 --      let y = \z -> ...x... in
1384                 --      \ x -> ...y...
1385                 -- We'll clone the inner \x, adding x->x' in the id_subst
1386                 -- Then when we inline y, we must *not* replace x by x' in
1387                 -- the inlined copy!!
1388
1389 ---------------------------------------------------------
1390 --      Dealing with a call site
1391
1392 completeCall :: SimplEnv -> OutId -> SimplCont -> SimplM (SimplEnv, OutExpr)
1393 completeCall env var cont
1394   = do  {   ------------- Try inlining ----------------
1395           dflags <- getDynFlags
1396         ; let  (lone_variable, arg_infos, call_cont) = contArgs cont
1397                 -- The args are OutExprs, obtained by *lazily* substituting
1398                 -- in the args found in cont.  These args are only examined
1399                 -- to limited depth (unless a rule fires).  But we must do
1400                 -- the substitution; rule matching on un-simplified args would
1401                 -- be bogus
1402
1403                n_val_args = length arg_infos
1404                interesting_cont = interestingCallContext call_cont
1405                unfolding    = activeUnfolding env var
1406                maybe_inline = callSiteInline dflags var unfolding
1407                                              lone_variable arg_infos interesting_cont
1408         ; case maybe_inline of {
1409             Just expr      -- There is an inlining!
1410               ->  do { checkedTick (UnfoldingDone var)
1411                      ; trace_inline dflags expr cont $
1412                        simplExprF (zapSubstEnv env) expr cont }
1413
1414             ; Nothing -> do               -- No inlining!
1415
1416         { rule_base <- getSimplRules
1417         ; let info = mkArgInfo var (getRules rule_base var) n_val_args call_cont
1418         ; rebuildCall env info cont
1419     }}}
1420   where
1421     trace_inline dflags unfolding cont stuff
1422       | not (dopt Opt_D_dump_inlinings dflags) = stuff
1423       | not (dopt Opt_D_verbose_core2core dflags) 
1424       = if isExternalName (idName var) then 
1425           pprDefiniteTrace dflags "Inlining done:" (ppr var) stuff
1426         else stuff
1427       | otherwise
1428       = pprDefiniteTrace dflags ("Inlining done: " ++ showSDocDump dflags (ppr var))
1429            (vcat [text "Inlined fn: " <+> nest 2 (ppr unfolding),
1430                   text "Cont:  " <+> ppr cont])
1431            stuff
1432
1433 rebuildCall :: SimplEnv
1434             -> ArgInfo
1435             -> SimplCont
1436             -> SimplM (SimplEnv, OutExpr)
1437 rebuildCall env (ArgInfo { ai_fun = fun, ai_args = rev_args, ai_strs = [] }) cont
1438   -- When we run out of strictness args, it means
1439   -- that the call is definitely bottom; see SimplUtils.mkArgInfo
1440   -- Then we want to discard the entire strict continuation.  E.g.
1441   --    * case (error "hello") of { ... }
1442   --    * (error "Hello") arg
1443   --    * f (error "Hello") where f is strict
1444   --    etc
1445   -- Then, especially in the first of these cases, we'd like to discard
1446   -- the continuation, leaving just the bottoming expression.  But the
1447   -- type might not be right, so we may have to add a coerce.
1448   | not (contIsTrivial cont)     -- Only do this if there is a non-trivial
1449   = return (env, castBottomExpr res cont_ty)  -- contination to discard, else we do it
1450   where                                       -- again and again!
1451     res     = mkApps (Var fun) (reverse rev_args)
1452     cont_ty = contResultType cont
1453
1454 rebuildCall env info (ApplyTo dup_flag (Type arg_ty) se cont)
1455   = do { arg_ty' <- if isSimplified dup_flag then return arg_ty
1456                     else simplType (se `setInScope` env) arg_ty
1457        ; rebuildCall env (info `addArgTo` Type arg_ty') cont }
1458
1459 rebuildCall env info@(ArgInfo { ai_encl = encl_rules, ai_type = fun_ty
1460                               , ai_strs = str:strs, ai_discs = disc:discs })
1461             (ApplyTo dup_flag arg arg_se cont)
1462   | isSimplified dup_flag     -- See Note [Avoid redundant simplification]
1463   = rebuildCall env (addArgTo info' arg) cont
1464
1465   | str                 -- Strict argument
1466   = -- pprTrace "Strict Arg" (ppr arg $$ ppr (seIdSubst env) $$ ppr (seInScope env)) $
1467     simplExprF (arg_se `setFloats` env) arg
1468                (StrictArg info' cci cont)
1469                 -- Note [Shadowing]
1470
1471   | otherwise                           -- Lazy argument
1472         -- DO NOT float anything outside, hence simplExprC
1473         -- There is no benefit (unlike in a let-binding), and we'd
1474         -- have to be very careful about bogus strictness through
1475         -- floating a demanded let.
1476   = do  { arg' <- simplExprC (arg_se `setInScope` env) arg
1477                              (mkLazyArgStop (funArgTy fun_ty) cci)
1478         ; rebuildCall env (addArgTo info' arg') cont }
1479   where
1480     info' = info { ai_strs = strs, ai_discs = discs }
1481     cci | encl_rules || disc > 0 = ArgCtxt encl_rules  -- Be keener here
1482         | otherwise              = BoringCtxt          -- Nothing interesting
1483
1484 rebuildCall env (ArgInfo { ai_fun = fun, ai_args = rev_args, ai_rules = rules }) cont
1485   = do {  -- We've accumulated a simplified call in <fun,rev_args> 
1486           -- so try rewrite rules; see Note [RULEs apply to simplified arguments]
1487           -- See also Note [Rules for recursive functions]
1488         ; let args = reverse rev_args
1489               env' = zapSubstEnv env
1490         ; mb_rule <- tryRules env rules fun args cont
1491         ; case mb_rule of {
1492              Just (n_args, rule_rhs) -> simplExprF env' rule_rhs $
1493                                         pushSimplifiedArgs env' (drop n_args args) cont ;
1494                  -- n_args says how many args the rule consumed
1495            ; Nothing -> rebuild env (mkApps (Var fun) args) cont      -- No rules
1496     } }
1497 \end{code}
1498
1499 Note [RULES apply to simplified arguments]
1500 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1501 It's very desirable to try RULES once the arguments have been simplified, because
1502 doing so ensures that rule cascades work in one pass.  Consider
1503    {-# RULES g (h x) = k x
1504              f (k x) = x #-}
1505    ...f (g (h x))...
1506 Then we want to rewrite (g (h x)) to (k x) and only then try f's rules. If
1507 we match f's rules against the un-simplified RHS, it won't match.  This 
1508 makes a particularly big difference when superclass selectors are involved:
1509         op ($p1 ($p2 (df d)))
1510 We want all this to unravel in one sweeep.
1511
1512 Note [Avoid redundant simplification]
1513 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1514 Because RULES apply to simplified arguments, there's a danger of repeatedly
1515 simplifying already-simplified arguments.  An important example is that of
1516             (>>=) d e1 e2
1517 Here e1, e2 are simplified before the rule is applied, but don't really
1518 participate in the rule firing. So we mark them as Simplified to avoid
1519 re-simplifying them.
1520
1521 Note [Shadowing]
1522 ~~~~~~~~~~~~~~~~
1523 This part of the simplifier may break the no-shadowing invariant
1524 Consider
1525         f (...(\a -> e)...) (case y of (a,b) -> e')
1526 where f is strict in its second arg
1527 If we simplify the innermost one first we get (...(\a -> e)...)
1528 Simplifying the second arg makes us float the case out, so we end up with
1529         case y of (a,b) -> f (...(\a -> e)...) e'
1530 So the output does not have the no-shadowing invariant.  However, there is
1531 no danger of getting name-capture, because when the first arg was simplified
1532 we used an in-scope set that at least mentioned all the variables free in its
1533 static environment, and that is enough.
1534
1535 We can't just do innermost first, or we'd end up with a dual problem:
1536         case x of (a,b) -> f e (...(\a -> e')...)
1537
1538 I spent hours trying to recover the no-shadowing invariant, but I just could
1539 not think of an elegant way to do it.  The simplifier is already knee-deep in
1540 continuations.  We have to keep the right in-scope set around; AND we have
1541 to get the effect that finding (error "foo") in a strict arg position will
1542 discard the entire application and replace it with (error "foo").  Getting
1543 all this at once is TOO HARD!
1544
1545
1546 %************************************************************************
1547 %*                                                                      *
1548                 Rewrite rules
1549 %*                                                                      *
1550 %************************************************************************
1551
1552 \begin{code}
1553 tryRules :: SimplEnv -> [CoreRule]
1554          -> Id -> [OutExpr] -> SimplCont 
1555          -> SimplM (Maybe (Arity, CoreExpr))         -- The arity is the number of
1556                                                      -- args consumed by the rule
1557 tryRules env rules fn args call_cont
1558   | null rules
1559   = return Nothing
1560   | otherwise
1561   = do { case lookupRule (activeRule env) (getUnfoldingInRuleMatch env) 
1562                          (getInScope env) fn args rules of {
1563            Nothing               -> return Nothing ;   -- No rule matches
1564            Just (rule, rule_rhs) ->
1565
1566              do { checkedTick (RuleFired (ru_name rule))
1567                 ; dflags <- getDynFlags
1568                 ; trace_dump dflags rule rule_rhs $
1569                   return (Just (ruleArity rule, rule_rhs)) }}}
1570   where
1571     trace_dump dflags rule rule_rhs stuff
1572       | not (dopt Opt_D_dump_rule_firings dflags)
1573       , not (dopt Opt_D_dump_rule_rewrites dflags) = stuff
1574
1575       | not (dopt Opt_D_dump_rule_rewrites dflags)
1576       = pprDefiniteTrace dflags "Rule fired:" (ftext (ru_name rule)) stuff
1577
1578       | otherwise
1579       = pprDefiniteTrace dflags "Rule fired"
1580            (vcat [text "Rule:" <+> ftext (ru_name rule),
1581                   text "Before:" <+> hang (ppr fn) 2 (sep (map pprParendExpr args)),
1582                   text "After: " <+> pprCoreExpr rule_rhs,
1583                   text "Cont:  " <+> ppr call_cont])
1584            stuff
1585 \end{code}
1586
1587 Note [Rules for recursive functions]
1588 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1589 You might think that we shouldn't apply rules for a loop breaker:
1590 doing so might give rise to an infinite loop, because a RULE is
1591 rather like an extra equation for the function:
1592      RULE:           f (g x) y = x+y
1593      Eqn:            f a     y = a-y
1594
1595 But it's too drastic to disable rules for loop breakers.
1596 Even the foldr/build rule would be disabled, because foldr
1597 is recursive, and hence a loop breaker:
1598      foldr k z (build g) = g k z
1599 So it's up to the programmer: rules can cause divergence
1600
1601
1602 %************************************************************************
1603 %*                                                                      *
1604                 Rebuilding a case expression
1605 %*                                                                      *
1606 %************************************************************************
1607
1608 Note [Case elimination]
1609 ~~~~~~~~~~~~~~~~~~~~~~~
1610 The case-elimination transformation discards redundant case expressions.
1611 Start with a simple situation:
1612
1613         case x# of      ===>   let y# = x# in e
1614           y# -> e
1615
1616 (when x#, y# are of primitive type, of course).  We can't (in general)
1617 do this for algebraic cases, because we might turn bottom into
1618 non-bottom!
1619
1620 The code in SimplUtils.prepareAlts has the effect of generalise this
1621 idea to look for a case where we're scrutinising a variable, and we
1622 know that only the default case can match.  For example:
1623
1624         case x of
1625           0#      -> ...
1626           DEFAULT -> ...(case x of
1627                          0#      -> ...
1628                          DEFAULT -> ...) ...
1629
1630 Here the inner case is first trimmed to have only one alternative, the
1631 DEFAULT, after which it's an instance of the previous case.  This
1632 really only shows up in eliminating error-checking code.
1633
1634 Note that SimplUtils.mkCase combines identical RHSs.  So
1635
1636         case e of       ===> case e of DEFAULT -> r
1637            True  -> r
1638            False -> r
1639
1640 Now again the case may be elminated by the CaseElim transformation.
1641 This includes things like (==# a# b#)::Bool so that we simplify
1642       case ==# a# b# of { True -> x; False -> x }
1643 to just
1644       x
1645 This particular example shows up in default methods for
1646 comparision operations (e.g. in (>=) for Int.Int32)
1647
1648 Note [Case elimination: lifted case]
1649 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1650 We also make sure that we deal with this very common case,
1651 where x has a lifted type:
1652
1653         case e of
1654           x -> ...x...
1655
1656 Here we are using the case as a strict let; if x is used only once
1657 then we want to inline it.  We have to be careful that this doesn't
1658 make the program terminate when it would have diverged before, so we
1659 check that
1660         (a) 'e' is already evaluated (it may so if e is a variable)
1661             Specifically we check (exprIsHNF e)
1662 or
1663         (b) the scrutinee is a variable and 'x' is used strictly
1664 or
1665         (c) 'x' is not used at all and e is ok-for-speculation
1666
1667 For the (c), consider
1668    case (case a ># b of { True -> (p,q); False -> (q,p) }) of
1669      r -> blah
1670 The scrutinee is ok-for-speculation (it looks inside cases), but we do
1671 not want to transform to
1672    let r = case a ># b of { True -> (p,q); False -> (q,p) }
1673    in blah
1674 because that builds an unnecessary thunk.
1675
1676 Note [Case elimination: unlifted case]
1677 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1678 Consider 
1679    case a +# b of r -> ...r...
1680 Then we do case-elimination (to make a let) followed by inlining,
1681 to get
1682         .....(a +# b)....
1683 If we have
1684    case indexArray# a i of r -> ...r...
1685 we might like to do the same, and inline the (indexArray# a i). 
1686 But indexArray# is not okForSpeculation, so we don't build a let
1687 in rebuildCase (lest it get floated *out*), so the inlining doesn't
1688 happen either.
1689
1690 This really isn't a big deal I think. The let can be 
1691
1692
1693 Further notes about case elimination
1694 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1695 Consider:       test :: Integer -> IO ()
1696                 test = print
1697
1698 Turns out that this compiles to:
1699     Print.test
1700       = \ eta :: Integer
1701           eta1 :: State# RealWorld ->
1702           case PrelNum.< eta PrelNum.zeroInteger of wild { __DEFAULT ->
1703           case hPutStr stdout
1704                  (PrelNum.jtos eta ($w[] @ Char))
1705                  eta1
1706           of wild1 { (# new_s, a4 #) -> PrelIO.lvl23 new_s  }}
1707
1708 Notice the strange '<' which has no effect at all. This is a funny one.
1709 It started like this:
1710
1711 f x y = if x < 0 then jtos x
1712           else if y==0 then "" else jtos x
1713
1714 At a particular call site we have (f v 1).  So we inline to get
1715
1716         if v < 0 then jtos x
1717         else if 1==0 then "" else jtos x
1718
1719 Now simplify the 1==0 conditional:
1720
1721         if v<0 then jtos v else jtos v
1722
1723 Now common-up the two branches of the case:
1724
1725         case (v<0) of DEFAULT -> jtos v
1726
1727 Why don't we drop the case?  Because it's strict in v.  It's technically
1728 wrong to drop even unnecessary evaluations, and in practice they
1729 may be a result of 'seq' so we *definitely* don't want to drop those.
1730 I don't really know how to improve this situation.
1731
1732 \begin{code}
1733 ---------------------------------------------------------
1734 --      Eliminate the case if possible
1735
1736 rebuildCase, reallyRebuildCase
1737    :: SimplEnv
1738    -> OutExpr          -- Scrutinee
1739    -> InId             -- Case binder
1740    -> [InAlt]          -- Alternatives (inceasing order)
1741    -> SimplCont
1742    -> SimplM (SimplEnv, OutExpr)
1743
1744 --------------------------------------------------
1745 --      1. Eliminate the case if there's a known constructor
1746 --------------------------------------------------
1747
1748 rebuildCase env scrut case_bndr alts cont
1749   | Lit lit <- scrut    -- No need for same treatment as constructors
1750                         -- because literals are inlined more vigorously
1751   , not (litIsLifted lit)
1752   = do  { tick (KnownBranch case_bndr)
1753         ; case findAlt (LitAlt lit) alts of
1754             Nothing           -> missingAlt env case_bndr alts cont
1755             Just (_, bs, rhs) -> simple_rhs bs rhs }
1756
1757   | Just (con, ty_args, other_args) <- exprIsConApp_maybe (getUnfoldingInRuleMatch env) scrut
1758         -- Works when the scrutinee is a variable with a known unfolding
1759         -- as well as when it's an explicit constructor application
1760   = do  { tick (KnownBranch case_bndr)
1761         ; case findAlt (DataAlt con) alts of
1762             Nothing  -> missingAlt env case_bndr alts cont
1763             Just (DEFAULT, bs, rhs) -> simple_rhs bs rhs
1764             Just (_, bs, rhs)       -> knownCon env scrut con ty_args other_args 
1765                                                 case_bndr bs rhs cont
1766         }
1767   where
1768     simple_rhs bs rhs = ASSERT( null bs ) 
1769                         do { env' <- simplNonRecX env case_bndr scrut
1770                            ; simplExprF env' rhs cont }
1771
1772
1773 --------------------------------------------------
1774 --      2. Eliminate the case if scrutinee is evaluated
1775 --------------------------------------------------
1776
1777 rebuildCase env scrut case_bndr [(_, bndrs, rhs)] cont
1778   -- See if we can get rid of the case altogether
1779   -- See Note [Case elimination] 
1780   -- mkCase made sure that if all the alternatives are equal,
1781   -- then there is now only one (DEFAULT) rhs
1782  | all isDeadBinder bndrs       -- bndrs are [InId]
1783
1784  , if isUnLiftedType (idType case_bndr)
1785    then elim_unlifted        -- Satisfy the let-binding invariant
1786    else elim_lifted
1787   = do  { -- pprTrace "case elim" (vcat [ppr case_bndr, ppr (exprIsHNF scrut),
1788           --                            ppr strict_case_bndr, ppr (scrut_is_var scrut),
1789           --                            ppr ok_for_spec,
1790           --                            ppr scrut]) $
1791           tick (CaseElim case_bndr)
1792         ; env' <- simplNonRecX env case_bndr scrut
1793           -- If case_bndr is deads, simplNonRecX will discard
1794         ; simplExprF env' rhs cont }
1795   where
1796     elim_lifted   -- See Note [Case elimination: lifted case]
1797       = exprIsHNF scrut
1798      || (strict_case_bndr && scrut_is_var scrut) 
1799               -- The case binder is going to be evaluated later,
1800               -- and the scrutinee is a simple variable
1801
1802      || (is_plain_seq && ok_for_spec)
1803               -- Note: not the same as exprIsHNF
1804
1805     elim_unlifted 
1806       | is_plain_seq = exprOkForSideEffects scrut
1807             -- The entire case is dead, so we can drop it,
1808             -- _unless_ the scrutinee has side effects
1809       | otherwise    = exprOkForSpeculation scrut
1810             -- The case-binder is alive, but we may be able
1811             -- turn the case into a let, if the expression is ok-for-spec
1812             -- See Note [Case elimination: unlifted case]
1813
1814     ok_for_spec      = exprOkForSpeculation scrut
1815     is_plain_seq     = isDeadBinder case_bndr   -- Evaluation *only* for effect
1816     strict_case_bndr = isStrictDmd (idDemandInfo case_bndr)
1817
1818     scrut_is_var (Cast s _) = scrut_is_var s
1819     scrut_is_var (Var _)    = True
1820     scrut_is_var _          = False
1821
1822
1823 --------------------------------------------------
1824 --      3. Try seq rules; see Note [User-defined RULES for seq] in MkId
1825 --------------------------------------------------
1826
1827 rebuildCase env scrut case_bndr alts@[(_, bndrs, rhs)] cont
1828   | all isDeadBinder (case_bndr : bndrs)  -- So this is just 'seq'
1829   = do { let rhs' = substExpr (text "rebuild-case") env rhs
1830              out_args = [Type (substTy env (idType case_bndr)), 
1831                          Type (exprType rhs'), scrut, rhs']
1832                       -- Lazily evaluated, so we don't do most of this
1833
1834        ; rule_base <- getSimplRules
1835        ; mb_rule <- tryRules env (getRules rule_base seqId) seqId out_args cont
1836        ; case mb_rule of 
1837            Just (n_args, res) -> simplExprF (zapSubstEnv env) 
1838                                             (mkApps res (drop n_args out_args))
1839                                             cont
1840            Nothing -> reallyRebuildCase env scrut case_bndr alts cont }
1841
1842 rebuildCase env scrut case_bndr alts cont
1843   = reallyRebuildCase env scrut case_bndr alts cont
1844
1845 --------------------------------------------------
1846 --      3. Catch-all case
1847 --------------------------------------------------
1848
1849 reallyRebuildCase env scrut case_bndr alts cont
1850   = do  {       -- Prepare the continuation;
1851                 -- The new subst_env is in place
1852           (env', dup_cont, nodup_cont) <- prepareCaseCont env alts cont
1853
1854         -- Simplify the alternatives
1855         ; (scrut', case_bndr', alts') <- simplAlts env' scrut case_bndr alts dup_cont
1856
1857         ; dflags <- getDynFlags
1858         ; let alts_ty' = contResultType dup_cont
1859         ; case_expr <- mkCase dflags scrut' case_bndr' alts_ty' alts'
1860
1861         -- Notice that rebuild gets the in-scope set from env', not alt_env
1862         -- (which in any case is only build in simplAlts)
1863         -- The case binder *not* scope over the whole returned case-expression
1864         ; rebuild env' case_expr nodup_cont }
1865 \end{code}
1866
1867 simplCaseBinder checks whether the scrutinee is a variable, v.  If so,
1868 try to eliminate uses of v in the RHSs in favour of case_bndr; that
1869 way, there's a chance that v will now only be used once, and hence
1870 inlined.
1871
1872 Historical note: we use to do the "case binder swap" in the Simplifier
1873 so there were additional complications if the scrutinee was a variable.
1874 Now the binder-swap stuff is done in the occurrence analyer; see
1875 OccurAnal Note [Binder swap].
1876
1877 Note [zapOccInfo]
1878 ~~~~~~~~~~~~~~~~~
1879 If the case binder is not dead, then neither are the pattern bound
1880 variables:  
1881         case <any> of x { (a,b) ->
1882         case x of { (p,q) -> p } }
1883 Here (a,b) both look dead, but come alive after the inner case is eliminated.
1884 The point is that we bring into the envt a binding
1885         let x = (a,b)
1886 after the outer case, and that makes (a,b) alive.  At least we do unless
1887 the case binder is guaranteed dead.
1888
1889 In practice, the scrutinee is almost always a variable, so we pretty
1890 much always zap the OccInfo of the binders.  It doesn't matter much though.
1891
1892 Note [Improving seq]
1893 ~~~~~~~~~~~~~~~~~~~
1894 Consider
1895         type family F :: * -> *
1896         type instance F Int = Int
1897
1898         ... case e of x { DEFAULT -> rhs } ...
1899
1900 where x::F Int.  Then we'd like to rewrite (F Int) to Int, getting
1901
1902         case e `cast` co of x'::Int
1903            I# x# -> let x = x' `cast` sym co
1904                     in rhs
1905
1906 so that 'rhs' can take advantage of the form of x'.  
1907
1908 Notice that Note [Case of cast] (in OccurAnal) may then apply to the result. 
1909
1910 Nota Bene: We only do the [Improving seq] transformation if the 
1911 case binder 'x' is actually used in the rhs; that is, if the case 
1912 is *not* a *pure* seq.  
1913   a) There is no point in adding the cast to a pure seq.
1914   b) There is a good reason not to: doing so would interfere 
1915      with seq rules (Note [Built-in RULES for seq] in MkId).
1916      In particular, this [Improving seq] thing *adds* a cast
1917      while [Built-in RULES for seq] *removes* one, so they
1918      just flip-flop.
1919
1920 You might worry about 
1921    case v of x { __DEFAULT ->
1922       ... case (v `cast` co) of y { I# -> ... }}
1923 This is a pure seq (since x is unused), so [Improving seq] won't happen.
1924 But it's ok: the simplifier will replace 'v' by 'x' in the rhs to get
1925    case v of x { __DEFAULT ->
1926       ... case (x `cast` co) of y { I# -> ... }}
1927 Now the outer case is not a pure seq, so [Improving seq] will happen,
1928 and then the inner case will disappear.
1929
1930 The need for [Improving seq] showed up in Roman's experiments.  Example:
1931   foo :: F Int -> Int -> Int
1932   foo t n = t `seq` bar n
1933      where
1934        bar 0 = 0
1935        bar n = bar (n - case t of TI i -> i)
1936 Here we'd like to avoid repeated evaluating t inside the loop, by
1937 taking advantage of the `seq`.
1938
1939 At one point I did transformation in LiberateCase, but it's more
1940 robust here.  (Otherwise, there's a danger that we'll simply drop the
1941 'seq' altogether, before LiberateCase gets to see it.)
1942
1943 \begin{code}
1944 simplAlts :: SimplEnv
1945           -> OutExpr
1946           -> InId                       -- Case binder
1947           -> [InAlt]                    -- Non-empty
1948           -> SimplCont
1949           -> SimplM (OutExpr, OutId, [OutAlt])  -- Includes the continuation
1950 -- Like simplExpr, this just returns the simplified alternatives;
1951 -- it does not return an environment
1952 -- The returned alternatives can be empty, none are possible
1953
1954 simplAlts env scrut case_bndr alts cont'
1955   = do  { let env0 = zapFloats env
1956
1957         ; (env1, case_bndr1) <- simplBinder env0 case_bndr
1958
1959         ; fam_envs <- getFamEnvs
1960         ; (alt_env', scrut', case_bndr') <- improveSeq fam_envs env1 scrut 
1961                                                        case_bndr case_bndr1 alts
1962
1963         ; (imposs_deflt_cons, in_alts) <- prepareAlts scrut' case_bndr' alts
1964           -- NB: it's possible that the returned in_alts is empty: this is handled
1965           -- by the caller (rebuildCase) in the missingAlt function
1966
1967         ; let mb_var_scrut = case scrut' of { Var v -> Just v; _ -> Nothing }
1968         ; alts' <- mapM (simplAlt alt_env' mb_var_scrut
1969                              imposs_deflt_cons case_bndr' cont') in_alts
1970         ; -- pprTrace "simplAlts" (ppr case_bndr $$ ppr alts_ty $$ ppr alts_ty' $$ ppr alts $$ ppr cont') $
1971           return (scrut', case_bndr', alts') }
1972
1973
1974 ------------------------------------
1975 improveSeq :: (FamInstEnv, FamInstEnv) -> SimplEnv
1976            -> OutExpr -> InId -> OutId -> [InAlt]
1977            -> SimplM (SimplEnv, OutExpr, OutId)
1978 -- Note [Improving seq]
1979 improveSeq fam_envs env scrut case_bndr case_bndr1 [(DEFAULT,_,_)]
1980   | not (isDeadBinder case_bndr)        -- Not a pure seq!  See Note [Improving seq]
1981   , Just (co, ty2) <- topNormaliseType fam_envs (idType case_bndr1)
1982   = do { case_bndr2 <- newId (fsLit "nt") ty2
1983         ; let rhs  = DoneEx (Var case_bndr2 `Cast` mkSymCo co)
1984               env2 = extendIdSubst env case_bndr rhs
1985         ; return (env2, scrut `Cast` co, case_bndr2) }
1986
1987 improveSeq _ env scrut _ case_bndr1 _
1988   = return (env, scrut, case_bndr1)
1989
1990
1991 ------------------------------------
1992 simplAlt :: SimplEnv
1993          -> Maybe OutId    -- Scrutinee
1994          -> [AltCon]       -- These constructors can't be present when
1995                            -- matching the DEFAULT alternative
1996          -> OutId          -- The case binder
1997          -> SimplCont
1998          -> InAlt
1999          -> SimplM OutAlt
2000
2001 simplAlt env scrut imposs_deflt_cons case_bndr' cont' (DEFAULT, bndrs, rhs)
2002   = ASSERT( null bndrs )
2003     do  { let env' = addBinderUnfolding env scrut case_bndr' 
2004                                         (mkOtherCon imposs_deflt_cons)
2005                 -- Record the constructors that the case-binder *can't* be.
2006         ; rhs' <- simplExprC env' rhs cont'
2007         ; return (DEFAULT, [], rhs') }
2008
2009 simplAlt env scrut _ case_bndr' cont' (LitAlt lit, bndrs, rhs)
2010   = ASSERT( null bndrs )
2011     do  { let env' = addBinderUnfolding env scrut case_bndr' 
2012                                         (mkSimpleUnfolding (Lit lit))
2013         ; rhs' <- simplExprC env' rhs cont'
2014         ; return (LitAlt lit, [], rhs') }
2015
2016 simplAlt env scrut _ case_bndr' cont' (DataAlt con, vs, rhs)
2017   = do  {       -- Deal with the pattern-bound variables
2018                 -- Mark the ones that are in ! positions in the
2019                 -- data constructor as certainly-evaluated.
2020                 -- NB: simplLamBinders preserves this eval info
2021           let vs_with_evals = add_evals (dataConRepStrictness con)
2022         ; (env', vs') <- simplLamBndrs env vs_with_evals
2023
2024                 -- Bind the case-binder to (con args)
2025         ; let inst_tys' = tyConAppArgs (idType case_bndr')
2026               con_args  = map Type inst_tys' ++ varsToCoreExprs vs'
2027               unf       = mkSimpleUnfolding (mkConApp con con_args)
2028               env''     = addBinderUnfolding env' scrut case_bndr' unf
2029
2030         ; rhs' <- simplExprC env'' rhs cont'
2031         ; return (DataAlt con, vs', rhs') }
2032   where
2033         -- add_evals records the evaluated-ness of the bound variables of
2034         -- a case pattern.  This is *important*.  Consider
2035         --      data T = T !Int !Int
2036         --
2037         --      case x of { T a b -> T (a+1) b }
2038         --
2039         -- We really must record that b is already evaluated so that we don't
2040         -- go and re-evaluate it when constructing the result.
2041         -- See Note [Data-con worker strictness] in MkId.lhs
2042     add_evals the_strs
2043         = go vs the_strs
2044         where
2045           go [] [] = []
2046           go (v:vs') strs | isTyVar v = v : go vs' strs
2047           go (v:vs') (str:strs)
2048             | isMarkedStrict str = evald_v  : go vs' strs
2049             | otherwise          = zapped_v : go vs' strs
2050             where
2051               zapped_v = zapBndrOccInfo keep_occ_info v
2052               evald_v  = zapped_v `setIdUnfolding` evaldUnfolding
2053           go _ _ = pprPanic "cat_evals" (ppr con $$ ppr vs $$ ppr the_strs)
2054
2055         -- See Note [zapOccInfo]
2056         -- zap_occ_info: if the case binder is alive, then we add the unfolding
2057         --      case_bndr = C vs
2058         -- to the envt; so vs are now very much alive
2059         -- Note [Aug06] I can't see why this actually matters, but it's neater
2060         --        case e of t { (a,b) -> ...(case t of (p,q) -> p)... }
2061         --   ==>  case e of t { (a,b) -> ...(a)... }
2062         -- Look, Ma, a is alive now.
2063     keep_occ_info = isDeadBinder case_bndr' && isNothing scrut
2064
2065 addBinderUnfolding :: SimplEnv -> Maybe OutId -> Id -> Unfolding -> SimplEnv
2066 addBinderUnfolding env scrut bndr unf
2067   = case scrut of
2068        Just v -> modifyInScope env1 (v `setIdUnfolding` unf)
2069        _      -> env1
2070   where
2071     env1 = modifyInScope env bndr_w_unf
2072     bndr_w_unf = bndr `setIdUnfolding` unf
2073
2074 zapBndrOccInfo :: Bool -> Id -> Id
2075 -- Consider  case e of b { (a,b) -> ... }
2076 -- Then if we bind b to (a,b) in "...", and b is not dead,
2077 -- then we must zap the deadness info on a,b
2078 zapBndrOccInfo keep_occ_info pat_id
2079   | keep_occ_info = pat_id
2080   | otherwise     = zapIdOccInfo pat_id
2081 \end{code}
2082
2083 Note [Add unfolding for scrutinee]
2084 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2085 In general it's unlikely that a variable scrutinee will appear 
2086 in the case alternatives   case x of { ...x unlikely to appear... }
2087 because the binder-swap in OccAnal has got rid of all such occcurrences
2088 See Note [Binder swap] in OccAnal.
2089
2090 BUT it is still VERY IMPORTANT to add a suitable unfolding for a
2091 variable scrutinee, in simplAlt.  Here's why
2092    case x of y
2093      (a,b) -> case b of c
2094                 I# v -> ...(f y)...
2095 There is no occurrence of 'b' in the (...(f y)...).  But y gets
2096 the unfolding (a,b), and *that* mentions b.  If f has a RULE
2097     RULE f (p, I# q) = ...
2098 we want that rule to match, so we must extend the in-scope env with a
2099 suitable unfolding for 'y'.  It's *essential* for rule matching; but
2100 it's also good for case-elimintation -- suppose that 'f' was inlined
2101 and did multi-level case analysis, then we'd solve it in one
2102 simplifier sweep instead of two.
2103
2104 Exactly the same issue arises in SpecConstr; 
2105 see Note [Add scrutinee to ValueEnv too] in SpecConstr
2106
2107 %************************************************************************
2108 %*                                                                      *
2109 \subsection{Known constructor}
2110 %*                                                                      *
2111 %************************************************************************
2112
2113 We are a bit careful with occurrence info.  Here's an example
2114
2115         (\x* -> case x of (a*, b) -> f a) (h v, e)
2116
2117 where the * means "occurs once".  This effectively becomes
2118         case (h v, e) of (a*, b) -> f a)
2119 and then
2120         let a* = h v; b = e in f a
2121 and then
2122         f (h v)
2123
2124 All this should happen in one sweep.
2125
2126 \begin{code}
2127 knownCon :: SimplEnv            
2128          -> OutExpr                             -- The scrutinee
2129          -> DataCon -> [OutType] -> [OutExpr]   -- The scrutinee (in pieces)
2130          -> InId -> [InBndr] -> InExpr          -- The alternative
2131          -> SimplCont
2132          -> SimplM (SimplEnv, OutExpr)
2133
2134 knownCon env scrut dc dc_ty_args dc_args bndr bs rhs cont
2135   = do  { env'  <- bind_args env bs dc_args
2136         ; env'' <- bind_case_bndr env'
2137         ; simplExprF env'' rhs cont }
2138   where
2139     zap_occ = zapBndrOccInfo (isDeadBinder bndr)    -- bndr is an InId
2140
2141                   -- Ugh!
2142     bind_args env' [] _  = return env'
2143
2144     bind_args env' (b:bs') (Type ty : args)
2145       = ASSERT( isTyVar b )
2146         bind_args (extendTvSubst env' b ty) bs' args
2147
2148     bind_args env' (b:bs') (arg : args)
2149       = ASSERT( isId b )
2150         do { let b' = zap_occ b
2151              -- Note that the binder might be "dead", because it doesn't
2152              -- occur in the RHS; and simplNonRecX may therefore discard
2153              -- it via postInlineUnconditionally.
2154              -- Nevertheless we must keep it if the case-binder is alive,
2155              -- because it may be used in the con_app.  See Note [zapOccInfo]
2156            ; env'' <- simplNonRecX env' b' arg
2157            ; bind_args env'' bs' args }
2158
2159     bind_args _ _ _ =
2160       pprPanic "bind_args" $ ppr dc $$ ppr bs $$ ppr dc_args $$
2161                              text "scrut:" <+> ppr scrut
2162
2163        -- It's useful to bind bndr to scrut, rather than to a fresh
2164        -- binding      x = Con arg1 .. argn
2165        -- because very often the scrut is a variable, so we avoid
2166        -- creating, and then subsequently eliminating, a let-binding
2167        -- BUT, if scrut is a not a variable, we must be careful
2168        -- about duplicating the arg redexes; in that case, make
2169        -- a new con-app from the args
2170     bind_case_bndr env
2171       | isDeadBinder bndr   = return env
2172       | exprIsTrivial scrut = return (extendIdSubst env bndr (DoneEx scrut))
2173       | otherwise           = do { dc_args <- mapM (simplVar env) bs
2174                                          -- dc_ty_args are aready OutTypes, 
2175                                          -- but bs are InBndrs
2176                                  ; let con_app = Var (dataConWorkId dc) 
2177                                                  `mkTyApps` dc_ty_args      
2178                                                  `mkApps`   dc_args
2179                                  ; simplNonRecX env bndr con_app }
2180   
2181 -------------------
2182 missingAlt :: SimplEnv -> Id -> [InAlt] -> SimplCont -> SimplM (SimplEnv, OutExpr)
2183                 -- This isn't strictly an error, although it is unusual. 
2184                 -- It's possible that the simplifer might "see" that 
2185                 -- an inner case has no accessible alternatives before 
2186                 -- it "sees" that the entire branch of an outer case is 
2187                 -- inaccessible.  So we simply put an error case here instead.
2188 missingAlt env case_bndr _ cont
2189   = WARN( True, ptext (sLit "missingAlt") <+> ppr case_bndr )
2190     return (env, mkImpossibleExpr (contResultType cont))
2191 \end{code}
2192
2193
2194 %************************************************************************
2195 %*                                                                      *
2196 \subsection{Duplicating continuations}
2197 %*                                                                      *
2198 %************************************************************************
2199
2200 \begin{code}
2201 prepareCaseCont :: SimplEnv
2202                 -> [InAlt] -> SimplCont
2203                 -> SimplM (SimplEnv, SimplCont, SimplCont)
2204 -- We are considering
2205 --     K[case _ of { p1 -> r1; ...; pn -> rn }] 
2206 -- where K is some enclosing continuation for the case
2207 -- Goal: split K into two pieces Kdup,Knodup so that
2208 --       a) Kdup can be duplicated
2209 --       b) Knodup[Kdup[e]] = K[e]
2210 -- The idea is that we'll transform thus:
2211 --          Knodup[ (case _ of { p1 -> Kdup[r1]; ...; pn -> Kdup[rn] }
2212 --
2213 -- We also return some extra bindings in SimplEnv (that scope over 
2214 -- the entire continuation)
2215
2216 prepareCaseCont env alts cont 
2217   | many_alts alts = mkDupableCont env cont 
2218   | otherwise      = return (env, cont, mkBoringStop (contResultType cont))
2219   where
2220     many_alts :: [InAlt] -> Bool  -- True iff strictly > 1 non-bottom alternative
2221     many_alts []  = False         -- See Note [Bottom alternatives]
2222     many_alts [_] = False
2223     many_alts (alt:alts) 
2224       | is_bot_alt alt = many_alts alts   
2225       | otherwise      = not (all is_bot_alt alts)
2226   
2227     is_bot_alt (_,_,rhs) = exprIsBottom rhs
2228 \end{code}
2229
2230 Note [Bottom alternatives]
2231 ~~~~~~~~~~~~~~~~~~~~~~~~~~
2232 When we have
2233      case (case x of { A -> error .. ; B -> e; C -> error ..) 
2234        of alts
2235 then we can just duplicate those alts because the A and C cases
2236 will disappear immediately.  This is more direct than creating
2237 join points and inlining them away; and in some cases we would
2238 not even create the join points (see Note [Single-alternative case])
2239 and we would keep the case-of-case which is silly.  See Trac #4930.
2240
2241 \begin{code}
2242 mkDupableCont :: SimplEnv -> SimplCont
2243               -> SimplM (SimplEnv, SimplCont, SimplCont)
2244
2245 mkDupableCont env cont
2246   | contIsDupable cont
2247   = return (env, cont, mkBoringStop (contResultType cont))
2248
2249 mkDupableCont _   (Stop {}) = panic "mkDupableCont"     -- Handled by previous eqn
2250
2251 mkDupableCont env (CoerceIt ty cont)
2252   = do  { (env', dup, nodup) <- mkDupableCont env cont
2253         ; return (env', CoerceIt ty dup, nodup) }
2254
2255 -- Duplicating ticks for now, not sure if this is good or not
2256 mkDupableCont env cont@(TickIt{})
2257   = return (env, mkBoringStop (contInputType cont), cont)
2258
2259 mkDupableCont env cont@(StrictBind {})
2260   =  return (env, mkBoringStop (contInputType cont), cont)
2261         -- See Note [Duplicating StrictBind]
2262
2263 mkDupableCont env (StrictArg info cci cont)
2264         -- See Note [Duplicating StrictArg]
2265   = do { (env', dup, nodup) <- mkDupableCont env cont
2266        ; (env'', args')     <- mapAccumLM (makeTrivial NotTopLevel) env' (ai_args info)
2267        ; return (env'', StrictArg (info { ai_args = args' }) cci dup, nodup) }
2268
2269 mkDupableCont env (ApplyTo _ arg se cont)
2270   =     -- e.g.         [...hole...] (...arg...)
2271         --      ==>
2272         --              let a = ...arg...
2273         --              in [...hole...] a
2274     do  { (env', dup_cont, nodup_cont) <- mkDupableCont env cont
2275         ; arg' <- simplExpr (se `setInScope` env') arg
2276         ; (env'', arg'') <- makeTrivial NotTopLevel env' arg'
2277         ; let app_cont = ApplyTo OkToDup arg'' (zapSubstEnv env'') dup_cont
2278         ; return (env'', app_cont, nodup_cont) }
2279
2280 mkDupableCont env cont@(Select _ case_bndr [(_, bs, _rhs)] _ _)
2281 --  See Note [Single-alternative case]
2282 --  | not (exprIsDupable rhs && contIsDupable case_cont)
2283 --  | not (isDeadBinder case_bndr)
2284   | all isDeadBinder bs  -- InIds
2285     && not (isUnLiftedType (idType case_bndr))
2286     -- Note [Single-alternative-unlifted]
2287   = return (env, mkBoringStop (contInputType cont), cont)
2288
2289 mkDupableCont env (Select _ case_bndr alts se cont)
2290   =     -- e.g.         (case [...hole...] of { pi -> ei })
2291         --      ===>
2292         --              let ji = \xij -> ei
2293         --              in case [...hole...] of { pi -> ji xij }
2294     do  { tick (CaseOfCase case_bndr)
2295         ; (env', dup_cont, nodup_cont) <- prepareCaseCont env alts cont
2296                 -- NB: We call prepareCaseCont here.  If there is only one
2297                 -- alternative, then dup_cont may be big, but that's ok
2298                 -- becuase we push it into the single alternative, and then
2299                 -- use mkDupableAlt to turn that simplified alternative into
2300                 -- a join point if it's too big to duplicate.
2301                 -- And this is important: see Note [Fusing case continuations]
2302
2303         ; let alt_env = se `setInScope` env'
2304
2305         ; (alt_env', case_bndr') <- simplBinder alt_env case_bndr
2306         ; alts' <- mapM (simplAlt alt_env' Nothing [] case_bndr' dup_cont) alts
2307         -- Safe to say that there are no handled-cons for the DEFAULT case
2308                 -- NB: simplBinder does not zap deadness occ-info, so
2309                 -- a dead case_bndr' will still advertise its deadness
2310                 -- This is really important because in
2311                 --      case e of b { (# p,q #) -> ... }
2312                 -- b is always dead, and indeed we are not allowed to bind b to (# p,q #),
2313                 -- which might happen if e was an explicit unboxed pair and b wasn't marked dead.
2314                 -- In the new alts we build, we have the new case binder, so it must retain
2315                 -- its deadness.
2316         -- NB: we don't use alt_env further; it has the substEnv for
2317         --     the alternatives, and we don't want that
2318
2319         ; (env'', alts'') <- mkDupableAlts env' case_bndr' alts'
2320         ; return (env'',  -- Note [Duplicated env]
2321                   Select OkToDup case_bndr' alts'' (zapSubstEnv env'') 
2322                          (mkBoringStop (contInputType nodup_cont)),
2323                   nodup_cont) }
2324
2325
2326 mkDupableAlts :: SimplEnv -> OutId -> [InAlt]
2327               -> SimplM (SimplEnv, [InAlt])
2328 -- Absorbs the continuation into the new alternatives
2329
2330 mkDupableAlts env case_bndr' the_alts
2331   = go env the_alts
2332   where
2333     go env0 [] = return (env0, [])
2334     go env0 (alt:alts)
2335         = do { (env1, alt') <- mkDupableAlt env0 case_bndr' alt
2336              ; (env2, alts') <- go env1 alts
2337              ; return (env2, alt' : alts' ) }
2338
2339 mkDupableAlt :: SimplEnv -> OutId -> (AltCon, [CoreBndr], CoreExpr)
2340               -> SimplM (SimplEnv, (AltCon, [CoreBndr], CoreExpr))
2341 mkDupableAlt env case_bndr (con, bndrs', rhs')
2342   | exprIsDupable rhs'  -- Note [Small alternative rhs]
2343   = return (env, (con, bndrs', rhs'))
2344   | otherwise
2345   = do  { let rhs_ty'  = exprType rhs'
2346               scrut_ty = idType case_bndr
2347               case_bndr_w_unf   
2348                 = case con of 
2349                       DEFAULT    -> case_bndr                                   
2350                       DataAlt dc -> setIdUnfolding case_bndr unf
2351                           where
2352                                  -- See Note [Case binders and join points]
2353                              unf = mkInlineUnfolding Nothing rhs
2354                              rhs = mkConApp dc (map Type (tyConAppArgs scrut_ty)
2355                                                 ++ varsToCoreExprs bndrs')
2356
2357                       LitAlt {} -> WARN( True, ptext (sLit "mkDupableAlt")
2358                                                 <+> ppr case_bndr <+> ppr con )
2359                                    case_bndr
2360                            -- The case binder is alive but trivial, so why has 
2361                            -- it not been substituted away?
2362
2363               used_bndrs' | isDeadBinder case_bndr = filter abstract_over bndrs'
2364                           | otherwise              = bndrs' ++ [case_bndr_w_unf]
2365               
2366               abstract_over bndr
2367                   | isTyVar bndr = True -- Abstract over all type variables just in case
2368                   | otherwise    = not (isDeadBinder bndr)
2369                         -- The deadness info on the new Ids is preserved by simplBinders
2370
2371         ; (final_bndrs', final_args)    -- Note [Join point abstraction]
2372                 <- if (any isId used_bndrs')
2373                    then return (used_bndrs', varsToCoreExprs used_bndrs')
2374                     else do { rw_id <- newId (fsLit "w") realWorldStatePrimTy
2375                             ; return ([rw_id], [Var realWorldPrimId]) }
2376
2377         ; join_bndr <- newId (fsLit "$j") (mkPiTypes final_bndrs' rhs_ty')
2378                 -- Note [Funky mkPiTypes]
2379
2380         ; let   -- We make the lambdas into one-shot-lambdas.  The
2381                 -- join point is sure to be applied at most once, and doing so
2382                 -- prevents the body of the join point being floated out by
2383                 -- the full laziness pass
2384                 really_final_bndrs     = map one_shot final_bndrs'
2385                 one_shot v | isId v    = setOneShotLambda v
2386                            | otherwise = v
2387                 join_rhs   = mkLams really_final_bndrs rhs'
2388                 join_arity = exprArity join_rhs
2389                 join_call  = mkApps (Var join_bndr) final_args
2390
2391         ; env' <- addPolyBind NotTopLevel env (NonRec (join_bndr `setIdArity` join_arity) join_rhs)
2392         ; return (env', (con, bndrs', join_call)) }
2393                 -- See Note [Duplicated env]
2394 \end{code}
2395
2396 Note [Fusing case continuations]
2397 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2398 It's important to fuse two successive case continuations when the
2399 first has one alternative.  That's why we call prepareCaseCont here.
2400 Consider this, which arises from thunk splitting (see Note [Thunk
2401 splitting] in WorkWrap):
2402
2403       let
2404         x* = case (case v of {pn -> rn}) of 
2405                I# a -> I# a
2406       in body
2407
2408 The simplifier will find
2409     (Var v) with continuation  
2410             Select (pn -> rn) (
2411             Select [I# a -> I# a] (
2412             StrictBind body Stop
2413
2414 So we'll call mkDupableCont on 
2415    Select [I# a -> I# a] (StrictBind body Stop)
2416 There is just one alternative in the first Select, so we want to
2417 simplify the rhs (I# a) with continuation (StricgtBind body Stop)
2418 Supposing that body is big, we end up with
2419           let $j a = <let x = I# a in body> 
2420           in case v of { pn -> case rn of 
2421                                  I# a -> $j a }
2422 This is just what we want because the rn produces a box that
2423 the case rn cancels with.  
2424
2425 See Trac #4957 a fuller example.
2426
2427 Note [Case binders and join points]
2428 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2429 Consider this 
2430    case (case .. ) of c {
2431      I# c# -> ....c....
2432
2433 If we make a join point with c but not c# we get
2434   $j = \c -> ....c....
2435
2436 But if later inlining scrutines the c, thus
2437
2438   $j = \c -> ... case c of { I# y -> ... } ...
2439
2440 we won't see that 'c' has already been scrutinised.  This actually
2441 happens in the 'tabulate' function in wave4main, and makes a significant
2442 difference to allocation.
2443
2444 An alternative plan is this:
2445
2446    $j = \c# -> let c = I# c# in ...c....
2447
2448 but that is bad if 'c' is *not* later scrutinised.  
2449
2450 So instead we do both: we pass 'c' and 'c#' , and record in c's inlining
2451 (an InlineRule) that it's really I# c#, thus
2452    
2453    $j = \c# -> \c[=I# c#] -> ...c....
2454
2455 Absence analysis may later discard 'c'.
2456
2457 NB: take great care when doing strictness analysis; 
2458     see Note [Lamba-bound unfoldings] in DmdAnal.
2459
2460 Also note that we can still end up passing stuff that isn't used.  Before
2461 strictness analysis we have
2462    let $j x y c{=(x,y)} = (h c, ...)
2463    in ...
2464 After strictness analysis we see that h is strict, we end up with
2465    let $j x y c{=(x,y)} = ($wh x y, ...)
2466 and c is unused.
2467    
2468 Note [Duplicated env]
2469 ~~~~~~~~~~~~~~~~~~~~~
2470 Some of the alternatives are simplified, but have not been turned into a join point
2471 So they *must* have an zapped subst-env.  So we can't use completeNonRecX to
2472 bind the join point, because it might to do PostInlineUnconditionally, and
2473 we'd lose that when zapping the subst-env.  We could have a per-alt subst-env,
2474 but zapping it (as we do in mkDupableCont, the Select case) is safe, and
2475 at worst delays the join-point inlining.
2476
2477 Note [Small alternative rhs]
2478 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2479 It is worth checking for a small RHS because otherwise we
2480 get extra let bindings that may cause an extra iteration of the simplifier to
2481 inline back in place.  Quite often the rhs is just a variable or constructor.
2482 The Ord instance of Maybe in PrelMaybe.lhs, for example, took several extra
2483 iterations because the version with the let bindings looked big, and so wasn't
2484 inlined, but after the join points had been inlined it looked smaller, and so
2485 was inlined.
2486
2487 NB: we have to check the size of rhs', not rhs.
2488 Duplicating a small InAlt might invalidate occurrence information
2489 However, if it *is* dupable, we return the *un* simplified alternative,
2490 because otherwise we'd need to pair it up with an empty subst-env....
2491 but we only have one env shared between all the alts.
2492 (Remember we must zap the subst-env before re-simplifying something).
2493 Rather than do this we simply agree to re-simplify the original (small) thing later.
2494
2495 Note [Funky mkPiTypes]
2496 ~~~~~~~~~~~~~~~~~~~~~~
2497 Notice the funky mkPiTypes.  If the contructor has existentials
2498 it's possible that the join point will be abstracted over
2499 type varaibles as well as term variables.
2500  Example:  Suppose we have
2501         data T = forall t.  C [t]
2502  Then faced with
2503         case (case e of ...) of
2504             C t xs::[t] -> rhs
2505  We get the join point
2506         let j :: forall t. [t] -> ...
2507             j = /\t \xs::[t] -> rhs
2508         in
2509         case (case e of ...) of
2510             C t xs::[t] -> j t xs
2511
2512 Note [Join point abstaction]
2513 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2514 If we try to lift a primitive-typed something out
2515 for let-binding-purposes, we will *caseify* it (!),
2516 with potentially-disastrous strictness results.  So
2517 instead we turn it into a function: \v -> e
2518 where v::State# RealWorld#.  The value passed to this function
2519 is realworld#, which generates (almost) no code.
2520
2521 There's a slight infelicity here: we pass the overall
2522 case_bndr to all the join points if it's used in *any* RHS,
2523 because we don't know its usage in each RHS separately
2524
2525 We used to say "&& isUnLiftedType rhs_ty'" here, but now
2526 we make the join point into a function whenever used_bndrs'
2527 is empty.  This makes the join-point more CPR friendly.
2528 Consider:       let j = if .. then I# 3 else I# 4
2529                 in case .. of { A -> j; B -> j; C -> ... }
2530
2531 Now CPR doesn't w/w j because it's a thunk, so
2532 that means that the enclosing function can't w/w either,
2533 which is a lose.  Here's the example that happened in practice:
2534         kgmod :: Int -> Int -> Int
2535         kgmod x y = if x > 0 && y < 0 || x < 0 && y > 0
2536                     then 78
2537                     else 5
2538
2539 I have seen a case alternative like this:
2540         True -> \v -> ...
2541 It's a bit silly to add the realWorld dummy arg in this case, making
2542         $j = \s v -> ...
2543            True -> $j s
2544 (the \v alone is enough to make CPR happy) but I think it's rare
2545
2546 Note [Duplicating StrictArg]
2547 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2548 The original plan had (where E is a big argument)
2549 e.g.    f E [..hole..]
2550         ==>     let $j = \a -> f E a
2551                 in $j [..hole..]
2552
2553 But this is terrible! Here's an example:
2554         && E (case x of { T -> F; F -> T })
2555 Now, && is strict so we end up simplifying the case with
2556 an ArgOf continuation.  If we let-bind it, we get
2557         let $j = \v -> && E v
2558         in simplExpr (case x of { T -> F; F -> T })
2559                      (ArgOf (\r -> $j r)
2560 And after simplifying more we get
2561         let $j = \v -> && E v
2562         in case x of { T -> $j F; F -> $j T }
2563 Which is a Very Bad Thing
2564
2565 What we do now is this
2566         f E [..hole..]
2567         ==>     let a = E
2568                 in f a [..hole..]
2569 Now if the thing in the hole is a case expression (which is when
2570 we'll call mkDupableCont), we'll push the function call into the
2571 branches, which is what we want.  Now RULES for f may fire, and
2572 call-pattern specialisation.  Here's an example from Trac #3116
2573      go (n+1) (case l of
2574                  1  -> bs'
2575                  _  -> Chunk p fpc (o+1) (l-1) bs')
2576 If we can push the call for 'go' inside the case, we get
2577 call-pattern specialisation for 'go', which is *crucial* for 
2578 this program.
2579
2580 Here is the (&&) example: 
2581         && E (case x of { T -> F; F -> T })
2582   ==>   let a = E in 
2583         case x of { T -> && a F; F -> && a T }
2584 Much better!
2585
2586 Notice that 
2587   * Arguments to f *after* the strict one are handled by 
2588     the ApplyTo case of mkDupableCont.  Eg
2589         f [..hole..] E
2590
2591   * We can only do the let-binding of E because the function
2592     part of a StrictArg continuation is an explicit syntax
2593     tree.  In earlier versions we represented it as a function
2594     (CoreExpr -> CoreEpxr) which we couldn't take apart.
2595
2596 Do *not* duplicate StrictBind and StritArg continuations.  We gain
2597 nothing by propagating them into the expressions, and we do lose a
2598 lot.  
2599
2600 The desire not to duplicate is the entire reason that
2601 mkDupableCont returns a pair of continuations.
2602
2603 Note [Duplicating StrictBind]
2604 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2605 Unlike StrictArg, there doesn't seem anything to gain from
2606 duplicating a StrictBind continuation, so we don't.
2607
2608
2609 Note [Single-alternative cases]
2610 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2611 This case is just like the ArgOf case.  Here's an example:
2612         data T a = MkT !a
2613         ...(MkT (abs x))...
2614 Then we get
2615         case (case x of I# x' ->
2616               case x' <# 0# of
2617                 True  -> I# (negate# x')
2618                 False -> I# x') of y {
2619           DEFAULT -> MkT y
2620 Because the (case x) has only one alternative, we'll transform to
2621         case x of I# x' ->
2622         case (case x' <# 0# of
2623                 True  -> I# (negate# x')
2624                 False -> I# x') of y {
2625           DEFAULT -> MkT y
2626 But now we do *NOT* want to make a join point etc, giving
2627         case x of I# x' ->
2628         let $j = \y -> MkT y
2629         in case x' <# 0# of
2630                 True  -> $j (I# (negate# x'))
2631                 False -> $j (I# x')
2632 In this case the $j will inline again, but suppose there was a big
2633 strict computation enclosing the orginal call to MkT.  Then, it won't
2634 "see" the MkT any more, because it's big and won't get duplicated.
2635 And, what is worse, nothing was gained by the case-of-case transform.
2636
2637 So, in circumstances like these, we don't want to build join points
2638 and push the outer case into the branches of the inner one. Instead,
2639 don't duplicate the continuation. 
2640
2641 When should we use this strategy?  We should not use it on *every*
2642 single-alternative case:
2643   e.g.  case (case ....) of (a,b) -> (# a,b #)
2644 Here we must push the outer case into the inner one!
2645 Other choices:
2646
2647    * Match [(DEFAULT,_,_)], but in the common case of Int,
2648      the alternative-filling-in code turned the outer case into
2649                 case (...) of y { I# _ -> MkT y }
2650
2651    * Match on single alternative plus (not (isDeadBinder case_bndr))
2652      Rationale: pushing the case inwards won't eliminate the construction.
2653      But there's a risk of
2654                 case (...) of y { (a,b) -> let z=(a,b) in ... }
2655      Now y looks dead, but it'll come alive again.  Still, this
2656      seems like the best option at the moment.
2657
2658    * Match on single alternative plus (all (isDeadBinder bndrs))
2659      Rationale: this is essentially  seq.
2660
2661    * Match when the rhs is *not* duplicable, and hence would lead to a
2662      join point.  This catches the disaster-case above.  We can test
2663      the *un-simplified* rhs, which is fine.  It might get bigger or
2664      smaller after simplification; if it gets smaller, this case might
2665      fire next time round.  NB also that we must test contIsDupable
2666      case_cont *too, because case_cont might be big!
2667
2668      HOWEVER: I found that this version doesn't work well, because
2669      we can get         let x = case (...) of { small } in ...case x...
2670      When x is inlined into its full context, we find that it was a bad
2671      idea to have pushed the outer case inside the (...) case.
2672
2673 Note [Single-alternative-unlifted]
2674 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2675 Here's another single-alternative where we really want to do case-of-case:
2676
2677 data Mk1 = Mk1 Int# | Mk2 Int#
2678
2679 M1.f =
2680     \r [x_s74 y_s6X]
2681         case
2682             case y_s6X of tpl_s7m {
2683               M1.Mk1 ipv_s70 -> ipv_s70;
2684               M1.Mk2 ipv_s72 -> ipv_s72;
2685             }
2686         of
2687         wild_s7c
2688         { __DEFAULT ->
2689               case
2690                   case x_s74 of tpl_s7n {
2691                     M1.Mk1 ipv_s77 -> ipv_s77;
2692                     M1.Mk2 ipv_s79 -> ipv_s79;
2693                   }
2694               of
2695               wild1_s7b
2696               { __DEFAULT -> ==# [wild1_s7b wild_s7c];
2697               };
2698         };
2699
2700 So the outer case is doing *nothing at all*, other than serving as a
2701 join-point.  In this case we really want to do case-of-case and decide
2702 whether to use a real join point or just duplicate the continuation:
2703
2704     let $j s7c = case x of
2705                    Mk1 ipv77 -> (==) s7c ipv77
2706                    Mk1 ipv79 -> (==) s7c ipv79
2707     in
2708     case y of 
2709       Mk1 ipv70 -> $j ipv70
2710       Mk2 ipv72 -> $j ipv72
2711
2712 Hence: check whether the case binder's type is unlifted, because then
2713 the outer case is *not* a seq.