Don't fail on missing happy/alex if we don't need them
[ghc.git] / aclocal.m4
1 # Extra autoconf macros for the Glasgow fptools
2 #
3 # To be a good autoconf citizen, names of local macros have prefixed with FP_ to
4 # ensure we don't clash with any pre-supplied autoconf ones.
5
6
7 # FP_EVAL_STDERR(COMMAND)
8 # -----------------------
9 # Eval COMMAND, save its stderr (without lines resulting from shell tracing)
10 # into the file conftest.err and the exit status in the variable fp_status.
11 AC_DEFUN([FP_EVAL_STDERR],
12 [{ (eval $1) 2>conftest.er1
13   fp_status=$?
14   grep -v '^ *+' conftest.er1 >conftest.err
15   rm -f conftest.er1
16   (exit $fp_status); }[]dnl
17 ])# FP_EVAL_STDERR
18
19
20 # FP_CHECK_FLAG(FLAG, [ACTION-IF-SUPPORTED], [ACTION-IF-NOT-SUPPORTED])
21 # ---------------------------------------------------------------------
22 # Check to see whether the compiler for the current language supports a
23 # particular option.
24 #
25 # Implementation note: When given an unkown option, GCC issues an warning on
26 # stderr only, but returns an exit value of 0 nevertheless. Consequently we have
27 # to check stderr *and* the exit value.
28 #
29 # Used by ghc.
30 AC_DEFUN([FP_CHECK_FLAG],
31 [AC_LANG_COMPILER_REQUIRE()dnl
32 AC_LANG_CASE([C],          [fp_compiler="$CC"  m4_pushdef([fp_Flags], [CFLAGS])],
33              [C++],        [fp_compiler="$CXX" m4_pushdef([fp_Flags], [CXXFLAGS])],
34              [Fortran 77], [fp_compiler="$F77" m4_pushdef([fp_Flags], [FFLAGS])])
35 m4_pushdef([fp_Cache], [fp_cv_[]fp_Flags[]AS_TR_SH([$1])])[]dnl
36 AC_CACHE_CHECK([whether $fp_compiler accepts $1], [fp_Cache],
37 [AC_LANG_CONFTEST([AC_LANG_PROGRAM()])
38 fp_save_flags="$fp_Flags"
39 fp_Flags="$fp_Flags $1"
40 fp_Cache=no
41 if FP_EVAL_STDERR([$ac_compile conftest.$ac_ext]) >/dev/null; then
42   test -s conftest.err || fp_Cache=yes
43 fi
44 fp_Flags="$fp_save_flags"
45 rm -f conftest.err conftest.$ac_ext])
46 AS_IF([test $fp_Cache = yes], [$2], [$3])[]dnl
47 m4_popdef([fp_Cache])[]dnl
48 m4_popdef([fp_Flags])[]dnl
49 ])# FP_CHECK_FLAG
50
51
52 # FP_PROG_CONTEXT_DIFF
53 # --------------------
54 # Figure out how to do context diffs. Sets the output variable ContextDiffCmd.
55 #
56 # Note: NeXTStep thinks diff'ing a file against itself is "trouble".
57 #
58 # Used by ghc, glafp-utils/ltx, and glafp-utils/runstdtest.
59 AC_DEFUN([FP_PROG_CONTEXT_DIFF],
60 [AC_CACHE_CHECK([for a working context diff], [fp_cv_context_diff],
61 [echo foo > conftest1
62 echo foo > conftest2
63 fp_cv_context_diff=no
64 for fp_var in '-C 1' '-c1'
65 do
66   if diff $fp_var conftest1 conftest2 > /dev/null 2>&1; then
67     fp_cv_context_diff="diff $fp_var"
68     break
69   fi
70 done])
71 if test x"$fp_cv_context_diff" = xno; then
72    AC_MSG_ERROR([cannot figure out how to do context diffs])
73 fi
74 AC_SUBST(ContextDiffCmd, [$fp_cv_context_diff])
75 ])# FP_PROG_CONTEXT_DIFF
76
77
78 # FP_COMPUTE_INT(EXPRESSION, VARIABLE, INCLUDES, IF-FAILS)
79 # --------------------------------------------------------
80 # Assign VARIABLE the value of the compile-time EXPRESSION using INCLUDES for
81 # compilation. Execute IF-FAILS when unable to determine the value. Works for
82 # cross-compilation, too.
83 #
84 # Implementation note: We are lazy and use an internal autoconf macro, but it
85 # is supported in autoconf versions 2.50 up to the actual 2.57, so there is
86 # little risk.
87 AC_DEFUN([FP_COMPUTE_INT],
88 [_AC_COMPUTE_INT([$1], [$2], [$3], [$4])[]dnl
89 ])# FP_COMPUTE_INT
90
91
92 # FP_CHECK_ALIGNMENT(TYPE, [IGNORED], [INCLUDES = DEFAULT-INCLUDES])
93 # ------------------------------------------------------------------
94 # A variation of AC_CHECK_SIZEOF for computing the alignment restrictions of a
95 # given type. Defines ALIGNMENT_TYPE.
96 AC_DEFUN([FP_CHECK_ALIGNMENT],
97 [AS_LITERAL_IF([$1], [],
98                [AC_FATAL([$0: requires literal arguments])])[]dnl
99 AC_CHECK_TYPE([$1], [], [], [$3])[]dnl
100 m4_pushdef([fp_Cache], [AS_TR_SH([fp_cv_alignment_$1])])[]dnl
101 AC_CACHE_CHECK([alignment of $1], [fp_Cache],
102 [if test "$AS_TR_SH([ac_cv_type_$1])" = yes; then
103   FP_COMPUTE_INT([(long) (&((struct { char c; $1 ty; } *)0)->ty)],
104                  [fp_Cache],
105                  [AC_INCLUDES_DEFAULT([$3])],
106                  [AC_MSG_ERROR([cannot compute alignment ($1)
107 See `config.log' for more details.], [77])])
108 else
109   fp_Cache=0
110 fi])[]dnl
111 AC_DEFINE_UNQUOTED(AS_TR_CPP(alignment_$1), $fp_Cache, [The alignment of a `$1'.])[]dnl
112 m4_popdef([fp_Cache])[]dnl
113 ])# FP_CHECK_ALIGNMENT
114
115
116 # FP_LEADING_UNDERSCORE
117 # ---------------------
118 # Test for determining whether symbol names have a leading underscore. We assume
119 # that they _haven't_ if anything goes wrong. Sets the output variable
120 # LeadingUnderscore to YES or NO and defines LEADING_UNDERSCORE correspondingly.
121 #
122 # Some nlist implementations seem to try to be compatible by ignoring a leading
123 # underscore sometimes (eg. FreeBSD). We therefore have to work around this by
124 # checking for *no* leading underscore first. Sigh.  --SDM
125 #
126 # Similarly on OpenBSD, but this test doesn't help. -- dons
127 AC_DEFUN([FP_LEADING_UNDERSCORE],
128 [AC_CHECK_LIB([elf], [nlist], [LIBS="-lelf $LIBS"])
129 AC_CACHE_CHECK([leading underscore in symbol names], [fptools_cv_leading_underscore], [
130 # Hack!: nlist() under Digital UNIX insist on there being an _,
131 # but symbol table listings shows none. What is going on here?!?
132 #
133 # Another hack: cygwin doesn't come with nlist.h , so we hardwire
134 # the underscoredness of that "platform"
135 case $HostPlatform in
136 *openbsd*) # x86 openbsd is ELF from 3.4 >, meaning no leading uscore
137   case $build in
138     i386-*2\.@<:@0-9@:>@ | i386-*3\.@<:@0-3@:>@ ) fptools_cv_leading_underscore=yes ;;
139     *) fptools_cv_leading_underscore=no ;;
140   esac ;;
141 alpha-dec-osf*) fptools_cv_leading_underscore=no;;
142 *cygwin32) fptools_cv_leading_underscore=yes;;
143 *mingw32) fptools_cv_leading_underscore=yes;;
144 *) AC_RUN_IFELSE([AC_LANG_SOURCE([[#ifdef HAVE_NLIST_H
145 #include <nlist.h>
146 struct nlist xYzzY1[] = {{"xYzzY1", 0},{0}};
147 struct nlist xYzzY2[] = {{"_xYzzY2", 0},{0}};
148 #endif
149
150 int main(argc, argv)
151 int argc;
152 char **argv;
153 {
154 #ifdef HAVE_NLIST_H
155     if(nlist(argv[0], xYzzY1) == 0 && xYzzY1[0].n_value != 0)
156         exit(1);
157     if(nlist(argv[0], xYzzY2) == 0 && xYzzY2[0].n_value != 0)
158         exit(0);
159 #endif
160     exit(1);
161 }]])],[fptools_cv_leading_underscore=yes],[fptools_cv_leading_underscore=no],[fptools_cv_leading_underscore=no])
162 ;;
163 esac]);
164 AC_SUBST([LeadingUnderscore], [`echo $fptools_cv_leading_underscore | sed 'y/yesno/YESNO/'`])
165 if test x"$fptools_cv_leading_underscore" = xyes; then
166    AC_DEFINE([LEADING_UNDERSCORE], [1], [Define to 1 if C symbols have a leading underscore added by the compiler.])
167 fi])# FP_LEADING_UNDERSCORE
168
169
170 # FP_COMPARE_VERSIONS(VERSION1, TEST, VERSION2, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
171 # ----------------------------------------------------------------------------------
172 # Compare dotted version numbers VERSION1 and VERSION2 lexicographically according
173 # to TEST (one of -eq, -ne, -lt, -le, -gt, or -ge).
174 AC_DEFUN([FP_COMPARE_VERSIONS],
175 [fp_version1=$1; fp_version2=$3
176 fp_save_IFS=$IFS; IFS='.'
177 while test x"$fp_version1" != x || test x"$fp_version2" != x
178 do
179
180   set dummy $fp_version1; shift
181   fp_num1=""
182   test $[@%:@] = 0 || { fp_num1="[$]1"; shift; }
183   test x"$fp_num1" = x && fp_num1="0"
184   fp_version1="[$]*"
185
186   set dummy $fp_version2; shift
187   fp_num2=""
188   test $[@%:@] = 0 || { fp_num2="[$]1"; shift; }
189   test x"$fp_num2" = x && fp_num2="0"
190   fp_version2="[$]*"
191
192   test "$fp_num1" = "$fp_num2" || break;
193 done
194 IFS=$fp_save_IFS
195 AS_IF([test "$fp_num1" $2 "$fp_num2"], [$4], [$5])[]dnl
196 ])# FP_COMPARE_VERSIONS
197
198
199 dnl
200 dnl Check for GreenCard and version.
201 dnl
202 AC_DEFUN([FPTOOLS_GREENCARD],
203 [
204 AC_PATH_PROG(GreenCardCmd,greencard)
205 AC_CACHE_CHECK([for version of greencard], fptools_cv_greencard_version,
206 changequote(, )dnl
207 [if test x"$GreenCardCmd" != x; then
208    fptools_cv_greencard_version="`$GreenCardCmd --version |
209                           grep 'version' | sed -e 's/greencard. version \([^ ]*\).*/\1/g'`"
210 else
211    fptools_cv_greencard_version=""
212 fi
213 changequote([, ])dnl
214 ])
215 FP_COMPARE_VERSIONS([$fptools_cv_greencard_version],[-lt],[$1],
216   [AC_MSG_ERROR([greencard version $1 or later is required (found '$fptools_cv_greencard_version')])])[]dnl
217 GreenCardVersion=$fptools_cv_greencard_version
218 AC_SUBST(GreenCardVersion)
219 ])
220
221 dnl
222 dnl Check for Happy and version.  If we're building GHC, then we need
223 dnl at least Happy version 1.14.  If there's no installed Happy, we look
224 dnl for a happy source tree and point the build system at that instead.
225 dnl
226 AC_DEFUN([FPTOOLS_HAPPY],
227 [AC_PATH_PROG(HappyCmd,happy,)
228 AC_CACHE_CHECK([for version of happy], fptools_cv_happy_version,
229 changequote(, )dnl
230 [if test x"$HappyCmd" != x; then
231    fptools_cv_happy_version="`$HappyCmd -v |
232                           grep 'Happy Version' | sed -e 's/Happy Version \([^ ]*\).*/\1/g'`" ;
233 else
234    fptools_cv_happy_version="";
235 fi;
236 changequote([, ])dnl
237 ])
238 if test ! -f compiler/parser/Parser.hs || test ! -f compiler/main/ParsePkgConf.hs || test ! -f compiler/cmm/CmmParse.hs || test ! -f compiler/parser/ParserCore.hs
239 then
240     FP_COMPARE_VERSIONS([$fptools_cv_happy_version],[-lt],[1.15],
241       [AC_MSG_ERROR([Happy version 1.15 or later is required to compile GHC.])])[]dnl
242 fi
243 HappyVersion=$fptools_cv_happy_version;
244 AC_SUBST(HappyVersion)
245 ])
246
247 dnl
248 dnl Check for Haddock and version.  If there's no installed Haddock, we look
249 dnl for a haddock source tree and point the build system at that instead.
250 dnl
251 AC_DEFUN([FPTOOLS_HADDOCK],
252 [AC_PATH_PROG(HaddockCmd,haddock,)
253 dnl Darn, I forgot to make Haddock print out its version number when
254 dnl invoked with -v.  We could try generating some HTML and grepping
255 dnl through that to find the version number, but I think we'll make
256 dnl do without it for now.
257 ])
258
259 dnl
260 dnl Check for Alex and version.  If we're building GHC, then we need
261 dnl at least Alex version 2.0.  If there's no installed Alex, we look
262 dnl for a alex source tree and point the build system at that instead.
263 dnl
264 AC_DEFUN([FPTOOLS_ALEX],
265 [
266 AC_PATH_PROG(AlexCmd,alex,)
267 AC_CACHE_CHECK([for version of alex], fptools_cv_alex_version,
268 changequote(, )dnl
269 [if test x"$AlexCmd" != x; then
270    fptools_cv_alex_version="`$AlexCmd -v |
271                           grep 'Alex [Vv]ersion' | sed -e 's/Alex [Vv]ersion \([0-9\.]*\).*/\1/g'`" ;
272 else
273    fptools_cv_alex_version="";
274 fi;
275 changequote([, ])dnl
276 ])
277 if test ! -f compiler/cmm/CmmLex.hs || test ! -f compiler/parser/Lexer.hs
278 then
279     FP_COMPARE_VERSIONS([$fptools_cv_alex_version],[-lt],[2.0],
280       [AC_MSG_ERROR([Alex version 2.0 or later is required to compile GHC.])])[]dnl
281 fi
282 AlexVersion=$fptools_cv_alex_version;
283 AC_SUBST(AlexVersion)
284 ])
285
286
287 # FP_PROG_LD
288 # ----------
289 # Sets the output variable LdCmd to the (non-Cygwin version of the) full path
290 # of ld. Exits if no ld can be found
291 AC_DEFUN([FP_PROG_LD],
292 [AC_PATH_PROG([fp_prog_ld_raw], [ld])
293 if test -z "$fp_prog_ld_raw"; then
294   AC_MSG_ERROR([cannot find ld in your PATH, no idea how to link])
295 fi
296 LdCmd=$fp_prog_ld_raw
297 case $HostPlatform in
298   *mingw32) if test x${OSTYPE} != xmsys; then
299               LdCmd="`cygpath -w ${fp_prog_ld_raw} | sed -e 's@\\\\@/@g'`"
300               AC_MSG_NOTICE([normalized ld command to $LdCmd])
301             fi
302             # Insist on >= ld-2.15.x, since earlier versions doesn't handle
303             # the generation of relocatable object files with large amounts
304             # of relocations correctly. (cf. HSbase.o splittage-hack)
305             fp_prog_ld_version=`${LdCmd} --version | sed -n '/GNU ld/p' | tr -cd 0-9 | cut -b1-3`
306             FP_COMPARE_VERSIONS([$fp_prog_ld_version],[-lt],[214],
307                                 [AC_MSG_ERROR([GNU ld version later than 2.14 required to compile GHC on Windows.])])[]dnl
308             ;;
309 esac
310 AC_SUBST([LdCmd])
311 ])# FP_PROG_LD
312
313
314 # FP_PROG_LD_X
315 # ------------
316 # Sets the output variable LdXFlag to -x if ld supports this flag, otherwise the
317 # variable's value is empty.
318 AC_DEFUN([FP_PROG_LD_X],
319 [AC_REQUIRE([FP_PROG_LD])
320 AC_CACHE_CHECK([whether ld understands -x], [fp_cv_ld_x],
321 [echo 'foo() {}' > conftest.c
322 ${CC-cc} -c conftest.c
323 if ${LdCmd} -r -x -o conftest2.o conftest.o > /dev/null 2>&1; then
324    fp_cv_ld_x=yes
325 else
326    fp_cv_ld_x=no
327 fi
328 rm -rf conftest*])
329 if test "$fp_cv_ld_x" = yes; then
330   LdXFlag=-x
331 else
332   LdXFlag=
333 fi
334 AC_SUBST([LdXFlag])
335 ])# FP_PROG_LD_X
336
337
338 # FP_PROG_LD_IS_GNU
339 # -----------------
340 # Sets the output variable LdIsGNULd to YES or NO, depending on whether it is
341 # GNU ld or not.
342 AC_DEFUN([FP_PROG_LD_IS_GNU],
343 [AC_REQUIRE([FP_PROG_LD])
344 AC_CACHE_CHECK([whether ld is GNU ld], [fp_cv_gnu_ld],
345 [if ${LdCmd} --version 2> /dev/null | grep "GNU" > /dev/null 2>&1; then
346   fp_cv_gnu_ld=yes
347 else
348   fp_cv_gnu_ld=no
349 fi])
350 AC_SUBST([LdIsGNULd], [`echo $fp_cv_gnu_ld | sed 'y/yesno/YESNO/'`])
351 ])# FP_PROG_LD_IS_GNU
352
353
354 # FP_PROG_AR
355 # ----------
356 # Sets fp_prog_ar_raw to the full path of ar and fp_prog_ar to a non-Cygwin
357 # version of it. Exits if no ar can be found
358 AC_DEFUN([FP_PROG_AR],
359 [AC_PATH_PROG([fp_prog_ar_raw], [ar])
360 if test -z "$fp_prog_ar_raw"; then
361   AC_MSG_ERROR([cannot find ar in your PATH, no idea how to make a library])
362 fi
363 fp_prog_ar=$fp_prog_ar_raw
364 case $HostPlatform in
365   *mingw32) if test x${OSTYPE} != xmsys; then
366               fp_prog_ar="`cygpath -w ${fp_prog_ar_raw} | sed -e 's@\\\\@/@g'`"
367               AC_MSG_NOTICE([normalized ar command to $fp_prog_ar])
368             fi
369             ;;
370 esac
371 ])# FP_PROG_AR
372
373
374 # FP_PROG_AR_IS_GNU
375 # -----------------
376 # Sets fp_prog_ar_is_gnu to yes or no, depending on whether it is GNU ar or not.
377 AC_DEFUN([FP_PROG_AR_IS_GNU],
378 [AC_REQUIRE([FP_PROG_AR])
379 AC_CACHE_CHECK([whether $fp_prog_ar_raw is GNU ar], [fp_cv_prog_ar_is_gnu],
380 [if $fp_prog_ar_raw --version 2> /dev/null | grep "GNU" > /dev/null 2>&1; then
381   fp_cv_prog_ar_is_gnu=yes
382 else
383   fp_cv_prog_ar_is_gnu=no
384 fi])
385 fp_prog_ar_is_gnu=$fp_cv_prog_ar_is_gnu
386 ])# FP_PROG_AR_IS_GNU
387
388
389 # FP_PROG_AR_ARGS
390 # ---------------
391 # Sets fp_prog_ar_args to the arguments for ar and the output variable ArCmd
392 # to a non-Cygwin invocation of ar including these arguments.
393 AC_DEFUN([FP_PROG_AR_ARGS],
394 [AC_REQUIRE([FP_PROG_AR_IS_GNU])
395 AC_CACHE_CHECK([for ar arguments], [fp_cv_prog_ar_args],
396 [
397 # GNU ar needs special treatment: it appears to have problems with
398 # object files with the same name if you use the 's' modifier, but
399 # simple 'ar q' works fine, and doesn't need a separate ranlib.
400 if test $fp_prog_ar_is_gnu = yes; then
401   fp_cv_prog_ar_args="q"
402 else
403   touch conftest.dummy
404   for fp_var in clqsZ clqs cqs clq cq ; do
405      rm -f conftest.a
406      if $fp_prog_ar_raw $fp_var conftest.a conftest.dummy > /dev/null 2> /dev/null; then
407         fp_cv_prog_ar_args=$fp_var
408         break
409      fi
410   done
411   rm -f conftest*
412   if test -z "$fp_cv_prog_ar_args"; then
413     AC_MSG_ERROR([cannot figure out how to use your $fp_prog_ar_raw])
414   fi
415 fi])
416 fp_prog_ar_args=$fp_cv_prog_ar_args
417 AC_SUBST([ArCmd], ["$fp_prog_ar $fp_prog_ar_args"])
418
419 ])# FP_PROG_AR_ARGS
420
421
422 # FP_PROG_AR_NEEDS_RANLIB
423 # -----------------------
424 # Sets the output variable RANLIB to "ranlib" if it is needed and found,
425 # to ":" otherwise.
426 AC_DEFUN([FP_PROG_AR_NEEDS_RANLIB],
427 [AC_REQUIRE([FP_PROG_AR_IS_GNU])
428 AC_REQUIRE([FP_PROG_AR_ARGS])
429 AC_REQUIRE([AC_PROG_CC])
430 AC_CACHE_CHECK([whether ranlib is needed], [fp_cv_prog_ar_needs_ranlib],
431 [if test $fp_prog_ar_is_gnu = yes; then
432   fp_cv_prog_ar_needs_ranlib=no
433 elif echo $TargetPlatform | grep "^.*-apple-darwin$"  > /dev/null 2> /dev/null; then
434   # It's quite tedious to check for Apple's crazy timestamps in .a files,
435   # so we hardcode it.
436   fp_cv_prog_ar_needs_ranlib=yes
437 elif echo $fp_prog_ar_args | grep "s" > /dev/null 2> /dev/null; then
438   fp_cv_prog_ar_needs_ranlib=no
439 else
440   fp_cv_prog_ar_needs_ranlib=yes
441 fi])
442 if test $fp_cv_prog_ar_needs_ranlib = yes; then
443    AC_PROG_RANLIB
444 else
445   RANLIB=":"
446   AC_SUBST([RANLIB])
447 fi
448 ])# FP_PROG_AR_NEEDS_RANLIB
449
450
451 # FP_PROG_AR_SUPPORTS_INPUT
452 # -------------------------
453 # Sets the output variable ArSupportsInput to "-input" or "", depending on
454 # whether ar supports -input flag is supported or not.
455 AC_DEFUN([FP_PROG_AR_SUPPORTS_INPUT],
456 [AC_REQUIRE([FP_PROG_AR_IS_GNU])
457 AC_REQUIRE([FP_PROG_AR_ARGS])
458 AC_CACHE_CHECK([whether $fp_prog_ar_raw supports -input], [fp_cv_prog_ar_supports_input],
459 [fp_cv_prog_ar_supports_input=no
460 if test $fp_prog_ar_is_gnu = no; then
461   rm -f conftest*
462   touch conftest.lst
463   if FP_EVAL_STDERR([$fp_prog_ar_raw $fp_prog_ar_args conftest.a -input conftest.lst]) >/dev/null; then
464     test -s conftest.err || fp_cv_prog_ar_supports_input=yes
465   fi
466   rm -f conftest*
467 fi])
468 if test $fp_cv_prog_ar_supports_input = yes; then
469     ArSupportsInput="-input"
470 else
471     ArSupportsInput=""
472 fi
473 AC_SUBST([ArSupportsInput])
474 ])# FP_PROG_AR_SUPPORTS_INPUT
475
476
477 dnl
478 dnl AC_SHEBANG_PERL - can we she-bang perl?
479 dnl
480 AC_DEFUN([FPTOOLS_SHEBANG_PERL],
481 [AC_CACHE_CHECK([if your perl works in shell scripts], fptools_cv_shebang_perl,
482 [echo "#!$PerlCmd"'
483 exit $1;
484 ' > conftest
485 chmod u+x conftest
486 (SHELL=/bin/sh; export SHELL; ./conftest 69 > /dev/null)
487 if test $? -ne 69; then
488    fptools_cv_shebang_perl=yes
489 else
490    fptools_cv_shebang_perl=no
491 fi
492 rm -f conftest
493 ])])
494
495
496 # FP_HAVE_GCC
497 # -----------
498 # Extra testing of the result AC_PROG_CC, testing the gcc version no. Sets the
499 # output variables HaveGcc and GccVersion.
500 AC_DEFUN([FP_HAVE_GCC],
501 [AC_REQUIRE([AC_PROG_CC])
502 if test -z "$GCC"; then
503    fp_have_gcc=NO
504 else
505    fp_have_gcc=YES
506 fi
507 if test "$fp_have_gcc" = "NO" -a -d $srcdir/ghc; then
508   AC_MSG_ERROR([gcc is required])
509 fi
510 AC_CACHE_CHECK([version of gcc], [fp_gcc_version],
511 [if test "$fp_have_gcc" = "YES"; then
512    fp_gcc_version="`$CC -v 2>&1 | grep 'version ' | sed -e 's/.*version [[^0-9]]*\([[0-9.]]*\).*/\1/g'`"
513    FP_COMPARE_VERSIONS([$fp_gcc_version], [-lt], [2.0],
514      [AC_MSG_ERROR([Need at least gcc version 2.0 (3.4+ recommended)])])
515  else
516    fp_gcc_version="not-installed"
517  fi
518 ])
519 AC_SUBST([HaveGcc], [$fp_have_gcc])
520 AC_SUBST([GccVersion], [$fp_gcc_version])
521 ])# FP_HAVE_GCC
522
523 AC_DEFUN([FP_MINGW_GCC],
524 [
525   case $HostOS_CPP in
526     mingw*)  AC_MSG_CHECKING([whether $CC is a mingw gcc])
527              if $CC -v 2>&1 | grep mingw >/dev/null; then
528                 AC_MSG_RESULT([yes])
529              else
530                 AC_MSG_RESULT([no])
531                 AC_MSG_ERROR([Please use --with-gcc to specify a mingw gcc])
532              fi;;
533     *) ;;       
534   esac
535 ])
536
537 dnl Small feature test for perl version. Assumes PerlCmd
538 dnl contains path to perl binary
539 dnl
540 AC_DEFUN([FPTOOLS_CHECK_PERL_VERSION],
541 [$PerlCmd -v >conftest.out 2>&1
542    if grep "v5.6" conftest.out >/dev/null 2>&1; then
543       :
544    else
545       if grep "v5.8" conftest.out >/dev/null 2>&1; then
546          :
547       else
548          if grep "version 6" conftest.out >/dev/null 2>&1; then
549             :
550          else
551             AC_MSG_ERROR([your version of perl probably won't work, try upgrading it.])
552          fi
553       fi
554    fi
555 rm -fr conftest*
556 ])
557
558
559 # FP_CHECK_PROG(VARIABLE, PROG-TO-CHECK-FOR,
560 #               [VALUE-IF-NOT-FOUND], [PATH], [REJECT])
561 # -----------------------------------------------------
562 # HACK: A small wrapper around AC_CHECK_PROG, setting VARIABLE to the full path
563 # of PROG-TO-CHECK-FOR when found.
564 AC_DEFUN([FP_CHECK_PROG],
565 [AC_CHECK_PROG([$1], [$2], [$as_dir/$ac_word$ac_exec_ext], [$3], [$4], [$5])][]dnl
566 )# FP_CHECK_PROC
567
568
569 # FP_PROG_FIND
570 # ------------
571 # Find a non-WinDoze version of the "find" utility.
572 AC_DEFUN([FP_PROG_FIND],
573 [AC_PATH_PROG([fp_prog_find], [find])
574 echo foo > conftest.txt
575 $fp_prog_find conftest.txt -print > conftest.out 2>&1
576 if grep '^conftest.txt$' conftest.out > /dev/null 2>&1 ; then
577   # OK, looks like a real "find".
578   FindCmd="$fp_prog_find"
579 else
580   # Found a poor WinDoze version of "find", ignore it.
581   AC_MSG_WARN([$fp_prog_find looks like a non-*nix find, ignoring it])
582   FP_CHECK_PROG([FindCmd], [find], [], [], [$fp_prog_find])
583 fi
584 rm -f conftest.txt conftest.out
585 AC_SUBST([FindCmd])[]dnl
586 ])# FP_PROG_FIND
587
588
589 # FP_PROG_SORT
590 # ------------
591 # Find a Unix-like sort
592 AC_DEFUN([FP_PROG_SORT],
593 [AC_PATH_PROG([fp_prog_sort], [sort])
594 echo conwip > conftest.txt
595 $fp_prog_sort -f conftest.txt > conftest.out 2>&1
596 if grep 'conwip' conftest.out > /dev/null 2>&1 ; then
597   # The goods
598   SortCmd="$fp_prog_sort"
599 else
600   # Summink else..pick next one.
601   AC_MSG_WARN([$fp_prog_sort looks like a non-*nix sort, ignoring it])
602   FP_CHECK_PROG([SortCmd], [sort], [], [], [$fp_prog_sort])
603 fi
604 rm -f conftest.txt conftest.out
605 AC_SUBST([SortCmd])[]dnl
606 ])# FP_PROG_SORT
607
608 dnl
609 dnl FPTOOLS_NOCACHE_CHECK prints a message, then sets the
610 dnl values of the second argument to the result of running
611 dnl the commands given by the third. It does not cache its
612 dnl result, so it is suitable for checks which should be
613 dnl run every time.
614 dnl
615 AC_DEFUN([FPTOOLS_NOCACHE_CHECK],
616 [AC_MSG_CHECKING([$1])
617  $3
618  AC_MSG_RESULT([$][$2])
619 ])
620
621 dnl
622 dnl FPTOOLS_GHC_VERSION(version)
623 dnl FPTOOLS_GHC_VERSION(major, minor [, patchlevel])
624 dnl FPTOOLS_GHC_VERSION(version, major, minor, patchlevel)
625 dnl
626 dnl Test for version of installed ghc.  Uses $GHC.
627 dnl [original version pinched from c2hs]
628 dnl
629 AC_DEFUN([FPTOOLS_GHC_VERSION],
630 [FPTOOLS_NOCACHE_CHECK([version of ghc], [fptools_version_of_ghc],
631 ["${WithGhc-ghc}" --version > conftestghc 2>&1
632   cat conftestghc >&AS_MESSAGE_LOG_FD
633 #Useless Use Of cat award...
634   fptools_version_of_ghc=`cat conftestghc | sed -n -e 's/, patchlevel *\([[0-9]]\)/.\1/;s/.* version \([[0-9]][[0-9.]]*\).*/\1/p'`
635   rm -fr conftest*
636   if test "[$]fptools_version_of_ghc" = ""
637   then
638     fptools_version_of_ghc='unknown'
639   fi
640 fptools_version_of_ghc[_major]=`echo [$]fptools_version_of_ghc | sed -e 's/^\([[0-9]]\).*/\1/'`
641 fptools_version_of_ghc[_minor]=`echo [$]fptools_version_of_ghc | sed -e 's/^[[0-9]]\.\([[0-9]]*\).*/\1/'`
642 fptools_version_of_ghc[_pl]=`echo [$]fptools_version_of_ghc | sed -n -e 's/^[[0-9]]\.[[0-9]]*\.\([[0-9]]*\)/\1/p'`
643 #
644 if test "[$]fptools_version_of_ghc[_pl]" = ""
645 then
646   fptools_version_of_ghc[_all]="[$]fptools_version_of_ghc[_major].[$]fptools_version_of_ghc[_minor]"
647   fptools_version_of_ghc[_pl]="0"
648 else
649   fptools_version_of_ghc[_all]="[$]fptools_version_of_ghc[_major].[$]fptools_version_of_ghc[_minor].[$]fptools_version_of_ghc[_pl]"
650 fi
651 #
652 ifelse($#, [1], [dnl
653 [$1]="[$]fptools_version_of_ghc[_all]"
654 ], $#, [2], [dnl
655 [$1]="[$]fptools_version_of_ghc[_major]"
656 [$2]="[$]fptools_version_of_ghc[_minor]"
657 ], $#, [3], [dnl
658 [$1]="[$]fptools_version_of_ghc[_major]"
659 [$2]="[$]fptools_version_of_ghc[_minor]"
660 [$3]="[$]fptools_version_of_ghc[_pl]"
661 ], $#, [4], [dnl
662 [$1]="[$]fptools_version_of_ghc[_all]"
663 [$2]="[$]fptools_version_of_ghc[_major]"
664 [$3]="[$]fptools_version_of_ghc[_minor]"
665 [$4]="[$]fptools_version_of_ghc[_pl]"
666 ])
667 ])
668 ])dnl
669
670
671 # FP_CHECK_FUNC(FUNCTION, PROLOGUE, BODY, [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND])
672 # ---------------------------------------------------------------------------------
673 # A variant of AC_CHECK_FUNCS, limited to a single FUNCTION, but with the
674 # additional flexibility of specifying the PROLOGUE and BODY.
675 AC_DEFUN([FP_CHECK_FUNC],
676 [AS_VAR_PUSHDEF([fp_func], [fp_cv_func_$1])dnl
677 AC_CACHE_CHECK([for $1], fp_func,
678 [AC_LINK_IFELSE([AC_LANG_PROGRAM([$2], [$3])],
679                 [AS_VAR_SET(fp_func, yes)],
680                 [AS_VAR_SET(fp_func, no)])])
681 AS_IF([test AS_VAR_GET(fp_func) = yes],
682       [AC_DEFINE(AS_TR_CPP(HAVE_$1), [1],
683                 [Define to 1 if you have the `]$1[' function.]) $4],
684       [$5])dnl
685 AS_VAR_POPDEF([fp_func])dnl
686 ])# FP_CHECK_FUNC
687
688
689 # FP_GEN_DOCBOOK_XML
690 # ------------------
691 # Generates a DocBook XML V4.2 document in conftest.xml.
692 AC_DEFUN([FP_GEN_DOCBOOK_XML],
693 [rm -f conftest.xml
694 cat > conftest.xml << EOF
695 <?xml version="1.0" encoding="iso-8859-1"?>
696 <!DOCTYPE book PUBLIC "-//OASIS//DTD DocBook XML V4.2//EN"
697    "http://www.oasis-open.org/docbook/xml/4.2/docbookx.dtd">
698 <book id="test">
699   <title>A DocBook Test Document</title>
700   <chapter id="id-one">
701     <title>A Chapter Title</title>
702     <para>This is a paragraph, referencing <xref linkend="id-two"/>.</para>
703   </chapter>
704   <chapter id="id-two">
705     <title>Another Chapter Title</title>
706     <para>This is another paragraph, referencing <xref linkend="id-one"/>.</para>
707   </chapter>
708 </book>
709 EOF
710 ]) # FP_GEN_DOCBOOK_XML
711
712
713 # FP_PROG_XSLTPROC
714 # ----------------
715 # Sets the output variable XsltprocCmd to the full path of the XSLT processor
716 # xsltproc. XsltprocCmd is empty if xsltproc could not be found.
717 AC_DEFUN([FP_PROG_XSLTPROC],
718 [AC_PATH_PROG([XsltprocCmd], [xsltproc])
719 if test -z "$XsltprocCmd"; then
720   AC_MSG_WARN([cannot find xsltproc in your PATH, you will not be able to build the documentation])
721 fi
722 ])# FP_PROG_XSLTPROC
723
724
725 # FP_DIR_DOCBOOK_XSL(XSL-DIRS)
726 # ----------------------------
727 # Check which of the directories XSL-DIRS contains DocBook XSL stylesheets. The
728 # output variable DIR_DOCBOOK_XSL will contain the first usable directory or
729 # will be empty if none could be found.
730 AC_DEFUN([FP_DIR_DOCBOOK_XSL],
731 [AC_REQUIRE([FP_PROG_XSLTPROC])dnl
732 if test -n "$XsltprocCmd"; then
733   AC_CACHE_CHECK([for DocBook XSL stylesheet directory], fp_cv_dir_docbook_xsl,
734   [FP_GEN_DOCBOOK_XML
735   fp_cv_dir_docbook_xsl=no
736   for fp_var in $1; do
737      if $XsltprocCmd ${fp_var}/html/docbook.xsl conftest.xml > /dev/null 2>&1; then
738         fp_cv_dir_docbook_xsl=$fp_var
739         break
740      fi
741   done
742   rm -rf conftest*])
743 fi
744 if test x"$fp_cv_dir_docbook_xsl" = xno; then
745   AC_MSG_WARN([cannot find DocBook XSL stylesheets, you will not be able to build the documentation])
746   DIR_DOCBOOK_XSL=
747 else
748   DIR_DOCBOOK_XSL=$fp_cv_dir_docbook_xsl
749 fi
750 AC_SUBST([DIR_DOCBOOK_XSL])
751 ])# FP_DIR_DOCBOOK_XSL
752
753
754 # FP_PROG_XMLLINT
755 # ----------------
756 # Sets the output variable XmllintCmd to the full path of the XSLT processor
757 # xmllint. XmllintCmd is empty if xmllint could not be found.
758 AC_DEFUN([FP_PROG_XMLLINT],
759 [AC_PATH_PROG([XmllintCmd], [xmllint])
760 if test -z "$XmllintCmd"; then
761   AC_MSG_WARN([cannot find xmllint in your PATH, you will not be able to validate your documentation])
762 fi
763 ])# FP_PROG_XMLLINT
764
765
766 # FP_CHECK_DOCBOOK_DTD
767 # --------------------
768 AC_DEFUN([FP_CHECK_DOCBOOK_DTD],
769 [AC_REQUIRE([FP_PROG_XMLLINT])dnl
770 if test -n "$XmllintCmd"; then
771   AC_MSG_CHECKING([for DocBook DTD])
772   FP_GEN_DOCBOOK_XML
773   if $XmllintCmd --valid --noout conftest.xml > /dev/null 2>&1; then
774     AC_MSG_RESULT([ok])
775   else
776     AC_MSG_RESULT([failed])
777     AC_MSG_WARN([cannot find a DTD for DocBook XML V4.2, you will not be able to validate your documentation])
778     AC_MSG_WARN([check your XML_CATALOG_FILES environment variable and/or /etc/xml/catalog])
779   fi
780   rm -rf conftest*
781 fi
782 ])# FP_CHECK_DOCBOOK_DTD
783
784
785 # FP_GEN_FO
786 # ------------------
787 # Generates a formatting objects document in conftest.fo.
788 AC_DEFUN([FP_GEN_FO],
789 [rm -f conftest.fo
790 cat > conftest.fo << EOF
791 <?xml version="1.0"?>
792 <fo:root xmlns:fo="http://www.w3.org/1999/XSL/Format">
793   <fo:layout-master-set>
794     <fo:simple-page-master master-name="blank">
795       <fo:region-body/>
796     </fo:simple-page-master>
797   </fo:layout-master-set>
798   <fo:page-sequence master-reference="blank">
799     <fo:flow flow-name="xsl-region-body">
800       <fo:block>
801         Test!
802       </fo:block>
803     </fo:flow>
804   </fo:page-sequence>
805 </fo:root>
806 EOF
807 ]) # FP_GEN_FO
808
809
810 # FP_PROG_FOP
811 # -----------
812 # Set the output variable 'FopCmd' to the first working 'fop' in the current
813 # 'PATH'. Note that /usr/bin/fop is broken in SuSE 9.1 (unpatched), so try
814 # /usr/share/fop/fop.sh in that case (or no 'fop'), too.
815 AC_DEFUN([FP_PROG_FOP],
816 [AC_PATH_PROGS([FopCmd1], [fop])
817 if test -n "$FopCmd1"; then
818   AC_CACHE_CHECK([for $FopCmd1 usability], [fp_cv_fop_usability],
819     [FP_GEN_FO
820     if "$FopCmd1" -fo conftest.fo -ps conftest.ps > /dev/null 2>&1; then
821       fp_cv_fop_usability=yes
822     else
823       fp_cv_fop_usability=no
824     fi
825     rm -rf conftest*])
826   if test x"$fp_cv_fop_usability" = xyes; then
827      FopCmd=$FopCmd1
828   fi
829 fi
830 if test -z "$FopCmd"; then
831   AC_PATH_PROGS([FopCmd2], [fop.sh], , [/usr/share/fop])
832   FopCmd=$FopCmd2
833 fi
834 AC_SUBST([FopCmd])
835 ])# FP_PROG_FOP
836
837
838 # FP_PROG_FO_PROCESSOR
839 # --------------------
840 # Try to find an FO processor. PassiveTeX output is sometimes a bit strange, so
841 # try FOP first. Sets the output variables FopCmd, XmltexCmd, DvipsCmd, and
842 # PdfxmltexCmd.
843 AC_DEFUN([FP_PROG_FO_PROCESSOR],
844 [AC_REQUIRE([FP_PROG_FOP])
845 AC_PATH_PROG([XmltexCmd], [xmltex])
846 AC_PATH_PROG([DvipsCmd], [dvips])
847 if test -z "$FopCmd"; then
848   if test -z "$XmltexCmd"; then
849     AC_MSG_WARN([cannot find an FO => DVI converter, you will not be able to build DVI or PostScript documentation])
850   else
851     if test -z "$DvipsCmd"; then
852       AC_MSG_WARN([cannot find a DVI  => PS converter, you will not be able to build PostScript documentation])
853     fi
854   fi
855   AC_PATH_PROG([PdfxmltexCmd], [pdfxmltex])
856   if test -z "$PdfxmltexCmd"; then
857     AC_MSG_WARN([cannot find an FO => PDF converter, you will not be able to build PDF documentation])
858   fi
859 elif test -z "$XmltexCmd"; then
860   AC_MSG_WARN([cannot find an FO => DVI converter, you will not be able to build DVI documentation])
861 fi
862 ])# FP_PROG_FO_PROCESSOR
863
864
865 # FP_PROG_GHC_PKG
866 # ----------------
867 # Try to find a ghc-pkg matching the ghc mentioned in the environment variable
868 # WithGhc. If the latter is unset or no matching ghc-pkg can be found, try to
869 # find a plain ghc-pkg. Sets the output variable GhcPkgCmd.
870 AC_DEFUN([FP_PROG_GHC_PKG],
871 [AC_CACHE_CHECK([for ghc-pkg matching $WithGhc], fp_cv_matching_ghc_pkg,
872 [fp_ghc_pkg_guess=`echo $WithGhc | sed 's,ghc\(@<:@^/\\@:>@*\)$,ghc-pkg\1,'`
873 if "$fp_ghc_pkg_guess" -l > /dev/null 2>&1; then
874   fp_cv_matching_ghc_pkg=$fp_ghc_pkg_guess
875 else
876   fp_cv_matching_ghc_pkg=no
877 fi])
878 if test x"$fp_cv_matching_ghc_pkg" = xno; then
879   AC_PATH_PROG([GhcPkgCmd], [ghc-pkg])
880 else
881   GhcPkgCmd=$fp_cv_matching_ghc_pkg
882 fi])# FP_PROG_GHC_PKG
883
884
885 # FP_GHC_HAS_READLINE
886 # -------------------
887 AC_DEFUN([FP_GHC_HAS_READLINE],
888 [AC_REQUIRE([FP_PROG_GHC_PKG])
889 AC_CACHE_CHECK([whether ghc has readline package], [fp_cv_ghc_has_readline],
890 [if "${GhcPkgCmd-ghc-pkg}" --show-package readline >/dev/null 2>&1; then
891   fp_cv_ghc_has_readline=yes
892 else
893   fp_cv_ghc_has_readline=no
894  fi])
895 AC_SUBST([GhcHasReadline], [`echo $fp_cv_ghc_has_readline | sed 'y/yesno/YESNO/'`])
896 ])# FP_GHC_HAS_READLINE
897
898
899 # FP_GCC_NEEDS_NO_OMIT_LFPTR
900 # --------------------------
901 # Some OSs (Mandrake Linux, in particular) configure GCC with
902 # -momit-leaf-frame-pointer on by default. If this is the case, we need to turn
903 # it off for mangling to work. The test is currently a bit crude, using only the
904 # version number of gcc. Defines HAVE_GCC_MNO_OMIT_LFPTR.
905 AC_DEFUN([FP_GCC_NEEDS_NO_OMIT_LFPTR],
906 [AC_REQUIRE([FP_HAVE_GCC])
907 AC_CACHE_CHECK([whether gcc needs -mno-omit-leaf-frame-pointer], [fp_cv_gcc_needs_no_omit_lfptr],
908 [FP_COMPARE_VERSIONS([$fp_gcc_version], [-ge], [3.2],
909   [fp_cv_gcc_needs_no_omit_lfptr=yes],
910   [fp_cv_gcc_needs_no_omit_lfptr=no])])
911 if test "$fp_cv_gcc_needs_no_omit_lfptr" = "yes"; then
912    AC_DEFINE([HAVE_GCC_MNO_OMIT_LFPTR], [1], [Define to 1 if gcc supports -mno-omit-leaf-frame-pointer.])
913 fi])# FP_GCC_NEEDS_NO_OMIT_LFPTR
914
915 # FP_GCC_HAS_NO_UNIT_AT_A_TIME
916 # --------------------------
917 AC_DEFUN([FP_GCC_HAS_NO_UNIT_AT_A_TIME],
918 [AC_REQUIRE([FP_HAVE_GCC])
919 AC_CACHE_CHECK([whether gcc has -fno-unit-at-a-time], [fp_cv_gcc_has_no_unit_at_a_time],
920 [FP_COMPARE_VERSIONS([$fp_gcc_version], [-ge], [3.4],
921   [fp_cv_gcc_has_no_unit_at_a_time=yes],
922   [fp_cv_gcc_has_no_unit_at_a_time=no])])
923 if test "$fp_cv_gcc_has_no_unit_at_a_time" = "yes"; then
924    AC_DEFINE([HAVE_GCC_HAS_NO_UNIT_AT_A_TIME], [1], [Define to 1 if gcc supports -fno-unit-at-a-time.])
925 fi])
926
927 # FP_SETUP_PROJECT_VERSION
928 # ---------------------
929 AC_DEFUN([FP_SETUP_PROJECT_VERSION],
930 [# Some renamings
931 AC_SUBST([ProjectName], [$PACKAGE_NAME])
932 AC_SUBST([ProjectVersion], [$PACKAGE_VERSION])
933
934 # Split PACKAGE_VERSION into (possibly empty) parts
935 VERSION_MAJOR=`echo $PACKAGE_VERSION | sed 's/^\(@<:@^.@:>@*\)\(\.\{0,1\}\(.*\)\)$/\1'/`
936 VERSION_TMP=`echo $PACKAGE_VERSION | sed 's/^\(@<:@^.@:>@*\)\(\.\{0,1\}\(.*\)\)$/\3'/`
937 VERSION_MINOR=`echo $VERSION_TMP | sed 's/^\(@<:@^.@:>@*\)\(\.\{0,1\}\(.*\)\)$/\1'/`
938 ProjectPatchLevel=`echo $VERSION_TMP | sed 's/^\(@<:@^.@:>@*\)\(\.\{0,1\}\(.*\)\)$/\3'/`
939
940 # Calculate project version as an integer, using 2 digits for minor version
941 case $VERSION_MINOR in
942   ?) ProjectVersionInt=${VERSION_MAJOR}0${VERSION_MINOR} ;;
943   ??) ProjectVersionInt=${VERSION_MAJOR}${VERSION_MINOR} ;;
944   *) AC_MSG_ERROR([bad minor version in $PACKAGE_VERSION]) ;;
945 esac
946 AC_SUBST([ProjectVersionInt])
947
948 # The project patchlevel is zero unless stated otherwise
949 test -z "$ProjectPatchLevel" && ProjectPatchLevel=0
950
951 # Remove dots from the patch level; this allows us to have versions like 6.4.1.20050508
952 ProjectPatchLevel=`echo $ProjectPatchLevel | sed 's/\.//'`
953
954 AC_SUBST([ProjectPatchLevel])
955 ])# FP_SETUP_PROJECT_VERSION
956
957 # LocalWords:  fi