compiler: de-lhs typecheck/
[ghc.git] / compiler / deSugar / DsListComp.lhs
1 %
2 % (c) The University of Glasgow 2006
3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
4 %
5
6 Desugaring list comprehensions, monad comprehensions and array comprehensions
7
8 \begin{code}
9 {-# LANGUAGE CPP, NamedFieldPuns #-}
10
11 module DsListComp ( dsListComp, dsPArrComp, dsMonadComp ) where
12
13 #include "HsVersions.h"
14
15 import {-# SOURCE #-} DsExpr ( dsExpr, dsLExpr, dsLocalBinds )
16
17 import HsSyn
18 import TcHsSyn
19 import CoreSyn
20 import MkCore
21
22 import DsMonad          -- the monadery used in the desugarer
23 import DsUtils
24
25 import DynFlags
26 import CoreUtils
27 import Id
28 import Type
29 import TysWiredIn
30 import Match
31 import PrelNames
32 import SrcLoc
33 import Outputable
34 import FastString
35 import TcType
36 import ListSetOps( getNth )
37 import Util
38 \end{code}
39
40 List comprehensions may be desugared in one of two ways: ``ordinary''
41 (as you would expect if you read SLPJ's book) and ``with foldr/build
42 turned on'' (if you read Gill {\em et al.}'s paper on the subject).
43
44 There will be at least one ``qualifier'' in the input.
45
46 \begin{code}
47 dsListComp :: [ExprLStmt Id]
48            -> Type              -- Type of entire list
49            -> DsM CoreExpr
50 dsListComp lquals res_ty = do
51     dflags <- getDynFlags
52     let quals = map unLoc lquals
53         elt_ty = case tcTyConAppArgs res_ty of
54                    [elt_ty] -> elt_ty
55                    _ -> pprPanic "dsListComp" (ppr res_ty $$ ppr lquals)
56
57     if not (gopt Opt_EnableRewriteRules dflags) || gopt Opt_IgnoreInterfacePragmas dflags
58        -- Either rules are switched off, or we are ignoring what there are;
59        -- Either way foldr/build won't happen, so use the more efficient
60        -- Wadler-style desugaring
61        || isParallelComp quals
62        -- Foldr-style desugaring can't handle parallel list comprehensions
63         then deListComp quals (mkNilExpr elt_ty)
64         else mkBuildExpr elt_ty (\(c, _) (n, _) -> dfListComp c n quals)
65              -- Foldr/build should be enabled, so desugar
66              -- into foldrs and builds
67
68   where
69     -- We must test for ParStmt anywhere, not just at the head, because an extension
70     -- to list comprehensions would be to add brackets to specify the associativity
71     -- of qualifier lists. This is really easy to do by adding extra ParStmts into the
72     -- mix of possibly a single element in length, so we do this to leave the possibility open
73     isParallelComp = any isParallelStmt
74
75     isParallelStmt (ParStmt {}) = True
76     isParallelStmt _            = False
77
78
79 -- This function lets you desugar a inner list comprehension and a list of the binders
80 -- of that comprehension that we need in the outer comprehension into such an expression
81 -- and the type of the elements that it outputs (tuples of binders)
82 dsInnerListComp :: (ParStmtBlock Id Id) -> DsM (CoreExpr, Type)
83 dsInnerListComp (ParStmtBlock stmts bndrs _)
84   = do { expr <- dsListComp (stmts ++ [noLoc $ mkLastStmt (mkBigLHsVarTup bndrs)])
85                             (mkListTy bndrs_tuple_type)
86        ; return (expr, bndrs_tuple_type) }
87   where
88     bndrs_tuple_type = mkBigCoreVarTupTy bndrs
89
90 -- This function factors out commonality between the desugaring strategies for GroupStmt.
91 -- Given such a statement it gives you back an expression representing how to compute the transformed
92 -- list and the tuple that you need to bind from that list in order to proceed with your desugaring
93 dsTransStmt :: ExprStmt Id -> DsM (CoreExpr, LPat Id)
94 dsTransStmt (TransStmt { trS_form = form, trS_stmts = stmts, trS_bndrs = binderMap
95                        , trS_by = by, trS_using = using }) = do
96     let (from_bndrs, to_bndrs) = unzip binderMap
97         from_bndrs_tys  = map idType from_bndrs
98         to_bndrs_tys    = map idType to_bndrs
99         to_bndrs_tup_ty = mkBigCoreTupTy to_bndrs_tys
100
101     -- Desugar an inner comprehension which outputs a list of tuples of the "from" binders
102     (expr, from_tup_ty) <- dsInnerListComp (ParStmtBlock stmts from_bndrs noSyntaxExpr)
103
104     -- Work out what arguments should be supplied to that expression: i.e. is an extraction
105     -- function required? If so, create that desugared function and add to arguments
106     usingExpr' <- dsLExpr using
107     usingArgs <- case by of
108                    Nothing   -> return [expr]
109                    Just by_e -> do { by_e' <- dsLExpr by_e
110                                    ; lam <- matchTuple from_bndrs by_e'
111                                    ; return [lam, expr] }
112
113     -- Create an unzip function for the appropriate arity and element types and find "map"
114     unzip_stuff <- mkUnzipBind form from_bndrs_tys
115     map_id <- dsLookupGlobalId mapName
116
117     -- Generate the expressions to build the grouped list
118     let -- First we apply the grouping function to the inner list
119         inner_list_expr = mkApps usingExpr' usingArgs
120         -- Then we map our "unzip" across it to turn the lists of tuples into tuples of lists
121         -- We make sure we instantiate the type variable "a" to be a list of "from" tuples and
122         -- the "b" to be a tuple of "to" lists!
123         -- Then finally we bind the unzip function around that expression
124         bound_unzipped_inner_list_expr
125           = case unzip_stuff of
126               Nothing -> inner_list_expr
127               Just (unzip_fn, unzip_rhs) -> Let (Rec [(unzip_fn, unzip_rhs)]) $
128                                             mkApps (Var map_id) $
129                                             [ Type (mkListTy from_tup_ty)
130                                             , Type to_bndrs_tup_ty
131                                             , Var unzip_fn
132                                             , inner_list_expr]
133
134     -- Build a pattern that ensures the consumer binds into the NEW binders,
135     -- which hold lists rather than single values
136     let pat = mkBigLHsVarPatTup to_bndrs
137     return (bound_unzipped_inner_list_expr, pat)
138
139 dsTransStmt _ = panic "dsTransStmt: Not given a TransStmt"
140 \end{code}
141
142 %************************************************************************
143 %*                                                                      *
144 \subsection[DsListComp-ordinary]{Ordinary desugaring of list comprehensions}
145 %*                                                                      *
146 %************************************************************************
147
148 Just as in Phil's chapter~7 in SLPJ, using the rules for
149 optimally-compiled list comprehensions.  This is what Kevin followed
150 as well, and I quite happily do the same.  The TQ translation scheme
151 transforms a list of qualifiers (either boolean expressions or
152 generators) into a single expression which implements the list
153 comprehension.  Because we are generating 2nd-order polymorphic
154 lambda-calculus, calls to NIL and CONS must be applied to a type
155 argument, as well as their usual value arguments.
156 \begin{verbatim}
157 TE << [ e | qs ] >>  =  TQ << [ e | qs ] ++ Nil (typeOf e) >>
158
159 (Rule C)
160 TQ << [ e | ] ++ L >> = Cons (typeOf e) TE <<e>> TE <<L>>
161
162 (Rule B)
163 TQ << [ e | b , qs ] ++ L >> =
164     if TE << b >> then TQ << [ e | qs ] ++ L >> else TE << L >>
165
166 (Rule A')
167 TQ << [ e | p <- L1, qs ]  ++  L2 >> =
168   letrec
169     h = \ u1 ->
170           case u1 of
171             []        ->  TE << L2 >>
172             (u2 : u3) ->
173                   (( \ TE << p >> -> ( TQ << [e | qs]  ++  (h u3) >> )) u2)
174                     [] (h u3)
175   in
176     h ( TE << L1 >> )
177
178 "h", "u1", "u2", and "u3" are new variables.
179 \end{verbatim}
180
181 @deListComp@ is the TQ translation scheme.  Roughly speaking, @dsExpr@
182 is the TE translation scheme.  Note that we carry around the @L@ list
183 already desugared.  @dsListComp@ does the top TE rule mentioned above.
184
185 To the above, we add an additional rule to deal with parallel list
186 comprehensions.  The translation goes roughly as follows:
187      [ e | p1 <- e11, let v1 = e12, p2 <- e13
188          | q1 <- e21, let v2 = e22, q2 <- e23]
189      =>
190      [ e | ((x1, .., xn), (y1, ..., ym)) <-
191                zip [(x1,..,xn) | p1 <- e11, let v1 = e12, p2 <- e13]
192                    [(y1,..,ym) | q1 <- e21, let v2 = e22, q2 <- e23]]
193 where (x1, .., xn) are the variables bound in p1, v1, p2
194       (y1, .., ym) are the variables bound in q1, v2, q2
195
196 In the translation below, the ParStmt branch translates each parallel branch
197 into a sub-comprehension, and desugars each independently.  The resulting lists
198 are fed to a zip function, we create a binding for all the variables bound in all
199 the comprehensions, and then we hand things off the the desugarer for bindings.
200 The zip function is generated here a) because it's small, and b) because then we
201 don't have to deal with arbitrary limits on the number of zip functions in the
202 prelude, nor which library the zip function came from.
203 The introduced tuples are Boxed, but only because I couldn't get it to work
204 with the Unboxed variety.
205
206 \begin{code}
207
208 deListComp :: [ExprStmt Id] -> CoreExpr -> DsM CoreExpr
209
210 deListComp [] _ = panic "deListComp"
211
212 deListComp (LastStmt body _ : quals) list
213   =     -- Figure 7.4, SLPJ, p 135, rule C above
214     ASSERT( null quals )
215     do { core_body <- dsLExpr body
216        ; return (mkConsExpr (exprType core_body) core_body list) }
217
218         -- Non-last: must be a guard
219 deListComp (BodyStmt guard _ _ _ : quals) list = do  -- rule B above
220     core_guard <- dsLExpr guard
221     core_rest <- deListComp quals list
222     return (mkIfThenElse core_guard core_rest list)
223
224 -- [e | let B, qs] = let B in [e | qs]
225 deListComp (LetStmt binds : quals) list = do
226     core_rest <- deListComp quals list
227     dsLocalBinds binds core_rest
228
229 deListComp (stmt@(TransStmt {}) : quals) list = do
230     (inner_list_expr, pat) <- dsTransStmt stmt
231     deBindComp pat inner_list_expr quals list
232
233 deListComp (BindStmt pat list1 _ _ : quals) core_list2 = do -- rule A' above
234     core_list1 <- dsLExpr list1
235     deBindComp pat core_list1 quals core_list2
236
237 deListComp (ParStmt stmtss_w_bndrs _ _ : quals) list
238   = do { exps_and_qual_tys <- mapM dsInnerListComp stmtss_w_bndrs
239        ; let (exps, qual_tys) = unzip exps_and_qual_tys
240
241        ; (zip_fn, zip_rhs) <- mkZipBind qual_tys
242
243         -- Deal with [e | pat <- zip l1 .. ln] in example above
244        ; deBindComp pat (Let (Rec [(zip_fn, zip_rhs)]) (mkApps (Var zip_fn) exps))
245                     quals list }
246   where
247         bndrs_s = [bs | ParStmtBlock _ bs _ <- stmtss_w_bndrs]
248
249         -- pat is the pattern ((x1,..,xn), (y1,..,ym)) in the example above
250         pat  = mkBigLHsPatTup pats
251         pats = map mkBigLHsVarPatTup bndrs_s
252
253 deListComp (RecStmt {} : _) _ = panic "deListComp RecStmt"
254 \end{code}
255
256
257 \begin{code}
258 deBindComp :: OutPat Id
259            -> CoreExpr
260            -> [ExprStmt Id]
261            -> CoreExpr
262            -> DsM (Expr Id)
263 deBindComp pat core_list1 quals core_list2 = do
264     let
265         u3_ty@u1_ty = exprType core_list1       -- two names, same thing
266
267         -- u1_ty is a [alpha] type, and u2_ty = alpha
268         u2_ty = hsLPatType pat
269
270         res_ty = exprType core_list2
271         h_ty   = u1_ty `mkFunTy` res_ty
272
273     [h, u1, u2, u3] <- newSysLocalsDs [h_ty, u1_ty, u2_ty, u3_ty]
274
275     -- the "fail" value ...
276     let
277         core_fail   = App (Var h) (Var u3)
278         letrec_body = App (Var h) core_list1
279
280     rest_expr <- deListComp quals core_fail
281     core_match <- matchSimply (Var u2) (StmtCtxt ListComp) pat rest_expr core_fail
282
283     let
284         rhs = Lam u1 $
285               Case (Var u1) u1 res_ty
286                    [(DataAlt nilDataCon,  [],       core_list2),
287                     (DataAlt consDataCon, [u2, u3], core_match)]
288                         -- Increasing order of tag
289
290     return (Let (Rec [(h, rhs)]) letrec_body)
291 \end{code}
292
293 %************************************************************************
294 %*                                                                      *
295 \subsection[DsListComp-foldr-build]{Foldr/Build desugaring of list comprehensions}
296 %*                                                                      *
297 %************************************************************************
298
299 @dfListComp@ are the rules used with foldr/build turned on:
300
301 \begin{verbatim}
302 TE[ e | ]            c n = c e n
303 TE[ e | b , q ]      c n = if b then TE[ e | q ] c n else n
304 TE[ e | p <- l , q ] c n = let
305                                 f = \ x b -> case x of
306                                                   p -> TE[ e | q ] c b
307                                                   _ -> b
308                            in
309                            foldr f n l
310 \end{verbatim}
311
312 \begin{code}
313 dfListComp :: Id -> Id      -- 'c' and 'n'
314         -> [ExprStmt Id]    -- the rest of the qual's
315         -> DsM CoreExpr
316
317 dfListComp _ _ [] = panic "dfListComp"
318
319 dfListComp c_id n_id (LastStmt body _ : quals)
320   = ASSERT( null quals )
321     do { core_body <- dsLExpr body
322        ; return (mkApps (Var c_id) [core_body, Var n_id]) }
323
324         -- Non-last: must be a guard
325 dfListComp c_id n_id (BodyStmt guard _ _ _  : quals) = do
326     core_guard <- dsLExpr guard
327     core_rest <- dfListComp c_id n_id quals
328     return (mkIfThenElse core_guard core_rest (Var n_id))
329
330 dfListComp c_id n_id (LetStmt binds : quals) = do
331     -- new in 1.3, local bindings
332     core_rest <- dfListComp c_id n_id quals
333     dsLocalBinds binds core_rest
334
335 dfListComp c_id n_id (stmt@(TransStmt {}) : quals) = do
336     (inner_list_expr, pat) <- dsTransStmt stmt
337     -- Anyway, we bind the newly grouped list via the generic binding function
338     dfBindComp c_id n_id (pat, inner_list_expr) quals
339
340 dfListComp c_id n_id (BindStmt pat list1 _ _ : quals) = do
341     -- evaluate the two lists
342     core_list1 <- dsLExpr list1
343
344     -- Do the rest of the work in the generic binding builder
345     dfBindComp c_id n_id (pat, core_list1) quals
346
347 dfListComp _ _ (ParStmt {} : _) = panic "dfListComp ParStmt"
348 dfListComp _ _ (RecStmt {} : _) = panic "dfListComp RecStmt"
349
350 dfBindComp :: Id -> Id          -- 'c' and 'n'
351            -> (LPat Id, CoreExpr)
352            -> [ExprStmt Id]     -- the rest of the qual's
353            -> DsM CoreExpr
354 dfBindComp c_id n_id (pat, core_list1) quals = do
355     -- find the required type
356     let x_ty   = hsLPatType pat
357         b_ty   = idType n_id
358
359     -- create some new local id's
360     [b, x] <- newSysLocalsDs [b_ty, x_ty]
361
362     -- build rest of the comprehesion
363     core_rest <- dfListComp c_id b quals
364
365     -- build the pattern match
366     core_expr <- matchSimply (Var x) (StmtCtxt ListComp)
367                 pat core_rest (Var b)
368
369     -- now build the outermost foldr, and return
370     mkFoldrExpr x_ty b_ty (mkLams [x, b] core_expr) (Var n_id) core_list1
371 \end{code}
372
373 %************************************************************************
374 %*                                                                      *
375 \subsection[DsFunGeneration]{Generation of zip/unzip functions for use in desugaring}
376 %*                                                                      *
377 %************************************************************************
378
379 \begin{code}
380
381 mkZipBind :: [Type] -> DsM (Id, CoreExpr)
382 -- mkZipBind [t1, t2]
383 -- = (zip, \as1:[t1] as2:[t2]
384 --         -> case as1 of
385 --              [] -> []
386 --              (a1:as'1) -> case as2 of
387 --                              [] -> []
388 --                              (a2:as'2) -> (a1, a2) : zip as'1 as'2)]
389
390 mkZipBind elt_tys = do
391     ass  <- mapM newSysLocalDs  elt_list_tys
392     as'  <- mapM newSysLocalDs  elt_tys
393     as's <- mapM newSysLocalDs  elt_list_tys
394
395     zip_fn <- newSysLocalDs zip_fn_ty
396
397     let inner_rhs = mkConsExpr elt_tuple_ty
398                         (mkBigCoreVarTup as')
399                         (mkVarApps (Var zip_fn) as's)
400         zip_body  = foldr mk_case inner_rhs (zip3 ass as' as's)
401
402     return (zip_fn, mkLams ass zip_body)
403   where
404     elt_list_tys      = map mkListTy elt_tys
405     elt_tuple_ty      = mkBigCoreTupTy elt_tys
406     elt_tuple_list_ty = mkListTy elt_tuple_ty
407
408     zip_fn_ty         = mkFunTys elt_list_tys elt_tuple_list_ty
409
410     mk_case (as, a', as') rest
411           = Case (Var as) as elt_tuple_list_ty
412                   [(DataAlt nilDataCon,  [],        mkNilExpr elt_tuple_ty),
413                    (DataAlt consDataCon, [a', as'], rest)]
414                         -- Increasing order of tag
415
416
417 mkUnzipBind :: TransForm -> [Type] -> DsM (Maybe (Id, CoreExpr))
418 -- mkUnzipBind [t1, t2]
419 -- = (unzip, \ys :: [(t1, t2)] -> foldr (\ax :: (t1, t2) axs :: ([t1], [t2])
420 --     -> case ax of
421 --      (x1, x2) -> case axs of
422 --                (xs1, xs2) -> (x1 : xs1, x2 : xs2))
423 --      ([], [])
424 --      ys)
425 --
426 -- We use foldr here in all cases, even if rules are turned off, because we may as well!
427 mkUnzipBind ThenForm _
428  = return Nothing    -- No unzipping for ThenForm
429 mkUnzipBind _ elt_tys
430   = do { ax  <- newSysLocalDs elt_tuple_ty
431        ; axs <- newSysLocalDs elt_list_tuple_ty
432        ; ys  <- newSysLocalDs elt_tuple_list_ty
433        ; xs  <- mapM newSysLocalDs elt_tys
434        ; xss <- mapM newSysLocalDs elt_list_tys
435
436        ; unzip_fn <- newSysLocalDs unzip_fn_ty
437
438        ; [us1, us2] <- sequence [newUniqueSupply, newUniqueSupply]
439
440        ; let nil_tuple = mkBigCoreTup (map mkNilExpr elt_tys)
441              concat_expressions = map mkConcatExpression (zip3 elt_tys (map Var xs) (map Var xss))
442              tupled_concat_expression = mkBigCoreTup concat_expressions
443
444              folder_body_inner_case = mkTupleCase us1 xss tupled_concat_expression axs (Var axs)
445              folder_body_outer_case = mkTupleCase us2 xs folder_body_inner_case ax (Var ax)
446              folder_body = mkLams [ax, axs] folder_body_outer_case
447
448        ; unzip_body <- mkFoldrExpr elt_tuple_ty elt_list_tuple_ty folder_body nil_tuple (Var ys)
449        ; return (Just (unzip_fn, mkLams [ys] unzip_body)) }
450   where
451     elt_tuple_ty       = mkBigCoreTupTy elt_tys
452     elt_tuple_list_ty  = mkListTy elt_tuple_ty
453     elt_list_tys       = map mkListTy elt_tys
454     elt_list_tuple_ty  = mkBigCoreTupTy elt_list_tys
455
456     unzip_fn_ty        = elt_tuple_list_ty `mkFunTy` elt_list_tuple_ty
457
458     mkConcatExpression (list_element_ty, head, tail) = mkConsExpr list_element_ty head tail
459 \end{code}
460
461 %************************************************************************
462 %*                                                                      *
463 \subsection[DsPArrComp]{Desugaring of array comprehensions}
464 %*                                                                      *
465 %************************************************************************
466
467 \begin{code}
468
469 -- entry point for desugaring a parallel array comprehension
470 --
471 --   [:e | qss:] = <<[:e | qss:]>> () [:():]
472 --
473 dsPArrComp :: [ExprStmt Id]
474             -> DsM CoreExpr
475
476 -- Special case for parallel comprehension
477 dsPArrComp (ParStmt qss _ _ : quals) = dePArrParComp qss quals
478
479 -- Special case for simple generators:
480 --
481 --  <<[:e' | p <- e, qs:]>> = <<[: e' | qs :]>> p e
482 --
483 -- if matching again p cannot fail, or else
484 --
485 --  <<[:e' | p <- e, qs:]>> =
486 --    <<[:e' | qs:]>> p (filterP (\x -> case x of {p -> True; _ -> False}) e)
487 --
488 dsPArrComp (BindStmt p e _ _ : qs) = do
489     filterP <- dsDPHBuiltin filterPVar
490     ce <- dsLExpr e
491     let ety'ce  = parrElemType ce
492         false   = Var falseDataConId
493         true    = Var trueDataConId
494     v <- newSysLocalDs ety'ce
495     pred <- matchSimply (Var v) (StmtCtxt PArrComp) p true false
496     let gen | isIrrefutableHsPat p = ce
497             | otherwise            = mkApps (Var filterP) [Type ety'ce, mkLams [v] pred, ce]
498     dePArrComp qs p gen
499
500 dsPArrComp qs = do -- no ParStmt in `qs'
501     sglP <- dsDPHBuiltin singletonPVar
502     let unitArray = mkApps (Var sglP) [Type unitTy, mkCoreTup []]
503     dePArrComp qs (noLoc $ WildPat unitTy) unitArray
504
505
506
507 -- the work horse
508 --
509 dePArrComp :: [ExprStmt Id]
510            -> LPat Id           -- the current generator pattern
511            -> CoreExpr          -- the current generator expression
512            -> DsM CoreExpr
513
514 dePArrComp [] _ _ = panic "dePArrComp"
515
516 --
517 --  <<[:e' | :]>> pa ea = mapP (\pa -> e') ea
518 --
519 dePArrComp (LastStmt e' _ : quals) pa cea
520   = ASSERT( null quals )
521     do { mapP <- dsDPHBuiltin mapPVar
522        ; let ty = parrElemType cea
523        ; (clam, ty'e') <- deLambda ty pa e'
524        ; return $ mkApps (Var mapP) [Type ty, Type ty'e', clam, cea] }
525 --
526 --  <<[:e' | b, qs:]>> pa ea = <<[:e' | qs:]>> pa (filterP (\pa -> b) ea)
527 --
528 dePArrComp (BodyStmt b _ _ _ : qs) pa cea = do
529     filterP <- dsDPHBuiltin filterPVar
530     let ty = parrElemType cea
531     (clam,_) <- deLambda ty pa b
532     dePArrComp qs pa (mkApps (Var filterP) [Type ty, clam, cea])
533
534 --
535 --  <<[:e' | p <- e, qs:]>> pa ea =
536 --    let ef = \pa -> e
537 --    in
538 --    <<[:e' | qs:]>> (pa, p) (crossMap ea ef)
539 --
540 -- if matching again p cannot fail, or else
541 --
542 --  <<[:e' | p <- e, qs:]>> pa ea =
543 --    let ef = \pa -> filterP (\x -> case x of {p -> True; _ -> False}) e
544 --    in
545 --    <<[:e' | qs:]>> (pa, p) (crossMapP ea ef)
546 --
547 dePArrComp (BindStmt p e _ _ : qs) pa cea = do
548     filterP <- dsDPHBuiltin filterPVar
549     crossMapP <- dsDPHBuiltin crossMapPVar
550     ce <- dsLExpr e
551     let ety'cea = parrElemType cea
552         ety'ce  = parrElemType ce
553         false   = Var falseDataConId
554         true    = Var trueDataConId
555     v <- newSysLocalDs ety'ce
556     pred <- matchSimply (Var v) (StmtCtxt PArrComp) p true false
557     let cef | isIrrefutableHsPat p = ce
558             | otherwise            = mkApps (Var filterP) [Type ety'ce, mkLams [v] pred, ce]
559     (clam, _) <- mkLambda ety'cea pa cef
560     let ety'cef = ety'ce                    -- filter doesn't change the element type
561         pa'     = mkLHsPatTup [pa, p]
562
563     dePArrComp qs pa' (mkApps (Var crossMapP)
564                                  [Type ety'cea, Type ety'cef, cea, clam])
565 --
566 --  <<[:e' | let ds, qs:]>> pa ea =
567 --    <<[:e' | qs:]>> (pa, (x_1, ..., x_n))
568 --                    (mapP (\v@pa -> let ds in (v, (x_1, ..., x_n))) ea)
569 --  where
570 --    {x_1, ..., x_n} = DV (ds)         -- Defined Variables
571 --
572 dePArrComp (LetStmt ds : qs) pa cea = do
573     mapP <- dsDPHBuiltin mapPVar
574     let xs     = collectLocalBinders ds
575         ty'cea = parrElemType cea
576     v <- newSysLocalDs ty'cea
577     clet <- dsLocalBinds ds (mkCoreTup (map Var xs))
578     let'v <- newSysLocalDs (exprType clet)
579     let projBody = mkCoreLet (NonRec let'v clet) $
580                    mkCoreTup [Var v, Var let'v]
581         errTy    = exprType projBody
582         errMsg   = ptext (sLit "DsListComp.dePArrComp: internal error!")
583     cerr <- mkErrorAppDs pAT_ERROR_ID errTy errMsg
584     ccase <- matchSimply (Var v) (StmtCtxt PArrComp) pa projBody cerr
585     let pa'    = mkLHsPatTup [pa, mkLHsPatTup (map nlVarPat xs)]
586         proj   = mkLams [v] ccase
587     dePArrComp qs pa' (mkApps (Var mapP)
588                                    [Type ty'cea, Type errTy, proj, cea])
589 --
590 -- The parser guarantees that parallel comprehensions can only appear as
591 -- singleton qualifier lists, which we already special case in the caller.
592 -- So, encountering one here is a bug.
593 --
594 dePArrComp (ParStmt {} : _) _ _ =
595   panic "DsListComp.dePArrComp: malformed comprehension AST: ParStmt"
596 dePArrComp (TransStmt {} : _) _ _ = panic "DsListComp.dePArrComp: TransStmt"
597 dePArrComp (RecStmt   {} : _) _ _ = panic "DsListComp.dePArrComp: RecStmt"
598
599 --  <<[:e' | qs | qss:]>> pa ea =
600 --    <<[:e' | qss:]>> (pa, (x_1, ..., x_n))
601 --                     (zipP ea <<[:(x_1, ..., x_n) | qs:]>>)
602 --    where
603 --      {x_1, ..., x_n} = DV (qs)
604 --
605 dePArrParComp :: [ParStmtBlock Id Id] -> [ExprStmt Id] -> DsM CoreExpr
606 dePArrParComp qss quals = do
607     (pQss, ceQss) <- deParStmt qss
608     dePArrComp quals pQss ceQss
609   where
610     deParStmt []             =
611       -- empty parallel statement lists have no source representation
612       panic "DsListComp.dePArrComp: Empty parallel list comprehension"
613     deParStmt (ParStmtBlock qs xs _:qss) = do        -- first statement
614       let res_expr = mkLHsVarTuple xs
615       cqs <- dsPArrComp (map unLoc qs ++ [mkLastStmt res_expr])
616       parStmts qss (mkLHsVarPatTup xs) cqs
617     ---
618     parStmts []             pa cea = return (pa, cea)
619     parStmts (ParStmtBlock qs xs _:qss) pa cea = do  -- subsequent statements (zip'ed)
620       zipP <- dsDPHBuiltin zipPVar
621       let pa'      = mkLHsPatTup [pa, mkLHsVarPatTup xs]
622           ty'cea   = parrElemType cea
623           res_expr = mkLHsVarTuple xs
624       cqs <- dsPArrComp (map unLoc qs ++ [mkLastStmt res_expr])
625       let ty'cqs = parrElemType cqs
626           cea'   = mkApps (Var zipP) [Type ty'cea, Type ty'cqs, cea, cqs]
627       parStmts qss pa' cea'
628
629 -- generate Core corresponding to `\p -> e'
630 --
631 deLambda :: Type                        -- type of the argument
632           -> LPat Id                    -- argument pattern
633           -> LHsExpr Id                 -- body
634           -> DsM (CoreExpr, Type)
635 deLambda ty p e =
636     mkLambda ty p =<< dsLExpr e
637
638 -- generate Core for a lambda pattern match, where the body is already in Core
639 --
640 mkLambda :: Type                        -- type of the argument
641          -> LPat Id                     -- argument pattern
642          -> CoreExpr                    -- desugared body
643          -> DsM (CoreExpr, Type)
644 mkLambda ty p ce = do
645     v <- newSysLocalDs ty
646     let errMsg = ptext (sLit "DsListComp.deLambda: internal error!")
647         ce'ty  = exprType ce
648     cerr <- mkErrorAppDs pAT_ERROR_ID ce'ty errMsg
649     res <- matchSimply (Var v) (StmtCtxt PArrComp) p ce cerr
650     return (mkLams [v] res, ce'ty)
651
652 -- obtain the element type of the parallel array produced by the given Core
653 -- expression
654 --
655 parrElemType   :: CoreExpr -> Type
656 parrElemType e  =
657   case splitTyConApp_maybe (exprType e) of
658     Just (tycon, [ty]) | tycon == parrTyCon -> ty
659     _                                                     -> panic
660       "DsListComp.parrElemType: not a parallel array type"
661 \end{code}
662
663 Translation for monad comprehensions
664
665 \begin{code}
666 -- Entry point for monad comprehension desugaring
667 dsMonadComp :: [ExprLStmt Id] -> DsM CoreExpr
668 dsMonadComp stmts = dsMcStmts stmts
669
670 dsMcStmts :: [ExprLStmt Id] -> DsM CoreExpr
671 dsMcStmts []                    = panic "dsMcStmts"
672 dsMcStmts (L loc stmt : lstmts) = putSrcSpanDs loc (dsMcStmt stmt lstmts)
673
674 ---------------
675 dsMcStmt :: ExprStmt Id -> [ExprLStmt Id] -> DsM CoreExpr
676
677 dsMcStmt (LastStmt body ret_op) stmts
678   = ASSERT( null stmts )
679     do { body' <- dsLExpr body
680        ; ret_op' <- dsExpr ret_op
681        ; return (App ret_op' body') }
682
683 --   [ .. | let binds, stmts ]
684 dsMcStmt (LetStmt binds) stmts
685   = do { rest <- dsMcStmts stmts
686        ; dsLocalBinds binds rest }
687
688 --   [ .. | a <- m, stmts ]
689 dsMcStmt (BindStmt pat rhs bind_op fail_op) stmts
690   = do { rhs' <- dsLExpr rhs
691        ; dsMcBindStmt pat rhs' bind_op fail_op stmts }
692
693 -- Apply `guard` to the `exp` expression
694 --
695 --   [ .. | exp, stmts ]
696 --
697 dsMcStmt (BodyStmt exp then_exp guard_exp _) stmts
698   = do { exp'       <- dsLExpr exp
699        ; guard_exp' <- dsExpr guard_exp
700        ; then_exp'  <- dsExpr then_exp
701        ; rest       <- dsMcStmts stmts
702        ; return $ mkApps then_exp' [ mkApps guard_exp' [exp']
703                                    , rest ] }
704
705 -- Group statements desugar like this:
706 --
707 --   [| (q, then group by e using f); rest |]
708 --   --->  f {qt} (\qv -> e) [| q; return qv |] >>= \ n_tup ->
709 --         case unzip n_tup of qv' -> [| rest |]
710 --
711 -- where   variables (v1:t1, ..., vk:tk) are bound by q
712 --         qv = (v1, ..., vk)
713 --         qt = (t1, ..., tk)
714 --         (>>=) :: m2 a -> (a -> m3 b) -> m3 b
715 --         f :: forall a. (a -> t) -> m1 a -> m2 (n a)
716 --         n_tup :: n qt
717 --         unzip :: n qt -> (n t1, ..., n tk)    (needs Functor n)
718
719 dsMcStmt (TransStmt { trS_stmts = stmts, trS_bndrs = bndrs
720                     , trS_by = by, trS_using = using
721                     , trS_ret = return_op, trS_bind = bind_op
722                     , trS_fmap = fmap_op, trS_form = form }) stmts_rest
723   = do { let (from_bndrs, to_bndrs) = unzip bndrs
724              from_bndr_tys          = map idType from_bndrs     -- Types ty
725
726        -- Desugar an inner comprehension which outputs a list of tuples of the "from" binders
727        ; expr <- dsInnerMonadComp stmts from_bndrs return_op
728
729        -- Work out what arguments should be supplied to that expression: i.e. is an extraction
730        -- function required? If so, create that desugared function and add to arguments
731        ; usingExpr' <- dsLExpr using
732        ; usingArgs <- case by of
733                         Nothing   -> return [expr]
734                         Just by_e -> do { by_e' <- dsLExpr by_e
735                                         ; lam <- matchTuple from_bndrs by_e'
736                                         ; return [lam, expr] }
737
738        -- Generate the expressions to build the grouped list
739        -- Build a pattern that ensures the consumer binds into the NEW binders,
740        -- which hold monads rather than single values
741        ; bind_op' <- dsExpr bind_op
742        ; let bind_ty  = exprType bind_op'    -- m2 (n (a,b,c)) -> (n (a,b,c) -> r1) -> r2
743              n_tup_ty = funArgTy $ funArgTy $ funResultTy bind_ty   -- n (a,b,c)
744              tup_n_ty = mkBigCoreVarTupTy to_bndrs
745
746        ; body       <- dsMcStmts stmts_rest
747        ; n_tup_var  <- newSysLocalDs n_tup_ty
748        ; tup_n_var  <- newSysLocalDs tup_n_ty
749        ; tup_n_expr <- mkMcUnzipM form fmap_op n_tup_var from_bndr_tys
750        ; us         <- newUniqueSupply
751        ; let rhs'  = mkApps usingExpr' usingArgs
752              body' = mkTupleCase us to_bndrs body tup_n_var tup_n_expr
753
754        ; return (mkApps bind_op' [rhs', Lam n_tup_var body']) }
755
756 -- Parallel statements. Use `Control.Monad.Zip.mzip` to zip parallel
757 -- statements, for example:
758 --
759 --   [ body | qs1 | qs2 | qs3 ]
760 --     ->  [ body | (bndrs1, (bndrs2, bndrs3))
761 --                     <- [bndrs1 | qs1] `mzip` ([bndrs2 | qs2] `mzip` [bndrs3 | qs3]) ]
762 --
763 -- where `mzip` has type
764 --   mzip :: forall a b. m a -> m b -> m (a,b)
765 -- NB: we need a polymorphic mzip because we call it several times
766
767 dsMcStmt (ParStmt blocks mzip_op bind_op) stmts_rest
768  = do  { exps_w_tys  <- mapM ds_inner blocks   -- Pairs (exp :: m ty, ty)
769        ; mzip_op'    <- dsExpr mzip_op
770
771        ; let -- The pattern variables
772              pats = [ mkBigLHsVarPatTup bs | ParStmtBlock _ bs _ <- blocks]
773              -- Pattern with tuples of variables
774              -- [v1,v2,v3]  =>  (v1, (v2, v3))
775              pat = foldr1 (\p1 p2 -> mkLHsPatTup [p1, p2]) pats
776              (rhs, _) = foldr1 (\(e1,t1) (e2,t2) ->
777                                  (mkApps mzip_op' [Type t1, Type t2, e1, e2],
778                                   mkBoxedTupleTy [t1,t2]))
779                                exps_w_tys
780
781        ; dsMcBindStmt pat rhs bind_op noSyntaxExpr stmts_rest }
782   where
783     ds_inner (ParStmtBlock stmts bndrs return_op) 
784        = do { exp <- dsInnerMonadComp stmts bndrs return_op
785             ; return (exp, mkBigCoreVarTupTy bndrs) }
786
787 dsMcStmt stmt _ = pprPanic "dsMcStmt: unexpected stmt" (ppr stmt)
788
789
790 matchTuple :: [Id] -> CoreExpr -> DsM CoreExpr
791 -- (matchTuple [a,b,c] body)
792 --       returns the Core term
793 --  \x. case x of (a,b,c) -> body
794 matchTuple ids body
795   = do { us <- newUniqueSupply
796        ; tup_id <- newSysLocalDs (mkBigCoreVarTupTy ids)
797        ; return (Lam tup_id $ mkTupleCase us ids body tup_id (Var tup_id)) }
798
799 -- general `rhs' >>= \pat -> stmts` desugaring where `rhs'` is already a
800 -- desugared `CoreExpr`
801 dsMcBindStmt :: LPat Id
802              -> CoreExpr        -- ^ the desugared rhs of the bind statement
803              -> SyntaxExpr Id
804              -> SyntaxExpr Id
805              -> [ExprLStmt Id]
806              -> DsM CoreExpr
807 dsMcBindStmt pat rhs' bind_op fail_op stmts
808   = do  { body     <- dsMcStmts stmts
809         ; bind_op' <- dsExpr bind_op
810         ; var      <- selectSimpleMatchVarL pat
811         ; let bind_ty = exprType bind_op'       -- rhs -> (pat -> res1) -> res2
812               res1_ty = funResultTy (funArgTy (funResultTy bind_ty))
813         ; match <- matchSinglePat (Var var) (StmtCtxt DoExpr) pat
814                                   res1_ty (cantFailMatchResult body)
815         ; match_code <- handle_failure pat match fail_op
816         ; return (mkApps bind_op' [rhs', Lam var match_code]) }
817
818   where
819     -- In a monad comprehension expression, pattern-match failure just calls
820     -- the monadic `fail` rather than throwing an exception
821     handle_failure pat match fail_op
822       | matchCanFail match
823         = do { fail_op' <- dsExpr fail_op
824              ; dflags <- getDynFlags
825              ; fail_msg <- mkStringExpr (mk_fail_msg dflags pat)
826              ; extractMatchResult match (App fail_op' fail_msg) }
827       | otherwise
828         = extractMatchResult match (error "It can't fail")
829
830     mk_fail_msg :: DynFlags -> Located e -> String
831     mk_fail_msg dflags pat
832         = "Pattern match failure in monad comprehension at " ++
833           showPpr dflags (getLoc pat)
834
835 -- Desugar nested monad comprehensions, for example in `then..` constructs
836 --    dsInnerMonadComp quals [a,b,c] ret_op
837 -- returns the desugaring of
838 --       [ (a,b,c) | quals ]
839
840 dsInnerMonadComp :: [ExprLStmt Id]
841                  -> [Id]        -- Return a tuple of these variables
842                  -> HsExpr Id   -- The monomorphic "return" operator
843                  -> DsM CoreExpr
844 dsInnerMonadComp stmts bndrs ret_op
845   = dsMcStmts (stmts ++ [noLoc (LastStmt (mkBigLHsVarTup bndrs) ret_op)])
846
847 -- The `unzip` function for `GroupStmt` in a monad comprehensions
848 --
849 --   unzip :: m (a,b,..) -> (m a,m b,..)
850 --   unzip m_tuple = ( liftM selN1 m_tuple
851 --                   , liftM selN2 m_tuple
852 --                   , .. )
853 --
854 --   mkMcUnzipM fmap ys [t1, t2]
855 --     = ( fmap (selN1 :: (t1, t2) -> t1) ys
856 --       , fmap (selN2 :: (t1, t2) -> t2) ys )
857
858 mkMcUnzipM :: TransForm
859            -> SyntaxExpr TcId   -- fmap
860            -> Id                -- Of type n (a,b,c)
861            -> [Type]            -- [a,b,c]
862            -> DsM CoreExpr      -- Of type (n a, n b, n c)
863 mkMcUnzipM ThenForm _ ys _
864   = return (Var ys) -- No unzipping to do
865
866 mkMcUnzipM _ fmap_op ys elt_tys
867   = do { fmap_op' <- dsExpr fmap_op
868        ; xs       <- mapM newSysLocalDs elt_tys
869        ; let tup_ty = mkBigCoreTupTy elt_tys
870        ; tup_xs   <- newSysLocalDs tup_ty
871
872        ; let mk_elt i = mkApps fmap_op'  -- fmap :: forall a b. (a -> b) -> n a -> n b
873                            [ Type tup_ty, Type (getNth elt_tys i)
874                            , mk_sel i, Var ys]
875
876              mk_sel n = Lam tup_xs $
877                         mkTupleSelector xs (getNth xs n) tup_xs (Var tup_xs)
878
879        ; return (mkBigCoreTup (map mk_elt [0..length elt_tys - 1])) }
880 \end{code}