Fix some bugs to do with tools in paths containing spaces
[ghc.git] / configure.ac
1 dnl == autoconf source for the Glasgow FP tools ==
2 dnl (run "grep '^dnl \*' configure.ac | sed -e 's/dnl / /g; s/\*\*/   +/g;'"
3 dnl  (or some such) to see the outline of this file)
4 dnl
5 #
6 # (c) The University of Glasgow 1994-2004
7 #
8 # Configure script template for GHC
9 #
10 # Process with 'autoreconf' to get a working configure script.
11 #
12 # For the generated configure script, do "./configure --help" to
13 # see what flags are available. (Better yet, read the documentation!)
14 #
15
16 AC_INIT([The Glorious Glasgow Haskell Compilation System], [6.13], [glasgow-haskell-bugs@haskell.org], [ghc])
17
18 # Set this to YES for a released version, otherwise NO
19 : ${RELEASE=NO}
20
21 # The primary version (e.g. 6.7, 6.6.1) is set in the AC_INIT line
22 # above.  If this is not a released version, then we will append the
23 # date to the version number (e.g. 6.7.20070204).  The date is
24 # constructed by finding the date of the most recent patch in the
25 # darcs repository.  If this is a source distribution (not a darcs
26 # checkout), then we ship a file 'VERSION' containing the full version
27 # when the source distribution was created.
28
29 if test ! -f mk/config.h.in; then
30    echo "mk/config.h.in doesn't exist: perhaps you haven't run 'sh boot'?"
31    exit 1
32 fi
33
34 AC_SUBST([CONFIGURE_ARGS], [$ac_configure_args])
35
36 dnl ----------------------------------------------------------
37 dnl ** Find unixy sort and find commands, 
38 dnl ** which are needed by FP_SETUP_PROJECT_VERSION
39
40 dnl ** Find find command (for Win32's benefit)
41 FP_PROG_FIND
42
43 dnl ** Find sort command (for the benefit of Win32 environs)
44 FP_PROG_SORT
45
46 dnl ----------------------------------------------------------
47 FP_SETUP_PROJECT_VERSION
48
49 # Hmmm, we fix the RPM release number to 1 here... Is this convenient?
50 AC_SUBST([release], [1])
51
52 # First off, a distrib sanity check..
53 AC_CONFIG_SRCDIR([mk/config.mk.in])
54
55 dnl * We require autoconf version 2.52
56 dnl We need 2.50 due to the use of AC_SYS_LARGEFILE and AC_MSG_NOTICE.
57 dnl We need 2.52 due to the use of AS_TR_CPP and AS_TR_SH.
58 AC_PREREQ([2.52])
59
60 # -------------------------------------------------------------------------
61 # Prepare to generate the following header files
62 #
63 #
64 AC_CONFIG_HEADER(mk/config.h)
65
66 # No, semi-sadly, we don't do `--srcdir'...
67 if test x"$srcdir" != 'x.' ; then
68     echo "This configuration does not support the \`--srcdir' option.."
69     exit 1
70 fi
71
72 dnl --------------------------------------------------------------
73 dnl * Project specific configuration options
74 dnl --------------------------------------------------------------
75 dnl What follows is a bunch of options that can either be configured
76 dnl through command line options to the configure script or by
77 dnl supplying defns in the build tree's mk/build.mk. Having the option to
78 dnl use either is considered a Feature.
79
80 dnl ** What command to use to compile compiler sources ?
81 dnl --------------------------------------------------------------
82
83 AC_ARG_WITH([ghc],
84 [AC_HELP_STRING([--with-ghc=ARG],
85   [Use ARG as the path to GHC  [default=autodetect]])],
86   [WithGhc="$withval"],
87   [if test "$GHC" = ""; then
88     AC_PATH_PROG([GHC], [ghc])
89   fi
90   WithGhc="$GHC"])
91
92 dnl ** Booting from .hc files?
93 dnl --------------------------------------------------------------
94 AC_ARG_ENABLE(hc-boot,
95 [AC_HELP_STRING([--enable-hc-boot],
96 [Boot the Glasgow Haskell Compiler from intermediate .hc files.
97  (This option is mostly of interest to porters.) [default=no]])],
98 [ if test x"$enableval" = x"yes"; then
99         BootingFromHc=YES
100   else
101         BootingFromHc=NO
102   fi
103 ],
104 [BootingFromHc=NO]
105 )
106 AC_SUBST(BootingFromHc)
107
108 AC_ARG_ENABLE(bootstrap-with-devel-snapshot,
109 [AC_HELP_STRING([--enable-bootstrap-with-devel-snapshot],
110                 [Allow bootstrapping using a development snapshot of GHC.  This is not guaranteed to work.])],
111         EnableBootstrapWithDevelSnaphost=YES,
112         EnableBootstrapWithDevelSnaphost=NO
113 )
114
115 if test "$WithGhc" != ""; then
116   FPTOOLS_GHC_VERSION([GhcVersion], [GhcMajVersion], [GhcMinVersion], [GhcPatchLevel])dnl
117
118   if test "$GhcMajVersion" = "unknown" -o "$GhcMinVersion" = "unknown"; then
119      AC_MSG_ERROR([Cannot determine the version of $WithGhc.  Is it really GHC?])
120   fi
121
122   AC_SUBST(GhcVersion)dnl
123   AC_SUBST(GhcMajVersion)dnl
124   AC_SUBST(GhcMinVersion)dnl
125   AC_SUBST(GhcPatchLevel)dnl
126   GhcMinVersion2=`echo "$GhcMinVersion" | sed 's/^\\(.\\)$/0\\1/'`
127   GhcCanonVersion="$GhcMajVersion$GhcMinVersion2"
128   if test $GhcCanonVersion -ge 609; then ghc_ge_609=YES; else ghc_ge_609=NO; fi
129   FP_COMPARE_VERSIONS($GhcVersion,[-ge],[6.10.2],
130                       [ghc_ge_6102=YES], [ghc_ge_6102=NO])
131   if test $GhcCanonVersion -ge 611; then ghc_ge_611=YES; else ghc_ge_611=NO; fi
132   AC_SUBST(ghc_ge_609)dnl
133   AC_SUBST(ghc_ge_6102)dnl
134   AC_SUBST(ghc_ge_611)dnl
135 fi
136
137 dnl ** Must have GHC to build GHC, unless --enable-hc-boot is on
138 if test "$BootingFromHc" = "NO" -a -d "$srcdir/compiler"; then
139   if test "$WithGhc" = ""; then
140      AC_MSG_ERROR([GHC is required unless bootstrapping from .hc files.])
141   fi
142   FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[6.8],
143     [AC_MSG_ERROR([GHC version 6.8 or later is required to compile GHC.])])dnl
144
145   if test `expr $GhcMinVersion % 2` = "1"; then
146      if test "$EnableBootstrapWithDevelSnaphost" = "NO"; then
147         AC_MSG_ERROR([
148      $WithGhc is a development snapshot of GHC, version $GhcVersion.
149      Bootstrapping using this version of GHC is not supported, and may not
150      work.  Use --enable-bootstrap-with-devel-snapshot to try it anyway,
151      or --with-ghc to specify a different GHC to use.])
152      fi
153   fi
154 fi;
155
156 # GHC is passed to Cabal, so we need a native path
157 if test "${WithGhc}" != ""
158 then
159     ghc_host=`"${WithGhc}" +RTS --info | grep 'Host platform' | sed -e 's/.*, "//' -e 's/")//'`
160
161     if test "$ghc_host" = "i386-unknown-mingw32"
162     then
163         if test "${OSTYPE}" = "msys"
164         then
165             WithGhc=`echo "${WithGhc}" | sed "s#^/\([a-zA-Z]\)/#\1:/#"`
166         else
167             # Canonicalise to <drive>:/path/to/ghc
168             WithGhc=`cygpath -m "${WithGhc}"`
169         fi
170         echo "GHC path canonicalised to: ${WithGhc}"
171     fi
172 fi
173 AC_SUBST([WithGhc])
174
175 dnl ** Without optimization some INLINE trickery fails for GHCi
176 SRC_CC_OPTS="-O"
177
178 dnl Allow to specify iconv options to the toplevel configure script
179 dnl so they can be properly passed to sub-builds.
180 dnl Note: ICONV_LIB_DIRS and ICONV_INCLUDE_DIRS are not predefined
181 dnl to the empty string to allow them to be overridden from the
182 dnl environment.
183
184 AC_ARG_WITH([iconv-includes],
185   [AC_HELP_STRING([--with-iconv-includes],
186     [directory containing iconv.h])],
187     [ICONV_INCLUDE_DIRS=$withval])
188
189 AC_ARG_WITH([iconv-libraries],
190   [AC_HELP_STRING([--with-iconv-libraries],
191     [directory containing iconv library])],
192     [ICONV_LIB_DIRS=$withval])
193
194 AC_SUBST(ICONV_INCLUDE_DIRS)
195 AC_SUBST(ICONV_LIB_DIRS)
196
197 dnl--------------------------------------------------------------------
198 dnl * Choose host(/target/build) platform
199 dnl--------------------------------------------------------------------
200 dnl We don't use the standard autoconf macros for this, but instead
201 dnl ask the bootstrapping compiler what platform it is for
202
203 dnl Guess host/target/build platform(s) if necessary.
204 m4_divert_once([HELP_CANON],
205 [[
206 System types:
207   --build=BUILD     configure for building on BUILD [guessed]
208   --host=HOST       cross-compile to build programs to run on HOST [guessed]
209   --target=TARGET   configure for building compilers for TARGET [guessed]]])dnl
210
211 if test "$build" = ""
212 then
213     if test "${WithGhc}" != ""
214     then
215         build=`"${WithGhc}" +RTS --info | grep '^ ,("Target platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
216         echo "Build platform inferred as: $build"
217     else
218         echo "Can't work out build platform"
219         exit 1
220     fi
221 fi
222
223 if test "$host" = ""
224 then
225     if test "${WithGhc}" != ""
226     then
227         host=`"${WithGhc}" +RTS --info | grep '^ ,("Target platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
228         echo "Host platform inferred as: $host"
229     else
230         echo "Can't work out host platform"
231         exit 1
232     fi
233 fi
234
235 if test "$target" = ""
236 then
237     if test "${WithGhc}" != ""
238     then
239         target=`"${WithGhc}" +RTS --info | grep '^ ,("Target platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
240         echo "Target platform inferred as: $target"
241     else
242         echo "Can't work out target platform"
243         exit 1
244     fi
245 fi
246
247 exeext=''
248 soext='.so'
249 case $host in
250 *-unknown-cygwin32)
251     AC_MSG_WARN([GHC does not support the Cygwin target at the moment])
252     AC_MSG_WARN([I'm assuming you wanted to build for i386-unknown-mingw32])
253     exit 1
254     ;;
255 *-unknown-mingw32)
256     exeext='.exe'
257     soext='.dll'
258     ;;
259 i386-apple-darwin|powerpc-apple-darwin)
260     soext='.dylib'
261     CFLAGS="$CFLAGS -m32"
262     LDFLAGS="$LDFLAGS -m32"
263     CONF_CC_OPTS="$CONF_CC_OPTS -m32"
264     CONF_LD_OPTS="$CONF_LD_OPTS -m32"
265     ;;
266 x86_64-apple-darwin)
267     soext='.dylib'
268     CFLAGS="$CFLAGS -m64"
269     LDFLAGS="$LDFLAGS -m64"
270     CONF_CC_OPTS="$CONF_CC_OPTS -m64"
271     CONF_LD_OPTS="$CONF_LD_OPTS -m64"
272     ;;
273 esac
274
275 checkArch() {
276     case $1 in
277     alpha|arm|hppa|hppa1_1|i386|ia64|m68k|mips|mipseb|mipsel|powerpc|powerpc64|rs6000|s390|sparc|sparc64|vax|x86_64)
278         ;;
279     *)
280         echo "Unknown arch $1"
281         exit 1
282         ;;
283     esac
284 }
285
286 checkVendor() {
287     case $1 in
288     dec|unknown|hp|apple|next|sun|sgi|ibm)
289         ;;
290     *)
291         echo "Unknown vendor $1"
292         exit 1
293         ;;
294     esac
295 }
296
297 checkOS() {
298     case $1 in
299     linux|freebsd|netbsd|openbsd|osf1|osf3|hpux|linuxaout|kfreebsdgnu|freebsd2|solaris2|cygwin32|mingw32|darwin|gnu|nextstep2|nextstep3|sunos4|ultrix|irix|aix)
300         ;;
301     *)
302         echo "Unknown OS '$1'"
303         exit 1
304         ;;
305     esac
306 }
307
308 BuildPlatform=$build
309 BuildArch=`echo "$build" | sed 's/-.*//'`
310 BuildVendor=`echo "$build" | sed -e 's/.*-\(.*\)-.*/\1/'`
311 BuildOS=`echo "$build" | sed 's/.*-//'`
312 BuildPlatform_CPP=`echo "$BuildPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
313 BuildArch_CPP=`    echo "$BuildArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
314 BuildVendor_CPP=`  echo "$BuildVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
315 BuildOS_CPP=`      echo "$BuildOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
316
317 checkArch "$BuildArch"
318 checkVendor "$BuildVendor"
319 checkOS "$BuildOS"
320
321 HostPlatform=$host
322 HostArch=`echo "$host" | sed 's/-.*//'`
323 HostVendor=`echo "$host" | sed -e 's/.*-\(.*\)-.*/\1/'`
324 HostOS=`echo "$host" | sed 's/.*-//'`
325 HostPlatform_CPP=`echo "$HostPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
326 HostArch_CPP=`    echo "$HostArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
327 HostVendor_CPP=`  echo "$HostVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
328 HostOS_CPP=`      echo "$HostOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
329
330 checkArch "$HostArch"
331 checkVendor "$HostVendor"
332 checkOS "$HostOS"
333
334 TargetPlatform=$target
335 TargetArch=`echo "$target" | sed 's/-.*//'`
336 TargetVendor=`echo "$target" | sed -e 's/.*-\(.*\)-.*/\1/'`
337 TargetOS=`echo "$target" | sed 's/.*-//'`
338 TargetPlatform_CPP=`echo "$TargetPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
339 TargetArch_CPP=`    echo "$TargetArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
340 TargetVendor_CPP=`  echo "$TargetVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
341 TargetOS_CPP=`      echo "$TargetOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
342
343 checkArch "$TargetArch"
344 checkVendor "$TargetVendor"
345 checkOS "$TargetOS"
346
347 AC_SUBST(BuildPlatform)
348 AC_SUBST(HostPlatform)
349 AC_SUBST(TargetPlatform)
350 AC_SUBST(HostPlatform_CPP)
351 AC_SUBST(BuildPlatform_CPP)
352 AC_SUBST(TargetPlatform_CPP)
353
354 AC_SUBST(HostArch_CPP)
355 AC_SUBST(BuildArch_CPP)
356 AC_SUBST(TargetArch_CPP)
357
358 AC_SUBST(HostOS_CPP)
359 AC_SUBST(BuildOS_CPP)
360 AC_SUBST(TargetOS_CPP)
361
362 AC_SUBST(HostVendor_CPP)
363 AC_SUBST(BuildVendor_CPP)
364 AC_SUBST(TargetVendor_CPP)
365
366 AC_SUBST(exeext)
367 AC_SUBST(soext)
368
369 AC_ARG_WITH(hc,
370 [AC_HELP_STRING([--with-hc=ARG],
371         [Use ARG as the path to the compiler for compiling ordinary
372          Haskell code  (default= value of --with-ghc)])],
373 [WithHc="$withval"],
374 [WithHc=$WithGhc]
375 )
376 AC_SUBST(WithHc)
377
378 AC_PATH_PROGS(NHC,nhc nhc98)
379 AC_PATH_PROG(HBC,hbc)
380
381 # This uses GHC, so put it after the "GHC is required" check above:
382 FP_FIND_ROOT
383
384 if test "$HostOS" = "mingw32"
385 then
386     CC="$hardtop/inplace/mingw/bin/gcc.exe"
387     LD="$hardtop/inplace/mingw/bin/ld.exe"
388     NM="$hardtop/inplace/mingw/bin/nm.exe"
389     if ! test -d inplace/mingw ||
390          test inplace/mingw -ot ghc-tarballs/mingw/binutils*.tar.gz ||
391          test inplace/mingw -ot ghc-tarballs/mingw/gcc-core*.tar.gz ||
392          test inplace/mingw -ot ghc-tarballs/mingw/libcrypt*.tar.bz2 ||
393          test inplace/mingw -ot ghc-tarballs/mingw/mingw-runtime*.tar.gz ||
394          test inplace/mingw -ot ghc-tarballs/mingw/perl*.tar.bz2 ||
395          test inplace/mingw -ot ghc-tarballs/mingw/w32api*.tar.gz
396     then
397         AC_MSG_NOTICE([Making in-tree mingw tree])
398         rm -rf inplace/mingw
399         mkdir inplace
400         mkdir inplace/mingw
401         (
402             cd inplace/mingw &&
403             tar -zxf ../../ghc-tarballs/mingw/binutils*.tar.gz &&
404             tar -zxf ../../ghc-tarballs/mingw/gcc-core*.tar.gz &&
405             tar -jxf ../../ghc-tarballs/mingw/libcrypt*.tar.bz2 &&
406             tar -zxf ../../ghc-tarballs/mingw/mingw-runtime*.tar.gz &&
407             tar -jxf ../../ghc-tarballs/mingw/perl*.tar.bz2 &&
408             tar -zxf ../../ghc-tarballs/mingw/w32api*.tar.gz &&
409             mv bin/gcc.exe bin/realgcc.exe
410         )
411         inplace/mingw/bin/realgcc.exe driver/gcc/gcc.c driver/utils/getLocation.c -Idriver/utils -o inplace/mingw/bin/gcc.exe
412         AC_MSG_NOTICE([In-tree mingw tree created])
413     fi
414 fi
415
416 dnl ** Which gcc to use?
417 dnl --------------------------------------------------------------
418 FP_ARG_WITH_PATH_GNU_PROG([CC], [gcc])
419 export CC
420 WhatGccIsCalled="$CC"
421 AC_SUBST(WhatGccIsCalled)
422
423 dnl ** Which ld to use?
424 dnl --------------------------------------------------------------
425 FP_ARG_WITH_PATH_GNU_PROG([LD], [ld])
426 LdCmd="$LD"
427 AC_SUBST([LdCmd])
428
429 dnl ** Which nm to use?
430 dnl --------------------------------------------------------------
431 FP_ARG_WITH_PATH_GNU_PROG([NM], [nm])
432 NmCmd="$NM"
433 AC_SUBST([NmCmd])
434
435 dnl ** Mac OS X: explicit deployment target
436 dnl --------------------------------------------------------------
437 AC_ARG_WITH([macosx-deployment-target],
438 [AC_HELP_STRING([--with-macosx-deployment-target=VERSION],
439         [Build for Mac OS VERSION and higher  (default= version of build host)])],
440 [FP_MACOSX_DEPLOYMENT_TARGET="$withval"
441  if test "x$TargetOS_CPP-$TargetVendor_CPP" != "xdarwin-apple"; then
442    # ignore everywhere, but on Mac OS
443    AC_MSG_WARN([--macosx-deployment-target is only available on Mac OS X])
444    FP_MACOSX_DEPLOYMENT_TARGET=none
445  fi],
446 [FP_MACOSX_DEPLOYMENT_TARGET=none]
447 )
448 FP_CHECK_MACOSX_DEPLOYMENT_TARGET
449 AC_SUBST(MACOSX_DEPLOYMENT_VERSION)
450 AC_SUBST(MACOSX_DEPLOYMENT_SDK)
451
452 dnl --------------------------------------------------------------
453 dnl End of configure script option section
454 dnl --------------------------------------------------------------
455
456
457 dnl --------------------------------------------------------------
458 dnl * General configuration checks
459 dnl --------------------------------------------------------------
460
461 dnl ** Can the unix package be built?
462 dnl --------------------------------------------------------------
463
464 if test x"$TargetPlatform" = x"i386-unknown-mingw32"; then
465    GhcLibsWithUnix=NO
466 else
467    GhcLibsWithUnix=YES
468 fi
469 AC_SUBST([GhcLibsWithUnix])
470
471 dnl ** does #! work?
472 AC_SYS_INTERPRETER()
473
474 dnl ** look for `perl', but only in /bin on Windows
475 case $HostOS_CPP in
476 cygwin32|mingw32)
477       AC_CHECK_PROG(PerlCmd,perl,/bin/perl,,/bin)
478       if test -z "$PerlCmd"; then
479          echo "You must install the version of Perl shipped with GHC"
480          echo "(or a compatible one) in /bin."
481          exit 1
482       fi
483    ;;
484 *)
485    AC_PATH_PROG(PerlCmd,perl)
486    if test -z "$PerlCmd"; then
487       echo "You must install perl before you can continue"
488       echo "Perhaps it is already installed, but not in your PATH?"
489       exit 1
490    else
491    FPTOOLS_CHECK_PERL_VERSION
492    fi
493    ;;
494 esac
495
496 dnl ** does #! path/to/perl work? (sometimes it's too long...)
497 FPTOOLS_SHEBANG_PERL
498
499 dnl ** check for Python
500 AC_PATH_PROG(PythonCmd,python)
501
502 dnl ** look for GCC and find out which version
503 dnl     Figure out which C compiler to use.  Gcc is preferred.
504 dnl     If gcc, make sure it's at least 2.1
505 dnl
506 FP_HAVE_GCC
507 FP_GCC_EXTRA_FLAGS
508
509 dnl ** figure out how to invoke cpp directly (gcc -E is no good)
510 AC_PROG_CPP
511
512 AC_SUBST(CONF_CC_OPTS)
513 AC_SUBST(CONF_LD_OPTS)
514
515 dnl ** figure out how to do context diffs
516 FP_PROG_CONTEXT_DIFF
517
518 dnl Let's make sure install-sh is executable here.  If we got it from
519 dnl a darcs repo, it might not be (see bug #978).
520 chmod +x install-sh
521 dnl ** figure out how to do a BSD-ish install
522 AC_PROG_INSTALL
523
524 dnl If you can run configure, you certainly have /bin/sh
525 AC_DEFINE([HAVE_BIN_SH], [1], [Define to 1 if you have /bin/sh.])
526
527 dnl ** how to invoke `ar' and `ranlib'
528 FP_PROG_AR_NEEDS_RANLIB
529 FP_PROG_AR_SUPPORTS_INPUT
530
531 dnl ** Check to see whether ln -s works
532 AC_PROG_LN_S
533
534
535 dnl ** Find the path to sed
536 AC_PATH_PROG(SedCmd,sed)
537
538
539 dnl ** check for time command
540 AC_PATH_PROG(TimeCmd,time)
541
542 dnl ** check for tar
543 dnl   if GNU tar is named gtar, look for it first.
544 AC_PATH_PROGS(TarCmd,gtar tar,tar)
545
546 dnl ** check for patch
547 dnl if GNU patch is named gpatch, look for it first
548 AC_PATH_PROGS(PatchCmd,gpatch patch, patch)
549
550 AC_PATH_PROG(HSCOLOUR,HsColour)
551 # HsColour is passed to Cabal, so we need a native path
552 if test "x$HostPlatform"  = "xi386-unknown-mingw32" && \
553    test "${OSTYPE}"      != "msys"                  && \
554    test "${HSCOLOUR}"    != ""
555 then
556     # Canonicalise to <drive>:/path/to/gcc
557     HSCOLOUR=`cygpath -m ${HSCOLOUR}`
558 fi
559
560 dnl ** check for DocBook toolchain
561 FP_CHECK_DOCBOOK_DTD
562 FP_DOCBOOK_XSL
563 FP_PROG_DBLATEX
564
565 FP_PROG_HSTAGS
566
567 dnl ** check for ghc-pkg command
568 FP_PROG_GHC_PKG
569
570 dnl ** check for installed happy binary + version
571 dnl    (don't do it if we're booting from .hc files though.)
572 if test "$BootingFromHc" = "NO"; then
573 FPTOOLS_HAPPY
574 fi;
575
576 dnl ** check for installed alex binary + version
577 dnl    (don't do it if we're booting from .hc files though.)
578 if test "$BootingFromHc" = "NO"; then
579 FPTOOLS_ALEX
580 fi;
581
582 dnl --------------------------------------------------
583 dnl ### program checking section ends here ###
584 dnl --------------------------------------------------
585
586 dnl --------------------------------------------------
587 dnl * Platform header file and syscall feature tests
588 dnl ### checking the state of the local header files and syscalls ###
589
590 dnl ** check for full ANSI header (.h) files
591 AC_HEADER_STDC
592
593 dnl ** Enable large file support.  NB. do this before testing the type of
594 dnl    off_t, because it will affect the result of that test.
595 AC_SYS_LARGEFILE
596
597 dnl ** check for specific header (.h) files that we are interested in
598 AC_CHECK_HEADERS([bfd.h ctype.h dirent.h dlfcn.h errno.h fcntl.h grp.h limits.h locale.h nlist.h pthread.h pwd.h signal.h sys/mman.h sys/resource.h sys/time.h sys/timeb.h sys/timers.h sys/times.h sys/utsname.h sys/wait.h termios.h time.h utime.h windows.h winsock.h sched.h])
599
600 dnl ** check if it is safe to include both <time.h> and <sys/time.h>
601 AC_HEADER_TIME
602
603 dnl ** do we have long longs?
604 AC_CHECK_TYPES([long long])
605
606 dnl ** what are the sizes of various types
607 AC_CHECK_SIZEOF(char,               1)
608 AC_CHECK_SIZEOF(double,             8)
609 AC_CHECK_SIZEOF(float,              4)
610 AC_CHECK_SIZEOF(int,                4)
611 AC_CHECK_SIZEOF(long,               4)
612 if test "$ac_cv_type_long_long" = yes; then
613 AC_CHECK_SIZEOF(long long,          8)
614 fi
615 AC_CHECK_SIZEOF(short,              2)
616 AC_CHECK_SIZEOF(unsigned char,      1)
617 AC_CHECK_SIZEOF(unsigned int,       4)
618 AC_CHECK_SIZEOF(unsigned long,      4)
619 if test "$ac_cv_type_long_long" = yes; then
620 AC_CHECK_SIZEOF(unsigned long long, 8)
621 fi
622 AC_CHECK_SIZEOF(unsigned short,     2)
623 AC_CHECK_SIZEOF(void *,             4)
624
625 dnl ** what are alignment constraints on various types
626 FP_CHECK_ALIGNMENT(char)
627 FP_CHECK_ALIGNMENT(double)
628 FP_CHECK_ALIGNMENT(float)
629 FP_CHECK_ALIGNMENT(int)
630 FP_CHECK_ALIGNMENT(long)
631 if test "$ac_cv_type_long_long" = yes; then
632 FP_CHECK_ALIGNMENT(long long)
633 fi
634 FP_CHECK_ALIGNMENT(short)
635 FP_CHECK_ALIGNMENT(unsigned char)
636 FP_CHECK_ALIGNMENT(unsigned int)
637 FP_CHECK_ALIGNMENT(unsigned long)
638 if test "$ac_cv_type_long_long" = yes; then
639 FP_CHECK_ALIGNMENT(unsigned long long)
640 fi
641 FP_CHECK_ALIGNMENT(unsigned short)
642 FP_CHECK_ALIGNMENT(void *)
643
644 FP_CHECK_FUNC([WinExec],
645   [@%:@include <windows.h>], [WinExec("",0)])
646
647 FP_CHECK_FUNC([GetModuleFileName],
648   [@%:@include <windows.h>], [GetModuleFileName((HMODULE)0,(LPTSTR)0,0)])
649
650 dnl ** check return type of signal handlers
651 dnl Foo: assumes we can use prototypes.
652 dnl On BCC, signal handlers have type "int(void)", elsewhere its "void(int)".
653 dnl AC_CACHE_CHECK([type of signal handlers], ac_cv_type_signal_handler,
654 dnl [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
655 dnl #include <signal.h>
656 dnl #ifdef signal
657 dnl #undef signal
658 dnl #endif
659 dnl void (*signal (int, void (*)(int)))(int);
660 dnl ]],
661 dnl [[int i;]])],
662 dnl [ac_cv_type_signal_handler=void_int],
663 dnl [ac_cv_type_signal_handler=int_void])])
664 dnl if test "$ac_cv_type_signal_handler" = void_int; then
665 dnl AC_DEFINE(VOID_INT_SIGNALS)
666 dnl fi
667
668 dnl On BCC, signal handlers have type "int(void)", elsewhere its "void(int)".
669 AC_TYPE_SIGNAL
670 if test "$ac_cv_type_signal" = void; then
671   AC_DEFINE([VOID_INT_SIGNALS], [1], [Define to 1 if signal handlers have type void (*)(int). Otherwise, they're assumed to have type int (*)(void).])
672 fi
673
674 dnl ** check for more functions
675 dnl ** The following have been verified to be used in ghc/, but might be used somewhere else, too.
676 AC_CHECK_FUNCS([getclock getrusage gettimeofday setitimer siginterrupt sysconf times ctime_r sched_setaffinity setlocale])
677
678 AC_TRY_RUN([
679 #include <sys/types.h>
680 #include <sys/time.h>
681 int main(void) {
682   struct itimerval tval;
683   tval.it_value.tv_sec = 1;
684   tval.it_value.tv_usec = 0;
685   tval.it_interval = tval.it_value;
686   return setitimer(ITIMER_VIRTUAL, &tval, (void*)0) != 0;
687 }
688 ],[AC_DEFINE([HAVE_SETITIMER_VIRTUAL], [1], [Define to 1 if setitimer accepts ITIMER_VIRTUAL, 0 else.])])
689
690 dnl ** On OS X 10.4 (at least), time.h doesn't declare ctime_r if
691 dnl ** _POSIX_C_SOURCE is defined
692 AC_CHECK_DECLS([ctime_r], , ,
693 [#define _POSIX_SOURCE 1
694 #define _POSIX_C_SOURCE 199506L
695 #include <time.h>])
696
697 dnl ** check for mingwex library
698 AC_CHECK_LIB(mingwex, closedir, HaveLibMingwEx=YES, HaveLibMingwEx=NO)
699 AC_SUBST(HaveLibMingwEx)
700
701 if test $HaveLibMingwEx = YES ; then
702   AC_DEFINE([HAVE_MINGWEX], [1], [Define to 1 if you have the mingwex library.])
703 fi
704
705 dnl ** check whether this machine has BFD and liberty installed (used for debugging)
706 dnl    the order of these tests matters: bfd needs liberty
707 AC_CHECK_LIB(iberty, xmalloc)
708 AC_CHECK_LIB(bfd,    bfd_init)
709
710 dnl ** check for math library
711 AC_CHECK_FUNC(atan,[fp_libm_not_needed=yes;LIBM=],[fp_libm_not_needed=dunno])
712 if test x"$fp_libm_not_needed" = xdunno; then
713    AC_CHECK_LIB([m], [atan], [LIBS="-lm $LIBS"; LIBM="-lm"],[LIBM=])
714 fi
715 AC_SUBST([LIBM])
716
717 dnl ################################################################
718 dnl Check for libraries
719 dnl ################################################################
720
721 dnl ** check whether we need -ldl to get dlopen()
722
723 AC_CHECK_LIB(dl, dlopen,
724     [HaveLibDL=YES
725      AC_DEFINE([HAVE_LIBDL], [1], [Define to 1 if you need -ldl to get dlopen().])
726      LIBS="$LIBS -ldl"],
727     [HaveLibDL=NO])
728 AC_SUBST(HaveLibDL)
729
730 dnl --------------------------------------------------
731 dnl * Miscellaneous feature tests
732 dnl --------------------------------------------------
733
734 dnl ** can we get alloca?
735 AC_FUNC_ALLOCA
736
737 dnl ** Working vfork?
738 AC_FUNC_FORK
739
740 dnl ** determine whether or not const works
741 AC_C_CONST
742
743 dnl ** are we big endian?
744 AC_C_BIGENDIAN
745 FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN
746
747 dnl ** check for leading underscores in symbol names
748 FP_LEADING_UNDERSCORE
749
750 dnl ** check for ld, whether it has an -x option, and if it is GNU ld
751 FP_PROG_LD_X
752 FP_PROG_LD_IS_GNU
753
754 dnl ** check for Apple-style dead-stripping support
755 dnl    (.subsections-via-symbols assembler directive)
756
757
758 AC_MSG_CHECKING(for .subsections_via_symbols)
759 AC_COMPILE_IFELSE(
760     [AC_LANG_PROGRAM([], [__asm__ (".subsections_via_symbols");])],
761     [AC_MSG_RESULT(yes)
762      AC_DEFINE([HAVE_SUBSECTIONS_VIA_SYMBOLS],[1],
763                [Define to 1 if Apple-style dead-stripping is supported.])
764     ],
765     [AC_MSG_RESULT(no)])
766
767 dnl *** check for GNU non-executable stack note support (ELF only)
768 dnl     (.section .note.GNU-stack,"",@progbits)
769
770 AC_MSG_CHECKING(for GNU non-executable stack support)
771 AC_COMPILE_IFELSE(
772     [AC_LANG_PROGRAM([__asm__ (".section .note.GNU-stack,\"\",@progbits");], [0])],
773     [AC_MSG_RESULT(yes)
774      AC_DEFINE([HAVE_GNU_NONEXEC_STACK],[1],
775                [Define to 1 if GNU non-executable stack notes are supported.])
776     ],
777     [AC_MSG_RESULT(no)])
778
779 dnl ** check for librt
780 AC_CHECK_LIB(rt, clock_gettime)
781 AC_CHECK_FUNCS(clock_gettime timer_create timer_settime)
782 FP_CHECK_TIMER_CREATE
783
784 dnl ** check for Apple's "interesting" long double compatibility scheme
785 AC_MSG_CHECKING(for printf\$LDBLStub)
786 AC_TRY_LINK_FUNC(printf\$LDBLStub,
787     [
788         AC_MSG_RESULT(yes)
789         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[1],
790             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
791     ],
792     [
793         AC_MSG_RESULT(no)
794         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[0],
795             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
796     ])
797
798 # test for GTK+
799 AC_PATH_PROGS([GTK_CONFIG], [pkg-config])
800 if test -n "$GTK_CONFIG"; then
801   if $GTK_CONFIG gtk+-2.0 --atleast-version=2.0; then
802     GTK_CONFIG="$GTK_CONFIG gtk+-2.0"
803   else
804     AC_MSG_WARN([GTK+ not usable, need at least version 2.0])
805     GTK_CONFIG=
806   fi
807 fi
808 AC_SUBST([GTK_CONFIG])
809
810 #Checking for PAPI
811 AC_CHECK_LIB(papi, PAPI_library_init, HavePapiLib=YES, HavePapiLib=NO)
812 AC_CHECK_HEADER([papi.h], [HavePapiHeader=YES], [HavePapiHeader=NO])
813 AC_SUBST(HavePapiLib)
814 AC_SUBST(HavePapiHeader)
815
816 AC_CHECK_FUNCS(__mingw_vfprintf)
817
818 if test "$HavePapiLib" = "YES" -a "$HavePapiHeader" = "YES"; then
819    HavePapi=YES
820 else
821    HavePapi=NO
822 fi
823 AC_SUBST(HavePapi)
824
825 if test "$HAVE_DOCBOOK_XSL" = "NO" ||
826    test "$XsltprocCmd" = ""
827 then
828     BUILD_DOCBOOK_HTML=NO
829 else
830     BUILD_DOCBOOK_HTML=YES
831 fi
832 AC_SUBST(BUILD_DOCBOOK_HTML)
833
834 if test "$DblatexCmd" = ""
835 then
836     BUILD_DOCBOOK_PS=NO
837     BUILD_DOCBOOK_PDF=NO
838 else
839     BUILD_DOCBOOK_PS=YES
840     BUILD_DOCBOOK_PDF=YES
841 fi
842 AC_SUBST(BUILD_DOCBOOK_PS)
843 AC_SUBST(BUILD_DOCBOOK_PDF)
844
845 if grep '       ' compiler/ghc.cabal.in 2>&1 >/dev/null; then
846    AC_MSG_ERROR([compiler/ghc.cabal.in contains tab characters; please remove them])
847 fi
848
849 AC_CONFIG_FILES([mk/config.mk mk/install.mk mk/project.mk compiler/ghc.cabal ghc/ghc-bin.cabal ghc.spec extra-gcc-opts docs/users_guide/ug-book.xml distrib/ghc.iss distrib/configure-bin.ac])
850 AC_CONFIG_COMMANDS([mk/stamp-h],[echo timestamp > mk/stamp-h])
851 AC_OUTPUT
852
853 # We get caught by
854 #     http://savannah.gnu.org/bugs/index.php?1516
855 #     $(eval ...) inside conditionals causes errors
856 # with make 3.80, so warn the user if it looks like they're about to
857 # try to use it.
858 # We would use "grep -q" here, but Solaris's grep doesn't support it.
859 checkMake380() {
860     if $1 --version 2>&1 | head -1 | grep 'GNU Make 3\.80' > /dev/null
861     then
862         echo
863         echo "WARNING: It looks like \"$1\" is GNU make 3.80."
864         echo "This version cannot be used to build GHC."
865         echo "Please use GNU make >= 3.81."
866     fi
867 }
868
869 checkMake380 make
870 checkMake380 gmake
871
872 echo ["
873 ----------------------------------------------------------------------
874 Configure completed successfully.
875
876    Building GHC version  : $ProjectVersion
877
878    Build platform        : $BuildPlatform
879    Host platform         : $HostPlatform
880    Target platform       : $TargetPlatform
881 "]
882
883 if test "$BootingFromHc" = "YES"; then
884 echo ["\
885    Bootstrapping from HC files.
886 "]
887 else
888 echo ["\
889    Bootstrapping using   : $WithGhc
890       which is version   : $GhcVersion
891 "]
892 fi
893
894 echo ["\
895    Using GCC             : $WhatGccIsCalled
896       which is version   : $GccVersion
897
898    ld       : $LdCmd
899    Happy    : $HappyCmd ($HappyVersion)
900    Alex     : $AlexCmd ($AlexVersion)
901    Python   : $PythonCmd
902    Perl     : $PerlCmd
903    dblatex  : $DblatexCmd
904    xsltproc : $XsltprocCmd"]
905
906 if test "$HSCOLOUR" = ""; then
907 echo ["
908    HsColour was not found; documentation will not contain source links
909 "]
910 else
911 echo ["\
912    HsColour : $HSCOLOUR
913 "]
914 fi
915
916 echo ["\
917    Building DocBook HTML documentation : $BUILD_DOCBOOK_HTML
918    Building DocBook PS documentation   : $BUILD_DOCBOOK_PS
919    Building DocBook PDF documentation  : $BUILD_DOCBOOK_PDF"]
920
921 echo ["----------------------------------------------------------------------
922 "]
923
924 echo "\
925 For a standard build of GHC (fully optimised with profiling), type (g)make.
926
927 To make changes to the default build configuration, copy the file
928 mk/build.mk.sample to mk/build.mk, and edit the settings in there.
929
930 For more information on how to configure your GHC build, see
931    http://hackage.haskell.org/trac/ghc/wiki/Building
932 "