Robustify the treatement of DFunUnfolding
[ghc.git] / compiler / main / TidyPgm.lhs
1
2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
3 %
4 \section{Tidying up Core}
5
6 \begin{code}
7 module TidyPgm( mkBootModDetailsDs, mkBootModDetailsTc, 
8                 tidyProgram, globaliseAndTidyId ) where
9
10 #include "HsVersions.h"
11
12 import TcRnTypes
13 import FamInstEnv
14 import DynFlags
15 import CoreSyn
16 import CoreUnfold
17 import CoreFVs
18 import CoreTidy
19 import CoreMonad
20 import CoreUtils
21 import Rules
22 import CoreArity        ( exprArity, exprBotStrictness_maybe )
23 import Class            ( classSelIds )
24 import VarEnv
25 import VarSet
26 import Var
27 import Id
28 import IdInfo
29 import InstEnv
30 import Demand
31 import BasicTypes
32 import Name hiding (varName)
33 import NameSet
34 import IfaceEnv
35 import NameEnv
36 import TcType
37 import DataCon
38 import TyCon
39 import Module
40 import HscTypes
41 import Maybes
42 import UniqSupply
43 import Outputable
44 import FastBool hiding ( fastOr )
45 import Util
46 import FastString
47
48 import Data.List        ( sortBy )
49 import Data.IORef       ( IORef, readIORef, writeIORef )
50 \end{code}
51
52
53 Constructing the TypeEnv, Instances, Rules, VectInfo from which the
54 ModIface is constructed, and which goes on to subsequent modules in
55 --make mode.
56
57 Most of the interface file is obtained simply by serialising the
58 TypeEnv.  One important consequence is that if the *interface file*
59 has pragma info if and only if the final TypeEnv does. This is not so
60 important for *this* module, but it's essential for ghc --make:
61 subsequent compilations must not see (e.g.) the arity if the interface
62 file does not contain arity If they do, they'll exploit the arity;
63 then the arity might change, but the iface file doesn't change =>
64 recompilation does not happen => disaster. 
65
66 For data types, the final TypeEnv will have a TyThing for the TyCon,
67 plus one for each DataCon; the interface file will contain just one
68 data type declaration, but it is de-serialised back into a collection
69 of TyThings.
70
71 %************************************************************************
72 %*                                                                      *
73                 Plan A: simpleTidyPgm
74 %*                                                                      * 
75 %************************************************************************
76
77
78 Plan A: mkBootModDetails: omit pragmas, make interfaces small
79 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
80 * Ignore the bindings
81
82 * Drop all WiredIn things from the TypeEnv 
83         (we never want them in interface files)
84
85 * Retain all TyCons and Classes in the TypeEnv, to avoid
86         having to find which ones are mentioned in the
87         types of exported Ids
88
89 * Trim off the constructors of non-exported TyCons, both
90         from the TyCon and from the TypeEnv
91
92 * Drop non-exported Ids from the TypeEnv
93
94 * Tidy the types of the DFunIds of Instances, 
95   make them into GlobalIds, (they already have External Names)
96   and add them to the TypeEnv
97
98 * Tidy the types of the (exported) Ids in the TypeEnv,
99   make them into GlobalIds (they already have External Names)
100
101 * Drop rules altogether
102
103 * Tidy the bindings, to ensure that the Caf and Arity
104   information is correct for each top-level binder; the 
105   code generator needs it. And to ensure that local names have
106   distinct OccNames in case of object-file splitting
107
108 \begin{code}
109 -- This is Plan A: make a small type env when typechecking only,
110 -- or when compiling a hs-boot file, or simply when not using -O
111 --
112 -- We don't look at the bindings at all -- there aren't any
113 -- for hs-boot files
114
115 mkBootModDetailsTc :: HscEnv -> TcGblEnv -> IO ModDetails
116 mkBootModDetailsTc hsc_env 
117         TcGblEnv{ tcg_exports   = exports,
118                   tcg_type_env  = type_env,
119                   tcg_insts     = insts,
120                   tcg_fam_insts = fam_insts
121                 }
122   = mkBootModDetails hsc_env exports type_env insts fam_insts
123
124 mkBootModDetailsDs :: HscEnv -> ModGuts -> IO ModDetails
125 mkBootModDetailsDs hsc_env 
126         ModGuts{ mg_exports   = exports,
127                  mg_types     = type_env,
128                  mg_insts     = insts,
129                  mg_fam_insts = fam_insts
130                 }
131   = mkBootModDetails hsc_env exports type_env insts fam_insts
132   
133 mkBootModDetails :: HscEnv -> [AvailInfo] -> NameEnv TyThing
134                  -> [Instance] -> [FamInstEnv.FamInst] -> IO ModDetails
135 mkBootModDetails hsc_env exports type_env insts fam_insts
136   = do  { let dflags = hsc_dflags hsc_env 
137         ; showPass dflags CoreTidy
138
139         ; let { insts'     = tidyInstances globaliseAndTidyId insts
140               ; dfun_ids   = map instanceDFunId insts'
141               ; type_env1  = tidyBootTypeEnv (availsToNameSet exports) type_env
142               ; type_env'  = extendTypeEnvWithIds type_env1 dfun_ids
143               }
144         ; return (ModDetails { md_types     = type_env'
145                              , md_insts     = insts'
146                              , md_fam_insts = fam_insts
147                              , md_rules     = []
148                              , md_anns      = []
149                              , md_exports   = exports
150                              , md_vect_info = noVectInfo
151                              })
152         }
153   where
154
155 tidyBootTypeEnv :: NameSet -> TypeEnv -> TypeEnv
156 tidyBootTypeEnv exports type_env 
157   = tidyTypeEnv True False exports type_env final_ids
158   where
159         -- Find the LocalIds in the type env that are exported
160         -- Make them into GlobalIds, and tidy their types
161         --
162         -- It's very important to remove the non-exported ones
163         -- because we don't tidy the OccNames, and if we don't remove
164         -- the non-exported ones we'll get many things with the
165         -- same name in the interface file, giving chaos.
166     final_ids = [ globaliseAndTidyId id
167                 | id <- typeEnvIds type_env
168                 , isLocalId id
169                 , keep_it id ]
170
171         -- default methods have their export flag set, but everything
172         -- else doesn't (yet), because this is pre-desugaring, so we
173         -- must test both.
174     keep_it id = isExportedId id || idName id `elemNameSet` exports
175
176
177
178 globaliseAndTidyId :: Id -> Id
179 -- Takes an LocalId with an External Name, 
180 -- makes it into a GlobalId 
181 --     * unchanged Name (might be Internal or External)
182 --     * unchanged details
183 --     * VanillaIdInfo (makes a conservative assumption about Caf-hood)
184 globaliseAndTidyId id   
185   = Id.setIdType (globaliseId id) tidy_type
186   where
187     tidy_type = tidyTopType (idType id)
188 \end{code}
189
190
191 %************************************************************************
192 %*                                                                      *
193         Plan B: tidy bindings, make TypeEnv full of IdInfo
194 %*                                                                      * 
195 %************************************************************************
196
197 Plan B: include pragmas, make interfaces 
198 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
199 * Figure out which Ids are externally visible
200
201 * Tidy the bindings, externalising appropriate Ids
202
203 * Drop all Ids from the TypeEnv, and add all the External Ids from 
204   the bindings.  (This adds their IdInfo to the TypeEnv; and adds
205   floated-out Ids that weren't even in the TypeEnv before.)
206
207 Step 1: Figure out external Ids
208 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
209 Note [choosing external names]
210
211 See also the section "Interface stability" in the
212 RecompilationAvoidance commentary:
213   http://hackage.haskell.org/trac/ghc/wiki/Commentary/Compiler/RecompilationAvoidance
214
215 First we figure out which Ids are "external" Ids.  An
216 "external" Id is one that is visible from outside the compilation
217 unit.  These are
218         a) the user exported ones
219         b) ones mentioned in the unfoldings, workers, 
220            or rules of externally-visible ones 
221
222 While figuring out which Ids are external, we pick a "tidy" OccName
223 for each one.  That is, we make its OccName distinct from the other
224 external OccNames in this module, so that in interface files and
225 object code we can refer to it unambiguously by its OccName.  The
226 OccName for each binder is prefixed by the name of the exported Id
227 that references it; e.g. if "f" references "x" in its unfolding, then
228 "x" is renamed to "f_x".  This helps distinguish the different "x"s
229 from each other, and means that if "f" is later removed, things that
230 depend on the other "x"s will not need to be recompiled.  Of course,
231 if there are multiple "f_x"s, then we have to disambiguate somehow; we
232 use "f_x0", "f_x1" etc.
233
234 As far as possible we should assign names in a deterministic fashion.
235 Each time this module is compiled with the same options, we should end
236 up with the same set of external names with the same types.  That is,
237 the ABI hash in the interface should not change.  This turns out to be
238 quite tricky, since the order of the bindings going into the tidy
239 phase is already non-deterministic, as it is based on the ordering of
240 Uniques, which are assigned unpredictably.
241
242 To name things in a stable way, we do a depth-first-search of the
243 bindings, starting from the exports sorted by name.  This way, as long
244 as the bindings themselves are deterministic (they sometimes aren't!),
245 the order in which they are presented to the tidying phase does not
246 affect the names we assign.
247
248 Step 2: Tidy the program
249 ~~~~~~~~~~~~~~~~~~~~~~~~
250 Next we traverse the bindings top to bottom.  For each *top-level*
251 binder
252
253  1. Make it into a GlobalId; its IdDetails becomes VanillaGlobal, 
254     reflecting the fact that from now on we regard it as a global, 
255     not local, Id
256
257  2. Give it a system-wide Unique.
258     [Even non-exported things need system-wide Uniques because the
259     byte-code generator builds a single Name->BCO symbol table.]
260
261     We use the NameCache kept in the HscEnv as the
262     source of such system-wide uniques.
263
264     For external Ids, use the original-name cache in the NameCache
265     to ensure that the unique assigned is the same as the Id had 
266     in any previous compilation run.
267
268  3. Rename top-level Ids according to the names we chose in step 1.
269     If it's an external Id, make it have a External Name, otherwise
270     make it have an Internal Name.  This is used by the code generator
271     to decide whether to make the label externally visible
272
273  4. Give it its UTTERLY FINAL IdInfo; in ptic, 
274         * its unfolding, if it should have one
275         
276         * its arity, computed from the number of visible lambdas
277
278         * its CAF info, computed from what is free in its RHS
279
280                 
281 Finally, substitute these new top-level binders consistently
282 throughout, including in unfoldings.  We also tidy binders in
283 RHSs, so that they print nicely in interfaces.
284
285 \begin{code}
286 tidyProgram :: HscEnv -> ModGuts -> IO (CgGuts, ModDetails)
287 tidyProgram hsc_env  (ModGuts { mg_module = mod, mg_exports = exports, 
288                                 mg_types = type_env, 
289                                 mg_insts = insts, mg_fam_insts = fam_insts,
290                                 mg_binds = binds, 
291                                 mg_rules = imp_rules,
292                                 mg_vect_info = vect_info,
293                                 mg_dir_imps = dir_imps, 
294                                 mg_anns = anns,
295                                 mg_deps = deps, 
296                                 mg_foreign = foreign_stubs,
297                                 mg_hpc_info = hpc_info,
298                                 mg_modBreaks = modBreaks })
299
300   = do  { let { dflags     = hsc_dflags hsc_env
301               ; omit_prags = dopt Opt_OmitInterfacePragmas dflags
302               ; expose_all = dopt Opt_ExposeAllUnfoldings  dflags
303               ; th         = dopt Opt_TemplateHaskell      dflags
304               }
305         ; showPass dflags CoreTidy
306
307         ; let { implicit_binds = getImplicitBinds type_env }
308
309         ; (unfold_env, tidy_occ_env)
310               <- chooseExternalIds hsc_env mod omit_prags expose_all 
311                                    binds implicit_binds imp_rules
312
313         ; let { ext_rules = findExternalRules omit_prags binds imp_rules unfold_env }
314                 -- Glom together imp_rules and rules currently attached to binders
315                 -- Then pick just the ones we need to expose
316                 -- See Note [Which rules to expose]
317
318         ; let { (tidy_env, tidy_binds)
319                  = tidyTopBinds hsc_env unfold_env tidy_occ_env binds }
320
321         ; let { export_set = availsToNameSet exports
322               ; final_ids  = [ id | id <- bindersOfBinds tidy_binds, 
323                                     isExternalName (idName id)]
324               ; tidy_type_env = tidyTypeEnv omit_prags th export_set
325                                             type_env final_ids
326               ; tidy_insts    = tidyInstances (lookup_dfun tidy_type_env) insts
327                 -- A DFunId will have a binding in tidy_binds, and so
328                 -- will now be in final_env, replete with IdInfo
329                 -- Its name will be unchanged since it was born, but
330                 -- we want Global, IdInfo-rich (or not) DFunId in the
331                 -- tidy_insts
332
333               ; tidy_rules = tidyRules tidy_env ext_rules
334                 -- You might worry that the tidy_env contains IdInfo-rich stuff
335                 -- and indeed it does, but if omit_prags is on, ext_rules is
336                 -- empty
337
338               ; tidy_vect_info = tidyVectInfo tidy_env vect_info
339
340               -- See Note [Injecting implicit bindings]
341               ; all_tidy_binds = implicit_binds ++ tidy_binds
342
343               ; alg_tycons = filter isAlgTyCon (typeEnvTyCons type_env)
344               }
345
346         ; endPass dflags CoreTidy all_tidy_binds tidy_rules
347
348           -- If the endPass didn't print the rules, but ddump-rules is on, print now
349         ; dumpIfSet (dopt Opt_D_dump_rules dflags 
350                      && (not (dopt Opt_D_dump_simpl dflags))) 
351                     CoreTidy
352                     (ptext (sLit "rules"))
353                     (pprRulesForUser tidy_rules)
354
355         ; let dir_imp_mods = moduleEnvKeys dir_imps
356
357         ; return (CgGuts { cg_module   = mod, 
358                            cg_tycons   = alg_tycons,
359                            cg_binds    = all_tidy_binds,
360                            cg_dir_imps = dir_imp_mods,
361                            cg_foreign  = foreign_stubs,
362                            cg_dep_pkgs = dep_pkgs deps,
363                            cg_hpc_info = hpc_info,
364                            cg_modBreaks = modBreaks }, 
365
366                    ModDetails { md_types     = tidy_type_env,
367                                 md_rules     = tidy_rules,
368                                 md_insts     = tidy_insts,
369                                 md_vect_info = tidy_vect_info,
370                                 md_fam_insts = fam_insts,
371                                 md_exports   = exports,
372                                 md_anns      = anns      -- are already tidy
373                               })
374         }
375
376 lookup_dfun :: TypeEnv -> Var -> Id
377 lookup_dfun type_env dfun_id
378   = case lookupTypeEnv type_env (idName dfun_id) of
379         Just (AnId dfun_id') -> dfun_id'
380         _other -> pprPanic "lookup_dfun" (ppr dfun_id)
381
382 --------------------------
383 tidyTypeEnv :: Bool     -- Compiling without -O, so omit prags
384             -> Bool     -- Template Haskell is on
385             -> NameSet -> TypeEnv -> [Id] -> TypeEnv
386
387 -- The competed type environment is gotten from
388 --      Dropping any wired-in things, and then
389 --      a) keeping the types and classes
390 --      b) removing all Ids, 
391 --      c) adding Ids with correct IdInfo, including unfoldings,
392 --              gotten from the bindings
393 -- From (c) we keep only those Ids with External names;
394 --          the CoreTidy pass makes sure these are all and only
395 --          the externally-accessible ones
396 -- This truncates the type environment to include only the 
397 -- exported Ids and things needed from them, which saves space
398
399 tidyTypeEnv omit_prags th exports type_env final_ids
400  = let  type_env1 = filterNameEnv keep_it type_env
401         type_env2 = extendTypeEnvWithIds type_env1 final_ids
402         type_env3 | omit_prags = mapNameEnv (trimThing th exports) type_env2
403                   | otherwise  = type_env2
404     in 
405     type_env3
406   where
407         -- We keep GlobalIds, because they won't appear 
408         -- in the bindings from which final_ids are derived!
409         -- (The bindings bind LocalIds.)
410     keep_it thing | isWiredInThing thing = False
411     keep_it (AnId id) = isGlobalId id   -- Keep GlobalIds (e.g. class ops)
412     keep_it _other    = True            -- Keep all TyCons, DataCons, and Classes
413
414 --------------------------
415 isWiredInThing :: TyThing -> Bool
416 isWiredInThing thing = isWiredInName (getName thing)
417
418 --------------------------
419 trimThing :: Bool -> NameSet -> TyThing -> TyThing
420 -- Trim off inessentials, for boot files and no -O
421 trimThing th exports (ATyCon tc)
422    | not th && not (mustExposeTyCon exports tc)
423    = ATyCon (makeTyConAbstract tc)      -- Note [Trimming and Template Haskell]
424
425 trimThing _th _exports (AnId id)
426    | not (isImplicitId id) 
427    = AnId (id `setIdInfo` vanillaIdInfo)
428
429 trimThing _th _exports other_thing 
430   = other_thing
431
432
433 {- Note [Trimming and Template Haskell]
434    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
435 Consider (Trac #2386) this
436         module M(T, makeOne) where
437           data T = Yay String
438           makeOne = [| Yay "Yep" |]
439 Notice that T is exported abstractly, but makeOne effectively exports it too!
440 A module that splices in $(makeOne) will then look for a declartion of Yay,
441 so it'd better be there.  Hence, brutally but simply, we switch off type
442 constructor trimming if TH is enabled in this module. -}
443
444
445 mustExposeTyCon :: NameSet      -- Exports
446                 -> TyCon        -- The tycon
447                 -> Bool         -- Can its rep be hidden?
448 -- We are compiling without -O, and thus trying to write as little as 
449 -- possible into the interface file.  But we must expose the details of
450 -- any data types whose constructors or fields are exported
451 mustExposeTyCon exports tc
452   | not (isAlgTyCon tc)         -- Synonyms
453   = True
454   | isEnumerationTyCon tc       -- For an enumeration, exposing the constructors
455   = True                        -- won't lead to the need for further exposure
456                                 -- (This includes data types with no constructors.)
457   | isOpenTyCon tc              -- Open type family
458   = True
459
460   | otherwise                   -- Newtype, datatype
461   = any exported_con (tyConDataCons tc)
462         -- Expose rep if any datacon or field is exported
463
464   || (isNewTyCon tc && isFFITy (snd (newTyConRhs tc)))
465         -- Expose the rep for newtypes if the rep is an FFI type.  
466         -- For a very annoying reason.  'Foreign import' is meant to
467         -- be able to look through newtypes transparently, but it
468         -- can only do that if it can "see" the newtype representation
469   where
470     exported_con con = any (`elemNameSet` exports) 
471                            (dataConName con : dataConFieldLabels con)
472
473 tidyInstances :: (DFunId -> DFunId) -> [Instance] -> [Instance]
474 tidyInstances tidy_dfun ispecs
475   = map tidy ispecs
476   where
477     tidy ispec = setInstanceDFunId ispec $
478                  tidy_dfun (instanceDFunId ispec)
479 \end{code}
480
481 \begin{code}
482 tidyVectInfo :: TidyEnv -> VectInfo -> VectInfo
483 tidyVectInfo (_, var_env) info@(VectInfo { vectInfoVar     = vars
484                                          , vectInfoPADFun  = pas
485                                          , vectInfoIso     = isos })
486   = info { vectInfoVar    = tidy_vars
487          , vectInfoPADFun = tidy_pas
488          , vectInfoIso    = tidy_isos }
489   where
490     tidy_vars = mkVarEnv
491               $ map tidy_var_mapping
492               $ varEnvElts vars
493
494     tidy_pas = mapNameEnv tidy_snd_var pas
495     tidy_isos = mapNameEnv tidy_snd_var isos
496
497     tidy_var_mapping (from, to) = (from', (from', lookup_var to))
498       where from' = lookup_var from
499     tidy_snd_var (x, var) = (x, lookup_var var)
500       
501     lookup_var var = lookupWithDefaultVarEnv var_env var var
502 \end{code}
503
504
505 %************************************************************************
506 %*                                                                      *
507         Implicit bindings
508 %*                                                                      *
509 %************************************************************************
510
511 Note [Injecting implicit bindings]
512 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
513 We inject the implict bindings right at the end, in CoreTidy.
514 Some of these bindings, notably record selectors, are not
515 constructed in an optimised form.  E.g. record selector for
516         data T = MkT { x :: {-# UNPACK #-} !Int }
517 Then the unfolding looks like
518         x = \t. case t of MkT x1 -> let x = I# x1 in x
519 This generates bad code unless it's first simplified a bit.  That is
520 why CoreUnfold.mkImplicitUnfolding uses simleExprOpt to do a bit of
521 optimisation first.  (Only matters when the selector is used curried;
522 eg map x ys.)  See Trac #2070.
523
524 [Oct 09: in fact, record selectors are no longer implicit Ids at all,
525 because we really do want to optimise them properly. They are treated
526 much like any other Id.  But doing "light" optimisation on an implicit
527 Id still makes sense.]
528
529 At one time I tried injecting the implicit bindings *early*, at the
530 beginning of SimplCore.  But that gave rise to real difficulty,
531 becuase GlobalIds are supposed to have *fixed* IdInfo, but the
532 simplifier and other core-to-core passes mess with IdInfo all the
533 time.  The straw that broke the camels back was when a class selector
534 got the wrong arity -- ie the simplifier gave it arity 2, whereas
535 importing modules were expecting it to have arity 1 (Trac #2844).
536 It's much safer just to inject them right at the end, after tidying.
537
538 Oh: two other reasons for injecting them late:
539
540   - If implicit Ids are already in the bindings when we start TidyPgm,
541     we'd have to be careful not to treat them as external Ids (in
542     the sense of findExternalIds); else the Ids mentioned in *their*
543     RHSs will be treated as external and you get an interface file 
544     saying      a18 = <blah>
545     but nothing refererring to a18 (because the implicit Id is the 
546     one that does, and implicit Ids don't appear in interface files).
547
548   - More seriously, the tidied type-envt will include the implicit
549     Id replete with a18 in its unfolding; but we won't take account
550     of a18 when computing a fingerprint for the class; result chaos.
551     
552 There is one sort of implicit binding that is injected still later,
553 namely those for data constructor workers. Reason (I think): it's
554 really just a code generation trick.... binding itself makes no sense.
555 See CorePrep Note [Data constructor workers].
556
557 \begin{code}
558 getImplicitBinds :: TypeEnv -> [CoreBind]
559 getImplicitBinds type_env
560   = map get_defn (concatMap implicit_ids (typeEnvElts type_env))
561   where
562     implicit_ids (ATyCon tc)  = mapCatMaybes dataConWrapId_maybe (tyConDataCons tc)
563     implicit_ids (AClass cls) = classSelIds cls
564     implicit_ids _            = []
565     
566     get_defn :: Id -> CoreBind
567     get_defn id = NonRec id (unfoldingTemplate (realIdUnfolding id))
568 \end{code}
569
570
571 %************************************************************************
572 %*                                                                      *
573 \subsection{Step 1: finding externals}
574 %*                                                                      * 
575 %************************************************************************
576
577 Sete Note [choosing external names].
578
579 \begin{code}
580 type UnfoldEnv  = IdEnv (Name{-new name-}, Bool {-show unfolding-})
581   -- Maps each top-level Id to its new Name (the Id is tidied in step 2)
582   -- The Unique is unchanged.  If the new Name is external, it will be
583   -- visible in the interface file.  
584   --
585   -- Bool => expose unfolding or not.
586
587 chooseExternalIds :: HscEnv
588                   -> Module
589                   -> Bool -> Bool
590                   -> [CoreBind]
591                   -> [CoreBind]
592                   -> [CoreRule]
593                   -> IO (UnfoldEnv, TidyOccEnv)
594         -- Step 1 from the notes above
595
596 chooseExternalIds hsc_env mod omit_prags expose_all binds implicit_binds imp_id_rules
597   = do { (unfold_env1,occ_env1) <- search init_work_list emptyVarEnv init_occ_env
598        ; let internal_ids = filter (not . (`elemVarEnv` unfold_env1)) binders
599        ; tidy_internal internal_ids unfold_env1 occ_env1 }
600  where
601   nc_var = hsc_NC hsc_env 
602
603   -- init_ext_ids is the intial list of Ids that should be
604   -- externalised.  It serves as the starting point for finding a
605   -- deterministic, tidy, renaming for all external Ids in this
606   -- module.
607   -- 
608   -- It is sorted, so that it has adeterministic order (i.e. it's the
609   -- same list every time this module is compiled), in contrast to the
610   -- bindings, which are ordered non-deterministically.
611   init_work_list = zip init_ext_ids init_ext_ids
612   init_ext_ids   = sortBy (compare `on` getOccName) $
613                    filter is_external binders
614
615   -- An Id should be external if either (a) it is exported or
616   -- (b) it appears in the RHS of a local rule for an imported Id.   
617   -- See Note [Which rules to expose]
618   is_external id = isExportedId id || id `elemVarSet` rule_rhs_vars
619   rule_rhs_vars = foldr (unionVarSet . ruleRhsFreeVars) emptyVarSet imp_id_rules
620
621   binders          = bindersOfBinds binds
622   implicit_binders = bindersOfBinds implicit_binds
623   binder_set       = mkVarSet binders
624
625   avoids   = [getOccName name | bndr <- binders ++ implicit_binders,
626                                 let name = idName bndr,
627                                 isExternalName name ]
628                 -- In computing our "avoids" list, we must include
629                 --      all implicit Ids
630                 --      all things with global names (assigned once and for
631                 --                                      all by the renamer)
632                 -- since their names are "taken".
633                 -- The type environment is a convenient source of such things.
634                 -- In particular, the set of binders doesn't include
635                 -- implicit Ids at this stage.
636
637         -- We also make sure to avoid any exported binders.  Consider
638         --      f{-u1-} = 1     -- Local decl
639         --      ...
640         --      f{-u2-} = 2     -- Exported decl
641         --
642         -- The second exported decl must 'get' the name 'f', so we
643         -- have to put 'f' in the avoids list before we get to the first
644         -- decl.  tidyTopId then does a no-op on exported binders.
645   init_occ_env = initTidyOccEnv avoids
646
647
648   search :: [(Id,Id)]    -- The work-list: (external id, referrring id)
649                          -- Make a tidy, external Name for the external id,
650                          --   add it to the UnfoldEnv, and do the same for the
651                          --   transitive closure of Ids it refers to
652                          -- The referring id is used to generate a tidy
653                          ---  name for the external id
654          -> UnfoldEnv    -- id -> (new Name, show_unfold)
655          -> TidyOccEnv   -- occ env for choosing new Names
656          -> IO (UnfoldEnv, TidyOccEnv)
657
658   search [] unfold_env occ_env = return (unfold_env, occ_env)
659
660   search ((idocc,referrer) : rest) unfold_env occ_env
661     | idocc `elemVarEnv` unfold_env = search rest unfold_env occ_env
662     | otherwise = do
663       (occ_env', name') <- tidyTopName mod nc_var (Just referrer) occ_env idocc
664       let 
665           (new_ids, show_unfold)
666                 | omit_prags = ([], False)
667                 | otherwise  = addExternal expose_all refined_id
668
669                 -- 'idocc' is an *occurrence*, but we need to see the
670                 -- unfolding in the *definition*; so look up in binder_set
671           refined_id = case lookupVarSet binder_set idocc of
672                          Just id -> id
673                          Nothing -> WARN( True, ppr idocc ) idocc
674
675           unfold_env' = extendVarEnv unfold_env idocc (name',show_unfold)
676           referrer' | isExportedId refined_id = refined_id
677                     | otherwise               = referrer
678       --
679       search (zip new_ids (repeat referrer') ++ rest) unfold_env' occ_env'
680
681   tidy_internal :: [Id] -> UnfoldEnv -> TidyOccEnv
682                 -> IO (UnfoldEnv, TidyOccEnv)
683   tidy_internal []       unfold_env occ_env = return (unfold_env,occ_env)
684   tidy_internal (id:ids) unfold_env occ_env = do
685       (occ_env', name') <- tidyTopName mod nc_var Nothing occ_env id
686       let unfold_env' = extendVarEnv unfold_env id (name',False)
687       tidy_internal ids unfold_env' occ_env'
688
689 addExternal :: Bool -> Id -> ([Id],Bool)
690 addExternal expose_all id = (new_needed_ids, show_unfold)
691   where
692     new_needed_ids = unfold_ids ++
693                      filter (\id -> isLocalId id &&
694                                     not (id `elemVarSet` unfold_set))
695                        (varSetElems spec_ids) -- XXX non-det ordering
696
697     idinfo         = idInfo id
698     never_active   = isNeverActive (inlinePragmaActivation (inlinePragInfo idinfo))
699     loop_breaker   = isNonRuleLoopBreaker (occInfo idinfo)
700     bottoming_fn   = isBottomingSig (strictnessInfo idinfo `orElse` topSig)
701     spec_ids       = specInfoFreeVars (specInfo idinfo)
702
703         -- Stuff to do with the Id's unfolding
704         -- We leave the unfolding there even if there is a worker
705         -- In GHCI the unfolding is used by importers
706     show_unfold = isJust mb_unfold_ids
707     (unfold_set, unfold_ids) = mb_unfold_ids `orElse` (emptyVarSet, [])
708
709     mb_unfold_ids :: Maybe (IdSet, [Id])        -- Nothing => don't unfold
710     mb_unfold_ids = case unfoldingInfo idinfo of
711                       CoreUnfolding { uf_tmpl = unf_rhs, uf_src = src, uf_guidance = guide } 
712                                             | show_unfolding src guide
713                                             -> Just (unf_ext_ids src unf_rhs)
714                       DFunUnfolding _ _ ops -> Just (exprsFvsInOrder ops)
715                       _                     -> Nothing
716                   where
717                     unf_ext_ids (InlineWrapper v) _ = (unitVarSet v, [v])
718                     unf_ext_ids _           unf_rhs = exprFvsInOrder unf_rhs
719                     -- For a wrapper, externalise the wrapper id rather than the
720                     -- fvs of the rhs.  The two usually come down to the same thing
721                     -- but I've seen cases where we had a wrapper id $w but a
722                     -- rhs where $w had been inlined; see Trac #3922
723
724     show_unfolding unf_source unf_guidance
725        =  expose_all         -- 'expose_all' says to expose all 
726                              -- unfoldings willy-nilly
727
728        || isInlineRuleSource unf_source      -- Always expose things whose 
729                                              -- source is an inline rule
730
731        || not (bottoming_fn      -- No need to inline bottom functions
732            || never_active       -- Or ones that say not to
733            || loop_breaker       -- Or that are loop breakers
734            || neverUnfoldGuidance unf_guidance)
735
736 -- We want a deterministic free-variable list.  exprFreeVars gives us
737 -- a VarSet, which is in a non-deterministic order when converted to a
738 -- list.  Hence, here we define a free-variable finder that returns
739 -- the free variables in the order that they are encountered.
740 --
741 -- Note [choosing external names]
742
743 exprFvsInOrder :: CoreExpr -> (VarSet, [Id])
744 exprFvsInOrder e = run (dffvExpr e)
745
746 exprsFvsInOrder :: [CoreExpr] -> (VarSet, [Id])
747 exprsFvsInOrder es = run (mapM_ dffvExpr es)
748
749 run :: DFFV () -> (VarSet, [Id])
750 run (DFFV m) = case m emptyVarSet [] of
751                  (set,ids,_) -> (set,ids)
752
753 newtype DFFV a = DFFV (VarSet -> [Var] -> (VarSet,[Var],a))
754
755 instance Monad DFFV where
756   return a = DFFV $ \set ids -> (set, ids, a)
757   (DFFV m) >>= k = DFFV $ \set ids ->
758     case m set ids of
759        (set',ids',a) -> case k a of
760                           DFFV f -> f set' ids' 
761
762 insert :: Var -> DFFV ()
763 insert v = DFFV $ \ set ids  -> case () of 
764  _ | v `elemVarSet` set -> (set,ids,())
765    | otherwise          -> (extendVarSet set v, v:ids, ())
766
767 dffvExpr :: CoreExpr -> DFFV ()
768 dffvExpr e = go emptyVarSet e
769   where
770     go scope e = case e of
771       Var v | isLocalId v && not (v `elemVarSet` scope) -> insert v
772       App e1 e2          -> do go scope e1; go scope e2
773       Lam v e            -> go (extendVarSet scope v) e
774       Note _ e           -> go scope e
775       Cast e _           -> go scope e
776       Let (NonRec x r) e -> do go scope r; go (extendVarSet scope x) e
777       Let (Rec prs) e    -> do let scope' = extendVarSetList scope (map fst prs)
778                                mapM_ (go scope') (map snd prs)
779                                go scope' e
780       Case e b _ as      -> do go scope e
781                                mapM_ (go_alt (extendVarSet scope b)) as
782       _other             -> return ()
783
784     go_alt scope (_,xs,r) = go (extendVarSetList scope xs) r
785 \end{code}
786
787
788 --------------------------------------------------------------------
789 --              tidyTopName
790 -- This is where we set names to local/global based on whether they really are 
791 -- externally visible (see comment at the top of this module).  If the name
792 -- was previously local, we have to give it a unique occurrence name if
793 -- we intend to externalise it.
794
795 \begin{code}
796 tidyTopName :: Module -> IORef NameCache -> Maybe Id -> TidyOccEnv
797             -> Id -> IO (TidyOccEnv, Name)
798 tidyTopName mod nc_var maybe_ref occ_env id
799   | global && internal = return (occ_env, localiseName name)
800
801   | global && external = return (occ_env, name)
802         -- Global names are assumed to have been allocated by the renamer,
803         -- so they already have the "right" unique
804         -- And it's a system-wide unique too
805
806   -- Now we get to the real reason that all this is in the IO Monad:
807   -- we have to update the name cache in a nice atomic fashion
808
809   | local  && internal = do { nc <- readIORef nc_var
810                             ; let (nc', new_local_name) = mk_new_local nc
811                             ; writeIORef nc_var nc'
812                             ; return (occ_env', new_local_name) }
813         -- Even local, internal names must get a unique occurrence, because
814         -- if we do -split-objs we externalise the name later, in the code generator
815         --
816         -- Similarly, we must make sure it has a system-wide Unique, because
817         -- the byte-code generator builds a system-wide Name->BCO symbol table
818
819   | local  && external = do { nc <- readIORef nc_var
820                             ; let (nc', new_external_name) = mk_new_external nc
821                             ; writeIORef nc_var nc'
822                             ; return (occ_env', new_external_name) }
823
824   | otherwise = panic "tidyTopName"
825   where
826     name        = idName id
827     external    = isJust maybe_ref
828     global      = isExternalName name
829     local       = not global
830     internal    = not external
831     loc         = nameSrcSpan name
832
833     old_occ     = nameOccName name
834     new_occ
835       | Just ref <- maybe_ref, ref /= id = 
836           mkOccName (occNameSpace old_occ) $
837              let
838                  ref_str = occNameString (getOccName ref)
839                  occ_str = occNameString old_occ
840              in
841              case occ_str of
842                '$':'w':_ -> occ_str
843                   -- workers: the worker for a function already
844                   -- includes the occname for its parent, so there's
845                   -- no need to prepend the referrer.
846                _other | isSystemName name -> ref_str
847                       | otherwise         -> ref_str ++ '_' : occ_str
848                   -- If this name was system-generated, then don't bother
849                   -- to retain its OccName, just use the referrer.  These
850                   -- system-generated names will become "f1", "f2", etc. for
851                   -- a referrer "f".
852       | otherwise = old_occ
853
854     (occ_env', occ') = tidyOccName occ_env new_occ
855
856     mk_new_local nc = (nc { nsUniqs = us2 }, mkInternalName uniq occ' loc)
857                     where
858                       (us1, us2) = splitUniqSupply (nsUniqs nc)
859                       uniq       = uniqFromSupply us1
860
861     mk_new_external nc = allocateGlobalBinder nc mod occ' loc
862         -- If we want to externalise a currently-local name, check
863         -- whether we have already assigned a unique for it.
864         -- If so, use it; if not, extend the table.
865         -- All this is done by allcoateGlobalBinder.
866         -- This is needed when *re*-compiling a module in GHCi; we must
867         -- use the same name for externally-visible things as we did before.
868 \end{code}
869
870 \begin{code}
871 findExternalRules :: Bool       -- Omit pragmas
872                   -> [CoreBind]
873                   -> [CoreRule] -- Local rules for imported fns
874                   -> UnfoldEnv  -- Ids that are exported, so we need their rules
875                   -> [CoreRule]
876   -- The complete rules are gotten by combining
877   --    a) local rules for imported Ids
878   --    b) rules embedded in the top-level Ids
879 findExternalRules omit_prags binds imp_id_rules unfold_env
880   | omit_prags = []
881   | otherwise  = filterOut internal_rule (imp_id_rules ++ local_rules)
882   where
883     local_rules  = [ rule
884                    | id <- bindersOfBinds binds,
885                      external_id id,
886                      rule <- idCoreRules id
887                    ]
888
889     internal_rule rule
890         =  any (not . external_id) (varSetElems (ruleLhsFreeIds rule))
891                 -- Don't export a rule whose LHS mentions a locally-defined
892                 --  Id that is completely internal (i.e. not visible to an
893                 -- importing module)
894
895     external_id id
896       | Just (name,_) <- lookupVarEnv unfold_env id = isExternalName name
897       | otherwise = False
898 \end{code}
899
900 Note [Which rules to expose]
901 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
902 findExternalRules filters imp_rules to avoid binders that 
903 aren't externally visible; but the externally-visible binders 
904 are computed (by findExternalIds) assuming that all orphan
905 rules are externalised (see init_ext_ids in function 
906 'search'). So in fact we may export more than we need. 
907 (It's a sort of mutual recursion.)
908
909 %************************************************************************
910 %*                                                                      *
911 \subsection{Step 2: top-level tidying}
912 %*                                                                      *
913 %************************************************************************
914
915
916 \begin{code}
917 -- TopTidyEnv: when tidying we need to know
918 --   * nc_var: The NameCache, containing a unique supply and any pre-ordained Names.  
919 --        These may have arisen because the
920 --        renamer read in an interface file mentioning M.$wf, say,
921 --        and assigned it unique r77.  If, on this compilation, we've
922 --        invented an Id whose name is $wf (but with a different unique)
923 --        we want to rename it to have unique r77, so that we can do easy
924 --        comparisons with stuff from the interface file
925 --
926 --   * occ_env: The TidyOccEnv, which tells us which local occurrences 
927 --     are 'used'
928 --
929 --   * subst_env: A Var->Var mapping that substitutes the new Var for the old
930
931 tidyTopBinds :: HscEnv
932              -> UnfoldEnv
933              -> TidyOccEnv
934              -> [CoreBind]
935              -> (TidyEnv, [CoreBind])
936
937 tidyTopBinds hsc_env unfold_env init_occ_env binds
938   = tidy init_env binds
939   where
940     init_env = (init_occ_env, emptyVarEnv)
941
942     this_pkg = thisPackage (hsc_dflags hsc_env)
943
944     tidy env []     = (env, [])
945     tidy env (b:bs) = let (env1, b')  = tidyTopBind this_pkg unfold_env env b
946                           (env2, bs') = tidy env1 bs
947                       in
948                           (env2, b':bs')
949
950 ------------------------
951 tidyTopBind  :: PackageId
952              -> UnfoldEnv
953              -> TidyEnv
954              -> CoreBind
955              -> (TidyEnv, CoreBind)
956
957 tidyTopBind this_pkg unfold_env (occ_env,subst1) (NonRec bndr rhs)
958   = (tidy_env2,  NonRec bndr' rhs')
959   where
960     Just (name',show_unfold) = lookupVarEnv unfold_env bndr
961     caf_info      = hasCafRefs this_pkg subst1 (idArity bndr) rhs
962     (bndr', rhs') = tidyTopPair show_unfold tidy_env2 caf_info name' (bndr, rhs)
963     subst2        = extendVarEnv subst1 bndr bndr'
964     tidy_env2     = (occ_env, subst2)
965
966 tidyTopBind this_pkg unfold_env (occ_env,subst1) (Rec prs)
967   = (tidy_env2, Rec prs')
968   where
969     prs' = [ tidyTopPair show_unfold tidy_env2 caf_info name' (id,rhs)
970            | (id,rhs) <- prs,
971              let (name',show_unfold) = 
972                     expectJust "tidyTopBind" $ lookupVarEnv unfold_env id
973            ]
974
975     subst2    = extendVarEnvList subst1 (bndrs `zip` map fst prs')
976     tidy_env2 = (occ_env, subst2)
977
978     bndrs = map fst prs
979
980         -- the CafInfo for a recursive group says whether *any* rhs in
981         -- the group may refer indirectly to a CAF (because then, they all do).
982     caf_info 
983         | or [ mayHaveCafRefs (hasCafRefs this_pkg subst1 (idArity bndr) rhs)
984              | (bndr,rhs) <- prs ] = MayHaveCafRefs
985         | otherwise                = NoCafRefs
986
987 -----------------------------------------------------------
988 tidyTopPair :: Bool  -- show unfolding
989             -> TidyEnv  -- The TidyEnv is used to tidy the IdInfo
990                         -- It is knot-tied: don't look at it!
991             -> CafInfo
992             -> Name             -- New name
993             -> (Id, CoreExpr)   -- Binder and RHS before tidying
994             -> (Id, CoreExpr)
995         -- This function is the heart of Step 2
996         -- The rec_tidy_env is the one to use for the IdInfo
997         -- It's necessary because when we are dealing with a recursive
998         -- group, a variable late in the group might be mentioned
999         -- in the IdInfo of one early in the group
1000
1001 tidyTopPair show_unfold rhs_tidy_env caf_info name' (bndr, rhs)
1002   = (bndr1, rhs1)
1003   where
1004     bndr1    = mkGlobalId details name' ty' idinfo'
1005     details  = idDetails bndr   -- Preserve the IdDetails
1006     ty'      = tidyTopType (idType bndr)
1007     rhs1     = tidyExpr rhs_tidy_env rhs
1008     idinfo'  = tidyTopIdInfo rhs_tidy_env name' rhs rhs1 (idInfo bndr) 
1009                              show_unfold caf_info
1010
1011 -- tidyTopIdInfo creates the final IdInfo for top-level
1012 -- binders.  There are two delicate pieces:
1013 --
1014 --  * Arity.  After CoreTidy, this arity must not change any more.
1015 --      Indeed, CorePrep must eta expand where necessary to make
1016 --      the manifest arity equal to the claimed arity.
1017 --
1018 --  * CAF info.  This must also remain valid through to code generation.
1019 --      We add the info here so that it propagates to all
1020 --      occurrences of the binders in RHSs, and hence to occurrences in
1021 --      unfoldings, which are inside Ids imported by GHCi. Ditto RULES.
1022 --      CoreToStg makes use of this when constructing SRTs.
1023 tidyTopIdInfo :: TidyEnv -> Name -> CoreExpr -> CoreExpr 
1024               -> IdInfo -> Bool -> CafInfo -> IdInfo
1025 tidyTopIdInfo rhs_tidy_env name orig_rhs tidy_rhs idinfo show_unfold caf_info
1026   | not is_external     -- For internal Ids (not externally visible)
1027   = vanillaIdInfo       -- we only need enough info for code generation
1028                         -- Arity and strictness info are enough;
1029                         --      c.f. CoreTidy.tidyLetBndr
1030         `setCafInfo`        caf_info
1031         `setArityInfo`      arity
1032         `setStrictnessInfo` final_sig
1033
1034   | otherwise           -- Externally-visible Ids get the whole lot
1035   = vanillaIdInfo
1036         `setCafInfo`           caf_info
1037         `setArityInfo`         arity
1038         `setStrictnessInfo`    final_sig
1039         `setOccInfo`           robust_occ_info
1040         `setInlinePragInfo`    (inlinePragInfo idinfo)
1041         `setUnfoldingInfo`     unfold_info
1042                 -- NB: we throw away the Rules
1043                 -- They have already been extracted by findExternalRules
1044   where
1045     is_external = isExternalName name
1046
1047     --------- OccInfo ------------
1048     robust_occ_info = zapFragileOcc (occInfo idinfo)
1049     -- It's important to keep loop-breaker information
1050     -- when we are doing -fexpose-all-unfoldings
1051
1052     --------- Strictness ------------
1053     final_sig | Just sig <- strictnessInfo idinfo
1054               = WARN( _bottom_hidden sig, ppr name ) Just sig
1055               | Just (_, sig) <- mb_bot_str = Just sig
1056               | otherwise                   = Nothing
1057
1058     -- If the cheap-and-cheerful bottom analyser can see that
1059     -- the RHS is bottom, it should jolly well be exposed
1060     _bottom_hidden id_sig = case mb_bot_str of
1061                                Nothing         -> False
1062                                Just (arity, _) -> not (appIsBottom id_sig arity)
1063
1064     mb_bot_str = exprBotStrictness_maybe orig_rhs
1065
1066     --------- Unfolding ------------
1067     unf_info = unfoldingInfo idinfo
1068     unfold_info | show_unfold = tidyUnfolding rhs_tidy_env tidy_rhs final_sig unf_info
1069                 | otherwise   = noUnfolding
1070     -- NB: do *not* expose the worker if show_unfold is off,
1071     --     because that means this thing is a loop breaker or
1072     --     marked NOINLINE or something like that
1073     -- This is important: if you expose the worker for a loop-breaker
1074     -- then you can make the simplifier go into an infinite loop, because
1075     -- in effect the unfolding is exposed.  See Trac #1709
1076     -- 
1077     -- You might think that if show_unfold is False, then the thing should
1078     -- not be w/w'd in the first place.  But a legitimate reason is this:
1079     --    the function returns bottom
1080     -- In this case, show_unfold will be false (we don't expose unfoldings
1081     -- for bottoming functions), but we might still have a worker/wrapper
1082     -- split (see Note [Worker-wrapper for bottoming functions] in WorkWrap.lhs
1083
1084     --------- Arity ------------
1085     -- Usually the Id will have an accurate arity on it, because
1086     -- the simplifier has just run, but not always. 
1087     -- One case I found was when the last thing the simplifier
1088     -- did was to let-bind a non-atomic argument and then float
1089     -- it to the top level. So it seems more robust just to
1090     -- fix it here.
1091     arity = exprArity orig_rhs
1092
1093
1094
1095 ------------ Unfolding  --------------
1096 tidyUnfolding :: TidyEnv -> CoreExpr -> Maybe StrictSig -> Unfolding -> Unfolding
1097 tidyUnfolding tidy_env _ _ (DFunUnfolding ar con ids)
1098   = DFunUnfolding ar con (map (tidyExpr tidy_env) ids)
1099 tidyUnfolding tidy_env tidy_rhs strict_sig
1100               unf@(CoreUnfolding { uf_tmpl = unf_rhs, uf_src = src })
1101   | isInlineRuleSource src
1102   = unf { uf_tmpl = tidyExpr tidy_env unf_rhs,     -- Preserves OccInfo
1103           uf_src  = tidyInl tidy_env src }
1104   | otherwise
1105   = mkTopUnfolding is_bot tidy_rhs
1106   where
1107     is_bot = case strict_sig of 
1108                 Just sig -> isBottomingSig sig
1109                 Nothing  -> False
1110
1111 tidyUnfolding _ _ _ unf = unf
1112
1113 tidyInl :: TidyEnv -> UnfoldingSource -> UnfoldingSource
1114 tidyInl tidy_env (InlineWrapper w) = InlineWrapper (tidyVarOcc tidy_env w)
1115 tidyInl _        inl_info          = inl_info
1116 \end{code}
1117
1118 %************************************************************************
1119 %*                                                                      *
1120 \subsection{Figuring out CafInfo for an expression}
1121 %*                                                                      *
1122 %************************************************************************
1123
1124 hasCafRefs decides whether a top-level closure can point into the dynamic heap.
1125 We mark such things as `MayHaveCafRefs' because this information is
1126 used to decide whether a particular closure needs to be referenced
1127 in an SRT or not.
1128
1129 There are two reasons for setting MayHaveCafRefs:
1130         a) The RHS is a CAF: a top-level updatable thunk.
1131         b) The RHS refers to something that MayHaveCafRefs
1132
1133 Possible improvement: In an effort to keep the number of CAFs (and 
1134 hence the size of the SRTs) down, we could also look at the expression and 
1135 decide whether it requires a small bounded amount of heap, so we can ignore 
1136 it as a CAF.  In these cases however, we would need to use an additional
1137 CAF list to keep track of non-collectable CAFs.  
1138
1139 \begin{code}
1140 hasCafRefs  :: PackageId -> VarEnv Var -> Arity -> CoreExpr -> CafInfo
1141 hasCafRefs this_pkg p arity expr 
1142   | is_caf || mentions_cafs 
1143                             = MayHaveCafRefs
1144   | otherwise               = NoCafRefs
1145  where
1146   mentions_cafs = isFastTrue (cafRefs p expr)
1147   is_caf = not (arity > 0 || rhsIsStatic this_pkg expr)
1148
1149   -- NB. we pass in the arity of the expression, which is expected
1150   -- to be calculated by exprArity.  This is because exprArity
1151   -- knows how much eta expansion is going to be done by 
1152   -- CorePrep later on, and we don't want to duplicate that
1153   -- knowledge in rhsIsStatic below.
1154
1155 cafRefs :: VarEnv Id -> Expr a -> FastBool
1156 cafRefs p (Var id)
1157         -- imported Ids first:
1158   | not (isLocalId id) = fastBool (mayHaveCafRefs (idCafInfo id))
1159         -- now Ids local to this module:
1160   | otherwise =
1161      case lookupVarEnv p id of
1162         Just id' -> fastBool (mayHaveCafRefs (idCafInfo id'))
1163         Nothing  -> fastBool False
1164
1165 cafRefs _ (Lit _)              = fastBool False
1166 cafRefs p (App f a)            = fastOr (cafRefs p f) (cafRefs p) a
1167 cafRefs p (Lam _ e)            = cafRefs p e
1168 cafRefs p (Let b e)            = fastOr (cafRefss p (rhssOfBind b)) (cafRefs p) e
1169 cafRefs p (Case e _bndr _ alts) = fastOr (cafRefs p e) (cafRefss p) (rhssOfAlts alts)
1170 cafRefs p (Note _n e)          = cafRefs p e
1171 cafRefs p (Cast e _co)         = cafRefs p e
1172 cafRefs _ (Type _)             = fastBool False
1173
1174 cafRefss :: VarEnv Id -> [Expr a] -> FastBool
1175 cafRefss _ []     = fastBool False
1176 cafRefss p (e:es) = fastOr (cafRefs p e) (cafRefss p) es
1177
1178 fastOr :: FastBool -> (a -> FastBool) -> a -> FastBool
1179 -- hack for lazy-or over FastBool.
1180 fastOr a f x = fastBool (isFastTrue a || isFastTrue (f x))
1181 \end{code}