a88d9430325d94a707ea492fb18bbe59ddfe2a08
[ghc.git] / compiler / simplCore / Simplify.lhs
1 %
2 % (c) The AQUA Project, Glasgow University, 1993-1998
3 %
4 \section[Simplify]{The main module of the simplifier}
5
6 \begin{code}
7 module Simplify ( simplTopBinds, simplExpr ) where
8
9 #include "HsVersions.h"
10
11 import DynFlags
12 import SimplMonad
13 import Type hiding      ( substTy, extendTvSubst, substTyVar )
14 import SimplEnv
15 import SimplUtils
16 import FamInstEnv       ( FamInstEnv )
17 import Literal          ( litIsLifted, mkMachInt )
18 import Id
19 import MkId             ( seqId, realWorldPrimId )
20 import MkCore           ( mkImpossibleExpr, castBottomExpr )
21 import IdInfo
22 import Name             ( mkSystemVarName, isExternalName )
23 import Coercion hiding  ( substCo, substTy, substCoVar, extendTvSubst )
24 import OptCoercion      ( optCoercion )
25 import FamInstEnv       ( topNormaliseType )
26 import DataCon          ( DataCon, dataConWorkId, dataConRepStrictness 
27                         , isMarkedStrict, dataConTyCon, dataConTag, fIRST_TAG )
28 import TyCon            ( isEnumerationTyCon )
29 import CoreMonad        ( Tick(..), SimplifierMode(..) )
30 import CoreSyn
31 import Demand           ( StrictSig(..), dmdTypeDepth )
32 import PprCore          ( pprParendExpr, pprCoreExpr )
33 import CoreUnfold
34 import CoreUtils
35 import CoreArity
36 import PrimOp           ( tagToEnumKey )
37 import Rules            ( lookupRule, getRules )
38 import TysPrim          ( realWorldStatePrimTy, intPrimTy )
39 import BasicTypes       ( TopLevelFlag(..), isTopLevel, RecFlag(..) )
40 import MonadUtils       ( foldlM, mapAccumLM, liftIO )
41 import Maybes           ( orElse )
42 import Unique           ( hasKey )
43 import Control.Monad
44 import Data.List        ( mapAccumL )
45 import Outputable
46 import FastString
47 import Pair
48 import Util
49 import ErrUtils
50 \end{code}
51
52
53 The guts of the simplifier is in this module, but the driver loop for
54 the simplifier is in SimplCore.lhs.
55
56
57 -----------------------------------------
58         *** IMPORTANT NOTE ***
59 -----------------------------------------
60 The simplifier used to guarantee that the output had no shadowing, but
61 it does not do so any more.   (Actually, it never did!)  The reason is
62 documented with simplifyArgs.
63
64
65 -----------------------------------------
66         *** IMPORTANT NOTE ***
67 -----------------------------------------
68 Many parts of the simplifier return a bunch of "floats" as well as an
69 expression. This is wrapped as a datatype SimplUtils.FloatsWith.
70
71 All "floats" are let-binds, not case-binds, but some non-rec lets may
72 be unlifted (with RHS ok-for-speculation).
73
74
75
76 -----------------------------------------
77         ORGANISATION OF FUNCTIONS
78 -----------------------------------------
79 simplTopBinds
80   - simplify all top-level binders
81   - for NonRec, call simplRecOrTopPair
82   - for Rec,    call simplRecBind
83
84
85         ------------------------------
86 simplExpr (applied lambda)      ==> simplNonRecBind
87 simplExpr (Let (NonRec ...) ..) ==> simplNonRecBind
88 simplExpr (Let (Rec ...)    ..) ==> simplify binders; simplRecBind
89
90         ------------------------------
91 simplRecBind    [binders already simplfied]
92   - use simplRecOrTopPair on each pair in turn
93
94 simplRecOrTopPair [binder already simplified]
95   Used for: recursive bindings (top level and nested)
96             top-level non-recursive bindings
97   Returns:
98   - check for PreInlineUnconditionally
99   - simplLazyBind
100
101 simplNonRecBind
102   Used for: non-top-level non-recursive bindings
103             beta reductions (which amount to the same thing)
104   Because it can deal with strict arts, it takes a
105         "thing-inside" and returns an expression
106
107   - check for PreInlineUnconditionally
108   - simplify binder, including its IdInfo
109   - if strict binding
110         simplStrictArg
111         mkAtomicArgs
112         completeNonRecX
113     else
114         simplLazyBind
115         addFloats
116
117 simplNonRecX:   [given a *simplified* RHS, but an *unsimplified* binder]
118   Used for: binding case-binder and constr args in a known-constructor case
119   - check for PreInLineUnconditionally
120   - simplify binder
121   - completeNonRecX
122
123         ------------------------------
124 simplLazyBind:  [binder already simplified, RHS not]
125   Used for: recursive bindings (top level and nested)
126             top-level non-recursive bindings
127             non-top-level, but *lazy* non-recursive bindings
128         [must not be strict or unboxed]
129   Returns floats + an augmented environment, not an expression
130   - substituteIdInfo and add result to in-scope
131         [so that rules are available in rec rhs]
132   - simplify rhs
133   - mkAtomicArgs
134   - float if exposes constructor or PAP
135   - completeBind
136
137
138 completeNonRecX:        [binder and rhs both simplified]
139   - if the the thing needs case binding (unlifted and not ok-for-spec)
140         build a Case
141    else
142         completeBind
143         addFloats
144
145 completeBind:   [given a simplified RHS]
146         [used for both rec and non-rec bindings, top level and not]
147   - try PostInlineUnconditionally
148   - add unfolding [this is the only place we add an unfolding]
149   - add arity
150
151
152
153 Right hand sides and arguments
154 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
155 In many ways we want to treat
156         (a) the right hand side of a let(rec), and
157         (b) a function argument
158 in the same way.  But not always!  In particular, we would
159 like to leave these arguments exactly as they are, so they
160 will match a RULE more easily.
161
162         f (g x, h x)
163         g (+ x)
164
165 It's harder to make the rule match if we ANF-ise the constructor,
166 or eta-expand the PAP:
167
168         f (let { a = g x; b = h x } in (a,b))
169         g (\y. + x y)
170
171 On the other hand if we see the let-defns
172
173         p = (g x, h x)
174         q = + x
175
176 then we *do* want to ANF-ise and eta-expand, so that p and q
177 can be safely inlined.
178
179 Even floating lets out is a bit dubious.  For let RHS's we float lets
180 out if that exposes a value, so that the value can be inlined more vigorously.
181 For example
182
183         r = let x = e in (x,x)
184
185 Here, if we float the let out we'll expose a nice constructor. We did experiments
186 that showed this to be a generally good thing.  But it was a bad thing to float
187 lets out unconditionally, because that meant they got allocated more often.
188
189 For function arguments, there's less reason to expose a constructor (it won't
190 get inlined).  Just possibly it might make a rule match, but I'm pretty skeptical.
191 So for the moment we don't float lets out of function arguments either.
192
193
194 Eta expansion
195 ~~~~~~~~~~~~~~
196 For eta expansion, we want to catch things like
197
198         case e of (a,b) -> \x -> case a of (p,q) -> \y -> r
199
200 If the \x was on the RHS of a let, we'd eta expand to bring the two
201 lambdas together.  And in general that's a good thing to do.  Perhaps
202 we should eta expand wherever we find a (value) lambda?  Then the eta
203 expansion at a let RHS can concentrate solely on the PAP case.
204
205
206 %************************************************************************
207 %*                                                                      *
208 \subsection{Bindings}
209 %*                                                                      *
210 %************************************************************************
211
212 \begin{code}
213 simplTopBinds :: SimplEnv -> [InBind] -> SimplM SimplEnv
214
215 simplTopBinds env0 binds0
216   = do  {       -- Put all the top-level binders into scope at the start
217                 -- so that if a transformation rule has unexpectedly brought
218                 -- anything into scope, then we don't get a complaint about that.
219                 -- It's rather as if the top-level binders were imported.
220                 -- See note [Glomming] in OccurAnal.
221         ; env1 <- simplRecBndrs env0 (bindersOfBinds binds0)
222         ; dflags <- getDynFlags
223         ; let dump_flag = dopt Opt_D_verbose_core2core dflags
224         ; env2 <- simpl_binds dump_flag env1 binds0
225         ; freeTick SimplifierDone
226         ; return env2 }
227   where
228         -- We need to track the zapped top-level binders, because
229         -- they should have their fragile IdInfo zapped (notably occurrence info)
230         -- That's why we run down binds and bndrs' simultaneously.
231         --
232         -- The dump-flag emits a trace for each top-level binding, which
233         -- helps to locate the tracing for inlining and rule firing
234     simpl_binds :: Bool -> SimplEnv -> [InBind] -> SimplM SimplEnv
235     simpl_binds _    env []           = return env
236     simpl_binds dump env (bind:binds) = do { env' <- trace_bind dump bind $
237                                                      simpl_bind env bind
238                                            ; simpl_binds dump env' binds }
239
240     trace_bind True  bind = pprTrace "SimplBind" (ppr (bindersOf bind))
241     trace_bind False _    = \x -> x
242
243     simpl_bind env (Rec pairs)  = simplRecBind      env  TopLevel pairs
244     simpl_bind env (NonRec b r) = simplRecOrTopPair env' TopLevel NonRecursive b b' r
245         where
246           (env', b') = addBndrRules env b (lookupRecBndr env b)
247 \end{code}
248
249
250 %************************************************************************
251 %*                                                                      *
252 \subsection{Lazy bindings}
253 %*                                                                      *
254 %************************************************************************
255
256 simplRecBind is used for
257         * recursive bindings only
258
259 \begin{code}
260 simplRecBind :: SimplEnv -> TopLevelFlag
261              -> [(InId, InExpr)]
262              -> SimplM SimplEnv
263 simplRecBind env0 top_lvl pairs0
264   = do  { let (env_with_info, triples) = mapAccumL add_rules env0 pairs0
265         ; env1 <- go (zapFloats env_with_info) triples
266         ; return (env0 `addRecFloats` env1) }
267         -- addFloats adds the floats from env1,
268         -- _and_ updates env0 with the in-scope set from env1
269   where
270     add_rules :: SimplEnv -> (InBndr,InExpr) -> (SimplEnv, (InBndr, OutBndr, InExpr))
271         -- Add the (substituted) rules to the binder
272     add_rules env (bndr, rhs) = (env', (bndr, bndr', rhs))
273         where
274           (env', bndr') = addBndrRules env bndr (lookupRecBndr env bndr)
275
276     go env [] = return env
277
278     go env ((old_bndr, new_bndr, rhs) : pairs)
279         = do { env' <- simplRecOrTopPair env top_lvl Recursive old_bndr new_bndr rhs
280              ; go env' pairs }
281 \end{code}
282
283 simplOrTopPair is used for
284         * recursive bindings (whether top level or not)
285         * top-level non-recursive bindings
286
287 It assumes the binder has already been simplified, but not its IdInfo.
288
289 \begin{code}
290 simplRecOrTopPair :: SimplEnv
291                   -> TopLevelFlag -> RecFlag
292                   -> InId -> OutBndr -> InExpr  -- Binder and rhs
293                   -> SimplM SimplEnv    -- Returns an env that includes the binding
294
295 simplRecOrTopPair env top_lvl is_rec old_bndr new_bndr rhs
296   = do dflags <- getDynFlags
297        -- Check for unconditional inline
298        if preInlineUnconditionally dflags env top_lvl old_bndr rhs
299            then do tick (PreInlineUnconditionally old_bndr)
300                    return (extendIdSubst env old_bndr (mkContEx env rhs))
301            else simplLazyBind env top_lvl is_rec old_bndr new_bndr rhs env
302 \end{code}
303
304
305 simplLazyBind is used for
306   * [simplRecOrTopPair] recursive bindings (whether top level or not)
307   * [simplRecOrTopPair] top-level non-recursive bindings
308   * [simplNonRecE]      non-top-level *lazy* non-recursive bindings
309
310 Nota bene:
311     1. It assumes that the binder is *already* simplified,
312        and is in scope, and its IdInfo too, except unfolding
313
314     2. It assumes that the binder type is lifted.
315
316     3. It does not check for pre-inline-unconditionallly;
317        that should have been done already.
318
319 \begin{code}
320 simplLazyBind :: SimplEnv
321               -> TopLevelFlag -> RecFlag
322               -> InId -> OutId          -- Binder, both pre-and post simpl
323                                         -- The OutId has IdInfo, except arity, unfolding
324               -> InExpr -> SimplEnv     -- The RHS and its environment
325               -> SimplM SimplEnv
326
327 simplLazyBind env top_lvl is_rec bndr bndr1 rhs rhs_se
328   = -- pprTrace "simplLazyBind" ((ppr bndr <+> ppr bndr1) $$ ppr rhs $$ ppr (seIdSubst rhs_se)) $
329     do  { let   rhs_env     = rhs_se `setInScope` env
330                 (tvs, body) = case collectTyBinders rhs of
331                                 (tvs, body) | not_lam body -> (tvs,body)
332                                             | otherwise    -> ([], rhs)
333                 not_lam (Lam _ _) = False
334                 not_lam _         = True
335                         -- Do not do the "abstract tyyvar" thing if there's
336                         -- a lambda inside, because it defeats eta-reduction
337                         --    f = /\a. \x. g a x
338                         -- should eta-reduce
339
340
341         ; (body_env, tvs') <- simplBinders rhs_env tvs
342                 -- See Note [Floating and type abstraction] in SimplUtils
343
344         -- Simplify the RHS
345         ; let   body_out_ty :: OutType
346                 body_out_ty = substTy body_env (exprType body)
347         ; (body_env1, body1) <- simplExprF body_env body (mkRhsStop body_out_ty)
348         -- ANF-ise a constructor or PAP rhs
349         ; (body_env2, body2) <- prepareRhs top_lvl body_env1 bndr1 body1
350
351         ; (env', rhs')
352             <-  if not (doFloatFromRhs top_lvl is_rec False body2 body_env2)
353                 then                            -- No floating, revert to body1
354                      do { rhs' <- mkLam env tvs' (wrapFloats body_env1 body1)
355                         ; return (env, rhs') }
356
357                 else if null tvs then           -- Simple floating
358                      do { tick LetFloatFromLet
359                         ; return (addFloats env body_env2, body2) }
360
361                 else                            -- Do type-abstraction first
362                      do { tick LetFloatFromLet
363                         ; (poly_binds, body3) <- abstractFloats tvs' body_env2 body2
364                         ; rhs' <- mkLam env tvs' body3
365                         ; env' <- foldlM (addPolyBind top_lvl) env poly_binds
366                         ; return (env', rhs') }
367
368         ; completeBind env' top_lvl bndr bndr1 rhs' }
369 \end{code}
370
371 A specialised variant of simplNonRec used when the RHS is already simplified,
372 notably in knownCon.  It uses case-binding where necessary.
373
374 \begin{code}
375 simplNonRecX :: SimplEnv
376              -> InId            -- Old binder
377              -> OutExpr         -- Simplified RHS
378              -> SimplM SimplEnv
379
380 simplNonRecX env bndr new_rhs
381   | isDeadBinder bndr   -- Not uncommon; e.g. case (a,b) of c { (p,q) -> p }
382   = return env          --               Here c is dead, and we avoid creating
383                         --               the binding c = (a,b)
384   | Coercion co <- new_rhs
385   = return (extendCvSubst env bndr co)
386   | otherwise           --               the binding b = (a,b)
387   = do  { (env', bndr') <- simplBinder env bndr
388         ; completeNonRecX NotTopLevel env' (isStrictId bndr) bndr bndr' new_rhs }
389                 -- simplNonRecX is only used for NotTopLevel things
390
391 completeNonRecX :: TopLevelFlag -> SimplEnv
392                 -> Bool
393                 -> InId                 -- Old binder
394                 -> OutId                -- New binder
395                 -> OutExpr              -- Simplified RHS
396                 -> SimplM SimplEnv
397
398 completeNonRecX top_lvl env is_strict old_bndr new_bndr new_rhs
399   = do  { (env1, rhs1) <- prepareRhs top_lvl (zapFloats env) new_bndr new_rhs
400         ; (env2, rhs2) <-
401                 if doFloatFromRhs NotTopLevel NonRecursive is_strict rhs1 env1
402                 then do { tick LetFloatFromLet
403                         ; return (addFloats env env1, rhs1) }   -- Add the floats to the main env
404                 else return (env, wrapFloats env1 rhs1)         -- Wrap the floats around the RHS
405         ; completeBind env2 NotTopLevel old_bndr new_bndr rhs2 }
406 \end{code}
407
408 {- No, no, no!  Do not try preInlineUnconditionally in completeNonRecX
409    Doing so risks exponential behaviour, because new_rhs has been simplified once already
410    In the cases described by the folowing commment, postInlineUnconditionally will
411    catch many of the relevant cases.
412         -- This happens; for example, the case_bndr during case of
413         -- known constructor:  case (a,b) of x { (p,q) -> ... }
414         -- Here x isn't mentioned in the RHS, so we don't want to
415         -- create the (dead) let-binding  let x = (a,b) in ...
416         --
417         -- Similarly, single occurrences can be inlined vigourously
418         -- e.g.  case (f x, g y) of (a,b) -> ....
419         -- If a,b occur once we can avoid constructing the let binding for them.
420
421    Furthermore in the case-binding case preInlineUnconditionally risks extra thunks
422         -- Consider     case I# (quotInt# x y) of
423         --                I# v -> let w = J# v in ...
424         -- If we gaily inline (quotInt# x y) for v, we end up building an
425         -- extra thunk:
426         --                let w = J# (quotInt# x y) in ...
427         -- because quotInt# can fail.
428
429   | preInlineUnconditionally env NotTopLevel bndr new_rhs
430   = thing_inside (extendIdSubst env bndr (DoneEx new_rhs))
431 -}
432
433 ----------------------------------
434 prepareRhs takes a putative RHS, checks whether it's a PAP or
435 constructor application and, if so, converts it to ANF, so that the
436 resulting thing can be inlined more easily.  Thus
437         x = (f a, g b)
438 becomes
439         t1 = f a
440         t2 = g b
441         x = (t1,t2)
442
443 We also want to deal well cases like this
444         v = (f e1 `cast` co) e2
445 Here we want to make e1,e2 trivial and get
446         x1 = e1; x2 = e2; v = (f x1 `cast` co) v2
447 That's what the 'go' loop in prepareRhs does
448
449 \begin{code}
450 prepareRhs :: TopLevelFlag -> SimplEnv -> OutId -> OutExpr -> SimplM (SimplEnv, OutExpr)
451 -- Adds new floats to the env iff that allows us to return a good RHS
452 prepareRhs top_lvl env id (Cast rhs co)    -- Note [Float coercions]
453   | Pair ty1 _ty2 <- coercionKind co       -- Do *not* do this if rhs has an unlifted type
454   , not (isUnLiftedType ty1)            -- see Note [Float coercions (unlifted)]
455   = do  { (env', rhs') <- makeTrivialWithInfo top_lvl env sanitised_info rhs
456         ; return (env', Cast rhs' co) }
457   where
458     sanitised_info = vanillaIdInfo `setStrictnessInfo` strictnessInfo info
459                                    `setDemandInfo` demandInfo info
460     info = idInfo id
461
462 prepareRhs top_lvl env0 _ rhs0
463   = do  { (_is_exp, env1, rhs1) <- go 0 env0 rhs0
464         ; return (env1, rhs1) }
465   where
466     go n_val_args env (Cast rhs co)
467         = do { (is_exp, env', rhs') <- go n_val_args env rhs
468              ; return (is_exp, env', Cast rhs' co) }
469     go n_val_args env (App fun (Type ty))
470         = do { (is_exp, env', rhs') <- go n_val_args env fun
471              ; return (is_exp, env', App rhs' (Type ty)) }
472     go n_val_args env (App fun arg)
473         = do { (is_exp, env', fun') <- go (n_val_args+1) env fun
474              ; case is_exp of
475                 True -> do { (env'', arg') <- makeTrivial top_lvl env' arg
476                            ; return (True, env'', App fun' arg') }
477                 False -> return (False, env, App fun arg) }
478     go n_val_args env (Var fun)
479         = return (is_exp, env, Var fun)
480         where
481           is_exp = isExpandableApp fun n_val_args   -- The fun a constructor or PAP
482                         -- See Note [CONLIKE pragma] in BasicTypes
483                         -- The definition of is_exp should match that in
484                         -- OccurAnal.occAnalApp
485
486     go _ env other
487         = return (False, env, other)
488 \end{code}
489
490
491 Note [Float coercions]
492 ~~~~~~~~~~~~~~~~~~~~~~
493 When we find the binding
494         x = e `cast` co
495 we'd like to transform it to
496         x' = e
497         x = x `cast` co         -- A trivial binding
498 There's a chance that e will be a constructor application or function, or something
499 like that, so moving the coerion to the usage site may well cancel the coersions
500 and lead to further optimisation.  Example:
501
502      data family T a :: *
503      data instance T Int = T Int
504
505      foo :: Int -> Int -> Int
506      foo m n = ...
507         where
508           x = T m
509           go 0 = 0
510           go n = case x of { T m -> go (n-m) }
511                 -- This case should optimise
512
513 Note [Preserve strictness when floating coercions]
514 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
515 In the Note [Float coercions] transformation, keep the strictness info.
516 Eg
517         f = e `cast` co    -- f has strictness SSL
518 When we transform to
519         f' = e             -- f' also has strictness SSL
520         f = f' `cast` co   -- f still has strictness SSL
521
522 Its not wrong to drop it on the floor, but better to keep it.
523
524 Note [Float coercions (unlifted)]
525 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
526 BUT don't do [Float coercions] if 'e' has an unlifted type.
527 This *can* happen:
528
529      foo :: Int = (error (# Int,Int #) "urk")
530                   `cast` CoUnsafe (# Int,Int #) Int
531
532 If do the makeTrivial thing to the error call, we'll get
533     foo = case error (# Int,Int #) "urk" of v -> v `cast` ...
534 But 'v' isn't in scope!
535
536 These strange casts can happen as a result of case-of-case
537         bar = case (case x of { T -> (# 2,3 #); F -> error "urk" }) of
538                 (# p,q #) -> p+q
539
540
541 \begin{code}
542 makeTrivialArg :: SimplEnv -> ArgSpec -> SimplM (SimplEnv, ArgSpec)
543 makeTrivialArg env (ValArg e)  = do { (env', e') <- makeTrivial NotTopLevel env e
544                                     ; return (env', ValArg e') }
545 makeTrivialArg env (CastBy co) = return (env, CastBy co)
546
547 makeTrivial :: TopLevelFlag -> SimplEnv -> OutExpr -> SimplM (SimplEnv, OutExpr)
548 -- Binds the expression to a variable, if it's not trivial, returning the variable
549 makeTrivial top_lvl env expr = makeTrivialWithInfo top_lvl env vanillaIdInfo expr
550
551 makeTrivialWithInfo :: TopLevelFlag -> SimplEnv -> IdInfo
552                     -> OutExpr -> SimplM (SimplEnv, OutExpr)
553 -- Propagate strictness and demand info to the new binder
554 -- Note [Preserve strictness when floating coercions]
555 -- Returned SimplEnv has same substitution as incoming one
556 makeTrivialWithInfo top_lvl env info expr
557   | exprIsTrivial expr                          -- Already trivial
558   || not (bindingOk top_lvl expr expr_ty)       -- Cannot trivialise
559                                                 --   See Note [Cannot trivialise]
560   = return (env, expr)
561   | otherwise           -- See Note [Take care] below
562   = do  { uniq <- getUniqueM
563         ; let name = mkSystemVarName uniq (fsLit "a")
564               var = mkLocalIdWithInfo name expr_ty info
565         ; env'  <- completeNonRecX top_lvl env False var var expr
566         ; expr' <- simplVar env' var
567         ; return (env', expr') }
568         -- The simplVar is needed becase we're constructing a new binding
569         --     a = rhs
570         -- And if rhs is of form (rhs1 |> co), then we might get
571         --     a1 = rhs1
572         --     a = a1 |> co
573         -- and now a's RHS is trivial and can be substituted out, and that
574         -- is what completeNonRecX will do
575         -- To put it another way, it's as if we'd simplified
576         --    let var = e in var
577   where
578     expr_ty = exprType expr
579
580 bindingOk :: TopLevelFlag -> CoreExpr -> Type -> Bool
581 -- True iff we can have a binding of this expression at this level
582 -- Precondition: the type is the type of the expression
583 bindingOk top_lvl _ expr_ty
584   | isTopLevel top_lvl = not (isUnLiftedType expr_ty)
585   | otherwise          = True
586 \end{code}
587
588 Note [Cannot trivialise]
589 ~~~~~~~~~~~~~~~~~~~~~~~~
590 Consider tih
591    f :: Int -> Addr#
592
593    foo :: Bar
594    foo = Bar (f 3)
595
596 Then we can't ANF-ise foo, even though we'd like to, because
597 we can't make a top-level binding for the Addr# (f 3). And if
598 so we don't want to turn it into
599    foo = let x = f 3 in Bar x
600 because we'll just end up inlining x back, and that makes the
601 simplifier loop.  Better not to ANF-ise it at all.
602
603 A case in point is literal strings (a MachStr is not regarded as
604 trivial):
605
606    foo = Ptr "blob"#
607
608 We don't want to ANF-ise this.
609
610 %************************************************************************
611 %*                                                                      *
612 \subsection{Completing a lazy binding}
613 %*                                                                      *
614 %************************************************************************
615
616 completeBind
617   * deals only with Ids, not TyVars
618   * takes an already-simplified binder and RHS
619   * is used for both recursive and non-recursive bindings
620   * is used for both top-level and non-top-level bindings
621
622 It does the following:
623   - tries discarding a dead binding
624   - tries PostInlineUnconditionally
625   - add unfolding [this is the only place we add an unfolding]
626   - add arity
627
628 It does *not* attempt to do let-to-case.  Why?  Because it is used for
629   - top-level bindings (when let-to-case is impossible)
630   - many situations where the "rhs" is known to be a WHNF
631                 (so let-to-case is inappropriate).
632
633 Nor does it do the atomic-argument thing
634
635 \begin{code}
636 completeBind :: SimplEnv
637              -> TopLevelFlag            -- Flag stuck into unfolding
638              -> InId                    -- Old binder
639              -> OutId -> OutExpr        -- New binder and RHS
640              -> SimplM SimplEnv
641 -- completeBind may choose to do its work
642 --      * by extending the substitution (e.g. let x = y in ...)
643 --      * or by adding to the floats in the envt
644
645 completeBind env top_lvl old_bndr new_bndr new_rhs
646  | isCoVar old_bndr
647  = case new_rhs of
648      Coercion co -> return (extendCvSubst env old_bndr co)
649      _           -> return (addNonRec env new_bndr new_rhs)
650
651  | otherwise
652  = ASSERT( isId new_bndr )
653    do { let old_info = idInfo old_bndr
654             old_unf  = unfoldingInfo old_info
655             occ_info = occInfo old_info
656
657         -- Do eta-expansion on the RHS of the binding
658         -- See Note [Eta-expanding at let bindings] in SimplUtils
659       ; (new_arity, final_rhs) <- tryEtaExpand env new_bndr new_rhs
660
661         -- Simplify the unfolding
662       ; new_unfolding <- simplUnfolding env top_lvl old_bndr final_rhs old_unf
663
664       ; dflags <- getDynFlags
665       ; if postInlineUnconditionally dflags env top_lvl new_bndr occ_info
666                                      final_rhs new_unfolding
667
668                         -- Inline and discard the binding
669         then do  { tick (PostInlineUnconditionally old_bndr)
670                  ; return (extendIdSubst env old_bndr (DoneEx final_rhs)) }
671                 -- Use the substitution to make quite, quite sure that the
672                 -- substitution will happen, since we are going to discard the binding
673         else
674    do { let info1 = idInfo new_bndr `setArityInfo` new_arity
675
676               -- Unfolding info: Note [Setting the new unfolding]
677             info2 = info1 `setUnfoldingInfo` new_unfolding
678
679               -- Demand info: Note [Setting the demand info]
680               --
681               -- We also have to nuke demand info if for some reason
682               -- eta-expansion *reduces* the arity of the binding to less
683               -- than that of the strictness sig. This can happen: see Note [Arity decrease].
684             info3 | isEvaldUnfolding new_unfolding
685                     || (case strictnessInfo info2 of
686                           StrictSig dmd_ty -> new_arity < dmdTypeDepth dmd_ty)
687                   = zapDemandInfo info2 `orElse` info2
688                   | otherwise
689                   = info2
690
691             final_id = new_bndr `setIdInfo` info3
692
693       ; -- pprTrace "Binding" (ppr final_id <+> ppr new_unfolding) $
694         return (addNonRec env final_id final_rhs) } }
695                 -- The addNonRec adds it to the in-scope set too
696
697 ------------------------------
698 addPolyBind :: TopLevelFlag -> SimplEnv -> OutBind -> SimplM SimplEnv
699 -- Add a new binding to the environment, complete with its unfolding
700 -- but *do not* do postInlineUnconditionally, because we have already
701 -- processed some of the scope of the binding
702 -- We still want the unfolding though.  Consider
703 --      let
704 --            x = /\a. let y = ... in Just y
705 --      in body
706 -- Then we float the y-binding out (via abstractFloats and addPolyBind)
707 -- but 'x' may well then be inlined in 'body' in which case we'd like the
708 -- opportunity to inline 'y' too.
709 --
710 -- INVARIANT: the arity is correct on the incoming binders
711
712 addPolyBind top_lvl env (NonRec poly_id rhs)
713   = do  { unfolding <- simplUnfolding env top_lvl poly_id rhs noUnfolding
714                         -- Assumes that poly_id did not have an INLINE prag
715                         -- which is perhaps wrong.  ToDo: think about this
716         ; let final_id = setIdInfo poly_id $
717                          idInfo poly_id `setUnfoldingInfo` unfolding
718
719         ; return (addNonRec env final_id rhs) }
720
721 addPolyBind _ env bind@(Rec _)
722   = return (extendFloats env bind)
723         -- Hack: letrecs are more awkward, so we extend "by steam"
724         -- without adding unfoldings etc.  At worst this leads to
725         -- more simplifier iterations
726
727 ------------------------------
728 simplUnfolding :: SimplEnv-> TopLevelFlag
729                -> InId
730                -> OutExpr
731                -> Unfolding -> SimplM Unfolding
732 -- Note [Setting the new unfolding]
733 simplUnfolding env _ _ _ df@(DFunUnfolding { df_bndrs = bndrs, df_args = args })
734   = do { (env', bndrs') <- simplBinders env bndrs
735        ; args' <- mapM (simplExpr env') args
736        ; return (df { df_bndrs = bndrs', df_args  = args' }) }
737
738 simplUnfolding env top_lvl id _
739     (CoreUnfolding { uf_tmpl = expr, uf_arity = arity
740                    , uf_src = src, uf_guidance = guide })
741   | isStableSource src
742   = do { expr' <- simplExpr rule_env expr
743        ; let is_top_lvl = isTopLevel top_lvl
744        ; case guide of
745            UnfWhen sat_ok _    -- Happens for INLINE things
746               -> let guide' = UnfWhen sat_ok (inlineBoringOk expr')
747                      -- Refresh the boring-ok flag, in case expr'
748                      -- has got small. This happens, notably in the inlinings
749                      -- for dfuns for single-method classes; see
750                      -- Note [Single-method classes] in TcInstDcls.
751                      -- A test case is Trac #4138
752                  in return (mkCoreUnfolding src is_top_lvl expr' arity guide')
753                  -- See Note [Top-level flag on inline rules] in CoreUnfold
754
755            _other              -- Happens for INLINABLE things
756               -> let bottoming = isBottomingId id
757                  in bottoming `seq` -- See Note [Force bottoming field]
758                     do dflags <- getDynFlags
759                        return (mkUnfolding dflags src is_top_lvl bottoming expr')
760                 -- If the guidance is UnfIfGoodArgs, this is an INLINABLE
761                 -- unfolding, and we need to make sure the guidance is kept up
762                 -- to date with respect to any changes in the unfolding.
763        }
764   where
765     act      = idInlineActivation id
766     rule_env = updMode (updModeForInlineRules act) env
767                -- See Note [Simplifying inside InlineRules] in SimplUtils
768
769 simplUnfolding _ top_lvl id new_rhs _
770   = let bottoming = isBottomingId id
771     in bottoming `seq`  -- See Note [Force bottoming field]
772        do dflags <- getDynFlags
773           return (mkUnfolding dflags InlineRhs (isTopLevel top_lvl) bottoming new_rhs)
774           -- We make an  unfolding *even for loop-breakers*.
775           -- Reason: (a) It might be useful to know that they are WHNF
776           --         (b) In TidyPgm we currently assume that, if we want to
777           --             expose the unfolding then indeed we *have* an unfolding
778           --             to expose.  (We could instead use the RHS, but currently
779           --             we don't.)  The simple thing is always to have one.
780 \end{code}
781
782 Note [Force bottoming field]
783 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
784 We need to force bottoming, or the new unfolding holds
785 on to the old unfolding (which is part of the id).
786
787 Note [Arity decrease]
788 ~~~~~~~~~~~~~~~~~~~~~
789 Generally speaking the arity of a binding should not decrease.  But it *can*
790 legitimately happen because of RULES.  Eg
791         f = g Int
792 where g has arity 2, will have arity 2.  But if there's a rewrite rule
793         g Int --> h
794 where h has arity 1, then f's arity will decrease.  Here's a real-life example,
795 which is in the output of Specialise:
796
797      Rec {
798         $dm {Arity 2} = \d.\x. op d
799         {-# RULES forall d. $dm Int d = $s$dm #-}
800
801         dInt = MkD .... opInt ...
802         opInt {Arity 1} = $dm dInt
803
804         $s$dm {Arity 0} = \x. op dInt }
805
806 Here opInt has arity 1; but when we apply the rule its arity drops to 0.
807 That's why Specialise goes to a little trouble to pin the right arity
808 on specialised functions too.
809
810 Note [Setting the new unfolding]
811 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
812 * If there's an INLINE pragma, we simplify the RHS gently.  Maybe we
813   should do nothing at all, but simplifying gently might get rid of
814   more crap.
815
816 * If not, we make an unfolding from the new RHS.  But *only* for
817   non-loop-breakers. Making loop breakers not have an unfolding at all
818   means that we can avoid tests in exprIsConApp, for example.  This is
819   important: if exprIsConApp says 'yes' for a recursive thing, then we
820   can get into an infinite loop
821
822 If there's an InlineRule on a loop breaker, we hang on to the inlining.
823 It's pretty dodgy, but the user did say 'INLINE'.  May need to revisit
824 this choice.
825
826 Note [Setting the demand info]
827 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
828 If the unfolding is a value, the demand info may
829 go pear-shaped, so we nuke it.  Example:
830      let x = (a,b) in
831      case x of (p,q) -> h p q x
832 Here x is certainly demanded. But after we've nuked
833 the case, we'll get just
834      let x = (a,b) in h a b x
835 and now x is not demanded (I'm assuming h is lazy)
836 This really happens.  Similarly
837      let f = \x -> e in ...f..f...
838 After inlining f at some of its call sites the original binding may
839 (for example) be no longer strictly demanded.
840 The solution here is a bit ad hoc...
841
842
843 %************************************************************************
844 %*                                                                      *
845 \subsection[Simplify-simplExpr]{The main function: simplExpr}
846 %*                                                                      *
847 %************************************************************************
848
849 The reason for this OutExprStuff stuff is that we want to float *after*
850 simplifying a RHS, not before.  If we do so naively we get quadratic
851 behaviour as things float out.
852
853 To see why it's important to do it after, consider this (real) example:
854
855         let t = f x
856         in fst t
857 ==>
858         let t = let a = e1
859                     b = e2
860                 in (a,b)
861         in fst t
862 ==>
863         let a = e1
864             b = e2
865             t = (a,b)
866         in
867         a       -- Can't inline a this round, cos it appears twice
868 ==>
869         e1
870
871 Each of the ==> steps is a round of simplification.  We'd save a
872 whole round if we float first.  This can cascade.  Consider
873
874         let f = g d
875         in \x -> ...f...
876 ==>
877         let f = let d1 = ..d.. in \y -> e
878         in \x -> ...f...
879 ==>
880         let d1 = ..d..
881         in \x -> ...(\y ->e)...
882
883 Only in this second round can the \y be applied, and it
884 might do the same again.
885
886
887 \begin{code}
888 simplExpr :: SimplEnv -> CoreExpr -> SimplM CoreExpr
889 simplExpr env expr = simplExprC env expr (mkBoringStop expr_out_ty)
890   where
891     expr_out_ty :: OutType
892     expr_out_ty = substTy env (exprType expr)
893
894 simplExprC :: SimplEnv -> CoreExpr -> SimplCont -> SimplM CoreExpr
895         -- Simplify an expression, given a continuation
896 simplExprC env expr cont
897   = -- pprTrace "simplExprC" (ppr expr $$ ppr cont {- $$ ppr (seIdSubst env) -} $$ ppr (seFloats env) ) $
898     do  { (env', expr') <- simplExprF (zapFloats env) expr cont
899         ; -- pprTrace "simplExprC ret" (ppr expr $$ ppr expr') $
900           -- pprTrace "simplExprC ret3" (ppr (seInScope env')) $
901           -- pprTrace "simplExprC ret4" (ppr (seFloats env')) $
902           return (wrapFloats env' expr') }
903
904 --------------------------------------------------
905 simplExprF :: SimplEnv -> InExpr -> SimplCont
906            -> SimplM (SimplEnv, OutExpr)
907
908 simplExprF env e cont
909   = {- pprTrace "simplExprF" (vcat
910       [ ppr e
911       , text "cont =" <+> ppr cont
912       , text "inscope =" <+> ppr (seInScope env)
913       , text "tvsubst =" <+> ppr (seTvSubst env)
914       , text "idsubst =" <+> ppr (seIdSubst env)
915       , text "cvsubst =" <+> ppr (seCvSubst env)
916       {- , ppr (seFloats env) -}
917       ]) $ -}
918     simplExprF1 env e cont
919
920 simplExprF1 :: SimplEnv -> InExpr -> SimplCont
921             -> SimplM (SimplEnv, OutExpr)
922 simplExprF1 env (Var v)        cont = simplIdF env v cont
923 simplExprF1 env (Lit lit)      cont = rebuild env (Lit lit) cont
924 simplExprF1 env (Tick t expr)  cont = simplTick env t expr cont
925 simplExprF1 env (Cast body co) cont = simplCast env body co cont
926 simplExprF1 env (Coercion co)  cont = simplCoercionF env co cont
927 simplExprF1 env (Type ty)      cont = ASSERT( contIsRhsOrArg cont )
928                                       rebuild env (Type (substTy env ty)) cont
929 simplExprF1 env (App fun arg)  cont = simplExprF env fun $
930                                       ApplyTo NoDup arg env cont
931
932 simplExprF1 env expr@(Lam {}) cont
933   = simplLam env zapped_bndrs body cont
934         -- The main issue here is under-saturated lambdas
935         --   (\x1. \x2. e) arg1
936         -- Here x1 might have "occurs-once" occ-info, because occ-info
937         -- is computed assuming that a group of lambdas is applied
938         -- all at once.  If there are too few args, we must zap the
939         -- occ-info, UNLESS the remaining binders are one-shot
940   where
941     (bndrs, body) = collectBinders expr
942     zapped_bndrs | need_to_zap = map zap bndrs
943                  | otherwise   = bndrs
944
945     need_to_zap = any zappable_bndr (drop n_args bndrs)
946     n_args = countArgs cont
947         -- NB: countArgs counts all the args (incl type args)
948         -- and likewise drop counts all binders (incl type lambdas)
949
950     zappable_bndr b = isId b && not (isOneShotBndr b)
951     zap b | isTyVar b = b
952           | otherwise = zapLamIdInfo b
953
954 simplExprF1 env (Case scrut bndr alts_ty alts) cont
955   | sm_case_case (getMode env)
956   =     -- Simplify the scrutinee with a Select continuation
957     simplExprF env scrut (Select NoDup bndr alts env cont)
958
959   | otherwise
960   =     -- If case-of-case is off, simply simplify the case expression
961         -- in a vanilla Stop context, and rebuild the result around it
962     do  { case_expr' <- simplExprC env scrut
963                              (Select NoDup bndr alts env (mkBoringStop alts_out_ty))
964         ; rebuild env case_expr' cont }
965   where
966     alts_out_ty = substTy env alts_ty
967
968 simplExprF1 env (Let (Rec pairs) body) cont
969   = do  { env' <- simplRecBndrs env (map fst pairs)
970                 -- NB: bndrs' don't have unfoldings or rules
971                 -- We add them as we go down
972
973         ; env'' <- simplRecBind env' NotTopLevel pairs
974         ; simplExprF env'' body cont }
975
976 simplExprF1 env (Let (NonRec bndr rhs) body) cont
977   = simplNonRecE env bndr (rhs, env) ([], body) cont
978
979 ---------------------------------
980 simplType :: SimplEnv -> InType -> SimplM OutType
981         -- Kept monadic just so we can do the seqType
982 simplType env ty
983   = -- pprTrace "simplType" (ppr ty $$ ppr (seTvSubst env)) $
984     seqType new_ty `seq` return new_ty
985   where
986     new_ty = substTy env ty
987
988 ---------------------------------
989 simplCoercionF :: SimplEnv -> InCoercion -> SimplCont
990                -> SimplM (SimplEnv, OutExpr)
991 simplCoercionF env co cont
992   = do { co' <- simplCoercion env co
993        ; rebuild env (Coercion co') cont }
994
995 simplCoercion :: SimplEnv -> InCoercion -> SimplM OutCoercion
996 simplCoercion env co
997   = let opt_co = optCoercion (getCvSubst env) co
998     in seqCo opt_co `seq` return opt_co
999
1000 -----------------------------------
1001 -- | Push a TickIt context outwards past applications and cases, as
1002 -- long as this is a non-scoping tick, to let case and application
1003 -- optimisations apply.
1004
1005 simplTick :: SimplEnv -> Tickish Id -> InExpr -> SimplCont
1006           -> SimplM (SimplEnv, OutExpr)
1007 simplTick env tickish expr cont
1008   -- A scoped tick turns into a continuation, so that we can spot
1009   -- (scc t (\x . e)) in simplLam and eliminate the scc.  If we didn't do
1010   -- it this way, then it would take two passes of the simplifier to
1011   -- reduce ((scc t (\x . e)) e').
1012   -- NB, don't do this with counting ticks, because if the expr is
1013   -- bottom, then rebuildCall will discard the continuation.
1014
1015 -- XXX: we cannot do this, because the simplifier assumes that
1016 -- the context can be pushed into a case with a single branch. e.g.
1017 --    scc<f>  case expensive of p -> e
1018 -- becomes
1019 --    case expensive of p -> scc<f> e
1020 --
1021 -- So I'm disabling this for now.  It just means we will do more
1022 -- simplifier iterations that necessary in some cases.
1023
1024 --  | tickishScoped tickish && not (tickishCounts tickish)
1025 --  = simplExprF env expr (TickIt tickish cont)
1026
1027   -- For non-scoped ticks, we push the continuation inside the
1028   -- tick.  This has the effect of moving the tick to the outside of a
1029   -- case or application context, allowing the normal case and
1030   -- application optimisations to fire.
1031   | not (tickishScoped tickish)
1032   = do { (env', expr') <- simplExprF env expr cont
1033        ; return (env', mkTick tickish expr')
1034        }
1035
1036   -- For breakpoints, we cannot do any floating of bindings around the
1037   -- tick, because breakpoints cannot be split into tick/scope pairs.
1038   | not (tickishCanSplit tickish)
1039   = no_floating_past_tick
1040
1041   | interesting_cont, Just expr' <- push_tick_inside tickish expr
1042     -- see Note [case-of-scc-of-case]
1043   = simplExprF env expr' cont
1044
1045   | otherwise
1046   = no_floating_past_tick -- was: wrap_floats, see below
1047
1048  where
1049   interesting_cont = case cont of
1050                         Select {} -> True
1051                         _ -> False
1052
1053   push_tick_inside t expr0
1054      | not (tickishCanSplit t) = Nothing
1055      | otherwise
1056        = case expr0 of
1057            Tick t' expr
1058               -- scc t (tick t' E)
1059               --   Pull the tick to the outside
1060               -- This one is important for #5363
1061               | not (tickishScoped t')
1062                  -> Just (Tick t' (Tick t expr))
1063
1064               -- scc t (scc t' E)
1065               --   Try to push t' into E first, and if that works,
1066               --   try to push t in again
1067               | Just expr' <- push_tick_inside t' expr
1068                  -> push_tick_inside t expr'
1069
1070               | otherwise -> Nothing
1071
1072            Case scrut bndr ty alts
1073               -> Just (Case (mkTick t scrut) bndr ty alts')
1074              where t_scope = mkNoTick t -- drop the tick on the dup'd ones
1075                    alts'   = [ (c,bs, mkTick t_scope e) | (c,bs,e) <- alts]
1076            _other -> Nothing
1077     where
1078
1079   no_floating_past_tick =
1080     do { let (inc,outc) = splitCont cont
1081        ; (env', expr') <- simplExprF (zapFloats env) expr inc
1082        ; let tickish' = simplTickish env tickish
1083        ; (env'', expr'') <- rebuild (zapFloats env')
1084                                     (wrapFloats env' expr')
1085                                     (TickIt tickish' outc)
1086        ; return (addFloats env env'', expr'')
1087        }
1088
1089 -- Alternative version that wraps outgoing floats with the tick.  This
1090 -- results in ticks being duplicated, as we don't make any attempt to
1091 -- eliminate the tick if we re-inline the binding (because the tick
1092 -- semantics allows unrestricted inlining of HNFs), so I'm not doing
1093 -- this any more.  FloatOut will catch any real opportunities for
1094 -- floating.
1095 --
1096 --  wrap_floats =
1097 --    do { let (inc,outc) = splitCont cont
1098 --       ; (env', expr') <- simplExprF (zapFloats env) expr inc
1099 --       ; let tickish' = simplTickish env tickish
1100 --       ; let wrap_float (b,rhs) = (zapIdStrictness (setIdArity b 0),
1101 --                                   mkTick (mkNoTick tickish') rhs)
1102 --              -- when wrapping a float with mkTick, we better zap the Id's
1103 --              -- strictness info and arity, because it might be wrong now.
1104 --       ; let env'' = addFloats env (mapFloats env' wrap_float)
1105 --       ; rebuild env'' expr' (TickIt tickish' outc)
1106 --       }
1107
1108
1109   simplTickish env tickish
1110     | Breakpoint n ids <- tickish
1111           = Breakpoint n (map (getDoneId . substId env) ids)
1112     | otherwise = tickish
1113
1114   -- push type application and coercion inside a tick
1115   splitCont :: SimplCont -> (SimplCont, SimplCont)
1116   splitCont (ApplyTo f (Type t) env c) = (ApplyTo f (Type t) env inc, outc)
1117     where (inc,outc) = splitCont c
1118   splitCont (CoerceIt co c) = (CoerceIt co inc, outc)
1119     where (inc,outc) = splitCont c
1120   splitCont other = (mkBoringStop (contInputType other), other)
1121
1122   getDoneId (DoneId id) = id
1123   getDoneId (DoneEx e)  = getIdFromTrivialExpr e -- Note [substTickish] in CoreSubst
1124   getDoneId other = pprPanic "getDoneId" (ppr other)
1125
1126 -- Note [case-of-scc-of-case]
1127 -- It's pretty important to be able to transform case-of-case when
1128 -- there's an SCC in the way.  For example, the following comes up
1129 -- in nofib/real/compress/Encode.hs:
1130 --
1131 --        case scctick<code_string.r1>
1132 --             case $wcode_string_r13s wild_XC w1_s137 w2_s138 l_aje
1133 --             of _ { (# ww1_s13f, ww2_s13g, ww3_s13h #) ->
1134 --             (ww1_s13f, ww2_s13g, ww3_s13h)
1135 --             }
1136 --        of _ { (ww_s12Y, ww1_s12Z, ww2_s130) ->
1137 --        tick<code_string.f1>
1138 --        (ww_s12Y,
1139 --         ww1_s12Z,
1140 --         PTTrees.PT
1141 --           @ GHC.Types.Char @ GHC.Types.Int wild2_Xj ww2_s130 r_ajf)
1142 --        }
1143 --
1144 -- We really want this case-of-case to fire, because then the 3-tuple
1145 -- will go away (indeed, the CPR optimisation is relying on this
1146 -- happening).  But the scctick is in the way - we need to push it
1147 -- inside to expose the case-of-case.  So we perform this
1148 -- transformation on the inner case:
1149 --
1150 --   scctick c (case e of { p1 -> e1; ...; pn -> en })
1151 --    ==>
1152 --   case (scctick c e) of { p1 -> scc c e1; ...; pn -> scc c en }
1153 --
1154 -- So we've moved a constant amount of work out of the scc to expose
1155 -- the case.  We only do this when the continuation is interesting: in
1156 -- for now, it has to be another Case (maybe generalise this later).
1157 \end{code}
1158
1159
1160 %************************************************************************
1161 %*                                                                      *
1162 \subsection{The main rebuilder}
1163 %*                                                                      *
1164 %************************************************************************
1165
1166 \begin{code}
1167 rebuild :: SimplEnv -> OutExpr -> SimplCont -> SimplM (SimplEnv, OutExpr)
1168 -- At this point the substitution in the SimplEnv should be irrelevant
1169 -- only the in-scope set and floats should matter
1170 rebuild env expr cont
1171   = case cont of
1172       Stop {}                       -> return (env, expr)
1173       CoerceIt co cont              -> rebuild env (mkCast expr co) cont
1174                                     -- NB: mkCast implements the (Coercion co |> g) optimisation
1175       Select _ bndr alts se cont    -> rebuildCase (se `setFloats` env) expr bndr alts cont
1176       StrictArg info _ cont         -> rebuildCall env (info `addArgTo` expr) cont
1177       StrictBind b bs body se cont  -> do { env' <- simplNonRecX (se `setFloats` env) b expr
1178                                           ; simplLam env' bs body cont }
1179       ApplyTo dup_flag arg se cont  -- See Note [Avoid redundant simplification]
1180         | isSimplified dup_flag     -> rebuild env (App expr arg) cont
1181         | otherwise                 -> do { arg' <- simplExpr (se `setInScope` env) arg
1182                                           ; rebuild env (App expr arg') cont }
1183       TickIt t cont                 -> rebuild env (mkTick t expr) cont
1184 \end{code}
1185
1186
1187 %************************************************************************
1188 %*                                                                      *
1189 \subsection{Lambdas}
1190 %*                                                                      *
1191 %************************************************************************
1192
1193 \begin{code}
1194 simplCast :: SimplEnv -> InExpr -> Coercion -> SimplCont
1195           -> SimplM (SimplEnv, OutExpr)
1196 simplCast env body co0 cont0
1197   = do  { co1 <- simplCoercion env co0
1198         ; -- pprTrace "simplCast" (ppr co1) $
1199           simplExprF env body (addCoerce co1 cont0) }
1200   where
1201        addCoerce co cont = add_coerce co (coercionKind co) cont
1202
1203        add_coerce _co (Pair s1 k1) cont     -- co :: ty~ty
1204          | s1 `eqType` k1 = cont    -- is a no-op
1205
1206        add_coerce co1 (Pair s1 _k2) (CoerceIt co2 cont)
1207          | (Pair _l1 t1) <- coercionKind co2
1208                 --      e |> (g1 :: S1~L) |> (g2 :: L~T1)
1209                 -- ==>
1210                 --      e,                       if S1=T1
1211                 --      e |> (g1 . g2 :: S1~T1)  otherwise
1212                 --
1213                 -- For example, in the initial form of a worker
1214                 -- we may find  (coerce T (coerce S (\x.e))) y
1215                 -- and we'd like it to simplify to e[y/x] in one round
1216                 -- of simplification
1217          , s1 `eqType` t1  = cont            -- The coerces cancel out
1218          | otherwise       = CoerceIt (mkTransCo co1 co2) cont
1219
1220        add_coerce co (Pair s1s2 _t1t2) (ApplyTo dup (Type arg_ty) arg_se cont)
1221                 -- (f |> g) ty  --->   (f ty) |> (g @ ty)
1222                 -- This implements the PushT rule from the paper
1223          | Just (tyvar,_) <- splitForAllTy_maybe s1s2
1224          = ASSERT( isTyVar tyvar )
1225            ApplyTo Simplified (Type arg_ty') (zapSubstEnv arg_se) (addCoerce new_cast cont)
1226          where
1227            new_cast = mkInstCo co arg_ty'
1228            arg_ty' | isSimplified dup = arg_ty
1229                    | otherwise        = substTy (arg_se `setInScope` env) arg_ty
1230
1231        add_coerce co (Pair s1s2 t1t2) (ApplyTo dup arg arg_se cont)
1232          | isFunTy s1s2   -- This implements the Push rule from the paper
1233          , isFunTy t1t2   -- Check t1t2 to ensure 'arg' is a value arg
1234                 --      (e |> (g :: s1s2 ~ t1->t2)) f
1235                 -- ===>
1236                 --      (e (f |> (arg g :: t1~s1))
1237                 --      |> (res g :: s2->t2)
1238                 --
1239                 -- t1t2 must be a function type, t1->t2, because it's applied
1240                 -- to something but s1s2 might conceivably not be
1241                 --
1242                 -- When we build the ApplyTo we can't mix the out-types
1243                 -- with the InExpr in the argument, so we simply substitute
1244                 -- to make it all consistent.  It's a bit messy.
1245                 -- But it isn't a common case.
1246                 --
1247                 -- Example of use: Trac #995
1248          = ApplyTo dup new_arg (zapSubstEnv arg_se) (addCoerce co2 cont)
1249          where
1250            -- we split coercion t1->t2 ~ s1->s2 into t1 ~ s1 and
1251            -- t2 ~ s2 with left and right on the curried form:
1252            --    (->) t1 t2 ~ (->) s1 s2
1253            [co1, co2] = decomposeCo 2 co
1254            new_arg    = mkCast arg' (mkSymCo co1)
1255            arg'       = substExpr (text "move-cast") arg_se' arg
1256            arg_se'    = arg_se `setInScope` env
1257
1258        add_coerce co _ cont = CoerceIt co cont
1259 \end{code}
1260
1261
1262 %************************************************************************
1263 %*                                                                      *
1264 \subsection{Lambdas}
1265 %*                                                                      *
1266 %************************************************************************
1267
1268 Note [Zap unfolding when beta-reducing]
1269 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1270 Lambda-bound variables can have stable unfoldings, such as
1271    $j = \x. \b{Unf=Just x}. e
1272 See Note [Case binders and join points] below; the unfolding for lets
1273 us optimise e better.  However when we beta-reduce it we want to
1274 revert to using the actual value, otherwise we can end up in the
1275 stupid situation of
1276           let x = blah in
1277           let b{Unf=Just x} = y
1278           in ...b...
1279 Here it'd be far better to drop the unfolding and use the actual RHS.
1280
1281 \begin{code}
1282 simplLam :: SimplEnv -> [InId] -> InExpr -> SimplCont
1283          -> SimplM (SimplEnv, OutExpr)
1284
1285 simplLam env [] body cont = simplExprF env body cont
1286
1287         -- Beta reduction
1288 simplLam env (bndr:bndrs) body (ApplyTo _ arg arg_se cont)
1289   = do  { tick (BetaReduction bndr)
1290         ; simplNonRecE env (zap_unfolding bndr) (arg, arg_se) (bndrs, body) cont }
1291   where
1292     zap_unfolding bndr  -- See Note [Zap unfolding when beta-reducing]
1293       | isId bndr, isStableUnfolding (realIdUnfolding bndr)
1294       = setIdUnfolding bndr NoUnfolding
1295       | otherwise = bndr
1296
1297       -- discard a non-counting tick on a lambda.  This may change the
1298       -- cost attribution slightly (moving the allocation of the
1299       -- lambda elsewhere), but we don't care: optimisation changes
1300       -- cost attribution all the time.
1301 simplLam env bndrs body (TickIt tickish cont)
1302   | not (tickishCounts tickish)
1303   = simplLam env bndrs body cont
1304
1305         -- Not enough args, so there are real lambdas left to put in the result
1306 simplLam env bndrs body cont
1307   = do  { (env', bndrs') <- simplLamBndrs env bndrs
1308         ; body' <- simplExpr env' body
1309         ; new_lam <- mkLam env' bndrs' body'
1310         ; rebuild env' new_lam cont }
1311
1312 ------------------
1313 simplNonRecE :: SimplEnv
1314              -> InBndr                  -- The binder
1315              -> (InExpr, SimplEnv)      -- Rhs of binding (or arg of lambda)
1316              -> ([InBndr], InExpr)      -- Body of the let/lambda
1317                                         --      \xs.e
1318              -> SimplCont
1319              -> SimplM (SimplEnv, OutExpr)
1320
1321 -- simplNonRecE is used for
1322 --  * non-top-level non-recursive lets in expressions
1323 --  * beta reduction
1324 --
1325 -- It deals with strict bindings, via the StrictBind continuation,
1326 -- which may abort the whole process
1327 --
1328 -- The "body" of the binding comes as a pair of ([InId],InExpr)
1329 -- representing a lambda; so we recurse back to simplLam
1330 -- Why?  Because of the binder-occ-info-zapping done before
1331 --       the call to simplLam in simplExprF (Lam ...)
1332
1333         -- First deal with type applications and type lets
1334         --   (/\a. e) (Type ty)   and   (let a = Type ty in e)
1335 simplNonRecE env bndr (Type ty_arg, rhs_se) (bndrs, body) cont
1336   = ASSERT( isTyVar bndr )
1337     do  { ty_arg' <- simplType (rhs_se `setInScope` env) ty_arg
1338         ; simplLam (extendTvSubst env bndr ty_arg') bndrs body cont }
1339
1340 simplNonRecE env bndr (rhs, rhs_se) (bndrs, body) cont
1341   = do dflags <- getDynFlags
1342        case () of
1343          _
1344           | preInlineUnconditionally dflags env NotTopLevel bndr rhs ->
1345             do  { tick (PreInlineUnconditionally bndr)
1346                 ; -- pprTrace "preInlineUncond" (ppr bndr <+> ppr rhs) $
1347                   simplLam (extendIdSubst env bndr (mkContEx rhs_se rhs)) bndrs body cont }
1348
1349           | isStrictId bndr ->           -- Includes coercions
1350             do  { simplExprF (rhs_se `setFloats` env) rhs
1351                              (StrictBind bndr bndrs body env cont) }
1352
1353           | otherwise ->
1354             ASSERT( not (isTyVar bndr) )
1355             do  { (env1, bndr1) <- simplNonRecBndr env bndr
1356                 ; let (env2, bndr2) = addBndrRules env1 bndr bndr1
1357                 ; env3 <- simplLazyBind env2 NotTopLevel NonRecursive bndr bndr2 rhs rhs_se
1358                 ; simplLam env3 bndrs body cont }
1359 \end{code}
1360
1361 %************************************************************************
1362 %*                                                                      *
1363                      Variables
1364 %*                                                                      *
1365 %************************************************************************
1366
1367 \begin{code}
1368 simplVar :: SimplEnv -> InVar -> SimplM OutExpr
1369 -- Look up an InVar in the environment
1370 simplVar env var
1371   | isTyVar var = return (Type (substTyVar env var))
1372   | isCoVar var = return (Coercion (substCoVar env var))
1373   | otherwise
1374   = case substId env var of
1375         DoneId var1          -> return (Var var1)
1376         DoneEx e             -> return e
1377         ContEx tvs cvs ids e -> simplExpr (setSubstEnv env tvs cvs ids) e
1378
1379 simplIdF :: SimplEnv -> InId -> SimplCont -> SimplM (SimplEnv, OutExpr)
1380 simplIdF env var cont
1381   = case substId env var of
1382         DoneEx e             -> simplExprF (zapSubstEnv env) e cont
1383         ContEx tvs cvs ids e -> simplExprF (setSubstEnv env tvs cvs ids) e cont
1384         DoneId var1          -> completeCall env var1 cont
1385                 -- Note [zapSubstEnv]
1386                 -- The template is already simplified, so don't re-substitute.
1387                 -- This is VITAL.  Consider
1388                 --      let x = e in
1389                 --      let y = \z -> ...x... in
1390                 --      \ x -> ...y...
1391                 -- We'll clone the inner \x, adding x->x' in the id_subst
1392                 -- Then when we inline y, we must *not* replace x by x' in
1393                 -- the inlined copy!!
1394
1395 ---------------------------------------------------------
1396 --      Dealing with a call site
1397
1398 completeCall :: SimplEnv -> OutId -> SimplCont -> SimplM (SimplEnv, OutExpr)
1399 completeCall env var cont
1400   = do  {   ------------- Try inlining ----------------
1401           dflags <- getDynFlags
1402         ; let  (lone_variable, arg_infos, call_cont) = contArgs cont
1403                n_val_args = length arg_infos
1404                interesting_cont = interestingCallContext call_cont
1405                unfolding    = activeUnfolding env var
1406                maybe_inline = callSiteInline dflags var unfolding
1407                                              lone_variable arg_infos interesting_cont
1408         ; case maybe_inline of {
1409             Just expr      -- There is an inlining!
1410               ->  do { checkedTick (UnfoldingDone var)
1411                      ; dump_inline dflags expr cont
1412                      ; simplExprF (zapSubstEnv env) expr cont }
1413
1414             ; Nothing -> do               -- No inlining!
1415
1416         { rule_base <- getSimplRules
1417         ; let info = mkArgInfo var (getRules rule_base var) n_val_args call_cont
1418         ; rebuildCall env info cont
1419     }}}
1420   where
1421     dump_inline dflags unfolding cont
1422       | not (dopt Opt_D_dump_inlinings dflags) = return ()
1423       | not (dopt Opt_D_verbose_core2core dflags)
1424       = when (isExternalName (idName var)) $
1425             liftIO $ printInfoForUser dflags alwaysQualify $
1426                 sep [text "Inlining done:", nest 4 (ppr var)]
1427       | otherwise
1428       = liftIO $ printInfoForUser dflags alwaysQualify $
1429            sep [text "Inlining done: " <> ppr var,
1430                 nest 4 (vcat [text "Inlined fn: " <+> nest 2 (ppr unfolding),
1431                               text "Cont:  " <+> ppr cont])]
1432
1433 rebuildCall :: SimplEnv
1434             -> ArgInfo
1435             -> SimplCont
1436             -> SimplM (SimplEnv, OutExpr)
1437 rebuildCall env (ArgInfo { ai_fun = fun, ai_args = rev_args, ai_strs = [] }) cont
1438   -- When we run out of strictness args, it means
1439   -- that the call is definitely bottom; see SimplUtils.mkArgInfo
1440   -- Then we want to discard the entire strict continuation.  E.g.
1441   --    * case (error "hello") of { ... }
1442   --    * (error "Hello") arg
1443   --    * f (error "Hello") where f is strict
1444   --    etc
1445   -- Then, especially in the first of these cases, we'd like to discard
1446   -- the continuation, leaving just the bottoming expression.  But the
1447   -- type might not be right, so we may have to add a coerce.
1448   | not (contIsTrivial cont)     -- Only do this if there is a non-trivial
1449   = return (env, castBottomExpr res cont_ty)  -- contination to discard, else we do it
1450   where                                       -- again and again!
1451     res     = argInfoExpr fun rev_args
1452     cont_ty = contResultType cont
1453
1454 rebuildCall env info (CoerceIt co cont) 
1455   = rebuildCall env (addCastTo info co) cont
1456
1457 rebuildCall env info (ApplyTo dup_flag (Type arg_ty) se cont)
1458   = do { arg_ty' <- if isSimplified dup_flag then return arg_ty
1459                     else simplType (se `setInScope` env) arg_ty
1460        ; rebuildCall env (info `addArgTo` Type arg_ty') cont }
1461
1462 rebuildCall env info@(ArgInfo { ai_encl = encl_rules, ai_type = fun_ty
1463                               , ai_strs = str:strs, ai_discs = disc:discs })
1464             (ApplyTo dup_flag arg arg_se cont)
1465   | isSimplified dup_flag     -- See Note [Avoid redundant simplification]
1466   = rebuildCall env (addArgTo info' arg) cont
1467
1468   | str                 -- Strict argument
1469   = -- pprTrace "Strict Arg" (ppr arg $$ ppr (seIdSubst env) $$ ppr (seInScope env)) $
1470     simplExprF (arg_se `setFloats` env) arg
1471                (StrictArg info' cci cont)
1472                 -- Note [Shadowing]
1473
1474   | otherwise                           -- Lazy argument
1475         -- DO NOT float anything outside, hence simplExprC
1476         -- There is no benefit (unlike in a let-binding), and we'd
1477         -- have to be very careful about bogus strictness through
1478         -- floating a demanded let.
1479   = do  { arg' <- simplExprC (arg_se `setInScope` env) arg
1480                              (mkLazyArgStop (funArgTy fun_ty) cci)
1481         ; rebuildCall env (addArgTo info' arg') cont }
1482   where
1483     info' = info { ai_strs = strs, ai_discs = discs }
1484     cci | encl_rules || disc > 0 = ArgCtxt encl_rules  -- Be keener here
1485         | otherwise              = BoringCtxt          -- Nothing interesting
1486
1487 rebuildCall env (ArgInfo { ai_fun = fun, ai_args = rev_args, ai_rules = rules }) cont
1488   | null rules
1489   = rebuild env (argInfoExpr fun rev_args) cont      -- No rules, common case
1490
1491   | otherwise
1492   = do {  -- We've accumulated a simplified call in <fun,rev_args>
1493           -- so try rewrite rules; see Note [RULEs apply to simplified arguments]
1494           -- See also Note [Rules for recursive functions]
1495         ; let env' = zapSubstEnv env
1496               (args, cont') = argInfoValArgs env' rev_args cont
1497         ; mb_rule <- tryRules env' rules fun args cont'
1498         ; case mb_rule of {
1499              Just (rule_rhs, cont'') -> simplExprF env' rule_rhs cont''
1500
1501                  -- Rules don't match
1502            ; Nothing -> rebuild env (argInfoExpr fun rev_args) cont      -- No rules
1503     } }
1504 \end{code}
1505
1506 Note [RULES apply to simplified arguments]
1507 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1508 It's very desirable to try RULES once the arguments have been simplified, because
1509 doing so ensures that rule cascades work in one pass.  Consider
1510    {-# RULES g (h x) = k x
1511              f (k x) = x #-}
1512    ...f (g (h x))...
1513 Then we want to rewrite (g (h x)) to (k x) and only then try f's rules. If
1514 we match f's rules against the un-simplified RHS, it won't match.  This
1515 makes a particularly big difference when superclass selectors are involved:
1516         op ($p1 ($p2 (df d)))
1517 We want all this to unravel in one sweeep.
1518
1519 Note [Avoid redundant simplification]
1520 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1521 Because RULES apply to simplified arguments, there's a danger of repeatedly
1522 simplifying already-simplified arguments.  An important example is that of
1523         (>>=) d e1 e2
1524 Here e1, e2 are simplified before the rule is applied, but don't really
1525 participate in the rule firing. So we mark them as Simplified to avoid
1526 re-simplifying them.
1527
1528 Note [Shadowing]
1529 ~~~~~~~~~~~~~~~~
1530 This part of the simplifier may break the no-shadowing invariant
1531 Consider
1532         f (...(\a -> e)...) (case y of (a,b) -> e')
1533 where f is strict in its second arg
1534 If we simplify the innermost one first we get (...(\a -> e)...)
1535 Simplifying the second arg makes us float the case out, so we end up with
1536         case y of (a,b) -> f (...(\a -> e)...) e'
1537 So the output does not have the no-shadowing invariant.  However, there is
1538 no danger of getting name-capture, because when the first arg was simplified
1539 we used an in-scope set that at least mentioned all the variables free in its
1540 static environment, and that is enough.
1541
1542 We can't just do innermost first, or we'd end up with a dual problem:
1543         case x of (a,b) -> f e (...(\a -> e')...)
1544
1545 I spent hours trying to recover the no-shadowing invariant, but I just could
1546 not think of an elegant way to do it.  The simplifier is already knee-deep in
1547 continuations.  We have to keep the right in-scope set around; AND we have
1548 to get the effect that finding (error "foo") in a strict arg position will
1549 discard the entire application and replace it with (error "foo").  Getting
1550 all this at once is TOO HARD!
1551
1552
1553 %************************************************************************
1554 %*                                                                      *
1555                 Rewrite rules
1556 %*                                                                      *
1557 %************************************************************************
1558
1559 \begin{code}
1560 tryRules :: SimplEnv -> [CoreRule]
1561          -> Id -> [OutExpr] -> SimplCont
1562          -> SimplM (Maybe (CoreExpr, SimplCont)) 
1563 -- The SimplEnv already has zapSubstEnv applied to it
1564
1565 tryRules env rules fn args call_cont
1566   | null rules
1567   = return Nothing
1568
1569   | fn `hasKey` tagToEnumKey   -- See Note [Optimising tagToEnum#]
1570   , [_type_arg, val_arg] <- args
1571   , Select dup bndr ((_,[],rhs1) : rest_alts) se cont <- call_cont
1572   , isDeadBinder bndr
1573   = do { dflags <- getDynFlags
1574        ; let enum_to_tag :: CoreAlt -> CoreAlt
1575                 -- Takes   K -> e  into   tagK# -> e
1576                 -- where tagK# is the tag of constructor K
1577              enum_to_tag (DataAlt con, [], rhs) 
1578                = ASSERT( isEnumerationTyCon (dataConTyCon con) )
1579                 (LitAlt tag, [], rhs)
1580               where
1581                 tag = mkMachInt dflags (toInteger (dataConTag con - fIRST_TAG))
1582              enum_to_tag alt = pprPanic "tryRules: tagToEnum" (ppr alt)
1583  
1584              new_alts = (DEFAULT, [], rhs1) : map enum_to_tag rest_alts
1585              new_bndr = setIdType bndr intPrimTy   
1586                  -- The binder is dead, but should have the right type
1587       ; return (Just (val_arg, Select dup new_bndr new_alts se cont)) } 
1588
1589   | otherwise
1590   = do { dflags <- getDynFlags
1591        ; case lookupRule dflags (getUnfoldingInRuleMatch env) (activeRule env) 
1592                          fn args rules of {
1593            Nothing               -> return Nothing ;   -- No rule matches
1594            Just (rule, rule_rhs) ->
1595              do { checkedTick (RuleFired (ru_name rule))
1596                 ; dump dflags rule rule_rhs
1597                 ; let cont' = pushSimplifiedArgs env
1598                                                  (drop (ruleArity rule) args) 
1599                                                  call_cont
1600                       -- (ruleArity rule) says how many args the rule consumed
1601                 ; return (Just (rule_rhs, cont')) }}}
1602   where
1603     dump dflags rule rule_rhs
1604       | dopt Opt_D_dump_rule_rewrites dflags
1605       = log_rule dflags Opt_D_dump_rule_rewrites "Rule fired" $ vcat
1606           [ text "Rule:" <+> ftext (ru_name rule)
1607           , text "Before:" <+> hang (ppr fn) 2 (sep (map pprParendExpr args))
1608           , text "After: " <+> pprCoreExpr rule_rhs
1609           , text "Cont:  " <+> ppr call_cont ]
1610
1611       | dopt Opt_D_dump_rule_firings dflags
1612       = log_rule dflags Opt_D_dump_rule_firings "Rule fired:" $
1613           ftext (ru_name rule)
1614
1615       | otherwise
1616       = return ()
1617
1618     log_rule dflags flag hdr details = liftIO . dumpSDoc dflags flag "" $
1619       sep [text hdr, nest 4 details]
1620 \end{code}
1621
1622 Note [Optimising tagToEnum#]
1623 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1624 We want to transform
1625    case tagToEnum# x of   ==>    case x of
1626      True -> e1                    DEFAULT -> e1
1627      False -> e2                   0#      -> e2
1628
1629 thereby getting rid of the tagToEnum# altogether.  If there was a DEFAULT
1630 alternative we retain it (remember it comes first).  If not the case must
1631 be exhaustive, and we reflect that in the transformed version by adding
1632 a DEFAULT.  Otherwise Lint complains that the new case is not exhaustive.
1633
1634 Note [Rules for recursive functions]
1635 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1636 You might think that we shouldn't apply rules for a loop breaker:
1637 doing so might give rise to an infinite loop, because a RULE is
1638 rather like an extra equation for the function:
1639      RULE:           f (g x) y = x+y
1640      Eqn:            f a     y = a-y
1641
1642 But it's too drastic to disable rules for loop breakers.
1643 Even the foldr/build rule would be disabled, because foldr
1644 is recursive, and hence a loop breaker:
1645      foldr k z (build g) = g k z
1646 So it's up to the programmer: rules can cause divergence
1647
1648
1649 %************************************************************************
1650 %*                                                                      *
1651                 Rebuilding a case expression
1652 %*                                                                      *
1653 %************************************************************************
1654
1655 Note [Case elimination]
1656 ~~~~~~~~~~~~~~~~~~~~~~~
1657 The case-elimination transformation discards redundant case expressions.
1658 Start with a simple situation:
1659
1660         case x# of      ===>   let y# = x# in e
1661           y# -> e
1662
1663 (when x#, y# are of primitive type, of course).  We can't (in general)
1664 do this for algebraic cases, because we might turn bottom into
1665 non-bottom!
1666
1667 The code in SimplUtils.prepareAlts has the effect of generalise this
1668 idea to look for a case where we're scrutinising a variable, and we
1669 know that only the default case can match.  For example:
1670
1671         case x of
1672           0#      -> ...
1673           DEFAULT -> ...(case x of
1674                          0#      -> ...
1675                          DEFAULT -> ...) ...
1676
1677 Here the inner case is first trimmed to have only one alternative, the
1678 DEFAULT, after which it's an instance of the previous case.  This
1679 really only shows up in eliminating error-checking code.
1680
1681 Note that SimplUtils.mkCase combines identical RHSs.  So
1682
1683         case e of       ===> case e of DEFAULT -> r
1684            True  -> r
1685            False -> r
1686
1687 Now again the case may be elminated by the CaseElim transformation.
1688 This includes things like (==# a# b#)::Bool so that we simplify
1689       case ==# a# b# of { True -> x; False -> x }
1690 to just
1691       x
1692 This particular example shows up in default methods for
1693 comparision operations (e.g. in (>=) for Int.Int32)
1694
1695 Note [Case elimination: lifted case]
1696 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1697 We also make sure that we deal with this very common case,
1698 where x has a lifted type:
1699
1700         case e of
1701           x -> ...x...
1702
1703 Here we are using the case as a strict let; if x is used only once
1704 then we want to inline it.  We have to be careful that this doesn't
1705 make the program terminate when it would have diverged before, so we
1706 check that
1707         (a) 'e' is already evaluated (it may so if e is a variable)
1708             Specifically we check (exprIsHNF e)
1709 or
1710         (b) 'x' is not used at all and e is ok-for-speculation
1711
1712 For the (b), consider
1713    case (case a ># b of { True -> (p,q); False -> (q,p) }) of
1714      r -> blah
1715 The scrutinee is ok-for-speculation (it looks inside cases), but we do
1716 not want to transform to
1717    let r = case a ># b of { True -> (p,q); False -> (q,p) }
1718    in blah
1719 because that builds an unnecessary thunk.
1720
1721 Note [Case binder next]
1722 ~~~~~~~~~~~~~~~~~~~~~~~
1723 If we have 
1724    case e of f { _ -> f e1 e2 }
1725 then we can safely do CaseElim.   The main criterion is that the
1726 case-binder is evaluated *next*.  Previously we just asked that
1727 the case-binder is used strictly; but that can change
1728     case x of { _ -> error "bad" }
1729     --> error "bad"
1730 which is very puzzling if 'x' is later bound to (error "good").
1731 Where the order of evaluation is specified (via seq or case)
1732 we should respect it.  
1733 See also Note [Empty case alternatives] in CoreSyn.
1734
1735 So instead we use case_bndr_evald_next to see when f is the *next*
1736 thing to be eval'd.  This came up when fixing Trac #7542.
1737 See also Note [Eta reduction of an eval'd function] in CoreUtils.
1738
1739   For reference, the old code was an extra disjunct in elim_lifted
1740        || (strict_case_bndr && scrut_is_var scrut)
1741       strict_case_bndr = isStrictDmd (idDemandInfo case_bndr)
1742       scrut_is_var (Cast s _) = scrut_is_var s
1743       scrut_is_var (Var _)    = True
1744       scrut_is_var _          = False
1745
1746       -- True if evaluation of the case_bndr is the next
1747       -- thing to be eval'd.  Then dropping the case
1748
1749 Note [Case elimination: unlifted case]
1750 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1751 Consider
1752    case a +# b of r -> ...r...
1753 Then we do case-elimination (to make a let) followed by inlining,
1754 to get
1755         .....(a +# b)....
1756 If we have
1757    case indexArray# a i of r -> ...r...
1758 we might like to do the same, and inline the (indexArray# a i).
1759 But indexArray# is not okForSpeculation, so we don't build a let
1760 in rebuildCase (lest it get floated *out*), so the inlining doesn't
1761 happen either.
1762
1763 This really isn't a big deal I think. The let can be
1764
1765
1766 Further notes about case elimination
1767 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1768 Consider:       test :: Integer -> IO ()
1769                 test = print
1770
1771 Turns out that this compiles to:
1772     Print.test
1773       = \ eta :: Integer
1774           eta1 :: State# RealWorld ->
1775           case PrelNum.< eta PrelNum.zeroInteger of wild { __DEFAULT ->
1776           case hPutStr stdout
1777                  (PrelNum.jtos eta ($w[] @ Char))
1778                  eta1
1779           of wild1 { (# new_s, a4 #) -> PrelIO.lvl23 new_s  }}
1780
1781 Notice the strange '<' which has no effect at all. This is a funny one.
1782 It started like this:
1783
1784 f x y = if x < 0 then jtos x
1785           else if y==0 then "" else jtos x
1786
1787 At a particular call site we have (f v 1).  So we inline to get
1788
1789         if v < 0 then jtos x
1790         else if 1==0 then "" else jtos x
1791
1792 Now simplify the 1==0 conditional:
1793
1794         if v<0 then jtos v else jtos v
1795
1796 Now common-up the two branches of the case:
1797
1798         case (v<0) of DEFAULT -> jtos v
1799
1800 Why don't we drop the case?  Because it's strict in v.  It's technically
1801 wrong to drop even unnecessary evaluations, and in practice they
1802 may be a result of 'seq' so we *definitely* don't want to drop those.
1803 I don't really know how to improve this situation.
1804
1805 \begin{code}
1806 ---------------------------------------------------------
1807 --      Eliminate the case if possible
1808
1809 rebuildCase, reallyRebuildCase
1810    :: SimplEnv
1811    -> OutExpr          -- Scrutinee
1812    -> InId             -- Case binder
1813    -> [InAlt]          -- Alternatives (inceasing order)
1814    -> SimplCont
1815    -> SimplM (SimplEnv, OutExpr)
1816
1817 --------------------------------------------------
1818 --      1. Eliminate the case if there's a known constructor
1819 --------------------------------------------------
1820
1821 rebuildCase env scrut case_bndr alts cont
1822   | Lit lit <- scrut    -- No need for same treatment as constructors
1823                         -- because literals are inlined more vigorously
1824   , not (litIsLifted lit)
1825   = do  { tick (KnownBranch case_bndr)
1826         ; case findAlt (LitAlt lit) alts of
1827             Nothing           -> missingAlt env case_bndr alts cont
1828             Just (_, bs, rhs) -> simple_rhs bs rhs }
1829
1830   | Just (con, ty_args, other_args) <- exprIsConApp_maybe (getUnfoldingInRuleMatch env) scrut
1831         -- Works when the scrutinee is a variable with a known unfolding
1832         -- as well as when it's an explicit constructor application
1833   = do  { tick (KnownBranch case_bndr)
1834         ; case findAlt (DataAlt con) alts of
1835             Nothing  -> missingAlt env case_bndr alts cont
1836             Just (DEFAULT, bs, rhs) -> simple_rhs bs rhs
1837             Just (_, bs, rhs)       -> knownCon env scrut con ty_args other_args
1838                                                 case_bndr bs rhs cont
1839         }
1840   where
1841     simple_rhs bs rhs = ASSERT( null bs )
1842                         do { env' <- simplNonRecX env case_bndr scrut
1843                            ; simplExprF env' rhs cont }
1844
1845
1846 --------------------------------------------------
1847 --      2. Eliminate the case if scrutinee is evaluated
1848 --------------------------------------------------
1849
1850 rebuildCase env scrut case_bndr [(_, bndrs, rhs)] cont
1851   -- See if we can get rid of the case altogether
1852   -- See Note [Case elimination]
1853   -- mkCase made sure that if all the alternatives are equal,
1854   -- then there is now only one (DEFAULT) rhs
1855  | all isDeadBinder bndrs       -- bndrs are [InId]
1856
1857  , if isUnLiftedType (idType case_bndr)
1858    then elim_unlifted        -- Satisfy the let-binding invariant
1859    else elim_lifted
1860   = do  { -- pprTrace "case elim" (vcat [ppr case_bndr, ppr (exprIsHNF scrut),
1861           --                            ppr ok_for_spec,
1862           --                            ppr scrut]) $
1863           tick (CaseElim case_bndr)
1864         ; env' <- simplNonRecX env case_bndr scrut
1865           -- If case_bndr is dead, simplNonRecX will discard
1866         ; simplExprF env' rhs cont }
1867   where
1868     elim_lifted   -- See Note [Case elimination: lifted case]
1869       = exprIsHNF scrut
1870      || (is_plain_seq && ok_for_spec)
1871               -- Note: not the same as exprIsHNF
1872      || case_bndr_evald_next rhs
1873
1874     elim_unlifted
1875       | is_plain_seq = exprOkForSideEffects scrut
1876             -- The entire case is dead, so we can drop it,
1877             -- _unless_ the scrutinee has side effects
1878       | otherwise    = ok_for_spec
1879             -- The case-binder is alive, but we may be able
1880             -- turn the case into a let, if the expression is ok-for-spec
1881             -- See Note [Case elimination: unlifted case]
1882
1883     ok_for_spec      = exprOkForSpeculation scrut
1884     is_plain_seq     = isDeadBinder case_bndr -- Evaluation *only* for effect
1885
1886     case_bndr_evald_next :: CoreExpr -> Bool
1887       -- See Note [Case binder next]
1888     case_bndr_evald_next (Var v)         = v == case_bndr
1889     case_bndr_evald_next (Cast e _)      = case_bndr_evald_next e
1890     case_bndr_evald_next (App e _)       = case_bndr_evald_next e
1891     case_bndr_evald_next (Case e _ _ _)  = case_bndr_evald_next e
1892     case_bndr_evald_next _               = False
1893       -- Could add a case for Let,
1894       -- but I'm worried it could become expensive
1895
1896 --------------------------------------------------
1897 --      3. Try seq rules; see Note [User-defined RULES for seq] in MkId
1898 --------------------------------------------------
1899
1900 rebuildCase env scrut case_bndr alts@[(_, bndrs, rhs)] cont
1901   | all isDeadBinder (case_bndr : bndrs)  -- So this is just 'seq'
1902   = do { let rhs' = substExpr (text "rebuild-case") env rhs
1903              env' = zapSubstEnv env
1904              out_args = [Type (substTy env (idType case_bndr)),
1905                          Type (exprType rhs'), scrut, rhs']
1906                       -- Lazily evaluated, so we don't do most of this
1907
1908        ; rule_base <- getSimplRules
1909        ; mb_rule <- tryRules env' (getRules rule_base seqId) seqId out_args cont
1910        ; case mb_rule of
1911            Just (rule_rhs, cont') -> simplExprF env' rule_rhs cont'
1912            Nothing                -> reallyRebuildCase env scrut case_bndr alts cont }
1913
1914 rebuildCase env scrut case_bndr alts cont
1915   = reallyRebuildCase env scrut case_bndr alts cont
1916
1917 --------------------------------------------------
1918 --      3. Catch-all case
1919 --------------------------------------------------
1920
1921 reallyRebuildCase env scrut case_bndr alts cont
1922   = do  {       -- Prepare the continuation;
1923                 -- The new subst_env is in place
1924           (env', dup_cont, nodup_cont) <- prepareCaseCont env alts cont
1925
1926         -- Simplify the alternatives
1927         ; (scrut', case_bndr', alts') <- simplAlts env' scrut case_bndr alts dup_cont
1928
1929         ; dflags <- getDynFlags
1930         ; let alts_ty' = contResultType dup_cont
1931         ; case_expr <- mkCase dflags scrut' case_bndr' alts_ty' alts'
1932
1933         -- Notice that rebuild gets the in-scope set from env', not alt_env
1934         -- (which in any case is only build in simplAlts)
1935         -- The case binder *not* scope over the whole returned case-expression
1936         ; rebuild env' case_expr nodup_cont }
1937 \end{code}
1938
1939 simplCaseBinder checks whether the scrutinee is a variable, v.  If so,
1940 try to eliminate uses of v in the RHSs in favour of case_bndr; that
1941 way, there's a chance that v will now only be used once, and hence
1942 inlined.
1943
1944 Historical note: we use to do the "case binder swap" in the Simplifier
1945 so there were additional complications if the scrutinee was a variable.
1946 Now the binder-swap stuff is done in the occurrence analyer; see
1947 OccurAnal Note [Binder swap].
1948
1949 Note [knownCon occ info]
1950 ~~~~~~~~~~~~~~~~~~~~~~~~
1951 If the case binder is not dead, then neither are the pattern bound
1952 variables:
1953         case <any> of x { (a,b) ->
1954         case x of { (p,q) -> p } }
1955 Here (a,b) both look dead, but come alive after the inner case is eliminated.
1956 The point is that we bring into the envt a binding
1957         let x = (a,b)
1958 after the outer case, and that makes (a,b) alive.  At least we do unless
1959 the case binder is guaranteed dead.
1960
1961 Note [Case alternative occ info]
1962 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1963 When we are simply reconstructing a case (the common case), we always
1964 zap the occurrence info on the binders in the alternatives.  Even
1965 if the case binder is dead, the scrutinee is usually a variable, and *that*
1966 can bring the case-alternative binders back to life.  
1967 See Note [Add unfolding for scrutinee]
1968
1969 Note [Improving seq]
1970 ~~~~~~~~~~~~~~~~~~~
1971 Consider
1972         type family F :: * -> *
1973         type instance F Int = Int
1974
1975         ... case e of x { DEFAULT -> rhs } ...
1976
1977 where x::F Int.  Then we'd like to rewrite (F Int) to Int, getting
1978
1979         case e `cast` co of x'::Int
1980            I# x# -> let x = x' `cast` sym co
1981                     in rhs
1982
1983 so that 'rhs' can take advantage of the form of x'.
1984
1985 Notice that Note [Case of cast] (in OccurAnal) may then apply to the result.
1986
1987 Nota Bene: We only do the [Improving seq] transformation if the
1988 case binder 'x' is actually used in the rhs; that is, if the case
1989 is *not* a *pure* seq.
1990   a) There is no point in adding the cast to a pure seq.
1991   b) There is a good reason not to: doing so would interfere
1992      with seq rules (Note [Built-in RULES for seq] in MkId).
1993      In particular, this [Improving seq] thing *adds* a cast
1994      while [Built-in RULES for seq] *removes* one, so they
1995      just flip-flop.
1996
1997 You might worry about
1998    case v of x { __DEFAULT ->
1999       ... case (v `cast` co) of y { I# -> ... }}
2000 This is a pure seq (since x is unused), so [Improving seq] won't happen.
2001 But it's ok: the simplifier will replace 'v' by 'x' in the rhs to get
2002    case v of x { __DEFAULT ->
2003       ... case (x `cast` co) of y { I# -> ... }}
2004 Now the outer case is not a pure seq, so [Improving seq] will happen,
2005 and then the inner case will disappear.
2006
2007 The need for [Improving seq] showed up in Roman's experiments.  Example:
2008   foo :: F Int -> Int -> Int
2009   foo t n = t `seq` bar n
2010      where
2011        bar 0 = 0
2012        bar n = bar (n - case t of TI i -> i)
2013 Here we'd like to avoid repeated evaluating t inside the loop, by
2014 taking advantage of the `seq`.
2015
2016 At one point I did transformation in LiberateCase, but it's more
2017 robust here.  (Otherwise, there's a danger that we'll simply drop the
2018 'seq' altogether, before LiberateCase gets to see it.)
2019
2020 \begin{code}
2021 simplAlts :: SimplEnv
2022           -> OutExpr
2023           -> InId                       -- Case binder
2024           -> [InAlt]                    -- Non-empty
2025           -> SimplCont
2026           -> SimplM (OutExpr, OutId, [OutAlt])  -- Includes the continuation
2027 -- Like simplExpr, this just returns the simplified alternatives;
2028 -- it does not return an environment
2029 -- The returned alternatives can be empty, none are possible
2030
2031 simplAlts env scrut case_bndr alts cont'
2032   = do  { let env0 = zapFloats env
2033
2034         ; (env1, case_bndr1) <- simplBinder env0 case_bndr
2035
2036         ; fam_envs <- getFamEnvs
2037         ; (alt_env', scrut', case_bndr') <- improveSeq fam_envs env1 scrut
2038                                                        case_bndr case_bndr1 alts
2039
2040         ; (imposs_deflt_cons, in_alts) <- prepareAlts scrut' case_bndr' alts
2041           -- NB: it's possible that the returned in_alts is empty: this is handled
2042           -- by the caller (rebuildCase) in the missingAlt function
2043
2044         ; alts' <- mapM (simplAlt alt_env' (Just scrut') imposs_deflt_cons case_bndr' cont') in_alts
2045         ; -- pprTrace "simplAlts" (ppr case_bndr $$ ppr alts_ty $$ ppr alts_ty' $$ ppr alts $$ ppr cont') $
2046           return (scrut', case_bndr', alts') }
2047
2048
2049 ------------------------------------
2050 improveSeq :: (FamInstEnv, FamInstEnv) -> SimplEnv
2051            -> OutExpr -> InId -> OutId -> [InAlt]
2052            -> SimplM (SimplEnv, OutExpr, OutId)
2053 -- Note [Improving seq]
2054 improveSeq fam_envs env scrut case_bndr case_bndr1 [(DEFAULT,_,_)]
2055   | not (isDeadBinder case_bndr) -- Not a pure seq!  See Note [Improving seq]
2056   , Just (co, ty2) <- topNormaliseType fam_envs (idType case_bndr1)
2057   = do { case_bndr2 <- newId (fsLit "nt") ty2
2058         ; let rhs  = DoneEx (Var case_bndr2 `Cast` mkSymCo co)
2059               env2 = extendIdSubst env case_bndr rhs
2060         ; return (env2, scrut `Cast` co, case_bndr2) }
2061
2062 improveSeq _ env scrut _ case_bndr1 _
2063   = return (env, scrut, case_bndr1)
2064
2065
2066 ------------------------------------
2067 simplAlt :: SimplEnv
2068          -> Maybe OutExpr  -- The scrutinee
2069          -> [AltCon]       -- These constructors can't be present when
2070                            -- matching the DEFAULT alternative
2071          -> OutId          -- The case binder
2072          -> SimplCont
2073          -> InAlt
2074          -> SimplM OutAlt
2075
2076 simplAlt env _ imposs_deflt_cons case_bndr' cont' (DEFAULT, bndrs, rhs)
2077   = ASSERT( null bndrs )
2078     do  { let env' = addBinderUnfolding env case_bndr'
2079                                         (mkOtherCon imposs_deflt_cons)
2080                 -- Record the constructors that the case-binder *can't* be.
2081         ; rhs' <- simplExprC env' rhs cont'
2082         ; return (DEFAULT, [], rhs') }
2083
2084 simplAlt env scrut' _ case_bndr' cont' (LitAlt lit, bndrs, rhs)
2085   = ASSERT( null bndrs )
2086     do  { env' <- addAltUnfoldings env scrut' case_bndr' (Lit lit)
2087         ; rhs' <- simplExprC env' rhs cont'
2088         ; return (LitAlt lit, [], rhs') }
2089
2090 simplAlt env scrut' _ case_bndr' cont' (DataAlt con, vs, rhs)
2091   = do  {       -- Deal with the pattern-bound variables
2092                 -- Mark the ones that are in ! positions in the
2093                 -- data constructor as certainly-evaluated.
2094                 -- NB: simplLamBinders preserves this eval info
2095         ; let vs_with_evals = add_evals (dataConRepStrictness con)
2096         ; (env', vs') <- simplLamBndrs env vs_with_evals
2097
2098                 -- Bind the case-binder to (con args)
2099         ; let inst_tys' = tyConAppArgs (idType case_bndr')
2100               con_app :: OutExpr
2101               con_app   = mkConApp2 con inst_tys' vs'
2102
2103         ; env'' <- addAltUnfoldings env' scrut' case_bndr' con_app
2104         ; rhs' <- simplExprC env'' rhs cont'
2105         ; return (DataAlt con, vs', rhs') }
2106   where
2107         -- add_evals records the evaluated-ness of the bound variables of
2108         -- a case pattern.  This is *important*.  Consider
2109         --      data T = T !Int !Int
2110         --
2111         --      case x of { T a b -> T (a+1) b }
2112         --
2113         -- We really must record that b is already evaluated so that we don't
2114         -- go and re-evaluate it when constructing the result.
2115         -- See Note [Data-con worker strictness] in MkId.lhs
2116     add_evals the_strs
2117         = go vs the_strs
2118         where
2119           go [] [] = []
2120           go (v:vs') strs | isTyVar v = v : go vs' strs
2121           go (v:vs') (str:strs)
2122             | isMarkedStrict str = evald_v  : go vs' strs
2123             | otherwise          = zapped_v : go vs' strs
2124             where
2125               zapped_v = zapIdOccInfo v   -- See Note [Case alternative occ info]
2126               evald_v  = zapped_v `setIdUnfolding` evaldUnfolding
2127           go _ _ = pprPanic "cat_evals" (ppr con $$ ppr vs $$ ppr the_strs)
2128
2129
2130 addAltUnfoldings :: SimplEnv -> Maybe OutExpr -> OutId -> OutExpr -> SimplM SimplEnv
2131 addAltUnfoldings env scrut case_bndr con_app
2132   = do { dflags <- getDynFlags
2133        ; let con_app_unf = mkSimpleUnfolding dflags con_app
2134              env1 = addBinderUnfolding env case_bndr con_app_unf
2135
2136              -- See Note [Add unfolding for scrutinee]
2137              env2 = case scrut of
2138                       Just (Var v)           -> addBinderUnfolding env1 v con_app_unf
2139                       Just (Cast (Var v) co) -> addBinderUnfolding env1 v $
2140                                                 mkSimpleUnfolding dflags (Cast con_app (mkSymCo co))
2141                       _                      -> env1
2142               
2143        ; traceSmpl "addAltUnf" (vcat [ppr case_bndr <+> ppr scrut, ppr con_app])
2144        ; return env2 }
2145
2146 addBinderUnfolding :: SimplEnv -> Id -> Unfolding -> SimplEnv
2147 addBinderUnfolding env bndr unf
2148   | debugIsOn, Just tmpl <- maybeUnfoldingTemplate unf
2149   = WARN( not (eqType (idType bndr) (exprType tmpl)), 
2150           ppr bndr $$ ppr (idType bndr) $$ ppr tmpl $$ ppr (exprType tmpl) ) 
2151     modifyInScope env (bndr `setIdUnfolding` unf)
2152
2153   | otherwise
2154   = modifyInScope env (bndr `setIdUnfolding` unf)
2155
2156 zapBndrOccInfo :: Bool -> Id -> Id
2157 -- Consider  case e of b { (a,b) -> ... }
2158 -- Then if we bind b to (a,b) in "...", and b is not dead,
2159 -- then we must zap the deadness info on a,b
2160 zapBndrOccInfo keep_occ_info pat_id
2161   | keep_occ_info = pat_id
2162   | otherwise     = zapIdOccInfo pat_id
2163 \end{code}
2164
2165 Note [Add unfolding for scrutinee]
2166 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2167 In general it's unlikely that a variable scrutinee will appear
2168 in the case alternatives   case x of { ...x unlikely to appear... }
2169 because the binder-swap in OccAnal has got rid of all such occcurrences
2170 See Note [Binder swap] in OccAnal.
2171
2172 BUT it is still VERY IMPORTANT to add a suitable unfolding for a
2173 variable scrutinee, in simplAlt.  Here's why
2174    case x of y
2175      (a,b) -> case b of c
2176                 I# v -> ...(f y)...
2177 There is no occurrence of 'b' in the (...(f y)...).  But y gets
2178 the unfolding (a,b), and *that* mentions b.  If f has a RULE
2179     RULE f (p, I# q) = ...
2180 we want that rule to match, so we must extend the in-scope env with a
2181 suitable unfolding for 'y'.  It's *essential* for rule matching; but
2182 it's also good for case-elimintation -- suppose that 'f' was inlined
2183 and did multi-level case analysis, then we'd solve it in one
2184 simplifier sweep instead of two.
2185
2186 Exactly the same issue arises in SpecConstr;
2187 see Note [Add scrutinee to ValueEnv too] in SpecConstr
2188
2189 HOWEVER, given
2190   case x of y { Just a -> r1; Nothing -> r2 }
2191 we do not want to add the unfolding x -> y to 'x', which might seem cool,
2192 since 'y' itself has different unfoldings in r1 and r2.  Reason: if we
2193 did that, we'd have to zap y's deadness info and that is a very useful
2194 piece of information.  
2195
2196 So instead we add the unfolding x -> Just a, and x -> Nothing in the
2197 respective RHSs.
2198
2199
2200 %************************************************************************
2201 %*                                                                      *
2202 \subsection{Known constructor}
2203 %*                                                                      *
2204 %************************************************************************
2205
2206 We are a bit careful with occurrence info.  Here's an example
2207
2208         (\x* -> case x of (a*, b) -> f a) (h v, e)
2209
2210 where the * means "occurs once".  This effectively becomes
2211         case (h v, e) of (a*, b) -> f a)
2212 and then
2213         let a* = h v; b = e in f a
2214 and then
2215         f (h v)
2216
2217 All this should happen in one sweep.
2218
2219 \begin{code}
2220 knownCon :: SimplEnv
2221          -> OutExpr                             -- The scrutinee
2222          -> DataCon -> [OutType] -> [OutExpr]   -- The scrutinee (in pieces)
2223          -> InId -> [InBndr] -> InExpr          -- The alternative
2224          -> SimplCont
2225          -> SimplM (SimplEnv, OutExpr)
2226
2227 knownCon env scrut dc dc_ty_args dc_args bndr bs rhs cont
2228   = do  { env'  <- bind_args env bs dc_args
2229         ; env'' <- bind_case_bndr env'
2230         ; simplExprF env'' rhs cont }
2231   where
2232     zap_occ = zapBndrOccInfo (isDeadBinder bndr)    -- bndr is an InId
2233
2234                   -- Ugh!
2235     bind_args env' [] _  = return env'
2236
2237     bind_args env' (b:bs') (Type ty : args)
2238       = ASSERT( isTyVar b )
2239         bind_args (extendTvSubst env' b ty) bs' args
2240
2241     bind_args env' (b:bs') (arg : args)
2242       = ASSERT( isId b )
2243         do { let b' = zap_occ b
2244              -- Note that the binder might be "dead", because it doesn't
2245              -- occur in the RHS; and simplNonRecX may therefore discard
2246              -- it via postInlineUnconditionally.
2247              -- Nevertheless we must keep it if the case-binder is alive,
2248              -- because it may be used in the con_app.  See Note [knownCon occ info]
2249            ; env'' <- simplNonRecX env' b' arg
2250            ; bind_args env'' bs' args }
2251
2252     bind_args _ _ _ =
2253       pprPanic "bind_args" $ ppr dc $$ ppr bs $$ ppr dc_args $$
2254                              text "scrut:" <+> ppr scrut
2255
2256        -- It's useful to bind bndr to scrut, rather than to a fresh
2257        -- binding      x = Con arg1 .. argn
2258        -- because very often the scrut is a variable, so we avoid
2259        -- creating, and then subsequently eliminating, a let-binding
2260        -- BUT, if scrut is a not a variable, we must be careful
2261        -- about duplicating the arg redexes; in that case, make
2262        -- a new con-app from the args
2263     bind_case_bndr env
2264       | isDeadBinder bndr   = return env
2265       | exprIsTrivial scrut = return (extendIdSubst env bndr (DoneEx scrut))
2266       | otherwise           = do { dc_args <- mapM (simplVar env) bs
2267                                          -- dc_ty_args are aready OutTypes,
2268                                          -- but bs are InBndrs
2269                                  ; let con_app = Var (dataConWorkId dc)
2270                                                  `mkTyApps` dc_ty_args
2271                                                  `mkApps`   dc_args
2272                                  ; simplNonRecX env bndr con_app }
2273
2274 -------------------
2275 missingAlt :: SimplEnv -> Id -> [InAlt] -> SimplCont -> SimplM (SimplEnv, OutExpr)
2276                 -- This isn't strictly an error, although it is unusual.
2277                 -- It's possible that the simplifer might "see" that
2278                 -- an inner case has no accessible alternatives before
2279                 -- it "sees" that the entire branch of an outer case is
2280                 -- inaccessible.  So we simply put an error case here instead.
2281 missingAlt env case_bndr _ cont
2282   = WARN( True, ptext (sLit "missingAlt") <+> ppr case_bndr )
2283     return (env, mkImpossibleExpr (contResultType cont))
2284 \end{code}
2285
2286
2287 %************************************************************************
2288 %*                                                                      *
2289 \subsection{Duplicating continuations}
2290 %*                                                                      *
2291 %************************************************************************
2292
2293 \begin{code}
2294 prepareCaseCont :: SimplEnv
2295                 -> [InAlt] -> SimplCont
2296                 -> SimplM (SimplEnv, SimplCont, SimplCont)
2297 -- We are considering
2298 --     K[case _ of { p1 -> r1; ...; pn -> rn }]
2299 -- where K is some enclosing continuation for the case
2300 -- Goal: split K into two pieces Kdup,Knodup so that
2301 --       a) Kdup can be duplicated
2302 --       b) Knodup[Kdup[e]] = K[e]
2303 -- The idea is that we'll transform thus:
2304 --          Knodup[ (case _ of { p1 -> Kdup[r1]; ...; pn -> Kdup[rn] }
2305 --
2306 -- We also return some extra bindings in SimplEnv (that scope over
2307 -- the entire continuation)
2308
2309 prepareCaseCont env alts cont
2310   | many_alts alts = mkDupableCont env cont
2311   | otherwise      = return (env, cont, mkBoringStop (contResultType cont))
2312   where
2313     many_alts :: [InAlt] -> Bool  -- True iff strictly > 1 non-bottom alternative
2314     many_alts []  = False         -- See Note [Bottom alternatives]
2315     many_alts [_] = False
2316     many_alts (alt:alts)
2317       | is_bot_alt alt = many_alts alts
2318       | otherwise      = not (all is_bot_alt alts)
2319
2320     is_bot_alt (_,_,rhs) = exprIsBottom rhs
2321 \end{code}
2322
2323 Note [Bottom alternatives]
2324 ~~~~~~~~~~~~~~~~~~~~~~~~~~
2325 When we have
2326      case (case x of { A -> error .. ; B -> e; C -> error ..)
2327        of alts
2328 then we can just duplicate those alts because the A and C cases
2329 will disappear immediately.  This is more direct than creating
2330 join points and inlining them away; and in some cases we would
2331 not even create the join points (see Note [Single-alternative case])
2332 and we would keep the case-of-case which is silly.  See Trac #4930.
2333
2334 \begin{code}
2335 mkDupableCont :: SimplEnv -> SimplCont
2336               -> SimplM (SimplEnv, SimplCont, SimplCont)
2337
2338 mkDupableCont env cont
2339   | contIsDupable cont
2340   = return (env, cont, mkBoringStop (contResultType cont))
2341
2342 mkDupableCont _   (Stop {}) = panic "mkDupableCont"     -- Handled by previous eqn
2343
2344 mkDupableCont env (CoerceIt ty cont)
2345   = do  { (env', dup, nodup) <- mkDupableCont env cont
2346         ; return (env', CoerceIt ty dup, nodup) }
2347
2348 -- Duplicating ticks for now, not sure if this is good or not
2349 mkDupableCont env cont@(TickIt{})
2350   = return (env, mkBoringStop (contInputType cont), cont)
2351
2352 mkDupableCont env cont@(StrictBind {})
2353   =  return (env, mkBoringStop (contInputType cont), cont)
2354         -- See Note [Duplicating StrictBind]
2355
2356 mkDupableCont env (StrictArg info cci cont)
2357         -- See Note [Duplicating StrictArg]
2358   = do { (env', dup, nodup) <- mkDupableCont env cont
2359        ; (env'', args')     <- mapAccumLM makeTrivialArg env' (ai_args info)
2360        ; return (env'', StrictArg (info { ai_args = args' }) cci dup, nodup) }
2361
2362 mkDupableCont env (ApplyTo _ arg se cont)
2363   =     -- e.g.         [...hole...] (...arg...)
2364         --      ==>
2365         --              let a = ...arg...
2366         --              in [...hole...] a
2367     do  { (env', dup_cont, nodup_cont) <- mkDupableCont env cont
2368         ; arg' <- simplExpr (se `setInScope` env') arg
2369         ; (env'', arg'') <- makeTrivial NotTopLevel env' arg'
2370         ; let app_cont = ApplyTo OkToDup arg'' (zapSubstEnv env'') dup_cont
2371         ; return (env'', app_cont, nodup_cont) }
2372
2373 mkDupableCont env cont@(Select _ case_bndr [(_, bs, _rhs)] _ _)
2374 --  See Note [Single-alternative case]
2375 --  | not (exprIsDupable rhs && contIsDupable case_cont)
2376 --  | not (isDeadBinder case_bndr)
2377   | all isDeadBinder bs  -- InIds
2378     && not (isUnLiftedType (idType case_bndr))
2379     -- Note [Single-alternative-unlifted]
2380   = return (env, mkBoringStop (contInputType cont), cont)
2381
2382 mkDupableCont env (Select _ case_bndr alts se cont)
2383   =     -- e.g.         (case [...hole...] of { pi -> ei })
2384         --      ===>
2385         --              let ji = \xij -> ei
2386         --              in case [...hole...] of { pi -> ji xij }
2387     do  { tick (CaseOfCase case_bndr)
2388         ; (env', dup_cont, nodup_cont) <- prepareCaseCont env alts cont
2389                 -- NB: We call prepareCaseCont here.  If there is only one
2390                 -- alternative, then dup_cont may be big, but that's ok
2391                 -- because we push it into the single alternative, and then
2392                 -- use mkDupableAlt to turn that simplified alternative into
2393                 -- a join point if it's too big to duplicate.
2394                 -- And this is important: see Note [Fusing case continuations]
2395
2396         ; let alt_env = se `setInScope` env'
2397
2398         ; (alt_env', case_bndr') <- simplBinder alt_env case_bndr
2399         ; alts' <- mapM (simplAlt alt_env' Nothing [] case_bndr' dup_cont) alts
2400         -- Safe to say that there are no handled-cons for the DEFAULT case
2401                 -- NB: simplBinder does not zap deadness occ-info, so
2402                 -- a dead case_bndr' will still advertise its deadness
2403                 -- This is really important because in
2404                 --      case e of b { (# p,q #) -> ... }
2405                 -- b is always dead, and indeed we are not allowed to bind b to (# p,q #),
2406                 -- which might happen if e was an explicit unboxed pair and b wasn't marked dead.
2407                 -- In the new alts we build, we have the new case binder, so it must retain
2408                 -- its deadness.
2409         -- NB: we don't use alt_env further; it has the substEnv for
2410         --     the alternatives, and we don't want that
2411
2412         ; (env'', alts'') <- mkDupableAlts env' case_bndr' alts'
2413         ; return (env'',  -- Note [Duplicated env]
2414                   Select OkToDup case_bndr' alts'' (zapSubstEnv env'')
2415                          (mkBoringStop (contInputType nodup_cont)),
2416                   nodup_cont) }
2417
2418
2419 mkDupableAlts :: SimplEnv -> OutId -> [InAlt]
2420               -> SimplM (SimplEnv, [InAlt])
2421 -- Absorbs the continuation into the new alternatives
2422
2423 mkDupableAlts env case_bndr' the_alts
2424   = go env the_alts
2425   where
2426     go env0 [] = return (env0, [])
2427     go env0 (alt:alts)
2428         = do { (env1, alt') <- mkDupableAlt env0 case_bndr' alt
2429              ; (env2, alts') <- go env1 alts
2430              ; return (env2, alt' : alts' ) }
2431
2432 mkDupableAlt :: SimplEnv -> OutId -> (AltCon, [CoreBndr], CoreExpr)
2433               -> SimplM (SimplEnv, (AltCon, [CoreBndr], CoreExpr))
2434 mkDupableAlt env case_bndr (con, bndrs', rhs') = do
2435   dflags <- getDynFlags
2436   if exprIsDupable dflags rhs'  -- Note [Small alternative rhs]
2437    then return (env, (con, bndrs', rhs'))
2438    else
2439     do  { let rhs_ty'  = exprType rhs'
2440               scrut_ty = idType case_bndr
2441               case_bndr_w_unf
2442                 = case con of
2443                       DEFAULT    -> case_bndr
2444                       DataAlt dc -> setIdUnfolding case_bndr unf
2445                           where
2446                                  -- See Note [Case binders and join points]
2447                              unf = mkInlineUnfolding Nothing rhs
2448                              rhs = mkConApp2 dc (tyConAppArgs scrut_ty) bndrs'
2449
2450                       LitAlt {} -> WARN( True, ptext (sLit "mkDupableAlt")
2451                                                 <+> ppr case_bndr <+> ppr con )
2452                                    case_bndr
2453                            -- The case binder is alive but trivial, so why has
2454                            -- it not been substituted away?
2455
2456               used_bndrs' | isDeadBinder case_bndr = filter abstract_over bndrs'
2457                           | otherwise              = bndrs' ++ [case_bndr_w_unf]
2458
2459               abstract_over bndr
2460                   | isTyVar bndr = True -- Abstract over all type variables just in case
2461                   | otherwise    = not (isDeadBinder bndr)
2462                         -- The deadness info on the new Ids is preserved by simplBinders
2463
2464         ; (final_bndrs', final_args)    -- Note [Join point abstraction]
2465                 <- if (any isId used_bndrs')
2466                    then return (used_bndrs', varsToCoreExprs used_bndrs')
2467                     else do { rw_id <- newId (fsLit "w") realWorldStatePrimTy
2468                             ; return ([rw_id], [Var realWorldPrimId]) }
2469
2470         ; join_bndr <- newId (fsLit "$j") (mkPiTypes final_bndrs' rhs_ty')
2471                 -- Note [Funky mkPiTypes]
2472
2473         ; let   -- We make the lambdas into one-shot-lambdas.  The
2474                 -- join point is sure to be applied at most once, and doing so
2475                 -- prevents the body of the join point being floated out by
2476                 -- the full laziness pass
2477                 really_final_bndrs     = map one_shot final_bndrs'
2478                 one_shot v | isId v    = setOneShotLambda v
2479                            | otherwise = v
2480                 join_rhs   = mkLams really_final_bndrs rhs'
2481                 join_arity = exprArity join_rhs
2482                 join_call  = mkApps (Var join_bndr) final_args
2483
2484         ; env' <- addPolyBind NotTopLevel env (NonRec (join_bndr `setIdArity` join_arity) join_rhs)
2485         ; return (env', (con, bndrs', join_call)) }
2486                 -- See Note [Duplicated env]
2487 \end{code}
2488
2489 Note [Fusing case continuations]
2490 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2491 It's important to fuse two successive case continuations when the
2492 first has one alternative.  That's why we call prepareCaseCont here.
2493 Consider this, which arises from thunk splitting (see Note [Thunk
2494 splitting] in WorkWrap):
2495
2496       let
2497         x* = case (case v of {pn -> rn}) of
2498                I# a -> I# a
2499       in body
2500
2501 The simplifier will find
2502     (Var v) with continuation
2503             Select (pn -> rn) (
2504             Select [I# a -> I# a] (
2505             StrictBind body Stop
2506
2507 So we'll call mkDupableCont on
2508    Select [I# a -> I# a] (StrictBind body Stop)
2509 There is just one alternative in the first Select, so we want to
2510 simplify the rhs (I# a) with continuation (StricgtBind body Stop)
2511 Supposing that body is big, we end up with
2512           let $j a = <let x = I# a in body>
2513           in case v of { pn -> case rn of
2514                                  I# a -> $j a }
2515 This is just what we want because the rn produces a box that
2516 the case rn cancels with.
2517
2518 See Trac #4957 a fuller example.
2519
2520 Note [Case binders and join points]
2521 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2522 Consider this
2523    case (case .. ) of c {
2524      I# c# -> ....c....
2525
2526 If we make a join point with c but not c# we get
2527   $j = \c -> ....c....
2528
2529 But if later inlining scrutines the c, thus
2530
2531   $j = \c -> ... case c of { I# y -> ... } ...
2532
2533 we won't see that 'c' has already been scrutinised.  This actually
2534 happens in the 'tabulate' function in wave4main, and makes a significant
2535 difference to allocation.
2536
2537 An alternative plan is this:
2538
2539    $j = \c# -> let c = I# c# in ...c....
2540
2541 but that is bad if 'c' is *not* later scrutinised.
2542
2543 So instead we do both: we pass 'c' and 'c#' , and record in c's inlining
2544 (an InlineRule) that it's really I# c#, thus
2545
2546    $j = \c# -> \c[=I# c#] -> ...c....
2547
2548 Absence analysis may later discard 'c'.
2549
2550 NB: take great care when doing strictness analysis;
2551     see Note [Lamba-bound unfoldings] in DmdAnal.
2552
2553 Also note that we can still end up passing stuff that isn't used.  Before
2554 strictness analysis we have
2555    let $j x y c{=(x,y)} = (h c, ...)
2556    in ...
2557 After strictness analysis we see that h is strict, we end up with
2558    let $j x y c{=(x,y)} = ($wh x y, ...)
2559 and c is unused.
2560
2561 Note [Duplicated env]
2562 ~~~~~~~~~~~~~~~~~~~~~
2563 Some of the alternatives are simplified, but have not been turned into a join point
2564 So they *must* have an zapped subst-env.  So we can't use completeNonRecX to
2565 bind the join point, because it might to do PostInlineUnconditionally, and
2566 we'd lose that when zapping the subst-env.  We could have a per-alt subst-env,
2567 but zapping it (as we do in mkDupableCont, the Select case) is safe, and
2568 at worst delays the join-point inlining.
2569
2570 Note [Small alternative rhs]
2571 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2572 It is worth checking for a small RHS because otherwise we
2573 get extra let bindings that may cause an extra iteration of the simplifier to
2574 inline back in place.  Quite often the rhs is just a variable or constructor.
2575 The Ord instance of Maybe in PrelMaybe.lhs, for example, took several extra
2576 iterations because the version with the let bindings looked big, and so wasn't
2577 inlined, but after the join points had been inlined it looked smaller, and so
2578 was inlined.
2579
2580 NB: we have to check the size of rhs', not rhs.
2581 Duplicating a small InAlt might invalidate occurrence information
2582 However, if it *is* dupable, we return the *un* simplified alternative,
2583 because otherwise we'd need to pair it up with an empty subst-env....
2584 but we only have one env shared between all the alts.
2585 (Remember we must zap the subst-env before re-simplifying something).
2586 Rather than do this we simply agree to re-simplify the original (small) thing later.
2587
2588 Note [Funky mkPiTypes]
2589 ~~~~~~~~~~~~~~~~~~~~~~
2590 Notice the funky mkPiTypes.  If the contructor has existentials
2591 it's possible that the join point will be abstracted over
2592 type varaibles as well as term variables.
2593  Example:  Suppose we have
2594         data T = forall t.  C [t]
2595  Then faced with
2596         case (case e of ...) of
2597             C t xs::[t] -> rhs
2598  We get the join point
2599         let j :: forall t. [t] -> ...
2600             j = /\t \xs::[t] -> rhs
2601         in
2602         case (case e of ...) of
2603             C t xs::[t] -> j t xs
2604
2605 Note [Join point abstaction]
2606 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2607 If we try to lift a primitive-typed something out
2608 for let-binding-purposes, we will *caseify* it (!),
2609 with potentially-disastrous strictness results.  So
2610 instead we turn it into a function: \v -> e
2611 where v::State# RealWorld#.  The value passed to this function
2612 is realworld#, which generates (almost) no code.
2613
2614 There's a slight infelicity here: we pass the overall
2615 case_bndr to all the join points if it's used in *any* RHS,
2616 because we don't know its usage in each RHS separately
2617
2618 We used to say "&& isUnLiftedType rhs_ty'" here, but now
2619 we make the join point into a function whenever used_bndrs'
2620 is empty.  This makes the join-point more CPR friendly.
2621 Consider:       let j = if .. then I# 3 else I# 4
2622                 in case .. of { A -> j; B -> j; C -> ... }
2623
2624 Now CPR doesn't w/w j because it's a thunk, so
2625 that means that the enclosing function can't w/w either,
2626 which is a lose.  Here's the example that happened in practice:
2627         kgmod :: Int -> Int -> Int
2628         kgmod x y = if x > 0 && y < 0 || x < 0 && y > 0
2629                     then 78
2630                     else 5
2631
2632 I have seen a case alternative like this:
2633         True -> \v -> ...
2634 It's a bit silly to add the realWorld dummy arg in this case, making
2635         $j = \s v -> ...
2636            True -> $j s
2637 (the \v alone is enough to make CPR happy) but I think it's rare
2638
2639 Note [Duplicating StrictArg]
2640 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2641 The original plan had (where E is a big argument)
2642 e.g.    f E [..hole..]
2643         ==>     let $j = \a -> f E a
2644                 in $j [..hole..]
2645
2646 But this is terrible! Here's an example:
2647         && E (case x of { T -> F; F -> T })
2648 Now, && is strict so we end up simplifying the case with
2649 an ArgOf continuation.  If we let-bind it, we get
2650         let $j = \v -> && E v
2651         in simplExpr (case x of { T -> F; F -> T })
2652                      (ArgOf (\r -> $j r)
2653 And after simplifying more we get
2654         let $j = \v -> && E v
2655         in case x of { T -> $j F; F -> $j T }
2656 Which is a Very Bad Thing
2657
2658 What we do now is this
2659         f E [..hole..]
2660         ==>     let a = E
2661                 in f a [..hole..]
2662 Now if the thing in the hole is a case expression (which is when
2663 we'll call mkDupableCont), we'll push the function call into the
2664 branches, which is what we want.  Now RULES for f may fire, and
2665 call-pattern specialisation.  Here's an example from Trac #3116
2666      go (n+1) (case l of
2667                  1  -> bs'
2668                  _  -> Chunk p fpc (o+1) (l-1) bs')
2669 If we can push the call for 'go' inside the case, we get
2670 call-pattern specialisation for 'go', which is *crucial* for
2671 this program.
2672
2673 Here is the (&&) example:
2674         && E (case x of { T -> F; F -> T })
2675   ==>   let a = E in
2676         case x of { T -> && a F; F -> && a T }
2677 Much better!
2678
2679 Notice that
2680   * Arguments to f *after* the strict one are handled by
2681     the ApplyTo case of mkDupableCont.  Eg
2682         f [..hole..] E
2683
2684   * We can only do the let-binding of E because the function
2685     part of a StrictArg continuation is an explicit syntax
2686     tree.  In earlier versions we represented it as a function
2687     (CoreExpr -> CoreEpxr) which we couldn't take apart.
2688
2689 Do *not* duplicate StrictBind and StritArg continuations.  We gain
2690 nothing by propagating them into the expressions, and we do lose a
2691 lot.
2692
2693 The desire not to duplicate is the entire reason that
2694 mkDupableCont returns a pair of continuations.
2695
2696 Note [Duplicating StrictBind]
2697 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2698 Unlike StrictArg, there doesn't seem anything to gain from
2699 duplicating a StrictBind continuation, so we don't.
2700
2701
2702 Note [Single-alternative cases]
2703 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2704 This case is just like the ArgOf case.  Here's an example:
2705         data T a = MkT !a
2706         ...(MkT (abs x))...
2707 Then we get
2708         case (case x of I# x' ->
2709               case x' <# 0# of
2710                 True  -> I# (negate# x')
2711                 False -> I# x') of y {
2712           DEFAULT -> MkT y
2713 Because the (case x) has only one alternative, we'll transform to
2714         case x of I# x' ->
2715         case (case x' <# 0# of
2716                 True  -> I# (negate# x')
2717                 False -> I# x') of y {
2718           DEFAULT -> MkT y
2719 But now we do *NOT* want to make a join point etc, giving
2720         case x of I# x' ->
2721         let $j = \y -> MkT y
2722         in case x' <# 0# of
2723                 True  -> $j (I# (negate# x'))
2724                 False -> $j (I# x')
2725 In this case the $j will inline again, but suppose there was a big
2726 strict computation enclosing the orginal call to MkT.  Then, it won't
2727 "see" the MkT any more, because it's big and won't get duplicated.
2728 And, what is worse, nothing was gained by the case-of-case transform.
2729
2730 So, in circumstances like these, we don't want to build join points
2731 and push the outer case into the branches of the inner one. Instead,
2732 don't duplicate the continuation.
2733
2734 When should we use this strategy?  We should not use it on *every*
2735 single-alternative case:
2736   e.g.  case (case ....) of (a,b) -> (# a,b #)
2737 Here we must push the outer case into the inner one!
2738 Other choices:
2739
2740    * Match [(DEFAULT,_,_)], but in the common case of Int,
2741      the alternative-filling-in code turned the outer case into
2742                 case (...) of y { I# _ -> MkT y }
2743
2744    * Match on single alternative plus (not (isDeadBinder case_bndr))
2745      Rationale: pushing the case inwards won't eliminate the construction.
2746      But there's a risk of
2747                 case (...) of y { (a,b) -> let z=(a,b) in ... }
2748      Now y looks dead, but it'll come alive again.  Still, this
2749      seems like the best option at the moment.
2750
2751    * Match on single alternative plus (all (isDeadBinder bndrs))
2752      Rationale: this is essentially  seq.
2753
2754    * Match when the rhs is *not* duplicable, and hence would lead to a
2755      join point.  This catches the disaster-case above.  We can test
2756      the *un-simplified* rhs, which is fine.  It might get bigger or
2757      smaller after simplification; if it gets smaller, this case might
2758      fire next time round.  NB also that we must test contIsDupable
2759      case_cont *too, because case_cont might be big!
2760
2761      HOWEVER: I found that this version doesn't work well, because
2762      we can get         let x = case (...) of { small } in ...case x...
2763      When x is inlined into its full context, we find that it was a bad
2764      idea to have pushed the outer case inside the (...) case.
2765
2766 Note [Single-alternative-unlifted]
2767 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2768 Here's another single-alternative where we really want to do case-of-case:
2769
2770 data Mk1 = Mk1 Int# | Mk2 Int#
2771
2772 M1.f =
2773     \r [x_s74 y_s6X]
2774         case
2775             case y_s6X of tpl_s7m {
2776               M1.Mk1 ipv_s70 -> ipv_s70;
2777               M1.Mk2 ipv_s72 -> ipv_s72;
2778             }
2779         of
2780         wild_s7c
2781         { __DEFAULT ->
2782               case
2783                   case x_s74 of tpl_s7n {
2784                     M1.Mk1 ipv_s77 -> ipv_s77;
2785                     M1.Mk2 ipv_s79 -> ipv_s79;
2786                   }
2787               of
2788               wild1_s7b
2789               { __DEFAULT -> ==# [wild1_s7b wild_s7c];
2790               };
2791         };
2792
2793 So the outer case is doing *nothing at all*, other than serving as a
2794 join-point.  In this case we really want to do case-of-case and decide
2795 whether to use a real join point or just duplicate the continuation:
2796
2797     let $j s7c = case x of
2798                    Mk1 ipv77 -> (==) s7c ipv77
2799                    Mk1 ipv79 -> (==) s7c ipv79
2800     in
2801     case y of
2802       Mk1 ipv70 -> $j ipv70
2803       Mk2 ipv72 -> $j ipv72
2804
2805 Hence: check whether the case binder's type is unlifted, because then
2806 the outer case is *not* a seq.