Produce new-style Cmm from the Cmm parser
[ghc.git] / compiler / nativeGen / AsmCodeGen.lhs
1 -- -----------------------------------------------------------------------------
2 --
3 -- (c) The University of Glasgow 1993-2004
4 --
5 -- This is the top-level module in the native code generator.
6 --
7 -- -----------------------------------------------------------------------------
8
9 \begin{code}
10 module AsmCodeGen ( nativeCodeGen ) where
11
12 #include "HsVersions.h"
13 #include "nativeGen/NCG.h"
14
15
16 import qualified X86.CodeGen
17 import qualified X86.Regs
18 import qualified X86.Instr
19 import qualified X86.Ppr
20
21 import qualified SPARC.CodeGen
22 import qualified SPARC.Regs
23 import qualified SPARC.Instr
24 import qualified SPARC.Ppr
25 import qualified SPARC.ShortcutJump
26 import qualified SPARC.CodeGen.Expand
27
28 import qualified PPC.CodeGen
29 import qualified PPC.Cond
30 import qualified PPC.Regs
31 import qualified PPC.RegInfo
32 import qualified PPC.Instr
33 import qualified PPC.Ppr
34
35 import RegAlloc.Liveness
36 import qualified RegAlloc.Linear.Main           as Linear
37
38 import qualified GraphColor                     as Color
39 import qualified RegAlloc.Graph.Main            as Color
40 import qualified RegAlloc.Graph.Stats           as Color
41 import qualified RegAlloc.Graph.TrivColorable   as Color
42
43 import TargetReg
44 import Platform
45 import Config
46 import Instruction
47 import PIC
48 import Reg
49 import NCGMonad
50
51 import BlockId
52 import CgUtils          ( fixStgRegisters )
53 import OldCmm
54 import CmmOpt           ( cmmMachOpFold )
55 import OldPprCmm
56 import CLabel
57
58 import UniqFM
59 import UniqSupply
60 import DynFlags
61 import Util
62
63 import BasicTypes       ( Alignment )
64 import Digraph
65 import qualified Pretty
66 import BufWrite
67 import Outputable
68 import FastString
69 import UniqSet
70 import ErrUtils
71 import Module
72 import Stream (Stream)
73 import qualified Stream
74
75 -- DEBUGGING ONLY
76 --import OrdList
77
78 import Data.List
79 import Data.Maybe
80 import Control.Monad
81 import System.IO
82
83 {-
84 The native-code generator has machine-independent and
85 machine-dependent modules.
86
87 This module ("AsmCodeGen") is the top-level machine-independent
88 module.  Before entering machine-dependent land, we do some
89 machine-independent optimisations (defined below) on the
90 'CmmStmts's.
91
92 We convert to the machine-specific 'Instr' datatype with
93 'cmmCodeGen', assuming an infinite supply of registers.  We then use
94 a machine-independent register allocator ('regAlloc') to rejoin
95 reality.  Obviously, 'regAlloc' has machine-specific helper
96 functions (see about "RegAllocInfo" below).
97
98 Finally, we order the basic blocks of the function so as to minimise
99 the number of jumps between blocks, by utilising fallthrough wherever
100 possible.
101
102 The machine-dependent bits break down as follows:
103
104   * ["MachRegs"]  Everything about the target platform's machine
105     registers (and immediate operands, and addresses, which tend to
106     intermingle/interact with registers).
107
108   * ["MachInstrs"]  Includes the 'Instr' datatype (possibly should
109     have a module of its own), plus a miscellany of other things
110     (e.g., 'targetDoubleSize', 'smStablePtrTable', ...)
111
112   * ["MachCodeGen"]  is where 'Cmm' stuff turns into
113     machine instructions.
114
115   * ["PprMach"] 'pprInstr' turns an 'Instr' into text (well, really
116     a 'SDoc').
117
118   * ["RegAllocInfo"] In the register allocator, we manipulate
119     'MRegsState's, which are 'BitSet's, one bit per machine register.
120     When we want to say something about a specific machine register
121     (e.g., ``it gets clobbered by this instruction''), we set/unset
122     its bit.  Obviously, we do this 'BitSet' thing for efficiency
123     reasons.
124
125     The 'RegAllocInfo' module collects together the machine-specific
126     info needed to do register allocation.
127
128    * ["RegisterAlloc"] The (machine-independent) register allocator.
129 -}
130
131 -- -----------------------------------------------------------------------------
132 -- Top-level of the native codegen
133
134 data NcgImpl statics instr jumpDest = NcgImpl {
135     cmmTopCodeGen             :: RawCmmDecl -> NatM [NatCmmDecl statics instr],
136     generateJumpTableForInstr :: instr -> Maybe (NatCmmDecl statics instr),
137     getJumpDestBlockId        :: jumpDest -> Maybe BlockId,
138     canShortcut               :: instr -> Maybe jumpDest,
139     shortcutStatics           :: (BlockId -> Maybe jumpDest) -> statics -> statics,
140     shortcutJump              :: (BlockId -> Maybe jumpDest) -> instr -> instr,
141     pprNatCmmDecl             :: NatCmmDecl statics instr -> SDoc,
142     maxSpillSlots             :: Int,
143     allocatableRegs           :: [RealReg],
144     ncg_x86fp_kludge          :: [NatCmmDecl statics instr] -> [NatCmmDecl statics instr],
145     ncgExpandTop              :: [NatCmmDecl statics instr] -> [NatCmmDecl statics instr],
146     ncgAllocMoreStack         :: Int -> NatCmmDecl statics instr -> NatCmmDecl statics instr,
147     ncgMakeFarBranches        :: [NatBasicBlock instr] -> [NatBasicBlock instr]
148     }
149
150 --------------------
151 nativeCodeGen :: DynFlags -> Handle -> UniqSupply -> Stream IO RawCmmGroup () -> IO ()
152 nativeCodeGen dflags h us cmms
153  = let platform = targetPlatform dflags
154        nCG' :: (Outputable statics, Outputable instr, Instruction instr) => NcgImpl statics instr jumpDest -> IO ()
155        nCG' ncgImpl = nativeCodeGen' dflags ncgImpl h us cmms
156        x86NcgImpl = NcgImpl {
157                          cmmTopCodeGen             = X86.CodeGen.cmmTopCodeGen
158                         ,generateJumpTableForInstr = X86.CodeGen.generateJumpTableForInstr dflags
159                         ,getJumpDestBlockId        = X86.Instr.getJumpDestBlockId
160                         ,canShortcut               = X86.Instr.canShortcut
161                         ,shortcutStatics           = X86.Instr.shortcutStatics
162                         ,shortcutJump              = X86.Instr.shortcutJump
163                         ,pprNatCmmDecl              = X86.Ppr.pprNatCmmDecl
164                         ,maxSpillSlots             = X86.Instr.maxSpillSlots dflags
165                         ,allocatableRegs           = X86.Regs.allocatableRegs platform
166                         ,ncg_x86fp_kludge          = id
167                         ,ncgAllocMoreStack         = X86.Instr.allocMoreStack platform
168                         ,ncgExpandTop              = id
169                         ,ncgMakeFarBranches        = id
170                     }
171    in case platformArch platform of
172                  ArchX86    -> nCG' (x86NcgImpl { ncg_x86fp_kludge = map x86fp_kludge })
173                  ArchX86_64 -> nCG' x86NcgImpl
174                  ArchPPC ->
175                      nCG' $ NcgImpl {
176                           cmmTopCodeGen             = PPC.CodeGen.cmmTopCodeGen
177                          ,generateJumpTableForInstr = PPC.CodeGen.generateJumpTableForInstr dflags
178                          ,getJumpDestBlockId        = PPC.RegInfo.getJumpDestBlockId
179                          ,canShortcut               = PPC.RegInfo.canShortcut
180                          ,shortcutStatics           = PPC.RegInfo.shortcutStatics
181                          ,shortcutJump              = PPC.RegInfo.shortcutJump
182                          ,pprNatCmmDecl              = PPC.Ppr.pprNatCmmDecl
183                          ,maxSpillSlots             = PPC.Instr.maxSpillSlots dflags
184                          ,allocatableRegs           = PPC.Regs.allocatableRegs platform
185                          ,ncg_x86fp_kludge          = id
186                          ,ncgAllocMoreStack         = noAllocMoreStack
187                          ,ncgExpandTop              = id
188                          ,ncgMakeFarBranches        = makeFarBranches
189                      }
190                  ArchSPARC ->
191                      nCG' $ NcgImpl {
192                           cmmTopCodeGen             = SPARC.CodeGen.cmmTopCodeGen
193                          ,generateJumpTableForInstr = SPARC.CodeGen.generateJumpTableForInstr dflags
194                          ,getJumpDestBlockId        = SPARC.ShortcutJump.getJumpDestBlockId
195                          ,canShortcut               = SPARC.ShortcutJump.canShortcut
196                          ,shortcutStatics           = SPARC.ShortcutJump.shortcutStatics
197                          ,shortcutJump              = SPARC.ShortcutJump.shortcutJump
198                          ,pprNatCmmDecl              = SPARC.Ppr.pprNatCmmDecl
199                          ,maxSpillSlots             = SPARC.Instr.maxSpillSlots dflags
200                          ,allocatableRegs           = SPARC.Regs.allocatableRegs
201                          ,ncg_x86fp_kludge          = id
202                          ,ncgAllocMoreStack         = noAllocMoreStack
203                          ,ncgExpandTop              = map SPARC.CodeGen.Expand.expandTop
204                          ,ncgMakeFarBranches        = id
205                      }
206                  ArchARM _ _ _ ->
207                      panic "nativeCodeGen: No NCG for ARM"
208                  ArchPPC_64 ->
209                      panic "nativeCodeGen: No NCG for PPC 64"
210                  ArchUnknown ->
211                      panic "nativeCodeGen: No NCG for unknown arch"
212
213
214 --
215 -- Allocating more stack space for spilling is currently only
216 -- supported for the linear register allocator on x86/x86_64, the rest
217 -- default to the panic below.  To support allocating extra stack on
218 -- more platforms provide a definition of ncgAllocMoreStack.
219 --
220 noAllocMoreStack :: Int -> NatCmmDecl statics instr -> NatCmmDecl statics instr
221 noAllocMoreStack amount _
222   = panic $   "Register allocator: out of stack slots (need " ++ show amount ++ ")\n"
223         ++  "   If you are trying to compile SHA1.hs from the crypto library then this\n"
224         ++  "   is a known limitation in the linear allocator.\n"
225         ++  "\n"
226         ++  "   Try enabling the graph colouring allocator with -fregs-graph instead."
227         ++  "   You can still file a bug report if you like.\n"
228
229
230 nativeCodeGen' :: (Outputable statics, Outputable instr, Instruction instr)
231                => DynFlags
232                -> NcgImpl statics instr jumpDest
233                -> Handle -> UniqSupply -> Stream IO RawCmmGroup () -> IO ()
234 nativeCodeGen' dflags ncgImpl h us cmms
235  = do
236         let platform = targetPlatform dflags
237             split_cmms  = Stream.map add_split cmms
238         -- BufHandle is a performance hack.  We could hide it inside
239         -- Pretty if it weren't for the fact that we do lots of little
240         -- printDocs here (in order to do codegen in constant space).
241         bufh <- newBufHandle h
242         (imports, prof) <- cmmNativeGenStream dflags ncgImpl bufh us split_cmms [] [] 0
243         bFlush bufh
244
245         let (native, colorStats, linearStats)
246                 = unzip3 prof
247
248         -- dump native code
249         dumpIfSet_dyn dflags
250                 Opt_D_dump_asm "Asm code"
251                 (vcat $ map (pprNatCmmDecl ncgImpl) $ concat native)
252
253         -- dump global NCG stats for graph coloring allocator
254         (case concat $ catMaybes colorStats of
255           []    -> return ()
256           stats -> do
257                 -- build the global register conflict graph
258                 let graphGlobal
259                         = foldl Color.union Color.initGraph
260                         $ [ Color.raGraph stat
261                                 | stat@Color.RegAllocStatsStart{} <- stats]
262
263                 dumpSDoc dflags Opt_D_dump_asm_stats "NCG stats"
264                         $ Color.pprStats stats graphGlobal
265
266                 dumpIfSet_dyn dflags
267                         Opt_D_dump_asm_conflicts "Register conflict graph"
268                         $ Color.dotGraph
269                                 (targetRegDotColor platform)
270                                 (Color.trivColorable platform
271                                         (targetVirtualRegSqueeze platform)
272                                         (targetRealRegSqueeze platform))
273                         $ graphGlobal)
274
275
276         -- dump global NCG stats for linear allocator
277         (case concat $ catMaybes linearStats of
278                 []      -> return ()
279                 stats   -> dumpSDoc dflags Opt_D_dump_asm_stats "NCG stats"
280                                 $ Linear.pprStats (concat native) stats)
281
282         -- write out the imports
283         Pretty.printDoc Pretty.LeftMode (pprCols dflags) h
284                 $ withPprStyleDoc dflags (mkCodeStyle AsmStyle)
285                 $ makeImportsDoc dflags (concat imports)
286
287         return  ()
288
289  where  add_split tops
290                 | dopt Opt_SplitObjs dflags = split_marker : tops
291                 | otherwise                 = tops
292
293         split_marker = CmmProc mapEmpty mkSplitMarkerLabel (ListGraph [])
294
295
296 cmmNativeGenStream :: (Outputable statics, Outputable instr, Instruction instr)
297               => DynFlags
298               -> NcgImpl statics instr jumpDest
299               -> BufHandle
300               -> UniqSupply
301               -> Stream IO RawCmmGroup ()
302               -> [[CLabel]]
303               -> [ ([NatCmmDecl statics instr],
304                    Maybe [Color.RegAllocStats statics instr],
305                    Maybe [Linear.RegAllocStats]) ]
306               -> Int
307               -> IO ( [[CLabel]],
308                       [([NatCmmDecl statics instr],
309                       Maybe [Color.RegAllocStats statics instr],
310                       Maybe [Linear.RegAllocStats])] )
311
312 cmmNativeGenStream dflags ncgImpl h us cmm_stream impAcc profAcc count
313  = do
314         r <- Stream.runStream cmm_stream
315         case r of
316           Left () -> return (reverse impAcc, reverse profAcc)
317           Right (cmms, cmm_stream') -> do
318             (impAcc,profAcc,us') <- cmmNativeGens dflags ncgImpl h us cmms
319                                               impAcc profAcc count
320             cmmNativeGenStream dflags ncgImpl h us' cmm_stream'
321                                               impAcc profAcc count
322
323
324 -- | Do native code generation on all these cmms.
325 --
326 cmmNativeGens :: (Outputable statics, Outputable instr, Instruction instr)
327               => DynFlags
328               -> NcgImpl statics instr jumpDest
329               -> BufHandle
330               -> UniqSupply
331               -> [RawCmmDecl]
332               -> [[CLabel]]
333               -> [ ([NatCmmDecl statics instr],
334                    Maybe [Color.RegAllocStats statics instr],
335                    Maybe [Linear.RegAllocStats]) ]
336               -> Int
337               -> IO ( [[CLabel]],
338                       [([NatCmmDecl statics instr],
339                        Maybe [Color.RegAllocStats statics instr],
340                        Maybe [Linear.RegAllocStats])],
341                       UniqSupply )
342
343 cmmNativeGens _ _ _ us [] impAcc profAcc _
344         = return (impAcc,profAcc,us)
345
346 cmmNativeGens dflags ncgImpl h us (cmm : cmms) impAcc profAcc count
347  = do
348         (us', native, imports, colorStats, linearStats)
349                 <- {-# SCC "cmmNativeGen" #-} cmmNativeGen dflags ncgImpl us cmm count
350
351         {-# SCC "pprNativeCode" #-} Pretty.bufLeftRender h
352                 $ withPprStyleDoc dflags (mkCodeStyle AsmStyle)
353                 $ vcat $ map (pprNatCmmDecl ncgImpl) native
354
355            -- carefully evaluate this strictly.  Binding it with 'let'
356            -- and then using 'seq' doesn't work, because the let
357            -- apparently gets inlined first.
358         lsPprNative <- return $!
359                 if  dopt Opt_D_dump_asm       dflags
360                  || dopt Opt_D_dump_asm_stats dflags
361                         then native
362                         else []
363
364         count' <- return $! count + 1;
365
366         -- force evaulation all this stuff to avoid space leaks
367         {-# SCC "seqString" #-} seqString (showSDoc dflags $ vcat $ map ppr imports) `seq` return ()
368
369         cmmNativeGens dflags ncgImpl
370             h us' cmms
371                         (imports : impAcc)
372                         ((lsPprNative, colorStats, linearStats) : profAcc)
373                         count'
374
375  where  seqString []            = ()
376         seqString (x:xs)        = x `seq` seqString xs `seq` ()
377
378
379 -- | Complete native code generation phase for a single top-level chunk of Cmm.
380 --      Dumping the output of each stage along the way.
381 --      Global conflict graph and NGC stats
382 cmmNativeGen
383         :: (Outputable statics, Outputable instr, Instruction instr)
384     => DynFlags
385     -> NcgImpl statics instr jumpDest
386         -> UniqSupply
387         -> RawCmmDecl                                   -- ^ the cmm to generate code for
388         -> Int                                          -- ^ sequence number of this top thing
389         -> IO   ( UniqSupply
390                 , [NatCmmDecl statics instr]                -- native code
391                 , [CLabel]                                  -- things imported by this cmm
392                 , Maybe [Color.RegAllocStats statics instr] -- stats for the coloring register allocator
393                 , Maybe [Linear.RegAllocStats])             -- stats for the linear register allocators
394
395 cmmNativeGen dflags ncgImpl us cmm count
396  = do
397         let platform = targetPlatform dflags
398
399         -- rewrite assignments to global regs
400         let fixed_cmm =
401                 {-# SCC "fixStgRegisters" #-}
402                 fixStgRegisters dflags cmm
403
404         -- cmm to cmm optimisations
405         let (opt_cmm, imports) =
406                 {-# SCC "cmmToCmm" #-}
407                 cmmToCmm dflags fixed_cmm
408
409         dumpIfSet_dyn dflags
410                 Opt_D_dump_opt_cmm "Optimised Cmm"
411                 (pprCmmGroup [opt_cmm])
412
413         -- generate native code from cmm
414         let ((native, lastMinuteImports), usGen) =
415                 {-# SCC "genMachCode" #-}
416                 initUs us $ genMachCode dflags (cmmTopCodeGen ncgImpl) opt_cmm
417
418         dumpIfSet_dyn dflags
419                 Opt_D_dump_asm_native "Native code"
420                 (vcat $ map (pprNatCmmDecl ncgImpl) native)
421
422         -- tag instructions with register liveness information
423         let (withLiveness, usLive) =
424                 {-# SCC "regLiveness" #-}
425                 initUs usGen
426                         $ mapM (regLiveness platform)
427                         $ map natCmmTopToLive native
428
429         dumpIfSet_dyn dflags
430                 Opt_D_dump_asm_liveness "Liveness annotations added"
431                 (vcat $ map ppr withLiveness)
432
433         -- allocate registers
434         (alloced, usAlloc, ppr_raStatsColor, ppr_raStatsLinear) <-
435          if ( dopt Opt_RegsGraph dflags
436            || dopt Opt_RegsIterative dflags)
437           then do
438                 -- the regs usable for allocation
439                 let (alloc_regs :: UniqFM (UniqSet RealReg))
440                         = foldr (\r -> plusUFM_C unionUniqSets
441                                         $ unitUFM (targetClassOfRealReg platform r) (unitUniqSet r))
442                                 emptyUFM
443                         $ allocatableRegs ncgImpl
444
445                 -- do the graph coloring register allocation
446                 let ((alloced, regAllocStats), usAlloc)
447                         = {-# SCC "RegAlloc" #-}
448                           initUs usLive
449                           $ Color.regAlloc
450                                 dflags
451                                 alloc_regs
452                                 (mkUniqSet [0 .. maxSpillSlots ncgImpl])
453                                 withLiveness
454
455                 -- dump out what happened during register allocation
456                 dumpIfSet_dyn dflags
457                         Opt_D_dump_asm_regalloc "Registers allocated"
458                         (vcat $ map (pprNatCmmDecl ncgImpl) alloced)
459
460                 dumpIfSet_dyn dflags
461                         Opt_D_dump_asm_regalloc_stages "Build/spill stages"
462                         (vcat   $ map (\(stage, stats)
463                                         -> text "# --------------------------"
464                                         $$ text "#  cmm " <> int count <> text " Stage " <> int stage
465                                         $$ ppr stats)
466                                 $ zip [0..] regAllocStats)
467
468                 let mPprStats =
469                         if dopt Opt_D_dump_asm_stats dflags
470                          then Just regAllocStats else Nothing
471
472                 -- force evaluation of the Maybe to avoid space leak
473                 mPprStats `seq` return ()
474
475                 return  ( alloced, usAlloc
476                         , mPprStats
477                         , Nothing)
478
479           else do
480                 -- do linear register allocation
481                 let reg_alloc proc = do
482                        (alloced, maybe_more_stack, ra_stats) <-
483                                Linear.regAlloc dflags proc
484                        case maybe_more_stack of
485                          Nothing -> return ( alloced, ra_stats )
486                          Just amount ->
487                            return ( ncgAllocMoreStack ncgImpl amount alloced
488                                   , ra_stats )
489
490                 let ((alloced, regAllocStats), usAlloc)
491                         = {-# SCC "RegAlloc" #-}
492                           initUs usLive
493                           $ liftM unzip
494                           $ mapM reg_alloc withLiveness
495
496                 dumpIfSet_dyn dflags
497                         Opt_D_dump_asm_regalloc "Registers allocated"
498                         (vcat $ map (pprNatCmmDecl ncgImpl) alloced)
499
500                 let mPprStats =
501                         if dopt Opt_D_dump_asm_stats dflags
502                          then Just (catMaybes regAllocStats) else Nothing
503
504                 -- force evaluation of the Maybe to avoid space leak
505                 mPprStats `seq` return ()
506
507                 return  ( alloced, usAlloc
508                         , Nothing
509                         , mPprStats)
510
511         ---- x86fp_kludge.  This pass inserts ffree instructions to clear
512         ---- the FPU stack on x86.  The x86 ABI requires that the FPU stack
513         ---- is clear, and library functions can return odd results if it
514         ---- isn't.
515         ----
516         ---- NB. must happen before shortcutBranches, because that
517         ---- generates JXX_GBLs which we can't fix up in x86fp_kludge.
518         let kludged = {-# SCC "x86fp_kludge" #-} ncg_x86fp_kludge ncgImpl alloced
519
520         ---- generate jump tables
521         let tabled      =
522                 {-# SCC "generateJumpTables" #-}
523                 generateJumpTables ncgImpl kludged
524
525         ---- shortcut branches
526         let shorted     =
527                 {-# SCC "shortcutBranches" #-}
528                 shortcutBranches dflags ncgImpl tabled
529
530         ---- sequence blocks
531         let sequenced   =
532                 {-# SCC "sequenceBlocks" #-}
533                 map (sequenceTop ncgImpl) shorted
534
535         ---- expansion of SPARC synthetic instrs
536         let expanded =
537                 {-# SCC "sparc_expand" #-}
538                 ncgExpandTop ncgImpl sequenced
539
540         dumpIfSet_dyn dflags
541                 Opt_D_dump_asm_expanded "Synthetic instructions expanded"
542                 (vcat $ map (pprNatCmmDecl ncgImpl) expanded)
543
544         return  ( usAlloc
545                 , expanded
546                 , lastMinuteImports ++ imports
547                 , ppr_raStatsColor
548                 , ppr_raStatsLinear)
549
550
551 x86fp_kludge :: NatCmmDecl (Alignment, CmmStatics) X86.Instr.Instr -> NatCmmDecl (Alignment, CmmStatics) X86.Instr.Instr
552 x86fp_kludge top@(CmmData _ _) = top
553 x86fp_kludge (CmmProc info lbl (ListGraph code)) =
554         CmmProc info lbl (ListGraph $ X86.Instr.i386_insert_ffrees code)
555
556
557 -- | Build a doc for all the imports.
558 --
559 makeImportsDoc :: DynFlags -> [CLabel] -> SDoc
560 makeImportsDoc dflags imports
561  = dyld_stubs imports
562             $$
563             -- On recent versions of Darwin, the linker supports
564             -- dead-stripping of code and data on a per-symbol basis.
565             -- There's a hack to make this work in PprMach.pprNatCmmDecl.
566             (if platformHasSubsectionsViaSymbols (targetPlatform dflags)
567              then text ".subsections_via_symbols"
568              else empty)
569             $$
570                 -- On recent GNU ELF systems one can mark an object file
571                 -- as not requiring an executable stack. If all objects
572                 -- linked into a program have this note then the program
573                 -- will not use an executable stack, which is good for
574                 -- security. GHC generated code does not need an executable
575                 -- stack so add the note in:
576             (if platformHasGnuNonexecStack (targetPlatform dflags)
577              then text ".section .note.GNU-stack,\"\",@progbits"
578              else empty)
579             $$
580                 -- And just because every other compiler does, lets stick in
581                 -- an identifier directive: .ident "GHC x.y.z"
582             (if platformHasIdentDirective (targetPlatform dflags)
583              then let compilerIdent = text "GHC" <+> text cProjectVersion
584                    in text ".ident" <+> doubleQuotes compilerIdent
585              else empty)
586
587  where
588         -- Generate "symbol stubs" for all external symbols that might
589         -- come from a dynamic library.
590         dyld_stubs :: [CLabel] -> SDoc
591 {-      dyld_stubs imps = vcat $ map pprDyldSymbolStub $
592                                     map head $ group $ sort imps-}
593
594         platform = targetPlatform dflags
595         arch = platformArch platform
596         os   = platformOS   platform
597
598         -- (Hack) sometimes two Labels pretty-print the same, but have
599         -- different uniques; so we compare their text versions...
600         dyld_stubs imps
601                 | needImportedSymbols dflags arch os
602                 = vcat $
603                         (pprGotDeclaration dflags arch os :) $
604                         map ( pprImportedSymbol dflags platform . fst . head) $
605                         groupBy (\(_,a) (_,b) -> a == b) $
606                         sortBy (\(_,a) (_,b) -> compare a b) $
607                         map doPpr $
608                         imps
609                 | otherwise
610                 = empty
611
612         doPpr lbl = (lbl, renderWithStyle dflags (pprCLabel platform lbl) astyle)
613         astyle = mkCodeStyle AsmStyle
614
615
616 -- -----------------------------------------------------------------------------
617 -- Sequencing the basic blocks
618
619 -- Cmm BasicBlocks are self-contained entities: they always end in a
620 -- jump, either non-local or to another basic block in the same proc.
621 -- In this phase, we attempt to place the basic blocks in a sequence
622 -- such that as many of the local jumps as possible turn into
623 -- fallthroughs.
624
625 sequenceTop
626         :: Instruction instr
627     => NcgImpl statics instr jumpDest -> NatCmmDecl statics instr -> NatCmmDecl statics instr
628
629 sequenceTop _       top@(CmmData _ _) = top
630 sequenceTop ncgImpl (CmmProc info lbl (ListGraph blocks)) =
631   CmmProc info lbl (ListGraph $ ncgMakeFarBranches ncgImpl $ sequenceBlocks info blocks)
632
633 -- The algorithm is very simple (and stupid): we make a graph out of
634 -- the blocks where there is an edge from one block to another iff the
635 -- first block ends by jumping to the second.  Then we topologically
636 -- sort this graph.  Then traverse the list: for each block, we first
637 -- output the block, then if it has an out edge, we move the
638 -- destination of the out edge to the front of the list, and continue.
639
640 -- FYI, the classic layout for basic blocks uses postorder DFS; this
641 -- algorithm is implemented in Hoopl.
642
643 sequenceBlocks
644         :: Instruction instr
645         => BlockEnv i
646         -> [NatBasicBlock instr]
647         -> [NatBasicBlock instr]
648
649 sequenceBlocks _ [] = []
650 sequenceBlocks infos (entry:blocks) =
651   seqBlocks infos (mkNode entry : reverse (flattenSCCs (sccBlocks blocks)))
652   -- the first block is the entry point ==> it must remain at the start.
653
654
655 sccBlocks
656         :: Instruction instr
657         => [NatBasicBlock instr]
658         -> [SCC ( NatBasicBlock instr
659                 , BlockId
660                 , [BlockId])]
661
662 sccBlocks blocks = stronglyConnCompFromEdgedVerticesR (map mkNode blocks)
663
664 -- we're only interested in the last instruction of
665 -- the block, and only if it has a single destination.
666 getOutEdges
667         :: Instruction instr
668         => [instr] -> [BlockId]
669
670 getOutEdges instrs
671         = case jumpDestsOfInstr (last instrs) of
672                 [one] -> [one]
673                 _many -> []
674
675 mkNode :: (Instruction t)
676        => GenBasicBlock t
677        -> (GenBasicBlock t, BlockId, [BlockId])
678 mkNode block@(BasicBlock id instrs) = (block, id, getOutEdges instrs)
679
680 seqBlocks :: BlockEnv i -> [(GenBasicBlock t1, BlockId, [BlockId])]
681                         -> [GenBasicBlock t1]
682 seqBlocks _ [] = []
683 seqBlocks infos ((block,_,[]) : rest)
684   = block : seqBlocks infos rest
685 seqBlocks infos ((block@(BasicBlock id instrs),_,[next]) : rest)
686   | can_fallthrough = BasicBlock id (init instrs) : seqBlocks infos rest'
687   | otherwise       = block : seqBlocks infos rest'
688   where
689         can_fallthrough = not (mapMember next infos) && can_reorder
690         (can_reorder, rest') = reorder next [] rest
691           -- TODO: we should do a better job for cycles; try to maximise the
692           -- fallthroughs within a loop.
693 seqBlocks _ _ = panic "AsmCodegen:seqBlocks"
694
695 reorder :: (Eq a) => a -> [(t, a, t1)] -> [(t, a, t1)] -> (Bool, [(t, a, t1)])
696 reorder  _ accum [] = (False, reverse accum)
697 reorder id accum (b@(block,id',out) : rest)
698   | id == id'  = (True, (block,id,out) : reverse accum ++ rest)
699   | otherwise  = reorder id (b:accum) rest
700
701
702 -- -----------------------------------------------------------------------------
703 -- Making far branches
704
705 -- Conditional branches on PowerPC are limited to +-32KB; if our Procs get too
706 -- big, we have to work around this limitation.
707
708 makeFarBranches
709         :: [NatBasicBlock PPC.Instr.Instr]
710         -> [NatBasicBlock PPC.Instr.Instr]
711 makeFarBranches blocks
712     | last blockAddresses < nearLimit = blocks
713     | otherwise = zipWith handleBlock blockAddresses blocks
714     where
715         blockAddresses = scanl (+) 0 $ map blockLen blocks
716         blockLen (BasicBlock _ instrs) = length instrs
717
718         handleBlock addr (BasicBlock id instrs)
719                 = BasicBlock id (zipWith makeFar [addr..] instrs)
720
721         makeFar _ (PPC.Instr.BCC PPC.Cond.ALWAYS tgt) = PPC.Instr.BCC PPC.Cond.ALWAYS tgt
722         makeFar addr (PPC.Instr.BCC cond tgt)
723             | abs (addr - targetAddr) >= nearLimit
724             = PPC.Instr.BCCFAR cond tgt
725             | otherwise
726             = PPC.Instr.BCC cond tgt
727             where Just targetAddr = lookupUFM blockAddressMap tgt
728         makeFar _ other            = other
729
730         nearLimit = 7000 -- 8192 instructions are allowed; let's keep some
731                          -- distance, as we have a few pseudo-insns that are
732                          -- pretty-printed as multiple instructions,
733                          -- and it's just not worth the effort to calculate
734                          -- things exactly
735
736         blockAddressMap = listToUFM $ zip (map blockId blocks) blockAddresses
737
738 -- -----------------------------------------------------------------------------
739 -- Generate jump tables
740
741 -- Analyzes all native code and generates data sections for all jump
742 -- table instructions.
743 generateJumpTables
744         :: NcgImpl statics instr jumpDest
745         -> [NatCmmDecl statics instr] -> [NatCmmDecl statics instr]
746 generateJumpTables ncgImpl xs = concatMap f xs
747     where f p@(CmmProc _ _ (ListGraph xs)) = p : concatMap g xs
748           f p = [p]
749           g (BasicBlock _ xs) = catMaybes (map (generateJumpTableForInstr ncgImpl) xs)
750
751 -- -----------------------------------------------------------------------------
752 -- Shortcut branches
753
754 shortcutBranches
755         :: DynFlags
756     -> NcgImpl statics instr jumpDest
757         -> [NatCmmDecl statics instr]
758         -> [NatCmmDecl statics instr]
759
760 shortcutBranches dflags ncgImpl tops
761   | optLevel dflags < 1 = tops    -- only with -O or higher
762   | otherwise           = map (apply_mapping ncgImpl mapping) tops'
763   where
764     (tops', mappings) = mapAndUnzip (build_mapping ncgImpl) tops
765     mapping = foldr plusUFM emptyUFM mappings
766
767 build_mapping :: NcgImpl statics instr jumpDest
768               -> GenCmmDecl d (BlockEnv t) (ListGraph instr)
769               -> (GenCmmDecl d (BlockEnv t) (ListGraph instr), UniqFM jumpDest)
770 build_mapping _ top@(CmmData _ _) = (top, emptyUFM)
771 build_mapping _ (CmmProc info lbl (ListGraph []))
772   = (CmmProc info lbl (ListGraph []), emptyUFM)
773 build_mapping ncgImpl (CmmProc info lbl (ListGraph (head:blocks)))
774   = (CmmProc info lbl (ListGraph (head:others)), mapping)
775         -- drop the shorted blocks, but don't ever drop the first one,
776         -- because it is pointed to by a global label.
777   where
778     -- find all the blocks that just consist of a jump that can be
779     -- shorted.
780     -- Don't completely eliminate loops here -- that can leave a dangling jump!
781     (_, shortcut_blocks, others) = foldl split (emptyBlockSet, [], []) blocks
782     split (s, shortcut_blocks, others) b@(BasicBlock id [insn])
783         | Just jd <- canShortcut ncgImpl insn,
784           Just dest <- getJumpDestBlockId ncgImpl jd,
785           not (has_info id),
786           (setMember dest s) || dest == id -- loop checks
787         = (s, shortcut_blocks, b : others)
788     split (s, shortcut_blocks, others) (BasicBlock id [insn])
789         | Just dest <- canShortcut ncgImpl insn,
790           not (has_info id)
791         = (setInsert id s, (id,dest) : shortcut_blocks, others)
792     split (s, shortcut_blocks, others) other = (s, shortcut_blocks, other : others)
793
794     -- do not eliminate blocks that have an info table
795     has_info l = mapMember l info
796
797     -- build a mapping from BlockId to JumpDest for shorting branches
798     mapping = foldl add emptyUFM shortcut_blocks
799     add ufm (id,dest) = addToUFM ufm id dest
800
801 apply_mapping :: NcgImpl statics instr jumpDest
802               -> UniqFM jumpDest
803               -> GenCmmDecl statics h (ListGraph instr)
804               -> GenCmmDecl statics h (ListGraph instr)
805 apply_mapping ncgImpl ufm (CmmData sec statics)
806   = CmmData sec (shortcutStatics ncgImpl (lookupUFM ufm) statics)
807 apply_mapping ncgImpl ufm (CmmProc info lbl (ListGraph blocks))
808   = CmmProc info lbl (ListGraph $ map short_bb blocks)
809   where
810     short_bb (BasicBlock id insns) = BasicBlock id $! map short_insn insns
811     short_insn i = shortcutJump ncgImpl (lookupUFM ufm) i
812                  -- shortcutJump should apply the mapping repeatedly,
813                  -- just in case we can short multiple branches.
814
815 -- -----------------------------------------------------------------------------
816 -- Instruction selection
817
818 -- Native code instruction selection for a chunk of stix code.  For
819 -- this part of the computation, we switch from the UniqSM monad to
820 -- the NatM monad.  The latter carries not only a Unique, but also an
821 -- Int denoting the current C stack pointer offset in the generated
822 -- code; this is needed for creating correct spill offsets on
823 -- architectures which don't offer, or for which it would be
824 -- prohibitively expensive to employ, a frame pointer register.  Viz,
825 -- x86.
826
827 -- The offset is measured in bytes, and indicates the difference
828 -- between the current (simulated) C stack-ptr and the value it was at
829 -- the beginning of the block.  For stacks which grow down, this value
830 -- should be either zero or negative.
831
832 -- Switching between the two monads whilst carrying along the same
833 -- Unique supply breaks abstraction.  Is that bad?
834
835 genMachCode
836         :: DynFlags
837         -> (RawCmmDecl -> NatM [NatCmmDecl statics instr])
838         -> RawCmmDecl
839         -> UniqSM
840                 ( [NatCmmDecl statics instr]
841                 , [CLabel])
842
843 genMachCode dflags cmmTopCodeGen cmm_top
844   = do  { initial_us <- getUs
845         ; let initial_st           = mkNatM_State initial_us 0 dflags
846               (new_tops, final_st) = initNat initial_st (cmmTopCodeGen cmm_top)
847               final_delta          = natm_delta final_st
848               final_imports        = natm_imports final_st
849         ; if   final_delta == 0
850           then return (new_tops, final_imports)
851           else pprPanic "genMachCode: nonzero final delta" (int final_delta)
852     }
853
854 -- -----------------------------------------------------------------------------
855 -- Generic Cmm optimiser
856
857 {-
858 Here we do:
859
860   (a) Constant folding
861   (c) Position independent code and dynamic linking
862         (i)  introduce the appropriate indirections
863              and position independent refs
864         (ii) compile a list of imported symbols
865   (d) Some arch-specific optimizations
866
867 (a) will be moving to the new Hoopl pipeline, however, (c) and
868 (d) are only needed by the native backend and will continue to live
869 here.
870
871 Ideas for other things we could do (put these in Hoopl please!):
872
873   - shortcut jumps-to-jumps
874   - simple CSE: if an expr is assigned to a temp, then replace later occs of
875     that expr with the temp, until the expr is no longer valid (can push through
876     temp assignments, and certain assigns to mem...)
877 -}
878
879 cmmToCmm :: DynFlags -> RawCmmDecl -> (RawCmmDecl, [CLabel])
880 cmmToCmm _ top@(CmmData _ _) = (top, [])
881 cmmToCmm dflags (CmmProc info lbl (ListGraph blocks)) = runCmmOpt dflags $ do
882   blocks' <- mapM cmmBlockConFold blocks
883   return $ CmmProc info lbl (ListGraph blocks')
884
885 newtype CmmOptM a = CmmOptM (([CLabel], DynFlags) -> (# a, [CLabel] #))
886
887 instance Monad CmmOptM where
888   return x = CmmOptM $ \(imports, _) -> (# x,imports #)
889   (CmmOptM f) >>= g =
890     CmmOptM $ \(imports, dflags) ->
891                 case f (imports, dflags) of
892                   (# x, imports' #) ->
893                     case g x of
894                       CmmOptM g' -> g' (imports', dflags)
895
896 addImportCmmOpt :: CLabel -> CmmOptM ()
897 addImportCmmOpt lbl = CmmOptM $ \(imports, _dflags) -> (# (), lbl:imports #)
898
899 instance HasDynFlags CmmOptM where
900     getDynFlags = CmmOptM $ \(imports, dflags) -> (# dflags, imports #)
901
902 runCmmOpt :: DynFlags -> CmmOptM a -> (a, [CLabel])
903 runCmmOpt dflags (CmmOptM f) = case f ([], dflags) of
904                         (# result, imports #) -> (result, imports)
905
906 cmmBlockConFold :: CmmBasicBlock -> CmmOptM CmmBasicBlock
907 cmmBlockConFold (BasicBlock id stmts) = do
908   stmts' <- mapM cmmStmtConFold stmts
909   return $ BasicBlock id stmts'
910
911 -- This does three optimizations, but they're very quick to check, so we don't
912 -- bother turning them off even when the Hoopl code is active.  Since
913 -- this is on the old Cmm representation, we can't reuse the code either:
914 --  * reg = reg      --> nop
915 --  * if 0 then jump --> nop
916 --  * if 1 then jump --> jump
917 -- We might be tempted to skip this step entirely of not Opt_PIC, but
918 -- there is some PowerPC code for the non-PIC case, which would also
919 -- have to be separated.
920 cmmStmtConFold :: CmmStmt -> CmmOptM CmmStmt
921 cmmStmtConFold stmt
922    = case stmt of
923         CmmAssign reg src
924            -> do src' <- cmmExprConFold DataReference src
925                  return $ case src' of
926                    CmmReg reg' | reg == reg' -> CmmNop
927                    new_src -> CmmAssign reg new_src
928
929         CmmStore addr src
930            -> do addr' <- cmmExprConFold DataReference addr
931                  src'  <- cmmExprConFold DataReference src
932                  return $ CmmStore addr' src'
933
934         CmmJump addr live
935            -> do addr' <- cmmExprConFold JumpReference addr
936                  return $ CmmJump addr' live
937
938         CmmCall target regs args returns
939            -> do target' <- case target of
940                               CmmCallee e conv -> do
941                                 e' <- cmmExprConFold CallReference e
942                                 return $ CmmCallee e' conv
943                               op@(CmmPrim _ Nothing) ->
944                                 return op
945                               CmmPrim op (Just stmts) ->
946                                 do stmts' <- mapM cmmStmtConFold stmts
947                                    return $ CmmPrim op (Just stmts')
948                  args' <- mapM (\(CmmHinted arg hint) -> do
949                                   arg' <- cmmExprConFold DataReference arg
950                                   return (CmmHinted arg' hint)) args
951                  return $ CmmCall target' regs args' returns
952
953         CmmCondBranch test dest
954            -> do test' <- cmmExprConFold DataReference test
955                  dflags <- getDynFlags
956                  return $ case test' of
957                    CmmLit (CmmInt 0 _) ->
958                      CmmComment (mkFastString ("deleted: " ++
959                                         showSDoc dflags (pprStmt stmt)))
960
961                    CmmLit (CmmInt _ _) -> CmmBranch dest
962                    _other -> CmmCondBranch test' dest
963
964         CmmSwitch expr ids
965            -> do expr' <- cmmExprConFold DataReference expr
966                  return $ CmmSwitch expr' ids
967
968         other
969            -> return other
970
971 cmmExprConFold :: ReferenceKind -> CmmExpr -> CmmOptM CmmExpr
972 cmmExprConFold referenceKind expr = do
973     dflags <- getDynFlags
974
975     -- With -O1 and greater, the cmmSink pass does constant-folding, so
976     -- we don't need to do it again here.
977     let expr' = if optLevel dflags >= 1
978                     then expr
979                     else cmmExprCon dflags expr
980
981     cmmExprNative referenceKind expr'
982
983 cmmExprCon :: DynFlags -> CmmExpr -> CmmExpr
984 cmmExprCon dflags (CmmLoad addr rep) = CmmLoad (cmmExprCon dflags addr) rep
985 cmmExprCon dflags (CmmMachOp mop args)
986     = cmmMachOpFold dflags mop (map (cmmExprCon dflags) args)
987 cmmExprCon _ other = other
988
989 -- handles both PIC and non-PIC cases... a very strange mixture
990 -- of things to do.
991 cmmExprNative :: ReferenceKind -> CmmExpr -> CmmOptM CmmExpr
992 cmmExprNative referenceKind expr = do
993      dflags <- getDynFlags
994      let platform = targetPlatform dflags
995          arch = platformArch platform
996      case expr of
997         CmmLoad addr rep
998            -> do addr' <- cmmExprNative DataReference addr
999                  return $ CmmLoad addr' rep
1000
1001         CmmMachOp mop args
1002            -> do args' <- mapM (cmmExprNative DataReference) args
1003                  return $ CmmMachOp mop args'
1004
1005         CmmLit (CmmBlock id)
1006            -> cmmExprNative referenceKind (CmmLit (CmmLabel (infoTblLbl id)))
1007            -- we must convert block Ids to CLabels here, because we
1008            -- might have to do the PIC transformation.  Hence we must
1009            -- not modify BlockIds beyond this point.
1010
1011         CmmLit (CmmLabel lbl)
1012            -> do
1013                 cmmMakeDynamicReference dflags addImportCmmOpt referenceKind lbl
1014         CmmLit (CmmLabelOff lbl off)
1015            -> do
1016                  dynRef <- cmmMakeDynamicReference dflags addImportCmmOpt referenceKind lbl
1017                  -- need to optimize here, since it's late
1018                  return $ cmmMachOpFold dflags (MO_Add (wordWidth dflags)) [
1019                      dynRef,
1020                      (CmmLit $ CmmInt (fromIntegral off) (wordWidth dflags))
1021                    ]
1022
1023         -- On powerpc (non-PIC), it's easier to jump directly to a label than
1024         -- to use the register table, so we replace these registers
1025         -- with the corresponding labels:
1026         CmmReg (CmmGlobal EagerBlackholeInfo)
1027           | arch == ArchPPC && not (dopt Opt_PIC dflags)
1028           -> cmmExprNative referenceKind $
1029              CmmLit (CmmLabel (mkCmmCodeLabel rtsPackageId (fsLit "__stg_EAGER_BLACKHOLE_info")))
1030         CmmReg (CmmGlobal GCEnter1)
1031           | arch == ArchPPC && not (dopt Opt_PIC dflags)
1032           -> cmmExprNative referenceKind $
1033              CmmLit (CmmLabel (mkCmmCodeLabel rtsPackageId (fsLit "__stg_gc_enter_1")))
1034         CmmReg (CmmGlobal GCFun)
1035           | arch == ArchPPC && not (dopt Opt_PIC dflags)
1036           -> cmmExprNative referenceKind $
1037              CmmLit (CmmLabel (mkCmmCodeLabel rtsPackageId (fsLit "__stg_gc_fun")))
1038
1039         other
1040            -> return other
1041
1042 \end{code}
1043