Refactor visible type application.
[ghc.git] / compiler / typecheck / TcExpr.hs
1 {-
2 %
3 (c) The University of Glasgow 2006
4 (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
5
6 \section[TcExpr]{Typecheck an expression}
7 -}
8
9 {-# LANGUAGE CPP, TupleSections, ScopedTypeVariables #-}
10
11 module TcExpr ( tcPolyExpr, tcMonoExpr, tcMonoExprNC,
12 tcInferSigma, tcInferSigmaNC, tcInferRho, tcInferRhoNC,
13 tcSyntaxOp, tcSyntaxOpGen, SyntaxOpType(..), synKnownType,
14 tcCheckId,
15 addExprErrCtxt,
16 getFixedTyVars ) where
17
18 #include "HsVersions.h"
19
20 import {-# SOURCE #-} TcSplice( tcSpliceExpr, tcTypedBracket, tcUntypedBracket )
21 import THNames( liftStringName, liftName )
22
23 import HsSyn
24 import TcHsSyn
25 import TcRnMonad
26 import TcUnify
27 import BasicTypes
28 import Inst
29 import TcBinds ( chooseInferredQuantifiers, tcLocalBinds
30 , tcUserTypeSig, tcExtendTyVarEnvFromSig )
31 import TcSimplify ( simplifyInfer )
32 import FamInst ( tcGetFamInstEnvs, tcLookupDataFamInst )
33 import FamInstEnv ( FamInstEnvs )
34 import RnEnv ( addUsedGRE, addNameClashErrRn
35 , unknownSubordinateErr )
36 import TcEnv
37 import TcArrows
38 import TcMatches
39 import TcHsType
40 import TcPatSyn( tcPatSynBuilderOcc, nonBidirectionalErr )
41 import TcPat
42 import TcMType
43 import TcType
44 import DsMonad
45 import Id
46 import IdInfo
47 import ConLike
48 import DataCon
49 import PatSyn
50 import Name
51 import RdrName
52 import TyCon
53 import Type
54 import TysPrim ( tYPE )
55 import TcEvidence
56 import VarSet
57 import TysWiredIn
58 import TysPrim( intPrimTy )
59 import PrimOp( tagToEnumKey )
60 import PrelNames
61 import MkId ( proxyHashId )
62 import DynFlags
63 import SrcLoc
64 import Util
65 import VarEnv ( emptyTidyEnv )
66 import ListSetOps
67 import Maybes
68 import Outputable
69 import FastString
70 import Control.Monad
71 import Class(classTyCon)
72 import qualified GHC.LanguageExtensions as LangExt
73
74 import Data.Function
75 import Data.List
76 import Data.Either
77 import qualified Data.Set as Set
78
79 {-
80 ************************************************************************
81 * *
82 \subsection{Main wrappers}
83 * *
84 ************************************************************************
85 -}
86
87 tcPolyExpr, tcPolyExprNC
88 :: LHsExpr Name -- Expression to type check
89 -> TcSigmaType -- Expected type (could be a polytype)
90 -> TcM (LHsExpr TcId) -- Generalised expr with expected type
91
92 -- tcPolyExpr is a convenient place (frequent but not too frequent)
93 -- place to add context information.
94 -- The NC version does not do so, usually because the caller wants
95 -- to do so himself.
96
97 tcPolyExpr expr res_ty = tc_poly_expr expr (mkCheckExpType res_ty)
98 tcPolyExprNC expr res_ty = tc_poly_expr_nc expr (mkCheckExpType res_ty)
99
100 -- these versions take an ExpType
101 tc_poly_expr, tc_poly_expr_nc :: LHsExpr Name -> ExpSigmaType -> TcM (LHsExpr TcId)
102 tc_poly_expr expr res_ty
103 = addExprErrCtxt expr $
104 do { traceTc "tcPolyExpr" (ppr res_ty); tc_poly_expr_nc expr res_ty }
105
106 tc_poly_expr_nc (L loc expr) res_ty
107 = do { traceTc "tcPolyExprNC" (ppr res_ty)
108 ; (wrap, expr')
109 <- tcSkolemiseET GenSigCtxt res_ty $ \ res_ty ->
110 setSrcSpan loc $
111 -- NB: setSrcSpan *after* skolemising, so we get better
112 -- skolem locations
113 tcExpr expr res_ty
114 ; return $ L loc (mkHsWrap wrap expr') }
115
116 ---------------
117 tcMonoExpr, tcMonoExprNC
118 :: LHsExpr Name -- Expression to type check
119 -> ExpRhoType -- Expected type
120 -- Definitely no foralls at the top
121 -> TcM (LHsExpr TcId)
122
123 tcMonoExpr expr res_ty
124 = addErrCtxt (exprCtxt expr) $
125 tcMonoExprNC expr res_ty
126
127 tcMonoExprNC (L loc expr) res_ty
128 = setSrcSpan loc $
129 do { expr' <- tcExpr expr res_ty
130 ; return (L loc expr') }
131
132 ---------------
133 tcInferSigma, tcInferSigmaNC :: LHsExpr Name -> TcM ( LHsExpr TcId
134 , TcSigmaType )
135 -- Infer a *sigma*-type.
136 tcInferSigma expr = addErrCtxt (exprCtxt expr) (tcInferSigmaNC expr)
137
138 tcInferSigmaNC (L loc expr)
139 = setSrcSpan loc $
140 do { (expr', sigma) <- tcInfer (tcExpr expr)
141 ; return (L loc expr', sigma) }
142
143 tcInferRho, tcInferRhoNC :: LHsExpr Name -> TcM (LHsExpr TcId, TcRhoType)
144 -- Infer a *rho*-type. The return type is always (shallowly) instantiated.
145 tcInferRho expr = addErrCtxt (exprCtxt expr) (tcInferRhoNC expr)
146
147 tcInferRhoNC expr
148 = do { (expr', sigma) <- tcInferSigmaNC expr
149 ; (wrap, rho) <- topInstantiate (exprCtOrigin (unLoc expr)) sigma
150 ; return (mkLHsWrap wrap expr', rho) }
151
152
153 {-
154 ************************************************************************
155 * *
156 tcExpr: the main expression typechecker
157 * *
158 ************************************************************************
159
160 NB: The res_ty is always deeply skolemised.
161 -}
162
163 tcExpr :: HsExpr Name -> ExpRhoType -> TcM (HsExpr TcId)
164 tcExpr (HsVar (L _ name)) res_ty = tcCheckId name res_ty
165 tcExpr (HsUnboundVar v) res_ty = tcUnboundId v res_ty
166
167 tcExpr e@(HsApp {}) res_ty = tcApp1 e res_ty
168 tcExpr e@(HsAppType {}) res_ty = tcApp1 e res_ty
169
170 tcExpr e@(HsLit lit) res_ty = do { let lit_ty = hsLitType lit
171 ; tcWrapResult e (HsLit lit) lit_ty res_ty }
172
173 tcExpr (HsPar expr) res_ty = do { expr' <- tcMonoExprNC expr res_ty
174 ; return (HsPar expr') }
175
176 tcExpr (HsSCC src lbl expr) res_ty
177 = do { expr' <- tcMonoExpr expr res_ty
178 ; return (HsSCC src lbl expr') }
179
180 tcExpr (HsTickPragma src info srcInfo expr) res_ty
181 = do { expr' <- tcMonoExpr expr res_ty
182 ; return (HsTickPragma src info srcInfo expr') }
183
184 tcExpr (HsCoreAnn src lbl expr) res_ty
185 = do { expr' <- tcMonoExpr expr res_ty
186 ; return (HsCoreAnn src lbl expr') }
187
188 tcExpr (HsOverLit lit) res_ty
189 = do { lit' <- newOverloadedLit lit res_ty
190 ; return (HsOverLit lit') }
191
192 tcExpr (NegApp expr neg_expr) res_ty
193 = do { (expr', neg_expr')
194 <- tcSyntaxOp NegateOrigin neg_expr [SynAny] res_ty $
195 \[arg_ty] ->
196 tcMonoExpr expr (mkCheckExpType arg_ty)
197 ; return (NegApp expr' neg_expr') }
198
199 tcExpr e@(HsIPVar x) res_ty
200 = do { {- Implicit parameters must have a *tau-type* not a
201 type scheme. We enforce this by creating a fresh
202 type variable as its type. (Because res_ty may not
203 be a tau-type.) -}
204 ip_ty <- newOpenFlexiTyVarTy
205 ; let ip_name = mkStrLitTy (hsIPNameFS x)
206 ; ipClass <- tcLookupClass ipClassName
207 ; ip_var <- emitWantedEvVar origin (mkClassPred ipClass [ip_name, ip_ty])
208 ; tcWrapResult e (fromDict ipClass ip_name ip_ty (HsVar (noLoc ip_var)))
209 ip_ty res_ty }
210 where
211 -- Coerces a dictionary for `IP "x" t` into `t`.
212 fromDict ipClass x ty = HsWrap $ mkWpCastR $
213 unwrapIP $ mkClassPred ipClass [x,ty]
214 origin = IPOccOrigin x
215
216 tcExpr e@(HsOverLabel l) res_ty -- See Note [Type-checking overloaded labels]
217 = do { isLabelClass <- tcLookupClass isLabelClassName
218 ; alpha <- newOpenFlexiTyVarTy
219 ; let lbl = mkStrLitTy l
220 pred = mkClassPred isLabelClass [lbl, alpha]
221 ; loc <- getSrcSpanM
222 ; var <- emitWantedEvVar origin pred
223 ; let proxy_arg = L loc (mkHsWrap (mkWpTyApps [typeSymbolKind, lbl])
224 (HsVar (L loc proxyHashId)))
225 tm = L loc (fromDict pred (HsVar (L loc var))) `HsApp` proxy_arg
226 ; tcWrapResult e tm alpha res_ty }
227 where
228 -- Coerces a dictionary for `IsLabel "x" t` into `Proxy# x -> t`.
229 fromDict pred = HsWrap $ mkWpCastR $ unwrapIP pred
230 origin = OverLabelOrigin l
231
232 tcExpr (HsLam match) res_ty
233 = do { (co_fn, _, match') <- tcMatchLambda herald match_ctxt match res_ty
234 ; return (mkHsWrap co_fn (HsLam match')) }
235 where
236 match_ctxt = MC { mc_what = LambdaExpr, mc_body = tcBody }
237 herald = sep [ text "The lambda expression" <+>
238 quotes (pprSetDepth (PartWay 1) $
239 pprMatches (LambdaExpr :: HsMatchContext Name) match),
240 -- The pprSetDepth makes the abstraction print briefly
241 text "has"]
242
243 tcExpr e@(HsLamCase _ matches) res_ty
244 = do { (co_fn, ~[arg_ty], matches')
245 <- tcMatchLambda msg match_ctxt matches res_ty
246 -- The laziness annotation is because we don't want to fail here
247 -- if there are multiple arguments
248 ; return (mkHsWrap co_fn $ HsLamCase arg_ty matches') }
249 where msg = sep [ text "The function" <+> quotes (ppr e)
250 , text "requires"]
251 match_ctxt = MC { mc_what = CaseAlt, mc_body = tcBody }
252
253 tcExpr e@(ExprWithTySig expr sig_ty) res_ty
254 = do { sig_info <- checkNoErrs $ -- Avoid error cascade
255 tcUserTypeSig sig_ty Nothing
256 ; (expr', poly_ty) <- tcExprSig expr sig_info
257 ; let expr'' = ExprWithTySigOut expr' sig_ty
258 ; tcWrapResult e expr'' poly_ty res_ty }
259
260 {-
261 Note [Type-checking overloaded labels]
262 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
263 Recall that (in GHC.OverloadedLabels) we have
264
265 class IsLabel (x :: Symbol) a where
266 fromLabel :: Proxy# x -> a
267
268 When we see an overloaded label like `#foo`, we generate a fresh
269 variable `alpha` for the type and emit an `IsLabel "foo" alpha`
270 constraint. Because the `IsLabel` class has a single method, it is
271 represented by a newtype, so we can coerce `IsLabel "foo" alpha` to
272 `Proxy# "foo" -> alpha` (just like for implicit parameters). We then
273 apply it to `proxy#` of type `Proxy# "foo"`.
274
275 That is, we translate `#foo` to `fromLabel (proxy# :: Proxy# "foo")`.
276 -}
277
278
279 {-
280 ************************************************************************
281 * *
282 Infix operators and sections
283 * *
284 ************************************************************************
285
286 Note [Left sections]
287 ~~~~~~~~~~~~~~~~~~~~
288 Left sections, like (4 *), are equivalent to
289 \ x -> (*) 4 x,
290 or, if PostfixOperators is enabled, just
291 (*) 4
292 With PostfixOperators we don't actually require the function to take
293 two arguments at all. For example, (x `not`) means (not x); you get
294 postfix operators! Not Haskell 98, but it's less work and kind of
295 useful.
296
297 Note [Typing rule for ($)]
298 ~~~~~~~~~~~~~~~~~~~~~~~~~~
299 People write
300 runST $ blah
301 so much, where
302 runST :: (forall s. ST s a) -> a
303 that I have finally given in and written a special type-checking
304 rule just for saturated appliations of ($).
305 * Infer the type of the first argument
306 * Decompose it; should be of form (arg2_ty -> res_ty),
307 where arg2_ty might be a polytype
308 * Use arg2_ty to typecheck arg2
309
310 Note [Typing rule for seq]
311 ~~~~~~~~~~~~~~~~~~~~~~~~~~
312 We want to allow
313 x `seq` (# p,q #)
314 which suggests this type for seq:
315 seq :: forall (a:*) (b:Open). a -> b -> b,
316 with (b:Open) meaning that be can be instantiated with an unboxed
317 tuple. The trouble is that this might accept a partially-applied
318 'seq', and I'm just not certain that would work. I'm only sure it's
319 only going to work when it's fully applied, so it turns into
320 case x of _ -> (# p,q #)
321
322 So it seems more uniform to treat 'seq' as it it was a language
323 construct.
324
325 See also Note [seqId magic] in MkId
326 -}
327
328 tcExpr expr@(OpApp arg1 op fix arg2) res_ty
329 | (L loc (HsVar (L lv op_name))) <- op
330 , op_name `hasKey` seqIdKey -- Note [Typing rule for seq]
331 = do { arg1_ty <- newFlexiTyVarTy liftedTypeKind
332 ; let arg2_exp_ty = res_ty
333 ; arg1' <- tcArg op arg1 arg1_ty 1
334 ; arg2' <- addErrCtxt (funAppCtxt op arg2 2) $
335 tc_poly_expr_nc arg2 arg2_exp_ty
336 ; arg2_ty <- readExpType arg2_exp_ty
337 ; op_id <- tcLookupId op_name
338 ; let op' = L loc (HsWrap (mkWpTyApps [arg1_ty, arg2_ty])
339 (HsVar (L lv op_id)))
340 ; return $ OpApp arg1' op' fix arg2' }
341
342 | (L loc (HsVar (L lv op_name))) <- op
343 , op_name `hasKey` dollarIdKey -- Note [Typing rule for ($)]
344 = do { traceTc "Application rule" (ppr op)
345 ; (arg1', arg1_ty) <- tcInferSigma arg1
346
347 ; let doc = text "The first argument of ($) takes"
348 orig1 = exprCtOrigin (unLoc arg1)
349 ; (wrap_arg1, [arg2_sigma], op_res_ty) <-
350 matchActualFunTys doc orig1 (Just arg1) 1 arg1_ty
351
352 -- We have (arg1 $ arg2)
353 -- So: arg1_ty = arg2_ty -> op_res_ty
354 -- where arg2_sigma maybe polymorphic; that's the point
355
356 ; arg2' <- tcArg op arg2 arg2_sigma 2
357
358 -- Make sure that the argument type has kind '*'
359 -- ($) :: forall (r:RuntimeRep) (a:*) (b:TYPE r). (a->b) -> a -> b
360 -- Eg we do not want to allow (D# $ 4.0#) Trac #5570
361 -- (which gives a seg fault)
362 --
363 -- The *result* type can have any kind (Trac #8739),
364 -- so we don't need to check anything for that
365 ; _ <- unifyKind (Just arg2_sigma) (typeKind arg2_sigma) liftedTypeKind
366 -- ignore the evidence. arg2_sigma must have type * or #,
367 -- because we know arg2_sigma -> or_res_ty is well-kinded
368 -- (because otherwise matchActualFunTys would fail)
369 -- There's no possibility here of, say, a kind family reducing to *.
370
371 ; wrap_res <- tcSubTypeHR orig1 (Just expr) op_res_ty res_ty
372 -- op_res -> res
373
374 ; op_id <- tcLookupId op_name
375 ; res_ty <- readExpType res_ty
376 ; let op' = L loc (HsWrap (mkWpTyApps [ getRuntimeRep "tcExpr ($)" res_ty
377 , arg2_sigma
378 , res_ty])
379 (HsVar (L lv op_id)))
380 -- arg1' :: arg1_ty
381 -- wrap_arg1 :: arg1_ty "->" (arg2_sigma -> op_res_ty)
382 -- wrap_res :: op_res_ty "->" res_ty
383 -- op' :: (a2_ty -> res_ty) -> a2_ty -> res_ty
384
385 -- wrap1 :: arg1_ty "->" (arg2_sigma -> res_ty)
386 wrap1 = mkWpFun idHsWrapper wrap_res arg2_sigma res_ty
387 <.> wrap_arg1
388
389 ; return (OpApp (mkLHsWrap wrap1 arg1') op' fix arg2') }
390
391 | (L loc (HsRecFld (Ambiguous lbl _))) <- op
392 , Just sig_ty <- obviousSig (unLoc arg1)
393 -- See Note [Disambiguating record fields]
394 = do { sig_tc_ty <- tcHsSigWcType ExprSigCtxt sig_ty
395 ; sel_name <- disambiguateSelector lbl sig_tc_ty
396 ; let op' = L loc (HsRecFld (Unambiguous lbl sel_name))
397 ; tcExpr (OpApp arg1 op' fix arg2) res_ty
398 }
399
400 | otherwise
401 = do { traceTc "Non Application rule" (ppr op)
402 ; (wrap, op', [Left arg1', Left arg2'])
403 <- tcApp (Just $ mk_op_msg op)
404 op [Left arg1, Left arg2] res_ty
405 ; return (mkHsWrap wrap $ OpApp arg1' op' fix arg2') }
406
407 -- Right sections, equivalent to \ x -> x `op` expr, or
408 -- \ x -> op x expr
409
410 tcExpr expr@(SectionR op arg2) res_ty
411 = do { (op', op_ty) <- tcInferFun op
412 ; (wrap_fun, [arg1_ty, arg2_ty], op_res_ty) <-
413 matchActualFunTys (mk_op_msg op) SectionOrigin (Just op) 2 op_ty
414 ; wrap_res <- tcSubTypeHR SectionOrigin (Just expr)
415 (mkFunTy arg1_ty op_res_ty) res_ty
416 ; arg2' <- tcArg op arg2 arg2_ty 2
417 ; return ( mkHsWrap wrap_res $
418 SectionR (mkLHsWrap wrap_fun op') arg2' ) }
419
420 tcExpr expr@(SectionL arg1 op) res_ty
421 = do { (op', op_ty) <- tcInferFun op
422 ; dflags <- getDynFlags -- Note [Left sections]
423 ; let n_reqd_args | xopt LangExt.PostfixOperators dflags = 1
424 | otherwise = 2
425
426 ; (wrap_fn, (arg1_ty:arg_tys), op_res_ty)
427 <- matchActualFunTys (mk_op_msg op) SectionOrigin (Just op)
428 n_reqd_args op_ty
429 ; wrap_res <- tcSubTypeHR SectionOrigin (Just expr)
430 (mkFunTys arg_tys op_res_ty) res_ty
431 ; arg1' <- tcArg op arg1 arg1_ty 1
432 ; return ( mkHsWrap wrap_res $
433 SectionL arg1' (mkLHsWrap wrap_fn op') ) }
434
435 tcExpr expr@(ExplicitTuple tup_args boxity) res_ty
436 | all tupArgPresent tup_args
437 = do { let arity = length tup_args
438 tup_tc = tupleTyCon boxity arity
439 ; res_ty <- expTypeToType res_ty
440 ; (coi, arg_tys) <- matchExpectedTyConApp tup_tc res_ty
441 -- Unboxed tuples have RuntimeRep vars, which we
442 -- don't care about here
443 -- See Note [Unboxed tuple RuntimeRep vars] in TyCon
444 ; let arg_tys' = case boxity of Unboxed -> drop arity arg_tys
445 Boxed -> arg_tys
446 ; tup_args1 <- tcTupArgs tup_args arg_tys'
447 ; return $ mkHsWrapCo coi (ExplicitTuple tup_args1 boxity) }
448
449 | otherwise
450 = -- The tup_args are a mixture of Present and Missing (for tuple sections)
451 do { let arity = length tup_args
452
453 ; arg_tys <- case boxity of
454 { Boxed -> newFlexiTyVarTys arity liftedTypeKind
455 ; Unboxed -> replicateM arity newOpenFlexiTyVarTy }
456 ; let actual_res_ty
457 = mkFunTys [ty | (ty, (L _ (Missing _))) <- arg_tys `zip` tup_args]
458 (mkTupleTy boxity arg_tys)
459
460 ; wrap <- tcSubTypeHR (Shouldn'tHappenOrigin "ExpTuple")
461 (Just expr)
462 actual_res_ty res_ty
463
464 -- Handle tuple sections where
465 ; tup_args1 <- tcTupArgs tup_args arg_tys
466
467 ; return $ mkHsWrap wrap (ExplicitTuple tup_args1 boxity) }
468
469 tcExpr (ExplicitList _ witness exprs) res_ty
470 = case witness of
471 Nothing -> do { res_ty <- expTypeToType res_ty
472 ; (coi, elt_ty) <- matchExpectedListTy res_ty
473 ; exprs' <- mapM (tc_elt elt_ty) exprs
474 ; return $
475 mkHsWrapCo coi $ ExplicitList elt_ty Nothing exprs' }
476
477 Just fln -> do { ((exprs', elt_ty), fln')
478 <- tcSyntaxOp ListOrigin fln
479 [synKnownType intTy, SynList] res_ty $
480 \ [elt_ty] ->
481 do { exprs' <-
482 mapM (tc_elt elt_ty) exprs
483 ; return (exprs', elt_ty) }
484
485 ; return $ ExplicitList elt_ty (Just fln') exprs' }
486 where tc_elt elt_ty expr = tcPolyExpr expr elt_ty
487
488 tcExpr (ExplicitPArr _ exprs) res_ty -- maybe empty
489 = do { res_ty <- expTypeToType res_ty
490 ; (coi, elt_ty) <- matchExpectedPArrTy res_ty
491 ; exprs' <- mapM (tc_elt elt_ty) exprs
492 ; return $
493 mkHsWrapCo coi $ ExplicitPArr elt_ty exprs' }
494 where
495 tc_elt elt_ty expr = tcPolyExpr expr elt_ty
496
497 {-
498 ************************************************************************
499 * *
500 Let, case, if, do
501 * *
502 ************************************************************************
503 -}
504
505 tcExpr (HsLet (L l binds) expr) res_ty
506 = do { (binds', expr') <- tcLocalBinds binds $
507 tcMonoExpr expr res_ty
508 ; return (HsLet (L l binds') expr') }
509
510 tcExpr (HsCase scrut matches) res_ty
511 = do { -- We used to typecheck the case alternatives first.
512 -- The case patterns tend to give good type info to use
513 -- when typechecking the scrutinee. For example
514 -- case (map f) of
515 -- (x:xs) -> ...
516 -- will report that map is applied to too few arguments
517 --
518 -- But now, in the GADT world, we need to typecheck the scrutinee
519 -- first, to get type info that may be refined in the case alternatives
520 (scrut', scrut_ty) <- tcInferRho scrut
521
522 ; traceTc "HsCase" (ppr scrut_ty)
523 ; matches' <- tcMatchesCase match_ctxt scrut_ty matches res_ty
524 ; return (HsCase scrut' matches') }
525 where
526 match_ctxt = MC { mc_what = CaseAlt,
527 mc_body = tcBody }
528
529 tcExpr (HsIf Nothing pred b1 b2) res_ty -- Ordinary 'if'
530 = do { pred' <- tcMonoExpr pred (mkCheckExpType boolTy)
531 -- this forces the branches to be fully instantiated
532 -- (See #10619)
533 ; res_ty <- mkCheckExpType <$> expTypeToType res_ty
534 ; b1' <- tcMonoExpr b1 res_ty
535 ; b2' <- tcMonoExpr b2 res_ty
536 ; return (HsIf Nothing pred' b1' b2') }
537
538 tcExpr (HsIf (Just fun) pred b1 b2) res_ty
539 = do { ((pred', b1', b2'), fun')
540 <- tcSyntaxOp IfOrigin fun [SynAny, SynAny, SynAny] res_ty $
541 \ [pred_ty, b1_ty, b2_ty] ->
542 do { pred' <- tcPolyExpr pred pred_ty
543 ; b1' <- tcPolyExpr b1 b1_ty
544 ; b2' <- tcPolyExpr b2 b2_ty
545 ; return (pred', b1', b2') }
546 ; return (HsIf (Just fun') pred' b1' b2') }
547
548 tcExpr (HsMultiIf _ alts) res_ty
549 = do { res_ty <- if isSingleton alts
550 then return res_ty
551 else mkCheckExpType <$> expTypeToType res_ty
552 -- Just like Note [Case branches must never infer a non-tau type]
553 -- in TcMatches
554 ; alts' <- mapM (wrapLocM $ tcGRHS match_ctxt res_ty) alts
555 ; res_ty <- readExpType res_ty
556 ; return (HsMultiIf res_ty alts') }
557 where match_ctxt = MC { mc_what = IfAlt, mc_body = tcBody }
558
559 tcExpr (HsDo do_or_lc stmts _) res_ty
560 = do { expr' <- tcDoStmts do_or_lc stmts res_ty
561 ; return expr' }
562
563 tcExpr (HsProc pat cmd) res_ty
564 = do { (pat', cmd', coi) <- tcProc pat cmd res_ty
565 ; return $ mkHsWrapCo coi (HsProc pat' cmd') }
566
567 -- Typechecks the static form and wraps it with a call to 'fromStaticPtr'.
568 tcExpr (HsStatic expr) res_ty
569 = do { res_ty <- expTypeToType res_ty
570 ; (co, (p_ty, expr_ty)) <- matchExpectedAppTy res_ty
571 ; (expr', lie) <- captureConstraints $
572 addErrCtxt (hang (text "In the body of a static form:")
573 2 (ppr expr)
574 ) $
575 tcPolyExprNC expr expr_ty
576 -- Require the type of the argument to be Typeable.
577 -- The evidence is not used, but asking the constraint ensures that
578 -- the current implementation is as restrictive as future versions
579 -- of the StaticPointers extension.
580 ; typeableClass <- tcLookupClass typeableClassName
581 ; _ <- emitWantedEvVar StaticOrigin $
582 mkTyConApp (classTyCon typeableClass)
583 [liftedTypeKind, expr_ty]
584 -- Insert the constraints of the static form in a global list for later
585 -- validation.
586 ; stWC <- tcg_static_wc <$> getGblEnv
587 ; updTcRef stWC (andWC lie)
588 -- Wrap the static form with the 'fromStaticPtr' call.
589 ; fromStaticPtr <- newMethodFromName StaticOrigin fromStaticPtrName p_ty
590 ; let wrap = mkWpTyApps [expr_ty]
591 ; loc <- getSrcSpanM
592 ; return $ mkHsWrapCo co $ HsApp (L loc $ mkHsWrap wrap fromStaticPtr)
593 (L loc (HsStatic expr'))
594 }
595
596 {-
597 ************************************************************************
598 * *
599 Record construction and update
600 * *
601 ************************************************************************
602 -}
603
604 tcExpr expr@(RecordCon { rcon_con_name = L loc con_name
605 , rcon_flds = rbinds }) res_ty
606 = do { con_like <- tcLookupConLike con_name
607
608 -- Check for missing fields
609 ; checkMissingFields con_like rbinds
610
611 ; (con_expr, con_sigma) <- tcInferId con_name
612 ; (con_wrap, con_tau) <-
613 topInstantiate (OccurrenceOf con_name) con_sigma
614 -- a shallow instantiation should really be enough for
615 -- a data constructor.
616 ; let arity = conLikeArity con_like
617 (arg_tys, actual_res_ty) = tcSplitFunTysN con_tau arity
618 ; case conLikeWrapId_maybe con_like of
619 Nothing -> nonBidirectionalErr (conLikeName con_like)
620 Just con_id -> do {
621 res_wrap <- tcSubTypeHR (Shouldn'tHappenOrigin "RecordCon")
622 (Just expr) actual_res_ty res_ty
623 ; rbinds' <- tcRecordBinds con_like arg_tys rbinds
624 ; return $
625 mkHsWrap res_wrap $
626 RecordCon { rcon_con_name = L loc con_id
627 , rcon_con_expr = mkHsWrap con_wrap con_expr
628 , rcon_con_like = con_like
629 , rcon_flds = rbinds' } } }
630
631 {-
632 Note [Type of a record update]
633 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
634 The main complication with RecordUpd is that we need to explicitly
635 handle the *non-updated* fields. Consider:
636
637 data T a b c = MkT1 { fa :: a, fb :: (b,c) }
638 | MkT2 { fa :: a, fb :: (b,c), fc :: c -> c }
639 | MkT3 { fd :: a }
640
641 upd :: T a b c -> (b',c) -> T a b' c
642 upd t x = t { fb = x}
643
644 The result type should be (T a b' c)
645 not (T a b c), because 'b' *is not* mentioned in a non-updated field
646 not (T a b' c'), because 'c' *is* mentioned in a non-updated field
647 NB that it's not good enough to look at just one constructor; we must
648 look at them all; cf Trac #3219
649
650 After all, upd should be equivalent to:
651 upd t x = case t of
652 MkT1 p q -> MkT1 p x
653 MkT2 a b -> MkT2 p b
654 MkT3 d -> error ...
655
656 So we need to give a completely fresh type to the result record,
657 and then constrain it by the fields that are *not* updated ("p" above).
658 We call these the "fixed" type variables, and compute them in getFixedTyVars.
659
660 Note that because MkT3 doesn't contain all the fields being updated,
661 its RHS is simply an error, so it doesn't impose any type constraints.
662 Hence the use of 'relevant_cont'.
663
664 Note [Implicit type sharing]
665 ~~~~~~~~~~~~~~~~~~~~~~~~~~~
666 We also take into account any "implicit" non-update fields. For example
667 data T a b where { MkT { f::a } :: T a a; ... }
668 So the "real" type of MkT is: forall ab. (a~b) => a -> T a b
669
670 Then consider
671 upd t x = t { f=x }
672 We infer the type
673 upd :: T a b -> a -> T a b
674 upd (t::T a b) (x::a)
675 = case t of { MkT (co:a~b) (_:a) -> MkT co x }
676 We can't give it the more general type
677 upd :: T a b -> c -> T c b
678
679 Note [Criteria for update]
680 ~~~~~~~~~~~~~~~~~~~~~~~~~~
681 We want to allow update for existentials etc, provided the updated
682 field isn't part of the existential. For example, this should be ok.
683 data T a where { MkT { f1::a, f2::b->b } :: T a }
684 f :: T a -> b -> T b
685 f t b = t { f1=b }
686
687 The criterion we use is this:
688
689 The types of the updated fields
690 mention only the universally-quantified type variables
691 of the data constructor
692
693 NB: this is not (quite) the same as being a "naughty" record selector
694 (See Note [Naughty record selectors]) in TcTyClsDecls), at least
695 in the case of GADTs. Consider
696 data T a where { MkT :: { f :: a } :: T [a] }
697 Then f is not "naughty" because it has a well-typed record selector.
698 But we don't allow updates for 'f'. (One could consider trying to
699 allow this, but it makes my head hurt. Badly. And no one has asked
700 for it.)
701
702 In principle one could go further, and allow
703 g :: T a -> T a
704 g t = t { f2 = \x -> x }
705 because the expression is polymorphic...but that seems a bridge too far.
706
707 Note [Data family example]
708 ~~~~~~~~~~~~~~~~~~~~~~~~~~
709 data instance T (a,b) = MkT { x::a, y::b }
710 --->
711 data :TP a b = MkT { a::a, y::b }
712 coTP a b :: T (a,b) ~ :TP a b
713
714 Suppose r :: T (t1,t2), e :: t3
715 Then r { x=e } :: T (t3,t1)
716 --->
717 case r |> co1 of
718 MkT x y -> MkT e y |> co2
719 where co1 :: T (t1,t2) ~ :TP t1 t2
720 co2 :: :TP t3 t2 ~ T (t3,t2)
721 The wrapping with co2 is done by the constructor wrapper for MkT
722
723 Outgoing invariants
724 ~~~~~~~~~~~~~~~~~~~
725 In the outgoing (HsRecordUpd scrut binds cons in_inst_tys out_inst_tys):
726
727 * cons are the data constructors to be updated
728
729 * in_inst_tys, out_inst_tys have same length, and instantiate the
730 *representation* tycon of the data cons. In Note [Data
731 family example], in_inst_tys = [t1,t2], out_inst_tys = [t3,t2]
732
733 Note [Mixed Record Field Updates]
734 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
735 Consider the following pattern synonym.
736
737 data MyRec = MyRec { foo :: Int, qux :: String }
738
739 pattern HisRec{f1, f2} = MyRec{foo = f1, qux=f2}
740
741 This allows updates such as the following
742
743 updater :: MyRec -> MyRec
744 updater a = a {f1 = 1 }
745
746 It would also make sense to allow the following update (which we reject).
747
748 updater a = a {f1 = 1, qux = "two" } ==? MyRec 1 "two"
749
750 This leads to confusing behaviour when the selectors in fact refer the same
751 field.
752
753 updater a = a {f1 = 1, foo = 2} ==? ???
754
755 For this reason, we reject a mixture of pattern synonym and normal record
756 selectors in the same update block. Although of course we still allow the
757 following.
758
759 updater a = (a {f1 = 1}) {foo = 2}
760
761 > updater (MyRec 0 "str")
762 MyRec 2 "str"
763
764 -}
765
766 tcExpr expr@(RecordUpd { rupd_expr = record_expr, rupd_flds = rbnds }) res_ty
767 = ASSERT( notNull rbnds )
768 do { -- STEP -2: typecheck the record_expr, the record to be updated
769 (record_expr', record_rho) <- tcInferRho record_expr
770
771 -- STEP -1 See Note [Disambiguating record fields]
772 -- After this we know that rbinds is unambiguous
773 ; rbinds <- disambiguateRecordBinds record_expr record_rho rbnds res_ty
774 ; let upd_flds = map (unLoc . hsRecFieldLbl . unLoc) rbinds
775 upd_fld_occs = map (occNameFS . rdrNameOcc . rdrNameAmbiguousFieldOcc) upd_flds
776 sel_ids = map selectorAmbiguousFieldOcc upd_flds
777 -- STEP 0
778 -- Check that the field names are really field names
779 -- and they are all field names for proper records or
780 -- all field names for pattern synonyms.
781 ; let bad_guys = [ setSrcSpan loc $ addErrTc (notSelector fld_name)
782 | fld <- rbinds,
783 -- Excludes class ops
784 let L loc sel_id = hsRecUpdFieldId (unLoc fld),
785 not (isRecordSelector sel_id),
786 let fld_name = idName sel_id ]
787 ; unless (null bad_guys) (sequence bad_guys >> failM)
788 -- See note [Mixed Record Selectors]
789 ; let (data_sels, pat_syn_sels) =
790 partition isDataConRecordSelector sel_ids
791 ; MASSERT( all isPatSynRecordSelector pat_syn_sels )
792 ; checkTc ( null data_sels || null pat_syn_sels )
793 ( mixedSelectors data_sels pat_syn_sels )
794
795 -- STEP 1
796 -- Figure out the tycon and data cons from the first field name
797 ; let -- It's OK to use the non-tc splitters here (for a selector)
798 sel_id : _ = sel_ids
799
800 mtycon :: Maybe TyCon
801 mtycon = case idDetails sel_id of
802 RecSelId (RecSelData tycon) _ -> Just tycon
803 _ -> Nothing
804
805 con_likes :: [ConLike]
806 con_likes = case idDetails sel_id of
807 RecSelId (RecSelData tc) _
808 -> map RealDataCon (tyConDataCons tc)
809 RecSelId (RecSelPatSyn ps) _
810 -> [PatSynCon ps]
811 _ -> panic "tcRecordUpd"
812 -- NB: for a data type family, the tycon is the instance tycon
813
814 relevant_cons = conLikesWithFields con_likes upd_fld_occs
815 -- A constructor is only relevant to this process if
816 -- it contains *all* the fields that are being updated
817 -- Other ones will cause a runtime error if they occur
818
819 -- Step 2
820 -- Check that at least one constructor has all the named fields
821 -- i.e. has an empty set of bad fields returned by badFields
822 ; checkTc (not (null relevant_cons)) (badFieldsUpd rbinds con_likes)
823
824 -- Take apart a representative constructor
825 ; let con1 = ASSERT( not (null relevant_cons) ) head relevant_cons
826 (con1_tvs, _, _, _prov_theta, req_theta, con1_arg_tys, _)
827 = conLikeFullSig con1
828 con1_flds = map flLabel $ conLikeFieldLabels con1
829 con1_tv_tys = mkTyVarTys con1_tvs
830 con1_res_ty = case mtycon of
831 Just tc -> mkFamilyTyConApp tc con1_tv_tys
832 Nothing -> conLikeResTy con1 con1_tv_tys
833
834 -- Check that we're not dealing with a unidirectional pattern
835 -- synonym
836 ; unless (isJust $ conLikeWrapId_maybe con1)
837 (nonBidirectionalErr (conLikeName con1))
838
839 -- STEP 3 Note [Criteria for update]
840 -- Check that each updated field is polymorphic; that is, its type
841 -- mentions only the universally-quantified variables of the data con
842 ; let flds1_w_tys = zipEqual "tcExpr:RecConUpd" con1_flds con1_arg_tys
843 bad_upd_flds = filter bad_fld flds1_w_tys
844 con1_tv_set = mkVarSet con1_tvs
845 bad_fld (fld, ty) = fld `elem` upd_fld_occs &&
846 not (tyCoVarsOfType ty `subVarSet` con1_tv_set)
847 ; checkTc (null bad_upd_flds) (badFieldTypes bad_upd_flds)
848
849 -- STEP 4 Note [Type of a record update]
850 -- Figure out types for the scrutinee and result
851 -- Both are of form (T a b c), with fresh type variables, but with
852 -- common variables where the scrutinee and result must have the same type
853 -- These are variables that appear in *any* arg of *any* of the
854 -- relevant constructors *except* in the updated fields
855 --
856 ; let fixed_tvs = getFixedTyVars upd_fld_occs con1_tvs relevant_cons
857 is_fixed_tv tv = tv `elemVarSet` fixed_tvs
858
859 mk_inst_ty :: TCvSubst -> (TyVar, TcType) -> TcM (TCvSubst, TcType)
860 -- Deals with instantiation of kind variables
861 -- c.f. TcMType.newMetaTyVars
862 mk_inst_ty subst (tv, result_inst_ty)
863 | is_fixed_tv tv -- Same as result type
864 = return (extendTvSubst subst tv result_inst_ty, result_inst_ty)
865 | otherwise -- Fresh type, of correct kind
866 = do { (subst', new_tv) <- newMetaTyVarX subst tv
867 ; return (subst', mkTyVarTy new_tv) }
868
869 ; (result_subst, con1_tvs') <- newMetaTyVars con1_tvs
870 ; let result_inst_tys = mkTyVarTys con1_tvs'
871
872 ; (scrut_subst, scrut_inst_tys) <- mapAccumLM mk_inst_ty emptyTCvSubst
873 (con1_tvs `zip` result_inst_tys)
874
875 ; let rec_res_ty = TcType.substTy result_subst con1_res_ty
876 scrut_ty = TcType.substTyUnchecked scrut_subst con1_res_ty
877 con1_arg_tys' = map (TcType.substTy result_subst) con1_arg_tys
878
879 ; wrap_res <- tcSubTypeHR (exprCtOrigin expr)
880 (Just expr) rec_res_ty res_ty
881 ; co_scrut <- unifyType (Just record_expr) record_rho scrut_ty
882 -- NB: normal unification is OK here (as opposed to subsumption),
883 -- because for this to work out, both record_rho and scrut_ty have
884 -- to be normal datatypes -- no contravariant stuff can go on
885
886 -- STEP 5
887 -- Typecheck the bindings
888 ; rbinds' <- tcRecordUpd con1 con1_arg_tys' rbinds
889
890 -- STEP 6: Deal with the stupid theta
891 ; let theta' = substThetaUnchecked scrut_subst (conLikeStupidTheta con1)
892 ; instStupidTheta RecordUpdOrigin theta'
893
894 -- Step 7: make a cast for the scrutinee, in the
895 -- case that it's from a data family
896 ; let fam_co :: HsWrapper -- RepT t1 .. tn ~R scrut_ty
897 fam_co | Just tycon <- mtycon
898 , Just co_con <- tyConFamilyCoercion_maybe tycon
899 = mkWpCastR (mkTcUnbranchedAxInstCo co_con scrut_inst_tys [])
900 | otherwise
901 = idHsWrapper
902
903 -- Step 8: Check that the req constraints are satisfied
904 -- For normal data constructors req_theta is empty but we must do
905 -- this check for pattern synonyms.
906 ; let req_theta' = substThetaUnchecked scrut_subst req_theta
907 ; req_wrap <- instCallConstraints RecordUpdOrigin req_theta'
908
909 -- Phew!
910 ; return $
911 mkHsWrap wrap_res $
912 RecordUpd { rupd_expr = mkLHsWrap fam_co (mkLHsWrapCo co_scrut record_expr')
913 , rupd_flds = rbinds'
914 , rupd_cons = relevant_cons, rupd_in_tys = scrut_inst_tys
915 , rupd_out_tys = result_inst_tys, rupd_wrap = req_wrap } }
916
917 tcExpr (HsRecFld f) res_ty
918 = tcCheckRecSelId f res_ty
919
920 {-
921 ************************************************************************
922 * *
923 Arithmetic sequences e.g. [a,b..]
924 and their parallel-array counterparts e.g. [: a,b.. :]
925
926 * *
927 ************************************************************************
928 -}
929
930 tcExpr (ArithSeq _ witness seq) res_ty
931 = tcArithSeq witness seq res_ty
932
933 tcExpr (PArrSeq _ seq@(FromTo expr1 expr2)) res_ty
934 = do { res_ty <- expTypeToType res_ty
935 ; (coi, elt_ty) <- matchExpectedPArrTy res_ty
936 ; expr1' <- tcPolyExpr expr1 elt_ty
937 ; expr2' <- tcPolyExpr expr2 elt_ty
938 ; enumFromToP <- initDsTc $ dsDPHBuiltin enumFromToPVar
939 ; enum_from_to <- newMethodFromName (PArrSeqOrigin seq)
940 (idName enumFromToP) elt_ty
941 ; return $
942 mkHsWrapCo coi $ PArrSeq enum_from_to (FromTo expr1' expr2') }
943
944 tcExpr (PArrSeq _ seq@(FromThenTo expr1 expr2 expr3)) res_ty
945 = do { res_ty <- expTypeToType res_ty
946 ; (coi, elt_ty) <- matchExpectedPArrTy res_ty
947 ; expr1' <- tcPolyExpr expr1 elt_ty
948 ; expr2' <- tcPolyExpr expr2 elt_ty
949 ; expr3' <- tcPolyExpr expr3 elt_ty
950 ; enumFromThenToP <- initDsTc $ dsDPHBuiltin enumFromThenToPVar
951 ; eft <- newMethodFromName (PArrSeqOrigin seq)
952 (idName enumFromThenToP) elt_ty -- !!!FIXME: chak
953 ; return $
954 mkHsWrapCo coi $
955 PArrSeq eft (FromThenTo expr1' expr2' expr3') }
956
957 tcExpr (PArrSeq _ _) _
958 = panic "TcExpr.tcExpr: Infinite parallel array!"
959 -- the parser shouldn't have generated it and the renamer shouldn't have
960 -- let it through
961
962 {-
963 ************************************************************************
964 * *
965 Template Haskell
966 * *
967 ************************************************************************
968 -}
969
970 tcExpr (HsSpliceE splice) res_ty
971 = tcSpliceExpr splice res_ty
972 tcExpr (HsBracket brack) res_ty
973 = tcTypedBracket brack res_ty
974 tcExpr (HsRnBracketOut brack ps) res_ty
975 = tcUntypedBracket brack ps res_ty
976
977 {-
978 ************************************************************************
979 * *
980 Catch-all
981 * *
982 ************************************************************************
983 -}
984
985 tcExpr other _ = pprPanic "tcMonoExpr" (ppr other)
986 -- Include ArrForm, ArrApp, which shouldn't appear at all
987 -- Also HsTcBracketOut, HsQuasiQuoteE
988
989 {-
990 ************************************************************************
991 * *
992 Arithmetic sequences [a..b] etc
993 * *
994 ************************************************************************
995 -}
996
997 tcArithSeq :: Maybe (SyntaxExpr Name) -> ArithSeqInfo Name -> ExpRhoType
998 -> TcM (HsExpr TcId)
999
1000 tcArithSeq witness seq@(From expr) res_ty
1001 = do { (wrap, elt_ty, wit') <- arithSeqEltType witness res_ty
1002 ; expr' <- tcPolyExpr expr elt_ty
1003 ; enum_from <- newMethodFromName (ArithSeqOrigin seq)
1004 enumFromName elt_ty
1005 ; return $ mkHsWrap wrap $
1006 ArithSeq enum_from wit' (From expr') }
1007
1008 tcArithSeq witness seq@(FromThen expr1 expr2) res_ty
1009 = do { (wrap, elt_ty, wit') <- arithSeqEltType witness res_ty
1010 ; expr1' <- tcPolyExpr expr1 elt_ty
1011 ; expr2' <- tcPolyExpr expr2 elt_ty
1012 ; enum_from_then <- newMethodFromName (ArithSeqOrigin seq)
1013 enumFromThenName elt_ty
1014 ; return $ mkHsWrap wrap $
1015 ArithSeq enum_from_then wit' (FromThen expr1' expr2') }
1016
1017 tcArithSeq witness seq@(FromTo expr1 expr2) res_ty
1018 = do { (wrap, elt_ty, wit') <- arithSeqEltType witness res_ty
1019 ; expr1' <- tcPolyExpr expr1 elt_ty
1020 ; expr2' <- tcPolyExpr expr2 elt_ty
1021 ; enum_from_to <- newMethodFromName (ArithSeqOrigin seq)
1022 enumFromToName elt_ty
1023 ; return $ mkHsWrap wrap $
1024 ArithSeq enum_from_to wit' (FromTo expr1' expr2') }
1025
1026 tcArithSeq witness seq@(FromThenTo expr1 expr2 expr3) res_ty
1027 = do { (wrap, elt_ty, wit') <- arithSeqEltType witness res_ty
1028 ; expr1' <- tcPolyExpr expr1 elt_ty
1029 ; expr2' <- tcPolyExpr expr2 elt_ty
1030 ; expr3' <- tcPolyExpr expr3 elt_ty
1031 ; eft <- newMethodFromName (ArithSeqOrigin seq)
1032 enumFromThenToName elt_ty
1033 ; return $ mkHsWrap wrap $
1034 ArithSeq eft wit' (FromThenTo expr1' expr2' expr3') }
1035
1036 -----------------
1037 arithSeqEltType :: Maybe (SyntaxExpr Name) -> ExpRhoType
1038 -> TcM (HsWrapper, TcType, Maybe (SyntaxExpr Id))
1039 arithSeqEltType Nothing res_ty
1040 = do { res_ty <- expTypeToType res_ty
1041 ; (coi, elt_ty) <- matchExpectedListTy res_ty
1042 ; return (mkWpCastN coi, elt_ty, Nothing) }
1043 arithSeqEltType (Just fl) res_ty
1044 = do { (elt_ty, fl')
1045 <- tcSyntaxOp ListOrigin fl [SynList] res_ty $
1046 \ [elt_ty] -> return elt_ty
1047 ; return (idHsWrapper, elt_ty, Just fl') }
1048
1049 {-
1050 ************************************************************************
1051 * *
1052 Applications
1053 * *
1054 ************************************************************************
1055 -}
1056
1057 type LHsExprArgIn = Either (LHsExpr Name) (LHsWcType Name)
1058 type LHsExprArgOut = Either (LHsExpr TcId) (LHsWcType Name)
1059
1060 tcApp1 :: HsExpr Name -- either HsApp or HsAppType
1061 -> ExpRhoType -> TcM (HsExpr TcId)
1062 tcApp1 e res_ty
1063 = do { (wrap, fun, args) <- tcApp Nothing (noLoc e) [] res_ty
1064 ; return (mkHsWrap wrap $ unLoc $ foldl mk_hs_app fun args) }
1065 where
1066 mk_hs_app f (Left a) = mkHsApp f a
1067 mk_hs_app f (Right a) = mkHsAppTypeOut f a
1068
1069 tcApp :: Maybe SDoc -- like "The function `f' is applied to"
1070 -- or leave out to get exactly that message
1071 -> LHsExpr Name -> [LHsExprArgIn] -- Function and args
1072 -> ExpRhoType -> TcM (HsWrapper, LHsExpr TcId, [LHsExprArgOut])
1073 -- (wrap, fun, args). For an ordinary function application,
1074 -- these should be assembled as (wrap (fun args)).
1075 -- But OpApp is slightly different, so that's why the caller
1076 -- must assemble
1077
1078 tcApp m_herald orig_fun orig_args res_ty
1079 = go orig_fun orig_args
1080 where
1081 go :: LHsExpr Name -> [LHsExprArgIn]
1082 -> TcM (HsWrapper, LHsExpr TcId, [LHsExprArgOut])
1083 go (L _ (HsPar e)) args = go e args
1084 go (L _ (HsApp e1 e2)) args = go e1 (Left e2:args)
1085 go (L _ (HsAppType e t)) args = go e (Right t:args)
1086
1087 go (L loc (HsVar (L _ fun))) args
1088 | fun `hasKey` tagToEnumKey
1089 , count isLeft args == 1
1090 = do { (wrap, expr, args) <- tcTagToEnum loc fun args res_ty
1091 ; return (wrap, expr, args) }
1092
1093 | fun `hasKey` seqIdKey
1094 , count isLeft args == 2
1095 = do { (wrap, expr, args) <- tcSeq loc fun args res_ty
1096 ; return (wrap, expr, args) }
1097
1098 go (L loc (HsRecFld (Ambiguous lbl _))) args@(Left (L _ arg) : _)
1099 | Just sig_ty <- obviousSig arg
1100 = do { sig_tc_ty <- tcHsSigWcType ExprSigCtxt sig_ty
1101 ; sel_name <- disambiguateSelector lbl sig_tc_ty
1102 ; go (L loc (HsRecFld (Unambiguous lbl sel_name))) args }
1103
1104 go fun args
1105 = do { -- Type-check the function
1106 ; (fun1, fun_sigma) <- tcInferFun fun
1107 ; let orig = exprCtOrigin (unLoc fun)
1108
1109 ; (wrap_fun, args1, actual_res_ty)
1110 <- tcArgs fun fun_sigma orig args
1111 (m_herald `orElse` mk_app_msg fun)
1112
1113 -- this is just like tcWrapResult, but the types don't line
1114 -- up to call that function
1115 ; wrap_res <- addFunResCtxt True (unLoc fun) actual_res_ty res_ty $
1116 tcSubTypeDS_NC_O orig GenSigCtxt
1117 (Just $ foldl mk_hs_app fun args)
1118 actual_res_ty res_ty
1119
1120 ; return (wrap_res, mkLHsWrap wrap_fun fun1, args1) }
1121
1122 mk_hs_app f (Left a) = mkHsApp f a
1123 mk_hs_app f (Right a) = mkHsAppType f a
1124
1125 mk_app_msg :: LHsExpr Name -> SDoc
1126 mk_app_msg fun = sep [ text "The function" <+> quotes (ppr fun)
1127 , text "is applied to"]
1128
1129 mk_op_msg :: LHsExpr Name -> SDoc
1130 mk_op_msg op = text "The operator" <+> quotes (ppr op) <+> text "takes"
1131
1132 ----------------
1133 tcInferFun :: LHsExpr Name -> TcM (LHsExpr TcId, TcSigmaType)
1134 -- Infer type of a function
1135 tcInferFun (L loc (HsVar (L _ name)))
1136 = do { (fun, ty) <- setSrcSpan loc (tcInferId name)
1137 -- Don't wrap a context around a plain Id
1138 ; return (L loc fun, ty) }
1139
1140 tcInferFun (L loc (HsRecFld f))
1141 = do { (fun, ty) <- setSrcSpan loc (tcInferRecSelId f)
1142 -- Don't wrap a context around a plain Id
1143 ; return (L loc fun, ty) }
1144
1145 tcInferFun fun
1146 = do { (fun, fun_ty) <- tcInferSigma fun
1147
1148 -- Zonk the function type carefully, to expose any polymorphism
1149 -- E.g. (( \(x::forall a. a->a). blah ) e)
1150 -- We can see the rank-2 type of the lambda in time to generalise e
1151 ; fun_ty' <- zonkTcType fun_ty
1152
1153 ; return (fun, fun_ty') }
1154
1155 ----------------
1156 -- | Type-check the arguments to a function, possibly including visible type
1157 -- applications
1158 tcArgs :: LHsExpr Name -- ^ The function itself (for err msgs only)
1159 -> TcSigmaType -- ^ the (uninstantiated) type of the function
1160 -> CtOrigin -- ^ the origin for the function's type
1161 -> [LHsExprArgIn] -- ^ the args
1162 -> SDoc -- ^ the herald for matchActualFunTys
1163 -> TcM (HsWrapper, [LHsExprArgOut], TcSigmaType)
1164 -- ^ (a wrapper for the function, the tc'd args, result type)
1165 tcArgs fun orig_fun_ty fun_orig orig_args herald
1166 = go [] 1 orig_fun_ty orig_args
1167 where
1168 orig_arity = length orig_args
1169
1170 go _ _ fun_ty [] = return (idHsWrapper, [], fun_ty)
1171
1172 go acc_args n fun_ty (Right hs_ty_arg:args)
1173 = do { (wrap1, upsilon_ty) <- topInstantiateInferred fun_orig fun_ty
1174 -- wrap1 :: fun_ty "->" upsilon_ty
1175 ; case tcSplitForAllTy_maybe upsilon_ty of
1176 Just (binder, inner_ty)
1177 | Just tv <- binderVar_maybe binder ->
1178 ASSERT( binderVisibility binder == Specified )
1179 do { let kind = tyVarKind tv
1180 ; ty_arg <- tcHsTypeApp hs_ty_arg kind
1181 ; let insted_ty = substTyWithUnchecked [tv] [ty_arg] inner_ty
1182 ; (inner_wrap, args', res_ty)
1183 <- go acc_args (n+1) insted_ty args
1184 -- inner_wrap :: insted_ty "->" (map typeOf args') -> res_ty
1185 ; let inst_wrap = mkWpTyApps [ty_arg]
1186 ; return ( inner_wrap <.> inst_wrap <.> wrap1
1187 , Right hs_ty_arg : args'
1188 , res_ty ) }
1189 _ -> ty_app_err upsilon_ty hs_ty_arg }
1190
1191 go acc_args n fun_ty (Left arg : args)
1192 = do { (wrap, [arg_ty], res_ty)
1193 <- matchActualFunTysPart herald fun_orig (Just fun) 1 fun_ty
1194 acc_args orig_arity
1195 -- wrap :: fun_ty "->" arg_ty -> res_ty
1196 ; arg' <- tcArg fun arg arg_ty n
1197 ; (inner_wrap, args', inner_res_ty)
1198 <- go (arg_ty : acc_args) (n+1) res_ty args
1199 -- inner_wrap :: res_ty "->" (map typeOf args') -> inner_res_ty
1200 ; return ( mkWpFun idHsWrapper inner_wrap arg_ty res_ty <.> wrap
1201 , Left arg' : args'
1202 , inner_res_ty ) }
1203
1204 ty_app_err ty arg
1205 = do { (_, ty) <- zonkTidyTcType emptyTidyEnv ty
1206 ; failWith $
1207 text "Cannot apply expression of type" <+> quotes (ppr ty) $$
1208 text "to a visible type argument" <+> quotes (ppr arg) }
1209
1210 ----------------
1211 tcArg :: LHsExpr Name -- The function (for error messages)
1212 -> LHsExpr Name -- Actual arguments
1213 -> TcRhoType -- expected arg type
1214 -> Int -- # of arugment
1215 -> TcM (LHsExpr TcId) -- Resulting argument
1216 tcArg fun arg ty arg_no = addErrCtxt (funAppCtxt fun arg arg_no) $
1217 tcPolyExprNC arg ty
1218
1219 ----------------
1220 tcTupArgs :: [LHsTupArg Name] -> [TcSigmaType] -> TcM [LHsTupArg TcId]
1221 tcTupArgs args tys
1222 = ASSERT( equalLength args tys ) mapM go (args `zip` tys)
1223 where
1224 go (L l (Missing {}), arg_ty) = return (L l (Missing arg_ty))
1225 go (L l (Present expr), arg_ty) = do { expr' <- tcPolyExpr expr arg_ty
1226 ; return (L l (Present expr')) }
1227
1228 ---------------------------
1229 -- See TcType.SyntaxOpType also for commentary
1230 tcSyntaxOp :: CtOrigin
1231 -> SyntaxExpr Name
1232 -> [SyntaxOpType] -- ^ shape of syntax operator arguments
1233 -> ExpType -- ^ overall result type
1234 -> ([TcSigmaType] -> TcM a) -- ^ Type check any arguments
1235 -> TcM (a, SyntaxExpr TcId)
1236 -- ^ Typecheck a syntax operator
1237 -- The operator is always a variable at this stage (i.e. renamer output)
1238 tcSyntaxOp orig expr arg_tys res_ty
1239 = tcSyntaxOpGen orig expr arg_tys (SynType res_ty)
1240
1241 -- | Slightly more general version of 'tcSyntaxOp' that allows the caller
1242 -- to specify the shape of the result of the syntax operator
1243 tcSyntaxOpGen :: CtOrigin
1244 -> SyntaxExpr Name
1245 -> [SyntaxOpType]
1246 -> SyntaxOpType
1247 -> ([TcSigmaType] -> TcM a)
1248 -> TcM (a, SyntaxExpr TcId)
1249 tcSyntaxOpGen orig (SyntaxExpr { syn_expr = HsVar (L _ op) })
1250 arg_tys res_ty thing_inside
1251 = do { (expr, sigma) <- tcInferId op
1252 ; (result, expr_wrap, arg_wraps, res_wrap)
1253 <- tcSynArgA orig sigma arg_tys res_ty $
1254 thing_inside
1255 ; return (result, SyntaxExpr { syn_expr = mkHsWrap expr_wrap expr
1256 , syn_arg_wraps = arg_wraps
1257 , syn_res_wrap = res_wrap }) }
1258
1259 tcSyntaxOpGen _ other _ _ _ = pprPanic "tcSyntaxOp" (ppr other)
1260
1261 {-
1262 Note [tcSynArg]
1263 ~~~~~~~~~~~~~~~
1264 Because of the rich structure of SyntaxOpType, we must do the
1265 contra-/covariant thing when working down arrows, to get the
1266 instantiation vs. skolemisation decisions correct (and, more
1267 obviously, the orientation of the HsWrappers). We thus have
1268 two tcSynArgs.
1269 -}
1270
1271 -- works on "expected" types, skolemising where necessary
1272 -- See Note [tcSynArg]
1273 tcSynArgE :: CtOrigin
1274 -> TcSigmaType
1275 -> SyntaxOpType -- ^ shape it is expected to have
1276 -> ([TcSigmaType] -> TcM a) -- ^ check the arguments
1277 -> TcM (a, HsWrapper)
1278 -- ^ returns a wrapper :: (type of right shape) "->" (type passed in)
1279 tcSynArgE orig sigma_ty syn_ty thing_inside
1280 = do { (skol_wrap, (result, ty_wrapper))
1281 <- tcSkolemise GenSigCtxt sigma_ty $ \ _ rho_ty ->
1282 go rho_ty syn_ty
1283 ; return (result, skol_wrap <.> ty_wrapper) }
1284 where
1285 go rho_ty SynAny
1286 = do { result <- thing_inside [rho_ty]
1287 ; return (result, idHsWrapper) }
1288
1289 go rho_ty SynRho -- same as SynAny, because we skolemise eagerly
1290 = do { result <- thing_inside [rho_ty]
1291 ; return (result, idHsWrapper) }
1292
1293 go rho_ty SynList
1294 = do { (list_co, elt_ty) <- matchExpectedListTy rho_ty
1295 ; result <- thing_inside [elt_ty]
1296 ; return (result, mkWpCastN list_co) }
1297
1298 go rho_ty (SynFun arg_shape res_shape)
1299 = do { ( ( ( (result, arg_ty, res_ty)
1300 , res_wrapper ) -- :: res_ty_out "->" res_ty
1301 , arg_wrapper1, [], arg_wrapper2 ) -- :: arg_ty "->" arg_ty_out
1302 , match_wrapper ) -- :: (arg_ty -> res_ty) "->" rho_ty
1303 <- matchExpectedFunTys herald 1 (mkCheckExpType rho_ty) $
1304 \ [arg_ty] res_ty ->
1305 do { arg_tc_ty <- expTypeToType arg_ty
1306 ; res_tc_ty <- expTypeToType res_ty
1307
1308 -- another nested arrow is too much for now,
1309 -- but I bet we'll never need this
1310 ; MASSERT2( case arg_shape of
1311 SynFun {} -> False;
1312 _ -> True
1313 , text "Too many nested arrows in SyntaxOpType" $$
1314 pprCtOrigin orig )
1315
1316 ; tcSynArgA orig arg_tc_ty [] arg_shape $
1317 \ arg_results ->
1318 tcSynArgE orig res_tc_ty res_shape $
1319 \ res_results ->
1320 do { result <- thing_inside (arg_results ++ res_results)
1321 ; return (result, arg_tc_ty, res_tc_ty) }}
1322
1323 ; return ( result
1324 , match_wrapper <.>
1325 mkWpFun (arg_wrapper2 <.> arg_wrapper1) res_wrapper
1326 arg_ty res_ty ) }
1327 where
1328 herald = text "This rebindable syntax expects a function with"
1329
1330 go rho_ty (SynType the_ty)
1331 = do { wrap <- tcSubTypeET orig the_ty rho_ty
1332 ; result <- thing_inside []
1333 ; return (result, wrap) }
1334
1335 -- works on "actual" types, instantiating where necessary
1336 -- See Note [tcSynArg]
1337 tcSynArgA :: CtOrigin
1338 -> TcSigmaType
1339 -> [SyntaxOpType] -- ^ argument shapes
1340 -> SyntaxOpType -- ^ result shape
1341 -> ([TcSigmaType] -> TcM a) -- ^ check the arguments
1342 -> TcM (a, HsWrapper, [HsWrapper], HsWrapper)
1343 -- ^ returns a wrapper to be applied to the original function,
1344 -- wrappers to be applied to arguments
1345 -- and a wrapper to be applied to the overall expression
1346 tcSynArgA orig sigma_ty arg_shapes res_shape thing_inside
1347 = do { (match_wrapper, arg_tys, res_ty)
1348 <- matchActualFunTys herald orig noThing (length arg_shapes) sigma_ty
1349 -- match_wrapper :: sigma_ty "->" (arg_tys -> res_ty)
1350 ; ((result, res_wrapper), arg_wrappers)
1351 <- tc_syn_args_e arg_tys arg_shapes $ \ arg_results ->
1352 tc_syn_arg res_ty res_shape $ \ res_results ->
1353 thing_inside (arg_results ++ res_results)
1354 ; return (result, match_wrapper, arg_wrappers, res_wrapper) }
1355 where
1356 herald = text "This rebindable syntax expects a function with"
1357
1358 tc_syn_args_e :: [TcSigmaType] -> [SyntaxOpType]
1359 -> ([TcSigmaType] -> TcM a)
1360 -> TcM (a, [HsWrapper])
1361 -- the wrappers are for arguments
1362 tc_syn_args_e (arg_ty : arg_tys) (arg_shape : arg_shapes) thing_inside
1363 = do { ((result, arg_wraps), arg_wrap)
1364 <- tcSynArgE orig arg_ty arg_shape $ \ arg1_results ->
1365 tc_syn_args_e arg_tys arg_shapes $ \ args_results ->
1366 thing_inside (arg1_results ++ args_results)
1367 ; return (result, arg_wrap : arg_wraps) }
1368 tc_syn_args_e _ _ thing_inside = (, []) <$> thing_inside []
1369
1370 tc_syn_arg :: TcSigmaType -> SyntaxOpType
1371 -> ([TcSigmaType] -> TcM a)
1372 -> TcM (a, HsWrapper)
1373 -- the wrapper applies to the overall result
1374 tc_syn_arg res_ty SynAny thing_inside
1375 = do { result <- thing_inside [res_ty]
1376 ; return (result, idHsWrapper) }
1377 tc_syn_arg res_ty SynRho thing_inside
1378 = do { (inst_wrap, rho_ty) <- deeplyInstantiate orig res_ty
1379 -- inst_wrap :: res_ty "->" rho_ty
1380 ; result <- thing_inside [rho_ty]
1381 ; return (result, inst_wrap) }
1382 tc_syn_arg res_ty SynList thing_inside
1383 = do { (inst_wrap, rho_ty) <- topInstantiate orig res_ty
1384 -- inst_wrap :: res_ty "->" rho_ty
1385 ; (list_co, elt_ty) <- matchExpectedListTy rho_ty
1386 -- list_co :: [elt_ty] ~N rho_ty
1387 ; result <- thing_inside [elt_ty]
1388 ; return (result, mkWpCastN (mkTcSymCo list_co) <.> inst_wrap) }
1389 tc_syn_arg _ (SynFun {}) _
1390 = pprPanic "tcSynArgA hits a SynFun" (ppr orig)
1391 tc_syn_arg res_ty (SynType the_ty) thing_inside
1392 = do { wrap <- tcSubTypeO orig GenSigCtxt res_ty the_ty
1393 ; result <- thing_inside []
1394 ; return (result, wrap) }
1395
1396 {-
1397 Note [Push result type in]
1398 ~~~~~~~~~~~~~~~~~~~~~~~~~~
1399 Unify with expected result before type-checking the args so that the
1400 info from res_ty percolates to args. This is when we might detect a
1401 too-few args situation. (One can think of cases when the opposite
1402 order would give a better error message.)
1403 experimenting with putting this first.
1404
1405 Here's an example where it actually makes a real difference
1406
1407 class C t a b | t a -> b
1408 instance C Char a Bool
1409
1410 data P t a = forall b. (C t a b) => MkP b
1411 data Q t = MkQ (forall a. P t a)
1412
1413 f1, f2 :: Q Char;
1414 f1 = MkQ (MkP True)
1415 f2 = MkQ (MkP True :: forall a. P Char a)
1416
1417 With the change, f1 will type-check, because the 'Char' info from
1418 the signature is propagated into MkQ's argument. With the check
1419 in the other order, the extra signature in f2 is reqd.
1420
1421 ************************************************************************
1422 * *
1423 Expressions with a type signature
1424 expr :: type
1425 * *
1426 ********************************************************************* -}
1427
1428 tcExprSig :: LHsExpr Name -> TcIdSigInfo -> TcM (LHsExpr TcId, TcType)
1429 tcExprSig expr sig@(TISI { sig_bndr = s_bndr
1430 , sig_skols = skol_prs
1431 , sig_theta = theta
1432 , sig_tau = tau })
1433 | null skol_prs -- Fast path when there is no quantification at all
1434 , null theta
1435 , CompleteSig {} <- s_bndr
1436 = do { expr' <- tcPolyExprNC expr tau
1437 ; return (expr', tau) }
1438
1439 | CompleteSig poly_id <- s_bndr
1440 = do { given <- newEvVars theta
1441 ; (ev_binds, expr') <- checkConstraints skol_info skol_tvs given $
1442 tcExtendTyVarEnvFromSig sig $
1443 tcPolyExprNC expr tau
1444
1445 ; let poly_wrap = mkWpTyLams skol_tvs
1446 <.> mkWpLams given
1447 <.> mkWpLet ev_binds
1448 ; return (mkLHsWrap poly_wrap expr', idType poly_id) }
1449
1450 | PartialSig { sig_name = name } <- s_bndr
1451 = do { (tclvl, wanted, expr') <- pushLevelAndCaptureConstraints $
1452 tcExtendTyVarEnvFromSig sig $
1453 tcPolyExprNC expr tau
1454 ; (qtvs, givens, ev_binds)
1455 <- simplifyInfer tclvl False [sig] [(name, tau)] wanted
1456 ; tau <- zonkTcType tau
1457 ; let inferred_theta = map evVarPred givens
1458 tau_tvs = tyCoVarsOfType tau
1459 ; (binders, my_theta) <- chooseInferredQuantifiers inferred_theta
1460 tau_tvs qtvs (Just sig)
1461 ; let inferred_sigma = mkInvSigmaTy qtvs inferred_theta tau
1462 my_sigma = mkForAllTys binders (mkPhiTy my_theta tau)
1463 ; wrap <- if inferred_sigma `eqType` my_sigma -- NB: eqType ignores vis.
1464 then return idHsWrapper -- Fast path; also avoids complaint when we infer
1465 -- an ambiguouse type and have AllowAmbiguousType
1466 -- e..g infer x :: forall a. F a -> Int
1467 else tcSubType_NC ExprSigCtxt inferred_sigma
1468 (mkCheckExpType my_sigma)
1469
1470 ; let poly_wrap = wrap
1471 <.> mkWpTyLams qtvs
1472 <.> mkWpLams givens
1473 <.> mkWpLet ev_binds
1474 ; return (mkLHsWrap poly_wrap expr', my_sigma) }
1475
1476 | otherwise = panic "tcExprSig" -- Can't happen
1477 where
1478 skol_info = SigSkol ExprSigCtxt (mkCheckExpType $ mkPhiTy theta tau)
1479 skol_tvs = map snd skol_prs
1480
1481 {- *********************************************************************
1482 * *
1483 tcInferId
1484 * *
1485 ********************************************************************* -}
1486
1487 tcCheckId :: Name -> ExpRhoType -> TcM (HsExpr TcId)
1488 tcCheckId name res_ty
1489 = do { (expr, actual_res_ty) <- tcInferId name
1490 ; traceTc "tcCheckId" (vcat [ppr name, ppr actual_res_ty, ppr res_ty])
1491 ; addFunResCtxt False (HsVar (noLoc name)) actual_res_ty res_ty $
1492 tcWrapResultO (OccurrenceOf name) expr actual_res_ty res_ty }
1493
1494 tcCheckRecSelId :: AmbiguousFieldOcc Name -> ExpRhoType -> TcM (HsExpr TcId)
1495 tcCheckRecSelId f@(Unambiguous (L _ lbl) _) res_ty
1496 = do { (expr, actual_res_ty) <- tcInferRecSelId f
1497 ; addFunResCtxt False (HsRecFld f) actual_res_ty res_ty $
1498 tcWrapResultO (OccurrenceOfRecSel lbl) expr actual_res_ty res_ty }
1499 tcCheckRecSelId (Ambiguous lbl _) res_ty
1500 = case tcSplitFunTy_maybe =<< checkingExpType_maybe res_ty of
1501 Nothing -> ambiguousSelector lbl
1502 Just (arg, _) -> do { sel_name <- disambiguateSelector lbl arg
1503 ; tcCheckRecSelId (Unambiguous lbl sel_name) res_ty }
1504
1505 ------------------------
1506 tcInferRecSelId :: AmbiguousFieldOcc Name -> TcM (HsExpr TcId, TcRhoType)
1507 tcInferRecSelId (Unambiguous (L _ lbl) sel)
1508 = do { (expr', ty) <- tc_infer_id lbl sel
1509 ; return (expr', ty) }
1510 tcInferRecSelId (Ambiguous lbl _)
1511 = ambiguousSelector lbl
1512
1513 ------------------------
1514 tcInferId :: Name -> TcM (HsExpr TcId, TcSigmaType)
1515 -- Look up an occurrence of an Id
1516 tcInferId id_name
1517 | id_name `hasKey` tagToEnumKey
1518 = failWithTc (text "tagToEnum# must appear applied to one argument")
1519 -- tcApp catches the case (tagToEnum# arg)
1520
1521 | id_name `hasKey` assertIdKey
1522 = do { dflags <- getDynFlags
1523 ; if gopt Opt_IgnoreAsserts dflags
1524 then tc_infer_id (nameRdrName id_name) id_name
1525 else tc_infer_assert id_name }
1526
1527 | otherwise
1528 = do { (expr, ty) <- tc_infer_id (nameRdrName id_name) id_name
1529 ; traceTc "tcInferId" (ppr id_name <+> dcolon <+> ppr ty)
1530 ; return (expr, ty) }
1531
1532 tc_infer_assert :: Name -> TcM (HsExpr TcId, TcSigmaType)
1533 -- Deal with an occurrence of 'assert'
1534 -- See Note [Adding the implicit parameter to 'assert']
1535 tc_infer_assert assert_name
1536 = do { assert_error_id <- tcLookupId assertErrorName
1537 ; (wrap, id_rho) <- topInstantiate (OccurrenceOf assert_name)
1538 (idType assert_error_id)
1539 ; return (mkHsWrap wrap (HsVar (noLoc assert_error_id)), id_rho)
1540 }
1541
1542 tc_infer_id :: RdrName -> Name -> TcM (HsExpr TcId, TcSigmaType)
1543 tc_infer_id lbl id_name
1544 = do { thing <- tcLookup id_name
1545 ; case thing of
1546 ATcId { tct_id = id }
1547 -> do { check_naughty id -- Note [Local record selectors]
1548 ; checkThLocalId id
1549 ; return_id id }
1550
1551 AGlobal (AnId id)
1552 -> do { check_naughty id
1553 ; return_id id }
1554 -- A global cannot possibly be ill-staged
1555 -- nor does it need the 'lifting' treatment
1556 -- hence no checkTh stuff here
1557
1558 AGlobal (AConLike cl) -> case cl of
1559 RealDataCon con -> return_data_con con
1560 PatSynCon ps -> tcPatSynBuilderOcc ps
1561
1562 _ -> failWithTc $
1563 ppr thing <+> text "used where a value identifier was expected" }
1564 where
1565 return_id id = return (HsVar (noLoc id), idType id)
1566
1567 return_data_con con
1568 -- For data constructors, must perform the stupid-theta check
1569 | null stupid_theta
1570 = return_id con_wrapper_id
1571
1572 | otherwise
1573 -- See Note [Instantiating stupid theta]
1574 = do { let (tvs, theta, rho) = tcSplitSigmaTy (idType con_wrapper_id)
1575 ; (subst, tvs') <- newMetaTyVars tvs
1576 ; let tys' = mkTyVarTys tvs'
1577 theta' = substTheta subst theta
1578 rho' = substTy subst rho
1579 ; wrap <- instCall (OccurrenceOf id_name) tys' theta'
1580 ; addDataConStupidTheta con tys'
1581 ; return (mkHsWrap wrap (HsVar (noLoc con_wrapper_id)), rho') }
1582
1583 where
1584 con_wrapper_id = dataConWrapId con
1585 stupid_theta = dataConStupidTheta con
1586
1587 check_naughty id
1588 | isNaughtyRecordSelector id = failWithTc (naughtyRecordSel lbl)
1589 | otherwise = return ()
1590
1591
1592 tcUnboundId :: OccName -> ExpRhoType -> TcM (HsExpr TcId)
1593 -- Typechedk an occurrence of an unbound Id
1594 --
1595 -- Some of these started life as a true hole "_". Others might simply
1596 -- be variables that accidentally have no binding site
1597 --
1598 -- We turn all of them into HsVar, since HsUnboundVar can't contain an
1599 -- Id; and indeed the evidence for the CHoleCan does bind it, so it's
1600 -- not unbound any more!
1601 tcUnboundId occ res_ty
1602 = do { ty <- newFlexiTyVarTy liftedTypeKind
1603 ; name <- newSysName occ
1604 ; let ev = mkLocalId name ty
1605 ; loc <- getCtLocM HoleOrigin Nothing
1606 ; let can = CHoleCan { cc_ev = CtWanted { ctev_pred = ty
1607 , ctev_dest = EvVarDest ev
1608 , ctev_loc = loc}
1609 , cc_occ = occ
1610 , cc_hole = ExprHole }
1611 ; emitInsoluble can
1612 ; tcWrapResultO (UnboundOccurrenceOf occ) (HsVar (noLoc ev)) ty res_ty }
1613
1614
1615 {-
1616 Note [Adding the implicit parameter to 'assert']
1617 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1618 The typechecker transforms (assert e1 e2) to (assertError e1 e2).
1619 This isn't really the Right Thing because there's no way to "undo"
1620 if you want to see the original source code in the typechecker
1621 output. We'll have fix this in due course, when we care more about
1622 being able to reconstruct the exact original program.
1623
1624 Note [tagToEnum#]
1625 ~~~~~~~~~~~~~~~~~
1626 Nasty check to ensure that tagToEnum# is applied to a type that is an
1627 enumeration TyCon. Unification may refine the type later, but this
1628 check won't see that, alas. It's crude, because it relies on our
1629 knowing *now* that the type is ok, which in turn relies on the
1630 eager-unification part of the type checker pushing enough information
1631 here. In theory the Right Thing to do is to have a new form of
1632 constraint but I definitely cannot face that! And it works ok as-is.
1633
1634 Here's are two cases that should fail
1635 f :: forall a. a
1636 f = tagToEnum# 0 -- Can't do tagToEnum# at a type variable
1637
1638 g :: Int
1639 g = tagToEnum# 0 -- Int is not an enumeration
1640
1641 When data type families are involved it's a bit more complicated.
1642 data family F a
1643 data instance F [Int] = A | B | C
1644 Then we want to generate something like
1645 tagToEnum# R:FListInt 3# |> co :: R:FListInt ~ F [Int]
1646 Usually that coercion is hidden inside the wrappers for
1647 constructors of F [Int] but here we have to do it explicitly.
1648
1649 It's all grotesquely complicated.
1650
1651 Note [Instantiating stupid theta]
1652 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1653 Normally, when we infer the type of an Id, we don't instantiate,
1654 because we wish to allow for visible type application later on.
1655 But if a datacon has a stupid theta, we're a bit stuck. We need
1656 to emit the stupid theta constraints with instantiated types. It's
1657 difficult to defer this to the lazy instantiation, because a stupid
1658 theta has no spot to put it in a type. So we just instantiate eagerly
1659 in this case. Thus, users cannot use visible type application with
1660 a data constructor sporting a stupid theta. I won't feel so bad for
1661 the users that complain.
1662
1663 -}
1664
1665 tcSeq :: SrcSpan -> Name -> [LHsExprArgIn]
1666 -> ExpRhoType -> TcM (HsWrapper, LHsExpr TcId, [LHsExprArgOut])
1667 -- (seq e1 e2) :: res_ty
1668 -- We need a special typing rule because res_ty can be unboxed
1669 -- See Note [Typing rule for seq]
1670 tcSeq loc fun_name args res_ty
1671 = do { fun <- tcLookupId fun_name
1672 ; (arg1_ty, args1) <- case args of
1673 (Right hs_ty_arg1 : args1)
1674 -> do { ty_arg1 <- tcHsTypeApp hs_ty_arg1 liftedTypeKind
1675 ; return (ty_arg1, args1) }
1676
1677 _ -> do { arg_ty1 <- newFlexiTyVarTy liftedTypeKind
1678 ; return (arg_ty1, args) }
1679
1680 ; (arg1, arg2, arg2_exp_ty) <- case args1 of
1681 [Right hs_ty_arg2, Left term_arg1, Left term_arg2]
1682 -> do { rr_ty <- newFlexiTyVarTy runtimeRepTy
1683 ; ty_arg2 <- tcHsTypeApp hs_ty_arg2 (tYPE rr_ty)
1684 -- see Note [Typing rule for seq]
1685 ; _ <- tcSubTypeDS GenSigCtxt noThing ty_arg2 res_ty
1686 ; return (term_arg1, term_arg2, mkCheckExpType ty_arg2) }
1687 [Left term_arg1, Left term_arg2]
1688 -> return (term_arg1, term_arg2, res_ty)
1689 _ -> too_many_args "seq" args
1690
1691 ; arg1' <- tcMonoExpr arg1 (mkCheckExpType arg1_ty)
1692 ; arg2' <- tcMonoExpr arg2 arg2_exp_ty
1693 ; res_ty <- readExpType res_ty -- by now, it's surely filled in
1694 ; let fun' = L loc (HsWrap ty_args (HsVar (L loc fun)))
1695 ty_args = WpTyApp res_ty <.> WpTyApp arg1_ty
1696 ; return (idHsWrapper, fun', [Left arg1', Left arg2']) }
1697
1698 tcTagToEnum :: SrcSpan -> Name -> [LHsExprArgIn] -> ExpRhoType
1699 -> TcM (HsWrapper, LHsExpr TcId, [LHsExprArgOut])
1700 -- tagToEnum# :: forall a. Int# -> a
1701 -- See Note [tagToEnum#] Urgh!
1702 tcTagToEnum loc fun_name args res_ty
1703 = do { fun <- tcLookupId fun_name
1704
1705 ; arg <- case args of
1706 [Right hs_ty_arg, Left term_arg]
1707 -> do { ty_arg <- tcHsTypeApp hs_ty_arg liftedTypeKind
1708 ; _ <- tcSubTypeDS GenSigCtxt noThing ty_arg res_ty
1709 -- other than influencing res_ty, we just
1710 -- don't care about a type arg passed in.
1711 -- So drop the evidence.
1712 ; return term_arg }
1713 [Left term_arg] -> do { _ <- expTypeToType res_ty
1714 ; return term_arg }
1715 _ -> too_many_args "tagToEnum#" args
1716
1717 ; res_ty <- readExpType res_ty
1718 ; ty' <- zonkTcType res_ty
1719
1720 -- Check that the type is algebraic
1721 ; let mb_tc_app = tcSplitTyConApp_maybe ty'
1722 Just (tc, tc_args) = mb_tc_app
1723 ; checkTc (isJust mb_tc_app)
1724 (mk_error ty' doc1)
1725
1726 -- Look through any type family
1727 ; fam_envs <- tcGetFamInstEnvs
1728 ; let (rep_tc, rep_args, coi)
1729 = tcLookupDataFamInst fam_envs tc tc_args
1730 -- coi :: tc tc_args ~R rep_tc rep_args
1731
1732 ; checkTc (isEnumerationTyCon rep_tc)
1733 (mk_error ty' doc2)
1734
1735 ; arg' <- tcMonoExpr arg (mkCheckExpType intPrimTy)
1736 ; let fun' = L loc (HsWrap (WpTyApp rep_ty) (HsVar (L loc fun)))
1737 rep_ty = mkTyConApp rep_tc rep_args
1738
1739 ; return (mkWpCastR (mkTcSymCo coi), fun', [Left arg']) }
1740 -- coi is a Representational coercion
1741 where
1742 doc1 = vcat [ text "Specify the type by giving a type signature"
1743 , text "e.g. (tagToEnum# x) :: Bool" ]
1744 doc2 = text "Result type must be an enumeration type"
1745
1746 mk_error :: TcType -> SDoc -> SDoc
1747 mk_error ty what
1748 = hang (text "Bad call to tagToEnum#"
1749 <+> text "at type" <+> ppr ty)
1750 2 what
1751
1752 too_many_args :: String -> [LHsExprArgIn] -> TcM a
1753 too_many_args fun args
1754 = failWith $
1755 hang (text "Too many type arguments to" <+> text fun <> colon)
1756 2 (sep (map pp args))
1757 where
1758 pp (Left e) = pprParendLExpr e
1759 pp (Right (HsWC { hswc_body = L _ t })) = pprParendHsType t
1760
1761
1762 {-
1763 ************************************************************************
1764 * *
1765 Template Haskell checks
1766 * *
1767 ************************************************************************
1768 -}
1769
1770 checkThLocalId :: Id -> TcM ()
1771 checkThLocalId id
1772 = do { mb_local_use <- getStageAndBindLevel (idName id)
1773 ; case mb_local_use of
1774 Just (top_lvl, bind_lvl, use_stage)
1775 | thLevel use_stage > bind_lvl
1776 , isNotTopLevel top_lvl
1777 -> checkCrossStageLifting id use_stage
1778 _ -> return () -- Not a locally-bound thing, or
1779 -- no cross-stage link
1780 }
1781
1782 --------------------------------------
1783 checkCrossStageLifting :: Id -> ThStage -> TcM ()
1784 -- If we are inside typed brackets, and (use_lvl > bind_lvl)
1785 -- we must check whether there's a cross-stage lift to do
1786 -- Examples \x -> [|| x ||]
1787 -- [|| map ||]
1788 -- There is no error-checking to do, because the renamer did that
1789 --
1790 -- This is similar to checkCrossStageLifting in RnSplice, but
1791 -- this code is applied to *typed* brackets.
1792
1793 checkCrossStageLifting id (Brack _ (TcPending ps_var lie_var))
1794 = -- Nested identifiers, such as 'x' in
1795 -- E.g. \x -> [|| h x ||]
1796 -- We must behave as if the reference to x was
1797 -- h $(lift x)
1798 -- We use 'x' itself as the splice proxy, used by
1799 -- the desugarer to stitch it all back together.
1800 -- If 'x' occurs many times we may get many identical
1801 -- bindings of the same splice proxy, but that doesn't
1802 -- matter, although it's a mite untidy.
1803 do { let id_ty = idType id
1804 ; checkTc (isTauTy id_ty) (polySpliceErr id)
1805 -- If x is polymorphic, its occurrence sites might
1806 -- have different instantiations, so we can't use plain
1807 -- 'x' as the splice proxy name. I don't know how to
1808 -- solve this, and it's probably unimportant, so I'm
1809 -- just going to flag an error for now
1810
1811 ; lift <- if isStringTy id_ty then
1812 do { sid <- tcLookupId THNames.liftStringName
1813 -- See Note [Lifting strings]
1814 ; return (HsVar (noLoc sid)) }
1815 else
1816 setConstraintVar lie_var $
1817 -- Put the 'lift' constraint into the right LIE
1818 newMethodFromName (OccurrenceOf (idName id))
1819 THNames.liftName id_ty
1820
1821 -- Update the pending splices
1822 ; ps <- readMutVar ps_var
1823 ; let pending_splice = PendingTcSplice (idName id) (nlHsApp (noLoc lift) (nlHsVar id))
1824 ; writeMutVar ps_var (pending_splice : ps)
1825
1826 ; return () }
1827
1828 checkCrossStageLifting _ _ = return ()
1829
1830 polySpliceErr :: Id -> SDoc
1831 polySpliceErr id
1832 = text "Can't splice the polymorphic local variable" <+> quotes (ppr id)
1833
1834 {-
1835 Note [Lifting strings]
1836 ~~~~~~~~~~~~~~~~~~~~~~
1837 If we see $(... [| s |] ...) where s::String, we don't want to
1838 generate a mass of Cons (CharL 'x') (Cons (CharL 'y') ...)) etc.
1839 So this conditional short-circuits the lifting mechanism to generate
1840 (liftString "xy") in that case. I didn't want to use overlapping instances
1841 for the Lift class in TH.Syntax, because that can lead to overlapping-instance
1842 errors in a polymorphic situation.
1843
1844 If this check fails (which isn't impossible) we get another chance; see
1845 Note [Converting strings] in Convert.hs
1846
1847 Local record selectors
1848 ~~~~~~~~~~~~~~~~~~~~~~
1849 Record selectors for TyCons in this module are ordinary local bindings,
1850 which show up as ATcIds rather than AGlobals. So we need to check for
1851 naughtiness in both branches. c.f. TcTyClsBindings.mkAuxBinds.
1852
1853
1854 ************************************************************************
1855 * *
1856 \subsection{Record bindings}
1857 * *
1858 ************************************************************************
1859 -}
1860
1861 getFixedTyVars :: [FieldLabelString] -> [TyVar] -> [ConLike] -> TyVarSet
1862 -- These tyvars must not change across the updates
1863 getFixedTyVars upd_fld_occs univ_tvs cons
1864 = mkVarSet [tv1 | con <- cons
1865 , let (u_tvs, _, eqspec, prov_theta
1866 , req_theta, arg_tys, _)
1867 = conLikeFullSig con
1868 theta = eqSpecPreds eqspec
1869 ++ prov_theta
1870 ++ req_theta
1871 flds = conLikeFieldLabels con
1872 fixed_tvs = exactTyCoVarsOfTypes fixed_tys
1873 -- fixed_tys: See Note [Type of a record update]
1874 `unionVarSet` tyCoVarsOfTypes theta
1875 -- Universally-quantified tyvars that
1876 -- appear in any of the *implicit*
1877 -- arguments to the constructor are fixed
1878 -- See Note [Implict type sharing]
1879
1880 fixed_tys = [ty | (fl, ty) <- zip flds arg_tys
1881 , not (flLabel fl `elem` upd_fld_occs)]
1882 , (tv1,tv) <- univ_tvs `zip` u_tvs
1883 , tv `elemVarSet` fixed_tvs ]
1884
1885 {-
1886 Note [Disambiguating record fields]
1887 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1888 When the -XDuplicateRecordFields extension is used, and the renamer
1889 encounters a record selector or update that it cannot immediately
1890 disambiguate (because it involves fields that belong to multiple
1891 datatypes), it will defer resolution of the ambiguity to the
1892 typechecker. In this case, the `Ambiguous` constructor of
1893 `AmbiguousFieldOcc` is used.
1894
1895 Consider the following definitions:
1896
1897 data S = MkS { foo :: Int }
1898 data T = MkT { foo :: Int, bar :: Int }
1899 data U = MkU { bar :: Int, baz :: Int }
1900
1901 When the renamer sees `foo` as a selector or an update, it will not
1902 know which parent datatype is in use.
1903
1904 For selectors, there are two possible ways to disambiguate:
1905
1906 1. Check if the pushed-in type is a function whose domain is a
1907 datatype, for example:
1908
1909 f s = (foo :: S -> Int) s
1910
1911 g :: T -> Int
1912 g = foo
1913
1914 This is checked by `tcCheckRecSelId` when checking `HsRecFld foo`.
1915
1916 2. Check if the selector is applied to an argument that has a type
1917 signature, for example:
1918
1919 h = foo (s :: S)
1920
1921 This is checked by `tcApp`.
1922
1923
1924 Updates are slightly more complex. The `disambiguateRecordBinds`
1925 function tries to determine the parent datatype in three ways:
1926
1927 1. Check for types that have all the fields being updated. For example:
1928
1929 f x = x { foo = 3, bar = 2 }
1930
1931 Here `f` must be updating `T` because neither `S` nor `U` have
1932 both fields. This may also discover that no possible type exists.
1933 For example the following will be rejected:
1934
1935 f' x = x { foo = 3, baz = 3 }
1936
1937 2. Use the type being pushed in, if it is already a TyConApp. The
1938 following are valid updates to `T`:
1939
1940 g :: T -> T
1941 g x = x { foo = 3 }
1942
1943 g' x = x { foo = 3 } :: T
1944
1945 3. Use the type signature of the record expression, if it exists and
1946 is a TyConApp. Thus this is valid update to `T`:
1947
1948 h x = (x :: T) { foo = 3 }
1949
1950
1951 Note that we do not look up the types of variables being updated, and
1952 no constraint-solving is performed, so for example the following will
1953 be rejected as ambiguous:
1954
1955 let bad (s :: S) = foo s
1956
1957 let r :: T
1958 r = blah
1959 in r { foo = 3 }
1960
1961 \r. (r { foo = 3 }, r :: T )
1962
1963 We could add further tests, of a more heuristic nature. For example,
1964 rather than looking for an explicit signature, we could try to infer
1965 the type of the argument to a selector or the record expression being
1966 updated, in case we are lucky enough to get a TyConApp straight
1967 away. However, it might be hard for programmers to predict whether a
1968 particular update is sufficiently obvious for the signature to be
1969 omitted. Moreover, this might change the behaviour of typechecker in
1970 non-obvious ways.
1971
1972 See also Note [HsRecField and HsRecUpdField] in HsPat.
1973 -}
1974
1975 -- Given a RdrName that refers to multiple record fields, and the type
1976 -- of its argument, try to determine the name of the selector that is
1977 -- meant.
1978 disambiguateSelector :: Located RdrName -> Type -> TcM Name
1979 disambiguateSelector lr@(L _ rdr) parent_type
1980 = do { fam_inst_envs <- tcGetFamInstEnvs
1981 ; case tyConOf fam_inst_envs parent_type of
1982 Nothing -> ambiguousSelector lr
1983 Just p ->
1984 do { xs <- lookupParents rdr
1985 ; let parent = RecSelData p
1986 ; case lookup parent xs of
1987 Just gre -> do { addUsedGRE True gre
1988 ; return (gre_name gre) }
1989 Nothing -> failWithTc (fieldNotInType parent rdr) } }
1990
1991 -- This field name really is ambiguous, so add a suitable "ambiguous
1992 -- occurrence" error, then give up.
1993 ambiguousSelector :: Located RdrName -> TcM a
1994 ambiguousSelector (L _ rdr)
1995 = do { env <- getGlobalRdrEnv
1996 ; let gres = lookupGRE_RdrName rdr env
1997 ; setErrCtxt [] $ addNameClashErrRn rdr gres
1998 ; failM }
1999
2000 -- Disambiguate the fields in a record update.
2001 -- See Note [Disambiguating record fields]
2002 disambiguateRecordBinds :: LHsExpr Name -> TcRhoType
2003 -> [LHsRecUpdField Name] -> ExpRhoType
2004 -> TcM [LHsRecField' (AmbiguousFieldOcc Id) (LHsExpr Name)]
2005 disambiguateRecordBinds record_expr record_rho rbnds res_ty
2006 -- Are all the fields unambiguous?
2007 = case mapM isUnambiguous rbnds of
2008 -- If so, just skip to looking up the Ids
2009 -- Always the case if DuplicateRecordFields is off
2010 Just rbnds' -> mapM lookupSelector rbnds'
2011 Nothing -> -- If not, try to identify a single parent
2012 do { fam_inst_envs <- tcGetFamInstEnvs
2013 -- Look up the possible parents for each field
2014 ; rbnds_with_parents <- getUpdFieldsParents
2015 ; let possible_parents = map (map fst . snd) rbnds_with_parents
2016 -- Identify a single parent
2017 ; p <- identifyParent fam_inst_envs possible_parents
2018 -- Pick the right selector with that parent for each field
2019 ; checkNoErrs $ mapM (pickParent p) rbnds_with_parents }
2020 where
2021 -- Extract the selector name of a field update if it is unambiguous
2022 isUnambiguous :: LHsRecUpdField Name -> Maybe (LHsRecUpdField Name, Name)
2023 isUnambiguous x = case unLoc (hsRecFieldLbl (unLoc x)) of
2024 Unambiguous _ sel_name -> Just (x, sel_name)
2025 Ambiguous{} -> Nothing
2026
2027 -- Look up the possible parents and selector GREs for each field
2028 getUpdFieldsParents :: TcM [(LHsRecUpdField Name
2029 , [(RecSelParent, GlobalRdrElt)])]
2030 getUpdFieldsParents
2031 = fmap (zip rbnds) $ mapM
2032 (lookupParents . unLoc . hsRecUpdFieldRdr . unLoc)
2033 rbnds
2034
2035 -- Given a the lists of possible parents for each field,
2036 -- identify a single parent
2037 identifyParent :: FamInstEnvs -> [[RecSelParent]] -> TcM RecSelParent
2038 identifyParent fam_inst_envs possible_parents
2039 = case foldr1 intersect possible_parents of
2040 -- No parents for all fields: record update is ill-typed
2041 [] -> failWithTc (noPossibleParents rbnds)
2042
2043 -- Exactly one datatype with all the fields: use that
2044 [p] -> return p
2045
2046 -- Multiple possible parents: try harder to disambiguate
2047 -- Can we get a parent TyCon from the pushed-in type?
2048 _:_ | Just p <- tyConOfET fam_inst_envs res_ty -> return (RecSelData p)
2049
2050 -- Does the expression being updated have a type signature?
2051 -- If so, try to extract a parent TyCon from it
2052 | Just {} <- obviousSig (unLoc record_expr)
2053 , Just tc <- tyConOf fam_inst_envs record_rho
2054 -> return (RecSelData tc)
2055
2056 -- Nothing else we can try...
2057 _ -> failWithTc badOverloadedUpdate
2058
2059 -- Make a field unambiguous by choosing the given parent.
2060 -- Emits an error if the field cannot have that parent,
2061 -- e.g. if the user writes
2062 -- r { x = e } :: T
2063 -- where T does not have field x.
2064 pickParent :: RecSelParent
2065 -> (LHsRecUpdField Name, [(RecSelParent, GlobalRdrElt)])
2066 -> TcM (LHsRecField' (AmbiguousFieldOcc Id) (LHsExpr Name))
2067 pickParent p (upd, xs)
2068 = case lookup p xs of
2069 -- Phew! The parent is valid for this field.
2070 -- Previously ambiguous fields must be marked as
2071 -- used now that we know which one is meant, but
2072 -- unambiguous ones shouldn't be recorded again
2073 -- (giving duplicate deprecation warnings).
2074 Just gre -> do { unless (null (tail xs)) $ do
2075 let L loc _ = hsRecFieldLbl (unLoc upd)
2076 setSrcSpan loc $ addUsedGRE True gre
2077 ; lookupSelector (upd, gre_name gre) }
2078 -- The field doesn't belong to this parent, so report
2079 -- an error but keep going through all the fields
2080 Nothing -> do { addErrTc (fieldNotInType p
2081 (unLoc (hsRecUpdFieldRdr (unLoc upd))))
2082 ; lookupSelector (upd, gre_name (snd (head xs))) }
2083
2084 -- Given a (field update, selector name) pair, look up the
2085 -- selector to give a field update with an unambiguous Id
2086 lookupSelector :: (LHsRecUpdField Name, Name)
2087 -> TcM (LHsRecField' (AmbiguousFieldOcc Id) (LHsExpr Name))
2088 lookupSelector (L l upd, n)
2089 = do { i <- tcLookupId n
2090 ; let L loc af = hsRecFieldLbl upd
2091 lbl = rdrNameAmbiguousFieldOcc af
2092 ; return $ L l upd { hsRecFieldLbl
2093 = L loc (Unambiguous (L loc lbl) i) } }
2094
2095
2096 -- Extract the outermost TyCon of a type, if there is one; for
2097 -- data families this is the representation tycon (because that's
2098 -- where the fields live).
2099 tyConOf :: FamInstEnvs -> TcSigmaType -> Maybe TyCon
2100 tyConOf fam_inst_envs ty0
2101 = case tcSplitTyConApp_maybe ty of
2102 Just (tc, tys) -> Just (fstOf3 (tcLookupDataFamInst fam_inst_envs tc tys))
2103 Nothing -> Nothing
2104 where
2105 (_, _, ty) = tcSplitSigmaTy ty0
2106
2107 -- Variant of tyConOf that works for ExpTypes
2108 tyConOfET :: FamInstEnvs -> ExpRhoType -> Maybe TyCon
2109 tyConOfET fam_inst_envs ty0 = tyConOf fam_inst_envs =<< checkingExpType_maybe ty0
2110
2111 -- For an ambiguous record field, find all the candidate record
2112 -- selectors (as GlobalRdrElts) and their parents.
2113 lookupParents :: RdrName -> RnM [(RecSelParent, GlobalRdrElt)]
2114 lookupParents rdr
2115 = do { env <- getGlobalRdrEnv
2116 ; let gres = lookupGRE_RdrName rdr env
2117 ; mapM lookupParent gres }
2118 where
2119 lookupParent :: GlobalRdrElt -> RnM (RecSelParent, GlobalRdrElt)
2120 lookupParent gre = do { id <- tcLookupId (gre_name gre)
2121 ; if isRecordSelector id
2122 then return (recordSelectorTyCon id, gre)
2123 else failWithTc (notSelector (gre_name gre)) }
2124
2125 -- A type signature on the argument of an ambiguous record selector or
2126 -- the record expression in an update must be "obvious", i.e. the
2127 -- outermost constructor ignoring parentheses.
2128 obviousSig :: HsExpr Name -> Maybe (LHsSigWcType Name)
2129 obviousSig (ExprWithTySig _ ty) = Just ty
2130 obviousSig (HsPar p) = obviousSig (unLoc p)
2131 obviousSig _ = Nothing
2132
2133
2134 {-
2135 Game plan for record bindings
2136 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2137 1. Find the TyCon for the bindings, from the first field label.
2138
2139 2. Instantiate its tyvars and unify (T a1 .. an) with expected_ty.
2140
2141 For each binding field = value
2142
2143 3. Instantiate the field type (from the field label) using the type
2144 envt from step 2.
2145
2146 4 Type check the value using tcArg, passing the field type as
2147 the expected argument type.
2148
2149 This extends OK when the field types are universally quantified.
2150 -}
2151
2152 tcRecordBinds
2153 :: ConLike
2154 -> [TcType] -- Expected type for each field
2155 -> HsRecordBinds Name
2156 -> TcM (HsRecordBinds TcId)
2157
2158 tcRecordBinds con_like arg_tys (HsRecFields rbinds dd)
2159 = do { mb_binds <- mapM do_bind rbinds
2160 ; return (HsRecFields (catMaybes mb_binds) dd) }
2161 where
2162 fields = map flLabel $ conLikeFieldLabels con_like
2163 flds_w_tys = zipEqual "tcRecordBinds" fields arg_tys
2164
2165 do_bind :: LHsRecField Name (LHsExpr Name)
2166 -> TcM (Maybe (LHsRecField TcId (LHsExpr TcId)))
2167 do_bind (L l fld@(HsRecField { hsRecFieldLbl = f
2168 , hsRecFieldArg = rhs }))
2169
2170 = do { mb <- tcRecordField con_like flds_w_tys f rhs
2171 ; case mb of
2172 Nothing -> return Nothing
2173 Just (f', rhs') -> return (Just (L l (fld { hsRecFieldLbl = f'
2174 , hsRecFieldArg = rhs' }))) }
2175
2176 tcRecordUpd
2177 :: ConLike
2178 -> [TcType] -- Expected type for each field
2179 -> [LHsRecField' (AmbiguousFieldOcc Id) (LHsExpr Name)]
2180 -> TcM [LHsRecUpdField TcId]
2181
2182 tcRecordUpd con_like arg_tys rbinds = fmap catMaybes $ mapM do_bind rbinds
2183 where
2184 flds_w_tys = zipEqual "tcRecordUpd" (map flLabel $ conLikeFieldLabels con_like) arg_tys
2185
2186 do_bind :: LHsRecField' (AmbiguousFieldOcc Id) (LHsExpr Name) -> TcM (Maybe (LHsRecUpdField TcId))
2187 do_bind (L l fld@(HsRecField { hsRecFieldLbl = L loc af
2188 , hsRecFieldArg = rhs }))
2189 = do { let lbl = rdrNameAmbiguousFieldOcc af
2190 sel_id = selectorAmbiguousFieldOcc af
2191 f = L loc (FieldOcc (L loc lbl) (idName sel_id))
2192 ; mb <- tcRecordField con_like flds_w_tys f rhs
2193 ; case mb of
2194 Nothing -> return Nothing
2195 Just (f', rhs') ->
2196 return (Just
2197 (L l (fld { hsRecFieldLbl
2198 = L loc (Unambiguous (L loc lbl)
2199 (selectorFieldOcc (unLoc f')))
2200 , hsRecFieldArg = rhs' }))) }
2201
2202 tcRecordField :: ConLike -> Assoc FieldLabelString Type -> LFieldOcc Name -> LHsExpr Name
2203 -> TcM (Maybe (LFieldOcc Id, LHsExpr Id))
2204 tcRecordField con_like flds_w_tys (L loc (FieldOcc lbl sel_name)) rhs
2205 | Just field_ty <- assocMaybe flds_w_tys field_lbl
2206 = addErrCtxt (fieldCtxt field_lbl) $
2207 do { rhs' <- tcPolyExprNC rhs field_ty
2208 ; let field_id = mkUserLocal (nameOccName sel_name)
2209 (nameUnique sel_name)
2210 field_ty loc
2211 -- Yuk: the field_id has the *unique* of the selector Id
2212 -- (so we can find it easily)
2213 -- but is a LocalId with the appropriate type of the RHS
2214 -- (so the desugarer knows the type of local binder to make)
2215 ; return (Just (L loc (FieldOcc lbl field_id), rhs')) }
2216 | otherwise
2217 = do { addErrTc (badFieldCon con_like field_lbl)
2218 ; return Nothing }
2219 where
2220 field_lbl = occNameFS $ rdrNameOcc (unLoc lbl)
2221
2222
2223 checkMissingFields :: ConLike -> HsRecordBinds Name -> TcM ()
2224 checkMissingFields con_like rbinds
2225 | null field_labels -- Not declared as a record;
2226 -- But C{} is still valid if no strict fields
2227 = if any isBanged field_strs then
2228 -- Illegal if any arg is strict
2229 addErrTc (missingStrictFields con_like [])
2230 else
2231 return ()
2232
2233 | otherwise = do -- A record
2234 unless (null missing_s_fields)
2235 (addErrTc (missingStrictFields con_like missing_s_fields))
2236
2237 warn <- woptM Opt_WarnMissingFields
2238 unless (not (warn && notNull missing_ns_fields))
2239 (warnTc (Reason Opt_WarnMissingFields) True
2240 (missingFields con_like missing_ns_fields))
2241
2242 where
2243 missing_s_fields
2244 = [ flLabel fl | (fl, str) <- field_info,
2245 isBanged str,
2246 not (fl `elemField` field_names_used)
2247 ]
2248 missing_ns_fields
2249 = [ flLabel fl | (fl, str) <- field_info,
2250 not (isBanged str),
2251 not (fl `elemField` field_names_used)
2252 ]
2253
2254 field_names_used = hsRecFields rbinds
2255 field_labels = conLikeFieldLabels con_like
2256
2257 field_info = zipEqual "missingFields"
2258 field_labels
2259 field_strs
2260
2261 field_strs = conLikeImplBangs con_like
2262
2263 fl `elemField` flds = any (\ fl' -> flSelector fl == fl') flds
2264
2265 {-
2266 ************************************************************************
2267 * *
2268 \subsection{Errors and contexts}
2269 * *
2270 ************************************************************************
2271
2272 Boring and alphabetical:
2273 -}
2274
2275 addExprErrCtxt :: LHsExpr Name -> TcM a -> TcM a
2276 addExprErrCtxt expr = addErrCtxt (exprCtxt expr)
2277
2278 exprCtxt :: LHsExpr Name -> SDoc
2279 exprCtxt expr
2280 = hang (text "In the expression:") 2 (ppr expr)
2281
2282 fieldCtxt :: FieldLabelString -> SDoc
2283 fieldCtxt field_name
2284 = text "In the" <+> quotes (ppr field_name) <+> ptext (sLit "field of a record")
2285
2286 addFunResCtxt :: Bool -- There is at least one argument
2287 -> HsExpr Name -> TcType -> ExpRhoType
2288 -> TcM a -> TcM a
2289 -- When we have a mis-match in the return type of a function
2290 -- try to give a helpful message about too many/few arguments
2291 --
2292 -- Used for naked variables too; but with has_args = False
2293 addFunResCtxt has_args fun fun_res_ty env_ty
2294 = addLandmarkErrCtxtM (\env -> (env, ) <$> mk_msg)
2295 -- NB: use a landmark error context, so that an empty context
2296 -- doesn't suppress some more useful context
2297 where
2298 mk_msg
2299 = do { mb_env_ty <- readExpType_maybe env_ty
2300 -- by the time the message is rendered, the ExpType
2301 -- will be filled in (except if we're debugging)
2302 ; fun_res' <- zonkTcType fun_res_ty
2303 ; env' <- case mb_env_ty of
2304 Just env_ty -> zonkTcType env_ty
2305 Nothing ->
2306 do { dumping <- doptM Opt_D_dump_tc_trace
2307 ; MASSERT( dumping )
2308 ; newFlexiTyVarTy liftedTypeKind }
2309 ; let (_, _, fun_tau) = tcSplitSigmaTy fun_res'
2310 (_, _, env_tau) = tcSplitSigmaTy env'
2311 (args_fun, res_fun) = tcSplitFunTys fun_tau
2312 (args_env, res_env) = tcSplitFunTys env_tau
2313 n_fun = length args_fun
2314 n_env = length args_env
2315 info | n_fun == n_env = Outputable.empty
2316 | n_fun > n_env
2317 , not_fun res_env
2318 = text "Probable cause:" <+> quotes (ppr fun)
2319 <+> text "is applied to too few arguments"
2320
2321 | has_args
2322 , not_fun res_fun
2323 = text "Possible cause:" <+> quotes (ppr fun)
2324 <+> text "is applied to too many arguments"
2325
2326 | otherwise
2327 = Outputable.empty -- Never suggest that a naked variable is -- applied to too many args!
2328 ; return info }
2329 where
2330 not_fun ty -- ty is definitely not an arrow type,
2331 -- and cannot conceivably become one
2332 = case tcSplitTyConApp_maybe ty of
2333 Just (tc, _) -> isAlgTyCon tc
2334 Nothing -> False
2335
2336 badFieldTypes :: [(FieldLabelString,TcType)] -> SDoc
2337 badFieldTypes prs
2338 = hang (text "Record update for insufficiently polymorphic field"
2339 <> plural prs <> colon)
2340 2 (vcat [ ppr f <+> dcolon <+> ppr ty | (f,ty) <- prs ])
2341
2342 badFieldsUpd
2343 :: [LHsRecField' (AmbiguousFieldOcc Id) (LHsExpr Name)] -- Field names that don't belong to a single datacon
2344 -> [ConLike] -- Data cons of the type which the first field name belongs to
2345 -> SDoc
2346 badFieldsUpd rbinds data_cons
2347 = hang (text "No constructor has all these fields:")
2348 2 (pprQuotedList conflictingFields)
2349 -- See Note [Finding the conflicting fields]
2350 where
2351 -- A (preferably small) set of fields such that no constructor contains
2352 -- all of them. See Note [Finding the conflicting fields]
2353 conflictingFields = case nonMembers of
2354 -- nonMember belongs to a different type.
2355 (nonMember, _) : _ -> [aMember, nonMember]
2356 [] -> let
2357 -- All of rbinds belong to one type. In this case, repeatedly add
2358 -- a field to the set until no constructor contains the set.
2359
2360 -- Each field, together with a list indicating which constructors
2361 -- have all the fields so far.
2362 growingSets :: [(FieldLabelString, [Bool])]
2363 growingSets = scanl1 combine membership
2364 combine (_, setMem) (field, fldMem)
2365 = (field, zipWith (&&) setMem fldMem)
2366 in
2367 -- Fields that don't change the membership status of the set
2368 -- are redundant and can be dropped.
2369 map (fst . head) $ groupBy ((==) `on` snd) growingSets
2370
2371 aMember = ASSERT( not (null members) ) fst (head members)
2372 (members, nonMembers) = partition (or . snd) membership
2373
2374 -- For each field, which constructors contain the field?
2375 membership :: [(FieldLabelString, [Bool])]
2376 membership = sortMembership $
2377 map (\fld -> (fld, map (Set.member fld) fieldLabelSets)) $
2378 map (occNameFS . rdrNameOcc . rdrNameAmbiguousFieldOcc . unLoc . hsRecFieldLbl . unLoc) rbinds
2379
2380 fieldLabelSets :: [Set.Set FieldLabelString]
2381 fieldLabelSets = map (Set.fromList . map flLabel . conLikeFieldLabels) data_cons
2382
2383 -- Sort in order of increasing number of True, so that a smaller
2384 -- conflicting set can be found.
2385 sortMembership =
2386 map snd .
2387 sortBy (compare `on` fst) .
2388 map (\ item@(_, membershipRow) -> (countTrue membershipRow, item))
2389
2390 countTrue = length . filter id
2391
2392 {-
2393 Note [Finding the conflicting fields]
2394 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2395 Suppose we have
2396 data A = A {a0, a1 :: Int}
2397 | B {b0, b1 :: Int}
2398 and we see a record update
2399 x { a0 = 3, a1 = 2, b0 = 4, b1 = 5 }
2400 Then we'd like to find the smallest subset of fields that no
2401 constructor has all of. Here, say, {a0,b0}, or {a0,b1}, etc.
2402 We don't really want to report that no constructor has all of
2403 {a0,a1,b0,b1}, because when there are hundreds of fields it's
2404 hard to see what was really wrong.
2405
2406 We may need more than two fields, though; eg
2407 data T = A { x,y :: Int, v::Int }
2408 | B { y,z :: Int, v::Int }
2409 | C { z,x :: Int, v::Int }
2410 with update
2411 r { x=e1, y=e2, z=e3 }, we
2412
2413 Finding the smallest subset is hard, so the code here makes
2414 a decent stab, no more. See Trac #7989.
2415 -}
2416
2417 naughtyRecordSel :: RdrName -> SDoc
2418 naughtyRecordSel sel_id
2419 = text "Cannot use record selector" <+> quotes (ppr sel_id) <+>
2420 text "as a function due to escaped type variables" $$
2421 text "Probable fix: use pattern-matching syntax instead"
2422
2423 notSelector :: Name -> SDoc
2424 notSelector field
2425 = hsep [quotes (ppr field), text "is not a record selector"]
2426
2427 mixedSelectors :: [Id] -> [Id] -> SDoc
2428 mixedSelectors data_sels@(dc_rep_id:_) pat_syn_sels@(ps_rep_id:_)
2429 = ptext
2430 (sLit "Cannot use a mixture of pattern synonym and record selectors") $$
2431 text "Record selectors defined by"
2432 <+> quotes (ppr (tyConName rep_dc))
2433 <> text ":"
2434 <+> pprWithCommas ppr data_sels $$
2435 text "Pattern synonym selectors defined by"
2436 <+> quotes (ppr (patSynName rep_ps))
2437 <> text ":"
2438 <+> pprWithCommas ppr pat_syn_sels
2439 where
2440 RecSelPatSyn rep_ps = recordSelectorTyCon ps_rep_id
2441 RecSelData rep_dc = recordSelectorTyCon dc_rep_id
2442 mixedSelectors _ _ = panic "TcExpr: mixedSelectors emptylists"
2443
2444
2445 missingStrictFields :: ConLike -> [FieldLabelString] -> SDoc
2446 missingStrictFields con fields
2447 = header <> rest
2448 where
2449 rest | null fields = Outputable.empty -- Happens for non-record constructors
2450 -- with strict fields
2451 | otherwise = colon <+> pprWithCommas ppr fields
2452
2453 header = text "Constructor" <+> quotes (ppr con) <+>
2454 text "does not have the required strict field(s)"
2455
2456 missingFields :: ConLike -> [FieldLabelString] -> SDoc
2457 missingFields con fields
2458 = text "Fields of" <+> quotes (ppr con) <+> ptext (sLit "not initialised:")
2459 <+> pprWithCommas ppr fields
2460
2461 -- callCtxt fun args = text "In the call" <+> parens (ppr (foldl mkHsApp fun args))
2462
2463 noPossibleParents :: [LHsRecUpdField Name] -> SDoc
2464 noPossibleParents rbinds
2465 = hang (text "No type has all these fields:")
2466 2 (pprQuotedList fields)
2467 where
2468 fields = map (hsRecFieldLbl . unLoc) rbinds
2469
2470 badOverloadedUpdate :: SDoc
2471 badOverloadedUpdate = text "Record update is ambiguous, and requires a type signature"
2472
2473 fieldNotInType :: RecSelParent -> RdrName -> SDoc
2474 fieldNotInType p rdr
2475 = unknownSubordinateErr (text "field of type" <+> quotes (ppr p)) rdr