Fix warnings
[ghc.git] / compiler / nativeGen / AsmCodeGen.lhs
1 -- -----------------------------------------------------------------------------
2 --
3 -- (c) The University of Glasgow 1993-2004
4 --
5 -- This is the top-level module in the native code generator.
6 --
7 -- -----------------------------------------------------------------------------
8
9 \begin{code}
10 {-# LANGUAGE GADTs #-}
11 module AsmCodeGen ( nativeCodeGen ) where
12
13 #include "HsVersions.h"
14 #include "nativeGen/NCG.h"
15
16
17 import qualified X86.CodeGen
18 import qualified X86.Regs
19 import qualified X86.Instr
20 import qualified X86.Ppr
21
22 import qualified SPARC.CodeGen
23 import qualified SPARC.Regs
24 import qualified SPARC.Instr
25 import qualified SPARC.Ppr
26 import qualified SPARC.ShortcutJump
27 import qualified SPARC.CodeGen.Expand
28
29 import qualified PPC.CodeGen
30 import qualified PPC.Cond
31 import qualified PPC.Regs
32 import qualified PPC.RegInfo
33 import qualified PPC.Instr
34 import qualified PPC.Ppr
35
36 import RegAlloc.Liveness
37 import qualified RegAlloc.Linear.Main           as Linear
38
39 import qualified GraphColor                     as Color
40 import qualified RegAlloc.Graph.Main            as Color
41 import qualified RegAlloc.Graph.Stats           as Color
42 import qualified RegAlloc.Graph.TrivColorable   as Color
43
44 import TargetReg
45 import Platform
46 import Config
47 import Instruction
48 import PIC
49 import Reg
50 import NCGMonad
51
52 import BlockId
53 import CgUtils          ( fixStgRegisters )
54 import Cmm
55 import CmmUtils
56 import Hoopl
57 import CmmOpt           ( cmmMachOpFold )
58 import PprCmm
59 import CLabel
60
61 import UniqFM
62 import UniqSupply
63 import DynFlags
64 import Util
65
66 import BasicTypes       ( Alignment )
67 import Digraph
68 import qualified Pretty
69 import BufWrite
70 import Outputable
71 import FastString
72 import UniqSet
73 import ErrUtils
74 import Module
75 import Stream (Stream)
76 import qualified Stream
77
78 -- DEBUGGING ONLY
79 --import OrdList
80
81 import Data.List
82 import Data.Maybe
83 import Control.Monad
84 import System.IO
85
86 {-
87 The native-code generator has machine-independent and
88 machine-dependent modules.
89
90 This module ("AsmCodeGen") is the top-level machine-independent
91 module.  Before entering machine-dependent land, we do some
92 machine-independent optimisations (defined below) on the
93 'CmmStmts's.
94
95 We convert to the machine-specific 'Instr' datatype with
96 'cmmCodeGen', assuming an infinite supply of registers.  We then use
97 a machine-independent register allocator ('regAlloc') to rejoin
98 reality.  Obviously, 'regAlloc' has machine-specific helper
99 functions (see about "RegAllocInfo" below).
100
101 Finally, we order the basic blocks of the function so as to minimise
102 the number of jumps between blocks, by utilising fallthrough wherever
103 possible.
104
105 The machine-dependent bits break down as follows:
106
107   * ["MachRegs"]  Everything about the target platform's machine
108     registers (and immediate operands, and addresses, which tend to
109     intermingle/interact with registers).
110
111   * ["MachInstrs"]  Includes the 'Instr' datatype (possibly should
112     have a module of its own), plus a miscellany of other things
113     (e.g., 'targetDoubleSize', 'smStablePtrTable', ...)
114
115   * ["MachCodeGen"]  is where 'Cmm' stuff turns into
116     machine instructions.
117
118   * ["PprMach"] 'pprInstr' turns an 'Instr' into text (well, really
119     a 'SDoc').
120
121   * ["RegAllocInfo"] In the register allocator, we manipulate
122     'MRegsState's, which are 'BitSet's, one bit per machine register.
123     When we want to say something about a specific machine register
124     (e.g., ``it gets clobbered by this instruction''), we set/unset
125     its bit.  Obviously, we do this 'BitSet' thing for efficiency
126     reasons.
127
128     The 'RegAllocInfo' module collects together the machine-specific
129     info needed to do register allocation.
130
131    * ["RegisterAlloc"] The (machine-independent) register allocator.
132 -}
133
134 -- -----------------------------------------------------------------------------
135 -- Top-level of the native codegen
136
137 data NcgImpl statics instr jumpDest = NcgImpl {
138     cmmTopCodeGen             :: RawCmmDecl -> NatM [NatCmmDecl statics instr],
139     generateJumpTableForInstr :: instr -> Maybe (NatCmmDecl statics instr),
140     getJumpDestBlockId        :: jumpDest -> Maybe BlockId,
141     canShortcut               :: instr -> Maybe jumpDest,
142     shortcutStatics           :: (BlockId -> Maybe jumpDest) -> statics -> statics,
143     shortcutJump              :: (BlockId -> Maybe jumpDest) -> instr -> instr,
144     pprNatCmmDecl             :: NatCmmDecl statics instr -> SDoc,
145     maxSpillSlots             :: Int,
146     allocatableRegs           :: [RealReg],
147     ncg_x86fp_kludge          :: [NatCmmDecl statics instr] -> [NatCmmDecl statics instr],
148     ncgExpandTop              :: [NatCmmDecl statics instr] -> [NatCmmDecl statics instr],
149     ncgAllocMoreStack         :: Int -> NatCmmDecl statics instr -> NatCmmDecl statics instr,
150     ncgMakeFarBranches        :: [NatBasicBlock instr] -> [NatBasicBlock instr]
151     }
152
153 --------------------
154 nativeCodeGen :: DynFlags -> Handle -> UniqSupply -> Stream IO RawCmmGroup () -> IO ()
155 nativeCodeGen dflags h us cmms
156  = let platform = targetPlatform dflags
157        nCG' :: (Outputable statics, Outputable instr, Instruction instr) => NcgImpl statics instr jumpDest -> IO ()
158        nCG' ncgImpl = nativeCodeGen' dflags ncgImpl h us cmms
159        x86NcgImpl = NcgImpl {
160                          cmmTopCodeGen             = X86.CodeGen.cmmTopCodeGen
161                         ,generateJumpTableForInstr = X86.CodeGen.generateJumpTableForInstr dflags
162                         ,getJumpDestBlockId        = X86.Instr.getJumpDestBlockId
163                         ,canShortcut               = X86.Instr.canShortcut
164                         ,shortcutStatics           = X86.Instr.shortcutStatics
165                         ,shortcutJump              = X86.Instr.shortcutJump
166                         ,pprNatCmmDecl              = X86.Ppr.pprNatCmmDecl
167                         ,maxSpillSlots             = X86.Instr.maxSpillSlots dflags
168                         ,allocatableRegs           = X86.Regs.allocatableRegs platform
169                         ,ncg_x86fp_kludge          = id
170                         ,ncgAllocMoreStack         = X86.Instr.allocMoreStack platform
171                         ,ncgExpandTop              = id
172                         ,ncgMakeFarBranches        = id
173                     }
174    in case platformArch platform of
175                  ArchX86    -> nCG' (x86NcgImpl { ncg_x86fp_kludge = map x86fp_kludge })
176                  ArchX86_64 -> nCG' x86NcgImpl
177                  ArchPPC ->
178                      nCG' $ NcgImpl {
179                           cmmTopCodeGen             = PPC.CodeGen.cmmTopCodeGen
180                          ,generateJumpTableForInstr = PPC.CodeGen.generateJumpTableForInstr dflags
181                          ,getJumpDestBlockId        = PPC.RegInfo.getJumpDestBlockId
182                          ,canShortcut               = PPC.RegInfo.canShortcut
183                          ,shortcutStatics           = PPC.RegInfo.shortcutStatics
184                          ,shortcutJump              = PPC.RegInfo.shortcutJump
185                          ,pprNatCmmDecl              = PPC.Ppr.pprNatCmmDecl
186                          ,maxSpillSlots             = PPC.Instr.maxSpillSlots dflags
187                          ,allocatableRegs           = PPC.Regs.allocatableRegs platform
188                          ,ncg_x86fp_kludge          = id
189                          ,ncgAllocMoreStack         = noAllocMoreStack
190                          ,ncgExpandTop              = id
191                          ,ncgMakeFarBranches        = makeFarBranches
192                      }
193                  ArchSPARC ->
194                      nCG' $ NcgImpl {
195                           cmmTopCodeGen             = SPARC.CodeGen.cmmTopCodeGen
196                          ,generateJumpTableForInstr = SPARC.CodeGen.generateJumpTableForInstr dflags
197                          ,getJumpDestBlockId        = SPARC.ShortcutJump.getJumpDestBlockId
198                          ,canShortcut               = SPARC.ShortcutJump.canShortcut
199                          ,shortcutStatics           = SPARC.ShortcutJump.shortcutStatics
200                          ,shortcutJump              = SPARC.ShortcutJump.shortcutJump
201                          ,pprNatCmmDecl              = SPARC.Ppr.pprNatCmmDecl
202                          ,maxSpillSlots             = SPARC.Instr.maxSpillSlots dflags
203                          ,allocatableRegs           = SPARC.Regs.allocatableRegs
204                          ,ncg_x86fp_kludge          = id
205                          ,ncgAllocMoreStack         = noAllocMoreStack
206                          ,ncgExpandTop              = map SPARC.CodeGen.Expand.expandTop
207                          ,ncgMakeFarBranches        = id
208                      }
209                  ArchARM _ _ _ ->
210                      panic "nativeCodeGen: No NCG for ARM"
211                  ArchPPC_64 ->
212                      panic "nativeCodeGen: No NCG for PPC 64"
213                  ArchUnknown ->
214                      panic "nativeCodeGen: No NCG for unknown arch"
215
216
217 --
218 -- Allocating more stack space for spilling is currently only
219 -- supported for the linear register allocator on x86/x86_64, the rest
220 -- default to the panic below.  To support allocating extra stack on
221 -- more platforms provide a definition of ncgAllocMoreStack.
222 --
223 noAllocMoreStack :: Int -> NatCmmDecl statics instr -> NatCmmDecl statics instr
224 noAllocMoreStack amount _
225   = panic $   "Register allocator: out of stack slots (need " ++ show amount ++ ")\n"
226         ++  "   If you are trying to compile SHA1.hs from the crypto library then this\n"
227         ++  "   is a known limitation in the linear allocator.\n"
228         ++  "\n"
229         ++  "   Try enabling the graph colouring allocator with -fregs-graph instead."
230         ++  "   You can still file a bug report if you like.\n"
231
232
233 nativeCodeGen' :: (Outputable statics, Outputable instr, Instruction instr)
234                => DynFlags
235                -> NcgImpl statics instr jumpDest
236                -> Handle -> UniqSupply -> Stream IO RawCmmGroup () -> IO ()
237 nativeCodeGen' dflags ncgImpl h us cmms
238  = do
239         let platform = targetPlatform dflags
240             split_cmms  = Stream.map add_split cmms
241         -- BufHandle is a performance hack.  We could hide it inside
242         -- Pretty if it weren't for the fact that we do lots of little
243         -- printDocs here (in order to do codegen in constant space).
244         bufh <- newBufHandle h
245         (imports, prof) <- cmmNativeGenStream dflags ncgImpl bufh us split_cmms [] [] 0
246         bFlush bufh
247
248         let (native, colorStats, linearStats)
249                 = unzip3 prof
250
251         -- dump native code
252         dumpIfSet_dyn dflags
253                 Opt_D_dump_asm "Asm code"
254                 (vcat $ map (pprNatCmmDecl ncgImpl) $ concat native)
255
256         -- dump global NCG stats for graph coloring allocator
257         (case concat $ catMaybes colorStats of
258           []    -> return ()
259           stats -> do
260                 -- build the global register conflict graph
261                 let graphGlobal
262                         = foldl Color.union Color.initGraph
263                         $ [ Color.raGraph stat
264                                 | stat@Color.RegAllocStatsStart{} <- stats]
265
266                 dumpSDoc dflags Opt_D_dump_asm_stats "NCG stats"
267                         $ Color.pprStats stats graphGlobal
268
269                 dumpIfSet_dyn dflags
270                         Opt_D_dump_asm_conflicts "Register conflict graph"
271                         $ Color.dotGraph
272                                 (targetRegDotColor platform)
273                                 (Color.trivColorable platform
274                                         (targetVirtualRegSqueeze platform)
275                                         (targetRealRegSqueeze platform))
276                         $ graphGlobal)
277
278
279         -- dump global NCG stats for linear allocator
280         (case concat $ catMaybes linearStats of
281                 []      -> return ()
282                 stats   -> dumpSDoc dflags Opt_D_dump_asm_stats "NCG stats"
283                                 $ Linear.pprStats (concat native) stats)
284
285         -- write out the imports
286         Pretty.printDoc Pretty.LeftMode (pprCols dflags) h
287                 $ withPprStyleDoc dflags (mkCodeStyle AsmStyle)
288                 $ makeImportsDoc dflags (concat imports)
289
290         return  ()
291
292  where  add_split tops
293                 | gopt Opt_SplitObjs dflags = split_marker : tops
294                 | otherwise                 = tops
295
296         split_marker = CmmProc mapEmpty mkSplitMarkerLabel []
297                                (ofBlockList (panic "split_marker_entry") [])
298
299 cmmNativeGenStream :: (Outputable statics, Outputable instr, Instruction instr)
300               => DynFlags
301               -> NcgImpl statics instr jumpDest
302               -> BufHandle
303               -> UniqSupply
304               -> Stream IO RawCmmGroup ()
305               -> [[CLabel]]
306               -> [ ([NatCmmDecl statics instr],
307                    Maybe [Color.RegAllocStats statics instr],
308                    Maybe [Linear.RegAllocStats]) ]
309               -> Int
310               -> IO ( [[CLabel]],
311                       [([NatCmmDecl statics instr],
312                       Maybe [Color.RegAllocStats statics instr],
313                       Maybe [Linear.RegAllocStats])] )
314
315 cmmNativeGenStream dflags ncgImpl h us cmm_stream impAcc profAcc count
316  = do
317         r <- Stream.runStream cmm_stream
318         case r of
319           Left () -> return (reverse impAcc, reverse profAcc)
320           Right (cmms, cmm_stream') -> do
321             (impAcc,profAcc,us') <- cmmNativeGens dflags ncgImpl h us cmms
322                                               impAcc profAcc count
323             cmmNativeGenStream dflags ncgImpl h us' cmm_stream'
324                                               impAcc profAcc count
325
326
327 -- | Do native code generation on all these cmms.
328 --
329 cmmNativeGens :: (Outputable statics, Outputable instr, Instruction instr)
330               => DynFlags
331               -> NcgImpl statics instr jumpDest
332               -> BufHandle
333               -> UniqSupply
334               -> [RawCmmDecl]
335               -> [[CLabel]]
336               -> [ ([NatCmmDecl statics instr],
337                    Maybe [Color.RegAllocStats statics instr],
338                    Maybe [Linear.RegAllocStats]) ]
339               -> Int
340               -> IO ( [[CLabel]],
341                       [([NatCmmDecl statics instr],
342                        Maybe [Color.RegAllocStats statics instr],
343                        Maybe [Linear.RegAllocStats])],
344                       UniqSupply )
345
346 cmmNativeGens _ _ _ us [] impAcc profAcc _
347         = return (impAcc,profAcc,us)
348
349 cmmNativeGens dflags ncgImpl h us (cmm : cmms) impAcc profAcc count
350  = do
351         (us', native, imports, colorStats, linearStats)
352                 <- {-# SCC "cmmNativeGen" #-} cmmNativeGen dflags ncgImpl us cmm count
353
354         {-# SCC "pprNativeCode" #-} Pretty.bufLeftRender h
355                 $ withPprStyleDoc dflags (mkCodeStyle AsmStyle)
356                 $ vcat $ map (pprNatCmmDecl ncgImpl) native
357
358            -- carefully evaluate this strictly.  Binding it with 'let'
359            -- and then using 'seq' doesn't work, because the let
360            -- apparently gets inlined first.
361         lsPprNative <- return $!
362                 if  dopt Opt_D_dump_asm       dflags
363                  || dopt Opt_D_dump_asm_stats dflags
364                         then native
365                         else []
366
367         count' <- return $! count + 1;
368
369         -- force evaulation all this stuff to avoid space leaks
370         {-# SCC "seqString" #-} seqString (showSDoc dflags $ vcat $ map ppr imports) `seq` return ()
371
372         cmmNativeGens dflags ncgImpl
373             h us' cmms
374                         (imports : impAcc)
375                         ((lsPprNative, colorStats, linearStats) : profAcc)
376                         count'
377
378  where  seqString []            = ()
379         seqString (x:xs)        = x `seq` seqString xs `seq` ()
380
381
382 -- | Complete native code generation phase for a single top-level chunk of Cmm.
383 --      Dumping the output of each stage along the way.
384 --      Global conflict graph and NGC stats
385 cmmNativeGen
386         :: (Outputable statics, Outputable instr, Instruction instr)
387     => DynFlags
388     -> NcgImpl statics instr jumpDest
389         -> UniqSupply
390         -> RawCmmDecl                                   -- ^ the cmm to generate code for
391         -> Int                                          -- ^ sequence number of this top thing
392         -> IO   ( UniqSupply
393                 , [NatCmmDecl statics instr]                -- native code
394                 , [CLabel]                                  -- things imported by this cmm
395                 , Maybe [Color.RegAllocStats statics instr] -- stats for the coloring register allocator
396                 , Maybe [Linear.RegAllocStats])             -- stats for the linear register allocators
397
398 cmmNativeGen dflags ncgImpl us cmm count
399  = do
400         let platform = targetPlatform dflags
401
402         -- rewrite assignments to global regs
403         let fixed_cmm =
404                 {-# SCC "fixStgRegisters" #-}
405                 fixStgRegisters dflags cmm
406
407         -- cmm to cmm optimisations
408         let (opt_cmm, imports) =
409                 {-# SCC "cmmToCmm" #-}
410                 cmmToCmm dflags fixed_cmm
411
412         dumpIfSet_dyn dflags
413                 Opt_D_dump_opt_cmm "Optimised Cmm"
414                 (pprCmmGroup [opt_cmm])
415
416         -- generate native code from cmm
417         let ((native, lastMinuteImports), usGen) =
418                 {-# SCC "genMachCode" #-}
419                 initUs us $ genMachCode dflags (cmmTopCodeGen ncgImpl) opt_cmm
420
421         dumpIfSet_dyn dflags
422                 Opt_D_dump_asm_native "Native code"
423                 (vcat $ map (pprNatCmmDecl ncgImpl) native)
424
425         -- tag instructions with register liveness information
426         let (withLiveness, usLive) =
427                 {-# SCC "regLiveness" #-}
428                 initUs usGen
429                         $ mapM (regLiveness platform)
430                         $ map natCmmTopToLive native
431
432         dumpIfSet_dyn dflags
433                 Opt_D_dump_asm_liveness "Liveness annotations added"
434                 (vcat $ map ppr withLiveness)
435
436         -- allocate registers
437         (alloced, usAlloc, ppr_raStatsColor, ppr_raStatsLinear) <-
438          if ( gopt Opt_RegsGraph dflags
439            || gopt Opt_RegsIterative dflags)
440           then do
441                 -- the regs usable for allocation
442                 let (alloc_regs :: UniqFM (UniqSet RealReg))
443                         = foldr (\r -> plusUFM_C unionUniqSets
444                                         $ unitUFM (targetClassOfRealReg platform r) (unitUniqSet r))
445                                 emptyUFM
446                         $ allocatableRegs ncgImpl
447
448                 -- do the graph coloring register allocation
449                 let ((alloced, regAllocStats), usAlloc)
450                         = {-# SCC "RegAlloc" #-}
451                           initUs usLive
452                           $ Color.regAlloc
453                                 dflags
454                                 alloc_regs
455                                 (mkUniqSet [0 .. maxSpillSlots ncgImpl])
456                                 withLiveness
457
458                 -- dump out what happened during register allocation
459                 dumpIfSet_dyn dflags
460                         Opt_D_dump_asm_regalloc "Registers allocated"
461                         (vcat $ map (pprNatCmmDecl ncgImpl) alloced)
462
463                 dumpIfSet_dyn dflags
464                         Opt_D_dump_asm_regalloc_stages "Build/spill stages"
465                         (vcat   $ map (\(stage, stats)
466                                         -> text "# --------------------------"
467                                         $$ text "#  cmm " <> int count <> text " Stage " <> int stage
468                                         $$ ppr stats)
469                                 $ zip [0..] regAllocStats)
470
471                 let mPprStats =
472                         if dopt Opt_D_dump_asm_stats dflags
473                          then Just regAllocStats else Nothing
474
475                 -- force evaluation of the Maybe to avoid space leak
476                 mPprStats `seq` return ()
477
478                 return  ( alloced, usAlloc
479                         , mPprStats
480                         , Nothing)
481
482           else do
483                 -- do linear register allocation
484                 let reg_alloc proc = do
485                        (alloced, maybe_more_stack, ra_stats) <-
486                                Linear.regAlloc dflags proc
487                        case maybe_more_stack of
488                          Nothing -> return ( alloced, ra_stats )
489                          Just amount ->
490                            return ( ncgAllocMoreStack ncgImpl amount alloced
491                                   , ra_stats )
492
493                 let ((alloced, regAllocStats), usAlloc)
494                         = {-# SCC "RegAlloc" #-}
495                           initUs usLive
496                           $ liftM unzip
497                           $ mapM reg_alloc withLiveness
498
499                 dumpIfSet_dyn dflags
500                         Opt_D_dump_asm_regalloc "Registers allocated"
501                         (vcat $ map (pprNatCmmDecl ncgImpl) alloced)
502
503                 let mPprStats =
504                         if dopt Opt_D_dump_asm_stats dflags
505                          then Just (catMaybes regAllocStats) else Nothing
506
507                 -- force evaluation of the Maybe to avoid space leak
508                 mPprStats `seq` return ()
509
510                 return  ( alloced, usAlloc
511                         , Nothing
512                         , mPprStats)
513
514         ---- x86fp_kludge.  This pass inserts ffree instructions to clear
515         ---- the FPU stack on x86.  The x86 ABI requires that the FPU stack
516         ---- is clear, and library functions can return odd results if it
517         ---- isn't.
518         ----
519         ---- NB. must happen before shortcutBranches, because that
520         ---- generates JXX_GBLs which we can't fix up in x86fp_kludge.
521         let kludged = {-# SCC "x86fp_kludge" #-} ncg_x86fp_kludge ncgImpl alloced
522
523         ---- generate jump tables
524         let tabled      =
525                 {-# SCC "generateJumpTables" #-}
526                 generateJumpTables ncgImpl kludged
527
528         ---- shortcut branches
529         let shorted     =
530                 {-# SCC "shortcutBranches" #-}
531                 shortcutBranches dflags ncgImpl tabled
532
533         ---- sequence blocks
534         let sequenced   =
535                 {-# SCC "sequenceBlocks" #-}
536                 map (sequenceTop ncgImpl) shorted
537
538         ---- expansion of SPARC synthetic instrs
539         let expanded =
540                 {-# SCC "sparc_expand" #-}
541                 ncgExpandTop ncgImpl sequenced
542
543         dumpIfSet_dyn dflags
544                 Opt_D_dump_asm_expanded "Synthetic instructions expanded"
545                 (vcat $ map (pprNatCmmDecl ncgImpl) expanded)
546
547         return  ( usAlloc
548                 , expanded
549                 , lastMinuteImports ++ imports
550                 , ppr_raStatsColor
551                 , ppr_raStatsLinear)
552
553
554 x86fp_kludge :: NatCmmDecl (Alignment, CmmStatics) X86.Instr.Instr -> NatCmmDecl (Alignment, CmmStatics) X86.Instr.Instr
555 x86fp_kludge top@(CmmData _ _) = top
556 x86fp_kludge (CmmProc info lbl live (ListGraph code)) =
557         CmmProc info lbl live (ListGraph $ X86.Instr.i386_insert_ffrees code)
558
559
560 -- | Build a doc for all the imports.
561 --
562 makeImportsDoc :: DynFlags -> [CLabel] -> SDoc
563 makeImportsDoc dflags imports
564  = dyld_stubs imports
565             $$
566             -- On recent versions of Darwin, the linker supports
567             -- dead-stripping of code and data on a per-symbol basis.
568             -- There's a hack to make this work in PprMach.pprNatCmmDecl.
569             (if platformHasSubsectionsViaSymbols (targetPlatform dflags)
570              then text ".subsections_via_symbols"
571              else empty)
572             $$
573                 -- On recent GNU ELF systems one can mark an object file
574                 -- as not requiring an executable stack. If all objects
575                 -- linked into a program have this note then the program
576                 -- will not use an executable stack, which is good for
577                 -- security. GHC generated code does not need an executable
578                 -- stack so add the note in:
579             (if platformHasGnuNonexecStack (targetPlatform dflags)
580              then text ".section .note.GNU-stack,\"\",@progbits"
581              else empty)
582             $$
583                 -- And just because every other compiler does, lets stick in
584                 -- an identifier directive: .ident "GHC x.y.z"
585             (if platformHasIdentDirective (targetPlatform dflags)
586              then let compilerIdent = text "GHC" <+> text cProjectVersion
587                    in text ".ident" <+> doubleQuotes compilerIdent
588              else empty)
589
590  where
591         -- Generate "symbol stubs" for all external symbols that might
592         -- come from a dynamic library.
593         dyld_stubs :: [CLabel] -> SDoc
594 {-      dyld_stubs imps = vcat $ map pprDyldSymbolStub $
595                                     map head $ group $ sort imps-}
596
597         platform = targetPlatform dflags
598         arch = platformArch platform
599         os   = platformOS   platform
600
601         -- (Hack) sometimes two Labels pretty-print the same, but have
602         -- different uniques; so we compare their text versions...
603         dyld_stubs imps
604                 | needImportedSymbols dflags arch os
605                 = vcat $
606                         (pprGotDeclaration dflags arch os :) $
607                         map ( pprImportedSymbol dflags platform . fst . head) $
608                         groupBy (\(_,a) (_,b) -> a == b) $
609                         sortBy (\(_,a) (_,b) -> compare a b) $
610                         map doPpr $
611                         imps
612                 | otherwise
613                 = empty
614
615         doPpr lbl = (lbl, renderWithStyle dflags (pprCLabel platform lbl) astyle)
616         astyle = mkCodeStyle AsmStyle
617
618
619 -- -----------------------------------------------------------------------------
620 -- Sequencing the basic blocks
621
622 -- Cmm BasicBlocks are self-contained entities: they always end in a
623 -- jump, either non-local or to another basic block in the same proc.
624 -- In this phase, we attempt to place the basic blocks in a sequence
625 -- such that as many of the local jumps as possible turn into
626 -- fallthroughs.
627
628 sequenceTop
629         :: Instruction instr
630     => NcgImpl statics instr jumpDest -> NatCmmDecl statics instr -> NatCmmDecl statics instr
631
632 sequenceTop _       top@(CmmData _ _) = top
633 sequenceTop ncgImpl (CmmProc info lbl live (ListGraph blocks)) =
634   CmmProc info lbl live (ListGraph $ ncgMakeFarBranches ncgImpl $ sequenceBlocks info blocks)
635
636 -- The algorithm is very simple (and stupid): we make a graph out of
637 -- the blocks where there is an edge from one block to another iff the
638 -- first block ends by jumping to the second.  Then we topologically
639 -- sort this graph.  Then traverse the list: for each block, we first
640 -- output the block, then if it has an out edge, we move the
641 -- destination of the out edge to the front of the list, and continue.
642
643 -- FYI, the classic layout for basic blocks uses postorder DFS; this
644 -- algorithm is implemented in Hoopl.
645
646 sequenceBlocks
647         :: Instruction instr
648         => BlockEnv i
649         -> [NatBasicBlock instr]
650         -> [NatBasicBlock instr]
651
652 sequenceBlocks _ [] = []
653 sequenceBlocks infos (entry:blocks) =
654   seqBlocks infos (mkNode entry : reverse (flattenSCCs (sccBlocks blocks)))
655   -- the first block is the entry point ==> it must remain at the start.
656
657
658 sccBlocks
659         :: Instruction instr
660         => [NatBasicBlock instr]
661         -> [SCC ( NatBasicBlock instr
662                 , BlockId
663                 , [BlockId])]
664
665 sccBlocks blocks = stronglyConnCompFromEdgedVerticesR (map mkNode blocks)
666
667 -- we're only interested in the last instruction of
668 -- the block, and only if it has a single destination.
669 getOutEdges
670         :: Instruction instr
671         => [instr] -> [BlockId]
672
673 getOutEdges instrs
674         = case jumpDestsOfInstr (last instrs) of
675                 [one] -> [one]
676                 _many -> []
677
678 mkNode :: (Instruction t)
679        => GenBasicBlock t
680        -> (GenBasicBlock t, BlockId, [BlockId])
681 mkNode block@(BasicBlock id instrs) = (block, id, getOutEdges instrs)
682
683 seqBlocks :: BlockEnv i -> [(GenBasicBlock t1, BlockId, [BlockId])]
684                         -> [GenBasicBlock t1]
685 seqBlocks _ [] = []
686 seqBlocks infos ((block,_,[]) : rest)
687   = block : seqBlocks infos rest
688 seqBlocks infos ((block@(BasicBlock id instrs),_,[next]) : rest)
689   | can_fallthrough = BasicBlock id (init instrs) : seqBlocks infos rest'
690   | otherwise       = block : seqBlocks infos rest'
691   where
692         can_fallthrough = not (mapMember next infos) && can_reorder
693         (can_reorder, rest') = reorder next [] rest
694           -- TODO: we should do a better job for cycles; try to maximise the
695           -- fallthroughs within a loop.
696 seqBlocks _ _ = panic "AsmCodegen:seqBlocks"
697
698 reorder :: (Eq a) => a -> [(t, a, t1)] -> [(t, a, t1)] -> (Bool, [(t, a, t1)])
699 reorder  _ accum [] = (False, reverse accum)
700 reorder id accum (b@(block,id',out) : rest)
701   | id == id'  = (True, (block,id,out) : reverse accum ++ rest)
702   | otherwise  = reorder id (b:accum) rest
703
704
705 -- -----------------------------------------------------------------------------
706 -- Making far branches
707
708 -- Conditional branches on PowerPC are limited to +-32KB; if our Procs get too
709 -- big, we have to work around this limitation.
710
711 makeFarBranches
712         :: [NatBasicBlock PPC.Instr.Instr]
713         -> [NatBasicBlock PPC.Instr.Instr]
714 makeFarBranches blocks
715     | last blockAddresses < nearLimit = blocks
716     | otherwise = zipWith handleBlock blockAddresses blocks
717     where
718         blockAddresses = scanl (+) 0 $ map blockLen blocks
719         blockLen (BasicBlock _ instrs) = length instrs
720
721         handleBlock addr (BasicBlock id instrs)
722                 = BasicBlock id (zipWith makeFar [addr..] instrs)
723
724         makeFar _ (PPC.Instr.BCC PPC.Cond.ALWAYS tgt) = PPC.Instr.BCC PPC.Cond.ALWAYS tgt
725         makeFar addr (PPC.Instr.BCC cond tgt)
726             | abs (addr - targetAddr) >= nearLimit
727             = PPC.Instr.BCCFAR cond tgt
728             | otherwise
729             = PPC.Instr.BCC cond tgt
730             where Just targetAddr = lookupUFM blockAddressMap tgt
731         makeFar _ other            = other
732
733         nearLimit = 7000 -- 8192 instructions are allowed; let's keep some
734                          -- distance, as we have a few pseudo-insns that are
735                          -- pretty-printed as multiple instructions,
736                          -- and it's just not worth the effort to calculate
737                          -- things exactly
738
739         blockAddressMap = listToUFM $ zip (map blockId blocks) blockAddresses
740
741 -- -----------------------------------------------------------------------------
742 -- Generate jump tables
743
744 -- Analyzes all native code and generates data sections for all jump
745 -- table instructions.
746 generateJumpTables
747         :: NcgImpl statics instr jumpDest
748         -> [NatCmmDecl statics instr] -> [NatCmmDecl statics instr]
749 generateJumpTables ncgImpl xs = concatMap f xs
750     where f p@(CmmProc _ _ _ (ListGraph xs)) = p : concatMap g xs
751           f p = [p]
752           g (BasicBlock _ xs) = catMaybes (map (generateJumpTableForInstr ncgImpl) xs)
753
754 -- -----------------------------------------------------------------------------
755 -- Shortcut branches
756
757 shortcutBranches
758         :: DynFlags
759     -> NcgImpl statics instr jumpDest
760         -> [NatCmmDecl statics instr]
761         -> [NatCmmDecl statics instr]
762
763 shortcutBranches dflags ncgImpl tops
764   | optLevel dflags < 1 = tops    -- only with -O or higher
765   | otherwise           = map (apply_mapping ncgImpl mapping) tops'
766   where
767     (tops', mappings) = mapAndUnzip (build_mapping ncgImpl) tops
768     mapping = foldr plusUFM emptyUFM mappings
769
770 build_mapping :: NcgImpl statics instr jumpDest
771               -> GenCmmDecl d (BlockEnv t) (ListGraph instr)
772               -> (GenCmmDecl d (BlockEnv t) (ListGraph instr), UniqFM jumpDest)
773 build_mapping _ top@(CmmData _ _) = (top, emptyUFM)
774 build_mapping _ (CmmProc info lbl live (ListGraph []))
775   = (CmmProc info lbl live (ListGraph []), emptyUFM)
776 build_mapping ncgImpl (CmmProc info lbl live (ListGraph (head:blocks)))
777   = (CmmProc info lbl live (ListGraph (head:others)), mapping)
778         -- drop the shorted blocks, but don't ever drop the first one,
779         -- because it is pointed to by a global label.
780   where
781     -- find all the blocks that just consist of a jump that can be
782     -- shorted.
783     -- Don't completely eliminate loops here -- that can leave a dangling jump!
784     (_, shortcut_blocks, others) = foldl split (emptyBlockSet, [], []) blocks
785     split (s, shortcut_blocks, others) b@(BasicBlock id [insn])
786         | Just jd <- canShortcut ncgImpl insn,
787           Just dest <- getJumpDestBlockId ncgImpl jd,
788           not (has_info id),
789           (setMember dest s) || dest == id -- loop checks
790         = (s, shortcut_blocks, b : others)
791     split (s, shortcut_blocks, others) (BasicBlock id [insn])
792         | Just dest <- canShortcut ncgImpl insn,
793           not (has_info id)
794         = (setInsert id s, (id,dest) : shortcut_blocks, others)
795     split (s, shortcut_blocks, others) other = (s, shortcut_blocks, other : others)
796
797     -- do not eliminate blocks that have an info table
798     has_info l = mapMember l info
799
800     -- build a mapping from BlockId to JumpDest for shorting branches
801     mapping = foldl add emptyUFM shortcut_blocks
802     add ufm (id,dest) = addToUFM ufm id dest
803
804 apply_mapping :: NcgImpl statics instr jumpDest
805               -> UniqFM jumpDest
806               -> GenCmmDecl statics h (ListGraph instr)
807               -> GenCmmDecl statics h (ListGraph instr)
808 apply_mapping ncgImpl ufm (CmmData sec statics)
809   = CmmData sec (shortcutStatics ncgImpl (lookupUFM ufm) statics)
810 apply_mapping ncgImpl ufm (CmmProc info lbl live (ListGraph blocks))
811   = CmmProc info lbl live (ListGraph $ map short_bb blocks)
812   where
813     short_bb (BasicBlock id insns) = BasicBlock id $! map short_insn insns
814     short_insn i = shortcutJump ncgImpl (lookupUFM ufm) i
815                  -- shortcutJump should apply the mapping repeatedly,
816                  -- just in case we can short multiple branches.
817
818 -- -----------------------------------------------------------------------------
819 -- Instruction selection
820
821 -- Native code instruction selection for a chunk of stix code.  For
822 -- this part of the computation, we switch from the UniqSM monad to
823 -- the NatM monad.  The latter carries not only a Unique, but also an
824 -- Int denoting the current C stack pointer offset in the generated
825 -- code; this is needed for creating correct spill offsets on
826 -- architectures which don't offer, or for which it would be
827 -- prohibitively expensive to employ, a frame pointer register.  Viz,
828 -- x86.
829
830 -- The offset is measured in bytes, and indicates the difference
831 -- between the current (simulated) C stack-ptr and the value it was at
832 -- the beginning of the block.  For stacks which grow down, this value
833 -- should be either zero or negative.
834
835 -- Switching between the two monads whilst carrying along the same
836 -- Unique supply breaks abstraction.  Is that bad?
837
838 genMachCode
839         :: DynFlags
840         -> (RawCmmDecl -> NatM [NatCmmDecl statics instr])
841         -> RawCmmDecl
842         -> UniqSM
843                 ( [NatCmmDecl statics instr]
844                 , [CLabel])
845
846 genMachCode dflags cmmTopCodeGen cmm_top
847   = do  { initial_us <- getUs
848         ; let initial_st           = mkNatM_State initial_us 0 dflags
849               (new_tops, final_st) = initNat initial_st (cmmTopCodeGen cmm_top)
850               final_delta          = natm_delta final_st
851               final_imports        = natm_imports final_st
852         ; if   final_delta == 0
853           then return (new_tops, final_imports)
854           else pprPanic "genMachCode: nonzero final delta" (int final_delta)
855     }
856
857 -- -----------------------------------------------------------------------------
858 -- Generic Cmm optimiser
859
860 {-
861 Here we do:
862
863   (a) Constant folding
864   (c) Position independent code and dynamic linking
865         (i)  introduce the appropriate indirections
866              and position independent refs
867         (ii) compile a list of imported symbols
868   (d) Some arch-specific optimizations
869
870 (a) will be moving to the new Hoopl pipeline, however, (c) and
871 (d) are only needed by the native backend and will continue to live
872 here.
873
874 Ideas for other things we could do (put these in Hoopl please!):
875
876   - shortcut jumps-to-jumps
877   - simple CSE: if an expr is assigned to a temp, then replace later occs of
878     that expr with the temp, until the expr is no longer valid (can push through
879     temp assignments, and certain assigns to mem...)
880 -}
881
882 cmmToCmm :: DynFlags -> RawCmmDecl -> (RawCmmDecl, [CLabel])
883 cmmToCmm _ top@(CmmData _ _) = (top, [])
884 cmmToCmm dflags (CmmProc info lbl live graph) = runCmmOpt dflags $ do
885   blocks' <- mapM cmmBlockConFold (toBlockList graph)
886   return $ CmmProc info lbl live (ofBlockList (g_entry graph) blocks')
887
888 newtype CmmOptM a = CmmOptM (([CLabel], DynFlags) -> (# a, [CLabel] #))
889
890 instance Monad CmmOptM where
891   return x = CmmOptM $ \(imports, _) -> (# x,imports #)
892   (CmmOptM f) >>= g =
893     CmmOptM $ \(imports, dflags) ->
894                 case f (imports, dflags) of
895                   (# x, imports' #) ->
896                     case g x of
897                       CmmOptM g' -> g' (imports', dflags)
898
899 addImportCmmOpt :: CLabel -> CmmOptM ()
900 addImportCmmOpt lbl = CmmOptM $ \(imports, _dflags) -> (# (), lbl:imports #)
901
902 instance HasDynFlags CmmOptM where
903     getDynFlags = CmmOptM $ \(imports, dflags) -> (# dflags, imports #)
904
905 runCmmOpt :: DynFlags -> CmmOptM a -> (a, [CLabel])
906 runCmmOpt dflags (CmmOptM f) = case f ([], dflags) of
907                         (# result, imports #) -> (result, imports)
908
909 cmmBlockConFold :: CmmBlock -> CmmOptM CmmBlock
910 cmmBlockConFold block = do
911   let (entry, middle, last) = blockSplit block
912       stmts = blockToList middle
913   stmts' <- mapM cmmStmtConFold stmts
914   last' <- cmmStmtConFold last
915   return $ blockJoin entry (blockFromList stmts') last'
916
917 -- This does three optimizations, but they're very quick to check, so we don't
918 -- bother turning them off even when the Hoopl code is active.  Since
919 -- this is on the old Cmm representation, we can't reuse the code either:
920 --  * reg = reg      --> nop
921 --  * if 0 then jump --> nop
922 --  * if 1 then jump --> jump
923 -- We might be tempted to skip this step entirely of not Opt_PIC, but
924 -- there is some PowerPC code for the non-PIC case, which would also
925 -- have to be separated.
926 cmmStmtConFold :: CmmNode e x -> CmmOptM (CmmNode e x)
927 cmmStmtConFold stmt
928    = case stmt of
929         CmmAssign reg src
930            -> do src' <- cmmExprConFold DataReference src
931                  return $ case src' of
932                    CmmReg reg' | reg == reg' -> CmmComment (fsLit "nop")
933                    new_src -> CmmAssign reg new_src
934
935         CmmStore addr src
936            -> do addr' <- cmmExprConFold DataReference addr
937                  src'  <- cmmExprConFold DataReference src
938                  return $ CmmStore addr' src'
939
940         CmmCall { cml_target = addr }
941            -> do addr' <- cmmExprConFold JumpReference addr
942                  return $ stmt { cml_target = addr' }
943
944         CmmUnsafeForeignCall target regs args
945            -> do target' <- case target of
946                               ForeignTarget e conv -> do
947                                 e' <- cmmExprConFold CallReference e
948                                 return $ ForeignTarget e' conv
949                               PrimTarget _ ->
950                                 return target
951                  args' <- mapM (cmmExprConFold DataReference) args
952                  return $ CmmUnsafeForeignCall target' regs args'
953
954         CmmCondBranch test true false
955            -> do test' <- cmmExprConFold DataReference test
956                  return $ case test' of
957                    CmmLit (CmmInt 0 _) -> CmmBranch false
958                    CmmLit (CmmInt _ _) -> CmmBranch true
959                    _other -> CmmCondBranch test' true false
960
961         CmmSwitch expr ids
962            -> do expr' <- cmmExprConFold DataReference expr
963                  return $ CmmSwitch expr' ids
964
965         other
966            -> return other
967
968 cmmExprConFold :: ReferenceKind -> CmmExpr -> CmmOptM CmmExpr
969 cmmExprConFold referenceKind expr = do
970     dflags <- getDynFlags
971
972     -- With -O1 and greater, the cmmSink pass does constant-folding, so
973     -- we don't need to do it again here.
974     let expr' = if optLevel dflags >= 1
975                     then expr
976                     else cmmExprCon dflags expr
977
978     cmmExprNative referenceKind expr'
979
980 cmmExprCon :: DynFlags -> CmmExpr -> CmmExpr
981 cmmExprCon dflags (CmmLoad addr rep) = CmmLoad (cmmExprCon dflags addr) rep
982 cmmExprCon dflags (CmmMachOp mop args)
983     = cmmMachOpFold dflags mop (map (cmmExprCon dflags) args)
984 cmmExprCon _ other = other
985
986 -- handles both PIC and non-PIC cases... a very strange mixture
987 -- of things to do.
988 cmmExprNative :: ReferenceKind -> CmmExpr -> CmmOptM CmmExpr
989 cmmExprNative referenceKind expr = do
990      dflags <- getDynFlags
991      let platform = targetPlatform dflags
992          arch = platformArch platform
993      case expr of
994         CmmLoad addr rep
995            -> do addr' <- cmmExprNative DataReference addr
996                  return $ CmmLoad addr' rep
997
998         CmmMachOp mop args
999            -> do args' <- mapM (cmmExprNative DataReference) args
1000                  return $ CmmMachOp mop args'
1001
1002         CmmLit (CmmBlock id)
1003            -> cmmExprNative referenceKind (CmmLit (CmmLabel (infoTblLbl id)))
1004            -- we must convert block Ids to CLabels here, because we
1005            -- might have to do the PIC transformation.  Hence we must
1006            -- not modify BlockIds beyond this point.
1007
1008         CmmLit (CmmLabel lbl)
1009            -> do
1010                 cmmMakeDynamicReference dflags addImportCmmOpt referenceKind lbl
1011         CmmLit (CmmLabelOff lbl off)
1012            -> do
1013                  dynRef <- cmmMakeDynamicReference dflags addImportCmmOpt referenceKind lbl
1014                  -- need to optimize here, since it's late
1015                  return $ cmmMachOpFold dflags (MO_Add (wordWidth dflags)) [
1016                      dynRef,
1017                      (CmmLit $ CmmInt (fromIntegral off) (wordWidth dflags))
1018                    ]
1019
1020         -- On powerpc (non-PIC), it's easier to jump directly to a label than
1021         -- to use the register table, so we replace these registers
1022         -- with the corresponding labels:
1023         CmmReg (CmmGlobal EagerBlackholeInfo)
1024           | arch == ArchPPC && not (gopt Opt_PIC dflags)
1025           -> cmmExprNative referenceKind $
1026              CmmLit (CmmLabel (mkCmmCodeLabel rtsPackageId (fsLit "__stg_EAGER_BLACKHOLE_info")))
1027         CmmReg (CmmGlobal GCEnter1)
1028           | arch == ArchPPC && not (gopt Opt_PIC dflags)
1029           -> cmmExprNative referenceKind $
1030              CmmLit (CmmLabel (mkCmmCodeLabel rtsPackageId (fsLit "__stg_gc_enter_1")))
1031         CmmReg (CmmGlobal GCFun)
1032           | arch == ArchPPC && not (gopt Opt_PIC dflags)
1033           -> cmmExprNative referenceKind $
1034              CmmLit (CmmLabel (mkCmmCodeLabel rtsPackageId (fsLit "__stg_gc_fun")))
1035
1036         other
1037            -> return other
1038
1039 \end{code}
1040