Amend configure script to support lndir build tree
[ghc.git] / configure.ac
1 dnl == autoconf source for the Glasgow FP tools ==
2 dnl (run "grep '^dnl \*' configure.ac | sed -e 's/dnl / /g; s/\*\*/   +/g;'"
3 dnl  (or some such) to see the outline of this file)
4 dnl
5 #
6 # (c) The University of Glasgow 1994-2012
7 #
8 # Configure script template for GHC
9 #
10 # Process with 'autoreconf' to get a working configure script.
11 #
12 # For the generated configure script, do "./configure --help" to
13 # see what flags are available. (Better yet, read the documentation!)
14 #
15
16 AC_INIT([The Glorious Glasgow Haskell Compilation System], [8.5], [glasgow-haskell-bugs@haskell.org], [ghc-AC_PACKAGE_VERSION])
17
18 # Set this to YES for a released version, otherwise NO
19 : ${RELEASE=NO}
20
21 # The primary version (e.g. 7.5, 7.4.1) is set in the AC_INIT line
22 # above.  If this is not a released version, then we will append the
23 # date to the version number (e.g. 7.4.20111220).  The date is
24 # constructed by finding the date of the most recent patch in the
25 # git repository.  If this is a source distribution (not a git
26 # checkout), then we ship a file 'VERSION' containing the full version
27 # when the source distribution was created.
28
29 if test ! -f mk/config.h.in; then
30    echo "mk/config.h.in doesn't exist: perhaps you haven't run 'python3 boot'?"
31    exit 1
32 fi
33
34 AC_SUBST([CONFIGURE_ARGS], [$ac_configure_args])
35
36 dnl this makes sure `./configure --target=<cross-compile-target>`
37 dnl works as expected, since we're slightly modifying how Autoconf
38 dnl interprets build/host/target and how this interacts with $CC tests
39 test -n "$target_alias" && ac_tool_prefix=$target_alias-
40
41 dnl ----------------------------------------------------------
42 dnl ** Find unixy sort and find commands,
43 dnl ** which are needed by FP_SETUP_PROJECT_VERSION
44
45 dnl ** Find find command (for Win32's benefit)
46 FP_PROG_FIND
47 FP_PROG_SORT
48
49 dnl ----------------------------------------------------------
50 FP_SETUP_PROJECT_VERSION
51
52 # Hmmm, we fix the RPM release number to 1 here... Is this convenient?
53 AC_SUBST([release], [1])
54
55 # First off, a distrib sanity check..
56 AC_CONFIG_SRCDIR([mk/config.mk.in])
57
58 dnl * We require autoconf version 2.69 due to
59 dnl   https://bugs.ruby-lang.org/issues/8179. Also see #14910.
60 dnl * We need 2.50 due to the use of AC_SYS_LARGEFILE and AC_MSG_NOTICE.
61 dnl * We need 2.52 due to the use of AS_TR_CPP and AS_TR_SH.
62 dnl * Using autoconf 2.59 started to give nonsense like this
63 dnl     #define SIZEOF_CHAR 0
64 dnl   recently.
65 AC_PREREQ([2.69])
66
67 # -------------------------------------------------------------------------
68 # Prepare to generate the following header files
69 #
70 #
71 AC_CONFIG_HEADER(mk/config.h)
72
73 # No, semi-sadly, we don't do `--srcdir'...
74 if test x"$srcdir" != 'x.' ; then
75     echo "This configuration does not support the \`--srcdir' option.."
76     exit 1
77 fi
78
79 dnl --------------------------------------------------------------
80 dnl * Project specific configuration options
81 dnl --------------------------------------------------------------
82 dnl What follows is a bunch of options that can either be configured
83 dnl through command line options to the configure script or by
84 dnl supplying defns in the build tree's mk/build.mk. Having the option to
85 dnl use either is considered a Feature.
86
87 dnl ** What command to use to compile compiler sources ?
88 dnl --------------------------------------------------------------
89
90 AC_ARG_WITH([ghc],
91 [AC_HELP_STRING([--with-ghc=ARG],
92   [Use ARG as the path to GHC  [default=autodetect]])],
93   [WithGhc="$withval"],
94   [if test "$GHC" = ""; then
95     AC_PATH_PROG([GHC], [ghc])
96   fi
97   WithGhc="$GHC"])
98
99 dnl ** Tell the make system which OS we are using
100 dnl $OSTYPE is set by the operating system to "msys" or "cygwin" or something
101 AC_SUBST(OSTYPE)
102
103 AC_ARG_ENABLE(bootstrap-with-devel-snapshot,
104 [AC_HELP_STRING([--enable-bootstrap-with-devel-snapshot],
105                 [Allow bootstrapping using a development snapshot of GHC.  This is not guaranteed to work.])],
106         EnableBootstrapWithDevelSnaphost=YES,
107         EnableBootstrapWithDevelSnaphost=NO
108 )
109
110 AC_ARG_ENABLE(tarballs-autodownload,
111 [AC_HELP_STRING([--enable-tarballs-autodownload],
112                 [Automatically download Windows distribution binaries if needed.])],
113         TarballsAutodownload=YES,
114         TarballsAutodownload=NO
115 )
116
117 AC_ARG_ENABLE(distro-toolchain,
118 [AC_HELP_STRING([--enable-distro-toolchain],
119                 [Do not use bundled Windows toolchain binaries.])],
120         EnableDistroToolchain=YES,
121         EnableDistroToolchain=NO
122 )
123
124 if test "$EnableDistroToolchain" = "YES"; then
125   TarballsAutodownload=NO
126 fi
127
128 dnl CC_STAGE0 is like the "previous" variable CC (inherited by CC_STAGE[123])
129 dnl but instead used by stage0 for bootstrapping stage1
130 AC_ARG_VAR(CC_STAGE0, [C compiler command (bootstrap)])
131
132 if test "$WithGhc" != ""; then
133   FPTOOLS_GHC_VERSION([GhcVersion], [GhcMajVersion], [GhcMinVersion], [GhcPatchLevel])dnl
134
135   if test "$GhcMajVersion" = "unknown" || test "$GhcMinVersion" = "unknown"; then
136      AC_MSG_ERROR([Cannot determine the version of $WithGhc.  Is it really GHC?])
137   fi
138
139   AC_SUBST(GhcVersion)dnl
140   AC_SUBST(GhcMajVersion)dnl
141   AC_SUBST(GhcMinVersion)dnl
142   AC_SUBST(GhcPatchLevel)dnl
143   GhcMinVersion2=`echo "$GhcMinVersion" | sed 's/^\\(.\\)$/0\\1/'`
144   GhcCanonVersion="$GhcMajVersion$GhcMinVersion2"
145
146   dnl infer CC_STAGE0 from `ghc --info` unless explicitly set by user
147   if test -z "$CC_STAGE0"; then
148     BOOTSTRAPPING_GHC_INFO_FIELD([CC_STAGE0],[C compiler command])
149   fi
150
151   BOOTSTRAPPING_GHC_INFO_FIELD([LD_STAGE0],[ld command])
152   BOOTSTRAPPING_GHC_INFO_FIELD([AR_STAGE0],[ar command])
153   BOOTSTRAPPING_GHC_INFO_FIELD([AR_OPTS_STAGE0],[ar flags])
154   BOOTSTRAPPING_GHC_INFO_FIELD([ArSupportsAtFile_STAGE0],[ar supports at file])
155 fi
156
157 dnl ** Must have GHC to build GHC
158 if test "$WithGhc" = ""
159 then
160     AC_MSG_ERROR([GHC is required.])
161 fi
162 FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[8.2],
163     [AC_MSG_ERROR([GHC version 8.2 or later is required to compile GHC.])])
164
165 if test `expr $GhcMinVersion % 2` = "1"
166 then
167     if test "$EnableBootstrapWithDevelSnaphost" = "NO"
168     then
169         AC_MSG_ERROR([
170      $WithGhc is a development snapshot of GHC, version $GhcVersion.
171      Bootstrapping using this version of GHC is not supported, and may not
172      work.  Use --enable-bootstrap-with-devel-snapshot to try it anyway,
173      or --with-ghc to specify a different GHC to use.])
174     fi
175 fi
176
177 GHC_PACKAGE_DB_FLAG=package-db
178 AC_SUBST(GHC_PACKAGE_DB_FLAG)
179
180 # GHC is passed to Cabal, so we need a native path
181 if test "${WithGhc}" != ""
182 then
183     ghc_host_os=`"${WithGhc}" +RTS --info | grep 'Host OS' | sed -e 's/.*, "//' -e 's/")//'`
184
185     if test "$ghc_host_os" = "mingw32"
186     then
187         if test "${OSTYPE}" = "msys"
188         then
189             WithGhc=`echo "${WithGhc}" | sed "s#^/\([a-zA-Z]\)/#\1:/#"`
190         else
191             # Canonicalise to <drive>:/path/to/ghc
192             WithGhc=`cygpath -m "${WithGhc}"`
193         fi
194         echo "GHC path canonicalised to: ${WithGhc}"
195     fi
196 fi
197 AC_SUBST([WithGhc])
198
199 dnl ** Without optimization some INLINE trickery fails for GHCi
200 SRC_CC_OPTS="-O"
201
202 dnl--------------------------------------------------------------------
203 dnl * Choose host(/target/build) platform
204 dnl--------------------------------------------------------------------
205 dnl If we aren't explicitly told what values to use with configure flags,
206 dnl we ask the bootstrapping compiler what platform it is for
207
208 if test "${WithGhc}" != ""
209 then
210         bootstrap_host=`"${WithGhc}" +RTS --info | grep '^ ,("Host platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
211         bootstrap_target=`"${WithGhc}" +RTS --info | grep '^ ,("Target platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
212         if test "$bootstrap_host" != "$bootstrap_target"
213         then
214                 echo "Bootstrapping GHC is a cross compiler. This probably isn't going to work"
215         fi
216 fi
217
218 # We have to run these unconditionally, but we may discard their
219 # results in the following code
220 AC_CANONICAL_BUILD
221 AC_CANONICAL_HOST
222 AC_CANONICAL_TARGET
223
224 FPTOOLS_SET_PLATFORM_VARS
225
226 # Verify that the installed (bootstrap) GHC is capable of generating
227 # code for the requested build platform.
228 if test "$BuildPlatform" != "$bootstrap_target"
229 then
230     echo "This GHC (${WithGhc}) does not generate code for the build platform"
231     echo "   GHC target platform    : $bootstrap_target"
232     echo "   Desired build platform : $BuildPlatform"
233     exit 1
234 fi
235
236 # Testing if we shall enable shared libs support on Solaris.
237 # Anything older than SunOS 5.11 aka Solaris 11 (Express) is broken.
238
239 SOLARIS_BROKEN_SHLD=NO
240
241 case $host in
242      i386-*-solaris2)
243      # here we go with the test
244      MINOR=`uname -r|cut -d '.' -f 2-`
245      if test "$MINOR" -lt "11"; then
246          SOLARIS_BROKEN_SHLD=YES
247      fi
248      ;;
249 esac
250
251 AC_SUBST(SOLARIS_BROKEN_SHLD)
252
253 dnl ** Do an unregisterised build?
254 dnl --------------------------------------------------------------
255 case "$TargetArch" in
256     i386|x86_64|powerpc|powerpc64|powerpc64le|arm|aarch64)
257         UnregisterisedDefault=NO
258         ;;
259     *)
260         UnregisterisedDefault=YES
261         ;;
262 esac
263 AC_ARG_ENABLE(unregisterised,
264 [AC_HELP_STRING([--enable-unregisterised],
265 [Build an unregisterised compiler (enabled by default on platforms without registerised support) [default="$UnregisterisedDefault"]])],
266 [ if test x"$enableval" = x"yes"; then
267         Unregisterised=YES
268   else
269         Unregisterised=NO
270   fi
271 ],
272 [Unregisterised="$UnregisterisedDefault"]
273 )
274 AC_SUBST(Unregisterised)
275
276 dnl ** Does target have runtime linker support?
277 dnl --------------------------------------------------------------
278 case "$target" in
279     powerpc64-*|powerpc64le-*|powerpc-ibm-aix*)
280         HaskellHaveRTSLinker=NO
281         ;;
282     *)
283         HaskellHaveRTSLinker=YES
284         ;;
285 esac
286 AC_SUBST(HaskellHaveRTSLinker)
287
288 # Requires FPTOOLS_SET_PLATFORM_VARS to be run first.
289 FP_FIND_ROOT
290
291 fail() {
292     echo >&2
293     echo "$1" >&2
294     exit 1
295 }
296
297
298 if test "$HostOS" = "mingw32"
299 then
300     # Find the mingw-w64 7z file to extract.
301     # NB. If you update the tarballs to a new version of gcc, don't
302     # forget to tweak the paths in driver/gcc/gcc.c.
303     if test "$HostArch" = "i386"
304     then
305         mingw_arch="i686"
306         tarball_dest_dir="mingw-w64/x86"
307         tarball_mingw_dir="mingw32"
308     else
309         mingw_arch="x86_64"
310         tarball_dest_dir="mingw-w64/x86_64"
311         tarball_mingw_dir="mingw64"
312     fi
313 fi
314
315 set_up_tarballs() {
316     AC_MSG_NOTICE([Checking for Windows toolchain tarballs...])
317     local action
318     if test "$TarballsAutodownload" = "NO"
319     then
320         action="verify"
321     else
322         action="download"
323     fi
324     mk/get-win32-tarballs.sh $action $HostArch > missing-win32-tarballs
325     case $? in
326         0)
327            rm missing-win32-tarballs
328            ;;
329         2)
330            echo
331            echo "Error:"
332            echo "Needed msys2 tarballs are missing. You have a few options to get them,"
333            echo
334            echo "  * run configure with the --enable-tarballs-autodownload option"
335            echo
336            echo "  * run mk/get-win32-tarballs.sh download ${HostArch}"
337            echo
338            echo "  * manually download the files listed in ./missing-win32-tarballs and place"
339            echo "    them in the ghc-tarballs directory."
340            echo
341            exit 1
342            ;;
343         *)
344            echo
345            echo "Error fetching msys2 tarballs; see errors above."
346            exit 1
347            ;;
348     esac
349
350     # Extract all the tarballs in one go
351     if ! test -d inplace/mingw
352     then
353         AC_MSG_NOTICE([Extracting Windows toolchain from archives (may take a while)...])
354         rm -rf inplace/mingw
355         local base_dir="../ghc-tarballs/${tarball_dest_dir}"
356         ( cd inplace &&
357         find "${base_dir}" -name "*.tar.xz" -exec tar xfJ {} \; &&
358         rm ".MTREE" &&
359         rm ".PKGINFO" &&
360         cd .. ) || fail "Error: Could not extract Windows toolchains."
361
362         mv "inplace/${tarball_mingw_dir}" inplace/mingw &&
363         touch inplace/mingw
364
365         # NB. Now since the GCC is hardcoded to use /mingw32 we need to
366         # make a wrapper around it to give it the proper paths
367         mv inplace/mingw/bin/gcc.exe inplace/mingw/bin/realgcc.exe
368         PATH=`pwd`/inplace/mingw/bin:$PATH
369         inplace/mingw/bin/realgcc.exe driver/gcc/gcc.c driver/utils/cwrapper.c driver/utils/getLocation.c -Idriver/utils -o inplace/mingw/bin/gcc.exe
370
371         AC_MSG_NOTICE([In-tree MingW-w64 tree created])
372     fi
373 }
374
375 if test "$HostOS" = "mingw32" -a "$EnableDistroToolchain" = "NO"
376 then
377     test -d inplace || mkdir inplace
378
379     # NB. Download and extract the MingW-w64 distribution if required
380     set_up_tarballs
381
382     mingwbin="$hardtop/inplace/mingw/bin/"
383     CC="${mingwbin}gcc.exe"
384     LD="${mingwbin}ld.exe"
385     NM="${mingwbin}nm.exe"
386     RANLIB="${mingwbin}ranlib.exe"
387     OBJDUMP="${mingwbin}objdump.exe"
388     fp_prog_ar="${mingwbin}ar.exe"
389
390     AC_PATH_PROG([Genlib],[genlib])
391
392     # NB. Download the perl binaries if required
393     if ! test -d inplace/perl ||
394          test inplace/perl -ot ghc-tarballs/perl/ghc-perl*.tar.gz
395     then
396         AC_MSG_NOTICE([Making in-tree perl tree])
397         rm -rf inplace/perl
398         mkdir inplace/perl
399         (
400             cd inplace/perl &&
401             tar -zxf ../../ghc-tarballs/perl/ghc-perl*.tar.gz
402         )
403         AC_MSG_NOTICE([In-tree perl tree created])
404     fi
405 fi
406
407 # We don't want to bundle a MinGW-w64 toolchain
408 # So we have to find these individual tools.
409 if test "$EnableDistroToolchain" = "YES"
410 then
411     # Ideally should use AC_CHECK_TARGET_TOOL but our triples
412     # are screwed up. Configure doesn't think they're ever equal and
413     # so never tried without the prefix.
414     AC_PATH_PROG([CC],[gcc], [clang])
415     AC_PATH_PROG([NM],[nm])
416     AC_PATH_PROG([AR],[ar])
417     AC_PATH_PROG([RANLIB],[ranlib])
418     AC_PATH_PROG([OBJDUMP],[objdump])
419     AC_PATH_PROG([DllWrap],[dllwrap])
420     AC_PATH_PROG([Windres],[windres])
421     AC_PATH_PROG([Genlib],[genlib])
422 else
423     AC_CHECK_TARGET_TOOL([Windres],[windres])
424     AC_CHECK_TARGET_TOOL([DllWrap],[dllwrap])
425     AC_CHECK_TARGET_TOOL([OBJDUMP],[objdump])
426 fi
427
428 DllWrapCmd="$DllWrap"
429 WindresCmd="$Windres"
430
431 HAVE_GENLIB=False
432 if test "$HostOS" = "mingw32"
433 then
434     if test "$Genlib" != ""; then
435         GenlibCmd="$(cygpath -m $Genlib)"
436         HAVE_GENLIB=True
437     fi
438 fi
439
440 AC_SUBST([DllWrapCmd])
441 AC_SUBST([WindresCmd])
442 AC_SUBST([GenlibCmd])
443 AC_SUBST([HAVE_GENLIB])
444
445 FP_ICONV
446 FP_GMP
447 FP_CURSES
448
449 XCODE_VERSION()
450
451
452 dnl ** Building a cross compiler?
453 dnl --------------------------------------------------------------
454 CrossCompiling=NO
455 # If 'host' and 'target' differ, then this means we are building a cross-compiler.
456 if test "$TargetPlatform" != "$HostPlatform" ; then
457     CrossCompiling=YES
458     cross_compiling=yes   # This tells configure that it can accept just 'target',
459                           # otherwise you get
460                           #   configure: error: cannot run C compiled programs.
461                           #   If you meant to cross compile, use `--host'.
462 fi
463 if test "$BuildPlatform" != "$HostPlatform" ; then
464    AC_MSG_ERROR([
465 You've selected:
466
467   BUILD:  $BuildPlatform   (the architecture we're building on)
468   HOST:   $HostPlatform    (the architecture the compiler we're building will execute on)
469   TARGET: $TargetPlatform  (the architecture the compiler we're building will produce code for)
470
471 BUILD must equal HOST; that is, we do not support building GHC itself
472 with a cross-compiler.  To cross-compile GHC itself, set TARGET: stage
473 1 will be a cross-compiler, and stage 2 will be the cross-compiled
474 GHC.
475 ])
476 fi
477 # Despite its similarity in name to TargetPlatform, TargetPlatformFull is used
478 # in calls to subproject configure scripts and thus must be set to the autoconf
479 # triple, not the normalized GHC triple that TargetPlatform is set to.
480 #
481 # We use the non-canonicalized triple, target_alias, here since the subproject
482 # configure scripts will use this triple to construct the names of the toolchain
483 # executables. If we instead passed down the triple produced by
484 # AC_CANONICAL_TARGET then it may look for the target toolchain under the wrong
485 # name (this is a known problem in the case of the Android NDK, which has
486 # slightly odd triples).
487 #
488 # It may be better to just do away with the GHC triples altogether. This would
489 # all be taken care of for us if we configured the subprojects using
490 # AC_CONFIG_DIR, but unfortunately Cabal needs to be the one to do the
491 # configuration.
492 #
493 # We also use non-canonicalized triple when install stage1 crosscompiler
494 if test -z "${target_alias}"
495 then
496   # --target wasn't given; use result from AC_CANONICAL_TARGET
497   TargetPlatformFull="${target}"
498 else
499   TargetPlatformFull="${target_alias}"
500 fi
501 if test "$CrossCompiling" = "YES"
502 then
503   # Use value passed by user from --target=
504   CrossCompilePrefix="${TargetPlatformFull}-"
505 else
506   CrossCompilePrefix=""
507 fi
508 AC_SUBST(CrossCompiling)
509 AC_SUBST(CrossCompilePrefix)
510 AC_SUBST(TargetPlatformFull)
511 AC_SUBST(EnableDistroToolchain)
512
513 dnl ** Which gcc to use?
514 dnl --------------------------------------------------------------
515
516 AC_ARG_WITH([gcc],
517         AS_HELP_STRING([--with-gcc=ARG], [Use ARG as the path to gcc (obsolete, use CC=ARG instead) [default=autodetect]]),
518         AC_MSG_ERROR([--with-gcc=$withval is obsolete (use './configure CC=$withval' or 'CC=$withval ./configure' instead)]))
519
520 AC_ARG_WITH([clang],
521         AS_HELP_STRING([--with-clang=ARG], [Use ARG as the path to gcc (obsolete, use CC=ARG instead) [default=autodetect]]),
522         AC_MSG_ERROR([--with-clang=$withval is obsolete (use './configure CC=$withval' or 'CC=$withval ./configure' instead)]))
523
524 dnl detect compiler (prefer gcc over clang) and set $CC (unless CC already set),
525 dnl later CC is copied to CC_STAGE{1,2,3}
526 AC_PROG_CC([gcc clang])
527
528 MAYBE_OVERRIDE_STAGE0([ar],[AR_STAGE0])
529
530 dnl make extensions visible to allow feature-tests to detect them lateron
531 AC_USE_SYSTEM_EXTENSIONS
532
533 dnl ** figure out how to invoke the C preprocessor (i.e. `gcc -E`)
534 AC_PROG_CPP
535
536 # --with-hs-cpp/--with-hs-cpp-flags
537 FP_CPP_CMD_WITH_ARGS(HaskellCPPCmd, HaskellCPPArgs)
538 AC_SUBST([HaskellCPPCmd])
539 AC_SUBST([HaskellCPPArgs])
540
541 FP_SET_CFLAGS_C99([CC],[CFLAGS],[CPPFLAGS])
542 FP_SET_CFLAGS_C99([CC_STAGE0],[CONF_CC_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
543 FP_SET_CFLAGS_C99([CC],[CONF_CC_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
544 FP_SET_CFLAGS_C99([CC],[CONF_CC_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])
545
546 dnl ** Which ld to use
547 dnl --------------------------------------------------------------
548 FIND_LD([$target],[GccUseLdOpt])
549 CONF_GCC_LINKER_OPTS_STAGE1="$CONF_GCC_LINKER_OPTS_STAGE1 $GccUseLdOpt"
550 CONF_GCC_LINKER_OPTS_STAGE2="$CONF_GCC_LINKER_OPTS_STAGE2 $GccUseLdOpt"
551 LdCmd="$LD"
552 LdNoGoldCmd="$LD_NO_GOLD"
553 CFLAGS="$CFLAGS $GccUseLdOpt"
554 AC_SUBST([LdCmd])
555 AC_SUBST([LdNoGoldCmd])
556
557 FP_PROG_LD_IS_GNU
558 FP_PROG_LD_BUILD_ID
559 FP_PROG_LD_NO_COMPACT_UNWIND
560 FP_PROG_LD_FILELIST
561
562 dnl ** Which nm to use?
563 dnl --------------------------------------------------------------
564 if test "$HostOS" != "mingw32"; then
565     AC_CHECK_TARGET_TOOL([NM], [nm])
566     if test "$NM" = ":"; then
567         AC_MSG_ERROR([cannot find nm in your PATH])
568     fi
569 fi
570 NmCmd="$NM"
571 AC_SUBST([NmCmd])
572
573 if test "$TargetOS_CPP" = "darwin"
574 then
575     AC_MSG_CHECKING(whether nm program is broken)
576     # Some versions of XCode ship a broken version of `nm`. Detect and work
577     # around this issue. See : https://ghc.haskell.org/trac/ghc/ticket/11744
578     nmver=$(${NM} --version | grep version | sed 's/ //g')
579     case "$nmver" in
580         LLVMversion7.3.0|LLVMversion7.3.1)
581             AC_MSG_RESULT(yes)
582             echo "The detected nm program is broken."
583             echo
584             echo "See: https://ghc.haskell.org/trac/ghc/ticket/11744"
585             echo
586             echo "Try re-running configure with:"
587             echo
588             echo '   NM=$(xcrun --find nm-classic) ./configure'
589             echo
590             exit 1
591             ;;
592         *)
593             AC_MSG_RESULT(no)
594             ;;
595         esac
596 fi
597
598 dnl ** Which objdump to use?
599 dnl --------------------------------------------------------------
600 dnl Note: we may not have objdump on OS X, and we only need it on
601 dnl Windows (for DLL checks), OpenBSD, and AIX
602 case $HostOS_CPP in
603   cygwin32|mingw32|openbsd|aix)
604     AC_CHECK_TARGET_TOOL([OBJDUMP], [objdump])
605     ;;
606 esac
607
608 ObjdumpCmd="$OBJDUMP"
609 AC_SUBST([ObjdumpCmd])
610
611 dnl ** Which ranlib to use?
612 dnl --------------------------------------------------------------
613 AC_PROG_RANLIB
614 if test "$RANLIB" = ":"; then
615     AC_MSG_ERROR([cannot find ranlib in your PATH])
616 fi
617 RanlibCmd="$RANLIB"
618 AC_SUBST([RanlibCmd])
619
620 dnl ** which strip to use?
621 dnl --------------------------------------------------------------
622 AC_CHECK_TARGET_TOOL([STRIP], [strip])
623 StripCmd="$STRIP"
624 AC_SUBST([StripCmd])
625
626
627 dnl ** which libtool to use?
628 dnl --------------------------------------------------------------
629 # The host normalization on Windows breaks autoconf, it no longer
630 # thinks that target == host so it never checks the unqualified
631 # tools for Windows. See #14274.
632 if test "$HostOS" = "mingw32"
633 then
634     AC_PATH_PROG([LIBTOOL],[libtool])
635     LibtoolCmd="$(cygpath -m $LIBTOOL)"
636 else
637     AC_CHECK_TARGET_TOOL([LIBTOOL], [libtool])
638     LibtoolCmd="$LIBTOOL"
639 fi
640 AC_SUBST([LibtoolCmd])
641
642 # Here is where we re-target which specific version of the LLVM
643 # tools we are looking for. In the past, GHC supported a number of
644 # versions of LLVM simultaneously, but that stopped working around
645 # 3.5/3.6 release of LLVM.
646 LlvmVersion=6.0
647 AC_SUBST([LlvmVersion])
648 sUPPORTED_LLVM_VERSION=$(echo \($LlvmVersion\) | sed 's/\./,/')
649 AC_DEFINE_UNQUOTED([sUPPORTED_LLVM_VERSION], ${sUPPORTED_LLVM_VERSION}, [The supported LLVM version number])
650
651 dnl ** Which LLVM clang to use?
652 dnl --------------------------------------------------------------
653 AC_CHECK_TARGET_TOOL([CLANG], [clang])
654 ClangCmd="$CLANG"
655 AC_SUBST([ClangCmd])
656
657 dnl ** Which LLVM llc to use?
658 dnl --------------------------------------------------------------
659 FIND_LLVM_PROG([LLC], [llc], [$LlvmVersion])
660 LlcCmd="$LLC"
661 AC_SUBST([LlcCmd])
662
663 dnl ** Which LLVM opt to use?
664 dnl --------------------------------------------------------------
665 FIND_LLVM_PROG([OPT], [opt], [$LlvmVersion])
666 OptCmd="$OPT"
667 AC_SUBST([OptCmd])
668
669 dnl --------------------------------------------------------------
670 dnl End of configure script option section
671 dnl --------------------------------------------------------------
672
673 dnl ** Copy the files from the "fs" utility into the right folders.
674 dnl --------------------------------------------------------------
675 AC_MSG_NOTICE([Creating links for in-tree file handling routines.])
676 ln -f -v -L utils/fs/fs.* utils/lndir/
677 ln -f -v -L utils/fs/fs.* utils/unlit/
678 ln -f -v -L utils/fs/fs.* rts/
679 ln -f -v -L utils/fs/fs.h libraries/base/include/
680 ln -f -v -L utils/fs/fs.c libraries/base/cbits/
681 AC_MSG_NOTICE([Routines in place. Packages can now be build normally.])
682
683 dnl --------------------------------------------------------------
684 dnl ** Can the unix package be built?
685 dnl --------------------------------------------------------------
686
687 if test "$TargetOS" = "mingw32"
688 then
689     GhcLibsWithUnix=NO
690 else
691     GhcLibsWithUnix=YES
692 fi
693 AC_SUBST([GhcLibsWithUnix])
694
695 dnl ** does #! work?
696 AC_SYS_INTERPRETER()
697
698 # Check for split-objs
699 SplitObjsBroken=NO
700 dnl ** look for `perl'
701 case $HostOS_CPP in
702 cygwin32|mingw32)
703   if test "$EnableDistroToolchain" = "NO"; then
704     PerlCmd=$hardtop/inplace/perl/perl
705   else
706     AC_PATH_PROG([PerlCmd],[perl])
707   fi
708   ;;
709 *)
710     AC_PATH_PROG([PerlCmd],[perl])
711     if test -z "$PerlCmd"
712     then
713         AC_MSG_WARN([No Perl on PATH, disabling split object support])
714         SplitObjsBroken=YES
715     else
716         FPTOOLS_CHECK_PERL_VERSION
717     fi
718     ;;
719 esac
720 AC_SUBST([SplitObjsBroken])
721
722 dnl ** look for GCC and find out which version
723 dnl     Figure out which C compiler to use.  Gcc is preferred.
724 dnl     If gcc, make sure it's at least 3.0
725 dnl
726 FP_GCC_VERSION
727
728 dnl ** See whether gcc supports -no-pie
729 FP_GCC_SUPPORTS_NO_PIE
730
731 FP_GCC_EXTRA_FLAGS
732
733 dnl ** look to see if we have a C compiler using an llvm back end.
734 dnl
735 FP_CC_LLVM_BACKEND
736
737 FPTOOLS_SET_C_LD_FLAGS([target],[CFLAGS],[LDFLAGS],[IGNORE_LINKER_LD_FLAGS],[CPPFLAGS])
738 FPTOOLS_SET_C_LD_FLAGS([build],[CONF_CC_OPTS_STAGE0],[CONF_GCC_LINKER_OPTS_STAGE0],[CONF_LD_LINKER_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
739 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE1],[CONF_GCC_LINKER_OPTS_STAGE1],[CONF_LD_LINKER_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
740 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE2],[CONF_GCC_LINKER_OPTS_STAGE2],[CONF_LD_LINKER_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])
741 # Stage 3 won't be supported by cross-compilation
742
743 # See rules/distdir-way-opts.mk for details.
744 # Flags passed to the C compiler
745 AC_SUBST(CONF_CC_OPTS_STAGE0)
746 AC_SUBST(CONF_CC_OPTS_STAGE1)
747 AC_SUBST(CONF_CC_OPTS_STAGE2)
748 # Flags passed to the C compiler when we ask it to link
749 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE0)
750 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE1)
751 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE2)
752 # Flags passed to the linker when we ask it to link
753 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE0)
754 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE1)
755 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE2)
756 # Flags passed to the C preprocessor
757 AC_SUBST(CONF_CPP_OPTS_STAGE0)
758 AC_SUBST(CONF_CPP_OPTS_STAGE1)
759 AC_SUBST(CONF_CPP_OPTS_STAGE2)
760 # Flags passed to the Haskell compiler
761 AC_SUBST(CONF_HC_OPTS_STAGE0)
762 AC_SUBST(CONF_HC_OPTS_STAGE1)
763 AC_SUBST(CONF_HC_OPTS_STAGE2)
764
765 dnl ** Set up the variables for the platform in the settings file.
766 dnl May need to use gcc to find platform details.
767 dnl --------------------------------------------------------------
768 FPTOOLS_SET_HASKELL_PLATFORM_VARS
769
770 dnl ** figure out how to do context diffs
771 FP_PROG_CONTEXT_DIFF
772
773 dnl Let's make sure install-sh is executable here.  If we got it from
774 dnl a darcs repo, it might not be (see bug #978).
775 chmod +x install-sh
776 dnl ** figure out how to do a BSD-ish install
777 AC_PROG_INSTALL
778
779 dnl ** how to invoke `ar' and `ranlib'
780 FP_PROG_AR_SUPPORTS_ATFILE
781 FP_PROG_AR_NEEDS_RANLIB
782
783 dnl ** Check to see whether ln -s works
784 AC_PROG_LN_S
785
786 FP_SETTINGS
787
788 dnl ** Find the path to sed
789 AC_PATH_PROGS(SedCmd,gsed sed,sed)
790
791
792 dnl ** check for time command
793 AC_PATH_PROG(TimeCmd,time)
794
795 dnl ** check for tar
796 dnl   if GNU tar is named gtar, look for it first.
797 AC_PATH_PROGS(TarCmd,gnutar gtar tar,tar)
798
799 dnl ** check for compressors
800 AC_PATH_PROGS(Bzip2Cmd,bzip2, bzip2)
801 AC_PATH_PROGS(GzipCmd,gzip, gzip)
802 AC_PATH_PROGS(XzCmd,pxz xz, xz)
803
804 dnl ** check for patch
805 dnl if GNU patch is named gpatch, look for it first
806 AC_PATH_PROGS(PatchCmd,gpatch patch, patch)
807
808 dnl ** check for dtrace (currently only implemented for Mac OS X)
809 AC_ARG_ENABLE(dtrace,
810     [AC_HELP_STRING([--enable-dtrace],
811         [Enable DTrace])],
812     EnableDtrace=$enableval,
813     EnableDtrace=yes
814 )
815
816 HaveDtrace=NO
817
818 AC_PATH_PROG(DtraceCmd,dtrace)
819 if test "x$EnableDtrace" = "xyes"; then
820   if test -n "$DtraceCmd"; then
821     if test "x$TargetOS_CPP-$TargetVendor_CPP" = "xdarwin-apple" \
822       -o "x$TargetOS_CPP-$TargetVendor_CPP" = "xfreebsd-portbld" \
823       -o "x$TargetOS_CPP-$TargetVendor_CPP" = "xsolaris2-unknown"; then
824       HaveDtrace=YES
825     fi
826   fi
827 fi
828 AC_SUBST(HaveDtrace)
829
830 AC_PATH_PROG(HSCOLOUR,HsColour)
831 # HsColour is passed to Cabal, so we need a native path
832 if test "$HostOS"      = "mingw32" && \
833    test "${OSTYPE}"   != "msys"    && \
834    test "${HSCOLOUR}" != ""
835 then
836     # Canonicalise to <drive>:/path/to/gcc
837     HSCOLOUR=`cygpath -m ${HSCOLOUR}`
838 fi
839
840 dnl ** check for Sphinx toolchain
841 AC_PATH_PROG(SPHINXBUILD,sphinx-build)
842 AC_CACHE_CHECK([for version of sphinx-build], fp_cv_sphinx_version,
843 changequote(, )dnl
844 [if test -n "$SPHINXBUILD"; then
845   fp_cv_sphinx_version=`"$SPHINXBUILD" --version 2>&1 | sed 's/.* v\?\([0-9]\.[0-9]\.[0-9]\)/\1/' | head -n1`;
846 fi;
847 changequote([, ])dnl
848 ])
849 FP_COMPARE_VERSIONS([$fp_cv_sphinx_version],-lt,1.0.0,
850     [AC_MSG_WARN([Sphinx version 1.0.0 or later is required to build documentation]); SPHINXBUILD=;])
851
852 dnl ** check for xelatex
853 AC_PATH_PROG(XELATEX,xelatex)
854
855 dnl ** check for ghc-pkg command
856 FP_PROG_GHC_PKG
857
858 dnl ** check for installed happy binary + version
859 FPTOOLS_HAPPY
860
861 dnl ** check for installed alex binary + version
862 FPTOOLS_ALEX
863
864 dnl --------------------------------------------------
865 dnl ### program checking section ends here ###
866 dnl --------------------------------------------------
867
868 dnl --------------------------------------------------
869 dnl * Platform header file and syscall feature tests
870 dnl ### checking the state of the local header files and syscalls ###
871
872 dnl ** check for full ANSI header (.h) files
873 AC_HEADER_STDC
874
875 dnl ** Enable large file support.  NB. do this before testing the type of
876 dnl    off_t, because it will affect the result of that test.
877 AC_SYS_LARGEFILE
878
879 dnl ** check for specific header (.h) files that we are interested in
880 AC_CHECK_HEADERS([ctype.h dirent.h dlfcn.h errno.h fcntl.h grp.h limits.h locale.h nlist.h pthread.h pwd.h signal.h sys/param.h sys/mman.h sys/resource.h sys/select.h sys/time.h sys/timeb.h sys/timerfd.h sys/timers.h sys/times.h sys/utsname.h sys/wait.h termios.h time.h utime.h windows.h winsock.h sched.h])
881
882 dnl sys/cpuset.h needs sys/param.h to be included first on FreeBSD 9.1; #7708
883 AC_CHECK_HEADERS([sys/cpuset.h], [], [],
884 [[#if HAVE_SYS_PARAM_H
885 # include <sys/param.h>
886 #endif
887 ]])
888
889 dnl ** check if it is safe to include both <time.h> and <sys/time.h>
890 AC_HEADER_TIME
891
892 dnl ** do we have long longs?
893 AC_CHECK_TYPES([long long])
894
895 dnl ** what are the sizes of various types
896 FP_CHECK_SIZEOF_AND_ALIGNMENT(char)
897 FP_CHECK_SIZEOF_AND_ALIGNMENT(double)
898 FP_CHECK_SIZEOF_AND_ALIGNMENT(float)
899 FP_CHECK_SIZEOF_AND_ALIGNMENT(int)
900 FP_CHECK_SIZEOF_AND_ALIGNMENT(long)
901 if test "$ac_cv_type_long_long" = yes; then
902 FP_CHECK_SIZEOF_AND_ALIGNMENT(long long)
903 fi
904 FP_CHECK_SIZEOF_AND_ALIGNMENT(short)
905 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned char)
906 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned int)
907 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned long)
908 if test "$ac_cv_type_long_long" = yes; then
909 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned long long)
910 fi
911 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned short)
912 FP_CHECK_SIZEOF_AND_ALIGNMENT(void *)
913
914 FP_CHECK_SIZEOF_AND_ALIGNMENT(int8_t)
915 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint8_t)
916 FP_CHECK_SIZEOF_AND_ALIGNMENT(int16_t)
917 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint16_t)
918 FP_CHECK_SIZEOF_AND_ALIGNMENT(int32_t)
919 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint32_t)
920 FP_CHECK_SIZEOF_AND_ALIGNMENT(int64_t)
921 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint64_t)
922
923
924 dnl for use in settings.in
925 TargetWordSize=$ac_cv_sizeof_void_p
926 if test "x$TargetWordSize" == 8; then
927   AC_SUBST([Cabal64bit],[True])
928 else
929   AC_SUBST([Cabal64bit],[False])
930 fi
931 AC_SUBST(TargetWordSize)
932 FP_CHECK_FUNC([WinExec],
933   [@%:@include <windows.h>], [WinExec("",0)])
934
935 FP_CHECK_FUNC([GetModuleFileName],
936   [@%:@include <windows.h>], [GetModuleFileName((HMODULE)0,(LPTSTR)0,0)])
937
938 dnl ** check for more functions
939 dnl ** The following have been verified to be used in ghc/, but might be used somewhere else, too.
940 AC_CHECK_FUNCS([getclock getrusage gettimeofday setitimer siginterrupt sysconf times ctime_r sched_setaffinity setlocale])
941
942 dnl ** On OS X 10.4 (at least), time.h doesn't declare ctime_r if
943 dnl ** _POSIX_C_SOURCE is defined
944 AC_CHECK_DECLS([ctime_r], , ,
945 [#define _POSIX_SOURCE 1
946 #define _POSIX_C_SOURCE 199506L
947 #include <time.h>])
948
949 dnl ** check for mingwex library
950 AC_CHECK_LIB(
951   [mingwex],
952   [closedir],
953   [AC_SUBST([HaveLibMingwEx],[YES])] [AC_SUBST([CabalMingwex],[True])],
954   [AC_SUBST([HaveLibMingwEx],[NO])] [AC_SUBST([CabalMingwex],[False])])
955
956 if test $HaveLibMingwEx = YES ; then
957   AC_DEFINE([HAVE_MINGWEX], [1], [Define to 1 if you have the mingwex library.])
958 fi
959
960 dnl ** check for math library
961 dnl    Keep that check as early as possible.
962 dnl    as we need to know whether we need libm
963 dnl    for math functions or not
964 dnl    (see http://ghc.haskell.org/trac/ghc/ticket/3730)
965 AC_CHECK_LIB(m, atan, HaveLibM=YES, HaveLibM=NO)
966 if test $HaveLibM = YES
967 then
968   AC_DEFINE([HAVE_LIBM], [1], [Define to 1 if you need to link with libm])
969   AC_SUBST([CabalHaveLibm],[True])
970 else
971   AC_SUBST([CabalHaveLibm],[False])
972 fi
973
974 FP_BFD_SUPPORT
975
976 dnl ################################################################
977 dnl Check for libraries
978 dnl ################################################################
979
980 # system libffi
981
982 AC_ARG_WITH([system-libffi],
983 [AC_HELP_STRING([--with-system-libffi],
984   [Use system provided libffi for RTS [default=no]])
985 ])
986
987 AS_IF([test "x$with_system_libffi" = "xyes"],
988   [UseSystemLibFFI="YES"], [UseSystemLibFFI="NO"]
989 )
990
991
992 AC_SUBST(UseSystemLibFFI)
993
994 AC_ARG_WITH([ffi-includes],
995 [AC_HELP_STRING([--with-ffi-includes=ARG],
996   [Find includes for libffi in ARG [default=system default]])
997 ],
998 [
999  if test "x$UseSystemLibFFI" != "xYES"; then
1000     AC_MSG_WARN([--with-ffi-includes will be ignored, --with-system-libffi not set])
1001  else
1002     FFIIncludeDir="$withval"
1003     LIBFFI_CFLAGS="-I$withval"
1004  fi
1005 ])
1006
1007 AC_SUBST(FFIIncludeDir)
1008
1009 AC_ARG_WITH([ffi-libraries],
1010 [AC_HELP_STRING([--with-ffi-libraries=ARG],
1011   [Find libffi in ARG [default=system default]])
1012 ],
1013 [
1014  if test "x$UseSystemLibFFI" != "xYES"; then
1015     AC_MSG_WARN([--with-ffi-libraries will be ignored, --with-system-libffi not set])
1016  else
1017     FFILibDir="$withval" LIBFFI_LDFLAGS="-L$withval"
1018  fi
1019 ])
1020
1021 AC_SUBST(FFILibDir)
1022
1023 AC_SUBST([CabalHaveLibffi],[False])
1024 AS_IF([test "$UseSystemLibFFI" = "YES"], [
1025  CFLAGS2="$CFLAGS"
1026  CFLAGS="$LIBFFI_CFLAGS $CFLAGS"
1027  LDFLAGS2="$LDFLAGS"
1028  LDFLAGS="$LIBFFI_LDFLAGS $LDFLAGS"
1029  if test "$HostOS" = "openbsd";
1030  then
1031    # OpenBSD's libffi is not directly linked to the libpthread but
1032    # still requires pthread functionality. This means that any client
1033    # binary which links with libffi also needs to link with
1034    # libpthread. If it does not, then linking fails with unresolved
1035    # symbols.
1036    LDFLAGS="$LDFLAGS -lpthread"
1037  fi
1038  AC_CHECK_LIB(ffi, ffi_call,
1039   [AC_CHECK_HEADERS([ffi.h], [break], [])
1040    AC_DEFINE([HAVE_LIBFFI], [1], [Define to 1 if you have libffi.])]
1041    AC_SUBST([CabalHaveLibffi],[True]),
1042   [AC_MSG_ERROR([Cannot find system libffi])])
1043  CFLAGS="$CFLAGS2"
1044  LDFLAGS="$LDFLAGS2"
1045 ])
1046
1047 dnl ** check whether we need -ldl to get dlopen()
1048 AC_CHECK_LIB([dl], [dlopen])
1049 AC_CHECK_LIB([dl], [dlopen], [AC_SUBST([CabalHaveLibdl], [True])], [AC_SUBST([CabalHaveLibdl], [False])])
1050
1051 dnl --------------------------------------------------
1052 dnl * Miscellaneous feature tests
1053 dnl --------------------------------------------------
1054
1055 dnl ** can we get alloca?
1056 AC_FUNC_ALLOCA
1057
1058 dnl ** working vfork?
1059 AC_FUNC_FORK
1060
1061 dnl ** determine whether or not const works
1062 AC_C_CONST
1063
1064 dnl ** are we big endian?
1065 AC_C_BIGENDIAN
1066 FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN
1067
1068 dnl ** check for leading underscores in symbol names
1069 FP_LEADING_UNDERSCORE
1070
1071 FP_VISIBILITY_HIDDEN
1072
1073 dnl ** check for librt
1074 AC_CHECK_LIB([rt], [clock_gettime])
1075 AC_CHECK_LIB([rt], [clock_gettime], [AC_SUBST([CabalHaveLibrt], [True])], [AC_SUBST([CabalHaveLibrt], [False])])
1076 AC_CHECK_FUNCS(clock_gettime timer_settime)
1077 FP_CHECK_TIMER_CREATE
1078
1079 dnl ** check for Apple's "interesting" long double compatibility scheme
1080 AC_MSG_CHECKING(for printf\$LDBLStub)
1081 AC_TRY_LINK_FUNC(printf\$LDBLStub,
1082     [
1083         AC_MSG_RESULT(yes)
1084         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[1],
1085             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
1086     ],
1087     [
1088         AC_MSG_RESULT(no)
1089         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[0],
1090             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
1091     ])
1092
1093 dnl Some platforms (e.g. Android's Bionic) have pthreads support available
1094 dnl without linking against libpthread. Check whether -lpthread is necessary
1095 dnl to use pthreads.
1096 dnl
1097 dnl Note that it is important that this happens before we AC_CHECK_LIB(thread)
1098 AC_MSG_CHECKING(whether -lpthread is needed for pthreads)
1099 AC_CHECK_FUNC(pthread_create,
1100     [
1101         AC_MSG_RESULT(no)
1102         AC_SUBST([CabalNeedLibpthread],[False])
1103         need_lpthread=0
1104     ],
1105     [
1106         AC_CHECK_LIB(pthread, pthread_create,
1107             [
1108                 AC_MSG_RESULT(yes)
1109                 AC_SUBST([CabalNeedLibpthread],[True])
1110                 need_lpthread=1
1111             ],
1112             [
1113                 AC_SUBST([CabalNeedLibpthread],[False])
1114                 AC_MSG_RESULT([no pthreads support found.])
1115                 need_lpthread=0
1116             ])
1117     ])
1118 AC_DEFINE_UNQUOTED([NEED_PTHREAD_LIB], [$need_lpthread],
1119     [Define 1 if we need to link code using pthreads with -lpthread])
1120
1121 dnl ** pthread_setname_np is a recent addition to glibc, and OS X has
1122 dnl    a different single-argument version.
1123 AC_CHECK_LIB(pthread, pthread_setname_np)
1124 AC_MSG_CHECKING(for pthread_setname_np)
1125 AC_TRY_LINK(
1126 [
1127 #define _GNU_SOURCE
1128 #include <pthread.h>
1129 ],
1130 [pthread_setname_np(pthread_self(), "name");],
1131     AC_MSG_RESULT(yes)
1132     AC_DEFINE([HAVE_PTHREAD_SETNAME_NP], [1],
1133       [Define to 1 if you have the glibc version of pthread_setname_np]),
1134     AC_MSG_RESULT(no)
1135 )
1136
1137 dnl ** check for eventfd which is needed by the I/O manager
1138 AC_CHECK_HEADERS([sys/eventfd.h])
1139 AC_CHECK_FUNCS([eventfd])
1140
1141 dnl ** Check for __thread support in the compiler
1142 AC_MSG_CHECKING(for __thread support)
1143 AC_COMPILE_IFELSE(
1144   [ AC_LANG_SOURCE([[__thread int tester = 0;]]) ],
1145   [
1146    AC_MSG_RESULT(yes)
1147    AC_DEFINE([CC_SUPPORTS_TLS],[1],[Define to 1 if __thread is supported])
1148   ],
1149   [
1150    AC_MSG_RESULT(no)
1151    AC_DEFINE([CC_SUPPORTS_TLS],[0],[Define to 1 if __thread is supported])
1152   ])
1153
1154 dnl large address space support (see includes/rts/storage/MBlock.h)
1155 dnl
1156 dnl Darwin has vm_allocate/vm_protect
1157 dnl Linux has mmap(MAP_NORESERVE)/madv(MADV_DONTNEED)
1158 dnl FreeBSD, Solaris and maybe other have MAP_NORESERVE/MADV_FREE
1159 dnl (They also have MADV_DONTNEED, but it means something else!)
1160 dnl
1161 dnl Windows has VirtualAlloc MEM_RESERVE/MEM_COMMIT, however
1162 dnl it counts page-table space as committed memory, and so quickly
1163 dnl runs out of paging file when we have multiple processes reserving
1164 dnl 1TB of address space, we get the following error:
1165 dnl    VirtualAlloc MEM_RESERVE 1099512676352 bytes failed: The paging file is too small for this operation to complete.
1166 dnl
1167
1168 AC_ARG_ENABLE(large-address-space,
1169     [AC_HELP_STRING([--enable-large-address-space],
1170         [Use a single large address space on 64 bit systems (enabled by default on 64 bit platforms)])],
1171     EnableLargeAddressSpace=$enableval,
1172     EnableLargeAddressSpace=yes
1173 )
1174
1175 use_large_address_space=no
1176 if test "$ac_cv_sizeof_void_p" -eq 8 ; then
1177     if test "x$EnableLargeAddressSpace" = "xyes" ; then
1178         if test "$ghc_host_os" = "darwin" ; then
1179             use_large_address_space=yes
1180         elif test "$ghc_host_os" = "openbsd" ; then
1181             # as of OpenBSD 5.8 (2015), OpenBSD does not support mmap with MAP_NORESERVE.
1182             # The flag MAP_NORESERVE is supported for source compatibility reasons,
1183             # but is completely ignored by OS mmap
1184             use_large_address_space=no
1185         else
1186             AC_CHECK_DECLS([MAP_NORESERVE, MADV_FREE, MADV_DONTNEED],[],[],
1187                 [
1188                 #include <unistd.h>
1189                 #include <sys/types.h>
1190                 #include <sys/mman.h>
1191                 #include <fcntl.h>
1192             ])
1193             if test "$ac_cv_have_decl_MAP_NORESERVE" = "yes" &&
1194                 test "$ac_cv_have_decl_MADV_FREE" = "yes" ||
1195                 test "$ac_cv_have_decl_MADV_DONTNEED" = "yes" ; then
1196                     use_large_address_space=yes
1197             fi
1198         fi
1199     fi
1200 fi
1201 if test "$use_large_address_space" = "yes" ; then
1202    AC_DEFINE([USE_LARGE_ADDRESS_SPACE], [1], [Enable single heap address space support])
1203 fi
1204
1205 dnl ** Use MMAP in the runtime linker?
1206 dnl --------------------------------------------------------------
1207
1208 case ${TargetOS} in
1209     linux|linux-android|freebsd|dragonfly|netbsd|openbsd|kfreebsdgnu|gnu|solaris2)
1210         RtsLinkerUseMmap=1
1211         ;;
1212     darwin|ios|watchos|tvos)
1213         # Don't use mmap on powerpc/darwin as the mmap there doesn't support
1214         # reallocating. Reallocating is needed to allocate jump islands just
1215         # after each object image. Jumps to these jump islands use relative
1216         # branches which are limited to offsets that can be represented in
1217         # 24-bits.
1218         if test "$TargetArch" != "powerpc" ; then
1219             RtsLinkerUseMmap=1
1220         else
1221             RtsLinkerUseMmap=0
1222         fi
1223         ;;
1224     *)
1225         # Windows (which doesn't have mmap) and everything else.
1226         RtsLinkerUseMmap=0
1227         ;;
1228     esac
1229
1230 AC_DEFINE_UNQUOTED([RTS_LINKER_USE_MMAP], [$RtsLinkerUseMmap],
1231                    [Use mmap in the runtime linker])
1232
1233 dnl ** Have libdw?
1234 dnl --------------------------------------------------------------
1235 UseLibdw=NO
1236 USE_LIBDW=0
1237 AC_ARG_ENABLE(dwarf-unwind,
1238     [AC_HELP_STRING([--enable-dwarf-unwind],
1239         [Enable DWARF unwinding support in the runtime system via elfutils' libdw [default=no]])],
1240     [AC_CHECK_LIB(dw, dwfl_attach_state, [UseLibdw=YES], [UseLibdw=NO])],
1241     [UseLibdw=NO]
1242 )
1243 AC_SUBST(UseLibdw)
1244 if test $UseLibdw = "YES" ; then
1245         USE_LIBDW=1
1246   AC_SUBST([CabalHaveLibdw],[True])
1247 else
1248   AC_SUBST([CabalHaveLibdw],[False])
1249 fi
1250 AC_DEFINE_UNQUOTED([USE_LIBDW], [$USE_LIBDW], [Set to 1 to use libdw])
1251
1252 dnl ** Have libnuma?
1253 dnl --------------------------------------------------------------
1254 HaveLibNuma=0
1255 AC_CHECK_HEADERS([numa.h numaif.h])
1256
1257 if test "$ac_cv_header_numa_h$ac_cv_header_numaif_h" = "yesyes" ; then
1258     AC_CHECK_LIB(numa, numa_available,HaveLibNuma=1)
1259 fi
1260 AC_DEFINE_UNQUOTED([HAVE_LIBNUMA], [$HaveLibNuma], [Define to 1 if you have libnuma])
1261 if test $HaveLibNuma = "YES" ; then
1262   AC_SUBST([CabalHaveLibNuma],[True])
1263 else
1264   AC_SUBST([CabalHaveLibNuma],[False])
1265 fi
1266
1267
1268 dnl ** Documentation
1269 dnl --------------------------------------------------------------
1270 if test -n "$SPHINXBUILD"; then
1271     BUILD_MAN=YES
1272     BUILD_SPHINX_HTML=YES
1273     if test -n "$XELATEX"; then
1274         BUILD_SPHINX_PDF=YES
1275     else
1276         BUILD_SPHINX_PDF=NO
1277     fi
1278 else
1279     BUILD_MAN=NO
1280     BUILD_SPHINX_HTML=NO
1281     BUILD_SPHINX_PDF=NO
1282 fi
1283 AC_SUBST(BUILD_MAN)
1284 AC_SUBST(BUILD_SPHINX_HTML)
1285 AC_SUBST(BUILD_SPHINX_PDF)
1286
1287 LIBRARY_VERSION(base)
1288 LIBRARY_VERSION(Cabal, Cabal/Cabal)
1289 LIBRARY_VERSION(ghc-prim)
1290 LIBRARY_VERSION(ghc-compact)
1291 LIBRARY_ghc_VERSION="$ProjectVersion"
1292 AC_SUBST(LIBRARY_ghc_VERSION)
1293
1294 if grep '       ' compiler/ghc.cabal.in 2>&1 >/dev/null; then
1295    AC_MSG_ERROR([compiler/ghc.cabal.in contains tab characters; please remove them])
1296 fi
1297
1298 # Create the configuration for the Hadrian build system if it is present
1299 if test -e hadrian/cfg/system.config.in; then
1300     AC_CONFIG_FILES([hadrian/cfg/system.config])
1301 fi
1302
1303 # We got caught by
1304 #     http://savannah.gnu.org/bugs/index.php?1516
1305 #     $(eval ...) inside conditionals causes errors
1306 # with make 3.80, so warn the user if it looks like they're about to
1307 # try to use it.
1308 # We would use "grep -q" here, but Solaris's grep doesn't support it.
1309 print_make_warning=""
1310 checkMake380() {
1311     make_ver=`$1 --version 2>&1 | head -1`
1312     if echo "$make_ver" | grep 'GNU Make 3\.80' > /dev/null
1313     then
1314         print_make_warning="true"
1315     fi
1316     if echo "$make_ver" | grep 'GNU Make' > /dev/null
1317     then
1318         MakeCmd=$1
1319         AC_SUBST(MakeCmd)
1320     fi
1321 }
1322
1323 checkMake380 make
1324 checkMake380 gmake
1325
1326 AC_CONFIG_FILES([mk/config.mk mk/install.mk mk/project.mk rts/rts.cabal compiler/ghc.cabal ghc/ghc-bin.cabal utils/runghc/runghc.cabal utils/gen-dll/gen-dll.cabal libraries/ghc-boot/ghc-boot.cabal libraries/ghc-boot-th/ghc-boot-th.cabal libraries/ghci/ghci.cabal libraries/ghc-heap/ghc-heap.cabal settings docs/users_guide/ghc_config.py docs/index.html libraries/prologue.txt distrib/configure.ac])
1327 AC_OUTPUT
1328 [
1329 if test "$print_make_warning" = "true"; then
1330    echo
1331    echo "WARNING: It looks like \"$MakeCmd\" is GNU make 3.80."
1332    echo "This version cannot be used to build GHC."
1333    echo "Please use GNU make >= 3.81."
1334 fi
1335
1336 echo "
1337 ----------------------------------------------------------------------
1338 Configure completed successfully.
1339
1340    Building GHC version  : $ProjectVersion
1341           Git commit id  : $ProjectGitCommitId
1342
1343    Build platform        : $BuildPlatform
1344    Host platform         : $HostPlatform
1345    Target platform       : $TargetPlatform
1346 "
1347
1348 echo "\
1349    Bootstrapping using   : $WithGhc
1350       which is version   : $GhcVersion
1351 "
1352
1353 if test "x$CC_LLVM_BACKEND" = "x1"; then
1354     if test "x$CC_CLANG_BACKEND" = "x1"; then
1355         CompilerName="clang        "
1356     else
1357         CompilerName="llvm-gcc     "
1358     fi
1359 else
1360     CompilerName="gcc          "
1361 fi
1362
1363 echo "\
1364    Using (for bootstrapping) : $CC_STAGE0
1365    Using $CompilerName       : $CC
1366       which is version       : $GccVersion
1367    Building a cross compiler : $CrossCompiling
1368    Unregisterised            : $Unregisterised
1369    hs-cpp       : $HaskellCPPCmd
1370    hs-cpp-flags : $HaskellCPPArgs
1371    ar           : $ArCmd
1372    ld           : $LdCmd
1373    nm           : $NmCmd
1374    libtool      : $LibtoolCmd
1375    objdump      : $ObjdumpCmd
1376    ranlib       : $RanlibCmd
1377    windres      : $WindresCmd
1378    dllwrap      : $DllWrapCmd
1379    genlib       : $GenlibCmd
1380    Happy        : $HappyCmd ($HappyVersion)
1381    Alex         : $AlexCmd ($AlexVersion)
1382    Perl         : $PerlCmd
1383    sphinx-build : $SPHINXBUILD
1384    xelatex      : $XELATEX
1385
1386    Using LLVM tools
1387       clang : $ClangCmd
1388       llc   : $LlcCmd
1389       opt   : $OptCmd"
1390
1391 if test "$HSCOLOUR" = ""; then
1392 echo "
1393    HsColour was not found; documentation will not contain source links
1394 "
1395 else
1396 echo "\
1397    HsColour : $HSCOLOUR
1398 "
1399 fi
1400
1401 echo "\
1402    Tools to build Sphinx HTML documentation available: $BUILD_SPHINX_HTML
1403    Tools to build Sphinx PDF documentation available: $BUILD_SPHINX_PDF"
1404
1405 echo "----------------------------------------------------------------------
1406 "
1407
1408 echo "\
1409 For a standard build of GHC (fully optimised with profiling), type (g)make.
1410
1411 To make changes to the default build configuration, copy the file
1412 mk/build.mk.sample to mk/build.mk, and edit the settings in there.
1413
1414 For more information on how to configure your GHC build, see
1415    http://ghc.haskell.org/trac/ghc/wiki/Building
1416 "]