Add configure flags for the location of GMP includes/library; fixes #4022
[ghc.git] / configure.ac
1 dnl == autoconf source for the Glasgow FP tools ==
2 dnl (run "grep '^dnl \*' configure.ac | sed -e 's/dnl / /g; s/\*\*/   +/g;'"
3 dnl  (or some such) to see the outline of this file)
4 dnl
5 #
6 # (c) The University of Glasgow 1994-2004
7 #
8 # Configure script template for GHC
9 #
10 # Process with 'autoreconf' to get a working configure script.
11 #
12 # For the generated configure script, do "./configure --help" to
13 # see what flags are available. (Better yet, read the documentation!)
14 #
15
16 AC_INIT([The Glorious Glasgow Haskell Compilation System], [6.13], [glasgow-haskell-bugs@haskell.org], [ghc])
17
18 # Set this to YES for a released version, otherwise NO
19 : ${RELEASE=NO}
20
21 # The primary version (e.g. 6.7, 6.6.1) is set in the AC_INIT line
22 # above.  If this is not a released version, then we will append the
23 # date to the version number (e.g. 6.7.20070204).  The date is
24 # constructed by finding the date of the most recent patch in the
25 # darcs repository.  If this is a source distribution (not a darcs
26 # checkout), then we ship a file 'VERSION' containing the full version
27 # when the source distribution was created.
28
29 if test ! -f mk/config.h.in; then
30    echo "mk/config.h.in doesn't exist: perhaps you haven't run 'perl boot'?"
31    exit 1
32 fi
33
34 AC_SUBST([CONFIGURE_ARGS], [$ac_configure_args])
35
36 dnl ----------------------------------------------------------
37 dnl ** Find unixy sort and find commands, 
38 dnl ** which are needed by FP_SETUP_PROJECT_VERSION
39
40 dnl ** Find find command (for Win32's benefit)
41 FP_PROG_FIND
42
43 dnl ** Find sort command (for the benefit of Win32 environs)
44 FP_PROG_SORT
45
46 dnl ----------------------------------------------------------
47 FP_SETUP_PROJECT_VERSION
48
49 # Hmmm, we fix the RPM release number to 1 here... Is this convenient?
50 AC_SUBST([release], [1])
51
52 # First off, a distrib sanity check..
53 AC_CONFIG_SRCDIR([mk/config.mk.in])
54
55 dnl * We require autoconf version 2.52
56 dnl We need 2.50 due to the use of AC_SYS_LARGEFILE and AC_MSG_NOTICE.
57 dnl We need 2.52 due to the use of AS_TR_CPP and AS_TR_SH.
58 AC_PREREQ([2.52])
59
60 # -------------------------------------------------------------------------
61 # Prepare to generate the following header files
62 #
63 #
64 AC_CONFIG_HEADER(mk/config.h)
65
66 # No, semi-sadly, we don't do `--srcdir'...
67 if test x"$srcdir" != 'x.' ; then
68     echo "This configuration does not support the \`--srcdir' option.."
69     exit 1
70 fi
71
72 dnl --------------------------------------------------------------
73 dnl * Project specific configuration options
74 dnl --------------------------------------------------------------
75 dnl What follows is a bunch of options that can either be configured
76 dnl through command line options to the configure script or by
77 dnl supplying defns in the build tree's mk/build.mk. Having the option to
78 dnl use either is considered a Feature.
79
80 dnl ** What command to use to compile compiler sources ?
81 dnl --------------------------------------------------------------
82
83 AC_ARG_WITH([ghc],
84 [AC_HELP_STRING([--with-ghc=ARG],
85   [Use ARG as the path to GHC  [default=autodetect]])],
86   [WithGhc="$withval"],
87   [if test "$GHC" = ""; then
88     AC_PATH_PROG([GHC], [ghc])
89   fi
90   WithGhc="$GHC"])
91
92 dnl ** Booting from .hc files?
93 dnl --------------------------------------------------------------
94 AC_ARG_ENABLE(hc-boot,
95 [AC_HELP_STRING([--enable-hc-boot],
96 [Boot the Glasgow Haskell Compiler from intermediate .hc files.
97  (This option is mostly of interest to porters.) [default=no]])],
98 [ if test x"$enableval" = x"yes"; then
99         BootingFromHc=YES
100   else
101         BootingFromHc=NO
102   fi
103 ],
104 [BootingFromHc=NO]
105 )
106 AC_SUBST(BootingFromHc)
107
108 AC_ARG_ENABLE(bootstrap-with-devel-snapshot,
109 [AC_HELP_STRING([--enable-bootstrap-with-devel-snapshot],
110                 [Allow bootstrapping using a development snapshot of GHC.  This is not guaranteed to work.])],
111         EnableBootstrapWithDevelSnaphost=YES,
112         EnableBootstrapWithDevelSnaphost=NO
113 )
114
115 if test "$WithGhc" != ""; then
116   FPTOOLS_GHC_VERSION([GhcVersion], [GhcMajVersion], [GhcMinVersion], [GhcPatchLevel])dnl
117
118   if test "$GhcMajVersion" = "unknown" -o "$GhcMinVersion" = "unknown"; then
119      AC_MSG_ERROR([Cannot determine the version of $WithGhc.  Is it really GHC?])
120   fi
121
122   AC_SUBST(GhcVersion)dnl
123   AC_SUBST(GhcMajVersion)dnl
124   AC_SUBST(GhcMinVersion)dnl
125   AC_SUBST(GhcPatchLevel)dnl
126   GhcMinVersion2=`echo "$GhcMinVersion" | sed 's/^\\(.\\)$/0\\1/'`
127   GhcCanonVersion="$GhcMajVersion$GhcMinVersion2"
128   FP_COMPARE_VERSIONS($GhcVersion,[-ge],[6.10.2],
129                       [ghc_ge_6102=YES], [ghc_ge_6102=NO])
130   if test $GhcCanonVersion -ge 611; then ghc_ge_611=YES; else ghc_ge_611=NO; fi
131   if test $GhcCanonVersion -ge 613; then ghc_ge_613=YES; else ghc_ge_613=NO; fi
132   AC_SUBST(ghc_ge_6102)dnl
133   AC_SUBST(ghc_ge_611)dnl
134   AC_SUBST(ghc_ge_613)dnl
135 fi
136
137 dnl ** Must have GHC to build GHC, unless --enable-hc-boot is on
138 if test "$BootingFromHc" = "NO" -a -d "$srcdir/compiler"; then
139   if test "$WithGhc" = ""; then
140      AC_MSG_ERROR([GHC is required unless bootstrapping from .hc files.])
141   fi
142   FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[6.10],
143     [AC_MSG_ERROR([GHC version 6.10 or later is required to compile GHC.])])dnl
144
145   if test `expr $GhcMinVersion % 2` = "1"; then
146      if test "$EnableBootstrapWithDevelSnaphost" = "NO"; then
147         AC_MSG_ERROR([
148      $WithGhc is a development snapshot of GHC, version $GhcVersion.
149      Bootstrapping using this version of GHC is not supported, and may not
150      work.  Use --enable-bootstrap-with-devel-snapshot to try it anyway,
151      or --with-ghc to specify a different GHC to use.])
152      fi
153   fi
154 fi;
155
156 # GHC is passed to Cabal, so we need a native path
157 if test "${WithGhc}" != ""
158 then
159     ghc_host=`"${WithGhc}" +RTS --info | grep 'Host platform' | sed -e 's/.*, "//' -e 's/")//'`
160
161     if test "$ghc_host" = "i386-unknown-mingw32"
162     then
163         if test "${OSTYPE}" = "msys"
164         then
165             WithGhc=`echo "${WithGhc}" | sed "s#^/\([a-zA-Z]\)/#\1:/#"`
166         else
167             # Canonicalise to <drive>:/path/to/ghc
168             WithGhc=`cygpath -m "${WithGhc}"`
169         fi
170         echo "GHC path canonicalised to: ${WithGhc}"
171     fi
172 fi
173 AC_SUBST([WithGhc])
174
175 dnl ** Without optimization some INLINE trickery fails for GHCi
176 SRC_CC_OPTS="-O"
177
178 dnl Allow to specify iconv options to the toplevel configure script
179 dnl so they can be properly passed to sub-builds.
180 dnl Note: ICONV_LIB_DIRS and ICONV_INCLUDE_DIRS are not predefined
181 dnl to the empty string to allow them to be overridden from the
182 dnl environment.
183
184 AC_ARG_WITH([iconv-includes],
185   [AC_HELP_STRING([--with-iconv-includes],
186     [directory containing iconv.h])],
187     [ICONV_INCLUDE_DIRS=$withval])
188
189 AC_ARG_WITH([iconv-libraries],
190   [AC_HELP_STRING([--with-iconv-libraries],
191     [directory containing iconv library])],
192     [ICONV_LIB_DIRS=$withval])
193
194 AC_SUBST(ICONV_INCLUDE_DIRS)
195 AC_SUBST(ICONV_LIB_DIRS)
196
197 dnl Allow to specify gmp options to the toplevel configure script
198 dnl so they can be properly passed to sub-builds.
199
200 AC_ARG_WITH([gmp-includes],
201   [AC_HELP_STRING([--with-gmp-includes],
202     [directory containing gmp.h])],
203     [GMP_INCLUDE_DIRS=$withval])
204
205 AC_ARG_WITH([gmp-libraries],
206   [AC_HELP_STRING([--with-gmp-libraries],
207     [directory containing gmp library])],
208     [GMP_LIB_DIRS=$withval])
209
210 AC_SUBST(GMP_INCLUDE_DIRS)
211 AC_SUBST(GMP_LIB_DIRS)
212
213 dnl--------------------------------------------------------------------
214 dnl * Choose host(/target/build) platform
215 dnl--------------------------------------------------------------------
216 dnl If we aren't explicitly told what values to use with configure flags,
217 dnl we ask the bootstrapping compiler what platform it is for
218
219 if test "${WithGhc}" != ""
220 then
221         bootstrap_host=`"${WithGhc}" +RTS --info | grep '^ ,("Host platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
222         bootstrap_target=`"${WithGhc}" +RTS --info | grep '^ ,("Target platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
223         if test "$bootstrap_host" != "$bootstrap_target"
224         then
225                 echo "Bootstrapping GHC is a cross compiler. This probably isn't going to work"
226         fi
227 fi
228
229 # We have to run these unconditionally, but we may discard their
230 # results in the following code
231 AC_CANONICAL_BUILD
232 AC_CANONICAL_HOST
233 AC_CANONICAL_TARGET
234
235 # If no argument was given for a configuration variable, then discard
236 # the guessed canonical system and use the configuration of the
237 # bootstrapping ghc. If an argument was given, map it from gnu format
238 # to ghc format.
239 #
240 # For why we do it this way, see: #3637, #1717, #2951
241
242 if test "$build_alias" = ""
243 then
244     if test "${WithGhc}" != ""
245     then
246         build=$bootstrap_target
247         echo "Build platform inferred as: $build"
248     else
249         echo "Can't work out build platform"
250         exit 1
251     fi
252
253     BuildArch=`echo "$build" | sed 's/-.*//'`
254     BuildVendor=`echo "$build" | sed -e 's/.*-\(.*\)-.*/\1/'`
255     BuildOS=`echo "$build" | sed 's/.*-//'`
256 else
257     GHC_CONVERT_CPU([$build_cpu], [BuildArch])
258     GHC_CONVERT_VENDOR([$build_vendor], [BuildVendor])
259     GHC_CONVERT_OS([$build_os], [BuildOS])
260 fi
261
262 if test "$host_alias" = ""
263 then
264     if test "${WithGhc}" != ""
265     then
266         host=$bootstrap_target
267         echo "Host platform inferred as: $host"
268     else
269         echo "Can't work out host platform"
270         exit 1
271     fi
272
273     HostArch=`echo "$host" | sed 's/-.*//'`
274     HostVendor=`echo "$host" | sed -e 's/.*-\(.*\)-.*/\1/'`
275     HostOS=`echo "$host" | sed 's/.*-//'`
276 else
277     GHC_CONVERT_CPU([$host_cpu], [HostArch])
278     GHC_CONVERT_VENDOR([$host_vendor], [HostVendor])
279     GHC_CONVERT_OS([$host_os], [HostOS])
280 fi
281
282 if test "$target_alias" = ""
283 then
284     if test "${WithGhc}" != ""
285     then
286         target=$bootstrap_target
287         echo "Target platform inferred as: $target"
288     else
289         echo "Can't work out target platform"
290         exit 1
291     fi
292
293     TargetArch=`echo "$target" | sed 's/-.*//'`
294     TargetVendor=`echo "$target" | sed -e 's/.*-\(.*\)-.*/\1/'`
295     TargetOS=`echo "$target" | sed 's/.*-//'`
296 else
297     GHC_CONVERT_CPU([$target_cpu], [TargetArch])
298     GHC_CONVERT_VENDOR([$target_vendor], [TargetVendor])
299     GHC_CONVERT_OS([$target_os], [TargetOS])
300 fi
301
302 exeext=''
303 soext='.so'
304 case $host in
305 *-unknown-cygwin32)
306     AC_MSG_WARN([GHC does not support the Cygwin target at the moment])
307     AC_MSG_WARN([I'm assuming you wanted to build for i386-unknown-mingw32])
308     exit 1
309     ;;
310 *-unknown-mingw32)
311     exeext='.exe'
312     soext='.dll'
313     ;;
314 i386-apple-darwin|powerpc-apple-darwin)
315     soext='.dylib'
316     CFLAGS="$CFLAGS -m32"
317     LDFLAGS="$LDFLAGS -m32"
318     CONF_CC_OPTS="$CONF_CC_OPTS -m32"
319     CONF_LD_OPTS="$CONF_LD_OPTS -m32"
320     ;;
321 x86_64-apple-darwin)
322     soext='.dylib'
323     CFLAGS="$CFLAGS -m64"
324     LDFLAGS="$LDFLAGS -m64"
325     CONF_CC_OPTS="$CONF_CC_OPTS -m64"
326     CONF_LD_OPTS="$CONF_LD_OPTS -m64"
327     ;;
328 esac
329
330 checkArch() {
331     case $1 in
332     alpha|arm|hppa|hppa1_1|i386|ia64|m68k|mips|mipseb|mipsel|powerpc|powerpc64|rs6000|s390|sparc|sparc64|vax|x86_64)
333         ;;
334     *)
335         echo "Unknown arch $1"
336         exit 1
337         ;;
338     esac
339 }
340
341 checkVendor() {
342     case $1 in
343     dec|unknown|hp|apple|next|sun|sgi|ibm)
344         ;;
345     *)
346         echo "Unknown vendor $1"
347         exit 1
348         ;;
349     esac
350 }
351
352 checkOS() {
353     case $1 in
354     linux|freebsd|netbsd|openbsd|dragonfly|osf1|osf3|hpux|linuxaout|kfreebsdgnu|freebsd2|solaris2|cygwin32|mingw32|darwin|gnu|nextstep2|nextstep3|sunos4|ultrix|irix|aix|haiku)
355         ;;
356     *)
357         echo "Unknown OS '$1'"
358         exit 1
359         ;;
360     esac
361 }
362
363 BuildPlatform="$BuildArch-$BuildVendor-$BuildOS"
364 BuildPlatform_CPP=`echo "$BuildPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
365 BuildArch_CPP=`    echo "$BuildArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
366 BuildVendor_CPP=`  echo "$BuildVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
367 BuildOS_CPP=`      echo "$BuildOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
368
369 checkArch "$BuildArch"
370 checkVendor "$BuildVendor"
371 checkOS "$BuildOS"
372
373 HostPlatform="$HostArch-$HostVendor-$HostOS"
374 HostPlatform_CPP=`echo "$HostPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
375 HostArch_CPP=`    echo "$HostArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
376 HostVendor_CPP=`  echo "$HostVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
377 HostOS_CPP=`      echo "$HostOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
378
379 checkArch "$HostArch"
380 checkVendor "$HostVendor"
381 checkOS "$HostOS"
382
383 TargetPlatform="$TargetArch-$TargetVendor-$TargetOS"
384 TargetPlatform_CPP=`echo "$TargetPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
385 TargetArch_CPP=`    echo "$TargetArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
386 TargetVendor_CPP=`  echo "$TargetVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
387 TargetOS_CPP=`      echo "$TargetOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
388
389 checkArch "$TargetArch"
390 checkVendor "$TargetVendor"
391 checkOS "$TargetOS"
392
393 AC_SUBST(BuildPlatform)
394 AC_SUBST(HostPlatform)
395 AC_SUBST(TargetPlatform)
396 AC_SUBST(HostPlatform_CPP)
397 AC_SUBST(BuildPlatform_CPP)
398 AC_SUBST(TargetPlatform_CPP)
399
400 AC_SUBST(HostArch_CPP)
401 AC_SUBST(BuildArch_CPP)
402 AC_SUBST(TargetArch_CPP)
403
404 AC_SUBST(HostOS_CPP)
405 AC_SUBST(BuildOS_CPP)
406 AC_SUBST(TargetOS_CPP)
407
408 AC_SUBST(HostVendor_CPP)
409 AC_SUBST(BuildVendor_CPP)
410 AC_SUBST(TargetVendor_CPP)
411
412 AC_SUBST(exeext)
413 AC_SUBST(soext)
414
415 AC_ARG_WITH(hc,
416 [AC_HELP_STRING([--with-hc=ARG],
417         [Use ARG as the path to the compiler for compiling ordinary
418          Haskell code  (default= value of --with-ghc)])],
419 [WithHc="$withval"],
420 [WithHc=$WithGhc]
421 )
422 AC_SUBST(WithHc)
423
424 AC_PATH_PROGS(NHC,nhc nhc98)
425 AC_PATH_PROG(HBC,hbc)
426
427 # This uses GHC, so put it after the "GHC is required" check above:
428 FP_FIND_ROOT
429
430 if test "$HostOS" = "mingw32"
431 then
432     CC="$hardtop/inplace/mingw/bin/gcc.exe"
433     LD="$hardtop/inplace/mingw/bin/ld.exe"
434     NM="$hardtop/inplace/mingw/bin/nm.exe"
435     fp_prog_ar_raw="$hardtop/inplace/mingw/bin/ar.exe"
436     if ! test -d inplace/mingw ||
437          test inplace/mingw -ot ghc-tarballs/mingw/binutils*.tar.gz ||
438          test inplace/mingw -ot ghc-tarballs/mingw/gcc-core*.tar.gz ||
439          test inplace/mingw -ot ghc-tarballs/mingw/gcc-g++*.tar.gz ||
440          test inplace/mingw -ot ghc-tarballs/mingw/libcrypt*.tar.bz2 ||
441          test inplace/mingw -ot ghc-tarballs/mingw/mingw-runtime*.tar.gz ||
442          test inplace/mingw -ot ghc-tarballs/mingw/w32api*.tar.gz
443     then
444         AC_MSG_NOTICE([Making in-tree mingw tree])
445         rm -rf inplace/mingw
446         mkdir inplace
447         mkdir inplace/mingw
448         (
449             cd inplace/mingw &&
450             tar -zxf ../../ghc-tarballs/mingw/binutils*.tar.gz &&
451             tar -zxf ../../ghc-tarballs/mingw/gcc-core*.tar.gz &&
452             tar -zxf ../../ghc-tarballs/mingw/gcc-g++*.tar.gz &&
453             tar -jxf ../../ghc-tarballs/mingw/libcrypt*.tar.bz2 &&
454             tar -zxf ../../ghc-tarballs/mingw/mingw-runtime*.tar.gz &&
455             tar -zxf ../../ghc-tarballs/mingw/w32api*.tar.gz &&
456             mv bin/gcc.exe bin/realgcc.exe
457         )
458         inplace/mingw/bin/realgcc.exe driver/gcc/gcc.c driver/utils/cwrapper.c driver/utils/getLocation.c -Idriver/utils -o inplace/mingw/bin/gcc.exe
459         AC_MSG_NOTICE([In-tree mingw tree created])
460     fi
461     if ! test -d inplace/perl ||
462          test inplace/perl -ot ghc-tarballs/perl/ghc-perl*.tar.gz
463     then
464         AC_MSG_NOTICE([Making in-tree perl tree])
465         rm -rf inplace/perl
466         mkdir inplace
467         mkdir inplace/perl
468         (
469             cd inplace/perl &&
470             tar -zxf ../../ghc-tarballs/perl/ghc-perl*.tar.gz
471         )
472         AC_MSG_NOTICE([In-tree perl tree created])
473     fi
474 fi
475
476 dnl ** Which gcc to use?
477 dnl --------------------------------------------------------------
478 FP_ARG_WITH_PATH_GNU_PROG([CC], [gcc])
479 export CC
480 WhatGccIsCalled="$CC"
481 AC_SUBST(WhatGccIsCalled)
482
483 dnl ** Which ld to use?
484 dnl --------------------------------------------------------------
485 FP_ARG_WITH_PATH_GNU_PROG([LD], [ld])
486 LdCmd="$LD"
487 AC_SUBST([LdCmd])
488
489 dnl ** Which nm to use?
490 dnl --------------------------------------------------------------
491 FP_ARG_WITH_PATH_GNU_PROG([NM], [nm])
492 NmCmd="$NM"
493 AC_SUBST([NmCmd])
494
495 dnl ** Mac OS X: explicit deployment target
496 dnl --------------------------------------------------------------
497 AC_ARG_WITH([macosx-deployment-target],
498 [AC_HELP_STRING([--with-macosx-deployment-target=VERSION],
499         [Build for Mac OS VERSION and higher  (default= version of build host)])],
500 [FP_MACOSX_DEPLOYMENT_TARGET="$withval"
501  if test "x$TargetOS_CPP-$TargetVendor_CPP" != "xdarwin-apple"; then
502    # ignore everywhere, but on Mac OS
503    AC_MSG_WARN([--macosx-deployment-target is only available on Mac OS X])
504    FP_MACOSX_DEPLOYMENT_TARGET=none
505  fi],
506 [FP_MACOSX_DEPLOYMENT_TARGET=none]
507 )
508 FP_CHECK_MACOSX_DEPLOYMENT_TARGET
509 AC_SUBST(MACOSX_DEPLOYMENT_VERSION)
510 AC_SUBST(MACOSX_DEPLOYMENT_SDK)
511
512 dnl --------------------------------------------------------------
513 dnl End of configure script option section
514 dnl --------------------------------------------------------------
515
516
517 dnl --------------------------------------------------------------
518 dnl * General configuration checks
519 dnl --------------------------------------------------------------
520
521 dnl ** Can the unix package be built?
522 dnl --------------------------------------------------------------
523
524 if test x"$TargetPlatform" = x"i386-unknown-mingw32"; then
525    GhcLibsWithUnix=NO
526 else
527    GhcLibsWithUnix=YES
528 fi
529 AC_SUBST([GhcLibsWithUnix])
530
531 dnl ** does #! work?
532 AC_SYS_INTERPRETER()
533
534 dnl ** look for `perl', but only in /bin on Windows
535 case $HostOS_CPP in
536 cygwin32|mingw32)
537       AC_CHECK_PROG(PerlCmd,perl,/bin/perl,,/bin)
538       if test -z "$PerlCmd"; then
539          echo "You must install the version of Perl shipped with GHC"
540          echo "(or a compatible one) in /bin."
541          exit 1
542       fi
543    ;;
544 *)
545    AC_PATH_PROG(PerlCmd,perl)
546    if test -z "$PerlCmd"; then
547       echo "You must install perl before you can continue"
548       echo "Perhaps it is already installed, but not in your PATH?"
549       exit 1
550    else
551    FPTOOLS_CHECK_PERL_VERSION
552    fi
553    ;;
554 esac
555
556 dnl ** does #! path/to/perl work? (sometimes it's too long...)
557 FPTOOLS_SHEBANG_PERL
558
559 dnl ** check for Python
560 AC_PATH_PROG(PythonCmd,python)
561
562 dnl ** look for GCC and find out which version
563 dnl     Figure out which C compiler to use.  Gcc is preferred.
564 dnl     If gcc, make sure it's at least 2.1
565 dnl
566 FP_HAVE_GCC
567 FP_GCC_EXTRA_FLAGS
568
569 dnl ** figure out how to invoke cpp directly (gcc -E is no good)
570 AC_PROG_CPP
571
572 AC_SUBST(CONF_CC_OPTS)
573 AC_SUBST(CONF_LD_OPTS)
574
575 dnl ** figure out how to do context diffs
576 FP_PROG_CONTEXT_DIFF
577
578 dnl Let's make sure install-sh is executable here.  If we got it from
579 dnl a darcs repo, it might not be (see bug #978).
580 chmod +x install-sh
581 dnl ** figure out how to do a BSD-ish install
582 AC_PROG_INSTALL
583
584 dnl If you can run configure, you certainly have /bin/sh
585 AC_DEFINE([HAVE_BIN_SH], [1], [Define to 1 if you have /bin/sh.])
586
587 dnl ** how to invoke `ar' and `ranlib'
588 FP_PROG_AR_SUPPORTS_ATFILE
589 FP_PROG_AR_NEEDS_RANLIB
590 FP_PROG_AR_SUPPORTS_INPUT
591
592 dnl ** Check to see whether ln -s works
593 AC_PROG_LN_S
594
595
596 dnl ** Find the path to sed
597 AC_PATH_PROGS(SedCmd,gsed sed,sed)
598
599
600 dnl ** check for time command
601 AC_PATH_PROG(TimeCmd,time)
602
603 dnl ** check for tar
604 dnl   if GNU tar is named gtar, look for it first.
605 AC_PATH_PROGS(TarCmd,gnutar gtar tar,tar)
606
607 dnl ** check for patch
608 dnl if GNU patch is named gpatch, look for it first
609 AC_PATH_PROGS(PatchCmd,gpatch patch, patch)
610
611 dnl ** check for dtrace (currently only implemented for Mac OS X)
612 HaveDtrace=NO
613 AC_PATH_PROG(DtraceCmd,dtrace)
614 if test -n "$DtraceCmd"; then
615   if test "x$TargetOS_CPP-$TargetVendor_CPP" == "xdarwin-apple"; then
616     HaveDtrace=YES
617   fi
618 fi
619 AC_SUBST(HaveDtrace)
620
621 AC_PATH_PROG(HSCOLOUR,HsColour)
622 # HsColour is passed to Cabal, so we need a native path
623 if test "x$HostPlatform"  = "xi386-unknown-mingw32" && \
624    test "${OSTYPE}"      != "msys"                  && \
625    test "${HSCOLOUR}"    != ""
626 then
627     # Canonicalise to <drive>:/path/to/gcc
628     HSCOLOUR=`cygpath -m ${HSCOLOUR}`
629 fi
630
631 dnl ** check for DocBook toolchain
632 FP_CHECK_DOCBOOK_DTD
633 FP_DOCBOOK_XSL
634 FP_PROG_DBLATEX
635
636 FP_PROG_HSTAGS
637
638 dnl ** check for ghc-pkg command
639 FP_PROG_GHC_PKG
640
641 dnl ** check for installed happy binary + version
642 dnl    (don't do it if we're booting from .hc files though.)
643 if test "$BootingFromHc" = "NO"; then
644 FPTOOLS_HAPPY
645 fi;
646
647 dnl ** check for installed alex binary + version
648 dnl    (don't do it if we're booting from .hc files though.)
649 if test "$BootingFromHc" = "NO"; then
650 FPTOOLS_ALEX
651 fi;
652
653 dnl --------------------------------------------------
654 dnl ### program checking section ends here ###
655 dnl --------------------------------------------------
656
657 dnl --------------------------------------------------
658 dnl * Platform header file and syscall feature tests
659 dnl ### checking the state of the local header files and syscalls ###
660
661 dnl ** check for full ANSI header (.h) files
662 AC_HEADER_STDC
663
664 dnl ** Enable large file support.  NB. do this before testing the type of
665 dnl    off_t, because it will affect the result of that test.
666 AC_SYS_LARGEFILE
667
668 dnl ** check for specific header (.h) files that we are interested in
669 AC_CHECK_HEADERS([bfd.h ctype.h dirent.h dlfcn.h errno.h fcntl.h grp.h limits.h locale.h nlist.h pthread.h pwd.h signal.h sys/mman.h sys/resource.h sys/select.h sys/time.h sys/timeb.h sys/timers.h sys/times.h sys/utsname.h sys/wait.h termios.h time.h utime.h windows.h winsock.h sched.h])
670
671 dnl ** check if it is safe to include both <time.h> and <sys/time.h>
672 AC_HEADER_TIME
673
674 dnl ** do we have long longs?
675 AC_CHECK_TYPES([long long])
676
677 dnl ** what are the sizes of various types
678 AC_CHECK_SIZEOF(char,               1)
679 AC_CHECK_SIZEOF(double,             8)
680 AC_CHECK_SIZEOF(float,              4)
681 AC_CHECK_SIZEOF(int,                4)
682 AC_CHECK_SIZEOF(long,               4)
683 if test "$ac_cv_type_long_long" = yes; then
684 AC_CHECK_SIZEOF(long long,          8)
685 fi
686 AC_CHECK_SIZEOF(short,              2)
687 AC_CHECK_SIZEOF(unsigned char,      1)
688 AC_CHECK_SIZEOF(unsigned int,       4)
689 AC_CHECK_SIZEOF(unsigned long,      4)
690 if test "$ac_cv_type_long_long" = yes; then
691 AC_CHECK_SIZEOF(unsigned long long, 8)
692 fi
693 AC_CHECK_SIZEOF(unsigned short,     2)
694 AC_CHECK_SIZEOF(void *,             4)
695
696 dnl ** what are alignment constraints on various types
697 FP_CHECK_ALIGNMENT(char)
698 FP_CHECK_ALIGNMENT(double)
699 FP_CHECK_ALIGNMENT(float)
700 FP_CHECK_ALIGNMENT(int)
701 FP_CHECK_ALIGNMENT(long)
702 if test "$ac_cv_type_long_long" = yes; then
703 FP_CHECK_ALIGNMENT(long long)
704 fi
705 FP_CHECK_ALIGNMENT(short)
706 FP_CHECK_ALIGNMENT(unsigned char)
707 FP_CHECK_ALIGNMENT(unsigned int)
708 FP_CHECK_ALIGNMENT(unsigned long)
709 if test "$ac_cv_type_long_long" = yes; then
710 FP_CHECK_ALIGNMENT(unsigned long long)
711 fi
712 FP_CHECK_ALIGNMENT(unsigned short)
713 FP_CHECK_ALIGNMENT(void *)
714
715 FP_CHECK_FUNC([WinExec],
716   [@%:@include <windows.h>], [WinExec("",0)])
717
718 FP_CHECK_FUNC([GetModuleFileName],
719   [@%:@include <windows.h>], [GetModuleFileName((HMODULE)0,(LPTSTR)0,0)])
720
721 dnl ** check return type of signal handlers
722 dnl Foo: assumes we can use prototypes.
723 dnl On BCC, signal handlers have type "int(void)", elsewhere its "void(int)".
724 dnl AC_CACHE_CHECK([type of signal handlers], ac_cv_type_signal_handler,
725 dnl [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
726 dnl #include <signal.h>
727 dnl #ifdef signal
728 dnl #undef signal
729 dnl #endif
730 dnl void (*signal (int, void (*)(int)))(int);
731 dnl ]],
732 dnl [[int i;]])],
733 dnl [ac_cv_type_signal_handler=void_int],
734 dnl [ac_cv_type_signal_handler=int_void])])
735 dnl if test "$ac_cv_type_signal_handler" = void_int; then
736 dnl AC_DEFINE(VOID_INT_SIGNALS)
737 dnl fi
738
739 dnl On BCC, signal handlers have type "int(void)", elsewhere its "void(int)".
740 AC_TYPE_SIGNAL
741 if test "$ac_cv_type_signal" = void; then
742   AC_DEFINE([VOID_INT_SIGNALS], [1], [Define to 1 if signal handlers have type void (*)(int). Otherwise, they're assumed to have type int (*)(void).])
743 fi
744
745 dnl ** check for more functions
746 dnl ** The following have been verified to be used in ghc/, but might be used somewhere else, too.
747 AC_CHECK_FUNCS([getclock getrusage gettimeofday setitimer siginterrupt sysconf times ctime_r sched_setaffinity setlocale])
748
749 AC_TRY_RUN([
750 #include <sys/types.h>
751 #include <sys/time.h>
752 int main(void) {
753   struct itimerval tval;
754   tval.it_value.tv_sec = 1;
755   tval.it_value.tv_usec = 0;
756   tval.it_interval = tval.it_value;
757   return setitimer(ITIMER_VIRTUAL, &tval, (void*)0) != 0;
758 }
759 ],[AC_DEFINE([HAVE_SETITIMER_VIRTUAL], [1], [Define to 1 if setitimer accepts ITIMER_VIRTUAL, 0 else.])])
760
761 dnl ** On OS X 10.4 (at least), time.h doesn't declare ctime_r if
762 dnl ** _POSIX_C_SOURCE is defined
763 AC_CHECK_DECLS([ctime_r], , ,
764 [#define _POSIX_SOURCE 1
765 #define _POSIX_C_SOURCE 199506L
766 #include <time.h>])
767
768 dnl ** check for mingwex library
769 AC_CHECK_LIB(mingwex, closedir, HaveLibMingwEx=YES, HaveLibMingwEx=NO)
770 AC_SUBST(HaveLibMingwEx)
771
772 if test $HaveLibMingwEx = YES ; then
773   AC_DEFINE([HAVE_MINGWEX], [1], [Define to 1 if you have the mingwex library.])
774 fi
775
776 dnl ** check for math library
777 dnl    Keep that check as early as possible.
778 dnl    as we need to know whether we need libm
779 dnl    for math functions or not
780 dnl    (see http://hackage.haskell.org/trac/ghc/ticket/3730)
781 AC_SEARCH_LIBS(atan, m, 
782   [AC_DEFINE([HAVE_LIBM], [1], [Define to 1 if you need to link with libm])])
783
784 dnl ** check whether this machine has BFD and liberty installed (used for debugging)
785 dnl    the order of these tests matters: bfd needs liberty
786 AC_CHECK_LIB(iberty, xmalloc)
787 AC_CHECK_LIB(bfd,    bfd_init)
788
789 dnl ################################################################
790 dnl Check for libraries
791 dnl ################################################################
792
793 dnl ** check whether we need -ldl to get dlopen()
794
795 AC_CHECK_LIB(dl, dlopen,
796     [HaveLibDL=YES
797      AC_DEFINE([HAVE_LIBDL], [1], [Define to 1 if you need -ldl to get dlopen().])
798      LIBS="$LIBS -ldl"],
799     [HaveLibDL=NO])
800 AC_SUBST(HaveLibDL)
801
802 dnl --------------------------------------------------
803 dnl * Miscellaneous feature tests
804 dnl --------------------------------------------------
805
806 dnl ** can we get alloca?
807 AC_FUNC_ALLOCA
808
809 dnl ** Working vfork?
810 AC_FUNC_FORK
811
812 dnl ** determine whether or not const works
813 AC_C_CONST
814
815 dnl ** are we big endian?
816 AC_C_BIGENDIAN
817 FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN
818
819 dnl ** check for leading underscores in symbol names
820 FP_LEADING_UNDERSCORE
821
822 dnl ** check for ld, whether it has an -x option, and if it is GNU ld
823 FP_PROG_LD_X
824 FP_PROG_LD_IS_GNU
825
826 dnl ** check for Apple-style dead-stripping support
827 dnl    (.subsections-via-symbols assembler directive)
828
829
830 AC_MSG_CHECKING(for .subsections_via_symbols)
831 AC_COMPILE_IFELSE(
832     [AC_LANG_PROGRAM([], [__asm__ (".subsections_via_symbols");])],
833     [AC_MSG_RESULT(yes)
834      AC_DEFINE([HAVE_SUBSECTIONS_VIA_SYMBOLS],[1],
835                [Define to 1 if Apple-style dead-stripping is supported.])
836     ],
837     [AC_MSG_RESULT(no)])
838
839 dnl *** check for GNU non-executable stack note support (ELF only)
840 dnl     (.section .note.GNU-stack,"",@progbits)
841
842 dnl This test doesn't work with "gcc -g" in gcc 4.4 (GHC trac #3889:
843 dnl     Error: can't resolve `.note.GNU-stack' {.note.GNU-stack section} - `.Ltext0' {.text section}
844 dnl so we empty CFLAGS while running this test
845 CFLAGS2="$CFLAGS"
846 CFLAGS=
847 AC_MSG_CHECKING(for GNU non-executable stack support)
848 AC_COMPILE_IFELSE(
849     [AC_LANG_PROGRAM([__asm__ (".section .note.GNU-stack,\"\",@progbits");], [0])],
850     [AC_MSG_RESULT(yes)
851      AC_DEFINE([HAVE_GNU_NONEXEC_STACK],[1],
852                [Define to 1 if GNU non-executable stack notes are supported.])
853     ],
854     [AC_MSG_RESULT(no)])
855 CFLAGS="$CFLAGS2"
856
857 dnl ** check for librt
858 AC_CHECK_LIB(rt, clock_gettime)
859 AC_CHECK_FUNCS(clock_gettime timer_create timer_settime)
860 FP_CHECK_TIMER_CREATE
861
862 dnl ** check for Apple's "interesting" long double compatibility scheme
863 AC_MSG_CHECKING(for printf\$LDBLStub)
864 AC_TRY_LINK_FUNC(printf\$LDBLStub,
865     [
866         AC_MSG_RESULT(yes)
867         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[1],
868             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
869     ],
870     [
871         AC_MSG_RESULT(no)
872         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[0],
873             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
874     ])
875
876 # test for GTK+
877 AC_PATH_PROGS([GTK_CONFIG], [pkg-config])
878 if test -n "$GTK_CONFIG"; then
879   if $GTK_CONFIG gtk+-2.0 --atleast-version=2.0; then
880     GTK_CONFIG="$GTK_CONFIG gtk+-2.0"
881   else
882     AC_MSG_WARN([GTK+ not usable, need at least version 2.0])
883     GTK_CONFIG=
884   fi
885 fi
886 AC_SUBST([GTK_CONFIG])
887
888 #Checking for PAPI
889 AC_CHECK_LIB(papi, PAPI_library_init, HavePapiLib=YES, HavePapiLib=NO)
890 AC_CHECK_HEADER([papi.h], [HavePapiHeader=YES], [HavePapiHeader=NO])
891 AC_SUBST(HavePapiLib)
892 AC_SUBST(HavePapiHeader)
893
894 AC_CHECK_FUNCS(__mingw_vfprintf)
895
896 if test "$HavePapiLib" = "YES" -a "$HavePapiHeader" = "YES"; then
897    HavePapi=YES
898 else
899    HavePapi=NO
900 fi
901 AC_SUBST(HavePapi)
902
903 if test "$HAVE_DOCBOOK_XSL" = "NO" ||
904    test "$XsltprocCmd" = ""
905 then
906     BUILD_DOCBOOK_HTML=NO
907 else
908     BUILD_DOCBOOK_HTML=YES
909 fi
910 AC_SUBST(BUILD_DOCBOOK_HTML)
911
912 if test "$DblatexCmd" = ""
913 then
914     BUILD_DOCBOOK_PS=NO
915     BUILD_DOCBOOK_PDF=NO
916 else
917     BUILD_DOCBOOK_PS=YES
918     BUILD_DOCBOOK_PDF=YES
919 fi
920 AC_SUBST(BUILD_DOCBOOK_PS)
921 AC_SUBST(BUILD_DOCBOOK_PDF)
922
923 LIBRARY_VERSION(base)
924 LIBRARY_VERSION(Cabal)
925 LIBRARY_VERSION(ghc-prim)
926 LIBRARY_ghc_VERSION="$ProjectVersion"
927 AC_SUBST(LIBRARY_ghc_VERSION)
928
929 if grep '       ' compiler/ghc.cabal.in 2>&1 >/dev/null; then
930    AC_MSG_ERROR([compiler/ghc.cabal.in contains tab characters; please remove them])
931 fi
932
933 AC_CONFIG_FILES([mk/config.mk mk/install.mk mk/project.mk compiler/ghc.cabal ghc/ghc-bin.cabal ghc.spec extra-gcc-opts docs/users_guide/ug-book.xml docs/users_guide/ug-ent.xml docs/index.html libraries/prologue.txt distrib/ghc.iss distrib/configure.ac])
934 AC_CONFIG_COMMANDS([mk/stamp-h],[echo timestamp > mk/stamp-h])
935 AC_OUTPUT
936
937 # We get caught by
938 #     http://savannah.gnu.org/bugs/index.php?1516
939 #     $(eval ...) inside conditionals causes errors
940 # with make 3.80, so warn the user if it looks like they're about to
941 # try to use it.
942 # We would use "grep -q" here, but Solaris's grep doesn't support it.
943 checkMake380() {
944     if $1 --version 2>&1 | head -1 | grep 'GNU Make 3\.80' > /dev/null
945     then
946         echo
947         echo "WARNING: It looks like \"$1\" is GNU make 3.80."
948         echo "This version cannot be used to build GHC."
949         echo "Please use GNU make >= 3.81."
950     fi
951 }
952
953 checkMake380 make
954 checkMake380 gmake
955
956 echo ["
957 ----------------------------------------------------------------------
958 Configure completed successfully.
959
960    Building GHC version  : $ProjectVersion
961
962    Build platform        : $BuildPlatform
963    Host platform         : $HostPlatform
964    Target platform       : $TargetPlatform
965 "]
966
967 if test "$BootingFromHc" = "YES"; then
968 echo ["\
969    Bootstrapping from HC files.
970 "]
971 else
972 echo ["\
973    Bootstrapping using   : $WithGhc
974       which is version   : $GhcVersion
975 "]
976 fi
977
978 echo ["\
979    Using GCC             : $WhatGccIsCalled
980       which is version   : $GccVersion
981
982    ld       : $LdCmd
983    Happy    : $HappyCmd ($HappyVersion)
984    Alex     : $AlexCmd ($AlexVersion)
985    Python   : $PythonCmd
986    Perl     : $PerlCmd
987    dblatex  : $DblatexCmd
988    xsltproc : $XsltprocCmd"]
989
990 if test "$HSCOLOUR" = ""; then
991 echo ["
992    HsColour was not found; documentation will not contain source links
993 "]
994 else
995 echo ["\
996    HsColour : $HSCOLOUR
997 "]
998 fi
999
1000 echo ["\
1001    Building DocBook HTML documentation : $BUILD_DOCBOOK_HTML
1002    Building DocBook PS documentation   : $BUILD_DOCBOOK_PS
1003    Building DocBook PDF documentation  : $BUILD_DOCBOOK_PDF"]
1004
1005 echo ["----------------------------------------------------------------------
1006 "]
1007
1008 echo "\
1009 For a standard build of GHC (fully optimised with profiling), type (g)make.
1010
1011 To make changes to the default build configuration, copy the file
1012 mk/build.mk.sample to mk/build.mk, and edit the settings in there.
1013
1014 For more information on how to configure your GHC build, see
1015    http://hackage.haskell.org/trac/ghc/wiki/Building
1016 "