Typos and grammar in manual/comments
[ghc.git] / compiler / main / TidyPgm.hs
1 {-
2 (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
3
4 \section{Tidying up Core}
5 -}
6
7 {-# LANGUAGE CPP, ViewPatterns #-}
8
9 module TidyPgm (
10 mkBootModDetailsTc, tidyProgram, globaliseAndTidyId
11 ) where
12
13 #include "HsVersions.h"
14
15 import TcRnTypes
16 import DynFlags
17 import CoreSyn
18 import CoreUnfold
19 import CoreFVs
20 import CoreTidy
21 import CoreMonad
22 import CorePrep
23 import CoreUtils (rhsIsStatic)
24 import CoreStats (coreBindsStats, CoreStats(..))
25 import CoreLint
26 import Literal
27 import Rules
28 import PatSyn
29 import ConLike
30 import CoreArity ( exprArity, exprBotStrictness_maybe )
31 import StaticPtrTable
32 import VarEnv
33 import VarSet
34 import Var
35 import Id
36 import MkId ( mkDictSelRhs )
37 import IdInfo
38 import InstEnv
39 import FamInstEnv
40 import Type ( tidyTopType )
41 import Demand ( appIsBottom, isTopSig, isBottomingSig )
42 import BasicTypes
43 import Name hiding (varName)
44 import NameSet
45 import NameEnv
46 import NameCache
47 import Avail
48 import IfaceEnv
49 import TcEnv
50 import TcRnMonad
51 import DataCon
52 import TyCon
53 import Class
54 import Module
55 import Packages( isDllName )
56 import HscTypes
57 import Maybes
58 import UniqSupply
59 import ErrUtils (Severity(..))
60 import Outputable
61 import UniqDFM
62 import SrcLoc
63 import qualified ErrUtils as Err
64
65 import Control.Monad
66 import Data.Function
67 import Data.List ( sortBy )
68 import Data.IORef ( atomicModifyIORef' )
69
70 {-
71 Constructing the TypeEnv, Instances, Rules, VectInfo from which the
72 ModIface is constructed, and which goes on to subsequent modules in
73 --make mode.
74
75 Most of the interface file is obtained simply by serialising the
76 TypeEnv. One important consequence is that if the *interface file*
77 has pragma info if and only if the final TypeEnv does. This is not so
78 important for *this* module, but it's essential for ghc --make:
79 subsequent compilations must not see (e.g.) the arity if the interface
80 file does not contain arity If they do, they'll exploit the arity;
81 then the arity might change, but the iface file doesn't change =>
82 recompilation does not happen => disaster.
83
84 For data types, the final TypeEnv will have a TyThing for the TyCon,
85 plus one for each DataCon; the interface file will contain just one
86 data type declaration, but it is de-serialised back into a collection
87 of TyThings.
88
89 ************************************************************************
90 * *
91 Plan A: simpleTidyPgm
92 * *
93 ************************************************************************
94
95
96 Plan A: mkBootModDetails: omit pragmas, make interfaces small
97 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
98 * Ignore the bindings
99
100 * Drop all WiredIn things from the TypeEnv
101 (we never want them in interface files)
102
103 * Retain all TyCons and Classes in the TypeEnv, to avoid
104 having to find which ones are mentioned in the
105 types of exported Ids
106
107 * Trim off the constructors of non-exported TyCons, both
108 from the TyCon and from the TypeEnv
109
110 * Drop non-exported Ids from the TypeEnv
111
112 * Tidy the types of the DFunIds of Instances,
113 make them into GlobalIds, (they already have External Names)
114 and add them to the TypeEnv
115
116 * Tidy the types of the (exported) Ids in the TypeEnv,
117 make them into GlobalIds (they already have External Names)
118
119 * Drop rules altogether
120
121 * Tidy the bindings, to ensure that the Caf and Arity
122 information is correct for each top-level binder; the
123 code generator needs it. And to ensure that local names have
124 distinct OccNames in case of object-file splitting
125
126 * If this an hsig file, drop the instances altogether too (they'll
127 get pulled in by the implicit module import.
128 -}
129
130 -- This is Plan A: make a small type env when typechecking only,
131 -- or when compiling a hs-boot file, or simply when not using -O
132 --
133 -- We don't look at the bindings at all -- there aren't any
134 -- for hs-boot files
135
136 mkBootModDetailsTc :: HscEnv -> TcGblEnv -> IO ModDetails
137 mkBootModDetailsTc hsc_env
138 TcGblEnv{ tcg_exports = exports,
139 tcg_type_env = type_env, -- just for the Ids
140 tcg_tcs = tcs,
141 tcg_patsyns = pat_syns,
142 tcg_insts = insts,
143 tcg_fam_insts = fam_insts,
144 tcg_mod = this_mod
145 }
146 = -- This timing isn't terribly useful since the result isn't forced, but
147 -- the message is useful to locating oneself in the compilation process.
148 Err.withTiming (pure dflags)
149 (text "CoreTidy"<+>brackets (ppr this_mod))
150 (const ()) $
151 do { let { insts' = map (tidyClsInstDFun globaliseAndTidyId) insts
152 ; pat_syns' = map (tidyPatSynIds globaliseAndTidyId) pat_syns
153 ; type_env1 = mkBootTypeEnv (availsToNameSet exports)
154 (typeEnvIds type_env) tcs fam_insts
155 ; type_env2 = extendTypeEnvWithPatSyns pat_syns' type_env1
156 ; dfun_ids = map instanceDFunId insts'
157 ; type_env' = extendTypeEnvWithIds type_env2 dfun_ids
158 }
159 ; return (ModDetails { md_types = type_env'
160 , md_insts = insts'
161 , md_fam_insts = fam_insts
162 , md_rules = []
163 , md_anns = []
164 , md_exports = exports
165 , md_vect_info = noVectInfo
166 })
167 }
168 where
169 dflags = hsc_dflags hsc_env
170
171 mkBootTypeEnv :: NameSet -> [Id] -> [TyCon] -> [FamInst] -> TypeEnv
172 mkBootTypeEnv exports ids tcs fam_insts
173 = tidyTypeEnv True $
174 typeEnvFromEntities final_ids tcs fam_insts
175 where
176 -- Find the LocalIds in the type env that are exported
177 -- Make them into GlobalIds, and tidy their types
178 --
179 -- It's very important to remove the non-exported ones
180 -- because we don't tidy the OccNames, and if we don't remove
181 -- the non-exported ones we'll get many things with the
182 -- same name in the interface file, giving chaos.
183 --
184 -- Do make sure that we keep Ids that are already Global.
185 -- When typechecking an .hs-boot file, the Ids come through as
186 -- GlobalIds.
187 final_ids = [ (if isLocalId id then globaliseAndTidyId id
188 else id)
189 `setIdUnfolding` BootUnfolding
190 | id <- ids
191 , keep_it id ]
192
193 -- default methods have their export flag set, but everything
194 -- else doesn't (yet), because this is pre-desugaring, so we
195 -- must test both.
196 keep_it id = isExportedId id || idName id `elemNameSet` exports
197
198
199
200 globaliseAndTidyId :: Id -> Id
201 -- Takes an LocalId with an External Name,
202 -- makes it into a GlobalId
203 -- * unchanged Name (might be Internal or External)
204 -- * unchanged details
205 -- * VanillaIdInfo (makes a conservative assumption about Caf-hood)
206 globaliseAndTidyId id
207 = Id.setIdType (globaliseId id) tidy_type
208 where
209 tidy_type = tidyTopType (idType id)
210
211 {-
212 ************************************************************************
213 * *
214 Plan B: tidy bindings, make TypeEnv full of IdInfo
215 * *
216 ************************************************************************
217
218 Plan B: include pragmas, make interfaces
219 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
220 * Figure out which Ids are externally visible
221
222 * Tidy the bindings, externalising appropriate Ids
223
224 * Drop all Ids from the TypeEnv, and add all the External Ids from
225 the bindings. (This adds their IdInfo to the TypeEnv; and adds
226 floated-out Ids that weren't even in the TypeEnv before.)
227
228 Step 1: Figure out external Ids
229 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
230 Note [choosing external names]
231
232 See also the section "Interface stability" in the
233 RecompilationAvoidance commentary:
234 http://ghc.haskell.org/trac/ghc/wiki/Commentary/Compiler/RecompilationAvoidance
235
236 First we figure out which Ids are "external" Ids. An
237 "external" Id is one that is visible from outside the compilation
238 unit. These are
239 a) the user exported ones
240 b) the ones bound to static forms
241 c) ones mentioned in the unfoldings, workers,
242 rules of externally-visible ones ,
243 or vectorised versions of externally-visible ones
244
245 While figuring out which Ids are external, we pick a "tidy" OccName
246 for each one. That is, we make its OccName distinct from the other
247 external OccNames in this module, so that in interface files and
248 object code we can refer to it unambiguously by its OccName. The
249 OccName for each binder is prefixed by the name of the exported Id
250 that references it; e.g. if "f" references "x" in its unfolding, then
251 "x" is renamed to "f_x". This helps distinguish the different "x"s
252 from each other, and means that if "f" is later removed, things that
253 depend on the other "x"s will not need to be recompiled. Of course,
254 if there are multiple "f_x"s, then we have to disambiguate somehow; we
255 use "f_x0", "f_x1" etc.
256
257 As far as possible we should assign names in a deterministic fashion.
258 Each time this module is compiled with the same options, we should end
259 up with the same set of external names with the same types. That is,
260 the ABI hash in the interface should not change. This turns out to be
261 quite tricky, since the order of the bindings going into the tidy
262 phase is already non-deterministic, as it is based on the ordering of
263 Uniques, which are assigned unpredictably.
264
265 To name things in a stable way, we do a depth-first-search of the
266 bindings, starting from the exports sorted by name. This way, as long
267 as the bindings themselves are deterministic (they sometimes aren't!),
268 the order in which they are presented to the tidying phase does not
269 affect the names we assign.
270
271 Step 2: Tidy the program
272 ~~~~~~~~~~~~~~~~~~~~~~~~
273 Next we traverse the bindings top to bottom. For each *top-level*
274 binder
275
276 1. Make it into a GlobalId; its IdDetails becomes VanillaGlobal,
277 reflecting the fact that from now on we regard it as a global,
278 not local, Id
279
280 2. Give it a system-wide Unique.
281 [Even non-exported things need system-wide Uniques because the
282 byte-code generator builds a single Name->BCO symbol table.]
283
284 We use the NameCache kept in the HscEnv as the
285 source of such system-wide uniques.
286
287 For external Ids, use the original-name cache in the NameCache
288 to ensure that the unique assigned is the same as the Id had
289 in any previous compilation run.
290
291 3. Rename top-level Ids according to the names we chose in step 1.
292 If it's an external Id, make it have a External Name, otherwise
293 make it have an Internal Name. This is used by the code generator
294 to decide whether to make the label externally visible
295
296 4. Give it its UTTERLY FINAL IdInfo; in ptic,
297 * its unfolding, if it should have one
298
299 * its arity, computed from the number of visible lambdas
300
301 * its CAF info, computed from what is free in its RHS
302
303
304 Finally, substitute these new top-level binders consistently
305 throughout, including in unfoldings. We also tidy binders in
306 RHSs, so that they print nicely in interfaces.
307 -}
308
309 tidyProgram :: HscEnv -> ModGuts -> IO (CgGuts, ModDetails)
310 tidyProgram hsc_env (ModGuts { mg_module = mod
311 , mg_exports = exports
312 , mg_rdr_env = rdr_env
313 , mg_tcs = tcs
314 , mg_insts = cls_insts
315 , mg_fam_insts = fam_insts
316 , mg_binds = binds
317 , mg_patsyns = patsyns
318 , mg_rules = imp_rules
319 , mg_vect_info = vect_info
320 , mg_anns = anns
321 , mg_deps = deps
322 , mg_foreign = foreign_stubs
323 , mg_hpc_info = hpc_info
324 , mg_modBreaks = modBreaks
325 })
326
327 = Err.withTiming (pure dflags)
328 (text "CoreTidy"<+>brackets (ppr mod))
329 (const ()) $
330 do { let { omit_prags = gopt Opt_OmitInterfacePragmas dflags
331 ; expose_all = gopt Opt_ExposeAllUnfoldings dflags
332 ; print_unqual = mkPrintUnqualified dflags rdr_env
333 }
334
335 ; let { type_env = typeEnvFromEntities [] tcs fam_insts
336
337 ; implicit_binds
338 = concatMap getClassImplicitBinds (typeEnvClasses type_env) ++
339 concatMap getTyConImplicitBinds (typeEnvTyCons type_env)
340 }
341
342 ; (unfold_env, tidy_occ_env)
343 <- chooseExternalIds hsc_env mod omit_prags expose_all
344 binds implicit_binds imp_rules (vectInfoVar vect_info)
345 ; let { (trimmed_binds, trimmed_rules)
346 = findExternalRules omit_prags binds imp_rules unfold_env }
347
348 ; (tidy_env, tidy_binds)
349 <- tidyTopBinds hsc_env mod unfold_env tidy_occ_env trimmed_binds
350
351 ; let { final_ids = [ id | id <- bindersOfBinds tidy_binds,
352 isExternalName (idName id)]
353 ; type_env1 = extendTypeEnvWithIds type_env final_ids
354
355 ; tidy_cls_insts = map (tidyClsInstDFun (tidyVarOcc tidy_env)) cls_insts
356 -- A DFunId will have a binding in tidy_binds, and so will now be in
357 -- tidy_type_env, replete with IdInfo. Its name will be unchanged since
358 -- it was born, but we want Global, IdInfo-rich (or not) DFunId in the
359 -- tidy_cls_insts. Similarly the Ids inside a PatSyn.
360
361 ; tidy_rules = tidyRules tidy_env trimmed_rules
362 -- You might worry that the tidy_env contains IdInfo-rich stuff
363 -- and indeed it does, but if omit_prags is on, ext_rules is
364 -- empty
365
366 ; tidy_vect_info = tidyVectInfo tidy_env vect_info
367
368 -- Tidy the Ids inside each PatSyn, very similarly to DFunIds
369 -- and then override the PatSyns in the type_env with the new tidy ones
370 -- This is really the only reason we keep mg_patsyns at all; otherwise
371 -- they could just stay in type_env
372 ; tidy_patsyns = map (tidyPatSynIds (tidyVarOcc tidy_env)) patsyns
373 ; type_env2 = extendTypeEnvWithPatSyns tidy_patsyns type_env1
374
375 ; tidy_type_env = tidyTypeEnv omit_prags type_env2
376 }
377 -- See Note [Grand plan for static forms] in StaticPtrTable.
378 ; (spt_init_code, tidy_binds') <-
379 sptCreateStaticBinds hsc_env mod tidy_binds
380 ; let { -- See Note [Injecting implicit bindings]
381 all_tidy_binds = implicit_binds ++ tidy_binds'
382
383 -- Get the TyCons to generate code for. Careful! We must use
384 -- the untidied TypeEnv here, because we need
385 -- (a) implicit TyCons arising from types and classes defined
386 -- in this module
387 -- (b) wired-in TyCons, which are normally removed from the
388 -- TypeEnv we put in the ModDetails
389 -- (c) Constructors even if they are not exported (the
390 -- tidied TypeEnv has trimmed these away)
391 ; alg_tycons = filter isAlgTyCon (typeEnvTyCons type_env)
392 }
393
394 ; endPassIO hsc_env print_unqual CoreTidy all_tidy_binds tidy_rules
395
396 -- If the endPass didn't print the rules, but ddump-rules is
397 -- on, print now
398 ; unless (dopt Opt_D_dump_simpl dflags) $
399 Err.dumpIfSet_dyn dflags Opt_D_dump_rules
400 (showSDoc dflags (ppr CoreTidy <+> text "rules"))
401 (pprRulesForUser tidy_rules)
402
403 -- Print one-line size info
404 ; let cs = coreBindsStats tidy_binds
405 ; when (dopt Opt_D_dump_core_stats dflags)
406 (log_action dflags dflags NoReason SevDump noSrcSpan defaultDumpStyle
407 (text "Tidy size (terms,types,coercions)"
408 <+> ppr (moduleName mod) <> colon
409 <+> int (cs_tm cs)
410 <+> int (cs_ty cs)
411 <+> int (cs_co cs) ))
412
413 ; return (CgGuts { cg_module = mod,
414 cg_tycons = alg_tycons,
415 cg_binds = all_tidy_binds,
416 cg_foreign = foreign_stubs `appendStubC`
417 spt_init_code,
418 cg_dep_pkgs = map fst $ dep_pkgs deps,
419 cg_hpc_info = hpc_info,
420 cg_modBreaks = modBreaks },
421
422 ModDetails { md_types = tidy_type_env,
423 md_rules = tidy_rules,
424 md_insts = tidy_cls_insts,
425 md_vect_info = tidy_vect_info,
426 md_fam_insts = fam_insts,
427 md_exports = exports,
428 md_anns = anns -- are already tidy
429 })
430 }
431 where
432 dflags = hsc_dflags hsc_env
433
434 tidyTypeEnv :: Bool -- Compiling without -O, so omit prags
435 -> TypeEnv -> TypeEnv
436
437 -- The competed type environment is gotten from
438 -- a) the types and classes defined here (plus implicit things)
439 -- b) adding Ids with correct IdInfo, including unfoldings,
440 -- gotten from the bindings
441 -- From (b) we keep only those Ids with External names;
442 -- the CoreTidy pass makes sure these are all and only
443 -- the externally-accessible ones
444 -- This truncates the type environment to include only the
445 -- exported Ids and things needed from them, which saves space
446 --
447 -- See Note [Don't attempt to trim data types]
448
449 tidyTypeEnv omit_prags type_env
450 = let
451 type_env1 = filterNameEnv (not . isWiredInName . getName) type_env
452 -- (1) remove wired-in things
453 type_env2 | omit_prags = mapNameEnv trimThing type_env1
454 | otherwise = type_env1
455 -- (2) trimmed if necessary
456 in
457 type_env2
458
459 --------------------------
460 trimThing :: TyThing -> TyThing
461 -- Trim off inessentials, for boot files and no -O
462 trimThing (AnId id)
463 | not (isImplicitId id)
464 = AnId (id `setIdInfo` vanillaIdInfo)
465
466 trimThing other_thing
467 = other_thing
468
469 extendTypeEnvWithPatSyns :: [PatSyn] -> TypeEnv -> TypeEnv
470 extendTypeEnvWithPatSyns tidy_patsyns type_env
471 = extendTypeEnvList type_env [AConLike (PatSynCon ps) | ps <- tidy_patsyns ]
472
473 tidyVectInfo :: TidyEnv -> VectInfo -> VectInfo
474 tidyVectInfo (_, var_env) info@(VectInfo { vectInfoVar = vars
475 , vectInfoParallelVars = parallelVars
476 })
477 = info { vectInfoVar = tidy_vars
478 , vectInfoParallelVars = tidy_parallelVars
479 }
480 where
481 -- we only export mappings whose domain and co-domain is exported (otherwise, the iface is
482 -- inconsistent)
483 tidy_vars = mkDVarEnv [ (tidy_var, (tidy_var, tidy_var_v))
484 | (var, var_v) <- eltsUDFM vars
485 , let tidy_var = lookup_var var
486 tidy_var_v = lookup_var var_v
487 , isExternalId tidy_var && isExportedId tidy_var
488 , isExternalId tidy_var_v && isExportedId tidy_var_v
489 , isDataConWorkId var || not (isImplicitId var)
490 ]
491
492 tidy_parallelVars = mkDVarSet
493 [ tidy_var
494 | var <- dVarSetElems parallelVars
495 , let tidy_var = lookup_var var
496 , isExternalId tidy_var && isExportedId tidy_var
497 ]
498
499 lookup_var var = lookupWithDefaultVarEnv var_env var var
500
501 -- We need to make sure that all names getting into the iface version of 'VectInfo' are
502 -- external; otherwise, 'MkIface' will bomb out.
503 isExternalId = isExternalName . idName
504
505 {-
506 Note [Don't attempt to trim data types]
507 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
508 For some time GHC tried to avoid exporting the data constructors
509 of a data type if it wasn't strictly necessary to do so; see Trac #835.
510 But "strictly necessary" accumulated a longer and longer list
511 of exceptions, and finally I gave up the battle:
512
513 commit 9a20e540754fc2af74c2e7392f2786a81d8d5f11
514 Author: Simon Peyton Jones <simonpj@microsoft.com>
515 Date: Thu Dec 6 16:03:16 2012 +0000
516
517 Stop attempting to "trim" data types in interface files
518
519 Without -O, we previously tried to make interface files smaller
520 by not including the data constructors of data types. But
521 there are a lot of exceptions, notably when Template Haskell is
522 involved or, more recently, DataKinds.
523
524 However Trac #7445 shows that even without TemplateHaskell, using
525 the Data class and invoking Language.Haskell.TH.Quote.dataToExpQ
526 is enough to require us to expose the data constructors.
527
528 So I've given up on this "optimisation" -- it's probably not
529 important anyway. Now I'm simply not attempting to trim off
530 the data constructors. The gain in simplicity is worth the
531 modest cost in interface file growth, which is limited to the
532 bits reqd to describe those data constructors.
533
534 ************************************************************************
535 * *
536 Implicit bindings
537 * *
538 ************************************************************************
539
540 Note [Injecting implicit bindings]
541 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
542 We inject the implicit bindings right at the end, in CoreTidy.
543 Some of these bindings, notably record selectors, are not
544 constructed in an optimised form. E.g. record selector for
545 data T = MkT { x :: {-# UNPACK #-} !Int }
546 Then the unfolding looks like
547 x = \t. case t of MkT x1 -> let x = I# x1 in x
548 This generates bad code unless it's first simplified a bit. That is
549 why CoreUnfold.mkImplicitUnfolding uses simpleOptExpr to do a bit of
550 optimisation first. (Only matters when the selector is used curried;
551 eg map x ys.) See Trac #2070.
552
553 [Oct 09: in fact, record selectors are no longer implicit Ids at all,
554 because we really do want to optimise them properly. They are treated
555 much like any other Id. But doing "light" optimisation on an implicit
556 Id still makes sense.]
557
558 At one time I tried injecting the implicit bindings *early*, at the
559 beginning of SimplCore. But that gave rise to real difficulty,
560 because GlobalIds are supposed to have *fixed* IdInfo, but the
561 simplifier and other core-to-core passes mess with IdInfo all the
562 time. The straw that broke the camels back was when a class selector
563 got the wrong arity -- ie the simplifier gave it arity 2, whereas
564 importing modules were expecting it to have arity 1 (Trac #2844).
565 It's much safer just to inject them right at the end, after tidying.
566
567 Oh: two other reasons for injecting them late:
568
569 - If implicit Ids are already in the bindings when we start TidyPgm,
570 we'd have to be careful not to treat them as external Ids (in
571 the sense of chooseExternalIds); else the Ids mentioned in *their*
572 RHSs will be treated as external and you get an interface file
573 saying a18 = <blah>
574 but nothing referring to a18 (because the implicit Id is the
575 one that does, and implicit Ids don't appear in interface files).
576
577 - More seriously, the tidied type-envt will include the implicit
578 Id replete with a18 in its unfolding; but we won't take account
579 of a18 when computing a fingerprint for the class; result chaos.
580
581 There is one sort of implicit binding that is injected still later,
582 namely those for data constructor workers. Reason (I think): it's
583 really just a code generation trick.... binding itself makes no sense.
584 See Note [Data constructor workers] in CorePrep.
585 -}
586
587 getTyConImplicitBinds :: TyCon -> [CoreBind]
588 getTyConImplicitBinds tc = map get_defn (mapMaybe dataConWrapId_maybe (tyConDataCons tc))
589
590 getClassImplicitBinds :: Class -> [CoreBind]
591 getClassImplicitBinds cls
592 = [ NonRec op (mkDictSelRhs cls val_index)
593 | (op, val_index) <- classAllSelIds cls `zip` [0..] ]
594
595 get_defn :: Id -> CoreBind
596 get_defn id = NonRec id (unfoldingTemplate (realIdUnfolding id))
597
598 {-
599 ************************************************************************
600 * *
601 \subsection{Step 1: finding externals}
602 * *
603 ************************************************************************
604
605 See Note [Choosing external names].
606 -}
607
608 type UnfoldEnv = IdEnv (Name{-new name-}, Bool {-show unfolding-})
609 -- Maps each top-level Id to its new Name (the Id is tidied in step 2)
610 -- The Unique is unchanged. If the new Name is external, it will be
611 -- visible in the interface file.
612 --
613 -- Bool => expose unfolding or not.
614
615 chooseExternalIds :: HscEnv
616 -> Module
617 -> Bool -> Bool
618 -> [CoreBind]
619 -> [CoreBind]
620 -> [CoreRule]
621 -> DVarEnv (Var, Var)
622 -> IO (UnfoldEnv, TidyOccEnv)
623 -- Step 1 from the notes above
624
625 chooseExternalIds hsc_env mod omit_prags expose_all binds implicit_binds imp_id_rules vect_vars
626 = do { (unfold_env1,occ_env1) <- search init_work_list emptyVarEnv init_occ_env
627 ; let internal_ids = filter (not . (`elemVarEnv` unfold_env1)) binders
628 ; tidy_internal internal_ids unfold_env1 occ_env1 }
629 where
630 nc_var = hsc_NC hsc_env
631
632 -- init_ext_ids is the intial list of Ids that should be
633 -- externalised. It serves as the starting point for finding a
634 -- deterministic, tidy, renaming for all external Ids in this
635 -- module.
636 --
637 -- It is sorted, so that it has adeterministic order (i.e. it's the
638 -- same list every time this module is compiled), in contrast to the
639 -- bindings, which are ordered non-deterministically.
640 init_work_list = zip init_ext_ids init_ext_ids
641 init_ext_ids = sortBy (compare `on` getOccName) $ filter is_external binders
642
643 -- An Id should be external if either (a) it is exported,
644 -- (b) it appears in the RHS of a local rule for an imported Id, or
645 -- (c) it is the vectorised version of an imported Id.
646 -- See Note [Which rules to expose]
647 is_external id = isExportedId id || id `elemVarSet` rule_rhs_vars
648 || id `elemVarSet` vect_var_vs
649
650 rule_rhs_vars = mapUnionVarSet ruleRhsFreeVars imp_id_rules
651 vect_var_vs = mkVarSet [var_v | (var, var_v) <- eltsUDFM vect_vars, isGlobalId var]
652
653 binders = map fst $ flattenBinds binds
654 implicit_binders = bindersOfBinds implicit_binds
655 binder_set = mkVarSet binders
656
657 avoids = [getOccName name | bndr <- binders ++ implicit_binders,
658 let name = idName bndr,
659 isExternalName name ]
660 -- In computing our "avoids" list, we must include
661 -- all implicit Ids
662 -- all things with global names (assigned once and for
663 -- all by the renamer)
664 -- since their names are "taken".
665 -- The type environment is a convenient source of such things.
666 -- In particular, the set of binders doesn't include
667 -- implicit Ids at this stage.
668
669 -- We also make sure to avoid any exported binders. Consider
670 -- f{-u1-} = 1 -- Local decl
671 -- ...
672 -- f{-u2-} = 2 -- Exported decl
673 --
674 -- The second exported decl must 'get' the name 'f', so we
675 -- have to put 'f' in the avoids list before we get to the first
676 -- decl. tidyTopId then does a no-op on exported binders.
677 init_occ_env = initTidyOccEnv avoids
678
679
680 search :: [(Id,Id)] -- The work-list: (external id, referrring id)
681 -- Make a tidy, external Name for the external id,
682 -- add it to the UnfoldEnv, and do the same for the
683 -- transitive closure of Ids it refers to
684 -- The referring id is used to generate a tidy
685 --- name for the external id
686 -> UnfoldEnv -- id -> (new Name, show_unfold)
687 -> TidyOccEnv -- occ env for choosing new Names
688 -> IO (UnfoldEnv, TidyOccEnv)
689
690 search [] unfold_env occ_env = return (unfold_env, occ_env)
691
692 search ((idocc,referrer) : rest) unfold_env occ_env
693 | idocc `elemVarEnv` unfold_env = search rest unfold_env occ_env
694 | otherwise = do
695 (occ_env', name') <- tidyTopName mod nc_var (Just referrer) occ_env idocc
696 let
697 (new_ids, show_unfold)
698 | omit_prags = ([], False)
699 | otherwise = addExternal expose_all refined_id
700
701 -- add vectorised version if any exists
702 new_ids' = new_ids ++ maybeToList (fmap snd $ lookupDVarEnv vect_vars idocc)
703
704 -- 'idocc' is an *occurrence*, but we need to see the
705 -- unfolding in the *definition*; so look up in binder_set
706 refined_id = case lookupVarSet binder_set idocc of
707 Just id -> id
708 Nothing -> WARN( True, ppr idocc ) idocc
709
710 unfold_env' = extendVarEnv unfold_env idocc (name',show_unfold)
711 referrer' | isExportedId refined_id = refined_id
712 | otherwise = referrer
713 --
714 search (zip new_ids' (repeat referrer') ++ rest) unfold_env' occ_env'
715
716 tidy_internal :: [Id] -> UnfoldEnv -> TidyOccEnv
717 -> IO (UnfoldEnv, TidyOccEnv)
718 tidy_internal [] unfold_env occ_env = return (unfold_env,occ_env)
719 tidy_internal (id:ids) unfold_env occ_env = do
720 (occ_env', name') <- tidyTopName mod nc_var Nothing occ_env id
721 let unfold_env' = extendVarEnv unfold_env id (name',False)
722 tidy_internal ids unfold_env' occ_env'
723
724 addExternal :: Bool -> Id -> ([Id], Bool)
725 addExternal expose_all id = (new_needed_ids, show_unfold)
726 where
727 new_needed_ids = bndrFvsInOrder show_unfold id
728 idinfo = idInfo id
729 show_unfold = show_unfolding (unfoldingInfo idinfo)
730 never_active = isNeverActive (inlinePragmaActivation (inlinePragInfo idinfo))
731 loop_breaker = isStrongLoopBreaker (occInfo idinfo)
732 bottoming_fn = isBottomingSig (strictnessInfo idinfo)
733
734 -- Stuff to do with the Id's unfolding
735 -- We leave the unfolding there even if there is a worker
736 -- In GHCi the unfolding is used by importers
737
738 show_unfolding (CoreUnfolding { uf_src = src, uf_guidance = guidance })
739 = expose_all -- 'expose_all' says to expose all
740 -- unfoldings willy-nilly
741
742 || isStableSource src -- Always expose things whose
743 -- source is an inline rule
744
745 || not (bottoming_fn -- No need to inline bottom functions
746 || never_active -- Or ones that say not to
747 || loop_breaker -- Or that are loop breakers
748 || neverUnfoldGuidance guidance)
749 show_unfolding (DFunUnfolding {}) = True
750 show_unfolding _ = False
751
752 {-
753 ************************************************************************
754 * *
755 Deterministic free variables
756 * *
757 ************************************************************************
758
759 We want a deterministic free-variable list. exprFreeVars gives us
760 a VarSet, which is in a non-deterministic order when converted to a
761 list. Hence, here we define a free-variable finder that returns
762 the free variables in the order that they are encountered.
763
764 See Note [Choosing external names]
765 -}
766
767 bndrFvsInOrder :: Bool -> Id -> [Id]
768 bndrFvsInOrder show_unfold id
769 = run (dffvLetBndr show_unfold id)
770
771 run :: DFFV () -> [Id]
772 run (DFFV m) = case m emptyVarSet (emptyVarSet, []) of
773 ((_,ids),_) -> ids
774
775 newtype DFFV a
776 = DFFV (VarSet -- Envt: non-top-level things that are in scope
777 -- we don't want to record these as free vars
778 -> (VarSet, [Var]) -- Input State: (set, list) of free vars so far
779 -> ((VarSet,[Var]),a)) -- Output state
780
781 instance Functor DFFV where
782 fmap = liftM
783
784 instance Applicative DFFV where
785 pure a = DFFV $ \_ st -> (st, a)
786 (<*>) = ap
787
788 instance Monad DFFV where
789 (DFFV m) >>= k = DFFV $ \env st ->
790 case m env st of
791 (st',a) -> case k a of
792 DFFV f -> f env st'
793
794 extendScope :: Var -> DFFV a -> DFFV a
795 extendScope v (DFFV f) = DFFV (\env st -> f (extendVarSet env v) st)
796
797 extendScopeList :: [Var] -> DFFV a -> DFFV a
798 extendScopeList vs (DFFV f) = DFFV (\env st -> f (extendVarSetList env vs) st)
799
800 insert :: Var -> DFFV ()
801 insert v = DFFV $ \ env (set, ids) ->
802 let keep_me = isLocalId v &&
803 not (v `elemVarSet` env) &&
804 not (v `elemVarSet` set)
805 in if keep_me
806 then ((extendVarSet set v, v:ids), ())
807 else ((set, ids), ())
808
809
810 dffvExpr :: CoreExpr -> DFFV ()
811 dffvExpr (Var v) = insert v
812 dffvExpr (App e1 e2) = dffvExpr e1 >> dffvExpr e2
813 dffvExpr (Lam v e) = extendScope v (dffvExpr e)
814 dffvExpr (Tick (Breakpoint _ ids) e) = mapM_ insert ids >> dffvExpr e
815 dffvExpr (Tick _other e) = dffvExpr e
816 dffvExpr (Cast e _) = dffvExpr e
817 dffvExpr (Let (NonRec x r) e) = dffvBind (x,r) >> extendScope x (dffvExpr e)
818 dffvExpr (Let (Rec prs) e) = extendScopeList (map fst prs) $
819 (mapM_ dffvBind prs >> dffvExpr e)
820 dffvExpr (Case e b _ as) = dffvExpr e >> extendScope b (mapM_ dffvAlt as)
821 dffvExpr _other = return ()
822
823 dffvAlt :: (t, [Var], CoreExpr) -> DFFV ()
824 dffvAlt (_,xs,r) = extendScopeList xs (dffvExpr r)
825
826 dffvBind :: (Id, CoreExpr) -> DFFV ()
827 dffvBind(x,r)
828 | not (isId x) = dffvExpr r
829 | otherwise = dffvLetBndr False x >> dffvExpr r
830 -- Pass False because we are doing the RHS right here
831 -- If you say True you'll get *exponential* behaviour!
832
833 dffvLetBndr :: Bool -> Id -> DFFV ()
834 -- Gather the free vars of the RULES and unfolding of a binder
835 -- We always get the free vars of a *stable* unfolding, but
836 -- for a *vanilla* one (InlineRhs), the flag controls what happens:
837 -- True <=> get fvs of even a *vanilla* unfolding
838 -- False <=> ignore an InlineRhs
839 -- For nested bindings (call from dffvBind) we always say "False" because
840 -- we are taking the fvs of the RHS anyway
841 -- For top-level bindings (call from addExternal, via bndrFvsInOrder)
842 -- we say "True" if we are exposing that unfolding
843 dffvLetBndr vanilla_unfold id
844 = do { go_unf (unfoldingInfo idinfo)
845 ; mapM_ go_rule (ruleInfoRules (ruleInfo idinfo)) }
846 where
847 idinfo = idInfo id
848
849 go_unf (CoreUnfolding { uf_tmpl = rhs, uf_src = src })
850 = case src of
851 InlineRhs | vanilla_unfold -> dffvExpr rhs
852 | otherwise -> return ()
853 _ -> dffvExpr rhs
854
855 go_unf (DFunUnfolding { df_bndrs = bndrs, df_args = args })
856 = extendScopeList bndrs $ mapM_ dffvExpr args
857 go_unf _ = return ()
858
859 go_rule (BuiltinRule {}) = return ()
860 go_rule (Rule { ru_bndrs = bndrs, ru_rhs = rhs })
861 = extendScopeList bndrs (dffvExpr rhs)
862
863 {-
864 ************************************************************************
865 * *
866 findExternalRules
867 * *
868 ************************************************************************
869
870 Note [Finding external rules]
871 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
872 The complete rules are gotten by combining
873 a) local rules for imported Ids
874 b) rules embedded in the top-level Ids
875
876 There are two complications:
877 * Note [Which rules to expose]
878 * Note [Trimming auto-rules]
879
880 Note [Which rules to expose]
881 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
882 The function 'expose_rule' filters out rules that mention, on the LHS,
883 Ids that aren't externally visible; these rules can't fire in a client
884 module.
885
886 The externally-visible binders are computed (by chooseExternalIds)
887 assuming that all orphan rules are externalised (see init_ext_ids in
888 function 'search'). So in fact it's a bit conservative and we may
889 export more than we need. (It's a sort of mutual recursion.)
890
891 Note [Trimming auto-rules]
892 ~~~~~~~~~~~~~~~~~~~~~~~~~~~
893 Second, with auto-specialisation we may specialise local or imported
894 dfuns or INLINE functions, and then later inline them. That may leave
895 behind something like
896 RULE "foo" forall d. f @ Int d = f_spec
897 where f is either local or imported, and there is no remaining
898 reference to f_spec except from the RULE.
899
900 Now that RULE *might* be useful to an importing module, but that is
901 purely speculative, and meanwhile the code is taking up space and
902 codegen time. I found that binary sizes jumped by 6-10% when I
903 started to specialise INLINE functions (again, Note [Inline
904 specialisations] in Specialise).
905
906 So it seems better to drop the binding for f_spec, and the rule
907 itself, if the auto-generated rule is the *only* reason that it is
908 being kept alive.
909
910 (The RULE still might have been useful in the past; that is, it was
911 the right thing to have generated it in the first place. See Note
912 [Inline specialisations] in Specialise. But now it has served its
913 purpose, and can be discarded.)
914
915 So findExternalRules does this:
916 * Remove all bindings that are kept alive *only* by isAutoRule rules
917 (this is done in trim_binds)
918 * Remove all auto rules that mention bindings that have been removed
919 (this is done by filtering by keep_rule)
920
921 NB: if a binding is kept alive for some *other* reason (e.g. f_spec is
922 called in the final code), we keep the rule too.
923
924 This stuff is the only reason for the ru_auto field in a Rule.
925 -}
926
927 findExternalRules :: Bool -- Omit pragmas
928 -> [CoreBind]
929 -> [CoreRule] -- Local rules for imported fns
930 -> UnfoldEnv -- Ids that are exported, so we need their rules
931 -> ([CoreBind], [CoreRule])
932 -- See Note [Finding external rules]
933 findExternalRules omit_prags binds imp_id_rules unfold_env
934 = (trimmed_binds, filter keep_rule all_rules)
935 where
936 imp_rules = filter expose_rule imp_id_rules
937 imp_user_rule_fvs = mapUnionVarSet user_rule_rhs_fvs imp_rules
938
939 user_rule_rhs_fvs rule | isAutoRule rule = emptyVarSet
940 | otherwise = ruleRhsFreeVars rule
941
942 (trimmed_binds, local_bndrs, _, all_rules) = trim_binds binds
943
944 keep_rule rule = ruleFreeVars rule `subVarSet` local_bndrs
945 -- Remove rules that make no sense, because they mention a
946 -- local binder (on LHS or RHS) that we have now discarded.
947 -- (NB: ruleFreeVars only includes LocalIds)
948 --
949 -- LHS: we have already filtered out rules that mention internal Ids
950 -- on LHS but that isn't enough because we might have by now
951 -- discarded a binding with an external Id. (How?
952 -- chooseExternalIds is a bit conservative.)
953 --
954 -- RHS: the auto rules that might mention a binder that has
955 -- been discarded; see Note [Trimming auto-rules]
956
957 expose_rule rule
958 | omit_prags = False
959 | otherwise = all is_external_id (ruleLhsFreeIdsList rule)
960 -- Don't expose a rule whose LHS mentions a locally-defined
961 -- Id that is completely internal (i.e. not visible to an
962 -- importing module). NB: ruleLhsFreeIds only returns LocalIds.
963 -- See Note [Which rules to expose]
964
965 is_external_id id = case lookupVarEnv unfold_env id of
966 Just (name, _) -> isExternalName name
967 Nothing -> False
968
969 trim_binds :: [CoreBind]
970 -> ( [CoreBind] -- Trimmed bindings
971 , VarSet -- Binders of those bindings
972 , VarSet -- Free vars of those bindings + rhs of user rules
973 -- (we don't bother to delete the binders)
974 , [CoreRule]) -- All rules, imported + from the bindings
975 -- This function removes unnecessary bindings, and gathers up rules from
976 -- the bindings we keep. See Note [Trimming auto-rules]
977 trim_binds [] -- Base case, start with imp_user_rule_fvs
978 = ([], emptyVarSet, imp_user_rule_fvs, imp_rules)
979
980 trim_binds (bind:binds)
981 | any needed bndrs -- Keep binding
982 = ( bind : binds', bndr_set', needed_fvs', local_rules ++ rules )
983 | otherwise -- Discard binding altogether
984 = stuff
985 where
986 stuff@(binds', bndr_set, needed_fvs, rules)
987 = trim_binds binds
988 needed bndr = isExportedId bndr || bndr `elemVarSet` needed_fvs
989
990 bndrs = bindersOf bind
991 rhss = rhssOfBind bind
992 bndr_set' = bndr_set `extendVarSetList` bndrs
993
994 needed_fvs' = needed_fvs `unionVarSet`
995 mapUnionVarSet idUnfoldingVars bndrs `unionVarSet`
996 -- Ignore type variables in the type of bndrs
997 mapUnionVarSet exprFreeVars rhss `unionVarSet`
998 mapUnionVarSet user_rule_rhs_fvs local_rules
999 -- In needed_fvs', we don't bother to delete binders from the fv set
1000
1001 local_rules = [ rule
1002 | id <- bndrs
1003 , is_external_id id -- Only collect rules for external Ids
1004 , rule <- idCoreRules id
1005 , expose_rule rule ] -- and ones that can fire in a client
1006
1007 {-
1008 ************************************************************************
1009 * *
1010 tidyTopName
1011 * *
1012 ************************************************************************
1013
1014 This is where we set names to local/global based on whether they really are
1015 externally visible (see comment at the top of this module). If the name
1016 was previously local, we have to give it a unique occurrence name if
1017 we intend to externalise it.
1018 -}
1019
1020 tidyTopName :: Module -> IORef NameCache -> Maybe Id -> TidyOccEnv
1021 -> Id -> IO (TidyOccEnv, Name)
1022 tidyTopName mod nc_var maybe_ref occ_env id
1023 | global && internal = return (occ_env, localiseName name)
1024
1025 | global && external = return (occ_env, name)
1026 -- Global names are assumed to have been allocated by the renamer,
1027 -- so they already have the "right" unique
1028 -- And it's a system-wide unique too
1029
1030 -- Now we get to the real reason that all this is in the IO Monad:
1031 -- we have to update the name cache in a nice atomic fashion
1032
1033 | local && internal = do { new_local_name <- atomicModifyIORef' nc_var mk_new_local
1034 ; return (occ_env', new_local_name) }
1035 -- Even local, internal names must get a unique occurrence, because
1036 -- if we do -split-objs we externalise the name later, in the code generator
1037 --
1038 -- Similarly, we must make sure it has a system-wide Unique, because
1039 -- the byte-code generator builds a system-wide Name->BCO symbol table
1040
1041 | local && external = do { new_external_name <- atomicModifyIORef' nc_var mk_new_external
1042 ; return (occ_env', new_external_name) }
1043
1044 | otherwise = panic "tidyTopName"
1045 where
1046 name = idName id
1047 external = isJust maybe_ref
1048 global = isExternalName name
1049 local = not global
1050 internal = not external
1051 loc = nameSrcSpan name
1052
1053 old_occ = nameOccName name
1054 new_occ | Just ref <- maybe_ref
1055 , ref /= id
1056 = mkOccName (occNameSpace old_occ) $
1057 let
1058 ref_str = occNameString (getOccName ref)
1059 occ_str = occNameString old_occ
1060 in
1061 case occ_str of
1062 '$':'w':_ -> occ_str
1063 -- workers: the worker for a function already
1064 -- includes the occname for its parent, so there's
1065 -- no need to prepend the referrer.
1066 _other | isSystemName name -> ref_str
1067 | otherwise -> ref_str ++ '_' : occ_str
1068 -- If this name was system-generated, then don't bother
1069 -- to retain its OccName, just use the referrer. These
1070 -- system-generated names will become "f1", "f2", etc. for
1071 -- a referrer "f".
1072 | otherwise = old_occ
1073
1074 (occ_env', occ') = tidyOccName occ_env new_occ
1075
1076 mk_new_local nc = (nc { nsUniqs = us }, mkInternalName uniq occ' loc)
1077 where
1078 (uniq, us) = takeUniqFromSupply (nsUniqs nc)
1079
1080 mk_new_external nc = allocateGlobalBinder nc mod occ' loc
1081 -- If we want to externalise a currently-local name, check
1082 -- whether we have already assigned a unique for it.
1083 -- If so, use it; if not, extend the table.
1084 -- All this is done by allcoateGlobalBinder.
1085 -- This is needed when *re*-compiling a module in GHCi; we must
1086 -- use the same name for externally-visible things as we did before.
1087
1088 {-
1089 ************************************************************************
1090 * *
1091 \subsection{Step 2: top-level tidying}
1092 * *
1093 ************************************************************************
1094 -}
1095
1096 -- TopTidyEnv: when tidying we need to know
1097 -- * nc_var: The NameCache, containing a unique supply and any pre-ordained Names.
1098 -- These may have arisen because the
1099 -- renamer read in an interface file mentioning M.$wf, say,
1100 -- and assigned it unique r77. If, on this compilation, we've
1101 -- invented an Id whose name is $wf (but with a different unique)
1102 -- we want to rename it to have unique r77, so that we can do easy
1103 -- comparisons with stuff from the interface file
1104 --
1105 -- * occ_env: The TidyOccEnv, which tells us which local occurrences
1106 -- are 'used'
1107 --
1108 -- * subst_env: A Var->Var mapping that substitutes the new Var for the old
1109
1110 tidyTopBinds :: HscEnv
1111 -> Module
1112 -> UnfoldEnv
1113 -> TidyOccEnv
1114 -> CoreProgram
1115 -> IO (TidyEnv, CoreProgram)
1116
1117 tidyTopBinds hsc_env this_mod unfold_env init_occ_env binds
1118 = do mkIntegerId <- lookupMkIntegerName dflags hsc_env
1119 integerSDataCon <- lookupIntegerSDataConName dflags hsc_env
1120 let cvt_integer = cvtLitInteger dflags mkIntegerId integerSDataCon
1121 return $ tidy cvt_integer init_env binds
1122 where
1123 dflags = hsc_dflags hsc_env
1124
1125 init_env = (init_occ_env, emptyVarEnv)
1126
1127 tidy _ env [] = (env, [])
1128 tidy cvt_integer env (b:bs)
1129 = let (env1, b') = tidyTopBind dflags this_mod
1130 cvt_integer unfold_env env b
1131 (env2, bs') = tidy cvt_integer env1 bs
1132 in (env2, b':bs')
1133
1134 ------------------------
1135 tidyTopBind :: DynFlags
1136 -> Module
1137 -> (Integer -> CoreExpr)
1138 -> UnfoldEnv
1139 -> TidyEnv
1140 -> CoreBind
1141 -> (TidyEnv, CoreBind)
1142
1143 tidyTopBind dflags this_mod cvt_integer unfold_env
1144 (occ_env,subst1) (NonRec bndr rhs)
1145 = (tidy_env2, NonRec bndr' rhs')
1146 where
1147 Just (name',show_unfold) = lookupVarEnv unfold_env bndr
1148 caf_info = hasCafRefs dflags this_mod (subst1, cvt_integer)
1149 (idArity bndr) rhs
1150 (bndr', rhs') = tidyTopPair dflags show_unfold tidy_env2 caf_info name'
1151 (bndr, rhs)
1152 subst2 = extendVarEnv subst1 bndr bndr'
1153 tidy_env2 = (occ_env, subst2)
1154
1155 tidyTopBind dflags this_mod cvt_integer unfold_env
1156 (occ_env, subst1) (Rec prs)
1157 = (tidy_env2, Rec prs')
1158 where
1159 prs' = [ tidyTopPair dflags show_unfold tidy_env2 caf_info name' (id,rhs)
1160 | (id,rhs) <- prs,
1161 let (name',show_unfold) =
1162 expectJust "tidyTopBind" $ lookupVarEnv unfold_env id
1163 ]
1164
1165 subst2 = extendVarEnvList subst1 (bndrs `zip` map fst prs')
1166 tidy_env2 = (occ_env, subst2)
1167
1168 bndrs = map fst prs
1169
1170 -- the CafInfo for a recursive group says whether *any* rhs in
1171 -- the group may refer indirectly to a CAF (because then, they all do).
1172 caf_info
1173 | or [ mayHaveCafRefs (hasCafRefs dflags this_mod
1174 (subst1, cvt_integer)
1175 (idArity bndr) rhs)
1176 | (bndr,rhs) <- prs ] = MayHaveCafRefs
1177 | otherwise = NoCafRefs
1178
1179 -----------------------------------------------------------
1180 tidyTopPair :: DynFlags
1181 -> Bool -- show unfolding
1182 -> TidyEnv -- The TidyEnv is used to tidy the IdInfo
1183 -- It is knot-tied: don't look at it!
1184 -> CafInfo
1185 -> Name -- New name
1186 -> (Id, CoreExpr) -- Binder and RHS before tidying
1187 -> (Id, CoreExpr)
1188 -- This function is the heart of Step 2
1189 -- The rec_tidy_env is the one to use for the IdInfo
1190 -- It's necessary because when we are dealing with a recursive
1191 -- group, a variable late in the group might be mentioned
1192 -- in the IdInfo of one early in the group
1193
1194 tidyTopPair dflags show_unfold rhs_tidy_env caf_info name' (bndr, rhs)
1195 = (bndr1, rhs1)
1196 where
1197 bndr1 = mkGlobalId details name' ty' idinfo'
1198 details = idDetails bndr -- Preserve the IdDetails
1199 ty' = tidyTopType (idType bndr)
1200 rhs1 = tidyExpr rhs_tidy_env rhs
1201 idinfo' = tidyTopIdInfo dflags rhs_tidy_env name' rhs rhs1 (idInfo bndr)
1202 show_unfold caf_info
1203
1204 -- tidyTopIdInfo creates the final IdInfo for top-level
1205 -- binders. There are two delicate pieces:
1206 --
1207 -- * Arity. After CoreTidy, this arity must not change any more.
1208 -- Indeed, CorePrep must eta expand where necessary to make
1209 -- the manifest arity equal to the claimed arity.
1210 --
1211 -- * CAF info. This must also remain valid through to code generation.
1212 -- We add the info here so that it propagates to all
1213 -- occurrences of the binders in RHSs, and hence to occurrences in
1214 -- unfoldings, which are inside Ids imported by GHCi. Ditto RULES.
1215 -- CoreToStg makes use of this when constructing SRTs.
1216 tidyTopIdInfo :: DynFlags -> TidyEnv -> Name -> CoreExpr -> CoreExpr
1217 -> IdInfo -> Bool -> CafInfo -> IdInfo
1218 tidyTopIdInfo dflags rhs_tidy_env name orig_rhs tidy_rhs idinfo show_unfold caf_info
1219 | not is_external -- For internal Ids (not externally visible)
1220 = vanillaIdInfo -- we only need enough info for code generation
1221 -- Arity and strictness info are enough;
1222 -- c.f. CoreTidy.tidyLetBndr
1223 `setCafInfo` caf_info
1224 `setArityInfo` arity
1225 `setStrictnessInfo` final_sig
1226
1227 | otherwise -- Externally-visible Ids get the whole lot
1228 = vanillaIdInfo
1229 `setCafInfo` caf_info
1230 `setArityInfo` arity
1231 `setStrictnessInfo` final_sig
1232 `setOccInfo` robust_occ_info
1233 `setInlinePragInfo` (inlinePragInfo idinfo)
1234 `setUnfoldingInfo` unfold_info
1235 -- NB: we throw away the Rules
1236 -- They have already been extracted by findExternalRules
1237 where
1238 is_external = isExternalName name
1239
1240 --------- OccInfo ------------
1241 robust_occ_info = zapFragileOcc (occInfo idinfo)
1242 -- It's important to keep loop-breaker information
1243 -- when we are doing -fexpose-all-unfoldings
1244
1245 --------- Strictness ------------
1246 mb_bot_str = exprBotStrictness_maybe orig_rhs
1247
1248 sig = strictnessInfo idinfo
1249 final_sig | not $ isTopSig sig
1250 = WARN( _bottom_hidden sig , ppr name ) sig
1251 -- try a cheap-and-cheerful bottom analyser
1252 | Just (_, nsig) <- mb_bot_str = nsig
1253 | otherwise = sig
1254
1255 _bottom_hidden id_sig = case mb_bot_str of
1256 Nothing -> False
1257 Just (arity, _) -> not (appIsBottom id_sig arity)
1258
1259 --------- Unfolding ------------
1260 unf_info = unfoldingInfo idinfo
1261 unfold_info | show_unfold = tidyUnfolding rhs_tidy_env unf_info unf_from_rhs
1262 | otherwise = noUnfolding
1263 unf_from_rhs = mkTopUnfolding dflags is_bot tidy_rhs
1264 is_bot = isBottomingSig final_sig
1265 -- NB: do *not* expose the worker if show_unfold is off,
1266 -- because that means this thing is a loop breaker or
1267 -- marked NOINLINE or something like that
1268 -- This is important: if you expose the worker for a loop-breaker
1269 -- then you can make the simplifier go into an infinite loop, because
1270 -- in effect the unfolding is exposed. See Trac #1709
1271 --
1272 -- You might think that if show_unfold is False, then the thing should
1273 -- not be w/w'd in the first place. But a legitimate reason is this:
1274 -- the function returns bottom
1275 -- In this case, show_unfold will be false (we don't expose unfoldings
1276 -- for bottoming functions), but we might still have a worker/wrapper
1277 -- split (see Note [Worker-wrapper for bottoming functions] in WorkWrap.hs
1278
1279 --------- Arity ------------
1280 -- Usually the Id will have an accurate arity on it, because
1281 -- the simplifier has just run, but not always.
1282 -- One case I found was when the last thing the simplifier
1283 -- did was to let-bind a non-atomic argument and then float
1284 -- it to the top level. So it seems more robust just to
1285 -- fix it here.
1286 arity = exprArity orig_rhs
1287
1288 {-
1289 ************************************************************************
1290 * *
1291 Figuring out CafInfo for an expression
1292 * *
1293 ************************************************************************
1294
1295 hasCafRefs decides whether a top-level closure can point into the dynamic heap.
1296 We mark such things as `MayHaveCafRefs' because this information is
1297 used to decide whether a particular closure needs to be referenced
1298 in an SRT or not.
1299
1300 There are two reasons for setting MayHaveCafRefs:
1301 a) The RHS is a CAF: a top-level updatable thunk.
1302 b) The RHS refers to something that MayHaveCafRefs
1303
1304 Possible improvement: In an effort to keep the number of CAFs (and
1305 hence the size of the SRTs) down, we could also look at the expression and
1306 decide whether it requires a small bounded amount of heap, so we can ignore
1307 it as a CAF. In these cases however, we would need to use an additional
1308 CAF list to keep track of non-collectable CAFs.
1309
1310 Note [Disgusting computation of CafRefs]
1311 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1312 We compute hasCafRefs here, because IdInfo is supposed to be finalised
1313 after TidyPgm. But CorePrep does some transformations that affect CAF-hood.
1314 So we have to *predict* the result here, which is revolting.
1315
1316 In particular CorePrep expands Integer literals. So in the prediction code
1317 here we resort to applying the same expansion (cvt_integer). Ugh!
1318 -}
1319
1320 type CafRefEnv = (VarEnv Id, Integer -> CoreExpr)
1321 -- The env finds the Caf-ness of the Id
1322 -- The Integer -> CoreExpr is the desugaring function for Integer literals
1323 -- See Note [Disgusting computation of CafRefs]
1324
1325 hasCafRefs :: DynFlags -> Module
1326 -> CafRefEnv -> Arity -> CoreExpr
1327 -> CafInfo
1328 hasCafRefs dflags this_mod p@(_,cvt_integer) arity expr
1329 | is_caf || mentions_cafs = MayHaveCafRefs
1330 | otherwise = NoCafRefs
1331 where
1332 mentions_cafs = cafRefsE p expr
1333 is_dynamic_name = isDllName dflags this_mod
1334 is_caf = not (arity > 0 || rhsIsStatic (targetPlatform dflags) is_dynamic_name cvt_integer expr)
1335
1336 -- NB. we pass in the arity of the expression, which is expected
1337 -- to be calculated by exprArity. This is because exprArity
1338 -- knows how much eta expansion is going to be done by
1339 -- CorePrep later on, and we don't want to duplicate that
1340 -- knowledge in rhsIsStatic below.
1341
1342 cafRefsE :: CafRefEnv -> Expr a -> Bool
1343 cafRefsE p (Var id) = cafRefsV p id
1344 cafRefsE p (Lit lit) = cafRefsL p lit
1345 cafRefsE p (App f a) = cafRefsE p f || cafRefsE p a
1346 cafRefsE p (Lam _ e) = cafRefsE p e
1347 cafRefsE p (Let b e) = cafRefsEs p (rhssOfBind b) || cafRefsE p e
1348 cafRefsE p (Case e _ _ alts) = cafRefsE p e || cafRefsEs p (rhssOfAlts alts)
1349 cafRefsE p (Tick _n e) = cafRefsE p e
1350 cafRefsE p (Cast e _co) = cafRefsE p e
1351 cafRefsE _ (Type _) = False
1352 cafRefsE _ (Coercion _) = False
1353
1354 cafRefsEs :: CafRefEnv -> [Expr a] -> Bool
1355 cafRefsEs _ [] = False
1356 cafRefsEs p (e:es) = cafRefsE p e || cafRefsEs p es
1357
1358 cafRefsL :: CafRefEnv -> Literal -> Bool
1359 -- Don't forget that mk_integer id might have Caf refs!
1360 -- We first need to convert the Integer into its final form, to
1361 -- see whether mkInteger is used.
1362 cafRefsL p@(_, cvt_integer) (LitInteger i _) = cafRefsE p (cvt_integer i)
1363 cafRefsL _ _ = False
1364
1365 cafRefsV :: CafRefEnv -> Id -> Bool
1366 cafRefsV (subst, _) id
1367 | not (isLocalId id) = mayHaveCafRefs (idCafInfo id)
1368 | Just id' <- lookupVarEnv subst id = mayHaveCafRefs (idCafInfo id')
1369 | otherwise = False
1370
1371
1372 {-
1373 ************************************************************************
1374 * *
1375 Old, dead, type-trimming code
1376 * *
1377 ************************************************************************
1378
1379 We used to try to "trim off" the constructors of data types that are
1380 not exported, to reduce the size of interface files, at least without
1381 -O. But that is not always possible: see the old Note [When we can't
1382 trim types] below for exceptions.
1383
1384 Then (Trac #7445) I realised that the TH problem arises for any data type
1385 that we have deriving( Data ), because we can invoke
1386 Language.Haskell.TH.Quote.dataToExpQ
1387 to get a TH Exp representation of a value built from that data type.
1388 You don't even need {-# LANGUAGE TemplateHaskell #-}.
1389
1390 At this point I give up. The pain of trimming constructors just
1391 doesn't seem worth the gain. So I've dumped all the code, and am just
1392 leaving it here at the end of the module in case something like this
1393 is ever resurrected.
1394
1395
1396 Note [When we can't trim types]
1397 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1398 The basic idea of type trimming is to export algebraic data types
1399 abstractly (without their data constructors) when compiling without
1400 -O, unless of course they are explicitly exported by the user.
1401
1402 We always export synonyms, because they can be mentioned in the type
1403 of an exported Id. We could do a full dependency analysis starting
1404 from the explicit exports, but that's quite painful, and not done for
1405 now.
1406
1407 But there are some times we can't do that, indicated by the 'no_trim_types' flag.
1408
1409 First, Template Haskell. Consider (Trac #2386) this
1410 module M(T, makeOne) where
1411 data T = Yay String
1412 makeOne = [| Yay "Yep" |]
1413 Notice that T is exported abstractly, but makeOne effectively exports it too!
1414 A module that splices in $(makeOne) will then look for a declaration of Yay,
1415 so it'd better be there. Hence, brutally but simply, we switch off type
1416 constructor trimming if TH is enabled in this module.
1417
1418 Second, data kinds. Consider (Trac #5912)
1419 {-# LANGUAGE DataKinds #-}
1420 module M() where
1421 data UnaryTypeC a = UnaryDataC a
1422 type Bug = 'UnaryDataC
1423 We always export synonyms, so Bug is exposed, and that means that
1424 UnaryTypeC must be too, even though it's not explicitly exported. In
1425 effect, DataKinds means that we'd need to do a full dependency analysis
1426 to see what data constructors are mentioned. But we don't do that yet.
1427
1428 In these two cases we just switch off type trimming altogether.
1429
1430 mustExposeTyCon :: Bool -- Type-trimming flag
1431 -> NameSet -- Exports
1432 -> TyCon -- The tycon
1433 -> Bool -- Can its rep be hidden?
1434 -- We are compiling without -O, and thus trying to write as little as
1435 -- possible into the interface file. But we must expose the details of
1436 -- any data types whose constructors or fields are exported
1437 mustExposeTyCon no_trim_types exports tc
1438 | no_trim_types -- See Note [When we can't trim types]
1439 = True
1440
1441 | not (isAlgTyCon tc) -- Always expose synonyms (otherwise we'd have to
1442 -- figure out whether it was mentioned in the type
1443 -- of any other exported thing)
1444 = True
1445
1446 | isEnumerationTyCon tc -- For an enumeration, exposing the constructors
1447 = True -- won't lead to the need for further exposure
1448
1449 | isFamilyTyCon tc -- Open type family
1450 = True
1451
1452 -- Below here we just have data/newtype decls or family instances
1453
1454 | null data_cons -- Ditto if there are no data constructors
1455 = True -- (NB: empty data types do not count as enumerations
1456 -- see Note [Enumeration types] in TyCon
1457
1458 | any exported_con data_cons -- Expose rep if any datacon or field is exported
1459 = True
1460
1461 | isNewTyCon tc && isFFITy (snd (newTyConRhs tc))
1462 = True -- Expose the rep for newtypes if the rep is an FFI type.
1463 -- For a very annoying reason. 'Foreign import' is meant to
1464 -- be able to look through newtypes transparently, but it
1465 -- can only do that if it can "see" the newtype representation
1466
1467 | otherwise
1468 = False
1469 where
1470 data_cons = tyConDataCons tc
1471 exported_con con = any (`elemNameSet` exports)
1472 (dataConName con : dataConFieldLabels con)
1473 -}