Fix bindist creation
[ghc.git] / aclocal.m4
1 # Extra autoconf macros for the Glasgow fptools
2 #
3 # To be a good autoconf citizen, names of local macros have prefixed with FP_ to
4 # ensure we don't clash with any pre-supplied autoconf ones.
5
6
7 # FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN
8 # ----------------------------------
9 # Little endian Arm on Linux with some ABIs has big endian word order
10 # in doubles. Define FLOAT_WORDS_BIGENDIAN if this is the case.
11 AC_DEFUN([FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN],
12   [AC_CACHE_CHECK([whether float word order is big endian], [fptools_cv_float_word_order_bigendian],
13     [AC_COMPILE_IFELSE(
14       [AC_LANG_PROGRAM(
15         [#include <endian.h>],
16         [#if defined(__FLOAT_WORD_ORDER) && __FLOAT_WORD_ORDER == BIG_ENDIAN
17              return 0;
18          #else
19              not float word order big endian
20          #endif]
21       )],
22       [fptools_cv_float_word_order_bigendian=yes],
23       [fptools_cv_float_word_order_bigendian=no])
24     ])
25   case $fptools_cv_float_word_order_bigendian in
26       yes)
27           AC_DEFINE([FLOAT_WORDS_BIGENDIAN], 1,
28           [Define to 1 if your processor stores words of floats with
29            the most significant byte first]) ;;
30   esac
31 ])
32
33
34 # FP_EVAL_STDERR(COMMAND)
35 # -----------------------
36 # Eval COMMAND, save its stderr (without lines resulting from shell tracing)
37 # into the file conftest.err and the exit status in the variable fp_status.
38 AC_DEFUN([FP_EVAL_STDERR],
39 [{ (eval $1) 2>conftest.er1
40   fp_status=$?
41   grep -v '^ *+' conftest.er1 >conftest.err
42   rm -f conftest.er1
43   (exit $fp_status); }[]dnl
44 ])# FP_EVAL_STDERR
45
46
47 # FP_CHECK_FLAG(FLAG, [ACTION-IF-SUPPORTED], [ACTION-IF-NOT-SUPPORTED])
48 # ---------------------------------------------------------------------
49 # Check to see whether the compiler for the current language supports a
50 # particular option.
51 #
52 # Implementation note: When given an unkown option, GCC issues an warning on
53 # stderr only, but returns an exit value of 0 nevertheless. Consequently we have
54 # to check stderr *and* the exit value.
55 #
56 # Used by ghc.
57 AC_DEFUN([FP_CHECK_FLAG],
58 [AC_LANG_COMPILER_REQUIRE()dnl
59 AC_LANG_CASE([C],          [fp_compiler="$CC"  m4_pushdef([fp_Flags], [CFLAGS])],
60              [C++],        [fp_compiler="$CXX" m4_pushdef([fp_Flags], [CXXFLAGS])],
61              [Fortran 77], [fp_compiler="$F77" m4_pushdef([fp_Flags], [FFLAGS])])
62 m4_pushdef([fp_Cache], [fp_cv_[]fp_Flags[]AS_TR_SH([$1])])[]dnl
63 AC_CACHE_CHECK([whether $fp_compiler accepts $1], [fp_Cache],
64 [AC_LANG_CONFTEST([AC_LANG_PROGRAM()])
65 fp_save_flags="$fp_Flags"
66 fp_Flags="$fp_Flags $1"
67 fp_Cache=no
68 if FP_EVAL_STDERR([$ac_compile conftest.$ac_ext]) >/dev/null; then
69   test -s conftest.err || fp_Cache=yes
70 fi
71 fp_Flags="$fp_save_flags"
72 rm -f conftest.err conftest.$ac_ext])
73 AS_IF([test $fp_Cache = yes], [$2], [$3])[]dnl
74 m4_popdef([fp_Cache])[]dnl
75 m4_popdef([fp_Flags])[]dnl
76 ])# FP_CHECK_FLAG
77
78
79 # FP_PROG_CONTEXT_DIFF
80 # --------------------
81 # Figure out how to do context diffs. Sets the output variable ContextDiffCmd.
82 #
83 # Note: NeXTStep thinks diff'ing a file against itself is "trouble".
84 #
85 # Used by ghc, glafp-utils/ltx, and glafp-utils/runstdtest.
86 AC_DEFUN([FP_PROG_CONTEXT_DIFF],
87 [AC_CACHE_CHECK([for a working context diff], [fp_cv_context_diff],
88 [echo foo > conftest1
89 echo foo > conftest2
90 fp_cv_context_diff=no
91 for fp_var in '-C 1' '-c1'
92 do
93   if diff $fp_var conftest1 conftest2 > /dev/null 2>&1; then
94     fp_cv_context_diff="diff $fp_var"
95     break
96   fi
97 done])
98 if test x"$fp_cv_context_diff" = xno; then
99    AC_MSG_ERROR([cannot figure out how to do context diffs])
100 fi
101 AC_SUBST(ContextDiffCmd, [$fp_cv_context_diff])
102 ])# FP_PROG_CONTEXT_DIFF
103
104
105 # FP_COMPUTE_INT(EXPRESSION, VARIABLE, INCLUDES, IF-FAILS)
106 # --------------------------------------------------------
107 # Assign VARIABLE the value of the compile-time EXPRESSION using INCLUDES for
108 # compilation. Execute IF-FAILS when unable to determine the value. Works for
109 # cross-compilation, too.
110 #
111 # Implementation note: We are lazy and use an internal autoconf macro, but it
112 # is supported in autoconf versions 2.50 up to the actual 2.57, so there is
113 # little risk.
114 AC_DEFUN([FP_COMPUTE_INT],
115 [_AC_COMPUTE_INT([$1], [$2], [$3], [$4])[]dnl
116 ])# FP_COMPUTE_INT
117
118
119 # FP_CHECK_ALIGNMENT(TYPE, [IGNORED], [INCLUDES = DEFAULT-INCLUDES])
120 # ------------------------------------------------------------------
121 # A variation of AC_CHECK_SIZEOF for computing the alignment restrictions of a
122 # given type. Defines ALIGNMENT_TYPE.
123 AC_DEFUN([FP_CHECK_ALIGNMENT],
124 [AS_LITERAL_IF([$1], [],
125                [AC_FATAL([$0: requires literal arguments])])[]dnl
126 AC_CHECK_TYPE([$1], [], [], [$3])[]dnl
127 m4_pushdef([fp_Cache], [AS_TR_SH([fp_cv_alignment_$1])])[]dnl
128 AC_CACHE_CHECK([alignment of $1], [fp_Cache],
129 [if test "$AS_TR_SH([ac_cv_type_$1])" = yes; then
130   FP_COMPUTE_INT([(long) (&((struct { char c; $1 ty; } *)0)->ty)],
131                  [fp_Cache],
132                  [AC_INCLUDES_DEFAULT([$3])],
133                  [AC_MSG_ERROR([cannot compute alignment ($1)
134 See `config.log' for more details.], [77])])
135 else
136   fp_Cache=0
137 fi])[]dnl
138 AC_DEFINE_UNQUOTED(AS_TR_CPP(alignment_$1), $fp_Cache, [The alignment of a `$1'.])[]dnl
139 m4_popdef([fp_Cache])[]dnl
140 ])# FP_CHECK_ALIGNMENT
141
142
143 # FP_LEADING_UNDERSCORE
144 # ---------------------
145 # Test for determining whether symbol names have a leading underscore. We assume
146 # that they _haven't_ if anything goes wrong. Sets the output variable
147 # LeadingUnderscore to YES or NO and defines LEADING_UNDERSCORE correspondingly.
148 #
149 # Some nlist implementations seem to try to be compatible by ignoring a leading
150 # underscore sometimes (eg. FreeBSD). We therefore have to work around this by
151 # checking for *no* leading underscore first. Sigh.  --SDM
152 #
153 # Similarly on OpenBSD, but this test doesn't help. -- dons
154 AC_DEFUN([FP_LEADING_UNDERSCORE],
155 [AC_CHECK_LIB([elf], [nlist], [LIBS="-lelf $LIBS"])
156 AC_CACHE_CHECK([leading underscore in symbol names], [fptools_cv_leading_underscore], [
157 # Hack!: nlist() under Digital UNIX insist on there being an _,
158 # but symbol table listings shows none. What is going on here?!?
159 #
160 # Another hack: cygwin doesn't come with nlist.h , so we hardwire
161 # the underscoredness of that "platform"
162 case $HostPlatform in
163 *openbsd*) # x86 openbsd is ELF from 3.4 >, meaning no leading uscore
164   case $build in
165     i386-*2\.@<:@0-9@:>@ | i386-*3\.@<:@0-3@:>@ ) fptools_cv_leading_underscore=yes ;;
166     *) fptools_cv_leading_underscore=no ;;
167   esac ;;
168 alpha-dec-osf*) fptools_cv_leading_underscore=no;;
169 *cygwin32) fptools_cv_leading_underscore=yes;;
170 *mingw32) fptools_cv_leading_underscore=yes;;
171
172     # HACK: Apple doesn't seem to provide nlist in the 64-bit-libraries
173 x86_64-apple-darwin*) fptools_cv_leading_underscore=yes;;
174
175 *) AC_RUN_IFELSE([AC_LANG_SOURCE([[#ifdef HAVE_NLIST_H
176 #include <nlist.h>
177 struct nlist xYzzY1[] = {{"xYzzY1", 0},{0}};
178 struct nlist xYzzY2[] = {{"_xYzzY2", 0},{0}};
179 #endif
180
181 int main(argc, argv)
182 int argc;
183 char **argv;
184 {
185 #ifdef HAVE_NLIST_H
186     if(nlist(argv[0], xYzzY1) == 0 && xYzzY1[0].n_value != 0)
187         exit(1);
188     if(nlist(argv[0], xYzzY2) == 0 && xYzzY2[0].n_value != 0)
189         exit(0);
190 #endif
191     exit(1);
192 }]])],[fptools_cv_leading_underscore=yes],[fptools_cv_leading_underscore=no],[fptools_cv_leading_underscore=no])
193 ;;
194 esac]);
195 AC_SUBST([LeadingUnderscore], [`echo $fptools_cv_leading_underscore | sed 'y/yesno/YESNO/'`])
196 if test x"$fptools_cv_leading_underscore" = xyes; then
197    AC_DEFINE([LEADING_UNDERSCORE], [1], [Define to 1 if C symbols have a leading underscore added by the compiler.])
198 fi])# FP_LEADING_UNDERSCORE
199
200
201 # FP_COMPARE_VERSIONS(VERSION1, TEST, VERSION2, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
202 # ----------------------------------------------------------------------------------
203 # Compare dotted version numbers VERSION1 and VERSION2 lexicographically according
204 # to TEST (one of -eq, -ne, -lt, -le, -gt, or -ge).
205 AC_DEFUN([FP_COMPARE_VERSIONS],
206 [fp_version1=$1; fp_version2=$3
207 fp_save_IFS=$IFS; IFS='.'
208 while test x"$fp_version1" != x || test x"$fp_version2" != x
209 do
210
211   set dummy $fp_version1; shift
212   fp_num1=""
213   test $[@%:@] = 0 || { fp_num1="[$]1"; shift; }
214   test x"$fp_num1" = x && fp_num1="0"
215   fp_version1="[$]*"
216
217   set dummy $fp_version2; shift
218   fp_num2=""
219   test $[@%:@] = 0 || { fp_num2="[$]1"; shift; }
220   test x"$fp_num2" = x && fp_num2="0"
221   fp_version2="[$]*"
222
223   test "$fp_num1" = "$fp_num2" || break;
224 done
225 IFS=$fp_save_IFS
226 AS_IF([test "$fp_num1" $2 "$fp_num2"], [$4], [$5])[]dnl
227 ])# FP_COMPARE_VERSIONS
228
229
230 dnl
231 dnl Check for GreenCard and version.
232 dnl
233 AC_DEFUN([FPTOOLS_GREENCARD],
234 [
235 AC_PATH_PROG(GreenCardCmd,greencard)
236 AC_CACHE_CHECK([for version of greencard], fptools_cv_greencard_version,
237 changequote(, )dnl
238 [if test x"$GreenCardCmd" != x; then
239    fptools_cv_greencard_version="`$GreenCardCmd --version |
240                           grep 'version' | sed -e 's/greencard. version \([^ ]*\).*/\1/g'`"
241 else
242    fptools_cv_greencard_version=""
243 fi
244 changequote([, ])dnl
245 ])
246 FP_COMPARE_VERSIONS([$fptools_cv_greencard_version],[-lt],[$1],
247   [AC_MSG_ERROR([greencard version $1 or later is required (found '$fptools_cv_greencard_version')])])[]dnl
248 GreenCardVersion=$fptools_cv_greencard_version
249 AC_SUBST(GreenCardVersion)
250 ])
251
252 dnl
253 dnl Check for Happy and version.  If we're building GHC, then we need
254 dnl at least Happy version 1.14.  If there's no installed Happy, we look
255 dnl for a happy source tree and point the build system at that instead.
256 dnl
257 AC_DEFUN([FPTOOLS_HAPPY],
258 [AC_PATH_PROG(HappyCmd,happy,)
259 AC_CACHE_CHECK([for version of happy], fptools_cv_happy_version,
260 changequote(, )dnl
261 [if test x"$HappyCmd" != x; then
262    fptools_cv_happy_version="`$HappyCmd -v |
263                           grep 'Happy Version' | sed -e 's/Happy Version \([^ ]*\).*/\1/g'`" ;
264 else
265    fptools_cv_happy_version="";
266 fi;
267 changequote([, ])dnl
268 ])
269 if test ! -f compiler/parser/Parser.hs || test ! -f compiler/main/ParsePkgConf.hs || test ! -f compiler/cmm/CmmParse.hs || test ! -f compiler/parser/ParserCore.hs
270 then
271     FP_COMPARE_VERSIONS([$fptools_cv_happy_version],[-lt],[1.15],
272       [AC_MSG_ERROR([Happy version 1.15 or later is required to compile GHC.])])[]dnl
273 fi
274 HappyVersion=$fptools_cv_happy_version;
275 AC_SUBST(HappyVersion)
276 ])
277
278 dnl
279 dnl Check for Haddock and version.  If there's no installed Haddock, we look
280 dnl for a haddock source tree and point the build system at that instead.
281 dnl
282 AC_DEFUN([FPTOOLS_HADDOCK],
283 [AC_PATH_PROG(HaddockCmd,haddock,)
284 dnl Darn, I forgot to make Haddock print out its version number when
285 dnl invoked with -v.  We could try generating some HTML and grepping
286 dnl through that to find the version number, but I think we'll make
287 dnl do without it for now.
288 ])
289
290 dnl
291 dnl Check for Alex and version.  If we're building GHC, then we need
292 dnl at least Alex version 2.0.1.
293 dnl
294 AC_DEFUN([FPTOOLS_ALEX],
295 [
296 AC_PATH_PROG(AlexCmd,alex,)
297 AC_CACHE_CHECK([for version of alex], fptools_cv_alex_version,
298 changequote(, )dnl
299 [if test x"$AlexCmd" != x; then
300    fptools_cv_alex_version="`$AlexCmd -v |
301                           grep 'Alex [Vv]ersion' | sed -e 's/Alex [Vv]ersion \([0-9\.]*\).*/\1/g'`" ;
302 else
303    fptools_cv_alex_version="";
304 fi;
305 changequote([, ])dnl
306 ])
307 if test ! -f compiler/cmm/CmmLex.hs || test ! -f compiler/parser/Lexer.hs
308 then
309     FP_COMPARE_VERSIONS([$fptools_cv_alex_version],[-lt],[2.0.1],
310       [AC_MSG_ERROR([Alex version 2.0.1 or later is required to compile GHC.])])[]dnl
311 fi
312 AlexVersion=$fptools_cv_alex_version;
313 AC_SUBST(AlexVersion)
314 ])
315
316
317 # FP_PROG_LD
318 # ----------
319 # Sets the output variable LdCmd to the (non-Cygwin version of the) full path
320 # of ld. Exits if no ld can be found
321 AC_DEFUN([FP_PROG_LD],
322 [
323 if test -z "$1"
324 then
325   AC_PATH_PROG([fp_prog_ld_raw], [ld])
326   if test -z "$fp_prog_ld_raw"; then
327     AC_MSG_ERROR([cannot find ld in your PATH, no idea how to link])
328   fi
329   LdCmd=$fp_prog_ld_raw
330   case $HostPlatform in
331     *mingw32) if test x${OSTYPE} != xmsys; then
332               LdCmd="`cygpath -w ${fp_prog_ld_raw} | sed -e 's@\\\\@/@g'`"
333                 AC_MSG_NOTICE([normalized ld command to $LdCmd])
334               fi
335             # Insist on >= ld-2.15.x, since earlier versions doesn't handle
336             # the generation of relocatable object files with large amounts
337             # of relocations correctly. (cf. HSbase.o splittage-hack)
338             fp_prog_ld_version=`${LdCmd} --version | sed -n '/GNU ld/p' | tr -cd 0-9 | cut -b1-3`
339             FP_COMPARE_VERSIONS([$fp_prog_ld_version],[-lt],[214],
340                                   [AC_MSG_ERROR([GNU ld version later than 2.14 required to compile GHC on Windows.])])[]dnl
341               ;;
342   esac
343 else
344   LdCmd="$1"
345 fi
346 AC_SUBST([LdCmd])
347 ])# FP_PROG_LD
348
349
350 # FP_PROG_LD_X
351 # ------------
352 # Sets the output variable LdXFlag to -x if ld supports this flag, otherwise the
353 # variable's value is empty.
354 AC_DEFUN([FP_PROG_LD_X],
355 [AC_REQUIRE([FP_PROG_LD])
356 AC_CACHE_CHECK([whether ld understands -x], [fp_cv_ld_x],
357 [echo 'foo() {}' > conftest.c
358 ${CC-cc} -c conftest.c
359 if ${LdCmd} -r -x -o conftest2.o conftest.o > /dev/null 2>&1; then
360    fp_cv_ld_x=yes
361 else
362    fp_cv_ld_x=no
363 fi
364 rm -rf conftest*])
365 if test "$fp_cv_ld_x" = yes; then
366   LdXFlag=-x
367 else
368   LdXFlag=
369 fi
370 AC_SUBST([LdXFlag])
371 ])# FP_PROG_LD_X
372
373
374 # FP_PROG_LD_IS_GNU
375 # -----------------
376 # Sets the output variable LdIsGNULd to YES or NO, depending on whether it is
377 # GNU ld or not.
378 AC_DEFUN([FP_PROG_LD_IS_GNU],
379 [AC_REQUIRE([FP_PROG_LD])
380 AC_CACHE_CHECK([whether ld is GNU ld], [fp_cv_gnu_ld],
381 [if ${LdCmd} --version 2> /dev/null | grep "GNU" > /dev/null 2>&1; then
382   fp_cv_gnu_ld=yes
383 else
384   fp_cv_gnu_ld=no
385 fi])
386 AC_SUBST([LdIsGNULd], [`echo $fp_cv_gnu_ld | sed 'y/yesno/YESNO/'`])
387 ])# FP_PROG_LD_IS_GNU
388
389
390 # FP_PROG_AR
391 # ----------
392 # Sets fp_prog_ar_raw to the full path of ar and fp_prog_ar to a non-Cygwin
393 # version of it. Exits if no ar can be found
394 AC_DEFUN([FP_PROG_AR],
395 [AC_PATH_PROG([fp_prog_ar_raw], [ar])
396 if test -z "$fp_prog_ar_raw"; then
397   AC_MSG_ERROR([cannot find ar in your PATH, no idea how to make a library])
398 fi
399 fp_prog_ar=$fp_prog_ar_raw
400 case $HostPlatform in
401   *mingw32) if test x${OSTYPE} != xmsys; then
402               fp_prog_ar="`cygpath -w ${fp_prog_ar_raw} | sed -e 's@\\\\@/@g'`"
403               AC_MSG_NOTICE([normalized ar command to $fp_prog_ar])
404             fi
405             ;;
406 esac
407 ])# FP_PROG_AR
408
409
410 # FP_PROG_AR_IS_GNU
411 # -----------------
412 # Sets fp_prog_ar_is_gnu to yes or no, depending on whether it is GNU ar or not.
413 AC_DEFUN([FP_PROG_AR_IS_GNU],
414 [AC_REQUIRE([FP_PROG_AR])
415 AC_CACHE_CHECK([whether $fp_prog_ar_raw is GNU ar], [fp_cv_prog_ar_is_gnu],
416 [if $fp_prog_ar_raw --version 2> /dev/null | grep "GNU" > /dev/null 2>&1; then
417   fp_cv_prog_ar_is_gnu=yes
418 else
419   fp_cv_prog_ar_is_gnu=no
420 fi])
421 fp_prog_ar_is_gnu=$fp_cv_prog_ar_is_gnu
422 ])# FP_PROG_AR_IS_GNU
423
424
425 # FP_PROG_AR_ARGS
426 # ---------------
427 # Sets fp_prog_ar_args to the arguments for ar and the output variable ArCmd
428 # to a non-Cygwin invocation of ar including these arguments.
429 AC_DEFUN([FP_PROG_AR_ARGS],
430 [AC_REQUIRE([FP_PROG_AR_IS_GNU])
431 AC_CACHE_CHECK([for ar arguments], [fp_cv_prog_ar_args],
432 [
433 # GNU ar needs special treatment: it appears to have problems with
434 # object files with the same name if you use the 's' modifier, but
435 # simple 'ar q' works fine, and doesn't need a separate ranlib.
436 if test $fp_prog_ar_is_gnu = yes; then
437   fp_cv_prog_ar_args="q"
438 else
439   touch conftest.dummy
440   for fp_var in clqsZ clqs cqs clq cq ; do
441      rm -f conftest.a
442      if $fp_prog_ar_raw $fp_var conftest.a conftest.dummy > /dev/null 2> /dev/null; then
443         fp_cv_prog_ar_args=$fp_var
444         break
445      fi
446   done
447   rm -f conftest*
448   if test -z "$fp_cv_prog_ar_args"; then
449     AC_MSG_ERROR([cannot figure out how to use your $fp_prog_ar_raw])
450   fi
451 fi])
452 fp_prog_ar_args=$fp_cv_prog_ar_args
453 AC_SUBST([ArCmd], ["$fp_prog_ar $fp_prog_ar_args"])
454
455 ])# FP_PROG_AR_ARGS
456
457
458 # FP_PROG_AR_NEEDS_RANLIB
459 # -----------------------
460 # Sets the output variable RANLIB to "ranlib" if it is needed and found,
461 # to ":" otherwise.
462 AC_DEFUN([FP_PROG_AR_NEEDS_RANLIB],
463 [AC_REQUIRE([FP_PROG_AR_IS_GNU])
464 AC_REQUIRE([FP_PROG_AR_ARGS])
465 AC_REQUIRE([AC_PROG_CC])
466 AC_CACHE_CHECK([whether ranlib is needed], [fp_cv_prog_ar_needs_ranlib],
467 [if test $fp_prog_ar_is_gnu = yes; then
468   fp_cv_prog_ar_needs_ranlib=no
469 elif echo $TargetPlatform | grep "^.*-apple-darwin$"  > /dev/null 2> /dev/null; then
470   # It's quite tedious to check for Apple's crazy timestamps in .a files,
471   # so we hardcode it.
472   fp_cv_prog_ar_needs_ranlib=yes
473 elif echo $fp_prog_ar_args | grep "s" > /dev/null 2> /dev/null; then
474   fp_cv_prog_ar_needs_ranlib=no
475 else
476   fp_cv_prog_ar_needs_ranlib=yes
477 fi])
478 if test $fp_cv_prog_ar_needs_ranlib = yes; then
479    AC_PROG_RANLIB
480 else
481   RANLIB=":"
482   AC_SUBST([RANLIB])
483 fi
484 ])# FP_PROG_AR_NEEDS_RANLIB
485
486
487 # FP_PROG_AR_SUPPORTS_INPUT
488 # -------------------------
489 # Sets the output variable ArSupportsInput to "-input" or "", depending on
490 # whether ar supports -input flag is supported or not.
491 AC_DEFUN([FP_PROG_AR_SUPPORTS_INPUT],
492 [AC_REQUIRE([FP_PROG_AR_IS_GNU])
493 AC_REQUIRE([FP_PROG_AR_ARGS])
494 AC_CACHE_CHECK([whether $fp_prog_ar_raw supports -input], [fp_cv_prog_ar_supports_input],
495 [fp_cv_prog_ar_supports_input=no
496 if test $fp_prog_ar_is_gnu = no; then
497   rm -f conftest*
498   touch conftest.lst
499   if FP_EVAL_STDERR([$fp_prog_ar_raw $fp_prog_ar_args conftest.a -input conftest.lst]) >/dev/null; then
500     test -s conftest.err || fp_cv_prog_ar_supports_input=yes
501   fi
502   rm -f conftest*
503 fi])
504 if test $fp_cv_prog_ar_supports_input = yes; then
505     ArSupportsInput="-input"
506 else
507     ArSupportsInput=""
508 fi
509 AC_SUBST([ArSupportsInput])
510 ])# FP_PROG_AR_SUPPORTS_INPUT
511
512
513 dnl
514 dnl AC_SHEBANG_PERL - can we she-bang perl?
515 dnl
516 AC_DEFUN([FPTOOLS_SHEBANG_PERL],
517 [AC_CACHE_CHECK([if your perl works in shell scripts], fptools_cv_shebang_perl,
518 [echo "#!$PerlCmd"'
519 exit $1;
520 ' > conftest
521 chmod u+x conftest
522 (SHELL=/bin/sh; export SHELL; ./conftest 69 > /dev/null)
523 if test $? -ne 69; then
524    fptools_cv_shebang_perl=yes
525 else
526    fptools_cv_shebang_perl=no
527 fi
528 rm -f conftest
529 ])])
530
531
532 # FP_HAVE_GCC
533 # -----------
534 # Extra testing of the result AC_PROG_CC, testing the gcc version no. Sets the
535 # output variables HaveGcc and GccVersion.
536 AC_DEFUN([FP_HAVE_GCC],
537 [AC_REQUIRE([AC_PROG_CC])
538 if test -z "$GCC"; then
539    fp_have_gcc=NO
540 else
541    fp_have_gcc=YES
542 fi
543 if test "$fp_have_gcc" = "NO" -a -d $srcdir/ghc; then
544   AC_MSG_ERROR([gcc is required])
545 fi
546 AC_CACHE_CHECK([version of gcc], [fp_gcc_version],
547 [if test "$fp_have_gcc" = "YES"; then
548    fp_gcc_version="`$CC -v 2>&1 | grep 'version ' | sed -e 's/.*version [[^0-9]]*\([[0-9.]]*\).*/\1/g'`"
549    FP_COMPARE_VERSIONS([$fp_gcc_version], [-lt], [2.0],
550      [AC_MSG_ERROR([Need at least gcc version 2.0 (3.4+ recommended)])])
551  else
552    fp_gcc_version="not-installed"
553  fi
554 ])
555 AC_SUBST([HaveGcc], [$fp_have_gcc])
556 AC_SUBST([GccVersion], [$fp_gcc_version])
557 ])# FP_HAVE_GCC
558
559 AC_DEFUN([FP_MINGW_GCC],
560 [
561   case $HostOS_CPP in
562     mingw*)  AC_MSG_CHECKING([whether $CC is a mingw gcc])
563              if $CC -v 2>&1 | grep mingw >/dev/null; then
564                 AC_MSG_RESULT([yes])
565              else
566                 AC_MSG_RESULT([no])
567                 AC_MSG_ERROR([Please use --with-gcc to specify a mingw gcc])
568              fi;;
569     *) ;;       
570   esac
571 ])
572
573 dnl Small feature test for perl version. Assumes PerlCmd
574 dnl contains path to perl binary
575 dnl
576 AC_DEFUN([FPTOOLS_CHECK_PERL_VERSION],
577 [$PerlCmd -v >conftest.out 2>&1
578    if grep "v5.6" conftest.out >/dev/null 2>&1; then
579       :
580    else
581       if grep "v5.8" conftest.out >/dev/null 2>&1; then
582          :
583       else
584          if grep "version 6" conftest.out >/dev/null 2>&1; then
585             :
586          else
587             AC_MSG_ERROR([your version of perl probably won't work, try upgrading it.])
588          fi
589       fi
590    fi
591 rm -fr conftest*
592 ])
593
594
595 # FP_CHECK_PROG(VARIABLE, PROG-TO-CHECK-FOR,
596 #               [VALUE-IF-NOT-FOUND], [PATH], [REJECT])
597 # -----------------------------------------------------
598 # HACK: A small wrapper around AC_CHECK_PROG, setting VARIABLE to the full path
599 # of PROG-TO-CHECK-FOR when found.
600 AC_DEFUN([FP_CHECK_PROG],
601 [AC_CHECK_PROG([$1], [$2], [$as_dir/$ac_word$ac_exec_ext], [$3], [$4], [$5])][]dnl
602 )# FP_CHECK_PROC
603
604
605 # FP_PROG_FIND
606 # ------------
607 # Find a non-WinDoze version of the "find" utility.
608 AC_DEFUN([FP_PROG_FIND],
609 [AC_PATH_PROG([fp_prog_find], [find])
610 echo foo > conftest.txt
611 $fp_prog_find conftest.txt -print > conftest.out 2>&1
612 if grep '^conftest.txt$' conftest.out > /dev/null 2>&1 ; then
613   # OK, looks like a real "find".
614   case $HostPlatform in
615     *mingw32)
616       if test x${OSTYPE} != xmsys
617       then
618             fp_prog_find="`cygpath --mixed ${fp_prog_find}`"
619         AC_MSG_NOTICE([normalized find command to $fp_prog_find])
620       fi ;;
621     *) ;;
622   esac
623   FindCmd="$fp_prog_find"
624 else
625   # Found a poor WinDoze version of "find", ignore it.
626   AC_MSG_WARN([$fp_prog_find looks like a non-*nix find, ignoring it])
627   FP_CHECK_PROG([FindCmd], [find], [], [], [$fp_prog_find])
628 fi
629 rm -f conftest.txt conftest.out
630 AC_SUBST([FindCmd])[]dnl
631 ])# FP_PROG_FIND
632
633
634 # FP_PROG_SORT
635 # ------------
636 # Find a Unix-like sort
637 AC_DEFUN([FP_PROG_SORT],
638 [AC_PATH_PROG([fp_prog_sort], [sort])
639 echo conwip > conftest.txt
640 $fp_prog_sort -f conftest.txt > conftest.out 2>&1
641 if grep 'conwip' conftest.out > /dev/null 2>&1 ; then
642   # The goods
643   SortCmd="$fp_prog_sort"
644 else
645   # Summink else..pick next one.
646   AC_MSG_WARN([$fp_prog_sort looks like a non-*nix sort, ignoring it])
647   FP_CHECK_PROG([SortCmd], [sort], [], [], [$fp_prog_sort])
648 fi
649 rm -f conftest.txt conftest.out
650 AC_SUBST([SortCmd])[]dnl
651 ])# FP_PROG_SORT
652
653 dnl
654 dnl FPTOOLS_NOCACHE_CHECK prints a message, then sets the
655 dnl values of the second argument to the result of running
656 dnl the commands given by the third. It does not cache its
657 dnl result, so it is suitable for checks which should be
658 dnl run every time.
659 dnl
660 AC_DEFUN([FPTOOLS_NOCACHE_CHECK],
661 [AC_MSG_CHECKING([$1])
662  $3
663  AC_MSG_RESULT([$][$2])
664 ])
665
666 dnl
667 dnl FPTOOLS_GHC_VERSION(version)
668 dnl FPTOOLS_GHC_VERSION(major, minor [, patchlevel])
669 dnl FPTOOLS_GHC_VERSION(version, major, minor, patchlevel)
670 dnl
671 dnl Test for version of installed ghc.  Uses $GHC.
672 dnl [original version pinched from c2hs]
673 dnl
674 AC_DEFUN([FPTOOLS_GHC_VERSION],
675 [FPTOOLS_NOCACHE_CHECK([version of ghc], [fptools_version_of_ghc],
676 ["${WithGhc-ghc}" --version > conftestghc 2>&1
677   cat conftestghc >&AS_MESSAGE_LOG_FD
678 #Useless Use Of cat award...
679   fptools_version_of_ghc=`cat conftestghc | sed -n -e 's/, patchlevel *\([[0-9]]\)/.\1/;s/.* version \([[0-9]][[0-9.]]*\).*/\1/p'`
680   rm -fr conftest*
681   if test "[$]fptools_version_of_ghc" = ""
682   then
683     fptools_version_of_ghc='unknown'
684   fi
685 fptools_version_of_ghc[_major]=`echo [$]fptools_version_of_ghc | sed -e 's/^\([[0-9]]\).*/\1/'`
686 fptools_version_of_ghc[_minor]=`echo [$]fptools_version_of_ghc | sed -e 's/^[[0-9]]\.\([[0-9]]*\).*/\1/'`
687 fptools_version_of_ghc[_pl]=`echo [$]fptools_version_of_ghc | sed -n -e 's/^[[0-9]]\.[[0-9]]*\.\([[0-9]]*\)/\1/p'`
688 #
689 if test "[$]fptools_version_of_ghc[_pl]" = ""
690 then
691   fptools_version_of_ghc[_all]="[$]fptools_version_of_ghc[_major].[$]fptools_version_of_ghc[_minor]"
692   fptools_version_of_ghc[_pl]="0"
693 else
694   fptools_version_of_ghc[_all]="[$]fptools_version_of_ghc[_major].[$]fptools_version_of_ghc[_minor].[$]fptools_version_of_ghc[_pl]"
695 fi
696 #
697 ifelse($#, [1], [dnl
698 [$1]="[$]fptools_version_of_ghc[_all]"
699 ], $#, [2], [dnl
700 [$1]="[$]fptools_version_of_ghc[_major]"
701 [$2]="[$]fptools_version_of_ghc[_minor]"
702 ], $#, [3], [dnl
703 [$1]="[$]fptools_version_of_ghc[_major]"
704 [$2]="[$]fptools_version_of_ghc[_minor]"
705 [$3]="[$]fptools_version_of_ghc[_pl]"
706 ], $#, [4], [dnl
707 [$1]="[$]fptools_version_of_ghc[_all]"
708 [$2]="[$]fptools_version_of_ghc[_major]"
709 [$3]="[$]fptools_version_of_ghc[_minor]"
710 [$4]="[$]fptools_version_of_ghc[_pl]"
711 ])
712 ])
713 ])dnl
714
715
716 # FP_CHECK_FUNC(FUNCTION, PROLOGUE, BODY, [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND])
717 # ---------------------------------------------------------------------------------
718 # A variant of AC_CHECK_FUNCS, limited to a single FUNCTION, but with the
719 # additional flexibility of specifying the PROLOGUE and BODY.
720 AC_DEFUN([FP_CHECK_FUNC],
721 [AS_VAR_PUSHDEF([fp_func], [fp_cv_func_$1])dnl
722 AC_CACHE_CHECK([for $1], fp_func,
723 [AC_LINK_IFELSE([AC_LANG_PROGRAM([$2], [$3])],
724                 [AS_VAR_SET(fp_func, yes)],
725                 [AS_VAR_SET(fp_func, no)])])
726 AS_IF([test AS_VAR_GET(fp_func) = yes],
727       [AC_DEFINE(AS_TR_CPP(HAVE_$1), [1],
728                 [Define to 1 if you have the `]$1[' function.]) $4],
729       [$5])dnl
730 AS_VAR_POPDEF([fp_func])dnl
731 ])# FP_CHECK_FUNC
732
733
734 # FP_GEN_DOCBOOK_XML
735 # ------------------
736 # Generates a DocBook XML V4.2 document in conftest.xml.
737 AC_DEFUN([FP_GEN_DOCBOOK_XML],
738 [rm -f conftest.xml
739 cat > conftest.xml << EOF
740 <?xml version="1.0" encoding="iso-8859-1"?>
741 <!DOCTYPE book PUBLIC "-//OASIS//DTD DocBook XML V4.2//EN"
742    "http://www.oasis-open.org/docbook/xml/4.2/docbookx.dtd">
743 <book id="test">
744   <title>A DocBook Test Document</title>
745   <chapter id="id-one">
746     <title>A Chapter Title</title>
747     <para>This is a paragraph, referencing <xref linkend="id-two"/>.</para>
748   </chapter>
749   <chapter id="id-two">
750     <title>Another Chapter Title</title>
751     <para>This is another paragraph, referencing <xref linkend="id-one"/>.</para>
752   </chapter>
753 </book>
754 EOF
755 ]) # FP_GEN_DOCBOOK_XML
756
757
758 # FP_PROG_XSLTPROC
759 # ----------------
760 # Sets the output variable XsltprocCmd to the full path of the XSLT processor
761 # xsltproc. XsltprocCmd is empty if xsltproc could not be found.
762 AC_DEFUN([FP_PROG_XSLTPROC],
763 [AC_PATH_PROG([XsltprocCmd], [xsltproc])
764 if test -z "$XsltprocCmd"; then
765   AC_MSG_WARN([cannot find xsltproc in your PATH, you will not be able to build the documentation])
766 fi
767 ])# FP_PROG_XSLTPROC
768
769
770 # FP_DIR_DOCBOOK_XSL(XSL-DIRS)
771 # ----------------------------
772 # Check which of the directories XSL-DIRS contains DocBook XSL stylesheets. The
773 # output variable DIR_DOCBOOK_XSL will contain the first usable directory or
774 # will be empty if none could be found.
775 AC_DEFUN([FP_DIR_DOCBOOK_XSL],
776 [AC_REQUIRE([FP_PROG_XSLTPROC])dnl
777 if test -n "$XsltprocCmd"; then
778   AC_CACHE_CHECK([for DocBook XSL stylesheet directory], fp_cv_dir_docbook_xsl,
779   [FP_GEN_DOCBOOK_XML
780   fp_cv_dir_docbook_xsl=no
781   for fp_var in $1; do
782      if $XsltprocCmd ${fp_var}/html/docbook.xsl conftest.xml > /dev/null 2>&1; then
783         fp_cv_dir_docbook_xsl=$fp_var
784         break
785      fi
786   done
787   rm -rf conftest*])
788 fi
789 if test x"$fp_cv_dir_docbook_xsl" = xno; then
790   AC_MSG_WARN([cannot find DocBook XSL stylesheets, you will not be able to build the documentation])
791   DIR_DOCBOOK_XSL=
792 else
793   DIR_DOCBOOK_XSL=$fp_cv_dir_docbook_xsl
794 fi
795 AC_SUBST([DIR_DOCBOOK_XSL])
796 ])# FP_DIR_DOCBOOK_XSL
797
798
799 # FP_PROG_XMLLINT
800 # ----------------
801 # Sets the output variable XmllintCmd to the full path of the XSLT processor
802 # xmllint. XmllintCmd is empty if xmllint could not be found.
803 AC_DEFUN([FP_PROG_XMLLINT],
804 [AC_PATH_PROG([XmllintCmd], [xmllint])
805 if test -z "$XmllintCmd"; then
806   AC_MSG_WARN([cannot find xmllint in your PATH, you will not be able to validate your documentation])
807 fi
808 ])# FP_PROG_XMLLINT
809
810
811 # FP_CHECK_DOCBOOK_DTD
812 # --------------------
813 AC_DEFUN([FP_CHECK_DOCBOOK_DTD],
814 [AC_REQUIRE([FP_PROG_XMLLINT])dnl
815 if test -n "$XmllintCmd"; then
816   AC_MSG_CHECKING([for DocBook DTD])
817   FP_GEN_DOCBOOK_XML
818   if $XmllintCmd --valid --noout conftest.xml > /dev/null 2>&1; then
819     AC_MSG_RESULT([ok])
820   else
821     AC_MSG_RESULT([failed])
822     AC_MSG_WARN([cannot find a DTD for DocBook XML V4.2, you will not be able to validate your documentation])
823     AC_MSG_WARN([check your XML_CATALOG_FILES environment variable and/or /etc/xml/catalog])
824   fi
825   rm -rf conftest*
826 fi
827 ])# FP_CHECK_DOCBOOK_DTD
828
829
830 # FP_GEN_FO
831 # ------------------
832 # Generates a formatting objects document in conftest.fo.
833 AC_DEFUN([FP_GEN_FO],
834 [rm -f conftest.fo
835 cat > conftest.fo << EOF
836 <?xml version="1.0"?>
837 <fo:root xmlns:fo="http://www.w3.org/1999/XSL/Format">
838   <fo:layout-master-set>
839     <fo:simple-page-master master-name="blank">
840       <fo:region-body/>
841     </fo:simple-page-master>
842   </fo:layout-master-set>
843   <fo:page-sequence master-reference="blank">
844     <fo:flow flow-name="xsl-region-body">
845       <fo:block>
846         Test!
847       </fo:block>
848     </fo:flow>
849   </fo:page-sequence>
850 </fo:root>
851 EOF
852 ]) # FP_GEN_FO
853
854
855 # FP_PROG_FOP
856 # -----------
857 # Set the output variable 'FopCmd' to the first working 'fop' in the current
858 # 'PATH'. Note that /usr/bin/fop is broken in SuSE 9.1 (unpatched), so try
859 # /usr/share/fop/fop.sh in that case (or no 'fop'), too.
860 AC_DEFUN([FP_PROG_FOP],
861 [AC_PATH_PROGS([FopCmd1], [fop fop.sh])
862 if test -n "$FopCmd1"; then
863   AC_CACHE_CHECK([for $FopCmd1 usability], [fp_cv_fop_usability],
864     [FP_GEN_FO
865     if "$FopCmd1" -fo conftest.fo -ps conftest.ps > /dev/null 2>&1; then
866       fp_cv_fop_usability=yes
867     else
868       fp_cv_fop_usability=no
869     fi
870     rm -rf conftest*])
871   if test x"$fp_cv_fop_usability" = xyes; then
872      FopCmd=$FopCmd1
873   fi
874 fi
875 if test -z "$FopCmd"; then
876   AC_PATH_PROGS([FopCmd2], [fop.sh], , [/usr/share/fop])
877   FopCmd=$FopCmd2
878 fi
879 AC_SUBST([FopCmd])
880 ])# FP_PROG_FOP
881
882
883 # FP_PROG_FO_PROCESSOR
884 # --------------------
885 # Try to find an FO processor. PassiveTeX output is sometimes a bit strange, so
886 # try FOP first. Sets the output variables FopCmd, XmltexCmd, DvipsCmd, and
887 # PdfxmltexCmd.
888 AC_DEFUN([FP_PROG_FO_PROCESSOR],
889 [AC_REQUIRE([FP_PROG_FOP])
890 AC_PATH_PROG([XmltexCmd], [xmltex])
891 AC_PATH_PROG([DvipsCmd], [dvips])
892 if test -z "$FopCmd"; then
893   if test -z "$XmltexCmd"; then
894     AC_MSG_WARN([cannot find an FO => DVI converter, you will not be able to build DVI or PostScript documentation])
895   else
896     if test -z "$DvipsCmd"; then
897       AC_MSG_WARN([cannot find a DVI  => PS converter, you will not be able to build PostScript documentation])
898     fi
899   fi
900   AC_PATH_PROG([PdfxmltexCmd], [pdfxmltex])
901   if test -z "$PdfxmltexCmd"; then
902     AC_MSG_WARN([cannot find an FO => PDF converter, you will not be able to build PDF documentation])
903   fi
904 elif test -z "$XmltexCmd"; then
905   AC_MSG_WARN([cannot find an FO => DVI converter, you will not be able to build DVI documentation])
906 fi
907 ])# FP_PROG_FO_PROCESSOR
908
909
910 # FP_PROG_GHC_PKG
911 # ----------------
912 # Try to find a ghc-pkg matching the ghc mentioned in the environment variable
913 # WithGhc. If the latter is unset or no matching ghc-pkg can be found, try to
914 # find a plain ghc-pkg. Sets the output variable GhcPkgCmd.
915 AC_DEFUN([FP_PROG_GHC_PKG],
916 [AC_CACHE_CHECK([for ghc-pkg matching $WithGhc], fp_cv_matching_ghc_pkg,
917 [fp_ghc_pkg_guess=`echo $WithGhc | sed 's,ghc\(@<:@^/\\@:>@*\)$,ghc-pkg\1,'`
918 if "$fp_ghc_pkg_guess" -l > /dev/null 2>&1; then
919   fp_cv_matching_ghc_pkg=$fp_ghc_pkg_guess
920 else
921   fp_cv_matching_ghc_pkg=no
922 fi])
923 if test x"$fp_cv_matching_ghc_pkg" = xno; then
924   AC_PATH_PROG([GhcPkgCmd], [ghc-pkg])
925 else
926   GhcPkgCmd=$fp_cv_matching_ghc_pkg
927 fi])# FP_PROG_GHC_PKG
928
929
930 # FP_GHC_HAS_READLINE
931 # -------------------
932 AC_DEFUN([FP_GHC_HAS_READLINE],
933 [AC_REQUIRE([FP_PROG_GHC_PKG])
934 AC_CACHE_CHECK([whether ghc has readline package], [fp_cv_ghc_has_readline],
935 [if "${GhcPkgCmd-ghc-pkg}" --show-package readline >/dev/null 2>&1; then
936   fp_cv_ghc_has_readline=yes
937 else
938   fp_cv_ghc_has_readline=no
939  fi])
940 AC_SUBST([GhcHasReadline], [`echo $fp_cv_ghc_has_readline | sed 'y/yesno/YESNO/'`])
941 ])# FP_GHC_HAS_READLINE
942
943
944 # FP_GCC_NEEDS_NO_OMIT_LFPTR
945 # --------------------------
946 # Some OSs (Mandrake Linux, in particular) configure GCC with
947 # -momit-leaf-frame-pointer on by default. If this is the case, we need to turn
948 # it off for mangling to work. The test is currently a bit crude, using only the
949 # version number of gcc. Defines HAVE_GCC_MNO_OMIT_LFPTR.
950 AC_DEFUN([FP_GCC_NEEDS_NO_OMIT_LFPTR],
951 [AC_REQUIRE([FP_HAVE_GCC])
952 AC_CACHE_CHECK([whether gcc needs -mno-omit-leaf-frame-pointer], [fp_cv_gcc_needs_no_omit_lfptr],
953 [FP_COMPARE_VERSIONS([$fp_gcc_version], [-ge], [3.2],
954   [fp_cv_gcc_needs_no_omit_lfptr=yes],
955   [fp_cv_gcc_needs_no_omit_lfptr=no])])
956 if test "$fp_cv_gcc_needs_no_omit_lfptr" = "yes"; then
957    AC_DEFINE([HAVE_GCC_MNO_OMIT_LFPTR], [1], [Define to 1 if gcc supports -mno-omit-leaf-frame-pointer.])
958 fi])# FP_GCC_NEEDS_NO_OMIT_LFPTR
959
960 # FP_GCC_HAS_NO_UNIT_AT_A_TIME
961 # --------------------------
962 AC_DEFUN([FP_GCC_HAS_NO_UNIT_AT_A_TIME],
963 [AC_REQUIRE([FP_HAVE_GCC])
964 AC_CACHE_CHECK([whether gcc has -fno-unit-at-a-time], [fp_cv_gcc_has_no_unit_at_a_time],
965 [FP_COMPARE_VERSIONS([$fp_gcc_version], [-ge], [3.4],
966   [fp_cv_gcc_has_no_unit_at_a_time=yes],
967   [fp_cv_gcc_has_no_unit_at_a_time=no])])
968 if test "$fp_cv_gcc_has_no_unit_at_a_time" = "yes"; then
969    AC_DEFINE([HAVE_GCC_HAS_NO_UNIT_AT_A_TIME], [1], [Define to 1 if gcc supports -fno-unit-at-a-time.])
970 fi])
971
972 # FP_GCC_HAS_WRAPV
973 # --------------------------
974 AC_DEFUN([FP_GCC_HAS_WRAPV],
975 [AC_REQUIRE([FP_HAVE_GCC])
976 AC_CACHE_CHECK([whether gcc has -fwrapv], [fp_cv_gcc_has_wrapv],
977 [FP_COMPARE_VERSIONS([$fp_gcc_version], [-ge], [3.4],
978   [fp_cv_gcc_has_wrapv=yes],
979   [fp_cv_gcc_has_wrapv=no])])
980 if test "$fp_cv_gcc_has_wrapv" = "yes"; then
981    AC_DEFINE([HAVE_GCC_HAS_WRAPV], [1], [Define to 1 if gcc supports -fwrapv.])
982 fi])
983
984 # FP_SETUP_PROJECT_VERSION
985 # ---------------------
986 AC_DEFUN([FP_SETUP_PROJECT_VERSION],
987 [
988 if test "$RELEASE" = "NO"; then
989     AC_MSG_CHECKING([for GHC version date])
990     if test -f VERSION_DATE; then
991         PACKAGE_VERSION=${PACKAGE_VERSION}.`cat VERSION_DATE`
992         AC_MSG_RESULT(given $PACKAGE_VERSION)
993     elif test -d _darcs; then
994         changequote(, )dnl
995         ver_date=`darcs changes --quiet --no-summary --xml | head -500 | grep 'date=' | sed "s/^.*date='\([0-9][0-9][0-9][0-9][0-9][0-9][0-9][0-9]\).*$/\1/g" | sort -n | tail -1`
996         if echo $ver_date | grep '^[0-9][0-9][0-9][0-9][0-9][0-9][0-9][0-9]$' 2>&1 >/dev/null; then true; else
997         changequote([, ])dnl
998                 AC_MSG_ERROR([failed to detect version date: check that darcs is in your path])
999         fi
1000         PACKAGE_VERSION=${PACKAGE_VERSION}.$ver_date
1001         AC_MSG_RESULT(inferred $PACKAGE_VERSION)
1002     elif test -f VERSION; then
1003         PACKAGE_VERSION=`cat VERSION`
1004         AC_MSG_RESULT(given $PACKAGE_VERSION)
1005     else
1006         AC_MSG_WARN([cannot determine snapshot version: no _darcs directory and no VERSION file])
1007     fi
1008 fi
1009
1010 # Some renamings
1011 AC_SUBST([ProjectName], [$PACKAGE_NAME])
1012 AC_SUBST([ProjectVersion], [$PACKAGE_VERSION])
1013
1014 # Split PACKAGE_VERSION into (possibly empty) parts
1015 VERSION_MAJOR=`echo $PACKAGE_VERSION | sed 's/^\(@<:@^.@:>@*\)\(\.\{0,1\}\(.*\)\)$/\1'/`
1016 VERSION_TMP=`echo $PACKAGE_VERSION | sed 's/^\(@<:@^.@:>@*\)\(\.\{0,1\}\(.*\)\)$/\3'/`
1017 VERSION_MINOR=`echo $VERSION_TMP | sed 's/^\(@<:@^.@:>@*\)\(\.\{0,1\}\(.*\)\)$/\1'/`
1018 ProjectPatchLevel=`echo $VERSION_TMP | sed 's/^\(@<:@^.@:>@*\)\(\.\{0,1\}\(.*\)\)$/\3'/`
1019
1020 # Calculate project version as an integer, using 2 digits for minor version
1021 case $VERSION_MINOR in
1022   ?) ProjectVersionInt=${VERSION_MAJOR}0${VERSION_MINOR} ;;
1023   ??) ProjectVersionInt=${VERSION_MAJOR}${VERSION_MINOR} ;;
1024   *) AC_MSG_ERROR([bad minor version in $PACKAGE_VERSION]) ;;
1025 esac
1026 AC_SUBST([ProjectVersionInt])
1027
1028 # The project patchlevel is zero unless stated otherwise
1029 test -z "$ProjectPatchLevel" && ProjectPatchLevel=0
1030
1031 # Remove dots from the patch level; this allows us to have versions like 6.4.1.20050508
1032 ProjectPatchLevel=`echo $ProjectPatchLevel | sed 's/\.//'`
1033
1034 AC_SUBST([ProjectPatchLevel])
1035 ])# FP_SETUP_PROJECT_VERSION
1036
1037 AC_DEFUN([FP_CHECK_TIMER_CREATE],
1038   [AC_CACHE_CHECK([for a working timer_create(CLOCK_REALTIME)], 
1039     [fptools_cv_timer_create_works],
1040     [AC_TRY_RUN([
1041 #ifdef HAVE_TIME_H
1042 #include <time.h>
1043 #endif
1044 #ifdef HAVE_SIGNAL_H
1045 #include <signal.h>
1046 #endif
1047 #ifdef HAVE_UNISTD_H
1048 #include <unistd.h>
1049 #endif
1050 int main(int argc, char *argv[])
1051 {
1052 #if HAVE_TIMER_CREATE && HAVE_TIMER_SETTIME
1053     struct sigevent ev;
1054     timer_t timer;
1055     ev.sigev_notify = SIGEV_SIGNAL;
1056     ev.sigev_signo  = SIGVTALRM;
1057     if (timer_create(CLOCK_PROCESS_CPUTIME_ID, &ev, &timer) != 0) {
1058        exit(1);
1059     }
1060 #else
1061     exit(1)
1062 #endif
1063     exit(0);
1064 }
1065      ],
1066      [fptools_cv_timer_create_works=yes],
1067      [fptools_cv_timer_create_works=no])
1068   ])
1069 case $fptools_cv_timer_create_works in
1070     yes) AC_DEFINE([USE_TIMER_CREATE], 1, 
1071                    [Define to 1 if we can use timer_create(CLOCK_PROCESS_CPUTIME_ID,...)]);;
1072 esac
1073 ])
1074
1075 # FP_ARG_GMP
1076 # -------------
1077 AC_DEFUN([FP_ARG_GMP],
1078 [
1079 AC_ARG_WITH([gmp-includes],
1080   [AC_HELP_STRING([--with-gmp-includes],
1081     [directory containing gmp.h])],
1082     [gmp_includes=$withval],
1083     [gmp_includes=NONE])
1084
1085 AC_ARG_WITH([gmp-libraries],
1086   [AC_HELP_STRING([--with-gmp-libraries],
1087     [directory containing gmp library])],
1088     [gmp_libraries=$withval],
1089     [gmp_libraries=NONE])
1090 ])# FP_ARG_GMP
1091
1092 AC_DEFUN([CHECK_GMP],
1093 [AC_REQUIRE([AC_PROG_CPP])
1094 AC_REQUIRE([AC_PROG_CC])
1095 ])
1096
1097 # --------------------------------------------------------------
1098 # Calculate absolute path to build tree
1099 # --------------------------------------------------------------
1100
1101 AC_DEFUN([FP_FIND_ROOT],[
1102 AC_MSG_CHECKING(for path to top of build tree)
1103
1104 hardtop=`pwd`
1105
1106 dnl Remove common automounter nonsense
1107 dnl
1108 hardtop=`echo $hardtop | sed 's|^/tmp_mnt.*\(/local/.*\)$|\1|' | sed 's|^/tmp_mnt/|/|' | sed 's|^//\(.\)/|\1:/|' `
1109
1110 dnl Find 'hardtop_plat', the native format for 'hardtop'
1111 dnl (i.e., right kind of \dnl slashes on a Win32 box, but with b-slashes
1112 dnl being escaped).
1113 dnl
1114 dnl Note OSTYPE: On Cygwin we need to use 'cygpath' to convert
1115 dnl              /cygdrive/c/foo to c:/foo but we must not do that if we
1116 dnl              aren't building using Cygwin (notably msys), because
1117 dnl              cygpath doesn't exist.  It seems that 'bash' sets
1118 dnl              OSTYPE to 'cygwin' or 'msys' respectively, but cygwin's
1119 dnl              'sh' does not.  So we hackily assume that if the shell
1120 dnl              hasn't set it to 'msys' then we must be in Cygwin.
1121 dnl              Sigh.
1122 dnl
1123 dnl              The Right Thing is probably to test $BuildPlatform
1124 dnl              instead, but we are sloppy about setting that correctly
1125 dnl              at the moment, so we just work around for now.
1126 dnl
1127 dnl              The quotes round "$(OSTYPE)" are essential, for the
1128 dnl              Cygwin-sh case where OSTYPE is not set.
1129 case $HostPlatform in
1130   i386-unknown-mingw32 | i386-unknown-cygwin32)
1131         if test "${OSTYPE}" != "msys"
1132           then
1133             # convert $hardtop to a path that mingw will understand too
1134             cyghardtop=${hardtop}
1135             hardtop=`cygpath -w ${cyghardtop} | sed -e 's@\\\\@/@g'`
1136             hardtop_plat=`cygpath -w ${cyghardtop} | sed -e 's@\\\\@\\\\\\\\@g'`
1137           else
1138 dnl OK, so we're in the MSYS case.  hardtop looks like /c/....
1139 dnl We want to make hardtop_plat into c:/...
1140 dnl Stop using [] for quotes temporarily, so we can use [] in the sed regexp
1141 changequote(, )dnl
1142                hardtop_plat=`echo ${hardtop} | sed -e 's@^/\\([a-zA-Z]\\)/@\\1:/@g'`
1143 changequote([, ])dnl
1144         fi
1145         ;;
1146   *)
1147         hardtop_plat=${hardtop}
1148         ;;
1149 esac
1150 AC_SUBST(hardtop)
1151 AC_SUBST(hardtop_plat)
1152
1153 AC_MSG_RESULT(${hardtop})
1154
1155 # We don't support building in directories with spaces.
1156 case "$hardtop" in
1157   *' '*) AC_MSG_ERROR([
1158    The build system does not support building in a directory containing
1159    space characters.  Suggestion: move the build tree somewhere else.])
1160  ;;
1161 esac
1162 ])
1163
1164 # LocalWords:  fi