Quote the paths to alex and happy in configure
[ghc.git] / aclocal.m4
1 # Extra autoconf macros for the Glasgow fptools
2 #
3 # To be a good autoconf citizen, names of local macros have prefixed with FP_ to
4 # ensure we don't clash with any pre-supplied autoconf ones.
5
6
7 # FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN
8 # ----------------------------------
9 # Little endian Arm on Linux with some ABIs has big endian word order
10 # in doubles. Define FLOAT_WORDS_BIGENDIAN if this is the case.
11 AC_DEFUN([FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN],
12   [AC_CACHE_CHECK([whether float word order is big endian], [fptools_cv_float_word_order_bigendian],
13     [AC_COMPILE_IFELSE(
14       [AC_LANG_PROGRAM(
15         [#include <endian.h>],
16         [#if defined(__FLOAT_WORD_ORDER) && __FLOAT_WORD_ORDER == BIG_ENDIAN
17              return 0;
18          #else
19              not float word order big endian
20          #endif]
21       )],
22       [fptools_cv_float_word_order_bigendian=yes],
23       [fptools_cv_float_word_order_bigendian=no])
24     ])
25   case $fptools_cv_float_word_order_bigendian in
26       yes)
27           AC_DEFINE([FLOAT_WORDS_BIGENDIAN], 1,
28           [Define to 1 if your processor stores words of floats with
29            the most significant byte first]) ;;
30   esac
31 ])
32
33
34 # FP_EVAL_STDERR(COMMAND)
35 # -----------------------
36 # Eval COMMAND, save its stderr (without lines resulting from shell tracing)
37 # into the file conftest.err and the exit status in the variable fp_status.
38 AC_DEFUN([FP_EVAL_STDERR],
39 [{ (eval $1) 2>conftest.er1
40   fp_status=$?
41   grep -v '^ *+' conftest.er1 >conftest.err
42   rm -f conftest.er1
43   (exit $fp_status); }[]dnl
44 ])# FP_EVAL_STDERR
45
46
47 # FP_ARG_WITH_PATH_GNU_PROG
48 # --------------------
49 # XXX
50 #
51 # $1 = the command to look for
52 # $2 = the variable to set
53 #
54 AC_DEFUN([FP_ARG_WITH_PATH_GNU_PROG],
55 [
56 AC_ARG_WITH($2,
57 [AC_HELP_STRING([--with-$2=ARG],
58         [Use ARG as the path to $2 [default=autodetect]])],
59 [
60     if test "$HostOS" = "mingw32"
61     then
62         AC_MSG_WARN([Request to use $withval will be ignored])
63     else
64         $1=$withval
65     fi
66 ],
67 [
68     if test "$HostOS" != "mingw32"
69     then
70         AC_PATH_PROG([$1], [$2])
71         if test -z "$$1"
72         then
73             AC_MSG_ERROR([cannot find $2 in your PATH, no idea how to link])
74         fi
75     fi
76 ]
77 )
78 ]) # FP_ARG_WITH_PATH_GNU_PROG
79
80
81 # FP_PROG_CONTEXT_DIFF
82 # --------------------
83 # Figure out how to do context diffs. Sets the output variable ContextDiffCmd.
84 #
85 # Note: NeXTStep thinks diff'ing a file against itself is "trouble".
86 #
87 # Used by ghc, glafp-utils/ltx, and glafp-utils/runstdtest.
88 AC_DEFUN([FP_PROG_CONTEXT_DIFF],
89 [AC_CACHE_CHECK([for a working context diff], [fp_cv_context_diff],
90 [echo foo > conftest1
91 echo foo > conftest2
92 fp_cv_context_diff=no
93 for fp_var in '-U 1' '-u1' '-C 1' '-c1'
94 do
95   if diff $fp_var conftest1 conftest2 > /dev/null 2>&1; then
96     fp_cv_context_diff="diff $fp_var"
97     break
98   fi
99 done])
100 if test x"$fp_cv_context_diff" = xno; then
101    AC_MSG_ERROR([cannot figure out how to do context diffs])
102 fi
103 AC_SUBST(ContextDiffCmd, [$fp_cv_context_diff])
104 ])# FP_PROG_CONTEXT_DIFF
105
106
107 # FP_COMPUTE_INT(EXPRESSION, VARIABLE, INCLUDES, IF-FAILS)
108 # --------------------------------------------------------
109 # Assign VARIABLE the value of the compile-time EXPRESSION using INCLUDES for
110 # compilation. Execute IF-FAILS when unable to determine the value. Works for
111 # cross-compilation, too.
112 #
113 # Implementation note: We are lazy and use an internal autoconf macro, but it
114 # is supported in autoconf versions 2.50 up to the actual 2.57, so there is
115 # little risk.
116 AC_DEFUN([FP_COMPUTE_INT],
117 [_AC_COMPUTE_INT([$1], [$2], [$3], [$4])[]dnl
118 ])# FP_COMPUTE_INT
119
120
121 # FP_CHECK_ALIGNMENT(TYPE, [IGNORED], [INCLUDES = DEFAULT-INCLUDES])
122 # ------------------------------------------------------------------
123 # A variation of AC_CHECK_SIZEOF for computing the alignment restrictions of a
124 # given type. Defines ALIGNMENT_TYPE.
125 AC_DEFUN([FP_CHECK_ALIGNMENT],
126 [AS_LITERAL_IF([$1], [],
127                [AC_FATAL([$0: requires literal arguments])])[]dnl
128 AC_CHECK_TYPE([$1], [], [], [$3])[]dnl
129 m4_pushdef([fp_Cache], [AS_TR_SH([fp_cv_alignment_$1])])[]dnl
130 AC_CACHE_CHECK([alignment of $1], [fp_Cache],
131 [if test "$AS_TR_SH([ac_cv_type_$1])" = yes; then
132   FP_COMPUTE_INT([(long) (&((struct { char c; $1 ty; } *)0)->ty)],
133                  [fp_Cache],
134                  [AC_INCLUDES_DEFAULT([$3])],
135                  [AC_MSG_ERROR([cannot compute alignment ($1)
136 See `config.log' for more details.], [77])])
137 else
138   fp_Cache=0
139 fi])[]dnl
140 AC_DEFINE_UNQUOTED(AS_TR_CPP(alignment_$1), $fp_Cache, [The alignment of a `$1'.])[]dnl
141 m4_popdef([fp_Cache])[]dnl
142 ])# FP_CHECK_ALIGNMENT
143
144
145 # FP_LEADING_UNDERSCORE
146 # ---------------------
147 # Test for determining whether symbol names have a leading underscore. We assume
148 # that they _haven't_ if anything goes wrong. Sets the output variable
149 # LeadingUnderscore to YES or NO and defines LEADING_UNDERSCORE correspondingly.
150 #
151 # Some nlist implementations seem to try to be compatible by ignoring a leading
152 # underscore sometimes (eg. FreeBSD). We therefore have to work around this by
153 # checking for *no* leading underscore first. Sigh.  --SDM
154 #
155 # Similarly on OpenBSD, but this test doesn't help. -- dons
156 AC_DEFUN([FP_LEADING_UNDERSCORE],
157 [AC_CHECK_LIB([elf], [nlist], [LIBS="-lelf $LIBS"])
158 AC_CACHE_CHECK([leading underscore in symbol names], [fptools_cv_leading_underscore], [
159 # Hack!: nlist() under Digital UNIX insist on there being an _,
160 # but symbol table listings shows none. What is going on here?!?
161 #
162 # Another hack: cygwin doesn't come with nlist.h , so we hardwire
163 # the underscoredness of that "platform"
164 case $HostPlatform in
165 *openbsd*) # x86 openbsd is ELF from 3.4 >, meaning no leading uscore
166   case $build in
167     i386-*2\.@<:@0-9@:>@ | i386-*3\.@<:@0-3@:>@ ) fptools_cv_leading_underscore=yes ;;
168     *) fptools_cv_leading_underscore=no ;;
169   esac ;;
170 alpha-dec-osf*) fptools_cv_leading_underscore=no;;
171 *cygwin32) fptools_cv_leading_underscore=yes;;
172 *mingw32) fptools_cv_leading_underscore=yes;;
173
174     # HACK: Apple doesn't seem to provide nlist in the 64-bit-libraries
175 x86_64-apple-darwin*) fptools_cv_leading_underscore=yes;;
176
177 *) AC_RUN_IFELSE([AC_LANG_SOURCE([[#ifdef HAVE_NLIST_H
178 #include <nlist.h>
179 struct nlist xYzzY1[] = {{"xYzzY1", 0},{0}};
180 struct nlist xYzzY2[] = {{"_xYzzY2", 0},{0}};
181 #endif
182
183 int main(argc, argv)
184 int argc;
185 char **argv;
186 {
187 #ifdef HAVE_NLIST_H
188     if(nlist(argv[0], xYzzY1) == 0 && xYzzY1[0].n_value != 0)
189         exit(1);
190     if(nlist(argv[0], xYzzY2) == 0 && xYzzY2[0].n_value != 0)
191         exit(0);
192 #endif
193     exit(1);
194 }]])],[fptools_cv_leading_underscore=yes],[fptools_cv_leading_underscore=no],[fptools_cv_leading_underscore=no])
195 ;;
196 esac]);
197 AC_SUBST([LeadingUnderscore], [`echo $fptools_cv_leading_underscore | sed 'y/yesno/YESNO/'`])
198 if test x"$fptools_cv_leading_underscore" = xyes; then
199    AC_DEFINE([LEADING_UNDERSCORE], [1], [Define to 1 if C symbols have a leading underscore added by the compiler.])
200 fi])# FP_LEADING_UNDERSCORE
201
202
203 # FP_COMPARE_VERSIONS(VERSION1, TEST, VERSION2, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
204 # ----------------------------------------------------------------------------------
205 # Compare dotted version numbers VERSION1 and VERSION2 lexicographically according
206 # to TEST (one of -eq, -ne, -lt, -le, -gt, or -ge).
207 AC_DEFUN([FP_COMPARE_VERSIONS],
208 [fp_version1=$1; fp_version2=$3
209 fp_save_IFS=$IFS; IFS='.'
210 while test x"$fp_version1" != x || test x"$fp_version2" != x
211 do
212
213   set dummy $fp_version1; shift
214   fp_num1=""
215   test $[@%:@] = 0 || { fp_num1="[$]1"; shift; }
216   test x"$fp_num1" = x && fp_num1="0"
217   fp_version1="[$]*"
218
219   set dummy $fp_version2; shift
220   fp_num2=""
221   test $[@%:@] = 0 || { fp_num2="[$]1"; shift; }
222   test x"$fp_num2" = x && fp_num2="0"
223   fp_version2="[$]*"
224
225   test "$fp_num1" = "$fp_num2" || break;
226 done
227 IFS=$fp_save_IFS
228 AS_IF([test "$fp_num1" $2 "$fp_num2"], [$4], [$5])[]dnl
229 ])# FP_COMPARE_VERSIONS
230
231
232 dnl
233 dnl Check for GreenCard and version.
234 dnl
235 AC_DEFUN([FPTOOLS_GREENCARD],
236 [
237 AC_PATH_PROG(GreenCardCmd,greencard)
238 AC_CACHE_CHECK([for version of greencard], fptools_cv_greencard_version,
239 changequote(, )dnl
240 [if test x"$GreenCardCmd" != x; then
241    fptools_cv_greencard_version="`$GreenCardCmd --version |
242                           grep 'version' | sed -e 's/greencard. version \([^ ]*\).*/\1/g'`"
243 else
244    fptools_cv_greencard_version=""
245 fi
246 changequote([, ])dnl
247 ])
248 FP_COMPARE_VERSIONS([$fptools_cv_greencard_version],[-lt],[$1],
249   [AC_MSG_ERROR([greencard version $1 or later is required (found '$fptools_cv_greencard_version')])])[]dnl
250 GreenCardVersion=$fptools_cv_greencard_version
251 AC_SUBST(GreenCardVersion)
252 ])
253
254 dnl
255 dnl Check for Happy and version.  If we're building GHC, then we need
256 dnl at least Happy version 1.14.  If there's no installed Happy, we look
257 dnl for a happy source tree and point the build system at that instead.
258 dnl
259 AC_DEFUN([FPTOOLS_HAPPY],
260 [AC_PATH_PROG(HappyCmd,happy,)
261 # Happy is passed to Cabal, so we need a native path
262 if test "x$HostPlatform"  = "xi386-unknown-mingw32" && \
263    test "${OSTYPE}"      != "msys"                  && \
264    test "${HappyCmd}"    != ""
265 then
266     # Canonicalise to <drive>:/path/to/gcc
267     HappyCmd=`cygpath -m "${HappyCmd}"`
268     AC_MSG_NOTICE([normalized happy command to $HappyCmd])
269 fi
270
271 AC_CACHE_CHECK([for version of happy], fptools_cv_happy_version,
272 changequote(, )dnl
273 [if test x"$HappyCmd" != x; then
274    fptools_cv_happy_version=`"$HappyCmd" -v |
275                           grep 'Happy Version' | sed -e 's/Happy Version \([^ ]*\).*/\1/g'` ;
276 else
277    fptools_cv_happy_version="";
278 fi;
279 changequote([, ])dnl
280 ])
281 if test ! -f compiler/parser/Parser.hs || test ! -f compiler/cmm/CmmParse.hs || test ! -f compiler/parser/ParserCore.hs
282 then
283     FP_COMPARE_VERSIONS([$fptools_cv_happy_version],[-lt],[1.16],
284       [AC_MSG_ERROR([Happy version 1.16 or later is required to compile GHC.])])[]
285 fi
286 HappyVersion=$fptools_cv_happy_version;
287 AC_SUBST(HappyVersion)
288 ])
289
290 dnl
291 dnl Check for Alex and version.  If we're building GHC, then we need
292 dnl at least Alex version 2.0.1.
293 dnl
294 AC_DEFUN([FPTOOLS_ALEX],
295 [
296 AC_PATH_PROG(AlexCmd,alex,)
297 # Alex is passed to Cabal, so we need a native path
298 if test "x$HostPlatform"  = "xi386-unknown-mingw32" && \
299    test "${OSTYPE}"      != "msys"                  && \
300    test "${AlexCmd}"     != ""
301 then
302     # Canonicalise to <drive>:/path/to/gcc
303     AlexCmd=`cygpath -m "${AlexCmd}"`
304 fi
305
306 AC_CACHE_CHECK([for version of alex], fptools_cv_alex_version,
307 changequote(, )dnl
308 [if test x"$AlexCmd" != x; then
309    fptools_cv_alex_version=`"$AlexCmd" -v |
310                           grep 'Alex [Vv]ersion' | sed -e 's/Alex [Vv]ersion \([0-9\.]*\).*/\1/g'` ;
311 else
312    fptools_cv_alex_version="";
313 fi;
314 changequote([, ])dnl
315 ])
316 if test ! -f compiler/cmm/CmmLex.hs || test ! -f compiler/parser/Lexer.hs
317 then
318     FP_COMPARE_VERSIONS([$fptools_cv_alex_version],[-lt],[2.1.0],
319       [AC_MSG_ERROR([Alex version 2.1.0 or later is required to compile GHC.])])[]
320 fi
321 AlexVersion=$fptools_cv_alex_version;
322 AC_SUBST(AlexVersion)
323 ])
324
325
326 # FP_PROG_LD_X
327 # ------------
328 # Sets the output variable LdXFlag to -x if ld supports this flag, otherwise the
329 # variable's value is empty.
330 AC_DEFUN([FP_PROG_LD_X],
331 [
332 AC_CACHE_CHECK([whether ld understands -x], [fp_cv_ld_x],
333 [echo 'foo() {}' > conftest.c
334 ${CC-cc} -c conftest.c
335 if ${LdCmd} -r -x -o conftest2.o conftest.o > /dev/null 2>&1; then
336    fp_cv_ld_x=yes
337 else
338    fp_cv_ld_x=no
339 fi
340 rm -rf conftest*])
341 if test "$fp_cv_ld_x" = yes; then
342   LdXFlag=-x
343 else
344   LdXFlag=
345 fi
346 AC_SUBST([LdXFlag])
347 ])# FP_PROG_LD_X
348
349
350 # FP_PROG_LD_IS_GNU
351 # -----------------
352 # Sets the output variable LdIsGNULd to YES or NO, depending on whether it is
353 # GNU ld or not.
354 AC_DEFUN([FP_PROG_LD_IS_GNU],
355 [
356 AC_CACHE_CHECK([whether ld is GNU ld], [fp_cv_gnu_ld],
357 [if ${LdCmd} --version 2> /dev/null | grep "GNU" > /dev/null 2>&1; then
358   fp_cv_gnu_ld=yes
359 else
360   fp_cv_gnu_ld=no
361 fi])
362 AC_SUBST([LdIsGNULd], [`echo $fp_cv_gnu_ld | sed 'y/yesno/YESNO/'`])
363 ])# FP_PROG_LD_IS_GNU
364
365
366 # FP_PROG_AR
367 # ----------
368 # Sets fp_prog_ar_raw to the full path of ar and fp_prog_ar to a non-Cygwin
369 # version of it. Exits if no ar can be found
370 AC_DEFUN([FP_PROG_AR],
371 [AC_PATH_PROG([fp_prog_ar_raw], [ar])
372 if test -z "$fp_prog_ar_raw"; then
373   AC_MSG_ERROR([cannot find ar in your PATH, no idea how to make a library])
374 fi
375 fp_prog_ar="$fp_prog_ar_raw"
376 case $HostPlatform in
377   *mingw32) if test x${OSTYPE} != xmsys; then
378               fp_prog_ar="`cygpath -w "${fp_prog_ar_raw}" | sed -e 's@\\\\@/@g'`"
379               AC_MSG_NOTICE([normalized ar command to $fp_prog_ar])
380             fi
381             ;;
382 esac
383 ])# FP_PROG_AR
384
385
386 # FP_PROG_AR_IS_GNU
387 # -----------------
388 # Sets fp_prog_ar_is_gnu to yes or no, depending on whether it is GNU ar or not.
389 AC_DEFUN([FP_PROG_AR_IS_GNU],
390 [AC_REQUIRE([FP_PROG_AR])
391 AC_CACHE_CHECK([whether $fp_prog_ar_raw is GNU ar], [fp_cv_prog_ar_is_gnu],
392 [if "$fp_prog_ar_raw" --version 2> /dev/null | grep "GNU" > /dev/null 2>&1; then
393   fp_cv_prog_ar_is_gnu=yes
394 else
395   fp_cv_prog_ar_is_gnu=no
396 fi])
397 fp_prog_ar_is_gnu=$fp_cv_prog_ar_is_gnu
398 AC_SUBST([ArIsGNUAr], [`echo $fp_prog_ar_is_gnu | tr 'a-z' 'A-Z'`])
399 ])# FP_PROG_AR_IS_GNU
400
401
402 # FP_PROG_AR_ARGS
403 # ---------------
404 # Sets fp_prog_ar_args to the arguments for ar and the output variable ArCmd
405 # to a non-Cygwin invocation of ar including these arguments.
406 AC_DEFUN([FP_PROG_AR_ARGS],
407 [AC_REQUIRE([FP_PROG_AR_IS_GNU])
408 AC_CACHE_CHECK([for ar arguments], [fp_cv_prog_ar_args],
409 [
410 # GNU ar needs special treatment: it appears to have problems with
411 # object files with the same name if you use the 's' modifier, but
412 # simple 'ar q' works fine, and doesn't need a separate ranlib.
413 if test $fp_prog_ar_is_gnu = yes; then
414   fp_cv_prog_ar_args="q"
415 else
416   touch conftest.dummy
417   for fp_var in clqsZ clqs cqs clq cq ; do
418      rm -f conftest.a
419      if "$fp_prog_ar_raw" $fp_var conftest.a conftest.dummy > /dev/null 2> /dev/null; then
420         fp_cv_prog_ar_args=$fp_var
421         break
422      fi
423   done
424   rm -f conftest*
425   if test -z "$fp_cv_prog_ar_args"; then
426     AC_MSG_ERROR([cannot figure out how to use your $fp_prog_ar_raw])
427   fi
428 fi])
429 fp_prog_ar_args=$fp_cv_prog_ar_args
430 AC_SUBST([ArCmd], ["$fp_prog_ar"])
431 AC_SUBST([ArArgs], ["$fp_prog_ar_args"])
432
433 ])# FP_PROG_AR_ARGS
434
435
436 # FP_PROG_AR_NEEDS_RANLIB
437 # -----------------------
438 # Sets the output variable RANLIB to "ranlib" if it is needed and found,
439 # to ":" otherwise.
440 AC_DEFUN([FP_PROG_AR_NEEDS_RANLIB],
441 [AC_REQUIRE([FP_PROG_AR_IS_GNU])
442 AC_REQUIRE([FP_PROG_AR_ARGS])
443 AC_REQUIRE([AC_PROG_CC])
444 AC_CACHE_CHECK([whether ranlib is needed], [fp_cv_prog_ar_needs_ranlib],
445 [if test $fp_prog_ar_is_gnu = yes; then
446   fp_cv_prog_ar_needs_ranlib=no
447 elif echo $TargetPlatform | grep "^.*-apple-darwin$"  > /dev/null 2> /dev/null; then
448   # It's quite tedious to check for Apple's crazy timestamps in .a files,
449   # so we hardcode it.
450   fp_cv_prog_ar_needs_ranlib=yes
451 elif echo $fp_prog_ar_args | grep "s" > /dev/null 2> /dev/null; then
452   fp_cv_prog_ar_needs_ranlib=no
453 else
454   fp_cv_prog_ar_needs_ranlib=yes
455 fi])
456 if test $fp_cv_prog_ar_needs_ranlib = yes; then
457    AC_PROG_RANLIB
458 else
459   RANLIB=":"
460   AC_SUBST([RANLIB])
461 fi
462 ])# FP_PROG_AR_NEEDS_RANLIB
463
464
465 # FP_PROG_AR_SUPPORTS_INPUT
466 # -------------------------
467 # Sets the output variable ArSupportsInput to "-input" or "", depending on
468 # whether ar supports -input flag is supported or not.
469 AC_DEFUN([FP_PROG_AR_SUPPORTS_INPUT],
470 [AC_REQUIRE([FP_PROG_AR_IS_GNU])
471 AC_REQUIRE([FP_PROG_AR_ARGS])
472 AC_CACHE_CHECK([whether $fp_prog_ar_raw supports -input], [fp_cv_prog_ar_supports_input],
473 [fp_cv_prog_ar_supports_input=no
474 if test $fp_prog_ar_is_gnu = no; then
475   rm -f conftest*
476   touch conftest.lst
477   if FP_EVAL_STDERR(["$fp_prog_ar_raw" $fp_prog_ar_args conftest.a -input conftest.lst]) >/dev/null; then
478     test -s conftest.err || fp_cv_prog_ar_supports_input=yes
479   fi
480   rm -f conftest*
481 fi])
482 if test $fp_cv_prog_ar_supports_input = yes; then
483     ArSupportsInput="-input"
484 else
485     ArSupportsInput=""
486 fi
487 AC_SUBST([ArSupportsInput])
488 ])# FP_PROG_AR_SUPPORTS_INPUT
489
490
491 dnl
492 dnl AC_SHEBANG_PERL - can we she-bang perl?
493 dnl
494 AC_DEFUN([FPTOOLS_SHEBANG_PERL],
495 [AC_CACHE_CHECK([if your perl works in shell scripts], fptools_cv_shebang_perl,
496 [echo "#!$PerlCmd"'
497 exit $1;
498 ' > conftest
499 chmod u+x conftest
500 (SHELL=/bin/sh; export SHELL; ./conftest 69 > /dev/null)
501 if test $? -ne 69; then
502    fptools_cv_shebang_perl=yes
503 else
504    fptools_cv_shebang_perl=no
505 fi
506 rm -f conftest
507 ])])
508
509
510 # FP_HAVE_GCC
511 # -----------
512 # Extra testing of the result AC_PROG_CC, testing the gcc version no. Sets the
513 # output variables HaveGcc and GccVersion.
514 AC_DEFUN([FP_HAVE_GCC],
515 [AC_REQUIRE([AC_PROG_CC])
516 if test -z "$GCC"; then
517    fp_have_gcc=NO
518 else
519    fp_have_gcc=YES
520 fi
521 if test "$fp_have_gcc" = "NO" -a -d $srcdir/ghc; then
522   AC_MSG_ERROR([gcc is required])
523 fi
524 GccLT34=
525 AC_CACHE_CHECK([version of gcc], [fp_cv_gcc_version],
526 [if test "$fp_have_gcc" = "YES"; then
527    fp_cv_gcc_version="`$CC -v 2>&1 | grep 'version ' | sed -e 's/.*version [[^0-9]]*\([[0-9.]]*\).*/\1/g'`"
528    FP_COMPARE_VERSIONS([$fp_cv_gcc_version], [-lt], [3.0],
529      [AC_MSG_ERROR([Need at least gcc version 3.0 (3.4+ recommended)])])
530    # See #2770: gcc 2.95 doesn't work any more, apparently.  There probably
531    # isn't a very good reason for that, but for now just make configure
532    # fail.
533    FP_COMPARE_VERSIONS([$fp_cv_gcc_version], [-lt], [3.4], GccLT34=YES)
534  else
535    fp_cv_gcc_version="not-installed"
536  fi
537 ])
538 AC_SUBST([HaveGcc], [$fp_have_gcc])
539 AC_SUBST([GccVersion], [$fp_cv_gcc_version])
540 AC_SUBST(GccLT34)
541 ])# FP_HAVE_GCC
542
543 dnl Small feature test for perl version. Assumes PerlCmd
544 dnl contains path to perl binary.
545 dnl
546 dnl (Perl versions prior to v5.6 does not contain the string "v5";
547 dnl instead they display version strings such as "version 5.005".)
548 dnl
549 AC_DEFUN([FPTOOLS_CHECK_PERL_VERSION],
550 [$PerlCmd -v >conftest.out 2>&1
551    if grep "v5" conftest.out >/dev/null 2>&1; then
552       :
553    else
554       AC_MSG_ERROR([your version of perl probably won't work, try upgrading it.])
555    fi
556 rm -fr conftest*
557 ])
558
559
560 # FP_CHECK_PROG(VARIABLE, PROG-TO-CHECK-FOR,
561 #               [VALUE-IF-NOT-FOUND], [PATH], [REJECT])
562 # -----------------------------------------------------
563 # HACK: A small wrapper around AC_CHECK_PROG, setting VARIABLE to the full path
564 # of PROG-TO-CHECK-FOR when found.
565 AC_DEFUN([FP_CHECK_PROG],
566 [AC_CHECK_PROG([$1], [$2], [$as_dir/$ac_word$ac_exec_ext], [$3], [$4], [$5])][]dnl
567 )# FP_CHECK_PROC
568
569
570 # FP_PROG_FIND
571 # ------------
572 # Find a non-WinDoze version of the "find" utility.
573 AC_DEFUN([FP_PROG_FIND],
574 [AC_PATH_PROGS([fp_prog_find], [gfind find], find)
575 echo foo > conftest.txt
576 $fp_prog_find conftest.txt -print > conftest.out 2>&1
577 if grep '^conftest.txt$' conftest.out > /dev/null 2>&1 ; then
578   # OK, looks like a real "find".
579   case $HostPlatform in
580     *mingw32)
581       if test x${OSTYPE} != xmsys
582       then
583             fp_prog_find="`cygpath --mixed ${fp_prog_find}`"
584         AC_MSG_NOTICE([normalized find command to $fp_prog_find])
585       fi ;;
586     *) ;;
587   esac
588   FindCmd="$fp_prog_find"
589 else
590   # Found a poor WinDoze version of "find", ignore it.
591   AC_MSG_WARN([$fp_prog_find looks like a non-*nix find, ignoring it])
592   FP_CHECK_PROG([FindCmd], [find], [], [], [$fp_prog_find])
593 fi
594 rm -f conftest.txt conftest.out
595 AC_SUBST([FindCmd])[]dnl
596 ])# FP_PROG_FIND
597
598
599 # FP_PROG_SORT
600 # ------------
601 # Find a Unix-like sort
602 AC_DEFUN([FP_PROG_SORT],
603 [AC_PATH_PROG([fp_prog_sort], [sort])
604 echo conwip > conftest.txt
605 $fp_prog_sort -f conftest.txt > conftest.out 2>&1
606 if grep 'conwip' conftest.out > /dev/null 2>&1 ; then
607   # The goods
608   SortCmd="$fp_prog_sort"
609 else
610   # Summink else..pick next one.
611   AC_MSG_WARN([$fp_prog_sort looks like a non-*nix sort, ignoring it])
612   FP_CHECK_PROG([SortCmd], [sort], [], [], [$fp_prog_sort])
613 fi
614 rm -f conftest.txt conftest.out
615 AC_SUBST([SortCmd])[]dnl
616 ])# FP_PROG_SORT
617
618 dnl
619 dnl FPTOOLS_NOCACHE_CHECK prints a message, then sets the
620 dnl values of the second argument to the result of running
621 dnl the commands given by the third. It does not cache its
622 dnl result, so it is suitable for checks which should be
623 dnl run every time.
624 dnl
625 AC_DEFUN([FPTOOLS_NOCACHE_CHECK],
626 [AC_MSG_CHECKING([$1])
627  $3
628  AC_MSG_RESULT([$][$2])
629 ])
630
631 dnl
632 dnl FPTOOLS_GHC_VERSION(version)
633 dnl FPTOOLS_GHC_VERSION(major, minor [, patchlevel])
634 dnl FPTOOLS_GHC_VERSION(version, major, minor, patchlevel)
635 dnl
636 dnl Test for version of installed ghc.  Uses $GHC.
637 dnl [original version pinched from c2hs]
638 dnl
639 AC_DEFUN([FPTOOLS_GHC_VERSION],
640 [FPTOOLS_NOCACHE_CHECK([version of ghc], [fptools_version_of_ghc],
641 ["${WithGhc-ghc}" --version > conftestghc 2>&1
642   cat conftestghc >&AS_MESSAGE_LOG_FD
643 #Useless Use Of cat award...
644   fptools_version_of_ghc=`cat conftestghc | sed -n -e 's/, patchlevel *\([[0-9]]\)/.\1/;s/.* version \([[0-9]][[0-9.]]*\).*/\1/p'`
645   rm -fr conftest*
646   if test "[$]fptools_version_of_ghc" = ""
647   then
648     fptools_version_of_ghc='unknown'
649   fi
650 fptools_version_of_ghc[_major]=`echo [$]fptools_version_of_ghc | sed -e 's/^\([[0-9]]\).*/\1/'`
651 fptools_version_of_ghc[_minor]=`echo [$]fptools_version_of_ghc | sed -e 's/^[[0-9]]\.\([[0-9]]*\).*/\1/'`
652 fptools_version_of_ghc[_pl]=`echo [$]fptools_version_of_ghc | sed -n -e 's/^[[0-9]]\.[[0-9]]*\.\([[0-9]]*\)/\1/p'`
653 #
654 if test "[$]fptools_version_of_ghc[_pl]" = ""
655 then
656   fptools_version_of_ghc[_all]="[$]fptools_version_of_ghc[_major].[$]fptools_version_of_ghc[_minor]"
657   fptools_version_of_ghc[_pl]="0"
658 else
659   fptools_version_of_ghc[_all]="[$]fptools_version_of_ghc[_major].[$]fptools_version_of_ghc[_minor].[$]fptools_version_of_ghc[_pl]"
660 fi
661 #
662 ifelse($#, [1], [dnl
663 [$1]="[$]fptools_version_of_ghc[_all]"
664 ], $#, [2], [dnl
665 [$1]="[$]fptools_version_of_ghc[_major]"
666 [$2]="[$]fptools_version_of_ghc[_minor]"
667 ], $#, [3], [dnl
668 [$1]="[$]fptools_version_of_ghc[_major]"
669 [$2]="[$]fptools_version_of_ghc[_minor]"
670 [$3]="[$]fptools_version_of_ghc[_pl]"
671 ], $#, [4], [dnl
672 [$1]="[$]fptools_version_of_ghc[_all]"
673 [$2]="[$]fptools_version_of_ghc[_major]"
674 [$3]="[$]fptools_version_of_ghc[_minor]"
675 [$4]="[$]fptools_version_of_ghc[_pl]"
676 ])
677 ])
678 ])dnl
679
680
681 # FP_CHECK_FUNC(FUNCTION, PROLOGUE, BODY, [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND])
682 # ---------------------------------------------------------------------------------
683 # A variant of AC_CHECK_FUNCS, limited to a single FUNCTION, but with the
684 # additional flexibility of specifying the PROLOGUE and BODY.
685 AC_DEFUN([FP_CHECK_FUNC],
686 [AS_VAR_PUSHDEF([fp_func], [fp_cv_func_$1])dnl
687 AC_CACHE_CHECK([for $1], fp_func,
688 [AC_LINK_IFELSE([AC_LANG_PROGRAM([$2], [$3])],
689                 [AS_VAR_SET(fp_func, yes)],
690                 [AS_VAR_SET(fp_func, no)])])
691 AS_IF([test AS_VAR_GET(fp_func) = yes],
692       [AC_DEFINE(AS_TR_CPP(HAVE_$1), [1],
693                 [Define to 1 if you have the `]$1[' function.]) $4],
694       [$5])dnl
695 AS_VAR_POPDEF([fp_func])dnl
696 ])# FP_CHECK_FUNC
697
698
699 # FP_GEN_DOCBOOK_XML
700 # ------------------
701 # Generates a DocBook XML V4.2 document in conftest.xml.
702 #
703 # It took a lot of experimentation to find a document that will cause
704 # xsltproc to fail with an error code when the relevant
705 # stylesheets/DTDs are not found.  I couldn't make xsltproc fail with
706 # a single-file document, it seems a multi-file document is needed.
707 # -- SDM 2009-06-03
708 #
709 AC_DEFUN([FP_GEN_DOCBOOK_XML],
710 [rm -f conftest.xml conftest-book.xml
711 cat > conftest.xml << EOF
712 <?xml version="1.0" encoding="iso-8859-1"?>
713 <!DOCTYPE book PUBLIC "-//OASIS//DTD DocBook XML V4.2//EN"
714    "http://www.oasis-open.org/docbook/xml/4.2/docbookx.dtd" [[
715 <!ENTITY conftest-book SYSTEM "conftest-book.xml">
716 ]]>
717 <book id="test">
718 &conftest-book;
719 </book>
720 EOF
721 cat >conftest-book.xml << EOF
722 <?xml version="1.0" encoding="iso-8859-1"?>
723   <title>A DocBook &ldquo;Test Document&rdquo;</title>
724   <chapter id="id-one">
725     <title>A Chapter Title</title>
726     <para>This is a paragraph, referencing <xref linkend="id-two"/>.</para>
727   </chapter>
728   <chapter id="id-two">
729     <title>Another Chapter Title</title>
730     <para>This is another paragraph, referencing <xref linkend="id-one"/>.</para>
731   </chapter>
732 EOF
733 ]) # FP_GEN_DOCBOOK_XML
734
735
736 # FP_PROG_DBLATEX
737 # ----------------
738 # Sets the output variable DblatexCmd to the full path of dblatex,
739 # which we use for building PDF and PS docs.
740 # DblatexCmd is empty if dblatex could not be found.
741 AC_DEFUN([FP_PROG_DBLATEX],
742 [AC_PATH_PROG([DblatexCmd], [dblatex])
743 if test -z "$DblatexCmd"; then
744   AC_MSG_WARN([cannot find dblatex in your PATH, you will not be able to build the PDF and PS documentation])
745 fi
746 ])# FP_PROG_DBLATEX
747
748
749 # FP_PROG_XSLTPROC
750 # ----------------
751 # Sets the output variable XsltprocCmd to the full path of the XSLT processor
752 # xsltproc. XsltprocCmd is empty if xsltproc could not be found.
753 AC_DEFUN([FP_PROG_XSLTPROC],
754 [AC_PATH_PROG([XsltprocCmd], [xsltproc])
755 if test -z "$XsltprocCmd"; then
756   AC_MSG_WARN([cannot find xsltproc in your PATH, you will not be able to build the HTML documentation])
757 fi
758 ])# FP_PROG_XSLTPROC
759
760
761 # FP_DOCBOOK_XSL
762 # ----------------------------
763 # Check that we can process a DocBook XML document to HTML using xsltproc.
764 AC_DEFUN([FP_DOCBOOK_XSL],
765 [AC_REQUIRE([FP_PROG_XSLTPROC])dnl
766 if test -n "$XsltprocCmd"; then
767   AC_CACHE_CHECK([for DocBook XSL stylesheet], fp_cv_dir_docbook_xsl,
768   [FP_GEN_DOCBOOK_XML
769   fp_cv_dir_docbook_xsl=no
770   if $XsltprocCmd --nonet http://docbook.sourceforge.net/release/xsl/current/html/chunk.xsl conftest.xml > /dev/null 2>&1; then
771      fp_cv_dir_docbook_xsl=yes
772   fi
773   rm -rf conftest*])
774 fi
775 if test x"$fp_cv_dir_docbook_xsl" = xno; then
776   AC_MSG_WARN([cannot find DocBook XSL stylesheets, you will not be able to build the documentation])
777   HAVE_DOCBOOK_XSL=NO
778 else
779   HAVE_DOCBOOK_XSL=YES
780 fi
781 AC_SUBST([HAVE_DOCBOOK_XSL])
782 ])# FP_DOCBOOK_XSL
783
784
785 # FP_PROG_XMLLINT
786 # ----------------
787 # Sets the output variable XmllintCmd to the full path of the XSLT processor
788 # xmllint. XmllintCmd is empty if xmllint could not be found.
789 AC_DEFUN([FP_PROG_XMLLINT],
790 [AC_PATH_PROG([XmllintCmd], [xmllint])
791 if test -z "$XmllintCmd"; then
792   AC_MSG_WARN([cannot find xmllint in your PATH, you will not be able to validate your documentation])
793 fi
794 ])# FP_PROG_XMLLINT
795
796
797 # FP_CHECK_DOCBOOK_DTD
798 # --------------------
799 AC_DEFUN([FP_CHECK_DOCBOOK_DTD],
800 [AC_REQUIRE([FP_PROG_XMLLINT])dnl
801 if test -n "$XmllintCmd"; then
802   AC_MSG_CHECKING([for DocBook DTD])
803   FP_GEN_DOCBOOK_XML
804   if $XmllintCmd --nonet --valid --noout conftest.xml ; then
805     AC_MSG_RESULT([ok])
806   else
807     AC_MSG_RESULT([failed])
808     AC_MSG_WARN([cannot find a DTD for DocBook XML V4.2, you will not be able to validate your documentation])
809     AC_MSG_WARN([check your XML_CATALOG_FILES environment variable and/or /etc/xml/catalog])
810   fi
811   rm -rf conftest*
812 fi
813 ])# FP_CHECK_DOCBOOK_DTD
814
815
816 # FP_GEN_FO
817 # ------------------
818 # Generates a formatting objects document in conftest.fo.
819 AC_DEFUN([FP_GEN_FO],
820 [rm -f conftest.fo
821 cat > conftest.fo << EOF
822 <?xml version="1.0"?>
823 <fo:root xmlns:fo="http://www.w3.org/1999/XSL/Format">
824   <fo:layout-master-set>
825     <fo:simple-page-master master-name="blank">
826       <fo:region-body/>
827     </fo:simple-page-master>
828   </fo:layout-master-set>
829   <fo:page-sequence master-reference="blank">
830     <fo:flow flow-name="xsl-region-body">
831       <fo:block>
832         Test!
833       </fo:block>
834     </fo:flow>
835   </fo:page-sequence>
836 </fo:root>
837 EOF
838 ]) # FP_GEN_FO
839
840
841 # FP_PROG_FOP
842 # -----------
843 # Set the output variable 'FopCmd' to the first working 'fop' in the current
844 # 'PATH'. Note that /usr/bin/fop is broken in SuSE 9.1 (unpatched), so try
845 # /usr/share/fop/fop.sh in that case (or no 'fop'), too.
846 AC_DEFUN([FP_PROG_FOP],
847 [AC_PATH_PROGS([FopCmd1], [fop fop.sh])
848 if test -n "$FopCmd1"; then
849   AC_CACHE_CHECK([for $FopCmd1 usability], [fp_cv_fop_usability],
850     [FP_GEN_FO
851     if "$FopCmd1" -fo conftest.fo -ps conftest.ps > /dev/null 2>&1; then
852       fp_cv_fop_usability=yes
853     else
854       fp_cv_fop_usability=no
855     fi
856     rm -rf conftest*])
857   if test x"$fp_cv_fop_usability" = xyes; then
858      FopCmd=$FopCmd1
859   fi
860 fi
861 if test -z "$FopCmd"; then
862   AC_PATH_PROGS([FopCmd2], [fop.sh], , [/usr/share/fop])
863   FopCmd=$FopCmd2
864 fi
865 AC_SUBST([FopCmd])
866 ])# FP_PROG_FOP
867
868
869 # FP_PROG_HSTAGS
870 # ----------------
871 # Sets the output variable HstagsCmd to the full Haskell tags program path.
872 # HstagsCmd is empty if no such program could be found.
873 AC_DEFUN([FP_PROG_HSTAGS],
874 [AC_PATH_PROG([HstagsCmd], [hasktags])
875 if test -z "$HstagsCmd"; then
876   AC_MSG_WARN([cannot find hasktags in your PATH, you will not be able to build the tags])
877 fi
878 ])# FP_PROG_HSTAGS
879
880
881 # FP_PROG_GHC_PKG
882 # ----------------
883 # Try to find a ghc-pkg matching the ghc mentioned in the environment variable
884 # WithGhc. If the latter is unset or no matching ghc-pkg can be found, try to
885 # find a plain ghc-pkg. Sets the output variable GhcPkgCmd.
886 AC_DEFUN([FP_PROG_GHC_PKG],
887 [AC_CACHE_CHECK([for ghc-pkg matching $WithGhc], fp_cv_matching_ghc_pkg,
888 [fp_ghc_pkg_guess=`echo $WithGhc | sed 's,ghc\(@<:@^/\\@:>@*\)$,ghc-pkg\1,'`
889 if "$fp_ghc_pkg_guess" -l > /dev/null 2>&1; then
890   fp_cv_matching_ghc_pkg=$fp_ghc_pkg_guess
891 elif "$fp_ghc_pkg_guess" list > /dev/null 2>&1; then
892   # from 6.10, ghc-pkg doesn't support the old -l syntax any more
893   fp_cv_matching_ghc_pkg=$fp_ghc_pkg_guess
894 else
895   fp_cv_matching_ghc_pkg=no
896 fi])
897 if test x"$fp_cv_matching_ghc_pkg" = xno; then
898   AC_PATH_PROG([GhcPkgCmd], [ghc-pkg])
899 else
900   GhcPkgCmd=$fp_cv_matching_ghc_pkg
901 fi])# FP_PROG_GHC_PKG
902
903
904 # FP_GCC_EXTRA_FLAGS
905 # ------------------
906 # Determine which extra flags we need to pass gcc when we invoke it
907 # to compile .hc code.
908 #
909 # Some OSs (Mandrake Linux, in particular) configure GCC with
910 # -momit-leaf-frame-pointer on by default. If this is the case, we
911 # need to turn it off for mangling to work. The test is currently a
912 # bit crude, using only the version number of gcc.
913
914 # -fwrapv is needed for gcc to emit well-behaved code in the presence of
915 # integer wrap around. (Trac #952)
916 #
917 # -fno-unit-at-a-time or -fno-toplevel-reoder is necessary to avoid gcc
918 # reordering things in the module and confusing the manger and/or splitter.
919 # (eg. Trac #1427)
920 #
921 AC_DEFUN([FP_GCC_EXTRA_FLAGS],
922 [AC_REQUIRE([FP_HAVE_GCC])
923 AC_CACHE_CHECK([for extra options to pass gcc when compiling via C], [fp_cv_gcc_extra_opts],
924 [fp_cv_gcc_extra_opts=
925  FP_COMPARE_VERSIONS([$fp_cv_gcc_version], [-ge], [3.4],
926   [fp_cv_gcc_extra_opts="$fp_cv_gcc_extra_opts -fwrapv"],
927   [])
928  case $TargetPlatform in
929   i386-*|x86_64-*) 
930      FP_COMPARE_VERSIONS([$fp_cv_gcc_version], [-ge], [3.2],
931       [fp_cv_gcc_extra_opts="$fp_cv_gcc_extra_opts -mno-omit-leaf-frame-pointer"],
932       [])
933     FP_COMPARE_VERSIONS([$fp_cv_gcc_version], [-ge], [3.4],
934      [FP_COMPARE_VERSIONS([$fp_cv_gcc_version], [-ge], [4.2],
935        [fp_cv_gcc_extra_opts="$fp_cv_gcc_extra_opts -fno-toplevel-reorder"],
936        [fp_cv_gcc_extra_opts="$fp_cv_gcc_extra_opts -fno-unit-at-a-time"]
937      )],
938      [])
939   ;;
940   sparc-*-solaris2) 
941     FP_COMPARE_VERSIONS([$fp_cv_gcc_version], [-ge], [4.2],
942       [fp_cv_gcc_extra_opts="$fp_cv_gcc_extra_opts -fno-toplevel-reorder"],
943       [])
944   ;;
945  esac
946 ])
947 AC_SUBST([GccExtraViaCOpts],$fp_cv_gcc_extra_opts)
948 ])
949
950
951 # FP_SETUP_PROJECT_VERSION
952 # ---------------------
953 AC_DEFUN([FP_SETUP_PROJECT_VERSION],
954 [
955 if test "$RELEASE" = "NO"; then
956     AC_MSG_CHECKING([for GHC version date])
957     if test -f VERSION_DATE; then
958         PACKAGE_VERSION=${PACKAGE_VERSION}.`cat VERSION_DATE`
959         AC_MSG_RESULT(given $PACKAGE_VERSION)
960     elif test -d .git; then
961         changequote(, )dnl
962         ver_date=`git log -n 1 --date=short --pretty=format:%ci | sed "s/^.*\([0-9][0-9][0-9][0-9]\)-\([0-9][0-9]\)-\([0-9][0-9]\).*$/\1\2\3/"`
963         if echo $ver_date | grep '^[0-9][0-9][0-9][0-9][0-9][0-9][0-9][0-9]$' 2>&1 >/dev/null; then true; else
964         changequote([, ])dnl
965                 AC_MSG_ERROR([failed to detect version date: check that git is in your path])
966         fi
967         PACKAGE_VERSION=${PACKAGE_VERSION}.$ver_date
968         AC_MSG_RESULT(inferred $PACKAGE_VERSION)
969     elif test -d _darcs; then
970         # TODO: Remove this branch after conversion to Git
971         changequote(, )dnl
972         ver_date=`darcs changes --quiet --no-summary --xml | head -500 | grep 'date=' | sed "s/^.*date='\([0-9][0-9][0-9][0-9][0-9][0-9][0-9][0-9]\).*$/\1/g" | ${SortCmd} -n | tail -1`
973         if echo $ver_date | grep '^[0-9][0-9][0-9][0-9][0-9][0-9][0-9][0-9]$' 2>&1 >/dev/null; then true; else
974         changequote([, ])dnl
975                 AC_MSG_ERROR([failed to detect version date: check that darcs is in your path])
976         fi
977         PACKAGE_VERSION=${PACKAGE_VERSION}.$ver_date
978         AC_MSG_RESULT(inferred $PACKAGE_VERSION)
979     elif test -f VERSION; then
980         PACKAGE_VERSION=`cat VERSION`
981         AC_MSG_RESULT(given $PACKAGE_VERSION)
982     else
983         AC_MSG_WARN([cannot determine snapshot version: no .git or _darcs directory and no VERSION file])
984     fi
985 fi
986
987 # Some renamings
988 AC_SUBST([ProjectName], [$PACKAGE_NAME])
989 AC_SUBST([ProjectVersion], [$PACKAGE_VERSION])
990
991 # Split PACKAGE_VERSION into (possibly empty) parts
992 VERSION_MAJOR=`echo $PACKAGE_VERSION | sed 's/^\(@<:@^.@:>@*\)\(\.\{0,1\}\(.*\)\)$/\1'/`
993 VERSION_TMP=`echo $PACKAGE_VERSION | sed 's/^\(@<:@^.@:>@*\)\(\.\{0,1\}\(.*\)\)$/\3'/`
994 VERSION_MINOR=`echo $VERSION_TMP | sed 's/^\(@<:@^.@:>@*\)\(\.\{0,1\}\(.*\)\)$/\1'/`
995 ProjectPatchLevel=`echo $VERSION_TMP | sed 's/^\(@<:@^.@:>@*\)\(\.\{0,1\}\(.*\)\)$/\3'/`
996
997 # Calculate project version as an integer, using 2 digits for minor version
998 case $VERSION_MINOR in
999   ?) ProjectVersionInt=${VERSION_MAJOR}0${VERSION_MINOR} ;;
1000   ??) ProjectVersionInt=${VERSION_MAJOR}${VERSION_MINOR} ;;
1001   *) AC_MSG_ERROR([bad minor version in $PACKAGE_VERSION]) ;;
1002 esac
1003 AC_SUBST([ProjectVersionInt])
1004
1005 # The project patchlevel is zero unless stated otherwise
1006 test -z "$ProjectPatchLevel" && ProjectPatchLevel=0
1007
1008 # Remove dots from the patch level; this allows us to have versions like 6.4.1.20050508
1009 ProjectPatchLevel=`echo $ProjectPatchLevel | sed 's/\.//'`
1010
1011 AC_SUBST([ProjectPatchLevel])
1012 ])# FP_SETUP_PROJECT_VERSION
1013
1014
1015 # Check for a working timer_create().  We need a pretty detailed check
1016 # here, because there exist partially-working implementations of
1017 # timer_create() in certain versions of Linux (see bug #1933).
1018 #
1019 AC_DEFUN([FP_CHECK_TIMER_CREATE],
1020   [AC_CACHE_CHECK([for a working timer_create(CLOCK_REALTIME)], 
1021     [fptools_cv_timer_create_works],
1022     [AC_TRY_RUN([
1023 #include <stdio.h>
1024 #ifdef HAVE_STDLIB_H
1025 #include <stdlib.h>
1026 #endif
1027 #ifdef HAVE_TIME_H
1028 #include <time.h>
1029 #endif
1030 #ifdef HAVE_SIGNAL_H
1031 #include <signal.h>
1032 #endif
1033 #ifdef HAVE_UNISTD_H
1034 #include <unistd.h>
1035 #endif
1036
1037 static volatile int tock = 0;
1038 static void handler(int i)
1039 {
1040    tock = 1;
1041 }
1042
1043 static void timeout(int i)
1044 {
1045   // timer_settime() has been known to hang, so just in case
1046   // we install a 1-second timeout (see #2257)
1047   exit(99);
1048 }
1049
1050 int main(int argc, char *argv[])
1051 {
1052
1053     struct sigevent ev;
1054     timer_t timer;
1055     struct itimerspec it;
1056     struct sigaction action;
1057     int m,n,count = 0;
1058
1059     ev.sigev_notify = SIGEV_SIGNAL;
1060     ev.sigev_signo  = SIGVTALRM;
1061
1062     action.sa_handler = handler;
1063     action.sa_flags = 0;
1064     sigemptyset(&action.sa_mask);
1065     if (sigaction(SIGVTALRM, &action, NULL) == -1) {
1066         fprintf(stderr,"SIGVTALRM problem\n");
1067         exit(3);
1068     }
1069
1070     action.sa_handler = timeout;
1071     action.sa_flags = 0;
1072     sigemptyset(&action.sa_mask);
1073     if (sigaction(SIGALRM, &action, NULL) == -1) {
1074       fprintf(stderr,"SIGALRM problem\n");
1075       exit(3);
1076     }
1077     alarm(1);
1078
1079     if (timer_create(CLOCK_PROCESS_CPUTIME_ID, &ev, &timer) != 0) {
1080         fprintf(stderr,"No CLOCK_PROCESS_CPUTIME_ID timer\n");
1081        exit(1);
1082     }
1083
1084     it.it_value.tv_sec = 0;
1085     it.it_value.tv_nsec = 1;
1086     it.it_interval = it.it_value;
1087     if (timer_settime(timer, 0, &it, NULL) != 0) {
1088         fprintf(stderr,"settime problem\n");
1089         exit(4);
1090     }
1091
1092     tock = 0;
1093
1094     for(n = 3; n < 20000; n++){
1095         for(m = 2; m <= n/2; m++){
1096             if (!(n%m)) count++;
1097             if (tock) goto out;
1098         }
1099     }
1100 out:
1101
1102     if (!tock) {
1103         fprintf(stderr,"no CLOCK_PROCESS_CPUTIME_ID signal\n");
1104         exit(5);
1105     }
1106
1107     timer_delete(timer);
1108
1109     if (timer_create(CLOCK_REALTIME, &ev, &timer) != 0) {
1110         fprintf(stderr,"No CLOCK_REALTIME timer\n");
1111         exit(2);
1112     }
1113
1114     it.it_value.tv_sec = 0;
1115     it.it_value.tv_nsec = 1000000;
1116     it.it_interval = it.it_value;
1117     if (timer_settime(timer, 0, &it, NULL) != 0) {
1118         fprintf(stderr,"settime problem\n");
1119         exit(4);
1120     }
1121
1122     tock = 0;
1123
1124     usleep(3000);
1125
1126     if (!tock) {
1127         fprintf(stderr,"no CLOCK_REALTIME signal\n");
1128         exit(5);
1129     }
1130
1131     timer_delete(timer);
1132
1133     exit(0);
1134 }
1135      ],
1136      [fptools_cv_timer_create_works=yes],
1137      [fptools_cv_timer_create_works=no])
1138   ])
1139 case $fptools_cv_timer_create_works in
1140     yes) AC_DEFINE([USE_TIMER_CREATE], 1, 
1141                    [Define to 1 if we can use timer_create(CLOCK_PROCESS_CPUTIME_ID,...)]);;
1142 esac
1143 ])
1144
1145 # FP_ARG_GMP
1146 # -------------
1147 AC_DEFUN([FP_ARG_GMP],
1148 [
1149 AC_ARG_WITH([gmp-includes],
1150   [AC_HELP_STRING([--with-gmp-includes],
1151     [directory containing gmp.h])],
1152     [gmp_includes=$withval],
1153     [gmp_includes=NONE])
1154
1155 AC_ARG_WITH([gmp-libraries],
1156   [AC_HELP_STRING([--with-gmp-libraries],
1157     [directory containing gmp library])],
1158     [gmp_libraries=$withval],
1159     [gmp_libraries=NONE])
1160 ])# FP_ARG_GMP
1161
1162 AC_DEFUN([CHECK_GMP],
1163 [AC_REQUIRE([AC_PROG_CPP])
1164 AC_REQUIRE([AC_PROG_CC])
1165 ])
1166
1167 # FP_CHECK_MACOSX_DEPLOYMENT_TARGET
1168 # ---------------------------------
1169 AC_DEFUN([FP_CHECK_MACOSX_DEPLOYMENT_TARGET],
1170 [
1171 if test "x$TargetOS_CPP-$TargetVendor_CPP" = "xdarwin-apple"; then
1172   AC_MSG_CHECKING([Mac OS X deployment target])
1173   case $FP_MACOSX_DEPLOYMENT_TARGET in
1174     none)  ;;
1175     10.4)  MACOSX_DEPLOYMENT_VERSION=10.4
1176            MACOSX_DEPLOYMENT_SDK=/Developer/SDKs/MacOSX10.4u.sdk
1177            ;;
1178     10.4u) MACOSX_DEPLOYMENT_VERSION=10.4
1179            MACOSX_DEPLOYMENT_SDK=/Developer/SDKs/MacOSX10.4u.sdk
1180            ;;
1181     *)     MACOSX_DEPLOYMENT_VERSION=$FP_MACOSX_DEPLOYMENT_TARGET
1182            MACOSX_DEPLOYMENT_SDK=/Developer/SDKs/MacOSX${FP_MACOSX_DEPLOYMENT_TARGET}.sdk
1183            ;;
1184   esac
1185   if test "x$FP_MACOSX_DEPLOYMENT_TARGET" = "xnone"; then
1186     AC_MSG_RESULT(none)
1187   else
1188     if test ! -d $MACOSX_DEPLOYMENT_SDK; then
1189       AC_MSG_ERROR([Unknown deployment target $FP_MACOSX_DEPLOYMENT_TARGET])
1190     fi
1191     AC_MSG_RESULT([${MACOSX_DEPLOYMENT_VERSION} (${MACOSX_DEPLOYMENT_SDK})])
1192   fi
1193 fi
1194 ])
1195
1196 # --------------------------------------------------------------
1197 # Calculate absolute path to build tree
1198 # --------------------------------------------------------------
1199
1200 AC_DEFUN([FP_FIND_ROOT],[
1201 AC_MSG_CHECKING(for path to top of build tree)
1202
1203 dnl This would be
1204 dnl     make -C utils/ghc-pwd clean && make -C utils/ghc-pwd
1205 dnl except we don't want to have to know what make is called. Sigh.
1206 if test ! -f utils/ghc-pwd/ghc-pwd && test ! -f utils/ghc-pwd/ghc-pwd.exe; then
1207   cd utils/ghc-pwd
1208   rm -f *.o
1209   rm -f *.hi
1210   rm -f ghc-pwd
1211   rm -f ghc-pwd.exe
1212   "$WithGhc" -v0 --make ghc-pwd -o ghc-pwd
1213   cd ../..
1214 fi
1215
1216 hardtop=`utils/ghc-pwd/ghc-pwd`
1217
1218 if ! test -d "$hardtop"; then
1219   AC_MSG_ERROR([cannot determine current directory])
1220 fi   
1221
1222 dnl Remove common automounter nonsense
1223 dnl
1224 hardtop=`echo $hardtop | sed 's|^/tmp_mnt.*\(/local/.*\)$|\1|' | sed 's|^/tmp_mnt/|/|'`
1225
1226 AC_SUBST(hardtop)
1227
1228 AC_MSG_RESULT(${hardtop})
1229
1230 # We don't support building in directories with spaces.
1231 case "$hardtop" in
1232   *' '*) AC_MSG_ERROR([
1233    The build system does not support building in a directory containing
1234    space characters.  Suggestion: move the build tree somewhere else.])
1235  ;;
1236 esac
1237 ])
1238
1239 # GHC_CONVERT_CPU(cpu, target_var)
1240 # --------------------------------
1241 # converts cpu from gnu to ghc naming, and assigns the result to $target_var
1242 AC_DEFUN([GHC_CONVERT_CPU],[
1243 case "$1" in
1244   alpha*)
1245     $2="alpha"
1246     ;;
1247   arm*)
1248     $2="arm"
1249     ;;
1250   hppa1.1*)
1251     $2="hppa1_1"
1252     ;;
1253   hppa*)
1254     $2="hppa"
1255     ;;
1256   i386)
1257     $2="i386"
1258     ;;
1259   ia64)
1260     $2="ia64"
1261     ;;
1262   m68k*)
1263     $2="m68k"
1264     ;;
1265   mipseb*)
1266     $2="mipseb"
1267     ;;
1268   mipsel*)
1269     $2="mipsel"
1270     ;;
1271   mips*)
1272     $2="mips"
1273     ;;
1274   powerpc64*)
1275     $2="powerpc64"
1276     ;;
1277   powerpc*)
1278     $2="powerpc"
1279     ;;
1280   rs6000)
1281     $2="rs6000"
1282     ;;
1283   s390*)
1284     $2="s390"
1285     ;;
1286   sparc64*)
1287     $2="sparc64"
1288     ;;
1289   sparc*)
1290     $2="sparc"
1291     ;;
1292   vax)
1293     $2="vax"
1294     ;;
1295   x86_64)
1296     $2="x86_64"
1297     ;;
1298   *)
1299     echo "Unknown CPU $1"
1300     exit 1
1301     ;;
1302   esac
1303 ])
1304
1305 # GHC_CONVERT_VENDOR(vendor, target_var)
1306 # --------------------------------
1307 # converts vendor from gnu to ghc naming, and assigns the result to $target_var
1308 AC_DEFUN([GHC_CONVERT_VENDOR],[
1309 $2="$1"
1310 ])
1311
1312 # GHC_CONVERT_OS(os, target_var)
1313 # --------------------------------
1314 # converts os from gnu to ghc naming, and assigns the result to $target_var
1315 AC_DEFUN([GHC_CONVERT_OS],[
1316 case "$1" in
1317   linux-*|linux)
1318     $2="linux"
1319     ;;
1320   # As far as I'm aware, none of these have relevant variants
1321   freebsd|netbsd|openbsd|dragonfly|osf1|osf3|hpux|linuxaout|kfreebsdgnu|freebsd2|solaris2|cygwin32|mingw32|darwin|gnu|nextstep2|nextstep3|sunos4|ultrix|irix|aix|haiku)
1322     $2="$1"
1323     ;;
1324   *)
1325     echo "Unknown OS $1"
1326     exit 1
1327     ;;
1328   esac
1329 ])
1330
1331 # LIBRARY_VERSION(lib)
1332 # --------------------------------
1333 # Gets the version number of a library.
1334 # If $1 is ghc-prim, then we define LIBRARY_ghc_prim_VERSION as 1.2.3
1335 AC_DEFUN([LIBRARY_VERSION],[
1336 LIBRARY_[]translit([$1], [-], [_])[]_VERSION=`grep -i "^version:" libraries/$1/$1.cabal | sed "s/.* //"`
1337 AC_SUBST(LIBRARY_[]translit([$1], [-], [_])[]_VERSION)
1338 ])
1339
1340 # LocalWords:  fi