Move more commands into the settings file
[ghc.git] / configure.ac
1 dnl == autoconf source for the Glasgow FP tools ==
2 dnl (run "grep '^dnl \*' configure.ac | sed -e 's/dnl / /g; s/\*\*/   +/g;'"
3 dnl  (or some such) to see the outline of this file)
4 dnl
5 #
6 # (c) The University of Glasgow 1994-2004
7 #
8 # Configure script template for GHC
9 #
10 # Process with 'autoreconf' to get a working configure script.
11 #
12 # For the generated configure script, do "./configure --help" to
13 # see what flags are available. (Better yet, read the documentation!)
14 #
15
16 AC_INIT([The Glorious Glasgow Haskell Compilation System], [7.1], [glasgow-haskell-bugs@haskell.org], [ghc])
17
18 # Set this to YES for a released version, otherwise NO
19 : ${RELEASE=NO}
20
21 # The primary version (e.g. 6.7, 6.6.1) is set in the AC_INIT line
22 # above.  If this is not a released version, then we will append the
23 # date to the version number (e.g. 6.7.20070204).  The date is
24 # constructed by finding the date of the most recent patch in the
25 # darcs repository.  If this is a source distribution (not a darcs
26 # checkout), then we ship a file 'VERSION' containing the full version
27 # when the source distribution was created.
28
29 if test ! -f mk/config.h.in; then
30    echo "mk/config.h.in doesn't exist: perhaps you haven't run 'perl boot'?"
31    exit 1
32 fi
33
34 AC_SUBST([CONFIGURE_ARGS], [$ac_configure_args])
35
36 dnl ----------------------------------------------------------
37 dnl ** Find unixy sort and find commands, 
38 dnl ** which are needed by FP_SETUP_PROJECT_VERSION
39
40 dnl ** Find find command (for Win32's benefit)
41 FP_PROG_FIND
42
43 dnl ** Find sort command (for the benefit of Win32 environs)
44 FP_PROG_SORT
45
46 dnl ----------------------------------------------------------
47 FP_SETUP_PROJECT_VERSION
48
49 # Hmmm, we fix the RPM release number to 1 here... Is this convenient?
50 AC_SUBST([release], [1])
51
52 # First off, a distrib sanity check..
53 AC_CONFIG_SRCDIR([mk/config.mk.in])
54
55 dnl * We require autoconf version 2.52
56 dnl We need 2.50 due to the use of AC_SYS_LARGEFILE and AC_MSG_NOTICE.
57 dnl We need 2.52 due to the use of AS_TR_CPP and AS_TR_SH.
58 AC_PREREQ([2.52])
59
60 # -------------------------------------------------------------------------
61 # Prepare to generate the following header files
62 #
63 #
64 AC_CONFIG_HEADER(mk/config.h)
65
66 # No, semi-sadly, we don't do `--srcdir'...
67 if test x"$srcdir" != 'x.' ; then
68     echo "This configuration does not support the \`--srcdir' option.."
69     exit 1
70 fi
71
72 dnl --------------------------------------------------------------
73 dnl * Project specific configuration options
74 dnl --------------------------------------------------------------
75 dnl What follows is a bunch of options that can either be configured
76 dnl through command line options to the configure script or by
77 dnl supplying defns in the build tree's mk/build.mk. Having the option to
78 dnl use either is considered a Feature.
79
80 dnl ** What command to use to compile compiler sources ?
81 dnl --------------------------------------------------------------
82
83 AC_ARG_WITH([ghc],
84 [AC_HELP_STRING([--with-ghc=ARG],
85   [Use ARG as the path to GHC  [default=autodetect]])],
86   [WithGhc="$withval"],
87   [if test "$GHC" = ""; then
88     AC_PATH_PROG([GHC], [ghc])
89   fi
90   WithGhc="$GHC"])
91
92
93 dnl ** Tell the make system which OS we are using
94 dnl $OSTYPE is set by the operating system to "msys" or "cygwin" or something 
95 AC_SUBST(OSTYPE)
96
97 dnl ** Booting from .hc files?
98 dnl --------------------------------------------------------------
99 AC_ARG_ENABLE(hc-boot,
100 [AC_HELP_STRING([--enable-hc-boot],
101 [Boot the Glasgow Haskell Compiler from intermediate .hc files.
102  (This option is mostly of interest to porters.) [default=no]])],
103 [ if test x"$enableval" = x"yes"; then
104         BootingFromHc=YES
105   else
106         BootingFromHc=NO
107   fi
108 ],
109 [BootingFromHc=NO]
110 )
111 AC_SUBST(BootingFromHc)
112
113 AC_ARG_ENABLE(bootstrap-with-devel-snapshot,
114 [AC_HELP_STRING([--enable-bootstrap-with-devel-snapshot],
115                 [Allow bootstrapping using a development snapshot of GHC.  This is not guaranteed to work.])],
116         EnableBootstrapWithDevelSnaphost=YES,
117         EnableBootstrapWithDevelSnaphost=NO
118 )
119
120 if test "$WithGhc" != ""; then
121   FPTOOLS_GHC_VERSION([GhcVersion], [GhcMajVersion], [GhcMinVersion], [GhcPatchLevel])dnl
122
123   if test "$GhcMajVersion" = "unknown" -o "$GhcMinVersion" = "unknown"; then
124      AC_MSG_ERROR([Cannot determine the version of $WithGhc.  Is it really GHC?])
125   fi
126
127   AC_SUBST(GhcVersion)dnl
128   AC_SUBST(GhcMajVersion)dnl
129   AC_SUBST(GhcMinVersion)dnl
130   AC_SUBST(GhcPatchLevel)dnl
131   GhcMinVersion2=`echo "$GhcMinVersion" | sed 's/^\\(.\\)$/0\\1/'`
132   GhcCanonVersion="$GhcMajVersion$GhcMinVersion2"
133   if test $GhcCanonVersion -ge 613; then ghc_ge_613=YES; else ghc_ge_613=NO; fi
134   AC_SUBST(ghc_ge_613)dnl
135
136   BOOTSTRAPPING_GHC_INFO_FIELD([CC_STAGE0],[C compiler command],['$(CC)'])
137   BOOTSTRAPPING_GHC_INFO_FIELD([AR_STAGE0],[ar command],['$(AR)'])
138   BOOTSTRAPPING_GHC_INFO_FIELD([AR_OPTS_STAGE0],[ar flags],['$(AR_OPTS)'])
139   BOOTSTRAPPING_GHC_INFO_FIELD([ArSupportsAtFile_STAGE0],[ar supports at file],['$(ArSupportsAtFile)'])
140 fi
141
142 dnl ** Must have GHC to build GHC, unless --enable-hc-boot is on
143 if test "$BootingFromHc" = "NO"; then
144   if test "$WithGhc" = ""; then
145      AC_MSG_ERROR([GHC is required unless bootstrapping from .hc files.])
146   fi
147   FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[6.12],
148     [AC_MSG_ERROR([GHC version 6.12 or later is required to compile GHC.])])dnl
149
150   if test `expr $GhcMinVersion % 2` = "1"; then
151      if test "$EnableBootstrapWithDevelSnaphost" = "NO"; then
152         AC_MSG_ERROR([
153      $WithGhc is a development snapshot of GHC, version $GhcVersion.
154      Bootstrapping using this version of GHC is not supported, and may not
155      work.  Use --enable-bootstrap-with-devel-snapshot to try it anyway,
156      or --with-ghc to specify a different GHC to use.])
157      fi
158   fi
159 fi;
160
161 # GHC is passed to Cabal, so we need a native path
162 if test "${WithGhc}" != ""
163 then
164     ghc_host=`"${WithGhc}" +RTS --info | grep 'Host platform' | sed -e 's/.*, "//' -e 's/")//'`
165
166     if test "$ghc_host" = "i386-unknown-mingw32"
167     then
168         if test "${OSTYPE}" = "msys"
169         then
170             WithGhc=`echo "${WithGhc}" | sed "s#^/\([a-zA-Z]\)/#\1:/#"`
171         else
172             # Canonicalise to <drive>:/path/to/ghc
173             WithGhc=`cygpath -m "${WithGhc}"`
174         fi
175         echo "GHC path canonicalised to: ${WithGhc}"
176     fi
177 fi
178 AC_SUBST([WithGhc])
179
180 dnl ** Without optimization some INLINE trickery fails for GHCi
181 SRC_CC_OPTS="-O"
182
183 FP_ICONV
184 FP_GMP
185
186 dnl--------------------------------------------------------------------
187 dnl * Choose host(/target/build) platform
188 dnl--------------------------------------------------------------------
189 dnl If we aren't explicitly told what values to use with configure flags,
190 dnl we ask the bootstrapping compiler what platform it is for
191
192 if test "${WithGhc}" != ""
193 then
194         bootstrap_host=`"${WithGhc}" +RTS --info | grep '^ ,("Host platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
195         bootstrap_target=`"${WithGhc}" +RTS --info | grep '^ ,("Target platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
196         if test "$bootstrap_host" != "$bootstrap_target"
197         then
198                 echo "Bootstrapping GHC is a cross compiler. This probably isn't going to work"
199         fi
200 fi
201
202 # We have to run these unconditionally, but we may discard their
203 # results in the following code
204 AC_CANONICAL_BUILD
205 AC_CANONICAL_HOST
206 AC_CANONICAL_TARGET
207
208 FPTOOLS_SET_PLATFORM_VARS
209
210 windows=NO
211 exeext=''
212 soext='.so'
213 case $host in
214 *-unknown-cygwin32)
215     AC_MSG_WARN([GHC does not support the Cygwin target at the moment])
216     AC_MSG_WARN([I'm assuming you wanted to build for i386-unknown-mingw32])
217     exit 1
218     ;;
219 *-unknown-mingw32)
220     windows=YES
221     exeext='.exe'
222     soext='.dll'
223     ;;
224 i386-apple-darwin|powerpc-apple-darwin)
225     soext='.dylib'
226     ;;
227 x86_64-apple-darwin)
228     soext='.dylib'
229     ;;
230 esac
231
232 # Testing if we shall enable shared libs support on Solaris.
233 # Anything older than SunOS 5.11 aka Solaris 11 (Express) is broken.
234
235 SOLARIS_BROKEN_SHLD=NO
236
237 case $host in
238      i386-*-solaris2)
239      # here we go with the test
240      MINOR=`uname -r|cut -d '.' -f 2-`
241      if test "$MINOR" -lt "11"; then
242         SOLARIS_BROKEN_SHLD=YES
243      fi
244      ;;
245 esac
246
247 checkArch() {
248     case $1 in
249     alpha|arm|hppa|hppa1_1|i386|ia64|m68k|mips|mipseb|mipsel|powerpc|powerpc64|rs6000|s390|sparc|sparc64|vax|x86_64)
250         ;;
251     *)
252         echo "Unknown arch $1"
253         exit 1
254         ;;
255     esac
256 }
257
258 checkVendor() {
259     case $1 in
260     dec|unknown|hp|apple|next|sun|sgi|ibm)
261         ;;
262     *)
263         echo "Unknown vendor $1"
264         exit 1
265         ;;
266     esac
267 }
268
269 checkOS() {
270     case $1 in
271     linux|freebsd|netbsd|openbsd|dragonfly|osf1|osf3|hpux|linuxaout|kfreebsdgnu|freebsd2|solaris2|cygwin32|mingw32|darwin|gnu|nextstep2|nextstep3|sunos4|ultrix|irix|aix|haiku)
272         ;;
273     *)
274         echo "Unknown OS '$1'"
275         exit 1
276         ;;
277     esac
278 }
279
280 BuildPlatform="$BuildArch-$BuildVendor-$BuildOS"
281 BuildPlatform_CPP=`echo "$BuildPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
282 BuildArch_CPP=`    echo "$BuildArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
283 BuildVendor_CPP=`  echo "$BuildVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
284 BuildOS_CPP=`      echo "$BuildOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
285
286 checkArch "$BuildArch"
287 checkVendor "$BuildVendor"
288 checkOS "$BuildOS"
289
290 HostPlatform="$HostArch-$HostVendor-$HostOS"
291 HostPlatform_CPP=`echo "$HostPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
292 HostArch_CPP=`    echo "$HostArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
293 HostVendor_CPP=`  echo "$HostVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
294 HostOS_CPP=`      echo "$HostOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
295
296 checkArch "$HostArch"
297 checkVendor "$HostVendor"
298 checkOS "$HostOS"
299
300 TargetPlatform="$TargetArch-$TargetVendor-$TargetOS"
301 TargetPlatform_CPP=`echo "$TargetPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
302 TargetArch_CPP=`    echo "$TargetArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
303 TargetVendor_CPP=`  echo "$TargetVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
304 TargetOS_CPP=`      echo "$TargetOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
305
306 checkArch "$TargetArch"
307 checkVendor "$TargetVendor"
308 checkOS "$TargetOS"
309
310 # Verify that the installed (bootstrap) GHC is capable of generating
311 # code for the requested build platform.
312 if test "$BootingFromHc" = "NO"
313 then
314     if test "$BuildPlatform" != "$bootstrap_target"
315     then
316         echo "This GHC (${WithGhc}) does not generate code for the build platform"
317         echo "   GHC target platform    : $bootstrap_target"
318         echo "   Desired build platform : $BuildPlatform"
319         exit 1
320     fi
321 fi
322
323 echo "GHC build  : $BuildPlatform"
324 echo "GHC host   : $HostPlatform"
325 echo "GHC target : $TargetPlatform"
326
327 AC_SUBST(BuildPlatform)
328 AC_SUBST(HostPlatform)
329 AC_SUBST(TargetPlatform)
330 AC_SUBST(HostPlatform_CPP)
331 AC_SUBST(BuildPlatform_CPP)
332 AC_SUBST(TargetPlatform_CPP)
333
334 AC_SUBST(HostArch_CPP)
335 AC_SUBST(BuildArch_CPP)
336 AC_SUBST(TargetArch_CPP)
337
338 AC_SUBST(HostOS_CPP)
339 AC_SUBST(BuildOS_CPP)
340 AC_SUBST(TargetOS_CPP)
341
342 AC_SUBST(HostVendor_CPP)
343 AC_SUBST(BuildVendor_CPP)
344 AC_SUBST(TargetVendor_CPP)
345
346 AC_SUBST(exeext)
347 AC_SUBST(soext)
348
349 AC_SUBST(SOLARIS_BROKEN_SHLD)
350
351 AC_ARG_WITH(hc,
352 [AC_HELP_STRING([--with-hc=ARG],
353         [Use ARG as the path to the compiler for compiling ordinary
354          Haskell code  (default= value of --with-ghc)])],
355 [WithHc="$withval"],
356 [WithHc=$WithGhc]
357 )
358 AC_SUBST(WithHc)
359
360 # This uses GHC, so put it after the "GHC is required" check above:
361 FP_INTREE_GHC_PWD
362 FP_FIND_ROOT
363
364 if test "$HostOS" = "mingw32"
365 then
366     test -d inplace || mkdir inplace
367
368     CC="$hardtop/inplace/mingw/bin/gcc.exe"
369     LD="$hardtop/inplace/mingw/bin/ld.exe"
370     NM="$hardtop/inplace/mingw/bin/nm.exe"
371     fp_prog_ar_raw="$hardtop/inplace/mingw/bin/ar.exe"
372
373     # NB. If you update the tarbballs to a new version of gcc, don't
374     # forget to tweak the paths in driver/gcc/gcc.c.
375     if ! test -d inplace/mingw ||
376          test inplace/mingw -ot ghc-tarballs/mingw/binutils*.tar.lzma  ||
377          test inplace/mingw -ot ghc-tarballs/mingw/gcc-core*.tar.lzma  ||
378          test inplace/mingw -ot ghc-tarballs/mingw/gcc-c++*.tar.lzma   ||
379          test inplace/mingw -ot ghc-tarballs/mingw/libgcc*.tar.gz      ||
380          test inplace/mingw -ot ghc-tarballs/mingw/libgmp*.tar.gz      ||
381          test inplace/mingw -ot ghc-tarballs/mingw/libmpc*.tar.gz      ||
382          test inplace/mingw -ot ghc-tarballs/mingw/libmpfr*.tar.gz     ||
383          test inplace/mingw -ot ghc-tarballs/mingw/libstdc*.tar.lzma   ||
384          test inplace/mingw -ot ghc-tarballs/mingw/mingwrt*-dev.tar.gz ||
385          test inplace/mingw -ot ghc-tarballs/mingw/mingwrt*-dll.tar.gz ||
386          test inplace/mingw -ot ghc-tarballs/mingw/w32api*.tar.lzma
387     then
388         AC_MSG_NOTICE([Making in-tree mingw tree])
389         rm -rf inplace/mingw
390         mkdir inplace/mingw
391         (
392             cd inplace/mingw &&
393             tar --lzma -xf ../../ghc-tarballs/mingw/binutils*.tar.lzma  &&
394             tar --lzma -xf ../../ghc-tarballs/mingw/gcc-core*.tar.lzma  &&
395             tar --lzma -xf ../../ghc-tarballs/mingw/gcc-c++*.tar.lzma   &&
396             tar --lzma -xf ../../ghc-tarballs/mingw/libgcc*.tar.lzma    &&
397             tar --lzma -xf ../../ghc-tarballs/mingw/libgmp*.tar.lzma    &&
398             tar --lzma -xf ../../ghc-tarballs/mingw/libmpc*.tar.lzma    &&
399             tar --lzma -xf ../../ghc-tarballs/mingw/libmpfr*.tar.lzma   &&
400             tar --lzma -xf ../../ghc-tarballs/mingw/libstdc*.tar.lzma   &&
401             tar -z     -xf ../../ghc-tarballs/mingw/mingwrt*-dev.tar.gz &&
402             tar -z     -xf ../../ghc-tarballs/mingw/mingwrt*-dll.tar.gz &&
403             tar --lzma -xf ../../ghc-tarballs/mingw/w32api*.tar.lzma    &&
404             mv bin/gcc.exe bin/realgcc.exe
405         )
406         PATH=`pwd`/inplace/mingw/bin:$PATH inplace/mingw/bin/realgcc.exe driver/gcc/gcc.c driver/utils/cwrapper.c driver/utils/getLocation.c -Idriver/utils -o inplace/mingw/bin/gcc.exe
407         if ! test -e inplace/mingw/bin/gcc.exe
408         then
409             AC_MSG_ERROR([GHC is required unless bootstrapping from .hc files.])
410         fi
411         AC_MSG_NOTICE([In-tree mingw tree created])
412     fi
413     if ! test -d inplace/perl ||
414          test inplace/perl -ot ghc-tarballs/perl/ghc-perl*.tar.gz
415     then
416         AC_MSG_NOTICE([Making in-tree perl tree])
417         rm -rf inplace/perl
418         mkdir inplace
419         mkdir inplace/perl
420         (
421             cd inplace/perl &&
422             tar -zxf ../../ghc-tarballs/perl/ghc-perl*.tar.gz
423         )
424         AC_MSG_NOTICE([In-tree perl tree created])
425     fi
426 fi
427
428 dnl ** Which gcc to use?
429 dnl --------------------------------------------------------------
430 FP_ARG_WITH_PATH_GNU_PROG([CC], [gcc])
431 export CC
432 WhatGccIsCalled="$CC"
433 AC_SUBST(WhatGccIsCalled)
434
435 dnl ** Which ld to use?
436 dnl --------------------------------------------------------------
437 FP_ARG_WITH_PATH_GNU_PROG([LD], [ld])
438 LdCmd="$LD"
439 AC_SUBST([LdCmd])
440
441 dnl ** Which nm to use?
442 dnl --------------------------------------------------------------
443 FP_ARG_WITH_PATH_GNU_PROG([NM], [nm])
444 NmCmd="$NM"
445 AC_SUBST([NmCmd])
446
447 SplitObjsBroken=NO
448 if test "$TargetOS_CPP" = "darwin"
449 then
450     AC_MSG_CHECKING(XCode version)
451     XCodeVersion=`xcodebuild -version | grep Xcode | sed "s/Xcode //"`
452     # Old XCode versions don't actually give the XCode version
453     if test "$XCodeVersion" = ""
454     then
455         AC_MSG_RESULT(not found (too old?))
456         SplitObjsBroken=YES
457     else
458         AC_MSG_RESULT($XCodeVersion)
459         XCodeVersion1=`echo "$XCodeVersion" | sed 's/\..*//'`
460 changequote(, )dnl
461         XCodeVersion2=`echo "$XCodeVersion" | sed 's/[^.]*\.\([^.]*\).*/\1/'`
462 changequote([, ])dnl
463         AC_MSG_NOTICE(XCode version component 1: $XCodeVersion1)
464         AC_MSG_NOTICE(XCode version component 2: $XCodeVersion2)
465         # Split objects is broken (#4013) with XCode < 3.2
466         if test "$XCodeVersion1" -lt 3
467         then
468             SplitObjsBroken=YES
469         else
470             if test "$XCodeVersion1" -eq 3
471             then
472                 if test "$XCodeVersion2" -lt 2
473                 then
474                     SplitObjsBroken=YES
475                 fi
476             fi
477         fi
478     fi
479 fi
480 AC_SUBST([SplitObjsBroken])
481
482 dnl ** Mac OS X: explicit deployment target
483 dnl --------------------------------------------------------------
484 AC_ARG_WITH([macosx-deployment-target],
485 [AC_HELP_STRING([--with-macosx-deployment-target=VERSION],
486         [Build for Mac OS VERSION and higher  (default= version of build host)])],
487 [FP_MACOSX_DEPLOYMENT_TARGET="$withval"
488  if test "x$TargetOS_CPP-$TargetVendor_CPP" != "xdarwin-apple"; then
489    # ignore everywhere, but on Mac OS
490    AC_MSG_WARN([--macosx-deployment-target is only available on Mac OS X])
491    FP_MACOSX_DEPLOYMENT_TARGET=none
492  fi],
493 [FP_MACOSX_DEPLOYMENT_TARGET=none]
494 )
495 FP_CHECK_MACOSX_DEPLOYMENT_TARGET
496 AC_SUBST(MACOSX_DEPLOYMENT_VERSION)
497 AC_SUBST(MACOSX_DEPLOYMENT_SDK)
498
499 dnl --------------------------------------------------------------
500 dnl End of configure script option section
501 dnl --------------------------------------------------------------
502
503
504 dnl --------------------------------------------------------------
505 dnl * General configuration checks
506 dnl --------------------------------------------------------------
507
508 dnl ** Can the unix package be built?
509 dnl --------------------------------------------------------------
510
511 if test x"$TargetPlatform" = x"i386-unknown-mingw32"; then
512    GhcLibsWithUnix=NO
513 else
514    GhcLibsWithUnix=YES
515 fi
516 AC_SUBST([GhcLibsWithUnix])
517
518 dnl ** does #! work?
519 AC_SYS_INTERPRETER()
520
521 dnl ** look for `perl'
522 case $HostOS_CPP in
523 cygwin32|mingw32)
524     PerlCmd=$hardtop/inplace/perl/perl
525     ;;
526 *)
527     AC_PATH_PROG(PerlCmd,perl)
528     if test -z "$PerlCmd"
529     then
530         echo "You must install perl before you can continue"
531         echo "Perhaps it is already installed, but not in your PATH?"
532         exit 1
533     else
534         FPTOOLS_CHECK_PERL_VERSION
535     fi
536     ;;
537 esac
538
539 dnl ** does #! path/to/perl work? (sometimes it's too long...)
540 FPTOOLS_SHEBANG_PERL
541
542 dnl ** check for Python
543 AC_PATH_PROG(PythonCmd,python)
544
545 dnl ** look for GCC and find out which version
546 dnl     Figure out which C compiler to use.  Gcc is preferred.
547 dnl     If gcc, make sure it's at least 2.1
548 dnl
549 FP_GCC_VERSION
550
551 FPTOOLS_SET_C_LD_FLAGS([target],[CFLAGS],[LDFLAGS],[IGNORE_LINKER_LD_FLAGS],[CPPFLAGS])
552 FPTOOLS_SET_C_LD_FLAGS([build],[CONF_CC_OPTS_STAGE0],[CONF_GCC_LINKER_OPTS_STAGE0],[CONF_LD_LINKER_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
553 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE1],[CONF_GCC_LINKER_OPTS_STAGE1],[CONF_LD_LINKER_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
554 # Stage 3 won't be supported by cross-compilation
555 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE2],[CONF_GCC_LINKER_OPTS_STAGE2],[CONF_LD_LINKER_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])
556
557 FP_GCC_EXTRA_FLAGS
558
559 dnl ** figure out how to invoke cpp directly (gcc -E is no good)
560 AC_PROG_CPP
561
562 AC_SUBST(CONF_CC_OPTS_STAGE0)
563 AC_SUBST(CONF_CC_OPTS_STAGE1)
564 AC_SUBST(CONF_CC_OPTS_STAGE2)
565 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE0)
566 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE1)
567 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE2)
568 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE0)
569 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE1)
570 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE2)
571 AC_SUBST(CONF_CPP_OPTS_STAGE0)
572 AC_SUBST(CONF_CPP_OPTS_STAGE1)
573 AC_SUBST(CONF_CPP_OPTS_STAGE2)
574
575 if test "$windows" = YES
576 then
577     SettingsCCompilerCommand='$topdir/../mingw/bin/gcc.exe'
578     SettingsCCompilerFlags=''
579     SettingsPerlCommand='$topdir/../perl/perl.exe'
580     SettingsDllWrapCommand='$topdir/../mingw/bin/dllwrap.exe'
581     SettingsWindresCommand='$topdir/../mingw/bin/windres.exe'
582     SettingsTouchCommand='$topdir/touch.exe'
583 else
584     SettingsCCompilerCommand="$WhatGccIsCalled"
585     SettingsCCompilerFlags="$CONF_CC_OPTS_STAGE2"
586     SettingsPerlCommand="$PerlCmd"
587     SettingsDllWrapCommand="/bin/false"
588     SettingsWindresCommand="/bin/false"
589     SettingsTouchCommand='touch'
590 fi
591 AC_SUBST(SettingsCCompilerCommand)
592 AC_SUBST(SettingsCCompilerFlags)
593 AC_SUBST(SettingsPerlCommand)
594 AC_SUBST(SettingsDllWrapCommand)
595 AC_SUBST(SettingsWindresCommand)
596 AC_SUBST(SettingsTouchCommand)
597
598 dnl ** figure out how to do context diffs
599 FP_PROG_CONTEXT_DIFF
600
601 dnl Let's make sure install-sh is executable here.  If we got it from
602 dnl a darcs repo, it might not be (see bug #978).
603 chmod +x install-sh
604 dnl ** figure out how to do a BSD-ish install
605 AC_PROG_INSTALL
606
607 dnl If you can run configure, you certainly have /bin/sh
608 AC_DEFINE([HAVE_BIN_SH], [1], [Define to 1 if you have /bin/sh.])
609
610 dnl ** how to invoke `ar' and `ranlib'
611 FP_PROG_AR_SUPPORTS_ATFILE
612 FP_PROG_AR_NEEDS_RANLIB
613
614 dnl ** Check to see whether ln -s works
615 AC_PROG_LN_S
616
617
618 dnl ** Find the path to sed
619 AC_PATH_PROGS(SedCmd,gsed sed,sed)
620
621
622 dnl ** check for time command
623 AC_PATH_PROG(TimeCmd,time)
624
625 dnl ** check for tar
626 dnl   if GNU tar is named gtar, look for it first.
627 AC_PATH_PROGS(TarCmd,gnutar gtar tar,tar)
628
629 dnl ** check for patch
630 dnl if GNU patch is named gpatch, look for it first
631 AC_PATH_PROGS(PatchCmd,gpatch patch, patch)
632
633 dnl ** check for dtrace (currently only implemented for Mac OS X)
634 HaveDtrace=NO
635 AC_PATH_PROG(DtraceCmd,dtrace)
636 if test -n "$DtraceCmd"; then
637   if test "x$TargetOS_CPP-$TargetVendor_CPP" == "xdarwin-apple" -o "x$TargetOS_CPP-$TargetVendor_CPP" == "xsolaris2-unknown"; then
638     HaveDtrace=YES
639   fi
640 fi
641 AC_SUBST(HaveDtrace)
642
643 AC_PATH_PROG(HSCOLOUR,HsColour)
644 # HsColour is passed to Cabal, so we need a native path
645 if test "x$HostPlatform"  = "xi386-unknown-mingw32" && \
646    test "${OSTYPE}"      != "msys"                  && \
647    test "${HSCOLOUR}"    != ""
648 then
649     # Canonicalise to <drive>:/path/to/gcc
650     HSCOLOUR=`cygpath -m ${HSCOLOUR}`
651 fi
652
653 dnl ** check for DocBook toolchain
654 FP_CHECK_DOCBOOK_DTD
655 FP_DOCBOOK_XSL
656 FP_PROG_DBLATEX
657
658 dnl ** check for ghc-pkg command
659 FP_PROG_GHC_PKG
660
661 dnl ** check for installed happy binary + version
662 dnl    (don't do it if we're booting from .hc files though.)
663 if test "$BootingFromHc" = "NO"; then
664 FPTOOLS_HAPPY
665 fi;
666
667 dnl ** check for installed alex binary + version
668 dnl    (don't do it if we're booting from .hc files though.)
669 if test "$BootingFromHc" = "NO"; then
670 FPTOOLS_ALEX
671 fi;
672
673 dnl --------------------------------------------------
674 dnl ### program checking section ends here ###
675 dnl --------------------------------------------------
676
677 dnl --------------------------------------------------
678 dnl * Platform header file and syscall feature tests
679 dnl ### checking the state of the local header files and syscalls ###
680
681 dnl ** check for full ANSI header (.h) files
682 AC_HEADER_STDC
683
684 dnl ** Enable large file support.  NB. do this before testing the type of
685 dnl    off_t, because it will affect the result of that test.
686 AC_SYS_LARGEFILE
687
688 dnl ** check for specific header (.h) files that we are interested in
689 AC_CHECK_HEADERS([bfd.h ctype.h dirent.h dlfcn.h errno.h fcntl.h grp.h limits.h locale.h nlist.h pthread.h pwd.h signal.h sys/cpuset.h sys/mman.h sys/resource.h sys/select.h sys/time.h sys/timeb.h sys/timers.h sys/times.h sys/utsname.h sys/wait.h termios.h time.h utime.h windows.h winsock.h sched.h])
690
691 dnl ** check if it is safe to include both <time.h> and <sys/time.h>
692 AC_HEADER_TIME
693
694 dnl ** do we have long longs?
695 AC_CHECK_TYPES([long long])
696
697 dnl ** what are the sizes of various types
698 AC_CHECK_SIZEOF(char,               1)
699 AC_CHECK_SIZEOF(double,             8)
700 AC_CHECK_SIZEOF(float,              4)
701 AC_CHECK_SIZEOF(int,                4)
702 AC_CHECK_SIZEOF(long,               4)
703 if test "$ac_cv_type_long_long" = yes; then
704 AC_CHECK_SIZEOF(long long,          8)
705 fi
706 AC_CHECK_SIZEOF(short,              2)
707 AC_CHECK_SIZEOF(unsigned char,      1)
708 AC_CHECK_SIZEOF(unsigned int,       4)
709 AC_CHECK_SIZEOF(unsigned long,      4)
710 if test "$ac_cv_type_long_long" = yes; then
711 AC_CHECK_SIZEOF(unsigned long long, 8)
712 fi
713 AC_CHECK_SIZEOF(unsigned short,     2)
714 AC_CHECK_SIZEOF(void *,             4)
715
716 dnl ** what are alignment constraints on various types
717 FP_CHECK_ALIGNMENT(char)
718 FP_CHECK_ALIGNMENT(double)
719 FP_CHECK_ALIGNMENT(float)
720 FP_CHECK_ALIGNMENT(int)
721 FP_CHECK_ALIGNMENT(long)
722 if test "$ac_cv_type_long_long" = yes; then
723 FP_CHECK_ALIGNMENT(long long)
724 fi
725 FP_CHECK_ALIGNMENT(short)
726 FP_CHECK_ALIGNMENT(unsigned char)
727 FP_CHECK_ALIGNMENT(unsigned int)
728 FP_CHECK_ALIGNMENT(unsigned long)
729 if test "$ac_cv_type_long_long" = yes; then
730 FP_CHECK_ALIGNMENT(unsigned long long)
731 fi
732 FP_CHECK_ALIGNMENT(unsigned short)
733 FP_CHECK_ALIGNMENT(void *)
734
735 FP_CHECK_FUNC([WinExec],
736   [@%:@include <windows.h>], [WinExec("",0)])
737
738 FP_CHECK_FUNC([GetModuleFileName],
739   [@%:@include <windows.h>], [GetModuleFileName((HMODULE)0,(LPTSTR)0,0)])
740
741 dnl ** check return type of signal handlers
742 dnl Foo: assumes we can use prototypes.
743 dnl On BCC, signal handlers have type "int(void)", elsewhere its "void(int)".
744 dnl AC_CACHE_CHECK([type of signal handlers], ac_cv_type_signal_handler,
745 dnl [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
746 dnl #include <signal.h>
747 dnl #ifdef signal
748 dnl #undef signal
749 dnl #endif
750 dnl void (*signal (int, void (*)(int)))(int);
751 dnl ]],
752 dnl [[int i;]])],
753 dnl [ac_cv_type_signal_handler=void_int],
754 dnl [ac_cv_type_signal_handler=int_void])])
755 dnl if test "$ac_cv_type_signal_handler" = void_int; then
756 dnl AC_DEFINE(VOID_INT_SIGNALS)
757 dnl fi
758
759 dnl On BCC, signal handlers have type "int(void)", elsewhere its "void(int)".
760 AC_TYPE_SIGNAL
761 if test "$ac_cv_type_signal" = void; then
762   AC_DEFINE([VOID_INT_SIGNALS], [1], [Define to 1 if signal handlers have type void (*)(int). Otherwise, they're assumed to have type int (*)(void).])
763 fi
764
765 dnl ** check for more functions
766 dnl ** The following have been verified to be used in ghc/, but might be used somewhere else, too.
767 AC_CHECK_FUNCS([getclock getrusage gettimeofday setitimer siginterrupt sysconf times ctime_r sched_setaffinity setlocale])
768
769 AC_TRY_RUN([
770 #include <sys/types.h>
771 #include <sys/time.h>
772 int main(void) {
773   struct itimerval tval;
774   tval.it_value.tv_sec = 1;
775   tval.it_value.tv_usec = 0;
776   tval.it_interval = tval.it_value;
777   return setitimer(ITIMER_VIRTUAL, &tval, (void*)0) != 0;
778 }
779 ],[AC_DEFINE([HAVE_SETITIMER_VIRTUAL], [1], [Define to 1 if setitimer accepts ITIMER_VIRTUAL, 0 else.])])
780
781 dnl ** On OS X 10.4 (at least), time.h doesn't declare ctime_r if
782 dnl ** _POSIX_C_SOURCE is defined
783 AC_CHECK_DECLS([ctime_r], , ,
784 [#define _POSIX_SOURCE 1
785 #define _POSIX_C_SOURCE 199506L
786 #include <time.h>])
787
788 dnl ** check for mingwex library
789 AC_CHECK_LIB(mingwex, closedir, HaveLibMingwEx=YES, HaveLibMingwEx=NO)
790 AC_SUBST(HaveLibMingwEx)
791
792 if test $HaveLibMingwEx = YES ; then
793   AC_DEFINE([HAVE_MINGWEX], [1], [Define to 1 if you have the mingwex library.])
794 fi
795
796 dnl ** check for math library
797 dnl    Keep that check as early as possible.
798 dnl    as we need to know whether we need libm
799 dnl    for math functions or not
800 dnl    (see http://hackage.haskell.org/trac/ghc/ticket/3730)
801 AC_CHECK_LIB(m, atan, HaveLibM=YES, HaveLibM=NO)
802 if test $HaveLibM = YES
803 then
804   AC_DEFINE([HAVE_LIBM], [1], [Define to 1 if you need to link with libm])
805 fi
806
807 dnl ** check whether this machine has BFD and liberty installed (used for debugging)
808 dnl    the order of these tests matters: bfd needs liberty
809 AC_CHECK_LIB(iberty, xmalloc)
810 AC_CHECK_LIB(bfd,    bfd_uncompress_section_contents)
811
812 dnl ################################################################
813 dnl Check for libraries
814 dnl ################################################################
815
816 dnl ** check whether we need -ldl to get dlopen()
817
818 AC_CHECK_LIB(dl, dlopen,
819     [HaveLibDL=YES
820      AC_DEFINE([HAVE_LIBDL], [1], [Define to 1 if you need -ldl to get dlopen().])
821      LIBS="$LIBS -ldl"],
822     [HaveLibDL=NO])
823 AC_SUBST(HaveLibDL)
824
825 dnl --------------------------------------------------
826 dnl * Miscellaneous feature tests
827 dnl --------------------------------------------------
828
829 dnl ** can we get alloca?
830 AC_FUNC_ALLOCA
831
832 dnl ** Working vfork?
833 AC_FUNC_FORK
834
835 dnl ** determine whether or not const works
836 AC_C_CONST
837
838 dnl ** are we big endian?
839 AC_C_BIGENDIAN
840 FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN
841
842 dnl ** check for leading underscores in symbol names
843 FP_LEADING_UNDERSCORE
844
845 dnl ** check for ld, whether it has an -x option, and if it is GNU ld
846 FP_PROG_LD_X
847 FP_PROG_LD_IS_GNU
848 FP_PROG_LD_BUILD_ID
849
850 dnl ** check for Apple-style dead-stripping support
851 dnl    (.subsections-via-symbols assembler directive)
852
853
854 AC_MSG_CHECKING(for .subsections_via_symbols)
855 AC_COMPILE_IFELSE(
856     [AC_LANG_PROGRAM([], [__asm__ (".subsections_via_symbols");])],
857     [AC_MSG_RESULT(yes)
858      AC_DEFINE([HAVE_SUBSECTIONS_VIA_SYMBOLS],[1],
859                [Define to 1 if Apple-style dead-stripping is supported.])
860     ],
861     [AC_MSG_RESULT(no)])
862
863 dnl *** check for GNU non-executable stack note support (ELF only)
864 dnl     (.section .note.GNU-stack,"",@progbits)
865
866 dnl This test doesn't work with "gcc -g" in gcc 4.4 (GHC trac #3889:
867 dnl     Error: can't resolve `.note.GNU-stack' {.note.GNU-stack section} - `.Ltext0' {.text section}
868 dnl so we empty CFLAGS while running this test
869 CFLAGS2="$CFLAGS"
870 CFLAGS=
871 AC_MSG_CHECKING(for GNU non-executable stack support)
872 AC_COMPILE_IFELSE(
873     [AC_LANG_PROGRAM([__asm__ (".section .note.GNU-stack,\"\",@progbits");], [0])],
874     [AC_MSG_RESULT(yes)
875      AC_DEFINE([HAVE_GNU_NONEXEC_STACK],[1],
876                [Define to 1 if GNU non-executable stack notes are supported.])
877     ],
878     [AC_MSG_RESULT(no)])
879 CFLAGS="$CFLAGS2"
880
881 FP_VISIBILITY_HIDDEN
882
883 dnl ** check for librt
884 AC_CHECK_LIB(rt, clock_gettime)
885 AC_CHECK_FUNCS(clock_gettime timer_create timer_settime)
886 FP_CHECK_TIMER_CREATE
887
888 dnl ** check for Apple's "interesting" long double compatibility scheme
889 AC_MSG_CHECKING(for printf\$LDBLStub)
890 AC_TRY_LINK_FUNC(printf\$LDBLStub,
891     [
892         AC_MSG_RESULT(yes)
893         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[1],
894             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
895     ],
896     [
897         AC_MSG_RESULT(no)
898         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[0],
899             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
900     ])
901
902 dnl ** check for eventfd which is needed by the I/O manager
903 AC_CHECK_HEADERS([sys/eventfd.h])
904 AC_CHECK_FUNCS([eventfd])
905
906 # test for GTK+
907 AC_PATH_PROGS([GTK_CONFIG], [pkg-config])
908 if test -n "$GTK_CONFIG"; then
909   if $GTK_CONFIG gtk+-2.0 --atleast-version=2.0; then
910     GTK_CONFIG="$GTK_CONFIG gtk+-2.0"
911   else
912     AC_MSG_WARN([GTK+ not usable, need at least version 2.0])
913     GTK_CONFIG=
914   fi
915 fi
916 AC_SUBST([GTK_CONFIG])
917
918 #Checking for PAPI
919 AC_CHECK_LIB(papi, PAPI_library_init, HavePapiLib=YES, HavePapiLib=NO)
920 AC_CHECK_HEADER([papi.h], [HavePapiHeader=YES], [HavePapiHeader=NO])
921 AC_SUBST(HavePapiLib)
922 AC_SUBST(HavePapiHeader)
923
924 AC_CHECK_FUNCS(__mingw_vfprintf)
925
926 if test "$HavePapiLib" = "YES" -a "$HavePapiHeader" = "YES"; then
927    HavePapi=YES
928 else
929    HavePapi=NO
930 fi
931 AC_SUBST(HavePapi)
932
933 if test "$HAVE_DOCBOOK_XSL" = "NO" ||
934    test "$XsltprocCmd" = ""
935 then
936     BUILD_DOCBOOK_HTML=NO
937 else
938     BUILD_DOCBOOK_HTML=YES
939 fi
940 AC_SUBST(BUILD_DOCBOOK_HTML)
941
942 if test "$DblatexCmd" = ""
943 then
944     BUILD_DOCBOOK_PS=NO
945     BUILD_DOCBOOK_PDF=NO
946 else
947     BUILD_DOCBOOK_PS=YES
948     BUILD_DOCBOOK_PDF=YES
949 fi
950 AC_SUBST(BUILD_DOCBOOK_PS)
951 AC_SUBST(BUILD_DOCBOOK_PDF)
952
953 LIBRARY_VERSION(base)
954 LIBRARY_VERSION(Cabal)
955 LIBRARY_VERSION(ghc-prim)
956 LIBRARY_ghc_VERSION="$ProjectVersion"
957 AC_SUBST(LIBRARY_ghc_VERSION)
958
959 if grep '       ' compiler/ghc.cabal.in 2>&1 >/dev/null; then
960    AC_MSG_ERROR([compiler/ghc.cabal.in contains tab characters; please remove them])
961 fi
962
963 AC_CONFIG_FILES([mk/config.mk mk/install.mk mk/project.mk compiler/ghc.cabal ghc/ghc-bin.cabal utils/runghc/runghc.cabal ghc.spec settings docs/users_guide/ug-book.xml docs/users_guide/ug-ent.xml docs/index.html libraries/prologue.txt distrib/ghc.iss distrib/configure.ac])
964 AC_CONFIG_COMMANDS([mk/stamp-h],[echo timestamp > mk/stamp-h])
965 AC_OUTPUT
966
967 # We get caught by
968 #     http://savannah.gnu.org/bugs/index.php?1516
969 #     $(eval ...) inside conditionals causes errors
970 # with make 3.80, so warn the user if it looks like they're about to
971 # try to use it.
972 # We would use "grep -q" here, but Solaris's grep doesn't support it.
973 checkMake380() {
974     if $1 --version 2>&1 | head -1 | grep 'GNU Make 3\.80' > /dev/null
975     then
976         echo
977         echo "WARNING: It looks like \"$1\" is GNU make 3.80."
978         echo "This version cannot be used to build GHC."
979         echo "Please use GNU make >= 3.81."
980     fi
981 }
982
983 checkMake380 make
984 checkMake380 gmake
985
986 echo ["
987 ----------------------------------------------------------------------
988 Configure completed successfully.
989
990    Building GHC version  : $ProjectVersion
991
992    Build platform        : $BuildPlatform
993    Host platform         : $HostPlatform
994    Target platform       : $TargetPlatform
995 "]
996
997 if test "$BootingFromHc" = "YES"; then
998 echo ["\
999    Bootstrapping from HC files.
1000 "]
1001 else
1002 echo ["\
1003    Bootstrapping using   : $WithGhc
1004       which is version   : $GhcVersion
1005 "]
1006 fi
1007
1008 echo ["\
1009    Using GCC             : $WhatGccIsCalled
1010       which is version   : $GccVersion
1011
1012    ld       : $LdCmd
1013    Happy    : $HappyCmd ($HappyVersion)
1014    Alex     : $AlexCmd ($AlexVersion)
1015    Python   : $PythonCmd
1016    Perl     : $PerlCmd
1017    dblatex  : $DblatexCmd
1018    xsltproc : $XsltprocCmd"]
1019
1020 if test "$HSCOLOUR" = ""; then
1021 echo ["
1022    HsColour was not found; documentation will not contain source links
1023 "]
1024 else
1025 echo ["\
1026    HsColour : $HSCOLOUR
1027 "]
1028 fi
1029
1030 echo ["\
1031    Building DocBook HTML documentation : $BUILD_DOCBOOK_HTML
1032    Building DocBook PS documentation   : $BUILD_DOCBOOK_PS
1033    Building DocBook PDF documentation  : $BUILD_DOCBOOK_PDF"]
1034
1035 echo ["----------------------------------------------------------------------
1036 "]
1037
1038 echo "\
1039 For a standard build of GHC (fully optimised with profiling), type (g)make.
1040
1041 To make changes to the default build configuration, copy the file
1042 mk/build.mk.sample to mk/build.mk, and edit the settings in there.
1043
1044 For more information on how to configure your GHC build, see
1045    http://hackage.haskell.org/trac/ghc/wiki/Building
1046 "