Don't try to float bindings through ticks
[ghc.git] / compiler / simplCore / Simplify.lhs
1 %
2 % (c) The AQUA Project, Glasgow University, 1993-1998
3 %
4 \section[Simplify]{The main module of the simplifier}
5
6 \begin{code}
7 {-# OPTIONS -fno-warn-tabs #-}
8 -- The above warning supression flag is a temporary kludge.
9 -- While working on this module you are encouraged to remove it and
10 -- detab the module (please do the detabbing in a separate patch). See
11 --     http://hackage.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#TabsvsSpaces
12 -- for details
13
14 module Simplify ( simplTopBinds, simplExpr ) where
15
16 #include "HsVersions.h"
17
18 import DynFlags
19 import SimplMonad
20 import Type hiding      ( substTy, extendTvSubst, substTyVar )
21 import SimplEnv
22 import SimplUtils
23 import FamInstEnv       ( FamInstEnv )
24 import Id
25 import MkId             ( seqId, realWorldPrimId )
26 import MkCore           ( mkImpossibleExpr )
27 import IdInfo
28 import Name             ( mkSystemVarName, isExternalName )
29 import Coercion hiding  ( substCo, substTy, substCoVar, extendTvSubst )
30 import OptCoercion      ( optCoercion )
31 import FamInstEnv       ( topNormaliseType )
32 import DataCon          ( DataCon, dataConWorkId, dataConRepStrictness )
33 import CoreMonad        ( Tick(..), SimplifierMode(..) )
34 import CoreSyn
35 import Demand           ( isStrictDmd, StrictSig(..), dmdTypeDepth )
36 import PprCore          ( pprParendExpr, pprCoreExpr )
37 import CoreUnfold 
38 import CoreUtils
39 import qualified CoreSubst
40 import CoreArity
41 import Rules            ( lookupRule, getRules )
42 import BasicTypes       ( isMarkedStrict, Arity )
43 import TysPrim          ( realWorldStatePrimTy )
44 import BasicTypes       ( TopLevelFlag(..), isTopLevel, RecFlag(..) )
45 import MonadUtils       ( foldlM, mapAccumLM )
46 import Maybes           ( orElse, isNothing )
47 import Data.List        ( mapAccumL )
48 import Outputable
49 import FastString
50 import Pair
51 \end{code}
52
53
54 The guts of the simplifier is in this module, but the driver loop for
55 the simplifier is in SimplCore.lhs.
56
57
58 -----------------------------------------
59         *** IMPORTANT NOTE ***
60 -----------------------------------------
61 The simplifier used to guarantee that the output had no shadowing, but
62 it does not do so any more.   (Actually, it never did!)  The reason is
63 documented with simplifyArgs.
64
65
66 -----------------------------------------
67         *** IMPORTANT NOTE ***
68 -----------------------------------------
69 Many parts of the simplifier return a bunch of "floats" as well as an
70 expression. This is wrapped as a datatype SimplUtils.FloatsWith.
71
72 All "floats" are let-binds, not case-binds, but some non-rec lets may
73 be unlifted (with RHS ok-for-speculation).
74
75
76
77 -----------------------------------------
78         ORGANISATION OF FUNCTIONS
79 -----------------------------------------
80 simplTopBinds
81   - simplify all top-level binders
82   - for NonRec, call simplRecOrTopPair
83   - for Rec,    call simplRecBind
84
85
86         ------------------------------
87 simplExpr (applied lambda)      ==> simplNonRecBind
88 simplExpr (Let (NonRec ...) ..) ==> simplNonRecBind
89 simplExpr (Let (Rec ...)    ..) ==> simplify binders; simplRecBind
90
91         ------------------------------
92 simplRecBind    [binders already simplfied]
93   - use simplRecOrTopPair on each pair in turn
94
95 simplRecOrTopPair [binder already simplified]
96   Used for: recursive bindings (top level and nested)
97             top-level non-recursive bindings
98   Returns:
99   - check for PreInlineUnconditionally
100   - simplLazyBind
101
102 simplNonRecBind
103   Used for: non-top-level non-recursive bindings
104             beta reductions (which amount to the same thing)
105   Because it can deal with strict arts, it takes a
106         "thing-inside" and returns an expression
107
108   - check for PreInlineUnconditionally
109   - simplify binder, including its IdInfo
110   - if strict binding
111         simplStrictArg
112         mkAtomicArgs
113         completeNonRecX
114     else
115         simplLazyBind
116         addFloats
117
118 simplNonRecX:   [given a *simplified* RHS, but an *unsimplified* binder]
119   Used for: binding case-binder and constr args in a known-constructor case
120   - check for PreInLineUnconditionally
121   - simplify binder
122   - completeNonRecX
123
124         ------------------------------
125 simplLazyBind:  [binder already simplified, RHS not]
126   Used for: recursive bindings (top level and nested)
127             top-level non-recursive bindings
128             non-top-level, but *lazy* non-recursive bindings
129         [must not be strict or unboxed]
130   Returns floats + an augmented environment, not an expression
131   - substituteIdInfo and add result to in-scope
132         [so that rules are available in rec rhs]
133   - simplify rhs
134   - mkAtomicArgs
135   - float if exposes constructor or PAP
136   - completeBind
137
138
139 completeNonRecX:        [binder and rhs both simplified]
140   - if the the thing needs case binding (unlifted and not ok-for-spec)
141         build a Case
142    else
143         completeBind
144         addFloats
145
146 completeBind:   [given a simplified RHS]
147         [used for both rec and non-rec bindings, top level and not]
148   - try PostInlineUnconditionally
149   - add unfolding [this is the only place we add an unfolding]
150   - add arity
151
152
153
154 Right hand sides and arguments
155 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
156 In many ways we want to treat
157         (a) the right hand side of a let(rec), and
158         (b) a function argument
159 in the same way.  But not always!  In particular, we would
160 like to leave these arguments exactly as they are, so they
161 will match a RULE more easily.
162
163         f (g x, h x)
164         g (+ x)
165
166 It's harder to make the rule match if we ANF-ise the constructor,
167 or eta-expand the PAP:
168
169         f (let { a = g x; b = h x } in (a,b))
170         g (\y. + x y)
171
172 On the other hand if we see the let-defns
173
174         p = (g x, h x)
175         q = + x
176
177 then we *do* want to ANF-ise and eta-expand, so that p and q
178 can be safely inlined.
179
180 Even floating lets out is a bit dubious.  For let RHS's we float lets
181 out if that exposes a value, so that the value can be inlined more vigorously.
182 For example
183
184         r = let x = e in (x,x)
185
186 Here, if we float the let out we'll expose a nice constructor. We did experiments
187 that showed this to be a generally good thing.  But it was a bad thing to float
188 lets out unconditionally, because that meant they got allocated more often.
189
190 For function arguments, there's less reason to expose a constructor (it won't
191 get inlined).  Just possibly it might make a rule match, but I'm pretty skeptical.
192 So for the moment we don't float lets out of function arguments either.
193
194
195 Eta expansion
196 ~~~~~~~~~~~~~~
197 For eta expansion, we want to catch things like
198
199         case e of (a,b) -> \x -> case a of (p,q) -> \y -> r
200
201 If the \x was on the RHS of a let, we'd eta expand to bring the two
202 lambdas together.  And in general that's a good thing to do.  Perhaps
203 we should eta expand wherever we find a (value) lambda?  Then the eta
204 expansion at a let RHS can concentrate solely on the PAP case.
205
206
207 %************************************************************************
208 %*                                                                      *
209 \subsection{Bindings}
210 %*                                                                      *
211 %************************************************************************
212
213 \begin{code}
214 simplTopBinds :: SimplEnv -> [InBind] -> SimplM SimplEnv
215
216 simplTopBinds env0 binds0
217   = do  {       -- Put all the top-level binders into scope at the start
218                 -- so that if a transformation rule has unexpectedly brought
219                 -- anything into scope, then we don't get a complaint about that.
220                 -- It's rather as if the top-level binders were imported.
221                 -- See note [Glomming] in OccurAnal.
222         ; env1 <- simplRecBndrs env0 (bindersOfBinds binds0)
223         ; dflags <- getDOptsSmpl
224         ; let dump_flag = dopt Opt_D_verbose_core2core dflags
225         ; env2 <- simpl_binds dump_flag env1 binds0
226         ; freeTick SimplifierDone
227         ; return env2 }
228   where
229         -- We need to track the zapped top-level binders, because
230         -- they should have their fragile IdInfo zapped (notably occurrence info)
231         -- That's why we run down binds and bndrs' simultaneously.
232         --
233         -- The dump-flag emits a trace for each top-level binding, which
234         -- helps to locate the tracing for inlining and rule firing
235     simpl_binds :: Bool -> SimplEnv -> [InBind] -> SimplM SimplEnv
236     simpl_binds _    env []           = return env
237     simpl_binds dump env (bind:binds) = do { env' <- trace_bind dump bind $
238                                                      simpl_bind env bind
239                                            ; simpl_binds dump env' binds }
240
241     trace_bind True  bind = pprTrace "SimplBind" (ppr (bindersOf bind))
242     trace_bind False _    = \x -> x
243
244     simpl_bind env (Rec pairs)  = simplRecBind      env  TopLevel pairs
245     simpl_bind env (NonRec b r) = simplRecOrTopPair env' TopLevel NonRecursive b b' r
246         where
247           (env', b') = addBndrRules env b (lookupRecBndr env b)
248 \end{code}
249
250
251 %************************************************************************
252 %*                                                                      *
253 \subsection{Lazy bindings}
254 %*                                                                      *
255 %************************************************************************
256
257 simplRecBind is used for
258         * recursive bindings only
259
260 \begin{code}
261 simplRecBind :: SimplEnv -> TopLevelFlag
262              -> [(InId, InExpr)]
263              -> SimplM SimplEnv
264 simplRecBind env0 top_lvl pairs0
265   = do  { let (env_with_info, triples) = mapAccumL add_rules env0 pairs0
266         ; env1 <- go (zapFloats env_with_info) triples
267         ; return (env0 `addRecFloats` env1) }
268         -- addFloats adds the floats from env1,
269         -- _and_ updates env0 with the in-scope set from env1
270   where
271     add_rules :: SimplEnv -> (InBndr,InExpr) -> (SimplEnv, (InBndr, OutBndr, InExpr))
272         -- Add the (substituted) rules to the binder
273     add_rules env (bndr, rhs) = (env', (bndr, bndr', rhs))
274         where
275           (env', bndr') = addBndrRules env bndr (lookupRecBndr env bndr)
276
277     go env [] = return env
278
279     go env ((old_bndr, new_bndr, rhs) : pairs)
280         = do { env' <- simplRecOrTopPair env top_lvl Recursive old_bndr new_bndr rhs
281              ; go env' pairs }
282 \end{code}
283
284 simplOrTopPair is used for
285         * recursive bindings (whether top level or not)
286         * top-level non-recursive bindings
287
288 It assumes the binder has already been simplified, but not its IdInfo.
289
290 \begin{code}
291 simplRecOrTopPair :: SimplEnv
292                   -> TopLevelFlag -> RecFlag
293                   -> InId -> OutBndr -> InExpr  -- Binder and rhs
294                   -> SimplM SimplEnv    -- Returns an env that includes the binding
295
296 simplRecOrTopPair env top_lvl is_rec old_bndr new_bndr rhs
297   | preInlineUnconditionally env top_lvl old_bndr rhs   -- Check for unconditional inline
298   = do  { tick (PreInlineUnconditionally old_bndr)
299         ; return (extendIdSubst env old_bndr (mkContEx env rhs)) }
300
301   | otherwise
302   = simplLazyBind env top_lvl is_rec old_bndr new_bndr rhs env
303 \end{code}
304
305
306 simplLazyBind is used for
307   * [simplRecOrTopPair] recursive bindings (whether top level or not)
308   * [simplRecOrTopPair] top-level non-recursive bindings
309   * [simplNonRecE]      non-top-level *lazy* non-recursive bindings
310
311 Nota bene:
312     1. It assumes that the binder is *already* simplified,
313        and is in scope, and its IdInfo too, except unfolding
314
315     2. It assumes that the binder type is lifted.
316
317     3. It does not check for pre-inline-unconditionallly;
318        that should have been done already.
319
320 \begin{code}
321 simplLazyBind :: SimplEnv
322               -> TopLevelFlag -> RecFlag
323               -> InId -> OutId          -- Binder, both pre-and post simpl
324                                         -- The OutId has IdInfo, except arity, unfolding
325               -> InExpr -> SimplEnv     -- The RHS and its environment
326               -> SimplM SimplEnv
327
328 simplLazyBind env top_lvl is_rec bndr bndr1 rhs rhs_se
329   = -- pprTrace "simplLazyBind" ((ppr bndr <+> ppr bndr1) $$ ppr rhs $$ ppr (seIdSubst rhs_se)) $
330     do  { let   rhs_env     = rhs_se `setInScope` env
331                 (tvs, body) = case collectTyBinders rhs of
332                                 (tvs, body) | not_lam body -> (tvs,body)
333                                             | otherwise    -> ([], rhs)
334                 not_lam (Lam _ _) = False
335                 not_lam _         = True
336                         -- Do not do the "abstract tyyvar" thing if there's
337                         -- a lambda inside, becuase it defeats eta-reduction
338                         --    f = /\a. \x. g a x  
339                         -- should eta-reduce
340
341         ; (body_env, tvs') <- simplBinders rhs_env tvs
342                 -- See Note [Floating and type abstraction] in SimplUtils
343
344         -- Simplify the RHS
345         ; (body_env1, body1) <- simplExprF body_env body mkRhsStop
346         -- ANF-ise a constructor or PAP rhs
347         ; (body_env2, body2) <- prepareRhs top_lvl body_env1 bndr1 body1
348
349         ; (env', rhs')
350             <-  if not (doFloatFromRhs top_lvl is_rec False body2 body_env2)
351                 then                            -- No floating, revert to body1
352                      do { rhs' <- mkLam env tvs' (wrapFloats body_env1 body1)
353                         ; return (env, rhs') }
354
355                 else if null tvs then           -- Simple floating
356                      do { tick LetFloatFromLet
357                         ; return (addFloats env body_env2, body2) }
358
359                 else                            -- Do type-abstraction first
360                      do { tick LetFloatFromLet
361                         ; (poly_binds, body3) <- abstractFloats tvs' body_env2 body2
362                         ; rhs' <- mkLam env tvs' body3
363                         ; env' <- foldlM (addPolyBind top_lvl) env poly_binds
364                         ; return (env', rhs') }
365
366         ; completeBind env' top_lvl bndr bndr1 rhs' }
367 \end{code}
368
369 A specialised variant of simplNonRec used when the RHS is already simplified,
370 notably in knownCon.  It uses case-binding where necessary.
371
372 \begin{code}
373 simplNonRecX :: SimplEnv
374              -> InId            -- Old binder
375              -> OutExpr         -- Simplified RHS
376              -> SimplM SimplEnv
377
378 simplNonRecX env bndr new_rhs
379   | isDeadBinder bndr   -- Not uncommon; e.g. case (a,b) of c { (p,q) -> p }
380   = return env          --               Here c is dead, and we avoid creating
381                         --               the binding c = (a,b)
382   | Coercion co <- new_rhs    
383   = return (extendCvSubst env bndr co)
384   | otherwise           --               the binding b = (a,b)
385   = do  { (env', bndr') <- simplBinder env bndr
386         ; completeNonRecX NotTopLevel env' (isStrictId bndr) bndr bndr' new_rhs }
387                 -- simplNonRecX is only used for NotTopLevel things
388
389 completeNonRecX :: TopLevelFlag -> SimplEnv
390                 -> Bool
391                 -> InId                 -- Old binder
392                 -> OutId                -- New binder
393                 -> OutExpr              -- Simplified RHS
394                 -> SimplM SimplEnv
395
396 completeNonRecX top_lvl env is_strict old_bndr new_bndr new_rhs
397   = do  { (env1, rhs1) <- prepareRhs top_lvl (zapFloats env) new_bndr new_rhs
398         ; (env2, rhs2) <- 
399                 if doFloatFromRhs NotTopLevel NonRecursive is_strict rhs1 env1
400                 then do { tick LetFloatFromLet
401                         ; return (addFloats env env1, rhs1) }   -- Add the floats to the main env
402                 else return (env, wrapFloats env1 rhs1)         -- Wrap the floats around the RHS
403         ; completeBind env2 NotTopLevel old_bndr new_bndr rhs2 }
404 \end{code}
405
406 {- No, no, no!  Do not try preInlineUnconditionally in completeNonRecX
407    Doing so risks exponential behaviour, because new_rhs has been simplified once already
408    In the cases described by the folowing commment, postInlineUnconditionally will
409    catch many of the relevant cases.
410         -- This happens; for example, the case_bndr during case of
411         -- known constructor:  case (a,b) of x { (p,q) -> ... }
412         -- Here x isn't mentioned in the RHS, so we don't want to
413         -- create the (dead) let-binding  let x = (a,b) in ...
414         --
415         -- Similarly, single occurrences can be inlined vigourously
416         -- e.g.  case (f x, g y) of (a,b) -> ....
417         -- If a,b occur once we can avoid constructing the let binding for them.
418
419    Furthermore in the case-binding case preInlineUnconditionally risks extra thunks
420         -- Consider     case I# (quotInt# x y) of
421         --                I# v -> let w = J# v in ...
422         -- If we gaily inline (quotInt# x y) for v, we end up building an
423         -- extra thunk:
424         --                let w = J# (quotInt# x y) in ...
425         -- because quotInt# can fail.
426
427   | preInlineUnconditionally env NotTopLevel bndr new_rhs
428   = thing_inside (extendIdSubst env bndr (DoneEx new_rhs))
429 -}
430
431 ----------------------------------
432 prepareRhs takes a putative RHS, checks whether it's a PAP or
433 constructor application and, if so, converts it to ANF, so that the
434 resulting thing can be inlined more easily.  Thus
435         x = (f a, g b)
436 becomes
437         t1 = f a
438         t2 = g b
439         x = (t1,t2)
440
441 We also want to deal well cases like this
442         v = (f e1 `cast` co) e2
443 Here we want to make e1,e2 trivial and get
444         x1 = e1; x2 = e2; v = (f x1 `cast` co) v2
445 That's what the 'go' loop in prepareRhs does
446
447 \begin{code}
448 prepareRhs :: TopLevelFlag -> SimplEnv -> OutId -> OutExpr -> SimplM (SimplEnv, OutExpr)
449 -- Adds new floats to the env iff that allows us to return a good RHS
450 prepareRhs top_lvl env id (Cast rhs co)    -- Note [Float coercions]
451   | Pair ty1 _ty2 <- coercionKind co       -- Do *not* do this if rhs has an unlifted type
452   , not (isUnLiftedType ty1)            -- see Note [Float coercions (unlifted)]
453   = do  { (env', rhs') <- makeTrivialWithInfo top_lvl env sanitised_info rhs
454         ; return (env', Cast rhs' co) }
455   where
456     sanitised_info = vanillaIdInfo `setStrictnessInfo` strictnessInfo info
457                                    `setDemandInfo`     demandInfo info
458     info = idInfo id
459
460 prepareRhs top_lvl env0 _ rhs0
461   = do  { (_is_exp, env1, rhs1) <- go 0 env0 rhs0
462         ; return (env1, rhs1) }
463   where
464     go n_val_args env (Cast rhs co)
465         = do { (is_exp, env', rhs') <- go n_val_args env rhs
466              ; return (is_exp, env', Cast rhs' co) }
467     go n_val_args env (App fun (Type ty))
468         = do { (is_exp, env', rhs') <- go n_val_args env fun
469              ; return (is_exp, env', App rhs' (Type ty)) }
470     go n_val_args env (App fun arg)
471         = do { (is_exp, env', fun') <- go (n_val_args+1) env fun
472              ; case is_exp of
473                 True -> do { (env'', arg') <- makeTrivial top_lvl env' arg
474                            ; return (True, env'', App fun' arg') }
475                 False -> return (False, env, App fun arg) }
476     go n_val_args env (Var fun)
477         = return (is_exp, env, Var fun)
478         where
479           is_exp = isExpandableApp fun n_val_args   -- The fun a constructor or PAP
480                         -- See Note [CONLIKE pragma] in BasicTypes
481                         -- The definition of is_exp should match that in
482                         -- OccurAnal.occAnalApp
483
484     go _ env other
485         = return (False, env, other)
486 \end{code}
487
488
489 Note [Float coercions]
490 ~~~~~~~~~~~~~~~~~~~~~~
491 When we find the binding
492         x = e `cast` co
493 we'd like to transform it to
494         x' = e
495         x = x `cast` co         -- A trivial binding
496 There's a chance that e will be a constructor application or function, or something
497 like that, so moving the coerion to the usage site may well cancel the coersions
498 and lead to further optimisation.  Example:
499
500      data family T a :: *
501      data instance T Int = T Int
502
503      foo :: Int -> Int -> Int
504      foo m n = ...
505         where
506           x = T m
507           go 0 = 0
508           go n = case x of { T m -> go (n-m) }
509                 -- This case should optimise
510
511 Note [Preserve strictness when floating coercions]
512 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
513 In the Note [Float coercions] transformation, keep the strictness info.
514 Eg
515         f = e `cast` co    -- f has strictness SSL
516 When we transform to
517         f' = e             -- f' also has strictness SSL
518         f = f' `cast` co   -- f still has strictness SSL
519
520 Its not wrong to drop it on the floor, but better to keep it.
521
522 Note [Float coercions (unlifted)]
523 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
524 BUT don't do [Float coercions] if 'e' has an unlifted type.
525 This *can* happen:
526
527      foo :: Int = (error (# Int,Int #) "urk")
528                   `cast` CoUnsafe (# Int,Int #) Int
529
530 If do the makeTrivial thing to the error call, we'll get
531     foo = case error (# Int,Int #) "urk" of v -> v `cast` ...
532 But 'v' isn't in scope!
533
534 These strange casts can happen as a result of case-of-case
535         bar = case (case x of { T -> (# 2,3 #); F -> error "urk" }) of
536                 (# p,q #) -> p+q
537
538
539 \begin{code}
540 makeTrivial :: TopLevelFlag -> SimplEnv -> OutExpr -> SimplM (SimplEnv, OutExpr)
541 -- Binds the expression to a variable, if it's not trivial, returning the variable
542 makeTrivial top_lvl env expr = makeTrivialWithInfo top_lvl env vanillaIdInfo expr
543
544 makeTrivialWithInfo :: TopLevelFlag -> SimplEnv -> IdInfo 
545                     -> OutExpr -> SimplM (SimplEnv, OutExpr)
546 -- Propagate strictness and demand info to the new binder
547 -- Note [Preserve strictness when floating coercions]
548 -- Returned SimplEnv has same substitution as incoming one
549 makeTrivialWithInfo top_lvl env info expr
550   | exprIsTrivial expr                          -- Already trivial
551   || not (bindingOk top_lvl expr expr_ty)       -- Cannot trivialise
552                                                 --   See Note [Cannot trivialise]
553   = return (env, expr)
554   | otherwise           -- See Note [Take care] below
555   = do  { uniq <- getUniqueM
556         ; let name = mkSystemVarName uniq (fsLit "a")
557               var = mkLocalIdWithInfo name expr_ty info
558         ; env'  <- completeNonRecX top_lvl env False var var expr
559         ; expr' <- simplVar env' var
560         ; return (env', expr') }
561         -- The simplVar is needed becase we're constructing a new binding
562         --     a = rhs
563         -- And if rhs is of form (rhs1 |> co), then we might get
564         --     a1 = rhs1
565         --     a = a1 |> co
566         -- and now a's RHS is trivial and can be substituted out, and that
567         -- is what completeNonRecX will do
568         -- To put it another way, it's as if we'd simplified
569         --    let var = e in var
570   where
571     expr_ty = exprType expr
572
573 bindingOk :: TopLevelFlag -> CoreExpr -> Type -> Bool
574 -- True iff we can have a binding of this expression at this level
575 -- Precondition: the type is the type of the expression
576 bindingOk top_lvl _ expr_ty
577   | isTopLevel top_lvl = not (isUnLiftedType expr_ty) 
578   | otherwise          = True
579 \end{code}
580
581 Note [Cannot trivialise]
582 ~~~~~~~~~~~~~~~~~~~~~~~~
583 Consider tih
584    f :: Int -> Addr#
585    
586    foo :: Bar
587    foo = Bar (f 3)
588
589 Then we can't ANF-ise foo, even though we'd like to, because
590 we can't make a top-level binding for the Addr# (f 3). And if
591 so we don't want to turn it into
592    foo = let x = f 3 in Bar x
593 because we'll just end up inlining x back, and that makes the
594 simplifier loop.  Better not to ANF-ise it at all.
595
596 A case in point is literal strings (a MachStr is not regarded as
597 trivial):
598
599    foo = Ptr "blob"#
600
601 We don't want to ANF-ise this.
602
603 %************************************************************************
604 %*                                                                      *
605 \subsection{Completing a lazy binding}
606 %*                                                                      *
607 %************************************************************************
608
609 completeBind
610   * deals only with Ids, not TyVars
611   * takes an already-simplified binder and RHS
612   * is used for both recursive and non-recursive bindings
613   * is used for both top-level and non-top-level bindings
614
615 It does the following:
616   - tries discarding a dead binding
617   - tries PostInlineUnconditionally
618   - add unfolding [this is the only place we add an unfolding]
619   - add arity
620
621 It does *not* attempt to do let-to-case.  Why?  Because it is used for
622   - top-level bindings (when let-to-case is impossible)
623   - many situations where the "rhs" is known to be a WHNF
624                 (so let-to-case is inappropriate).
625
626 Nor does it do the atomic-argument thing
627
628 \begin{code}
629 completeBind :: SimplEnv
630              -> TopLevelFlag            -- Flag stuck into unfolding
631              -> InId                    -- Old binder
632              -> OutId -> OutExpr        -- New binder and RHS
633              -> SimplM SimplEnv
634 -- completeBind may choose to do its work
635 --      * by extending the substitution (e.g. let x = y in ...)
636 --      * or by adding to the floats in the envt
637
638 completeBind env top_lvl old_bndr new_bndr new_rhs
639  | isCoVar old_bndr
640  = case new_rhs of
641      Coercion co -> return (extendCvSubst env old_bndr co)
642      _           -> return (addNonRec env new_bndr new_rhs)
643
644  | otherwise
645  = ASSERT( isId new_bndr )
646    do { let old_info = idInfo old_bndr
647             old_unf  = unfoldingInfo old_info
648             occ_info = occInfo old_info
649
650         -- Do eta-expansion on the RHS of the binding
651         -- See Note [Eta-expanding at let bindings] in SimplUtils
652       ; (new_arity, final_rhs) <- tryEtaExpand env new_bndr new_rhs
653
654         -- Simplify the unfolding
655       ; new_unfolding <- simplUnfolding env top_lvl old_bndr final_rhs old_unf
656
657       ; if postInlineUnconditionally env top_lvl new_bndr occ_info
658                                      final_rhs new_unfolding
659
660                         -- Inline and discard the binding
661         then do  { tick (PostInlineUnconditionally old_bndr)
662                  ; return (extendIdSubst env old_bndr (DoneEx final_rhs)) }
663                 -- Use the substitution to make quite, quite sure that the
664                 -- substitution will happen, since we are going to discard the binding
665         else
666    do { let info1 = idInfo new_bndr `setArityInfo` new_arity
667         
668               -- Unfolding info: Note [Setting the new unfolding]
669             info2 = info1 `setUnfoldingInfo` new_unfolding
670
671               -- Demand info: Note [Setting the demand info]
672               --
673               -- We also have to nuke demand info if for some reason
674               -- eta-expansion *reduces* the arity of the binding to less
675               -- than that of the strictness sig. This can happen: see Note [Arity decrease].
676             info3 | isEvaldUnfolding new_unfolding
677                     || (case strictnessInfo info2 of
678                           Just (StrictSig dmd_ty) -> new_arity < dmdTypeDepth dmd_ty
679                           Nothing                 -> False)
680                   = zapDemandInfo info2 `orElse` info2
681                   | otherwise
682                   = info2
683
684             final_id = new_bndr `setIdInfo` info3
685
686       ; -- pprTrace "Binding" (ppr final_id <+> ppr new_unfolding) $
687         return (addNonRec env final_id final_rhs) } }
688                 -- The addNonRec adds it to the in-scope set too
689
690 ------------------------------
691 addPolyBind :: TopLevelFlag -> SimplEnv -> OutBind -> SimplM SimplEnv
692 -- Add a new binding to the environment, complete with its unfolding
693 -- but *do not* do postInlineUnconditionally, because we have already
694 -- processed some of the scope of the binding
695 -- We still want the unfolding though.  Consider
696 --      let 
697 --            x = /\a. let y = ... in Just y
698 --      in body
699 -- Then we float the y-binding out (via abstractFloats and addPolyBind)
700 -- but 'x' may well then be inlined in 'body' in which case we'd like the 
701 -- opportunity to inline 'y' too.
702 --
703 -- INVARIANT: the arity is correct on the incoming binders
704
705 addPolyBind top_lvl env (NonRec poly_id rhs)
706   = do  { unfolding <- simplUnfolding env top_lvl poly_id rhs noUnfolding
707                         -- Assumes that poly_id did not have an INLINE prag
708                         -- which is perhaps wrong.  ToDo: think about this
709         ; let final_id = setIdInfo poly_id $
710                          idInfo poly_id `setUnfoldingInfo` unfolding
711
712         ; return (addNonRec env final_id rhs) }
713
714 addPolyBind _ env bind@(Rec _) 
715   = return (extendFloats env bind)
716         -- Hack: letrecs are more awkward, so we extend "by steam"
717         -- without adding unfoldings etc.  At worst this leads to
718         -- more simplifier iterations
719
720 ------------------------------
721 simplUnfolding :: SimplEnv-> TopLevelFlag
722                -> InId
723                -> OutExpr
724                -> Unfolding -> SimplM Unfolding
725 -- Note [Setting the new unfolding]
726 simplUnfolding env _ _ _ (DFunUnfolding ar con ops)
727   = return (DFunUnfolding ar con ops')
728   where
729     ops' = map (substExpr (text "simplUnfolding") env) ops
730
731 simplUnfolding env top_lvl id _
732     (CoreUnfolding { uf_tmpl = expr, uf_arity = arity
733                    , uf_src = src, uf_guidance = guide })
734   | isStableSource src
735   = do { expr' <- simplExpr rule_env expr
736        ; let src' = CoreSubst.substUnfoldingSource (mkCoreSubst (text "inline-unf") env) src
737              is_top_lvl = isTopLevel top_lvl
738        ; case guide of
739            UnfWhen sat_ok _    -- Happens for INLINE things
740               -> let guide' = UnfWhen sat_ok (inlineBoringOk expr')
741                      -- Refresh the boring-ok flag, in case expr'
742                      -- has got small. This happens, notably in the inlinings
743                      -- for dfuns for single-method classes; see
744                      -- Note [Single-method classes] in TcInstDcls.
745                      -- A test case is Trac #4138
746                  in return (mkCoreUnfolding src' is_top_lvl expr' arity guide')
747                  -- See Note [Top-level flag on inline rules] in CoreUnfold
748
749            _other              -- Happens for INLINABLE things
750               -> let bottoming = isBottomingId id
751                  in bottoming `seq` -- See Note [Force bottoming field]
752                     return (mkUnfolding src' is_top_lvl bottoming expr')
753                 -- If the guidance is UnfIfGoodArgs, this is an INLINABLE
754                 -- unfolding, and we need to make sure the guidance is kept up
755                 -- to date with respect to any changes in the unfolding.
756        }
757   where
758     act      = idInlineActivation id
759     rule_env = updMode (updModeForInlineRules act) env
760                -- See Note [Simplifying inside InlineRules] in SimplUtils
761
762 simplUnfolding _ top_lvl id new_rhs _
763   = let bottoming = isBottomingId id
764     in bottoming `seq`  -- See Note [Force bottoming field]
765        return (mkUnfolding InlineRhs (isTopLevel top_lvl) bottoming new_rhs)
766           -- We make an  unfolding *even for loop-breakers*.
767           -- Reason: (a) It might be useful to know that they are WHNF
768           --         (b) In TidyPgm we currently assume that, if we want to
769           --             expose the unfolding then indeed we *have* an unfolding
770           --             to expose.  (We could instead use the RHS, but currently
771           --             we don't.)  The simple thing is always to have one.
772 \end{code}
773
774 Note [Force bottoming field]
775 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
776 We need to force bottoming, or the new unfolding holds
777 on to the old unfolding (which is part of the id).
778
779 Note [Arity decrease]
780 ~~~~~~~~~~~~~~~~~~~~~
781 Generally speaking the arity of a binding should not decrease.  But it *can* 
782 legitimately happen becuase of RULES.  Eg
783         f = g Int
784 where g has arity 2, will have arity 2.  But if there's a rewrite rule
785         g Int --> h
786 where h has arity 1, then f's arity will decrease.  Here's a real-life example,
787 which is in the output of Specialise:
788
789      Rec {
790         $dm {Arity 2} = \d.\x. op d
791         {-# RULES forall d. $dm Int d = $s$dm #-}
792         
793         dInt = MkD .... opInt ...
794         opInt {Arity 1} = $dm dInt
795
796         $s$dm {Arity 0} = \x. op dInt }
797
798 Here opInt has arity 1; but when we apply the rule its arity drops to 0.
799 That's why Specialise goes to a little trouble to pin the right arity
800 on specialised functions too.
801
802 Note [Setting the new unfolding]
803 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
804 * If there's an INLINE pragma, we simplify the RHS gently.  Maybe we
805   should do nothing at all, but simplifying gently might get rid of 
806   more crap.
807
808 * If not, we make an unfolding from the new RHS.  But *only* for
809   non-loop-breakers. Making loop breakers not have an unfolding at all
810   means that we can avoid tests in exprIsConApp, for example.  This is
811   important: if exprIsConApp says 'yes' for a recursive thing, then we
812   can get into an infinite loop
813
814 If there's an InlineRule on a loop breaker, we hang on to the inlining.
815 It's pretty dodgy, but the user did say 'INLINE'.  May need to revisit
816 this choice.
817
818 Note [Setting the demand info]
819 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
820 If the unfolding is a value, the demand info may
821 go pear-shaped, so we nuke it.  Example:
822      let x = (a,b) in
823      case x of (p,q) -> h p q x
824 Here x is certainly demanded. But after we've nuked
825 the case, we'll get just
826      let x = (a,b) in h a b x
827 and now x is not demanded (I'm assuming h is lazy)
828 This really happens.  Similarly
829      let f = \x -> e in ...f..f...
830 After inlining f at some of its call sites the original binding may
831 (for example) be no longer strictly demanded.
832 The solution here is a bit ad hoc...
833
834
835 %************************************************************************
836 %*                                                                      *
837 \subsection[Simplify-simplExpr]{The main function: simplExpr}
838 %*                                                                      *
839 %************************************************************************
840
841 The reason for this OutExprStuff stuff is that we want to float *after*
842 simplifying a RHS, not before.  If we do so naively we get quadratic
843 behaviour as things float out.
844
845 To see why it's important to do it after, consider this (real) example:
846
847         let t = f x
848         in fst t
849 ==>
850         let t = let a = e1
851                     b = e2
852                 in (a,b)
853         in fst t
854 ==>
855         let a = e1
856             b = e2
857             t = (a,b)
858         in
859         a       -- Can't inline a this round, cos it appears twice
860 ==>
861         e1
862
863 Each of the ==> steps is a round of simplification.  We'd save a
864 whole round if we float first.  This can cascade.  Consider
865
866         let f = g d
867         in \x -> ...f...
868 ==>
869         let f = let d1 = ..d.. in \y -> e
870         in \x -> ...f...
871 ==>
872         let d1 = ..d..
873         in \x -> ...(\y ->e)...
874
875 Only in this second round can the \y be applied, and it
876 might do the same again.
877
878
879 \begin{code}
880 simplExpr :: SimplEnv -> CoreExpr -> SimplM CoreExpr
881 simplExpr env expr = simplExprC env expr mkBoringStop
882
883 simplExprC :: SimplEnv -> CoreExpr -> SimplCont -> SimplM CoreExpr
884         -- Simplify an expression, given a continuation
885 simplExprC env expr cont
886   = -- pprTrace "simplExprC" (ppr expr $$ ppr cont {- $$ ppr (seIdSubst env) -} $$ ppr (seFloats env) ) $
887     do  { (env', expr') <- simplExprF (zapFloats env) expr cont
888         ; -- pprTrace "simplExprC ret" (ppr expr $$ ppr expr') $
889           -- pprTrace "simplExprC ret3" (ppr (seInScope env')) $
890           -- pprTrace "simplExprC ret4" (ppr (seFloats env')) $
891           return (wrapFloats env' expr') }
892
893 --------------------------------------------------
894 simplExprF :: SimplEnv -> InExpr -> SimplCont
895            -> SimplM (SimplEnv, OutExpr)
896
897 simplExprF env e cont
898   = {- pprTrace "simplExprF" (vcat 
899       [ ppr e
900       , text "cont =" <+> ppr cont
901       , text "inscope =" <+> ppr (seInScope env)
902       , text "tvsubst =" <+> ppr (seTvSubst env)
903       , text "idsubst =" <+> ppr (seIdSubst env)
904       , text "cvsubst =" <+> ppr (seCvSubst env)
905       {- , ppr (seFloats env) -} 
906       ]) $ -}
907     simplExprF1 env e cont
908
909 simplExprF1 :: SimplEnv -> InExpr -> SimplCont
910             -> SimplM (SimplEnv, OutExpr)
911 simplExprF1 env (Var v)        cont = simplIdF env v cont
912 simplExprF1 env (Lit lit)      cont = rebuild env (Lit lit) cont
913 simplExprF1 env (Tick t expr)  cont = simplTick env t expr cont
914 simplExprF1 env (Cast body co) cont = simplCast env body co cont
915 simplExprF1 env (Coercion co)  cont = simplCoercionF env co cont
916 simplExprF1 env (Type ty)      cont = ASSERT( contIsRhsOrArg cont )
917                                       rebuild env (Type (substTy env ty)) cont
918 simplExprF1 env (App fun arg)  cont = simplExprF env fun $
919                                       ApplyTo NoDup arg env cont
920
921 simplExprF1 env expr@(Lam {}) cont
922   = simplLam env zapped_bndrs body cont
923         -- The main issue here is under-saturated lambdas
924         --   (\x1. \x2. e) arg1
925         -- Here x1 might have "occurs-once" occ-info, because occ-info
926         -- is computed assuming that a group of lambdas is applied
927         -- all at once.  If there are too few args, we must zap the
928         -- occ-info, UNLESS the remaining binders are one-shot
929   where
930     (bndrs, body) = collectBinders expr
931     zapped_bndrs | need_to_zap = map zap bndrs
932                  | otherwise   = bndrs
933
934     need_to_zap = any zappable_bndr (drop n_args bndrs)
935     n_args = countArgs cont
936         -- NB: countArgs counts all the args (incl type args)
937         -- and likewise drop counts all binders (incl type lambdas)
938
939     zappable_bndr b = isId b && not (isOneShotBndr b)
940     zap b | isTyVar b = b
941           | otherwise = zapLamIdInfo b
942
943 simplExprF1 env (Case scrut bndr _ alts) cont
944   | sm_case_case (getMode env)
945   =     -- Simplify the scrutinee with a Select continuation
946     simplExprF env scrut (Select NoDup bndr alts env cont)
947
948   | otherwise
949   =     -- If case-of-case is off, simply simplify the case expression
950         -- in a vanilla Stop context, and rebuild the result around it
951     do  { case_expr' <- simplExprC env scrut
952                              (Select NoDup bndr alts env mkBoringStop)
953         ; rebuild env case_expr' cont }
954
955 simplExprF1 env (Let (Rec pairs) body) cont
956   = do  { env' <- simplRecBndrs env (map fst pairs)
957                 -- NB: bndrs' don't have unfoldings or rules
958                 -- We add them as we go down
959
960         ; env'' <- simplRecBind env' NotTopLevel pairs
961         ; simplExprF env'' body cont }
962
963 simplExprF1 env (Let (NonRec bndr rhs) body) cont
964   = simplNonRecE env bndr (rhs, env) ([], body) cont
965
966 ---------------------------------
967 simplType :: SimplEnv -> InType -> SimplM OutType
968         -- Kept monadic just so we can do the seqType
969 simplType env ty
970   = -- pprTrace "simplType" (ppr ty $$ ppr (seTvSubst env)) $
971     seqType new_ty `seq` return new_ty
972   where
973     new_ty = substTy env ty
974
975 ---------------------------------
976 simplCoercionF :: SimplEnv -> InCoercion -> SimplCont
977                -> SimplM (SimplEnv, OutExpr)
978 -- We are simplifying a term of form (Coercion co)
979 -- Simplify the InCoercion, and then try to combine with the 
980 -- context, to implememt the rule
981 --     (Coercion co) |> g
982 --  =  Coercion (syn (nth 0 g) ; co ; nth 1 g) 
983 simplCoercionF env co cont 
984   = do { co' <- simplCoercion env co
985        ; simpl_co co' cont }
986   where
987     simpl_co co (CoerceIt g cont)
988        = simpl_co new_co cont
989      where
990        -- g :: (s1 ~# s2) ~# (t1 ~#  t2)
991        -- g1 :: s1 ~# t1
992        -- g2 :: s2 ~# t2
993        new_co = mkSymCo g1 `mkTransCo` co `mkTransCo` g2
994        [_reflk, g1, g2] = decomposeCo 3 g
995             -- Remember, (~#) :: forall k. k -> k -> *
996             -- so it takes *three* arguments, not two
997
998     simpl_co co cont
999        = seqCo co `seq` rebuild env (Coercion co) cont
1000
1001 simplCoercion :: SimplEnv -> InCoercion -> SimplM OutCoercion
1002 simplCoercion env co
1003   = let opt_co = optCoercion (getCvSubst env) co
1004     in opt_co `seq` return opt_co
1005
1006 -----------------------------------
1007 -- | Push a TickIt context outwards past applications and cases, as
1008 -- long as this is a non-scoping tick, to let case and application
1009 -- optimisations apply.
1010
1011 simplTick :: SimplEnv -> Tickish Id -> InExpr -> SimplCont
1012           -> SimplM (SimplEnv, OutExpr)
1013 simplTick env tickish expr cont
1014   -- A scoped tick turns into a continuation, so that we can spot
1015   -- (scc t (\x . e)) in simplLam and eliminate the scc.  If we didn't do
1016   -- it this way, then it would take two passes of the simplifier to
1017   -- reduce ((scc t (\x . e)) e').
1018   -- NB, don't do this with counting ticks, because if the expr is
1019   -- bottom, then rebuildCall will discard the continuation.
1020
1021 -- XXX: we cannot do this, because the simplifier assumes that
1022 -- the context can be pushed into a case with a single branch. e.g.
1023 --    scc<f>  case expensive of p -> e
1024 -- becomes
1025 --    case expensive of p -> scc<f> e
1026 --
1027 -- So I'm disabling this for now.  It just means we will do more
1028 -- simplifier iterations that necessary in some cases.
1029
1030 --  | tickishScoped tickish && not (tickishCounts tickish)
1031 --  = simplExprF env expr (TickIt tickish cont)
1032
1033   -- For non-scoped ticks, we push the continuation inside the
1034   -- tick.  This has the effect of moving the tick to the outside of a
1035   -- case or application context, allowing the normal case and
1036   -- application optimisations to fire.
1037   | not (tickishScoped tickish)
1038   = do { (env', expr') <- simplExprF env expr cont
1039        ; return (env', mkTick tickish expr')
1040        }
1041
1042   -- For breakpoints, we cannot do any floating of bindings around the
1043   -- tick, because breakpoints cannot be split into tick/scope pairs.
1044   | not (tickishCanSplit tickish)
1045   = no_floating_past_tick
1046
1047   | Just expr' <- want_to_push_tick_inside
1048     -- see Note [case-of-scc-of-case]
1049   = simplExprF env expr' cont
1050
1051   | otherwise
1052   = no_floating_past_tick -- was: wrap_floats, see below
1053
1054  where
1055   want_to_push_tick_inside
1056      | not interesting_cont = Nothing
1057      | not (tickishCanSplit tickish) = Nothing
1058      | otherwise
1059        = case expr of
1060            Case scrut bndr ty alts
1061               -> Just (Case (mkTick tickish scrut) bndr ty alts')
1062              where t_scope = mkNoTick tickish -- drop the tick on the dup'd ones
1063                    alts'   = [ (c,bs, mkTick t_scope e) | (c,bs,e) <- alts]
1064            _other -> Nothing
1065     where
1066       interesting_cont = case cont of
1067                             Select _ _ _ _ _ -> True
1068                             _ -> False
1069
1070   no_floating_past_tick =
1071     do { let (inc,outc) = splitCont cont
1072        ; (env', expr') <- simplExprF (zapFloats env) expr inc
1073        ; let tickish' = simplTickish env tickish
1074        ; (env'', expr'') <- rebuild (zapFloats env')
1075                                     (wrapFloats env' expr')
1076                                     (TickIt tickish' outc)
1077        ; return (addFloats env env'', expr'')
1078        }
1079
1080 -- Alternative version that wraps outgoing floats with the tick.  This
1081 -- results in ticks being duplicated, as we don't make any attempt to
1082 -- eliminate the tick if we re-inline the binding (because the tick
1083 -- semantics allows unrestricted inlining of HNFs), so I'm not doing
1084 -- this any more.  FloatOut will catch any real opportunities for
1085 -- floating.
1086 --
1087 --  wrap_floats =
1088 --    do { let (inc,outc) = splitCont cont
1089 --       ; (env', expr') <- simplExprF (zapFloats env) expr inc
1090 --       ; let tickish' = simplTickish env tickish
1091 --       ; let wrap_float (b,rhs) = (zapIdStrictness (setIdArity b 0),
1092 --                                   mkTick (mkNoTick tickish') rhs)
1093 --              -- when wrapping a float with mkTick, we better zap the Id's
1094 --              -- strictness info and arity, because it might be wrong now.
1095 --       ; let env'' = addFloats env (mapFloats env' wrap_float)
1096 --       ; rebuild env'' expr' (TickIt tickish' outc)
1097 --       }
1098
1099
1100   simplTickish env tickish
1101     | Breakpoint n ids <- tickish
1102           = Breakpoint n (map (getDoneId . substId env) ids)
1103     | otherwise = tickish
1104
1105   -- push type application and coercion inside a tick
1106   splitCont :: SimplCont -> (SimplCont, SimplCont)
1107   splitCont (ApplyTo f (Type t) env c) = (ApplyTo f (Type t) env inc, outc)
1108     where (inc,outc) = splitCont c
1109   splitCont (CoerceIt co c) = (CoerceIt co inc, outc)
1110     where (inc,outc) = splitCont c
1111   splitCont other = (mkBoringStop, other)
1112
1113   getDoneId (DoneId id) = id
1114   getDoneId (DoneEx e)  = getIdFromTrivialExpr e -- Note [substTickish] in CoreSubst
1115   getDoneId other = pprPanic "getDoneId" (ppr other)
1116
1117 -- Note [case-of-scc-of-case]
1118 -- It's pretty important to be able to transform case-of-case when
1119 -- there's an SCC in the way.  For example, the following comes up
1120 -- in nofib/real/compress/Encode.hs:
1121 --
1122 --        case scctick<code_string.r1>
1123 --             case $wcode_string_r13s wild_XC w1_s137 w2_s138 l_aje
1124 --             of _ { (# ww1_s13f, ww2_s13g, ww3_s13h #) ->
1125 --             (ww1_s13f, ww2_s13g, ww3_s13h)
1126 --             }
1127 --        of _ { (ww_s12Y, ww1_s12Z, ww2_s130) ->
1128 --        tick<code_string.f1>
1129 --        (ww_s12Y,
1130 --         ww1_s12Z,
1131 --         PTTrees.PT
1132 --           @ GHC.Types.Char @ GHC.Types.Int wild2_Xj ww2_s130 r_ajf)
1133 --        }
1134 --  
1135 -- We really want this case-of-case to fire, because then the 3-tuple
1136 -- will go away (indeed, the CPR optimisation is relying on this
1137 -- happening).  But the scctick is in the way - we need to push it
1138 -- inside to expose the case-of-case.  So we perform this
1139 -- transformation on the inner case:
1140 --
1141 --   scctick c (case e of { p1 -> e1; ...; pn -> en })
1142 --    ==>
1143 --   case (scctick c e) of { p1 -> scc c e1; ...; pn -> scc c en }
1144 --
1145 -- So we've moved a constant amount of work out of the scc to expose
1146 -- the case.  We only do this when the continuation is interesting: in
1147 -- for now, it has to be another Case (maybe generalise this later).
1148 \end{code}
1149
1150
1151 %************************************************************************
1152 %*                                                                      *
1153 \subsection{The main rebuilder}
1154 %*                                                                      *
1155 %************************************************************************
1156
1157 \begin{code}
1158 rebuild :: SimplEnv -> OutExpr -> SimplCont -> SimplM (SimplEnv, OutExpr)
1159 -- At this point the substitution in the SimplEnv should be irrelevant
1160 -- only the in-scope set and floats should matter
1161 rebuild env expr cont
1162   = case cont of
1163       Stop {}                      -> return (env, expr)
1164       CoerceIt co cont             -> rebuild env (Cast expr co) cont
1165       Select _ bndr alts se cont   -> rebuildCase (se `setFloats` env) expr bndr alts cont
1166       StrictArg info _ cont        -> rebuildCall env (info `addArgTo` expr) cont
1167       StrictBind b bs body se cont -> do { env' <- simplNonRecX (se `setFloats` env) b expr
1168                                          ; simplLam env' bs body cont }
1169       ApplyTo dup_flag arg se cont -- See Note [Avoid redundant simplification]
1170         | isSimplified dup_flag    -> rebuild env (App expr arg) cont
1171         | otherwise                -> do { arg' <- simplExpr (se `setInScope` env) arg
1172                                          ; rebuild env (App expr arg') cont }
1173       TickIt t cont                -> rebuild env (mkTick t expr) cont
1174 \end{code}
1175
1176
1177 %************************************************************************
1178 %*                                                                      *
1179 \subsection{Lambdas}
1180 %*                                                                      *
1181 %************************************************************************
1182
1183 \begin{code}
1184 simplCast :: SimplEnv -> InExpr -> Coercion -> SimplCont
1185           -> SimplM (SimplEnv, OutExpr)
1186 simplCast env body co0 cont0
1187   = do  { co1 <- simplCoercion env co0
1188         ; -- pprTrace "simplCast" (ppr co1) $
1189           simplExprF env body (addCoerce co1 cont0) }
1190   where
1191        addCoerce co cont = add_coerce co (coercionKind co) cont
1192
1193        add_coerce _co (Pair s1 k1) cont     -- co :: ty~ty
1194          | s1 `eqType` k1 = cont    -- is a no-op
1195
1196        add_coerce co1 (Pair s1 _k2) (CoerceIt co2 cont)
1197          | (Pair _l1 t1) <- coercionKind co2
1198                 --      e |> (g1 :: S1~L) |> (g2 :: L~T1)
1199                 -- ==>
1200                 --      e,                       if S1=T1
1201                 --      e |> (g1 . g2 :: S1~T1)  otherwise
1202                 --
1203                 -- For example, in the initial form of a worker
1204                 -- we may find  (coerce T (coerce S (\x.e))) y
1205                 -- and we'd like it to simplify to e[y/x] in one round
1206                 -- of simplification
1207          , s1 `eqType` t1  = cont            -- The coerces cancel out
1208          | otherwise       = CoerceIt (mkTransCo co1 co2) cont
1209
1210        add_coerce co (Pair s1s2 _t1t2) (ApplyTo dup (Type arg_ty) arg_se cont)
1211                 -- (f |> g) ty  --->   (f ty) |> (g @ ty)
1212                 -- This implements the PushT rule from the paper
1213          | Just (tyvar,_) <- splitForAllTy_maybe s1s2
1214          = ASSERT( isTyVar tyvar )
1215            ApplyTo Simplified (Type arg_ty') (zapSubstEnv arg_se) (addCoerce new_cast cont)
1216          where
1217            new_cast = mkInstCo co arg_ty'
1218            arg_ty' | isSimplified dup = arg_ty
1219                    | otherwise        = substTy (arg_se `setInScope` env) arg_ty
1220
1221        add_coerce co (Pair s1s2 t1t2) (ApplyTo dup arg arg_se cont)
1222          | isFunTy s1s2   -- This implements the Push rule from the paper
1223          , isFunTy t1t2   -- Check t1t2 to ensure 'arg' is a value arg
1224                 --      (e |> (g :: s1s2 ~ t1->t2)) f
1225                 -- ===>
1226                 --      (e (f |> (arg g :: t1~s1))
1227                 --      |> (res g :: s2->t2)
1228                 --
1229                 -- t1t2 must be a function type, t1->t2, because it's applied
1230                 -- to something but s1s2 might conceivably not be
1231                 --
1232                 -- When we build the ApplyTo we can't mix the out-types
1233                 -- with the InExpr in the argument, so we simply substitute
1234                 -- to make it all consistent.  It's a bit messy.
1235                 -- But it isn't a common case.
1236                 --
1237                 -- Example of use: Trac #995
1238          = ApplyTo dup new_arg (zapSubstEnv arg_se) (addCoerce co2 cont)
1239          where
1240            -- we split coercion t1->t2 ~ s1->s2 into t1 ~ s1 and
1241            -- t2 ~ s2 with left and right on the curried form:
1242            --    (->) t1 t2 ~ (->) s1 s2
1243            [co1, co2] = decomposeCo 2 co
1244            new_arg    = mkCoerce (mkSymCo co1) arg'
1245            arg'       = substExpr (text "move-cast") arg_se' arg
1246            arg_se'    = arg_se `setInScope` env
1247
1248        add_coerce co _ cont = CoerceIt co cont
1249 \end{code}
1250
1251
1252 %************************************************************************
1253 %*                                                                      *
1254 \subsection{Lambdas}
1255 %*                                                                      *
1256 %************************************************************************
1257
1258 Note [Zap unfolding when beta-reducing]
1259 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1260 Lambda-bound variables can have stable unfoldings, such as
1261    $j = \x. \b{Unf=Just x}. e
1262 See Note [Case binders and join points] below; the unfolding for lets
1263 us optimise e better.  However when we beta-reduce it we want to
1264 revert to using the actual value, otherwise we can end up in the
1265 stupid situation of
1266           let x = blah in
1267           let b{Unf=Just x} = y
1268           in ...b...
1269 Here it'd be far better to drop the unfolding and use the actual RHS.
1270
1271 \begin{code}
1272 simplLam :: SimplEnv -> [InId] -> InExpr -> SimplCont
1273          -> SimplM (SimplEnv, OutExpr)
1274
1275 simplLam env [] body cont = simplExprF env body cont
1276
1277         -- Beta reduction
1278 simplLam env (bndr:bndrs) body (ApplyTo _ arg arg_se cont)
1279   = do  { tick (BetaReduction bndr)
1280         ; simplNonRecE env (zap_unfolding bndr) (arg, arg_se) (bndrs, body) cont }
1281   where
1282     zap_unfolding bndr  -- See Note [Zap unfolding when beta-reducing]
1283       | isId bndr, isStableUnfolding (realIdUnfolding bndr)
1284       = setIdUnfolding bndr NoUnfolding
1285       | otherwise = bndr
1286
1287       -- discard a non-counting tick on a lambda.  This may change the
1288       -- cost attribution slightly (moving the allocation of the
1289       -- lambda elsewhere), but we don't care: optimisation changes
1290       -- cost attribution all the time.
1291 simplLam env bndrs body (TickIt tickish cont)
1292   | not (tickishCounts tickish)
1293   = simplLam env bndrs body cont
1294
1295         -- Not enough args, so there are real lambdas left to put in the result
1296 simplLam env bndrs body cont
1297   = do  { (env', bndrs') <- simplLamBndrs env bndrs
1298         ; body' <- simplExpr env' body
1299         ; new_lam <- mkLam env' bndrs' body'
1300         ; rebuild env' new_lam cont }
1301
1302 ------------------
1303 simplNonRecE :: SimplEnv
1304              -> InBndr                  -- The binder
1305              -> (InExpr, SimplEnv)      -- Rhs of binding (or arg of lambda)
1306              -> ([InBndr], InExpr)      -- Body of the let/lambda
1307                                         --      \xs.e
1308              -> SimplCont
1309              -> SimplM (SimplEnv, OutExpr)
1310
1311 -- simplNonRecE is used for
1312 --  * non-top-level non-recursive lets in expressions
1313 --  * beta reduction
1314 --
1315 -- It deals with strict bindings, via the StrictBind continuation,
1316 -- which may abort the whole process
1317 --
1318 -- The "body" of the binding comes as a pair of ([InId],InExpr)
1319 -- representing a lambda; so we recurse back to simplLam
1320 -- Why?  Because of the binder-occ-info-zapping done before
1321 --       the call to simplLam in simplExprF (Lam ...)
1322
1323         -- First deal with type applications and type lets
1324         --   (/\a. e) (Type ty)   and   (let a = Type ty in e)
1325 simplNonRecE env bndr (Type ty_arg, rhs_se) (bndrs, body) cont
1326   = ASSERT( isTyVar bndr )
1327     do  { ty_arg' <- simplType (rhs_se `setInScope` env) ty_arg
1328         ; simplLam (extendTvSubst env bndr ty_arg') bndrs body cont }
1329
1330 simplNonRecE env bndr (rhs, rhs_se) (bndrs, body) cont
1331   | preInlineUnconditionally env NotTopLevel bndr rhs
1332   = do  { tick (PreInlineUnconditionally bndr)
1333         ; -- pprTrace "preInlineUncond" (ppr bndr <+> ppr rhs) $
1334           simplLam (extendIdSubst env bndr (mkContEx rhs_se rhs)) bndrs body cont }
1335
1336   | isStrictId bndr              -- Includes coercions
1337   = do  { simplExprF (rhs_se `setFloats` env) rhs
1338                      (StrictBind bndr bndrs body env cont) }
1339
1340   | otherwise
1341   = ASSERT( not (isTyVar bndr) )
1342     do  { (env1, bndr1) <- simplNonRecBndr env bndr
1343         ; let (env2, bndr2) = addBndrRules env1 bndr bndr1
1344         ; env3 <- simplLazyBind env2 NotTopLevel NonRecursive bndr bndr2 rhs rhs_se
1345         ; simplLam env3 bndrs body cont }
1346 \end{code}
1347
1348 %************************************************************************
1349 %*                                                                      *
1350                      Variables
1351 %*                                                                      *
1352 %************************************************************************
1353
1354 \begin{code}
1355 simplVar :: SimplEnv -> InVar -> SimplM OutExpr
1356 -- Look up an InVar in the environment
1357 simplVar env var
1358   | isTyVar var = return (Type (substTyVar env var))
1359   | isCoVar var = return (Coercion (substCoVar env var))
1360   | otherwise
1361   = case substId env var of
1362         DoneId var1          -> return (Var var1)
1363         DoneEx e             -> return e
1364         ContEx tvs cvs ids e -> simplExpr (setSubstEnv env tvs cvs ids) e
1365
1366 simplIdF :: SimplEnv -> InId -> SimplCont -> SimplM (SimplEnv, OutExpr)
1367 simplIdF env var cont
1368   = case substId env var of
1369         DoneEx e             -> simplExprF (zapSubstEnv env) e cont
1370         ContEx tvs cvs ids e -> simplExprF (setSubstEnv env tvs cvs ids) e cont
1371         DoneId var1          -> completeCall env var1 cont
1372                 -- Note [zapSubstEnv]
1373                 -- The template is already simplified, so don't re-substitute.
1374                 -- This is VITAL.  Consider
1375                 --      let x = e in
1376                 --      let y = \z -> ...x... in
1377                 --      \ x -> ...y...
1378                 -- We'll clone the inner \x, adding x->x' in the id_subst
1379                 -- Then when we inline y, we must *not* replace x by x' in
1380                 -- the inlined copy!!
1381
1382 ---------------------------------------------------------
1383 --      Dealing with a call site
1384
1385 completeCall :: SimplEnv -> Id -> SimplCont -> SimplM (SimplEnv, OutExpr)
1386 completeCall env var cont
1387   = do  {   ------------- Try inlining ----------------
1388           dflags <- getDOptsSmpl
1389         ; let  (lone_variable, arg_infos, call_cont) = contArgs cont
1390                 -- The args are OutExprs, obtained by *lazily* substituting
1391                 -- in the args found in cont.  These args are only examined
1392                 -- to limited depth (unless a rule fires).  But we must do
1393                 -- the substitution; rule matching on un-simplified args would
1394                 -- be bogus
1395
1396                n_val_args = length arg_infos
1397                interesting_cont = interestingCallContext call_cont
1398                unfolding    = activeUnfolding env var
1399                maybe_inline = callSiteInline dflags var unfolding
1400                                              lone_variable arg_infos interesting_cont
1401         ; case maybe_inline of {
1402             Just expr      -- There is an inlining!
1403               ->  do { checkedTick (UnfoldingDone var)
1404                      ; trace_inline dflags expr cont $
1405                        simplExprF (zapSubstEnv env) expr cont }
1406
1407             ; Nothing -> do               -- No inlining!
1408
1409         { rule_base <- getSimplRules
1410         ; let info = mkArgInfo var (getRules rule_base var) n_val_args call_cont
1411         ; rebuildCall env info cont
1412     }}}
1413   where
1414     trace_inline dflags unfolding cont stuff
1415       | not (dopt Opt_D_dump_inlinings dflags) = stuff
1416       | not (dopt Opt_D_verbose_core2core dflags) 
1417       = if isExternalName (idName var) then 
1418           pprDefiniteTrace "Inlining done:" (ppr var) stuff
1419         else stuff
1420       | otherwise
1421       = pprDefiniteTrace ("Inlining done: " ++ showSDoc (ppr var))
1422            (vcat [text "Inlined fn: " <+> nest 2 (ppr unfolding),
1423                   text "Cont:  " <+> ppr cont])
1424            stuff
1425
1426 rebuildCall :: SimplEnv
1427             -> ArgInfo
1428             -> SimplCont
1429             -> SimplM (SimplEnv, OutExpr)
1430 rebuildCall env (ArgInfo { ai_fun = fun, ai_args = rev_args, ai_strs = [] }) cont
1431   -- When we run out of strictness args, it means
1432   -- that the call is definitely bottom; see SimplUtils.mkArgInfo
1433   -- Then we want to discard the entire strict continuation.  E.g.
1434   --    * case (error "hello") of { ... }
1435   --    * (error "Hello") arg
1436   --    * f (error "Hello") where f is strict
1437   --    etc
1438   -- Then, especially in the first of these cases, we'd like to discard
1439   -- the continuation, leaving just the bottoming expression.  But the
1440   -- type might not be right, so we may have to add a coerce.
1441   | not (contIsTrivial cont)     -- Only do this if there is a non-trivial
1442   = return (env, mk_coerce res)  -- contination to discard, else we do it
1443   where                          -- again and again!
1444     res     = mkApps (Var fun) (reverse rev_args)
1445     res_ty  = exprType res
1446     cont_ty = contResultType env res_ty cont
1447     co      = mkUnsafeCo res_ty cont_ty
1448     mk_coerce expr | cont_ty `eqType` res_ty = expr
1449                    | otherwise = mkCoerce co expr
1450
1451 rebuildCall env info (ApplyTo dup_flag (Type arg_ty) se cont)
1452   = do { arg_ty' <- if isSimplified dup_flag then return arg_ty
1453                     else simplType (se `setInScope` env) arg_ty
1454        ; rebuildCall env (info `addArgTo` Type arg_ty') cont }
1455
1456 rebuildCall env info@(ArgInfo { ai_encl = encl_rules
1457                               , ai_strs = str:strs, ai_discs = disc:discs })
1458             (ApplyTo dup_flag arg arg_se cont)
1459   | isSimplified dup_flag     -- See Note [Avoid redundant simplification]
1460   = rebuildCall env (addArgTo info' arg) cont
1461
1462   | str                 -- Strict argument
1463   = -- pprTrace "Strict Arg" (ppr arg $$ ppr (seIdSubst env) $$ ppr (seInScope env)) $
1464     simplExprF (arg_se `setFloats` env) arg
1465                (StrictArg info' cci cont)
1466                 -- Note [Shadowing]
1467
1468   | otherwise                           -- Lazy argument
1469         -- DO NOT float anything outside, hence simplExprC
1470         -- There is no benefit (unlike in a let-binding), and we'd
1471         -- have to be very careful about bogus strictness through
1472         -- floating a demanded let.
1473   = do  { arg' <- simplExprC (arg_se `setInScope` env) arg
1474                              (mkLazyArgStop cci)
1475         ; rebuildCall env (addArgTo info' arg') cont }
1476   where
1477     info' = info { ai_strs = strs, ai_discs = discs }
1478     cci | encl_rules || disc > 0 = ArgCtxt encl_rules  -- Be keener here
1479         | otherwise              = BoringCtxt          -- Nothing interesting
1480
1481 rebuildCall env (ArgInfo { ai_fun = fun, ai_args = rev_args, ai_rules = rules }) cont
1482   = do {  -- We've accumulated a simplified call in <fun,rev_args> 
1483           -- so try rewrite rules; see Note [RULEs apply to simplified arguments]
1484           -- See also Note [Rules for recursive functions]
1485         ; let args = reverse rev_args
1486               env' = zapSubstEnv env
1487         ; mb_rule <- tryRules env rules fun args cont
1488         ; case mb_rule of {
1489              Just (n_args, rule_rhs) -> simplExprF env' rule_rhs $
1490                                         pushSimplifiedArgs env' (drop n_args args) cont ;
1491                  -- n_args says how many args the rule consumed
1492            ; Nothing -> rebuild env (mkApps (Var fun) args) cont      -- No rules
1493     } }
1494 \end{code}
1495
1496 Note [RULES apply to simplified arguments]
1497 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1498 It's very desirable to try RULES once the arguments have been simplified, because
1499 doing so ensures that rule cascades work in one pass.  Consider
1500    {-# RULES g (h x) = k x
1501              f (k x) = x #-}
1502    ...f (g (h x))...
1503 Then we want to rewrite (g (h x)) to (k x) and only then try f's rules. If
1504 we match f's rules against the un-simplified RHS, it won't match.  This 
1505 makes a particularly big difference when superclass selectors are involved:
1506         op ($p1 ($p2 (df d)))
1507 We want all this to unravel in one sweeep.
1508
1509 Note [Avoid redundant simplification]
1510 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1511 Because RULES apply to simplified arguments, there's a danger of repeatedly
1512 simplifying already-simplified arguments.  An important example is that of
1513             (>>=) d e1 e2
1514 Here e1, e2 are simplified before the rule is applied, but don't really
1515 participate in the rule firing. So we mark them as Simplified to avoid
1516 re-simplifying them.
1517
1518 Note [Shadowing]
1519 ~~~~~~~~~~~~~~~~
1520 This part of the simplifier may break the no-shadowing invariant
1521 Consider
1522         f (...(\a -> e)...) (case y of (a,b) -> e')
1523 where f is strict in its second arg
1524 If we simplify the innermost one first we get (...(\a -> e)...)
1525 Simplifying the second arg makes us float the case out, so we end up with
1526         case y of (a,b) -> f (...(\a -> e)...) e'
1527 So the output does not have the no-shadowing invariant.  However, there is
1528 no danger of getting name-capture, because when the first arg was simplified
1529 we used an in-scope set that at least mentioned all the variables free in its
1530 static environment, and that is enough.
1531
1532 We can't just do innermost first, or we'd end up with a dual problem:
1533         case x of (a,b) -> f e (...(\a -> e')...)
1534
1535 I spent hours trying to recover the no-shadowing invariant, but I just could
1536 not think of an elegant way to do it.  The simplifier is already knee-deep in
1537 continuations.  We have to keep the right in-scope set around; AND we have
1538 to get the effect that finding (error "foo") in a strict arg position will
1539 discard the entire application and replace it with (error "foo").  Getting
1540 all this at once is TOO HARD!
1541
1542
1543 %************************************************************************
1544 %*                                                                      *
1545                 Rewrite rules
1546 %*                                                                      *
1547 %************************************************************************
1548
1549 \begin{code}
1550 tryRules :: SimplEnv -> [CoreRule]
1551          -> Id -> [OutExpr] -> SimplCont 
1552          -> SimplM (Maybe (Arity, CoreExpr))         -- The arity is the number of
1553                                                      -- args consumed by the rule
1554 tryRules env rules fn args call_cont
1555   | null rules
1556   = return Nothing
1557   | otherwise
1558   = do { case lookupRule (activeRule env) (getUnfoldingInRuleMatch env) 
1559                          (getInScope env) fn args rules of {
1560            Nothing               -> return Nothing ;   -- No rule matches
1561            Just (rule, rule_rhs) ->
1562
1563              do { checkedTick (RuleFired (ru_name rule))
1564                 ; dflags <- getDOptsSmpl
1565                 ; trace_dump dflags rule rule_rhs $
1566                   return (Just (ruleArity rule, rule_rhs)) }}}
1567   where
1568     trace_dump dflags rule rule_rhs stuff
1569       | not (dopt Opt_D_dump_rule_firings dflags)
1570       , not (dopt Opt_D_dump_rule_rewrites dflags) = stuff
1571
1572       | not (dopt Opt_D_dump_rule_rewrites dflags)
1573       = pprDefiniteTrace "Rule fired:" (ftext (ru_name rule)) stuff
1574
1575       | otherwise
1576       = pprDefiniteTrace "Rule fired"
1577            (vcat [text "Rule:" <+> ftext (ru_name rule),
1578                   text "Before:" <+> hang (ppr fn) 2 (sep (map pprParendExpr args)),
1579                   text "After: " <+> pprCoreExpr rule_rhs,
1580                   text "Cont:  " <+> ppr call_cont])
1581            stuff
1582 \end{code}
1583
1584 Note [Rules for recursive functions]
1585 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1586 You might think that we shouldn't apply rules for a loop breaker:
1587 doing so might give rise to an infinite loop, because a RULE is
1588 rather like an extra equation for the function:
1589      RULE:           f (g x) y = x+y
1590      Eqn:            f a     y = a-y
1591
1592 But it's too drastic to disable rules for loop breakers.
1593 Even the foldr/build rule would be disabled, because foldr
1594 is recursive, and hence a loop breaker:
1595      foldr k z (build g) = g k z
1596 So it's up to the programmer: rules can cause divergence
1597
1598
1599 %************************************************************************
1600 %*                                                                      *
1601                 Rebuilding a case expression
1602 %*                                                                      *
1603 %************************************************************************
1604
1605 Note [Case elimination]
1606 ~~~~~~~~~~~~~~~~~~~~~~~
1607 The case-elimination transformation discards redundant case expressions.
1608 Start with a simple situation:
1609
1610         case x# of      ===>   let y# = x# in e
1611           y# -> e
1612
1613 (when x#, y# are of primitive type, of course).  We can't (in general)
1614 do this for algebraic cases, because we might turn bottom into
1615 non-bottom!
1616
1617 The code in SimplUtils.prepareAlts has the effect of generalise this
1618 idea to look for a case where we're scrutinising a variable, and we
1619 know that only the default case can match.  For example:
1620
1621         case x of
1622           0#      -> ...
1623           DEFAULT -> ...(case x of
1624                          0#      -> ...
1625                          DEFAULT -> ...) ...
1626
1627 Here the inner case is first trimmed to have only one alternative, the
1628 DEFAULT, after which it's an instance of the previous case.  This
1629 really only shows up in eliminating error-checking code.
1630
1631 Note that SimplUtils.mkCase combines identical RHSs.  So
1632
1633         case e of       ===> case e of DEFAULT -> r
1634            True  -> r
1635            False -> r
1636
1637 Now again the case may be elminated by the CaseElim transformation.
1638 This includes things like (==# a# b#)::Bool so that we simplify
1639       case ==# a# b# of { True -> x; False -> x }
1640 to just
1641       x
1642 This particular example shows up in default methods for
1643 comparision operations (e.g. in (>=) for Int.Int32)
1644
1645 Note [CaseElimination: lifted case]
1646 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1647 We also make sure that we deal with this very common case,
1648 where x has a lifted type:
1649
1650         case e of
1651           x -> ...x...
1652
1653 Here we are using the case as a strict let; if x is used only once
1654 then we want to inline it.  We have to be careful that this doesn't
1655 make the program terminate when it would have diverged before, so we
1656 check that
1657         (a) 'e' is already evaluated (it may so if e is a variable)
1658             Specifically we check (exprIsHNF e)
1659 or
1660         (b) the scrutinee is a variable and 'x' is used strictly
1661 or
1662         (c) 'x' is not used at all and e is ok-for-speculation
1663
1664 For the (c), consider
1665    case (case a ># b of { True -> (p,q); False -> (q,p) }) of
1666      r -> blah
1667 The scrutinee is ok-for-speculation (it looks inside cases), but we do
1668 not want to transform to
1669    let r = case a ># b of { True -> (p,q); False -> (q,p) }
1670    in blah
1671 because that builds an unnecessary thunk.
1672
1673
1674 Further notes about case elimination
1675 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1676 Consider:       test :: Integer -> IO ()
1677                 test = print
1678
1679 Turns out that this compiles to:
1680     Print.test
1681       = \ eta :: Integer
1682           eta1 :: State# RealWorld ->
1683           case PrelNum.< eta PrelNum.zeroInteger of wild { __DEFAULT ->
1684           case hPutStr stdout
1685                  (PrelNum.jtos eta ($w[] @ Char))
1686                  eta1
1687           of wild1 { (# new_s, a4 #) -> PrelIO.lvl23 new_s  }}
1688
1689 Notice the strange '<' which has no effect at all. This is a funny one.
1690 It started like this:
1691
1692 f x y = if x < 0 then jtos x
1693           else if y==0 then "" else jtos x
1694
1695 At a particular call site we have (f v 1).  So we inline to get
1696
1697         if v < 0 then jtos x
1698         else if 1==0 then "" else jtos x
1699
1700 Now simplify the 1==0 conditional:
1701
1702         if v<0 then jtos v else jtos v
1703
1704 Now common-up the two branches of the case:
1705
1706         case (v<0) of DEFAULT -> jtos v
1707
1708 Why don't we drop the case?  Because it's strict in v.  It's technically
1709 wrong to drop even unnecessary evaluations, and in practice they
1710 may be a result of 'seq' so we *definitely* don't want to drop those.
1711 I don't really know how to improve this situation.
1712
1713 \begin{code}
1714 ---------------------------------------------------------
1715 --      Eliminate the case if possible
1716
1717 rebuildCase, reallyRebuildCase
1718    :: SimplEnv
1719    -> OutExpr          -- Scrutinee
1720    -> InId             -- Case binder
1721    -> [InAlt]          -- Alternatives (inceasing order)
1722    -> SimplCont
1723    -> SimplM (SimplEnv, OutExpr)
1724
1725 --------------------------------------------------
1726 --      1. Eliminate the case if there's a known constructor
1727 --------------------------------------------------
1728
1729 rebuildCase env scrut case_bndr alts cont
1730   | Lit lit <- scrut    -- No need for same treatment as constructors
1731                         -- because literals are inlined more vigorously
1732   = do  { tick (KnownBranch case_bndr)
1733         ; case findAlt (LitAlt lit) alts of
1734             Nothing           -> missingAlt env case_bndr alts cont
1735             Just (_, bs, rhs) -> simple_rhs bs rhs }
1736
1737   | Just (con, ty_args, other_args) <- exprIsConApp_maybe (getUnfoldingInRuleMatch env) scrut
1738         -- Works when the scrutinee is a variable with a known unfolding
1739         -- as well as when it's an explicit constructor application
1740   = do  { tick (KnownBranch case_bndr)
1741         ; case findAlt (DataAlt con) alts of
1742             Nothing  -> missingAlt env case_bndr alts cont
1743             Just (DEFAULT, bs, rhs) -> simple_rhs bs rhs
1744             Just (_, bs, rhs)       -> knownCon env scrut con ty_args other_args 
1745                                                 case_bndr bs rhs cont
1746         }
1747   where
1748     simple_rhs bs rhs = ASSERT( null bs ) 
1749                         do { env' <- simplNonRecX env case_bndr scrut
1750                            ; simplExprF env' rhs cont }
1751
1752
1753 --------------------------------------------------
1754 --      2. Eliminate the case if scrutinee is evaluated
1755 --------------------------------------------------
1756
1757 rebuildCase env scrut case_bndr [(_, bndrs, rhs)] cont
1758   -- See if we can get rid of the case altogether
1759   -- See Note [Case elimination] 
1760   -- mkCase made sure that if all the alternatives are equal,
1761   -- then there is now only one (DEFAULT) rhs
1762  | all isDeadBinder bndrs       -- bndrs are [InId]
1763
1764  , if isUnLiftedType (idType case_bndr)
1765    then ok_for_spec         -- Satisfy the let-binding invariant
1766    else elim_lifted
1767   = do  { tick (CaseElim case_bndr)
1768         ; env' <- simplNonRecX env case_bndr scrut
1769           -- If case_bndr is deads, simplNonRecX will discard
1770         ; simplExprF env' rhs cont }
1771   where
1772     elim_lifted   -- See Note [Case elimination: lifted case]
1773       = exprIsHNF scrut
1774      || (strict_case_bndr && scrut_is_var scrut) 
1775               -- The case binder is going to be evaluated later,
1776               -- and the scrutinee is a simple variable
1777
1778      || (is_plain_seq && ok_for_spec)
1779               -- Note: not the same as exprIsHNF
1780
1781     ok_for_spec      = exprOkForSpeculation scrut
1782     is_plain_seq     = isDeadBinder case_bndr   -- Evaluation *only* for effect
1783     strict_case_bndr = isStrictDmd (idDemandInfo case_bndr)
1784
1785     scrut_is_var (Cast s _) = scrut_is_var s
1786     scrut_is_var (Var _)    = True
1787     scrut_is_var _          = False
1788
1789
1790 --------------------------------------------------
1791 --      3. Try seq rules; see Note [User-defined RULES for seq] in MkId
1792 --------------------------------------------------
1793
1794 rebuildCase env scrut case_bndr alts@[(_, bndrs, rhs)] cont
1795   | all isDeadBinder (case_bndr : bndrs)  -- So this is just 'seq'
1796   = do { let rhs' = substExpr (text "rebuild-case") env rhs
1797              out_args = [Type (substTy env (idType case_bndr)), 
1798                          Type (exprType rhs'), scrut, rhs']
1799                       -- Lazily evaluated, so we don't do most of this
1800
1801        ; rule_base <- getSimplRules
1802        ; mb_rule <- tryRules env (getRules rule_base seqId) seqId out_args cont
1803        ; case mb_rule of 
1804            Just (n_args, res) -> simplExprF (zapSubstEnv env) 
1805                                             (mkApps res (drop n_args out_args))
1806                                             cont
1807            Nothing -> reallyRebuildCase env scrut case_bndr alts cont }
1808
1809 rebuildCase env scrut case_bndr alts cont
1810   = reallyRebuildCase env scrut case_bndr alts cont
1811
1812 --------------------------------------------------
1813 --      3. Catch-all case
1814 --------------------------------------------------
1815
1816 reallyRebuildCase env scrut case_bndr alts cont
1817   = do  {       -- Prepare the continuation;
1818                 -- The new subst_env is in place
1819           (env', dup_cont, nodup_cont) <- prepareCaseCont env alts cont
1820
1821         -- Simplify the alternatives
1822         ; (scrut', case_bndr', alts') <- simplAlts env' scrut case_bndr alts dup_cont
1823
1824         -- Check for empty alternatives
1825         ; if null alts' then missingAlt env case_bndr alts cont
1826           else do
1827         { dflags <- getDOptsSmpl
1828         ; case_expr <- mkCase dflags scrut' case_bndr' alts'
1829
1830         -- Notice that rebuild gets the in-scope set from env', not alt_env
1831         -- (which in any case is only build in simplAlts)
1832         -- The case binder *not* scope over the whole returned case-expression
1833         ; rebuild env' case_expr nodup_cont } }
1834 \end{code}
1835
1836 simplCaseBinder checks whether the scrutinee is a variable, v.  If so,
1837 try to eliminate uses of v in the RHSs in favour of case_bndr; that
1838 way, there's a chance that v will now only be used once, and hence
1839 inlined.
1840
1841 Historical note: we use to do the "case binder swap" in the Simplifier
1842 so there were additional complications if the scrutinee was a variable.
1843 Now the binder-swap stuff is done in the occurrence analyer; see
1844 OccurAnal Note [Binder swap].
1845
1846 Note [zapOccInfo]
1847 ~~~~~~~~~~~~~~~~~
1848 If the case binder is not dead, then neither are the pattern bound
1849 variables:  
1850         case <any> of x { (a,b) ->
1851         case x of { (p,q) -> p } }
1852 Here (a,b) both look dead, but come alive after the inner case is eliminated.
1853 The point is that we bring into the envt a binding
1854         let x = (a,b)
1855 after the outer case, and that makes (a,b) alive.  At least we do unless
1856 the case binder is guaranteed dead.
1857
1858 In practice, the scrutinee is almost always a variable, so we pretty
1859 much always zap the OccInfo of the binders.  It doesn't matter much though.
1860
1861 Note [Improving seq]
1862 ~~~~~~~~~~~~~~~~~~~
1863 Consider
1864         type family F :: * -> *
1865         type instance F Int = Int
1866
1867         ... case e of x { DEFAULT -> rhs } ...
1868
1869 where x::F Int.  Then we'd like to rewrite (F Int) to Int, getting
1870
1871         case e `cast` co of x'::Int
1872            I# x# -> let x = x' `cast` sym co
1873                     in rhs
1874
1875 so that 'rhs' can take advantage of the form of x'.  
1876
1877 Notice that Note [Case of cast] (in OccurAnal) may then apply to the result. 
1878
1879 Nota Bene: We only do the [Improving seq] transformation if the 
1880 case binder 'x' is actually used in the rhs; that is, if the case 
1881 is *not* a *pure* seq.  
1882   a) There is no point in adding the cast to a pure seq.
1883   b) There is a good reason not to: doing so would interfere 
1884      with seq rules (Note [Built-in RULES for seq] in MkId).
1885      In particular, this [Improving seq] thing *adds* a cast
1886      while [Built-in RULES for seq] *removes* one, so they
1887      just flip-flop.
1888
1889 You might worry about 
1890    case v of x { __DEFAULT ->
1891       ... case (v `cast` co) of y { I# -> ... }}
1892 This is a pure seq (since x is unused), so [Improving seq] won't happen.
1893 But it's ok: the simplifier will replace 'v' by 'x' in the rhs to get
1894    case v of x { __DEFAULT ->
1895       ... case (x `cast` co) of y { I# -> ... }}
1896 Now the outer case is not a pure seq, so [Improving seq] will happen,
1897 and then the inner case will disappear.
1898
1899 The need for [Improving seq] showed up in Roman's experiments.  Example:
1900   foo :: F Int -> Int -> Int
1901   foo t n = t `seq` bar n
1902      where
1903        bar 0 = 0
1904        bar n = bar (n - case t of TI i -> i)
1905 Here we'd like to avoid repeated evaluating t inside the loop, by
1906 taking advantage of the `seq`.
1907
1908 At one point I did transformation in LiberateCase, but it's more
1909 robust here.  (Otherwise, there's a danger that we'll simply drop the
1910 'seq' altogether, before LiberateCase gets to see it.)
1911
1912 \begin{code}
1913 simplAlts :: SimplEnv
1914           -> OutExpr
1915           -> InId                       -- Case binder
1916           -> [InAlt]                    -- Non-empty
1917           -> SimplCont
1918           -> SimplM (OutExpr, OutId, [OutAlt])  -- Includes the continuation
1919 -- Like simplExpr, this just returns the simplified alternatives;
1920 -- it does not return an environment
1921
1922 simplAlts env scrut case_bndr alts cont'
1923   = -- pprTrace "simplAlts" (ppr alts $$ ppr (seTvSubst env)) $
1924     do  { let env0 = zapFloats env
1925
1926         ; (env1, case_bndr1) <- simplBinder env0 case_bndr
1927
1928         ; fam_envs <- getFamEnvs
1929         ; (alt_env', scrut', case_bndr') <- improveSeq fam_envs env1 scrut 
1930                                                        case_bndr case_bndr1 alts
1931
1932         ; (imposs_deflt_cons, in_alts) <- prepareAlts scrut' case_bndr' alts
1933
1934         ; let mb_var_scrut = case scrut' of { Var v -> Just v; _ -> Nothing }
1935         ; alts' <- mapM (simplAlt alt_env' mb_var_scrut
1936                              imposs_deflt_cons case_bndr' cont') in_alts
1937         ; return (scrut', case_bndr', alts') }
1938
1939
1940 ------------------------------------
1941 improveSeq :: (FamInstEnv, FamInstEnv) -> SimplEnv
1942            -> OutExpr -> InId -> OutId -> [InAlt]
1943            -> SimplM (SimplEnv, OutExpr, OutId)
1944 -- Note [Improving seq]
1945 improveSeq fam_envs env scrut case_bndr case_bndr1 [(DEFAULT,_,_)]
1946   | not (isDeadBinder case_bndr)        -- Not a pure seq!  See Note [Improving seq]
1947   , Just (co, ty2) <- topNormaliseType fam_envs (idType case_bndr1)
1948   = do { case_bndr2 <- newId (fsLit "nt") ty2
1949         ; let rhs  = DoneEx (Var case_bndr2 `Cast` mkSymCo co)
1950               env2 = extendIdSubst env case_bndr rhs
1951         ; return (env2, scrut `Cast` co, case_bndr2) }
1952
1953 improveSeq _ env scrut _ case_bndr1 _
1954   = return (env, scrut, case_bndr1)
1955
1956
1957 ------------------------------------
1958 simplAlt :: SimplEnv
1959          -> Maybe OutId    -- Scrutinee
1960          -> [AltCon]       -- These constructors can't be present when
1961                            -- matching the DEFAULT alternative
1962          -> OutId          -- The case binder
1963          -> SimplCont
1964          -> InAlt
1965          -> SimplM OutAlt
1966
1967 simplAlt env scrut imposs_deflt_cons case_bndr' cont' (DEFAULT, bndrs, rhs)
1968   = ASSERT( null bndrs )
1969     do  { let env' = addBinderUnfolding env scrut case_bndr' 
1970                                         (mkOtherCon imposs_deflt_cons)
1971                 -- Record the constructors that the case-binder *can't* be.
1972         ; rhs' <- simplExprC env' rhs cont'
1973         ; return (DEFAULT, [], rhs') }
1974
1975 simplAlt env scrut _ case_bndr' cont' (LitAlt lit, bndrs, rhs)
1976   = ASSERT( null bndrs )
1977     do  { let env' = addBinderUnfolding env scrut case_bndr' 
1978                                         (mkSimpleUnfolding (Lit lit))
1979         ; rhs' <- simplExprC env' rhs cont'
1980         ; return (LitAlt lit, [], rhs') }
1981
1982 simplAlt env scrut _ case_bndr' cont' (DataAlt con, vs, rhs)
1983   = do  {       -- Deal with the pattern-bound variables
1984                 -- Mark the ones that are in ! positions in the
1985                 -- data constructor as certainly-evaluated.
1986                 -- NB: simplLamBinders preserves this eval info
1987           let vs_with_evals = add_evals (dataConRepStrictness con)
1988         ; (env', vs') <- simplLamBndrs env vs_with_evals
1989
1990                 -- Bind the case-binder to (con args)
1991         ; let inst_tys' = tyConAppArgs (idType case_bndr')
1992               con_args  = map Type inst_tys' ++ varsToCoreExprs vs'
1993               unf       = mkSimpleUnfolding (mkConApp con con_args)
1994               env''     = addBinderUnfolding env' scrut case_bndr' unf
1995
1996         ; rhs' <- simplExprC env'' rhs cont'
1997         ; return (DataAlt con, vs', rhs') }
1998   where
1999         -- add_evals records the evaluated-ness of the bound variables of
2000         -- a case pattern.  This is *important*.  Consider
2001         --      data T = T !Int !Int
2002         --
2003         --      case x of { T a b -> T (a+1) b }
2004         --
2005         -- We really must record that b is already evaluated so that we don't
2006         -- go and re-evaluate it when constructing the result.
2007         -- See Note [Data-con worker strictness] in MkId.lhs
2008     add_evals the_strs
2009         = go vs the_strs
2010         where
2011           go [] [] = []
2012           go (v:vs') strs | isTyVar v = v : go vs' strs
2013           go (v:vs') (str:strs)
2014             | isMarkedStrict str = evald_v  : go vs' strs
2015             | otherwise          = zapped_v : go vs' strs
2016             where
2017               zapped_v = zapBndrOccInfo keep_occ_info v
2018               evald_v  = zapped_v `setIdUnfolding` evaldUnfolding
2019           go _ _ = pprPanic "cat_evals" (ppr con $$ ppr vs $$ ppr the_strs)
2020
2021         -- See Note [zapOccInfo]
2022         -- zap_occ_info: if the case binder is alive, then we add the unfolding
2023         --      case_bndr = C vs
2024         -- to the envt; so vs are now very much alive
2025         -- Note [Aug06] I can't see why this actually matters, but it's neater
2026         --        case e of t { (a,b) -> ...(case t of (p,q) -> p)... }
2027         --   ==>  case e of t { (a,b) -> ...(a)... }
2028         -- Look, Ma, a is alive now.
2029     keep_occ_info = isDeadBinder case_bndr' && isNothing scrut
2030
2031 addBinderUnfolding :: SimplEnv -> Maybe OutId -> Id -> Unfolding -> SimplEnv
2032 addBinderUnfolding env scrut bndr unf
2033   = case scrut of
2034        Just v -> modifyInScope env1 (v `setIdUnfolding` unf)
2035        _      -> env1
2036   where
2037     env1 = modifyInScope env bndr_w_unf
2038     bndr_w_unf = bndr `setIdUnfolding` unf
2039
2040 zapBndrOccInfo :: Bool -> Id -> Id
2041 -- Consider  case e of b { (a,b) -> ... }
2042 -- Then if we bind b to (a,b) in "...", and b is not dead,
2043 -- then we must zap the deadness info on a,b
2044 zapBndrOccInfo keep_occ_info pat_id
2045   | keep_occ_info = pat_id
2046   | otherwise     = zapIdOccInfo pat_id
2047 \end{code}
2048
2049 Note [Add unfolding for scrutinee]
2050 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2051 In general it's unlikely that a variable scrutinee will appear 
2052 in the case alternatives   case x of { ...x unlikely to appear... }
2053 because the binder-swap in OccAnal has got rid of all such occcurrences
2054 See Note [Binder swap] in OccAnal.
2055
2056 BUT it is still VERY IMPORTANT to add a suitable unfolding for a
2057 variable scrutinee, in simplAlt.  Here's why
2058    case x of y
2059      (a,b) -> case b of c
2060                 I# v -> ...(f y)...
2061 There is no occurrence of 'b' in the (...(f y)...).  But y gets
2062 the unfolding (a,b), and *that* mentions b.  If f has a RULE
2063     RULE f (p, I# q) = ...
2064 we want that rule to match, so we must extend the in-scope env with a
2065 suitable unfolding for 'y'.  It's *essential* for rule matching; but
2066 it's also good for case-elimintation -- suppose that 'f' was inlined
2067 and did multi-level case analysis, then we'd solve it in one
2068 simplifier sweep instead of two.
2069
2070 Exactly the same issue arises in SpecConstr; 
2071 see Note [Add scrutinee to ValueEnv too] in SpecConstr
2072
2073 %************************************************************************
2074 %*                                                                      *
2075 \subsection{Known constructor}
2076 %*                                                                      *
2077 %************************************************************************
2078
2079 We are a bit careful with occurrence info.  Here's an example
2080
2081         (\x* -> case x of (a*, b) -> f a) (h v, e)
2082
2083 where the * means "occurs once".  This effectively becomes
2084         case (h v, e) of (a*, b) -> f a)
2085 and then
2086         let a* = h v; b = e in f a
2087 and then
2088         f (h v)
2089
2090 All this should happen in one sweep.
2091
2092 \begin{code}
2093 knownCon :: SimplEnv            
2094          -> OutExpr                             -- The scrutinee
2095          -> DataCon -> [OutType] -> [OutExpr]   -- The scrutinee (in pieces)
2096          -> InId -> [InBndr] -> InExpr          -- The alternative
2097          -> SimplCont
2098          -> SimplM (SimplEnv, OutExpr)
2099
2100 knownCon env scrut dc dc_ty_args dc_args bndr bs rhs cont
2101   = do  { env'  <- bind_args env bs dc_args
2102         ; env'' <- bind_case_bndr env'
2103         ; simplExprF env'' rhs cont }
2104   where
2105     zap_occ = zapBndrOccInfo (isDeadBinder bndr)    -- bndr is an InId
2106
2107                   -- Ugh!
2108     bind_args env' [] _  = return env'
2109
2110     bind_args env' (b:bs') (Type ty : args)
2111       = ASSERT( isTyVar b )
2112         bind_args (extendTvSubst env' b ty) bs' args
2113
2114     bind_args env' (b:bs') (arg : args)
2115       = ASSERT( isId b )
2116         do { let b' = zap_occ b
2117              -- Note that the binder might be "dead", because it doesn't
2118              -- occur in the RHS; and simplNonRecX may therefore discard
2119              -- it via postInlineUnconditionally.
2120              -- Nevertheless we must keep it if the case-binder is alive,
2121              -- because it may be used in the con_app.  See Note [zapOccInfo]
2122            ; env'' <- simplNonRecX env' b' arg
2123            ; bind_args env'' bs' args }
2124
2125     bind_args _ _ _ =
2126       pprPanic "bind_args" $ ppr dc $$ ppr bs $$ ppr dc_args $$
2127                              text "scrut:" <+> ppr scrut
2128
2129        -- It's useful to bind bndr to scrut, rather than to a fresh
2130        -- binding      x = Con arg1 .. argn
2131        -- because very often the scrut is a variable, so we avoid
2132        -- creating, and then subsequently eliminating, a let-binding
2133        -- BUT, if scrut is a not a variable, we must be careful
2134        -- about duplicating the arg redexes; in that case, make
2135        -- a new con-app from the args
2136     bind_case_bndr env
2137       | isDeadBinder bndr   = return env
2138       | exprIsTrivial scrut = return (extendIdSubst env bndr (DoneEx scrut))
2139       | otherwise           = do { dc_args <- mapM (simplVar env) bs
2140                                          -- dc_ty_args are aready OutTypes, 
2141                                          -- but bs are InBndrs
2142                                  ; let con_app = Var (dataConWorkId dc) 
2143                                                  `mkTyApps` dc_ty_args      
2144                                                  `mkApps`   dc_args
2145                                  ; simplNonRecX env bndr con_app }
2146   
2147 -------------------
2148 missingAlt :: SimplEnv -> Id -> [InAlt] -> SimplCont -> SimplM (SimplEnv, OutExpr)
2149                 -- This isn't strictly an error, although it is unusual. 
2150                 -- It's possible that the simplifer might "see" that 
2151                 -- an inner case has no accessible alternatives before 
2152                 -- it "sees" that the entire branch of an outer case is 
2153                 -- inaccessible.  So we simply put an error case here instead.
2154 missingAlt env case_bndr alts cont
2155   = WARN( True, ptext (sLit "missingAlt") <+> ppr case_bndr )
2156     return (env, mkImpossibleExpr res_ty)
2157   where
2158     res_ty = contResultType env (substTy env (coreAltsType alts)) cont
2159 \end{code}
2160
2161
2162 %************************************************************************
2163 %*                                                                      *
2164 \subsection{Duplicating continuations}
2165 %*                                                                      *
2166 %************************************************************************
2167
2168 \begin{code}
2169 prepareCaseCont :: SimplEnv
2170                 -> [InAlt] -> SimplCont
2171                 -> SimplM (SimplEnv, SimplCont, SimplCont)
2172 -- We are considering
2173 --     K[case _ of { p1 -> r1; ...; pn -> rn }] 
2174 -- where K is some enclosing continuation for the case
2175 -- Goal: split K into two pieces Kdup,Knodup so that
2176 --       a) Kdup can be duplicated
2177 --       b) Knodup[Kdup[e]] = K[e]
2178 -- The idea is that we'll transform thus:
2179 --          Knodup[ (case _ of { p1 -> Kdup[r1]; ...; pn -> Kdup[rn] }
2180 --
2181 -- We also return some extra bindings in SimplEnv (that scope over 
2182 -- the entire continuation)
2183
2184 prepareCaseCont env alts cont 
2185   | many_alts alts = mkDupableCont env cont 
2186   | otherwise      = return (env, cont, mkBoringStop)
2187   where
2188     many_alts :: [InAlt] -> Bool  -- True iff strictly > 1 non-bottom alternative
2189     many_alts []  = False         -- See Note [Bottom alternatives]
2190     many_alts [_] = False
2191     many_alts (alt:alts) 
2192       | is_bot_alt alt = many_alts alts   
2193       | otherwise      = not (all is_bot_alt alts)
2194   
2195     is_bot_alt (_,_,rhs) = exprIsBottom rhs
2196 \end{code}
2197
2198 Note [Bottom alternatives]
2199 ~~~~~~~~~~~~~~~~~~~~~~~~~~
2200 When we have
2201      case (case x of { A -> error .. ; B -> e; C -> error ..) 
2202        of alts
2203 then we can just duplicate those alts because the A and C cases
2204 will disappear immediately.  This is more direct than creating
2205 join points and inlining them away; and in some cases we would
2206 not even create the join points (see Note [Single-alternative case])
2207 and we would keep the case-of-case which is silly.  See Trac #4930.
2208
2209 \begin{code}
2210 mkDupableCont :: SimplEnv -> SimplCont
2211               -> SimplM (SimplEnv, SimplCont, SimplCont)
2212
2213 mkDupableCont env cont
2214   | contIsDupable cont
2215   = return (env, cont, mkBoringStop)
2216
2217 mkDupableCont _   (Stop {}) = panic "mkDupableCont"     -- Handled by previous eqn
2218
2219 mkDupableCont env (CoerceIt ty cont)
2220   = do  { (env', dup, nodup) <- mkDupableCont env cont
2221         ; return (env', CoerceIt ty dup, nodup) }
2222
2223 -- Duplicating ticks for now, not sure if this is good or not
2224 mkDupableCont env cont@(TickIt{})
2225   = return (env, mkBoringStop, cont)
2226
2227 mkDupableCont env cont@(StrictBind {})
2228   =  return (env, mkBoringStop, cont)
2229         -- See Note [Duplicating StrictBind]
2230
2231 mkDupableCont env (StrictArg info cci cont)
2232         -- See Note [Duplicating StrictArg]
2233   = do { (env', dup, nodup) <- mkDupableCont env cont
2234        ; (env'', args')     <- mapAccumLM (makeTrivial NotTopLevel) env' (ai_args info)
2235        ; return (env'', StrictArg (info { ai_args = args' }) cci dup, nodup) }
2236
2237 mkDupableCont env (ApplyTo _ arg se cont)
2238   =     -- e.g.         [...hole...] (...arg...)
2239         --      ==>
2240         --              let a = ...arg...
2241         --              in [...hole...] a
2242     do  { (env', dup_cont, nodup_cont) <- mkDupableCont env cont
2243         ; arg' <- simplExpr (se `setInScope` env') arg
2244         ; (env'', arg'') <- makeTrivial NotTopLevel env' arg'
2245         ; let app_cont = ApplyTo OkToDup arg'' (zapSubstEnv env'') dup_cont
2246         ; return (env'', app_cont, nodup_cont) }
2247
2248 mkDupableCont env cont@(Select _ case_bndr [(_, bs, _rhs)] _ _)
2249 --  See Note [Single-alternative case]
2250 --  | not (exprIsDupable rhs && contIsDupable case_cont)
2251 --  | not (isDeadBinder case_bndr)
2252   | all isDeadBinder bs  -- InIds
2253     && not (isUnLiftedType (idType case_bndr))
2254     -- Note [Single-alternative-unlifted]
2255   = return (env, mkBoringStop, cont)
2256
2257 mkDupableCont env (Select _ case_bndr alts se cont)
2258   =     -- e.g.         (case [...hole...] of { pi -> ei })
2259         --      ===>
2260         --              let ji = \xij -> ei
2261         --              in case [...hole...] of { pi -> ji xij }
2262     do  { tick (CaseOfCase case_bndr)
2263         ; (env', dup_cont, nodup_cont) <- prepareCaseCont env alts cont
2264                 -- NB: We call prepareCaseCont here.  If there is only one
2265                 -- alternative, then dup_cont may be big, but that's ok
2266                 -- becuase we push it into the single alternative, and then
2267                 -- use mkDupableAlt to turn that simplified alternative into
2268                 -- a join point if it's too big to duplicate.
2269                 -- And this is important: see Note [Fusing case continuations]
2270
2271         ; let alt_env = se `setInScope` env'
2272         ; (alt_env', case_bndr') <- simplBinder alt_env case_bndr
2273         ; alts' <- mapM (simplAlt alt_env' Nothing [] case_bndr' dup_cont) alts
2274         -- Safe to say that there are no handled-cons for the DEFAULT case
2275                 -- NB: simplBinder does not zap deadness occ-info, so
2276                 -- a dead case_bndr' will still advertise its deadness
2277                 -- This is really important because in
2278                 --      case e of b { (# p,q #) -> ... }
2279                 -- b is always dead, and indeed we are not allowed to bind b to (# p,q #),
2280                 -- which might happen if e was an explicit unboxed pair and b wasn't marked dead.
2281                 -- In the new alts we build, we have the new case binder, so it must retain
2282                 -- its deadness.
2283         -- NB: we don't use alt_env further; it has the substEnv for
2284         --     the alternatives, and we don't want that
2285
2286         ; (env'', alts'') <- mkDupableAlts env' case_bndr' alts'
2287         ; return (env'',  -- Note [Duplicated env]
2288                   Select OkToDup case_bndr' alts'' (zapSubstEnv env'') mkBoringStop,
2289                   nodup_cont) }
2290
2291
2292 mkDupableAlts :: SimplEnv -> OutId -> [InAlt]
2293               -> SimplM (SimplEnv, [InAlt])
2294 -- Absorbs the continuation into the new alternatives
2295
2296 mkDupableAlts env case_bndr' the_alts
2297   = go env the_alts
2298   where
2299     go env0 [] = return (env0, [])
2300     go env0 (alt:alts)
2301         = do { (env1, alt') <- mkDupableAlt env0 case_bndr' alt
2302              ; (env2, alts') <- go env1 alts
2303              ; return (env2, alt' : alts' ) }
2304
2305 mkDupableAlt :: SimplEnv -> OutId -> (AltCon, [CoreBndr], CoreExpr)
2306               -> SimplM (SimplEnv, (AltCon, [CoreBndr], CoreExpr))
2307 mkDupableAlt env case_bndr (con, bndrs', rhs')
2308   | exprIsDupable rhs'  -- Note [Small alternative rhs]
2309   = return (env, (con, bndrs', rhs'))
2310   | otherwise
2311   = do  { let rhs_ty'  = exprType rhs'
2312               scrut_ty = idType case_bndr
2313               case_bndr_w_unf   
2314                 = case con of 
2315                       DEFAULT    -> case_bndr                                   
2316                       DataAlt dc -> setIdUnfolding case_bndr unf
2317                           where
2318                                  -- See Note [Case binders and join points]
2319                              unf = mkInlineUnfolding Nothing rhs
2320                              rhs = mkConApp dc (map Type (tyConAppArgs scrut_ty)
2321                                                 ++ varsToCoreExprs bndrs')
2322
2323                       LitAlt {} -> WARN( True, ptext (sLit "mkDupableAlt")
2324                                                 <+> ppr case_bndr <+> ppr con )
2325                                    case_bndr
2326                            -- The case binder is alive but trivial, so why has 
2327                            -- it not been substituted away?
2328
2329               used_bndrs' | isDeadBinder case_bndr = filter abstract_over bndrs'
2330                           | otherwise              = bndrs' ++ [case_bndr_w_unf]
2331               
2332               abstract_over bndr
2333                   | isTyVar bndr = True -- Abstract over all type variables just in case
2334                   | otherwise    = not (isDeadBinder bndr)
2335                         -- The deadness info on the new Ids is preserved by simplBinders
2336
2337         ; (final_bndrs', final_args)    -- Note [Join point abstraction]
2338                 <- if (any isId used_bndrs')
2339                    then return (used_bndrs', varsToCoreExprs used_bndrs')
2340                     else do { rw_id <- newId (fsLit "w") realWorldStatePrimTy
2341                             ; return ([rw_id], [Var realWorldPrimId]) }
2342
2343         ; join_bndr <- newId (fsLit "$j") (mkPiTypes final_bndrs' rhs_ty')
2344                 -- Note [Funky mkPiTypes]
2345
2346         ; let   -- We make the lambdas into one-shot-lambdas.  The
2347                 -- join point is sure to be applied at most once, and doing so
2348                 -- prevents the body of the join point being floated out by
2349                 -- the full laziness pass
2350                 really_final_bndrs     = map one_shot final_bndrs'
2351                 one_shot v | isId v    = setOneShotLambda v
2352                            | otherwise = v
2353                 join_rhs   = mkLams really_final_bndrs rhs'
2354                 join_arity = exprArity join_rhs
2355                 join_call  = mkApps (Var join_bndr) final_args
2356
2357         ; env' <- addPolyBind NotTopLevel env (NonRec (join_bndr `setIdArity` join_arity) join_rhs)
2358         ; return (env', (con, bndrs', join_call)) }
2359                 -- See Note [Duplicated env]
2360 \end{code}
2361
2362 Note [Fusing case continuations]
2363 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2364 It's important to fuse two successive case continuations when the
2365 first has one alternative.  That's why we call prepareCaseCont here.
2366 Consider this, which arises from thunk splitting (see Note [Thunk
2367 splitting] in WorkWrap):
2368
2369       let
2370         x* = case (case v of {pn -> rn}) of 
2371                I# a -> I# a
2372       in body
2373
2374 The simplifier will find
2375     (Var v) with continuation  
2376             Select (pn -> rn) (
2377             Select [I# a -> I# a] (
2378             StrictBind body Stop
2379
2380 So we'll call mkDupableCont on 
2381    Select [I# a -> I# a] (StrictBind body Stop)
2382 There is just one alternative in the first Select, so we want to
2383 simplify the rhs (I# a) with continuation (StricgtBind body Stop)
2384 Supposing that body is big, we end up with
2385           let $j a = <let x = I# a in body> 
2386           in case v of { pn -> case rn of 
2387                                  I# a -> $j a }
2388 This is just what we want because the rn produces a box that
2389 the case rn cancels with.  
2390
2391 See Trac #4957 a fuller example.
2392
2393 Note [Case binders and join points]
2394 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2395 Consider this 
2396    case (case .. ) of c {
2397      I# c# -> ....c....
2398
2399 If we make a join point with c but not c# we get
2400   $j = \c -> ....c....
2401
2402 But if later inlining scrutines the c, thus
2403
2404   $j = \c -> ... case c of { I# y -> ... } ...
2405
2406 we won't see that 'c' has already been scrutinised.  This actually
2407 happens in the 'tabulate' function in wave4main, and makes a significant
2408 difference to allocation.
2409
2410 An alternative plan is this:
2411
2412    $j = \c# -> let c = I# c# in ...c....
2413
2414 but that is bad if 'c' is *not* later scrutinised.  
2415
2416 So instead we do both: we pass 'c' and 'c#' , and record in c's inlining
2417 (an InlineRule) that it's really I# c#, thus
2418    
2419    $j = \c# -> \c[=I# c#] -> ...c....
2420
2421 Absence analysis may later discard 'c'.
2422
2423 NB: take great care when doing strictness analysis; 
2424     see Note [Lamba-bound unfoldings] in DmdAnal.
2425
2426 Also note that we can still end up passing stuff that isn't used.  Before
2427 strictness analysis we have
2428    let $j x y c{=(x,y)} = (h c, ...)
2429    in ...
2430 After strictness analysis we see that h is strict, we end up with
2431    let $j x y c{=(x,y)} = ($wh x y, ...)
2432 and c is unused.
2433    
2434 Note [Duplicated env]
2435 ~~~~~~~~~~~~~~~~~~~~~
2436 Some of the alternatives are simplified, but have not been turned into a join point
2437 So they *must* have an zapped subst-env.  So we can't use completeNonRecX to
2438 bind the join point, because it might to do PostInlineUnconditionally, and
2439 we'd lose that when zapping the subst-env.  We could have a per-alt subst-env,
2440 but zapping it (as we do in mkDupableCont, the Select case) is safe, and
2441 at worst delays the join-point inlining.
2442
2443 Note [Small alternative rhs]
2444 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2445 It is worth checking for a small RHS because otherwise we
2446 get extra let bindings that may cause an extra iteration of the simplifier to
2447 inline back in place.  Quite often the rhs is just a variable or constructor.
2448 The Ord instance of Maybe in PrelMaybe.lhs, for example, took several extra
2449 iterations because the version with the let bindings looked big, and so wasn't
2450 inlined, but after the join points had been inlined it looked smaller, and so
2451 was inlined.
2452
2453 NB: we have to check the size of rhs', not rhs.
2454 Duplicating a small InAlt might invalidate occurrence information
2455 However, if it *is* dupable, we return the *un* simplified alternative,
2456 because otherwise we'd need to pair it up with an empty subst-env....
2457 but we only have one env shared between all the alts.
2458 (Remember we must zap the subst-env before re-simplifying something).
2459 Rather than do this we simply agree to re-simplify the original (small) thing later.
2460
2461 Note [Funky mkPiTypes]
2462 ~~~~~~~~~~~~~~~~~~~~~~
2463 Notice the funky mkPiTypes.  If the contructor has existentials
2464 it's possible that the join point will be abstracted over
2465 type varaibles as well as term variables.
2466  Example:  Suppose we have
2467         data T = forall t.  C [t]
2468  Then faced with
2469         case (case e of ...) of
2470             C t xs::[t] -> rhs
2471  We get the join point
2472         let j :: forall t. [t] -> ...
2473             j = /\t \xs::[t] -> rhs
2474         in
2475         case (case e of ...) of
2476             C t xs::[t] -> j t xs
2477
2478 Note [Join point abstaction]
2479 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2480 If we try to lift a primitive-typed something out
2481 for let-binding-purposes, we will *caseify* it (!),
2482 with potentially-disastrous strictness results.  So
2483 instead we turn it into a function: \v -> e
2484 where v::State# RealWorld#.  The value passed to this function
2485 is realworld#, which generates (almost) no code.
2486
2487 There's a slight infelicity here: we pass the overall
2488 case_bndr to all the join points if it's used in *any* RHS,
2489 because we don't know its usage in each RHS separately
2490
2491 We used to say "&& isUnLiftedType rhs_ty'" here, but now
2492 we make the join point into a function whenever used_bndrs'
2493 is empty.  This makes the join-point more CPR friendly.
2494 Consider:       let j = if .. then I# 3 else I# 4
2495                 in case .. of { A -> j; B -> j; C -> ... }
2496
2497 Now CPR doesn't w/w j because it's a thunk, so
2498 that means that the enclosing function can't w/w either,
2499 which is a lose.  Here's the example that happened in practice:
2500         kgmod :: Int -> Int -> Int
2501         kgmod x y = if x > 0 && y < 0 || x < 0 && y > 0
2502                     then 78
2503                     else 5
2504
2505 I have seen a case alternative like this:
2506         True -> \v -> ...
2507 It's a bit silly to add the realWorld dummy arg in this case, making
2508         $j = \s v -> ...
2509            True -> $j s
2510 (the \v alone is enough to make CPR happy) but I think it's rare
2511
2512 Note [Duplicating StrictArg]
2513 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2514 The original plan had (where E is a big argument)
2515 e.g.    f E [..hole..]
2516         ==>     let $j = \a -> f E a
2517                 in $j [..hole..]
2518
2519 But this is terrible! Here's an example:
2520         && E (case x of { T -> F; F -> T })
2521 Now, && is strict so we end up simplifying the case with
2522 an ArgOf continuation.  If we let-bind it, we get
2523         let $j = \v -> && E v
2524         in simplExpr (case x of { T -> F; F -> T })
2525                      (ArgOf (\r -> $j r)
2526 And after simplifying more we get
2527         let $j = \v -> && E v
2528         in case x of { T -> $j F; F -> $j T }
2529 Which is a Very Bad Thing
2530
2531 What we do now is this
2532         f E [..hole..]
2533         ==>     let a = E
2534                 in f a [..hole..]
2535 Now if the thing in the hole is a case expression (which is when
2536 we'll call mkDupableCont), we'll push the function call into the
2537 branches, which is what we want.  Now RULES for f may fire, and
2538 call-pattern specialisation.  Here's an example from Trac #3116
2539      go (n+1) (case l of
2540                  1  -> bs'
2541                  _  -> Chunk p fpc (o+1) (l-1) bs')
2542 If we can push the call for 'go' inside the case, we get
2543 call-pattern specialisation for 'go', which is *crucial* for 
2544 this program.
2545
2546 Here is the (&&) example: 
2547         && E (case x of { T -> F; F -> T })
2548   ==>   let a = E in 
2549         case x of { T -> && a F; F -> && a T }
2550 Much better!
2551
2552 Notice that 
2553   * Arguments to f *after* the strict one are handled by 
2554     the ApplyTo case of mkDupableCont.  Eg
2555         f [..hole..] E
2556
2557   * We can only do the let-binding of E because the function
2558     part of a StrictArg continuation is an explicit syntax
2559     tree.  In earlier versions we represented it as a function
2560     (CoreExpr -> CoreEpxr) which we couldn't take apart.
2561
2562 Do *not* duplicate StrictBind and StritArg continuations.  We gain
2563 nothing by propagating them into the expressions, and we do lose a
2564 lot.  
2565
2566 The desire not to duplicate is the entire reason that
2567 mkDupableCont returns a pair of continuations.
2568
2569 Note [Duplicating StrictBind]
2570 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2571 Unlike StrictArg, there doesn't seem anything to gain from
2572 duplicating a StrictBind continuation, so we don't.
2573
2574
2575 Note [Single-alternative cases]
2576 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2577 This case is just like the ArgOf case.  Here's an example:
2578         data T a = MkT !a
2579         ...(MkT (abs x))...
2580 Then we get
2581         case (case x of I# x' ->
2582               case x' <# 0# of
2583                 True  -> I# (negate# x')
2584                 False -> I# x') of y {
2585           DEFAULT -> MkT y
2586 Because the (case x) has only one alternative, we'll transform to
2587         case x of I# x' ->
2588         case (case x' <# 0# of
2589                 True  -> I# (negate# x')
2590                 False -> I# x') of y {
2591           DEFAULT -> MkT y
2592 But now we do *NOT* want to make a join point etc, giving
2593         case x of I# x' ->
2594         let $j = \y -> MkT y
2595         in case x' <# 0# of
2596                 True  -> $j (I# (negate# x'))
2597                 False -> $j (I# x')
2598 In this case the $j will inline again, but suppose there was a big
2599 strict computation enclosing the orginal call to MkT.  Then, it won't
2600 "see" the MkT any more, because it's big and won't get duplicated.
2601 And, what is worse, nothing was gained by the case-of-case transform.
2602
2603 So, in circumstances like these, we don't want to build join points
2604 and push the outer case into the branches of the inner one. Instead,
2605 don't duplicate the continuation. 
2606
2607 When should we use this strategy?  We should not use it on *every*
2608 single-alternative case:
2609   e.g.  case (case ....) of (a,b) -> (# a,b #)
2610 Here we must push the outer case into the inner one!
2611 Other choices:
2612
2613    * Match [(DEFAULT,_,_)], but in the common case of Int,
2614      the alternative-filling-in code turned the outer case into
2615                 case (...) of y { I# _ -> MkT y }
2616
2617    * Match on single alternative plus (not (isDeadBinder case_bndr))
2618      Rationale: pushing the case inwards won't eliminate the construction.
2619      But there's a risk of
2620                 case (...) of y { (a,b) -> let z=(a,b) in ... }
2621      Now y looks dead, but it'll come alive again.  Still, this
2622      seems like the best option at the moment.
2623
2624    * Match on single alternative plus (all (isDeadBinder bndrs))
2625      Rationale: this is essentially  seq.
2626
2627    * Match when the rhs is *not* duplicable, and hence would lead to a
2628      join point.  This catches the disaster-case above.  We can test
2629      the *un-simplified* rhs, which is fine.  It might get bigger or
2630      smaller after simplification; if it gets smaller, this case might
2631      fire next time round.  NB also that we must test contIsDupable
2632      case_cont *too, because case_cont might be big!
2633
2634      HOWEVER: I found that this version doesn't work well, because
2635      we can get         let x = case (...) of { small } in ...case x...
2636      When x is inlined into its full context, we find that it was a bad
2637      idea to have pushed the outer case inside the (...) case.
2638
2639 Note [Single-alternative-unlifted]
2640 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2641 Here's another single-alternative where we really want to do case-of-case:
2642
2643 data Mk1 = Mk1 Int# | Mk2 Int#
2644
2645 M1.f =
2646     \r [x_s74 y_s6X]
2647         case
2648             case y_s6X of tpl_s7m {
2649               M1.Mk1 ipv_s70 -> ipv_s70;
2650               M1.Mk2 ipv_s72 -> ipv_s72;
2651             }
2652         of
2653         wild_s7c
2654         { __DEFAULT ->
2655               case
2656                   case x_s74 of tpl_s7n {
2657                     M1.Mk1 ipv_s77 -> ipv_s77;
2658                     M1.Mk2 ipv_s79 -> ipv_s79;
2659                   }
2660               of
2661               wild1_s7b
2662               { __DEFAULT -> ==# [wild1_s7b wild_s7c];
2663               };
2664         };
2665
2666 So the outer case is doing *nothing at all*, other than serving as a
2667 join-point.  In this case we really want to do case-of-case and decide
2668 whether to use a real join point or just duplicate the continuation:
2669
2670     let $j s7c = case x of
2671                    Mk1 ipv77 -> (==) s7c ipv77
2672                    Mk1 ipv79 -> (==) s7c ipv79
2673     in
2674     case y of 
2675       Mk1 ipv70 -> $j ipv70
2676       Mk2 ipv72 -> $j ipv72
2677
2678 Hence: check whether the case binder's type is unlifted, because then
2679 the outer case is *not* a seq.