Doing the smart canonicalization only if we are not simplifying a Rule LHS.
[ghc.git] / compiler / typecheck / TcCanonical.lhs
1 \begin{code}
2 module TcCanonical(
3     mkCanonical, mkCanonicals, canWanteds, canGivens, canOccursCheck, canEq,
4  ) where
5
6 #include "HsVersions.h"
7
8 import BasicTypes 
9 import Type
10 import TcRnTypes
11
12 import TcType
13 import TcErrors
14 import Coercion
15 import Class
16 import TyCon
17 import TypeRep
18 import Name
19 import Var
20 import Outputable
21 import Control.Monad    ( when, zipWithM )
22 import MonadUtils
23 import Control.Applicative ( (<|>) )
24
25 import VarSet
26 import Bag
27
28 import HsBinds 
29
30 import Control.Monad  ( unless )
31 import TcSMonad  -- The TcS Monad 
32 \end{code}
33
34 Note [Canonicalisation]
35 ~~~~~~~~~~~~~~~~~~~~~~~
36 * Converts (Constraint f) _which_does_not_contain_proper_implications_ to CanonicalCts
37 * Unary: treats individual constraints one at a time
38 * Does not do any zonking
39 * Lives in TcS monad so that it can create new skolem variables
40
41
42 %************************************************************************
43 %*                                                                      *
44 %*        Flattening (eliminating all function symbols)                 *
45 %*                                                                      *
46 %************************************************************************
47
48 Note [Flattening]
49 ~~~~~~~~~~~~~~~~~~~~
50   flatten ty  ==>   (xi, cc)
51     where
52       xi has no type functions
53       cc = Auxiliary given (equality) constraints constraining
54            the fresh type variables in xi.  Evidence for these 
55            is always the identity coercion, because internally the
56            fresh flattening skolem variables are actually identified
57            with the types they have been generated to stand in for.
58
59 Note that it is flatten's job to flatten *every type function it sees*.
60 flatten is only called on *arguments* to type functions, by canEqGiven.
61
62 Recall that in comments we use alpha[flat = ty] to represent a
63 flattening skolem variable alpha which has been generated to stand in
64 for ty.
65
66 ----- Example of flattening a constraint: ------
67   flatten (List (F (G Int)))  ==>  (xi, cc)
68     where
69       xi  = List alpha
70       cc  = { G Int ~ beta[flat = G Int],
71               F beta ~ alpha[flat = F beta] }
72 Here
73   * alpha and beta are 'flattening skolem variables'.
74   * All the constraints in cc are 'given', and all their coercion terms 
75     are the identity.
76
77 NB: Flattening Skolems only occur in canonical constraints, which
78 are never zonked, so we don't need to worry about zonking doing
79 accidental unflattening.
80
81 Note that we prefer to leave type synonyms unexpanded when possible,
82 so when the flattener encounters one, it first asks whether its
83 transitive expansion contains any type function applications.  If so,
84 it expands the synonym and proceeds; if not, it simply returns the
85 unexpanded synonym.
86
87 TODO: caching the information about whether transitive synonym
88 expansions contain any type function applications would speed things
89 up a bit; right now we waste a lot of energy traversing the same types
90 multiple times.
91
92 \begin{code}
93 -- Flatten a bunch of types all at once.
94 flattenMany :: CtFlavor -> [Type] -> TcS ([Xi], [Coercion], CanonicalCts)
95 -- Coercions :: Xi ~ Type 
96 flattenMany ctxt tys 
97   = do { (xis, cos, cts_s) <- mapAndUnzip3M (flatten ctxt) tys
98        ; return (xis, cos, andCCans cts_s) }
99
100 -- Flatten a type to get rid of type function applications, returning
101 -- the new type-function-free type, and a collection of new equality
102 -- constraints.  See Note [Flattening] for more detail.
103 flatten :: CtFlavor -> TcType -> TcS (Xi, Coercion, CanonicalCts)
104 -- Postcondition: Coercion :: Xi ~ TcType 
105 flatten ctxt ty 
106   | Just ty' <- tcView ty
107   = do { (xi, co, ccs) <- flatten ctxt ty'
108         -- Preserve type synonyms if possible
109         -- We can tell if ty' is function-free by
110         -- whether there are any floated constraints
111        ; if isEmptyCCan ccs then
112              return (ty, ty, emptyCCan)  
113          else
114              return (xi, co, ccs) }
115
116 flatten _ v@(TyVarTy _)
117   = return (v, v, emptyCCan)
118
119 flatten ctxt (AppTy ty1 ty2)
120   = do { (xi1,co1,c1) <- flatten ctxt ty1
121        ; (xi2,co2,c2) <- flatten ctxt ty2
122        ; return (mkAppTy xi1 xi2, mkAppCoercion co1 co2, c1 `andCCan` c2) }
123
124 flatten ctxt (FunTy ty1 ty2)
125   = do { (xi1,co1,c1) <- flatten ctxt ty1
126        ; (xi2,co2,c2) <- flatten ctxt ty2
127        ; return (mkFunTy xi1 xi2, mkFunCoercion co1 co2, c1 `andCCan` c2) }
128
129 flatten fl (TyConApp tc tys)
130   -- For a normal type constructor or data family application, we just
131   -- recursively flatten the arguments.
132   | not (isSynFamilyTyCon tc)
133     = do { (xis,cos,ccs) <- flattenMany fl tys
134          ; return (mkTyConApp tc xis, mkTyConCoercion tc cos, ccs) }
135
136   -- Otherwise, it's a type function application, and we have to
137   -- flatten it away as well, and generate a new given equality constraint
138   -- between the application and a newly generated flattening skolem variable.
139   | otherwise 
140   = ASSERT( tyConArity tc <= length tys )       -- Type functions are saturated
141       do { (xis, cos, ccs) <- flattenMany fl tys
142          ; let (xi_args, xi_rest)  = splitAt (tyConArity tc) xis
143                (cos_args, cos_rest) = splitAt (tyConArity tc) cos 
144                  -- The type function might be *over* saturated
145                  -- in which case the remaining arguments should
146                  -- be dealt with by AppTys
147                fam_ty = mkTyConApp tc xi_args 
148                fam_co = fam_ty -- identity 
149
150          ; (ret_co, rhs_var, ct) <- 
151              if isGiven fl then
152                do { rhs_var <- newFlattenSkolemTy fam_ty
153                   ; cv <- newGivOrDerCoVar fam_ty rhs_var fam_co
154                   ; let ct = CFunEqCan { cc_id     = cv
155                                        , cc_flavor = fl -- Given
156                                        , cc_fun    = tc 
157                                        , cc_tyargs = xi_args 
158                                        , cc_rhs    = rhs_var }
159                   ; return $ (mkCoVarCoercion cv, rhs_var, ct) }
160              else -- Derived or Wanted: make a new *unification* flatten variable
161                do { rhs_var <- newFlexiTcSTy (typeKind fam_ty)
162                   ; cv <- newWantedCoVar fam_ty rhs_var
163                   ; let ct = CFunEqCan { cc_id = cv
164                                        , cc_flavor = mkWantedFlavor fl
165                                            -- Always Wanted, not Derived
166                                        , cc_fun = tc
167                                        , cc_tyargs = xi_args
168                                        , cc_rhs    = rhs_var }
169                   ; return $ (mkCoVarCoercion cv, rhs_var, ct) }
170
171          ; return ( foldl AppTy rhs_var xi_rest
172                   , foldl AppTy (mkSymCoercion ret_co 
173                                     `mkTransCoercion` mkTyConCoercion tc cos_args) cos_rest
174                   , ccs `extendCCans` ct) }
175
176
177 flatten ctxt (PredTy pred) 
178   = do { (pred', co, ccs) <- flattenPred ctxt pred
179        ; return (PredTy pred', co, ccs) }
180
181 flatten ctxt ty@(ForAllTy {})
182 -- We allow for-alls when, but only when, no type function
183 -- applications inside the forall involve the bound type variables
184 -- TODO: What if it is a (t1 ~ t2) => t3
185 --       Must revisit when the New Coercion API is here! 
186   = do { let (tvs, rho) = splitForAllTys ty
187        ; (rho', co, ccs) <- flatten ctxt rho
188        ; let bad_eqs  = filterBag is_bad ccs
189              is_bad c = tyVarsOfCanonical c `intersectsVarSet` tv_set
190              tv_set   = mkVarSet tvs
191        ; unless (isEmptyBag bad_eqs)
192                 (flattenForAllErrorTcS ctxt ty bad_eqs)
193        ; return (mkForAllTys tvs rho', mkForAllTys tvs co, ccs)  }
194
195 ---------------
196 flattenPred :: CtFlavor -> TcPredType -> TcS (TcPredType, Coercion, CanonicalCts)
197 flattenPred ctxt (ClassP cls tys)
198   = do { (tys', cos, ccs) <- flattenMany ctxt tys
199        ; return (ClassP cls tys', mkClassPPredCo cls cos, ccs) }
200 flattenPred ctxt (IParam nm ty)
201   = do { (ty', co, ccs) <- flatten ctxt ty
202        ; return (IParam nm ty', mkIParamPredCo nm co, ccs) }
203 -- TODO: Handling of coercions between EqPreds must be revisited once the New Coercion API is ready!
204 flattenPred ctxt (EqPred ty1 ty2)
205   = do { (ty1', co1, ccs1) <- flatten ctxt ty1
206        ; (ty2', co2, ccs2) <- flatten ctxt ty2
207        ; return (EqPred ty1' ty2', mkEqPredCo co1 co2, ccs1 `andCCan` ccs2) }
208
209 \end{code}
210
211 %************************************************************************
212 %*                                                                      *
213 %*                Canonicalising given constraints                      *
214 %*                                                                      *
215 %************************************************************************
216
217 \begin{code}
218 canWanteds :: [WantedEvVar] -> TcS CanonicalCts 
219 canWanteds = fmap andCCans . mapM (\(WantedEvVar ev loc) -> mkCanonical (Wanted loc) ev)
220
221 canGivens :: GivenLoc -> [EvVar] -> TcS CanonicalCts
222 canGivens loc givens = do { ccs <- mapM (mkCanonical (Given loc)) givens
223                           ; return (andCCans ccs) }
224
225 mkCanonicals :: CtFlavor -> [EvVar] -> TcS CanonicalCts 
226 mkCanonicals fl vs = fmap andCCans (mapM (mkCanonical fl) vs)
227
228 mkCanonical :: CtFlavor -> EvVar -> TcS CanonicalCts 
229 mkCanonical fl ev = case evVarPred ev of 
230                         ClassP clas tys -> canClass fl ev clas tys 
231                         IParam ip ty    -> canIP    fl ev ip ty
232                         EqPred ty1 ty2  -> canEq    fl ev ty1 ty2 
233                          
234
235 canClass :: CtFlavor -> EvVar -> Class -> [TcType] -> TcS CanonicalCts 
236 canClass fl v cn tys 
237   = do { (xis,cos,ccs) <- flattenMany fl tys  -- cos :: xis ~ tys
238        ; let no_flattening_happened = isEmptyCCan ccs
239              dict_co = mkTyConCoercion (classTyCon cn) cos
240        ; v_new <- if no_flattening_happened then return v
241                   else if isGiven fl        then return v
242                          -- The cos are all identities if fl=Given,
243                          -- hence nothing to do
244                   else do { v' <- newDictVar cn xis  -- D xis
245                           ; if isWanted fl
246                             then setDictBind v  (EvCast v' dict_co)
247                             else setDictBind v' (EvCast v (mkSymCoercion dict_co))
248                           ; return v' }
249
250        -- Add the superclasses of this one here, See Note [Adding superclasses]. 
251        -- But only if we are not simplifying the LHS of a rule. 
252        ; sctx <- getTcSContext
253        ; sc_cts <- if simplEqsOnly sctx then return emptyCCan 
254                    else newSCWorkFromFlavored v_new fl cn xis
255
256        ; return (sc_cts `andCCan` ccs `extendCCans` CDictCan { cc_id     = v_new
257                                                              , cc_flavor = fl
258                                                              , cc_class  = cn 
259                                                              , cc_tyargs = xis }) }
260
261 \end{code}
262
263 Note [Adding superclasses]
264 ~~~~~~~~~~~~~~~~~~~~~~~~~~ 
265 Since dictionaries are canonicalized only once in their lifetime, the
266 place to add their superclasses is canonicalisation (The alternative
267 would be to do it during constraint solving, but we'd have to be
268 extremely careful to not repeatedly introduced the same superclass in
269 our worklist). Here is what we do:
270
271 For Givens: 
272        We add all their superclasses as Givens. 
273
274 For Wanteds: 
275        Generally speaking, we want to be able to add derived
276        superclasses of unsolved wanteds, and wanteds that have been
277        partially being solved via an instance. This is important to be
278        able to simplify the inferred constraints more (and to allow
279        for recursive dictionaries, less importantly).
280
281        Example: Inferred wanted constraint is (Eq a, Ord a), but we'd
282        only like to quantify over Ord a, hence we would like to be
283        able to add the superclass of Ord a as Derived and use it to
284        solve the wanted Eq a.
285
286 For Deriveds: 
287        Deriveds either arise as wanteds that have been partially
288        solved, or as superclasses of other wanteds or deriveds. Hence,
289        their superclasses must be already there so we must do nothing
290        at al.
291
292        DV: In fact, it is probably true that the canonicaliser is
293           *never* asked to canonicalise Derived dictionaries
294
295 There is one disadvantage to this. Suppose the wanted constraints are
296 (Num a, Num a).  Then we'll add all the superclasses of both during
297 canonicalisation, only to eliminate them later when they are
298 interacted.  That seems like a waste of work.  Still, it's simple.
299
300 Here's an example that demonstrates why we chose to NOT add
301 superclasses during simplification: [Comes from ticket #4497]
302
303    class Num (RealOf t) => Normed t
304    type family RealOf x
305
306 Assume the generated wanted constraint is: 
307    RealOf e ~ e, Normed e 
308 If we were to be adding the superclasses during simplification we'd get: 
309    Num uf, Normed e, RealOf e ~ e, RealOf e ~ uf 
310 ==> 
311    e ~ uf, Num uf, Normed e, RealOf e ~ e 
312 ==> [Spontaneous solve] 
313    Num uf, Normed uf, RealOf uf ~ uf 
314
315 While looks exactly like our original constraint. If we add the superclass again we'd loop. 
316 By adding superclasses definitely only once, during canonicalisation, this situation can't 
317 happen.
318
319 \begin{code}
320 newSCWorkFromFlavored :: EvVar -> CtFlavor -> Class -> [Xi] -> TcS CanonicalCts
321 -- Returns superclasses, see Note [Adding superclasses]
322 newSCWorkFromFlavored ev orig_flavor cls xis 
323   = do { let (tyvars, sc_theta, _, _) = classBigSig cls 
324              sc_theta1 = substTheta (zipTopTvSubst tyvars xis) sc_theta
325        ; sc_vars <- zipWithM inst_one sc_theta1 [0..]
326        ; mkCanonicals flavor sc_vars }
327              -- NB: Since there is a call to mkCanonicals,
328              -- this will add *recursively* all superclasses
329   where
330     inst_one pred n = newGivOrDerEvVar pred (EvSuperClass ev n)
331     flavor = case orig_flavor of 
332                Given loc  -> Given loc
333                Wanted loc -> Derived loc DerSC
334                Derived {} -> orig_flavor
335                    -- NB: the non-immediate superclasses will show up as
336                    --     Derived, and we want their superclasses too!
337
338 canIP :: CtFlavor -> EvVar -> IPName Name -> TcType -> TcS CanonicalCts
339 -- See Note [Canonical implicit parameter constraints] to see why we don't 
340 -- immediately canonicalize (flatten) IP constraints. 
341 canIP fl v nm ty 
342   = return $ singleCCan $ CIPCan { cc_id = v
343                                  , cc_flavor = fl
344                                  , cc_ip_nm = nm
345                                  , cc_ip_ty = ty } 
346
347 -----------------
348 canEq :: CtFlavor -> EvVar -> Type -> Type -> TcS CanonicalCts 
349 canEq fl cv ty1 ty2 
350   | tcEqType ty1 ty2    -- Dealing with equality here avoids
351                         -- later spurious occurs checks for a~a
352   = do { when (isWanted fl) (setWantedCoBind cv ty1)
353        ; return emptyCCan }
354
355 -- If one side is a variable, orient and flatten, 
356 -- WITHOUT expanding type synonyms, so that we tend to 
357 -- substitute a ~ Age rather than a ~ Int when @type Age = Int@
358 canEq fl cv ty1@(TyVarTy {}) ty2 
359   = do { untch <- getUntouchables 
360        ; canEqLeaf untch fl cv (classify ty1) (classify ty2) }
361 canEq fl cv ty1 ty2@(TyVarTy {}) 
362   = do { untch <- getUntouchables 
363        ; canEqLeaf untch fl cv (classify ty1) (classify ty2) }
364       -- NB: don't use VarCls directly because tv1 or tv2 may be scolems!
365
366 canEq fl cv (TyConApp fn tys) ty2 
367   | isSynFamilyTyCon fn, length tys == tyConArity fn
368   = do { untch <- getUntouchables 
369        ; canEqLeaf untch fl cv (FunCls fn tys) (classify ty2) }
370 canEq fl cv ty1 (TyConApp fn tys)
371   | isSynFamilyTyCon fn, length tys == tyConArity fn
372   = do { untch <- getUntouchables 
373        ; canEqLeaf untch fl cv (classify ty1) (FunCls fn tys) }
374
375 canEq fl cv s1 s2
376   | Just (t1a,t1b,t1c) <- splitCoPredTy_maybe s1, 
377     Just (t2a,t2b,t2c) <- splitCoPredTy_maybe s2
378   = do { (v1,v2,v3) <- if isWanted fl then 
379                          do { v1 <- newWantedCoVar t1a t2a
380                             ; v2 <- newWantedCoVar t1b t2b 
381                             ; v3 <- newWantedCoVar t1c t2c 
382                             ; let res_co = mkCoPredCo (mkCoVarCoercion v1) 
383                                                       (mkCoVarCoercion v2) (mkCoVarCoercion v3)
384                             ; setWantedCoBind cv res_co
385                             ; return (v1,v2,v3) }
386                        else let co_orig = mkCoVarCoercion cv 
387                                 coa = mkCsel1Coercion co_orig
388                                 cob = mkCsel2Coercion co_orig
389                                 coc = mkCselRCoercion co_orig
390                             in do { v1 <- newGivOrDerCoVar t1a t2a coa
391                                   ; v2 <- newGivOrDerCoVar t1b t2b cob
392                                   ; v3 <- newGivOrDerCoVar t1c t2c coc 
393                                   ; return (v1,v2,v3) }
394        ; cc1 <- canEq fl v1 t1a t2a 
395        ; cc2 <- canEq fl v2 t1b t2b 
396        ; cc3 <- canEq fl v3 t1c t2c 
397        ; return (cc1 `andCCan` cc2 `andCCan` cc3) }
398
399
400 -- Split up an equality between function types into two equalities.
401 canEq fl cv (FunTy s1 t1) (FunTy s2 t2)
402   = do { (argv, resv) <- 
403              if isWanted fl then 
404                  do { argv <- newWantedCoVar s1 s2 
405                     ; resv <- newWantedCoVar t1 t2 
406                     ; setWantedCoBind cv $ 
407                       mkFunCoercion (mkCoVarCoercion argv) (mkCoVarCoercion resv) 
408                     ; return (argv,resv) } 
409              else let [arg,res] = decomposeCo 2 (mkCoVarCoercion cv) 
410                   in do { argv <- newGivOrDerCoVar s1 s2 arg 
411                         ; resv <- newGivOrDerCoVar t1 t2 res
412                         ; return (argv,resv) } 
413        ; cc1 <- canEq fl argv s1 s2 -- inherit original kinds and locations
414        ; cc2 <- canEq fl resv t1 t2
415        ; return (cc1 `andCCan` cc2) }
416
417 canEq fl cv (PredTy (IParam n1 t1)) (PredTy (IParam n2 t2))
418   | n1 == n2
419   = if isWanted fl then 
420         do { v <- newWantedCoVar t1 t2 
421            ; setWantedCoBind cv $ mkIParamPredCo n1 (mkCoVarCoercion cv)
422            ; canEq fl v t1 t2 } 
423     else return emptyCCan -- DV: How to decompose given IP coercions? 
424
425 canEq fl cv (PredTy (ClassP c1 tys1)) (PredTy (ClassP c2 tys2))
426   | c1 == c2
427   = if isWanted fl then 
428        do { vs <- zipWithM newWantedCoVar tys1 tys2 
429           ; setWantedCoBind cv $ mkClassPPredCo c1 (map mkCoVarCoercion vs) 
430           ; andCCans <$> zipWith3M (canEq fl) vs tys1 tys2
431           }
432     else return emptyCCan 
433   -- How to decompose given dictionary (and implicit parameter) coercions? 
434   -- You may think that the following is right: 
435   --    let cos = decomposeCo (length tys1) (mkCoVarCoercion cv) 
436   --    in  zipWith3M newGivOrDerCoVar tys1 tys2 cos
437   -- But this assumes that the coercion is a type constructor-based 
438   -- coercion, and not a PredTy (ClassP cn cos) coercion. So we chose
439   -- to not decompose these coercions. We have to get back to this 
440   -- when we clean up the Coercion API.
441
442 canEq fl cv (TyConApp tc1 tys1) (TyConApp tc2 tys2)
443   | isAlgTyCon tc1 && isAlgTyCon tc2
444   , tc1 == tc2
445   , length tys1 == length tys2
446   = -- Generate equalities for each of the corresponding arguments
447     do { argsv <- if isWanted fl then
448                     do { argsv <- zipWithM newWantedCoVar tys1 tys2
449                             ; setWantedCoBind cv $ mkTyConCoercion tc1 (map mkCoVarCoercion argsv)
450                             ; return argsv } 
451                   else 
452                     let cos = decomposeCo (length tys1) (mkCoVarCoercion cv) 
453                     in zipWith3M newGivOrDerCoVar tys1 tys2 cos
454        ; andCCans <$> zipWith3M (canEq fl) argsv tys1 tys2 }
455
456 -- See Note [Equality between type applications]
457 --     Note [Care with type applications] in TcUnify
458 canEq fl cv ty1 ty2
459   | Just (s1,t1) <- tcSplitAppTy_maybe ty1
460   , Just (s2,t2) <- tcSplitAppTy_maybe ty2
461     = do { (cv1,cv2) <- 
462              if isWanted fl 
463              then do { cv1 <- newWantedCoVar s1 s2 
464                      ; cv2 <- newWantedCoVar t1 t2 
465                      ; setWantedCoBind cv $ 
466                        mkAppCoercion (mkCoVarCoercion cv1) (mkCoVarCoercion cv2) 
467                      ; return (cv1,cv2) } 
468              else let co1 = mkLeftCoercion  $ mkCoVarCoercion cv 
469                       co2 = mkRightCoercion $ mkCoVarCoercion cv
470                   in do { cv1 <- newGivOrDerCoVar s1 s2 co1 
471                         ; cv2 <- newGivOrDerCoVar t1 t2 co2 
472                         ; return (cv1,cv2) } 
473          ; cc1 <- canEq fl cv1 s1 s2 
474          ; cc2 <- canEq fl cv2 t1 t2 
475          ; return (cc1 `andCCan` cc2) } 
476
477 canEq fl _ s1@(ForAllTy {}) s2@(ForAllTy {})  
478  | tcIsForAllTy s1, tcIsForAllTy s2, 
479    Wanted {} <- fl 
480  = canEqFailure fl s1 s2
481  | otherwise
482  = do { traceTcS "Ommitting decomposition of given polytype equality" (pprEq s1 s2)
483       ; return emptyCCan }
484
485 -- Finally expand any type synonym applications.
486 canEq fl cv ty1 ty2 | Just ty1' <- tcView ty1 = canEq fl cv ty1' ty2
487 canEq fl cv ty1 ty2 | Just ty2' <- tcView ty2 = canEq fl cv ty1 ty2'
488 canEq fl _  ty1 ty2                           = canEqFailure fl ty1 ty2
489
490 canEqFailure :: CtFlavor -> Type -> Type -> TcS CanonicalCts
491 canEqFailure fl ty1 ty2
492   = do { addErrorTcS MisMatchError fl ty1 ty2
493        ; return emptyCCan }
494 \end{code}
495
496 Note [Equality between type applications]
497 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
498 If we see an equality of the form s1 t1 ~ s2 t2 we can always split
499 it up into s1 ~ s2 /\ t1 ~ t2, since s1 and s2 can't be type
500 functions (type functions use the TyConApp constructor, which never
501 shows up as the LHS of an AppTy).  Other than type functions, types
502 in Haskell are always 
503
504   (1) generative: a b ~ c d implies a ~ c, since different type
505       constructors always generate distinct types
506
507   (2) injective: a b ~ a d implies b ~ d; we never generate the
508       same type from different type arguments.
509
510
511 Note [Canonical ordering for equality constraints]
512 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
513 Implemented as (<+=) below:
514
515   - Type function applications always come before anything else.  
516   - Variables always come before non-variables (other than type
517       function applications).
518
519 Note that we don't need to unfold type synonyms on the RHS to check
520 the ordering; that is, in the rules above it's OK to consider only
521 whether something is *syntactically* a type function application or
522 not.  To illustrate why this is OK, suppose we have an equality of the
523 form 'tv ~ S a b c', where S is a type synonym which expands to a
524 top-level application of the type function F, something like
525
526   type S a b c = F d e
527
528 Then to canonicalize 'tv ~ S a b c' we flatten the RHS, and since S's
529 expansion contains type function applications the flattener will do
530 the expansion and then generate a skolem variable for the type
531 function application, so we end up with something like this:
532
533   tv ~ x
534   F d e ~ x
535
536 where x is the skolem variable.  This is one extra equation than
537 absolutely necessary (we could have gotten away with just 'F d e ~ tv'
538 if we had noticed that S expanded to a top-level type function
539 application and flipped it around in the first place) but this way
540 keeps the code simpler.
541
542 Unlike the OutsideIn(X) draft of May 7, 2010, we do not care about the
543 ordering of tv ~ tv constraints.  There are several reasons why we
544 might:
545
546   (1) In order to be able to extract a substitution that doesn't
547       mention untouchable variables after we are done solving, we might
548       prefer to put touchable variables on the left. However, in and
549       of itself this isn't necessary; we can always re-orient equality
550       constraints at the end if necessary when extracting a substitution.
551
552   (2) To ensure termination we might think it necessary to put
553       variables in lexicographic order. However, this isn't actually 
554       necessary as outlined below.
555
556 While building up an inert set of canonical constraints, we maintain
557 the invariant that the equality constraints in the inert set form an
558 acyclic rewrite system when viewed as L-R rewrite rules.  Moreover,
559 the given constraints form an idempotent substitution (i.e. none of
560 the variables on the LHS occur in any of the RHS's, and type functions
561 never show up in the RHS at all), the wanted constraints also form an
562 idempotent substitution, and finally the LHS of a given constraint
563 never shows up on the RHS of a wanted constraint.  There may, however,
564 be a wanted LHS that shows up in a given RHS, since we do not rewrite
565 given constraints with wanted constraints.
566
567 Suppose we have an inert constraint set
568
569
570   tg_1 ~ xig_1         -- givens
571   tg_2 ~ xig_2
572   ...
573   tw_1 ~ xiw_1         -- wanteds
574   tw_2 ~ xiw_2
575   ...
576
577 where each t_i can be either a type variable or a type function
578 application. Now suppose we take a new canonical equality constraint,
579 t' ~ xi' (note among other things this means t' does not occur in xi')
580 and try to react it with the existing inert set.  We show by induction
581 on the number of t_i which occur in t' ~ xi' that this process will
582 terminate.
583
584 There are several ways t' ~ xi' could react with an existing constraint:
585
586 TODO: finish this proof.  The below was for the case where the entire
587 inert set is an idempotent subustitution...
588
589 (b) We could have t' = t_j for some j.  Then we obtain the new
590     equality xi_j ~ xi'; note that neither xi_j or xi' contain t_j.  We
591     now canonicalize the new equality, which may involve decomposing it
592     into several canonical equalities, and recurse on these.  However,
593     none of the new equalities will contain t_j, so they have fewer
594     occurrences of the t_i than the original equation.
595
596 (a) We could have t_j occurring in xi' for some j, with t' /=
597     t_j. Then we substitute xi_j for t_j in xi' and continue.  However,
598     since none of the t_i occur in xi_j, we have decreased the
599     number of t_i that occur in xi', since we eliminated t_j and did not
600     introduce any new ones.
601
602 \begin{code}
603 data TypeClassifier 
604   = FskCls TcTyVar      -- ^ Flatten skolem 
605   | VarCls TcTyVar      -- ^ Non-flatten-skolem variable 
606   | FunCls TyCon [Type] -- ^ Type function, exactly saturated
607   | OtherCls TcType     -- ^ Neither of the above
608
609 unClassify :: TypeClassifier -> TcType
610 unClassify (VarCls tv)      = TyVarTy tv
611 unClassify (FskCls tv) = TyVarTy tv 
612 unClassify (FunCls fn tys)  = TyConApp fn tys
613 unClassify (OtherCls ty)    = ty
614
615 classify :: TcType -> TypeClassifier
616
617 classify (TyVarTy tv) 
618   | isTcTyVar tv, 
619     FlatSkol {} <- tcTyVarDetails tv = FskCls tv
620   | otherwise                        = VarCls tv
621 classify (TyConApp tc tys) | isSynFamilyTyCon tc
622                            , tyConArity tc == length tys
623                            = FunCls tc tys
624 classify ty                | Just ty' <- tcView ty
625                            = case classify ty' of
626                                OtherCls {} -> OtherCls ty
627                                var_or_fn   -> var_or_fn
628                            | otherwise 
629                            = OtherCls ty
630
631 -- See note [Canonical ordering for equality constraints].
632 reOrient :: TcsUntouchables -> TypeClassifier -> TypeClassifier -> Bool 
633 -- (t1 `reOrient` t2) responds True 
634 --   iff we should flip to (t2~t1)
635 -- We try to say False if possible, to minimise evidence generation
636 --
637 -- Postcondition: After re-orienting, first arg is not OTherCls
638 reOrient _untch (OtherCls {}) (FunCls {})   = True
639 reOrient _untch (OtherCls {}) (FskCls {})   = True
640 reOrient _untch (OtherCls {}) (VarCls {})   = True
641 reOrient _untch (OtherCls {}) (OtherCls {}) = panic "reOrient"  -- One must be Var/Fun
642
643 reOrient _untch (FunCls {})   (VarCls {})    = False
644   -- See Note [No touchables as FunEq RHS] in TcSMonad
645 reOrient _untch (FunCls {}) _                = False             -- Fun/Other on rhs
646
647 reOrient _untch (VarCls {}) (FunCls {})      = True 
648
649 reOrient _untch (VarCls {}) (FskCls {})      = False
650
651 reOrient _untch (VarCls {})  (OtherCls {})   = False
652 reOrient _untch (VarCls tv1)  (VarCls tv2)  
653   | isMetaTyVar tv2 && not (isMetaTyVar tv1) = True 
654   | otherwise                                = False 
655   -- Just for efficiency, see CTyEqCan invariants 
656
657 reOrient _untch (FskCls {}) (VarCls tv2)     = isMetaTyVar tv2 
658   -- Just for efficiency, see CTyEqCan invariants
659
660 reOrient _untch (FskCls {}) (FskCls {})     = False
661 reOrient _untch (FskCls {}) (FunCls {})     = True 
662 reOrient _untch (FskCls {}) (OtherCls {})   = False 
663
664 ------------------
665 canEqLeaf :: TcsUntouchables 
666           -> CtFlavor -> CoVar 
667           -> TypeClassifier -> TypeClassifier -> TcS CanonicalCts 
668 -- Canonicalizing "leaf" equality constraints which cannot be
669 -- decomposed further (ie one of the types is a variable or
670 -- saturated type function application).  
671
672   -- Preconditions: 
673   --    * one of the two arguments is not OtherCls
674   --    * the two types are not equal (looking through synonyms)
675 canEqLeaf untch fl cv cls1 cls2 
676   | cls1 `re_orient` cls2
677   = do { cv' <- if isWanted fl 
678                 then do { cv' <- newWantedCoVar s2 s1 
679                         ; setWantedCoBind cv $ mkSymCoercion (mkCoVarCoercion cv') 
680                         ; return cv' } 
681                 else newGivOrDerCoVar s2 s1 (mkSymCoercion (mkCoVarCoercion cv)) 
682        ; canEqLeafOriented fl cv' cls2 s1 }
683
684   | otherwise
685   = canEqLeafOriented fl cv cls1 s2
686   where
687     re_orient = reOrient untch 
688     s1 = unClassify cls1  
689     s2 = unClassify cls2  
690
691 ------------------
692 canEqLeafOriented :: CtFlavor -> CoVar 
693                   -> TypeClassifier -> TcType -> TcS CanonicalCts 
694 -- First argument is not OtherCls
695 canEqLeafOriented fl cv cls1@(FunCls fn tys1) s2         -- cv : F tys1
696   | let k1 = kindAppResult (tyConKind fn) tys1,
697     let k2 = typeKind s2, 
698     isGiven fl && not (k1 `compatKind` k2) -- Establish the kind invariant for CFunEqCan
699   = addErrorTcS KindError fl (unClassify cls1) s2 >> return emptyCCan
700     -- Eagerly fails, see Note [Kind errors] in TcInteract
701
702   | otherwise 
703   = ASSERT2( isSynFamilyTyCon fn, ppr (unClassify cls1) )
704     do { (xis1,cos1,ccs1) <- flattenMany fl tys1 -- Flatten type function arguments
705                                                  -- cos1 :: xis1 ~ tys1
706        ; (xi2, co2, ccs2) <- flatten fl s2       -- Flatten entire RHS
707                                                  -- co2  :: xi2 ~ s2
708        ; let ccs = ccs1 `andCCan` ccs2
709              no_flattening_happened = isEmptyCCan ccs
710        ; cv_new <- if no_flattening_happened then return cv
711                    else if isGiven fl        then return cv
712                    else do { cv' <- newWantedCoVar (unClassify (FunCls fn xis1)) xi2
713                                  -- cv' : F xis ~ xi2
714                            ; let -- fun_co :: F xis1 ~ F tys1
715                                  fun_co = mkTyConCoercion fn cos1
716                                  -- want_co :: F tys1 ~ s2
717                                  want_co = mkSymCoercion fun_co
718                                            `mkTransCoercion` mkCoVarCoercion cv'
719                                            `mkTransCoercion` co2
720                                  -- der_co :: F xis1 ~ xi2
721                                  der_co = fun_co
722                                           `mkTransCoercion` mkCoVarCoercion cv
723                                           `mkTransCoercion` mkSymCoercion co2
724                            ; if isWanted fl
725                              then setWantedCoBind cv  want_co
726                              else setWantedCoBind cv' der_co
727                            ; return cv' }
728
729        ; let final_cc = CFunEqCan { cc_id     = cv_new
730                                   , cc_flavor = fl
731                                   , cc_fun    = fn
732                                   , cc_tyargs = xis1 
733                                   , cc_rhs    = xi2 }
734        ; return $ ccs `extendCCans` final_cc }
735
736 -- Otherwise, we have a variable on the left, so call canEqLeafTyVarLeft
737 canEqLeafOriented fl cv (FskCls tv) s2 
738   = canEqLeafTyVarLeft fl cv tv s2 
739 canEqLeafOriented fl cv (VarCls tv) s2 
740   = canEqLeafTyVarLeft fl cv tv s2 
741 canEqLeafOriented _ cv (OtherCls ty1) ty2 
742   = pprPanic "canEqLeaf" (ppr cv $$ ppr ty1 $$ ppr ty2)
743
744 canEqLeafTyVarLeft :: CtFlavor -> CoVar -> TcTyVar -> TcType -> TcS CanonicalCts
745 -- Establish invariants of CTyEqCans 
746 canEqLeafTyVarLeft fl cv tv s2       -- cv : tv ~ s2
747   | isGiven fl && not (k1 `compatKind` k2) -- Establish the kind invariant for CTyEqCan
748   = addErrorTcS KindError fl (mkTyVarTy tv) s2 >> return emptyCCan
749        -- Eagerly fails, see Note [Kind errors] in TcInteract
750   | otherwise
751   = do { (xi2, co, ccs2) <- flatten fl s2  -- Flatten RHS   co : xi2 ~ s2
752        ; mxi2' <- canOccursCheck fl tv xi2 -- Do an occurs check, and return a possibly
753                                            -- unfolded version of the RHS, if we had to 
754                                            -- unfold any type synonyms to get rid of tv.
755        ; case mxi2' of {
756            Nothing   -> addErrorTcS OccCheckError fl (mkTyVarTy tv) xi2 >> return emptyCCan ;
757            Just xi2' ->
758     do { let no_flattening_happened = isEmptyCCan ccs2
759        ; cv_new <- if no_flattening_happened then return cv
760                    else if isGiven fl        then return cv
761                    else do { cv' <- newWantedCoVar (mkTyVarTy tv) xi2'  -- cv' : tv ~ xi2
762                            ; if isWanted fl
763                              then setWantedCoBind cv  (mkCoVarCoercion cv' `mkTransCoercion` co)
764                              else setWantedCoBind cv' (mkCoVarCoercion cv  `mkTransCoercion`
765                                                        mkSymCoercion co)
766                            ; return cv' }
767
768        ; return $ ccs2 `extendCCans` CTyEqCan { cc_id     = cv_new
769                                               , cc_flavor = fl
770                                               , cc_tyvar  = tv
771                                               , cc_rhs    = xi2' } } } }
772   where
773     k1 = tyVarKind tv
774     k2 = typeKind s2
775
776 -- See Note [Type synonyms and canonicalization].
777 -- Check whether the given variable occurs in the given type.  We may
778 -- have needed to do some type synonym unfolding in order to get rid
779 -- of the variable, so we also return the unfolded version of the
780 -- type, which is guaranteed to be syntactically free of the given
781 -- type variable.  If the type is already syntactically free of the
782 -- variable, then the same type is returned.
783 --
784 -- Precondition: the two types are not equal (looking though synonyms)
785 canOccursCheck :: CtFlavor -> TcTyVar -> Xi -> TcS (Maybe Xi)
786 canOccursCheck _gw tv xi = return (expandAway tv xi)
787 \end{code}
788
789 @expandAway tv xi@ expands synonyms in xi just enough to get rid of
790 occurrences of tv, if that is possible; otherwise, it returns Nothing.
791 For example, suppose we have
792   type F a b = [a]
793 Then
794   expandAway b (F Int b) = Just [Int]
795 but
796   expandAway a (F a Int) = Nothing
797
798 We don't promise to do the absolute minimum amount of expanding
799 necessary, but we try not to do expansions we don't need to.  We
800 prefer doing inner expansions first.  For example,
801   type F a b = (a, Int, a, [a])
802   type G b   = Char
803 We have
804   expandAway b (F (G b)) = F Char
805 even though we could also expand F to get rid of b.
806
807 \begin{code}
808 expandAway :: TcTyVar -> Xi -> Maybe Xi
809 expandAway tv t@(TyVarTy tv') 
810   | tv == tv' = Nothing
811   | otherwise = Just t
812 expandAway tv xi
813   | not (tv `elemVarSet` tyVarsOfType xi) = Just xi
814 expandAway tv (AppTy ty1 ty2) 
815   = do { ty1' <- expandAway tv ty1
816        ; ty2' <- expandAway tv ty2 
817        ; return (mkAppTy ty1' ty2') }
818 -- mkAppTy <$> expandAway tv ty1 <*> expandAway tv ty2
819 expandAway tv (FunTy ty1 ty2)
820   = do { ty1' <- expandAway tv ty1 
821        ; ty2' <- expandAway tv ty2 
822        ; return (mkFunTy ty1' ty2') } 
823 -- mkFunTy <$> expandAway tv ty1 <*> expandAway tv ty2
824 expandAway tv ty@(ForAllTy {}) 
825   = let (tvs,rho) = splitForAllTys ty
826         tvs_knds  = map tyVarKind tvs 
827     in if tv `elemVarSet` tyVarsOfTypes tvs_knds then 
828        -- Can't expand away the kinds unless we create 
829        -- fresh variables which we don't want to do at this point.
830            Nothing 
831        else do { rho' <- expandAway tv rho
832                ; return (mkForAllTys tvs rho') }
833 expandAway tv (PredTy pred) 
834   = do { pred' <- expandAwayPred tv pred  
835        ; return (PredTy pred') }
836 -- For a type constructor application, first try expanding away the
837 -- offending variable from the arguments.  If that doesn't work, next
838 -- see if the type constructor is a type synonym, and if so, expand
839 -- it and try again.
840 expandAway tv ty@(TyConApp tc tys)
841   = (mkTyConApp tc <$> mapM (expandAway tv) tys) <|> (tcView ty >>= expandAway tv)
842
843 expandAwayPred :: TcTyVar -> TcPredType -> Maybe TcPredType 
844 expandAwayPred tv (ClassP cls tys) 
845   = do { tys' <- mapM (expandAway tv) tys; return (ClassP cls tys') } 
846 expandAwayPred tv (EqPred ty1 ty2)
847   = do { ty1' <- expandAway tv ty1
848        ; ty2' <- expandAway tv ty2 
849        ; return (EqPred ty1' ty2') }
850 expandAwayPred tv (IParam nm ty) 
851   = do { ty' <- expandAway tv ty
852        ; return (IParam nm ty') }
853
854                 
855
856 \end{code}
857
858 Note [Type synonyms and canonicalization]
859 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
860
861 We treat type synonym applications as xi types, that is, they do not
862 count as type function applications.  However, we do need to be a bit
863 careful with type synonyms: like type functions they may not be
864 generative or injective.  However, unlike type functions, they are
865 parametric, so there is no problem in expanding them whenever we see
866 them, since we do not need to know anything about their arguments in
867 order to expand them; this is what justifies not having to treat them
868 as specially as type function applications.  The thing that causes
869 some subtleties is that we prefer to leave type synonym applications
870 *unexpanded* whenever possible, in order to generate better error
871 messages.
872
873 If we encounter an equality constraint with type synonym applications
874 on both sides, or a type synonym application on one side and some sort
875 of type application on the other, we simply must expand out the type
876 synonyms in order to continue decomposing the equality constraint into
877 primitive equality constraints.  For example, suppose we have
878
879   type F a = [Int]
880
881 and we encounter the equality
882
883   F a ~ [b]
884
885 In order to continue we must expand F a into [Int], giving us the
886 equality
887
888   [Int] ~ [b]
889
890 which we can then decompose into the more primitive equality
891 constraint
892
893   Int ~ b.
894
895 However, if we encounter an equality constraint with a type synonym
896 application on one side and a variable on the other side, we should
897 NOT (necessarily) expand the type synonym, since for the purpose of
898 good error messages we want to leave type synonyms unexpanded as much
899 as possible.
900
901 However, there is a subtle point with type synonyms and the occurs
902 check that takes place for equality constraints of the form tv ~ xi.
903 As an example, suppose we have
904
905   type F a = Int
906
907 and we come across the equality constraint
908
909   a ~ F a
910
911 This should not actually fail the occurs check, since expanding out
912 the type synonym results in the legitimate equality constraint a ~
913 Int.  We must actually do this expansion, because unifying a with F a
914 will lead the type checker into infinite loops later.  Put another
915 way, canonical equality constraints should never *syntactically*
916 contain the LHS variable in the RHS type.  However, we don't always
917 need to expand type synonyms when doing an occurs check; for example,
918 the constraint
919
920   a ~ F b
921
922 is obviously fine no matter what F expands to. And in this case we
923 would rather unify a with F b (rather than F b's expansion) in order
924 to get better error messages later.
925
926 So, when doing an occurs check with a type synonym application on the
927 RHS, we use some heuristics to find an expansion of the RHS which does
928 not contain the variable from the LHS.  In particular, given
929
930   a ~ F t1 ... tn
931
932 we first try expanding each of the ti to types which no longer contain
933 a.  If this turns out to be impossible, we next try expanding F
934 itself, and so on.
935
936
937