FreeBSD dtrace probe support
[ghc.git] / configure.ac
1 dnl == autoconf source for the Glasgow FP tools ==
2 dnl (run "grep '^dnl \*' configure.ac | sed -e 's/dnl / /g; s/\*\*/   +/g;'"
3 dnl  (or some such) to see the outline of this file)
4 dnl
5 #
6 # (c) The University of Glasgow 1994-2012
7 #
8 # Configure script template for GHC
9 #
10 # Process with 'autoreconf' to get a working configure script.
11 #
12 # For the generated configure script, do "./configure --help" to
13 # see what flags are available. (Better yet, read the documentation!)
14 #
15
16 AC_INIT([The Glorious Glasgow Haskell Compilation System], [8.3], [glasgow-haskell-bugs@haskell.org], [ghc-AC_PACKAGE_VERSION])
17
18 # Set this to YES for a released version, otherwise NO
19 : ${RELEASE=NO}
20
21 # The primary version (e.g. 7.5, 7.4.1) is set in the AC_INIT line
22 # above.  If this is not a released version, then we will append the
23 # date to the version number (e.g. 7.4.20111220).  The date is
24 # constructed by finding the date of the most recent patch in the
25 # git repository.  If this is a source distribution (not a git
26 # checkout), then we ship a file 'VERSION' containing the full version
27 # when the source distribution was created.
28
29 if test ! -f mk/config.h.in; then
30    echo "mk/config.h.in doesn't exist: perhaps you haven't run 'python3 boot'?"
31    exit 1
32 fi
33
34 AC_SUBST([CONFIGURE_ARGS], [$ac_configure_args])
35
36 dnl this makes sure `./configure --target=<cross-compile-target>`
37 dnl works as expected, since we're slightly modifying how Autoconf
38 dnl interprets build/host/target and how this interacts with $CC tests
39 test -n "$target_alias" && ac_tool_prefix=$target_alias-
40
41 dnl ----------------------------------------------------------
42 dnl ** Find unixy sort and find commands,
43 dnl ** which are needed by FP_SETUP_PROJECT_VERSION
44
45 dnl ** Find find command (for Win32's benefit)
46 FP_PROG_FIND
47 FP_PROG_SORT
48
49 dnl ----------------------------------------------------------
50 FP_SETUP_PROJECT_VERSION
51
52 # Hmmm, we fix the RPM release number to 1 here... Is this convenient?
53 AC_SUBST([release], [1])
54
55 # First off, a distrib sanity check..
56 AC_CONFIG_SRCDIR([mk/config.mk.in])
57
58 dnl * We require autoconf version 2.60
59 dnl We need 2.50 due to the use of AC_SYS_LARGEFILE and AC_MSG_NOTICE.
60 dnl We need 2.52 due to the use of AS_TR_CPP and AS_TR_SH.
61 dnl Using autoconf 2.59 started to give nonsense like this
62 dnl  #define SIZEOF_CHAR 0
63 dnl recently.
64 AC_PREREQ([2.60])
65
66 # -------------------------------------------------------------------------
67 # Prepare to generate the following header files
68 #
69 #
70 AC_CONFIG_HEADER(mk/config.h)
71
72 # No, semi-sadly, we don't do `--srcdir'...
73 if test x"$srcdir" != 'x.' ; then
74     echo "This configuration does not support the \`--srcdir' option.."
75     exit 1
76 fi
77
78 dnl --------------------------------------------------------------
79 dnl * Project specific configuration options
80 dnl --------------------------------------------------------------
81 dnl What follows is a bunch of options that can either be configured
82 dnl through command line options to the configure script or by
83 dnl supplying defns in the build tree's mk/build.mk. Having the option to
84 dnl use either is considered a Feature.
85
86 dnl ** What command to use to compile compiler sources ?
87 dnl --------------------------------------------------------------
88
89 AC_ARG_WITH([ghc],
90 [AC_HELP_STRING([--with-ghc=ARG],
91   [Use ARG as the path to GHC  [default=autodetect]])],
92   [WithGhc="$withval"],
93   [if test "$GHC" = ""; then
94     AC_PATH_PROG([GHC], [ghc])
95   fi
96   WithGhc="$GHC"])
97
98 dnl ** Tell the make system which OS we are using
99 dnl $OSTYPE is set by the operating system to "msys" or "cygwin" or something
100 AC_SUBST(OSTYPE)
101
102 AC_ARG_ENABLE(bootstrap-with-devel-snapshot,
103 [AC_HELP_STRING([--enable-bootstrap-with-devel-snapshot],
104                 [Allow bootstrapping using a development snapshot of GHC.  This is not guaranteed to work.])],
105         EnableBootstrapWithDevelSnaphost=YES,
106         EnableBootstrapWithDevelSnaphost=NO
107 )
108
109 AC_ARG_ENABLE(tarballs-autodownload,
110 [AC_HELP_STRING([--enable-tarballs-autodownload],
111                 [Automatically download Windows distribution binaries if needed.])],
112         TarballsAutodownload=YES,
113         TarballsAutodownload=NO
114 )
115
116 AC_ARG_ENABLE(distro-toolchain,
117 [AC_HELP_STRING([--enable-distro-toolchain],
118                 [Do not use bundled Windows toolchain binaries.])],
119         EnableDistroToolchain=YES,
120         EnableDistroToolchain=NO
121 )
122
123 if test "$EnableDistroToolchain" = "YES"; then
124   TarballsAutodownload=NO
125 fi
126
127 dnl CC_STAGE0 is like the "previous" variable CC (inherited by CC_STAGE[123])
128 dnl but instead used by stage0 for bootstrapping stage1
129 AC_ARG_VAR(CC_STAGE0, [C compiler command (bootstrap)])
130
131 if test "$WithGhc" != ""; then
132   FPTOOLS_GHC_VERSION([GhcVersion], [GhcMajVersion], [GhcMinVersion], [GhcPatchLevel])dnl
133
134   if test "$GhcMajVersion" = "unknown" || test "$GhcMinVersion" = "unknown"; then
135      AC_MSG_ERROR([Cannot determine the version of $WithGhc.  Is it really GHC?])
136   fi
137
138   AC_SUBST(GhcVersion)dnl
139   AC_SUBST(GhcMajVersion)dnl
140   AC_SUBST(GhcMinVersion)dnl
141   AC_SUBST(GhcPatchLevel)dnl
142   GhcMinVersion2=`echo "$GhcMinVersion" | sed 's/^\\(.\\)$/0\\1/'`
143   GhcCanonVersion="$GhcMajVersion$GhcMinVersion2"
144
145   dnl infer CC_STAGE0 from `ghc --info` unless explicitly set by user
146   if test -z "$CC_STAGE0"; then
147     BOOTSTRAPPING_GHC_INFO_FIELD([CC_STAGE0],[C compiler command])
148   fi
149
150   BOOTSTRAPPING_GHC_INFO_FIELD([LD_STAGE0],[ld command])
151   BOOTSTRAPPING_GHC_INFO_FIELD([AR_STAGE0],[ar command])
152   BOOTSTRAPPING_GHC_INFO_FIELD([AR_OPTS_STAGE0],[ar flags])
153   BOOTSTRAPPING_GHC_INFO_FIELD([ArSupportsAtFile_STAGE0],[ar supports at file])
154 fi
155
156 dnl ** Must have GHC to build GHC
157 if test "$WithGhc" = ""
158 then
159     AC_MSG_ERROR([GHC is required.])
160 fi
161 FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[8.0],
162     [AC_MSG_ERROR([GHC version 8.0 or later is required to compile GHC.])])
163
164 if test `expr $GhcMinVersion % 2` = "1"
165 then
166     if test "$EnableBootstrapWithDevelSnaphost" = "NO"
167     then
168         AC_MSG_ERROR([
169      $WithGhc is a development snapshot of GHC, version $GhcVersion.
170      Bootstrapping using this version of GHC is not supported, and may not
171      work.  Use --enable-bootstrap-with-devel-snapshot to try it anyway,
172      or --with-ghc to specify a different GHC to use.])
173     fi
174 fi
175
176 GHC_PACKAGE_DB_FLAG=package-db
177 AC_SUBST(GHC_PACKAGE_DB_FLAG)
178
179 # GHC is passed to Cabal, so we need a native path
180 if test "${WithGhc}" != ""
181 then
182     ghc_host_os=`"${WithGhc}" +RTS --info | grep 'Host OS' | sed -e 's/.*, "//' -e 's/")//'`
183
184     if test "$ghc_host_os" = "mingw32"
185     then
186         if test "${OSTYPE}" = "msys"
187         then
188             WithGhc=`echo "${WithGhc}" | sed "s#^/\([a-zA-Z]\)/#\1:/#"`
189         else
190             # Canonicalise to <drive>:/path/to/ghc
191             WithGhc=`cygpath -m "${WithGhc}"`
192         fi
193         echo "GHC path canonicalised to: ${WithGhc}"
194     fi
195 fi
196 AC_SUBST([WithGhc])
197
198 dnl ** Without optimization some INLINE trickery fails for GHCi
199 SRC_CC_OPTS="-O"
200
201 dnl--------------------------------------------------------------------
202 dnl * Choose host(/target/build) platform
203 dnl--------------------------------------------------------------------
204 dnl If we aren't explicitly told what values to use with configure flags,
205 dnl we ask the bootstrapping compiler what platform it is for
206
207 if test "${WithGhc}" != ""
208 then
209         bootstrap_host=`"${WithGhc}" +RTS --info | grep '^ ,("Host platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
210         bootstrap_target=`"${WithGhc}" +RTS --info | grep '^ ,("Target platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
211         if test "$bootstrap_host" != "$bootstrap_target"
212         then
213                 echo "Bootstrapping GHC is a cross compiler. This probably isn't going to work"
214         fi
215 fi
216
217 # We have to run these unconditionally, but we may discard their
218 # results in the following code
219 AC_CANONICAL_BUILD
220 AC_CANONICAL_HOST
221 AC_CANONICAL_TARGET
222
223 FPTOOLS_SET_PLATFORM_VARS
224
225 # Verify that the installed (bootstrap) GHC is capable of generating
226 # code for the requested build platform.
227 if test "$BuildPlatform" != "$bootstrap_target"
228 then
229     echo "This GHC (${WithGhc}) does not generate code for the build platform"
230     echo "   GHC target platform    : $bootstrap_target"
231     echo "   Desired build platform : $BuildPlatform"
232     exit 1
233 fi
234
235 # Testing if we shall enable shared libs support on Solaris.
236 # Anything older than SunOS 5.11 aka Solaris 11 (Express) is broken.
237
238 SOLARIS_BROKEN_SHLD=NO
239
240 case $host in
241      i386-*-solaris2)
242      # here we go with the test
243      MINOR=`uname -r|cut -d '.' -f 2-`
244      if test "$MINOR" -lt "11"; then
245          SOLARIS_BROKEN_SHLD=YES
246      fi
247      ;;
248 esac
249
250 AC_SUBST(SOLARIS_BROKEN_SHLD)
251
252 dnl ** Do an unregisterised build?
253 dnl --------------------------------------------------------------
254 case "$TargetArch" in
255     i386|x86_64|powerpc|powerpc64|powerpc64le|arm|aarch64)
256         UnregisterisedDefault=NO
257         ;;
258     *)
259         UnregisterisedDefault=YES
260         ;;
261 esac
262 AC_ARG_ENABLE(unregisterised,
263 [AC_HELP_STRING([--enable-unregisterised],
264 [Build an unregisterised compiler (enabled by default on platforms without registerised support) [default="$UnregisterisedDefault"]])],
265 [ if test x"$enableval" = x"yes"; then
266         Unregisterised=YES
267   else
268         Unregisterised=NO
269   fi
270 ],
271 [Unregisterised="$UnregisterisedDefault"]
272 )
273 AC_SUBST(Unregisterised)
274
275 dnl ** Does target have runtime linker support?
276 dnl --------------------------------------------------------------
277 case "$target" in
278     powerpc64-*|powerpc64le-*|powerpc-ibm-aix*)
279         HaskellHaveRTSLinker=NO
280         ;;
281     *)
282         HaskellHaveRTSLinker=YES
283         ;;
284 esac
285 AC_SUBST(HaskellHaveRTSLinker)
286
287 # Requires FPTOOLS_SET_PLATFORM_VARS to be run first.
288 FP_FIND_ROOT
289
290 fail() {
291     echo >&2
292     echo "$1" >&2
293     exit 1
294 }
295
296
297 if test "$HostOS" = "mingw32"
298 then
299     # Find the mingw-w64 7z file to extract.
300     # NB. If you update the tarballs to a new version of gcc, don't
301     # forget to tweak the paths in driver/gcc/gcc.c.
302     if test "$HostArch" = "i386"
303     then
304         mingw_arch="i686"
305         tarball_dest_dir="mingw-w64/x86"
306         tarball_mingw_dir="mingw32"
307     else
308         mingw_arch="x86_64"
309         tarball_dest_dir="mingw-w64/x86_64"
310         tarball_mingw_dir="mingw64"
311     fi
312 fi
313
314 set_up_tarballs() {
315     AC_MSG_NOTICE([Checking for Windows toolchain tarballs...])
316     local action
317     if test "$TarballsAutodownload" = "NO"
318     then
319         action="verify"
320     else
321         action="download"
322     fi
323     mk/get-win32-tarballs.sh $action $HostArch > missing-win32-tarballs
324     case $? in
325         0)
326            rm missing-win32-tarballs
327            ;;
328         2)
329            echo
330            echo "Error:"
331            echo "Needed msys2 tarballs are missing. You have a few options to get them,"
332            echo
333            echo "  * run configure with the --enable-tarballs-autodownload option"
334            echo
335            echo "  * run mk/get-win32-tarballs.sh download ${HostArch}"
336            echo
337            echo "  * manually download the files listed in ./missing-win32-tarballs and place"
338            echo "    them in the ghc-tarballs directory."
339            echo
340            exit 1
341            ;;
342         *)
343            echo
344            echo "Error fetching msys2 tarballs; see errors above."
345            exit 1
346            ;;
347     esac
348
349     # Extract all the tarballs in one go
350     if ! test -d inplace/mingw
351     then
352         AC_MSG_NOTICE([Extracting Windows toolchain from archives (may take a while)...])
353         rm -rf inplace/mingw
354         local base_dir="../ghc-tarballs/${tarball_dest_dir}"
355         ( cd inplace &&
356         find "${base_dir}" -name "*.tar.xz" -exec tar xfJ {} \; &&
357         rm ".MTREE" &&
358         rm ".PKGINFO" &&
359         cd .. ) || fail "Error: Could not extract Windows toolchains."
360
361         mv "inplace/${tarball_mingw_dir}" inplace/mingw &&
362         touch inplace/mingw
363
364         # NB. Now since the GCC is hardcoded to use /mingw32 we need to
365         # make a wrapper around it to give it the proper paths
366         mv inplace/mingw/bin/gcc.exe inplace/mingw/bin/realgcc.exe
367         PATH=`pwd`/inplace/mingw/bin:$PATH
368         inplace/mingw/bin/realgcc.exe driver/gcc/gcc.c driver/utils/cwrapper.c driver/utils/getLocation.c -Idriver/utils -o inplace/mingw/bin/gcc.exe
369
370         AC_MSG_NOTICE([In-tree MingW-w64 tree created])
371     fi
372 }
373
374 if test "$HostOS" = "mingw32" -a "$EnableDistroToolchain" = "NO"
375 then
376     test -d inplace || mkdir inplace
377
378     # NB. Download and extract the MingW-w64 distribution if required
379     set_up_tarballs
380
381     mingwbin="$hardtop/inplace/mingw/bin/"
382     CC="${mingwbin}gcc.exe"
383     LD="${mingwbin}ld.exe"
384     NM="${mingwbin}nm.exe"
385     RANLIB="${mingwbin}ranlib.exe"
386     OBJDUMP="${mingwbin}objdump.exe"
387     fp_prog_ar="${mingwbin}ar.exe"
388
389     AC_PATH_PROG([Genlib],[genlib])
390
391     # NB. Download the perl binaries if required
392     if ! test -d inplace/perl ||
393          test inplace/perl -ot ghc-tarballs/perl/ghc-perl*.tar.gz
394     then
395         AC_MSG_NOTICE([Making in-tree perl tree])
396         rm -rf inplace/perl
397         mkdir inplace/perl
398         (
399             cd inplace/perl &&
400             tar -zxf ../../ghc-tarballs/perl/ghc-perl*.tar.gz
401         )
402         AC_MSG_NOTICE([In-tree perl tree created])
403     fi
404 fi
405
406 # We don't want to bundle a MinGW-w64 toolchain
407 # So we have to find these individual tools.
408 if test "$EnableDistroToolchain" = "YES"
409 then
410     # Ideally should use AC_CHECK_TARGET_TOOL but our triples
411     # are screwed up. Configure doesn't think they're ever equal and
412     # so never tried without the prefix.
413     AC_PATH_PROG([CC],[gcc], [clang])
414     AC_PATH_PROG([NM],[nm])
415     AC_PATH_PROG([AR],[ar])
416     AC_PATH_PROG([RANLIB],[ranlib])
417     AC_PATH_PROG([OBJDUMP],[objdump])
418     AC_PATH_PROG([DllWrap],[dllwrap])
419     AC_PATH_PROG([Windres],[windres])
420     AC_PATH_PROG([Genlib],[genlib])
421 fi
422
423 DllWrapCmd="$DllWrap"
424 WindresCmd="$Windres"
425
426 HAVE_GENLIB=False
427 if test "$HostOS" = "mingw32"
428 then
429     if test "$Genlib" != ""; then
430         GenlibCmd="$(cygpath -m $Genlib)"
431         HAVE_GENLIB=True
432     fi
433 fi
434
435 AC_SUBST([DllWrapCmd])
436 AC_SUBST([WindresCmd])
437 AC_SUBST([GenlibCmd])
438 AC_SUBST([HAVE_GENLIB])
439
440 FP_ICONV
441 FP_GMP
442 FP_CURSES
443
444 XCODE_VERSION()
445
446
447 dnl ** Building a cross compiler?
448 dnl --------------------------------------------------------------
449 CrossCompiling=NO
450 # If 'host' and 'target' differ, then this means we are building a cross-compiler.
451 if test "$TargetPlatform" != "$HostPlatform" ; then
452     CrossCompiling=YES
453     cross_compiling=yes   # This tells configure that it can accept just 'target',
454                           # otherwise you get
455                           #   configure: error: cannot run C compiled programs.
456                           #   If you meant to cross compile, use `--host'.
457 fi
458 if test "$BuildPlatform" != "$HostPlatform" ; then
459    AC_MSG_ERROR([
460 You've selected:
461
462   BUILD:  $BuildPlatform   (the architecture we're building on)
463   HOST:   $HostPlatform    (the architecture the compiler we're building will execute on)
464   TARGET: $TargetPlatform  (the architecture the compiler we're building will produce code for)
465
466 BUILD must equal HOST; that is, we do not support building GHC itself
467 with a cross-compiler.  To cross-compile GHC itself, set TARGET: stage
468 1 will be a cross-compiler, and stage 2 will be the cross-compiled
469 GHC.
470 ])
471 fi
472 # Despite its similarity in name to TargetPlatform, TargetPlatformFull is used
473 # in calls to subproject configure scripts and thus must be set to the autoconf
474 # triple, not the normalized GHC triple that TargetPlatform is set to.
475 #
476 # We use the non-canonicalized triple, target_alias, here since the subproject
477 # configure scripts will use this triple to construct the names of the toolchain
478 # executables. If we instead passed down the triple produced by
479 # AC_CANONICAL_TARGET then it may look for the target toolchain under the wrong
480 # name (this is a known problem in the case of the Android NDK, which has
481 # slightly odd triples).
482 #
483 # It may be better to just do away with the GHC triples altogether. This would
484 # all be taken care of for us if we configured the subprojects using
485 # AC_CONFIG_DIR, but unfortunately Cabal needs to be the one to do the
486 # configuration.
487 #
488 # We also use non-canonicalized triple when install stage1 crosscompiler
489 if test -z "${target_alias}"
490 then
491   # --target wasn't given; use result from AC_CANONICAL_TARGET
492   TargetPlatformFull="${target}"
493 else
494   TargetPlatformFull="${target_alias}"
495 fi
496 if test "$CrossCompiling" = "YES"
497 then
498   # Use value passed by user from --target=
499   CrossCompilePrefix="${TargetPlatformFull}-"
500 else
501   CrossCompilePrefix=""
502 fi
503 AC_SUBST(CrossCompiling)
504 AC_SUBST(CrossCompilePrefix)
505 AC_SUBST(TargetPlatformFull)
506 AC_SUBST(EnableDistroToolchain)
507
508 dnl ** Which gcc to use?
509 dnl --------------------------------------------------------------
510
511 AC_ARG_WITH([gcc],
512         AS_HELP_STRING([--with-gcc=ARG], [Use ARG as the path to gcc (obsolete, use CC=ARG instead) [default=autodetect]]),
513         AC_MSG_ERROR([--with-gcc=$withval is obsolete (use './configure CC=$withval' or 'CC=$withval ./configure' instead)]))
514
515 AC_ARG_WITH([clang],
516         AS_HELP_STRING([--with-clang=ARG], [Use ARG as the path to gcc (obsolete, use CC=ARG instead) [default=autodetect]]),
517         AC_MSG_ERROR([--with-clang=$withval is obsolete (use './configure CC=$withval' or 'CC=$withval ./configure' instead)]))
518
519 dnl detect compiler (prefer gcc over clang) and set $CC (unless CC already set),
520 dnl later CC is copied to CC_STAGE{1,2,3}
521 AC_PROG_CC([gcc clang])
522
523 MAYBE_OVERRIDE_STAGE0([ar],[AR_STAGE0])
524
525 dnl make extensions visible to allow feature-tests to detect them lateron
526 AC_USE_SYSTEM_EXTENSIONS
527
528 dnl ** figure out how to invoke the C preprocessor (i.e. `gcc -E`)
529 AC_PROG_CPP
530
531 # --with-hs-cpp/--with-hs-cpp-flags
532 FP_CPP_CMD_WITH_ARGS(HaskellCPPCmd, HaskellCPPArgs)
533 AC_SUBST([HaskellCPPCmd])
534 AC_SUBST([HaskellCPPArgs])
535
536 FP_SET_CFLAGS_C99([CC],[CFLAGS],[CPPFLAGS])
537 FP_SET_CFLAGS_C99([CC_STAGE0],[CONF_CC_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
538 FP_SET_CFLAGS_C99([CC],[CONF_CC_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
539 FP_SET_CFLAGS_C99([CC],[CONF_CC_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])
540
541 dnl ** Choose a linker
542 dnl --------------------------------------------------------------
543 FIND_LD([$target],[GccUseLdOpt])
544 CONF_GCC_LINKER_OPTS_STAGE1="$CONF_GCC_LINKER_OPTS_STAGE1 $GccUseLdOpt"
545 CONF_GCC_LINKER_OPTS_STAGE2="$CONF_GCC_LINKER_OPTS_STAGE2 $GccUseLdOpt"
546 LdCmd="$LD"
547 CFLAGS="$CFLAGS $GccUseLdOpt"
548 AC_SUBST([LdCmd])
549
550 dnl ** Which nm to use?
551 dnl --------------------------------------------------------------
552 if test "$HostOS" != "mingw32"; then
553     AC_CHECK_TARGET_TOOL([NM], [nm])
554     if test "$NM" = ":"; then
555         AC_MSG_ERROR([cannot find nm in your PATH])
556     fi
557 fi
558 NmCmd="$NM"
559 AC_SUBST([NmCmd])
560
561 if test "$TargetOS_CPP" = "darwin"
562 then
563     AC_MSG_CHECKING(whether nm program is broken)
564     # Some versions of XCode ship a broken version of `nm`. Detect and work
565     # around this issue. See : https://ghc.haskell.org/trac/ghc/ticket/11744
566     nmver=$(${NM} --version | grep version | sed 's/ //g')
567     case "$nmver" in
568         LLVMversion7.3.0|LLVMversion7.3.1)
569             AC_MSG_RESULT(yes)
570             echo "The detected nm program is broken."
571             echo
572             echo "See: https://ghc.haskell.org/trac/ghc/ticket/11744"
573             echo
574             echo "Try re-running configure with:"
575             echo
576             echo '   NM=$(xcrun --find nm-classic) ./configure'
577             echo
578             exit 1
579             ;;
580         *)
581             AC_MSG_RESULT(no)
582             ;;
583         esac
584 fi
585
586 dnl ** Which objdump to use?
587 dnl --------------------------------------------------------------
588 dnl Note: we may not have objdump on OS X, and we only need it on
589 dnl Windows (for DLL checks), OpenBSD, and AIX
590 case $HostOS_CPP in
591   cygwin32|mingw32|openbsd|aix)
592     AC_CHECK_TARGET_TOOL([OBJDUMP], [objdump])
593     ;;
594 esac
595
596 ObjdumpCmd="$OBJDUMP"
597 AC_SUBST([ObjdumpCmd])
598
599 dnl ** Which ranlib to use?
600 dnl --------------------------------------------------------------
601 AC_PROG_RANLIB
602 if test "$RANLIB" = ":"; then
603     AC_MSG_ERROR([cannot find ranlib in your PATH])
604 fi
605 RanlibCmd="$RANLIB"
606 RANLIB="$RanlibCmd"
607
608 dnl ** which strip to use?
609 dnl --------------------------------------------------------------
610 AC_CHECK_TARGET_TOOL([STRIP], [strip])
611 StripCmd="$STRIP"
612 AC_SUBST([StripCmd])
613
614
615 dnl ** which libtool to use?
616 dnl --------------------------------------------------------------
617 # The host normalization on Windows breaks autoconf, it no longer
618 # thinks that target == host so it never checks the unqualified
619 # tools for Windows. See #14274.
620 if test "$HostOS" = "mingw32"
621 then
622     AC_PATH_PROG([LIBTOOL],[libtool])
623     LibtoolCmd="$(cygpath -m $LIBTOOL)"
624 else
625     AC_CHECK_TARGET_TOOL([LIBTOOL], [libtool])
626     LibtoolCmd="$LIBTOOL"
627     LIBTOOL="$LibtoolCmd"
628 fi
629 AC_SUBST([LibtoolCmd])
630
631 # Here is where we re-target which specific version of the LLVM
632 # tools we are looking for. In the past, GHC supported a number of
633 # versions of LLVM simultaneously, but that stopped working around
634 # 3.5/3.6 release of LLVM.
635 LlvmVersion=5.0
636 AC_SUBST([LlvmVersion])
637 sUPPORTED_LLVM_VERSION=$(echo \($LlvmVersion\) | sed 's/\./,/')
638 AC_DEFINE_UNQUOTED([sUPPORTED_LLVM_VERSION], ${sUPPORTED_LLVM_VERSION}, [The supported LLVM version number])
639
640 dnl ** Which LLVM clang to use?
641 dnl --------------------------------------------------------------
642 AC_CHECK_TARGET_TOOL([CLANG], [clang])
643 ClangCmd="$CLANG"
644 AC_SUBST([ClangCmd])
645
646 dnl ** Which LLVM llc to use?
647 dnl --------------------------------------------------------------
648 FIND_LLVM_PROG([LLC], [llc], [$LlvmVersion])
649 LlcCmd="$LLC"
650 AC_SUBST([LlcCmd])
651
652 dnl ** Which LLVM opt to use?
653 dnl --------------------------------------------------------------
654 FIND_LLVM_PROG([OPT], [opt], [$LlvmVersion])
655 OptCmd="$OPT"
656 AC_SUBST([OptCmd])
657
658 dnl --------------------------------------------------------------
659 dnl End of configure script option section
660 dnl --------------------------------------------------------------
661
662
663 dnl --------------------------------------------------------------
664 dnl ** Can the unix package be built?
665 dnl --------------------------------------------------------------
666
667 if test "$TargetOS" = "mingw32"
668 then
669     GhcLibsWithUnix=NO
670 else
671     GhcLibsWithUnix=YES
672 fi
673 AC_SUBST([GhcLibsWithUnix])
674
675 dnl ** does #! work?
676 AC_SYS_INTERPRETER()
677
678 # Check for split-objs
679 SplitObjsBroken=NO
680 dnl ** look for `perl'
681 case $HostOS_CPP in
682 cygwin32|mingw32)
683   if test "$EnableDistroToolchain" = "NO"; then
684     PerlCmd=$hardtop/inplace/perl/perl
685   else
686     AC_PATH_PROG([PerlCmd],[perl])
687   fi
688   ;;
689 *)
690     AC_PATH_PROG([PerlCmd],[perl])
691     if test -z "$PerlCmd"
692     then
693         AC_MSG_WARN([No Perl on PATH, disabling split object support])
694         SplitObjsBroken=YES
695     else
696         FPTOOLS_CHECK_PERL_VERSION
697     fi
698     ;;
699 esac
700 AC_SUBST([SplitObjsBroken])
701
702 dnl ** look for GCC and find out which version
703 dnl     Figure out which C compiler to use.  Gcc is preferred.
704 dnl     If gcc, make sure it's at least 3.0
705 dnl
706 FP_GCC_VERSION
707
708 dnl ** See whether gcc supports -no-pie
709 FP_GCC_SUPPORTS_NO_PIE
710
711 dnl ** look to see if we have a C compiler using an llvm back end.
712 dnl
713 FP_CC_LLVM_BACKEND
714
715 FP_PROG_LD_IS_GNU
716 FP_PROG_LD_BUILD_ID
717 FP_PROG_LD_NO_COMPACT_UNWIND
718 FP_PROG_LD_FILELIST
719
720 FPTOOLS_SET_C_LD_FLAGS([target],[CFLAGS],[LDFLAGS],[IGNORE_LINKER_LD_FLAGS],[CPPFLAGS])
721 FPTOOLS_SET_C_LD_FLAGS([build],[CONF_CC_OPTS_STAGE0],[CONF_GCC_LINKER_OPTS_STAGE0],[CONF_LD_LINKER_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
722 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE1],[CONF_GCC_LINKER_OPTS_STAGE1],[CONF_LD_LINKER_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
723 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE2],[CONF_GCC_LINKER_OPTS_STAGE2],[CONF_LD_LINKER_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])
724 # Stage 3 won't be supported by cross-compilation
725
726 FP_GCC_EXTRA_FLAGS
727
728 # See rules/distdir-way-opts.mk for details.
729 # Flags passed to the C compiler
730 AC_SUBST(CONF_CC_OPTS_STAGE0)
731 AC_SUBST(CONF_CC_OPTS_STAGE1)
732 AC_SUBST(CONF_CC_OPTS_STAGE2)
733 # Flags passed to the C compiler when we ask it to link
734 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE0)
735 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE1)
736 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE2)
737 # Flags passed to the linker when we ask it to link
738 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE0)
739 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE1)
740 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE2)
741 # Flags passed to the C preprocessor
742 AC_SUBST(CONF_CPP_OPTS_STAGE0)
743 AC_SUBST(CONF_CPP_OPTS_STAGE1)
744 AC_SUBST(CONF_CPP_OPTS_STAGE2)
745 # Flags passed to the Haskell compiler
746 AC_SUBST(CONF_HC_OPTS_STAGE0)
747 AC_SUBST(CONF_HC_OPTS_STAGE1)
748 AC_SUBST(CONF_HC_OPTS_STAGE2)
749
750 dnl ** Set up the variables for the platform in the settings file.
751 dnl May need to use gcc to find platform details.
752 dnl --------------------------------------------------------------
753 FPTOOLS_SET_HASKELL_PLATFORM_VARS
754
755 dnl ** figure out how to do context diffs
756 FP_PROG_CONTEXT_DIFF
757
758 dnl Let's make sure install-sh is executable here.  If we got it from
759 dnl a darcs repo, it might not be (see bug #978).
760 chmod +x install-sh
761 dnl ** figure out how to do a BSD-ish install
762 AC_PROG_INSTALL
763
764 dnl ** how to invoke `ar' and `ranlib'
765 FP_PROG_AR_SUPPORTS_ATFILE
766 FP_PROG_AR_NEEDS_RANLIB
767
768 dnl ** Check to see whether ln -s works
769 AC_PROG_LN_S
770
771 FP_SETTINGS
772
773 dnl ** Find the path to sed
774 AC_PATH_PROGS(SedCmd,gsed sed,sed)
775
776
777 dnl ** check for time command
778 AC_PATH_PROG(TimeCmd,time)
779
780 dnl ** check for tar
781 dnl   if GNU tar is named gtar, look for it first.
782 AC_PATH_PROGS(TarCmd,gnutar gtar tar,tar)
783
784 dnl ** check for compressors
785 AC_PATH_PROGS(Bzip2Cmd,bzip2, bzip2)
786 AC_PATH_PROGS(GzipCmd,gzip, gzip)
787 AC_PATH_PROGS(XzCmd,pxz xz, xz)
788
789 dnl ** check for patch
790 dnl if GNU patch is named gpatch, look for it first
791 AC_PATH_PROGS(PatchCmd,gpatch patch, patch)
792
793 dnl ** check for dtrace (currently only implemented for Mac OS X)
794 HaveDtrace=NO
795 AC_PATH_PROG(DtraceCmd,dtrace)
796 if test -n "$DtraceCmd"; then
797   if test "x$TargetOS_CPP-$TargetVendor_CPP" = "xdarwin-apple" \
798                 -o "x$TargetOS_CPP-$TargetVendor_CPP" = "xfreebsd-portbld" \
799                 -o "x$TargetOS_CPP-$TargetVendor_CPP" = "xsolaris2-unknown"; then
800     HaveDtrace=YES
801   fi
802 fi
803 AC_SUBST(HaveDtrace)
804
805 AC_PATH_PROG(HSCOLOUR,HsColour)
806 # HsColour is passed to Cabal, so we need a native path
807 if test "$HostOS"      = "mingw32" && \
808    test "${OSTYPE}"   != "msys"    && \
809    test "${HSCOLOUR}" != ""
810 then
811     # Canonicalise to <drive>:/path/to/gcc
812     HSCOLOUR=`cygpath -m ${HSCOLOUR}`
813 fi
814
815 dnl ** check for Sphinx toolchain
816 AC_PATH_PROG(SPHINXBUILD,sphinx-build)
817 AC_CACHE_CHECK([for version of sphinx-build], fp_cv_sphinx_version,
818 changequote(, )dnl
819 [if test -n "$SPHINXBUILD"; then
820   fp_cv_sphinx_version=`"$SPHINXBUILD" --version 2>&1 | sed 's/Sphinx\( (sphinx-build)\)\? v\?\([0-9]\.[0-9]\.[0-9]\)/\2/' | head -n1`;
821 fi;
822 changequote([, ])dnl
823 ])
824 FP_COMPARE_VERSIONS([$fp_cv_sphinx_version],-lt,1.0.0,
825     [AC_MSG_WARN([Sphinx version 1.0.0 or later is required to build documentation]); SPHINXBUILD=;])
826
827 dnl ** check for xelatex
828 AC_PATH_PROG(XELATEX,xelatex)
829
830 dnl ** check for ghc-pkg command
831 FP_PROG_GHC_PKG
832
833 dnl ** check for installed happy binary + version
834 FPTOOLS_HAPPY
835
836 dnl ** check for installed alex binary + version
837 FPTOOLS_ALEX
838
839 dnl --------------------------------------------------
840 dnl ### program checking section ends here ###
841 dnl --------------------------------------------------
842
843 dnl --------------------------------------------------
844 dnl * Platform header file and syscall feature tests
845 dnl ### checking the state of the local header files and syscalls ###
846
847 dnl ** check for full ANSI header (.h) files
848 AC_HEADER_STDC
849
850 dnl ** Enable large file support.  NB. do this before testing the type of
851 dnl    off_t, because it will affect the result of that test.
852 AC_SYS_LARGEFILE
853
854 dnl ** check for specific header (.h) files that we are interested in
855 AC_CHECK_HEADERS([ctype.h dirent.h dlfcn.h errno.h fcntl.h grp.h limits.h locale.h nlist.h pthread.h pwd.h signal.h sys/param.h sys/mman.h sys/resource.h sys/select.h sys/time.h sys/timeb.h sys/timerfd.h sys/timers.h sys/times.h sys/utsname.h sys/wait.h termios.h time.h utime.h windows.h winsock.h sched.h])
856
857 dnl sys/cpuset.h needs sys/param.h to be included first on FreeBSD 9.1; #7708
858 AC_CHECK_HEADERS([sys/cpuset.h], [], [],
859 [[#if HAVE_SYS_PARAM_H
860 # include <sys/param.h>
861 #endif
862 ]])
863
864 dnl ** check if it is safe to include both <time.h> and <sys/time.h>
865 AC_HEADER_TIME
866
867 dnl ** do we have long longs?
868 AC_CHECK_TYPES([long long])
869
870 dnl ** what are the sizes of various types
871 FP_CHECK_SIZEOF_AND_ALIGNMENT(char)
872 FP_CHECK_SIZEOF_AND_ALIGNMENT(double)
873 FP_CHECK_SIZEOF_AND_ALIGNMENT(float)
874 FP_CHECK_SIZEOF_AND_ALIGNMENT(int)
875 FP_CHECK_SIZEOF_AND_ALIGNMENT(long)
876 if test "$ac_cv_type_long_long" = yes; then
877 FP_CHECK_SIZEOF_AND_ALIGNMENT(long long)
878 fi
879 FP_CHECK_SIZEOF_AND_ALIGNMENT(short)
880 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned char)
881 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned int)
882 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned long)
883 if test "$ac_cv_type_long_long" = yes; then
884 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned long long)
885 fi
886 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned short)
887 FP_CHECK_SIZEOF_AND_ALIGNMENT(void *)
888
889 FP_CHECK_SIZEOF_AND_ALIGNMENT(int8_t)
890 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint8_t)
891 FP_CHECK_SIZEOF_AND_ALIGNMENT(int16_t)
892 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint16_t)
893 FP_CHECK_SIZEOF_AND_ALIGNMENT(int32_t)
894 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint32_t)
895 FP_CHECK_SIZEOF_AND_ALIGNMENT(int64_t)
896 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint64_t)
897
898
899 dnl for use in settings.in
900 TargetWordSize=$ac_cv_sizeof_void_p
901 AC_SUBST(TargetWordSize)
902 FP_CHECK_FUNC([WinExec],
903   [@%:@include <windows.h>], [WinExec("",0)])
904
905 FP_CHECK_FUNC([GetModuleFileName],
906   [@%:@include <windows.h>], [GetModuleFileName((HMODULE)0,(LPTSTR)0,0)])
907
908 dnl ** check for more functions
909 dnl ** The following have been verified to be used in ghc/, but might be used somewhere else, too.
910 AC_CHECK_FUNCS([getclock getrusage gettimeofday setitimer siginterrupt sysconf times ctime_r sched_setaffinity setlocale])
911
912 dnl ** On OS X 10.4 (at least), time.h doesn't declare ctime_r if
913 dnl ** _POSIX_C_SOURCE is defined
914 AC_CHECK_DECLS([ctime_r], , ,
915 [#define _POSIX_SOURCE 1
916 #define _POSIX_C_SOURCE 199506L
917 #include <time.h>])
918
919 dnl ** check for mingwex library
920 AC_CHECK_LIB(mingwex, closedir, HaveLibMingwEx=YES, HaveLibMingwEx=NO)
921 AC_SUBST(HaveLibMingwEx)
922
923 if test $HaveLibMingwEx = YES ; then
924   AC_DEFINE([HAVE_MINGWEX], [1], [Define to 1 if you have the mingwex library.])
925 fi
926
927 dnl ** check for math library
928 dnl    Keep that check as early as possible.
929 dnl    as we need to know whether we need libm
930 dnl    for math functions or not
931 dnl    (see http://ghc.haskell.org/trac/ghc/ticket/3730)
932 AC_CHECK_LIB(m, atan, HaveLibM=YES, HaveLibM=NO)
933 if test $HaveLibM = YES
934 then
935   AC_DEFINE([HAVE_LIBM], [1], [Define to 1 if you need to link with libm])
936 fi
937
938 FP_BFD_SUPPORT
939
940 dnl ################################################################
941 dnl Check for libraries
942 dnl ################################################################
943
944 # system libffi
945
946 AC_ARG_WITH([system-libffi],
947 [AC_HELP_STRING([--with-system-libffi],
948   [Use system provided libffi for RTS [default=no]])
949 ])
950
951 AS_IF([test "x$with_system_libffi" = "xyes"],
952   [UseSystemLibFFI="YES"], [UseSystemLibFFI="NO"]
953 )
954
955
956 AC_SUBST(UseSystemLibFFI)
957
958 AC_ARG_WITH([ffi-includes],
959 [AC_HELP_STRING([--with-ffi-includes=ARG],
960   [Find includes for libffi in ARG [default=system default]])
961 ],
962 [
963  if test "x$UseSystemLibFFI" != "xYES"; then
964     AC_MSG_WARN([--with-ffi-includes will be ignored, --with-system-libffi not set])
965  else
966     FFIIncludeDir="$withval"
967     LIBFFI_CFLAGS="-I$withval"
968  fi
969 ])
970
971 AC_SUBST(FFIIncludeDir)
972
973 AC_ARG_WITH([ffi-libraries],
974 [AC_HELP_STRING([--with-ffi-libraries=ARG],
975   [Find libffi in ARG [default=system default]])
976 ],
977 [
978  if test "x$UseSystemLibFFI" != "xYES"; then
979     AC_MSG_WARN([--with-ffi-libraries will be ignored, --with-system-libffi not set])
980  else
981     FFILibDir="$withval" LIBFFI_LDFLAGS="-L$withval"
982  fi
983 ])
984
985 AC_SUBST(FFILibDir)
986
987 AS_IF([test "$UseSystemLibFFI" = "YES"], [
988  CFLAGS2="$CFLAGS"
989  CFLAGS="$LIBFFI_CFLAGS $CFLAGS"
990  LDFLAGS2="$LDFLAGS"
991  LDFLAGS="$LIBFFI_LDFLAGS $LDFLAGS"
992  if test "$HostOS" = "openbsd";
993  then
994    # OpenBSD's libffi is not directly linked to the libpthread but
995    # still requires pthread functionality. This means that any client
996    # binary which links with libffi also needs to link with
997    # libpthread. If it does not, then linking fails with unresolved
998    # symbols.
999    LDFLAGS="$LDFLAGS -lpthread"
1000  fi
1001  AC_CHECK_LIB(ffi, ffi_call,
1002   [AC_CHECK_HEADERS([ffi.h], [break], [])
1003    AC_DEFINE([HAVE_LIBFFI], [1], [Define to 1 if you have libffi.])],
1004   [AC_MSG_ERROR([Cannot find system libffi])])
1005  CFLAGS="$CFLAGS2"
1006  LDFLAGS="$LDFLAGS2"
1007 ])
1008
1009 dnl ** check whether we need -ldl to get dlopen()
1010 AC_CHECK_LIB(dl, dlopen)
1011
1012 dnl --------------------------------------------------
1013 dnl * Miscellaneous feature tests
1014 dnl --------------------------------------------------
1015
1016 dnl ** can we get alloca?
1017 AC_FUNC_ALLOCA
1018
1019 dnl ** working vfork?
1020 AC_FUNC_FORK
1021
1022 dnl ** determine whether or not const works
1023 AC_C_CONST
1024
1025 dnl ** are we big endian?
1026 AC_C_BIGENDIAN
1027 FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN
1028
1029 dnl ** check for leading underscores in symbol names
1030 FP_LEADING_UNDERSCORE
1031
1032 FP_VISIBILITY_HIDDEN
1033
1034 dnl ** check for librt
1035 AC_CHECK_LIB(rt, clock_gettime)
1036 AC_CHECK_FUNCS(clock_gettime timer_settime)
1037 FP_CHECK_TIMER_CREATE
1038
1039 dnl ** check for Apple's "interesting" long double compatibility scheme
1040 AC_MSG_CHECKING(for printf\$LDBLStub)
1041 AC_TRY_LINK_FUNC(printf\$LDBLStub,
1042     [
1043         AC_MSG_RESULT(yes)
1044         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[1],
1045             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
1046     ],
1047     [
1048         AC_MSG_RESULT(no)
1049         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[0],
1050             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
1051     ])
1052
1053 dnl Some platforms (e.g. Android's Bionic) have pthreads support available
1054 dnl without linking against libpthread. Check whether -lpthread is necessary
1055 dnl to use pthreads.
1056 dnl
1057 dnl Note that it is important that this happens before we AC_CHECK_LIB(thread)
1058 AC_MSG_CHECKING(whether -lpthread is needed for pthreads)
1059 AC_CHECK_FUNC(pthread_create,
1060     [
1061         AC_MSG_RESULT(no)
1062         need_lpthread=0
1063     ],
1064     [
1065         AC_CHECK_LIB(pthread, pthread_create,
1066             [
1067                 AC_MSG_RESULT(yes)
1068                 need_lpthread=1
1069             ],
1070             [
1071                 AC_MSG_RESULT([no pthreads support found.])
1072                 need_lpthread=0
1073             ])
1074     ])
1075 AC_DEFINE_UNQUOTED([NEED_PTHREAD_LIB], [$need_lpthread],
1076     [Define 1 if we need to link code using pthreads with -lpthread])
1077
1078 dnl ** pthread_setname_np is a recent addition to glibc, and OS X has
1079 dnl    a different single-argument version.
1080 AC_CHECK_LIB(pthread, pthread_setname_np)
1081 AC_MSG_CHECKING(for pthread_setname_np)
1082 AC_TRY_LINK(
1083 [
1084 #define _GNU_SOURCE
1085 #include <pthread.h>
1086 ],
1087 [pthread_setname_np(pthread_self(), "name");],
1088     AC_MSG_RESULT(yes)
1089     AC_DEFINE([HAVE_PTHREAD_SETNAME_NP], [1],
1090       [Define to 1 if you have the glibc version of pthread_setname_np]),
1091     AC_MSG_RESULT(no)
1092 )
1093
1094 dnl ** check for eventfd which is needed by the I/O manager
1095 AC_CHECK_HEADERS([sys/eventfd.h])
1096 AC_CHECK_FUNCS([eventfd])
1097
1098 dnl ** Check for __thread support in the compiler
1099 AC_MSG_CHECKING(for __thread support)
1100 AC_COMPILE_IFELSE(
1101   [ AC_LANG_SOURCE([[__thread int tester = 0;]]) ],
1102   [
1103    AC_MSG_RESULT(yes)
1104    AC_DEFINE([CC_SUPPORTS_TLS],[1],[Define to 1 if __thread is supported])
1105   ],
1106   [
1107    AC_MSG_RESULT(no)
1108    AC_DEFINE([CC_SUPPORTS_TLS],[0],[Define to 1 if __thread is supported])
1109   ])
1110
1111 dnl large address space support (see includes/rts/storage/MBlock.h)
1112 dnl
1113 dnl Darwin has vm_allocate/vm_protect
1114 dnl Linux has mmap(MAP_NORESERVE)/madv(MADV_DONTNEED)
1115 dnl FreeBSD, Solaris and maybe other have MAP_NORESERVE/MADV_FREE
1116 dnl (They also have MADV_DONTNEED, but it means something else!)
1117 dnl
1118 dnl Windows has VirtualAlloc MEM_RESERVE/MEM_COMMIT, however
1119 dnl it counts page-table space as committed memory, and so quickly
1120 dnl runs out of paging file when we have multiple processes reserving
1121 dnl 1TB of address space, we get the following error:
1122 dnl    VirtualAlloc MEM_RESERVE 1099512676352 bytes failed: The paging file is too small for this operation to complete.
1123 dnl
1124
1125 AC_ARG_ENABLE(large-address-space,
1126     [AC_HELP_STRING([--enable-large-address-space],
1127         [Use a single large address space on 64 bit systems (enabled by default on 64 bit platforms)])],
1128     EnableLargeAddressSpace=$enableval,
1129     EnableLargeAddressSpace=yes
1130 )
1131
1132 use_large_address_space=no
1133 if test "$ac_cv_sizeof_void_p" -eq 8 ; then
1134     if test "x$EnableLargeAddressSpace" = "xyes" ; then
1135         if test "$ghc_host_os" = "darwin" ; then
1136             use_large_address_space=yes
1137         elif test "$ghc_host_os" = "openbsd" ; then
1138             # as of OpenBSD 5.8 (2015), OpenBSD does not support mmap with MAP_NORESERVE.
1139             # The flag MAP_NORESERVE is supported for source compatibility reasons,
1140             # but is completely ignored by OS mmap
1141             use_large_address_space=no
1142         else
1143             AC_CHECK_DECLS([MAP_NORESERVE, MADV_FREE, MADV_DONTNEED],[],[],
1144                 [
1145                 #include <unistd.h>
1146                 #include <sys/types.h>
1147                 #include <sys/mman.h>
1148                 #include <fcntl.h>
1149             ])
1150             if test "$ac_cv_have_decl_MAP_NORESERVE" = "yes" &&
1151                 test "$ac_cv_have_decl_MADV_FREE" = "yes" ||
1152                 test "$ac_cv_have_decl_MADV_DONTNEED" = "yes" ; then
1153                     use_large_address_space=yes
1154             fi
1155         fi
1156     fi
1157 fi
1158 if test "$use_large_address_space" = "yes" ; then
1159    AC_DEFINE([USE_LARGE_ADDRESS_SPACE], [1], [Enable single heap address space support])
1160 fi
1161
1162 dnl ** Use MMAP in the runtime linker?
1163 dnl --------------------------------------------------------------
1164
1165 case ${TargetOS} in
1166     linux|linux-android|freebsd|dragonfly|netbsd|openbsd|kfreebsdgnu|gnu|solaris2)
1167         RtsLinkerUseMmap=1
1168         ;;
1169     darwin|ios)
1170         # Don't use mmap on powerpc/darwin as the mmap there doesn't support
1171         # reallocating. Reallocating is needed to allocate jump islands just
1172         # after each object image. Jumps to these jump islands use relative
1173         # branches which are limited to offsets that can be represented in
1174         # 24-bits.
1175         if test "$TargetArch" != "powerpc" ; then
1176             RtsLinkerUseMmap=1
1177         else
1178             RtsLinkerUseMmap=0
1179         fi
1180         ;;
1181     *)
1182         # Windows (which doesn't have mmap) and everything else.
1183         RtsLinkerUseMmap=0
1184         ;;
1185     esac
1186
1187 AC_DEFINE_UNQUOTED([RTS_LINKER_USE_MMAP], [$RtsLinkerUseMmap],
1188                    [Use mmap in the runtime linker])
1189
1190 dnl ** Have libdw?
1191 dnl --------------------------------------------------------------
1192 UseLibdw=NO
1193 USE_LIBDW=0
1194 AC_ARG_ENABLE(dwarf-unwind,
1195     [AC_HELP_STRING([--enable-dwarf-unwind],
1196         [Enable DWARF unwinding support in the runtime system via elfutils' libdw [default=no]])],
1197     [AC_CHECK_LIB(dw, dwfl_attach_state, [UseLibdw=YES], [UseLibdw=NO])],
1198     [UseLibdw=NO]
1199 )
1200 AC_SUBST(UseLibdw)
1201 if test $UseLibdw = "YES" ; then
1202         USE_LIBDW=1
1203 fi
1204 AC_DEFINE_UNQUOTED([USE_LIBDW], [$USE_LIBDW], [Set to 1 to use libdw])
1205
1206 dnl ** Have libnuma?
1207 dnl --------------------------------------------------------------
1208 HaveLibNuma=0
1209 AC_CHECK_HEADERS([numa.h numaif.h])
1210
1211 if test "$ac_cv_header_numa_h$ac_cv_header_numaif_h" = "yesyes" ; then
1212     AC_CHECK_LIB(numa, numa_available,HaveLibNuma=1)
1213 fi
1214 AC_DEFINE_UNQUOTED([HAVE_LIBNUMA], [$HaveLibNuma], [Define to 1 if you have libnuma])
1215
1216 dnl ** Documentation
1217 dnl --------------------------------------------------------------
1218 if test -n "$SPHINXBUILD"; then
1219     BUILD_MAN=YES
1220     BUILD_SPHINX_HTML=YES
1221     if test -n "$XELATEX"; then
1222         BUILD_SPHINX_PDF=YES
1223     else
1224         BUILD_SPHINX_PDF=NO
1225     fi
1226 else
1227     BUILD_MAN=NO
1228     BUILD_SPHINX_HTML=NO
1229     BUILD_SPHINX_PDF=NO
1230 fi
1231 AC_SUBST(BUILD_MAN)
1232 AC_SUBST(BUILD_SPHINX_HTML)
1233 AC_SUBST(BUILD_SPHINX_PDF)
1234
1235 LIBRARY_VERSION(base)
1236 LIBRARY_VERSION(Cabal, Cabal/Cabal)
1237 LIBRARY_VERSION(ghc-prim)
1238 LIBRARY_VERSION(ghc-compact)
1239 LIBRARY_ghc_VERSION="$ProjectVersion"
1240 AC_SUBST(LIBRARY_ghc_VERSION)
1241
1242 if grep '       ' compiler/ghc.cabal.in 2>&1 >/dev/null; then
1243    AC_MSG_ERROR([compiler/ghc.cabal.in contains tab characters; please remove them])
1244 fi
1245
1246 # Create the configuration for the Hadrian build system if it is present
1247 if test -e hadrian/cfg/system.config.in; then
1248     AC_CONFIG_FILES([hadrian/cfg/system.config])
1249 fi
1250
1251 # We got caught by
1252 #     http://savannah.gnu.org/bugs/index.php?1516
1253 #     $(eval ...) inside conditionals causes errors
1254 # with make 3.80, so warn the user if it looks like they're about to
1255 # try to use it.
1256 # We would use "grep -q" here, but Solaris's grep doesn't support it.
1257 print_make_warning=""
1258 checkMake380() {
1259     make_ver=`$1 --version 2>&1 | head -1`
1260     if echo "$make_ver" | grep 'GNU Make 3\.80' > /dev/null
1261     then
1262         print_make_warning="true"
1263     fi
1264     if echo "$make_ver" | grep 'GNU Make' > /dev/null
1265     then
1266         MakeCmd=$1
1267         AC_SUBST(MakeCmd)
1268     fi
1269 }
1270
1271 checkMake380 make
1272 checkMake380 gmake
1273
1274 AC_CONFIG_FILES([mk/config.mk mk/install.mk mk/project.mk compiler/ghc.cabal ghc/ghc-bin.cabal utils/runghc/runghc.cabal utils/gen-dll/gen-dll.cabal libraries/ghc-boot/ghc-boot.cabal libraries/ghc-boot-th/ghc-boot-th.cabal libraries/ghci/ghci.cabal settings docs/users_guide/ghc_config.py docs/index.html libraries/prologue.txt distrib/configure.ac])
1275 AC_OUTPUT
1276 [
1277 if test "$print_make_warning" = "true"; then
1278    echo
1279    echo "WARNING: It looks like \"$MakeCmd\" is GNU make 3.80."
1280    echo "This version cannot be used to build GHC."
1281    echo "Please use GNU make >= 3.81."
1282 fi
1283
1284 echo "
1285 ----------------------------------------------------------------------
1286 Configure completed successfully.
1287
1288    Building GHC version  : $ProjectVersion
1289           Git commit id  : $ProjectGitCommitId
1290
1291    Build platform        : $BuildPlatform
1292    Host platform         : $HostPlatform
1293    Target platform       : $TargetPlatform
1294 "
1295
1296 echo "\
1297    Bootstrapping using   : $WithGhc
1298       which is version   : $GhcVersion
1299 "
1300
1301 if test "x$CC_LLVM_BACKEND" = "x1"; then
1302     if test "x$CC_CLANG_BACKEND" = "x1"; then
1303         CompilerName="clang        "
1304     else
1305         CompilerName="llvm-gcc     "
1306     fi
1307 else
1308     CompilerName="gcc          "
1309 fi
1310
1311 echo "\
1312    Using (for bootstrapping) : $CC_STAGE0
1313    Using $CompilerName       : $CC
1314       which is version       : $GccVersion
1315    Building a cross compiler : $CrossCompiling
1316    Unregisterised            : $Unregisterised
1317    hs-cpp       : $HaskellCPPCmd
1318    hs-cpp-flags : $HaskellCPPArgs
1319    ar           : $ArCmd
1320    ld           : $LdCmd
1321    nm           : $NmCmd
1322    libtool      : $LibtoolCmd
1323    objdump      : $ObjdumpCmd
1324    ranlib       : $RanlibCmd
1325    windres      : $WindresCmd
1326    dllwrap      : $DllWrapCmd
1327    genlib       : $GenlibCmd
1328    Happy        : $HappyCmd ($HappyVersion)
1329    Alex         : $AlexCmd ($AlexVersion)
1330    Perl         : $PerlCmd
1331    sphinx-build : $SPHINXBUILD
1332    xelatex      : $XELATEX
1333
1334    Using LLVM tools
1335       clang : $ClangCmd
1336       llc   : $LlcCmd
1337       opt   : $OptCmd"
1338
1339 if test "$HSCOLOUR" = ""; then
1340 echo "
1341    HsColour was not found; documentation will not contain source links
1342 "
1343 else
1344 echo "\
1345    HsColour : $HSCOLOUR
1346 "
1347 fi
1348
1349 echo "\
1350    Tools to build Sphinx HTML documentation available: $BUILD_SPHINX_HTML
1351    Tools to build Sphinx PDF documentation available: $BUILD_SPHINX_PDF"
1352
1353 echo "----------------------------------------------------------------------
1354 "
1355
1356 echo "\
1357 For a standard build of GHC (fully optimised with profiling), type (g)make.
1358
1359 To make changes to the default build configuration, copy the file
1360 mk/build.mk.sample to mk/build.mk, and edit the settings in there.
1361
1362 For more information on how to configure your GHC build, see
1363    http://ghc.haskell.org/trac/ghc/wiki/Building
1364 "]